         TITLE 'IERROV - OS/360 SORT/MERGE - 360S-SM-023  03/22/65'     00100013
*MODULE NAME:*** IERROV ***                                             00200013
         SPACE 2                                                        00300013
*STATUS: CHANGE LEVEL 000                                               00400013
         SPACE 2                                                        00500013
*MODULE FUNCTION/OPERATION: PHASE 2 AND 3, 1-8 WAY MERGE NETWORK WITH   00600013
*   A SINGLE CONTROL FIELD. THE FUNCTION OF THIS MODULE IS TO MERGE     00700013
*   FIXED OR VARIABLE LENGTH RECORDS IN ASCENDING OR DECENDING SEQUENCE 00800013
*   INITIALLY IERROV SEQUENCES THE INPUT RECORDS IN THE PHASE TO PHASE  00900013
*   INFORMATION AREA, CUTSBACK THE NETWORK FOR SPECIFIED MERGE ORDER    01000013
*   AND THEN UTILIZES A BINARY INSERTION TECHNIQUE. THIS IS ACCOMPLISH- 01100013
*   ED BY USING THE ADDRESSES OF THE RECORDS IN THE GENERAL REGISTERS   01200013
*   RE THRU RK. THE LOW ORDER 3 BYTES OF THE REGISTER CONTAIN THE       01300013
*   ADDRESS OF THE RECORD. THE HIGH ORDER BYTE HAS A FILE INDENTIFIER   01400013
*   FOR THE DEBLOCK ROUTINE. REGISTER RD IS THE NEW RECORD CONVEYER     01500013
*   FROM DEBLOCK AND COMMUNICATES TO BLOCK.                             01600013
         SPACE 2                                                        01700013
*MACRO'S USED:                                                          01800013
         SPACE 1                                                        01900013
*   SMPPI                                                               02000013
         SPACE 2                                                        02100013
*ENTRY POINTS:                                                          02200013
         SPACE 1                                                        02300013
*        ENTRY IERROQ              ENTRY FROM:                          02400013
*                                    CALLING SEQUENCE-                  02500013
*                                      LA   RP,PPINETM+4                02600013
*                                      BR   RP                          02700013
         SPACE 2                                                        02800013
*INPUT: PPI FIELDS REFERENCED-                                          02900013
         SPACE 1                                                        03000013
*   PPIDOOBA  PPIMRGMX  PPIPSVA    PPIBLK    PPIRMC                     03100013
*   PPIDOUA   PPIPDWA   PPISW1     PPIBLK2                              03200013
         SPACE 2                                                        03300013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             03400013
         SPACE 1                                                        03500013
*    PPIPSVA                                                            03600013
         SPACE 2                                                        03700013
*EXTERNAL ROUTINES:                                                     03800013
         SPACE 1                                                        03900013
*        EXTRN IERRMC              MESSAGE MODULE                       04000013
*        EXTRN IERDB2              PHASE TWO BLOCK ROUTINE              04100013
*        EXTRN IERDB34             PHASE THREE BLOCK ROUTINE            04200013
         SPACE 2                                                        04300013
*EXTERNAL PARAMETERS:                                                   04400013
         SPACE 1                                                        04500013
*        N/A                                                            04600013
*EXITS: NORMAL                                                          04700013
         SPACE 1                                                        04800013
*        IERDB2                    BLOCK PHASE 2                        04900013
*        IERDB34                   BLOCK PHASE 3                        05000013
         SPACE 2                                                        05100013
*EXITS: ERROR                                                           05200013
         SPACE 1                                                        05300013
*        IERRNC                    MESSAGE MODULE                       05400013
         SPACE 2                                                        05500013
*TABLES/WORK AREAS:                                                     05600013
         SPACE 1                                                        05700013
*        N/A                                                            05800013
         SPACE 2                                                        05900013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  06000013
         SPACE 2                                                        06100013
*NOTES: N/A                                                             06200013
         SPACE 1                                                        06300013
         SPACE 2                                                        06400013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            06500013
         SPACE 1                                                        06600013
