SCAN     TITLE 'IEBUPDTE CONTROL CARD SCAN AND ANALYSER'                00020000
*TITLE- IEBUPDTE CONTROL CARD SCAN AND ANALYSIS CSECT- IEBASCAN       * 00040000
*                                                                     * 00060000
*STATUS- CHANGE LEVEL 001                                             * 00080000
*                                                                     * 00100000
*FUNCTION/OPERATION- THIS MODULE IS ABLE TO CREATE AND UPDATE         * 00120000
*   SYMBOLIC LIBRARIES WHICH ARE EITHER PHYSICAL SEQUENTIAL OR        * 00140000
*   PARTITIONED DATA SETS CONTAINED ON DIRECT ACCESS OR TAPE VOLUMES. * 00160000
*                                                                     * 00180000
*   THIS MODULE HANDLES FIXED OR FIXED-BLOCKED RECORDS. IT HAS THE    * 00200000
*   ABITLITY TO HANDLE RECORD OF LOGICAL RECORD LENGTHS UP TO EIGHTY  * 00220000
*   BYTES. IF BLOCKSIZE AND/OR LOGICAL RECORD LENGTH ARE NOT GIVEN    * 00240000
*   BY OPEN TIME, UNBLOCKED RECORDS OF 80 BYTES IS ASSUMED AND A      * 00260000
*   WARNING MESSAGE IS GIVEN ON THE LOG OUT DEVICE.                   * 00280000
*                                                                     * 00300000
*   THIS MODULE CAN-                                                  * 00320000
*                                                                     * 00340000
*   1. CREATE A NEW PARTITIONED OR PHYSICAL SEQUENTIAL DATA SET       * 00360000
*                                                                     * 00380000
*   2. SEQUENCE THE NEW DATA SET OR RESEQUENCE AN OLD ONE             * 00400000
*                                                                     * 00420000
*   3. REPRODUCE OR REPLACE A MEMBER OR A DATA SET                    * 00440000
*                                                                     * 00460000
*   4. PRODUCE A PARTITIONED DATA SET FROM A PHYSICAL SEQUENTIAL      * 00480000
*   MASTER OR THE CONVERSE.                                           * 00500000
*                                                                     * 00520000
*   4. ADD A MEMBER TO A PARTITIONED DATA SET.                        * 00540000
*                                                                     * 00560000
*   5. ASSIGN AN ALIAS NAME TO ANY MEMBER UPDATED                     * 00580000
*                                                                     * 00600000
*   6. CHANGE RECORDS IN A DATA SET                                   * 00620000
*                                                                     * 00640000
*   7. HANDLE RECORDS WITH NON-STANDARD SEQUENCE NUMBER FIELDS AND    * 00660000
*   LENGTHS OF SEQUENCE NUMBERS FROM 1 TO 8 CHARACTERS.               * 00680000
*                                                                     * 00700000
*   8. UPDATE ONLY SPECIFIED PORTION OF DATA SET RECORDS.             * 00720000
*                                                                     * 00740000
*   9. UPDATE INPLACE DATA SETS OR MEMBERS ON DIRECT ACCESS VOLUMES.  * 00760000
*                                                                     * 00780000
*ENTRY POINTS- ENTERED FROM THE OPERATING SYSTEM AT 'IEBUPDTE'.       * 00800000
*                                                                     * 00820000
*INPUT- SYSIN WHICH CONSISTS OF CONTROL CARDS AND LOGICAL DATA        * 00840000
*   RECORDS FOR INSERTION OR REPLACEMENT, THE INPUT DATA SET.         * 00860000
*                                                                     * 00880000
*       SYSUT1 WHICH DEFINES THE 'OLD MASTER' DATA SET WHICH MAY BE   * 00900000
*   PARTITIONED OR PHYSICAL SEQUENTIAL IN ORGANIZATION.               * 00920000
*                                                                     * 00940000
*OUTPUT-SYSPRINT WHICH CONTAINS DIAGNOSTIC MESSAGES, THE CONTENTS OF  * 00960000
*   SYSIN AND-IF THE 'LIST=ALL' CONDITION IS PRIMED- THE ENTIRE       * 00980000
*   'NEW MASTER' IS LISTED ON THE DEVICE DESIGNATED.                  * 01000000
*                                                                     * 01020000
*       SYSUT2 WHICH DEFINES THE 'NEW MASTER' DATA SET. IT WILL BE A  * 01040000
*   COMPOSITE OF THE SYSIN AND SYSUT1 DATA SETS. IT CAN BE EITHER     * 01060000
*   PARTITIONED OR PHYSICAL SEQUENTIAL IN ORGANIZATION.               * 01080000
*                                                                     * 01100000
*EXITS- NORMAL- A RETURN IS GIVEN TO THE SCHEDULAR MODULE OF THE      * 01120000
*   OPERATING SYSTEM. CONDITION CODE RETURNED ON A SUCCESSFUL RUN     * 01140000
*   WILL BE ZERO.                                                     * 01160000
*                                                                     * 01180000
*EXITS- ERROR- IF AN ERROR OCCURS, A CODE IS STORED, A MESSAGE        * 01200000
*   GIVEN TO THE USER EXPLAINING THE ERROR CONDITION AND A            * 01220000
*   RETURN TO THE OPERATING SYSTEM SCHEDULAR MODULE IS GIVEN.         * 01240000
*   RETURN CODE GIVEN ARE-                                            * 01260000
*   00 NORMAL TERMINATION OF A SUCCESSFUL RUN                         * 01280000
*   04 ERROR WITHIN A MEMBER- WILL TRY TO PROCESS NEXT MEMBER IF PODS * 01300000
*   12 UNRECOVERABLE ERROR- TERMINATION OF JOB.                       * 01320000
*   16 ERROR IN LABEL HANDLING IN USERS ROUTINE- TERMINATION OF JOB   * 01340000
*                                                                     * 01360000
*EXTERNAL ROUTINES- I/O HANDLED AT READ/WRITE LEVEL, GETMAIN, LINK,   * 01380000
*   BLDL, FIND, STOW USED.                                            * 01400000
*                                                                     * 01420000
*TABLES/WORK AREAS-                                                   * 01440000
*   -KEYTAB- LIST OF VALID KEY WORDS USED ON CONTROL CARDS            * 01460000
*   -COMDTABL- LIST OF VALID COMMAND WORDS USED ON CONTROL CARDS      * 01480000
*   -SWITCHRD- BUFFER CONTAINING CONTROL CARD AND SWITCHES USED       * 01500000
*   BY CARD SCAN ROUTINE.                                             * 01520000
*   -LOGOUTAR- BUFFER WHICH IS USED BY LOG OUT ROUTINE FOR MESSAGES.  * 01540000
*   -STARTAB- TABLE OF SWITCHES WHICH ARE RESET TO ZERO UPON ENTRY    * 01560000
*   TO MODULE. ALL SWITCHES NEEDING REINITIALIZATION SHOULD BE PUT    * 01580000
*   INTO THIS TABLE.                                                  * 01600000
*                                                                     * 01620000
*ATTRIBUTES- SERIAL REUSABLE, BLOCK LOADS                               01640000
*                                                                     * 01660000
*   THIS CSECT- 1. SCANS CONTROL STATEMENTS AND RETURNS POINTERS TO   * 01680000
*        THE 'TOSCAN' ROUTINE WHICH ANALYZES COMMANDS, KEYWORDS, AND  * 01700000
*        PARAMETERS.                                                  * 01720000
*               2. SWITCHRD BUFFER CONTAINS THE CONTROL STATEMENT AS  * 01740000
*        WELL AS THE SWITCHES AND BUFFERS NEEDED.                     * 01760000
*               3. 'LENGTH' REGISTER IS PASSED BACK FROM 'READCC'     * 01780000
*        CONTAINING THE NUMBER OF BYTES IN THE COMMAND, KEYWORD, OR   * 01800000
*        PARAMETER ENCOUNTERED DURING THE SCAN.                       * 01820000
*               4. 'SCANADR' REGISTER POINTS TO THE START OF THE      * 01840000
*        COMMAND/KEYWORD/PARAMETER.                                   * 01860000
*               5. 'KEYTAB' IS A TABLE CONTAINING THE VALID KEYWORDS. * 01880000
*               6. 'COMDTABL' IS A TABLE OF VALID COMMAND WORDS.      * 01900000
*               7. EACH COMMAND WORD AND KEYWORD HAS A ROUTINE TO     * 01920000
*        ANALYZE THE PARAMETERS ASSOCIATED WITH IT.                   * 01940000
*                                                                     * 01960000
         EJECT                                                          01980000
*     CHECKING OF VALID PARAMETER COMBINATIONS IS DONE IN 'SEQCKOUT'. * 02000000
*  'PARMSW' IS SET AS FOLLOWS-                                        * 02020000
*        KEYWORD             SETTING OF PARMSW                        * 02040000
*         SEQ1                    '01'                                * 02060000
*         SEQ2                    '02'                                * 02080000
*         INCR                    '04'                                * 02100000
*         NEW1                    '08'                                * 02120000
*         NAME                    '10'                                * 02140000
*         NEW                     '20'                                * 02160000
*         MEMBER                  '40'                                * 02180000
*                                                                     * 02200000
*     SYMBOLIC REGISTER NOTATION   GR0 - GR15                           02220000
GR0      EQU   0                                                        02240000
GR1      EQU   1                                                        02260000
GR2      EQU   2                                                        02280000
GR3      EQU   3                                                        02300000
GR4      EQU   4                       REGISTER RESERVED FOR CSECT1     02320000
GR5      EQU   5                                                        02340000
GR6      EQU   6                                                        02360000
GR7      EQU   7                                                        02380000
GR8      EQU   8                                                        02400000
GR9      EQU   9                                                        02420000
GR10     EQU   10                                                       02440000
GR11     EQU   11                                                       02460000
GR12     EQU   12                                                       02480000
GR13     EQU   13                                                       02500000
GR14     EQU   14                                                       02520000
GR15     EQU   15                                                       02540000
IEBASCAN CSECT                                                          02580000
*1101027400,047400-047800,145200,147600-148200,148800-151400,      UL0H 02581017
*1101152400-159800,166200-213400,219000                            UL0H 02582017
*1132                                                              MA0H 02584017
*1132                                                              4929 02586017
*1132                                                              6701 02588017
*1132                                                              6728 02592017
*1132                                                              7198 02596017
*1101132200                                                       20497 02597017
*1132                                                             20194 02598017
*1132                                                             19013 02599017
*1132                                                            PTM901 02599517
* 077800-078150                                                  A30501 02601519
* 125200-125400,125600                                           A25432 02603519
*                                                                A24189 02603921
*                                                                A25924 02605519
* 037680-036810,037600-037800,042400-042600,069400-069600        A30480 02605920
* 118600-118800,145400-145600                                    A30480 02606320
* 070920,130600,141000                                           A33286 02606720
* 050600-050800,055400-058000                                    A33314 02607120
* 084600-084800                                                  A33318 02607320
* 160150                                                         A31449 02607420
*                                                                A36128 02607521
*A144300,144320                                                  A38748 02609521
*A078100                                                         A41839 02609921
*A158150                                                         A45121 02615921
*A135900,135920,136700-136740                                    A54134 02618921
*D135800                                                         A54134 02621921
*D061400-061600,108200-109800                                    A54081 02625921
*A037150,037250,037350,042100                                   SA52860 02627921
*D037200,042200                                                 SA52860 02634321
*A029100,029120,029500,029520,132700,132720,132900,133300       SA61411 02636321
*A133320,156820,156840                                          SA61411 02638321
*D133000                                                        SA61411 02640321
*A161100-161160,161500-161540                                  @SA66054 02640721
*D161200                                                       @SA66054 02647221
*A160884-160924                                                @SA67456 02649221
*C160932                                                       @SA67456 02651221
*A076100-076340,076410-076500                                  @SA67452 02652221
*D076200,076500                                                @SA67452 02653221
         SAVE  (14,12)                                                  02654021
         BALR  GR2,0                   BASE ADDRESS ALL CSECTS EXCEPT 1 02660521
         USING NEXT,2                  CSECT1 USES GR4                  02667021
         USING IEBUPCON,12                                              02673521
NEXT     ST    GR13,SAVE13X            SAVE REGISTER 13                 02680000
         LA    GR13,REGSAVE            REGISTER SAVE AREA               02700000
