*********************************************************************** 00020000
*                                                                     * 00040000
* NAME             *****   *   *   *****   *       *   *              * 00060000
*                  *   *   **  *   *   *   *        * *               * 00080000
*                  *****   * * *   *****   *         *                * 00100000
*                  *   *   *  **   *   *   *         *                * 00120000
*                  *   *   *   *   *   *   *****     *                * 00140000
*                                                                     * 00160000
*********************************************************************** 00180000
*                                                                     * 00200000
* FUNCTION/OPERATION                                                  * 00220000
*                                                                     * 00240000
*      THIS IS THE CONTROL CARD ANALYZER MODULE FOR THE DATA SET      * 00260000
*   UTILITY IEBCOMPR.  ITS MAIN FUNCTIONS ARE THE FOLLOWING:          * 00280000
*                                                                     * 00300000
*       1. PRINT THE CONTROL CARDS FOR IEBCOMPR                       * 00320000
*       2. PRINT DIAGNOSTIC MESSAGES ABOUT THE CONTROL CARDS, AFTER   * 00340000
*            THE CARDS HAVE BEEN THROUGHLY ANALYZED BY THE MODULE     * 00360000
*       3. SET THE ABORT SWITCH WHEN APPLICABLE                       * 00380000
*       4. SET UP THE EXITS PARAMETER LIST FOR THE MAIN PROCESSOR     * 00400000
*       5. PRINT THE DIAGNOTIC MESSAGE TO INDICATE THAT SYSIN COULD   * 00420000
*            NOT BE OPENED IF THE CARD SCANNER FINDS THIS TO BE THE   * 00440000
*            CASE                                                     * 00460000
*                                                                     * 00480000
*********************************************************************** 00500000
*                                                                     * 00520000
* ENTRY POINTS                                                        * 00540000
*                                                                     * 00560000
*   1. 'ANALY'      THIS IS THE ENTRY POINT TO THE FIRST OVERLAY      * 00580000
*                 SEGMENT. CONTROL IS PASSED TO THIS POINT FROM THE   * 00600000
*                 ROOT SEGMENT.                                       * 00620000
*                                                                     * 00640000
*   2. 'DDRTN'      THE CARD SCANNER ENTERS HERE IF IT FINDS THAT     * 00660000
*                 SYSIN CANNOT BE OPPENED.                            * 00680000
*                                                                     * 00700000
*   3. 'BLKRTN'     THE CARD SCANNER ENTERS HERE IF IT FINDS THAT* BS0H 00706017
*                 SYSIN HAS AN INVALID BLOCKSIZE.                * BS0H 00712017
*********************************************************************** 00720000
         EJECT                                                          00740000
*********************************************************************** 00760000
*                                                                     * 00780000
* INPUT                                                               * 00800000
*                                                                     * 00820000
*       INPUT TO THE ANALYZER COMES FROM THE GENERALIZED CARD SCANNER.* 00840000
*   PARAMETERS ARE PASSED ONE AT A TIME FROM THE SCANNER TO THE       * 00860000
*   ANALYZER, AT WHICH TIME THE PARAMETERS ARE INTERROGATED.          * 00880000
*   WHEN CONTROL IS RECEIVED FROM THE CCS02 SCAN ROUTINE,         *SA0I 00885018
*   REGISTER 0 CONTAINS THE LENGTH OF THE WORD BEING ANALYZED AND *SA0I 00890018
*   REGISTER 1 IS A POINTER TO THAT WORD.                         *SA0I 00895018
*                                                                     * 00900000
*********************************************************************** 00920000
*                                                                     * 00940000
* OUTPUT                                                              * 00960000
*                                                                     * 00980000
*     THE OUTPUT OF THE ANALYZER IS SIMPLY THE SETTING OF SWITCHES,   * 01000000
*   THE BUILDING OF PARAMETER LISTS FOR THE MAIN PROCESSOR, OR THE    * 01020000
*   SETTING OF PARAMETERS FOR THE GENERALIZED MESSAGE WRITER.         * 01040000
*                                                                     * 01060000
*********************************************************************** 01080000
*                                                                     * 01100000
* EXTERNAL ROUTINES                                                   * 01120000
*                                                                     * 01140000
*     THE CONTROL CARD SCANNER IS CALLED EACH TIME A NEW PARAMETER IS * 01160000
*   WANTED.  THE ONLY OTHER EXTERNAL ROUTINES ARE THE PRINT ROUTINES  * 01180000
*   WHICH ARE LOCATED IN THE ROOT SEGMENT.  THESE ROUTINES ARE 'ZZPR' * 01200000
*   AND 'JPRINTRT', AND ARE REACHED BY BRANCH AND LINK INSTRUCTIONS.  * 01220000
*                                                                     * 01240000
*********************************************************************** 01260000
         EJECT                                                          01280000
*********************************************************************** 01300000
*                                                                     * 01320000
* EXITS                                                               * 01340000
*                                                                     * 01360000
*     THE ONLY EXIT FROM THE ANALYZER IS A BRANCH ON REGISTER 14,     * 01380000
*   TAKING ONE BACK TO THE ROOT SEGMENT FOR IEBCOMR.                  * 01400000
*                                                                     * 01420000
*********************************************************************** 01440000
*                                                                     * 01460000
* TABLES /WORK AREAS                                                  * 01480000
*                                                                     * 01500000
*     THERE ARE NO TABLES AS SUCH, JUST PARAMETER LISTS AND SWITCHES  * 01520000
*   WHICH ARE CONSTRUCTED BY THE ANALYZER OR INTERROGATED BY IT.      * 01540000
*                                                                     * 01560000
*********************************************************************** 01580000
*                                                                     * 01600000
* ATTRIBUTES                                                          * 01620000
*                                                                     * 01640000
*     NON-REENTRANT AND NON-REUSEABLE                                 * 01660000
*                                                                     * 01680000
*********************************************************************** 01700000
         EJECT                                                          01720000
