         TITLE '    IERROU - OS/360 SORT/MERGE - 360S-SM-023 03/11/65'  00100013
*MODULE NAME:*** IERROU ***                                             00200013
         SPACE 2                                                        00300013
*STATUS: CHANGE LEVEL 000                                               00400013
         SPACE 2                                                        00500013
*MODULE FUNCTION/OPERATION: PHASE 2 AND 3, 1-8 WAY MERGE NETWORK WITH   00600013
*   MULTIPLE CONTROL FIELDS. THE FUNCTION OF THIS MODULE IS TO MERGE    00700013
*   FIXED OR VARIABLE LENGTH RECORDS IN ASCENDING OR DECENDING SEQUENCE 00800013
*   INITIALLY IERROU SEQUENCES THE INPUT RECORDS IN THE PHASE TO PHASE  00900013
*   INFORMATION AREA, CUTSBACK THE NETWORK FOR SPECIFIED MERGE ORDER ,  01000013
*   AND THEN UTILIZES A BINARY INSERTION TECHNIQUE. THIS IS ACCOMPLISH- 01100013
*   ED BY USING THE ADDRESSES OF THE RECORDS IN THE GENERAL REGISTERS   01200013
*   RE THRU RK. THE LOW ORDER 3 BYTES OF THE REGISTER CONTAIN THE       01300013
*   ADDRESS OF THE RECORD. THE HIGH ORDER BYTE HAS A FILE INDENTIFIER   01400013
*   FOR THE DEBLOCK ROUTINE. REGISTER RD IS THE NEW RECORD CONVEYER     01500013
*   FROM DEBLOCK AND COMMUNICATES TO BLOCK.                             01600013
         SPACE 2                                                        01700013
*USED AS A DSECT IN -                                                   01800013
*                                                                       01900013
*   IERAOU                                                              02000013
*                                                                       02100013
*                                                                       02200013
*MACROS USED -                                                          02300013
         SPACE 1                                                        02400013
*   SMPPI                                                               02500013
         SPACE 2                                                        02600013
*ENTRY POINTS:                                                          02700013
         SPACE 1                                                        02800013
*        ENTRY IERROU              ENTRY FROM:                          02900013
*                                    CALLING SEQUENCE-                  03000013
*                                      LA   RP,PPINETM+4                03100013
*                                      BR   RP                          03200013
         SPACE 2                                                        03300013
*INPUT: PPI FIELDS REFERENCED-                                          03400013
         SPACE 1                                                        03500013
*   PPIDOOBA  PPIMRGMX  PPIPSVA    PPIBLK    PPIRMC                     03600013
*   PPIDOUA   PPIPDWA   PPISW1     PPIBLK2                              03700013
         SPACE 2                                                        03800013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             03900013
         SPACE 1                                                        04000013
*    PPIPSVA                                                            04100013
         SPACE 2                                                        04200013
*EXTERNAL ROUTINES:                                                     04300013
         SPACE 1                                                        04400013
*        EXTRN IERRMC              MESSAGE MODULE                       04500013
*        EXTRN IERDB2              PHASE TWO BLOCK ROUTINE              04600013
*        EXTRN IERDB34             PHASE THREE BLOCK ROUTINE            04700013
         SPACE 2                                                        04800013
*EXTERNAL PARAMETERS:                                                   04900013
         SPACE 1                                                        05000013
*        N/A                                                            05100013
*EXITS: NORMAL                                                          05200013
         SPACE 1                                                        05300013
*        IERDB2                    BLOCK PHASE 2                        05400013
*        IERDB34                   BLOCK PHASE 3                        05500013
         SPACE 2                                                        05600013
*EXITS: ERROR                                                           05700013
         SPACE 1                                                        05800013
*        IERRMC                    MESSAGE MODULE                       05900013
         SPACE 2                                                        06000013
*TABLES/WORK AREAS:                                                     06100013
         SPACE 1                                                        06200013
*        N/A                                                            06300013
         SPACE 2                                                        06400013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  06500013
         SPACE 2                                                        06600013
*NOTES: N/A                                                             06700013
         SPACE 1                                                        06800013
         SPACE 2                                                        06900013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            07000013
         SPACE 1                                                        07100013