TOSCAN   CLI   CCSCANSW,BIT01          IS THIS RETURN FROM CONTINUATION 02720000
         BE    SCANLINK                                            UL0H 02740017
         TM    SWITCHRD,BIT40          ARE ALL PARAMETERS COMPLETE      02760000
         BC    14,SCANLINK             NO- KEEP SCANNING                02780000
SEQCKOUT CLI   COMDCD,X'0E'            JUST ANALYSED A COMMAND CARD     02800000
         BE    CHEKPARM                YES- CHECK TH PARAMETERS         02820000
         BAL   GR14,CARDPRNT           PRINT CARD                       02840000
         MVI   PRINTED,X'0F'           FLAG AS CARD PRINTED             02860000
         CLC   DELTSEQ1(8),DELTSEQ2    COMPARE IF SEQ1 MORE THAN SEQ2   02880000
         BH    SCANERR                 YES- ERROR                       02900000
         CLI   NUMBR2SW,X'0F'     SECOND NUMBER STMT ANALYSED?  SA61411 02910021
         BE    NUMBR2             YES,BRANCH TO TEST IF INSERT  SA61411 02912021
         CLI   NUMBRSW,X'0E'           JUST ANALYSED NUMBER STATEMENT   02920000
         BNE   SKIPCOMP                NO- CONTINUE                     02940000
NUMBR2   CLI   OMEND,X'0F'        IS OLD MASTER FINISHED        SA61411 02950021
         BE    SEQERR             YES,GO TO GIVE ERROR MSG      SA61411 02952021
         MVI   NUMBRSW,X'0F'           FLAG AS NUMBER                   02960000
         TM    INSERTSW,X'0F'          TEST FOR BLOCK INSERT            02980000
         BC    1,TESTPARS              FIRST INSERT                     03000000
         BC    4,PLAINUMB              INSERT AFTER INSERT IN EFFECT    03020000
         CLI   PARMSW,X'0C'            NEW1 AND INCR PARAMETERS GIVEN   03040000
         BE    CHK4CHNG                YES- NO SEQ FIELDS CHECK CHANGE  03060000
         TM    ADDSW,X'0E'             ADD OPERATION                    03080000
         BC    1,SKIPCOMP              YES- IGNORE SEQ1 OR 2 FIELDS     03100000
         TM    REPLSW,X'0E'            REPLACE OPERATION                03120000
         BC    1,SKIPCOMP              YES- IGNORE SEQ1 OR 2 FIELDS     03140000
         CLI   PARMSW,X'0F'            ALL FIELDS ON NUMBER STATEMENT   03160000
         BE    COMPNMBR                YES- CHECK IF SEQ2 GREATER SEQ1  03180000
         CLI   PARMSW,X'0D'            SEQ1 MISSING IF NOT '0D' OR '0F' 03200000
         BNE   SCANERR                 SEQ1 MISSING- INVALID            03220000
         CLI   INPLCSW,X'0F'           UPDATE IN PLACE                  03240000
         BE    SKIPCOMP                SEQ2 MISSING                     03260000
         CLI   RENUMALL,X'0F'          RENUMBERING ALL DATA SET         03280000
         BNE   SCANERR                 NO- SEQ2 FIELD MISSING           03300000
         B     SKIPCOMP                CONTINUE                         03320000
CHK4CHNG TM    CHNGESW,X'0E'           CHANGE OPERATION                 03340000
         BC    12,SKIPCOMP             NO- CONTINUE NO SEQ1 OR 2        03360000
         MVI   RENUMALL,X'0F'          FORCE RENUMBERING OF ENTIRE DATA 03380000
         B     SKIPCOMP                FORCE RENUMBERING OF DATA SET    03400000
PLAINUMB CLI   INSRTRD,X'01'           PLAIN NUMBER WHILE INSERT EFFECT 03420000
         BNE   SCANERR                 YES- ILLEGAL MIXED NUMBER/INSERT 03440000
         MVI   INSERTSW,X'1F'          SET AS NEXT BLOCK INSERT + FORCE 03460000
         MVI   INSRTRD,RESET0          RESET SWITCH                     03480000
         TM    PARMSW,X'01'            SEQ1 GIVEN FOR INSERT            03500000
         BC    8,SCANERR               NO- ERROR                        03520000
         B     SKIPCOMP                OK- CONTINUE                     03540000
COMPNMBR CLC   NUMRSEQ1(8),NUMRSEQ2    COMPARE SEQ1 AND SEQ2            03560000
         BH    SCANERR                 IF SEQUENCE 1 MORE THAN 2 -ERROR 03580000
SKIPCOMP CLI   FIRSENTR,BIT10          FIRST ENTRY                      03600000
         BE    RESET                   YES- CHECK DCB SETTING           03620000
RESETPAR MVI   PARMSW,RESET0           RESET PARAMETER SWITCH           03640000
         MVI   PRINTED,RESET0          RESET CARD PRINTED SWITCH        03660000
         MVI   FIRSTCON,X'00'          RESET CONT. CARD PRINT SWITCUL0H 03661017
         CLI   ENDONLY,X'0F'           ACCEPT ENDUP ONLY           4929 03663017
         BNE   READNOW                 NO NOT FLUSHING             4929 03666017
         CLI   INPLCSW,X'0F'           UPDATE INPLACE              4929 03669017
         LA    GR11,UPDATMSG           UPDATE ERROR CODE           4929 03672017
         BE    STOWIT3                 SHOULD NOT HAVE ANOTHER     4929 03675017
         TM    CTONLYSW,X'11'     ALL INPUT FROM SYSIN           A30480 03678020
         BZ    OLDTO              NO.. OLD TO                    A30480 03681020
         CLI   PSSWNM,X'0F'            NM SEQUENTIAL               4929 03684017
         BE    REDNW                   NO- PARTITIONED             4929 03687017
         B     STOWIT2                 SEQUENTIAL                  4929 03690017
OLDTO    CLI   PSSWOM,X'0F'            OLD MASTER SEQUENTIAL       4929 03693017
         BE    REDNW                   NO- PARTITIONED             4929 03696017
         B     STOWIT2                 SEQUENTIAL                  4929 03699017
REDNW    MVI   ENDONLY,X'00'           CLEAR SWITCH                4929 03702017
         B     READNOW                 RETURN TO PROCESS           4929 03705017
RESET    CLI   FIRSTCON,X'0F'     CONTINUATION SWITCH SET?      SA52860 03715021
         BE    TESTORG            YES BRANCH TO TEST DSORG      SA52860 03725021
         MVI   FIRSENTR,RESET0    RESET FIRST ENTRY SWITCH      SA52860 03735021
         L     GR11,DCBNM              NEW MASTER DCB ADDRESS           03740000
         TM    CTONLYSW,X'11'     ALL INPUT FROM SYSIN           A30480 03760020
         BM    CHKIFDIF           YES.. SET UP DCBNM             A30480 03780020
         CLI   PARMSW,X'00'            BOTH PS- NO NAME,NEW OR MEMBER   03800000
         BNE   RESETPAR                NEW, NAME OR MEMBER ESTABLISHED  03820000
         L     GR10,DCBOM              OLD MASTER DCB                   03840000
         MVI   BDSORG(GR10),PSDSET     SET OLD MASTER AS PS        3628 03860015
SETNM2PS MVI   BDSORG(GR11),PSDSET     SET NEW MASTER AS PS        3628 03880015
         B     RESETPAR                CONTINUE                         03900000
CHKIFDIF TM    PARMSW,X'10'            'NAME' KEYWORD PRESENT           03920000
         BC    14,SETNM2PS             NO- SET NEW MASTER AS PS         03940000
         B     RESETPAR                CONTINUE- NM SET TO PO- FLAGDCBP 03960000
CHEKPARM MVI   COMDCD,X'0F'            FLAG AS COMMAND PROCESSED        03980000
         CLI   FIRSTCON,X'0F'          LAST PART OF COMMAND CONTINUED   04000000
         BE    JUSTPRNT                YES- JUST PRINT THIS PART        04020000
         CLI   FIRSENTR,BIT10          FIRST ENTRY                      04040000
         BNE   NOTFIRST                NO- PRINT HEADER                 04060000
JUSTPRNT LA    GR14,RESET              RETURN FROM PRINT                04080000
CARDPRNT MVI   ASISMSW,X'0F'           FORCE PRINTING OF CARD           04100000
PRINTY   MVC   LOGOUTAR+7(80),SWITCHRD+1         MOVE CARD TO BUFFER    04120000
         L     GR15,PRIMEWRT           ADDRESS OF MESSAGE ROUTINE       04140000
         BR    GR15                    RETURN PRESET IN GR14            04160000
NOTFIRST MVI   PRIMESW,X'0E'           FORCE PRINTING OF HEADER         04180000
         BAL   GR14,PRINTY             PRINT HEADER AND CARD            04200000
TESTORG  MVI   PRINTED,X'0F'      FLAG AS CARD ALREADY PRINTED  SA52860 04210021
         TM    CTONLYSW,X'11'     ALL INPUT FROM SYSIN           A30480 04240020
         BM    SAMETYPE           YES.. SPECIAL CASE             A30480 04260020
         CLC   PSSWOM(1),PSSWNM        ORGANIZATION SAME OM/NM          04280000
         BE    SAMETYPE                YES- CHECK SOME MORE             04300000
         CLI   NEWNAME,X'0F'           PS TO PO ORGANIZATION            04320000
         BE    PS2PO                   YES                              04340000
         CLI   PARMSW,X'30'            PO TO PS- 'NAME, NEW' ONLY       04360000
         B     VALIDITY                TEST IF VALID                    04380000
TESTPARS CLI   RENUMALL,X'0F'          RENUMBER ALL OF NEW MASTER       04400000
         BE    SCANERR                 YES- INVALID SEQ1=ALL            04420000
         CLI   PARMSW,X'0D'            SEQ1,INCR,NEW1, ON STATEMENT     04440000
         BL    SCANERR                 NO- SOMETHING MISSING            04460000
         CLC   NUMRSEQ1(8),NEW1NUMB    SEQ1 LOWER THAN NEW1 FOR INSERT  04480000
         BNL   SCANERR                 NO- CONTROL STATEMENT ERROR      04500000
         B     SKIPCOMP                CONTINUE                         04520000
SAMETYPE CLI   PSSWNM,X'00'            NEW MASTER PS OR BOTH PS         04540000
         BE    CHKPRMSW                YES CHECK PARAMETERS             04560000
         TM    PARMSW,X'10'            BOTH PO OR ONLY HAVE NM 'NAME'   04580000
         BC    8,SCANERR               NO 'NAME' CONTROL STATEMENT ERR. 04600000
         B     SKIPCOMP                PARAMETER ARE OK CONTINUE        04620000
CHKPRMSW CLI   PARMSW,X'00'            SHOULD HAVE NO 'NAME,NEW,MEMBER' 04640000
         B     VALIDITY                TEST IF VALID                    04660000
PS2PO    CLI   PARMSW,X'60'            ALLOW ONLY 'NEW' AND 'MEMBER'    04680000
VALIDITY BNE   SCANERR                 NO- CONTROL STATEMENT ERROR      04700000
         B     SKIPCOMP                PARAMETERS OK CONTINUE           04720000
SCANLINK L     GR15,RDCARD                                         UL0H 04730017
         BALR  GR14,GR15               SCAN FOR NEXT PARAMETER     UL0H 04740017
         LM    LENGTH,SCANADR,STOREG   RESTORE SCAN REGISTERS (0,1)UL0H 04750017
         CLI   LABEL2SW,X'F0'          HAS TRALER PROC BEEN REQUESTUL0H 04760017
         BE    CHEKCOMD                                            UL0H 04770017
SCANNED  TM    SWITCHRD,BIT80          IS ERROR BIT ON             UL0H 04780017
         BC    1,SCANERR               YES- CONTROL STATEMENT ERROR     04800000
         TM    SWITCHRD,BIT40          LAST PARAMETER IN CARD ENCOUNTER 04820000
         BC    1,COMMTEST              TEST FOR COMMAND OR KEY WORD     04840000
         LTR   LENGTH,LENGTH           IS SCAN LENGTH ZERO              04860000
         BZ    SCANERR                 YES- CONTROL STATEMENT ERROR     04880000
         LTR   SCANADR,SCANADR         SCAN ADDRESS POINTER ZERO        04900000
         BZ    SCANERR                 YES- CONTROL STATEMENT ERROR     04920000
