         TITLE 'IERROP - OS/360 SORT/MERGE - 360-SM-023   05/06/65'     00100013
*MODULE NAME:*** IERROP ***                                             00200013
         SPACE 2                                                        00300013
*STATUS: CHANGE LEVEL 000                                               00400013
         SPACE 2                                                        00500013
*MODULE FUNCTION/OPERATION: PHASE 2 & 3 1 TO  16 WAY MERGE NETWORK.     00600013
*   THE FUNCTION OF THIS MODULE IS TO MERGE FIXED OR VARIABLE LENGTH    00700013
*   RECORDS IN ASCENDING OR DECENDING SEQUENCES FOR PHASE 2 AND 3 .     00800013
*   IERROP INITIALLY SEQUENCES THE INPUT RECORDS IN PHASE TO PHASE      00900013
*   INFORMATION AREA,CUTBACKS THE NETWORK FOR SPECIFIED MERGE ORDER     01000013
*   AND THEN UTILIZES A BINARY INSERTION TECHNIQUE. THIS IS ACCOMPLISH  01100013
*   ED USING THE ADDRESSES OF THE RECORDS IN GENERAL REGISTERS RE THRU  01200013
*   RK. THE LOW ORDER 3 BYTES OF THE REGISTER CONTAIN THE ADDRESS OF    01300013
*   THE RECORD. THE HIGH ORDER BYTE HAS THE FILE IDENTIFICATION FOR THE 01400013
*   DEBLOCK ROUTINE                                                     01500013
         SPACE 2                                                        01600013
*MACRO'S USED:                                                          01700013
         SPACE 1                                                        01800013
*USED AS A DSECT IN - IERAOP                                            01900013
*                                                                       02000013
*                                                                       02100013
*MACROS USED -                                                          02200013
         SPACE 2                                                        02300013
*ENTRY POINTS:                                                          02400013
         SPACE 1                                                        02500013
*        ENTRY IERROP              ENTRY FROM: DEBLOCK OR ALGORITHM     02600013
*                                    CALLING SEQUENCE-                  02700013
*                                      L    15,PPINET+4                 02800013
*                                      B    DISP(15)                    02900013
         SPACE 2                                                        03000013
*INPUT: PPI FIELDS REFERENCED-                                          03100013
         SPACE 1                                                        03200013
*   PPIADSSC    PPIMRGMX  PPIDOUA  PPISW1   PPIBLK2                     03300013
*   PPIDOOBA    PPIPDWA   PPIPSVA  PPIBLK   PPIRMC                      03400013
         SPACE 2                                                        03500013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             03600013
         SPACE 1                                                        03700013
*   PPISW1                                                              03800013
         SPACE 2                                                        03900013
*EXTERNAL ROUTINES:                                                     04000013
         SPACE 1                                                        04100013
*        EXTRN IERRMC              MESSAGE MODULE                       04200013
*        EXTRN IERDB2              BLOCK ROUTINE PHASE 2                04300013
*        EXTRN IERDB34             BLOCK ROUTINE PHASE 3                04400013
         SPACE 2                                                        04500013
*EXTERNAL PARAMETERS:                                                   04600013
         SPACE 1                                                        04700013
*        N/A                                                            04800013
*EXITS: NORMAL                                                          04900013
         SPACE 1                                                        05000013
*        IERDB2                    PHASE TWO BLOCK ROUTINE              05100013
*        IERDB34                   PHASE THREE BLOCK ROUTINE            05200013
         SPACE 2                                                        05300013
*EXITS: ERROR                                                           05400013
         SPACE 1                                                        05500013
*        IERRMC                    ERROR MESSAGE MODULE                 05600013
         SPACE 2                                                        05700013
*TABLES/WORK AREAS:                                                     05800013
         SPACE 1                                                        05900013
*   WORK AREA STARTING AT ROPMRGAU SAVES ADDRESSES OF FIRST 7 RECORDS   06000013
*   WORK AREA STARTING AT ROPMRGAL SAVES ADDRESSES OF LAST  7 RECORDS   06100013
         SPACE 2                                                        06200013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  06300013
         SPACE 2                                                        06400013
*NOTES: N/A                                                             06500013
         SPACE 1                                                        06600013
         SPACE 2                                                        06700013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            06800013
         SPACE 1                                                        06900013
RA       EQU   0                   CONTENTS IN- N/A                     07000013
*                                  USE- GENERAL WORK REGISTER           07100013
*                                  CONTENTS OUT- N/A                    07200013
RB       EQU   1                   CONTENTS IN- N/A                     07300013
*                                  USE- SYSTEM PARAMETER REGISTER       07400013
*                                  CONTENTS OUT- N/A                    07500013
RC       EQU   2                   CONTENTS IN- N/A                     07600013
*                                  USE- GET PUT REGISTER                07700013
*                                  CONTENTS OUT- N/A                    07800013
RD       EQU   3                   CONTENTS IN- WINNER + NEXT REC REG   07900013
*                                  USE- WINNER + NEXT REC REQ           08000013
*                                  CONTENTS OUT- WINNER + NEXT REC REG  08100013
RE       EQU   4                   CONTENTS IN- MERGE NETWORK REGISTER  08200013
*                                  USE- MERGE NETWORK REGISTER ITEM 9   08300013
*                                  CONTENTS OUT- MERGE NETWORK REGISTER 08400013
RF       EQU   5                   CONTENTS IN- MERGE NETWORK REGISTER  08500013
*                                  USE- MERGE NETWORK REGISTER ITEM 10  08600013
*                                  CONTENTS OUT- MERGE NETWRK REGISTER  08700013
RG       EQU   6                   CONTENTS IN- MERGE NETWORK REGISTER  08800013
*                                  USE- MERGE NETWORK REGISTER ITEM 11  08900013
*                                  CONTENTS OUT-MERGE NETWORK REGISTER  09000013
RH       EQU   7                   CONTENTS IN- MERGE NETWORK REGISTER  09100013
*                                  USE- MERGE NETWORK REGISTER ITEM 12  09200013
*                                  CONTENTS OUT- MERGE NETWORK REGISTER 09300013
RI       EQU   8                   CONTENTS IN-MERGE NETWORK REGISTER   09400013
*                                  USE- MERGE NETWORK REGISTER ITEM 13  09500013
*                                  CONTENTS OUT- MERGE NETWORK REGISTER 09600013
RJ       EQU   9                   CONTENTS IN- MERGE NETWORK REGISTER  09700013
*                                  USE- MERGE NETWORK REGISTER ITEM 14  09800013
*                                  CONTENTS OUT- MERGE NETWORK REGISTER 09900013
RK       EQU   10                  CONTENTS IN- MERGE NETWORK REGISTER  10000013
*                                  USE- MERGE NETWORK REGISTER ITEM 15  10100013
*                                  CONTENTS OUT- MERGE NETWORK REGISTER 10200013
RL       EQU   11                  CONTENTS IN- N/A                     10300013
*                                  USE- PROGRAM BASE ADDRESS            10400013
*                                  CONTENTS OUT- N/A                    10500013
RM       EQU   12                  CONTENTS IN- EQUALS ROUTINE BASE     10600013
*                                  USE- EQUALS ROUTINE BASE ADDRESS     10700013
*                                  CONTENTS OUT- EQUALS ROUTINE BASE    10800013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          10900013
*                                  USE- PPI REFERENCE,REGISTER SAVE     11000013
*                                    AREA                               11100013
*                                  CONTENTS OUT- ADDRESS OF PPI         11200013
RO       EQU   14                  CONTENTS IN - MESSAGE MODULE ADDRESS 11300013
*                                  USE- MESSAGE MODULE BASE ADDRESS REG 11400013
*                                  CONTENTS OUT- MESSAGE MODULE ADDRESS 11500013
RP       EQU   15                  CONTENTS IN- SORT SYSTEM CONTROL     11600013
*                                  USE- SORT SYSTEM INTERFACE REGISTER  11700013
*                                  CONTENTS OUT- SORT SYSTEM CONTROL    11800013
         SPACE 2                                                        11900013
