         TITLE 'IERROQ - OS/360 SORT/MERGE - 360-SM-023   04/26/65'     00100013
*MODULE NAME:*** IERROQ ***                                             00200013
         SPACE 2                                                        00300013
*STATUS: CHANGE LEVEL 000                                               00400013
         SPACE 2                                                        00500013
*MODULE FUNCTION/OPERATION: PHASE 2 AND 3 1-16 WAY MERGE NETWORK WITH   00600013
*   A SINGLE CONTROL  FIELD. THE FUNCTION OF THIS MODULE IS TO MERGE    00700013
*   FIXED OR VARIABLE LENGTH RECORDS IN ASCENDING OR DECENDING SEQUENCE 00800013
*   INITIALLY IERROQ SEQUENCES THE INPUT RECORDS IN THE PHASE TO PHASE  00900013
*   INFORMATION AREA, CUTSBACK THE NETWORK FOR SPECIFIED MERGE ORDER ,  01000013
*   AND THEN UTILIZES A BINARY INSERTION TECHNIQUE. THIS IS ACCOMPLISH- 01100013
*   ED BY USING THE ADDRESSES OF THE RECORDS IN THE GENERAL REGISTERS   01200013
*   RE THRU RK. THE LOW ORDER 3 BYTES OF THE REGISTER CONTAIN THE       01300013
*   ADDRESS OF THE RECORD. THE HIGH ORDER BYTE HAS A FILE INDENTIFIER   01400013
*   FOR THE DEBLOCK ROUTINE. REGISTER RD IS THE NEW RECORD CONVEYER     01500013
*   FROM DEBLOCK AND COMMUNICATES TO BLOCK.                             01600013
         SPACE 2                                                        01700013
*USED AS A DSECT IN - IERAOQ                                            01800013
*                                                                       01900013
*                                                                       02000013
*MACROS USED -                                                          02100013
         SPACE 1                                                        02200013
*   SMPPI                                                               02300013
         SPACE 2                                                        02400013
*ENTRY POINTS:                                                          02500013
         SPACE 1                                                        02600013
*        ENTRY IERROQ              ENTRY FROM:                          02700013
*                                    CALLING SEQUENCE-                  02800013
*                                      LA   RP,PPINETM+4                02900013
*                                      BR   RP                          03000013
         SPACE 2                                                        03100013
*INPUT: PPI FIELDS REFERENCED-                                          03200013
         SPACE 1                                                        03300013
*   PPIDOOBA  PPIMRGMX  PPIPSVA    PPIBLK    PPIRMC                     03400013
*   PPIDOUA   PPIPDWA   PPISW1     PPIBLK2                              03500013
         SPACE 2                                                        03600013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             03700013
         SPACE 1                                                        03800013
*    PPIPSVA                                                            03900013
         SPACE 2                                                        04000013
*EXTERNAL ROUTINES:                                                     04100013
         SPACE 1                                                        04200013
*        EXTRN IERRMC              MESSAGE MODULE                       04300013
*        EXTRN IERDR2              PHASE TWO BLOCK ROUTINE              04400013
*        EXTRN IERDB34             PHASE THREE BLOCK ROUTINE            04500013
         SPACE 2                                                        04600013
*EXTERNAL PARAMETERS:                                                   04700013
         SPACE 1                                                        04800013
*        N/A                                                            04900013
*EXITS: NORMAL                                                          05000013
         SPACE 1                                                        05100013
*        IERDB2                    BLOCK PHASE 2                        05200013
*        IERDB34                   BLOCK PHASE 3                        05300013
         SPACE 2                                                        05400013
*EXITS: ERROR                                                           05500013
         SPACE 1                                                        05600013
*        IERRMC                    MESSAGE MODULE                       05700013
         SPACE 2                                                        05800013
*TABLES/WORK AREAS:                                                     05900013
         SPACE 1                                                        06000013
*        N/A                                                            06100013
         SPACE 2                                                        06200013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  06300013
         SPACE 2                                                        06400013
*NOTES: N/A                                                             06500013
         SPACE 1                                                        06600013
         SPACE 2                                                        06700013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            06800013
         SPACE 1                                                        06900013
RA       EQU   0                   CONTENTS IN- N/A                     07000013
*                                  USE- SYSTEM WORK REGISTER            07100013
*                                  CONTENTS OUT- N/A                    07200013
RB       EQU   1                   CONTENTS IN- N/A                     07300013
*                                  USE- SYSTEM PARAMETER REG            07400013
*                                  CONTENTS OUT- N/A                    07500013
RC       EQU   2                   CONTENTS IN- TO REGISTER EXTRACT     07600013
*                                  USE- TO REGISTER FOR EXTRACT RTN     07700013
*                                  CONTENTS OUT- TO REGISTER EXTRACT    07800013
RD       EQU   3                   CONTENTS IN- FROM REGISTER           07900013
*                                  USE- FROM REGISTER EXTRACT,WNR,NXT   08000013
*                                  CONTENTS OUT- FROM REGISTER          08100013
RE       EQU   4                   CONTENTS IN- MERGE ADDRESS ITEM 9    08200013
*                                  USE- MERGE NETWORK REGISTER          08300013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 9   08400013
RF       EQU   5                   CONTENTS IN- MERGE ADDRESS ITEM 10   08500013
*                                  USE- MERGE NETWORK REGISTER          08600013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 10  08700013
RG       EQU   6                   CONTENTS IN- MERGE ADDRESS ITEM 11   08800013
*                                  USE- MERGE NETWORK REGISTER          08900013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 11  09000013
RH       EQU   7                   CONTENTS IN- MERGE ADDRESS ITEM 12   09100013
*                                  USE- MERGE NETWORK REGISTER          09200013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 12  09300013
RI       EQU   8                   CONTENTS IN- MERGE ADDRESS ITEM 13   09400013
*                                  USE- MERGE NETWORK REGISTER          09500013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 13  09600013
RJ       EQU   9                   CONTENTS IN- MERGE ADDRESS ITEM 14   09700013
*                                  USE- MERGE NETWORK REGISTER          09800013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 14  09900013
RK       EQU   10                  CONTENTS IN- MERGE ADDRESS ITEM 15   10000013
*                                  USE- MERGE NETWORK REGISTER          10100013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 15  10200013
RL       EQU   11                  CONTENTS IN- N/A                     10300013
*                                  USE- PROGRAM BASE ADDRESS            10400013
*                                  CONTENTS OUT- PROGRAM ADDRESS        10500013
RM       EQU   12                  CONTENTS IN- EXTRACT RTN ADDRESS     10600013
*                                  USE- EXTRACT ROUTINE BASE REGISTER   10700013
*                                  CONTENTS OUT- EXTRACT RTN ADDRESS    10800013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          10900013
*                                  USE- PPI REFERENCE,REGISTER SAVE     11000013
*                                    AREA                               11100013
*                                  CONTENTS OUT- ADDRESS OF PPI         11200013
RO       EQU   14                  CONTENTS IN N/A                      11300013
*                                  USE- MESSAGE MODULE BASE ADDRESS REG 11400013
*                                  CONTENTS OUT- MESSAGE MODULE ADDRESS 11500013
RP       EQU   15                  CONTENTS IN- THIS MODULE ADDRESS     11600013
*                                  USE- SORT SYSTEM CONTROL INTERFACE   11700013
*                                  CONTENTS OUT- N/A                    11800013
         SPACE 2                                                        11900013