RA       EQU   0                   CONTENTS IN- N/A                     06700013
*                                  USE- SYSTEM WORK REGISTER            06800013
*                                  CONTENTS OUT- N/A                    06900013
RB       EQU   1                   CONTENTS IN- N/A                     07000013
*                                  USE- SYSTEM PARAMETER REG            07100013
*                                  CONTENTS OUT- N/A                    07200013
RC       EQU   2                   CONTENTS IN- TO REGISTER EXTRACT     07300013
*                                  USE- TO REGISTER FOR EXTRACT RTN     07400013
*                                  CONTENTS OUT- TO REGISTER EXTRACT    07500013
RD       EQU   3                   CONTENTS IN- FROM REGISTER           07600013
*                                  USE- FROM REGISTER EXTRACT,WNR,NXT   07700013
*                                  CONTENTS OUT- FROM REGISTER          07800013
RE       EQU   4                   CONTENTS IN- MERGE ADDRESS ITEM 1    07900013
*                                  USE- MERGE NETWORK REGISTER          08000013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 1   08100013
RF       EQU   5                   CONTENTS IN- MERGE ADDRESS ITEM  2   08200013
*                                  USE- MERGE NETWORK REGISTER          08300013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 2   08400013
RG       EQU   6                   CONTENTS IN- MERGE ADDRESS ITEM 3    08500013
*                                  USE- MERGE NETWORK REGISTER          08600013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 3   08700013
RH       EQU   7                   CONTENTS IN- MERGE ADDRESS  ITEM 4   08800013
*                                  USE- MERGE NETWORK REGISTER          08900013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 4   09000013
RI       EQU   8                   CONTENTS IN- MERGE ADDRESS ITEM 5    09100013
*                                  USE- MERGE NETWORK REGISTER          09200013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 5   09300013
RJ       EQU   9                   CONTENTS IN- MERGE ADDRESS ITEM 6    09400013
*                                  USE- MERGE NETWORK REGISTER          09500013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 6   09600013
RK       EQU   10                  CONTENTS IN- MERGE ADDRESS ITEM 7    09700013
*                                  USE- MERGE NETWORK REGISTER          09800013
*                                  CONTENTS OUT- MERGE ADDRESS ITEM 7   09900013
RL       EQU   11                  CONTENTS IN- N/A                     10000013
*                                  USE- PROGRAM BASE ADDRESS            10100013
*                                  CONTENTS OUT- PROGRAM ADDRESS        10200013
RM       EQU   12                  CONTENTS IN- EXTRACT RTN ADDRESS     10300013
*                                  USE- EXTRACT ROUTINE BASE REGISTER   10400013
*                                  CONTENTS OUT- EXTRACT RTN ADDRESS    10500013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          10600013
*                                  USE- PPI REFERENCE,REGISTER SAVE     10700013
*                                    AREA                               10800013
*                                  CONTENTS OUT- ADDRESS OF PPI         10900013
RO       EQU   14                  CONTENTS IN N/A                      11000013
*                                  USE- MESSAGE MODULE BASE ADDRESS REG 11100013
*                                  CONTENTS OUT- MESSAGE MODULE ADDRESS 11200013
RP       EQU   15                  CONTENTS IN- THIS MODULE ADDRESS     11300013
*                                  USE- SORT SYSTEM CONTROL INTERFACE   11400013
*                                  CONTENTS OUT- N/A                    11500013
         SPACE 2                                                        11600013
*START OF MODULE CODE PROPER:                                           11700013
         SPACE 2                                                        11800013
IERROV   CSECT                     MODULE IDENTICATION                  11900013
         USING *,RL                MODULE USING REGISTER                12000013
         USING IERRCA,RN           SETTING PPI DSECT USING REGISTER     12100013
         USING DIERRMC,RO          MESSAGE MODULE                       12200013
IERDO1   B     ROVSINIT            READ PRIME ENTRY BR TO INITIALIZAT   12300013
         B     ROVCUTEN            READ + ALGORITHM ENTRY BR TO CUTBACK 12400013
         LM    RE,RK,ROVSVREG      DEBLOCK ENTRY - RESTORE REGISTERS    12500013
IERDOET  B     ROVNTENS            FALL THRU IF EXTRACTING  CHRT FQC1   12600013
         L     RC,ROVSVEXA         SET RC WITH EXTR POS ADDR            12700013
         ST    RD,0(0,RC)          STORE RCD ADDR IN EXTRACT POS ADDR   12800013
         LR    RA,RC                                                    12900013
         LR    RC,RD               SET FROM AND TO REG FOR EXTRACT RTN  13000013
         LR    RD,RA                                                    13100013
         BAL   RO,4(0,RM)          EXIT TO EXTRACT ROUTINE              13200013
         LM    RE,RK,ROVSVREG      RESTORE MERGE REGISTERS              13300013
ROVNTENS B     IERDOM8             NETWORK ENTR SWTCH SET BY CUTBACK    13400013
         SPACE 2                                                        13500013
*    THE FIND THE WINNER LOOP                                           13600013
         SPACE 1                                                        13700013
*    ENTRANCE FOR A 6, 7, 8 WAY MERGE                                   13800013
         SPACE 1                                                        13900013
IERDOM8  CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 4         14000013
*    THIS BRANCH INSTR IS BH BL DEPENDING ON THE INPUT SEQUENCE         14100013
ROVI4B   BH    IERDOCK6            IF HI/LO GO TO CMP ITEM 6 OR 5       14200013
*    ENTRANCE FOR A 3, 4, 5 WAY MERGE                                   14300013
IERDOM4  CLC   0(1,RD),0(RF)       COMPARE NEW ITEM WITH ITEM 2         14400013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      14500013
ROVI2B   BH    IERDOCK3            IF HI/LO GO TO CMP ITEM 3,4 OR UPDAT 14600013
*    ENTRANCE FOR A 2 WAY MERGE                                         14700013
IERDOM2  CLC   0(1,RD),0(RE)       COMPARE NEW ITEM WITH ITEM 1         14800013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      14900013
ROVI1B   BH    ROVMOV1             IF HI/LO NEW COLLATES AFTER ITEM 1   15000013
         SPACE 1                                                        15100013
*    ENTRANCE FOR A ONE WAY MERGE AND NEW ITEM IS THE WINNER            15200013
         SPACE 1                                                        15300013
ROV1WM   XI    ROVSCSW+1,X'F0'     SET SEQ CHK SWITCH TO YES            15400013
         SPACE 1                                                        15500013