*START OF MODULE CODE PROPER:                                           12000013
         SPACE 2                                                        12100013
IERROP   CSECT                                                          12200013
         USING *,RL                PROGRAM BASE                         12300013
         USING IERRCA,RN           PPI BASE                             12400013
         USING DIERRMC,RO          MESSAGE MODULE BASE                  12500013
IERDO1   B     ROPSINIT            READ PRIME ENTRY BR TO INITIALIZAT   12600013
         B     ROPCUTEN            READ + ALGORITHM ENTRY BR TO CUTBACK 12700013
*    NETWORK ENTRANCE SWITCH                                            12800013
         SPACE 1                                                        12900013
ROPNTENS BC    0,ROPLF8            FOR MRG ORD GT 8, FALL THRU          13000013
         SPACE 1                                                        13100013
*    DETERMINATION OF WHICH HALF OF MRG NTWK RCDS THE NEW RCD MUST CMP  13200013
         SPACE 1                                                        13300013
         L     RC,ROPMRGAM         ADDR OF ITEM 8                       13400013
IERROPWH CLC   0(1,RD),0(RC)       CMP NEW ITEM WITH ITEM 8             13500013
         BNE   ROPWHB              IF EQUAL GO TO EQUALS RTN            13600013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       13700013
         SPACE 1                                                        13800013
*    THIS INSTR IS BC 10/12 DEPENDING ON THE INPUT SEQUENCE             13900013
         SPACE 1                                                        14000013
ROPWHB   BC    12,ROPLF8           IF NEW GT / LT ITEM 8, FALL THRU     14100013
ROPLF16  LM    0,0,ROPMRGAL        LOAD NTWK REG WITH THOSE NECESSARY   14200013
*                                  RCD FROM ITEMS 9 THRU 15. INSTR IS   14300013
*                                  SET BY THE CUTBACK RTN               14400013
         SPACE 1                                                        14500013
*    PARTIAL NETWORK FOR CMP NEW AGAINST ITEMS 9 THRU 15                14600013
         SPACE 1                                                        14700013
ROPPNELA B     IERROPL4            PARTIAL NTWK ENTR SWITCH SET BY      14800013
*                                  CUTBACK RTN                          14900013
         SPACE 1                                                        15000013
*    ENTRANCE FOR A 14,15,16 WAY MERGE                                  15100013
         SPACE 1                                                        15200013
IERROPL4 CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 12        15300013
         BNE   ROP12B              IF EQUAL GO TO EQUALS RTN            15400013
         LR    RC,RH               LOAD EQ RTN COMPARE REG WITH ITEM 12 15500013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       15600013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             15700013
ROP12B   BH    IERROC14            IF HI/LO GO TO CMP ITEM 14 OR 13     15800013
         SPACE 1                                                        15900013
*    ENTRANCE FOR 11,12,13 WAY MERGE                                    16000013
         SPACE 1                                                        16100013
IERROPL2 CLC   0(1,RD),0(RF)       COMPARE NEW ITEM WITH ITEM 10        16200013
         BNE   ROP10B              IF EQUAL GO TO EQUALS RTN            16300013
         LR    RC,RF               LOAD EQ RTN COMPARE REG WITH ITEM 10 16400013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       16500013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             16600013
ROP10B   BH    IERROC11            IF HI/LO GO TO CMP ITEM 11,12/UPDATE 16700013
         SPACE 1                                                        16800013
*    ENTRANCE FOR A 10 WAY MERGE                                        16900013
         SPACE 1                                                        17000013
IERROPL1 CLC   0(1,RD),0(RE)       COMPARE NEW ITEM WITH ITEM 9         17100013
         BNE   ROP9B               IF EQUAL GO TO EQUALS RTN            17200013
         LR    RC,RE               LOAD EQ RTN COMPARE REG WITH ITEM 9  17300013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       17400013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             17500013
ROP9B    BH    ROPMOV9             INSERT ITEM IN COLLATING SEQUENCE    17600018
         SPACE 1                                                        17700013
*    ENTRANCE FOR A 9 WAY MERGE AND NEW ITEM COLLATES AFT ITEM 8        17800013
         SPACE 1                                                        17900013
ROP9WMRG LR    RC,RD                                                    18000013
         LM    RD,RK,ROPMRGAU                                           18100013
         STM   RE,RK,ROPMRGAU                                           18200013
         ST    RC,ROPMRGAM                                              18300013
         SPACE 1                                                        18400013
*    PUTTING OUT THE NETWORK WINNER  CHART OG                           18500013
*    SEQUENCE CHECKING IS NOT NECESSARY                                 18600013
*    THE ASSIGNMENT RTN SETS THE BRANCH INSTR ACCORDING TO THE PHASE    18700013
         SPACE 1                                                        18800013
IERDOBWR BC    0,ROPPH3NS          DROP THRU FOR PHASE 2                18900013
         L     RL,PPIBLK2+4                                             19000013
         B     16(0,RL)            EXIT TO BLK RTN WANT NEXT RCD        19100013
         SPACE 2                                                        19200013
ROPPH3NS L     RL,PPIBLK+4                                              19300013
         B     4(0,RL)             EXIT TO BLK RTN WANT NEXT RCD        19400013
         EJECT                                                          19500013
IERROC14 CLC   0(1,RD),0(RJ)       COMPARE NEW ITEM WITH ITEM 14        19600013
         BNE   ROP14B              IF EQUAL GO TO EQUALS RTN            19700013
         LR    RC,RJ               LOAD EQ RTN COMPARE REG WITH ITEM 14 19800013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       19900013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             20000013
ROP14B   BH    IERROC15            IF HI/LO GO TO CMP ITM 15 OR UPDATE  20100013
         SPACE 1                                                        20200013