COMMX    DSECT                                                          01740000
         USING COMMX,10                                                 01760000
SAVE1315 DS    3F                  SAVE AREA FOR REGS 13,14, AND 15     01780000
SAVEREGS DS    18F                 MY REGISTER SAVE AREA                01800000
PARALIST DS    8F            THE EXITS PARAMETER LIST-USER RTNS    SA0I 01820018
*                                    1. INHDR PARAMETER NAME            01840000
*                                    2. INTLR PARAMETER NAME            01860000
*                                    3. ERROR PARAMETER NAME            01880000
*                                    4. PRECOMP PARAMETER NAME          01900000
DDSYSIN  DS    2F                  SYSIN PARAMETER                      01920000
DDSUBNAM DS    4F                  DDNAME PARAMETER LIST                01940000
*                                    1. SYSUT1 DDNAME                   01960000
*                                    2. SYSUT2 DDNAME                   01980000
HICONCOD DS    2X                  RETURN CODE STORAGE AREA             02000000
CCADSORG DS    1X                  SET TO '01' IF PARTITIONED DATA SET  02020000
ABORTSW  DS    1X                  ABORT SWITCH - SET TO '01' IF ON     02040000
LABEL    DS    1X             SET TO X'00' IF DATA=YES             UL0H 02044017
*                                    X'01' IF DATA=NO              UL0H 02048017
*                                    X'10' IF DATA=ONLY            UL0H 02052017
*                                    X'20' IF DATA=ALL             UL0H 02056017
*********************************************************************** 02060000
ANALY    CSECT                                                          02080000
* 044970-045600,045620                                           A27718 02082019
*8047046600                                                        BS0H 02084017
*2652018200,020980,023460-023600,024000,026200,026900-028400,      SA0I 02084518
* 029600-030600,030700,031000,031130,031200,031600-031900,         SA0I 02085018
* 032600,032700,033400,034000,034200,035000,035800,035960-         SA0I 02085518
* 036600,036800,037200,037400,038000,038200,038800,040400,041600,  SA0I 02086018
* 042800,044000,044032,044056,044088,044096,044186-045200,045800,  SA0I 02086518
* 045900,050800-051400,053400                                      SA0I 02087018
* 030160,030800,030852-030856                                     M2002 02087518
* REGISTER ASSIGNMENTS                                             BS0H 02088017
PARMREG  EQU   1                                                   BS0H 02092017
R15      EQU   15                                                  BS0H 02096017
R14      EQU   14                                                       02097017
R0       EQU   0                  CONTAINS LENGTH OF WORD SCANNED  SA0I 02097518
R1       EQU   1                                                   SA0I 02098018
R2       EQU   2                  CONTAINS MESSAGE CODE            SA0I 02098518
R3       EQU   3                                                   SA0I 02099018
R4       EQU   4                                                   SA0I 02099518
         ENTRY DDRTN                                                    02100000
         ENTRY BLKRTN                                              BS0H 02110017
         SAVE  (14,12)                                                  02120000
         BALR  11,0                                                     02140000
         USING *,11                                                     02160000
         STM   13,14,SAV13A14                                           02180000
         LA    13,SAVANALR                                              02200000
         XC    CTLAREA(144),CTLAREA  FILL WORK AREA WITH ZEROS          02220000
         MVI   PARALIST,X'40'      FILL PARAMETER LIST                  02240000
         MVC   PARALIST+1(31),PARALIST  WITH BLANKS                     02260000
         MVC   DDJOSIN(8),DDSYSIN                                       02280000
CALLSCAN CALL  ACTCCS,(CTLAREA,DDJOSIN),ID=1                            02300000
         TM    CTLAREA,X'20'       END OF FILE TEST                     02320000
         BO    ENDOFANA              BRANCH BACK TO ROOT SEG (IS EOF)   02340000
         CLI   CTLAREA+144,X'01'  IS NEW CARD SW ON                SA0I 02360018
         BH    ERRFRSCA              INPUT ERROR - ABORT JOB            02380000
         BL    ERRTST             NO-BRANCH TO ERROR TESTS         SA0I 02400018
*********************************************************************** 02420000
***      GO PRINT CONTROL CARD AND CONTINUE PROCESSING                  02440000
*********************************************************************** 02460000
         STM   0,1,SAVEREG0                                             02480000
         LA    0,79                                                     02500000
         LA    1,CTLAREA+1                                              02520000
         L     15,MYPRTCON                                              02540000
         BALR  14,15                                                    02560000
         LM    0,1,SAVEREG0                                             02580000
*********************************************************************** 02600000
*******************************************************************SA0I 02600318
*                TEST FOR ERRORS FLAGGED BY CCS02 SCAN ROUTINE    *SA0I 02600618
*******************************************************************SA0I 02600918
ERRTST   TM    CTLAREA,X'80'      IS ERROR BIT ON                  SA0I 02601218
         BZ    BPASTST            NO-TEST BYPASS BIT               SA0I 02601518
         TM    CTLAREA,X'40'      YES-IS BYPASS BIT ON             SA0I 02601818
         BO    COMTST             YES THEN DETERMINE TYPE OF ERROR SA0I 02602118
         LA    R1,26              NO-WARNING INVALID NAME          SA0I 02602418
         L     R15,PRINCONS       LOAD PRINT ROUTINE ADDRESS       SA0I 02602718
         BALR  R14,R15            BRANCH TO PRINT ERROR MESSAGE    SA0I 02603018
         B     CALLSCAN           RETURN TO SCAN ROUTINE           SA0I 02603318