*    THIS SECTION OF CODE COMMUNICATES THE NETWORKS WINNING RECORD      15600013
*       ADDRESS TO THE BLOCK ROUTINE AFTER TAKING APPROPRIATE ACTION    15700013
*       IF EXTRACTING AND IF THERE IS TO BE A SEQUENCE CHECK. THE PHASE 15800013
*    AND EXTRACT SWITCHES ARE SET BY THE ASSGN RTN.                     15900013
         SPACE 1                                                        16000013
IERDOBWR BC    0,IERNEXTR          IF EXTRACTING FALL THRU              16100013
IERDOBB1 BC    0,ROVEPH3P          FALL THRU FOR PHASE 2                16200013
         ST    RD,ROVSVEXA         SAVE EXTRACT POS ADDR                16300013
         L     RD,0(0,RD)          LOAD ACTUAL ADDRESS OF WINNING RCD   16400013
ROVBBLK2 STM   RE,RK,ROVSVREG      SAVE NETWORK REGISTERS               16500013
ROVBBFIS BC    0,ROVISOUT          IF RCD FROM INT SEQ BRANCH           16600013
         SPACE 1                                                        16700013
         L     RL,PPIBLK2+4                                             16800013
         B     16(0,RL)            EXIT TO BLK RTN WANT NEXT RCD        16900013
         SPACE 2                                                        17000013
ROVISOUT XI    ROVBBFIS+1,X'F0'                                         17100013
         L     RL,PPIBLK2+4                                             17200013
         B     12(0,RL)            EXIT TO BLK RTN WANT NEXT RCD        17300013
         SPACE 2                                                        17400013
*    PHASE 3 + MERGE ONLY PROCEDURE IF EXTRACTING                       17500013
         SPACE 1                                                        17600013
ROVEPH3P L     RC,ROVSQCWD         PUT EXTRACT POS ADDR IN RC           17700013
         ST    RC,ROVSVEXA                                              17800013
         ST    RD,ROVSQCWD         SAVE WIN EXTRACT POS ADDR FOR SEQ CK 17900013
*    SWITCH SET BY INITIAL SEQUENCING RTN TO BYPASS CHK FOR SEQ CHK     18000013
ROVFRSW1 BC    0,ROVFR1            FALL THRU IF NOT FIRST RECORD        18100013
         SPACE 1                                                        18200013
*    IF THE NEW RECORD IS THE WINNER,A SEQUENCE CHECK WILL BE PERFORMED 18300013
*       IF REQUESTED. IF THE NEW RECORD IS NOT THE WINNER,NO SEQUENCE   18400013
*       CHECK IS NECESSARY.                                             18500013
         SPACE 1                                                        18600013
ROVSCSW  BC    0,ROVNIW            FALL THRU IF NEW IS NOT WINNER       18700013
IERXTRT1 BC    0,ROVSVR            FALL THRU IF EXTRACTING              18800013
ROVSAA   L     RD,0(0,RD)          LOAD ACTUAL ADDRESS OF WINNING RCD   18900013
ROVSVR   STM   RE,RK,ROVSVREG      SAVE NETWORK REGISTERS               19000013
         L     RL,PPIBLK+4                                              19100013
         B     4(0,RL)             EXIT TO BLK RTN WANT NEXT RECORD     19200013
         SPACE 2                                                        19300013
ROVFR1   XI    ROVFRSW1+1,X'F0'    SET FIRST RCD SWITCH 1 TO FALL THRU  19400013
         B     ROVSAA              BRANCH TO SET ACTUAL ADDRESS         19500013
         SPACE 2                                                        19600013
ROVNIW   XI    ROVSCSW+1,X'F0'     SET ROVSCSW TO FALL THRU             19700013
         SPACE 1                                                        19800013
*    SEQUENCE CHECK OF CURRENT NETWORK WINNER AND PREVIOUS NETWORK      19900013
*       WINNER. CHECK DONE USING REG RD AND RC.                         20000013
*    THE USER COMMUNICATES A 0 OR 4 TO THE BLOCK RTN. THE BLOCK RTN.    20100013
*       SETS PPIDOUO IF A RECORD MODIFICATION EXIT IS ACTIVATED. IF NO  20200013
*       EXITS ARE ACTIVATED,THE BLOCK RTN TAKES NO ACTION CONCERNING    20300013
*       PPIDOUO.                                                        20400013
*    A 0 MEANS A SEQUENCE CHECK IS TO BE PERFORMED. A 4 MEANS NO        20500013
*       SEQUENCE CHECK. IF NO RCD MODIFICATION EXITS ARE ACTIVATED,     20600013
*       PPIDOUO IS 0.                                                   20700013
         SPACE 2                                                        20800013
         L     RB,PPIDOUO                                               20900013
         B     ROVCKISC(RB)        USER MOD.                            21000018
ROVCKISC B     IERDOSCK            SEQUENCE CHECK                       21100018
         SPACE 1                                                        21200013
*    NO SEQUENCE CHECK                                                  21300013
         SPACE 1                                                        21400013
IERXTRT2 BC    15,ROVSAA           IF EXTRACTING BRANCH TO ROVSAA       21500013
         B     ROVSVR              IF NOT EXTRACTING BRANCH TO ROVSVR   21600013
         SPACE 2                                                        21700013