IERROC13 CLC   0(1,RD),0(RI)       COMPARE NEW ITEM WITH ITEM 13        20300013
         BNE   ROP13B              IF EQUAL GO TO THE EQUALS RTN        20400013
         LR    RC,RI               LOAD EQ RTN COMPARE REG WITH ITEM 13 20500013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       20600013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             20700013
ROP13B   BH    ROPMOV13            IF HI/LO NEW COLLATES AFTER ITEM 13  20800013
         SPACE 1                                                        20900013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 12 + BEFORE ITEM 13      21000013
         SPACE 1                                                        21100013
ROPMOV12 L     RK,ROPMRGAM                                              21200013
         LR    RI,RD                                                    21300013
         STM   RE,RI,ROPMRGAM                                           21400013
         LM    RD,RJ,ROPMRGAU                                           21500013
         STM   RE,RK,ROPMRGAU                                           21600013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              21700013
         SPACE 2                                                        21800013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 13 + BEFORE ITEM 14      21900013
         SPACE 1                                                        22000013
ROPMOV13 L     RK,ROPMRGAM                                              22100013
         LR    RJ,RD                                                    22200013
         STM   RE,RJ,ROPMRGAM                                           22300013
         LM    RD,RJ,ROPMRGAU                                           22400013
         STM   RE,RK,ROPMRGAU                                           22500013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              22600013
         SPACE 2                                                        22700013
IERROC15 CLC   0(1,RD),0(RK)       COMPARE NEW ITEM WITH ITEM 15        22800013
         BNE   ROP15B              IF EQUAL GO TO EQUALS RTN            22900013
         LR    RC,RK               LOAD EQ RTN COMPARE REG WITH ITEM 15 23000013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       23100013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             23200013
ROP15B   BH    ROPMOV15            IF HI/LO NEW COLLATES AFTER ITEM 15  23300013
         SPACE 1                                                        23400013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 14 + BEFORE ITEM 15      23500013
         SPACE 1                                                        23600013
ROPMOV14 L     RC,ROPMRGAM                                              23700013
         LR    RK,RD                                                    23800013
         STM   RE,RK,ROPMRGAM                                           23900013
         LM    RD,RJ,ROPMRGAU                                           24000013
         LR    RK,RC                                                    24100013
         STM   RE,RK,ROPMRGAU                                           24200013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              24300013
         SPACE 2                                                        24400013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 15                     24500013
         SPACE 1                                                        24600013
ROPMOV15 L     RC,ROPMRGAM                                              24700013
         STM   RE,RK,ROPMRGAM                                           24800013
         ST    RD,ROPMRGAL+24                                           24900013
         LR    RK,RC                                                    25000013
         LM    RD,RJ,ROPMRGAU                                           25100013
         STM   RE,RK,ROPMRGAU                                           25200013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              25300013
         SPACE 2                                                        25400013
IERROC11 CLC   0(1,RD),0(RG)       COMPARE NEW ITEM WITH ITEM 11        25500013
         BNE   ROP11B              IF EQUAL GO TO EQUALS RTN            25600013
         LR    RC,RG               LOAD EQ RTN COMPARE REG WITH ITEM 11 25700013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       25800013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             25900013
ROP11B   BH    ROPMOV11            INSERT NEW ITEM IN SEQUENCE          26000018
         SPACE 1                                                        26100013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 10 + BEFORE ITEM 11      26200013
         SPACE 1                                                        26300013
ROPMOV10 L     RK,ROPMRGAM                                              26400013
         LR    RG,RD                                                    26500013
         STM   RE,RG,ROPMRGAM                                           26600013
         LM    RD,RJ,ROPMRGAU                                           26700013
         STM   RE,RK,ROPMRGAU                                           26800013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              26900013
         SPACE 2                                                        27000013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 11 + BEFORE ITEM 12      27100013
         SPACE 1                                                        27200013
ROPMOV11 L     RK,ROPMRGAM                                              27300013
         LR    RH,RD                                                    27400013
         STM   RE,RH,ROPMRGAM                                           27500013
         LM    RD,RJ,ROPMRGAU                                           27600013
         STM   RE,RK,ROPMRGAU                                           27700013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              27800013
         SPACE 2                                                        27900013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 9 + BEFORE ITEM 10       28000013
         SPACE 1                                                        28100013
ROPMOV9  L     RK,ROPMRGAM                                              28200013
         LR    RF,RD                                                    28300013
         STM   RE,RF,ROPMRGAM                                           28400013
         LM    RD,RJ,ROPMRGAU                                           28500013
         STM   RE,RK,ROPMRGAU                                           28600013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              28700013
         SPACE 2                                                        28800013
*    SPECIAL ITEM 12 COMPARE FOR 13 WAY MERGE                           28900013
         SPACE 1                                                        29000013
IERROPS4 CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 12        29100013
         BNE   ROPS12B             IF EQUAL GO TO EQUALS RTN            29200013
         LR    RC,RH               LOAD EQ RTN COMPARE REG WITH ITEM 12 29300013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       29400013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             29500013
ROPS12B  BH    ROPMOV12            IF HI/LO GO TO UPDATE                29600013
         B     IERROC11            GO TO CMP NEW ITEM WITH ITEM 11      29700013
         EJECT                                                          29800013
ROPLF8   LM    0,0,ROPMRGAU        LOAD NTWK REG WITH THOSE NECESSARY   29900013
*                                  RCD FROM ITEMS 1 THRU 7. INSTR IS    30000013
*                                  SET BY THE CUTBACK RTN               30100013
         SPACE 1                                                        30200013
*    PARTIAL NETWORK FOR CMP NEW AGAINST ITEMS 1 THRU 7                 30300013
         SPACE 1                                                        30400013
ROPPNEL9 B     IERROPU4            PARTIAL NTWK ENTR SWITCH SET BY      30500013
*                                  CUTBACK RTN                          30600013
         SPACE 1                                                        30700013
*    ENTRANCE FOR A 6,7,8 WAY MERGE                                     30800013
         SPACE 1                                                        30900013
IERROPU4 CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 4         31000013
         BNE   ROP4B               IF EQUAL GO TO EQUALS RTN            31100013
         LR    RC,RH               LOAD EQ RTN COMPARE REG WITH ITEM 4  31200013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       31300013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             31400013
ROP4B    BH    IERROC6             IF HI/LO GO TO CMP ITEM 6 OR 5       31500013
         SPACE 1                                                        31600013
*    ENTRANCE FOR A 3,4,5 WAY MERGE                                     31700013
         SPACE 1                                                        31800013
IERROPU2 CLC   0(1,RD),0(RF)       COMPARE NEW ITEM WITH ITEM 2         31900013
         BNE   ROP2B               IF EQUAL GO TO EQ RTN                32000013
         LR    RC,RF               LOAD EQ RTN COMPARE REG WITH ITEM 2  32100013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       32200013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             32300013
ROP2B    BH    IERROC3             IF HI/LO GO TO CMP ITEM 3,4/UPDATE   32400013
         SPACE 1                                                        32500013
*    ENTRANCE FOR A 2 WAY MERGE                                         32600013
         SPACE 1                                                        32700013