*START OF MODULE CODE PROPER:                                           12000013
         SPACE 2                                                        12100013
IERROQ   CSECT                                                          12200013
         USING *,RL                MODULE USING REG                     12300013
         USING IERRCA,RN           SETTING PPI DSECT USING REG          12400013
         USING DIERRMC,RO          MESSAGE MODULE                       12500013
IERDO1   B     ROQSINIT            READ PRIME ENTRY BR TO INITIALIZAT   12600013
         B     ROQCUTEN            READ + ALGORITHM ENTRY BR TO CUTBACK 12700013
IERDOET  B     ROQNTENS            DEBLOCK ENTRY FALL THRU IF EXTRACT   12800013
*                                  CHART L6                             12900013
         L     RC,ROQSVEXA         SET REG WITH EXTRACT ADDRESS         13000013
         ST    RD,0(0,RC)          STORE REC ADDR IN EXTRACT POS ADDR   13100013
         LR    RA,RC                                                    13200013
         LR    RC,RD               SET FROM AND TO REG FOR EXTRACT RTN  13300013
         LR    RD,RA                                                    13400013
         BAL   RO,4(0,RM)          EXIT TO EXTRACT ROUTINE              13500013
*    NETWORK ENTRANCE SWITCH                                            13600013
         SPACE 1                                                        13700013
ROQNTENS BC    0,ROQLF8            FOR MRG ORD > 8, FALL THRU           13800013
         SPACE 1                                                        13900013
*    DETERMINATION OF WHICH HALF OF MRG NTWK RCDS THE NEW RCD MUST CMP  14000013
         SPACE 1                                                        14100013
         L     RC,ROQMRGAM         ADDR OF ITEM 8                       14200013
IERROQWH CLC   0(1,RD),0(RC)                                            14300013
         SPACE 1                                                        14400013
*    THIS INSTR IS BC 10/12 DEPENDING ON THE INPUT SEQUENCE             14500013
         SPACE 1                                                        14600013
ROQWHB   BC    12,ROQLF8           IF NEW GT / LT ITEM 8, FALL THRU     14700013
ROQLF16  LM    0,0,ROQMRGAL        LOAD NTWK REG WITH THOSE NECESSARY   14800013
*                                  RCD FROM ITEMS 9 THRU 15.INSTR IS    14900013
*                                  SET BY THE CUTBACK RTN               15000013
         SPACE 1                                                        15100013
*    PARTIAL NETWORK FOR CMP NEW AGAINST ITEMS 9 THRU 15                15200013
         SPACE 1                                                        15300013
ROQPNELA B     IERROQL4            PARTIAL NTWK ENTR SWITCH SET BY      15400013
*                                  CUTBACK RTN                          15500013
         SPACE 2                                                        15600013
*    ENTRANCE FOR A 14, 15, 16 WAY MERGE                                15700013
         SPACE 1                                                        15800013
IERROQL4 CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 12        15900013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             16000013
ROQ12B   BH    IERROC14            IF HI/LO GO TO CMP ITEM 14 OR 13     16100013
         SPACE 1                                                        16200013
*    ENTRANCE FOR 11, 12, 13 WAY MERGE                                  16300013
         SPACE 1                                                        16400013
IERROQL2 CLC   0(1,RD),0(RF)       COMPARE NEW ITEM WITH ITEM 10        16500013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             16600013
ROQ10B   BH    IERROC11            IF HI/LO GO TO CMP ITEM 11,12/ UPDAT 16700013
         SPACE 1                                                        16800013
*    ENTRANCE FOR A 10 WAY MERGE                                        16900013
         SPACE 1                                                        17000013
IERROQL1 CLC   0(1,RD),0(RE)       COMPARE NEW ITEM WITH ITEM 9         17100013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             17200013
ROQ9B    BH    ROQMOV9             FIT INTO COLLATING SEQUENCE          17300018
         SPACE 1                                                        17400013
*    ENTRANCE FOR A 9 WAY MERGE AND NEW ITEM COLLATES AFT ITEM 8        17500013
         SPACE 1                                                        17600013
ROQ9WMRG LR    RC,RD                                                    17700013
         LM    RD,RK,ROQMRGAU                                           17800013
         STM   RE,RK,ROQMRGAU                                           17900013
         ST    RC,ROQMRGAM                                              18000013
         SPACE 1                                                        18100013
*    THIS SECTION OF CODE COMMUNICATES THE NETWORKS WINNING RECORD      18200013
*       ADDRESS TO THE BLOCK ROUTINE AFTER TAKING APPROPRIATE ACTION    18300013
*       IF EXTRACTING AND IF THERE IS TO BE A SEQUENCE CHECK. THE PHASE 18400013
*    AND EXTRACT SWITCHES ARE SET BY THE ASSGN RTN. CHART OG            18500013
         SPACE 1                                                        18600013
IERROBWR BC    0,IERNEXTR          IF EXTRACTING FALL THRU              18700013
IERROBB1 BC    0,ROQEPH3P          FALL THRU FOR PHASE 2                18800013
         ST    RD,ROQSVEXA         SAVE EXTRACT POSITION ADDR           18900013
         L     RD,0(0,RD)          LOAD ACTUAL ADDR OF WINNING RCD      19000013
ROQBBFIS BC    0,ROQISOUT          CHANGED FROM NO-OP TO UNCODITIONAL   19100018
         L     RL,PPIBLK2+4                                             19200013
         SPACE 1                                                        19300013
         B     16(0,RL)            EXIT TO BLK RTN WANT NEXT RCD        19400013
         SPACE 2                                                        19500013
ROQISOUT XI    ROQBBFIS+1,X'F0'                                         19600013
         L     RL,PPIBLK2+4                                             19700013
         B     12(0,RL)            BLOCK ROUTINE                        19800018
         SPACE 2                                                        19900013
*    PHASE 3 + MERGE ONLY PROCEDURE IF EXTRACTING                       20000013
         SPACE 1                                                        20100013
ROQEPH3P L     RC,ROQSQCWD         AVAIL EXTRACT POS ADDR               20200013
         ST    RC,ROQSVEXA         SAVE AVAIL EXTRACT POS ADDR          20300013
         ST    RD,ROQSQCWD         SAVE WIN EXTRACT POS ADDR FOR SEQ CK 20400013
*    SWITCH SET BY INITIAL SEQUENCING RTN TO BYPASS CHK FOR SEQ CHK     20500013
         SPACE 1                                                        20600013
ROQFRSW1 BC    0,ROQFR1            FALL THRU IF NOT FIRST RECORD        20700013
         SPACE 1                                                        20800013
*    IF THE NEW RECORD IS THE WINNER,A SEQUENCE CHECK WILL BE PERFORMED 20900013
*       IF REQUESTED. IF THE NEW RECORD IS NOT THE WINNER,NO SEQUENCE   21000013
*       CHECK IS NECESSARY.                                             21100013
         SPACE 1                                                        21200013