RA       EQU   0                   CONTENTS IN- N/A                     07200013
*                                  USE- SYSTEM WORK REGISTER            07300013
*                                  CONTENTS OUT- N/A                    07400013
RB       EQU   1                   CONTENTS IN- N/A                     07500013
*                                  USE- SYSTEM PARAMETER REG            07600013
*                                  CONTENTS OUT- N/A                    07700013
RC       EQU   2                   CONTENTS IN- TO REGISTER EXTRACT     07800013
*                                  USE- TO REGISTER FOR EXTRACT RTN     07900013
*                                  CONTENTS OUT- TO REGISTER EXTRACT    08000013
RD       EQU   3                   CONTENTS IN- FROM REGISTER           08100013
*                                  USE- FROM REGISTER EXTRACT,WNR,NXT   08200013
*                                  CONTENTS OUT- FROM REGISTER          08300013
RE       EQU   4                   CONTENTS IN- MERGE ADDRESS ITEM 1    08400013
*                                  USE- MERGE NETWORK REGISTER          08500013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 1   08600013
RF       EQU   5                   CONTENTS IN- MERGE ADDRESS ITEM 2    08700013
*                                  USE- MERGE NETWORK REGISTER          08800013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 2   08900013
RG       EQU   6                   CONTENTS IN- MERGE ADDRESS ITEM 3    09000013
*                                  USE- MERGE NETWORK REGISTER          09100013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 3   09200013
RH       EQU   7                   CONTENTS IN- MERGE ADDRESS  ITEM 4   09300013
*                                  USE- MERGE NETWORK REGISTER          09400013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 4   09500013
RI       EQU   8                   CONTENTS IN- MERGE ADDRESS ITEM 5    09600013
*                                  USE- MERGE NETWORK REGISTER          09700013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 5   09800013
RJ       EQU   9                   CONTENTS IN- MERGE ADDRESS ITEM 6    09900013
*                                  USE- MERGE NETWORK REGISTER          10000013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 6   10100013
RK       EQU   10                  CONTENTS IN- MERGE ADDRESS ITEM 7    10200013
*                                  USE- MERGE NETWORK REGISTER          10300013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 7   10400013
RL       EQU   11                  CONTENTS IN- N/A                     10500013
*                                  USE- PROGRAM BASE ADDRESS            10600013
*                                  CONTENTS OUT- PROGRAM ADDRESS        10700013
RM       EQU   12                  CONTENTS IN- EXTRACT RTN ADDRESS     10800013
*                                  USE- EXTRACT ROUTINE BASE REGISTER   10900013
*                                  CONTENTS OUT- EXTRACT RTN ADDRESS    11000013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          11100013
*                                  USE- PPI REFERENCE,REGISTER SAVE     11200013
*                                    AREA                               11300013
*                                  CONTENTS OUT- ADDRESS OF PPI         11400013
RO       EQU   14                  CONTENTS IN N/A                      11500013
*                                  USE- MESSAGE MODULE BASE ADDRESS REG 11600013
*                                  CONTENTS OUT- MESSAGE MODULE ADDRESS 11700013
RP       EQU   15                  CONTENTS IN- THIS MODULE ADDRESS     11800013
*                                  USE- SORT SYSTEM CONTROL INTERFACE   11900013
*                                  CONTENTS OUT- N/A                    12000013
         SPACE 2                                                        12100013
*START OF MODULE CODE PROPER:                                           12200013
         SPACE 2                                                        12300013
IERROU   CSECT                     MODULE IDENTIFICATION                12400013
*********************************************************************** 12500013
         USING *,RL                SETTING MODULE USING REGISTER        12600013
         USING IERRCA,RN           SETTING PPI DSECT USING REG          12700013
         USING DIERRMC,RO          MESSAGE MODULE USING REG             12800013
IERDO1   B     ROUSINIT            READ PRIME ENTRY  BR TO INITIALIZAT  12900013
         B     ROUCUTEN            READ + ALGORITHM ENTRY BR TO CUTBACK 13000013
         LM    RE,RK,ROUSVREG      DEBLOCK ENTRY - RESTORE REGISTERS    13100013
ROUNTENS B     IERDOM8             NETWORK ENTR SWTCH SET BY CUTBACK    13200013
         SPACE 2                                                        13300013
*    THE FIND THE WINNER LOOP                                           13400013
         SPACE 1                                                        13500013
*    ENTRANCE FOR A 6, 7, 8 WAY MERGE                                   13600013
         SPACE 1                                                        13700013
IERDOM8  CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 4         13800013
         BNE   ROUNOEQ8            IF EQUAL GO TO EQUALS ROUTINE        13900013
         LR    RC,RH               LOAD EQ RTN COMPARE REG WITH ITEM 4  14000013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    14100013
*    THIS BRANCH INSTR IS BH OF BL DEPENDING ON THE INPUT SEQUENCE      14200013
ROUNOEQ8 BH    IERDOCK6            IF HI/LO GO TO CMP ITEM 6 OR 5       14300013
         SPACE 1                                                        14400013
*    ENTRANCE FOR A 3, 4, 5 WAY MERGE                                   14500013
         SPACE 1                                                        14600013
IERDOM4  CLC   0(1,RD),0(RF)       COMPARE NEW ITEM WITH ITEM 2         14700013
         BNE   ROUNOEQ4            IF EQUAL GO TO EQUALS ROUTINE        14800013
         LR    RC,RF               LOAD EQ RTN COMPARE REG WITH ITEM 2  14900013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    15000013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      15100013
ROUNOEQ4 BH    IERDOCK3            IF HI/LO GO TO CMP ITEM 3,4 OR UPDAT 15200013
         SPACE 1                                                        15300013
*    ENTRANCE FOR A 2 WAY MERGE                                         15400013
         SPACE 1                                                        15500013
IERDOM2  CLC   0(1,RD),0(RE)       COMPARE NEW ITEM WITH ITEM 1         15600013
         BNE   ROUNOEQ2            IF EQUAL GO TO EQUALS ROUTINE        15700013
         LR    RC,RE               LOAD EQ RTN COMPARE REG WITH ITEM 1  15800013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    15900013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      16000013