IERROPU1 CLC   0(1,RD),0(RE)       COMPARE NEW ITEM WITH ITEM 1         32800013
         BNE   ROP1B               IF EQUAL GO TO EQ RTN                32900013
         LR    RC,RE               LOAD EQ RTN COMPARE REG WITH ITEM 1  33000013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       33100013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             33200013
ROP1B    BH    ROPMOV1             INSERT NEW ITEM IN SEQUENCE          33300018
         SPACE 1                                                        33400013
*    ENTRANCE FOR A 1 WAY MERGE AND NEW IS WINNER                       33500013
         SPACE 1                                                        33600013
*    CHART ID OG   IF PHASE 2 EXIT TO THE BLOCK RTN                     33700013
*    IF PHASE 3 OR MERGE ONLY PERFORM SEQUENCE CHECK IF REQUESTED       33800013
*    THE ASSIGNMENT ROUTINE SETS THE BRANCH INSTR ACCORDING TO THE PHAS 33900013
         SPACE 1                                                        34000013
IERDOM1  BC    0,ROPPH3            DROP THRU FOR PHASE 2                34100013
         L     RL,PPIBLK2+4                                             34200013
         B     16(0,RL)            EXIT TO BLK RTN WANT NEXT RCD        34300013
         SPACE 2                                                        34400013
*    SEQUENCE CHECK OF CURRENT NETWORK WINNER AND PREVIOUS NETWORK      34500013
*    WINNER. CHECK DONE USING REG RD AND RC                             34600013
         SPACE 1                                                        34700013
*    THE USER COMMUNICATES A 0 OR 4 TO THE BLK RTN. THE BLK RTN         34800013
*       SETS PPIDOUO IF A RECORD MODIFICATION EXIT IS ACTIVATED. IF NO  34900013
*       EXITS ARE ACTIVATED, THE BLK RTN TAKES NO ACTION CONCERNING     35000013
*       PPIDOUO.                                                        35100013
*    A 0 MEANS A SEQUENCE CHECK IS TO BE PERFORMED. A 4 MEANS NO        35200013
*       SEQUENCE CHECK. IF NO RCD MODIFICATION EXITS ARE ACTIVATED,     35300013
*       PPIDOUO IS 0.                                                   35400013
         SPACE 1                                                        35500013
ROPPH3   L     RC,PPIDOUO                                               35600013
         B     ROPCKISC(RC)        BRANCH TO EXIT                       35700018
ROPCKISC B     ROPSCK              SEQUENCE CHECK                       35800018
         SPACE 2                                                        35900013
*    NO SEQUENCE CHECK                                                  36000013
         SPACE 1                                                        36100013
ROPOUT   L     RL,PPIBLK+4                                              36200013
         B     4(0,RL)             EXIT TO BLK RTN WANT NEXT RCD        36300013
         SPACE 2                                                        36400013
ROPSCK   L     RC,PPIDOOBA         ADDR OF REC IN OUTPUT BUFFER         36500013
IERDOSCK CLC   0(1,RD),0(RC)                                            36600013
         BNE   ROPSCB              IF EQUAL GO TO EQ RTN                36700013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    36800013
*    THIS INSTR IS BC 10 OR 12 DEPENDING ON THE INPUT SEQUENCE          36900013
ROPSCB   BC    10,ROPOUT           BLOCK RTN.                           37000018
         SPACE 1                                                        37100013
*    OUT OF SEQUENCE ERROR                                              37200013
         SPACE 1                                                        37300013
         L     RO,PPIRMC+4                                              37400013
         TM    PPISW1+2,X'02'      MERGE ONLY                           37420017
         BO    ROPMERG             YES                                  37440017
         SPACE 1                                                        37460017
         LM    RA,RB,MSGP3A04      OUT OF SEQUENCE MESSAGE              37500013
ROPSEQ   EQU   *                                                        37550017
         L     RP,PPIADSSC                                              37600013
         BAL   RO,12(0,RP)         SORT SYS CNTRL                       37700013
         L     RP,PPIADSSC                                              37800013
         BAL   RO,16(0,RP)         ABORT THE SORT CODE                  37900013
         SPACE 2                                                        37910017
ROPMERG  SRL   RD,26               CONVERT DCB INDEX TO UNIT NUMBER     37920017
         CVD   RD,ROPCONV          CONVERT INDEX TO DECIMAL             37930017
         UNPK  ROPTEMP(2),ROPCONV+6(2) UNPACK FOR PRINTING              37940017
         OI    ROPTEMP+1,X'F0'     SET SIGN POSITIVE                    37950017
         MVC   MSGP3MA8(2),ROPTEMP MOVE UNIT NUMBER INTO MESSAGE        37960017
         LM    RA,RB,MSGP3A08      MERGE OUT OF SEQUENCE                37970017
         B     ROPSEQ              GO TO PRINT MESSAGE                  37980017
         EJECT                                                          38000013
IERROC6  CLC   0(1,RD),0(RJ)       COMPARE NEW ITEM WITH ITEM 6         38100013
         BNE   ROP6B               IF EQUAL GO TO EQUALS RTN            38200013
         LR    RC,RJ               LOAD EQ RTN COMPARE REG WITH ITEM 6  38300013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       38400013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             38500013
ROP6B    BH    IERROC7             IF HI/LO GO TO CMP ITEM 7 OR UPDATE  38600013
         SPACE 1                                                        38700013
IERROC5  CLC   0(1,RD),0(RI)       COMPARE NEW ITEM WITH ITEM 5         38800013
         BNE   ROP5B               IF EQ GO TO EQ RTN                   38900013
         LR    RC,RI               LOAD EQ RTN CMP REG WITH ITEM 5      39000013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       39100013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             39200013
ROP5B    BH    ROPMOV5             IF HI/LO NEW COLLATES AFTER ITEM 5   39300013
         SPACE 1                                                        39400013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 4 + BEFORE ITEM 5        39500013
         SPACE 1                                                        39600013
ROPMOV4  LR    RI,RD                                                    39700013
         LR    RD,RE                                                    39800013
         STM   RF,RI,ROPMRGAU                                           39900013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              40000013
         SPACE 2                                                        40100013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 5 + BEFORE ITEM 6        40200013
         SPACE 1                                                        40300013
ROPMOV5  LR    RJ,RD                                                    40400013
         LR    RD,RE                                                    40500013
         STM   RF,RJ,ROPMRGAU                                           40600013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              40700013
         SPACE 2                                                        40800013
IERROC7  CLC   0(1,RD),0(RK)       COMPARE NEW ITEM WITH ITEM 7         40900013
         BNE   ROP7B               IF EQ GO TO EQ RTN                   41000013
         LR    RC,RK               LOAD EQ RTN COMPARE REG WITH ITEM 7  41100013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       41200013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             41300013
ROP7B    BH    ROPMOV7             IF HI/LO NEW COLLATES AFTER ITEM 7   41400013
         SPACE 1                                                        41500013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 6 + BEFORE ITEM 7        41600013
         SPACE 1                                                        41700013