COMTST   TM    CTLAREA,X'08'      IS COMMAND BIT ON                SA0I 02603618
         BZ    KEYTST             NO-THEN TEST KEYWORD BIT         SA0I 02603918
         OI    FIRSTCOC,X'01'     YES-SET SWITCH IF NOT ON         SA0I 02604218
         TM    CTLAREA,X'06'      IS KEYWORD OR PARAMETER BIT ON   SA0I 02604518
         BZ    WRNGCOM            NO-BRANCH FOR INVALID COMMAND    SA0I 02604818
         LA    R2,60              YES MISSING COMMAND              SA0I 02605118
         B     COLCALC            CALCULATE ERROR COLUMN NUMBER    SA0I 02605418
WRNGCOM  LA    R2,65              INVALID COMMAND                  SA0I 02605718
         B     COLCALC            CALCULATE ERROR COLUMN NUMBER    SA0I 02606018
KEYTST   TM    CTLAREA,X'04'      IS KEYWORD BIT ON                SA0I 02606318
         BZ    PARATST            NO-THEN TEST PARAMETER BIT       SA0I 02606618
WRNGKEY  NI    PARMSW,X'00'       YES-TURN OFF PARMSW              SA0I 02606918
         LA    R2,59              INVALID KEYWORD                  SA0I 02607218
         B     COLCALC            CALCULATE ERROR COLUMN NUMBER    SA0I 02607518
PARATST  TM    CTLAREA,X'02'      IS PARAMETER BIT ON              SA0I 02607818
         BZ    KEYREQ             NO-TEST KEYWORD REQUIRED BIT     SA0I 02608118
         LA    R2,61              YES-INVALID PARAMETER            SA0I 02608418
         B     COLCALC            CALCULATE ERROR COLUMN NUMBER    SA0I 02608718
KEYREQ   TM    CTLAREA+81,X'02'   IS KEYWORD REQUIRED BIT ON       SA0I 02609018
         BZ    PARAREQ            NO-TEST PARAMETER REQUIRED BIT   SA0I 02609318
         LA    R2,62              MISSING KEYWORD                  SA0I 02609618
         B     COLCALC            CALCULATE ERROR COLUMN NUMBER    SA0I 02609918
PARAREQ  TM    CTLAREA+81,X'01'   IS PARAMETER REQUIRED BIT ON     SA0I 02610218
         BZ    WRNGCOL            NO-THEN CONTINUATION IN ERROR    SA0I 02610518
         LA    R2,63              MISSING PARAMETER                SA0I 02610818
         B     COLCALC            CALCULATE ERROR COLUMN NUMBER    SA0I 02611118
WRNGCOL  LA    R1,66              CONTINUATION CARD IN WRONG COL   SA0I 02611418
         L     R15,PRINCONS       LOAD PRINT ROUTINE ADDRESS       SA0I 02611718
         BALR  R14,R15            BRANCH TO PRINT ERROR MESSAGE    SA0I 02612018
         OI    HICONCOD+1,X'0C'   RETURN CODE                      SA0I 02612318
         OI    ABORTSW,X'01'      TURN ON ABORT SWITCH             SA0I 02612618
         B     CALLSCAN           BRANCH TO SCAN ROUTINE           SA0I 02612918
BPASTST  TM    CTLAREA,X'40'      IS BYPASS BIT ON                 SA0I 02613218
         BZ    COMPCD             NO-THEN NO SYNTAX ERRORS FOUND   SA0I*02613518
                                  BY CCS02, CONTINUE ANALYSIS      SA0I 02613818
         TM    CTLAREA,X'01'      IS END OF PARAMETER BIT ON       SA0I 02614118
         BZ    CALLSCAN           NO-THEN RETURN TO SCAN,          SA0I*02614418
                                  YES-THEN CONTINUE ANALYSIS       SA0I 02614718
*******************************************************************SA0I 02615018
*        TEST FOR COMPARE COMMAND ON FIRST CONTROL CARD           *SA0I 02615318
*******************************************************************SA0I 02615618
COMPCD   TM    FIRSTCOC,1         HAS COMPARE CARD BEEN READ       SA0I 02625618
         BO    TESFORER              YES-BRANCH AROUND                  02640000
         MVI   FIRSTCOC,1          SET SWITCH IND. COMPARE CD. READ     02660000
         CLC   COMWORD1(7),0(1)    DOES COMMAND WORD = COMPARE          02680000
         BE    LENG7              YES-THEN TEST WORD LENGTH        SA0I 02680918
         LA    R1,64           NO-FIRST CONTROL CARD NOT 'COMPARE' SA0I 02681818
         L     R15,PRINCONS       LOAD PRINT ROUTINE ADDRESS       SA0I 02682718
         BALR  R14,R15            BRANCH TO PRINT ERROR MESSAGE    SA0I 02683618
         B     BYPASCD            SET BY PASS SW ON                SA0I 02684518
LENG7    LA    R3,7               IS WORD LENGTH=7                 SA0I 02685418
         CLR   R0,R3                                               SA0I 02686318
         BE    COMPST             YES THEN COMMAND IS VALID        SA0I 02687218
         LA    R2,65              INVALID COMMAND                  SA0I 02688118
         B     COLCALC            CALCULATE ERROR COLUMN NUMBER    SA0I 02689018