IERDOSCK CLC   0(1,RD),0(RC)                                            21800013
*    THIS BRANCH INSTR IS BC 10 OR 12 DEPENDING ON THE INPUT SEQUENCE   21900013
ROVSCB   BC    10,IERXTRT1         GET NEXT RECORD FROM BLOCK RTN.      22000018
*    OUT OF SEQUENCE ERROR                                              22100013
         L     RO,PPIRMC+4                                              22200013
         TM    PPISW1+2,X'02'      TEST FOR MERGE RUN                   22220017
         BO    ROVMERG             YES, BRANCH                          22240017
         SPACE                                                          22260017
         LM    RA,RB,MSGP3A04      OUT OF SEQUENCE MESSAGE              22300013
ROVSEQ   L     RP,PPIADSSC                                              22400017
         BAL   RO,12(0,RP)         SORT SYS CNTRL                       22500013
         L     RP,PPIADSSC                                              22600013
         BAL   RO,16(0,RP)         ABORT THE SORT CODE                  22700013
         SPACE 2                                                        22800013
ROVMERG  BC    0,ROV100            FALL THRU IF EXTRACTING              22803017
         SPACE 1                                                        22806017
         L     RD,0(RD)            LOAD RECORD ADDRESS FROM EXTRACT     22809017
*                                    WORK AREA                          22812017
ROV100   SRL   RD,26               CONVERT DCB INDEX TO UNIT NUMBER     22815017
         CVD   RD,ROVCONV          CONVERT INDEX TO DECIMAL             22820017
         UNPK  ROVTEMP(2),ROVCONV+7(1)  UNPACK FOR PRINTING             22830017
         OI    ROVTEMP+1,X'F0'     SET SIGN POSITIVE                    22840017
         MVC   MSGP3MA8(2),ROVTEMP      MOVE UNIT NUMBER INTO MESSAGE   22850017
         LM    RA,RB,MSGP3A08      MERGE OUT OF SEQ MESSAGE             22860017
         B     ROVSEQ              GO PRINT MESSAGE                     22870017
         SPACE 2                                                        22880017
*    NOT EXTRACTING                                                     22900013
IERNEXTR B     ROVBBLK2            IF PHASE 2 BRANCH                    23000013
ROVFRSW2 BC    0,ROVFR2            IF FIRST RECORD BRANCH               23100013
         L     RC,PPIDOOBA         ADDR OF RCD IN OUTPUT BUFFER         23200013
         B     ROVSCSW             BRANCH TO CHK IF SEQ CHK REQUIRED    23300013
         SPACE 2                                                        23400013
ROVFR2   XI    ROVFRSW2+1,X'F0'    SET FIRST RCD SW 2 TO FALL THRU      23500013
         B     ROVSVR              BRANCH TO BLOCK RECORD               23600013
         SPACE 2                                                        23700013
IERDOCK6 CLC   0(1,RD),0(RJ)       COMPARE NEW ITEM WITH ITEM 6         23800013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      23900013
ROVI6B   BH    IERDOCK7            IF HI/LO GO TO CMP ITEM 7 OR UPDATE  24000013
IERDOCK5 CLC   0(1,RD),0(RI)       COMPARE NEW ITEM WITH ITEM 5         24100013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      24200013
ROVI5B   BH    ROVMOV5             IF HI/LO NEW COLLATES AFTER ITEM 5   24300013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 4 + BEFORE ITEM 5      24400013
         SPACE 1                                                        24500013
ROVMOV4  LR    RC,RD                                                    24600013
         LR    RD,RE                                                    24700013
         LR    RE,RF                                                    24800013
         LR    RF,RG                                                    24900013
         LR    RG,RH                                                    25000013
         LR    RH,RC                                                    25100013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              25200013
         SPACE 1                                                        25300013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 5 + BEFORE ITEM 6      25400013
ROVMOV5  LR    RC,RD                                                    25500013
         LR    RD,RE                                                    25600013
         LR    RE,RF                                                    25700013
         LR    RF,RG                                                    25800013
         LR    RG,RH                                                    25900013
         LR    RH,RI                                                    26000013
         LR    RI,RC                                                    26100013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              26200013
         SPACE 2                                                        26300013
IERDOCK7 CLC   0(1,RD),0(RK)       COMPARE NEW ITEM WITH ITEM 7         26400013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      26500013
ROVI7B   BH    ROVMOV7             IF HI/LO NEW COLLATES AFTER ITEM 7   26600013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 6 + BEFORE ITEM 7      26700013
ROVMOV6  LR    RC,RD                                                    26800013
         LR    RD,RE                                                    26900013
         LR    RE,RF                                                    27000013
         LR    RF,RG                                                    27100013
         LR    RG,RH                                                    27200013
         LR    RH,RI                                                    27300013
         LR    RI,RJ                                                    27400013
         LR    RJ,RC                                                    27500013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              27600013
         SPACE 1                                                        27700013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 7                      27800013
ROVMOV7  LR    RC,RD                                                    27900013
ROVMMOV7 LR    RD,RE               UPDATE EXECUTED AFT CUTBACK OPERAT   28000013
         LR    RE,RF                                                    28100013
         LR    RF,RG                                                    28200013
         LR    RG,RH                                                    28300013
         LR    RH,RI                                                    28400013
         LR    RI,RJ                                                    28500013
         LR    RJ,RK                                                    28600013
         LR    RK,RC                                                    28700013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              28800013
         SPACE 2                                                        28900013