ROPMOV6  LR    RK,RD                                                    41800013
         LR    RD,RE                                                    41900013
         STM   RF,RK,ROPMRGAU                                           42000013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              42100013
         SPACE 2                                                        42200013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 7                      42300013
         SPACE 1                                                        42400013
ROPMOV7  ST    RD,ROPMRGAM-4                                            42500013
         LR    RD,RE                                                    42600013
         STM   RF,RK,ROPMRGAU                                           42700013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              42800013
         SPACE 2                                                        42900013
IERROC3  CLC   0(1,RD),0(RG)       COMPARE NEW ITEM WITH ITEM 3         43000013
         BNE   ROP3B               IF EQ GO TO EQ RTN                   43100013
         LR    RC,RG               LOAD EQ RTN COMPARE REG WITH ITEM 3  43200013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       43300013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             43400013
ROP3B    BH    ROPMOV3             INSERT NEW ITEM IN SEQUENCE          43500018
         SPACE 1                                                        43600013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 2 + BEFORE ITEM 3        43700013
         SPACE 1                                                        43800013
ROPMOV2  LR    RG,RD                                                    43900013
         LR    RD,RE                                                    44000013
         STM   RF,RG,ROPMRGAU                                           44100013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              44200013
         SPACE 2                                                        44300013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 3 + BEFORE ITEM 4        44400013
         SPACE 1                                                        44500013
ROPMOV3  LR    RH,RD                                                    44600013
         LR    RD,RE                                                    44700013
         STM   RF,RH,ROPMRGAU                                           44800013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              44900013
         SPACE 2                                                        45000013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 1 + BEFORE ITEM 2        45100013
         SPACE 1                                                        45200013
ROPMOV1  ST    RD,ROPMRGAU                                              45300013
         LR    RD,RE                                                    45400013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              45500013
         SPACE 2                                                        45600013
*    SPECIAL ITEM 4 COMPARE FOR A 5 WAY MERGE                           45700013
         SPACE 1                                                        45800013
IERROP4S CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 4         45900013
         BNE   ROPS4B              IF EQ GO TO EQ RTN                   46000013
         LR    RC,RH               LOAD EQ RTN COMPARE REG WITH ITEM 4  46100013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       46200013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             46300013
ROPS4B   BH    ROPMOV4             IF HI/LO GO TO UPDATE                46400013
         B     IERROC3             GO TO COMPARE NEW ITEM WITH ITEM 3   46500013
         EJECT                                                          46600013
*    THE NETWORK CUTBACK SECTION. CHART OF                              46700013
*    IT IS THAT CODE WHICH TAILORS THE NETWORK FOR THE MERGE ORDER      46800013
         SPACE 1                                                        46900013
*    THE INITIAL ENTRANCE TO THE CUTBACK SECTION                        47000013
         SPACE 1                                                        47100013
*    SET NETWORK FOR A 16 WAY MERGE                                     47200013
         SPACE 1                                                        47300013
ROPCSSWM MVC   ROPNTENS(4),ROPSESC8 SET NTWK ENTR SW FOR NEW/ITM 8 CMP  47400013
         MVI   ROPLF16+1,X'4A'     LOAD NTWK REG WITH ITEMS 9 THRU 15   47500013
         MVI   ROPLF8+1,X'4A'      LOAD NTWK REG WITH ITEMS 1 THRU 7    47600013
         MVC   ROP12B(4),ROP12SB   SET BR TO CMP ITEM 14 AFT ITEM 12    47700013
         MVC   ROP4B(4),ROPST4B    SET BR TO CMP ITEM 6 AFT ITEM 4 CMP  47800013
         MVC   ROP14B(4),ROPS14B   SET BR TO CMP ITEM 15 AFT ITEM 14    47900013
         MVC   ROP6B(4),ROPS6B     SET BR TO CMP ITEM 7 AFT ITEM 6 CMP  48000013
         MVC   ROP10B(4),ROPS10B   SET BR TO CMP ITEM 11 AFT ITEM 10    48100013
         MVC   ROP2B(4),ROPS2B     SET BR TO CMP ITEM 3 AFT ITEM 2 CMP  48200013
         MVC   ROPPNELA(4),ROPSPNS1 SET NTWK ENTR FOR ITEMS 9 TO 15     48300013
         MVC   ROPPNEL9(4),ROPSPNS2 SET NTWK ENTR FOR ITEMS 1 TO 7      48400013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 48500013
         SPACE 1                                                        48600013
*    SET NETWORK FOR A 15 WAY MERGE                                     48700013
         SPACE 1                                                        48800013
         MVC   ROP14B(4),ROPFTWM   SET BR TO UPDATE AFTER ITEM 14 CMP   48900013
         MVI   ROPLF16+1,X'49'     LOAD NTWK REG WITH ITEMS 9 THRU 14   49000013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 49100013
         SPACE 1                                                        49200013
*    SET NETWORK FOR A 14 WAY MERGE                                     49300013
         SPACE 1                                                        49400013
         MVC   ROP12B(4),ROP14WM   SET BR TO CMP ITEM 13 AFT ITEM 12    49500013
         MVI   ROPLF16+1,X'48'     LOAD NTWK REG WITH ITEMS 9 TO 13     49600013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 49700013
         SPACE 1                                                        49800013
*    SET NETWORK FOR A 13 WAY MERGE                                     49900013
         SPACE 1                                                        50000013
         MVC   ROP10B(4),ROP13WM   SET BR TO CMP ITEM 12 AFT ITM 10 CMP 50100013
         MVI   ROPLF16+1,X'47'     LOAD NTWK REG WITH ITEMS 9 TO 12     50200013
         MVC   ROPPNELA(4),ROPE13WM SET NTWK ENTR FOR A 13 WAY MERGE    50300013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 50400013
         SPACE 1                                                        50500013
*    SET NETWORK FOR A 12 WAY MERGE                                     50600013
         SPACE 1                                                        50700013
         MVC   ROP10B(4),ROPS10B   SET BR TO CMP ITEM 11 AFT ITM 10 CMP 50800013
         MVI   ROPLF16+1,X'46'     LOAD NTWK REG WITH ITEMS 9 TO 11     50900013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 51000013
         SPACE 1                                                        51100013
*    SET NETWORK FOR AN 11 WAY MERGE                                    51200013
         SPACE 1                                                        51300013
         MVC   ROP10B(4),ROP11WM   SET BR TO UPDATE AFT ITEM 10 CMP     51400013
         MVI   ROPLF16+1,X'45'     LOAD NTWK REG WITH ITEMS 9 + 10      51500013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 51600013
         SPACE 1                                                        51700013
*    SET NETWORK FOR A 10 WAY MERGE                                     51800013
         SPACE 1                                                        51900013
         MVC   ROPPNELA(4),ROPE10WM SET NTWK ENTR FOR A 10 WAY MRG      52000013
         MVI   ROPLF16+1,X'44'     LOAD NTWK REG WITH ITEM 9            52100013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 52200013
         SPACE 1                                                        52300013