ROUNOEQ2 BH    ROUMOV1             IF HI/LO NEW COLLATES AFTER ITEM 1   16100013
         SPACE 1                                                        16200013
*    ENTRANCE FOR A 1 WAY MERGE AND NEW ITEM IS THE WINNER              16300013
         SPACE 1                                                        16400013
*    IF PHASE 2 EXIT TO THE BLOCK RTN                                   16500013
*    IF PHASE 3 OR MERGE ONLY PERFORM RECORD SEQUENCE CHECK             16600013
*    THE ASSIGNMENT ROUTINE SETS THE BRANCH INSTR ACCORDING TO THE PHAS 16700013
IERDOM1  BC    0,ROUPH3            DROP THRU FOR PHASE 2                16800013
         STM   RE,RK,ROUSVREG      SAVE NETWORK REGISTERS               16900013
         L     RL,PPIBLK2+4                                             17000013
         B     16(0,RL)            EXIT TO BLK RTN WANT NEXT RCD        17100013
         SPACE 2                                                        17200013
*    SEQUENCE CHECK OF CURRENT NETWORK WINNER AND PREVIOUS NETWORK      17300013
*    WINNER. CHECK DONE USING REG RD AND RC.                            17400013
         SPACE 1                                                        17500013
*    THE USER COMMUNICATES A 0 OR 4 TO THE BLK RTN. THEBLK RTN          17600013
*       SETS PPIDOUO IF A RECORD MODIFICATION EXIT IS ACTIVATED. IF NO  17700013
*       EXITS ARE ACTIVATED, THE BLK RTN TAKES NO ACTION CONCERNING     17800013
*       PPIDOUO                                                         17900013
*    A 0 MEANS A SEQUENCE CHECK IS TO BE PERFORMED. A 4 MEANS NO        18000013
*    SEQUENCE CHECK. IF NO RCD MODIFICATION EXITS ARE ACTIVATED,        18100013
*       PPIDOUO IS 0.                                                   18200013
         SPACE 2                                                        18300013
ROUPH3   L     RC,PPIDOUO                                               18400013
         B     ROUCKISC(RC)        BRANCH TO EXIT                       18500018
ROUCKISC B     ROUSCK              SEQUENCE CHECK                       18600018
         SPACE 2                                                        18700013
*    NO SEQUENCE CHECK                                                  18800013
ROUOUT   STM   RE,RK,ROUSVREG      SAVE NETWORK REGISTERS               18900013
         L     RL,PPIBLK+4                                              19000013
         B     4(0,RL)             EXIT TO BLOCK RTN WANT NEXT RECORD   19100013
         SPACE 2                                                        19200013
ROUSCK   L     RC,PPIDOOBA         ADDR OF REC IN OUTPUT BUFFER         19300013
IERDOSCK CLC   0(1,RD),0(RC)                                            19400013
         BNE   ROUSCB              IF UNEQUAL BYPASS NSI                19500018
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    19600013
*    THIS BRANCH INSTR IS BC 10 OR 12 DEPENDING ON THE INPUT SEQUENCE   19700013
ROUSCB   BC    10,ROUOUT           BLOCK RTN.                           19800018
*    OUT OF SEQUENCE ERROR                                              19900013
         L     RO,PPIRMC+4                                              20000013
         TM    PPISW1+2,X'02'      TEST FOR MERGE RUN                   20030017
         BO    ROUMERG             YES, BRANCH                          20060017
         LM    RA,RB,MSGP3A04      OUT OF SEQUENCE MESSAGE              20100013
ROUSEQ   L     RP,PPIADSSC                                              20200017
         BAL   RO,12(0,RP)         SORT SYS CNTRL                       20300013
         L     RP,PPIADSSC                                              20400013
         BAL   RO,16(0,RP)         ABORT THE SORT CODE                  20500013
ROUMERG  SRL   RD,26               CONVERT DCB INDEX TO UNIT NUMBER     20510017
         CVD   RD,ROUCONV          CONVERT INDEX TO DECIMAL             20520017
         UNPK  ROUTEMP(2),ROUCONV+7(1)  UNPACK FOR PRINTING             20530017
         OI    ROUTEMP+1,X'F0'     SET SIGN POSITIVE                    20540017
         MVC   MSGP3MA8(2),ROUTEMP      MOVE UNIT NUMBER INTO MESSAGE   20550017
         LM    RA,RB,MSGP3A08      MERGE OUT OF SEQUENCE                20560017
         B     ROUSEQ              GO PRINT MESSAGE                     20570017
         EJECT                                                          20600013
IERDOCK6 CLC   0(1,RD),0(RJ)       COMPARE NEW ITEM WITH ITEM 6         20700013
         BNE   ROUNOEQ6            IF EQUAL GO TO EQUALS ROUTINE        20800013
         LR    RC,RJ               LOAD EQ RTN COMPARE REG WITH ITEM 6  20900013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    21000013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      21100013