COMPST   OI    CDSW,X'01'         SET SW TO COMPARE STMNT ANALYSIS SA0I 02694018
         B     CALLSCAN           BRANCH TO SCAN ROUTINE           SA0I 02704018
TESFORER TM    CTLAREA,X'02'      PARAMETER TEST                   SA0I 02774018
         BO    PARSET                POSITIVE RESPONSE                  02860000
         TM    CTLAREA,X'04'       KEYWORD TEST                         02880000
         BO    KEYWORDT              POSITIVE RESPONSE                  02900000
         TM    CTLAREA,X'08'       COMMAND WORD TEST                    02920000
         BO    COMWORDT              POSITIVE RESPONSE                  02940000
         LA    R1,1               INVALID CONTROL STATEMENT        SA0I 02944018
         L     R15,PRINCONS       LOAD PRINT ROUTINE ADDRESS       SA0I 02948018
         BALR  R14,R15            BRANCH TO PRINT ERROR MESSAGE    SA0I 02952018
         B     BYPASCD            GO TO SET BYPASS SW              SA0I 02956018
*******************************************************************SA0I 02966018
*                  TEST FOR VALID COMMAND WORD                    *SA0I 02976018
*******************************************************************SA0I 02986018
COMWORDT LA    R3,5               IS COMMAND LENGTH=5              SA0I 02996018
         CLR   R0,R3                                               SA0I 03006018
         BNE   COMWDT2            CHECK OTHER COMMANDS            M2002 03016018
         CLC   COMWORD2(5),0(R1)  DOES COMMAND WORD=EXITS          SA0I 03036018
         BNE   ERMSG                   NOT EXITS                   SA0I 03046018
         MVI   CDSW,X'02'     YES-SET SW IND. IN EXITS STMNT ANAL. SA0I 03068018
         OI    CTLAREA+81,X'02'   TURN ON KEYWORD REQUIRED BIT     SA0I 03071018
         B     CALLSCAN            BRANCH                          UL0H 03075017
COMWDT2  CLC   COMWORD3(6),0(R1)  DOES COMMAND WORD = LABELS      M2002 03080018
         BNE   ERMSG          NO                                   UL0H 03085017
         LA    R3,6               CONSTANT SIX IN REG             M2002 03086018
         CLR   R0,R3              IS LENGTH = SIX                 M2002 03087018
         BNE   ERMSG              NO, WRITE ERR MSG               M2002 03088018
         TM    CCADSORG,X'01'      ARE DATA SETS PARTITIONED       UL0H 03090017
         BO    ULABPO              YES, BRANCH                     UL0H 03095017
         MVI   CDSW,X'04'      NO-SET SW IND IN LABEL STMNT ANAL.  SA0I 03098018
         OI    CTLAREA+81,X'02'   TURN ON KEYWORD REQUIRED BIT     SA0I 03101018
         B     CALLSCAN      BRANCH                                UL0H 03106017
ERMSG    CLC   COMWORD1(5),0(R1)  IS COMMAND=COMPARE               SA0I 03107018
         BE    COMPRD             YES-CHECK FOR DUPLICATE          SA0I 03108018
         LA    R2,65              NO-INVALID COMMAND               SA0I 03109018
         B     COLCALC            CALCULATE ERROR COLUMN NUMBER    SA0I 03110018
COMPRD   TM    CDSW,X'01'         HAS COMPARE CARD BEEN READ       SA0I 03111018
         BZ    ILLSEQ             NO-THEN INVALID SEQUENCE         SA0I 03112018
         LA    R1,13              YES-REPETITIOUS CARD INVALID     SA0I 03113018
         B     WRTMSG             PRINT ERROR MESSAGE              SA0I 03114018
ILLSEQ   LA    R1,16              ILLEGAL CONTROL CARD SEQUENCE    SA0I 03115018
WRTMSG   L     R15,PRINCONS       LOAD PRINT ROUTINE ADDRESS       SA0I 03125018
         BALR  14,15               BRANCH TO PRINT ERROR MESSAGE        03140000
         B     BYPASCD            SET BYPASS SW ON                 SA0I 03160018
*******************************************************************SA0I 03166018
*                    TEST FOR A VALID KEYWORD                     *SA0I 03172018
*******************************************************************SA0I 03178018
KEYWORDT NI    PARMSW,X'00'       TURN OFF PARMSW                  SA0I 03184018
         TM    CDSW,X'01'         IS COMPARE STMNT ANALYSIS        SA0I 03190018
         BZ    KCOMP2         NO                                   UL0H 03200017
         LA    R3,6               YES IS KEYWORD LENGTH=6          SA0I 03202018
         CLR   R0,R3                                               SA0I 03204018
         BNE   BADKEYW            NO-INVALID KEYWORD               SA0I 03206018
         CLC   KEYWORD1(6),0(R1) DOES KEYWORD=TYPORG               UL0H 03210017
         BNE   BADKEYW        NO,ILLEGAL KEY WORD                  UL0H 03220017
         MVI   KWORDSW,X'01'         YES, SET KWORDSW = 1               03240000
TURNOF   NI    CTLAREA+81,X'FD'   TURN OFF KEYWORD REQUIRED BIT    SA0I 03246018
         OI    CTLAREA+81,X'01'   TURN ON PARAMETER REQUIRED BIT   SA0I 03252018
         B     CALLSCAN           BRANCH TO SCAN ROUTINE           SA0I 03261018