*    SET NETWORK FOR A 9 WAY MERGE                                      52400013
         SPACE 1                                                        52500013
         MVC   ROPPNELA(4),ROPE9WM SET NTWK ENTR FOR A 9 WAY MERGE      52600013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 52700013
         SPACE 1                                                        52800013
*    SET NETWORK FOR AN 8 WAY MERGE                                     52900013
         SPACE 1                                                        53000013
         XI    ROPNTENS+1,X'F0'    SET NTWK ENTR SW FOR 8/LESS MRG ORD  53100013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 53200013
         SPACE 1                                                        53300013
*    SET NETWORK FOR A 7 WAY MERGE                                      53400013
         SPACE 1                                                        53500013
         MVC   ROP6B(4),ROP7WM     BR TO UPDATE IF GT ITEM 7            53600013
         MVI   ROPLF8+1,X'49'      LOAD NTWK REG WITH ITEMS 1 TO 6      53700013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 53800013
         SPACE 1                                                        53900013
*    SET NETWORK FOR A 6 WAY MERGE                                      54000013
         SPACE 1                                                        54100013
         MVC   ROP4B(4),ROP6WM     BR TO CMP ITEM 5 IF GT ITEM 4        54200013
         MVI   ROPLF8+1,X'48'      LOAD NETWORK REG WITH ITEMS 1 TO 5   54300013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 54400013
         SPACE 1                                                        54500013
*    SET NETWORK FOR A 5 WAY MERGE                                      54600013
         SPACE 1                                                        54700013
         MVC   ROP2B(4),ROP5WM     BR TO CMP ITEM 4 IF GT ITEM 2        54800013
         MVI   ROPLF8+1,X'47'      LOAD NTWK REG WITH ITEMS 1 TO 4      54900013
         MVC   ROPPNEL9(4),ROPE5WM SET NTWK ENTR FOR A 5 WAY MRG        55000013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 55100013
         SPACE 1                                                        55200013
*    SET NETWORK FOR A 4 WAY MERGE                                      55300013
         SPACE 1                                                        55400013
         MVC   ROP2B(4),ROPS2B     BR TO CMP ITEM 3 IF GT ITEM 2        55500013
         MVI   ROPLF8+1,X'46'      LOAD NTWK REG WITH ITEMS 1 TO 3      55600013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 55700013
         SPACE 1                                                        55800013
*    SET NETWORK FOR A 3 WAY MERGE                                      55900013
         SPACE 1                                                        56000013
         MVC   ROP2B(4),ROP3WM     BR TO UPDATE IF GT ITEM 2            56100013
         MVI   ROPLF8+1,X'45'      LOAD NTWK REG WITH ITEMS 1 + 2       56200013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 56300013
         SPACE 1                                                        56400013
*    SET NETWORK FOR A 2 WAY MERGE                                      56500013
         SPACE 1                                                        56600013
         MVC   ROPPNEL9(4),ROPE2WM SET NTWK ENTR FOR A 2 WAY MERGE      56700013
         MVI   ROPLF8+1,X'44'      LOAD NTWK REG WITH ITEM 1            56800013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 56900013
         SPACE 1                                                        57000013
*    SET NETWORK FOR A 1 WAY MERGE                                      57100013
         SPACE 1                                                        57200013
         MVC   ROPPNEL9(4),ROPE1WM SET NTWK ENTR FOR A 1 WAY MERGE      57300013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 57400013
         SPACE 1                                                        57500013
*    A ZERO WAY MERGE                                                   57600013
         SPACE 1                                                        57700013
IERDOCPS BC    0,ROPCPH3           FALL THRU IF PHASE 2                 57800013
         L     RL,PPIBLK2+4                                             57900013
         BR    RL                  EXIT TO BLK RTN  RELEASE BLK TO WRIT 58000013
         SPACE 2                                                        58100013
ROPCPH3  L     RL,PPIBLK+4                                              58200013
         BR    RL                  EXIT TO BLK RTN (END OF JOB)         58300013
         SPACE 2                                                        58400013
*    THIS IS ENTRY TO THE CUTBACK RTN FROM READ RTN + THE ALGORITHM     58500013
         SPACE 1                                                        58600013
ROPCUTEN L     RC,ROPSVCBA         SET APPROPRIATE CUTBACK SECTION ADDR 58700013
         BR    RC                  GO TO NEXT CUTBACK ADDRESS           58800018
         SPACE 2                                                        58900013
*    THIS SECTION OF CODE ENTERED UPON COMPLETION OF A CUTBACK OPERATON 59000013
*    THIS SECTION INITIALLY CHECKS FOR THE NETWORK BEING SET FOR THE    59100013
*    MERGE ORDER. SUBSEQUENTLY AN UPDATE IS EXECUTED. CHART OG          59200013
         SPACE 1                                                        59300013
ROPFMUDS BC    0,ROPFDMO           SET TO BRANCH BY INITIALIZATION RTN  59400013
*    FALL THRU FOR UPDATING NETWORK AFTER A CUTBACK OPERATION           59500013
         SPACE 1                                                        59600013
         ST    RC,ROPSVCBA                                              59700013
         L     RD,ROPMRGAU                                              59800013
         L     RE,ROPACMO          MERGE ORDER LESS 1 MINUS 1           59900013
         S     RE,KROONE                                                60000013
         ST    RE,ROPACMO                                               60100013
         SLL   RE,2                TOTAL NO. BYTES TO BE UPDATED        60200013
         EX    RE,ROPUPDT          EXECUTE MOVE INSTR                   60300013
         SPACE 1                                                        60400013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              60500013
         SPACE 2                                                        60600013
         EJECT                                                          60700013
ROPFDMO  L     RF,ROPIDMO          SET TO 16 BY INITIALIZATION RTN      60800013
         C     RF,ROPACMO          SET TO ACTUAL MERGE ORDER BY INITIAL 60900013
         BE    ROPSFTTU            SET FALL THRU TO UPDATE              61000013
         S     RF,KROONE                                                61100013
         ST    RF,ROPIDMO                                               61200013
         BR    RC                  BRANCH BACK TO CUTBACK RTN           61300013
         SPACE 2                                                        61400013
ROPSFTTU XI    ROPFMUDS+1,X'F0'    SET ROPFMUDS BRANCH TO FALL THRU     61500013
         ST    RC,ROPSVCBA         SAVE ADDRESS OF NEXT CUTBACK CODE    61600013
         B     ROPINTSQ            GO TO INIT SEQ THE RECORDS           61700013
         SPACE 2                                                        61800013