ROUNOEQ6 BH    IERDOCK7            IF HI/LO GO TO CMP ITEM 7 OR UPDATE  21200013
IERDOCK5 CLC   0(1,RD),0(RI)       COMPARE NEW ITEM WITH ITEM 5         21300013
         BNE   ROUNOEQ5            IF EQUAL GO TO EQUALS ROUTINE        21400013
         LR    RC,RI               LOAD EQ RTN COMPARE REG WITH ITEM 5  21500013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    21600013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      21700013
ROUNOEQ5 BH    ROUMOV5             IF HI/LO NEW COLLATES AFTER ITEM 5   21800013
         SPACE 1                                                        21900013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 4 + BEFORE ITEM 5      22000013
         SPACE 1                                                        22100013
ROUMOV4  LR    RC,RD                                                    22200013
         LR    RD,RE                                                    22300013
         LR    RE,RF                                                    22400013
         LR    RF,RG                                                    22500013
         LR    RG,RH                                                    22600013
         LR    RH,RC                                                    22700013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              22800013
         SPACE 2                                                        22900013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 5 + BEFORE ITEM 6      23000013
ROUMOV5  LR    RC,RD                                                    23100013
         LR    RD,RE                                                    23200013
         LR    RE,RF                                                    23300013
         LR    RF,RG                                                    23400013
         LR    RG,RH                                                    23500013
         LR    RH,RI                                                    23600013
         LR    RI,RC                                                    23700013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              23800013
         SPACE 2                                                        23900013
IERDOCK7 CLC   0(1,RD),0(RK)       COMPARE NEW ITEM WITH ITEM 7         24000013
         BNE   ROUNOEQ7            IF EQUAL GO TO EQUALS ROUTINE        24100013
         LR    RC,RK               LOAD EQ RTN COMPARE REG WITH ITEM 7  24200013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    24300013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      24400013
ROUNOEQ7 BH    ROUMOV7             IF HI/LO NEW COLLATES AFTER ITEM 7   24500013
         SPACE 1                                                        24600013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 6 + BEFORE ITEM 7      24700013
         SPACE 1                                                        24800013
ROUMOV6  LR    RC,RD                                                    24900013
         LR    RD,RE                                                    25000013
         LR    RE,RF                                                    25100013
         LR    RF,RG                                                    25200013
         LR    RG,RH                                                    25300013
         LR    RH,RI                                                    25400013
         LR    RI,RJ                                                    25500013
         LR    RJ,RC                                                    25600013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              25700013
         SPACE 2                                                        25800013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 7                      25900013
         SPACE 1                                                        26000013
ROUMOV7  LR    RC,RD                                                    26100013
ROUMMOV7 LR    RD,RE               UPDATE EXECUTED AFT CUTBACK OPERAT   26200013
         LR    RE,RF                                                    26300013
         LR    RF,RG                                                    26400013
         LR    RG,RH                                                    26500013
         LR    RH,RI                                                    26600013
         LR    RI,RJ                                                    26700013
         LR    RJ,RK                                                    26800013
         LR    RK,RC                                                    26900013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              27000013
         SPACE 2                                                        27100013
IERDOCK3 CLC   0(1,RD),0(RG)       COMPARE NEW ITEM WITH ITEM 3         27200013
         BNE   ROUNOEQ3            IF EQUAL GO TO EQUALS ROUTINE        27300013
         LR    RC,RG               LOAD EQ RTN COMPARE REG WITH ITEM 3  27400013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    27500013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      27600013
ROUNOEQ3 BH    ROUMOV3             IF HI/LO NEW COLLATES AFTER ITEM 3   27700013
         SPACE 1                                                        27800013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 2 + BEFORE ITEM 3      27900013
         SPACE 1                                                        28000013
ROUMOV2  LR    RC,RD                                                    28100013
         LR    RD,RE                                                    28200013
         LR    RE,RF                                                    28300013
         LR    RF,RC                                                    28400013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              28500013
         SPACE 2                                                        28600013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 3 + BEFORE ITEM 4      28700013
         SPACE 1                                                        28800013
ROUMOV3  LR    RC,RD                                                    28900013
         LR    RD,RE                                                    29000013
         LR    RE,RF                                                    29100013
         LR    RF,RG                                                    29200013
         LR    RG,RC                                                    29300013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              29400013
         SPACE 2                                                        29500013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 1 + BEFORE ITEM 2      29600013
         SPACE 1                                                        29700013
ROUMOV1  LR    RC,RD                                                    29800013
         LR    RD,RE                                                    29900013
         LR    RE,RC                                                    30000013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              30100013
         SPACE 2                                                        30200013
*    SPECIAL ITEM 4 COMPARE FOR 5 WAY MERGE                             30300013
         SPACE 1                                                        30400013
IERDOCK4 CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 4         30500013
         BNE   ROUNOEQS            IF EQUAL GO TO EQUALS ROUTINE        30600013
         LR    RC,RH               LOAD EQ RTN COMPARE REG WITH ITEM 4  30700013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    30800013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      30900013