KCOMP2   TM    CDSW,X'02'         IS EXITS STMNT ANALYSIS          SA0I 03270018
         BZ    KCOMP6         NO                                   UL0H 03280017
         LA    R3,5               YES-IS LENGTH=5                  SA0I 03282018
         CLR   R0,R3                                               SA0I 03284018
         BNE   KCOMP5             NO-THEN TEST FOR LENGTH=7        SA0I 03286018
         CLC   KEYWORD2(5),0(R1) DOES KEYWORD=INHDR                UL0H 03290017
         BNE   KCOMP3                NO                                 03300000
         TM    CCADSORG,X'01'      ARE DATA SETS PARTITIONED       UL0H 03306017
         BO    ULABPO              YES, BRANCH                     UL0H 03312017
         MVI   KWORDSW,X'02'      NO, SET KWORDSW=2                SA0I 03322018
         B     TURNOF             PARAMETER IS REQUIRED            SA0I 03332018
KCOMP3   CLC   KEYWORD3(5),0(1)    DOES KEYWORD = INTLR                 03360000
         BNE   KCOMP4                NO                                 03380000
         TM    CCADSORG,X'01'      ARE DATA SETS PARTITIONED       UL0H 03386017
         BO    ULABPO              YES, BRANCH                     UL0H 03392017
         MVI   KWORDSW,X'04'      NO,SET KWORDSW=4                 SA0I 03402018
         B     TURNOF             PARAMETER IS REQUIRED            SA0I 03412018
KCOMP4   CLC   KEYWORD4(5),0(1)    DOES KEYWORD = ERROR                 03440000
         BNE   KCOMP5                NO                                 03460000
         MVI   KWORDSW,X'08'         YES, SET KWORDSW = 8               03480000
         B     TURNOF             PARAMETER IS REQUIRED            SA0I 03500018
KCOMP5   CLC   KEYWORD5(7),0(1)    DOES KEYWORD = PRECOMP               03520000
         BNE   BADKEYW               NO                                 03540000
         LA    R3,7               IS LENGTH=7                      SA0I 03545018
         CLR   R0,R3                                               SA0I 03550018
         BNE   BADKEYW            NO-INVALID KEYWORD               SA0I 03555018
         MVI   KWORDSW,X'10'         YES, SET KWORDSW = 10              03560000
         B     TURNOF             PARAMETER IS REQUIRED            SA0I 03570018
KCOMP6   CLC   KEYWORD6(4),0(R1) DOES KEYWORD=DATA                 UL0H 03584017
         BNE   BADKEYW            NO-INVALID KEYWORD               SA0I 03585018
         LA    R3,4               IS WORD LENGTH=4                 SA0I 03586018
         CLR   R0,R3                                               SA0I 03587018
         BNE   BADKEYW        NO,ILLEGAL KEY WORD                  UL0H 03588017
         MVI   KWORDSW,X'20'  YES SET KWORDSW=X'20'                UL0H 03592017
         B     TURNOF             PARAMETER IS REQUIRED            SA0I 03596018
BADKEYW  LA    R2,59              INVALID KEYWORD                  SA0I 03606018
         B     COLCALC            CALCULATE ERROR COLUMN NUMBER    SA0I 03616018
*******************************************************************SA0I 03626018
*                    TEST FOR A VALID PARAMETER                   *SA0I 03636018
*******************************************************************SA0I 03646018
PARSET   LTR   0,0                 DOES PARAMETER LENGTH EQUAL ZERO     03700000
         BNZ   KEYTYP             NO-TEST FOR VALID PARAMETER      SA0I 03710018
         LA    R2,63              MISSING PARAMETER                SA0I 03720018
         B     COLCALC            CALCULATE ERROR COLUMN NUMBER    SA0I 03730018
KEYTYP   TM    PARMSW,X'01'       HAS A PARAMETER BEEN READ        SA0I 03736018
         BO    PARERR             YES, INVALID PARAMETER           SA0I 03742018
         OI    PARMSW,X'01'       NO, TURN ON PARMSW               SA0I 03748018
         TM    KWORDSW,X'01'      TEST FOR TYPORG KEYWORD          SA0I 03754018
         BZ    PTEST2                BRANCH - NOT TYPORG                03760000
         LA    R3,2               IS PARAMETER LENGTH=2            SA0I 03762018
         CLR   R0,R3                                               SA0I 03764018
         BE    TYPRD              YES-CHECK FOR DUPLICATE          SA0I 03766018
PARERR   LA    R2,61              INVALID PARAMETER                SA0I 03768018
         B     COLCALC            CALCULATE ERROR COLUMN NUMBER    SA0I 03770018
TYPRD    TM    TYPARA,X'01'       HAS TYPORG BEEN READ             SA0I 03772018
         BO    REPRTN             YES-INVALID REPETITIOUS CARD     SA0I 03774018
         OI    TYPARA,X'01'       NO-SET TYPORG SW ON              SA0I 03776018
         CLC   PARWORD2(2),0(1)       IS TYPORG PS                      03780000
         BNE   TYPPO              NO-THEN IS PO                    SA0I 03786018
         NI    CTLAREA+81,X'FC'   TURN OFF PARAMETER REQUIRED BIT  SA0I 03792018
         B     CALLSCAN           RETURN TO SCAN ROUTINE           SA0I 03802018
TYPPO    CLC   PARWORD1(2),0(R1)  IS TYPORG=PO                     SA0I 03812018
         BNE   PARERR                NO-BRANCH-PARAMETER ERROR          03840000
         MVI   CCADSORG,X'01'        YES-SET SW TO PO PARAMETER         03860000