*    INITIAL SEQUENCING OF RECORDS SECTION EXECUTED AT THE BEGINNING OF 61900013
*    EACH MERGE OPERATION. CHART OG                                     62000013
*    A RELATIVE POSITION METHOD IS EMPLOYED FOR THE SEQUENCING.         62100013
*    THIS METHOD CAN BE DESCRIBED AS COMPARING ONE ITEM OF A LIST WITH  62200013
*       THE REMAINDER OF THE ITEMS AND,THEREBY,DETERMINING ITS PROPER   62300013
*       POSITION IN THE LIST. TO ACCOMPLISH THIS,A TWO AREA SYSTEM IN   62400013
*       PPI IS UTILIZED.                                                62500013
         SPACE 1                                                        62600013
ROPINTSQ SR    RI,RI               INDEX USED TO GET ITEMS TO BE SEQD   62700013
         L     RB,ROPACMO          DETERMINES WHEN ALL ITEMS ARE SEQD   62800013
         LA    RG,PPIPDWA          BEGINNING ADDR OF RCD ADDR IN PPI    62900013
ROPRETRN L     RF,ROPACMO          USED TO CHECK WHEN AN ITEM HAS BEEN  63000013
*                                  CHECKED WITH ALL THE OTHER ITEMS     63100013
         L     RD,0(RI,RG)         THE ITEM WE ARE POSITIONING          63200013
         LA    RE,PPIPSVA-4        ADDR WHERE ITEM IS STORED AFT POS FD 63300013
         SR    RH,RH               INDEX USED TO COMPARE ALL OTHER ITEM 63400013
ROPANOTH L     RC,0(RH,RG)         ADDR OF ITEMS CMP TO ITEM IN RC      63500013
IERDOICP CLC   0(1,RD),0(RC)                                            63600013
*    THIS BRANCH INSTR IS BC 10 OR 12 DEPENDING ON THE INPUT SEQ        63700013
ROPISNLH BC    10,ROPHIEQ          HI/LO AND EQUAL CASE TREATED SAME    63800013
ROPDECR  LA    RH,4(0,RH)                                               63900013
         BCT   RF,ROPANOTH         TRY NEXT ITEM                        64000018
ROPCHEK  CLC   0(4,RE),KROZERO     STORAGE AREA OF ITEMS IS INITIALLY   64100013
*                                  ZERO CHECKED TO INSURE THAT ANOTHER  64200013
*                                  ITEM DOES NOT OCCUPY THIS POSITION   64300013
         BE    ROPINSRT            IF ZERO STORE ITEM                   64400013
         S     RE,KROFOUR          IF EQUAL CHECK NEXT LOWER POSITION   64500013
         B     ROPCHEK             CONTINUE CHECKING FOR ZEROS          64600018
         SPACE 2                                                        64700013
ROPINSRT ST    RD,0(0,RE)          STORE POSITIONED ITEM                64800013
         BCT   RB,ROPINCR          IF NOT DONE GET NEXT ITEM TO POSITIN 64900013
         B     ROPOUTIS            BRANCH TO SET NETWORK ADDRESS        65000013
         SPACE 2                                                        65100013
*    THIS BRANCH INSTR IS BC 2 OR 4 DEPENDING ON THE INPUT SEQUENCE     65200013
ROPHIEQ  BC    2,ROPRND            IF NOT EQ INCR STORE POS POINTER     65300013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       65400013
*    THIS BRANCH INSTR IS BC 4 OR 2 DEPENDING ON THE INPUT SEQUENCE     65500013
ROPLOHI  BC    4,ROPDECR           CHECK NEXT ITEM                      65600018
ROPRND   LA    RE,4(0,RE)                                               65700013
         B     ROPDECR             DECREMENT RF AND CHECK FOR ZEROS     65800018
         SPACE 2                                                        65900013
ROPINCR  LA    RI,4(0,RI)                                               66000013
         B     ROPRETRN            LAST COMPARE                         66100018
         SPACE 2                                                        66200013
*    SET NETWORK AREA WITH ADDRESSES OF PRIMED RECORDS                  66300013
         SPACE 1                                                        66400013
ROPOUTIS L     RD,PPIPSVA          SET REG WITH WINNING RECORD ADDR     66500013
         L     RE,ROPACMO                                               66600013
         S     RE,KROONE                                                66700013
         LR    RF,RE                                                    66800013
         SLL   RE,2                                                     66900013
         LTR   RE,RE                                                    67000013
         BZ    ROPSTM              BYPASS NSI                           67100018
         S     RE,KROONE           DET NO. BYTES TO BE MOVED TO MRG ARA 67200013
         EX    RE,ROPSANW                                               67300013
ROPSTM   ST    RF,ROPACMO          SET ACTUAL MERGE ORDER MINUS ONE FOR 67400013
*                                  UPDATING AFTER A CUTBACK OPERATION   67500013
IERDOIP3 BC    0,ROPINSP3          FALL THRU IF PHASE 2                 67600013
         L     RL,PPIBLK2+4                                             67700013
         B     12(0,RL)            EXIT TO BLK RTN WANT NEXT RCD        67800013
         SPACE 2                                                        67900013
ROPINSP3 L     RL,PPIBLK+4                                              68000013
         B     4(0,RL)             EXIT TO BLK RTN WANT NEXT RCD        68100013
         SPACE 2                                                        68200013
         EJECT                                                          68300013
*    THIS IS SELF INITIALIZATION SECTION PERFORMED AT THE BEGINNING     68400013
*    OF EACH PASS OR SUB PASS.                                          68500013
         SPACE 1                                                        68600013
ROPSINIT MVC   ROPIDMO(4),KROSXTN  SET MAX MERGE ORDER TO 16            68700013
         LH    RE,PPIMRGMX         SET ACTUAL MRG ORD FROM PPI          68800013
         ST    RE,ROPACMO                                               68900013
         SR    RE,RE                                                    69000013
         ST    RE,PPIPSVA                                               69100013
         MVC   PPIPSVA+4(60),PPIPSVA  ZERO INT SEQ STORE AREA           69200013
         XI    ROPFMUDS+1,X'F0'    SET ROPFMUDS TO BRANCH               69300013
         TM    PPISW1+3,X'10'      IS INPUT SEQ ASDNG OR DESCG          69400013
         BC    1,ROPISD            FALL THRU IF INPUT SEQ IS ASDNG      69500013
         TM    ROP12B+1,X'20'      IS ROUTINE SET FOR ASDNG             69600013
