         TITLE ' IERROR - OS/360 SORT /MERGE - 360S-SM-023 02/15/65 '   00200013
*MODULE NAME:*** IERROR ***                                             00400013
         SPACE 2                                                        00600013
*STATUS: CHANGE LEVEL 000                                               00800013
         SPACE 2                                                        01000013
*MODULE FUNCTION/OPERATION: MERGE PHASE BALANCED TAPE ALGORITM.         01200013
*   THE FUNCTION OF THIS MODULE IS TO CONTROL:                          01400013
*   A. POINTERS FOR OUTPUT UNITS DURING MERGE.                          01600013
*   B. COUNTERS CONTROLLING TAPE TABLE.                                 01800013
*   C. NUMBER OF STRINGS PUT OUT.                                       02000013
*   D. SET OPEN AND CLOSE BITS FOR DCB'S.                               02200013
*   E. CHECKING FOR NMAX EXCEEDED OR UNENDING MERGE. IF CONDITIONS.     02400013
*      OCCUR, IT ISSUES A MESSAGE AND RETURNS TO SORT SYSTEM CONTROL.   02600013
*   F. SUPPLYING DISPLACEMENT TO DCB TABLE.                             02800013
*   G. DECIDES IF PHASE 2 OR TO GO TO PHASE 3.                          03000013
*    1 IF STILL PHASE TWO AND END OF PASS IT TURNS OFF SWITCHES THAT    03200013
*      CONTROL BLOCKING DIRECTION AND REWINDING.                        03400013
*    2 IF STILL  PHASE TWO AND END OF PASS AND READ FORWARD LATER BIT   03600013
*      IS ON IT SETS READ FORWARD SWITCH ON AND REWIND ON.              03800013
*    3 IF STILL PHASE TWO AND END OF PASS AND PHASE 3 SEQUENCE WOULD BE 04000013
*      IN WRONG ORDER AND WITHIN TWO PASSES OF END OF PHASE2,IT TURNS   04200013
*      ON BLOCK FORWARD AND READ FORWARD LATER SWITCHES.                04400013
         SPACE 2                                                        04600013
*USED AS A DSECT IN - IERAOR                                            04800013
*                                                                       05000013
*                                                                       05200013
*MACROS USED -                                                          05400013
         SPACE 1                                                        05600013
*   SMPPI                                                               05800013
         SPACE 2                                                        06000013
*ENTRY POINTS:                                                          06200013
         SPACE 1                                                        06400013