PARMOFF  NI    CTLAREA+81,X'FC'   TURN OFF PARAMETER REQ BIT       SA0I 03870018
         B     CALLSCAN           RETURN TO SCAN ROUTINE           SA0I 03880018
PTEST2   CH    0,EIGHT             IS LENGTH GREATER THAN EIGHT         03900000
         BH    PARERR                YES-PARAMETER ERROR                03920000
         TM    KWORDSW,X'02'       IS KEYWORD=INHDR                     03940000
         BZ    PTEST3                NO                                 03960000
         SH    0,ONE                                                    03980000
         STC   0,MOVE1+1           MOVE INHDR ROUTINE NAME              04000000
MOVE1    MVC   PARALIST(1),0(1)      INTO PARAMETER LIST                04020000
         TM    CTLAREA,X'01'      IS END OF PARAMETER BIT ON       SA0I 04028018
         BC    1,PARMOFF          YES, TURN OFF PARAMETER REQ BIT  SA0I 04036018
         XI    CTLAREA+81,X'03'   NO, TURN ON KEYWORD REQ BIT      SA0I 04044018
         B     CALLSCAN           BRANCH TO SCAN ROUTINE           SA0I 04052018
PTEST3   TM    KWORDSW,X'04'       IS KEYWORD=INTLR                     04060000
         BZ    PTEST4                NO                                 04080000
         SH    0,ONE                                                    04100000
         STC   0,MOVE2+1           MOVE INTLR ROUTINE NAME              04120000
MOVE2    MVC   PARALIST+8(1),0(1)    INTO PARAMETER LIST                04140000
         TM    CTLAREA,X'01'      IS END OF PARAMETER BIT ON       SA0I 04148018
         BC    1,PARMOFF          YES, TURN OFF PARAMETER REQ BIT  SA0I 04156018
         XI    CTLAREA+81,X'03'   NO, TURN ON KEYWORD REQ BIT      SA0I 04164018
         B     CALLSCAN           BRANCH TO SCAN ROUTINE           SA0I 04172018
PTEST4   TM    KWORDSW,X'08'       IS KEYWORD=ERROR                     04180000
         BZ    PTEST5                NO                                 04200000
         SH    0,ONE                                                    04220000
         STC   0,MOVE3+1           MOVE ERROR ROUTINE NAME              04240000
MOVE3    MVC   PARALIST+16(1),0(1)   INTO PARAMETER LIST                04260000
         TM    CTLAREA,X'01'      IS END OF PARAMETER BIT ON       SA0I 04268018
         BC    1,PARMOFF          YES, TURN OFF PARAMETER REQ BIT  SA0I 04276018
         XI    CTLAREA+81,X'03'   NO, TURN ON KEYWORD REQ BIT      SA0I 04284018
         B     CALLSCAN           BRANCH TO SCAN ROUTINE           SA0I 04292018
PTEST5   TM    KWORDSW,X'10'       IS KEYWORD=PRECOMP                   04300000
         BZ    PTEST6         NO                                   UL0H 04320017
         SH    0,ONE                                                    04340000
         STC   0,MOVE4+1           MOVE PRECOMP ROUTINE NAME            04360000
MOVE4    MVC   PARALIST+24(1),0(1)   INTO PARAMETER LIST                04380000
         TM    CTLAREA,X'01'      IS END OF PARAMETER BIT ON       SA0I 04384018
         BC    1,PARMOFF          YES, TURN OFF PARAMETER REQ BIT  SA0I 04388018
         XI    CTLAREA+81,X'03'   NO, TURN ON KEYWORD REQ BIT      SA0I 04392018
         B     CALLSCAN           BRANCH TO SCAN ROUTINE           SA0I 04396018
PTEST6   TM    KWORDSW,X'20'       DOES KEYWORD=DATA               UL0H 04400817
         BZ    PARERR              NO,INVALID PARAMETER            UL0H 04401617
         TM    CTLAREA+81,X'01'   HAS PARAMETER BEEN READ          SA0I 04401718
         BZ    PARERR             YES-INVALID PARAMETER            SA0I 04401818
         LA    R3,2               NO-IS PARAMETER LENGTH=2         SA0I 04401918
         CLR   R0,R3                                               SA0I 04402018
         BNE   PTEST7             NO-THEN IS LENGTH=3              SA0I 04402118
         CLC   DATA1(2),0(R1)      YES,DATA=NO                     UL0H 04402417
         BNE   PARERR             NO-INVALID PARAMETER             SA0I 04403218
         MVI   LABEL,X'01' X       YES,SET SW IND. DATA=NO         UL0H 04404017
         NI    CTLAREA+81,X'FC'   TURN OFF PARAMETER REQUIRED BIT  SA0I 04404418
         B     CALLSCAN       BRANCH                               UL0H 04404817
PTEST7   LA    R3,3               IS PARAMETER LENGTH=3            SA0I 04405318
         CLR   R0,R3                                               SA0I 04405818
         BNE   PTEST8              NO                              UL0H 04406417
         CLC   DATA2(3),0(R1)     IS DATA=YES                      SA0I 04406618
         BNE   PTEST9             NO-TEST FOR DATA=ALL             SA0I 04406818
         MVI   LABEL,X'00'         YES,SET SW IND. DATA=YES        UL0H 04407217
         NI    CTLAREA+81,X'FC'   TURN OFF PARAMETER REQUIRED BIT  SA0I 04407618
         B     CALLSCAN       BRANCH                               UL0H 04408017