ROQSCSW  BC    0,ROQNIW            FALL THRU IF NEW IS NOT WINNER       21300013
IERXTRT1 BC    0,ROQEPH3           FALL THRU IF EXTRACTING              21400013
ROQSAA   L     RD,0(0,RD)          LOAD ACTUAL ADDRESS OF WINNING RCD   21500013
ROQEPH3  L     RL,PPIBLK+4                                              21600013
         B     4(0,RL)             EXIT TO BLK RTN WANT NEXT RECORD     21700013
         SPACE 2                                                        21800013
ROQFR1   XI    ROQFRSW1+1,X'F0'    SET FIRST RCD SWITCH 1 TO FALL THRU  21900013
         B     ROQSAA              BRANCH TO SET ACTUAL ADDRESS         22000013
         SPACE 2                                                        22100013
ROQNIW   XI    ROQSCSW+1,X'F0'     SET ROQSCSW TO FALL THRU             22200013
         SPACE 1                                                        22300013
*    SEQUENCE CHECK OF CURRENT NETWORK WINNER AND PREVIOUS NETWORK      22400013
*       WINNER. CHECK DONE USING REG RD AND RC.                         22500013
*    THE USER COMMUNICATES A 0 OR 4 TO THE BLOCK RTN. THE BLOCK RTN.    22600013
*       SETS PPIDOUO IF A RECORD MODIFICATION EXIT IS ACTIVATED. IF NO  22700013
*       EXITS ARE ACTIVATED,THE BLOCK RTN TAKES NO ACTION CONCERNING    22800013
*       PPIDOUO.                                                        22900013
*    A 0 MEANS A SEQUENCE CHECK IS TO BE PERFORMED. A 4 MEANS NO        23000013
*       SEQUENCE CHECK. IF NO RCD MODIFICATION EXITS ARE ACTIVATED,     23100013
*       PPIDOUO IS 0.                                                   23200013
         SPACE 1                                                        23300013
         L     RB,PPIDOUO                                               23400013
         B     ROQCKISC(RB)        EXIT IF USER MOD.                    23500018
ROQCKISC B     IERDOSCK            BRANCH TO TEST                       23600018
         SPACE 2                                                        23700013
*    NO  SEQUENCE CHECK                                                 23800013
         SPACE 1                                                        23900013
IERXTRT2 BC    15,ROQSAA           IF EXTRACTING BRANCH TO ROQSAA       24000013
         B     ROQEPH3             IF NOT EXTRACTING BRANCH TO ROQEPH3  24100013
         SPACE 2                                                        24200013
IERDOSCK CLC   0(1,RD),0(RC)                                            24300013
*    THIS BRANCH INSTR IS BC 10 OR 12 DEPENDING ON THE INPUT SEQUENCE   24400013
ROQSCB   BC    10,IERXTRT1         EXTRACT                              24500018
         SPACE 1                                                        24600013
*    OUT OF SEQUENCE ERROR                                              24700013
         SPACE 1                                                        24800013
         L     RO,PPIRMC+4                                              24900013
         TM    PPISW1+2,X'02'      TEST FOR MERGE RUN                   24930017
         BO    ROQMERG             YES, BRANCH                          24960017
         LM    RA,RB,MSGP3A04      OUT OF SEQUENCE MESSAGE              25000013
ROQSEQ   L     RP,PPIADSSC                                              25100017
         BAL   RO,12(0,RP)         SORT SYS CNTRL                       25200013
         L     RP,PPIADSSC                                              25300013
         BAL   RO,16(0,RP)         ABORT THE SORT CODE                  25400013
ROQMERG  BC    0,ROQ100            FALL THRU IF EXTRACTING              25403017
         SPACE 1                                                        25406017
         L     RD,0(RD)            LOAD RECORD ADDRESS FROM EXTRACT     25409017
*                                    WORK AREA                          25412017
ROQ100   SRL   RD,26               CONVERT DCB INDEX TO UNIT NUMBER     25415017
         CVD   RD,ROQCONV          CONVERT INDEX TO DECIMAL             25420017
         UNPK  ROQTEMP(2),ROQCONV+6(2) UNPACK FOR PRINTING              25430017
         OI    ROQTEMP+1,X'F0'     SET SIGN POSITIVE                    25440017
         MVC   MSGP3MA8(2),ROQTEMP      MOVE UNIT NUMBER INTO MESSAGE   25450017
         LM    RA,RB,MSGP3A08      MERGE OUT OF SEQUENCE                25460017
         B     ROQSEQ              GO PRINT MESSAGE                     25470017
         SPACE 2                                                        25500013
*    NOT EXTRACTING                                                     25600013
         SPACE 1                                                        25700013
IERNEXTR B     ROQBBFIS            IF PHASE 2 BRANCH                    25800013
ROQFRSW2 BC    0,ROQFR2            IF FIRST RCD BRANCH                  25900013
         L     RC,PPIDOOBA         ADDR OF RCD IN OUTPUT BUFFER         26000013
         B     ROQSCSW             BRANCH TO CHK IF SEQ CHK REQUIRED    26100013
         SPACE 2                                                        26200013
ROQFR2   XI    ROQFRSW2+1,X'F0'    SET FIRST RCD SW 2 TO FALL THRU      26300013
         B     ROQEPH3             BRANCH TO BLOCK RECORD               26400013
         SPACE 2                                                        26500013
IERROC14 CLC   0(1,RD),0(RJ)       COMPARE NEW ITEM WITH ITEM 14        26600013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             26700013
ROQ14B   BH    IERROC15            IF HI/LO GO TO CMP ITM 15 OR UPDATE  26800013
         SPACE 1                                                        26900013
IERROC13 CLC   0(1,RD),0(RI)       COMPARE NEW ITEM WITH ITEM 13        27000013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             27100013
ROQ13B   BH    ROQMOV13            IF HI/LO NEW COLLATES AFTER ITEM 13  27200013
         SPACE 1                                                        27300013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 12 + BEFORE ITEM 13      27400013
         SPACE 1                                                        27500013
ROQMOV12 L     RK,ROQMRGAM                                              27600013
         LR    RI,RD                                                    27700013
         STM   RE,RI,ROQMRGAM                                           27800013
         LM    RD,RJ,ROQMRGAU                                           27900013
         STM   RE,RK,ROQMRGAU                                           28000013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              28100013
         SPACE 2                                                        28200013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 13 + BEFORE ITEM 14      28300013
         SPACE 1                                                        28400013
ROQMOV13 L     RK,ROQMRGAM                                              28500013
         LR    RJ,RD                                                    28600013
         STM   RE,RJ,ROQMRGAM                                           28700013
         LM    RD,RJ,ROQMRGAU                                           28800013
         STM   RE,RK,ROQMRGAU                                           28900013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              29000013
         SPACE 2                                                        29100013
IERROC15 CLC   0(1,RD),0(RK)       COMPARE NEW ITEM WITH ITEM 15        29200013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      29300013
ROQ15B   BH    ROQMOV15            IF HI/LO NEW COLLATES AFTER ITEM 15  29400013
         SPACE 1                                                        29500013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 14 + BEFORE ITEM 15      29600013
