         TITLE ' IERROT - OS/360 SORT/MERGE - 360S-SM-023 02/10/65 '    00200013
*MODULE NAME:*** IERROT ***                                             00400013
         SPACE 2                                                        00600013
*STATUS: CHANGE LEVEL 000                                               00800013
         SPACE 2                                                        01000013
*MODULE FUNCTION/OPERATION: MERGE PHASE DISK ALGORITM.                  01200013
*   THE FUNCTION OF THIS MODULE IS TO OPERATE UPON A MERGE TABLE WHICH  01400013
*   IS USED TO CONTROL WHERE TO WRITE THE MERGED SEQUENCES ON DISK      01600013
*   AREAS. IN ADDITION IT COUNTS NUMBER OF STRINGS AND KEEPS A DIRECT-  01800013
*   ORY OF ADDRESSES WHERE EACH STRING BEGINS. IT DETERMINES IF PHASE   02000013
*   2 WILL BE NEEDED FOR CONTINUED MERGING OR IF S/M IS READY FOR PHASE 02200013
*   3 FINAL MERGE. IT MAY CAUSE S/M TO ABORT THE SORT FOR CERTAIN       02400013
*   ABNORMAL CONDITIONS.                                                02600013
         SPACE 2                                                        02800013
*USED AS A DSECT IN -                                                   03000013
*                                                                       03200013
*  IERAOT                                                               03400013
*                                                                       03600013
*                                                                       03800013
*MACROS USED -                                                          04000013
         SPACE 1                                                        04200013
*   SMPPI                                                               04400013
         SPACE 2                                                        04600013
*ENTRY POINTS:                                                          04800013
         SPACE 1                                                        05000013
