 @ANNOTATE=1                                                            00050019
 @MSGLEVEL=1                                                            00100019
  GEN;                                                                  00150019
*                                                                     * 00200019
*  TITLE 'IEBDGMSG'   DATA GENERATOR MESSAGE MODULE                   * 00300019
*                                                                     * 00400019
* STATUS CHANGE LEVEL  0                                              * 00500019
*                                                                     * 00600019
* FUNCTION: TO PRINT MESSAGES,CONTROL CARD IMAGES,FLAG MESSAGES WHILE * 00700019
*           KEEPING A CORRECT COUNT OF PAGES . LINECT FROM PARM INFO  * 00800019
*           HONORED.CHANNEL 12 IS TESTED FIRST AND A NEW HEADING      * 00900019
*           PRINTED WHEN NECESSARY.OPERATOR MUST HAVE CORRECT CARRIAGE* 01000019
*           CONTROL TAPE INSTALLED.                                   * 01100019
*                                                                     * 01200019
* ENTRY POINT IEBDGMSG THE CSECT NAME OF THIS MODULE .                * 01300019
* CONTROL RECEIVED AS A RESULT OF A LINK FROM IEBDG                   * 01400019
*                                                                     * 01500019
* INPUT:                                                              * 01600019
*        1. COMMON AREA ( A DYNAMIC AREA GOT BY THE IEBDG MODULE)     * 01700019
*        2. REG 5-REGISTER CONTAINING COMMON AREA ADDRESS             * 01800019
*        3. MS - A TWO BYTE AREA IN COMMON WHICH CONTAINS:            * 01900019
*              A- THE NUMBER INDICATING WHICH MESSAGE TO PRINT        * 02000019
*              B- THE NUMBER 30 INDICATES CONTROL CARD IMAGE WANTED   * 02100019
*                  WHICH IS ACCESSED AT LABEL-INBUFA1                 * 02200019
*        4. LINECT -A FOUR BYTE AREA IN COMMON WHICH CONTAINS THE     * 02300019
*                   BINARY LINE COUNT OF 58 AS A DEFAULT OR THE LINE  * 02400019
*                   COUNT WHICH COMES FROM PARM INFORMATION           * 02500019
*        5. PAGENO -A FOUR BYTE AREA IN COMMON WHICH CONTAINS THE     * 02600019
*                   EBCDIC PAGE NUMBER 1 AS A DEFAULT OR THE PAGE     * 02700019
*                   NUMBER FROM INVOCATION IF PRESENT.                * 02800019
*        6. SYSP  THE NAME BY WHICH THE OUTPUT DCB IS ACCESSED        * 02900019
*        7. OFLGS BIT 4 THE INDICATION OF THE DCB BEING OPEN          * 03000019
*        8. IFLGS BIT 3 CHANNEL NINE INDICATOR                        * 03100019
*        9. IFLGS BIT 4 CHANNEL TWELVE INDICATOR                      * 03200019
*        10.  FLAGSW BIT 1 FLAG INDICATOR                             * 03300019
*        11.  FLAGSW BIT 2 HEADING INDICATOR                          * 03400019
*                                                                     * 03500019
* EXITS- NORMAL RETURN TO THE CALLER (IEBDG)                          * 03600019
*                                                                     * 03700019
* TABLES-WORKAREAS                                                    * 03800019
*                                                                     * 03900019
*        MSGPTR -A TABLE OF 30 FOUR BYTE ENTRIES CONTAINING MESSAGE   * 04000019
*                ADDRESSES                                            * 04100019
*                                                                     * 04200019
*        MESSAGES-ALL 121 BYTES LONG CONTAINING STANDARD MESSAGE      * 04300019
*                 IDENTIFIERS-  AS  IEB701I                           * 04400019
*                                                                     * 04500019
*        Q - THE WORKAREA USED WHEN CONVERTING,PACKING,ETC WHICH IS   * 04600019
*           ACCESSED IN COMMON AREA                                   * 04700019
*                                                                    *  04800019
* ATTRIBUTES--REFRESHIBLE,REENTRANT,REUSEABLE                         * 04900019
*********************************************************************** 05000019
 @ENDGEN                                                                05100019
  GEN;                                                                  05200019