ROQMOV14 L     RC,ROQMRGAM                                              29700013
         LR    RK,RD                                                    29800013
         STM   RE,RK,ROQMRGAM                                           29900013
         LM    RD,RJ,ROQMRGAU                                           30000013
         LR    RK,RC                                                    30100013
         STM   RE,RK,ROQMRGAU                                           30200013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              30300013
         SPACE 2                                                        30400013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 15                     30500013
ROQMOV15 L     RC,ROQMRGAM                                              30600013
         STM   RE,RK,ROQMRGAM                                           30700013
         ST    RD,ROQMRGAL+24                                           30800013
         LR    RK,RC                                                    30900013
         LM    RD,RJ,ROQMRGAU                                           31000013
         STM   RE,RK,ROQMRGAU                                           31100013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              31200013
         SPACE 2                                                        31300013
IERROC11 CLC   0(1,RD),0(RG)       COMPARE NEW ITEM WITH ITEM 11        31400013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             31500013
ROQ11B   BH    ROQMOV11            FIT INTO COLLATING SEQUENCE          31600018
         SPACE 1                                                        31700013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 10 + BEFORE ITEM 11      31800013
ROQMOV10 L     RK,ROQMRGAM                                              31900013
         LR    RG,RD                                                    32000013
         STM   RE,RG,ROQMRGAM                                           32100013
         LM    RD,RJ,ROQMRGAU                                           32200013
         STM   RE,RK,ROQMRGAU                                           32300013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              32400013
         SPACE 2                                                        32500013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 11 + BEFORE ITEM 12      32600013
ROQMOV11 L     RK,ROQMRGAM                                              32700013
         LR    RH,RD                                                    32800013
         STM   RE,RH,ROQMRGAM                                           32900013
         LM    RD,RJ,ROQMRGAU                                           33000013
         STM   RE,RK,ROQMRGAU                                           33100013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              33200013
         SPACE 2                                                        33300013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 9 + BEFORE ITEM 10       33400013
ROQMOV9  L     RK,ROQMRGAM                                              33500013
         LR    RF,RD                                                    33600013
         STM   RE,RF,ROQMRGAM                                           33700013
         LM    RD,RJ,ROQMRGAU                                           33800013
         STM   RE,RK,ROQMRGAU                                           33900013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              34000013
         SPACE 2                                                        34100013
*    SPECIAL ITEM 12 COMPARE FOR 13 WAY MERGE                           34200013
         SPACE 1                                                        34300013
IERROQS4 CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 12        34400013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             34500013
ROQS12B  BH    ROQMOV12            IF HI/LO GO TO UPDATE                34600013
         B     IERROC11            GO TO COMPARE NEW ITEM WITH ITEM 11  34700013
         EJECT                                                          34800013
ROQLF8   LM    0,0,ROQMRGAU        LOAD NTWK REG WITH THOSE NECESSARY   34900013
*                                  RCD FROM ITEMS 1 THRU 7. INSTR IS    35000013
*                                  SET BY THE CUTBACK RTN               35100013
         SPACE 1                                                        35200013
*    PARTIAL NETWORK FOR CMP NEW AGAINST ITEMS 1 THRU 7                 35300013
         SPACE 1                                                        35400013
ROQPNEL9 B     IERROQU4            PARTIAL NTWK ENTR SWITCH SET BY      35500013
*                                  CUTBACK RTN                          35600013
         SPACE 1                                                        35700013
*    ENTRANCE FOR A 6, 7, 8 WAY MERGE                                   35800013
         SPACE 1                                                        35900013
IERROQU4 CLC   0(1,RD),0(RH)       COMPARE NEW ITEM TO ITEM 4           36000013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             36100013
ROQ4B    BH    IERROC6             IF HI/ LO GO TO CMP ITEM 6 OR 5      36200013
         SPACE 1                                                        36300013
*    ENTRANCE FOR A 3, 4, 5 WAY MERGE                                   36400013
         SPACE 1                                                        36500013
IERROQU2 CLC   0(1,RD),0(RF)       COMPARE NEW ITEM WITH ITEM 2         36600013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             36700013
ROQ2B    BH    IERROC3             IF HI/LO GO TO CMP ITEM 3,4 / UPDATE 36800013
         SPACE 1                                                        36900013
*    ENTRANCE FOR A 2 WAY MERGE                                         37000013
         SPACE 1                                                        37100013
IERROQU1 CLC   0(1,RD),0(RE)       COMPARE NEW ITEM WITH ITEM 1         37200013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             37300013
ROQ1B    BH    ROQMOV1             FIT INTO COLLATING SEQUENCE          37400018
         SPACE 1                                                        37500013
*    ENTRANCE FOR A 1 WAY MERGE AND NEW IS WINNER                       37600013
         SPACE 1                                                        37700013
ROQ1WMRG XI    ROQSCSW+1,X'F0'     SET SEQ CHK SWITCH TO YES            37800013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              37900018
         SPACE 2                                                        38000013
IERROC6  CLC   0(1,RD),0(RJ)       COMPARE NEW ITEM WITH ITEM 6         38100013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      38200013
ROQ6B    BH    IERROC7             IF HI/LO GO TO CMP ITEM 7 OR UPDATE  38300013
         SPACE 1                                                        38400013
IERROC5  CLC   0(1,RD),0(RI)       COMPARE NEW ITEM WITH ITEM 5         38500013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             38600013
ROQ5B    BH    ROQMOV5             IF HI/ LO NEW COLLATES AFTER ITEM 5  38700013
         SPACE 1                                                        38800013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 4 + BEFORE ITEM 5        38900013
         SPACE 1                                                        39000013
ROQMOV4  LR    RI,RD                                                    39100013
         LR    RD,RE                                                    39200013
         STM   RF,RI,ROQMRGAU                                           39300013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              39400013
         SPACE 2                                                        39500013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 5 + BEFORE ITEM 6        39600013
         SPACE 1                                                        39700013
ROQMOV5  LR    RJ,RD                                                    39800013
         LR    RD,RE                                                    39900013
         STM   RF,RJ,ROQMRGAU                                           40000013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              40100013
         SPACE 2                                                        40200013
IERROC7  CLC   0(1,RD),0(RK)       COMPARE NEW ITEM WITH ITEM 7         40300013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             40400013
ROQ7B    BH    ROQMOV7             IF HI/LO NEW COLLATES AFTER ITEM 7   40500013
         SPACE 1                                                        40600013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 6 + BEFORE ITEM 7        40700013
         SPACE 1                                                        40800013
ROQMOV6  LR    RK,RD                                                    40900013
         LR    RD,RE                                                    41000013
         STM   RF,RK,ROQMRGAU                                           41100013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              41200013
         SPACE 2                                                        41300013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 7                      41400013
         SPACE 1                                                        41500013
ROQMOV7  ST    RD,ROQMRGAM-4                                            41600013
         LR    RD,RE                                                    41700013
         STM   RF,RK,ROQMRGAU                                           41800013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              41900013
         SPACE 2                                                        42000013
IERROC3  CLC   0(1,RD),0(RG)       COMPARE NEW ITEM WITH ITEM 3         42100013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             42200013
ROQ3B    BH    ROQMOV3             FIT INTO COLLATING SEQUENCE          42300018
         SPACE 1                                                        42400013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 2 + BEFORE ITEM 3        42500013