*        ENTRY IERROT              ENTRY FROM:(INITIALIZATION)          05200013
*                                    CALLING SEQUENCE-                  05400013
*                                      L    RL,PPIALG+4                 05600013
*                                      BR   RL                          05800013
*                                  (ENTRIES FOR DISPLACEMENTS OF:)      06000013
*                                  ( 4,8 AND 12 ARE DUMMIES.     )      06200013
*                                  ENTRY FROM: IERRPE (WRITE)           06400013
*                                    CALLING SEQUENCE-                  06600013
*                                      L    RL,PPIALG+4                 06800013
*                                      B    16(0,RL) (END OF SEQUENCE)  07000013
*                                  ENTRY FROM: IERROT (READ)            07200013
*                                    CALLING SEQUENCE -                 07400013
*                                      L    RL,PPIALG+4                 07600013
*                                      BR   RO (RETURN ON READING DRCTY 07800013
*                                  ENTRY FROM: IERRPE (WRITE DRCTRY)    08000013
*                                    CALLING SEQUENCE-                  08200013
*                                      L    RL,PPIALG+4                 08400013
*                                      BR   RO (RETURN ON WRITING       08600013
*                                                       DIRECTORY)      08800013
         SPACE 2                                                        09000013
*INPUT: PPI FIELDS REFERENCED-                                          09200013
         SPACE 1                                                        09400013
*   PPIADSSC  PPIWRT    PPIMRGAL   PPIWKARE                             09600013
*   PPIRD     PPILAB01  PPINDSKA                                        09800013
         SPACE 2                                                        10000013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             10200013
         SPACE 1                                                        10400013
*    PPIDEPHO  PPIMRGMX  PPISEQCT                                       10600013
*    PPIRD     PPIMRGOP  PPISW1                                         10800013
         SPACE 2                                                        11000013
*EXTERNAL ROUTINES:                                                     11200013
         SPACE 1                                                        11400013
*        EXTRN IERRPE              WRITE ROUTINE                        11600013
*        EXTRN IERRGC              READ  ROUTINE                        11800013
*        EXTRN IERRCV              SORT SYSTEM CONTROL                  12000013
         SPACE 2                                                        12200013
*EXTERNAL PARAMETERS:                                                   12400013
         SPACE 1                                                        12600013
*        EXTRN IERRMA              MESSAGE MODULE                       12800013
*EXITS: NORMAL                                                          13000013
         SPACE 1                                                        13200013
*        IERRCV                    RETURN TO SSC                        13400013
         SPACE 2                                                        13600013
*EXITS: ERROR                                                           13800013
         SPACE 1                                                        14000013
*        IERRCV                    RETURN TO SSC FOR ABORT              14200013
         SPACE 2                                                        14400013
*TABLES/WORK AREAS:                                                     14600013
         SPACE 1                                                        14800013
*   A TABLE NAMED WTABLE IS USED TO CONTROL AREA USAGE                  15000013
         SPACE 2                                                        15200013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  15400013
         SPACE 2                                                        15600013
*NOTES:                                                                 15800013
         SPACE 1                                                        16000013
*   THIS MODULE USES A BALANCED TECHNIQUE ANALOGOUS TO BALANCED TAPE.   16200013
         SPACE 2                                                        16400013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            16600013
         SPACE 1                                                        16800013
RA       EQU   0                   CONTENTS IN-  N/A                    17000013
*                                  USE- NOT USED                        17200013
*                                  CONTENTS OUT- N/A                    17400013
RB       EQU   1                   CONTENTS IN-  N/A                    17600013
*                                  USE- PARAMETER FOR PHASE 2 OR 3 CALL 17800013
*                                  CONTENTS OUT- PH2/3 CALL PARAMETER   18000013
RC       EQU   2                   CONTENTS IN-  N/A                    18200013
*                                  USE- NOT USED                        18400013
*                                  CONTENTS OUT- N/A                    18600013
RD       EQU   3                   CONTENTS IN-  N/A                    18800013
*                                  USE- NOT USED                        19000013
*                                  CONTENTS OUT- N/A                    19200013
RE       EQU   4                   CONTENTS IN-  N/A                    19400013
*                                  USE- GENERAL WORK REGISTER           19600013
*                                  CONTENTS OUT- N/A                    19800013
RF       EQU   5                   CONTENTS IN-  N/A                    20000013
*                                  USE- GENERAL WORK REGISTER           20200013
*                                  CONTENTS OUT- N/A                    20400013
RG       EQU   6                   CONTENTS IN-  N/A                    20600013
*                                  USE- GENERAL WORK REGISTER           20800013
*                                  CONTENTS OUT- N/A                    21000013
RH       EQU   7                   CONTENTS IN-  N/A                    21200013
*                                  USE- GENERAL WORK REGISTER           21400013
*                                  CONTENTS OUT- N/A                    21600013
RI       EQU   8                   CONTENTS IN-  N/A                    21800013
*                                  USE- GENERAL WORK REGISTER           22000013
*                                  CONTENTS OUT- N/A                    22200013
RJ       EQU   9                   CONTENTS IN-  N/A                    22400013
*                                  USE- GENERAL WORK REGISTER           22600013
*                                  CONTENTS OUT- N/A                    22800013
RK       EQU   10                  CONTENTS IN-  N/A                    23000013
*                                  USE- NOT USED                        23200013
*                                  CONTENTS OUT- N/A                    23400013
RL       EQU   11                  CONTENTS IN- ADDRESS OF MODULE       23600013
*                                  USE- BASE ADDRESS OF MODULE          23800013
*                                  CONTENTS OUT- ADDRESS OF NEXT MODULE 24000013
RM       EQU   12                  CONTENTS IN-  N/A                    24200013
*                                  USE- NOT USED                        24400013
*                                  CONTENTS OUT- N/A                    24600013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          24800013
*                                  USE- PPI REFERENCE,REGISTER SAVE     25000013
*                                    AREA                               25200013
*                                  CONTENTS OUT- ADDRESS OF PPI         25400013
RO       EQU   14                  CONTENTS IN-  RETURN ADDRESS         25600013
*                                  USE- RETURN REGISTER                 25800013
*                                  CONTENTS OUT- RETURN ADDRESS         26000013
RP       EQU   15                  CONTENTS IN-  N/A                    26200013
*                                  USE- SYSTEM INTERFACE REGISTER       26400013
*                                  CONTENTS OUT- ADDRESS OF SSC         26600013
         SPACE 2                                                        26800013
*START OF MODULE CODE PROPER:                                           27000013
         SPACE 2                                                        27200013
IERROT   CSECT                     MODULE BEGINNING                     27400013
         USING *,RL                SET BASE REG FOR THIS PROGRAM        27600013
         USING IERRCA,RN                                                27800013
IERDOT   B     ROTSTART            ENTRY FROM ASSMT ROUTINE             28000013
         DC    A(0)                NO ENTRY PT                          28200013
         DC    A(0)                NO ENTRY PT                          28400013
         DC    A(0)                NO ENTRY PT                          28600013
         B     ROTEOS              GO TO EOS ROUTINE                    28800018
*                                                                       29000013
*  SET REG. I TO NTH POS. OF TABLE ************************************ 29200013
ROTSTART LA    RI,WTABLE           GET BEG.ADDR/TABLE                   29400013
         L     RF,WNODSKA                                               29600013
         LA    RH,1                CONSTANT 1                           29800013
         SR    RF,RH               REDUCE NO./AREAS BY 1                30000013
         ST    RF,WNODSKA          SET UP COUNTER TO DETERMINE END/PASS 30200013
         LA    RG,36               GENERATE MULTIPLIER CONST.           30400013
         MR    RE,RG               DISPLCMT TO NTH POS./TABLE           30600013
         LA    RH,0(RF,RI)         GET ADDR OF NTH POS. IN TABLE        30800013
         LR    RI,RH               HENCEFORTH RI= ADDR/NTH POS.         31000013
         SR    RH,RG               HENCEFORTH RH= ADDR/N-1 POS.         31200013
*  SEQ. CT. AT N-1 = 0                                                  31400013
         LH    RE,34(0,RH)        GET SEQ CT IN                         31600013
         LTR   RE,RE                                                    31800013
         BC    7,ROTGOA            BRANCH IF NOT EQUAL.                 32000013
         SPACE 1                                                        32200013
         L     RE,0(0,RI)          GET 'N' AREA KEY.                    32400013
         SLL   RE,1                MULTIPLY BY 2.                       32600013
         LA    RF,PPISEQCT         GET START POINT OF PPI SEQUENCE CTRS 32800013
         AR    RF,RE               GET PPI SEQ CT LOCATION.             33000013
         MVC   0(2,RF),34(RH)      STORE IN PPI.                        33200013
         B     ROTGOB              GO TO GET N CT.                      33400018
         SPACE 2                                                        33600013
ROTGOA   LA    RE,4(0,RI)          GET NEXT SEQ ADDR FROM NTH POS.      33800013
         MVC   WCLBKAR(8),0(RE)    BLOCK ONE ADDRESS.                   34000013
         MVC   PPIDEPHO(8),0(RE)   STOW NEXT SEQ ADDR FOR WRITE IN PPI. 34200013
ROTGON   CLC   PPIMRGOP(2),34(RH)  IS OPT MRG ORD=NO./SEQ IN AREA N-1.  34400013
         BNL   ROTGOC              GO TO STORE NO/SEQ                   34600018
         MVC   PPIMRGMX(2),PPIMRGOP  STOW OPT MRG ORDER IN MAX MRG ORD. 34800013
*  DECREMENT NO./SEQS. IN POS. N-1 BY MAX MRG ORD.                      35000013
ROTGOE   LH    RE,34(0,RH)         GET NO./SEQ IN N-1 POS.              35200013
         SH    RE,PPIMRGMX                                              35400013
         STH   RE,34(0,RH)         PUT BACK                             35600013
         B     ROTGOF              GO TO READ ROUTINE                   35800018
*                                                                       36000013
* STORE NO/SEQ IN N-1 POS.,IN MAX                                       36200013
ROTGOC   MVC   PPIMRGMX(2),34(RH)                                       36400013
         B     ROTGOE              GO TO DECREMENT NO/SEQ               36600018
*                                                                       36800013
*  DETAIL CHART ******************************************************* 37000013
*  SAVE REG'RI'=NTH ADDR ********************************************** 37200013
ROTGOF   ST    RI,WSAVERI                                               37400013
*  GET ADDR. OF PPI SEQ WORK AREA -'TO'ADDR *************************** 37600013
         LA    RG,PPIWKARE                                              37800013
*  GET ADDR/NXT POS.IN BLK RETRIEVED,FOR N-1 POS-'FROM ADDR'*********** 38000013
         L     RF,28(0,RH)                                              38200013
*  PUT ADDR/NXT DICTY BLK FR.TBL. INTO PPI FOR'READ'******************* 38400013
         MVC   PPIDIRAD(8),20(RH)                                       38600013
*  SAVE REGS RF,RG,RH ************************************************* 38800013
         STM   RF,RH,WSAVERF                                            39000013
*  READ ROUTINE ******************************************************* 39200013
         L     RL,PPIRD+4          TO READ DIRECTORY                    39400013
         BALR  RO,RL               GO TO READ DIRECTORY                 39600018
*  RESTORE REGS RF,RG,RH ********************************************** 39800013
         LM    RF,RH,WSAVERF                                            40000013
*  GET MAX MRG ORDER                                                    40200013
         LH    RB,PPIMRGMX                                              40400013
*  MOVE 1 DISK ADDR FR.'FROM',TO'TO'IN WORK AREA (PPI) **************** 40600013
ROTGOK   MVC   0(8,RG),0(RF)                                            40800013
*  BUMP'FROM'ADDR.***************************************************** 41000013
         LA    RF,8(0,RF)                                               41200013
*  BUMP 'TO' ADDR.                                                      41400013
         LA    RG,8(0,RG)                                               41600013
         B     ROTGOG              GO TO COMPARE LIMIT OF NEW BLK       41800018
*  DECREMENT MERGE ORDER CT., CHECK IF ZERO                             42000013
ROTGOX   BCT   RB,ROTGOK           GO TO MOVE DISK ADDR IN WORK AREA    42200018
*  STORE INDEXED 'FROM' ADDR INTO TABLE (NXT-POS-IN-BLK)                42400013
         ST    RF,28(0,RH)                                              42600013
*  SAVE REG RH (N-1)                                                    42800013
         ST    RH,WSAVERH                                               43000013
         L     RL,PPIRD+4                                               43200013
         B     4(0,RL)             GO TO READ PH2 AND PH3               43400018
         SPACE 2                                                        43600013
*  LIMIT OF NEW BLOCK{ ************************************************ 43800013
ROTGOG   LA    RE,PPILAB01+64                                           44000013
         CLR   RF,RE                                                    44200013
         BL    ROTGOX             NO                                    44400013
*  RESET'FROM'ADDR.TO BEG/BLK ***************************************** 44600013
         LA    RF,PPILAB01                                              44800013
*  WAS LAST BLOCK,LAST ON TRACK{ ************************************** 45000013
         SPACE 2                                                        45060017
ROT100   EQU   *                                                        45120017
         CLI   27(RH),X'1C'       IS TRACK CT = 28 (IN N-1)             45200013
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS PRESENT AND     45240017
*     USING THE 2311 ALGORITHM. THE NEW INSTRUCTION WILL BE             45280017
*        CLI   27(RH),X'2C'                                             45320017
         SPACE 2                                                        45360017
         BE    ROTNEWTK            NO,BRANCH                            45400013
*  INCREMENT TO NXT BLK ADDR(RECD CT) BY 1 (IN TABLE)                   45600013
         L     RE,24(0,RH)         GET RIGHT HALF OF NXT DIR BLK (N-1)  45800013
         LA    RJ,1               GET A 1                               46000013
         AR    RE,RJ              ADD TO TRACK CT.                      46200013
         ST    RE,24(0,RH)         PUT BACK                             46400013
*  MUST ANOTHER BLOCK OF DIRCTY BE READ?                                46600013
ROTGOH   LA    RE,1                                                     46800013
         CLR   RB,RE                                                    47000013
         BE    ROTGOX             NO,                                   47200013
*  SET UP 'DIRAD' FOR ANOTHER READ                                      47400013
         MVC   PPIDIRAD(8),20(RH)                                       47600013
*  SAVE REGS RF,RG,RH ************************************************* 47800013
         STM   RF,RH,WSAVERF                                            48000013
*  SAVE DECREMENTED MRG ORDER                                           48200013
         ST    RB,WSAVERB                                               48400013
*  READ ROUTINE ******************************************************* 48600013
         L     RL,PPIRD+4          TO READ DIRECTORY                    48800013
         BALR  RO,RL               GO TO READ DIRECTORY                 49000018
*  RESTORE REGS RF,RG,RH ********************************************** 49200013
         LM    RF,RH,WSAVERF                                            49400013
*  RESTORE DECREMENTED MRG ORDER                                        49600013
         L     RB,WSAVERB                                               49800013
         B     ROTGOX              GO TO DECREMENT MERGE ORDER          50000018
*                                                                       50200013
*  DECREMENT NXT BLOCK ADDR BACK 1 TRK AND RESET RECD CT TO 1           50400013
ROTNEWTK LA    RE,1                                                     50600013
         STC   RE,27(0,RH)                                              50800013
         CLI   26(RH),X'00'        IS TRACK NO.= 0                      51000013
         BNE   ROTREDTK            NO, REDUCE TRACK NO.                 51200013
*  REDUCE CYLINDER NO. ************************************************ 51400013
         SR    RE,RE                                                    51600013
         IC    RE,24(0,RH)         GET CYL NO.                          51800013
         BCT   RE,ROTINCTK         REDUCE BY 1                          52000013
*  NO FALL THRU POS.---JOB WOULD HAVE ABORTED IN PHASE 1 ************** 52200013
ROTINCTK STC   RE,24(0,RH)         REPLACE UPDATED CYL. NO.             52400013
         LA    RE,9                                                     52600013
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS PRESENT AND     52650017
*     USING THE 2311 ALGORITHM. THE NEW INSTRUCTION WILL BE             52700017
*        LA    RE,19                                                    52750017
         STC   RE,26(0,RH)         RESET HEAD NO.=9                     52800013
         B     ROTGOH              GO TO CHK IF ANOTHER DICTY TO BE RD  53000018
*                                                                       53200013
*  REDUCE TRACK NO. *************************************************** 53400013
ROTREDTK SR    RE,RE               CLEAR REG                            53600013
         IC    RE,26(0,RH)         GET TRACK NO.                        53800013
         LA    RO,1                CONSTANT 1                           54000013
         SR    RE,RO               REDUCE BY 1                          54200013
         STC   RE,26(0,RH)         PUT TRACK NO. BACK                   54400013
         B     ROTGOH              GO TO CHK IF ANOTHER DICTY TO BE RD  54600018
*                                                                       54800013
*  EOS ROUTINE ******************************************************** 55000013
*  RESET REGS RH,RI= N-1,N ******************************************** 55200013
ROTEOS   LM    RH,RI,WSAVERH                                            55400013
*  BUMP NO.NEW SEQS IN TABLE ****************************************** 55600013
         LH    RE,32(0,RI)         GET NO.NEW SEQ                       55800013
         LA    RE,1(0,RE)          BUMP BY 1                            56000013
         STH   RE,32(0,RI)         PUT BACK                             56200013
*  DECREMENT BLKG CTR FOR DICTY BY 1 --- IS BLOCK FILLED{ ************* 56400013
         L     RE,WBLKCT                                                56600013
         BCT   RE,ROTGOL           NO,BRANCH                            56800013
         B     ROTGOM              GO TO SAVE ADDR OF NXT SEQ           57000018
*                                                                       57200013
*  BLOCK NEXT OUTPUT SEQ. DISK ADDR *********************************** 57400013
ROTGOL   LA    RF,8                GET DISPLCMT IN BLKG AREA VIA BLKCTR 57600013
         SR    RF,RE                                                    57800013
         ST    RE,WBLKCT          STORE DECRM'TD BLOCK COUNT            58000013
         SLL   RF,3                                                     58200013
         LA    RG,WCLBKAR          GET ST.PT.                           58400013
         AR    RG,RF                                                    58600013
         MVC   0(8,RG),PPIDEPHO    MOVE INTO BLOCK                      58800013
*  ALL SEQS FR. TABLE POS.N-1 PASSED{ *                                 59000013
         LH    RE,34(0,RH)                                              59200013
         LTR   RE,RE                                                    59400013
         BNE   ROTGON              GO TO CHK OPT MRG ORD                59600018
         SPACE 2                                                        59800013
*   THIS SERIES OF INSTRUCTIONS IS EXECUTED WHEN WRITING A PARTIALLY    60000013
*   FILLED BLOCK OF DIRECTORY.                                          60200013
         SPACE 2                                                        60400013
         BAL   RO,ROTSETDR         BRANCH TO DIRECTORY SET UP SUBRTNE.  60600013
         SPACE 1                                                        60800013
         L     RL,PPIWRT+4         LOAD ADR OF WRITE ROUTINE (IERRPE).  61000013
         BAL   RO,12(0,RL)         GO TO WRITE A BLOCK OF DIRECTORY.    61200013
         SPACE 1                                                        61400013
         LM    RH,RI,WSAVERH       RESTORE REGS.                        61600013
*  STORE NO.NEW SEQS FOR POS.N IN ITS COUNTER IN PPI ****************** 61800013
ROTGOR   L     RE,0(0,RI)          GET N AREA KEY                       62000017
         SLL   RE,1                MULTPY BY 2                          62200013
         LA    RF,PPISEQCT         GET ST.PT.                           62400013
         AR    RF,RE                                                    62600013
         MVC   0(2,RF),32(RI)                                           62800013
ROTGOB   LA    RE,1                CONSTANT 1                           63000013
         L     RF,WNODSKA          GET N CT.                            63200013
*  END OF PASS{,(NO/AREA CTR=1)                                         63400013
         CLR   RF,RE                                                    63600013
         BNE   ROT300              NO- LOOP TO BEG PT AND CONT. PASS    63800017
*  STORE A ZERO IN POS. 1'S AREA IN PPI COUNTERS ********************** 64000013
         L     RE,0(0,RH)          GET 'N'1 AREA KEY                    64200013
         SLL   RE,1                MULTPY BY 2                          64400013
         LA    RF,PPISEQCT         GET ST. PT.                          64600013
         AR    RF,RE               DISPLC.                              64800013
         MVC   0(2,RF),32(RH)                                           65000013
*  SUM SEQUENCE COUNTERS ********************************************** 65200013
         SR    RF,RF                                                    65400013
         LH    RE,PPINDSKA                                              65600013
         LA    RG,PPISEQCT                                              65800013
ROTLOOPH AH    RF,0(0,RG)          SUM IN RF                            66000013
         LA    RG,2(0,RG)          BUMP TO NXT CTR                      66200013
         BCT   RE,ROTLOOPH         BRANCH BACK TO THE LOOP              66400018
         SPACE 3                                                        66600013
* SUM VS. ALT                                                           66800013
         LH    RG,PPIMRGAL                                              67000013
         CLR   RF,RG                                                    67200013
         BH    ROTPHAS2            GO SET INDICATOR TO PHASE 2          67400018
*  CLOSE ROUTINE ****************************************************** 67600013
         STH   RF,PPIMRGOP         STORE NO. STRINGS FOR MERGE          67800013
         STH   RF,PPIMRGMX         UPDATE MRGMX WITH SUM OF SEQ CNTS.   68000013
ROTGOP   L     RP,PPIADSSC                                              68200013
         LA    RB,4                RETURN TO SSC ASKING FOR PHASE 3     68400013
         B     20(0,RP)            GO TO SSC                            68600013
*                                                                       68800013
*  REVERSE A OR D SWITCH ********************************************** 69000013
ROTPHAS2 XI    PPISW1+3,X'08'     GO TURN BIT 29 TO OPPOSITE            69200013
*  SET INDICATOR TO PHASE 2 ******************************************* 69400013
         L     RP,PPIADSSC                                              69600013
         LA    RB,0                RETURN TO SSC ASKING FOR PHASE 2     69800013
         B     20(0,RP)            GO TO SSC                            70000013
ROT300   B     ROTSTART            GO SET RI TO NTH POS OF TABLE        70020018
*   THE ABOVE INSTRUCTION WILL BE MODIFIED TO A NO-OP IF CHECKPOINT     70040017
*    HAS BEEN INDICATED. IF CHECKPOINTS ARE BEING TAKEN WE WILL LINK TO 70060017
*    THE CHECKPOINT MODULE.                                             70080017
         SPACE 2                                                        70100017
         L     RP,PPICHKAD         LOAD BASE ADDRESS                    70120017
         BALR  RO,RP               ISSUE CHECKPOINT                     70140017
         SPACE 1                                                        70160017
         B     ROTSTART            GO SET RI TO NTH POS OF TABLE        70180018
*                                                                       70200013
*  SAVE THE ADDR OF WHERE TO WRITE NXT SEQ IN TABLE ******************* 70400013
ROTGOM   MVC   4(8,RI),PPIDEPHO   PUT IN 'N' POS.                       70600013
*  STORE ADDR OF WHERE TO RECD NXT DICTY BLK IN PPI FOR'N'POS.********* 70800013
         SPACE 2                                                        71000013
*   THIS SERIES OF INSTRUCTIONS IS ENTERED WHEN WRITING A FULL BLOCK    71200013
*   OF DIRECTORY.                                                       71400013
         SPACE 2                                                        71600013
         BAL   RO,ROTSETDR         BRANCH TO DIRECTORY SET UP SUBRTNE.  71800013
         SPACE 1                                                        72000013
         L     RL,PPIWRT+4         LOAD ADR OF WRITE ROUTINE (IERRPE).  72200013
         BAL   RO,12(0,RL)         GO TO WRITE A BLOCK OF DIRECTORY.    72400013
         SPACE 1                                                        72600013
         LM    RH,RI,WSAVERH       RESTORE REGS.                        72800013
*  ALL SEQ'S FROM TABLE (POS N-1) PASSED{ ***************************** 73000013
         LH    RE,34(0,RH)                                              73200013
         LTR   RE,RE                                                    73400013
         BE    ROTGOR              GO STORE NO OF NEW SEQS              73600018
*  IS THIS TRACK OF DICTY FILLED{ ************************************* 73800013
         SPACE 2                                                        73860017
ROT200   EQU   *                                                        73920017
         CLI   19(RI),X'1C'       IS RECORD CT = 28 (LAST POSS RECD)    74000013
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS PRESENT AND     74040017
*     USING THE 2311 ALGORITHM. THE NEW INSTRUCTION WILL BE             74080017
*        CLI   19(RI),X'2C'                                             74120017
         SPACE 2                                                        74160017
         BNE   ROTGOS              NO,BRANCH                            74200013
*  RESET RECORD CT FOR POS. 'N' IN TABLE TO 1                           74400013
         LA    RE,1                                                     74600013
         STC   RE,19(0,RI)                                              74800013
*  DECREMENT TRACK ADDR BY 1,TO'N' POS. IN TABLE ********************** 75000013
         CLI   18(RI),X'00'        TRACK NO.= 0{                        75200013
         BNE   ROTDECTK            NO                                   75400013
         SR    RF,RF               CLEAR REG                            75600013
         IC    RF,16(0,RI)         GET CYL. NO.                         75800013
         BCT   RF,ROTBMPTK         REDUCE BY 1                          76000013
*  NO FALL THRU POS.---JOB WOULD HAVE ABORTED IN PHASE 1 ************** 76200013
*  RESET TRACK NO. TO 9 *********************************************** 76400013
ROTBMPTK LA    RE,9                CONSTANT 9                           76600013
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS PRESENT AND     76640017
*     USING THE 2311 ALGORITHM. THE NEW INSTRUCTION WILL BE             76680017
*        LA    RE,19                                                    76720017
         SPACE 2                                                        76760017
         STC   RE,18(0,RI)                                              76800013
         B     ROTGOA              GO SET NXT SEQ ADDR                  77000018
*                                                                       77200013
*  DECREMENT TRACK NO. BY 1 ******************************************* 77400013
ROTDECTK LA    RE,1                                                     77600013
         IC    RF,18(0,RI)         GET TRK NO.                          77800013
         SR    RF,RE               DECR BY 1                            78000013
         STC   RF,18(0,RI)         PUT BACK                             78200013
         B     ROTGOA              GO SET NXT SEQ ADDR                  78400018
*  BUMP RECORD CT FOR POS. 'N',CONT. TO WRITE ON SAME TRACK             78600013
ROTGOS   IC    RE,19(0,RI)        GET RECORD CT.                        78800013
         LA    RE,1(0,RE)          ADD 1                                79000013
         STC   RE,19(0,RI)         PUT BACK                             79200013
         B     ROTGOA              GO GET NXT SEQ ADDR                  79400018
         SPACE 2                                                        79600013
*   THIS SUBROUTINE IS ENTERED EACH TIME A BLOCK OF DIRECTORY IS TO BE  79800013
*   WRITTEN. ITS FUNCTION IS TO MOVE THE DIRECTORY TO PPI, STORE THE    80000013
*   DISK ADDRESS IN PPI, AND RESET THE DIRECTORY BLOCKING COUNTER.      80200013
         SPACE 2                                                        80400013
ROTSETDR MVC   PPIDIRAD(8),12(RI)  PUT DIRECTORY ADDR IN PPI.           80600013
         MVC   PPIWKARE(64),WCLBKAR  PUT BLOCK OF DIRECTORY IN PPI.     80800013
         STM   RH,RI,WSAVERH       SAVE REGS.                           81000013
         LA    RE,8                                                     81200013
         ST    RE,WBLKCT           RESET DIRECTORY BLOCKING COUNTER.    81400013
         BR    RO                  RETURN TO MAIN LINE.                 81600013
         SPACE 2                                                        81800013
         DS    0F                                                       82000013
WTABLE   DC    X'00000000'         MERGE TABLE    FIRST AREA            82200013
         DS    8F                                ENTRY                  82400018
         DC    X'00000001'                        SECOND AREA           82600013
         DS    8F                                ENTRY                  82800018
         DC    X'00000002'                        THIRD AREA            83000013
         DS    8F                                ENTRY                  83200018
         DC    X'00000003'                        FOURTH AREA           83400013
         DS    8F                                ENTRY                  83600018
         DC    X'00000004'                        FIFTH AREA            83800013
         DS    8F                                ENTRY                  84000018
         DC    X'00000005'                        SIXTH AREA            84200013
         DS    8F                                ENTRY                  84400018
WSAVERB  DS    1F                  SAVE AREA FOR REG.RB WHEN LINKING    84600018
WSAVERF  DS    1F                  SAVE AREA FOR REG.RF WHEN LINKING    84800013
WSAVERG  DS    1F                  SAVE AREA FOR REG.RG WHEN LINKING    85000013
WSAVERH  DS    1F                  SAVE AREA FOR REG.RH WHEN LINKING    85200013
WSAVERI  DS    1F                  SAVE AREA FOR REG.RI WHEN LINKING    85400013
WCLBKAR  DS    16F                 DICTY BLOCKING AREA=64 BYTES         85600013
WBLKCT   DC    X'00000008'         DICTY BLOCKING COUNTER               85800013
WNODSKA  DC    X'00000000'         NO. DISK AREAS COUNT.-DET. END/PASS  86000013
         SMPPI                                                          86200013
         END                                                            86400013