COMMTEST TM    SWITCHRD,BIT08          IS THIS A COMMAND WORD           04940000
         BC    1,OPRLUP                YES- CHECK COMMAND               04960000
         TM    SWITCHRD,BIT04          IS THIS A KEYWORD                04980000
         BC    14,SEQCKOUT             CARD SCAN MUST BE COMPLETED      05000000
         SPACE 1                                                        05020000
*   KEYWORD LOOKUP ROUTINE                                              05040000
         L     GR7,KEYCHECK            GET DISPL. IN STARTTAB    A33314 05050020
         L     GR5,KEYSTART(GR7)       GET START ADDR. OF KEYTAB A33314 05060020
         L     GR7,KEYSTART+4(GR7)     GET END ADDR. OF KEYTAB   A33314 05070020
         B     SCANTBL                 SEARCH FOR KEY WORD              05100000
*   COMMAND WORD LOOKUP ROUTINE                                         05120000
OPRLUP   LA    GR5,COMDTABL            START OF COMMAND TABLE           05140000
         LA    GR7,1                   PREPARE TO INCREMENT LENGTH20194 05146017
         AR    LENGTH,GR7              INSURE BLANK FOLLOWS COMAND20194 05152017
         LA    GR7,COMDEND             END OF COMMAND TABLE             05160000
         MVI   KEYCHECK+3,X'00'   SET DISPL. FOR KEY START TAB   A33314 05170020
SCANTBL  STC   LENGTH,SAVLGTH          SAVE LENGTH REGISTER (0)         05180000
         CLI   SAVLGTH,8               TEST IF LENGTH LESS THAN 8       05200000
         BH    SCANERR                 NO- LENGTH EXCEEDS 8 ERROR       05220000
         LA    GR6,12                  INCREMENT VALUE                  05240000
         MVC   SARG(8),BLANKS8         CLEAR SEARCH ARGUMENT TO BLANKS  05260000
         LR    GR9,LENGTH              BE SURE REGISTER IS EXECUTABLE   05280000
         BCTR  GR9,0                   DECREMENT LENGTH FOR EXECUTE     05300000
         EX    GR9,OPRLUP3             MOVE PARAMETER TO STORAGE AREA   05320000
OPRCMP   CLC   SARG(8),0(GR5)          TEST IF SEARCH ARGUMENT IN TABLE 05340000
         BNE   OPRLUP2                 NO- CONTINUE SCAN OF TABLE       05360000
         LA    GR5,8(GR5)              ENTRY ADDRESS OF ROUTINE         05380000
         LM    LENGTH,SCANADR,STOREG   LOAD SCAN REGISTERS ( 0 AND 1)   05400000
         BR    GR5                     ENTER PROPER ROUTINE             05420000
OPRLUP2  BXLE  GR5,GR6,OPRCMP          LOOP TO CONTINUE SEARCH          05440000
         B     SCANERR                 COMMAND INVALID- NOT IN TABLE    05460000
* START AND END ADDRESSES OF VALID KEYWORDS IN KEYTAB            A33314 05462020
KEYCHECK DC    F'0'               DISPLACEMENT IN THIS TABLE     A33314 05464020
KEYSTART DC    A(OTHKEYS)         FIRST KEY FOR FUNCTION STMT    A33314 05466020
         DC    A(KEYEND)          LAST KEY FOR FUNCTION STMT     A33314 05468020
         DC    A(NMRKEYS)         FIRST KEY FOR NUMBER STMT      A33314 05470020
         DC    A(KEYEND1)         LAST KEY FOR NUMBER STMT       A33314 05472020
         DC    A(DELKEYS)         FIRST KEY FOR DELETE STMT      A33314 05474020
         DC    A(KEYEND2)         LAST KEY FOR DELETE STMT       A33314 05476020
         EJECT                                                          05480000
*    KEYWORD LOOKUP TABLE                                               05500000
         DS    0F                                                       05520000
* TABLE OF VALID KEYWORDS AND ADDRESSES OF THE ANALYSIS ROUTINES A33314 05530020
DELKEYS  EQU   *                  FIRST VALID KEY FOR DELETE     A33314 05540020
NMRKEYS  EQU   *                  FIRST VALID KEY FOR NUMBER     A33314 05550020
         DC    C'SEQ1    '                                       A33314 05560020
         B     CHKSEQ1                                           A33314 05570020
KEYEND2  EQU   *                  LAST VALID KEY FOR DELETE      A33314 05580020
         DC    C'SEQ2    '                                       A33314 05590020
         B     CHKSEQ2                                           A33314 05600020
         DC    C'INCR    '                                       A33314 05610020
         B     CHKINCR                                           A33314 05620020
         DC    C'NEW1    '                                       A33314 05630020
         B     CHKNEW1                                           A33314 05640020
KEYEND1  EQU   *                  LAST VALID KEY FOR NUMBER      A33314 05650020
         DC    C'INSERT  '                                       A33314 05660020
         B     CHKINSRT                                          A33314 05670020
OTHKEYS  EQU   *                  FIRST VALID KEY FOR FUNCTION   A33314 05680020
         DC    C'LIST    '                                       A33314 05690020
         B     CHKLIST                                           A33314 05700020
         DC    C'NAME    '                                       A33314 05710020
         B     CHKNAME                                           A33314 05720020
         DC    C'DATA    '              DATA FOR NO LABEL        A45205 05770022
         B     CHKDATA                  CHECK IF VALID           A45205 05780022
         DC    C'COLUMN  '                                              05820000
         B     CHKCOLMN                                                 05840000
         DC    C'SEQFLD  '                                              05860000
         B     CHKIDENT                                                 05880000
         DC    C'MEMBER  '                                              05900000
         B     CHKMEMBR                                                 05920000
         DC    C'NEW     '                                              05940000
         B     CHKNEW                                                   05960000
         DC    C'UPDATE  '                                              05980000
         B     UPDATANL                                                 06000000
         DC    C'LEVEL   '                                              06020000
         B     CHKLEVEL                                                 06040000
         DC    C'SSI     '                                              06060000
         B     CHKSSI                                                   06080000
         DC    C'SOURCE  '                                              06100000
         B     CHKSORCE                                                 06120000
         DC    C'INHDR   '                                              06180000
         B     CHKINHDR                                                 06200000
         DC    C'INTLR   '                                              06220000
         B     CHKINTRL                                                 06240000
         DC    C'OUTHDR  '                                              06260000
         B     CHKOUTHD                                                 06280000
         DC    C'TOTAL   '                                              06286018
         B     CHKTOTAL                                            UL0H 06293017
KEYEND   DC    C'OUTTLR  '             END OF TABLE OF KEY WORDS        06300000
         B     CKOUTTLR                                                 06320000
*    COMMAND LOOKUP TABLE                                               06340000
         DS    0F                                                       06360000
COMDTABL DC    C'ADD     '             START OF COMMAND WORD TABLE      06380000
         B     ADDANAL                 ADDRESS OF COMMAND ANALYSIS      06400000
LABEL    DC    C'LABEL   '                                         UL0H 06406017
         B     LABELANL                                            UL0H 06413017
         DC    C'CHANGE  '                                              06420000
         B     CHNGEANL                                                 06440000
         DC    C'NUMBER  '                                              06460000
         B     NUMBRANL                                                 06480000
         DC    C'DELETE  '                                              06500000
         B     DELETANL                                                 06520000
         DC    C'REPL    '                                              06540000
         B     REPLANAL                                                 06560000
         DC    C'REPRO   '                                              06580000
         B     REPROANL                                                 06600000
         DC    C'ALIAS   '                                              06620000
         B     ALIASANL                                                 06640000
COMDEND  DC    C'ENDUP   '             END OF COMMAND WORD TABLE        06660000
         B     ENDUPANL                                                 06680000
         EJECT                                                          06700000
*********************************************************************** 06720000
***        CONTROL STATEMENT KEYWORD/PARAMETER PROCESSING           *** 06740000
*********************************************************************** 06760000
         SPACE 1                                                        06780000
ADDANAL  BAL   GR5,ADDONLY             CHECK ADD/REPL SEQUENCE          06800000
         CLI   COMDCD,X'0F'            PREVIOUS COMMAND IN EFFECT       06820000
         BE    KEEPPEND                YES- KEEP COMMAND PENDING        06840000
         MVI   ADDSW,X'0F'             SET ADD SWITCH ON FIRST ADD      06860000
         B     SETNDRET                SET COMMAND SWITCH AND CONTINUE  06880000
         SPACE 1                                                        06900000
REPLANAL LA    GR5,RETREPL             RETURN FROM SEQUENCE CHECK       06920000
REPLADD  TM    CTONLYSW,X'11'     IS THERE AN OLD MASTER         A30480 06940020
         BM    INVALOP            NO.. CAN DO ADD ONLY           A30480 06960020
ADDONLY  CLI   REPLSW,X'0F'            TWO CONSECUTIVE REPL STATEMENTS  06980000
         BE    ABSEQERR                YES- STATEMENT SEQUENCE ERROR    07000000
         CLI   ADDSW,X'0F'             CONSECUTIVE REPL-ADD CARDS       07020000
         BE    ABSEQERR                YES- STATEMENT SEQUENCE ERROR    07040000
         CLI   CHNGESW,X'0F'           CONSECUTIVE COMD CARDS           07060000
         BE    ABSEQERR                YES- CONTROL SEQUENCE ERROR      07080000
         CLI   FINICCS,X'0F'      SYSIN THRU                     A24189 07081018
         BE    TSTSEQ             ENDUP BEING PROCESSED          A24189 07082018
         CLI   INPLCSW,X'0F'            UPDATE INPLACE JUST DONE PTM901 07086017
         BE    STOPNOW                 YES.. MSG AND QUIT        A33286 07094020