ROUNOEQS BH    ROUMOV4             IF HI/LO GO TO UPDATE                31000013
         B     IERDOCK3            IF NOT HI/LO GO TO CMP ITEM 3        31100013
         SPACE 2                                                        31200013
*    COMPLETION OF THE FIND THE LOW LOOP                                31300013
         EJECT                                                          31400013
*    PUTTING OUT THE NETWORK WINNER.                                    31500013
*    SEQUENCE CHECKING IS NOT NECESSARY                                 31600013
*    IF PHASE 2 EXIT TO THE BLOCK ROUTINE                               31700013
*    THE ASSIGNMENT ROUTINE SETS THE BRANCH INSTR ACCORDING TO THE PHAS 31800013
IERDOBWR BC    0,ROUPH3NS          DROP THRU FOR PHASE 2                31900013
         STM   RE,RK,ROUSVREG      SAVE NETWORK REGISTERS               32000013
         L     RL,PPIBLK2+4                                             32100013
         B     16(0,RL)            EXIT TO BLK RTN WANT NEXT RCD        32200013
         SPACE 2                                                        32300013
ROUPH3NS STM   RE,RK,ROUSVREG      SAVE NETWORK REGISTERS               32400013
         L     RL,PPIBLK+4                                              32500013
         B     4(0,RL)             EXIT TO BLOCK RTN WANT NEXT RECORD   32600013
         EJECT                                                          32700013
*    THIS SECTION OF CODE ENTERED UPON COMPLETION OF A CUTBACK OPERTION 32800013
*    THIS SECTION INITIALLY CHECKS FOR THE NETWORK BEING SET FOR THE    32900013
*    MERGE ORDER.  SUBSEQUENTLY A BRANCH TO UPDATE IS EXECUTED.         33000013
         SPACE 1                                                        33100013
ROUFMUDS BC    0,ROUFDMO           SET TO BRANCH BY INITIALIZATION RTN  33200013
*    FALL THROUGH FOR UPDATING NETWORK AFTER A CUTBACK OPERATION        33300013
         ST    RC,ROUSVCBA         SAVE NEXT CUTBACK ADDRESS            33400013
         B     ROUMMOV7            MODIFIED MOVE AFTER ITEM 7 NOTE BELO 33500013
*                                  ALL REGISTERS EXCEPT RC INVOLVED     33600013
         SPACE 1                                                        33700013
         SPACE 1                                                        33800013
         SPACE 1                                                        33900013
ROUFDMO  L     RF,ROUIDMO          SET TO 8 BY INITIALIZATION RTN       34000013
         C     RF,ROUACMO          SET TO ACTUAL MERGE ORDER BY INITIAL 34100013
         BE    ROUSFTTU            SET FALL THRU TO UPDATE              34200013
         S     RF,KROONE           CONSTANT OF ONE                      34300013
         ST    RF,ROUIDMO                                               34400013
         BR    RC                  BRANCH BACK TO CUTBACK RTN           34500013
         SPACE 2                                                        34600013
ROUSFTTU XI    ROUFMUDS+1,X'F0'    SET ROUFMUDS BRANCH TO FALL THRU     34700013
         ST    RC,ROUSVCBA         SAVE ADDRESS OF NEXT CUTBACK CODE    34800013
         B     ROUINTSQ            EXIT TO INIT SEQ THE RECORDS ID FLC1 34900013
         EJECT                                                          35000013
*    THE NETWORK CUTBACK SECTION.                                       35100013
*    IT IS THAT CODE WHICH TAILORS THE NETWORK FOR THE MERGE ORDER      35200013
         SPACE 1                                                        35300013
*    THE INITIAL ENTRANCE TO THE CUTBACK SECTION                        35400013
*    SET NETWORK FOR AN 8 WAY MERGE                                     35500013
         SPACE 1                                                        35600013
ROUCSEWM MVC   ROUNOEQ8(4),ROUEGW1 SET BR TO CMP ITEM 6 AFT ITEM 4 CMP  35700013
         MVC   ROUNOEQ6(4),ROUEGW2 SET BR TO CMP ITEM 7 AFT ITEM 6 CMP  35800013
         MVC   ROUNOEQ4(4),ROUEGW3 SET BR TO CMP ITEM 3 AFT ITEM 2 CMP  35900013
         MVC   ROUNTENS(4),ROUANT8 SET NETWORK ENTRANCE FOR 8 WAY MERGE 36000013
         BAL   RC,ROUFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 36100013
         SPACE 1                                                        36200013
*    SET NETWORK FOR AN 7 WAY MERGE                                     36300013
         SPACE 1                                                        36400013
         MVC   ROUNOEQ6(4),ROUSVWM SET BR TO UPDATE AFTER ITEM 6 CMP    36500013
         BAL   RC,ROUFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 36600013
         SPACE 1                                                        36700013
*    SET NETWORK FOR A 6 WAY MERGE                                      36800013
         SPACE 1                                                        36900013
         MVC   ROUNOEQ8(4),ROUSXWM SET BR TO CMP ITEM 5 AFT ITEM 4 CMP  37000013
         BAL   RC,ROUFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 37100013
         SPACE 1                                                        37200013