PTEST8   LA    R3,4               IS PARAMETER LENGTH=4            SA0I 04408218
         CLR   R0,R3                                               SA0I 04408418
         BNE   PARERR             NO-INVALID PARAMETER             SA0I 04408618
         CLC   DATA3(4),0(R1)     IS DATA=ONLY                     SA0I 04408818
         BNE   PARERR             NO-INVALID PARAMETER             SA0I 04409018
         MVI   LABEL,X'10'         YES,SET SW IND. DATA=ONLY       UL0H 04410417
         NI    CTLAREA+81,X'FC'   TURN OFF PARAMETER REQUIRED BIT  SA0I 04410818
         B     CALLSCAN       BRANCH                               UL0H 04411217
PTEST9   CLC   DATA4(3),0(R1)      DATA=ALL                        UL0H 04412017
         BNE   PARERR              NO, INVALID PARAM               UL0H 04412817
         MVI   LABEL,X'20'         YES, SET SW IND. DATA=ALL       UL0H 04413617
         NI    CTLAREA+81,X'FC'   TURN OFF PARAMETER REQUIRED BIT  SA0I 04414018
         B     CALLSCAN       BRANCH                               UL0H 04414417
ULABPO   LA    R1,50          USER LABEL NOT SUPPORT BY PO DATA SETUL0H 04415217
         L     R15,PRINCONS                                        UL0H 04416017
         BALR  R14,R15             PRINT                           UL0H 04416817
         MVI   HICONCOD+1,X'0C'                                    UL0H 04417617
         NI    CTLAREA+81,X'FC'   TURN OFFKEYWORD REQUIRED BIT     SA0I 04418118
         B     BYPASCD            SET BYPASS SW ON                 SA0I 04419018
*******************************************************************SA0I 04421018
*                  CALCULATE CONTROL CARD COLUMN WHERE            *SA0I 04423018
*                       ERROR IS FOUND                            *SA0I 04425018
*******************************************************************SA0I 04427018
COLCALC  LR    R4,R1              ADDRESS OF ERROR IN CTLAREA      SA0I 04429018
         LA    R3,CTLAREA                                          SA0I 04431018
         SR    R4,R3              R4 CONTAINS CARD COL NO WHERE    SA0I*04433018
                                  ERROR IS FOUND                   SA0I 04435018
         CVD   R4,DECAREA                                          SA0I 04437018
         OI    DECAREA+7,X'0F'                                     SA0I 04439018
         UNPK  PKARA(2),DECAREA(8)                                 SA0I 04441018
*******************************************************************SA0I 04443018
*                   MOVE COLUMN NUMBER INTO MESSAGE               *SA0I 04445018
*                  AND BRANCH TO PRINT ROUTINE                    *SA0I 04447018
*******************************************************************SA0I 04449018
         LR    R1,R2              MESSAGE NUMBER IN R1             SA0I 04451018
         LR    R3,R2              MESSAGE NUMBER IN R3             SA0I 04453018
         S     R3,THRE1   GET RELATIVE DISPLACEMENT FROM MSG31     SA0I 04455018
         M     R2,SEV2            MULTIPLY BY MESSAGE LENGTH       SA0I 04457018
         A     R3,MSGMOD          ADD LOAD ADDRESS OF MSG31        SA0I 04459018
         MVC   47(2,R3),PKARA     INSERT COLUMN NUMBER             SA0I 04461018
         L     R15,PRINCONS       LOAD PRINT ROUTINE ADDRESS       SA0I 04463018
         BALR  R14,R15            PRINT ERROR MESSAGE              SA0I 04465018
         B     BYPASCD            BRANCH TO SET ERROR SWITCHES     SA0I 04467018
ERRFRSCA MVC   MYPRTARE(120),BLANKS  CLEAR OUTPUT BUFFER         A27718 04475019
         MVC   MYPRTARE(18),IOERR  MOVE MSG. NO. INTO OUTPUT BUF A27718 04483019
         MVC   MYPRTARE+19(79),49(R1) MOVE I/O ERROR STATUS INTO A27718 04491019
*                                BY IEBCCS02 INTO OUTPUT BUFFER  A27718 04499019
         LA    R0,79               FREE 79 BYTES GOT BY          A27718 04507019
         FREEMAIN  R,LV=(0),A=(1)  SYSIN'S SYNADAF               A27718 04515019
         LA    R0,119                NO. OF BYTES TO BE PRINTED  A27718 04523019
         LA    R1,MYPRTARE           ADDRESS OF OUTPUT BUFFER    A27718 04531019
         L     R15,MYPRTCON          GET ADDR. OF PRINT ROUTINE  A27718 04539019
         BALR  R14,R15               GO TO PRINT MSG             A27718 04547019
         MVI   HICONCOD+1,X'0C'   RETURN CODE                      SA0I 04561018
         OI    ABORTSW,X'01'       TURN ON ABORT SW              A27718 04561619
         B     ENDOFANA            BRANCH TO WRAP UP ROUTINE     A27718 04562219
REPRTN   LA    R1,13              REPETITIOUS CARD INVALID         SA0I 04563018
         L     R15,PRINCONS       LOAD PRINT ROUTINE ADDRESS       SA0I 04564018
         BALR  R14,R15            BRANCH TO PRINT ERROR MESSAGE    SA0I 04565018
