         TITLE ' IERROK - OS/360 SORT/MERGE - 360S-SM-023 02/10/65 '    00200013
*MODULE NAME:*** IERROK ***                                             00400013
         SPACE 2                                                        00600013
*STATUS: CHANGE LEVEL 000                                               00800013
         SPACE 2                                                        01000013
*MODULE FUNCTION/OPERATION: SORT PHASE DISK ALGORITHM.                  01200013
*   THE FUNCTION OF THIS MODULE IS TO CONTROL (VIA A TABLE) WHERE TO    01400013
*   WRITE THE NEXT STRING OF SEQUENCED DATA IN DISK AREAS. IT CHECKS    01600013
*   FOR ENDS OF AREA,IF NMAX IS EXCEEDED AND ACTS AS AN AREA MANAGER    01800013
*   FOR THE WRITE ROUTINE. IT DETERMINES IF PASSES OF PHASE 2 IS NEED-  02000013
*   ED AND MAY ABORT FOR CERTAIN UNUSUAL CONDITIONS.                    02200013
         SPACE 2                                                        02400013
*MACROS USED -                                                          02600013
         SPACE 1                                                        02800013
*   SMPPI                                                               03000013
         SPACE 2                                                        03200013
*ENTRY POINTS:                                                          03400013
         SPACE 1                                                        03600013
*        ENTRY IERROK              ENTRY FROM: IERRPB (WRITE)           03800013
*                                    CALLING SEQUENCE-                  04000013
*                                      L     RL,PPIALG+4                04200013
*                                      B     DISP,(0,RL)                04400013
*                                        DISP = 0 FOR END OF FILE       04600013
*                                             = 4 FOR EOA & NOT EOS     04800013
*                                             = 8 FOR END OF AREA & EOS 05000013
*                                             =12 FOR END OF SEQUENCE   05200013
*                                  ENTRY FROM: IERRPB (WRITE)           05400013
*                                    CALLING SEQUENCE-                  05600013
*                                      L     RL,PPIALG+4                05800013
*                                      BR    RO (RETURN ON WRITING      06000013
*                                                  DIRECTORY)           06200013
         SPACE 2                                                        06400013
*INPUT: PPI FIELDS REFERENCED-                                          06600013
         SPACE 1                                                        06800013
*   PPIWRT  PPIADSSC  PPIMRGMX  PPIPDWA                                 07000013
*   PPIDEB  PPIDSKED  PPINDSKA                                          07200013
         SPACE 2                                                        07400013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             07600013
         SPACE 1                                                        07800013
*    PPIBDSVA  PPIDIRAD  PPIMRGOP                                       08000013
*    PPIDEPHO  PPIENDAR                                                 08200013
         SPACE 2                                                        08400013
*EXTERNAL ROUTINES:                                                     08600013
         SPACE 1                                                        08800013
*        EXTRN IERRCV              SORT SYSTEM CONTROL                  09000013
*        EXTRN IERRPB              WRITE ROUTINE                        09200013
*        EXTRN IERDD1              DEBLOCK MODULE                       09400013
         SPACE 2                                                        09600013
*EXTERNAL PARAMETERS:                                                   09800013
         SPACE 1                                                        10000013
*        EXTRN IERRMA              MESSAGE MODULE                       10200013
*EXITS: NORMAL                                                          10400013
         SPACE 1                                                        10600013
*        IERRCV                    SORT SYSTEM CONTROL                  10800013
         SPACE 2                                                        11000013
*EXITS: ERROR                                                           11200013
         SPACE 1                                                        11400013
*        IERRCV                    SORT SYSTEM CONTROL                  11600013
         SPACE 2                                                        11800013
*TABLES/WORK AREAS:                                                     12000013
         SPACE 1                                                        12200013
*    A TABLE CALLED 'TABLE' IS USED TO CONTROL AREAS                    12400013
         SPACE 2                                                        12600013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  12800013
         SPACE 2                                                        13000013
*NOTES:                                                                 13200013
         SPACE 1                                                        13400013