TSTSEQ   MVI   IGNORESW,X'00'     CLEAR IGNORE /* AT EACH COMD   A24189 07102018
         BAL   GR9,TESTSEQC            TEST IF MULTIPLE COMDS ALLOWED   07120000
         BR    GR5                     SEQUENCE IS OK                   07140000
RETREPL  CLI   COMDCD,X'0F'            PREVIOUS COMMAND IN EFFECT       07160000
         BNE   SETREPLS                NO- SET REPLACE SWITCH           07180000
KEEPPEND MVI   COMDCD2,X'0F'           SET COMMAND PENDING SWITCH       07200000
         MVI   DONOTRDC,X'0F'          DO NOT READ MORE CONTROL CARDS   07220000
         B     STOWIT                  RETURN TO PROCESSING CSECT       07240000
SETREPLS MVI   REPLSW,X'0F'            FLAG AS REPLACE FUNCTION         07260000
SETNDRET MVI   COMDCD,X'0E'            TEMPORARY SETTING OF COMMAND SW  07280000
         CLI   FLUSHSW,X'0F'           IS FLUSH ROUTINE PROCESSING      07300000
         BNE   TOSCAN                  NO- CONTINUE                     07320000
         MVI   RIDIT2SW,X'0E'          SET AS COMMAND DURING FLUSH      07340000
         B     TOSCAN                  RETURN TO SCAN                   07360000
CHNGEANL BAL   GR5,REPLADD             CHECK FOR CONSECUTIVE COMMANDS   07380000
         MVC   LASTCTRC(8),ZEROHEX      REINITIALIZE LAST SEQ. NO.19013 07390017
         CLI   COMDCD,X'0F'            PREVIOUS COMMAND IN EFFECT       07400000
         BE    KEEPPEND                YES- KEEP COMMAND PENDING        07420000
         MVI   CHNGESW,X'0F'           SET CHANGE SWITCH                07440000
         B     SETNDRET                SET COMMAND SWITCH AND CONTINUE  07460000
ALIASANL CLI   ALIASW,X'0F'            PREVIOUS ALIAS                   07480000
         MVI   DONOTRDC,X'00'          ALLOW NEXT STATEMENT TO BE READ  07500000
         BE    ALIAS2                  SET ALIAS PENDING SWITCH    MA0H 07520017
         CLI   PSSWNM,X'00'            IS NEW MASTER SEQUENTIAL         07540000
         BE    IGNOREPS                YES- ALIAS HAS NO MEANING        07560000
         CLI   INPLCSW,X'00'           IS IT UPDATE=INPLACE        UL0H 07562017
         BNE   IGNORALS                THEN PRINT IGNORE ALIAS MSG UL0H 07564017
         CLI   ENDONLY,X'0F'           ACCEPT ENDUP ONLY           4929 07566017
         BE    STOWIT1                 YES GO READ MORE SYSIN      4929 07572017
         MVI   ALIASW,X'0F'            SET ALIAS SWITCH                 07580000
         B     TOSCAN                  RETURN TO SCAN                   07600000
ALIASTNM CLI   ALIASW2,X'0F'      NAME ON FIRST ALIAS CARD?    @SA67452 07610021
         BE    MOREALIA           NO,BRANCH TO ADJUST POINTER  @SA67452 07620021
         LA    GR7,ALIASNM        ADDR OF ALIAS NAME SAVE      @SA67452 07630021
         ST    GR7,ALIASNM1       STORE INITIAL POINTER TO     @SA67452 07632021
         ST    GR7,ALIASNM2       USE WHEN SEVERAL ALIAS       @SA67452 07634021
         B     ISNAMEOK                CHECK NAME VALIDITY- STORE IT    07640000
MOREALIA L     GR7,ALIASNM1       PICK UP LAST ADDRESS         @SA67452 07641021
         LA    GR7,8(GR7)         AND ADD TO MOVE NEXT NAME    @SA67452 07642021
         ST    GR7,ALIASNM1       SAVE THIS POINTER            @SA67452 07643021
         LA    GR5,ALIASNM1       ADDRESS OF ALIAS SAVE END    @SA67452 07644021
         CR    GR7,GR5            MORE THAN 16 ALIAS?          @SA67452 07645021
         BE    INVALOP            YES,GO TO GIVE MSG           @SA67452 07646021
         B     ISNAMEOK           NO,GO TO CHECK NAME          @SA67452 07647021
ALIAS2   CLI   ALIASW2,X'0F'      ALREADY TWO ALIASES?         @SA67452 07648021
         BE    TOSCAN             YES,SCAN THE NEXT STATEMENT  @SA67452 07649021
         OI    ALIASW2,X'0F'      SET SW MORE THAN ONE ALIAS   @SA67452 07650021
         MVI   COMDCD2,X'0F'           TURN ON TO FORCE STOW       MA0H 07660017
         MVI   DONOTRDC,X'0F'          DO NOT READ SYSIN           MA0H 07670017
         B     STOWIT                  PROCESS ALIAS               MA0H 07680017
CARDGET  L     GR15,PRIMEWRT           ADDRESS OF MESSAGE ROUTINE       07700000
         BALR  GR14,GR15               GIVE MESSAGE                     07720000
READNOW  MVI   PRINTWRT,X'0F'          NEXT RECORD TO BE READ           07740000
         B     STOWIT                  RETURN TO PROCESSING CSECT       07760000
IGNOREPS LA    GR11,PSALIAS       ALIAS IGNORED MESSAGE CODE     A30501 07766019
         B     ALIASERR                                          A30501 07772019
IGNORALS LA    GR11,UPALIAS        ALIAS IGNORED MESSAGE CODE    A30501 07778019
ALIASERR MVI   PRINTED,X'00'       CLEAR PRINT SWITCH            A30501 07784019
         BAL   GR14,CARDPRNT       PRINT   INVALID STATEMENT     A30501 07790019
         L     GR15,PRIMEWRT       ADDRESS OF MESSAGE WRITER     A30501 07796019
         MVI   PRINTED,RESET0      CLEAR PRINT  SWITCH           A30501 07802019
         BALR  GR14,GR15           GIVE MESSAGE                  A30501 07808019
         MVI   PRINTWRT,X'0F'           SET SWITCH CARD PRINT    A41839 07810021
         B     STOWIT                                            A30501 07814019
         SPACE 1                                                        07820000
CHKNEW   BAL   GR9,PARATEST            GET NEXT CORRECT PARAMETER       07840000
         BAL   GR9,TESTCMD             TEST IF PARAMETER ON A COMD CARD 07860000
         LA    GR6,2                   MAXIMUM SIZE OF THIS PARAMETER   07880000
         L     GR11,DCBNM              ADDRESS OF NEW MASTER DCB        07900000
         CR    GR6,LENGTH              IS PARAMETER SIZE 2 BYTES        07920000
         BNE   SCANERR                 NO- ERROR                        07940000
         OI    PARMSW,X'20'            FLAG AS 'NEW' PARAMETER          07960000
         L     GR10,DCBOM              OLD MASTER DCB ADDRESS           07980000
         CLC   0(2,SCANADR),NEWPO      IS NEW MASTER TO BE PARTITIONED  08000000
         BE    PS2PONOW                NEW MASTER PO, OLD IS PS         08020000
         CLC   0(2,SCANADR),NEWPS      IS NEW MASTER TO BE SEQUENTIAL   08040000
         BNE   SCANERR                 NO- INVALID PARAMETER            08060000
         MVI   BDSORG(GR11),PSDSET     SET DCB ORGANIZATION AS PS  3628 08080015
         MVI   BDSORG(GR10),PODSET     SET OLD MASTER DCB AS PO    3628 08100015
         MVI   PSSWOM,X'0F'            FLAG OLD MASTER AS PO            08120000
         MVI   PSSWNM,X'00'            SET NEW MASTER SWITCH TO PS      08140000
         B     TOSCAN                  RETURN TO SCAN                   08160000
PS2PONOW MVI   BDSORG(GR11),PODSET     SET NEW MASTER AS PO        3628 08180015
         MVI   BDSORG(GR10),PSDSET     SET OLD MASTER AS PS        3628 08200015
         MVI   PSSWNM,X'0F'            FLAG NEW MASTER AS PO            08220000
         MVI   PSSWOM,X'00'            FLAG OLD MASTER AS PS       3628 08230015
         B     TOSCAN                  RETURN TO SCAN                   08240000
CHKLIST  BAL   GR9,PARATEST            GET NEXT PARAMETER               08260000
         BAL   GR9,TESTCMD             TEST IF PARAMETER ON A COMD CARD 08280000
         LA    GR6,3                                                    08300000
         CR    GR6,LENGTH              IS PARAMETER 3 BYTES (ALL)       08320000
         BNE   SCANERR                 NO- ERROR                        08340000
         CLC   0(3,SCANADR),LISTSET    IS LIST SETTING FOR ALL          08360000
         BNE   SCANERR                 NO- ERROR                        08380000
         MVI   FLLISTSW,X'01'          LIST EVERYTHING                  08400000
         B     TOSCAN                  RETURN TO SCAN                   08420000
         SPACE 1                                                        08440000
CHKINSRT CLI   INPLCSW,X'0F'      UPDATE=INPLACE REQUESTED       A33318 08460020
         BE    SCANERR            YES.. INVALID PARAMETER        A33318 08480020
         BAL   GR9,PARATEST            GET PARAMETER                    08500000
         LA    GR6,3                                                    08520000
         CR    GR6,LENGTH              IS PARAMETER 3 BYTES             08540000
         BNE   SCANERR                 NO- CONTROL STATEMENT ERROR      08560000
         CLC   0(3,SCANADR),YESYES     IS SETTING 'YES'                 08580000
         BNE   SCANERR                 NO- CONTROL STATEMENT ERROR      08600000
         CLI   INSERTSW,X'0E'          PREVIOUS INSERT                  08620000
         BNE   SETINSRT                NO- FLAG AS FIRST INSERT         08640000
         MVI   INSRTRD,X'01'           SET TO INDICATE ANOTHER INSERT   08660000
         B     TOSCAN                  RETURN TO SCAN                   08680000
SETINSRT MVI   INSERTSW,X'0F'          SET FIRST INSERT SWITCH SETTING  08700000
         B     TOSCAN                  RETURN TO SCAN                   08720000
         SPACE 1                                                        08740000
*              TEST PARAMETERS FOR SCAN ERRORS                          08760000
PARATEST L     GR15,RDCARD                                         UL0H 08770017
         BALR  GR14,GR15               SCAN FOR NEXT PARAMETER     UL0H 08780017
         TM    SWITCHRD,BIT80          SCAN ERROR SWITCH ON             08800000
         BC    1,SCANERR               YES- CONTROL STATEMENT ERROR     08820000
         TM    SWITCHRD,BIT02          IS THIS A PARAMETER              08840000
         BC    14,SCANERR              NO- CONTROL STATEMENT ERROR      08860000
         LM    LENGTH,SCANADR,STOREG   LOAD POINTERS TO LENGTH AND PARM 08880000
         BR    GR9                     RETURN                           08900000
CHKIDENT BAL   GR9,PARATEST            GET NEXT PARAMETER               08920000
         BAL   GR9,TESTCMD             TEST IF PARAMETER ON A COMD CARD 08940000
         LA    GR9,TESTSEQ             RETURN FROM COLUMN CHECK         08960000
         LA    GR6,3                   VALID PARAMETER LENGTH           08980000
         CR    GR6,LENGTH              IS PARAMETER THREE BYTES         09000000
         BNE   SCANERR                 NO- CONTROL STATEMENT ERROR      09020000
COLMCHKX CLC   0(2,SCANADR),COLUMN80   IS COLUMN GREATER THAN 80        09040000
         BH    SCANERR                 YES- CONTROL STATEMENT ERROR     09060000
         CLC   0(2,SCANADR),COLUMN01   IS COLUMN LESS THAN 1            09080000
         BL    SCANERR                 YES- CONTROL STATEMENT ERROR     09100000
         BR    GR9                     RETURN                           09120000
TESTSEQ  CLI   2(SCANADR),C'8'         IS SEQUENCE SIZE MORE THAN 8     09140000
         BH    SCANERR                 YES- CONTROL STATEMENT ERROR     09160000
         CLI   2(SCANADR),C'1'         IS SEQUENCE SIZE LESS THAN 1     09180000
         BL    SCANERR                 YES- CONTROL STATEMENT ERROR     09200000
         MVN   IDENTY+1(1),2(SCANADR)  MOVE SEQUENCE SIZE TO BUFFER     09220000
         LA    GR9,STORID              RETURN FROM ROUTINE              09240000
         LA    GR7,IDENTXX             START COLUMN SEQUENCE NUMBER     09260000
GETCOLMS MVC   TEMPWA(8),ZERO          CLEAR BUFFER                     09280000
         PACK  TEMPWA+6(2),0(2,SCANADR)   UNPACK COLUMN                 09300000
         CVB   GR5,TEMPWA              CONVERT TO BINARY                09320000
         BCTR  GR5,0                   DECREMENT FOR INDEXING           09340000
         STH   GR5,0(GR7)              STORE IN IDENTXX OR UPDATCOL     09360000
         LH    GR3,LRECL               PICK UP LOGICAL RECORD LENGTH    09380000
         LA    GR5,1(GR5)              RETURN TO ORIGINAL COLUMN        09400000
         CR    GR5,GR3                 COLUMN LESS THAN LRECL (IDENTXX) 09420000
         BH    SCANERR                 NO- FIELD WILL BE OUT OF LRECL   09440000
         BR    GR9                     RETURN TO STORID OR TOSCAN       09460000
STORID   SR    GR8,GR8                 PROCESS IDENT FIELD              09480000
         IC    GR8,IDENTY+1            SIZE OF SEQUENCE FIELD           09500000
         BCTR  GR8,0                   DECREMENT                        09520000
         SR    GR3,GR8                 MAXIMUM START OF SEQUENCE FIELD  09540000
         CR    GR5,GR3                 WILL SEQUENCE RUN OUT OF LRECL   09560000
         BH    SCANERR                 YES- ERROR                       09580000
         B     TOSCAN                  RETURN TO SCAN                   09600000
TESTCMD  TM    COMDCD,X'0E'            IS PARAMETER ON A COMMAND CARD   09620000
         BC    12,SCANERR              NO- CONTROL STATEMENT ERROR      09640000
         BR    GR9                     RETURN                           09660000
REPROANL BAL   GR5,REPLADD             CHECK FOR CONSECUTIVE COMMANDS   09680000
         CLI   COMDCD,X'0F'            A COMMAND IN EFFECT              09700000
         BE    KEEPPEND                YES- KEEP REPRO PENDING          09720000
         MVI   REPROSW,X'0F'           SIGNAL REPRO COMMAND             09740000
         B     SETNDRET                SET COMMAND SWITCH AND RETURN    09760000
CHKCOLMN BAL   GR9,PARATEST            GET THE PARAMETER                09780000
         BAL   GR9,TESTCMD             TEST IF PARAMETER ON A COMD CARD 09800000
         LA    GR6,2                   MAXIMUM SIZE OF PARAMETER        09820000
         CR    GR6,LENGTH              MAXIMUM OF 2 BYTES               09840000
         BE    CHECKOUT                YES- CHECK IF VALID COLUMNS      09860000
         BL    SCANERR                 GREATER THAN 2- STATEMENT ERROR  09880000
         MVC   COLM1BUF+1(1),0(SCANADR) MOVE TO BUFFER THE 1 CHARACTER  09900000
         LA    SCANADR,COLM1BUF        PUT ADDRESS OF 2 CHARACTER AREA  09920000
CHECKOUT BAL   GR9,COLMCHKX            CHECK IF COLUMN VALID            09940000
         MVI   COLUMNSW,X'0F'          SIGNAL SELECTIVE UPDATE          09960000
         LA    GR9,TOSCAN              LOAD RETURN ADDRESS              09980000
         LA    GR7,UPDATCOL            BUFFER FOR COLUMN UPDATE START   10000000
         B     GETCOLMS                CONVERT COLUMN AND CHECK         10020000
CHKNAME  BAL   GR9,PARATEST            GET PARAMETER                    10040000
         CLI   ALIASW,X'0F'            IS NAME FIELD IN ALIAS STATEMENT 10060000
         BE    ALIASTNM                YES- ENTER ALIAS ANALYSIS        10080000
         LA    GR7,MEMNAME             OLD MASTER MEMBER NAME BUFFER    10100000
         OI    PARMSW,X'10'            FLAG AS 'NAME' PARAMETER         10120000
         TM    PARMSW,X'20'            HAS 'NEW' PARAMETER COME IN      10140000
         BC    1,ESTNAME               YES- DCB AND SWITCHES SET BY NOW 10160000
         L     GR10,DCBOM              ADDRESS OF OLD MASTER DCB   3628 10180015
         L     GR11,DCBNM              ADDRESS OF NEW MASTER DCB   3628 10200015
         MVI   BDSORG(GR10),PODSET     FLAG DCB OM AS PARTITIONED  3628 10220015
         MVI   PSSWNM,X'0F'            FLAG NEW MASTER AS PODS          10240000
         MVI   PSSWOM,X'0F'            MUST ALSO FLAG OM FOR TESTS      10260000
         MVI   BDSORG(GR11),PODSET     FLAG DCB NM AS PARTITIONED  3628 10280015
ESTNAME  BAL   GR9,TESTCMD             TEST IF PARAMETER ON A COMD CARD 10300000
ISNAMEOK LA    GR5,BLANKS8             DOUBLE WORD OF BLANKS            10320000
         LA    GR9,TESTCHR             RETURN FROM SUBROUTINE           10340000
CLRSTOR  C     LENGTH,EIGHT            TEST IF NAME/SEQ MORE THAN 8     10360000
         BH    SCANERR                 CONTROL STATEMENT ERROR          10380000
         MVC   0(8,GR7),0(GR5)         CLEAR BUFFER TO BLANKS OR ZERO   10400000
         BR    GR9                     RETURN                           10420000
TESTCHR  LR    GR6,LENGTH              IF LENGTH REG IS 0 CANNOT EXEC   10440000
         BCTR  GR6,0                   DECREMENT FOR EXECUTE            10460000
         EX    GR6,MOVNAME             MOVE NAME LEFT ADJUST            10480000
         CLI   0(GR7),C'A'             FIRST CHARACTER ALPHABETIC       10500000
         BL    NATLETTR      CHAR NOT ALPHA,MAY BE NAT'L LETTER    3083 10520015
         CLI   0(GR7),C'Z'             FIRST CHARACTER ALPHABETIC       10540000
         BH    SCANERR                 CONTROL STATEMENT ERROR          10560000
VALCHAR  B     TOSCAN        VALID CHARACTER, KEEP SCANNING        3083 10564015
NATLETTR CLI   0(GR7),C'$'   IS CHARACTER A DOLLAR SIGN            3083 10568015
         BE    VALCHAR       YES, CHARACTER IS VALID               3083 10572015
         CLI   0(GR7),C'@'   IS CHARACTER AN "AT" SIGN             3083 10576015
         BE    VALCHAR       YES, CHARACTER IS VALID               3083 10580015
         CLI   0(GR7),C'#'   IS CHARACTER A POUND SIGN             3083 10584015
         BE    VALCHAR       YES, CHARACTER IS VALID               3083 10588015
         B     SCANERR       CHARACTER WAS NONE OF THESE, ERROR    3083 10592015
CHKSORCE BAL   GR9,TESTCMD             IS THIS KEY WORD ON COMD CARD    10600000
         BAL   GR9,PARATEST            GET THE PARAMETER                10620000
         LA    GR6,1                   SIZE OF SOURCE DATA              10640000
         CR    LENGTH,GR6              MORE THAN 1 BYTE CODE GIVEN      10660000
         BNE   SCANERR                 YES- CONTROL STATEMENT ERROR     10680000
         CLI   0(SCANADR),C'1'         TEST IF IBM MODIFICATION         10700000
         BE    STORCODE                YES- CODE IS OK                  10720000
         CLI   0(SCANADR),C'0'         TEST IF USER MODIFICATION        10740000
         BNE   SCANERR                 NO- INVALID SOURCE CODE          10760000
STORCODE MVC   SOURCECD(1),0(SCANADR)  STORE SOURCE CODE                10780000
         B     TOSCAN                  RETURN TO SCAN                   10800000
         SPACE 1                                                        11000000
CHKLEVEL BAL   GR9,TESTCMD             IS KEY WORD ON COMD CARD         11020000
         BAL   GR9,PARATEST            GET THE PARAMETER                11040000
         LA    GR6,2                   MAXIMUM LENGTH THIS PARAMETER    11060000
         CR    GR6,LENGTH              IS PARAMETER 2 BYTES (00 - 99)   11080000
         BNE   SCANERR                 NO- CONTROL STATEMENT ERROR      11100000
         BAL   GR9,TESTSCAN            TEST AND CONVERT TO HEX          11120000
         PACK  LEVELXX(2),RRSAVE(3)    STORE CHANGE LEVEL               11140000
         B     TOSCAN                  RETURN TO SCAN                   11160000
         SPACE 1                                                        11180000
CHKSSI   BAL   GR9,TESTCMD             IS KEY WORD ON COMD CARD         11200000
         BAL   GR9,PARATEST            GET PARAMETER                    11220000
         C     LENGTH,EIGHT            IS PARAMETER LENGTH 8            11240000
         BNE   SCANERR                 NO- CONTROL STATEMENT ERROR      11260000
         LA    GR9,PACKSSI             RETURN FROM TEST/CONVERT         11280000
TESTSCAN LA    GR3,RRSAVE              ADDRESS OF WORK AREA             11300000
         LR    GR8,LENGTH              LOAD COUNT OF REGISTER WITH SIZE 11320000
         EX    GR8,MOVESSIL            MOVE SSI OR LEVEL (ONE EXTRA OK) 11340000
SCANLOOP TM    0(GR3),C'0'             IS DIGIT NUMERIC                 11360000
         BO    UPPOINTR                YES- PASS TO NEXT CHARACTER      11380000
         CLI   0(GR3),C'A'             IS THIS A HEX CHARACTER (A-F)    11400000
         BL    SCANERR                 NO- ERROR                        11420000
         CLI   0(GR3),C'F'             IS THIS A HEX CHARACTER (A-F)    11440000
         BH    SCANERR                 NO- ERROR                        11460000
         OI    0(GR3),X'20'            CHANGE C ZONE TO E ZONE          11480000
UPPOINTR LA    GR3,1(GR3)              POINT TO NEXT CHARACTER          11500000
         BCT   GR8,SCANLOOP            CHECK ALL EIGHT CHARACTERS       11520000
         TR    RRSAVE(8),ALTTT-225     CONVERT TO HEX                   11540000
         BR    GR9                     RETURN                           11560000
PACKSSI  PACK  SSIBUF(5),RRSAVE(9)     PACK SSI INFORMATION             11580000
         MVI   SSISW,X'0F'             SET SWITCH SSI TO OVERIDE LEVEL- 11600000
         B     TOSCAN                  RETURN TO SCAN                   11620000
         SPACE 1                                                        11640000
UPDATANL TM    CHNGESW,X'0F'           IS PARAMETER ON A CHANGE CARD    11660000
         BC    14,SCANERR              NO- ERROR                        11680000
         CLI   FIRSENTR,BIT10          FIRST ENTRY                      11700000
         BNE   STOPNOW                 NO- CANNOT MIX INPLACE/REGULAR   11720000
         BAL   GR9,PARATEST            GET PARAMETER                    11740000
         LA    GR6,7                                                    11760000
         CR    GR6,LENGTH              TEST IF 7 CHARACTERS             11780000
         BNE   SCANERR                 ERROR IF NOT 7                   11800000
         CLC   0(7,SCANADR),INPLACE    COMPARE IF PARAMETER = 'INPLACE' 11820000
         BNE   SCANERR                 NO- CONTROL STATEMENT ERROR      11840000
         TM    CTONLYSW,X'11'     IS THERE AN OLD MASTER         A30480 11860020
         BM    INVALOP            NO.. CANNOT UPDATE INPL. NM    A30480 11880020
         MVI   INPLCSW,X'0F'           FLAG AS UPDATE IN PLACE- NO NM   11900000
         B     TOSCAN                  RETURN TO SCAN                   11920000
         SPACE 1                                                        11940000
DELETANL CLI   FLUSHSW,X'0F'           FLUSHING IN PROCESS              11960000
         BE    MSGNREAD                YES- GIVE SCAN MESSAGE           11980000
         MVI   KEYCHECK+3,X'10'   SET DISPL. FOR KEY START TAB   A33314 11990020
         CLI   INPLCSW,X'0F'           UPDATE TYPE RUN                  12000000
         BE    INVALOP                 INVALID OPERATION DELETE/UPDATE  12020000
         TM    CHNGESW,X'0E'           FOLLOWS A CHANGE COMMAND         12040000
         BC    12,ABSEQERR             NO- CONTROL SEQUENCE ERROR       12060000
         CLI   DELETSW,X'0F'           FOLLOWS A DELET CARD IMMEDIATELY 12080000
         BE    DELETPND                YES- KEEP THIS DELET PENDING     12100000
         MVI   DELETSW,X'0F'           FLAG AS DELETE STATEMENT         12120000
         MVI   CHNGESW,X'0E'           FLAG AS CHANGE PLUS ANOTHER COMD 12140000
         B     TOSCAN                  RETURN TO SCAN                   12160000
DELETPND MVI   DELET2SW,X'0F'          SET 2 CONSECUTIVE DELETS SWITCH  12180000
CHKIFOPN MVI   DONOTRDC,X'0F'          DO NOT READ MORE CONTROL CARDS   12200000
         CLI   OPENSW,X'0F'            HAS DATA SET BEEN OPENED         12220000
         BE    STOWIT                  NO- RETURN TO CSECT2- OPEN IT    12240000
         B     READNOW                 RETURN TO PROCESS                12260000
         SPACE 1                                                        12280000
NUMBRANL CLI   FLUSHSW,X'0F'           FLUSHING IN PROCESS              12300000
         BE    MSGNREAD                YES- GIVE SCAN MESSAGE           12320000
         MVI   KEYCHECK+3,X'08'   SET DISPL. FOR KEY START TAB   A33314 12330020
         TM    CHNGESW,X'0E'           IN SEQUENCE OF CHANGE COMMANDS   12340000
         BO    CHNGEOEX                YES- COMMAND WITH CHANGE         12360000
         TM    REPLSW,X'0E'            IN SEQUENCE OF REPL COMD         12380000
         BO    REPLOEX                 YES- FOLLOWS A REPLACE CARD      12400000
         TM    ADDSW,X'0E'             IN SEQUENCE OF ADD COMD          12420000
         BC    12,ABSEQERR             DOES NOT FOLLOW ADD-REPL-CHNGE   12440000
         CLI   NUMBRSW,X'0F'           PREVIOUS NUMBER STATEMENT   6701 12446017
         BE    INVALOP                 ONLY ONE NUMBER FOR ADD     6701 12452017
         MVI   ADDSW,X'0E'             RESET TO SHOW NUMBER AFTER ADD   12460000
         B     NUMBER01                NEW NUMBER STATEMENT        6701 12470017
NUMBRSWS CLI   NUMBRSW,X'0F'           PREVIOUS NUMBER STATEMENT        12480000
         BNE   NUMBER01                NO- THIS IS NEW ONE              12500000
         TM    INSERTSW,X'0F'                                    A25432 12507019
         BM    NUMBER01                                          A25432 12514019
         BZ    ONEINSRT                                          A25432 12521019
         CLI   FSTINSRT,X'0F'          CONSECUTIVE INSERT=YES ?  A25432 12528019
         MVI   FSTINSRT,X'00'          RESET FIRST DATA CARD SW  A25432 12535019
         BNE   ABSEQERR                YES, ERROR - DATA MUST    A25432 12542019
*                                      FOLLOW INSERT=YES         A25432 12549019
ONEINSRT CLI   RENUMALL,X'0F'                                    A25432 12559019
         BE    INVALOP                 YES- INVALID OPERATION           12580000
         MVI   NUMBR2SW,X'0F'          SET 2 CONSECUTIVE NUMBER SWITCH  12600000
         B     CHKIFOPN                SET UP TO CONTINUE PROCESSING    12620000
NUMBER01 MVI   NUMBRSW,X'0E'           FLAG AS NUMBER STATEMENT SCANNED 12640000
         B     TOSCAN                  RETURN TO SCAN                   12660000
CHNGEOEX MVI   CHNGESW,X'0E'           RESET TO SHOW NUMBER AFTER CHNGE 12680000
         B     NUMBRSWS                SET NUMBER SWITCH                12700000
REPLOEX  TM    NUMBRSW,X'0F'           PREVIOUS NUMBER STMT      A25924 12710019
         BC    5,INVALOP               ONLY ONE NUMBER FOR REPL  A25924 12720019
         MVI   REPLSW,X'0E'     RESET TO SHOW NUMBER AFTER REPL  A25924 12730019
         B     NUMBRSWS                SET NUMBER SWITCH                12740000
MSGNREAD MVI   RIDIT2SW,X'0F'          SET TO SCAN BEYOND DETAIL CARD   12760000
         B     STOWIT                  BACK TO PROCESSING CSECT         12800000
         SPACE 1                                                        12820000
TESTSEQC CLI   FINICCS,X'0F'           HERE FROM ENDUP ANALYSIS         12840000
         BCR   8,GR9                   YES- RETURN TO ENDUP ANALYSIS    12860000
         CLI   PSSWOM,X'00'            TEST IF OM PHYSICAL SEQUENTIAL   12880000
         BNE   ONENOTPS                OLD MASTER NOT PHYSICAL SEQUENT. 12900000
         CLI   PSSWNM,X'00'            TEST IF NM PHYSICAL SEQUENTIAL   12920000
         BCR   7,GR9                   NO- RETURN                       12940000
CHKFIRST CLI   COMDCD,X'0F'            PREVIOUS COMD CARD ENCOUNTERED   12960000
         BCR   7,GR9                   NO- OK THIS IS FIRST COMD CARD   12980000
QUITNOW  LA    GR11,ERRMSGC            CODE FOR TERMINATE MESSAGE       13000000
         B     ALLENDS                 GIVE MESSAGE                     13020000
STOPNOW  LA    GR11,UPDATMSG           CODE FOR INVALID INPLACE MESSAGE 13040000
ALLENDS  BAL   GR14,CARDPRNT           PRINT INVALID CARD        A33286 13050020
         L     GR15,PRIMEWRT           MESSAGE CSECT ADDR        A33286 13060020
         MVI   TEMPCON,12              SET TEMPORARY CONDITION CODE     13080000
         LA    GR14,QUITS              RETURN FROM MSG ROUT      A33286 13100020
         BR    GR15                    GIVE MESSAGE- TERMINATE          13120000
ONENOTPS CLI   PSSWNM,X'00'            TEST IF NM PHYSICAL SEQUENTIAL   13140000
         BCR   7,GR9                   NO- RETURN                       13160000
         B     CHKFIRST                SEE IF FIRST ENTRY- 1 SEQUENTIAL 13180000
         SPACE 1                                                        13200000
CHKSEQ1  TM    ADDSW,X'0E'             PROCESSING ADD FUNC        20497 13206017
         BC    1,INVALOP               IF SO INVALID OPERATION    20497 13212017
         TM    REPLSW,X'0E'            PROCESSING REPL FUNCTION   20497 13218017
         BC    1,INVALOP               IF SO INVALID OPERATION    20497 13224017
         CLI   NUMBRSW,X'0E'           SEQUENCE ON NUMBER CARD     5666 13230017
         LA    GR8,TOSCAN              RETURN                           13240000
         LA    GR7,DELTSEQ1            ADDRESS OF DELETE BUFFER SEQ1    13260000
         BE    NUMBR              YES,BRANCH TO SET NUMBER SEQ1 SA61411 13270021
         CLI   NUMBR2SW,X'0F'     SEQ1 ON SECOND NUMBER CARD?   SA61411 13272021
         BNE   TESTPARM           NO, ON DELETE- BRANCH            5666 13280016
NUMBR    LA    GR7,NUMRSEQ1       ADDRESS OF NUMBER SEQ1 BUFFER SA61411 13290021
         OI    PARMSW,X'01'            FLAG AS 'SEQ1' PARAMETER         13320000
         CLI   NUMBR2SW,X'0F'     FIELD ON SECOND NUMBER CARD?  SA61411 13330021
         BE    TESTPARM           YES,GO TO TEST PARAMETER      SA61411 13332021
TESTUNIT TM    NUMBRSW,X'0E'           FIELD ON NUMBER CARD             13340000
         BC    14,SCANERR              NO- INVALID ON ANY OTHER         13360000
TESTPARM BAL   GR9,PARATEST            GET PARAMETER                    13380000
         CLC   0(3,SCANADR),LISTSET    SEE IF SETTING IS 'ALL'          13400000
         BE    ALLNUMBR                YES- RENUMBER ENTIRE DATA SET    13420000
         LA    GR5,ZEROHEX             DOUBLE WORD OF HEX ZEROS         13440000
         BAL   GR9,CLRSTOR             CLEAR BUFFER AND RIGHT ADJUST    13460000
         LR    GR6,LENGTH              LENGTH OF PARAMETER              13480000
         LA    GR7,8(GR7)              ALIGN TO END OF BUFFER           13500000
         SR    GR7,GR6                 BACK UP FROM RIGHT               13520000
         BCTR  GR6,0                   DECREMENT FOR EXECUTE            13540000
         EX    GR6,MOVNAME             RIGHT ADJUST SEQUENCE NUMBER     13560000
         LA    GR6,1(GR6)              RESET REG 6 TO ORG. VALUE A54134 13580021
CHKNMRIC EQU   *                       LOOP FOR NUMER. TESTING   A54134 13590021
         CLI   0(GR7),C'0'             TEST IF NUMERIC CHARACTER        13600000
         BL    SCANERR                 NO- CONTROL STATEMENT ERROR      13620000
         CLI   0(GR7),C'9'             TEST IF VALID NUMBER             13640000
         BH    SCANERR                 NO- CONTROL STATEMENT ERROR      13660000
         LA    GR7,1(GR7)              SKIP TO NEXT CHARACTER    A54134 13665021
         BCT   GR6,CHKNMRIC            SCAN NEXT CHAR. IF NECC.  A54134 13670021
         BCTR  GR7,0                   ADJUST TO UNITS POSITION  A54134 13675021
         BR    GR8                     RETURN TOSCAN OR TESTNUMB        13680000
ALLNUMBR TM    NUMBRSW,X'0E'           SEQ1=ALL ON NUMBER STATEMENT     13700000
         BC    14,SCANERR              NO- INVALID CONTROL STATEMENT    13720000
         MVI   RENUMALL,X'0F'          SET RENUMBER ALL SWITCH          13740000
         B     TOSCAN                  RETURN TO SCAN                   13760000
         SPACE 1                                                        13780000
CHKSEQ2  LA    GR7,DELTSEQ2            ADDRESS OF DELETE SEQ2 BUFFER    13800000
         TM    ADDSW,X'0E'             PROCESSING ADD FUNC        20497 13804017
         BC    1,INVALOP               IF SO INVALID OPERATION    20497 13808017
         TM    REPLSW,X'0E'            PROCESSING REPL FUNCTION   20497 13812017
         BC    1,INVALOP               IF SO INVALID OPERATION    20497 13816017
         CLI   NUMBRSW,X'0E'      SEQUENCE ON NUMBER CARD          5666 13820016
         LA    GR8,TOSCAN              RETURN                           13840000
         BNE   TESTPARM           NO, DELETE CAED - BRANCH         5666 13860016
         LA    GR7,NUMRSEQ2            ADDRESS OF NUMBER SEQ2 BUFFER    13880000
         OI    PARMSW,X'02'            FLAG AS 'SEQ2' PARAMETER         13900000
         B     TESTUNIT                GET PARAMETER AND TEST IT        13920000
         SPACE 1                                                        13940000
CHKINCR  LA    GR7,INCRNUMB            ADDRESS OF INCREMENT BUFFER      13960000
         CLI   INSERTSW,X'0E'          PREVIOUS INSERT IN EFFECT        13980000
         BE    SAVEPARM                YES- SAVE THE PARAMETER          14000000
         LA    GR11,INCREMWA           INCREMENT FACTOR IN BINARY       14020000
FLAGINCR OI    PARMSW,X'04'            FLAG AS 'INCR' PARAMETER         14040000
TESTNUMB LR    GR10,GR7                ADDRESS OF BUFFER                14060000
         BAL   GR8,TESTUNIT            ADJUST AND TEST NUMBER           14080000
         PACK  TEMPWA(8),0(8,GR10)     PACK INCREMENT OR INITIAL NUMBER 14100000
         CVB   GR6,TEMPWA              CONVERT TO BINARY                14120000
         ST    GR6,0(GR11)             SEQUENCE OR INCREMENT IN BINARY  14140000
         B     TOSCAN                  RETURN TO SCAN                   14160000
SAVEPARM LA    GR11,TEMPINCR           TEMPORARY INCREMENT AREA         14180000
         B     FLAGINCR                CONTINUE- STORE NEW INCREMENT    14200000
         SPACE 1                                                        14220000
CHKNEW1  LA    GR7,NEW1NUMB            ADDRESS OF NEW1 SEQUENCE NUMBER  14240000
         LA    GR11,SEQWA              STARTING SEQUENCE NUMBER BINARY  14260000
         CLI   INSERTSW,X'0E'          PREVIOUS INSERT IN EFFECT        14280000
         BNE   FLAGNEW1                NO- CONTINUE                     14300000
         LA    GR11,TEMPSEQA           TEMPORARY SEQUENCE AREA          14320000
FLAGNEW1 OI    PARMSW,X'08'            FLAG AS 'NEW1' PARAMETER         14340000
         B     TESTNUMB                TEST IF KEY WORD- PARAMETER OK   14360000
         SPACE 1                                                        14380000
CHKMEMBR LA    GR7,MEMBNEW             NEW MEMBER NAME, NEW PODS MADE   14400000
         BAL   GR9,PARATEST            GET PARAMETER                    14420000
         CLI   CTONLYSW,X'01'          PARM=NEW SPECIFIED        A38748 14430000
         BE    SCANERR                 YES,INVALID USE OF CONTROLA38748 14432000
         MVI   NEWNAME,X'0F'           FLAG NM IS PO                    14440000
         L     GR11,DCBNM              ADDRESS OF NEW MASTER DCB        14460000
         OI    PARMSW,X'40'            FLAG AS 'MEMBER' PARAMETER       14480000
         B     ESTNAME                 CHECK VALIDITY OF NAME- STORE IT 14500000
CHKTOTAL CLI   TOTALSW,X'00'            FIRST TOTAL PARM           UL0H 14500317
         BNE   INVALOP                  IF NOT,ERROR               UL0H 14500617
         MVI   TOTALSW,X'F0'            BEGIN TOTAL ANALYSIS       UL0H 14500917
         BAL   GR9,PARATEST             TEST FOR PARAMETER         UL0H 14501217
         BAL   GR9,TESTCMD              TEST FOR COMMAND           UL0H 14501517
         CLI   TOTALSW,X'FC'            HAS NAME BEEN ANALYSED     UL0H 14501817
         BNE   SCANERR                  IF NOT,ERROR               UL0H 14502117
         C     LENGTH,ZERO              LENCH GREATER THEN ZERO    UL0H 14502417
         BNH   INVALCHR                 IF NOT,ERROR               UL0H 14502717
         LA    GR5,BLANKS8                                         UL0H 14503017
         LA    GR7,TOTALRTN             USER ROUTINE NAME          UL0H 14503317
         BAL   GR9,CLRSTOR              CLEAR OUT BUFFER           UL0H 14503617
         LR    GR6,LENGTH               PICK UP LENGTH             UL0H 14503917
         BCTR  GR6,0                    DECREMENT                  UL0H 14504217
         EX    GR6,MOVNAME              AND MOVE IT TO SAVE AREA   UL0H 14504517
         BAL   GR14,TESTCHAR           DOES RTN NAME START WITH ALPUL0H 14504817
LOADTOTL LOAD  EPLOC=TOTALRTN                                      UL0H 14505117
         ST    0,TOTALADR                                          UL0H 14505417
         MVI   DELIMIN,X'80'           SET SECOND PARM SWITCH      UL0H 14505717
         BAL   GR9,PARATEST             GET CORE SIZE              UL0H 14506017
         CLI   TOTALSW,X'FE'            PROPER SYNTAX              UL0H 14506317
         BNE   SCANERR                  IF NOT,ERROR               UL0H 14506617
         LR    GR6,LENGTH               GET  LENGTH                UL0H 14506917
         C     GR6,ZERO                 IS IT GREATER THAN ZERO    UL0H 14507217
         BNH   NOCORE                   IF NOT,ERROR               UL0H 14507517
         C     GR6,FIVE                 IS IT LONGER THEN FIVE     UL0H 14507817
         BH    NOCORE                   IF SO,ERROR                UL0H 14508117
 SPACE  1                                                               14508417
*     THIS ROUTINE WILL DETERMINE IF LENGTH IS A VALID DECIMAL NO. UL0H 14508717
         LA    GR6,0(SCANADR,GR6)                                  UL0H 14509017
         BCTR  GR6,0                   POINT TO LAST DIGIT         UL0H 14509317
         LR    GR9,LENGTH                                          UL0H 14509617
COMPNO   CLI   0(GR6),C'0'             US NO. LESS THEN 'F0'       UL0H 14509917
         BL    NOCORE             YES.. PRINT ERROR MESSAGE      A36128 14510221
         CLI   0(GR6),C'9'             IS CHARACTER GREATER THEN F9UL0H 14510517
         BH    NOCORE             YES.. PRINT ERROR MESSAGE      A36128 14510821
         BCTR  GR6,0                   DECREMENT POINTER BY ONE    UL0H 14511117
         BCT   LENGTH,COMPNO           DECREMENT COUNTER BY ONE    UL0H 14511417
         BCTR  GR9,0                    DECREMENT                  UL0H 14511717
         LA    GR9,112(0,GR9)     GET LENGTH FIRST OPERAND       A36128 14512021
         EX    GR9,PACKSIZE       PREPARE REQUESTED SIZE         A36128 14512121
         CVB   GR5,TEMPTOT                                       A36128 14512221
         C     GR5,MAXCORE        REQUESTED MORE THAN 32K        A36128 14512321
         BNL   NOCORE             YES.. ERROR PRINT MESSAGE      A36128 14512421
         ST    GR5,TOTALSIZ       SAVE REQUESTED SIZE            A36128 14512521
         MVC   TOTLPARM+4(4),DCBNM      MOVE IN DCB ADDRESS        UL0H 14513817
         LR    GR0,GR5                  PREPARE FOR GETMAIN        UL0H 14514117
         GETMAIN R,LV=(0)                                          UL0H 14514417
         ST    GR1,TOTLPARM+12          SAVE ADDRESS IN PARMLIST   000I 14514718
         STH   GR5,0(GR1)              SAVE AREA ADDRESS IN AREA   UL0H 14515017
         MVI   TOTALSW,X'FF'                                       UL0H 14515317
      L        GR5,DCBNM               LOAD ADDRESS OF NEW MAST DCBUL0H 14515617
         ST    GR5,TOTLPARM+4           SAVE DCB ADDR IN PARM LIST 000I 14515718
      L        GR5,EXLIST(GR5)         LOAD ADDRESS OF NM XIT LIST UL0H 14515917
         ST    GR1,8(GR5)              STORE CORE ADDRESS IN XIT LSUL0H 14516217
         MVI   8(GR5),X'0A'            FLAG EXIT AS ACTIVE         UL0H 14516517
         SR    GR5,GR5                  ZERO OUT I/O               000I 14517518
         ST    GR5,TOTLPARM+8           ERROR PARAMETER            000I 14518518
         B     TOSCAN                  ANALIZE NEXT PARAMETER      UL0H 14519517
NOCORE   LA    GR11,BDCORESZ           CORE SIZE ERROR MSG CON     UL0H 14522517
         B     TONEXT                  PRINT  CARD AND MESSAGE          14523518
ERMSGSTP L     GR15,PRIMEWRT           ADDRESS OF MESSAGE ROUTINE  UL0H 14525517
         MVI   QUITALL,X'0F'           SET END OF PROCESS SWITCH   UL0H 14528517
         BR    GR15                    PRINT ERROR MSG AND QUIT    UL0H 14531517
TEST4OM  TM    CTONLYSW,X'11'     ALL INPUT FROM SYSIN           A30480 14541520
         BM    SCANERR            YES.. AN ERROR                 A30480 14551520
TEST4NM  BAL   GR9,TESTCMD             TEST IF PARAMETER ON COMD CARD   14580000
         BAL   GR9,PARATEST            GET PARAMETER                    14600000
         LR    GR5,SCANADR             START OF NAME                    14620000
         TM    0(GR5),ALPHA            TEST IF FIRST CHARACTER A LETTER 14640000
         BO    TSLTGTNO                YES- CHECK SOME MORE             14660000
INVALCHR LA    GR11,PLUS8MSG           CODE FOR ERROR MESSAGE           14680000
         B     TONEXT                  PRINT CARD AND MESSAGE      UL0H 14730017
TSLTGTNO BAL   GR14,TESTCHAR           TEST FIRST CHAR FOR ALPHA   UL0H 14790017
         LR    GR10,SCANADR            POINTER TO NAME                  14840000
         LR    GR9,LENGTH              PUT LENGTH INTO CORRECT REGISTER 14860000
         BR    GR8                     ENTER HANDLER  HEADER/TRAILER    14880000
CHKINHDR BAL   GR8,TEST4OM             IS THERE AN OLD MASTER      UL0H 14890017
         LA    GR3,OMHDR               ADDRESS OF RTN NAME/ADDRESS UL0H 14900017
         MVI   OMHDRSW,X'0F'           FLAG USER RTN FOR OLD MASTERUL0H 14910017
         B     MOVEARND                PREPARE TO LOAD ROUTINE     UL0H 14920017
CHKINTRL BAL   GR8,TEST4OM             IS THERE AN OLD MASTER      UL0H 14930017
         LA    GR3,OMTRLR              ADDRESS OF RTN NAME/ADDRESS UL0H 14940017
         MVI   OMTRLRSW,X'0F'          FLAG USER RTN FOR OLD MASTERUL0H 14950017
         B     MOVEARND                PREPARE TO LOAD ROUTINE     UL0H 14960017
CHKOUTHD BAL   GR8,TEST4NM             IS THERE AN NEW MASTER      UL0H 14970017
         LA    GR3,NMHDR               ADDRESS OF RTN NAME/ADDRESS UL0H 14980017
         MVI   NMHDRSW,X'0F'           FLAG USER RTN FOR NEW MASTERUL0H 14990017
         B     MOVEARND                PREPARE TO LOAD ROUTINE     UL0H 15000017
CKOUTTLR BAL   GR8,TEST4NM             IS THERE AN NEW MASTER      UL0H 15010017
         LA    GR3,NMTRLR              ADDRESS OF RTN NAME/ADDRESS UL0H 15020017
         MVI   NMTRLRSW,X'0F'          FLAG USER RTN FOR NEW MASTERUL0H 15030017
         B     MOVEARND                PREPARE TO LOAD ROUTINE     UL0H 15040017
MOVEARND C     GR9,EIGHT               TEST IF LABEL EXCEEDS 8 BYTES    15160000
         BH    INVALCHR                YES- ERROR                       15180000
         MVC   0(8,GR3),BLANKS8        CLEAR BUFFER                     15200000
         BCTR  GR9,0                   DECREMENT FOR EXECUTE            15220000
         EX    GR9,MVINHDEX            MOVE ROUTINE TO PROPER BUFFRUL0H 15230017
         LOAD  EPLOC=(GR3)             LOAD ROUTINE INTO CORE      UL0H 15240017
         ST    GR0,8(GR3)              STORE ADDRESS BEHIND NAME   UL0H 15250017
         B    TOSCAN                   BEGIN ANALIZING NEXT PARM   UL0H 15260017
  SPACE  2                                                              15270017
*  THIS ROUTINE WILL INTERROGATE FIRST CHARACTER OF NAME FOR VALIDIUL0H 15280017
  SPACE 1                                                               15290017
TESTCHAR CLI   0(SCANADR),C'#'         IS IT A NATIONAL CHARACTER  UL0H 15300017
         BCR   8,GR14                   IF SO,IT IS VALID,RETURN   000I 15310018
         CLI   0(SCANADR),C'@'         IS IT A NATIONAL CHARACTER  UL0H 15320017
         BCR   8,GR14                   IF SO,IT IS VALID,RETURN   000I 15330018
         CLI   0(SCANADR),C'$'         IS IT A NATIONAL CHARACTER  UL0H 15340017
         BCR   8,GR14                   IF SO,IT IS VALID,RETUR-   000I 15350018
         CLI   0(SCANADR),C'A'          ITS CHARACTER LESS THEN 'A'000I 15360018
         BL    INVALCHR                 IF SO,INVALID              000I 15370018
         CLI   0(SCANADR),C'I'          ITS CHARACTER LESS THEN I  000I 15380018
         BCR   12,GR14                  IF SI,ITIS VALID           000I 15390018
         CLI   0(SCANADR),C'J'          IS CHARACTER LESS THEN 'J' 000I 15400018
         BL    INVALCHR                 IF SO INVALID              000I 15410018
         CLI   0(SCANADR),C'R'          IS CHARACTER LESS THAN 'R' 000I 15420018
         BCR   12,GR14                  IF SO IT IS VALID          000I 15430018
         CLI   0(SCANADR),C'S'          IS CHARACTER LESS THEN 'S' 000I 15440018
         BL    INVALCHR                 IF SO,INVALID              000I 15450018
         CLI   0(SCANADR),C'Z'          IS CHARACTER GREATER THEN Z000I 15460018
         BH    INVALCHR                 IF SO INVALID                   15470018
         BR    GR14                    RETURN TO CALLER            UL0H 15480017
         SPACE 1                                                        15680000
SEQERR   LA    GR11,NUMMSG        INVALID NUMBER RANGE          SA61411 15682021
         B     TONEXT             GIVE MESSAGE,FLUSH            SA61411 15684021
SCANERR  LA    GR11,SCANMSG            CONTROL STATEMENT ERROR     UL0H 15690017
         B     TONEXT                  GIVE MESSAGE, FLUSH         UL0H 15700017
ABSEQERR LA    GR11,SEQMSG             SEQUENCE ERROR MESSAGE CODE UL0H 15710017
         B     TONEXT                  GIVE MESSAGE, FLUSH         UL0H 15720017
INVALOP  LA    GR11,ERROP              INVALID OPERATION MESSAGE COUL0H 15730017
TONEXT   CLI   PRINTED,X'0F'           HAS CARD ALREADY BEEN PRINTEUL0H 15740017
         BE    SKIPPRNT                YES- DO NOT PRINT IT AGAIN  UL0H 15750017
         BAL   GR14,CARDPRNT           PRINT INVALID STATEMENT     UL0H 15760017
SKIPPRNT L     GR15,PRIMEWRT           ADDRESS OF MESSAGE WRITER   UL0H 15770017
         MVI   PRINTED,RESET0          CLEAR PRINT SWITCH          UL0H 15780017
         BALR  GR14,GR15               GIVE MESSAGE                UL0H 15790017
         MVI   FLUSHSW,X'0F'           SET FLUSH SWITCH            UL0H 15800017
         MVI   RIDIT2SW,RESET0         NEXT COMMAND IN ERROR TOO   UL0H 15810017
         MVI   TEMPCON,X'04'           SET RETURN CODE           A45121 15812021
STOWIT   L     GR15,PROCESS            ADDRESS OF CSECT WITH FLUSH UL0H 15820017
         BR    GR15                    ENTER CSECT                 UL0H 15830017
STOWIT1  MVI   COMDCD,X'00'            RESET COMMAND SWITCH        4929 15983017
         B     STOWIT                                              4929 15986017
STOWIT2  LA    GR11,ERRMSGC            CANNOT PROCESS MORE THAN ONE4929 15989017
STOWIT3  MVI   COMDCD,X'00'            RESET COMMAND SWITCH        4929 15992017
         B     SKIPPRNT                GO PRINT ERROR MESSAGE      4329 15995017
LABELANL TM    PARAMSW,X'20'           DOES PARAMETER FOLLOW     A45205 15995122
         BNO   NORMLAB                 NO,NORMAL PROCESSING      A45205 15996222
         MVI   LABEL2SW,X'FF'          SET SWITCH ,NO LABEL PROC A45205 15998222
         B     TOSCAN                  CONTINUE SCANNING KEYW    A45205 15998622
NORMLAB  BAL   GR14,CARDPRNT            PRINT RECORD             A45205 15998722
         CLI   LABELSW,X'00'            IS IT HEADER PROCESSING    UL0H 15999822
         BE    HEADERIN                 IF SO,GET CORE             UL0H 16000922
         CLI   LABELSW,X'10'            IS IT TRAILER PROCESSING   UL0H 16002022
         BNE   INVALOP                  IF NOT,ERROR               UL0H 16003122
         MVI   LABELCNT,X'00'           INIT NO. OF LABELS         UL0H 16004222
         MVI   LABELSW,X'20'            TRAILER LABELS             UL0H 16005322
READLABL CLI   LABELSW,X'20'           PROCESSING TRAILER LABELS   UL0H 16006422
         BE    READTRLR                IF SO,GET PROPER SAVE AREA  UL0H 16007522
         LA    GR6,OMLABELS            ADDRESS OF O M LABEL SAVE ARUL0H 16008622
         B     READLBLS                PREPARE TO READ LABELS      UL0H 16009722
READTRLR L     GR6,LABELBUF            ADDRESS OF GETMAIN AREA     UL0H 16010822
READLBLS SR    GR7,GR7                 INIT LABEL COUNT FIELD      UL0H 16011922
         MVI   LABEL2SW,X'0F'           LABELS TO BE PROCESSED     UL0H 16013022
         B     STOWIT                   PREPARE TO ENTER IEBUPDT2  UL0H 16014122
HEADERIN CLI   FRSTCOMD,X'FF'          HAS A COMMAND BEEN SEEVICED UL0H 16015222
         BNE   HEADLABL                 IF NOT,MUST BE HEADERS     UL0H 16016322
         MVI   FRSTCOMD,X'00'           RESET DCB'S OPENED         UL0H 16017422
         MVI   LABELSW,X'10'            HEADERS TO CREATE          UL0H 16018522
HEADLABL IC    GR15,LABELSW             PICK UP NO OF LABELS       UL0H 16019622
         LA    GR15,16(GR15)            ADD TEN TO                 UL0H 16020722
         STC   GR15,LABELSW             LABEL SWITCH               UL0H 16021822
         GETMAIN    R,LV=720            GET 8 LABEL BUFFER         UL0H 16022922
         ST    GR1,LABELBUF             SAVE ITS ADDRESS           UL0H 16024022
         B     READLABL                 PREPARE TO READ LABELS     UL0H 16025122
CHEKCOMD CLC   0(6,SCANADR),COMDEND     IS COMMAND 'ENDUP'         UL0H 16026222
         MVI   LABEL2SW,X'00'          RESET LABEL PROCESS SWITCH  UL0H 16027322
         BE    SCANNED                  IF SO,CONTINUE             UL0H 16028422
         B     ABSEQERR                 ELSE,ERROR                 UL0H 16029522
CHKDATA  BAL   GR9,PARATEST            TEST PARAMETER            A45205 16029922
         CLI   LABEL2SW,X'FF'          COMMAND WAS LABEL         A45205 16030422
         BNE   SCANERR                 NO,ERROR                  A45205 16030522
         LA    GR6,2                   LENGTH OF PARAMETER MUST  A45205 16039522
         CR    GR6,LENGTH              BE TWO                    A45205 16041522
         BNE   SCANERR                 IF NOT,ERROR              A45205 16043522
         CLC   0(2,SCANADR),NO         IS PARAMETER NO           A45205 16043922
         BNE   SCANERR                 IF NOT,ERROR              A45205 16044322
         L     GR6,DCBOM               LOAD DCB OLD MASTER       A45205 16044422
         L     GR6,36(GR6)             LOAD DCBEXIT ADDRESS      A45205 16044522
         MVI   0(GR6),X'00'            INACTIVATE INHDR EXIT     A45205 16044722
         MVI   4(GR6),X'00'            INACTIVATE INTRL EXIT     A45205 16044822
         L     GR6,DCBNM               LOAD DCB NEW MASTER       A45205 16048322
         L     GR6,36(GR6)             LOAD DCBEXIT ADDRESS      A45205 16050322
         MVI   0(GR6),X'00'            INACTIVATE OUTHDR EXIT    A45205 16055522
         MVI   4(GR6),X'00'            INACTIVATE OUTTRL EXIT    A45205 16059022
         BAL   GR14,CARDPRNT           PRINT CARD                A45205 16062522
         B     STOWIT                  RETURN                    A45205 16066022
ENDUPANL CLI   FLUSHSW,X'0F'           EOF DURING FLUSH            4929 16069522
         MVI   EODCTSW,X'0F'      SET EOF SWITCH OF SYSIN        A31449 16073022
         BE    STOWIT             YES.. FINISH PROCESSING        A31449 16076522
         BAL   GR14,CARDPRNT           PRINT ENDUP DETAIL STATEMEMT4929 16080022
         MVI   PRINTED,X'0F'           FLAG AS CARD ALREADY PRINTED4929 16086400
         CLI   CHNGESW,X'0F'      CHANGE COMMAND?              @SA67456 16088421
         BNE   BYPASS             NO,BRANCH TO TEST OTHER COMD @SA67456 16090421
         B     INVALOP            BRANCH TO GIVE ERROR MSG     @SA67456 16092421
BYPASS   BAL   GR9,TESTCMD        MUST HAVE A COMD CARD        @SA67456 16093221
         MVI   FINICCS,X'0F'           FLAG AS SYSIN THRU               16100000
         CLI   REPLSW,X'0F'       REPL COMMAND?                @SA66054 16110021
         BE    NORECIN            YES,BRANCH TO GIVE ERROR MSG @SA66054 16112021
         CLI   ADDSW,X'0F'        ADD COMMAND?                 @SA66054 16114021
         BE    NORECIN            YES,BRANCH TO GIVE ERROR MSG @SA66054 16116021
         B     STOWIT                  ENTER PROCESSING ROUTINE         16140000
NORECIN  LA    GR7,SYSINNM        ADDR OF SYSIN DD NAME        @SA66054 16150021
         LA    GR11,ERRMSGN       SYSIN HAS NO RECORDS MSG     @SA66054 16152021
         B     TONEXT             ENTER PROCESSING ROUTINE     @SA66054 16154021
QUITS    MVI   PRINTED,X'0F'           FLAG AS ENDUP PRINTED            16160000
LASTLEG  LA    GR11,EOJMESSG           ADDRESS OF EOJ MESSAGE           16180000
         CLC   TEMPCON(1),HICONCDE+1   RETURN CODE LESS                 16200000
         BNH   RSAME                   EQUAL OR LESS USE HICONCDE       16220000
         MVC   HICONCDE+1(1),TEMPCON   SWAP FOR HIGHER CODE             16240000
RSAME    MVI   QUITALL,X'0E'           FORCE EOJ AND EOJ MESSAGE        16260000
         B     TONEXT                  END JOB                          16280000
         EJECT                                                          16300000
         SPACE 1                                                        16380000
LENGTH   EQU   0                       LENGTH OF PARAM REGISTER 0       16400000
SCANADR  EQU   1                       ADDRESS OF PARAMETER REGISTER 1  16420000
BIT80    EQU   X'80'                   ERROR SWITCH                     16440000
BIT40    EQU   X'40'                   BYPASS SWITCH                    16460000
BIT20    EQU   X'20'                   EOF, PARAMETER FOLLOWS SWITCH    16480000
BIT10    EQU   X'10'                   FIRST ENTRY, PARTIAL PARAMETER   16500000
BIT08    EQU   X'08'                   COMMAND, COLUMN 72 NON-BLANK SW  16520000
BIT04    EQU   X'04'                   KEYWORD, COLUMN 72 NON-BLANK SW  16540000
BIT02    EQU   X'02'                   PARAMETER SWITCH                 16560000
BIT01    EQU   X'01'                   LENGTH EQUALS ZERO SWITCH        16580000
RESET0   EQU   X'00'                   RESET BITS                       16600000
MOVESSIL MVC   0(1,GR3),0(SCANADR)     MOVE SSI DATA OR LEVEL TO RRSAVE 21360000
SAVE13X  DS    F                       SAVE REGISTER 13                 21380000
SAVLGTH  DS    F                       SAVES LENGTH REGISTER            21400000
BLANKS8  DC    CL8' '                  8 HEX BLANKS                     21420000
ZEROHEX  DC    C'00000000'             DOUBLE WORD HEX ZEROS            21440000
PRIMEWRT DC    V(IEBUPLOG)             ADDRESS OF LOG ROUTINE           21460000
PROCESS  DC    V(IEBUPDT2)             ADDRESS OF PROCESSING CSECT      21480000
RDCARD   DC    V(IEBBSCAN)             ADDRESS OF CARD SCAN RTN    UL0H 21490017
SARG     DS    D                       SEARCH ARGUMENT                  21500000
REGSAVE  DS    18F                     SAVE REGISTERS                   21520000
RRSAVE   DS    16F                     SAVE AREA USED BY RDCARD         21540000
ZERO     DC    D'0'                    BUFFER OF ZEROS                  21560000
EIGHT    DC    F'8'                                                     21580000
MVINHDEX MVC   0(1,GR3),0(GR10)        MOVE LABEL NAME TO BUFFER        21600000
OPRLUP3  MVC   SARG(1),0(SCANADR)      MOVE KEYWORD TO SEARCH ARGUMENT  21620000
MOVNAME  MVC   0(1,GR7),0(SCANADR)     LEFT ADJUST MEMBER NAME          21640000
ALTTT    DC    X'0A0B0C0D0E0FDDDDDD'   TABLE TO CONVERT TO HEX          21660000
         DC    X'DDDDDDDDDDDD'                                          21680000
         DC    X'00010203040506070809'                                  21700000
YESYES   DC    C'YES'                  DESIGNATES INSERT BLOCK          21720000
LISTSET  DC    C'ALL'                  ONLY ALLOWABLE 'LIST' PARAMETER  21740000
EOFDC    DC    C'EOF'                  ONLY INPUT FOR 'IGNORE' OPTION   21760000
NEWPO    DC    C'PO'                   NEW MASTER DS TYPE IDENTIFIER    21780000
NEWPS    DC    C'PS'                   NEW MASTER DS TYPE IDENTIFIER    21800000
INPLACE  DC    C'INPLACE'              PARAMETER FOR UPDATE INPLACE     21820000
COLUMN80 DC    C'80'                   COLUMN 80                        21840000
COLUMN01 DC    C'01'                   COLUMN 01                        21860000
DOTSLASH DC    C'./'                   CONTROL CARD INDICATION          21880000
NO       DC    C'NO'                   INDICATING NO USER LABEL  A45205 21882022
MAXCORE  DC    F'32769'           MAX TOTALSIZE + 1              A36128 21890021
PACKSIZE PACK  TEMPTOT(8),0(1,SCANADR)                             UL0H 21900017
COLM1BUF DC    C'00'                   HOLDS COLUMN SPEC IF ONLY 1 CHAR 21920000
FIVE     DC    F'5'                                                UL0H 21946017
TEMPTOT  DS    D                                                   UL0H 21953017
NUMERIC  EQU   X'F0'                                                    21960000
ALPHA    EQU   X'C0'                                                    21980000
PODSET   EQU   2                       DSORG FIELD SETTING FOR PODS     22000000
PSDSET   EQU   X'40'                   DCB SETTING FOR SEQUENTIAL       22020000
PODPS    EQU   PODSET+PSDSET           SETTING FOR PODS OR PS DSORG     22040000
EXLIST   EQU   X'24'                   OFFSET OF EXIT LIST POINTER DCB  22060000
         EJECT                                                          22080000
         DCBD  DSORG=PS                                                 22100000
BDSORG   EQU   DCBDSORG-IHADCB         DATA SET ORGANIZATION FIELD DCB  22120000
         EJECT                                                          22140000
         IEBUPCON                                                       22160000
         END   IEBASCAN                                                 22180000