IERDOCK3 CLC   0(1,RD),0(RG)       COMPARE NEW ITEM WITH ITEM 3         29000013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      29100013
ROVI3B   BH    ROVMOV3             INSERT INTO COLLATING SEQUENCE       29200018
         SPACE 1                                                        29300013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 2 + BEFORE ITEM 3      29400013
ROVMOV2  LR    RC,RD                                                    29500013
         LR    RD,RE                                                    29600013
         LR    RE,RF                                                    29700013
         LR    RF,RC                                                    29800013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              29900013
         SPACE 1                                                        30000013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 3 + BEFORE ITEM 4      30100013
ROVMOV3  LR    RC,RD                                                    30200013
         LR    RD,RE                                                    30300013
         LR    RE,RF                                                    30400013
         LR    RF,RG                                                    30500013
         LR    RG,RC                                                    30600013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              30700013
         SPACE 1                                                        30800013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 1 + BEFORE ITEM 2      30900013
ROVMOV1  LR    RC,RD                                                    31000013
         LR    RD,RE                                                    31100013
         LR    RE,RC                                                    31200013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              31300013
         SPACE 1                                                        31400013
*    SPECIAL ITEM 4 COMPARE FOR 5 WAY MERGE                             31500013
IERDOCK4 CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 4         31600013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      31700013
ROVSI4B  BH    ROVMOV4             IF HI/LO GO TO UPDATE                31800013
         B     IERDOCK3            GO TO COMPARE NEW ITEM WITH ITEM 3   31900013
         EJECT                                                          32000013
         SPACE 2                                                        32100013
*    THE NETWORK CUTBACK SECTION.                                       32200013
*    IT IS THAT CODE WHICH TAILORS THE NETWORK FOR THE MERGE ORDER      32300013
         SPACE 2                                                        32400013
*    THE INITIAL ENTRANCE TO THE CUTBACK SECTION                        32500013
         SPACE 1                                                        32600013
*    SET NETWORK FOR AN 8 WAY MERGE                                     32700013
         SPACE 1                                                        32800013
ROVCSEWM MVC   ROVI4B(4),ROVEGW1   SET BR TO CMP ITEM 6 AFT ITEM 4 CMP  32900013
         MVC   ROVI6B(4),ROVEGW2   SET BR TO CMP ITEM 7 AFT ITEM 6 CMP  33000013
         MVC   ROVI2B(4),ROVEGW3   SET BR TO CMP ITEM 3 AFT ITEM 2 CMP  33100013
         MVC   ROVNTENS(4),ROVANT8 SET NETWORK ENTRANCE FOR 8 WAY MERGE 33200013
         BAL   RC,ROVFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 33300013
         SPACE 1                                                        33400013
*    SET NETWORK FOR AN 7 WAY MERGE                                     33500013
         SPACE 1                                                        33600013
         MVC   ROVI6B(4),ROVSVWM   SET BR TO UPDATE AFTER ITEM 6 CMP    33700013
         BAL   RC,ROVFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 33800013
         SPACE 1                                                        33900013
*    SET NETWORK FOR A 6 WAY MERGE                                      34000013
         SPACE 1                                                        34100013
         MVC   ROVI4B(4),ROVSXWM   SET BR TO CMP ITEM 5 AFT ITEM 4 CMP  34200013
         BAL   RC,ROVFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 34300013
         SPACE 1                                                        34400013
*    SET NETWORK FOR A 5 WAY MERGE                                      34500013
         SPACE 1                                                        34600013
         MVC   ROVI2B(4),ROVFVWM   SET BR TO CMP ITEM 4 AFT ITEM 2 CMP  34700013
         MVC   ROVNTENS(4),ROVANT4 SET NETWORK ENTRANCE FOR A 5 WAY MRG 34800013
         BAL   RC,ROVFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 34900013
         SPACE 1                                                        35000013
*    SET NETWORK FOR A 4 WAY MERGE                                      35100013
         SPACE 1                                                        35200013
         MVC   ROVI2B(4),ROVEGW3   SET BR TO CMP ITEM 3 AFT ITEM 2 CMP  35300013
         BAL   RC,ROVFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 35400013
         SPACE 1                                                        35500013
*    SET NETWORK FOR A 3 WAY MERGE                                      35600013
         SPACE 1                                                        35700013
         MVC   ROVI2B(4),ROVTHWM   SET BR TO UPDATE AFTER ITEM 2 CMP    35800013
         BAL   RC,ROVFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 35900013
         SPACE 1                                                        36000013
*    SET NETWORK FOR A 2 WAY MERGE                                      36100013
         SPACE 1                                                        36200013
         MVC   ROVNTENS(4),ROVANT2 SET NETWORK ENTRANCE FOR A 2 WAY MRG 36300013
         BAL   RC,ROVFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 36400013
         SPACE 1                                                        36500013
*    SET NETWORK FOR A 1 WAY MERGE                                      36600013
         SPACE 1                                                        36700013
         MVC   ROVNTENS(4),ROVANT1 SET NETWORK ENTRANCE FOR A 1 WAY MRG 36800013
         BAL   RC,ROVFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 36900013
         SPACE 1                                                        37000013
*    A ZERO WAY MERGE                                                   37100013
         SPACE 1                                                        37200013