ROQMOV2  LR    RG,RD                                                    42600013
         LR    RD,RE                                                    42700013
         STM   RF,RG,ROQMRGAU                                           42800013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              42900013
         SPACE 2                                                        43000013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 3 + BEFORE ITEM 4        43100013
         SPACE 1                                                        43200013
ROQMOV3  LR    RH,RD                                                    43300013
         LR    RD,RE                                                    43400013
         STM   RF,RH,ROQMRGAU                                           43500013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              43600013
         SPACE 2                                                        43700013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 1 + BEFORE ITEM 2        43800013
         SPACE 1                                                        43900013
ROQMOV1  ST    RD,ROQMRGAU                                              44000013
         LR    RD,RE                                                    44100013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              44200013
         SPACE 2                                                        44300013
*    SPECIAL ITEM 4 COMPARE FOR 5 WAY MERGE                             44400013
IERROQ4S CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 4         44500013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             44600013
ROQS4B   BH    ROQMOV4             IF HI/LO GO TO UPDATE                44700013
         B     IERROC3             GO TO COMPARE NEW ITEM WITH ITEM 3   44800013
         EJECT                                                          44900013
*    THE NETWORK CUTBACK SECTION. CHART OF                              45000013
*    IT IS THAT CODE WHICH TAILORS THE NETWORK FOR THE MERGE ORDER      45100013
         SPACE 1                                                        45200013
*    THE INITIAL ENTRANCE TO THE CUTBACK SECTION                        45300013
         SPACE 1                                                        45400013
*    SET NETWORK FOR A 16 WAY MERGE                                     45500013
         SPACE 1                                                        45600013
ROQCSSWM MVC   ROQNTENS(4),ROQSESC8  SET NTWK ENTR SW FOR NEW/ITM 8 CMP 45700013
         MVI   ROQLF16+1,X'4A'     LOAD NTWK REG WITH ITEMS 9 THRU 15   45800013
         MVI   ROQLF8+1,X'4A'      LOAD NTWK REG WITH ITEMS 1 THRU 7    45900013
         MVC   ROQ12B(4),ROQ12SB   SET BR TO CMP ITEM 14 AFT ITEM 12    46000013
         MVC   ROQ4B(4),ROQST4B    SET BR TO CMP ITEM 6 AFT ITEM 4 CMP  46100013
         MVC   ROQ14B(4),ROQS14B   SET BR TO CMP ITEM 15 AFT ITEM 14    46200013
         MVC   ROQ6B(4),ROQS6B     SET BR TO CMP ITEM 7 AFT ITEM 6 CMP  46300013
         MVC   ROQ10B(4),ROQS10B   SET BR TO CMP ITEM 11 AFT ITEM 10    46400013
         MVC   ROQ2B(4),ROQS2B     SET BR TO CMP ITEM 3 AFT ITEM 2 CMP  46500013
         MVC   ROQPNELA(4),ROQSPNS1 SET NTWK ENTRANCE FOR ITMS 9 TO 15  46600013
         MVC   ROQPNEL9(4),ROQSPNS2 SET NTWK ENTRANCE FOR ITMS 1 TO 7   46700013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 46800013
         SPACE 1                                                        46900013
*    SET NETWORK FOR A 15 WAY MERGE                                     47000013
         SPACE 1                                                        47100013
         MVC   ROQ14B(4),ROQFTWM   SET BR TO UPDATE AFTER ITEM 14 CMP   47200013
         MVI   ROQLF16+1,X'49'     LOAD NTWK REG WITH ITEMS 9 THRU 14   47300013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 47400013
         SPACE 1                                                        47500013
*    SET NETWORK FOR A 14 WAY MERGE                                     47600013
         SPACE 1                                                        47700013
         MVC   ROQ12B(4),ROQ14WM   SET BR TO CMP ITEM 13 AFT ITEM 12    47800013
         MVI   ROQLF16+1,X'48'     LOAD NTWK REG WITH ITEMS 9 TO 13     47900013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 48000013
         SPACE 1                                                        48100013
*    SET NETWORK FOR A 13 WAY MERGE                                     48200013
         SPACE 1                                                        48300013
         MVC   ROQ10B(4),ROQ13WM   SET BR TO CMP ITEM 12 AFT ITM 10 CMP 48400013
         MVI   ROQLF16+1,X'47'     LOAD NTWK REG WITH ITEMS 9 TO 12     48500013
         MVC   ROQPNELA(4),ROQE13WM SET NTWK ENTR FOR A 13 WAY MERGE    48600013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 48700013
         SPACE 1                                                        48800013
*    SET NETWORK FOR A 12 WAY MERGE                                     48900013
         SPACE 1                                                        49000013
         MVC   ROQ10B(4),ROQS10B   SET BR TO CMP ITEM 11 AFT ITM 10 CMP 49100013
         MVI   ROQLF16+1,X'46'     LOAD NTWK REG WITH ITEMS 9 TO 11     49200013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 49300013
         SPACE 1                                                        49400013
*    SET NETWORK FOR AN 11 WAY MERGE                                    49500013
         SPACE 1                                                        49600013
         MVC   ROQ10B(4),ROQ11WM   SET BR TO UPDATE AFT ITEM 10 CMP     49700013
         MVI   ROQLF16+1,X'45'     LOAD NTWK REG WITH ITEMS 9 + 10      49800013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 49900013
         SPACE 1                                                        50000013
*    SET NETWORK FOR A 10 WAY MERGE                                     50100013
         SPACE 1                                                        50200013
         MVC   ROQPNELA(4),ROQE10WM SET NTWK ENTR FOR A 10 WAY MRG      50300013
         MVI   ROQLF16+1,X'44'     LOAD NTWK REG WITH ITEM 9            50400013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 50500013
         SPACE 1                                                        50600013
*    SET NETWORK FOR A 9 WAY MERGE                                      50700013
         SPACE 1                                                        50800013
         MVC   ROQPNELA(4),ROQE9WM SET NTWK ENTR FOR A 9 WAY MERGE      50900013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 51000013
         SPACE 1                                                        51100013
*    SET NETWORK FOR AN 8 WAY MERGE                                     51200013
         SPACE 1                                                        51300013
         XI    ROQNTENS+1,X'F0'    SET NTWK ENTR SW FOR 8/LESS MRG ORD  51400013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 51500013
         SPACE 1                                                        51600013
*    SET NETWORK FOR A 7 WAY MERGE                                      51700013
         SPACE 1                                                        51800013
         MVC   ROQ6B(4),ROQ7WM     BR TO UPDATE IF GT ITEM 7            51900013
         MVI   ROQLF8+1,X'49'      LOAD NTWK REG WITH ITEMS 1 TO 6      52000013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 52100013
         SPACE 1                                                        52200013
*    SET NETWORK FOR A 6 WAY MERGE                                      52300013
         SPACE 1                                                        52400013
         MVC   ROQ4B(4),ROQ6WM     BR TO CMP ITEM 5 IF GT ITEM 4        52500013
         MVI   ROQLF8+1,X'48'      LOAD NETWORK REG WITH ITEMS 1 TO 5   52600013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 52700013
         SPACE 1                                                        52800013