*    NEW MODULE, RELEASE 17.                                       DG0H 05300019
 @ENDGEN                                                                05400019
  IEBDGMSG: PROCEDURE OPTIONS(REENTRANT,DONTSAVE(9,15));                05500019
  DCL  R14 REG(14);                                                     05600019
  DCL  R15 REG(15);                                                     05700019
  DCL R0 REG(0);                                                        05800019
  DCL R1 REG(1) PTR;                                                    05900019
  DCL R2 REG(2);                                                        06000019
  DCL R3 REG(3);                                                        06100019
  DCL R4 REG(4);                                                        06200019
  DCL R5 REG(5) PTR(31);                                                06300019
         RESTRICT(5);                                                   06400019
  DCL R6 REG(6) PTR(31);                                                06500019
  RESTRICT(6);                                                          06600019
  DCL R7 REG(7) PTR(31);                                                06700019
  RESTRICT(7);                                                          06800019
  DCL R8 REG(8) PTR(31);                                                06900019
  RESTRICT (8);                                                         07000019
  DCL R9 REG(9) PTR(31);                                                07100019
   RESTRICT (9);                                                        07200019
  DCL    1     COMMON BDY(DWORD) BASED(R5),                             07300019
               2  PAGENO CHAR(4),                                       07400019
                   2  LINECT FIXED(31),                                 07500019
                   2  LINECTR FIXED(31),                                07600019
         2     PARM PTR(31),                                            07700019
               2 REPEATNO FIXED(15),                                    07800019
               2 CREATENO FIXED(15),                                    07900019
         2     SYSP CHAR(96),                                           08000019
         2     SYSI CHAR(96),                                           08100019
        2 Q CHAR(16) BDY(DWORD),                                        08200019
              3 QFILL CHAR(7),                                          08300019
              3 QSIGN BIT(8),                                           08400019
              3 QFILL1 CHAR(7),                                         08500019
              3 QSIGN1 BIT(8),                                          08600019
         2 COUNTER  PTR(31),                                            08700019
         2 OPENLIST CHAR(8),                                            08800019
                                   3 OPTBYTE1 CHAR(4),                  08900019
                                   3 OPTBYTE2 CHAR(4),                  09000019
               2  EXLST,                                                09100019
                                        3  INHDR CHAR(1),               09200019
                                        3 INHDR1 PTR(24),               09300019
                                        3 OUTHDR CHAR(1),               09400019
                                        3 OUTHDR1 PTR(24),              09500019
                                        3 INTRL CHAR(1),                09600019
                                        3 INTRL1 PTR(24),               09700019
                                        3 OUTTRL CHAR(1),               09800019
                                        3 OUTTRL1 PTR(24),              09900019
                                        3 EXITDCB CHAR(1),              10000019
                                        3 EXITDCB1 PTR(24),             10100019
                                        3 TOTAL CHAR(1),                10200019
                                        3 TOTAL1 PTR(24),               10300019
               2 EXLST1,                                                10400019
                                       3 EDCB1 CHAR(1),                 10500019
                                       3 EDCB2 PTR(24),                 10600019
              2 EXLST2,                                                 10700019
                                       3 EDCB3 CHAR(1),                 10800019
                                       3 EDCB4 PTR(24),                 10900019
         2  EXLST3,                                                     11000019
               3  EDCB5 CHAR(1),                                        11100019
               3 EDCB6  PTR(24),                                        11200019
               2 DLRECL FIXED(15),                                      11300019
               2 DBLKSI FIXED(15),                                      11400019
               2 DRECFM BIT(8),                                         11500019
               2 LEFTOVER FIXED(31),                                    11600019
         2     OFFSET PTR(31),                                          11700019
         2     LPTR PTR(31),                                            11800019
         2     DCBPTR PTR(31),                                          11900019
         2 DUMMY PTR(31);                                               12000019
  DCL 1 COMMON1 BASED(ADDR(DUMMY)) BDY(WORD),                           12100019
               2   SAVEMS  FIXED(15),                                   12200019
               2   CONCODE FIXED(15),                                   12300019
         2 OUTREC   PTR(31),                                            12400019
         2 CRTABPT  PTR(31),                                            12500019
         2 CURCRTE  PTR(31),                                            12600019
         2 CURCRGM  PTR(31),                                            12700019
         2 CURPIC PTR(31),                                              12800019
         2 PICCTR FIXED(31),                                            12900019
         2 EXITTAB PTR(31),                                             13000019
         2 EXITGM PTR(31),                                              13100019
         2 CUREXIT PTR(31),                                             13200019
         2 DELIM CHAR(4),                                               13300019
         2 RECREM   FIXED(31),                                          13400019
         2 CURFD    PTR(31),                                            13500019
         2 CUROUT PTR(31),                                              13600019
         2  SAVE14  PTR(31),                                            13700019
         2 GETMLIST CHAR(16) BDY(WORD),                                 13800019
            3 GLENGTH FIXED(31),                                        13900019
            3 ADRLIST PTR(31),                                          14000019
            3 IND CHAR(4),                                              14100019
               4 GCODE CHAR(1),                                         14200019
               4 SPOOL CHAR(1),                                         14300019
               4 CCODE CHAR(2),                                         14400019
            3 GCADDR PTR(31),                                           14500019
         2     FIRSTGMO  PTR(31),                                       14600019
         2     CURRGMO   PTR(31),                                       14700019
         2     LASTGMO   PTR(31),                                       14800019
         2     FIRSTGMI  PTR(31),                                       14900019
         2     CURRGMI   PTR(31),                                       15000019
         2     LASTGMI   PTR(31),                                       15100019
         2     CONDCODE FIXED(15),                                      15200019
               2       MS     FIXED(15),                                15300019
               2 INBUFA1 CHAR(121),                                     15400019
                   3   INFILL CHAR(10),                                 15500019
               3  INBUFA CHAR(111),                                     15600019
         2     DDPTR PTR(31),                                           15700019
               2  DUMMY1 PTR(31);                                       15800019
  DCL 1 COMMON2 BASED (ADDR(DUMMY1)) BDY(WORD),                         15900019
         2  SWITCH   CHAR(52),                                          16000019
               3  FDCSW      CHAR(1),                                   16100019
               3  FDNAMESW   CHAR(1),                                   16200019
               3  FDPCSW     CHAR(1),                                   16300019
               3  FDFMTSW    CHAR(1),                                   16400019
               3  FDPLSW     CHAR(1),                                   16500019
               3  RANGESW    CHAR(1),                                   16600019
               3  FILLSW     CHAR(1),                                   16700019
               3  REPSW      CHAR(1),                                   16800019
               3  INDEXSW    CHAR(1),                                   16900019
               3  INDNMSW    CHAR(1),                                   17000019
               3  BQUOTESW   CHAR(1),                                   17100019
               3  PQUOTESW   CHAR(1),                                   17200019
               3  EQUOTESW   CHAR(1),                                   17300019
               3  FDSW       CHAR(1),                                   17400019
               3  DSDSW      CHAR(1),                                   17500019
               3  NOGOSW     CHAR(1),                                   17600019
               3  CREATESW   CHAR(1),                                   17700019
               3  DSDCSW     CHAR(1),                                   17800019
               3  CRCSW      CHAR(1),                                   17900019
               3  EXITSW     CHAR(1),                                   18000019
               3  EODSTOP    CHAR(1),                                   18100019
               3  DSDNULSW   CHAR(1),                                   18200019
               3  DSDORGSW   CHAR(1),                                   18300019
               3  DSDDDSW    CHAR(1),                                   18400019
               3  CRTBLK     CHAR(1),                                   18500019
               3  NAMCSW     BIT(8),                                    18600019
               3  PICCSW     BIT(8),                                    18700019
               3  BUFPSW     CHAR(1),                                   18800019
               3  ENDSW      CHAR(1),                                   18900019
               3  COMCSW     CHAR(1),                                   19000019
               3  FLAGSW     BIT(8),                                    19100019
               3  PAGESW     CHAR(1),                                   19200019
               3  EPSW       PTR(8),                                    19300019
               3  SYSISW     CHAR(1),                                   19400019
               3  SYSPSW     CHAR(1),                                   19500019
               3  OLDNEWSW   CHAR(1),                                   19600019
               3  FLUSHSW    CHAR(1),                                   19700019
               3  FLUSHSW1   CHAR(1),                                   19800019
               3  DSDOSW     CHAR(1),                                   19900019
               3  DSDISW     CHAR(1),                                   20000019
               3  QUANSW     CHAR(1),                                   20100019
               3  PARENSW    CHAR(1),                                   20200019
               3  REPEATSW   CHAR(1),                                   20300019
         2 FDPLGTH FIXED(15),                                           20400019
         2 SGCADDR PTR(31),                                             20500019
         2 FDPTR   PTR(31),                                             20600019
         2 FDPTR1  PTR(31),                                             20700019
         2 FDPTR2  PTR(31),                                             20800019
         2  DUMMY2  PTR(31);                                            20900019
  DCL 1 COMMON3 BASED(ADDR(DUMMY2)) BDY(WORD),                          21000019
               2 FDCTR PTR(15),                                         21100019
               2 LREMAIN PTR(31),                                       21200019
               2 COMPCTR PTR(31),                                       21300019
               2 LMOVED PTR(15),                                        21400019
               2  U  PTR(31),                                           21500019
               2 PICEND  PTR(15),                                       21600019
               2 CURFDGM PTR(31),                                       21700019
               2 SWTCH,                                                 21800019
               3    SYSINSEL CHAR(1),                                   21900019
                 3 FIRSTSW CHAR(1),                                     22000019
                 3 FRSTSW  CHAR(1),                                     22100019
                 3 STOPSW  CHAR(1),                                     22200019
               2 COPYVAL FIXED(15),                                     22300019
               2 COPYFD  PTR(31),                                       22400019
               2 COPYFDGM PTR(31),                                      22500019
               2 NAMCTR   FIXED(15),                                    22600019
               2 NAMCTR1  FIXED(15),                                    22700019
               2 INRECSZ  PTR(15),                                      22800019
               2 OUTRECSZ PTR(15),                                      22900019
               2 INRECFM  CHAR(1),                                      23000019
               2 RECOFFST PTR(8),                                       23100019
               2 OUTRECFM CHAR(1),                                      23200019
               2 PICBASE  PTR(31),                                      23300019
               2 MESSAGE  CHAR(121),                                    23400019
         2  DUMMY3  PTR(31);                                            23500019
  DCL OPTPTR PTR(31);                                                   23600019
  DCL PGPTR PTR(31);                                                    23700019
  DCL OPTIONS CHAR(256) BASED(OPTPTR);                                  23800019
  DCL PAGE CHAR(256) BASED(PGPTR);                                      23900019
  DCL DDLST CHAR(256) BASED(DDPTR);                                     24000019
  DCL 1 DCBD BASED(DCBPTR) BDY(DWORD),                                  24100019
               2  FILL CHAR(26),                                        24200019
               2  DSORG1 CHAR(2),                                       24300019
                                        3  DSORG  BIT(8),               24400019
               2  FILLER CHAR(8),                                       24500019
                   3  IOBAD CHAR(4),                                    24600019
                   3  BFTEK BIT(8),                                     24700019
                   3  EODAD  CHAR(3),                                   24800019
         2  RECFM  BIT(8),                                              24900019
         2  EXLIST  PTR(24),                                            25000019
         2 DDNAME CHAR(8),                                              25100019
                   3  FILL1 CHAR(2),                                    25200019
                   3  MACRF CHAR(2),                                    25300019
          3 DEBAD CHAR(4),                                              25400019
              4 IFLGS BIT(8),                                           25500019
         2     GETAD CHAR(4),                                           25600019
                                   3 OFLGS BIT(8),                      25700019
         2     FILL2 CHAR(10),                                          25800019
         2     BLKSI FIXED(15),                                         25900019
         2     FILL3 CHAR(18),                                          26000019
         2     LRECL FIXED(15),                                         26100019
         2 FILL4 CHAR(172),                                             26200019
         2 NEXTDCB PTR(31),                                             26300019
               2  DDNAME1 CHAR(8),                                      26400019
               2  EODSW   CHAR(1),                                      26500019
               2 DCBSW1   CHAR(1),                                      26600019
               2 DCBSW2   CHAR(1),                                      26700019
         2     DCBSW3 BIT(8),                                           26800019
         2     INREC  PTR(31),                                          26900019
         2     GMLGTH FIXED(15),                                        27000019
         2     FIELDSEL CHAR(1),                                        27100019
         2     SPARE    CHAR(1);                                        27200019
         DCL ON CHAR(1) INIT('FF'X);                                    27300019
         DCL OFF CHAR(1) INIT('00'X);                                   27400019
  DCL INBUF CHAR(80) BASED(R9);                                         27500019
  DCL ERRORS LABEL;                                                     27600019
   DCL MSGPTR(30) PTR INIT(ADDR(M1),ADDR(M2),ADDR(M3),ADDR(M4),ADDR(M5),27700019
 ADDR(M6),ADDR(M7),ADDR(M8),ADDR(M9),ADDR(M10),ADDR(M11),ADDR(M12),     27800019
 ADDR(M13),ADDR(M14),ADDR(M15),ADDR(M16),ADDR(M17),ADDR(M18),ADDR(M19), 27900019
 ADDR(M20),ADDR(M21),ADDR(M22),ADDR(M23),ADDR(M24),ADDR(M25),           28000019
 ADDR(M26),ADDR(M27),ADDR(M28),ADDR(M29),ADDR(INBUFA));                 28100019
  DCL M1 CHAR(121) INIT('1                              DATA GENERATOR O28200019
 UTPUT FOR CONTROL CARDS AND MESSAGES                       PAGE        28300019
   ');                                                                  28400019
  DCL M2 CHAR(121) INIT(' IEB702I OPERATION WAS NOT DSD,FD,CREATE,REPEAT28500019
 ,OR END.CORRECT AND RERUN');                                           28600019
  DCL M3 CHAR(121) INIT(' IEB703I INVALID KEYWORD VALUE.DELIMITER,DESCRI28700019
 PTOR OR TYPE IS IMPROPER, OR DUPLICATED');                             28800019
  DCL M4 CHAR(121) INIT(' IEB704I INPUT DDNAME ON CREATE OR FD CARD IS N28900019
 OT SPECIFIED ON DSD CARD');                                            29000019
  DCL M5 CHAR(121) INIT(' IEB705I INVALID KEYWORD,POSSIBLE IMBEDDED COMM29100019
 A');                                                                   29200019
  DCL M6 CHAR(121) INIT(' IEB706I NUMBER SPECIFIED IS LARGER THAN 32,76729300019
  OR EXCEEDS MACHINE CAPACITY (2,147,483,647).');                       29400019
  DCL M7 CHAR(121) INIT(' IEB707I FD NAME ON CREATE CARD IS NOT PREVIOUS29500019
 LY DEFINED BY AN FD CARD OR IS NOT ASSOCIATED WITH CORRECT DCB');      29600019
  DCL M8 CHAR(121) INIT(' IEB708I PICTURE LENGTH TOO LARGE FOR CONVERSIO29700019
 N');                                                                   29800019
  DCL M9 CHAR(121) INIT(' IEB709I USER EXIT ROUTINE RETURNED AN INVALID 29900019
 RETURN CODE.');                                                        30000019
  DCL M10 CHAR(121) INIT(' IEB710I UNABLE TO GET ENOUGH SPACE TO PROCESS30100019
  REMAINING CONTROL CARDS');                                            30200019
  DCL M11 CHAR(121) INIT(' IEB711I KEYWORD VALUE NOT FOLLOWED BY A BLANK30300019
  OR COMMA.');                                                          30400019
  DCL M12 CHAR(121) INIT(' IEB712I CONTROL CARD NAME OR KEYWORD VALUE EX30500019
 CEEDS EIGHT CHARACTERS.');                                             30600019
  DCL M13 CHAR(121) INIT(' IEB713I FLAGGED KEYWORD IS NOT COMPATIBLE WIT30700019
 H A PRECEDING KEYWORD.');                                              30800019
  DCL M14 CHAR(121) INIT(' IEB714I REPEAT CARD ERROR OR REQUIRED NUMBER 30900019
 OF CREATE CARDS NOT PRESENT');                                         31000019
  DCL M15 CHAR(121) INIT(' IEB715I NAME AND/OR LENGTH OR QUANTITY SPECIF31100019
 ICATION(S) OMITTED FROM FD AND/OR REPEAT CARD.');                      31200019
  DCL M16 CHAR(121) INIT(' IEB716I PICTURE STRING OR FD FIELD OVERFLOWS 31300019
 OUTPUT RECORD OR INPUT FIELD SELECTED OVERRUNS INPUT WORKAREA');       31400019
  DCL M17 CHAR(121) INIT(' IEB717I INPUT RECORD SIZE EXCEEDS SPECIFIED O31500019
 UTPUT RECORD SIZE.');                                                  31600019
  DCL M18 CHAR(121) INIT(' IEB718I DSD CONTROL CARD MUST BE FIRST CARD O31700019
 F SET');                                                               31800019
  DCL M19 CHAR(8) INIT(' IEB719I');                                     31900019
  DCL M20 CHAR(121) INIT(' IEB720I BLANK DOES NOT FOLLOW OPERATION OR CO32000019
 NTROL CARD NAME.');                                                    32100019
  DCL M21 CHAR(121) INIT(' IEB721I KEYWORD,KEYWORD VALUE OR DELIMITER,IS32200019
  MISSING OR EXTENDS INTO COLUMN 72');                                  32300019
  DCL M22 CHAR(8) INIT(' IEB722I');                                     32400019
  DCL M23 CHAR(121) INIT(' IEB723I PICTURE PARAMETER IS NOT FOLLOWED BY 32500019
 A BLANK OR COMMA');                                                    32600019
  DCL M24 CHAR(121) INIT(' IEB724I UNABLE TO OPEN DATA SET.LOOK FOR CONF32700019
 LICTING VALUES OR MISSING DD CARD');                                   32800019
  DCL M25 CHAR(121) INIT(' IEB725I  A DUPLICATE DSD CONTROL CARD HAS BEE32900019
 N FOUND.CHECK FOR MISSING END CARD');                                  33000019
  DCL M26 CHAR(121) INIT(' IEB726I EXEC STATEMENT PARM PARAMETER IS CODE33100019
 D INCORRECTLY');                                                       33200019
  DCL M27 CHAR(121) INIT(' IEB727I');                                   33300019
  DCL M28 CHAR(121) INIT(' IEB728I INPUT STREAM FLUSHED FROM THIS POINT 33400019
 LRECL,BLKSIZE,OR RECFM INCORRECT IN OUTPUT OR INPUT DCB');             33500019
  DCL M29 CHAR(121) INIT('1IEB700I                     DATA GENERATION H33600019
 AS BEEN SUCCESSFULLY COMPLETED COMPLETION CODE IS ZERO');              33700019
  GEN ( EJECT);                                                         33800019
  /********************************************************************/33900019
  /**                                                                **/34000019
  /**                  ENTRY IS AT THIS POINT                        **/34100019
  /**                                                                **/34200019
  /**    IF THE DATA GENERATOR OUTPUT DCB IS NOT OPEN,CONTROL RETURNS**/34300019
  /** TO THE BASE MODULE.                                            **/34400019
  /**                                                                **/34500019
  /********************************************************************/34600019
               DCBPTR = ADDR(SYSP) /** PICK UP SYSP ADDR **/;           34700019
         IF OFLGS(4) = '1'B THEN GO TO MSG01 /**BR IF DCB OPEN **/;     34800019
           RETURN        /* IF NOT RETURN*/;                            34900019
  /********************************************************************/35000019
  /**                                                                **/35100019
  /**    THE COMMUNICATION POINTER MS WILL CONTAIN THE NUMBER OF THE **/35200019
  /** MESSAGE TO BE PRINTED.THE HEADING MSG IS INDICATED FROM TWO    **/35300019
  /** PLACES 1. THE BASE MODULE WHEN IT IS FIRST ENTERED AS MS = 1   **/35400019
  /**        2. THIS MODULE AFTER A PAGE IS FILLED AS INDICATED BY   **/35500019
  /**           LINE COUNT OR CHANNEL 12.                            **/35600019
  /** WHEN MS = 30 WE PRINT A CARD IMAGE FROM THE INPUT.             **/35700019
  /** ANY OTHER NUMBER,THE MESSAGE IS TAKEN FROM THIS MODULE.MESSAGES**/35800019
  /** ARE CARRIED AS CONSTANTS OF 121 BYTES LONG.                    **/35900019
  /**    *****                                                       **/36000019
  /**    *****                                                       **/36100019
  /**          MESSAGE 27 MAY NEVER BE CHANGED.THIS IS USED FOR ERROR**/36200019
  /**          FLAGGING.                                             **/36300019
  /**    *****                                                       **/36400019
  /**    *****                                                       **/36500019
  /**                                                                **/36600019
  /********************************************************************/36700019
  MSG01:;                                                               36800019
  /********************************************************************/36900019
  /**                                                                **/37000019
  /**    WHEN A HEADING MESSAGE IS INDICATED A BRANCH IS TAKEN TO    **/37100019
  /** MSG03 TO PROCESS THE MESSAGE                                   **/37200019
  /**                                                                **/37300019
  /********************************************************************/37400019
         IF MS = 1 THEN GO TO MSG03 /*IF HDNG MSG BR TO SET PAGENO*/;   37500019
         PARM = SYNAD;        /**SAVE DCBIOBL AND SYNAD IN PARM**/      37600019
         SYNAD = ADDR(ERRORS); /**PLACE MSG SYNAD ADDRESS IN DCB**/     37700019
  /********************************************************************/37800019
  /**                                                                **/37900019
  /**    THIS SECTION TESTS FOR AN INDICATION OF CHANNEL 12 BEING ON.**/38000019
  /** A BRANCH IS TAKEN TO MSG03 FOR PRINTING OF A HEADER MSG IF ON. **/38100019
  /**                                                                **/38200019
  /********************************************************************/38300019
               IFLGS(3) = '0'B /*TURNS OFF CH 9 INDICATOR*/;            38400019
  GEN ( EJECT);                                                         38500019
         IF IFLGS(4) = '1'B THEN DO /*IS CH 12 ON */;                   38600019
               IFLGS(4) = '0'B /*IF SO TURN OFF CH 12*/;                38700019
               GO TO MSG03; /* BRANCH */                                38800019
         END;                                                           38900019
  /********************************************************************/39000019
  /**                                                                **/39100019
  /**    IF PAGE IS FULL AS INDICATED BY LINECT AND LINECTR BEING    **/39200019
  /** EQUAL A BRANCH IS TAKEN TO MSG03 TO PRINT A HEADER             **/39300019
  /**                                                                **/39400019
  /********************************************************************/39500019
         IF LINECT = LINECTR THEN GO TO MSG03 /* IS LINECTR AT MAX*/;   39600019
  /********************************************************************/39700019
  /**                                                                **/39800019
  /**    THIS SECTION BRANCHES TO MSG04 IF PRINTING OF A CONTROL     **/39900019
  /** CARD IMAGE IS DESIRED.                                         **/40000019
  /**                                                                **/40100019
  /********************************************************************/40200019
  MSG02:;                                                               40300019
         IF MS = 30 THEN GO TO MSG04 /*BR TO PICK UP ADDR IF CNTRL*/;   40400019
  /********************************************************************/40500019
  /**                                                                **/40600019
  /**    THIS SECTION BRANCHES TO MSG05 IF ERROR FLAGGING IS DESIRED **/40700019
  /** IF ERROR FLAGGING IS NOT INDICATED BY FIRST BIT IN FLAG SWITCH **/40800019
  /** A MESSAGE IS INDICATED.THE MESSAGE ADDRESS IS THEN PICKED UP   **/40900019
  /** AND A BRANCH TAKEN TO MSG06 TO 'PUT'THE MESSAGE ON THE SYSP DCB**/41000019
  /**                                                                **/41100019
  /********************************************************************/41200019
         IF FLAGSW(1) = '1'B THEN GO TO MSG05 /*IS FLAGSW ON*/;         41300019
               R0 = MSGPTR(MS) /* PICK UP MSG ADDRESS*/;                41400019
  /********************************************************************/41500019
  /** THIS SECTION WILL CHECK FOR COMPLETION CODES IF MESSAGE NUMBER **/41600019
  /** 29 IS INDICATED. THE WORD SUCCESSFUL WILL BE BLANKED OUT FOR   **/41700019
  /** CODES OTHER THAN ZERO AND THE PROPER CODE PLACED WITHIN THE    **/41800019
  /** MESSAGE.CONTROL IS THEN TRANSFERRED TO LABEL MSG06 TO INITIATE **/41900019
  /** PRINTING OF THE MESSAGE                                        **/42000019
  /********************************************************************/42100019
         IF MS = 29 THEN DO   /** IF MSG 29 THEN DO BELOW**/;           42200019
         IF CONCODE = '0000'X THEN GO TO MSG06 /** BRANCH IF 0 CODE **/;42300019
         R0 = ADDR(MESSAGE);                                            42400019
         MESSAGE = M29;                                                 42500019
         MESSAGE(55:66) = ' ';                                          42600019
         IF CONCODE = '000C'X THEN                                      42700019
         DO;                                                            42800019
         MESSAGE(97:102) = 'TWELVE';                                    42900019
         GO TO MSG06          /** BRANCH TO PRINT MESSAGE**/;           43000019
         END;                                                           43100019
         IF CONCODE = '0004'X THEN DO /**DO BELOW IF FOUR**/;           43200019
         MESSAGE(97:100) = 'FOUR';                                      43300019
               GO TO MSG06    /** BRANCH TO PRINT MESSAGE **/;          43400019
                                   END;                                 43500019
         IF CONCODE = '0008'X THEN DO /** IF 8 DO BELOW**/;             43600019
         MESSAGE(97:101) = 'EIGHT';                                     43700019
               GO TO MSG06    /** BRANCH TO PRINT MESSAGE**/;           43800019
                                    END;                                43900019
         IF CONCODE = '0010'X THEN DO /** IF 16 DO BELOW**/;            44000019
         MESSAGE(97:103) = 'SIXTEEN';                                   44100019
                                  END;                                  44200019
                         END;                                           44300019
               GO TO MSG06 /* BRANCH TO PICK UP DCB ADDRESS*/;          44400019
  /********************************************************************/44500019
  /**    THIS SECTION IS ENTERED WHEN A HEADING IS DESIRED.THE       **/44600019
  /** LINECTR IS RESTORED TO ZERO AND THE INTERNAL HEADING SWITCH,   **/44700019
  /** SECOND BIT OF FLAG SWITCH,IS TURNED ON.THE HEADING MESSAGE IS  **/44800019
  /** THEN MOVED INTO THE COMMUNICATION AREA(ADDRESSED BY REG5) FOR  **/44900019
  /** PURPOSES OF REENTRANTCY.AFTER THE PAGENO IS MOVED INTO THE     **/45000019
  /** MESSAGE,THE MSG ADDRESS IS PICKED UP AND A BRANCH TAKEN TO     **/45100019
  /** MSG06 TO PUT THE MESSAGE.                                      **/45200019
  /**                                                                **/45300019
  /********************************************************************/45400019
  GEN ( EJECT);                                                         45500019
  MSG03:;                                                               45600019
               LINECTR = 0     /* RESTORE COUNT TO ZERO */;             45700019
               FLAGSW(2) = '1'B /* SET HEADING SW */;                   45800019
               R1 = ADDR(M1) /*PICK UP HDNG ADDRESS*/;                  45900019
               /** MOVE HEADING MESSAGE TO REENTRANT AREA**/            46000019
         GEN ( MVC MESSAGE(121,R5),0(R1));                              46100019
         R1 = ADDR(MESSAGE)   /** PICK UP HEADER LINE ADDRESS**/;       46200019
            /* MOVE PAGE NO TO HEADING MESSAGE*/                        46300019
         GEN ( MVC 112(4,R1),PAGENO(R5));                               46400019
         R0 = ADDR(MESSAGE)   /** PICK UP HEADER LINE ADDRESS**/;       46500019
               GO TO MSG06       /* BRANCH TO PICK UP DCB ADDRESS */;   46600019
  /********************************************************************/46700019
  /**                                                                **/46800019
  /**    THIS SECTION PICKS UP THE ADDRESS OF THE CONTROL CARD IMAGE **/46900019
  /** FROM THE REENTRANT COMMUNICATION AREA AND BRANCHES TO MSG06 TO **/47000019
  /** PUT THE CARD IMAGE UPON SYSP.                                  **/47100019
  /**                                                                **/47200019
  /********************************************************************/47300019
  MSG04:;                                                               47400019
               R0 = ADDR(INBUFA1)  /*PICK UP CONTROL CARD ADDRESS*/;    47500019
               GO TO MSG06        /* BR TO PICK UP DCB ADDRESS*/;       47600019
  GEN ( EJECT);                                                         47700019
  /********************************************************************/47800019
  /**                                                                **/47900019
  /**    THIS SECTION PICKS UP THE FLAG MESSAGE ADDRESS AND MOVES    **/48000019
  /** THE MESSAGE TO THE COMMUNICATION AREA.AT THIS TIME REG 9 IS    **/48100019
  /** POINTING AT A SPOT WITHIN THE CARD IMAGE.REG 9 HAS BEEN USED AS**/48200019
  /** A SCAN POINTER BY SOME OTHER MODULE.THIS OTHER MODULE HAS      **/48300019
  /** DETECTED AN ERROR OF SOME KIND AND HAS INDICATED A DESIRE FOR  **/48400019
  /** ERROR FLAGGING BY TURNING ON THE FIRST BIT OF THE FLAG SWITCH. **/48500019
  /** THE POSITION OF THE ERROR FLAG IS DETERMINED BY RESOLVING THE  **/48600019
  /** POSITION OF REG 9 IN RELATION TO THE START OF THE CONTROL CARD **/48700019
  /** IMAGE.ONCE DETERMINED THE WORD -- ERROR -- IS PLACED IN THE    **/48800019
  /** MESSAGE AND BRANCH POINT MSG06 IS ENTERED FOR OUTPUTING THE    **/48900019
  /** MESSAGE.THE 'E' OF THE WORD ERROR WILL LINE UP EXACTLY UNDER   **/49000019
  /** THE ERROR IN THE CONTROL CARD AS THE CONTROL CARD IMAGE WAS    **/49100019
  /** JUST PLACED UPON THE OUTPUT DATA SET.                          **/49200019
  /**                                                                **/49300019
  /********************************************************************/49400019
  MSG05:;                                                               49500019
               R1 = MSGPTR(27)     /*PICK UP FLAG MSG ADDRESS*/;        49600019
  GEN ( MVC MESSAGE(121,R5),0(R1));                                     49700019
         R1 = ADDR(MESSAGE)   /** PICK UP HEADER LINE ADDRESS**/;       49800019
               R8 = R9 - ADDR(INBUFA) /* RESOLVE OFFSET IN INBUF*/;     49900019
               R1 = R1 + R8 + 10 /* RESOLVE ADDRESS IN MESSAGE*/;       50000019
         R1 -> COMMON(1:5) = 'ERROR' /* PLACE FLAG IN MESSAGE*/;        50100019
         R0 = ADDR(MESSAGE)   /** PICK UP HEADER LINE ADDRESS**/;       50200019
  GEN ( EJECT);                                                         50300019
  /********************************************************************/50400019
  /**                                                                **/50500019
  /**    THIS SECTION WILL ISSUE THE DATA MANAGEMENT MACRO 'PUT'.    **/50600019
  /** UPON ENTRY REG 0 CONTAINS THE ADDRESS OF THE WORKAREA. REG 1   **/50700019
  /** WILL BE LOADED WITH THE ADDRESS OF THE SYSP DCB.               **/50800019
  /**                                                                **/50900019
  /********************************************************************/51000019
  MSG06:;                                                               51100019
               R1 = ADDR(SYSP)    /* PICK UP DCB ADDRESS*/;             51200019
         GEN ( PUT (1),(0));                                            51300019
  /********************************************************************/51400019
  /**                                                                **/51500019
  /**    THE LINECTR IS NOW INCREMENTED BY ONE.IF A HEADING WAS JUST **/51600019
  /** 'PUT' A BRANCH IS TAKEN TO MSG07 FOR FURTHER PROCESSING.IF AN  **/51700019
  /** ERROR FLAG WAS JUST 'PUT' A BRANCH IS TAKEN TO MSG08 FOR       **/51800019
  /** FURTHER PROCESSING,OTHERWISE CONTROL RETURN TO THE BASE MODULE **/51900019
  /**                                                                **/52000019
  /********************************************************************/52100019
               LINECTR = LINECTR+ 1 /* ADD 1 TO LINE COUNTER*/;         52200019
         IF FLAGSW(2) = '1'B THEN GO TO MSG07 /*BR IF HDNG SW ON*/;     52300019
         IF FLAGSW(1) = '1'B THEN GO TO MSG08 /*IF FLAG ON BRANCH*/;    52400019
         SYNAD = PARM;        /**RESTORE DCBIOBL FOR CLOSE**/           52500019
               RETURN;                                                  52600019
  GEN ( EJECT);                                                         52700019
  /********************************************************************/52800019
  /**                                                                **/52900019
  /**    THIS SECTION IS ENTERED AFTER A HEADING HAS JUST BEEN 'PUT'.**/53000019
  /** THE PAGENO IN THE COMMUNICATION AREA MUST BE INCREMENTED BY ONE**/53100019
  /** THIS IS DONE BY PACKING THE NUMBER,CONVERTING TO BINARY,ADDING **/53200019
  /** ONE,CONVERTING TO DECIMAL,CHANGING THE SIGN TO A PRINTIBLE     **/53300019
  /** CHARACTER AND UNPACKING THE NUMBER BACK TO 'PAGENO'.IF A       **/53400019
  /** HEADING ONLY WAS PRINTED,ONLY CALLED ONCE AS MS = 1,CONTROL    **/53500019
  /** RETURNS TO THE BASE MODULE,OTHERWISE A BRANCH IS TAKEN TO MSG02**/53600019
  /** TO PRINT A CARD IMAGE OR ERROR FLAG.                           **/53700019
  /**                                                                **/53800019
  /********************************************************************/53900019
  MSG07:;                                                               54000019
               FLAGSW(2) = '0'B    /* TURN OFF HDNG SW */;              54100019
           /* THIS SECTION WILL INCREMENT PAGE NO BY ONE */             54200019
         GEN ( PACK Q(8,R5),PAGENO(4,R5));                              54300019
         GEN ( CVB 6,Q(0,R5));                                          54400019
         GEN ( LA 6,1(0,6));                                            54500019
         GEN ( CVD 6,Q(0,R5));                                          54600019
               QSIGN = QSIGN  '0F'X /* CHANGE SIGN TO PRINTABLE CHAR*/;54700019
         GEN ( UNPK PAGENO(4,R5),Q(8,R5));                              54800019
         IF MS = 1 THEN DO /* IF HDNG MSG BRANCH TO RETURN */;          54900019
         RETURN;                                                        55000019
         END;                                                           55100019
               GO TO MSG02 /* BRANCH TO CONTINUE*/;                     55200019
  GEN ( EJECT);                                                         55300019
  /********************************************************************/55400019
  /**                                                                **/55500019
  /**    THIS SECTION WILL TURN OFF THE ERROR FLAG INDICATOR,BIT ONE **/55600019
  /** OF FLAG SWITCH,AND BRANCH TO MSG01 FOR FURTHER PROCESSING      **/55700019
  /**                                                                **/55800019
  /********************************************************************/55900019
  MSG08:;                                                               56000019
               FLAGSW(1) = '0'B   /* TURN OFF FLAG SW*/;                56100019
               GO TO MSG01     /* BR TO TEST FOR CHANNEL 12 */;         56200019
  ERRORS:;                                                              56300019
         FLUSHSW1 = ON; /**TURN ON FLUSH CAUSES BASE TO GO TO CLEANUP**/56400019
         SYNAD = PARM;        /**RESTORE DCBIOBL FOR CLOSE**/           56500019
         RETURN;                                                        56600019
  END IEBDGMSG;                                                         56700019