*        ENTRY IERROR              ENTRY FROM: IERRPD                   06600013
*                                    CALLING SEQUENCE-                  06800013
*                                      LA   RL,PPIALG+4                 07000013
*                                      B    DISP(0,RL                   07200013
*                                      WHERE DISP = 4 FOR END OF VOL &  07400013
*                                                     NOT END OF SEQ.   07600013
*                                                 = 8 FOR END OF VOL &  07800013
*                                                     END OF SEQUENCE.  08000013
*                                                 =16 FOR END OF SEQ.   08200013
*                                                 = O FOR DUMMY LINK TO 08400013
*                                                     READ PRIME        08600013
*                                  ENTRY FROM: IERRGB                   08800013
*                                    CALLING SEQUENCE -                 09000013
*                                      LA   RL,PPIALG+4                 09200013
*                                      BAL  RO,12(0,RL) = LOAD PT REACH 09400013
         SPACE 2                                                        09600013
*INPUT: PPI FIELDS REFERENCED-                                          09800013
         SPACE 1                                                        10000013
*   PPIRD    PPIADSSC  PPIMRGMX  PPISW1                                 10200013
*   PPIWRT   PPIMRGAL  PPISEQCT                                         10400013
         SPACE 2                                                        10600013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             10800013
         SPACE 1                                                        11000013
*    PPISW1     PPIMRGAL  PPISEQCT                                      11200013
*    PPIDEPHO   PPIMRGMX                                                11400013
         SPACE 2                                                        11600013
*EXTERNAL ROUTINES:                                                     11800013
         SPACE 1                                                        12000013
*        EXTRN IERRMB              MESSAGE PROGRAM                      12200013
*        EXTRN IERRGB              READ PROGRAM                         12400013
*        EXTRN IERRGB              WRITE PPOGRAM                        12600013
*        EXTRN IERRCV              CONTROL PROGRAM                      12800013
         SPACE 2                                                        13000013
*EXTERNAL PARAMETERS: NONE                                              13200013
         SPACE 1                                                        13400013
*EXITS: NORMAL                                                          13600013
         SPACE 1                                                        13800013
*        IERRCV                    LOAD END OF PHASE EXIT IN CALLER     14000013
*        IERRGB                    READ PROGRAM USED AT PRIMING AND     14200013
*                                    LOAD POINT RETURN                  14400013
*        IERRPD                    WRITE PROGRAM                        14600013
         SPACE 2                                                        14800013
*EXITS: ERROR                                                           15000013
         SPACE 1                                                        15200013
*        IERRCV                    ERROR EXITS AFTER 'NMAX EXCEEDED' OR 15400013
*                                    'UNENDING MERGE' MESSAGES          15600013
         SPACE 2                                                        15800013
*TABLES/WORK AREAS: N/A                                                 16000013
         SPACE 1                                                        16200013
         SPACE 2                                                        16400013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  16600013
         SPACE 2                                                        16800013
*NOTES: NONE                                                            17000013
         SPACE 1                                                        17200013
         SPACE 2                                                        17400013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            17600013
         SPACE 1                                                        17800013
RA       EQU   0                   CONTENTS IN- N/A                     18000013
*                                  USE- MESSAGE STARTING ADDRESS        18200013
*                                  CONTENTS OUT- N/A                    18400013
RB       EQU   1                   CONTENTS IN- N/A                     18600013
*                                  USE- LENGTH OF MESSAGE IF ERROR OR   18800013
*                                      O TO INDICATE PHASE 2 AND 4= PH3 19000013
*                                  CONTENTS OUT- AS IN USE.             19200013
RC       EQU   2                   CONTENTS IN- N/A                     19400013
*                                  USE- UNUSED                          19600013
*                                  CONTENTS OUT- N/A                    19800013
RD       EQU   3                   CONTENTS IN- INCREMENT OF UNITS AL   20000013
*                                    LOAD POINT OR END OF FILE.         20200013
*                                  USE- INCREMENT REGISTER              20400013
*                                  CONTENTS OUT- N/A                    20600013
RE       EQU   4                   CONTENTS IN- N/A                     20800013
*                                  USE- GENERAL WORK REGISTER           21000013
*                                  CONTENTS OUT- N/A                    21200013
RF       EQU   5                   CONTENTS IN- N/A                     21400013
*                                  USE- GENERAL WORK REGISTER           21600013
*                                  CONTENTS OUT- N/A                    21800013
RG       EQU   6                   CONTENTS IN- N/A                     22000013
*                                  USE- UNUSED                          22200013
*                                  CONTENTS OUT- N/A                    22400013
RH       EQU   7                   CONTENTS IN- N/A                     22600013
*                                  USE- UNUSED                          22800013
*                                  CONTENTS OUT- N/A                    23000013
RI       EQU   8                   CONTENTS IN- N/A                     23200013
*                                  USE- UNUSED                          23400013
*                                  CONTENTS OUT- N/A                    23600013
RJ       EQU   9                   CONTENTS IN- N/A                     23800013
*                                  USE- UNUSED                          24000013
*                                  CONTENTS OUT- N/A                    24200013
RK       EQU   10                  CONTENTS IN- N/A                     24400013
*                                  USE- UNUSED                          24600013
*                                  CONTENTS OUT- N/A                    24800013
RL       EQU   11                  CONTENTS IN- ADDRESS OF THIS MODULE  25000013
*                                  USE- BASE ADDRESS REGISTER           25200013
*                                  CONTENTS OUT- ADDRESS OF THIS MODULE 25400013
RM       EQU   12                  CONTENTS IN- EQUAL/EXTRACT ADDRESS   25600013
*                                  USE- NOT USED                        25800013
*                                  CONTENTS OUT- EQUAL/EXTRACT ADDRESS  26000013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          26200013
*                                  USE- PPI REFERENCE,REGISTER SAVE     26400013
*                                    AREA                               26600013
*                                  CONTENTS OUT- ADDRESS OF PPI         26800013
RO       EQU   14                  CONTENTS IN- RETURN ADDRESS          27000013
*                                  USE- RETURN REGISTER                 27200013
*                                  CONTENTS OUT- RETURN ADDRESS         27400013
RP       EQU   15                  CONTENTS IN- N/A                     27600013
*                                  USE- COMPLETION CODE                 27800013
*                                  CONTENTS OUT- N/A                    28000013
         EJECT                                                          28200013
         SPACE 2                                                        28400013
*START OF MODULE CODE PROPER:                                           28600013
IERROR   CSECT                                                          28800013
* 640000                                                         A24560 28900019
         USING *,RL                                                     29000013
         USING IERRCA,RN                                                29200013
IERDOT   B     RORSKIP                                                  29400013
         B     RORNLST                                                  29600013
         B     RORLST                                                   29800013
         B     RORLDPT                                                  30000013
*  END OF SEQUENCE - ENTRY VIA WRITE ROUTINE ************************** 30200013
*  BUMP NO. SEQ OUT BY 1 ********************************************** 30400013
ROREOSQ  L     RE,PPISEQCT+4                                            30600013
         LA    RE,1(0,RE)                                               30800013
         ST    RE,PPISEQCT+4                                            31000013
*  IS POINTER AT LIMIT OF TABLE { ************************************* 31200013
RORNORM  LH    RE,KLIMITX                                               31400013
         BCT   RE,RORGOB                                                31600013
*  SET POINTER TO ST. PT. ********************************************* 31800013
         MVC   KTBLPTBX(4),KTBLPTAX                                     32000013
*  RESET TABLE LIMIT CTR = CHGING ALT MRG ORDER *********************** 32200013
         LH    RE,PPIMRGAL                                              32400013
         STH   RE,KLIMITX                                               32600013
*  IS OPEN BYTE OFF IN THIS NEW UNIT{ ********************************* 32800013
RORGOC   L     RE,KTBLPTBX                                              33000013
         TM    0(RE),X'40'                                              33200013
         BZ    RORNORM             YES,BYTE OFF,SKIP UNIT               33400013
*  PUT'X'IN PPIDEPHO ************************************************** 33600013
         MVC   PPIDEPHO+3(1),1(RE)                                      33800013
*  IS'S'SWITCH ON{ **************************************************** 34000013
RORSSW   BC    0,RORSWOFF          IF YES,BRANCH                        34200013
*  EXIT TO READ PRIME ROUTINE ***************************************** 34400013
RORSKIP  L     RL,PPIRD+4                                               34600013
         B     4(0,RL)                                                  34800013
         SPACE 2                                                        35000013
*  RESTORE DECREMENTED COUNTER **************************************** 35200013
RORGOB   STH   RE,KLIMITX                                               35400013
*  INCREMENT TAPE POINTER ********************************************* 35600013
         L     RF,KTBLPTBX         GET TRVLG PTR.                       35800013
         LA    RF,2(0,RF)          BUMP BY 2                            36000013
         ST    RF,KTBLPTBX                                              36200013
         B     RORGOC                                                   36400013
         SPACE 2                                                        36600013
* THIS ROUTINE HAS THE RESPONSIBILITY OF DETERMINING IF PHASE 3 SHOULD  36800013
* BE CALLED. IF NOT,IT DETERMINES WHETHER WE ARE ABOUT TO ENTER EITHER  37000013
* THE LAST PASS OR THE NEXT TO LAST PASS OF PHASE 2 AND SETS SWITCHES   37200013
* IN PPI TO INDICATE IF FORWARD BLOCKING, REWINDING AND FORWARD READING 37400013
* IS REQUIRED TO ELIMINATE A PHASE 3 COPY PASS. THE TEST USED HERE CAN  37600013
* FAIL IF ANY REEL(S) CONTAINS A SINGLE SEQUENCE WHICH COMPLETELY FILLS 37800013
* THE REEL. IN THIS CASE, NEEDLESS REWINDING COULD OCCUR,BUT THE FINAL  38000013
* RESULT WILL BE CORRECT ANYWAY. THIS UNUSUAL CONDITION IS CONSIDERED   38200013
* UNLIKELY, SINCE SUCH FILES NORMALLY WILL BE HANDLED BY OSCILLATING,   38400013
* NOT BALANCED TAPE SORTS.                                              38600013
         SPACE 2                                                        38800013
* IS.THE NUMBER OF STRINGS OUT GREATER OR EQUAL TO NO. OF STRINGS IN    39000013
         SPACE 1                                                        39200013
RORGOA   CLC   PPISEQCT+4(4),PPISEQCT                                   39400013
         BNL   RORGOE              BRANCH TO UNENDING MERGE TEST        39600013
* SINCE COUNT OF SEQUENCES WAS REDUCED,RESET ERROR COUNTER FOR 2 RETRY. 39800013
         LA    RE,2                                                     40000013
         STH   RE,PPISEQCT+8                                            40200013
RORGOF   NI    PPISW1+6,X'8F'      TURN OFF BLK FRWD,READ FRWD & REWIND 40400013
         MVC   PPIMRGMX(2),KSVMAX  RESET M                              40600013
         TM    PPISW1+6,X'08'      IS READ FRWD LATER SW ON OR OFF      40800013
         BZ    RORX1               SKIP OVER SWITCH SETTING IF OFF      41000013
         XI    PPISW1+6,X'68'      TURN ON RD FRWD,REWIND,OFF RD LATER  41200013
         XI    PPISW1+3,X'10'      INVERT SEQ BIT (TO BYPASS INVERT)    41400013
         SPACE 1                                                        41600013
* IS S/M READY TO ENTER FINAL MERGE (IS SEQCT .LE. MRGAL).              41800013
         SPACE 1                                                        42000013
RORX1    LH    RE,PPIMRGAL         IS ALTERNAT5 MERGE .GE. TO           42200013
         CL    RE,PPISEQCT+4         STRINGS OUT.                       42400013
         BNL   RORPH3              BRANCH TO ENTER PHASE 3 IF TRUE.     42600013
         SPACE 2                                                        42800013
         MH    RE,KSVMAX           FORM MRGAL*KSVMAX(MAX SIZE OF ANY    43000013
         CL    RE,PPISEQCT+4         CASE WHERE S/M IS ABOUT TO ENTER   43200013
         BNL   RORLPASS              THE LAST PASS OF PHASE 2.)         43400013
         SPACE 2                                                        43600013
         MH    RE,PPIMRGAL         FORM MRGAL*KSVMAX*MRGAL (MAX SIZE    43800013
         CL    RE,PPISEQCT+4         CASE WHERE S/M IS ABOUT TO ENTER   44000013
         BNL   RORNXT2L            THE NEXT TO LAST PASS OF PHASE 2     44200013
         SPACE 2                                                        44400013
RORPH2NM NOP   RORPH2NM            THIS WAS CHANGED TO CORRECT COPY     44600013
*                                    PASS TROUBLE                       44800013
         B     RORGOG              GO EXIT TO SSC                       45000013
         SPACE 2                                                        45200013
RORNXT2L TM    PPISW1+3,X'60'      IF NOT EXTRACTING OR USER WANTS      45400013
         BC    14,RORCHK2            ASCENDING SEQUENCE GO TO CHK2      45600013
RORCHK1  TM    PPISW1+3,X'30'      IF USER SEQ IS OPPOSITE TO PRES SEQ  45800013
         BC    11,RORPH2NM         DO NOT PERFORM SPECIAL ROUTINES      46000013
RORSET   OI    PPISW1+6,X'18'      TURN ON READ FORW LATER & BLOCK      46200013
         B     RORGOG                FORWARD AND SET UP FOR PHASE 2     46400013
RORCHK2  TM    PPISW1+3,X'30'      IF USER SEQ IS SAME AS PRESENT SEQ   46600013
         BM    RORPH2NM            DO NOT PERFORM SPECIAL ROUTINES      46800013
         B     RORSET                                                   47000013
         SPACE 1                                                        47200013
RORLPASS TM    PPISW1+3,X'60'      IF NOT EXTRACTING OR USER WANTS      47400013
         BC    14,RORCHK1            ASCENDING SEQUENCE GO TO CHK1,     47600013
         B     RORCHK2               ELSE GO TO CHK2.                   47800013
         SPACE 2                                                        48000013
*  CALL PHASE 2 --- EXIT TO CLOSE RTN ********************************* 48200013
RORCLOSE L     RP,PPIADSSC                                              48400013
         XI    PPISW1+3,X'10'      REVERSE SEQUENCE INDICATOR BIT       48600013
         LA    RB,0                RETURN TO SSC REQUESTING PHASE 2.    48800013
         BAL   RO,20(0,RP)                                              49000013
*                                                                       49200013
*  SET MRG ORD.(REVERSE MAX AND ALT FOR ANOTHER PHASE 2)*************** 49400013
RORGOG   LH    RE,PPIMRGMX                                              49600013
         MVC   PPIMRGMX(2),PPIMRGAL                                     49800013
         STH   RE,PPIMRGAL                                              50000013
         B     RORCLOSE                                                 50200013
         SPACE 2                                                        50400013
*  CALL PHASE 3 ******************************************************* 50600013
RORPH3   MVC   PPIMRGMX(2),PPISEQCT+6   SET CORRECT MERGE ORDER.        50800013
         TM    PPISW1+3,X'60'      IF NOT EXTRACTING OR USER WANTS      51000013
         BC    14,RORA               ASCENDING SEQUENCE GO TO RORA      51200013
         TM    PPISW1+3,X'30'      IS USER SEQ = INPUT SEQ              51400013
         BM    RORCLOSE              IF NOT GO TO PHASE TWO             51600013
RORB     L     RF,KTBLPTCX                                              51800013
         XI    0(RF),X'80'         TURN ON BIT FOR PH 3 TO INDIC INP-   52000013
*                                 UUT SIDE OF TABLE                     52200013
         L     RP,PPIADSSC                                              52400013
         XI    PPISW1+3,X'10'      REVERSE SEQUENCE INDICATOR BIT       52600013
         LA    RB,4                RETURN TO SSC REQUESTING PHASE 3.    52800013
         BAL   RO,20(0,RP)                                              53000013
RORA     TM    PPISW1+3,X'30'      IS USER SEQ = INPUT SEQ              53200013
         BM    RORB                  IF NOT GO TO PHASE THREE           53400013
         B     RORCLOSE              ELSE GOT TO PHASE TWO              53600013
         SPACE 2                                                        53800013
*  DECREMENT ERROR CTR BY 1--- IS COUNT= ZERO{ ************************ 54000013
RORGOE   LH    RE,PPISEQCT+8                                            54200013
         BCT   RE,RORGOJ           NO,BRANCH + RESTORE CTR FR REG.      54400013
*  EXIT TO SSC--- UNENDING MERGE ************************************** 54600013
         USING DIERRMB,RO                                               54800013
         L     RO,PPIRMB+4                                              55000013
         LM    RA,RB,MSGP2A05                                           55200013
         L     RP,PPIADSSC                                              55400013
         BAL   RO,12(0,RP)                                              55600013
         L     RP,PPIADSSC                                              55800013
         BAL   RO,16(0,RP)         RETURN TO SSC REQUESTING AN ABORT.   56000013
         SPACE 2                                                        56200013
*  RESTORE ERROR CTR FROM REG.***************************************** 56400013
RORGOJ   STH   RE,PPISEQCT+8                                            56600013
         B     RORGOF                                                   56800013
         SPACE 2                                                        57000013
*********************************************************************** 57200013
*  ENTRY FROM READ RTN---REACHED LOAD POINT *************************** 57400013
* FIND UNIT AT LOAD PT AND TURN OFF INPUT BIT  VIA INCRMT IN REG D      57600013
RORLDPT  LH    RE,KSVMAX                                                57800013
         L     RF,KTBLPTCX                                              58000013
         STC   RD,KINCRMT                                               58200013
RORSCAN  CLC   KINCRMT(1),1(RF)                                         58400013
         BE    RORDROP                                                  58600013
         LA    RF,2(0,RF)          BUMP TO NEXT UNIT                    58800013
         BCT   RE,RORSCAN          IF NOT AT END OF TBL, LOOK AT NXT UT 59000013
* IF FALL THRU,INCRMT NOT IN TBL = ERROR                                59200013
RORDROP  XI    0(RF),X'80'         TURN OFF INPUT BYTE                  59400013
         SPACE 1                                                        59600013
* CUTBACK MERGE ORDER,IF ZERO,DECIDE ABOUT ENTRY INTO COPY PASS ELIM.   59800013
* ROUTINES,NORMAL PHASE TWO ROUTINES OR INTO PHASE 3.                   60000013
         SPACE 1                                                        60200013
         LH    RE,PPIMRGMX                                              60400013
         BCT   RE,RORREAD          SOME UNIT(S) POSSIBLY NOT AT LD PT   60600013
         B     RORGOA              ALL UNITS AT LOAD POINT,HENCE EOP    60800013
         SPACE 1                                                        61000013
* EXIT BACK TO READ-PRIME TO SEE IF MORE INPUTS AT EOF(LOAD POINT).     61200013
         SPACE 1                                                        61400013
RORREAD  L     RL,PPIRD+4                                               61600013
         STH   RE,PPIMRGMX                                              61800013
         BR    RO                                                       62000013
         SPACE 2                                                        62200013
*********************************************************************** 62400013
*  ENTRY FROM WRITE RTN---EOV DETECT, MIDDLE OF A STRING ************** 62600013
*  SET'S'SWITCH ON **************************************************** 62800013
RORNLST  XI    RORSSW+1,X'F0'                                           63000013
         B     RORGOM                                                   63200013
         SPACE 2                                                        63400013
*  ENTRY FROM WRITE RTN---EOV DETECT, END OF STRING,NOT END OF PASS *** 63600013
*  SET 'S' SWITCH OFF  ************************************************ 63800013
RORLST   NI    RORSSW+1,X'F0'                                    A24560 64000019
*  INCREMENT NO. OF STRINGS OUT BY 1 ********************************** 64200013
RORGOM   L     RE,PPISEQCT+4                                            64400013
         LA    RE,1(0,RE)                                               64600013
         ST    RE,PPISEQCT+4                                            64800013
*  DECREMENT EOV CTR---IS CTR=ZERO{(NMAX EXCEEDED) ******************** 65000013
         L     RF,KEOVCTX                                               65200013
         BCT   RF,RORUPDT          NO,BRANCH TO UPDATE                  65400013
*  EXIT TO SSC NMAX EXCEEDED ****************************************** 65600013
         L     RO,PPIRMB+4                                              65800013
         LM    RA,RB,MSGP2A01                                           66000013
         L     RP,PPIADSSC                                              66200013
         BAL   RO,12(0,RP)                                              66400013
*APROX RCD CNT IS PPICOUNT - B, WHERE B IS A MAX. VALUE.  SO            66600013
*   IF CNT TURNS NEGATIVE, CNT IS SET TO B.                             66800013
*   THIS NEGATIVE CONDITION IS MOST LIKELY IF THE BLOCK BEING WRITTEN   67000013
*   OUT IS SHORT AND/OR RECORD FORMAT IS VARIABLE.                      67200013
         SPACE 1                                                        67400013
         L     RB,PPICOUNT         NO. RCD. BLOCKED                     67600013
         LH    RP,PPISRTBL         B - F = NO. RCDS/BLOCK               67800013
         TM    PPISW1,X'80'            V = BYTES/BLOCK                  68000013
         BO    RORGOM1                                                  68200013
         SPACE 1                                                        68400013
         LH    RA,PPIRCDL4         B / MIN. RCD. LENGTH = MAX. NO.      68600013
         SR    RO,RO                                                    68800013
         DR    RO,RA                 RCDS. IN BLOCK                     69000013
RORGOM1  CR    RB,RP               CHECK TO MAKE SURE CNT ISN'T         69200013
         BH    RORGOM2               NEGATIVE                           69400013
         SPACE 1                                                        69600013
         LR    RB,RP               SET CNT TO B                         69800013
         B     RORGOM3                                                  70000013
         SPACE 2                                                        70200013
RORGOM2  SR    RB,RP               APROX RCD CNT = PPICOUNT - B         70400013
RORGOM3  CVD   RB,PPIWKARE           USUALLY - SET UP CNT FOR           70600013
         UNPK  PPIWKARE+8(8),PPIWKARE(8) PRINTING                       70800013
         OI    PPIWKARE+15,X'F0'                                        71000013
         SPACE 2                                                        71200013
         L     RO,PPIRMB+4                                              71400013
         LM    RA,RB,MSGP2A06                                           71600013
         MVC   MSGP2R06+24(7),PPIWKARE+9                                71800013
         L     RP,PPIRCV+4         PRINT MESSAGE - APROX RCD CNT        72000013
         BAL   RO,12(0,RP)                                              72200013
         SPACE 1                                                        72400013
         L     RP,PPIADSSC                                              72600013
         B     16(0,RP)            RETURN TO SSC AFTER NMAX EXCEEDED    72800013
         SPACE 2                                                        73000013
* UPDATE TAPE TABLE---SET OPEN BYTE OFF ON FULL UNIT ****************** 73200013
RORUPDT  ST    RF,KEOVCTX                                               73400013
         L     RF,KTBLPTBX                                              73600013
         XI    0(RF),X'40'                                              73800013
         B     RORNORM                                                  74000013
         SPACE 2                                                        74200013
*  TURN OFF SSWITCH *************************************************** 74400013
RORSWOFF XI    RORSSW+1,X'F0'                                           74600013
*  EXIT TO WRITE RTN ---MORE WRITES PENDING *************************** 74800013
         L     RL,PPIWRT+4                                              75000013
         B     0(0,RL)                                                  75200013
         SPACE 2                                                        75400013
         DS    0F                                                       75600013
KMRGCTRX DC    X'0000'             COUNTER=MAX MRG TO DET. EOP(LOAD PT) 75800013
         DS    0F                                                       76000013
KTBLPTAX DC    X'00000000'         START POINT (TO RESET TRVLG PTR)     76200013
KLIMITX  DC    X'0000'             COUNTER TO DETERMINE LIMIT OF TABLE  76400013
         DS    0F                                                       76600013
KTBLPTBX DC    X'00000000'         TRAVELING PTR.                       76800013
KTBLPTCX DC    X'00000000'         POINTER TO INPUT SIDE OF TABLE       77000013
KEOVCTX  DC    X'00000000'         SORT CAP. EXCEEDED CTR.              77200013
*                                     ARE FILLED AND MORE INPUT TO GO   77400013
KINCRMT  DC    X'0000'             HOLD AREA FOR DCB INCRMT PASSED      77600013
KSVMAX   DC    X'0000'             HOLD AREA FOR RESETTING A CUT BK MRG 77800013
         EJECT                                                          78000013
DIERRMB  DSECT                                                          78200013
*                                                                       78400013
* MODULE NAME ***IERRMB***                                              78600013
*                                                                       78800013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        79000013
* PHASE 2 RUNNING PROGRAM.                                              79200013
         SPACE 1                                                        79400013
*                                                                       79600013
         COPY  RMBMAIN                                                  79800013
*                                                                       80000013
         EJECT                                                          80200013
         SMPPI                                                          80400013
         END                                                            80600013