*   THIS ROUTINE OPERATES IN A MANNER ANALOGOUS TO A BALANCED TAPE      13600013
*   ALGORITHM WITH A MINIMUM OF 3 AREAS(WORK TAPES) AND A MAXIMUM OF 6  13800013
         SPACE 2                                                        14000013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            14200013
         SPACE 1                                                        14400013
RA       EQU   0                   CONTENTS IN-  N/A                    14600013
*                                  USE- ADDRESS OF MESSAGE              14800013
*                                  CONTENTS OUT- N/A                    15000013
RB       EQU   1                   CONTENTS IN-  N/A                    15200013
*                                  USE- MESSAGE LENGTH & SYST PARAMETER 15400013
*                                  CONTENTS OUT- PARAMETER (PH2/3 CALL) 15600013
RC       EQU   2                   CONTENTS IN-  N/A                    15800013
*                                  USE- NOT USED                        16000013
*                                  CONTENTS OUT- N/A                    16200013
RD       EQU   3                   CONTENTS IN-  N/A                    16400013
*                                  USE- NOT USED                        16600013
*                                  CONTENTS OUT- N/A                    16800013
RE       EQU   4                   CONTENTS IN-  N/A                    17000013
*                                  USE- GENERAL WORK REGISTER           17200013
*                                  CONTENTS OUT- N/A                    17400013
RF       EQU   5                   CONTENTS IN-  N/A                    17600013
*                                  USE- GENERAL WORK REGISTER           17800013
*                                  CONTENTS OUT- N/A                    18000013
RG       EQU   6                   CONTENTS IN-  N/A                    18200013
*                                  USE- GENERAL WORK REGISTER           18400013
*                                  CONTENTS OUT- N/A                    18600013
RH       EQU   7                   CONTENTS IN-  N/A                    18800013
*                                  USE- GENERAL WORK REGISTER           19000013
*                                  CONTENTS OUT- N/A                    19200013
RI       EQU   8                   CONTENTS IN-  N/A                    19400013
*                                  USE- GENERAL WORK REGISTER           19600013
*                                  CONTENTS OUT- N/A                    19800013
RJ       EQU   9                   CONTENTS IN-  N/A                    20000013
*                                  USE- NOT USED                        20200013
*                                  CONTENTS OUT- N/A                    20400013
RK       EQU   10                  CONTENTS IN-  N/A                    20600013
*                                  USE- NOT USED                        20800013
*                                  CONTENTS OUT- N/A                    21000013
RL       EQU   11                  CONTENTS IN-  N/A                    21200013
*                                  USE- PROGRAM BASE ADDRESS REGISTER   21400013
*                                  CONTENTS OUT- N/A                    21600013
RM       EQU   12                  CONTENTS IN-  N/A                    21800013
*                                  USE- NOT USED                        22000013
*                                  CONTENTS OUT- N/A                    22200013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          22400013
*                                  USE- PPI REFERENCE,REGISTER SAVE     22600013
*                                    AREA                               22800013
*                                  CONTENTS OUT- ADDRESS OF PPI         23000013
RO       EQU   14                  CONTENTS IN-  N/A                    23200013
*                                  USE- BASE ADDRESS REGISTER FOR MSG.  23400013
*                                  CONTENTS OUT- RETURN ADDRESS         23600013
RP       EQU   15                  CONTENTS IN- N/A                     23800013
*                                  USE- ADDRESSING SSC                  24000013
*                                  CONTENTS OUT- ADDRESS OF SSC         24200013
         SPACE 2                                                        24400013
*START OF MODULE CODE PROPER:                                           24600013
         SPACE 2                                                        24800013
IERROK   CSECT                     MODULE BEGINNING                     25000013
*                                                                A27992 25100000
         USING *,RL                SET BASE RG                          25200013
         USING IERRCA,RN                                                25400013
         USING DIERRMA,RO                                               25600013
IERDOK   B     ROKEOF              OUTPUT END OF FILE                   25800013
         B     ROKEOA              END OF AREA,DETERMINED BY'WRITE'     26000013
         B     ROKEOASQ            END OF AREA+ SEQ,DET.BY'WRITE'       26200013