*    SET NETWORK FOR A 5 WAY MERGE                                      52900013
         SPACE 1                                                        53000013
         MVC   ROQ2B(4),ROQ5WM     BR TO CMP ITEM 4 IF GT ITEM 2        53100013
         MVI   ROQLF8+1,X'47'      LOAD NTWK REG WITH ITEMS 1 TO 4      53200013
         MVC   ROQPNEL9(4),ROQE5WM SET NTWK ENTR FOR A 5 WAY MRG        53300013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 53400013
         SPACE 1                                                        53500013
*    SET NETWORK FOR A 4 WAY MERGE                                      53600013
         SPACE 1                                                        53700013
         MVC   ROQ2B(4),ROQS2B     BR TO CMP ITEM 3 IF GT ITEM 2        53800013
         MVI   ROQLF8+1,X'46'      LOAD NTWK REG WITH ITEMS 1 TO 3      53900013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 54000013
         SPACE 1                                                        54100013
*    SET NETWORK FOR A 3 WAY MERGE                                      54200013
         SPACE 1                                                        54300013
         MVC   ROQ2B(4),ROQ3WM     BR TO UPDATE IF GT ITEM 2            54400013
         MVI   ROQLF8+1,X'45'      LOAD NTWK REG WITH ITEMS 1 + 2       54500013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 54600013
         SPACE 1                                                        54700013
*    SET NETWORK FOR A 2 WAY MERGE                                      54800013
         SPACE 1                                                        54900013
         MVC   ROQPNEL9(4),ROQE2WM SET NTWK ENTR FOR A 2 WAY MERGE      55000013
         MVI   ROQLF8+1,X'44'      LOAD NTWK REG WITH ITEM 1            55100013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 55200013
         SPACE 1                                                        55300013
*    SET NETWORK FOR A 1 WAY MERGE                                      55400013
         SPACE 1                                                        55500013
         MVC   ROQPNEL9(4),ROQE1WM SET NTWK ENTR FOR A 1 WAY MERGE      55600013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 55700013
         SPACE 1                                                        55800013
*    A ZERO WAY MERGE                                                   55900013
         SPACE 1                                                        56000013
*    IF PHASE 2 EXIT TO THE BLOCK RTN (RELEASE CURRENT BLK TO WRITE)    56100013
*    IF PHASE 3 OR MERGE ONLY EXIT TO THE BLOCK RTN (END OF JOB)        56200013
         SPACE 1                                                        56300013
IERDOCPS BC    0,ROQCPH3           FALL THRU IF PHASE 2                 56400013
         L     RL,PPIBLK2+4                                             56500013
         BR    RL                  BLOCK/DEBLOCK                        56600018
         SPACE 2                                                        56700013
ROQCPH3  L     RL,PPIBLK+4                                              56800013
         BR    RL                  BLOCK                                56900018
         SPACE 2                                                        57000013
*    THIS IS ENTRY TO THE CUTBACK RTN FROM READ RTN + THE ALGORITHM     57100013
         SPACE 1                                                        57200013
ROQCUTEN L     RC,ROQSVCBA         SET APPROPRIATE CUTBACK SECTION ADDR 57300013
         BR    RC                  NEXT WORD OF CUTBACK                 57400018
         SPACE 2                                                        57500013
*    THIS SECTION OF CODE ENTERED UPON COMPLETION OF A CUTBACK OPERTION 57600013
*    THIS SECTION INITIALLY CHECKS FOR THE NETWORK BEING SET FOR THE    57700013
*    MERGE ORDER. SUBSEQUENTLY AN UPDATE IS EXECUTED. CHART OG          57800013
         SPACE 1                                                        57900013
ROQFMUDS BC    0,ROQFDMO           SET TO BRANCH BY INITIALIZATION RTN  58000013
*    FALL THRU FOR UPDATING NETWORK AFTER A CUTBACK OPERATION           58100013
         SPACE 1                                                        58200013
         ST    RC,ROQSVCBA                                              58300013
         L     RD,ROQMRGAU                                              58400013
         L     RE,ROQACMO          MERGE ORDER LESS 1 MINUS 1           58500013
         S     RE,KROONE                                                58600013
         ST    RE,ROQACMO                                               58700013
         SLL   RE,2                TOTAL NO. BYTES TO BE UPDATED        58800013
         EX    RE,ROQUPDT          EXECUTE MOVE INSTR                   58900013
         SPACE 1                                                        59000013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              59100013
         SPACE 2                                                        59200013
         SPACE 2                                                        59300013
ROQFDMO  L     RF,ROQIDMO          SET TO 16 BY INITIALIZATION RTN      59400013
         C     RF,ROQACMO          SET TO ACTUAL MERGE ORDER BY INITIAL 59500013
         BE    ROQSFTTU            SET FALL THRU TO UPDATE              59600013
         S     RF,KROONE                                                59700013
         ST    RF,ROQIDMO                                               59800013
         BR    RC                  BRANCH BACK TO CUTBACK RTN           59900013
         SPACE 2                                                        60000013
ROQSFTTU XI    ROQFMUDS+1,X'F0'    SET ROQFMUDS BRANCH TO FALL THRU     60100013
         ST    RC,ROQSVCBA         SAVE ADDRESS OF NEXT CUTBACK CODE    60200013
         B     ROQINTSQ            GO TO INIT SEQ THE RECORDS           60300013
         EJECT                                                          60400013
*    INITIAL SEQUENCING OF RECORDS SECTION EXECUTED AT THE BEGINNING OF 60500013
*    EACH MERGE OPERATION.                                              60600013
*    A RELATIVE POSITION METHOD IS EMPLOYED FOR THE SEQUENCING.         60700013
*    THIS METHOD CAN BE DESCRIBED AS COMPARING ONE ITEM OF A LIST WITH  60800013
*       THE REMAINDER OF THE ITEMS AND,THEREBY,DETERMINING ITS PROPER   60900013
*       POSITION IN THE LIST. TO ACCOMPLISH THIS,A TWO AREA SYSTEM IN   61000013
*       PPI IS UTILIZED.                                                61100013
         SPACE 1                                                        61200013
ROQINTSQ SR    RI,RI               INDEX USED TO GET ITEMS TO BE SEQD   61300013
         L     RB,ROQACMO          DETERMINES WHEN ALL ITEMS ARE SEQD   61400013
         LA    RG,PPIPDWA          BEGINNING ADDR OF RCD ADDR IN PPI    61500013
ROQRETRN L     RF,ROQACMO          USED TO CHECK WHEN AN ITEM HAS BEEN  61600013
*                                  CHECKED WITH ALL THE OTHER ITEMS     61700013
         L     RD,0(RI,RG)         THE ITEM WE ARE POSITIONING          61800013
         LA    RE,PPIPSVA-4        ADDR WHERE ITEM IS STORED AFT POS FD 61900013
         SR    RH,RH               INDEX USED TO COMPARE ALL OTHER ITEM 62000013