*    SET NETWORK FOR A 5 WAY MERGE                                      37300013
         SPACE 1                                                        37400013
         MVC   ROUNOEQ4(4),ROUFVWM SET BR TO CMP ITEM 4 AFT ITEM 2 CMP  37500013
         MVC   ROUNTENS(4),ROUANT4 SET NETWORK ENTRANCE FOR 5 WAY MERGE 37600013
         BAL   RC,ROUFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 37700013
         SPACE 1                                                        37800013
*    SET NETWORK FOR A 4 WAY MERGE                                      37900013
         SPACE 1                                                        38000013
         MVC   ROUNOEQ4(4),ROUEGW3 SET BR TO CMP ITEM 3 AFT ITEM 2 CMP  38100013
         BAL   RC,ROUFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 38200013
         SPACE 1                                                        38300013
*    SET NETWORK FOR A 3 WAY MERGE                                      38400013
         SPACE 1                                                        38500013
         MVC   ROUNOEQ4(4),ROUTHWM SET BR TO UPDATE AFTER ITEM 2 CMP    38600013
         BAL   RC,ROUFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 38700013
         SPACE 1                                                        38800013
*    SET NETWORK FOR A 2 WAY MERGE                                      38900013
         SPACE 1                                                        39000013
         MVC   ROUNTENS(4),ROUANT2 SET NETWORK ENTRANCE FOR 2 WAY MERGE 39100013
         BAL   RC,ROUFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 39200013
         SPACE 1                                                        39300013
*    SET NETWORK FOR A 1 WAY MERGE                                      39400013
         SPACE 1                                                        39500013
         MVC   ROUNTENS(4),ROUANT1 SET NETWORK ENTRANCE FOR 1 WAY MERGE 39600013
         BAL   RC,ROUFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 39700013
         SPACE 1                                                        39800013
*    A ZERO WAY MERGE                                                   39900013
*    IF PHASE 2 EXIT TO THE BLOCK RTN (RELEASE CURRENT BLK TO WRITE)    40000013
*    IF PHASE 3 OR MERGE ONLY EXIT TO THE BLOCK RTN (END OF JOB)        40100013
*    THIS BRANCH INSTR IS SET BY THE ASSIGNMENT ROUTINE ACCORD TO PHASE 40200013
IERDOCPS BC    0,ROUCPH3           FALL THRU FOR PHASE 2                40300013
         L     RL,PPIBLK2+4                                             40400013
         BR    RL                  EXIT TO BLOCK RTN (WRITE THE BLK)    40500013
         SPACE 2                                                        40600013
ROUCPH3  L     RL,PPIBLK+4                                              40700013
         BR    RL                  EXIT TO BLOCK RTN (END OF JOB)       40800013
         SPACE 2                                                        40900013
*    THIS IS ENTRY TO THE CUTBACK RTN FROM READ RTN + THE ALGOR         41000013
ROUCUTEN LM    RE,RK,ROUSVREG      RESTORE NETWORK REGISTERS            41100013
         L     RC,ROUSVCBA         SET APPROPRIATE CUTBACK SECTION ADDR 41200013
         BR    RC                  BRANCH TO APPROPRIATE CUTBACK SECTN  41300013
         SPACE 2                                                        41400013
*    THIS IS THE END OF THE CUTBACK SECTION                             41500013
         EJECT                                                          41600013
*    INITIAL SEQUENCING OF RECORDS SECTION EXECUTED AT THE BEGINNING OF 41700013
*    EACH MERGE OPERATION.                                              41800013
*    A RELATIVE POSITION METHOD IS EMPLOYED FOR THE SEQUENCING          41900013
*    THIS METHOD CAN BE DESCRIBED AS COMPARING ONE ITEM OF A LIST WITH  42000013
*       THE REMAINDER OF THE ITEMS AND, THEREBY, DETERMINING ITS PROPER 42100013
*       POSITION IN THE LIST. TO ACCOMPLISH THIS, A TWO AREA SYSTEM IN  42200013
*       PPI IS UTILIZED.                                                42300013
         SPACE 1                                                        42400013
ROUINTSQ SR    RI,RI               INDEX USED TO GET ITEM S TO BE SEQD  42500013
         L     RB,ROUACMO          DETERMINES WHEN ALL ITEMS ARE SEQD   42600013
         LA    RG,PPIPDWA          BEGINNING ADDR OF REC ADDR IN PPI    42700013
ROURETRN L     RF,ROUACMO          USED TO CHECK WHEN AN ITEM HAS BEEN  42800013
*                                  CHECKED WITH ALL THE OTHER ITEMS     42900013
         L     RD,0(RI,RG)         THE ITEM WE ARE POSITIONING          43000013
         LA    RE,PPIPSVA-4        ADDR WHERE ITEM IS STORED AFT POS FD 43100013
         SR    RH,RH               INDEX USED TO CMP ALL OTHER ITEMS    43200013