ROKEOSQ  L     RE,WPOINT           GET ADDR OF AN AREA IN TABLE         26400013
         L     RF,0(0,RE)          GET AREA KEY (EG.0,1,2,3,4,OR5)      26600013
         SLL   RF,1                CALC. DISPLC.(AREA KEY X CTR SIZE)   26800013
         LA    RG,PPISEQCT         GET ST PT OF COUNTERS                27000013
         LH    RH,0(RF,RG)         GET DATA FROM COUNTER                27200013
         LA    RH,1(0,RH)          INCRMT CTR                           27400013
         STH   RH,0(RF,RG)         RESTORE CTR TO PPI                   27600013
*       * DECRMT BLKG COUNTER - BLOCK OF ADDRS FILLED{ **************** 27800013
         L     RE,WBLKCT           GET DICTY BLKG CTR                   28000013
         BCT   RE,ROKDRBLK         DECRMT BLKG CTR/BLK FILLED{          28200013
*            * SV ADDR IN TBL-PUT DICTY ADDR IN PPI-MV DICTY BLK TO PPI 28400013
*  WRITE DICTY BLK OF ADDRS ******************************************* 28600013
         L     RE,WPOINT                                                28800013
         MVC   4(8,RE),PPIDEPHO    SV NXT SEQ IN TBL                    29000013
         MVC   PPIDIRAD(8),12(RE)  PUT NXT DICTY BLOCK ADDR IN PPI      29200013
         MVC   PPIPDWA(64),WCLBKAR    PUT DICTY BLKG AREA IN PPI        29400013
         L     RL,PPIWRT+4                                              29600013
         BAL   RO,12(0,RL)                                              29800013
*    * RESET DICTY BLKG CTR TO 8 ************************************** 30000013
         LA    RE,8                RESET BLKG CTR TO 8                  30200013
         ST    RE,WBLKCT           RESET BLKG CTR TO 8                  30400013
*    * TRACK OF DICTY FILLED{ ***************************************** 30600013
         L     RG,WPOINT           GET AREA ADDR FROM TABLE             30800013
ROK100   EQU   *                                                        30900017
         CLI   19(RG),X'1C'       IS RECORD CT ALREADY AT 28 (LST BLK)  31000013
         SPACE 2                                                        31040017
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS USING THE       31080017
*   2311 ALGORITHM. THE NEW INSTRUCTION WILL BE   CLI  19(RG),X'2C'     31120017
         SPACE 2                                                        31160017
         BNE   ROKSMTK             NO,BRANCH                            31200013
*    * GET PROPER ENDG ADDR IN PPI ************************************ 31400013
         L     RH,0(0,RG)          YES,TRACK IS FILLED.                 31600013
         SLL   RH,3                CALC.DISPLC(AREA X DSK ADDR SIZE -8) 31800013
         LA    RI,PPIENDAR         GET START.ADDR IN PPI                32000013
         AR    RI,RH               ADD DISPLC.                          32200013
*    * IS ANOTHER TRACK AVAILABLE ************************************* 32400013
         CLC   4(3,RI),PPIDEPHO+4  HAS SEQ.AREA REACHED END ADDR IN PPI 32600013
         BNH   ROKNOTRK            YES,NO TRACKS AVAILABLE              32800013
*  RESET RCD CT FOR NXT WRITE OF DICTY (IN TBL) = 1 ---REGARDLESS       33000013
         MVI   19(RG),X'01'                                             33200013
         CLI   6(RI),X'00'         IS TRACK NO.= 0{                     33400013
         BNE   ROKDECTK            NO, BRANCH AND REDUCE TRACK NO.      33600013
         SPACE 2                                                        33800013
* SUPPLY TABLE,(NEW DICTY ADDR),USING ENDAR IN PPI AND ADDING 1 TRACK   34000013
*  TO IT SO AS TO LEAVE THE 1 TRACK BUFFER ALWAYS OPEN (AT ASSIGNMENT   34200013
*  TIME THE REAL ENDAR IS PUSHED BACK BY 2 TRACKS)SO NOW BY USING ENDAR 34400013
*  AND ADDING 1 TRACK, WE ARE POSITIONED READY TO WRITE THE NXT OPEN    34600013
*  TRACK OF DIRECTORY EG. TRK 8=LAST TRACK FOR STRINGS,TRK 9=EOF BUFFER 34800013
*  AND TRACK 10=DIRECTORY ---- WHEN TRK 10 IS FULL,ALL 3 TRACKS SHIFT   35000013
*  DOWN 1 IN THE FOLLOWING MANNER:                                      35200013
*   1.DIRCTY ADDR (IN TABLE) IS REDUCED 1 TRACK BY'ADDING 1 TRACK'TO    35400013
*     THE ENDAR IN PPI (SINCE IT IS ALREADY 2 TRACKS AWAY FROM THE      35600013
*     DIRCTY TRACK JUST FILLED)AND CLOBBERING OLD DIRCTY ADDR IN TABLE  35800013
*     TO PROVIDE A NEW (THE NEXT OPEN)TRACK  TO WRITE DIRCTY IN.        36000013
*   2.THEN THE ENDAR IS REDUCED BY 1 TRACK SO THAT PRIOR TO THE FIRST   36200013
*     WRITE IN THE NEW DICTY TRACK (USING ABOVE EXP.)THE TRACKS ARE     36400013
*     ASSIGNED: TRK 7=LAST TRACK FOR STRINGS (ENDAR), TRK 8=EOF BUFFER, 36600013
*     TRACK 9=NEW EMPTY DIRCTY TRK,AND TRK 10=OLD FILLED DICTY TRK.     36800013
         SPACE 2                                                        37000013
* USING ADDR AT ENDAR,ADD 1 TO HEAD NO.AND PLUG INTO TABLE (NEW DIRCTY) 37200013
         SR    RH,RH               CLEAR REG.                           37400013
         IC    RH,6(0,RI)          GET HD NO. FROM PPI (ENDAR)          37600013
         LA    RH,1(0,RH)          ADD 1                                37800013
         STC   RH,18(0,RG)         STORE IN TABLE (NEW DICTRY)          38000013
*  DECRM'T ENDAR BY 1 TRACK (DECRM'T CYL BY 1, RESET TRK=9)             38200013
         SR    RF,RF                                                    38400013
         IC    RF,4(0,RI)         GET CYL NO.                           38600013
         BCT   RF,ROKBACK         REDUCE BY 1                           38800013
         B     ROKABORT            SORT CAPACITY REACHED -ABORT JOB     39000013
         SPACE 2                                                        39200013
ROKBACK  STC   RF,4(0,RI)         RESTORE NEW CYL NO. TO ENDAR IN PPI   39400013
         MVI   6(RI),X'09'        RESTORE ENDAR TRACK NO. TO 9          39600013
         SPACE 2                                                        39640017
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS USING THE       39680017
*   2311 ALGORITHM. THE NEW INSTRUCTION WILL BE   MVI  6(RI),X'13'      39720017
         SPACE 2                                                        39760017
         B     ROKGOB              GO TO INCREMET TABLE PTR             39860018
         SPACE 2                                                        40000013
ROKDECTK CLI   6(RI),X'09'        IS TRACK NO. IN ENDAR =9?             40200013
         SPACE 2                                                        40240017
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS USING THE       40280017
*   2311 ALGORITHM. THE NEW INSTRUCTION WILL BE   CLI  6(RI),X'13'      40320017
         SPACE 2                                                        40360017
         BE    ROKHNINE           YES,RESET TRK=0,ENDAR CYL+1 INTO TBL  40400013
* USING ADDR AT ENDAR,ADD 1 TO HEAD NO.AND PLUG INTO TABLE (NEW DIRCTY) 40600013
         SR    RH,RH               CLEAR REG.                           40800013
         IC    RH,6(0,RI)          GET HD NO. FROM PPI (ENDAR)          41000013
         LA    RH,1(0,RH)          ADD 1                                41200013
         STC   RH,18(0,RG)         STORE IN TABLE (NEW DICTRY)          41400013
ROK200   EQU   *                                                        41500017
         CLI   6(RI),X'08'        ENDAR HD. NO. = 8                     41600013
         SPACE 2                                                        41640017
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS USING THE       41680017
*   2311 ALGORITHM. THE NEW INSTRUCTION WILL BE   CLI  6(RI),X'12'      41720017
         SPACE 2                                                        41760017
         BNE   ROKRETN2            GO TO DECRMENT TRK NO.               41860018
*  DECRM'T CYL NO. IN TBL BY 1 (NOW EQUAL TO CYL NO. IN ENDAR)          42000013
         MVC   16(1,RG),4(RI)                                           42200013
         B     ROKRETN2            GO TO DECREMENT TRK NO.              42400018
         SPACE 3                                                        42600013
ROKHNINE MVI   18(RG),X'00'        SET HEAD NO.=ZERO IN TABLE           42800013
ROKRETN2 IC    RG,6(0,RI)         GET ENDAR TRK NO. AND DECRM'T BY 1    43000013
         LA    RF,1                CONSTANT 1                           43200013
         SR    RG,RF               DECR. TRACK NO.BY 1                  43400013
         STC   RG,6(0,RI)          RESTORE TRK NO. IN PPI               43600013
         B     ROKGOB              GO TO INCREMENT TABLE PTR            43800018
*                                                                       44000013
*  INCRM'T RCD COUNT FOR NXT WRITE ON SAME TRACK( IN TABLE)             44200013
ROKSMTK  IC    RH,19(0,RG)                                              44400013
         LA    RH,1(0,RH)                                               44600013
         STC   RH,19(0,RG)                                              44800013
         B     ROKGOB              GO TO INCREMENT TABLE PTR            45000018
*                                                                       45200013
*    *  BLOCK THE NXT SEQ ADDR PASSED BY WRITE ************************ 45400013
ROKDRBLK ST    RE,WBLKCT           RESTORE DICTY BLKG CTR.              45600013
         LA    RF,8                CALC.DISPLC.TO REACH PROPER ADDR IN  45800013
         SR    RF,RE                 DICTY BLOCK,TO FILL NXT BLOCK      46000013
         SLL   RF,3                MLTPY TIMES ADDR SIZE (8)            46200013
         LA    RG,WCLBKAR          GET ST PT OF DICTY BLKG AREA         46400013
         AR    RG,RF               DETERMINE WHERE TO INSERT NXT SEQ    46600013
*                                    ADDR IN BLOCK OF DIRECTORY         46800013
         MVC   0(8,RG),PPIDEPHO    INSERT ADDR.                         47000013
*    * DEBLOCK ******************************************************** 47200013
ROKDEBL  L     RL,PPIDEB+4         SET BASE REGISTER TO DEBLOCK ST PT   47400013
         B     8(RL)               GO TO DEBLOCK                        47600013
*                                                                       47800013
*    * INCREMENT TABLE POINTER **************************************** 48000013
ROKGOB   L     RE,WPOINT           INCREMT TABLE POINTER                48200013
         LA    RE,20(0,RE)         INCREMT TABLE POINTER                48400013
         ST    RE,WPOINT           INCREMT TABLE POINTER                48600013
* C4 * EXCEED LIMIT OF TABLE{****************************************** 48800013
         CL    RE,WTBLLIMT         AT END OF TABLE{                     49000013
         BE    ROKSETPT            YES,GO TO RESET POINTER              49200013
*    * STORE ADDR OF WHERE TO RECORD FIRST OF NXT SEQUENCES *********** 49400013
ROKNXT1  L     RE,WPOINT                                                49600013
         MVC   PPIDEPHO(8),4(RE)   STORE ADDR OF WHERE TO WRITE NEXT SQ 49800013
*                                    INTO PPI                           50000013
*    * BLOCK ADDR OF FIRST SEQUENCE *********************************** 50200013
         MVC   WCLBKAR(8),4(RE)                                         50400013
*                                    DICTY BLOCK                        50600013
*    * IS SWITCH ON{ ************************************************** 50800013
         TM    KSWA7E4,X'01'       DID LAST 'WRITE'HAVE AREA ENOUGH{    51000013
         BO    ROKDEBL            YES,SW IS ON,GET NXT SQ FR DEBLK RTN  51200013
*   * TURN SWITCH ON ************************************************** 51400013
         OI    KSWA7E4,X'01'      NO,TURN ON SW, WRITE SEQ IN NXT AREA  51600013
*   * GO TO WRITE ***************************************************** 51800013
         L     RL,PPIWRT+4                                              52000013
         BR    RL                  LINK TO BLOCK AFTER WRITE DIRECTORY  52200013
*                                                                       52400013
* C5 * SET POINTER TO FST POS. IN TABLE ******************************* 52600013
ROKSETPT LA    RG,TABLE            SET POINTER TO FIRST POS. OF SORT-   52800013
         ST    RG,WPOINT             TABLE                              53000013
         B     ROKNXT1             GO BACK TO MAIN FLOW                 53200013
*                                                                       53400013
*                                                                       53600013
*          * OUTPUT END OF FILE *************************************** 53800013
*    * UPDATE COUNTER OF SEQUENCES FOR CURRENT AREA ******************* 54000013
ROKEOF   L     RE,WPOINT           GET ADDR OF AN AREA IN TABLE         54200013
         L     RF,0(0,RE)          GET AREA KEY                         54400013
         SLL   RF,1                CALC DISPLC IN CTR AREA IN PPI       54600013
         LA    RG,PPISEQCT         GET ST PT OF CTRS                    54800013
         LH    RH,0(RF,RG)         GET NO.FR CTR                        55000013
         LA    RH,1(0,RH)          INCRMT CTR                           55200013
         STH   RH,0(RF,RG)         RESTORE CTR TO PPI                   55400013
*    * PUT DIRECTORY ADDR INTO PPI ************************************ 55600013
         MVC   PPIDIRAD(8),12(RE)                                       55800013
*    * MOVE BLKG AREA TO PPI ****************************************** 56000013
         MVC   PPIPDWA(64),WCLBKAR                                      56200013
*    * GO TO WRITE BLOCK OF DICTY ADDRS.                                56400013
         L     RL,PPIWRT+4                                              56600013
         BAL   RO,12(0,RL)         GO TO WRITE BLK OF DICTY ADDRS.      56800018
*    * SUM SEQUENCE COUNTERS ****************************************** 57000013
         LH    RI,PPINDSKA                                              57200013
         SR    RE,RE                                                    57400013
         LA    RG,PPISEQCT                                              57600013
ROKLOOPD LH    RF,0(0,RG)          GET DATA IN CTR                      57800013
         AR    RE,RF               SUM IN RE                            58000013
         LA    RG,2(0,RG)          BUMP TO NXT CTR                      58200013
         BCT   RI,ROKLOOPD         ADDED ALL CTRS{ NO,LOOP              58400013
*    * RESTORE END ADDRS TO PPI FROM PPI SAVE AREA ******************** 58600013
         MVC   PPIENDAR(48),PPIDSKED                                    58800013
         LH    RH,PPIMRGMX                                              59000013
         LA    RH,1(0,RH)         PLUS ONE                              59200013
         STC   RH,PPIBDSVA                                              59400013
*    * SUM VS M ******************************************************* 59600013
         CH    RE,PPIMRGMX                                              59800013
         BH    ROKGOF              GO TO CLOSE ROUTINE                  60000018
         STH   RE,PPIMRGOP                                              60200013
*    * SET INDICATOR TO PHASE 3 *************************************** 60400013
         L     RP,PPIADSSC                                              60600013
         LA    RB,4                RETURN TO SSC CALLING FOR PHASE 3    60800013
         BAL   RO,20(0,RP)         GO TO SSC                            61000018
*                                                                       61200013
*    * CLOSE ROUTINE ************************************************** 61400013
ROKGOF   L     RP,PPIADSSC                                              61600013
         LA    RB,0                RETURN TO SSC CALLING FOR PHASE 2    61800013
         BAL   RO,20(0,RP)         GO TO SSC                            62000018
*          * END OF AREA AS DETERMINED BY WRITE ROUTINE *************** 62200013
*    * TURN SWITCH A7-E4 OFF ****************************************** 62400013
ROKEOA   NI    KSWA7E4,X'00'                                            62600013
*    * UPDATE COUNT OF SEQUENCES FOR CURRENT AREA ********************* 62800013
ROKEOASQ L     RE,WPOINT                                                63000013
         L     RF,0(0,RE)                                               63200013
         SLL   RF,1                                                     63400013
         LA    RG,PPISEQCT                                              63600013
         LH    RH,0(RF,RG)                                              63800013
         LA    RH,1(0,RH)                                               64000013
         STH   RH,0(RF,RG)                                              64200013
*    * PUT DIRECTORY ADDR INTO PPI ************************************ 64400013
         MVC   PPIDIRAD(8),12(RE)                                       64600013
*    * MOVE BLKG AREA TO PPI ****************************************** 64800013
         MVC   PPIPDWA(64),WCLBKAR                                      65000013
*    * GO TO WRITE BLOCK OF DICTY ADDRS ******************************* 65200013
         L     RL,PPIWRT+4                                              65400013
         BAL   RO,12(0,RL)         GO TO WRITE BLK OF DICTY ADDRS       65600018
*    * RESET DICTY BLKG CTR TO 8 ************************************** 65800013
         LA    RE,8                                                     66000013
         ST    RE,WBLKCT                                                66200013
*    * LAST AREA{-CHECK LIMIT. **************************************** 66400013
ROKNOTRK LA    RF,20                                                    66600013
         LA    RE,TABLE                                                 66800013
         ALR   RE,RF                                                    67000013
         CL    RE,WTBLLIMT                                              67200013
         BE    ROKABORT            NO MORE AREAS-ABORT JOB              67400013
         B     ROKGOH              GO TO CHECK LIMIT OF SORT TABLE      67600018
*SORT CAPACITY REACHED                                                  67800013
         SPACE 1                                                        68000013
ROKABORT L     RO,PPIRMA+4                                              68200013
         LM    RA,RB,MSGP1A02                                           68400013
         L     RP,PPIADSSC                                              68600013
         BAL   RO,12(0,RP)         ABORT                                68800018
         SPACE 1                                                        69000013
*APROX RCD CNT IS PPICOUNT -G - B, WHERE G AND B ARE MAX. VALUES.  SO   69200013
*   IF CNT TURNS NEGATIVE, CNT IS SET TO PPICOUNT-G+B OR JUST B.        69400013
*   THIS NEGATIVE CONDITION IS MOST LIKELY IF THE BLOCK BEING WRITTEN   69600013
*   OUT IS SHORT AND/OR RECORD FORMAT IS VARIABLE.                      69800013
         SPACE 1                                                        70000013
         L     RB,PPICOUNT         NO. RCD. READ IN MINUS G             70200013
         A     RB,PPIINSCT         ADD NO. OF INSERTED RECORDS   A27992 70260000
         S     RB,PPIDELCT         SUBTRACT NO. DELETED RECORDS  A27992 70320000
         S     RB,PPISRTG            G - MAX. NO. OF RCDS. IN TREE      70400013
         LH    RP,PPISRTBL           B - F = NO. RCDS/BLOCK             70600013
         TM    PPISW1,X'80'              V = BYTES/BLOCK                70800013
         BO    ROI031              GO TO CHECK CNT FOR NEG              71000018
         SPACE 1                                                        71200013
         LH    RA,PPIRCDL4         B / MIN. RCD. LENGTH = MAX. NO.      71400013
         SR    RO,RO                                                    71600013
         DR    RO,RA                 RCDS. IN BLOCK                     71800013
ROI031   CR    RB,RP               CHECK TO MAKE SURE CNT ISN'T         72000013
         BH    ROI032                NEGATIVE                           72200013
         SPACE 1                                                        72400013
         AR    RB,RP               ADD B TO CNT                         72600013
         CR    RB,RP               IS CNT STILL NEG. -IF YES,           72800013
         BNL   ROI033              GO TO SET CNT FOR PRINTING           73000018
         SPACE 1                                                        73200013
         LR    RB,RP               SET CNT TO B                         73400013
         B     ROI033              GO TO SET CNT FOR PRINTING           73600018
         SPACE 2                                                        73800013
ROI032   SR    RB,RP               APROX. RCD CNT = PPICOUNT -G -B      74000013
ROI033   CVD   RB,PPIWKARE           USUALLY - SET UP CNT FOR           74200013
         UNPK  PPIWKARE+8(8),PPIWKARE(8) PRINTING                       74400013
         OI    PPIWKARE+15,X'F0'                                        74600013
         SPACE 2                                                        74800013
         L     RO,PPIRMA+4                                              75000013
         LM    RA,RB,MSGP1A06                                           75200013
         MVC   MSGP1R06+24(7),PPIWKARE+9                                75400013
         L     RP,PPIRCV+4         PRINT MESSAGE - APROX RCD CNT        75600013
         BAL   RO,12(0,RP)         GO TO PRINT MESSAGE                  75800018
         SPACE 1                                                        76000013
         L     RP,PPIADSSC                                              76200013
         B     16(0,RP)            GO TO SSC                            76400018
*    * LIMIT OF SORT TABLE{ ******************************************* 76600013
ROKGOH   L     RE,WPOINT                                                76800013
         L     RG,WPOINT                                                77000013
         LA    RG,20(0,RG)                                              77200013
         CL    RG,WTBLLIMT                                              77400013
         BE    ROKRESET            YES,RESET POINTER TO BEG. POS.       77600013
*    * PUT LIMIT PORTION OF SORT TABLE IN FILLED AREA'S POS. ********** 77800013
         L     RF,WTBLLIMT                                              78000013
         LA    RG,20    MT                                              78200013
         SLR   RF,RG                                                    78400013
         MVC   0(20,RE),0(RF)                                           78600013
*    * DECREMT LIMIT OF SORT TABLE BY 1 ******************************* 78800013
ROKGOG   L     RF,WTBLLIMT                                              79000013
         LA    RE,20                                                    79200013
         SLR   RF,RE                                                    79400013
         ST    RF,WTBLLIMT                                              79600013
         B     ROKNXT1             GO TO ST ADDR OF WHERE TO WT NXT SEQ 79800018
*                                                                       80000013
*    * RESET POINTER TO FIRST POS. IN SORT TABLE ********************** 80200013
ROKRESET LA    RG,TABLE                                                 80400013
         ST    RG,WPOINT                                                80600013
         B     ROKGOG              GO TO DECREMENT LIMIT OF SORT TABLE  80800018
         EJECT                                                          81000013
         DS    0F                                                       81200013
WPOINT   DC    X'00000000'         SET UP POINTER                       81400013
         DS    0F                                                       81600013
WBLKCT   DC    X'00000008'         SET UP DIRECTORY BLK CTR.            81800013
         DS    0F                                                       82000013
WCLBKAR  DS    16F                 DICTY BLOCKING AREA=64 BYTES         82200013
         DS    0F                                                       82400013
WTBLLIMT DC    X'00000000'         SET UP TABLE LIMIT POINTER           82600013
         DS    0F                                                       82800013
KSWA7E4  DC    X'01'              SWITCH A7-E4 NORMALLY ON              83000013
         DS    0F                                                       83200013
TABLE    DC    X'00000000'         SET UP TABLE -FIRST AREA             83400013
         DS    4F                  SET UP TABLE -FIRST AREA             83600013
         DC    X'00000001'         SET UP TABLE -SECOND AREA            83800013
         DS    4F                  SET UP TABLE -SECOND AREA            84000013
         DC    X'00000002'         SET UP TABLE -THIRD AREA             84200013
         DS    4F                  SET UP TABLE -THIRD AREA             84400013
         DC    X'00000003'         SET UP TABLE -FOURTH AREA            84600013
         DS    4F                  SET UP TABLE -FOURTH AREA            84800013
         DC    X'00000004'         SET UP TABLE -FIFTH AREA             85000013
         DS    4F                  SET UP TABLE -FIFTH AREA             85200013
         DS    0F                                                       85400013
         EJECT                                                          85600013
DIERRMA  DSECT                                                          85800013
*                                                                       86000013
*                                                                       86200013
* MODULE NAME ***IERRMA***                                              86400013
*                                                                       86600013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        86800013
* PHASE 1 RUNNING PROGRAM.                                              87000013
         SPACE 1                                                        87200013
*                                                                       87400013
         COPY  RMAMAIN                                                  87600013
         EJECT                                                          87800013
         SMPPI                                                          88000013
         END                                                            88200013