ROQANOTH L     RC,0(RH,RG)         ADDR OF ITEMS CMP TO ITEM IN RC      62100013
IERDOICP CLC   0(1,RD),0(RC)                                            62200013
*    THIS BRANCH INSTR IS BC 10 OR 12 DEPENDING ON THE INPUT SEQUENCE   62300013
ROQISNLH BC    10,ROQHIEQ          HI/LO AND EQUAL CASE TREATED SAME    62400013
ROQDECR  LA    RH,4(0,RH)                                               62500013
         BCT   RF,ROQANOTH         DECREMENT MERGE ORDER                62600018
ROQCHEK  CLC   0(4,RE),KROZERO     STORAGE AREA OF ITEMS IS INITIALLY   62700013
*                                  ZERO CHECKED TO INSURE THAT ANOTHER  62800013
*                                  ITEM DOES NOT OCCUPY THIS POSITION   62900013
         BE    ROQINSRT            IF ZERO STORE ITEM                   63000013
         S     RE,KROFOUR          IF EQUAL CHECK NEXT LOWER POSITION   63100013
         B     ROQCHEK             CHECK NEXT ITEM                      63200018
         SPACE 2                                                        63300013
ROQINSRT ST    RD,0(0,RE)          STORE POSITIONED ITEM                63400013
         BCT   RB,ROQINCR          IF NOT DONE GET NEXT ITEM TO POSITIN 63500013
         B     ROQOUTIS            BRANCH TO SET NETWORK ADDRESS        63600013
         SPACE 2                                                        63700013
ROQHIEQ  LA    RE,4(0,RE)                                               63800013
         B     ROQDECR             GO TO DECREMENT MERGE ORDER          63900018
         SPACE 2                                                        64000013
ROQINCR  LA    RI,4(0,RI)                                               64100013
         B     ROQRETRN            BRANCH FOR END OF COMPARE            64200018
         SPACE 2                                                        64300013
*    SET NETWORK AREA WITH ADDRESSES OF PRIMED RECORDS                  64400013
         SPACE 1                                                        64500013
ROQOUTIS L     RD,PPIPSVA          SET REG WITH WINNING RECORD ADDR     64600013
         L     RE,ROQACMO                                               64700013
         S     RE,KROONE                                                64800013
         LR    RF,RE                                                    64900013
         SLL   RE,2                                                     65000013
         LTR   RE,RE                                                    65100013
         BZ    ROQSTM              IF ZERO BYPASS NSI                   65200018
         S     RE,KROONE           DET NO. BYTES TO BE MOVED TO MRG ARA 65300013
         EX    RE,ROQSANW          EXECUTE MOVE OF ADDR TO MOVE AREA    65400013
ROQSTM   ST    RF,ROQACMO          SET ACTUAL MERGE ORDER MINUS ONE FOR 65500013
*                                  UPDATING AFTER A CUTBACK OPERATION   65600013
         XI    ROQFRSW1+1,X'F0'    SETTING OF FIRST RCD SW TO BRANCH    65700013
         XI    ROQFRSW2+1,X'F0'                                         65800013
         XI    ROQBBFIS+1,X'F0'                                         65900013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              66000013
         SPACE 2                                                        66100013
         EJECT                                                          66200013
*    THIS IS SELF INITIALIZATION SECTION PERFORMED AT THE BEGINNING     66300013
*    OF EACH PASS OR SUB PASS.                                          66400013
         SPACE 1                                                        66500013
ROQSINIT MVC   ROQIDMO(4),KROSXTN  SET MAX MERGE ORDER TO 16            66600013
         LH    RE,PPIMRGMX         SET ACTUAL MRG ORD FROM PPI          66700013
         ST    RE,ROQACMO                                               66800013
         SR    RE,RE                                                    66900013
         ST    RE,PPIPSVA                                               67000013
         MVC   PPIPSVA+4(60),PPIPSVA   ZERO INT SEQ STORE AREA          67100013
         XI    ROQFMUDS+1,X'F0'    SET ROQFMUDS TO BRANCH               67200013
         TM    PPISW1+3,X'10'      IS INPUT SEQ ASDNG OR DESCG          67300013
         BC    1,ROQISD            FALL THRU IF INPUT SEQ IS ASDNG      67400013
         TM    ROQ12B+1,X'20'      IS ROUTINE SET FOR ASDNG             67500013
ROQFDSQ  BC    1,IERDOSET          IF THE ROUTINE IS SET FOR THE INPUT  67600013
         XI    ROQWHB+1,X'60'      SEQUENCE,BRANCH TO EXTRACT TEST. IF  67700013
         XI    ROQ12B+1,X'60'      THE ROUTINE IS NOT SET FOR THE INPUT 67800013
         XI    ROQ10B+1,X'60'      CHANGE THE MASK OF THE BRANCH ON     67900013
         XI    ROQ9B+1,X'60'       CONDITION INSTR.                     68000013
         XI    ROQSCB+1,X'60'                                           68100013
         XI    ROQ14B+1,X'60'                                           68200013
         XI    ROQ13B+1,X'60'                                           68300013
         XI    ROQ15B+1,X'60'                                           68400013
         XI    ROQ11B+1,X'60'                                           68500013
         XI    ROQS12B+1,X'60'                                          68600013
         XI    ROQ4B+1,X'60'                                            68700013
         XI    ROQ2B+1,X'60'                                            68800013
         XI    ROQ1B+1,X'60'                                            68900013
         XI    ROQ6B+1,X'60'                                            69000013
         XI    ROQ5B+1,X'60'                                            69100013
         XI    ROQ7B+1,X'60'                                            69200013
         XI    ROQ3B+1,X'60'                                            69300013
         XI    ROQS4B+1,X'60'                                           69400013
         XI    ROQISNLH+1,X'60'                                         69500013
         XI    ROQ12SB+1,X'60'                                          69600013
         XI    ROQST4B+1,X'60'                                          69700013
         XI    ROQS14B+1,X'60'                                          69800013
         XI    ROQS6B+1,X'60'                                           69900013
         XI    ROQS10B+1,X'60'                                          70000013
         XI    ROQS2B+1,X'60'                                           70100013
         XI    ROQFTWM+1,X'60'                                          70200013
         XI    ROQ14WM+1,X'60'                                          70300013
         XI    ROQ13WM+1,X'60'                                          70400013
         XI    ROQ11WM+1,X'60'                                          70500013
         XI    ROQ7WM+1,X'60'                                           70600013
         XI    ROQ6WM+1,X'60'                                           70700013
         XI    ROQ5WM+1,X'60'                                           70800013
         XI    ROQ3WM+1,X'60'                                           70900013
IERDOSET BC    0,ROQCSSWM          FALL THRU IF EXTRACTING              71000013
*                                  IF NOT EXTRACTING,GO TO CUTBACK CODE 71100013
         LM    RD,RE,IERDOAGE      ADDR + LGH OF EXTRACT INFO           71200013
         LA    RK,PPIPDWA          ADDR OF RCDS IN PPI                  71300013
         L     RG,KROONE           INDEX TO DETERMINE WHEN DONE         71400013
         LR    RI,RG                                                    71500013
         L     RJ,ROQACMO                                               71600013