ROUANOTH L     RC,0(RH,RG)         ADDR OF ITEM S CMP TO ITEM IN RC     43300013
IERDOICP CLC   0(1,RD),0(RC)                                            43400013
*    THIS BRANCH INSTR IS BC 10 OR 12 DEPENDING ON THE INPUT SEQUENCE   43500013
ROUISNLH BC    10,ROUHIEQ          HI/LO AND EQUAL CASE TREATED SAME    43600013
ROUDECR  LA    RH,4(0,RH)                                               43700013
         BCT   RF,ROUANOTH         TRY NEXT ITEM                        43800018
ROUCHEK  CLC   0(4,RE),KROZERO     STORAGE AREA OF ITEMS IS INITIALLY   43900013
*                                  ZERO CHECK TO INSURE ANOTHER ITEM    44000013
*                                  DOES NOT OCCUPY THIS POSITION        44100013
         BE    ROUINSRT            IF ZERO STORE ITEM                   44200013
         S     RE,KROFOUR          IF EQUAL CHECK NEXT LOWER POSITION   44300013
         B     ROUCHEK             CONTINUE CHECKING FOR ZEROS          44400018
         SPACE 2                                                        44500013
ROUINSRT ST    RD,0(0,RE)          STORE POSITIONED ITEM                44600013
         BCT   RB,ROUINCR          IF NOT DONE GET NEXT ITEM TO POSITIN 44700013
         B     ROUOUTIS            BRANCH TO SET NETWORK REG IF DONE    44800013
         SPACE 2                                                        44900013
*    THIS BRANCH INSTR IS BC 2 OR 4 DEPENDING ON THE INPUT SEQUENCE     45000013
ROUHIEQ  BC    2,ROURND            IF NOT EQ INCR STORE POS POINTER     45100013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    45200013
*    THIS BRANCH INSTR IS BC 4 OR 2 DEPENDING ON THE INPUT SEQUENCE     45300013
ROULOHI  BC    4,ROUDECR           CHECK NEXT ITEM                      45400018
ROURND   LA    RE,4(0,RE)                                               45500013
         B     ROUDECR             DECREMENT AND CHECK FOR ZEROS        45600018
         SPACE 2                                                        45700013
ROUINCR  LA    RI,4(0,RI)                                               45800013
         B     ROURETRN            LAST COMPARE                         45900018
*    THE END OF THE INITIAL SEQUENCING SECTION                          46000013
         SPACE 2                                                        46100013
*    MOVE ADDRESSES OF SEQUENCED ITEMS  TO MERGE NETWORK REGISTERS      46200013
ROUOUTIS LA    RB,PPIPSVA          ADDR OF FIRST SEQUENCED ITEM         46300013
         L     RC,ROUACMO          MERGE ORDER                          46400013
         A     RC,KROTWO                                                46500013
         EX    RC,ROULODMR         EXECUTE LOAD REGISTERS INSTR         46600013
*    THIS BRANCH INSTR SET BY THE ASSIGN RTN ACCORDING TO THE PHASE     46700013
IERDOIP3 BC    0,ROUINSP3          FALL THRU IF PHASE 2                 46800013
         STM   RE,RK,ROUSVREG      SAVE NETWORK REGISTERS               46900013
         L     RL,PPIBLK2+4                                             47000013
         B     12(0,RL)            EXIT TO BLK RTN WANT NEXT RCD        47100013
*    PHASE 3 PROCEDURE                                                  47200013
ROUINSP3 STM   RE,RK,ROUSVREG      SAVE NETWORK REGISTERS               47300013
         L     RL,PPIBLK+4                                              47400013
         B     4(0,RL)             EXIT TO BLOCK RTN WANT NEXT RCD      47500013
         SPACE 2                                                        47600013
         EJECT                                                          47700013
*    THIS IS SELF INITIALIZATION SECTION PERFORMED AT THE BEGINNING     47800013
*    OF EACH PASS OR SUB PASS.                                          47900013
         SPACE 1                                                        48000013
ROUSINIT MVC   ROUIDMO(4),KROEIGHT SET MAX MRG ORD TO 8  A FIND M PARAM 48100013
         LH    RE,PPIMRGMX         SET ACTUAL MRG ORD FROM PPI          48200013
         ST    RE,ROUACMO                                               48300013
         SR    RE,RE                                                    48400013
         ST    RE,PPIPSVA                                               48500013
         MVC   PPIPSVA+4(60),PPIPSVA      ZERO INT SEQ STORE AREA       48600013
         XI    ROUFMUDS+1,X'F0'    SET ROUFMUDS TO BRANCH               48700013
         TM    PPISW1+3,X'10'      IS INPUT SEQ ASDNG OR DESCG BIT 28   48800013
         BC    1,ROUISD            FALL THRU IF INPUT SEQ IS ASDNG      48900013
         TM    ROUNOEQ8+1,X'20'    IS RTN SET FOR ASDNG                 49000013