*******************************************************************SA0I 04566018
*        AN ERROR HAS BEEN FOUND-SET BYPASS SWITCH TO INFORM      *SA0I 04567018
*        CCS02 THAT THE REST OF THE CONTROL CARD NOW BEING        *SA0I 04568018
*        ANALYZED SHOULD BE IGNORED.                              *SA0I 04569018
*******************************************************************SA0I 04570018
BYPASCD  NI    CTLAREA+81,X'FC'   TURN OFF KEYWORD AND PARAMETER   SA0I*04571018
                                  REQUIRED BITS                    SA0I 04572018
         MVI   HICONCOD+1,X'0C'   SET RETURN CODE                  SA0I 04573018
         OI    CTLAREA,X'40'      TURN ON BYPASS CARD BIT          SA0I 04574018
         OI    ABORTSW,X'01'      TURN ON ABORT SWITCH             SA0I 04575018
         B     CALLSCAN           RETURN TO SCAN ROUTINE           SA0I 04576018
ENDOFANA LM    13,14,SAV13A14                                           04600000
         RETURN (2,12)                                                  04620000
BLKRTN   LA    PARMREG,30     INVALID BLKSIZE PARAMETER -PRINT MSG BS0H 04626017
         B     RTNOUT                   PRINT MESSAGE              BS0H 04633017
DDRTN    LA    1,29               COULD NOT OPEN SYSIN-PRINT MESSAGE    04640000
RTNOUT   L     R15,PRINCONS                                        BS0H 04660017
         BALR  14,15                                                    04680000
         LA    15,12              LOAD RETURN CODE OF '0C' IN REG15     04700000
         LM    13,14,SAVE1315                                           04720000
         RETURN (2,12)            COULD NOT OPEN SYSPRINT               04740000
*********************************************************************** 04760000
*                   CONSTANT AND WORK AREA                              04780000
PRINCONS DC    V(JPRINTRT)         ADDR OF ROUTINE TO SET UP PARAMETERS 04800000
*                                    FOR PRINT ROUTINE                  04820000
MYPRTCON DC    V(ZZPR)             ADDR OF PRINT ROUTINE                04840000
SAVANALR DS    18F                 REGISTER SAVE AREA                   04860000
SAV13A14 DS    2F                  SAVE AREA FOR REGS 13-14             04880000
DDJOSIN  DC    D'0'                SYSIN DDNAME FIELD FOR CD SCAN       04900000
SAVEREG0 DS    2F                  SAVE AREA FOR REGS O-1               04920000
EIGHT    DC    H'8'                                                     04940000
ONE      DC    H'1'                                                     04960000
CTLAREA  DS    145X                CARD IMAGE AREA-WORK AREA-LAST BYTE  04980000
*                                    IS SWITCH WHICH WHEN 01 INDICATES  05000000
*                                    INPUT ERROR FROM CD SCAN           05020000
FIRSTCOC DC    X'00'               SWITCH  00=COMPARE CTL CARD NOT READ 05040000
*                                          01=COMPARE CD READ           05060000
CDSW     DC    X'00'          SET TO X'01' IN COMPARE STMT ANALY   UL0H 05065017
*                                    X'02' IN EXITS STMT ANALY     UL0H 05070017
*                                    X'04' IN LABEL STMT ANALY     UL0H 05075017
KWORDSW  DC    X'00'              SWITCH  2 BIT KEYWORD=DATA       SA0I 05078018
*                                         3 BIT KEYWORD=PRECOMP    SA0I 05081018
*                                         4 BIT KEYWORD=ERROR      SA0I 05084018
*                                         5 BIT KEYWORD=INTLR      SA0I 05087018
*                                         6 BIT KEYWORD=INHDR      SA0I 05090018
*                                         7 BIT KEYWORD=TYPORG     SA0I 05093018
COMWORD1 DC    CL7'COMPARE'                                             05160000
COMWORD2 DC    CL5'EXITS'                                               05180000
COMWORD3 DC    CL6'LABELS'                                         SA0I 05190018
KEYWORD1 DC    CL6'TYPORG'                                              05200000
KEYWORD2 DC    CL5'INHDR'                                               05220000
KEYWORD3 DC    CL5'INTLR'                                               05240000
KEYWORD4 DC    CL5'ERROR'                                               05260000
KEYWORD5 DC    CL7'PRECOMP'                                             05280000
KEYWORD6 DC    CL4'DATA'                                           UL0H 05290017
PARWORD1 DC    CL2'PO'                                                  05300000
PARWORD2 DC    CL2'PS'                                                  05320000
DATA1    DC    CL2'NO'                                             UL0H 05324017
DATA2    DC    CL3'YES'                                            UL0H 05328017
DATA3    DC    CL4'ONLY'                                           UL0H 05332017
DATA4    DC    CL3'ALL'                                            UL0H 05336017
IOERR    DC    CL18'IEB267I I/O ERROR,'                          A27718 07336019
BLANKS   DC    X'40'                                             A27718 09336019
MYPRTARE DS    30F                                               A27718 11336019
DECAREA  DC    D'0'                                                SA0I 13336018
PKARA    DC    C'00'                                               SA0I 21336018
LABCD    DC    X'00'              LABEL CARD SWITCH                SA0I 29336018
TYPARA   DC    X'00'              TYPORG CARD SWITCH               SA0I 37336018
MSGMOD   DC    V(MSG31)           ADDR OF MESSAGE MODULE           SA0I 45336018
THRE1    DC    F'31'              CONSTANT 31                      SA0I 53336018
SEV2     DC    F'72'              CONSTANT 72                      SA0I 61336018
PARMSW   DC    X'00'              PARAMETER SW- SET TO '01' WHEN   SA0I 69336018
*                                 A PARAMETER HAS BEEN READ        SA0I 77336018
          END                                                           85336018