ROPFDSQ  BC    1,ROPCSSWM          IF THE ROUTINE IS SET FOR THE INPUT  69700013
         XI    ROPWHB+1,X'60'      SEQUENCE BRANCH TO THE CUTBACK       69800013
         XI    ROP12B+1,X'60'      SECTION. IF THE ROUTINE IS NOT SET   69900013
         XI    ROP10B+1,X'60'      FOR THE INPUT  CHANGE THE MASK OF    70000013
         XI    ROP9B+1,X'60'       THE BRANCH ON CONDITION INSTR.       70100013
         XI    ROP14B+1,X'60'                                           70200013
         XI    ROP13B+1,X'60'                                           70300013
         XI    ROP15B+1,X'60'                                           70400013
         XI    ROP11B+1,X'60'                                           70500013
         XI    ROPS12B+1,X'60'                                          70600013
         XI    ROP4B+1,X'60'                                            70700013
         XI    ROP2B+1,X'60'                                            70800013
         XI    ROP1B+1,X'60'                                            70900013
         XI    ROPSCB+1,X'60'                                           71000013
         XI    ROP6B+1,X'60'                                            71100013
         XI    ROP5B+1,X'60'                                            71200013
         XI    ROP7B+1,X'60'                                            71300013
         XI    ROP3B+1,X'60'                                            71400013
         XI    ROPS4B+1,X'60'                                           71500013
         XI    ROPISNLH+1,X'60'                                         71600013
         XI    ROPHIEQ+1,X'60'                                          71700013
         XI    ROPLOHI+1,X'60'                                          71800013
         XI    ROP12SB+1,X'60'                                          71900013
         XI    ROPST4B+1,X'60'                                          72000013
         XI    ROPS14B+1,X'60'                                          72100013
         XI    ROPS6B+1,X'60'                                           72200013
         XI    ROPS10B+1,X'60'                                          72300013
         XI    ROPS2B+1,X'60'                                           72400013
         XI    ROPFTWM+1,X'60'                                          72500013
         XI    ROP14WM+1,X'60'                                          72600013
         XI    ROP13WM+1,X'60'                                          72700013
         XI    ROP11WM+1,X'60'                                          72800013
         XI    ROP7WM+1,X'60'                                           72900013
         XI    ROP6WM+1,X'60'                                           73000013
         XI    ROP5WM+1,X'60'                                           73100013
         XI    ROP3WM+1,X'60'                                           73200013
         B     ROPCSSWM            BRANCH TO CUTBACK SECTION            73300013
         SPACE 2                                                        73400013
*    INPUT IS IN DESCENDING ORDER                                       73500013
         SPACE 1                                                        73600013
ROPISD   TM    ROP12B+1,X'40'      IS ROUTINE SET FOR DESCG             73700013
         B     ROPFDSQ             CHANGE BRANCHES IF NECCESSARY        73800018
         SPACE 2                                                        73900013
*    EXECUTED MOVE INSTRUCTIONS                                         74000013
         SPACE 1                                                        74100013
ROPUPDT  MVC   ROPMRGAU(1),ROPMRGAU+4  UPDATING NETWORK ADDRESSES       74200013
ROPSANW  MVC   ROPMRGAU(1),PPIPSVA+4   SET NETWORK WITH PRIMED ADDRS    74300013
         EJECT                                                          74400013
         DS    0F                                                       74500013
ROPMRGAU DS    7F                  ADDR OF FIRST 7 RCDS FOR MRG NTWK    74600013
ROPMRGAM DS    1F                  ADDR OF RECORD 8 OF MRG NTWK         74700013
ROPMRGAL DS    7F                  ADDR OF LAST 7 RCDS FOR MRG NTWK     74800013
ROPSVCBA DS    1F                  SAVE NEXT CUTBACK ADDRESS WORD       74900013
ROPIDMO  DS    1F                  MAX MRG ORD SET BY INITIAL           75000013
ROPACMO  DS    1F                  ACTUAL MRG ORD SET BY INITIAL        75100013
*********************************************************************** 75200013
KROSXTN  DC    X'00000010'         MAX. MERGE ORDER                     75300018
KROONE   DC    XL4'1'              CONSTANT OF ONE                      75400018
KROZERO  DC    XL4'0'              CONSTANT OF ZERO                     75500018
KROFOUR  DC    XL4'4'              CONSTANT OF FOUR                     75560018
ROPTEMP  DC    H'0'                TEMP STORAGE FOR UNIT NUMBER         75630017
ROPCONV  DC    D'0'                CONVERSION AREA FOR UNIT NUMBER      75660017
*********************************************************************** 75700013
ROPSESC8 BC    0,ROPLF8            SET NTWK ENTR SW TO CMP NEW VS ITM 8 75800013
*    THE FOLLOWING 14 INSTR ARE SET DEPENDING ON THE INPUT SEQUENCE     75900013
ROP12SB  BH    IERROC14            BR TO CMP ITEM 14 AFT ITEM 12 CMP    76000013
ROPST4B  BH    IERROC6             BR TO CMP ITEM 6 AFT ITEM 4 CMP      76100013
ROPS14B  BH    IERROC15            BR TO CMP ITEM 15 AFT ITEM 14 CMP    76200013
ROPS6B   BH    IERROC7             BR TO CMP ITEM 7 AFT ITEM 6 CMP      76300013
ROPS10B  BH    IERROC11            BR TO CMP ITEM 11 AFT ITEM 10 CMP    76400013
ROPS2B   BH    IERROC3             BR TO CMP ITEM 3 AFT ITEM 2 CMP      76500013
ROPFTWM  BH    ROPMOV14            BR TO UPDATE IF GT ITEM 14           76600013
ROP14WM  BH    IERROC13            BR TO CMP ITEM 13 AFT ITEM 12 CMP    76700013
ROP13WM  BH    IERROPS4            BR TO CMP ITEM 12 AFT ITEM 10 CMP    76800013
ROP11WM  BH    ROPMOV10            BR TO UPDATE AFT ITEM 10 CMP         76900013
ROP7WM   BH    ROPMOV6             BR TO UPDATE IF GT ITEM 7            77000013
ROP6WM   BH    IERROC5             BR TO CMP ITEM 5 AFT ITEM 4 CMP      77100013
ROP5WM   BH    IERROP4S            BR TO CMP ITEM 4 IF GT ITEM 2        77200013
ROP3WM   BH    ROPMOV2             BR TO UPDATE AFT ITEM 10 CMP         77300013
         SPACE 2                                                        77400013
ROPSPNS1 B     IERROPL4            SET ENTR SW FOR PARTIAL NTWK         77500013
ROPSPNS2 B     IERROPU4            SET ENTR SW FOR PARTIAL NTWK         77600013
ROPE13WM B     IERROPL2            ENTR FOR A 11,12,13 WAY MRG          77700013
ROPE10WM B     IERROPL1            ENTR FOR A 10 WAY MRG                77800013
ROPE9WM  B     ROP9WMRG            ENTR FOR A 9 WAY MRG                 77900013
ROPE5WM  B     IERROPU2            ENTR FOR A 3,4,5 WAY MRG             78000013
ROPE2WM  B     IERROPU1            ENTR FOR A 2 WAY MRG                 78100013
ROPE1WM  B     IERDOM1             ENTR FOR A 1 WAY MRG                 78200013
*********************************************************************** 78300013
*                                                                       78400013
* MODULE NAME ***IERRMC***                                              78500013
*                                                                       78600013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        78700013
* PHASE 3 OR MERGE ONLY RUNNING PROGRAM.                                78800013
         SPACE 1                                                        78900013
DIERRMC  DSECT                                                          79000013
*                                                                       79100013
       COPY  RMCMAIN                                                    79200013
*                                                                       79300013
         SMPPI                                                          79400013
         END                                                            79500013