*    IF PHASE 2 EXIT TO THE BLOCK RTN (RELEASE CURRENT BLK TO WRITE)    37300013
*    IF PHASE 3 OR MERGE ONLY EXIT TO THE BLOCK RTN (END OF JOB)        37400013
         SPACE 1                                                        37500013
IERDOCPS BC    0,ROVCPH3           FALL THRU FOR PHASE 2                37600013
         L     RL,PPIBLK2+4                                             37700013
         BR    RL                  PH2 BLOCK/DEBLOCK                    37800018
         SPACE 2                                                        37900013
ROVCPH3  L     RL,PPIBLK+4                                              38000013
         BR    RL                  BLOCK RTN.                           38100018
         SPACE 2                                                        38200013
*    THIS IS ENTRY TO THE CUTBACK RTN FROM READ RTN + THE ALGORITHM     38300013
         SPACE 1                                                        38400013
ROVCUTEN LM    RE,RK,ROVSVREG      RESTORE NETWORK REGISTERS            38500013
         L     RC,ROVSVCBA         SET APPROPRIATE CUTBACK SECTION ADDR 38600013
         BR    RC                  CUTBACK                              38700018
         EJECT                                                          38800013
*    THIS SECTION OF CODE ENTERED UPON COMPLETION OF A CUTBACK OPERTION 38900013
*    THIS SECTION INITIALLY CHECKS FOR THE NETWORK BEING SET FOR THE    39000013
*    MERGE ORDER.  SUBSEQUENTLY A BRANCH TO UPDATE IS EXECUTED.         39100013
         SPACE 1                                                        39200013
ROVFMUDS BC    0,ROVFDMO           SET TO BRANCH BY INITIALIZATION RTN  39300013
*    FALL THRU FOR UPDATING NETWORK AFTER A CUTBACK OPERATION           39400013
         SPACE 1                                                        39500013
         ST    RC,ROVSVCBA         SAVE NEXT CUTBACK ADDRESS            39600013
         B     ROVMMOV7            MODIFIED MOVE AFTER ITEM 7           39700013
         SPACE 2                                                        39800013
ROVFDMO  L     RF,ROVIDMO          SET TO 8 BY INITIALIZATION RTN       39900013
         C     RF,ROVACMO          SET TO ACTUAL MERGE ORDER BY INITIAL 40000013
         BE    ROVSFTTU            SET FALL THRU TO UPDATE              40100013
         S     RF,KROONE           CONSTANT OF ONE                      40200013
         ST    RF,ROVIDMO                                               40300013
         BR    RC                  BRANCH BACK TO CUTBACK RTN           40400013
         SPACE 2                                                        40500013
ROVSFTTU XI    ROVFMUDS+1,X'F0'    SET ROVFMUDS BRANCH TO FALL THRU     40600013
         ST    RC,ROVSVCBA         SAVE ADDRESS OF NEXT CUTBACK CODE    40700013
         B     ROVINTSQ            EXIT TO INIT SEQ THE RECORDS         40800013
         EJECT                                                          40900013
*    INITIAL SEQUENCING OF RECORDS SECTION EXECUTED AT THE BEGINNING OF 41000013
*    EACH MERGE OPERATION.                                              41100013
*    A RELATIVE POSITION METHOD IS EMPLOYED FOR THE SEQUENCING.         41200013
*    THIS METHOD CAN BE DESCRIBED AS COMPARING ONE ITEM OF A LIST WITH  41300013
*       THE REMAINDER OF THE ITEMS AND,THEREBY,DETERMINING ITS PROPER   41400013
*       POSITION IN THE LIST. TO ACCOMPLISH THIS,A TWO AREA SYSTEM IN   41500013
*       PPI IS UTILIZED.                                                41600013
         SPACE 2                                                        41700013
ROVINTSQ SR    RI,RI               INDEX USED TO GET ITEMS TO BE SEQD   41800013
         L     RB,ROVACMO          DETERMINES WHEN ALL ITEMS ARE SEQD   41900013
         LA    RG,PPIPDWA          BEGINNING ADDR OF RCD ADDR IN PPI    42000013
ROVRETRN L     RF,ROVACMO          USED TO CHECK WHEN AN ITEM HAS BEEN  42100013
*                                  CHECKED WITH ALL THE OTHER ITEMS     42200013
         L     RD,0(RI,RG)         THE ITEM WE ARE POSITIONING          42300013
         LA    RE,PPIPSVA-4        ADDR WHERE ITEM IS STORED AFT POS FD 42400013
         SR    RH,RH               INDEX USED TO CMP ALL OTHER ITEMS    42500013
ROVANOTH L     RC,0(RH,RG)         ADDR OF ITEMS CMP TO ITEM IN RC      42600013
IERDOICP CLC   0(1,RD),0(RC)                                            42700013
*    THIS BRANCH INSTR IS BC 10 OR 12 DEPENDING ON THE INPUT SEQUENCE   42800013
ROVISNLH BC    10,ROVHIEQ          HI/LO AND EQUAL CASE TREATED SAME    42900013
ROVDECR  LA    RH,4(0,RH)                                               43000013
         BCT   RF,ROVANOTH         CHECK NEXT ITEM                      43100018