ROUFDSQ  BC    1,ROUCSEWM          IF THE ROUTINE IS SET FOR THE INPUT  49100013
         XI    ROUNOEQ8+1,X'60'    SEQUENCE  BRANCH TO THE CUTBACK      49200013
         XI    ROUNOEQ4+1,X'60'    SECTION.  IF THE ROUTINE IS NOT SET  49300013
         XI    ROUNOEQ2+1,X'60'    FOR THE INPUT   CHANGE THE MASK OF   49400013
         XI    ROUSCB+1,X'60'      THE BRANCH ON CONDITION INSTR.       49500013
         XI    ROUNOEQ6+1,X'60'                                         49600013
         XI    ROUNOEQ5+1,X'60'                                         49700013
         XI    ROUNOEQ7+1,X'60'                                         49800013
         XI    ROUNOEQ3+1,X'60'                                         49900013
         XI    ROUNOEQS+1,X'60'                                         50000013
         XI    ROUISNLH+1,X'60'                                         50100013
         XI    ROUHIEQ+1,X'60'                                          50200013
         XI    ROULOHI+1,X'60'                                          50300013
         XI    ROUEGW1+1,X'60'                                          50400013
         XI    ROUEGW2+1,X'60'                                          50500013
         XI    ROUEGW3+1,X'60'                                          50600013
         XI    ROUSVWM+1,X'60'                                          50700013
         XI    ROUSXWM+1,X'60'                                          50800013
         XI    ROUFVWM+1,X'60'                                          50900013
         XI    ROUTHWM+1,X'60'                                          51000013
         B     ROUCSEWM            BRANCH TO CUTBACK SECTION            51100013
         SPACE 2                                                        51200013
*    THE INPUT SEQUENCE IS IN DESCENDING ORDER                          51300013
ROUISD   TM    ROUNOEQ8+1,X'40'    IS ROUTINE SET FOR DESCG             51400013
         B     ROUFDSQ             MODIFY BRANCHES IF NECESSARY         51500018
         SPACE 2                                                        51600013
*    EXECUTED MOVE INSTRUCTION                                          51700013
         SPACE 1                                                        51800013
ROULODMR LM    RD,0,0(RB)          LOAD NETWORK REGISTERS               51900013
         EJECT                                                          52000013
         SPACE 2                                                        52100013
         DS    0F                  ALIGNMENT TO WORD BOUNDARY           52200013
ROUSVREG DS    7F                  REGISTER SAVE AREA FOR INTERFACING   52300013
ROUANT8  B     IERDOM8             NETWORK ENTR ADDR FOR 6,7,8 WAY MRG  52400013
ROUANT4  B     IERDOM4             NETWORK ENTR ADDR FOR 3,4,5 WAY MRG  52500013
ROUANT2  B     IERDOM2             NETWORK ENTR ADDR FOR 2 WAY MERGE    52600013
ROUANT1  B     IERDOM1             NETWORK ENTR ADDR FOR 1 WAY MERGE    52700013
ROUIDMO  DS    1F                  MAXIMUM MERGE ORDER SET BY INITIAL   52800013
ROUACMO  DS    1F                  ACTUAL MERGE ORDER SET BY INITIAL    52900013
ROUSVCBA DS    1F                  SAVE NEXT CUTBACK ADDRESS WORD       53000013
*    THE FOLLOWING 7 INSTR ARE BH OR BL DEPENDING ON THE INPUT SEQUENCE 53100013
ROUEGW1  BH    IERDOCK6            BRANCH TO COMPARE TIME 6 SET BY INIT 53200013
ROUEGW2  BH    IERDOCK7            BRANCH TO COMPARE ITEM 7 SET BY INIT 53300013
ROUEGW3  BH    IERDOCK3            BRANCH TO COMPARE ITEM 3 SET BY INIT 53400013
ROUSVWM  BH    ROUMOV6             BRANCH TO UPDATE RD TO RI SET BY INT 53500013
ROUSXWM  BH    IERDOCK5            BRANCH TO COMPARE ITEM 5 SET BY INIT 53600013
ROUFVWM  BH    IERDOCK4            BRANCH TO COMPARE ITEM 4 SET BY INIT 53700013
ROUTHWM  BH    ROUMOV2             BRANCH TO UPDATE RE TO RF SET BY INT 53800013
KROZERO  DC    XL4'0'              CONSTANT OF ZERO                     53900018
KROFOUR  DC    XL4'4'              CONSTANT OF FOUR                     54000018
KROEIGHT DC    XL4'8'              CONSTANT OF EIGHT                    54100018
KROTWO   DC    XL4'2'              CONSTANT OF TWO                      54200018
KROONE   DC    XL4'1'              CONSTANT OF ONE                      54260018
ROUTEMP  DC    H'0'                TEMP STORAGE FOR UNIT NUMBER         54330017
ROUCONV  DC    D'0'                CONVERSION AREA FOR UNIT NUMBER      54360017
         SPACE 2                                                        54400013
         SPACE 2                                                        54500013
         EJECT                                                          54600013
*                                                                       54700013
* MODULE NAME ***IERRMC***                                              54800013
*                                                                       54900013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        55000013
* PHASE 3 OR MERGE ONLY RUNNING PROGRAM.                                55100013
         SPACE 1                                                        55200013
DIERRMC  DSECT                                                          55300013
*                                                                       55400013
       COPY  RMCMAIN                                                    55500013
*                                                                       55600013
         SMPPI                                                          55700013
         END                                                            55800013
