         TITLE 'CONTROL CARD SCANNER -- IEBCCS0209'                     00020000
*        TITLE UTILITY CONTROL CARD SCANNER ROUTINE                     00040000
*                                                                       00060000
* THIS ROUTINE IS EXECUTED EVERY TIME THE CONTROL CARD ANALYZER    ULOH 00080017
* OF THE FOLLOWING UTILITIES REQUEST INFORMATION FROM THE CONTROL  ULOH 00090018
* DATA SET- IEBPTPCH,IEBCOPY,IEBGENER,AND IEBCOMPR                 ULOH 00100018
*   IT OPENS SYSIN,READS THE CONTROL CARDS AND PASSES THESE CARDS  ULOH 00120017
* AND LOCATION,LENGTH,AND IDENTIFICATION OF CONTROL CARD FIELDS TO ULOH 00140017
* THE CONTROL CARD ANALYZING ROUTINE.                              ULOH 00160017
*                                                                  ULOH 00180017
*     ENTRY POINTS:                                                ULOH 00200017
*                                                                  ULOH 00220017
*        IEBCCS02(CSECT NAME)                                      ULOH 00240017
*        ACTCCS  (MAIN ENTRY FROM ANALYZING ROUTINE)               ULOH 00260017
*        GENLABEL(THIS IS NOT A CONTROL FLOW ENTRY,BUT A SWITCH IN ULOH 00280017
*                 CCS02 THAT IS SET BY IEBGSCAN,INDICATING THAT THEULOH 00300017
*                 NEXT CARD FROM SYSIN NOT NEEDS TO BE SCANNED     ULOH 00320017
*                                                                  ULOH 00340017
*     INPUT:                                                       ULOH 00360017
*                                                                  ULOH 00380017
*        THE DATA FROM THE CONTROL DATA SET (SYSIN)                ULOH 00400017
*                                                                  ULOH 00420017
*     OUTPUT:                                                      ULOH 00440017
*                                                                  ULOH 00460017
*        CONTROL STATEMENT AND,IF THE SWITCH GENLABEL IS NOT       ULOH 00480017
*        ACTIVE,COMMAND,KEYWORD AND PARAMETER INDICATION TO        ULOH 00500017
*        THE ANALYZING ROUTINE                                     ULOH 00520017
*                                                                  ULOH 00540017
*     ATTRIBUTES:                                                  ULOH 00560017
*                                                                  ULOH 00580017
*        NON-REUSABLE                                              ULOH 00600017
*                                                                  ULOH 00620017
*********************************************************************** 00700000
*                                                                       00720000
         EJECT                                                          00740000
*                                                                       00760000
IEBCCS02 CSECT                                                          00780000
* 033420-033440,13200                                             M3310 00785018
*0514050800-051800,052000,052400-054600,055000-055200,056000-056200BS0H 00790017
*128600-129000,132000-132600                                       BS0H 00800017
*0704012800-013000,014200-014800,015400-017200,018800,023600       SA0I 00803018
*027800,028600,032800-033600,038600,044000,045200,058600,061000,   SA0I 00806018
*063600,066600,067400,068600-072000,072600-072800,076000,078600,   SA0I 00809018
*080200,081200,081800-082000,083400,086600-086800,092400,          SA0I 00812018
*096000-097000,103200,107400-107600,110600-110800,133000           SA0I 00815018
*                                                                A27717 00816019
*                                                                A29174 00817019
*                                                                A28288 00818019
*                                                                A30916 00819019
*                                                                A32633 00819520
*A061300-061360                                                  A41815 00819921
*A060920-061020,106410-106500                                    A55761 00826021
*D060920-061040                                                  A55761 00832021
*A027900-027960                                                 SA63312 00832500
*C030600,033460,033500                                          SA63312 00833000
*D033480                                                        SA63312 00833500
*A110820,145020                                                 SA61471 00834000
*                                                                       00840000
*        THE ROUTINE SAVES REGISTERS 3 THROUGH 14 UPON ENTRY            00860000
*        IT TESTS SWITCHES TO CONTROL ENTRY TO THE SCAN RTN,            00880000
*        INITIALIZES A POINTER TO START SCAN ADDRESS                    00900000
*                                                                       00920000
*********************************************************************** 00940000
*                                                                       00960000
         ENTRY ACTCCS                                                   00980000
         ENTRY RDCARD                                                   01000000
         ENTRY GENLABEL                                            ULOH 01010017
         USING RDCARD,REG12        SET UP BASE                          01012000
ACTCCS   DS    0H                                                       01020000
RDCARD   SAVE  (14,12),T,IEBCCS02-JULY-66      SAVE REGISTERS 14-12     01040000
         LR    REG12,GO            INITIALIZE BASE                      01060000
         LM    REG0,REG1,0(REG1)   LOAD WORK ADDRESS AND DDNAME ADDRESS 01080000
         LR    REG7,REG0           LOAD WORK ADDRESS                    01100000
         MVC   KSIDD(8),0(REG1)    SAVE USER DDNAME                     01120000
         STM   REG13,REG14,SAVE13  SAVE REGISTERS                       01140000
         LA    REG1,KREGSAVE       GET POINTER TO SAVE AREA             01160018
         ST    REG1,8(REG13)       STORE POINTER TO SAVE AREA           01170018
*                                      IN SAVE AREA                     01180018
         L     REG1,24(REG13)           RESTORE REG 1                   01200000
         LA    REG13,KREGSAVE      ADDRESS OF REGISTER SAVE AREA        01220000
         MVI   144(REG7),X'00'     RESET CARD AND ERROR SWITCHES        01240000
         L     REG3,DSP13(0,REG7)  RESTORE POINTER                      01260000
         TM    0(REG7),CMP2        IS END OF FILE BIT ON           SA0I 01263021
         BO    EOFRET              YES, GO TO EOF RETURN           SA0I 01266018
         TM    0(REG7),CMP0        IS ERROR BIT ON?                SA0I 01269021
         BZ    RSTERR1             NO-BRANCH AROUND THIS TEST      SA0I 01272018
         TM    0(REG7),CMP1        IS BYPASS BIT ON?               SA0I 01275021
         BO    RSTERR              YES-BRANCH AROUND BIT SETTING   SA0I 01278018
         NI    0(REG7),X'7F'       TURN OFF ERR BIT-BYPASS OFF AND SA0I 01281018
         B     KOMMD1              ERR ON MEANS ERROR IN NAME FLD  SA0I 01284018
*                                  BRANCH TO COMMAND CHECK RTN     SA0I 01287018
RSTERR   NI    0(REG7),X'7F'       TURN OFF ERROR BIT              SA0I 01290018
RSTERR1  TM    0(REG7),CMP3        TEST FIRST ENTRY SWITCH         SA0I 01300021
         BZ    KIRSCD              BRANCH IF OFF                        01320000
         CLI   GENLABEL+3,X'F0'        IF LABEL GENERATION         UL0H 01326017
         BE    KGTCD                   BRANCH TO READ CARD         UL0H 01332017
         TM    0(REG7),CMP1        TEST BYPASS SWITCH                   01340021
         BO    KBYPO               BRANCH IF ON                         01360000
KPFOL1   TM    DSP5(REG7),CMP4         TEST READ CARD SWITCH       ULOH 01392021
         BO    KGTCD               BRANCH IF ON                         01400000
KPFOL    TM    DSP5(REG7),CMP1     TEST CONTINUATION SWITCH        SA0I 01420021
         BO    KCONT               ON, BRANCH TO CONTINUE ROUTINE  SA0I 01440018
         TM    DSP5(REG7),CMP2     TEST PARAMETER FOLLOW SWITCH    SA0I 01460021
         BO    SCANR               ON, GO TO SCAN                  SA0I 01480018
         LA    REG3,ONE(0,REG7)    ADDRESS OF BEGIN COLUMN              01500000
*********************************************************************** 01520000
*        THIS ROUTINE CHECKS FOR A NAME. IF NAME IS PRESENT,       SA0I 01524018
*        THE FIRST CHARACTER IS CHECKED TO ASSURE THAT IT IS       SA0I 01528018
*        ALPHABETIC. SUBSEQUENT CHARACTERS MUST BE ALPHAMERIC      SA0I 01532018
*        OR NATIONAL.  IF THESE CONDITIONS ARE NOT MET, OR IF THE  SA0I 01536018
*        LENGTH IS GREATER THAN NINE, AN ERROR CODE IS RETURNED    SA0I 01540018
*        TO THE CALLING ROUTINE, BUT THE REMAINDER OF THE CARD     SA0I 01544018
*        WILL BE SCANNED UPON RETURN.  IF NO ERRORS ARE FOUND      SA0I 01548018
*        THE NAME FIELD IS BYPASSED AND A POINTER SET TO THE       SA0I 01552018
*        FIRST BLANK COLUMN.                                       SA0I 01556018
*                                                                  SA0I 01560018
KNAME    CLI   0(REG3),BLANKCOL    IS COL. 1 BLANK                 SA0I 01564018
         BE    KOMMD               YES, GO TO COMMAND SCAN         SA0I 01568018
         CLI   0(REG3),X'C1'       IF FIRST CHAR IN NAME FIELD     SA0I 01572018
         BL    SETERR              IS NOT ALPHA, SET ERROR BIT.    SA0I 01576018
         CLI   0(REG3),X'E9'       IF IT IS ALPHA, CONTINUE THE    SA0I 01580018
         BNH   INIT                NAME FIELD SCAN                 SA0I 01584018
SETERR   OI    0(REG7),CMP0        SET ERROR BIT                   SA0I 01588021
INIT     SR    REG2,REG2           ZERO REGISTER TWO               SA0I 01592018
INCRMT   LA    REG3,ONE(REG3)      INCREMENT THE POINTER           SA0I 01596018
         LA    REG2,ONE(REG2)      INCREMENT THE LENGTH            SA0I 01600018
         CLI   0(REG3),BLANKCOL    IS CURRENT COL. BLANK           SA0I 01604018
         BE    LGTHCHK             YES, GO TO LENGTH CHECK         SA0I 01608018
         LA    REG5,DSP3(REG7)     LOAD ADDR. OF END COL.          SA0I 01612018
         CR    REG3,REG5           IS THIS THE END COL.            SA0I 01616018
         BE    KNOP                YES, GO TO NO COMMAND ROUTINE   SA0I 01620018
         CLI   0(REG3),X'5B'       NO, BEGIN SCAN FOR              SA0I 01624018
         BE    INCRMT              NATIONAL OR ALPAHMERIC          SA0I 01628018
         CLI   0(REG3),X'7B'       CHARACTERS. IF ONE OF THESE     SA0I 01632018
         BE    INCRMT              IS FOUND ,LOOP BACK TO          SA0I 01636018
         CLI   0(REG3),X'7C'       CONTINUE SCAN                   SA0I 01640018
         BE    INCRMT                                              SA0I 01644018
         CLI   0(REG3),X'C1'                                       SA0I 01648018
         BL    STER                ELSE, SET ERROR BIT             SA0I 01652018
         CLI   0(REG3),X'F9'                                       SA0I 01656018
         BNH   INCRMT                                              SA0I 01660018
STER     OI    0(REG7),CMP0        SET ERROR BIT                   SA0I 01664021
         B     INCRMT              SCAN REMAINDER OF NAME FIELD    SA0I 01668018
LGTHCHK  C     REG2,EIGHT          IS LENGTH GREATER THAN EIGHT    SA0I 01672018
         BH    ERR                 YES, GO TO SET ERROR BIT        SA0I 01676018
         TM    0(REG7),CMP0        NO, TEST ERROR BIT              SA0I 01680021
         BO    KPASS               IF ON, GO TO RETURN ROUTINE     SA0I 01684018
         B     KOMMD               IF NOT ON GO TO COMMAND RTN     SA0I 01688018
ERR      OI    0(REG7),CMP0        TURN ON ERROR BIT               SA0I 01692021
         B     KPASS               GO TO RETURN ROUTINE            SA0I 01696018
         EJECT                                                          01740000
*********************************************************************** 01760000
*        INITIALIZE SWITCHES AND INDICATORS TO RECOGNIZE COMMAND        01780000
*             WORD IN FIRST CARD OF A GROUP                             01800000
*        RESET PARENTHESES COUNTER                                      01820000
*                                                                       01840000
KOMMD    LA    REG3,ONE(0,REG3)    SET POINTER TO NEXT COLUMN           01860000
KOMMD1   SR    REG2,REG2           SET REGISTER TO ZERO            SA0I 01880018
         STH   REG2,DSP9(0,REG7)   SET PARENTHESES COUNTER TO ZERO      01900000
         OI    DSP5(REG7),CMP5     SET COMMAND CONTROL SWITCH           01920021
         OI    0(REG7),CMP4        SET COMMAND BIT IN SWITCH AREA       01940021
         NI    DSP10(REG7),RESET0  RESET DELIMITER INDICATOR            01960000
*                                                                       01980000
*********************************************************************** 02000000
*        ADJUST POINTER TO FIRST CHARACTER OF COMMAND                   02020000
*             IF NO COMMAND FOUND BEFORE COL 71,SET BYPASS BIT          02040000
*                                                                       02060000
         LA    REG5,DSP3(0,REG7)   ADDRESS OF END COLUMN                02080000
KABC     CLI   0(REG3),BLANKCOL    TEST FOR BLANK COLUMN                02100000
         BNE   SCAN                COLUMN NOT BLANK-SCAN                02120000
         CR    REG3,REG5           TEST FOR END COLUMN                  02140000
         BE    KNOP                END COLUMN-BRANCH                    02160000
         LA    REG3,ONE(0,REG3)    ADJUST POINTER TO NEXT COLUMN        02180000
         B     KABC                CHECK NEXT COLUMN                    02200000
*********************************************************************** 02220000
*        RESET SWITCH AREA CONTROLS                                SA0I 02240018
*        RESET EXIT CONTROLS                                       SA0I 02260018
*        SAVE LAST DELIMITER AND CLEAR CURRENT DELIMITER INDICATOR SA0I 02280018
*                                                                       02300000
SCANR    NI    0(REG7),RESET1      RESET COMMAND BIT                    02320000
SCAN     NI    0(REG7),RESET2      RESET ALL BITS BUT ERROR,FIRST       02330018
*                                      ENTRY AND COMMAND                02340018
         NI    DSP5(REG7),X'17'    RESET CONTINUATION,PARAMETER    SA0I 02350018
*                                      FOLLOW AND RD CD SWITCHES   SA0I 02360018
SCANPP   MVC   DSP11(ONE,REG7),DSP10(REG7)   SAVE LAST DELIMITER        02380000
KCPSS    NI    DSP10(REG7),RESET0            RESET DELIMITER INDICATOR  02400000
         NI    DSP8(REG7),RESET10            RESET EXIT CONTROL SWITCH  02420000
         EJECT                                                          02440000
*********************************************************************** 02460000
*        THIS ROUTINE SCANS THE COMMAND KEYWORD AND PARAMETER      SA0I 02470018
*        FIELDS OF THE CARD.  IF NO QUOTES ARE FOUND IN THE SCAN   SA0I 02480018
*        THE ROUTINE KOMPARA HANDLES THE SCAN FOR CORRECT          SA0I 02490018
*        CHARACTERS AND LENGTH.  LITERALS ARE HANDLED BY MEANS     SA0I 02500018
*        OF INSTRUCTION MODIFICATION PRIOR TO KOMPARA.             SA0I 02510018
*                                                                       02540000
KTRT     SR    REG1,REG1           ZERO REGISTER                        02560000
         SR    REG2,REG2           ZERO REGISTER                        02580000
         LA    REG5,DSP3(0,REG7)   ADDRESS OF END COLUMN                02600000
         LR    REG1,REG3           POINTER TO CURRENT COLUMN            02620000
KA       NOP   KE                  CHECK FOR DELIMITER,                 02640000
         CLI   0(REG3),X'7D'            QUOTE                           02660000
KB       BNE   KF                  NOT QUOTE                            02680000
         TM    DSP5(REG7),CMP7     IS PARAMETER REQUIRED BIT ON    SA0I 02682021
         BO    QUOTE               YES, GO TO QUOTE SET            SA0I 02684018
         CLI   129(REG7),X'01'     IS PARENTHESES COUNTER =1       SA0I 02686018
         BE    QUOTE               YES, GO TO QUOTE SET            SA0I 02688018
         OI    0(REG7),CMP1        TURN ON BYPASS BIT              SA0I 02690021
         B     KPASS               GO TO RETURN ROUTINE            SA0I 02692018
QUOTE    OI    DSP10(REG7),CMP5    SET QUOTE DELIMITER ON          SA0I 02694021
*                                      FOR LITERAL                 SA0I 02696018
         CLI   0(REG3),X'7D'       IS CURRENT COLUMN A QUOTE       SA0I 02698018
KC       NOP   KD                  FIRST QUOTE FOUND BRANCH             02700000
         NI    KA+1,X'0F'          SET QUOTE FOUND BRANCH OFF           02720000
         NI    KB+1,X'0F'          SET TRUE DELIMITER BRANCH OFF        02740000
         OI    KC+1,X'80'          SET QUOTE FOUND BRANCH TO BE         02760000
         B     KOMPLIT             BRANCH TO LENGTH ADD            SA0I 02780018
KC1      NI    KA+1,X'0F'         SET QUOTE FOUND BRANCH OFF    SA63312 02784000
         NI    KB+1,X'0F'         SET TRUE DELIMITER BRANCH OFF SA63312 02788000
         OI    KC+1,X'80'         SET QUOTE FOUND BRANCH TO BE  SA63312 02792000
         B     KOMPLITT           BRANCH TO INCREMENT POINTER   SA63312 02796000
KD       OI    KA+1,X'F0'          SET QUOTE FOUND BRANCH UNC           02800018
         OI    KB+1,X'70'          SET BRANCH NE                        02820000
         NI    KC+1,X'0F'          SET QUOTE FOUND BRANCH OFF           02840000
         B     KOMPLIT             BRANCH TO LENGTH ADD            SA0I 02860018
KE       CLI   0(REG3),X'5B'       TEST FOR DOLLAR SIGN                 02880018
         BE    KC                 BRANCH FOR VALID CHAR.                02900000
         CLI   0(REG3),X'7B'       TEST FOR POUND SIGN                  02920018
         BE    KC                 BRANCH FOR VALID CHAR.                02940000
         CLI   0(REG3),X'7C'       TEST FOR AT SIGN                     02960018
         BE    KC                 BRANCH FOR VALID CHAR.                02980000
         CLI   0(REG3),X'7F'      TEST FOR DELIMITER                    03000000
         BH    KC                  NOT DELIMITER -CHAR TOO HIGH         03020000
         CLI   0(REG3),X'7D'       TEST FOR QUOTE                       03040000
         BE    KC1                YES,BRANCH TO SET BRANCH COND SA63312 03060000
         NI    KA+1,X'0F'          SET QUOTE FOUND BR OFF               03080000
         B     KFIND               BRANCH TO OTHER DELIMITER CHECK      03100000
KF       CLI   0(REG3),X'5B'       TEST FOR DOLLAR SIGN                 03120018
         BE    KOMPARA            BRANCH FOR VALID CHAR.                03140000
         CLI   0(REG3),X'7B'       TEST FOR POUND SIGN                  03160018
         BE    KOMPARA            BRANCH FOR VALID CHAR.                03180000
         CLI   0(REG3),X'7C'       TEST FOR AT SIGN                     03200018
         BE    KOMPARA            BRANCH FOR VALID CHAR.                03220000
         CLI   0(REG3),X'7F'      TEST FOR DELIMITER                    03240000
         BNH   KFIND               YES,BRANCH                           03260000
KOMPARA  LTR   REG2,REG2           IS THIS FIRST CHAR SCANNED?     SA0I 03262018
         BP    LNGTHADD            NO-GO TO INCREMENT LENGTH RTN   SA0I 03264018
         CLI   129(REG7),X'01'     IS PARENTHESES COUNTER =1       SA0I 03266018
         BNE   TESTPARM            NO-GO TO TEST PARAMETER BIT RTN SA0I 03268018
ALPHANUM CLI   0(REG3),X'5B'       TEST FOR DOLLAR SIGN          A29174 03268519
         BE    LNGTHADD            ADD 1 TO LENGTH               A29174 03269019
         CLI   0(REG3),X'7B'       TEST FOR POUND SIGN           A29174 03269519
         BE    LNGTHADD            ADD 1 TO LENGTH               A29174 03270019
         CLI   0(REG3),X'7C'       TEST FOR AT SIGN              A29174 03270519
         BE    LNGTHADD            ADD 1 TO LENGTH               A29174 03271019
         CLI   0(REG3),X'C1'       IS THIS CHARACTER ALPHAMERIC  A29174 03271519
         BNL   LNGTHADD            YES-GO TO INCREMENT LENGTH RTN  SA0I 03272018
ERROR    OI    0(REG7),X'C0'       NO -SET ERROR AND BYPASS BITS   SA0I 03274018
LNGTHADD LA    REG2,ONE(0,REG2)    INCREMENT LENGTH BY ONE         SA0I 03276018
         C     REG2,EIGHT          IS LENGTH GREATER THAN EIGHT?   SA0I 03278018
         BNH   ENDCHK              NO-CHECK FOR END COLUMN         SA0I 03280018
         TM    0(REG7),CMP4        IS COMMAND BIT ON?              SA0I 03282021
         BZ    SETBYP              NO-GO TO SET BYPASS RTN         SA0I 03284018
         OI    0(REG7),X'C0'       SET ERROR AND BYPASS BITS       SA0I 03286018
         B     KPASS               GO TO RETURN RTN                SA0I 03288018
SETBYP   OI    0(REG7),CMP1        SET BYPASS BIT                  SA0I 03290021
         TM    DSP5(REG7),CMP6     IS KEYWORD REQUIRED BIT ON      SA0I 03292021
         BZ    PARMTEST            NO, TEST PARAMETER REQUIRED BIT SA0I 03294018
         OI    0(REG7),CMP5        YES, TURN ON KEYWORD BIT        SA0I 03296021
         B     KPASS               GO TO RETURN ROUTINE            SA0I 03298018
PARMTEST TM    DSP5(REG7),CMP7     IS PARAMETER REQUIRED BIT ON    SA0I 03300021
         BZ    PRNTEST             NO, TEST PARENTHESES COUNTER    SA0I 03302018
         OI    0(REG7),CMP6        YES, TURN ON PARAMETER BIT      SA0I 03304021
         B     KPASS               GO TO RETURN ROUTINE            SA0I 03306018
PRNTEST  CLI   129(REG7),X'01'     IS PARENTHESES COUNTER =1       SA0I 03308018
         BNE   KPASS               NO, GO TO RETURN ROUTINE        SA0I 03310018
         OI    0(REG7),X'82'       YES,TURN ON ERROR AND           SA0I 03312018
*                                      PARAMETER BITS              SA0I 03314018
         B     KPASS               GO TO RETURN RTN                SA0I 03316018
ENDCHK   CR    REG3,REG5           IS THIS END COLUMN?             SA0I 03318018
         BE    KPART               YES-SAVE PARTIAL PARAMETER      SA0I 03320018
         LA    REG3,ONE(0,REG3)    ADJUST POINTER TO NEXT COLUMN   SA0I 03322018
         B     KA                  CONTINUE CHECKING               SA0I 03324018
TESTPARM TM    DSP5(REG7),CMP7     IS PARAMETER REQUIRED BIT ON    SA0I 03326021
         BO    ALPHANUM            YES-GO TO ALPHAMERIC CHECK      SA0I 03328018
         CLI   0(REG3),X'5B'       TEST FOR DOLLAR SIGN          A29174 03328219
         BE    LNGTHADD            ADD 1 TO LENGTH               A29174 03328419
         CLI   0(REG3),X'7B'       TEST FOR POUND SIGN           A29174 03328619
         BE    LNGTHADD            ADD 1 TO LENGTH               A29174 03328819
         CLI   0(REG3),X'7C'       TEST FOR AT SIGN              A29174 03329019
         BE    LNGTHADD            ADD 1 TO LENGTH               A29174 03329219
         CLI   0(REG3),X'C1'       IS THIS CHAR ALPHABETIC?        SA0I 03330018
         BL    ERROR               NO-GO TO SET ERROR BIT RTN      SA0I 03332018
         CLI   0(REG3),X'E9'                                       SA0I 03334018
         BH    ERROR                                               SA0I 03336018
         B     LNGTHADD            YES-GO TO INCREMENT LENGTH RTN  SA0I 03338018
KOMPLIT  LA    REG2,ONE(0,REG2)    INCREMENT LENGTH BY ONE         SA0I 03340018
         C     REG2,FOUR3          IS LITERAL GT 43               M3310 03343018
         BNL   ZRPARN              YES,SET PARANT COUNT TO ZERO SA63312 03346000
KOMPLITT CR    REG3,REG5           IS THIS END COLUMN?          SA63312 03350000
         BE    KPART               YES-GO TO PARTIAL PARAMETER RTN      03352018
         LA    REG3,ONE(0,REG3)    NO-INCREMENT POINTER BY ONE     SA0I 03354018
         B     KA                  CONTINUE CHECKING               SA0I 03356018
*                                                                       03380000
*********************************************************************** 03400000
*        KFIND CHECKS FOR DELIMITER OF PERIOD OR MINUS. IF EITHER IS    03420000
*        PRESENT,RETURNS TO SCAN ROUTINE. TESTS FOR END COLUMN. IF      03440000
*        DELIMITER IS IN END COLUMN,CC2 BIT IS SET; IF BEFORE END       03460000
*        COLUMN,CC1 BIT IS SET. THEN GOES TO TEST DELIMITER ROUTINE.    03480000
*                                                                       03500000
*                                                                       03520000
KFIND    CLI   0(REG3),PERIOD      TEST FOR PERIOD                      03540000
         BE    KOMPARA             YES-BRANCH TO LENGTH INCREMENT       03560000
         CLI   0(REG3),MINUS       TEST FOR MINUS SIGN                  03580000
         BE    KOMPARA             YES-BRANCH TO LENGTH INCREMENT       03600000
         CR    REG3,REG5           TEST FOR END COLUMN                  03620000
         BNE   SETCC1              NOT END-SET CC1 BIT                  03640000
         OI    DSP8(REG7),CMP2     END-SET CC2 BIT                      03660021
         TM    DSP5(REG7),CMP3     TEST IF PARTIAL PARAMETER            03670021
*                                      SWITCH ON                        03680018
         BO    KTERBY              TOO LONG IF ON-BYPASS                03700000
         B     TESTPAR             BRANCH TO PARAM TEST                 03720000
*                                                                       03740000
*********************************************************************** 03760000
*        THIS ROUTINE SETS BITS IN THE SWITCH AREA WHEN NO         SA0I 03780018
*        COMMAND IS FOUND OR WHEN NO KEYWORD OR PARAMETER          SA0I 03800018
*        FOLLOWS A COMMAND                                         SA0I 03820018
*                                                                       03840000
KNOP     OI    0(REG7),X'8C'       NO COMMAND ON CARD              SA0I 03860018
         SR    REG1,REG1           ZERO REGISTER                        03880000
         SR    REG2,REG2           ZERO REGISTER                        03900000
KNOPAR   OI    0(REG7),CMP1        NO KEYWORD OR PARAMETERS             03910021
*                                      FOLLOW, TURN ON BYPASS BIT       03920018
         LR    REG1,REG3           PUT COLUMN POINTER IN REG1      SA0I 03930018
         B     KPASS               BRANCH TO RETURN ROUTINE             03940000
*                                                                       03960000
         EJECT                                                          03980000
*********************************************************************** 04000000
*        TESTPAR CHECKS FOR --                                          04020000
*              PRESENCE OF PARTIAL PARAMETER                            04040000
*              LENGTH EQUAL TO OR GREATER THAN ZERO,AND                 04060000
*        SETS CORRECT LENGTH BIT                                        04080000
*                                                                       04100000
TESTPAR  TM    DSP5(REG7),CMP3     TEST IF PARTIAL PARAMETER SWITCH ON  04120021
         BO    KPPAR               BRANCH TO PARTIAL PARAMETER ROUTINE  04140000
         SR    REG4,REG4           ZERO REGISTER FOR ADD-TEST           04160000
         AR    REG4,REG2           GET PARAMETER LENGTH                 04180000
         BZ    SETLZ               BRANCH TO SET LENGTH ZERO            04200000
         OI    DSP8(REG7),CMP6     SET LENGTH GREATER THAN ZERO BIT     04220021
*                                                                       04240000
*********************************************************************** 04260000
*        DELIM CHECKS FOR VALID DELIMITER AND BRANCHES TO ROUTINE TO    04280000
*              SET CONTROL SWITCHES                                     04300000
*        IF INVALID DELIMITER IS FOUND,BRANCHES TO KINVAL               04320000
*        IT ALSO DETERMINES WHETHER OR NOT A PARTICULAR DELIMITER  SA0I 04325018
*        INDICATES THAT A COMMENT HAS BEEN FOUND. IF SO, THE       SA0I 04330018
*        BYPASS BIT IS TURNED ON.                                  SA0I 04335018
*                                                                       04340000
DELIM    CLI   0(REG3),EQUAL       TEST FOR EQUAL SIGN                  04360000
         BE    KEY                 YES-BRANCH TO SWITCH SET-KEY.        04380000
         TM    DSP5(REG7),CMP7     IS PARAMETER REQUIRED BIT ON    SA0I 04382021
         BO    COMTEST             YES-GO TO COMMA TEST            SA0I 04384018
         CLI   129(REG7),X'01'     IS PARENTHESES COUNTER =1       SA0I 04386018
         BE    COMTEST             YES-GO TO COMMA TEST            SA0I 04388018
         TM    0(REG7),CMP4        IS COMMAND BIT ON               SA0I 04390021
         BO    TESTB               YES, GO TO TEST FOR BLANK       SA0I 04392018
         CLI   0(REG3),BLANKCOL    IS CURRENT COLUMN BLANK         SA0I 04394018
         BE    PARBLANK            YES, GO TO PARBLANK             SA0I 04396018
         CLI   0(REG3),COMMA       TEST FOR COMMA                  SA0I 04398018
         BNE   BYPSET              NOT COMMA, SET BYPASS BIT       SA0I 04400018
         TM    DSP11(REG7),CMP4    WAS LAST DELIMITER A BLANK      SA0I 04402021
         BZ    PARAMC              NO, BRANCH TO COMMA ROUTINE     SA0I 04404018
BYPSET   CLI   0(REG3),LPARN       CHECK FOR A LEFT PAREN        A28288 04404619
         BNE   BYPASS              NO-SET BYPASS BIT             A28288 04405219
         OI    0(REG7),X'02'       SET PARAMETER BIT                    04405819
         B     SET                 BR TO SET ERR AND BYPASS BITS A28288 04406419
BYPASS   OI    0(REG7),CMP1        SET BYPASS BIT                A28288 04407021
         B     KPASS               GO TO RETURN RTN                SA0I 04408018
COMTEST  CLI   0(REG3),COMMA       TEST FOR COMMA                  SA0I 04410018
         BE    PARAMC              YES-BRANCH TO SET PARAMETER          04420018
*                                      AND COMMA BITS                   04430018
         CLI   0(REG3),LPARN       TEST FOR LEFT PARENTHESIS            04440018
         BE    PARAMLP             YES-BRANCH TO SET PARAMETER          04450018
*                                      AND LEFT PARENTHESIS BITS        04460018
         CLI   0(REG3),RPARN       TEST FOR RIGHT PARENTHESIS           04480018
         BE    PARAMRP             YES-BRANCH TO SET PARAMETER          04490018
*                                      AND RIGHT PARENTHESIS BITS       04500018
TESTB    CLI   0(REG3),BLANKCOL    IS DELIMITER A BLANK            SA0I 04520018
         BE    PARBLANK            YES-BRANCH TO SET PARAMETER          04530018
*                                      AND BLANK BITS                   04540018
         B     KINVALD             INVALID DELIMITER                    04560000
         EJECT                                                          04580000
*                                                                       04600000
*********************************************************************** 04620000
*                                                                       04640000
*        KIRSCD,THE FIRST-ENTRY ROUTINE,CLEARS CONTROL SWITCHES TO      04660000
*        ZERO FOR FIRST READ AND GOES TO THE READ CARD ROUTINE.         04680000
*                                                                       04700000
KIRSCD   OI    0(REG7),CMP3        SET FIRST ENTRY BIT                  04720021
         SR    REG3,REG3           *CLEAR READ ROUTINE*                 04740000
         ST    REG3,DSP9(0,REG7)   *SWITCH AREAS ON   *                 04760000
         STC   REG3,DSP5(0,REG7)   *FIRST ENTRY INTO  *                 04780000
         STC   REG3,DSP8(0,REG7)   *ROUTINE           *                 04800000
KGTCD4   NOP   KGTCD5              SKIP SWITCH                          04820000
         MVC   KDCBSAVE(80),KSYSIN SAVE SYSIN DCB                       04840000
         OI    KGTCD4+1,X'F0'      SET SKIP SWITCH TO UNC BRANCH        04860018
KGTCD5   MVC   KSYSIN(80),KDCBSAVE RESTORE SYSIN DCB                    04880000
         SR    REG1,REG1           ZERO REGISTER FOR COMPARE            04900000
         C     REG1,KSIDD          TEST IF USER DDNAME GIVEN            04920000
         BE    KGTCD6              NO USER DDNAME                       04940000
         LA    REG1,KSYSIN         LOAD SYSIN DCB ADDRESS               04960000
         MVC   DDNAME(8,REG1),KSIDD INSERT USER DDNAME IN SYSIN DCB     04980000
KGTCD6   OPEN  (KSYSIN,INPUT)      OPEN SYSIN                           05000000
         LA    REG1,KSYSIN         LOAD SYSIN DCB ADDRESS               05020000
         TM    OFLGS(REG1),X'10'   TEST IF SYSIN DCB HAS BEEN OPENED    05040000
         BZ    DDERROR             NOT OPENED-BRANCH TO ERR PRINT SETUP 05060000
         TM    DFLAG,X'10'              TEST FOR INVALID BLKSIZE   BS0H 05070017
         BC    8,KGTCD                  GET CONTROL CARD           BS0H 05080017
         CLOSE (KSYSIN)           IF BLKSIZE INVALID CLOSE DCB     BS0H 05090017
         FREEPOOL  KSYSIN                                          BS0H 05100017
         L     REG13,SAVE13        AND RETURN WITH ADDRESS OF      BS0H 05110017
         L     REG14,VBLKRTN              ERROR ROUTINE            BS0H 05120017
         RETURN (2,12)                                             BS0H 05130017
KGTCD    GET   KSYSIN,1(7)              GET A RECORD IN WORK AREA  BS0H 05140017
         EJECT                                                          05220000
         MVI   144(REG7),X'01'     SET NEW CARD SWITCH                  05480000
         CLC   1(2,REG7),KEND      TEST FOR LAST CARD                   05540000
         BE    KEOF                BRANCH TO END OF FILE ROUTINE        05560000
         CLI   GENLABEL+3,X'F0'        TEST GENLABEL SWITCH        UL0H 05566017
         BE    RETLABEL                 ON- RETURN TO IEBGSCAN     UL0H 05572017
         B     KGTCDR              BRANCH TO CONTINUATION TEST          05580000
*                                                                       05640000
*********************************************************************** 05660000
*        KGTCDR TESTS COLUMN 72 FOR BLANK AND SETS BIT FOR BLANK OR     05680000
*        NON-BLANK. IT TESTS THE BYPASS BIT. IF THIS IS ON,GOES TO      05700000
*        KCONT TO DETERMINE IF THE CARD BEGINS IN THE PROPER       SA0I 05704018
*        COLUMN FOR A CONTINUATION CARD (THIS SITUATION WILL       SA0I 05708018
*        ARISE IF A COMMENT IS CONTINUED OR IF AN ERROR HAS        SA0I 05712018
*        BEEN FOUND ON A CARD THAT WAS TO BE CONTINUED.)           SA0I 05716018
*        IF THE BYPASS BIT IS NOT ON, THE ROUTINE BRANCHES TO      SA0I 05720018
*        KPFOL (THIS SITUATION ARISES IF A CARD IS CONTINUED       SA0I 05724018
*        WITHOUT THE USE OF A CONTINUATION CHARACTER OR IF         SA0I 05728018
*        THE PREVIOUS CARD WAS NOT CONTINUED.)                     SA0I 05732018
*                                                                       05740000
KGTCDR   NI    DSP8(REG7),RESET0   SET BLANK SWITCH                     05760000
         CLI   DSP4(REG7),BLANKCOL TEST FOR COL 72 BLANK                05780000
         BE    SET72B              BRANCH TO SETBLANK                   05800000
         OI    DSP8(REG7),CMP5     SET SWITCH FOR COL 72 NON-BLANK      05820021
RETURN   TM    0(REG7),CMP1        TEST BYPASS SWITCH                   05840021
         BO    KCONT               GO TO CONTINUATION CARD RTN     SA0I 05860018
         B     KPFOL               NO - BYPASS                          05880018
         EJECT                                                          05900000
*                                                                       05920000
*********************************************************************** 05940000
*        PARBLANK IS ENTERED IF DELIMITER WAS A BLANK. IT CHECKS FOR    05960000
*        COMMAND WORD. IF THE BLANK IS A DELIMITER FOR A COMMAND   SA0I 05968018
*        CONTROL GOES TO KPCMD.  IF THE LENGTH IS ZERO, THE BLANK  SA0I 05976018
*        DELIMITER BIT IS SET AND CONTROL GOES TO KFORZRO.         SA0I 05984018
*        IF THE LENGTH IS NOT ZERO AND A KEYWORD IS NOT EXPECTED   SA0I 05992018
*        THE PARAMETER AND BLANK DELIMITER BITS ARE SET.  IF A     SA0I 06000018
*        KEYWORD WAS EXPECTED, THE BYPASS BIT IS TURNED ON AND     SA0I 06008018
*        CONTROL GOES TO KPASS WHERE THE ERROR BIT WILL ALSO BE    SA0I 06016018
*        TURNED ON.                                                SA0I 06024018
*                                                                       06040000
PARBLANK TM    DSP5(REG7),CMP5     TEST COMMAND SWITCH                  06060021
         BO    KPCMD               BRANCH IF COMMAND                    06080000
         TM    DSP8(REG7),CMP7     IS LENGTH EQUAL TO ZERO         SA0I 06084021
         BO    SETB                GO TO SET BLANK                 SA0I 06088018
         TM    DSP5(REG7),CMP7    IS PARAM. REQ. BIT ON ?        A55761 06092021
         BO    SETP               YES, SET PARAMETER BIT ON      A55761 06097021
         B     SETBPASS           NO, SET BYPASS BIT ON          A55761 06102021
SETB     OI    DSP10(REG7),CMP4    SET BLANK DELIMITER             SA0I 06108021
         B     KFORZRO             GO TO ZERO, COUNT ROUTINE       SA0I 06112018
SETP     OI    0(REG7),CMP6        SET PARAMETER BIT               SA0I 06116021
         OI    DSP10(REG7),CMP4    SET BLANK DELIM BIT                  06120021
         TM    DSP5(REG7),CMP3     IS PARTIAL PARAM. SWITCH ON   A41815 06130021
         BC    1,DECID             YES, DONT SET END-OF-PAR SW.  A41815 06132021
         OI    0(REG7),PRPARN      NO, SET END-OF-PAR. SW ON     A41815 06136021
*                                                                       06140000
*********************************************************************** 06150018
*        DECID CHECKS THE EXIT CONTROL SWITCH AND DELIMITER INDICATOR   06160000
*        AND OTHER PERTINENT BITS  TO DECIDE WHETHER OR NOT THERE  SA0I 06170018
*        IS A VALID FIELD TO BE PASSED TO THE ANALYSIS ROUTINE.    SA0I 06180018
*        IF NOT, THE REMAINDER OF THE CARD IS TO BE BYPASSED.      SA0I 06190018
*        THE ERROR BIT WILL BE TURNED ON IF A BLANK DELIMITER      SA0I 06200018
*        IS FOUND IN AN INVALID SITUATION.                         SA0I 06210018
*                                                                       06220000
DECID    TM    DSP8(REG7),CMP2     IS DELIM IN END COLUMN               06240021
         BO    KWENT               BRANCH IF YES TO KWENT               06260000
         TM    DSP8(REG7),CMP7     IS LENGTH EQUAL TO ZERO              06280021
         BO    KFORZRO             YES,BRANCH                           06300000
         OI    DSP5(REG7),CMP2     SET PARAM FOLLOW SWITCH              06320021
         TM    DSP10(REG7),CMP4    IS DELIM A BLANK                     06340021
         BZ    KPASS               NO, GO TO RETURN ROUTINE        SA0I 06344018
         TM    DSP5(REG7),CMP7     IS PARAMETER REQUIRED BIT ON    SA0I 06348021
         BO    KETBYP              YES, GO TO BYPASS               SA0I 06352018
         CLI   129(REG7),X'01'     IS PARENTHESES COUNTER =1       SA0I 06356018
         BE    KETBYP              YES, GO TO BYPASS               SA0I 06360018
         TM    DSP11(REG7),CMP1    WAS LAST DELIMITER A COMMA      SA0I 06364021
         BZ    SETBPASS            NO - GO TO SET BYPASS BIT       SA0I 06368018
         OI    0(REG7),CMP0        YES - TURN ON ERROR BIT         SA0I 06372021
SETBPASS OI    0(REG7),CMP1        TURN ON BYPASS BIT              SA0I 06376021
         B     KPASS               DELIMITER NOT BLANK                  06386018
*                                                                       06400000
*                                                                       06420000
KETBYP   OI    0(REG7),CMP1        SET BYPASS SWITCH ON                 06440021
         BAL   REG9,PARAN          GO TO TEST PARAN CTR                 06460000
         TM    DSP5(REG7),CMP3     IS PARTIAL PARAMETER SWITCH ON  4364 06464021
         BC    1,BKPASS            YES, DO NOT SET END-OF-         4364 06466018
*                                      PARAMETER SWITCH            4364 06468018
         OI    0(REG7),PRPARN      NO, SET END-OF-PARAMETER        4364 06470018
*                                      SWITCH ON                   4364 06472018
BKPASS   B     KPASS                                                    06476016
*                                                                       06500000
*                                                                       06520000
*********************************************************************** 06522018
*        KFORZRO HANDLES THE CASE WHERE A DELIMITER WITH NO        SA0I 06524018
*        PRECEEDING FIELD IS FOUND.(IN THIS CASE, THE LENGTH       SA0I 06526018
*        COUNTER WILL BE ZERO.)  IF THE DELIMITER WAS A BLANK,     SA0I 06528018
*        KETRDCD IS CALLED. OTHERWISE THE PROPER RETURN BITS       SA0I 06530018
*        WILL BE SET, DEPENDING ON THE DELIMITER.                  SA0I 06532018
*                                                                  SA0I 06534018
KFORZRO  SR    REG1,REG1           ZERO REGISTER                        06540000
         SR    REG2,REG2           ZERO REGISTER                        06560000
         TM    DSP10(REG7),CMP4    TEST DELIM FOR BLANK                 06580021
         BO    KETRDCD             BRANCH ON BLANK                      06600000
         OI    DSP5(REG7),CMP2     SET PARAMETER FOLLOW SWITCH          06620021
         TM    DSP10(REG7),CMP0    TEST DELIMITER FOR EQUAL SIGN        06640021
         BO    KEYSET              BRANCH IF EQUAL SIGN            SA0I 06660018
         TM    DSP10(REG7),CMP2    TEST DELIMITER FOR                   06670021
*                                      LEFT PARENTHESIS                 06680018
         BO    KPAFOL              BRANCH IF LEFT PARENTHESIS           06700018
         TM    DSP10(REG7),CMP3    TEST DELIMITER FOR                   06710021
*                                      RIGHT PARENTHESIS                06720018
         BO    LDPNTR              BRANCH IF RIGHT PARENTHESIS     SA0I 06740018
         TM    DSP11(REG7),CMP3    WAS LAST DELIMITER A                 06750021
*                                      RIGHT PARENTHESIS                06760018
         BO    KPAFOL              YES-BRANCH                           06780000
LDPNTR   LR    REG1,REG3           SAVE POINTER TO CURRENT COLUMN  SA0I 06790018
         B     KPASS               BRANCH TO KPASS                      06800000
*                                                                       06820000
*                                                                       06840000
*********************************************************************** 06842018
*        KETRDCD GETS CONTROL FROM KFORZRO WHEN A BLANK DELIMITING SA0I 06844018
*        A FIELD OF LENGTH ZERO IS FOUND. IF THE LAST DELIMITER    SA0I 06846018
*        WAS A COMMA, THE NEXT CARD IS ASSUMED TO BE A CONTINUATIONSA0I 06848018
*        CARD. OTHERWISE, PROPER RETURN BITS ARE SET, DEPENDING    SA0I 06850018
*        ON THE LAST DELIMITER.                                    SA0I 06852018
*                                                                  SA0I 06854018
KETRDCD  TM    DSP11(REG7),CMP1    WAS LAST DELIMITER A COMMA      SA0I 06864021
         BO    SETRD               YES,SET RD CD AND CONTINUATION  SA0I 06874018
*                                      SWITCHES                    SA0I 06884018
         TM    DSP11(REG7),CMP0    WAS LAST DELIMITER AN EQUAL SIGNSA0I 06894021
         BO    SET                 YES,SET ERROR AND BYPASS BITS   SA0I 06904018
         TM    DSP11(REG7),CMP2    WAS LAST DELIMITER A            SA0I 06914021
*                                      LEFT PARENTHESIS            SA0I 06924018
         BO    SET                 YES,SET ERROR AND BYPASS BITS   SA0I 06934018
         OI    0(REG7),CMP1        IF NONE OF THESE,TURN ON BYPASS SA0I 06944021
         LR    REG1,REG3           LOAD POINTER TO CURRENT COL     SA0I 06954018
         B     KPASS               GO TO RETURN ROUTINE            SA0I 06964018
SETRD    OI    DSP5(REG7),X'48'    SET RD CD AND                   SA0I 06974018
*                                      CONTINUATION SWITCHES       SA0I 06984018
         CLI   129(REG7),X'01'     IS PARENTHESES COUNTER=1             06994018
         BE    SETPRM              GO TO SET PARAMETER BIT         SA0I 07004018
         OI    DSP5(REG7),CMP6     TURN ON KEYWORD REQUIRED BIT    SA0I 07014021
         B     KGTCD               READ A NEW CARD                 SA0I 07024018
SETPRM   OI    DSP5(REG7),CMP7     TURN ON PARAMETER REQUIRED BIT  SA0I 07034021
         B     KGTCD               READ A NEW CARD                 SA0I 07044018
SET      OI    0(REG7),X'C0'       SET ERROR AND BYPASS BITS       SA0I 07054018
         LR    REG1,REG3           MOVE COLUMN POINTER TO REG 3    SA0I 07064018
         B     KPASS               GO TO RETURN ROUTINE            SA0I 07074018
*                                                                       07220000
*                                                                       07240000
KEYSET   NI    0(REG7),X'FB'       TURN OFF KEYWORD BIT            SA0I 07246018
         OI    DSP5(REG7),CMP6     TURN ON KEYWORD REQUIRED BIT    SA0I 07252021
KTERBY   OI    0(REG7),X'C0'       SET ERROR AND BYPASS BITS       SA0I 07262018
         LR    REG1,REG3           SAVE POINTER TO CURRENT COLUMN  SA0I 07272018
         B     KPASS               BRANCH TO BYPASS                     07300000
*                                                                       07320000
*                                                                       07340000
*********************************************************************** 07344018
*        KWENT GETS CONTROL IF A DELIMITER WAS FOUND IN THE        SA0I 07348018
*        END COLUMN                                                SA0I 07352018
*                                                                  SA0I 07356018
KWENT    OI    DSP5(REG7),CONT     SET RD CARD AND CONTINUE             07360000
         TM    DSP8(REG7),CMP4     TEST FOR COL 72 BLANK                07380021
         BO    KETCTBL             YES-BRANCH TO BYPASS SET             07400000
         TM    DSP8(REG7),CMP7     DOES LENGTH EQUAL ZERO               07420021
         BO    KZERO               YES-BRANCH TO DELIM TEST             07440000
         TM    DSP10(REG7),CMP4    TEST FOR DELIM BLANK                 07460021
         BO    KETBYP              BLANK-BRANCH TO BYPASS               07480000
         B     KPASS               BRANCH TO RETURN ROUTINE             07500018
*                                                                       07520000
*                                                                       07540000
*********************************************************************** 07544018
*        KZERO GETS CONTROL FROM KWENT IF COLUMN 72 IS NON -BLANK  SA0I 07548018
*        AND IF THE DELIMITER OF A ZERO LENGTH FIELD IS IN COL 71. SA0I 07552018
*                                                                  SA0I 07556018
KZERO    SR    REG1,REG1           ZERO REGISTER                        07560000
         TM    DSP10(REG7),CMP0    TEST FOR EQUAL SIGN DELIMITER        07580021
         BO    KTERBY              YES, BRANCH TO ERROR SET        SA0I 07600018
         TM    DSP10(REG7),RESETB  IS DELIMITER A COMMA OR              07610018
*                                      A RIGHT PARENTHESIS              07620018
         BZ    KGTCD               NEITHER-BRANCH TO CARD READ          07640000
         CLC   DSP10(1,REG7),DSP11(REG7)  TEST IF DELIM SAME AS LAST    07660000
         BE    KPASS                      YES-BRANCH TO BYPASS          07680000
         B     KGTCD               NO-BRANCH TO CARD READ               07700000
*                                                                       07720000
*                                                                       07740000
*********************************************************************** 07742018
*        KETCTBL IS CALLED BY KWENT IF A DELIMITER IS IN THE END   SA0I 07744018
*        COLUMN AND IF COLUMN 72 IS BLANK.IF THE DELIMITER WAS A   SA0I 07746018
*        COMMA, KETCTBL DECIDES THAT THERE SHOULD HAVE BEEN A      SA0I 07748018
*        CONTINUATION CHARACTER IN COLUMN 72.                      SA0I 07750018
*                                                                  SA0I 07752018
KETCTBL  OI    0(REG7),CMP1        SET BYPASS SWITCH                    07760021
         BAL   REG9,PARAN          CHECK PARENTHESES COUNTER            07780018
         TM    DSP8(REG7),CMP7     IS LENGTH EQUAL TO ZERO              07800021
         BO    KETLPRN             ON-BRANCH TO RIGHT PARENTHESIS       07810018
*                                      TEST                             07820018
         TM    DSP8(REG7),CMP1     IS CC1 BIT ON                   SA0I 07840021
         BO    KTERBY              YES, BRANCH TO ERROR SET        SA0I 07860018
         B     KPASS               BRANCH TO RETURN ROUTINE             07880018
*                                                                       07900000
*                                                                       07920000
KETLPRN  TM    DSP10(REG7),CMP3    IS DELIMITER A RIGHT PAREN           07940021
         BO    KPASS               YES-BRANCH TO RETURN ROUTINE         07960018
         TM    DSP10(REG7),CMP4    IS DELIMITER A BLANK                 07980021
         BO    KETBLK              YES-BRANCH TO BLANK ROUTINE          08000000
         B     KTERBY              OTHERWISE GO TO ERROR SET       SA0I 08020018
*                                                                       08040000
*                                                                       08060000
KETBLK   TM    DSP11(REG7),MSKG    WAS LAST DELIMITER A COMMA OR        08070018
*                                      A LEFT PARENTHESIS               08080018
         BZ    KPASS               NO-BRANCH TO BYPASS                  08100000
         B     KTERBY              BRANCH TO ERROR SET             SA0I 08120018
*                                                                       08140000
*                                                                       08160000
*                                                                       08220000
*                                                                       08240000
SET72B   OI    DSP8(REG7),CMP4     SET COL 72 BLANK SWITCH              08260021
         B     RETURN              BRANCH TO PRELIMINARY TEST           08280000
*                                                                       08300000
*                                                                       08320000
*********************************************************************** 08322018
*        KBYPO GETS CONTROL IF THE BYPASS BIT IS ON WHEN CCS02     SA0I 08324018
*        IS FIRST CALLED. IF THE ANALYSIS ROUTINE WAS EXPECTING    SA0I 08326018
*        A KEYWORD OR A PARAMETER, CONTROL IS GIVEN TO KPASS.      SA0I 08328018
*        OTHERWISE, KBYPO DETERMINES IF THERE ARE ANY CONTINUATION SA0I 08330018
*        CARDS WHICH SHOULD ALSO BE BYPASSED.                      SA0I 08332018
*                                                                       08334018
KBYPO    NI    0(REG7),X'FE'       TURN OFF "END OF PARAMETERS" BITSA0I 08336018
         TM    DSP5(REG7),X'03'    ARE KEYWORD REQUIRED OR         SA0I 08338018
*                                    PARAMETER REQUIRED BITS ON    SA0I 08340018
         BZ    TEST72              NO-CHECK COLUMN 72              SA0I 08342018
         NI    0(REG7),X'F7'       TURN OFF COMMAND BIT            SA0I 08344018
         LR    REG1,REG3           SAVE POINTER TO CURRENT COLUMN  SA0I 08346018
         B     KPASS               YES-GO TO RETURN ROUTINE        SA0I 08348018
TEST72   CLI   DSP4(REG7),BLANKCOL TEST FOR COLUMN 72 BLANK        SA0I 08350018
         BNE   KGTCD               NO-BRANCH TO READ NEXT CARD          08360000
         NI    0(REG7),CMP3        RESET SWITCH AREA                    08380021
         NI    DSP5(REG7),RESET0   RESET ENTRY CONTROL SWITCH           08400000
         B     KGTCD               BRANCH TO READ NEXT CARD             08420000
*                                                                       08440000
*                                                                       08460000
SETCC1   OI    DSP8(REG7),CMP1     SET CONDITION CODE 1 SWITCH          08480021
         B     TESTPAR             BRANCH TO TEST PARAMETER             08500018
*                                                                       08520000
*                                                                       08540000
SETLZ    OI    DSP8(REG7),CMP7     SET LENGTH EQUAL TO ZERO BIT         08560021
         B     DELIM               BRANCH TO DELIMITER CHECK            08580018
*                                                                       08600000
*                                                                       08620000
*********************************************************************** 08623018
*        KEY GETS CONTROL WHEN AN EQUAL SIGN DELIMITER IS FOUND    SA0I 08626018
*        IF A COMMAND HAS NOT PREVIOUSLY BEEN FOUND, THE ERROR     SA0I 08629018
*        BIT IS SET.                                               SA0I 08632018
*                                                                       08635018
KEY      CLI   SYNSW,X'01'         TEST IF SYNSW SET TO 1               08645018
         BE    SETSYN              YES, GO TO RESET SYNSW          SA0I 08655018
         OI    0(REG7),CMP5        NO, TURN ON KEYWORD BIT         SA0I 08665021
         B     KTERBY              GO TO ERROR SET                 SA0I 08675018
SETSYN   MVI   SYNSW,X'00'         SET SYNSW TO ZERO               SA0I 08685018
         OI    0(REG7),CMP5        SET KEYWORD BIT                      08695021
         OI    DSP10(REG7),CMP0    SET DELIMITER BIT - EQUAL            08715021
         B     DECID               BRANCH TO EXIT CHECK                 08740000
*                                                                       08760000
*                                                                       08780000
PARAMC   OI    0(REG7),CMP6        SET PARAMETER BIT                    08800021
         OI    DSP10(REG7),CMP1    SET DELIMITER BIT-COMMA              08820021
         MVI   SYNSW,X'01'         SET SYNSW                            08840000
         B     DECID               BRANCH TO EXIT CHECK                 08860000
*                                                                       08880000
*                                                                       08900000
PARAMLP  OI    0(REG7),CMP6        SET PARAMETER BIT                    08920021
         OI    DSP10(REG7),CMP2    SET DELIMITER BIT -                  08930021
*                                      LEFT PARENTHESIS                 08940018
         BAL   REG9,ADD            BAL TO COUNTER ADD                   08960000
         B     DECID               BRANCH TO EXIT CHECK                 08980000
*                                                                       09000000
*                                                                       09020000
PARAMRP  OI    0(REG7),PRPARN      SET PARAMETER BIT AND                09030018
*                                      END-OF-PARAMETER BIT             09040018
         OI    DSP10(REG7),CMP3    SET DELIMITER BIT -                  09050021
         CLI   1(REG3),RPARN       ARE THERE 2 RIGHT PARENTHESES A32633 09053020
         BE    KPASERR             YES, ERROR BRANCH             A32633 09056020
*                                      RIGHT PARENTHESIS                09060018
         BAL   REG9,SUBT           BAL TO SUBTRACT UNATTACHED           09070018
*                                      PARENTHESIS                      09080018
         B     DECID               BRANCH TO EXIT CHECK                 09100000
*                                                                       09120000
*                                                                       09140000
PRFOL    OI    DSP5(REG7),CMP2     SET PARAMETER FOLLOW SWITCH          09160021
         B     KPASS               BRANCH TO RETURN ROUTINE             09180018
*                                                                       09200000
*                                                                       09220000
KINVAL   OI    0(REG7),X'C0'       TURN ON ERR AND BYPASS  BITS    SA0I 09240018
         LA    REG2,ONE(0,REG2)    ADJUST TO NEXT DELIMITER             09260000
         LA    REG3,ONE(0,REG3)    INCREMENT POINTER                    09280000
         CLI   0(REG3),X'5B'       TEST FOR DOLLAR SIGN                 09300018
         BE    NOTDELIM                                                 09320000
         CLI   0(REG3),X'7B'       TEST FOR POUND SIGN                  09340018
         BE    NOTDELIM                                                 09360000
         CLI   0(REG3),X'7C'       TEST FOR AT SIGN                     09370018
         BE    NOTDELIM            IF "AT" SIGN BRANCH TO NOTDELIM SA0I 09380018
         CLI   0(REG3),KSPLT       CHECK FOR DELIMITER                  09400000
         BL    KINV                INVALID DELIMITER                    09420000
NOTDELIM CR    REG3,REG5          TEST IF END COLUMN                    09440000
         BL    KINVAL              NOT END-CONTINUE CHECKING            09460000
         TM    DSP8(REG7),CMP4     TEST IF COLUMN 72 BLANK              09480021
         BO    KTERBY              YES-BRANCH TO ERROR BYPASS           09500000
         LA    REG2,ONE(0,REG2)    INCREMENT POINTER                    09520000
         B     KPTERR              BRANCH TO LENGTH CHECK               09540000
*                                                                       09560000
*                                                                       09580000
*********************************************************************** 09582018
*        KCONT GETS CONTROL WHEN A CONTINUATION CARD HAS BEEN      SA0I 09584018
*        READ. IT FIRST CHECKS TO SEE THAT THE CARD BEGINS IN      SA0I 09586018
*        THE PROPER COLUMN.  IF THE CARD WAS TO BE BYPASSED,       SA0I 09588018
*        CONTROL IS GIVEN TO KPASS.  OTHERWISE CONTROL IS GIVEN    SA0I 09590018
*        TO SCANR, THE SCAN ROUTINE.                               SA0I 09592018
*                                                                       09594018
KCONT    CLC   1(3,REG7),BLANKS    ARE FIRST THREE COLUMNS ON      SA0I 09599018
*                                     CONTINUATION CARD BLANK      SA0I 09604018
         BNE   SETBITS             NO, GO TO SET ERR,BYPASS BITS   SA0I 09609018
         LA    REG3,DSP1(REG7)     SET PNTR TO CONTINUATION COL.(4)SA0I 09614018
         TM    0(REG7),CMP1        IS BYPASS BIT ON                SA0I 09619021
         BO    KPASS               YES, GO TO RETURN ROUTINE       SA0I 09624018
CHKBLNK  CLI   0(REG3),X'40'       IS CURRENT COL BLANK            SA0I 09629018
         BNE   RESET               NO,GO TO RESET DELIMITERS       SA0I 09634018
         LA    REG3,ONE(REG3)      ELSE, SET POINTER TO NEXT COL   SA0I 09639018
         TM    DSP10(REG7),CMP5    IS THIS A LITERAL               SA0I 09644021
         BZ    LOADAD              NO, CHECK FOR COL. 17           SA0I 09649018
         LA    REG5,DSP2(REG7)     LOAD ADDRESS OF COL. 16         SA0I 09654018
         CR    REG3,REG5           IS THIS COL. 16                 SA0I 09659018
         BE    RESET               YES, GO TO RESET DELIMITER      SA0I 09664018
         B     CHKBLNK             NO, GO TO CHECK FOR BLANK COL.  SA0I 09669018
LOADAD   LA    REG5,DSP17(REG7)    LOAD ADDRESS OF COL. 17         SA0I 09674018
         CR    REG3,REG5           IS POINTER SET TO COL 17        SA0I 09679018
         BNE   CHKBLNK             NO,GO TO CHK FOR BLNK COL.      SA0I 09684018
SETBITS  OI    0(REG7),X'C0'       YES,SET ERR AND BYPASS BITS     SA0I 09689018
         NI    DSP5(REG7),X'FC'    TURN OFF KEYWORD REQUIRED BIT   SA0I 09694018
*                                      AND PARAMETER REQUIRED BIT  SA0I 09699018
         B     KPASS               GO TO RETURN ROUTINE            SA0I 09704018
RESET    NI    DSP10(REG7),RESET0  RESET DELIMITER INDICATORS      SA0I 09709018
         B     SCANR               GO TO SCAN ROUTINE              SA0I 09714018
*                                                                       09720000
*                                                                       09740000
*********************************************************************** 09741018
*        KPART GETS CONTROL WHEN A FIELD EXTENDS INTO COLUMN       SA0I 09742018
*        71.  IF A CONTINUATION CHARACTER HAS BEEN CODED IN        SA0I 09743018
*        COLUMN 72, THE FIELD IS TO BE CONTINUED ON THE NEXT       SA0I 09744018
*        CARD.  IN THIS CASE, THE PARTIAL PARAMETER SWITCH IS      SA0I 09745018
*        TURNED ON AND THE FIRST PART OF THE FIELD IS MOVED INTO   SA0I 09746018
*        A SPECIAL BUFFER AREA WHILE ITS LENGTH IS STORED.  THE    SA0I 09747018
*        CONTINUATION BIT IS ALSO SET AND A NEW CARD IS READ INTO  SA0I 09748018
*        THE REGULAR BUFFER.                                       SA0I 09749018
*                                                                       09750018
KPART    TM    DSP5(REG7),CMP3     TEST IF PARTIAL PARAM SWITCH ON      09760021
         BO    KTERBY              YES-BRANCH TO ERROR BYPASS           09780000
         OI    DSP8(REG7),CMP0     SET CCO BIT                          09800021
KPTERR   OI    DSP5(REG7),CMP3     SET PARTIAL PARAMETER SWITCH ON      09820021
         TM    DSP8(REG7),CMP4     TEST FOR COL 72 BLANK                09840021
         BO    KLAST               ON-BRANCH TO PARAMETER SET           09860018
         MVI   DSP7(REG7),CMP1             MOVE BLANK TO WORK AREA      09880021
         MVC   DSP7+1(43,REG7),DSP7(REG7)  MOVE BLANK CHARACTERS        09900000
         STC   REG2,DSP6(0,REG7)   STORE PARTIAL PARAMETER LENGTH       09920018
         BCTR  REG2,REG0           ADJUST LENGTH FOR MOVE               09940000
         EX    REG2,MOVEP          MOVE PARTIAL PARAMETER               09950018
*                                     TO WORK AREA                      09960018
         OI    DSP5(REG7),CMP1     SET CONTINUE BIT                     09980021
         B     KCDFL               BRANCH TO COL 72 TEST                10000000
*                                                                       10020000
*                                                                       10040000
KLAST    OI    0(REG7),CMP6        SET PARAMETER BIT                    10050021
         NI    DSP5(REG7),X'EF'    TURN PARTIAL PARAMETER          SA0I 10060018
*                                      SWITCH OFF                  SA0I 10070018
         B     KETBYP              BRANCH TO SET BYPASS BIT             10080000
*                                                                       10100000
*                                                                       10120000
*********************************************************************** 10122018
*        KPPAR GETS CONTROL WHEN THE SECOND HALF OF A SPLIT FIELD  SA0I 10124018
*        IS FOUND. IT MOVES THIS SECOND PART INTO THE SAME SPECIAL SA0I 10126018
*        BUFFER AREA USED BY KPART TO STORE THE FIRST HALF OF THE  SA0I 10128018
*        FIELD.  THE TWO PARTS ARE JOINED TOGETHER AND THE FIELD   SA0I 10130018
*        IS PASSED TO THE ANALYSIS ROUTINE AS IF IT WERE A         SA0I 10132018
*        NORMAL FIELD.                                             SA0I 10134018
*                                                                       10136018
KPPAR    SR    REG4,REG4           ZERO REGISTER                        10140000
         IC    REG4,DSP6(0,REG7)   TEST PARAMETER LENGTH                10160000
         LR    REG6,REG4           FIRST LENGTH IN INDEX                10180000
         AR    REG4,REG2           ADD PARTIAL LENGTH                   10200000
         CH    REG4,FOUR4          COMPARE LENGTH TO MAXIMUM            10220000
         BH    KTERBY              HIGH-BRANCH TO ERROR BYPASS          10240000
         LA    REG4,DSP7(REG6,REG7)    INITIALIZE THE REGISTER     SA0I 10242018
*                                      SO THAT THE PARTIAL         SA0I 10244018
*                                      PARAMETER MAY BE MOVED      SA0I 10246018
         CLI   0(REG3),EQUAL       TEST FOR EQUAL SIGN             SA0I 10248018
         BE    SKIPDCR             YES - DO NOT DECREMENT LENGTH   SA0I 10250018
*                                      COUNTER, SO THAT EQUAL SIGN SA0I 10252018
*                                      WILL ALSO BE MOVED INTO     SA0I 10254018
*                                      PARTIAL PARAMETER BUFFER    SA0I 10256018
         SR    REG4,REG4           ZERO REGISTER                        10260000
         AR    REG4,REG2           PARTIAL LENGTH                       10280000
         BE    KOMPL               PART ZERO,ALL IN HOLD                10300000
         LA    REG4,DSP7(REG6,REG7)    INITIALIZE THE REGISTER     SA0I 10310018
*                                      SO THAT THE PARTIAL         SA0I 10320018
*                                      PARAMETER MAY BE MOVED      SA0I 10330018
         BCTR  REG2,REG0           DECREMENT FOR EXECUTE                10340000
         EX    REG2,MOVPP          MOVE PARAMETER                       10360018
         LA    REG2,ONE(0,REG2)    INCREMENT LOCATION REGISTER          10380000
         B     KOMPL               BRANCH TO LENGTH COMPUTATION    SA0I 10385018
SKIPDCR  EX    REG2,MOVPP          MOVE KEYWORD INTO PARTIAL       SA0I 10390018
*                                      PARAMETER BUFFER            SA0I 10395018
KOMPL    SR    REG4,REG4           ZERO REGISTER                        10400000
         IC    REG4,DSP6(0,REG7)   COMPUTE LENGTH AND                   10420000
         AR    REG2,REG4           PLACE IN REGISTER2                   10440000
         LA    REG1,DSP7(0,REG7)   ADDRESS OF HOLD AREA                 10460000
         NI    DSP8(REG7),RESET10  RESET EXIT CONTROL SWITCH            10470018
*                                      TO ZERO                          10480018
         OI    DSP8(REG7),MSKE     SET CC1 AND LENGTH GREATER THAN ZERO 10500000
         MVC   DSP11(ONE,REG7),DSP10(REG7)     MOVE PRESENT TO          10510018
*                                      LAST DELIMITER                   10520018
         NI    DSP10(REG7),RESET0  SET PRESENT DELIMITER TO ZERO        10540018
         NI    DSP5(REG7),RESET6   RESET PARTIAL PARAMETER SWITCH       10560018
         B     DELIM               BRANCH TO DELIMITER CHECK            10580000
*                                                                       10600000
*                                                                       10620000
*********************************************************************** 10621018
*        KPASS RETURNS CONTROL TO THE CALLING ANALYSIS ROUTINE.    SA0I 10622018
*        IT FIRST CHECKS VARIOUS COMBINATIONS OF BITS TO DETERMINE SA0I 10623018
*        IF AN ERROR CONDITION IS PRESENT. THE COMBINATION OF      SA0I 10624018
*        ERROR, BYPASS, COMMAND, KEYWORD, PARAMETER, KEYWORD       SA0I 10625018
*        REQUIRED, AND PARAMETER REQUIRED BITS TELLS THE CALLING   SA0I 10626018
*        ROUTINE EXACTLY WHAT TYPE OF INFORMATION IS BEING PASSED, SA0I 10627018
*        AND IF AN ERROR CONDITION EXISTS,JUST WHAT TYPE OF ERROR  SA0I 10628018
*        IT IS.                                                    SA0I 10629018
*                                                                       10630018
KPASS    LA    REG3,ONE(0,REG3)    SET POINTER TO NEXT COLUMN           10640000
         TM    0(REG7),X'C0'      BYPASS AND ERROR BITS ON ?     A55761 10641021
         BNO   KPASS2             NO, CONTINUE CHECKING          A55761 10642021
         TM    0(REG7),X'08'      COMMAND BIT ON ?               A55761 10643021
         BO    KPASS2             YES, LEAVE ERROR BIT ON        A55761 10644021
         TM    DSP5(REG7),CMP6    IS KEYW.  REQ. BIT ON ?        A55761 10645021
         BO    KPASS2             YES, LEAVE ERROR BIT ON        A55761 10646021
         TM    DSP5(REG7),CMP7    IS PARAM. REQ. BIT ON ?        A55761 10647021
         BO    KPASS2             YES, LEAVE ERROR BIT ON        A55761 10648021
         NI    0(REG7),X'7F'      SET OFF ERR. BIT , BEC. COMM.  A55761 10649021
KPASS2   EQU   *                  CONTINUE CHECKING              A55761 10650021
         TM    0(REG7),X'0C'       COMMAND AND KEYWORD BOTH ON          10660000
         BO    KPASERR             YES-BRANCH TO ERROR SET              10680000
         TM    0(REG7),X'0A'       COMMAND AND PARAMETER BOTH ON?       10700000
         BO    KPASERR             YES-BRANCH TO ERROR SET              10720000
         TM    0(REG7),CMP6        IS PARAMETER BIT ON             SA0I 10721021
         BZ    TESTKEY             NO-CHECK KEYWORD BIT            SA0I 10722018
         TM    DSP5(REG7),CMP6     IS KEYWORD REQUIRED BIT ON      SA0I 10723021
         BO    PAROFF              YES-BRANCH TO TURN OFF PARAMETERSA0I 10724018
*                                  BIT                             SA0I 10725018
TESTKEY  TM    0(REG7),CMP5        IS KEYWORD BIT ON               SA0I 10726021
         BZ    CHKBYP              NO-CHECK BYPASS BIT             SA0I 10727018
         TM    DSP5(REG7),CMP7     IS PARAMETER REQUIRED BIT ON    SA0I 10728021
         BO    KEYOFF              YES-BRANCH TO TURN OFF KEYWORD  SA0I 10729018
*                                  BIT                             SA0I 10730018
CHKBYP   TM    0(REG7),CMP1        IS BYPASS BIT ON                SA0I 10731021
         BZ    KPASS1              NO, SKIP ERROR SET              SA0I 10732018
         TM    0(REG7),CMP7        IS END-OF-PARAMETER BIT ON      SA0I 10733021
         BO    KPASS1              YES, RETURN TO ANALYSIS ROUTINE SA0I 10734018
         TM    DSP5(REG7),CMP6     IS KEYWORD REQUIRED BIT ON      SA0I 10735021
         BZ    PTEST               NO, TEST PARAMETER REQUIRED BIT SA0I 10736018
         B     KPASERR             GO TO ERROR SET                 SA0I 10737018
PTEST    TM    DSP5(REG7),CMP7     IS PARAMETER REQUIRED BIT ON    SA0I 10738021
         BZ    ETEST               NO, TEST ERROR BIT              SA0I 10739018
         B     KPASERR             GO TO ERROR SET                 SA0I 10740018
ETEST    TM    0(REG7),CMP0        IS ERROR BIT ON                 SA0I 10741021
         BO    KPASS1              IF SO, SKIP ERROR SET           SA0I 10742018
         CLI   144(REG7),X'01'     IS NEW CARD SWITCH ON           SA0I 10743018
         BE    KPASS1              YES,SKIP ERROR SET              SA0I 10744018
         TM    DSP8(REG7),CMP4     IS COL. 72 BLANK                SA0I 10745021
         BZ    KGTCD               NO,READ NEXT CARD AS            SA0I 10746018
*                                      CONTINUATION CARD           SA0I 10747018
         NI    0(REG7),X'BF'       TURN OFF BYPASS BIT ONLY        SA0I 10748018
         NI    DSP5(REG7),RESET0   RESET ENTRY CONTROL SWITCHES    SA0I 10749018
         B     KGTCD               NO, READ A NEW CARD             SA0I 10750018
PAROFF   NI    0(REG7),X'FD'       TURN OFF PARAMETER BIT          SA0I 10756018
         B     KPASERR             BRANCH TO ERROR SET             SA0I 10762018
KEYOFF   NI    0(REG7),X'FB'       TURN OFF KEYWORD BIT            SA0I 10768018
KPASERR  OI    0(REG7),X'C0'       SET ERROR AND BYPASS BITS       SA0I 10774018
KPASS1   NI    DSP5(REG7),X'EB'    RESET PARTIAL PARAM SWITCH           10780000
         NI    140(REG7),X'00'     RESET CARD SEQUENCE SWITCH           10800018
         ST    REG3,DSP13(0,REG7)  SAVE POINTER TO NEXT PARAMETER       10820000
         NI    KA+1,X'0F'          SET INLINE SWITCH-                   10840000
         OI    KB+1,X'70'          SET INLINE SWITCH --TO ORIGINAL      10860000
         NI    KC+1,X'0F'          SET INLINE SWITCH-                   10880000
         LR    REG0,REG2           LOAD PARAMETER LENGTH                10900018
RETLABEL LM    REG13,REG14,SAVE13       RESTORE REGISTERS               10920000
         RETURN  (2,12)                                                 10940000
*********************************************************************** 10942018
*        KPCMD RECEIVES CONTROL WHEN A BLANK DELIMITER IS FOUND    SA0I 10944018
*        AT THE END OF A COMMAND FIELD.  THE COLUMN POINTER IS     SA0I 10946018
*        INCREMENTED UNTIL THE FIRST NON-BLANK COLUMN IS FOUND     SA0I 10948018
*        OR UNTIL THE END COLUMN IS HIT.                           SA0I 10950018
*                                                                       10952018
KPCMD    MVI   SYNSW,X'01'         SET SWITCH                           10960000
KPCMD2   LA    REG3,ONE(0,REG3)    INCREMENT POINTER                    10980000
         CLI   0(REG3),BLANKCOL    TEST FOR BLANK COLUMN                11000000
         BNE   KPCMA               NOT BLANK-BRANCH TO KPCMA            11020000
         CR    REG5,REG3           TEST FOR END COLUMN                  11040000
         BNE   KPCMD2              NOT END, INCREMENT COUNTER      SA0I 11050018
*                                          AND CONTINUE            SA0I 11060018
         OI    0(REG7),X'41'       TURN ON BYPASS AND END OF       SA0I 11070018
*                                          PARAMETERS BITS         SA0I 11080018
         OI    DSP15(REG7),X'0F'   SET RECORD WITHOUT PARAM SW  SA61471 11082000
         B     KPASS               GO TO RETURN ROUTINE            SA0I 11090018
*                                                                       11100000
*                                                                       11120000
KPCMA    CLI   0(REG3),COMMA       TEST FOR COMMA                       11140000
         BE    KTERBY              YES-BRANCH TO ERROR BYPASS           11160000
         BCTR  REG3,REG0           DECREMENT LOCATION FOR TEST          11180000
         OI    DSP10(REG7),CMP4    TURN ON BLANK DELIMITER BIT     SA0I 11190021
         B     PRFOL               BRANCH TO PARAMETER FOLLOW SET       11200018
*                                                                       11220000
*                                                                       11240000
KSETP    OI    DSP5(REG7),CMP3     SET PARAMETER FOLLOW BIT             11260021
         LA    REG2,ONE(REG0,REG2) ADJUST LENGTH                        11280000
         B     KPTERR              BRANCH TO PARAMETER SET              11300018
*                                                                       11320000
*                                                                       11340000
KINV     TM    DSP5(REG7),CMP5     TEST FOR COMMAND CONTROL SWITCH      11360021
         BO    KPCMD               YES-BRANCH TO SWITCH SET             11380000
         OI    0(REG7),CMP6        TURN ON PARAMETER BIT           SA0I 11390021
         B     PRFOL               BRANCH TO PARAMETER FOLLOW SET       11400018
*                                                                       11420000
*                                                                       11440000
KCDFL    TM    DSP8(REG7),CMP5     TEST COL 72 NON-BLANK                11460021
         BO    KGTCD               NON-BLANK,BRANCH TO READ NEW CARD    11480000
         OI    0(REG7),CMP0        SET ERROR                            11500021
KBYPS    OI    0(REG7),CMP1        SET BYPASS                           11520021
         B     KPASS               BRANCH TO BYPASS                     11540000
*                                                                       11560000
*                                                                       11580000
SUBT     LH    REG4,DSP9(REG0,REG7)    DELIMITER WAS A                  11590018
*                                      RIGHT PARENTHESIS                11600018
         BCTR  REG4,REG0            SUBTRACT ONE FROM COUNTER           11620000
         STH   REG4,DSP9(REG0,REG7) STORE UPDATED COUNTER               11640000
         NI    DSP5(REG7),X'FE'    TURN OFF PARAMETER REQ BIT    A30916 11650019
         LTR   REG4,REG4           TEST COUNTER FOR ZERO                11660000
         BNL   KACK                OK-BRANCH TO ESCAPE                  11680000
         OI    0(REG7),CMP0        SET ERROR                            11700021
KACK     BR    REG9                BRANCH BACK TO NEXT SEQUENTIAL       11710018
*                                     INSTRUCTION AFTER BAL             11720018
*                                                                       11740000
*                                                                       11760000
ADD      LH    REG4,DSP9(REG0,REG7)    DELIMITER WAS A                  11770018
*                                      LEFT PARENTHESIS                 11780018
         LA    REG4,ONE(REG0,REG4)  ADD ONE TO COUNTER                  11800000
         STH   REG4,DSP9(REG0,REG7) STORE UPDATED COUNTER               11820000
         BR    REG9                BRANCH BACK TO NEXT SEQUENTIAL       11830018
*                                      INSTRUCTION AFTER BAL            11840018
*                                                                       11860000
*                                                                       11880000
EOFRET   NI    0(REG7),CMP2        TURN OFF ALL BITS EXCEPT EOF    SA0I 11884021
         B     RETLABEL            RETURN TO ANALYSIS ROUTINE      SA0I 11888018
*                                                                       11892018
*                                                                       11896018
KPAFOL   LA    REG3,ONE(REG0,REG3) ADJUST POINTER TO NEXT COLUMN        11900000
         B     SCANR               BRANCH TO READ NEXT CARD             11920000
*                                                                       11940000
*                                                                       11960000
KINVALD  OI    0(REG7),CMP0        SET ERROR                            11980021
         TM    DSP8(REG7),CMP2     TEST IF DELIMITER IS IN END COL      12000021
         BO    KSETP               BRANCH TO PARAMETER FOLLOW SET       12020018
         B     KINVAL              BRANCH TO INVALID DELIMITER ROUTINE  12040000
*                                                                       12060000
*                                                                       12080000
ZRPARN   OI    0(REG7),CMP6        TURN ON PARAMETER BIT           SA0I 12083021
         SR    REG4,REG4           ZERO REGISTER FOUR              SA0I 12086018
         STH   REG4,DSP9(REG7)     RESET PARENTHESES COUNTER       SA0I 12089018
*                                      TO ZERO                     SA0I 12092018
         B     KPASS               GO TO RETURN ROUTINE            SA0I 12095018
KEOF     NI    0(REG7),X'00'       RESET SWITCH AREA                    12105018
         OI    0(REG7),X'20'       SET EOF SWITCH                       12120000
         BAL   REG9,PARAN          BRANCH TO PARENTHESES COUNTER        12130018
*                                      CHECK                            12140018
KEOF2    CLOSE (KSYSIN)            CLOSE SYSIN                          12160000
         FREEPOOL  KSYSIN                                          BS0H 12169017
         LR    REG1,REG9                                         A27717 12175019
         B     RETLABEL                                          A27717 12181019
*                                                                       12187017
*                                                                       12196017
PARAN    SR    REG4,REG4           ZERO WORK REGISTER                   12205017
         AH    REG4,128(REG0,REG7) LOAD PARENTHESIS COUNT               12214017
         BZ    OKAY                COUNT ZERO-BRANCH TO ESCAPE          12223017
         OI    0(REG7),X'80'       NON-ZERO,SET ERROR                   12232017
         OI    DSP10(REG7),CMP6    TURN ON PARENTHESES-            SA0I 12233021
*                                     NOT-CLOSED BIT               SA0I 12234018
         SR    REG4,REG4           ZERO REGISTER 4                 SA0I 12235018
         STH   REG4,DSP9(REG7)     RESET PARENTHESES COUNTER TO 0  SA0I 12236018
OKAY     BR    REG9                BRANCH TO NEXT SEQUENTIAL            12240018
*                                      INSTRUCTION AFTER BAL            12244018
*                                                                       12250017
*                                                                       12259017
DDERROR  LA    REG2,DDNAME(REG1)   ADDRESS OF DDNAME IN DCB             12268017
         L     REG1,VMSG           ADDRESS OF ERROR MESSAGE             12277017
         MVC   7(8,REG1),0(REG2)   MOVE DDNAME TO ERROR MESSAGE         12286017
         L     REG13,SAVE13        RESTORE REGISTER                     12295017
         L     REG14,VADDR         WHERE TO GO IN ANALYZER ROUTINE      12304017
         RETURN  (2,12)                                                 12313017
DCBEXITN LA    REG3,KSYSIN                                         BS0H 12322017
         LH    REG5,BLKSI(REG3)                                    BS0H 12331017
         OR    REG5,REG5                                           BS0H 12340017
         BC    8,DCBSIZ                 IF NONE SPECIFIED --       BS0H 12349017
         LA    REG6,80                                             BS0H 12358017
         SR    REG4,REG4                                           BS0H 12367017
         DR    REG4,REG6                                           BS0H 12376017
         LTR   REG4,REG4                TEST FOR MODULAR BLKSIZE   BS0H 12385017
         BC    2,BLKERR                 IF NOT MODULAR --          BS0H 12394017
         RETURN                                                         12403017
         USING IHADCB,REG3                                         BS0H 12412017
DCBSIZ   MVI   DCBBLKSI+1,X'50'         INSERT BLKSIZE -- 80       BS0H 12421017
         RETURN                                                         12430017
BLKERR   MVI   DFLAG,X'10'              SET BLKSIZE ERROR SWITCH   BS0H 12439017
         MVC   DCBBLKSI(2),DCBLRECL     MOVE LRECL TO BLKSIZE      BS0H 12448017
         DROP  REG3                                                BS0H 12457017
         RETURN                                                         12477017
*                                                                       12500000
*                                                                       12520000
*                                                                       12540000
MOVEP    MVC   DSP7(ONE,REG7),0(REG1)   MOVE FOR EXECUTE                12560000
MOVPP    MVC   0(ONE,REG4),0(REG1)      MOVE FOR EXECUTE                12580000
*                                                                       12600000
         EJECT                                                          12620000
*********************************************************************** 12640000
*                                                                       12660000
*              CCS02 CONSTANTS AND DCB                                  12680000
*                                                                       12700000
GENLABEL DC    F'0'                NO-SCAN SWITCH,SET BY IEBGSCAN  UL0H 12710017
KEND     DC    C'/*'                                                    12720000
EODA     DC    AL3(KEOF)                                                12740000
         EXTRN DDERROR1                                                 12760000
VMSG     DC    A(DDERROR1)                                              12780000
         EXTRN DDRTN                                                    12800000
VADDR    DC    A(DDRTN)                                                 12820000
         EXTRN BLKRTN                                              BS0H 12830017
VBLKRTN  DC    A(BLKRTN)                                           BS0H 12840017
*                                                                       12850017
KSYSIN   DCB   DSORG=PS,MACRF=(GM),DDNAME=SYSIN,RECFM=FB,LRECL=80, BS0H*12860017
               EXLST=OPT,EODAD=KEOF,SYNAD=KERR                     BS0H 12870017
OPT      DC    X'85'                                               BS0H 12880017
         DC    AL3(DCBEXITN)                                       BS0H 12890017
DFLAG    DC    X'00'                                               BS0H 12900017
*                                                                       12920000
*                                                                       12940000
KERR     SYNADAF ACSMETH=QSAM                                    A27717 12945019
         LR    REG9,REG1               SAVE POINTER TO SYNAD INFOA27717 12950019
         LA    REG1,79                 GET STORAGE TO SAVE       A27717 12955019
         GETMAIN  R,LV=(1)             SYNAD INFO                A27717 12960019
         MVC   0(79,REG1),49(REG9)     MOVE SYNAD INFO TO GOTTEN A27717 12965019
         LR    REG9,REG1               CORE AND SAVE POINTER     A27717 12970019
         SYNADRLS                                                A27717 12975019
         LR    REG1,REG9               RESTORE POINTER           A27717 12980019
         MVI   144(REG7),X'02'         SET INPUT ERROR SWITCH    A27717 12985019
         B     KEOF2                   BRANCH TO CLOSE           A27717 12990019
*                                                                       13000000
*                                                                       13020000
SYNSW    DC    X'00'                                                    13040000
*                                                                       13060000
*              CONSTANTS                                                13080000
*                                                                       13100000
KREGSAVE DS    18F                 REGISTER SAVE AREA                   13120000
KDCBSAVE DS    20F                 SYSIN DCB SAVE AREA                  13140000
KSIDD    DS    2F                  USER DDNAME AREA                     13160000
SAVE13   DS    2F                  REGISTERS 13-14 SAVE AREA            13180000
FOUR3    DC    F'43'                                              M3310 13200018
         DS    0F                                                       13220018
EIGHT    DC    X'00000008'                                         SA0I 13240018
FOUR4    DC    H'44'                                                    13280000
BLANKS   DC    CL3' '                                              SA0I 13300018
*                                                                       13320000
*              REGISTER EQUATES                                         13340000
*                                                                       13360000
REG0     EQU   0                                                        13380000
REG1     EQU   1                                                        13400000
REG2     EQU   2                                                        13420000
REG3     EQU   3                                                        13440000
REG4     EQU   4                                                        13460000
REG5     EQU   5                                                        13480000
REG6     EQU   6                                                        13500000
REG7     EQU   7                                                        13520000
REG8     EQU   8                                                        13540000
REG9     EQU   9                                                        13560000
REG10    EQU   10                                                       13580000
REG11    EQU   11                                                       13600000
REG12    EQU   12                                                       13620000
REG13    EQU   13                                                       13640000
REG14    EQU   14                                                       13660000
GO       EQU   15                                                       13680000
*                                                                       13700000
*              EQUATE BIT SWITCHES                                      13720000
*                                                                       13740000
CMP0     EQU   X'80'          SET  ERROR,CC0                            13760021
CMP1     EQU   X'40'          SET  BYPASS,CONT,CC1                      13780021
CMP2     EQU   X'20'          SET  EOF,PARAM FOLL,CC2                   13800021
CMP3     EQU   X'10'          SET  FIRST ENTRY,PARTIAL PARAM            13820021
CMP4     EQU   X'08'          SET  COMMAND,RDCD,COL72 NON-BLANK         13840021
CMP5     EQU   X'04'           SET KEYWORD,CSWITCH,COL72 NON-BLANK      13860021
CMP6     EQU   X'02'          SET  PARAM,L70                            13880021
CMP7     EQU   X'01'          SET  RPAREN,L=0                           13900021
*                                                                       13920000
*              RESET EQUATES                                            13940000
*                                                                       13960000
CMP8     EQU   X'14'         RESET ENTRY CONTROL SWITCH                 13980021
RESET0   EQU   X'00'         RESET TO ZERO                              14000000
RESET1   EQU   X'F7'         RESET COMMAND,RDCD,COL 72 BLANK            14020000
RESET2   EQU   X'98'         RESET ALL BUT ERR,FST ENT,COMM             14040000
RESET6   EQU   X'EF'         RESET PART PARM SWITCH                     14060000
RESET10  EQU   X'0C'         RESET EXIT CONTROL SWITCH                  14080000
RESETB   EQU   X'50'               TEST COMMA OR RIGHT PAREN            14100000
*                                                                       14120000
CC0      EQU   8                   CONDITION CODE CMP0=8                14140021
CC1      EQU   4                   CONDITION CODE CMP1=4                14160021
CONT     EQU   X'48'               SETS ENTRY CONTROL SWITCH            14180000
ONE      EQU   1                                                        14200000
KSPLT    EQU   X'7F'               DELIMITER TEST                       14220000
*                                                                       14240000
*              WORK AREA DISPLACEMENTS                                  14260000
*                                                                       14280000
DSP1     EQU   4                                                   SA0I 14290018
DSP2     EQU   16                  COL 16 OF CARD                       14300000
DSP3     EQU   71                  COL 71 OF CARD                       14320000
DSP4     EQU   72                  COL 72 (CONTINUATION)                14340000
DSP5     EQU   81                  ENTRY CONTROL SWITCH                 14360000
DSP6     EQU   82                  LENGTH OF PARTIAL PARAMETER          14380000
DSP7     EQU   83                  PARTIAL PARAMETER                    14400000
DSP8     EQU   127                 EXIT CONTROL SWITCH                  14420000
DSP9     EQU   128                 PARENTHESIS COUNTER                  14440000
DSP10    EQU   130                 PRESENT DELIMITER INDICATOR          14460000
DSP11    EQU   131                 LAST DELIMITER INDICATOR             14480000
DSP13    EQU   136                 SAVE NEXT PARAMETER POINTER          14500000
DSP15    EQU   141                 RECORD WITHOUT PARAM SW      SA61471 14502000
DSP17    EQU   17                                                  SA0I 14510018
*                                                                       14520000
*              TEST CONSTANTS                                           14540000
*                                                                       14560000
EQUAL    EQU   C'='                                                     14580000
COMMA    EQU   C','                                                     14600000
BLANKCOL EQU   C' '                                                     14620000
LPARN    EQU   C'('                                                     14640000
RPARN    EQU   C')'                                                     14660000
PERIOD   EQU   C'.'                                                     14680000
MINUS    EQU   C'-'                                                     14700000
PRPARN   EQU   X'03'                                                    14720000
EQRPN    EQU   X'90'                                                    14740000
MSKE     EQU   X'42'                                                    14760000
MSKG     EQU   X'60'                                                    14780000
*                                                                       14800000
         DCBD  DSORG=PS                                                 14820000
DDNAME   EQU   DCBDDNAM-IHADCB                                          14840000
BLKSI    EQU   DCBBLKSI-IHADCB                                          14860000
OFLGS    EQU   DCBOFLGS-IHADCB                                          14880000
         END                                                            14900000