ROVCHEK  CLC   0(4,RE),KROZERO     STORAGE AREA OF ITEMS IS INITIALLY   43200013
*                                  ZERO CHECKED TO INSURE THAT ANOTHER  43300013
*                                  ITEM DOES NOT OCCUPY THIS POSITION   43400013
         BE    ROVINSRT            IF ZERO STORE ITEM                   43500013
         S     RE,KROFOUR          IF EQUAL CHECK NEXT LOWER POSITION   43600013
         B     ROVCHEK             CHECK NEXT POSITION                  43700018
ROVINSRT ST    RD,0(0,RE)          STORE POSITIONED ITEM                43800013
         BCT   RB,ROVINCR          IF NOT DONE GET NEXT ITEM TO POSITIN 43900013
         B     ROVOUTIS            BRANCH TO SET NETWORK REG            44000013
         SPACE 2                                                        44100013
ROVHIEQ  LA    RE,4(0,RE)                                               44200013
         B     ROVDECR             CHECK NEXT ITEM                      44300018
         SPACE 2                                                        44400013
ROVINCR  LA    RI,4(0,RI)                                               44500013
         B     ROVRETRN            BRANCH FOR LAST CHECK                44600018
         SPACE 2                                                        44700013
*    THE END OF THE INITIAL SEQUENCING SECTION                          44800013
         SPACE 2                                                        44900013
*    MOVE ADDRESSES OF SEQUENCED ITEMS TO MERGE NETWORK REGISTERS       45000013
ROVOUTIS LA    RB,PPIPSVA          ADDR OF FIRST SEQUENCED ITEM         45100013
         L     RC,ROVACMO          MERGE ORDER                          45200013
         A     RC,KROTWO                                                45300013
         EX    RC,ROVLODMR         EXECUTE LOAD REGISTERS INSTR         45400013
         XI    ROVFRSW1+1,X'F0'    SETTING FIRST RCD SWITCHES TO BRANCH 45500013
         XI    ROVFRSW2+1,X'F0'                                         45600013
         XI    ROVBBFIS+1,X'F0'    SET INT SEQ BRANCH FOR BLK INTERFACE 45700013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              45800013
         SPACE 2                                                        45900013
         EJECT                                                          46000013
*    THIS IS SELF INITIALIZATION SECTION PERFORMED AT THE BEGINNING     46100013
*    OF EACH PASS OR SUB PASS.                                          46200013
         SPACE 2                                                        46300013
ROVSINIT MVC   ROVIDMO(4),KROEIGHT SET MAX MERGE ORDER TO 8             46400013
         LH    RE,PPIMRGMX         SET ACTUAL MRG ORD FROM PPI          46500013
         ST    RE,ROVACMO                                               46600013
         SR    RE,RE                                                    46700013
         ST    RE,PPIPSVA                                               46800013
         MVC   PPIPSVA+4(60),PPIPSVA    ZERO INT SEQ STORE AREA         46900013
         XI    ROVFMUDS+1,X'F0'    SET ROVFMUDS TO BRANCH               47000013
         TM    PPISW1+3,X'10'      IS INPUT SEQ ASDNG OR DESCG BIT 28   47100013
         BC    1,ROVISD            FALL THRU IF INPUT SEQ IS ASDNG      47200013
         TM    ROVI4B+1,X'20'      IS ROUTINE SET FOR ASDNG             47300013
ROVFDSQ  BC    1,IERDOSET          IF THE ROUTINE IS SET FOR THE INPUT  47400013
         XI    ROVI4B+1,X'60'      SEQUENCE, BRANCH TO EXTRACT TEST.IF  47500013
         XI    ROVI2B+1,X'60'      THE ROUTINE IS NOT SET FOR THE INPUT 47600013
         XI    ROVI1B+1,X'60'      CHANGE THE MASK OF THE BRANCH ON     47700013
         XI    ROVSCB+1,X'60'      CONDITION INSTR.                     47800013
         XI    ROVI6B+1,X'60'                                           47900013
         XI    ROVI5B+1,X'60'                                           48000013
         XI    ROVI7B+1,X'60'                                           48100013
         XI    ROVI3B+1,X'60'                                           48200013
         XI    ROVSI4B+1,X'60'                                          48300013
         XI    ROVISNLH+1,X'60'                                         48400013
         XI    ROVEGW1+1,X'60'                                          48500013
         XI    ROVEGW2+1,X'60'                                          48600013
         XI    ROVEGW3+1,X'60'                                          48700013
         XI    ROVSVWM+1,X'60'                                          48800013
         XI    ROVSXWM+1,X'60'                                          48900013
         XI    ROVFVWM+1,X'60'                                          49000013
         XI    ROVTHWM+1,X'60'                                          49100013
IERDOSET BC    0,ROVCSEWM          FALL THRU IF EXTRACTING              49200013
*                                  IF NOT EXTRACTING,GO TO CUTBACK CODE 49300013
         LM    RD,RE,IERDOAGE      ADDR + LGH OF EXTRACT INFO           49400013
         LA    RK,PPIPDWA          ADDR OF RCDS IN PPI                  49500013
         L     RG,KROONE           INDEX TO DETERMINE WHEN DONE         49600013
         LR    RI,RG                                                    49700013
         L     RJ,ROVACMO                                               49800013