ROQRLD   L     RC,0(0,RK)          SET FROM ADDR FOR EXTR RTN           71700013
         STM   RE,RK,ROQSVREG      SAVE MERGE REG                       71800013
         BAL   RO,4(0,RM)          EXTRACT THIS RECORD                  71900013
         LM    RE,RK,ROQSVREG      RESTORE MERGE REG                    72000013
         ST    RC,0(0,RD)          STORE ADDR OF RCD AT EXTR POS        72100013
         ST    RD,0(0,RK)          STORE EXTR POS ADDR IN PPIPDWA AREA  72200013
         AR    RD,RE               INCR EXTR POS LENGTH                 72300013
         A     RK,KROFOUR          INCR TO NEXT RCD ADDR IN PPIPDWA     72400013
         BXLE  RG,RI,ROQRLD        ARE WE DONE EXTR THE RCDS IN PPIPDWA 72500013
         ST    RD,ROQSQCWD         SAVE NEXT EXTR POS ADDR              72600013
         B     ROQCSSWM            BRANCH TO CUTBACK SECTION            72700013
         SPACE 2                                                        72800013
*    THE INPUT SEQUENCE IS IN DESCENDING ORDER                          72900013
         SPACE 1                                                        73000013
ROQISD   TM    ROQ12B+1,X'40'      IS ROUTINE SET FOR DESCG             73100013
         B     ROQFDSQ             GO TO CHANGE BRANCHES                73200018
         SPACE 2                                                        73300013
*    EXECUTED MOVE INSTRUCTIONS                                         73400013
         SPACE 1                                                        73500013
ROQUPDT  MVC   ROQMRGAU(1),ROQMRGAU+4  UPDATING NETWORK ADDRESSES       73600013
ROQSANW  MVC   ROQMRGAU(1),PPIPSVA+4   SET NETWORK WITH PRIMED ADDRS    73700013
         EJECT                                                          73800013
         DS    0F                                                       73900013
ROQSVREG DS    7F                  REGISTER SAVE AREA FOR INTERFACING   74000013
ROQMRGAU DS    7F                  ADDR OF FIRST 7 RCDS FOR MRG NTWK    74100013
ROQMRGAM DS    1F                  ADDR OF RECORD 8 OF MRG NTWK         74200013
ROQMRGAL DS    7F                  ADDR OF LAST 7 RCDS FOR MRG NTWK     74300013
ROQSVEXA DS    1F                  SAVE AREA FOR ADDR OF EXTR POS       74400013
ROQSQCWD DS    1F                  WORD TO SAVE ADDRESS OF EXTRACT POS  74500013
*                                  OF RCD FOR SEQUENCE CHECK            74600013
ROQSVCBA DS    1F                  SAVE NEXT CUTBACK ADDRESS WORD       74700013
IERDOAGE DS    1F                  BEGIN ADDR FOR GENERATED EXTRACT POS 74800013
IERDOEXL DS    1F                  LGH OF EXTR CTRL FLDS + 4 ADDR BYTES 74900013
ROQIDMO  DS    1F                  MAXIMUM MERGE ORDER SET BY INITIAL   75000013
ROQACMO  DS    1F                  ACTUAL MERGE ORDER SET BY INITIAL    75100013
*********************************************************************** 75200013
KROSXTN  DC    X'00000010'         MAXIMUM MERGE ORDER                  75300018
KROONE   DC    XL4'1'              CONSTANT OF ONE                      75400018
KROZERO  DC    XL4'0'              CONSTANT OF ZERO                     75500018
KROFOUR  DC    XL4'4'              CONSTANT OF FOUR                     75560018
ROQTEMP  DC    H'0'                TEMP STORAGE FOR UNIT NUMBER         75630017
ROQCONV  DC    D'0'                CONVERSION AREA FOR UNIT NUMBER      75660017
*********************************************************************** 75700013
         SPACE 2                                                        75800013
ROQSESC8 BC    0,ROQLF8            SET NTWK ENTR SW TO CMP NEW VS ITM 8 75900013
*    THE FOLLOWING 14 INSTR ARE SET DEPENDING ON THE INPUT SEQUENCE     76000013
*       TO BH OR BL                                                     76100013
ROQ12SB  BH    IERROC14            BR TO CMP ITEM 14 AFT ITEM 12 CMP    76200013
ROQST4B  BH    IERROC6             BR TO CMP ITEM 6 AFT ITEM 4 CMP      76300013
ROQS14B  BH    IERROC15            BR TO CMP ITEM 15 AFT ITEM 14 CMP    76400013
ROQS6B   BH    IERROC7             BR TO CMP ITEM 7 AFT ITEM 6 CMP      76500013
ROQS10B  BH    IERROC11            BR TO CMP ITEM 11 AFT ITEM 10 CMP    76600013
ROQS2B   BH    IERROC3             BR TO CMP ITEM 3 AFT ITEM 2 CMP      76700013
ROQFTWM  BH    ROQMOV14            BR TO UPDATE IF GT ITEM 14           76800013
ROQ14WM  BH    IERROC13            BR TO CMP ITEM 13 AFT ITEM 12 CMP    76900013
ROQ13WM  BH    IERROQS4            BR TO CMP ITEM 12 AFT ITEM 10 CMP    77000013
ROQ11WM  BH    ROQMOV10            BR TO UPDATE AFT ITEM 10 CMP         77100013
ROQ7WM   BH    ROQMOV6             BR TO UPDATE IF GT ITEM 7            77200013
ROQ6WM   BH    IERROC5             BR TO CMP ITEM 5 AFT ITEM 4 CMP      77300013
ROQ5WM   BH    IERROQ4S            BR TO CMP ITEM 4 IF GT ITEM 2        77400013
ROQ3WM   BH    ROQMOV2             BR TO UPDATE AFT ITEM 10 CMP         77500013
         SPACE 1                                                        77600013
         SPACE 2                                                        77700013
         SPACE 2                                                        77800013
ROQSPNS1 B     IERROQL4            SET ENTRANCE SW FOR PARTIAL NTWK     77900013
ROQSPNS2 B     IERROQU4            SET ENTRANCE SW FOR PARTIAL NTWK     78000013
ROQE13WM B     IERROQL2            ENTRANCE FOR A 11,12,13 WAY MRG      78100013
ROQE10WM B     IERROQL1            ENTRANCE FOR A 10 WAY MERGE          78200013
ROQE9WM  B     ROQ9WMRG            ENTRANCE FOR A 9 WAY MERGE           78300013
ROQE5WM  B     IERROQU2            ENTRANCE FOR A 3,4,5 WAY MERGE       78400013
ROQE2WM  B     IERROQU1            ENTRANCE FOR A 2 WAY MRG             78500013
ROQE1WM  B     ROQ1WMRG            ENTRANCE FOR A 1 WAY MRG             78600013
*********************************************************************** 78700013
         EJECT                                                          78800013
*                                                                       78900013
* MODULE NAME ***IERRMC***                                              79000013
*                                                                       79100013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        79200013
* PHASE 3 OR MERGE ONLY RUNNING PROGRAM.                                79300013
         SPACE 1                                                        79400013
DIERRMC  DSECT                                                          79500013
*                                                                       79600013
       COPY  RMCMAIN                                                    79700013
*                                                                       79800013
         SMPPI                                                          79900013
         END                                                            80000013