ROVRLD   L     RC,0(0,RK)          SET FROM ADDR FOR EXTR RTN           49900013
         STM   RE,RK,ROVSVREG      SAVE MERGE REG                       50000013
         BAL   RO,4(0,RM)          EXTRACT THIS RECORD                  50100013
         LM    RE,RK,ROVSVREG      RESTORE MERGE REG                    50200013
         ST    RC,0(0,RD)          STORE ADDR OF RCD AT EXTR POS        50300013
         ST    RD,0(0,RK)          STORE EXTR POS ADDR IN PPIPDWA AREA  50400013
         AR    RD,RE               INCR EXTR POS LENGTH                 50500013
         A     RK,KROFOUR          INCR TO NEXT RCD ADDR IN PPIPDWA     50600013
         BXLE  RG,RI,ROVRLD        ARE WE DONE EXTR THE RCDS IN PPIPDWA 50700013
         ST    RD,ROVSQCWD         SAVE NEXT EXTR POS ADDR              50800013
         B     ROVCSEWM            BRANCH TO CUTBACK SECTION            50900013
         SPACE 2                                                        51000013
*    THE INPUT SEQUENCE IS IN DESCENDING ORDER                          51100013
         SPACE 1                                                        51200013
ROVISD   TM    ROVI4B+1,X'40'      IS ROUTINE SET FOR DESCG             51300013
         B     ROVFDSQ             MODIFY BRANCH INSTRUCTIONS           51400018
         SPACE 2                                                        51500013
*    EXECUTED MOVE INSTRUCTION                                          51600013
         SPACE 1                                                        51700013
ROVLODMR LM    RD,0,0(RB)          LOAD NETWORK REGISTERS               51800013
         EJECT                                                          51900013
         DS    0F                  ALIGNMENT                            52000013
ROVSVREG DS    7F                  REGISTER SAVE AREA FOR INTERFACING   52100013
ROVSQCWD DS    1F                  WORD TO SAVE ADDRESS OF EXTRACT POS  52200013
*                                  OF RCD FOR SEQUENCE CHECK            52300013
IERDOAGE DS    1F                  BEGIN ADDR FOR GENERATED EXTRACT POS 52400013
IERDOEXL DS    1F                  LGH OF EXTR CTRL FLDS + 4 ADDR BYTES 52500013
         SPACE 1                                                        52600013
*    THE FOLLOWING 7 INSTR ARE BH OR BL DEPENDING ON THE INPUT SEQUENCE 52700013
         SPACE 1                                                        52800013
ROVEGW1  BH    IERDOCK6            BRANCH TO COMPARE ITEM 6 SET BY INIT 52900013
ROVEGW2  BH    IERDOCK7            BRANCH TO COMPARE ITEM 7 SET BY INIT 53000013
ROVEGW3  BH    IERDOCK3            BRANCH TO COMPARE ITEM 3 SET BY INIT 53100013
ROVSVWM  BH    ROVMOV6             BRANCH TO UPDATE RD TO RI SET BY INT 53200013
ROVSXWM  BH    IERDOCK5            BRANCH TO COMPARE ITEM 5 SET BY INIT 53300013
ROVFVWM  BH    IERDOCK4            BRANCH TO COMPARE ITEM 4 SET BY INIT 53400013
ROVTHWM  BH    ROVMOV2             BRANCH TO UPDATE RE TO RF SET BY INT 53500013
         SPACE 2                                                        53600013
ROVANT8  B     IERDOM8             NETWORK ENTR ADDR FOR 6,7,8 WAY MRG  53700013
ROVANT4  B     IERDOM4             NETWORK ENTR ADDR FOR 3,4,5 WAY MRG  53800013
ROVANT2  B     IERDOM2             NETWORK ENTR ADDR FOR 2 WAY MERGE    53900013
ROVANT1  B     ROV1WM              NETWORK ENTR ADDR FOR 1 WAY MERGE    54000013
ROVSVCBA DS    1F                  SAVE NEXT CUTBACK ADDRESS WORD       54100013
ROVIDMO  DS    1F                  MAXIMUM MERGE ORDER SET BY INITIAL   54200013
ROVACMO  DS    1F                  ACTUAL MERGE ORDER SET BY INITIAL    54300013
ROVSVEXA DS    1F                  EXT POS ADDR SAVE AREA               54400013
KROONE   DC    XL4'1'              CONSTANT OF ONE                      54500018
KROZERO  DC    XL4'0'              CONSTANT OF ZERO                     54600018
KROTWO   DC    XL4'2'              CONSTANT OF TWO                      54700018
KROFOUR  DC    XL4'4'              CONSTANT OF FOUR                     54800018
KROEIGHT DC    XL4'8'              CONSTANT OF EIGHT                    54860018
ROVTEMP  DC    H'0'                TEMP STORAGE FOR UNIT NUMBER         54930017
ROVCONV  DC    D'0'                CONVERSION AREA FOR UNIT NUMBER      54960017
         EJECT                                                          55000013
*                                                                       55100013
* MODULE NAME ***IERRMC***                                              55200013
*                                                                       55300013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        55400013
* PHASE 3 OR MERGE ONLY RUNNING PROGRAM.                                55500013
         SPACE 1                                                        55600013
DIERRMC  DSECT                                                          55700013
*                                                                       55800013
       COPY  RMCMAIN                                                    55900013
*                                                                       56000013
         SMPPI                                                          56100013
         END                                                            56200013
