         TITLE 'IEBDSCPY - MAIN PROCESSING MODULE'                      00060019
IEBDSCPY CSECT                                                          00120019
*D180800,496200,497200-497900,504120-504340,504440,564400-566400 A34431 00126021
*D181100-271200,403500-403800,405600-418800  (IEBBAM)            S20201 00132021
*C642510,962100                                                  A41780 00134021
*C041960-041980                                                  A44338 00134121
*C834600                                                         A44336 00136121
*C403300                                                         A44144 00138100
*A403000-403100,618300-619300,631400-631900,831000-831300        A44144 00138500
*D403400,619800,830500                                           A44144 00139300
*C389200,390000,392400                                          SA64802 00139721
*D391800,393000                                                 SA64802 00139821
*C389200,390000,392400                                         @SA67504 00139921
*A391700-392300                                                @SA67504 00140121
*C331800-332400                                                @SA69540 00140221
*********************************************************************** 00140321
*                                                                     * 00160019
*TITLE   IEBDSCPY - IEBCOPY MAIN CONTROL MODULE                       * 00180019
*STATUS  CHANGE LEVEL 001                                               00200019
*                                                                     * 00220019
*FUNCTION/OPERATION  -  MONITORS THE FLOW OF CONTROL FOR THE IEBCOPY  * 00240019
*        UTILITY                                                      * 00250019
*        ALLOCATES CORE STORAGE                                       * 00260019
*        INITIALIZES FOR THE PROCESSING OF AN INDD-GROUP              * 00270019
*        DOES NECESSARY INITIALIZATION FOR PROCESSING MULTIPLE INDD'S * 00280019
*        AND/OR OUTDD'S                                               * 00290019
*        ALLOCATES I/O BUFFERS                                        * 00300019
*        'FINDS' SELECTED OR UN-EXCLUDED INPUT MEMBERS                * 00310019
*        PERFORMS OUTPUT PRESCAN FOR DUPLICATE INPUT DIRECTORY        * 00360019
*        ENTRIES                                                      * 00380019
*        SETS UP FOR COPYING A MEMBER                                 * 00400019
*        CONVERTS TTR'S TO MBBCCHHR'S                                 * 00420019
*        CONVERTS MBBCCHHR'S TO TTR'S                                 * 00440019
*        HANDLES SYSIN AND SYSPRINT I/O ERRORS                        * 00460019
*        RETURNS A POINTER TO AN OUTPUT DIRECTORY ENTRY IN THE I/O    * 00480019
*        BUFFER                                                       * 00500019
*        BUILDS THE CTLTAB AND SAVES INPUT DIRECTORY ENTRIES IN  CORE * 00520019
*        WHEN POSSIBLE                                                * 00540019
*        RETURNS A POINTER TO AN INPUT DIRECTORY ENTRY IN CORE OR     * 00560019
*        READS IN A SPILLED INPUT DIRECTORY ENTRY AND RETURNS A       * 00580019
*        POINTER TO IT                                                * 00610019
*        SAVES OUTPUT DIRECTORY BLOCKS IN CORE WHEN POSSIBLE          * 00640019
*ENTRY POINTS                                                         * 00680019
*IEBDSCPY - ALLOCATES CORE STORAGE,DOES INITIALIZATION FOR PROCESSING * 00700019
*        AN INDD GROUP                                                * 00720019
*IEBGME - FOR RE-ISSUING GETMAIN IF IEBVTM ISSUED FREEMAIN BETWEEN    * 00730019
*        COPY OPERATIONS                                              * 00740019
*IEBMNI - ALLOCATES I/O BUFFERS, SEARCHES INPUT DIRECTORY FOR SELECTED* 00750019
*        OR NON-EXCLUDED MEMBERS, PERFORMS OUTPUT DIRECTORY 'PRE-SCAN'* 00760019
*IEBMNM - SETS UP FOR COPYING A MEMBER WITHOUT RE/DE BLOCKING         * 00780019
*IEBEOF - SYSIN EODAD INTERFACE                                       * 00800019
*IEBIOE - EXCP READ OR WRITE I/O ERROR HANDLING                       * 00820019
*IEBCER - SYSIN SYNAD EXIT                                            * 00840019
*IEBPER - SYSPRINT SYNAD EXIT                                         * 00860019
*IEBSCX - USED BY IEBVTM TO EXIT TO IEBSCN                            * 00880019
*IEBDSCP2 -  A CSECT WITHIN THE MAIN CONTROL MODULE,CONTAINING        * 00900019
*        SUBROUTINES WHICH MUST ALWAYS BE IN CORE (IN ROOT SEGMENT)   * 00930019
*                                                                     * 00960019
*THE FOLLOWING SUBROUTINES ARE CONTAINED WITHIN IEBDSCP2 -            * 00980019
*TTOCC - CONVERTS TTR'S TO MBBCCHHR'S                                 * 01000019
*CCOTT - CONVERTS MBBCCHHR'S TO TTR'S                                 * 01020019
*IEBMGD - RETURNS A POINTER TO AN OUTPUT DIRECTORY ENTRY IN THE I/O   * 01040019
*        BUFFER.                                                      * 01060019
*IEBMBT - BUILDS CTLTAB AND SAVES IDE'S                               * 01080019
*IEBMGI - RETURNS A POINTER TO AN IDE IN CORE OR READS AN IDE IN IF IT* 01100019
*        IS SPILLED.                                                  * 01120019
*IEBMKO - RETAINS OUTPUT DIRECTORY ENTRIES IN CORE                    * 01140019
*INPUT - PARAMETER LIST FROM INVOKER                                  * 01160019
*        INPUT AND OUTPUT DIRECTORIES                                 * 01180019
*        MEMBERS TO BE COPIED                                         * 01200019
*                                                                     * 01220019
*OUTPUT - COPIED MEMBERS                                              * 01240019
*        MERGED OUTPUT DIRECTORY                                      * 01260019
*                                                                     * 01280019
*EXITS - NORMAL - RETURNS TO CALLER VIA IEBVTM WITH A RETURN CODE IN  * 01300019
*        REGISTER 15 OF -                                             * 01320019
*        00- NORMAL TERMINATION                                       * 01340019
*        04- AN ERROR CONDITION EXISTS PROCESSING CAN CONTINUE        * 01360019
*        08- AN ERROR CONDITION EXISTS - PROCESSING CANNOT CONTINUE   * 01380019
*       ERROR - SYSIN/SYSPRINT I/O ERRORS EXIT BACK TO I/O-ISSUING    * 01390019
*               MODULE                                                * 01400019
*                                                                     * 01410019
*EXTERNAL ROUTINES -                                                  * 01420019
*                  IEBDV1                                             * 01430019
*                  IEBSCN                                             * 01460019
*                  IEBDRD                                             * 01480019
*                  IEBVCT                                             * 01500019
*                  IEBVTT                                             * 01520019
*                  IEBVWS                                             * 01540019
*                  IEBDWR                                             * 01560019
*                  IEBVDM                                             * 01580019
*                  IEBVTM                                             * 01600019
*                  IEBVMS                                             * 01620019
*                  IEBMCM                                             * 01640019
*                  IEBDRB                                             * 01660019
*                  IEBIOE                                             * 01666019
*                  IGG019C8 (PCI APPENDAGE)                           * 01672019
*                  IEBBAM                                        S20201 01675020
*                                                                     * 01678019
*TABLES/WORK AREAS -                                                  * 01684019
*        ALL SWITCHES, TABLES, AND WORK AREAS NECESSARY FOR           * 01690019
*        MONITORING THE IEBCOPY UTILITY                               * 01700019
*                                                                     * 01720019
*ATTRIBUTES - SERIALLY REUSEABLE                                      * 01740019
*                                                                     * 01760019
*********************************************************************** 01780019
*                                                                       02160019
         EJECT                                                          02220019
* GENERAL REGISTER DEFINITION / USAGE                                   02280019
         SPACE 2                                                        02340019
R0       EQU   0             WORK REG                                   02400019
R1       EQU   1             WORK REG                                   02460019
R2       EQU   2             WORK REG                                   02520019
R3       EQU   3             WORK REG                                   02580019
R4       EQU   4             ADDR OF COMMUNICATION AREA                 02640019
R5       EQU   5             WORK REG                                   02700019
R6       EQU   6             WORK REG                                   02760019
R7       EQU   7             WORK REG                                   02820019
R8       EQU   8             WORK REG                                   02880019
R9       EQU   9             WORK REG                                   02940019
R10      EQU   10            WORK REG                                   03000019
R11      EQU   11            BASE REG 1                                 03060019
R12      EQU   12            WORK REG                                   03120019
R13      EQU   13            ADDR OF SAVE AREA                          03180019
R14      EQU   14            LINK-BACK REG                              03240019
R15      EQU   15            LINK-OUT REG                               03300019
TKOFLO   EQU   X'20'              BIT FOR TRACK OVERFLOW TEST OF DCB    03360019
TABLEN   EQU   10                 LENGTH OF ONE SETAB/CTLTAB ENTRY      03420019
C1CTEL   EQU   TABLEN                                                   03450019
CON12    EQU   12                 LENGTH OF FLAG+MBB+COUNT FIELDS       03480019
NLLEN    EQU   1300          LENGTH OF RESERVED NOTE-LIST WORK AREA     03570019
ZERO     EQU   X'00'              CONSTANT                              03660019
ONE      EQU   X'01'              CONSTANT                              03720019
FF       EQU   X'FF'              CONSTANT                              03750019
RPS      EQU   X'10'              RPS BIT IN DEVICE INFO         S20201 03757020
S16      EQU   16                 SHIFT VALUE OF 16              S20201 03764020
S24      EQU   24                 SHIFT VALUE OF 24              S20201 03771020
NMDISP   EQU   2             DISPLACEMENT OF NAME FRM BEG OF TBL ENTRY  03780019
NAMLEN   EQU   8                  LENGTH OF NAME IN TABLE(S)            03840019
DBOFF    EQU   4                  OFFSET FROM START OF DEVTYPE TO BLKSZ 03900019
SXTN     EQU   NAMLEN+NAMLEN      TWO TIMES LENGTH OF NAME FIELD        03960019
OPEN     EQU   X'10'              TO TEST DCBOFLGS FOR OPENED DCB       04080019
USERMASK EQU   X'60'              TO TEST FOR ANY USER TTRN IN DIR ENT  04140019
ADCVT    EQU   16                 ABSOLUTE ADDR OF POINTER TO CVT       04142019
BLNK     EQU   C' '               BLANK CHARACTER                       04144019
CHAINBK  EQU   4                  FOR SAVE AREA LINKAGE                 04146019
CHAINTHS EQU   8                  FOR SAVE AREA LINKAGE                 04148019
DDLORPG  EQU   X'80'              BIT TO TEST FOR DDNAME LIST OR PG NBR 04150019
DIV2     EQU   1                  TO DIVIDE BY 2 VIA 'SRL' INSTRUCTION  04152019
ENDOFPNO EQU   3                  END OF PAGE NBR AREA                  04154019
FDEOFF   EQU   22                 OFFSET TO 1ST DE IN BLOCK             04156019
LEN8     EQU   8                  LENGTH OF 8                           04158019
LFT8     EQU   8                  FOR 'SLL' INSTRUCTION                 04160019
LFT25    EQU   25                 USED IN 'SLL' INSTRUCTIONS            04162019
LFT27    EQU   27                 USED IN 'SLL' INSTRUCTIONS            04164019
LSYN1    EQU   78                 *  UP                                 04166019
LSYN2    EQU   21                 * SYNADAF                             04168019
LSYN3    EQU   22                 *  MSG                                04170019
MAXDE    EQU   80                 LENGTH(+6) OF MAXIMUM DIR ENTRY       04172019
MBLEN    EQU   120                LENGTH (-1) OF MSG BUFFER             04174019
NNLEN    EQU   4                  LENGTH OF 1 ENTRY IN NNPTRTAB         04176019
NOT0     EQU   7                  FOR BC INSTRUCTIONS                   04178019
OFF140I  EQU   0                  OFFSET IN MSG IEB140I FOR DDNAME      04180019
OFF141I  EQU   54                 OFFSET IN MSG IEB141I FOR MBRNAME     04182019
OFF159I  EQU   52                 OFFSET IN MSG IEB159I FOR DDNAME      04184019
PRFXLEN  EQU   7                  * AND MSG NBR                         04186019
REC      EQU   7                  OFFSET TO 'R' OF MBBCCHHR             04188019
RT26     EQU   26                 USED IN 'SRL' INSTRUCTIONS            04190019
RT30     EQU   30                 USED IN 'SRL' INSTRUCTIONS            04192019
SPILLEN  EQU   80                 LENGTH OF SYSUT3 RECORD               04194019
SYNMT    EQU   50                 * TEXT                         A44338 04196021
SYN1     EQU   42                 * USED                         A44338 04198021
SYN2     EQU   19                 *  TO                                 04200019
SYN3     EQU   18                 *  SET                                04202019
TKOFUDGE EQU   12                 FUDGE FACTOR FOR TRK OVFLO BFR ALLOC  04204019
L1       EQU   1                  LENGTH OF 1                           04206019
L2       EQU   2                  LENGTH OF 2                           04208019
L3       EQU   3                  LENGTH OF 3                           04210019
L4       EQU   4                  LENGTH OF 4                           04212019
P1       EQU   1                  TO ADD 1 TO SOMETHING                 04214019
P2       EQU   2                  TO ADD 2 TO SOMETHING                 04216019
P3       EQU   3                  TO ADD 3 TO SOMETHING                 04218019
P4       EQU   4                  TO ADD 4 TO SOMETHING                 04220019
P8       EQU   8                  TO ADD 8 TO SOMETHING                 04222019
P16      EQU   16                 TO ADD 16 TO SOMETHING                04224019
P24      EQU   24                 TO ADD 24 TO SOMETHING                04226019
P32      EQU   32                 TO ADD 32 TO SOMETHING                04228019
P40      EQU   40                 TO ADD 40 TO SOMETHING                04230019
X0       EQU   0                  OFFSET OF ZERO                        04232019
X1       EQU   1                  OFFSET OF 1                           04234019
X2       EQU   2                  OFFSET OF 2                           04236019
X3       EQU   3                  OFFSET OF 3                           04238019
X4       EQU   4                  OFFSET OF 4                           04240019
X6       EQU   6                  OFFSET OF 6                           04242019
X7       EQU   7                  OFFSET OF 7                           04244019
X8       EQU   8                  OFFSET OF 8                           04246019
X12      EQU   12                 OFFSET OF 12                          04248019
* FOLLOWING EQUATES MUST BE CHANGED IF DIRECTORY FORMAT IS CHANGED -    04260019
C1KL     EQU   9             OFFSET FROM BEGINNING OF A DIRECTORY BLOCK 04320019
*                            TO THE KEYLENGTH FIELD OF THE HDWR COUNT   04380019
C1DL     EQU   10            OFFSET FROM BEGINNING OF A DIRECTORY BLOCK 04440019
*                            TO THE DTALENGTH FIELD OF THE HDWR COUNT   04500019
C1DECT   EQU   11            OFFSET FROM BEGINNING OF DE TO COUNT BYTE  04560019
*                            OF NBR OF USER HALFWORDS                   04620019
C1FXL    EQU   12            LENGTH OF FIXED PORTION OF A DE -          04680019
*                            MBRNAME=8, MBRTTR=3, COUNT BYTE=1          04740019
KL       EQU   8                  LENGTH OF DIRECTORY KEY               04800019
BL       EQU   256                LENGTH OF ONE DIRECTORY BLOCK         04860019
KBLEN    EQU   KL+BL              LENGTH OF KEY + BLOCK                 04920019
SPIDEOFF EQU   12                 OFFSET FROM BEGINNING OF WORK AREA TO 04980019
*                                 ACCESS 1ST BYTE OF A SPILLED INPUT DE 05040019
CH4      EQU   C'4'               CHAR. CONSTANT FOR COMPLETION CODE    05160019
CH8      EQU   C'8'               CHAR. CONSTANT FOR COMPLETION CODE    05220019
         EJECT                                                          05280019
MAINFLOW EQU   *                                                        05340019
         SPACE 2                                                        05400019
         ENTRY IEBDSCME                                                 05440019
         ENTRY IEBDSCNI                                                 05480019
         SAVE  (14,12)                 SAVE REGS                        05520019
         BALR  R11,R0             ADDRESSIBILITY                        05580019
         USING *,R11                                                    05640019
         L     R4,VCOMM                ADDR OF COMMUNICATION AREA       05700019
         USING IEBMCA,R4               BASE REG FOR COMMUNICATION AREA  05760019
         ST    R13,SV1+CHAINBK    SET UP SAVE AREA LINKAGE              05820019
         LA    R10,SV1                                                  05880019
         ST    R10,CHAINTHS(R13)                                        05940019
         LR    R13,R10                                                  06000019
         LA    R2,NAMLEN          INITIALIZE REGS FOR INVOKATION TESTS  06060019
         SR    R7,R7                                                    06120019
         SR    R8,R8                                                    06180019
         SR    R9,R9                                                    06240019
         TM    X0(R1),DDLORPG     IS THERE A DDNAME LIST                06300019
         BO    EXTEST             IF NOT, TEST FOR PARAMETER - COMPRESS 06360019
         L     R5,X4(R1)          GET ADDR OF LIST                      06420019
         LH    R6,X0(R5)          GET LENGTH OF LIST                    06480019
         LA    R5,X2(R5)          ACTUAL ADDR OF LIST ENTRY             06540019
DDFIN    LTR   R6,R6              IS LIST EXHAUSTED                     06600019
         BNH   TSTPG              YES, GO SEE IF PAGE NBR IS SPECIFIED  06660019
         LA    R9,P1(R9)          NO, ADD 1 TO SLOT-MODIFIER            06720019
         CH    R9,DDSL(R8)        IS THIS SLOT MODIFYABLE BY USER       06780019
         BNE   NEXTDD             IF NOT, GO SET TO TRY NEXT SLOT       06840019
         CLI   X0(R5),ZERO        IS THERE A NON-ZERO ENTRY HERE        06900019
         BE    NXTDD1             IF NOT, USER DIDNT CHANGE THIS DDNAME 06960019
         LA    R14,DDLIST(R7)     ELSE GET ADDR WHERE TO MOVE THIS NAME 07020019
         MVC   X0(NAMLEN,R14),X0(R5)  OVLY ASSEMB DDNAME WITH USER'S    07080019
NXTDD1   AR    R7,R2              INDEX TO NEXT NAME IN DDNAME TABLE    07140019
         LA    R8,P2(R8)          POINT TO NEXT SLOT INDICATOR          07200019
NEXTDD   SR    R6,R2              DECREASE LENGTH OF LIST BY 8          07260019
         AR    R5,R2              POINT TO NEXT ENTRY IN USERS DDLIST   07320019
         B     DDFIN              LOOP TO SEE IF ALL DONE               07380019
*                                                                       07440019
*        USE USER'S PAGE NBR IF SPECIFIED                               07500019
*                                                                       07560019
TSTPG    TM    X4(R1),DDLORPG     IS THERE A USER-SPECIFIED PAGE NUMBER 07620019
         BO    EXTEST             IF NOT, CHECK FOR COMPRESS            07680019
         L     R5,X8(R1)          ADDR OF PAGE NBR-2 (LENGTH FIELD)     07740019
         LH    R6,X0(R5)          LENGTH OF NBR                         07800019
         BCTR  R6,R0              LENGTH-1 FOR EXECUTING MVC            07860019
         LA    R8,PGNO+ENDOFPNO   POINT TO END OF PAGE NBR AREA         07920019
         SR    R8,R6              ADJUST TO POINT TO 1ST CHARACTER TO   07980019
*                                 BE OVERLAYED BY USER'S PAGE NUMBER    08040019
         EX    R6,SETPGNO         MOVE IN USERS PAGE NUMBER             08100019
EXTEST   L     R1,X0(R1)          ADDR OF POINTER LIST                  08160019
         LH    R6,X0(R1)          LENGTH OF LIST                        08220019
         LTR   R6,R6              IS THERE A LIST                       08280019
         BNH   SETDCBNS           IF NOT, DONT LOOK FOR 'COMPRESS'      08340019
         CLC   X2(LEN8,R1),COMP   DOES PARAMETER = 'COMPRESS'           08400019
         BNE   SETDCBNS           IF NOT, IGNORE IT                     08460019
         OI    COMDCDSW,COMPRESS  ELSE SET SWITCH                       08520019
SETDCBNS LA    R6,CARDCB                                                08580019
         USING IHADCB,R6                                                08640019
         MVC   DCBDDNAM(NAMLEN),DDLIST                                  08700019
         LA    R6,PRTDCB                                                08760019
         MVC   DCBDDNAM(NAMLEN),DDLIST+P8                               08820019
         LA    R6,INDCB                                                 08880019
         MVC   DCBDDNAM(NAMLEN),DDLIST+P16                              08940019
         LA    R6,OUTDCB                                                09000019
         MVC   DCBDDNAM(NAMLEN),DDLIST+P24                              09060019
         LA    R6,UT3DCB                                                09120019
         MVC   DCBDDNAM(NAMLEN),DDLIST+P32                              09180019
         LA    R6,UT4DCB                                                09240019
         MVC   DCBDDNAM(NAMLEN),DDLIST+P40                              09300019
         DROP  R6                                                       09360019
         LA    R14,ENTSCAN        SET UP EXIT REG FOR IEBVMS USE        09420019
         STM   R11,R14,RESET1     SAVE CRITICAL REGS - USED BY IEBVTM   09450019
*                                 TO RESTORE FROM IF EXITING TO IEBSCN  09480019
         MVI   VTMFLG1,NOMAIN     SET INDICATOR IN CASE CANNOT OPEN     09510019
*                                 SYSIN OR CANT SUCCESSFULLY GETMAIN    09540019
         MVI   IOEF2,NOSYSIN      PRESET BAD-SYSIN SWITCH               09940019
         L     R15,VIEBDV0        ADDR OF ROUTINE TO OPEN AND VALIDATE  10380019
*                                 SYSIN AND SYSPRINT DCB'S              10440019
         BALR  R14,R15            LINK TO ROUTINE                       10500019
         NI    IOEF2,SPRNOPN      RESET ALL BUT POSSIBLY THIS BIT       10510019
         OI    CCSWITCH,FIRSTSCN  SET FIRST ENTRY TO SCN SWITCH         10520019
IEBGME   EQU   *                  ENTRY POINT - USED WHEN IEBVTM HAS    10530019
*                                 ISSUED A FREEMAIN BETWEEN COPY OPERA- 10540019
*                                 TIONS AND ANOTHER GETMAIN MUST BE DUN 10550019
IEBDSCME EQU   IEBGME                                                   10555019
         GETMAIN VC,LA=ADWANT,A=ADGOT                                   10560019
         LTR   R15,R15                                                  10620019
         BC    NOT0,LACKCORE      IF RC NOT 0, TELL USER AND TERMINATE  10660019
         MVI   VTMFLG1,ZERO       CLEAR ALL POSS ERROR INDICATORS       10710019
         SPACE 2                                                        10740019
***                                                                     10800019
* PERFORM ALL ONE-TIME INITIALIZATION HERE                              10860019
***                                                                     10920019
         LM    R7,R8,ADGOT        GET ADDR AND LENGTH OF ACQUIRED CORE  10980019
         AR    R8,R7                   ADDR OF LOWCORE + LENGTH =       11040019
*                                      ADDR OF HICORE (+1)              11100019
         L     R0,FREEAMT         GET LENGTH OF CORE TO FREE UP         11160019
         SR    R8,R0              SUBTR FROM CALCULATED MAX HI ADDRESS  11220019
         LR    R1,R8              GET ADDRESS FROM WHICH TO FREE UP     11280019
         ST    R8,HICOR                PUT MODIFIED ADDR INTO COMMAREA  11340019
         ST    R8,SVHI            SAVE ADDR OF HIGHEST AVAIL CORE       11400019
         ST    R8,END2ND2         SET ENDING ADDR OF 2ND I/O BUFFER     11460019
         ST    R7,ADNL                 ADDR OF NOTE-LIST WKAREA         11520019
         LA    R7,NLLEN(R7)            ADD LENGTH OF NOTE-LIST AREA     11580019
         ST    R7,ADWK            ADDR OF 128-BYTE WORK AREA            11640019
         LA    R7,WKLEN(R7)            ADD LENGTH                       11700019
         ST    R7,LOCOR           SET ADDR OF LOWEST UNUSED CORE        11760019
         ST    R7,INBEGIN              THIS IS ADDR OF 1ST CURRENTLY    11820019
*                                      UNUSED BYTE OF AVAILABLE CORE -  11880019
*                                      INDD TABLE WILL START HERE       11940019
         ST    R7,NXTINDS         SET AS ADDR OF CURRENT INDD NAME      12000019
         FREEMAIN   R,LV=(0),A=(1) FREE CORE AT HI END OF ACQUIRED AREA 12060019
         OI    FLG4,NEWODS        INITIALIZE 'OUTDD-NOT-WRITTEN-TO' SW  12090019
         SPACE 2                                                        12120019
         L     R15,VIEBSCN   GET ADDR OF CTL-CD SCAN MODULE             12960019
         BALR  R14,R15       EXIT TO CCSCAN                             13020019
         EJECT                                                          13080019
* CCSCAN RETURNS TO THIS POINT...THE SCAN WILL HAVE SET UP THE FOL-     13140019
* LOWING TABLES -                                                       13200019
*        INDDTAB   -TABLE OF INPUT DD NAMES SPECIFIED IN ''THE CUR-     13260019
*                   RENT'' INDD                                         13320019
*        OUTNAME   -NAME OF THE OUTPUT DD                               13380019
*        SETAB     -IF SELECT, TABLE OF NAMES TO BE SELECTED AND NEW-   13440019
*                   NAMES, IF ANY SPECIFIED.                            13500019
*                  -IF EXCLUDE, TABLE OF NAMES TO BE EXCLUDED           13560019
* CARDCB WILL BE OPENED BY IEBSCN WHEN FIRSTENT SW IS SET.              13620019
* ALSO, SEVERAL SWITCHES AND ADDRESSES WILL BE SET IN COMMAREA.         13680019
*                                                                       13740019
* CCSCAN CAN ENTER MAINFLOW AT THIS POINT WITH EITHER ONLY A NEW INDD-  13800019
* GROUP OR WITH BOTH A NEW INDD-GROUP AND NEW OUTDD.                    13860019
*                                                                       13920019
* FIRST, MAINFLOW PERFORMS ALL NECESSARY INITIALIZATION FOR THE NEW     13980019
* INDD-GROUP.                                                           14040019
ENTSCAN  EQU   *                                                        14100019
         XC    ADNNPTRT(L4),ADNNPTRT   ZERO PTR TO NEWNAME TABLE        14130019
         MVC   LOCOR(L4),SESTOP   SET CURRENT ADDR OF AVAIL CORE (LOW)  14160019
         MVC   INIDDCTS(L2),INDDCT SAVE NBR OF CURRENT INDD'S           14190019
*                                 THIS NUMBER MAY BE USED TO AID IN DE- 14234019
*                                 TERMINING WHETHER ANY INPUT DATA SETS 14241019
*                                 HAVE BEEN PROCESSED, SINCE 'INDDCT'   14248019
*                                 WILL HAVE BEEN DECREMENTED WHILE      14255019
*                                 'INIDDCTS' REMAINS UNCHANGED UNTIL    14262019
*                                 THE NEXT INDD-GROUP IS BEGUN.         14269019
         MVC   UFCT(L2),ENCT      PRIME COUNT OF NOT-YET-FOUND'S        14299019
         MVI   FLG3,ZERO               TURN OFF SWITCHES                14340019
         TM    COMDCDSW,SELECTSC+EXCLUDES  IS THIS A FULL COPY          14346019
         BZ    CKICT              IF SO, DONT TEST FOR ONLY 1 SETAB ENT 14352019
         LA    R6,ONE                                                   14360019
         CH    R6,COUNT           IS ONLY 1 MBR BEING SELECTED/EXCLUDED 14368019
         BNE   CKICT              IF NOT, DONT WORRY ABOUT FLAG         14376019
         L     R7,SEBEGIN         ELSE GET ADDR OF THE ONE SETAB ENTRY  14384019
         OI    X0(R7),SEBIT6      MAKE SURE LAST-ENTRY BIT IS SET       14394019
         B     CKICT              SINCE THIS IS 1ST TIME THRU THE CUR-  14414019
*                                 RENT INDD GROUP, DONT BUMP 'NXTINDS'  14434019
VCOMM    DC    V(IEBDSMCA)        ADDRESS OF COMMUNICATION REGION       14494019
COMP     DC    CL8'COMPRESS'      COMPARAND FOR 'PARM=COMPRESS'         14560019
DDSL     DC    H'5'               *INDEX *                              14660019
         DC    H'6'               *COUNTS*                              14760019
         DC    H'8'               * FOR  *                              14860019
         DC    H'9'               *VALID *                              14960019
         DC    H'10'              *DDLIST*                              15060019
         DC    H'11'              *SLOTS *                              15160019
SETPGNO  MVC   X0(L1,R8),X2(R5)   EXECUTED TO SET UP USER'S PAGE NUMBER 15260019
TENCON   DC    H'10'              CONSTANT OF 10                        15420019
         SPACE 2                                                        15480019
* CONTROL IS RETURNED TO THIS POINT BY THE TERMINATION ROUTINE WHENEVER 15540019
* IT DETERMINES THAT THERE ARE MORE UN-PROCESSED INPUT DATA SETS (DD-   15600019
* NAMES) IN THE INDD TABLE.                                             15660019
         SPACE 2                                                        15720019
IEBMNI   EQU   *                  ENTRY POINT FOR NXT IN DS OF SAME GRP 15780019
IEBDSCNI EQU   IEBMNI                                                   15810019
         L     R6,NXTINDS    SET ADDR OF NEXT INPUT DDNAME IN INDDTAB   15840019
         LA    R6,TABLEN(R6) NOTE - THIS IS THE ONLY DIFFERENCE BETW.   15900019
         ST    R6,NXTINDS    THE NEXT INPUT DS OF SAME INDD GRP AND     15960019
*                            THE 1ST INPUT DS OF A NEW INDD GRP.        16020019
         MVC   END2ND2(L4),SVHI   RESET ADDR OF END OF 2ND BUFFER       16024019
         SPACE 2                                                        16028019
CKICT    EQU   *                                                        16078019
         LH    R6,INDDCT     DECREMENT COUNT OF NBR OF INPUT DATA SETS  16140019
         LPR   R6,R6         STILL TO BE PROCESSED AFTER CURRENT ONE    16200019
         BCTR  R6,R0         SUBTR 1 FROM INDDCT                        16260019
         STH   R6,INDDCT                                                16320019
         MVC   HICOR(L4),SVHI     RE-INIT PTR TO HIGHEST AVAIL CORE     16380019
         XC    ICPT(OBCT+P2-ICPT),ICPT INITIALIZE AREA TO ZEROES        16440019
         MVI   FLG7,FRSTMBR       SET FIRST-MEMBER INDICATOR            16500019
         L     R6,NXTINDS                                               16560019
         LA    R1,INDCB           SET UP DCB ADDR FOR MOVING            16620019
         USING IHADCB,R1                                                16680019
         MVC   DCBDDNAM(NAMLEN),NMDISP(R6) INPUT DDNAME TO DCB          16740019
         DROP  R1                                                       16860019
         SPACE 1                                                        16960019
* NOW CHECK TO SEE IF OUTDD WAS PROCESSED BY SCAN JUST NOW              17030019
         TM    FLG4,NEWCOPOP      DID SCAN FIND A NEW COPY OPERATION    17100019
         BZ    EXVAL2             NO, GO OPEN AND VALIDATE INPUT ONLY   17170019
         SPACE 1                                                        17240019
         NI    FLG4,FF-NEWCOPOP   RESET NEW COPY OPERATION SWITCH       17310019
         MVI   STATUS,ZERO        CLEAR SWITCHES                        17400019
         XC    DIRBCNT(L2),DIRBCNT RESET DIRECTORY BLK COUNT TO 0       17460019
         MVI   NDBTR,ZERO         RESET BLOCKS PER TRACK COUNT   A36049 17490000
         OI    TAG,CTOUT          INDIC NEED TO CT NBR BLKS IN OUT DIR  17520019
* NOW GO TO VALIDATE I/O DEVICE ASSIGNMENTS                             17580019
         L     R15,VIEBDV1        GET ADDR OF E.P. FOR INPUT AND OUTPUT 17640019
         B     GOVAL              GO TO LINK TO VALIDATE INPUT & OUTPUT 17700019
EXVAL2   L     R15,VIEBDV2        ENTRY-POINT FOR INPUT ONLY            17760019
GOVAL    EQU   *                                                        17820019
         BALR  R14,R15       EXIT TO I/O VALIDATION ROUTINE             17880019
* RETURN FROM VALIDATION ONLY IF THE DCB(S) OPEN AND VALIDATED          17940019
         EJECT                                                          18000019
* THE MAIN PROGRAM NOW MUST DETERMINE SIZE AND LOCATION OF I/O BUFFERS. 18060019
         L     R15,VIEBBAM             ADDR OF BUFFER ALLOCATION S20201 18084020
         BALR  R14,R15                 EXIT TO BUFFER ALLOCATION S20201 18088020
         B     *+4(R15)           RETURNING FROM IEBBAM INTO     S20201 18092020
         B     ASRT1              BRANCH TABLE                   S20201 18096020
         B     SBFLGS             BRANCH TABLE                   S20201 18100020
         B     SLMSG              BRANCH TABLE                   S20201 18104020
ASRT1    EQU   *                                                        27180019
         L     R15,VIEBVCT        ADDR OF TABLE-SORTING RTNE            27240019
         BALR  R14,R15            LINK TO ROUTINE                       27300019
         EJECT                                                          27360019
* WHEN RETURNED TO AT THIS POINT, MAINFLOW EXPECTS SETAB TO BE SORTED.  27420019
* IF SELECT, LOCOR WILL CONTAIN ADDR IN SESTOP (IF NO NEWNAMES), OR     27480019
* ADDR OF NNPTRTAB END + 1 IF NEWNAMES WERE SPECIFIED.  NOW READY TO    27540019
* SET UP TO SEARCH FOR MEMBERS TO BE COPIED FROM THE CURRENT INPUT DATA 27640019
* SET.                                                                  27740019
SBFLGS   OI    FLG2,FMTSPL        INDICATE TO WRITE CT-KEY-DATA IF NEED 27840019
*                                 TO SPILL IDE'S TO SYSUT3 ARISES       28090019
         MVI   UT3SCTOR,ZERO      SET UT3 SECTOR VALUE TO 0      S20201 28092020
*                                   (USED ONLY IF ON AN RPS      S20201 28094020
*                                   DEVICE)                      S20201 28096020
         MVI   SENSE,ZERO         RESET SWITCHES                        28100019
         NI    STATUS,STAT5+STAT7 RESET SWITCHES                        28110019
         OI    STATUS,STAT1       INDIC READING INPUT DIRECTORY         28140019
         MVI   INSCTOR,ZERO       SET INPUT SECTOR VALUE TO 0    S20201 28150020
*                                   (USED ONLY IF ON AN RPS      S20201 28160020
*                                   DEVICE)                      S20201 28170020
         MVC   SVLO(L4),LOCOR     SAVE PTR TO LOWEST AVAILABLE CORE     28190019
         BAL   R2,RDLNK           LINK TO SET TO READ INTO 1ST BFR-AREA 28250019
         SPACE 2                                                        28309019
         MVC   WRTNEXT+X1(L3),BEGFST1  INITIALIZE POINTER FOR IEBDWR    28339019
         L     R15,VIEBMGD   ADDR OF RTNE TO FIND NEXT DE IN BFR        28380019
         BALR  R14,R15       GO GET THE 1ST DE FROM BFR                 28440019
         B     NOMBRS             IF NO DE FOUND, GO WRT MSG            28500019
*              IEBMGD RETURNS TO R14+4 IF DE IS FOUND                   28560019
         TM    COMDCDSW,SELECTSC+EXCLUDES  FULL COPY (NEITHER BIT ON)   28620019
         BZ    NMEQ          IF SO, GO SAVE DE AND BUILD CTLTAB ENTRY   28680019
         L     R9,NMAD            ADDR OF NEXT ENTRY IN SETAB           28740019
         TM    COMDCDSW,EXCLUDES  IS IT AN EXCLUSIVE COPY               28800019
         BO    CN1           IF SO, GO COMP NAME                        28860019
         SPACE 2                                                        28920019
* FOLLOWING CODE IS EXECUTED FOR SELECTIVE COPY ONLY                    28980019
TSL1     TM    X0(R9),SEBIT1+SEBIT4+SEBIT5                              29040019
*                            IS THIS ENTRY FLAGGED AS NEWNAME, DONTCO-  29100019
*                            PY, OR FOUND                               29160019
         BZ    CN2           IF NOT, GO COMP. NAME                      29220019
TS6      TM    X0(R9),SEBIT6      IS THIS THE LAST ENTRY IN THE SETAB   29280019
         BO    TFCT               IF SO, TEST COUNT OF ''FOUNDS''       29340019
ABMNM    LA    R9,TABLEN(R9)      SET POINTER TO CTLTAB TO NEXT ENTRY   29400019
         ST    R9,BUMP                                                  29460019
         ST    R9,NMAD            SINCE THIS IS A SELECT, SET POINTER   29520019
*                                 TO NAME BEING SOUGHT TO SAME AS BUMP  29580019
         B     TSL1               LOOP TO TEST NEXT ENTRY               29640019
CN2      L     R6,DEPTR           ADDR OF NEXT DE IN BFR                29700019
         CLC   NMDISP(NAMLEN,R9),X0(R6) TABLE NAME VS. MBRNAME FROM DE  29760019
         BL    TS6                IF TABLE LO, SEE IF THIS IS LAST ENT. 29820019
         BE    NMEQ               IF SAME, GO SAVE DE                   29880019
         BAL   R2,NXID1           GO LINK TO GET NEXT IDE               29940019
         B     CN2                IF DE FOUND, GO COMP WITH TABLE       30000019
TFCT     SR    R8,R8              EOD WAS REACHED (OR EOF)              30060019
         CH    R8,FCT             DOES NBR MBRS ''FOUND'' = ZERO        30120019
         BE    NOMBRSCP           IF SO, WRT 'NO MBRS COPIED' MSG       30180019
         TM    COMDCDSW,SELECTSC  IS THIS A SELECTIVE COPY              30240019
         BO    ONU                IF SO, GO SETUP FOR OUTPUT PRE-SCAN   30300019
         L     R9,BUMP            GET ADDR OF ''NEXT'' CTLTAB SLOT      30360019
         SH    R9,TENCON          SUBTRACT LENGTH OF ONE CTLTAB ENTRY   30450019
         OI    X0(R9),SEBIT6      SET LAST-ENTRY INDICATOR IN THIS ENT. 30520019
         B     ONU                NOW SET UP FOR OUTPUT PRE-SCAN        30600019
         SPACE 2                                                        30660019
* THIS CODE EXECUTED FOR AN EXCLUSIVE COPY ONLY                         30720019
CN1      EQU   *                                                        30780019
         L     R6,DEPTR           ADDR OF ''NEXT'' DE IN BFR            30840019
         CLC   NMDISP(NAMLEN,R9),X0(R6) TABLE NAME VS. MBRNAME FROM DE  30900019
         BH    NMEQ               IF TABLE HI, GO SAVE THIS DE, GET NXT 30960019
         BL    LSTEX              IF TABLE LO, GO UPDT PTR TO TBL IF    31020019
*                                 THIS ISNT LAST ENTRY                  31080019
*                                 TABLE NAME EQUALS MBRNAME             31140019
         BAL   R2,NXID1           GO GET NEXT DE PRIOR TO BUMPING PTR   31200019
LSTEX    TM    X0(R9),SEBIT6      IS THIS LAST ENTRY IN SETAB           31260019
         BO    NMEQ               IF SO, DONT TRY MORE COMPARING        31320019
         LA    R9,TABLEN(R9)      BUMP PTR TO NXT NAME TO BE EXCLUDED   31380019
         ST    R9,NMAD                                                  31440019
         B     CN1                GO TO COMPARE TABLE VS DE             31500019
         SPACE 2                                                        31560019
* THIS CODE IS EXECUTED FOR ALL MODES OF COPY                           31620019
NXID1    L     R15,VIEBMGD        ADDR OF GETDE SUBRTNE                 31680019
         BALR  R14,R15            LINK TO GET ADDR OF NXT DE IN BFR     31740019
         B     TFCT               IF NO DE GOTTEN SEE IF ANY WERE FOUND 31800019
*              IEBMGD RETURNS TO R14+4 IF DE IS FOUND                   31860019
         BR    R2                 EXIT TO INTERNAL LINK ADDR            31920019
         SPACE 1                                                        31980019
NMEQ     L     R15,VIEBMBT        GET ADDR OF BLDTAB SUBR               32040019
         BALR  R14,R15            LINK TO BLD CTLTAB ENTRY              32100019
         TM    COMDCDSW,SELECTSC  IS THIS A SELECTIVE COPY              32160019
         BO    DECUF              IF SO, GO TEST COUNT OF ''UN-FOUNDS'' 32220019
         SPACE 2                                                        32280019
* THIS CODE IS EXECUTED FOR EXCLUSIVE AND FULL COPY                     32340019
         LH    R8,ENCT            ADD 1 TO COUNT OF ENTRIES             32400019
         LPR   R8,R8              ASSURE POSITIVE VALUE                 32460019
         LA    R8,P1(R8)                                                32520019
         STH   R8,ENCT                                                  32580019
         BAL   R2,NXID1           GO GET POINTER TO NEXT DE             32640019
         TM    COMDCDSW,EXCLUDES  IS THIS AN EXCLUSIVE COPY             32700019
         BO    CN1                IF SO, GO CK NEXT DE VS TABLE         32760019
         B     NMEQ               ELSE GO BLD NEXT CTLTAB ENTRY         32820019
         SPACE 2                                                        32880019
* FOLLOWING CODE IS EXECUTED FOR SELECTIVE COPY ONLY                    32940019
DECUF    LH    R8,UFCT            GET COUNT OF ''NOT-YET-FOUNDS''       33000019
         BCTR  R8,R0              SUBTRACT 1 - ONE MORE WAS FOUND       33060019
         STH   R8,UFCT            SAVE UPDATED CT                       33120019
         TM    X0(R9),SEBIT6      IS IT LAST ENTRY IN SETAB    @SA69540 33180021
         BO    TFCT               IF SO, SEE IF ANY FOUND      @SA69540 33240021
         BAL   R2,NXID1           GO GET POINTER TO NEXT DE             33300019
         B     ABMNM              ELSE LOCATE NXT SELECT TABLE ENTRY    33360019
         EJECT                                                          33840019
ONU      EQU   *                                                        33890019
         SPACE 2                                                        33950019
* AT THIS POINT, PREPARE TO PERFORM PRE-SCAN OF OUTPUT DIRECTORY TO AS- 33960019
* SURE THAT NO DUPLICATE NAMED MEMBERS (WITHOUT REPLACE OPTION) GET     34020019
* COPIED.                                                               34080019
         NI    FLG5,FF-DEFSW      ASSURE INITIALIZATION SWITCH IS       34100019
*                                   OFF FOR IEBMGD                      34120019
         MVI   SENSE,ZERO         RESET SWITCHES                        34140019
         NI    FLG2,TRKS2+MBUSED  RESET RDEOF SWITCH                    34200019
         MVI   SWITCH1,ZERO       RESET IEBMGI SWITCHES                 34230019
         TM    COMDCDSW,COMPRESS  IS COMPRESS-IN-PLACE SPECIFIED        34260019
         BO    PRETTR             IF SO, SKIP PRESCAN AND GO DO TTRSORT 34320019
         MVI   STATUS,STAT2       INDIC RDG OUT DIR FROM OUTPUT DATASET 34800019
         MVI   OUTSCTOR,ZERO      SET OUTPUT SECTOR VALUE TO 0   S20201 34810020
*                                   (USED ONLY IF ON AN RPS      S20201 34820020
*                                   DEVICE)                      S20201 34830020
         TM    FLG4,ODALT         IS OUT DIR ON SYSUT4                  34860019
         BZ    SETORD             IF NOT, LEAVE 'STAT2' SET             34920019
         MVI   UT4SCTOR,ZERO      SET UT4 SECTOR VALUE TO 0      S20201 34930020
*                                   (USED ONLY IF ON AN RPS      S20201 34940020
*                                   DEVICE)                      S20201 34950020
         MVI   STATUS,STAT3       INDIC RDG OUT DIR FROM SYSUT4 DATASET 34980019
SETORD   EQU   *                                                        35040019
         BAL   R2,RDLNK           LINK TO SET TO READ INTO 1ST BFR-AREA 35090019
         SPACE 2                                                        35148019
         TM    FLG6,SPL           WERE ANY INPUT DE'S SPILLED           35160019
         BO    OSCIN              IF SO, DONT ATTEMPT TO RETAIN ODE'S   35220019
         MVC   SVFSTO(L4),LOCOR   ADDR OF 1ST OUT DIR BLOCK TO BE SAVED 35280019
         MVC   ALO(L4),LOCOR      INITIALIZE FOR IEBMKO - ADDR AND      35340019
         XC    OBCT(L2),OBCT      NBR OF BLOCKS SAVED IN CORE           35400019
         L     R15,VIEBMKO        ADDR OF ROUTINE TO RETAIN OUTPUT DE'S 35460019
         BALR  R14,R15            LINK TO ROUTINE                       35510019
         SPACE 2                                                        35569019
OSCIN    TM    FLG5,OSCAN         WAS SCAN OF OUT DIR INITIALIZED       35580019
         BO    GNODE              IF SO, BYPASS INITIALIZATION          35640019
         OI    FLG5,OSCAN+OSW1    INDIC OUTPUT DIRECTORY PRESCAN AND    35670019
*                                 SET INITIALIZATION BIT                35700019
         NI    FLG4,FF-LE         RESET IEBMGI'S LAST-ENTRY BIT         35730019
         XC    NNTCT(L2),NNTCT    SET NEWNAME-TABLE INDEX TO ZERO       35770019
         L     R15,VIEBMGD        ADDR OF RTNE TO GET DE FROM BFR       35820019
         BALR  R14,R15            LINK TO GET 1ST DE OF OUT DIR         35880019
         B     SETST5             INDIC NULL OUTPUT - NO OUTPUT DE'S    35940019
*              IEBMGD RETURNS TO R14+4 IF DE IS FOUND                   36000019
GNI      L     R15,VIEBMGI        RTNE TO GET NXT IDE (USING CTLTAB)    36060019
         BALR  R14,R15            LINK TO RTNE                          36120019
* IEBMGI WILL RETURN ADDR OF THE INPUT NAME (OR NEWNAME IF INPUT RE-    36180019
* NAMED) IN ''IDEAD''                                                   36240019
         TM    SWITCH1,MGINODE    WAS NO IDE RETURNED DUE TO UT3 ERROR  36247019
         BZ    CMPNS              NO - AN IDE WAS RETURNED              36254019
         NI    SWITCH1,FF-MGINODE RESET 'NO-IDE' SWITCH                 36261019
         L     R8,TABAD                                                 36268019
         SH    R8,TENCON          POINT TO CTLTAB ENTRY FOR WHICH THE   36275019
*                                 IDE COULD NOT BE RETRIEVED FROM UT3   36282019
         B     SETDNTCP           GO TO FLAG IT AS DONT-COPY            36289019
CMPNS    L     R6,DEPTR           ADDR OF NEXT OUTPUT DE IN BFR         36300019
         L     R7,IDEAD           ADDR OF NAME OF ''NEXT'' INPUT MEMBER 36360019
         CLC   X0(NAMLEN,R6),X0(R7) OUTPUT MBRNAME VS. INPUT MBRNAME    36420019
         BL    GNODE              IF OUTNAME LO, GET NEXT OUTNAME       36480019
         BH    TLE                IF HI, SEE IF THERE ARE MORE INPUT DE 36540019
         L     R9,NXTINDS         GET ADDR IF INDDTAB ENTRY FOR THIS DS 36600019
         TM    X0(R9),REPLACOP    IS INDD-LEVEL REPLACE SPECIFIED       36660019
         BO    GNODE              IF SO, GO GET NEXT OUTPUT DE          36720019
         L     R8,TABAD           GET PTR TO NEXT TABLE ELEMENT         36780019
         SH    R8,TENCON          ADJUST TO POINT TO CURRENT ELEMENT    36840019
         TM    X0(R8),SEBIT3      IS MEMBER-LEVEL REPLACE SPECIFIED     36900019
         BO    GNODE              IF SO, ALLOW TABLE ENTRY TO REMAIN    36960019
         LR    R7,R8              SAVE PTR TO ENTRY IN CASE ITS NEWNAME 37020019
         TM    X0(R8),SEBIT1      IS THIS A NEWNAME ENTRY               37080019
         BO    DCOLD              IF SO, FIND OLDNAME AND SET DONTCPY   37140019
SETDNTCP EQU   *                                                        37170019
         OI    X0(R8),SEBIT4      SET 'DONT-COPY' INDICATOR             37240019
         MVI   X2(R8),FF          SET OFFSET BYTE TO INHIBIT USE        37310019
         LH    R7,FCT             GET CT OF NBR OF CTLTAB ENTRIES       37380019
         LPR   R7,R7                                                    37440019
         BCTR  R7,R0              SUBTRACT 1 FROM CT, TO REFLECT DE-    37500019
*                                 LETED ENTRY                           37560019
         LTR   R7,R7              IS COUNT NOW SET TO ZERO              37620019
         BZ    NOMBRSCP           IF SO, WRT 'NO MBRS COPIED' MSG       37680019
         STH   R7,FCT             ELSE SET DECREMENTED COUNT            37740019
TLE      TM    FLG4,LE            WAS LAST IDE GOTTEN YET               37800019
         BO    ODEALL             IF SO, SEE IF OUT DIR PROCESSING DONE 37860019
         B     GNI                ELSE GO GET NEXT IDE                  37920019
GNODE    L     R15,VIEBMGD        SET TO GET ADDR OF NXT ODE IN BFR     37980019
         BALR  R14,R15            LINK TO SUBROUTINE                    38040019
         B     ODEALL             IF NO MORE ODE'S, SEE IF ALL SAVED    38100019
         B     CMPNS              ELSE GO COMPARE MBRNAMES              38160019
SETST5   OI    STATUS,STAT5       INDICATE ABSENCE OF AN OUTPUT DATASET 38220019
TSTCTO   TM    TAG,CTOUT          IS MAX LENGTH OF OUT DIR TO BE CALC   38280019
         BZ    ALLDUN             IF NOT, CLEANUP AND GO TO SORT CTLTAB 38320019
*                                 BY MEMBER TTR                         38360019
         TM    FLG2,RDEOF         WAS EOF REACHED ON OUTPUT DS          38400019
         BZ    RDTILEOF           IF NOT, NEED TO RD AND CT TILL EOF    38460019
ALLDUN   NI    TAG,FF-CTOUT       RESET SWITCH USED BY READ ROUTINE     38520019
         NI    FLG2,FF-RDEOF      RESET EOF-REACHED SWITCH              38580019
         NI    FLG4,FF-LE         RESET LAST-ENTRY-REACHED INDICATOR    38640019
         B     PRETTR             GO PREPARE FOR TTR SORT               38700019
ODEALL   TM    FLG2,RDEOF         DID EOF OCCUR ON OUTPUT DIRECTORY YET 38760019
         BO    ALLDUN             IF SO, DONT TRY TO READ MORE          38820019
         TM    FLG4,LE            NEED TO DO MORE SCANNING OF OUTPUT    38830019
         BO    TF6SPL             NO.  SEE IF POSSIBLE TO RETAIN MORE   38840019
*                                 ODE'S IN CORE                         38850019
RDMOROUT EQU   *                                                        38860019
         MVI   SENSE,ZERO         RESET BITS IN CASE SYSUT3 WAS USED    38870019
         BAL   R2,RDLNK           ELSE READ MORE OF OUTPUT DIRECTORY    38880019
         TM    FLG6,SPL           WERE ANY IDE'S SPILLED                38900019
         BO    TRYLE              IF SO, NAMES ARE TO BE COMP  @SA67504 38920021
         TM    FLG5,NSP           DID IEBMKO INDIC NO SPACE REMAINING   38940019
         BO    TRYLE              IF SO, NAMES ARE TO BE COMP  @SA67504 39000021
         L     R15,VIEBMKO        ADDR OF ROUTINE TO RETAIN OUTPUT DE'S 39060019
         BALR  R14,R15            LINK TO ROUTINE                       39120019
TRYLE    TM    FLG4,LE            WAS LAST IDE GOTTEN YET      @SA67504 39170021
         BZ    GNODE              NO, GET NEXT ODE TO COMP     @SA67504 39220021
         NI    FLG5,FF-DEFSW      RESET INIT SWITCH, LAST IDE  @SA67504 39230021
         B     GNODE              MAY NOT BE COMP TO ALL ODE'S @SA67504 39240021
TF6SPL   TM    FLG6,SPL           WAS ANY ''SPILLING'' DONE             39310019
         BO    TSTCTO             YES - SEE IF NEED TO COUNT OUTPUT     39320019
*                                 DIRECTORY BLOCKS                      39330019
         B     RDMOROUT           NO, SO TRY TO READ AND RETAIN MORE    39340019
RDTILEOF MVI   SENSE,ZERO         RESET BITS POSSIBLY USED TO READ UT3  39360019
LNKRTEOF BAL   R2,RDLNK           GO TO READ AND COUNT OUT DIR BLOCKS   39380019
         TM    FLG2,RDEOF         WAS EOF REACHED ON OUTPUT DIRECTORY   39410019
         BZ    LNKRTEOF           NO, LOOP UNTIL OUTPUT DIR EOF REACHED 39440019
         B     ALLDUN             WHEN GET HERE, MAX NO BLKS IS CALC    39480019
DCOLD    L     R8,NNTABAD         PTR TO 'NXT' NEWNAME PTRTAB ENTRY     39540019
         LA    R15,NNLEN          LENGTH OF ONE NNPTRTAB ENTRY          39600019
         SR    R8,R15             ADJUST POINTER TO CURRENT ENTRY       39660019
         L     R8,X0(R8)          POINT TO OLDNAME ENTRY IN CTLTAB      39720019
         TM    X0(R8),SEBIT5      IS OLDNAME FLAGGED AS 'FOUND'         39780019
         BZ    TLE                IF NOT, GET NEXT ENTRY.  THE INDD     39840019
*                                 ON WHICH THIS OLDNAME MIGHT BE FOUND  39900019
*                                 MAY HAVE THE INDD-REPLACE OPTION.     39960019
         OI    X0(R7),SEBIT4      SET 'DONT-COPY' INDICATOR IN NEWNAME  40020019
*                                 CTLTAB ELEMENT                        40080019
         B     SETDNTCP           GO TO SET IT IN THE OLDNAME ELEMENT   40140019
         EJECT                                                          40200019
LACKCORE EQU   *        MIN CORE NOT AVAIL - TERMINATE ENTIRE JOB       40260019
         MVI   MSG1+P1,M38        MSG CODE                              40290019
         CLI   RCBUF,CH8          IS COMPLETION CODE 8 OR HIGHER A44144 40300000
         BNL   SLMSG              YES- DON'T SET RETURN CODE     A44144 40310000
         MVI   RCBUF,CH8          SET COMPLETION CODE            A44144 40340022
SLMSG    EQU   *                                                        40390019
         MVI   MSG1,LASTMSG       INDICATE THE LAST MSG CODE IN LIST    40400019
EXWRM    EQU   *                                                        40410019
         L     R15,VIEBVMS        ADDR OF MESSAGE WRITER                40420019
         BALR  R14,R15            WRITE MESSAGE                         40430019
         L     R15,VIEBVTM        ADDR OF STEP/OPERATION TERMINATOR     40440019
         BALR  R14,R15            EXIT TO TERMINATE THIS COPY OPERATION 40450019
*                                 NO RETURN WILL BE MADE TO THIS POINT  40460019
*                                 BY IEBVTM                             40470019
NOMBRS   EQU   *                  NULL INPUT DATA SET MSG               41940019
         TM    COMDCDSW,COMPRESS  WAS A COMPRESS IN PLACE TO HAVE BEEN  41942019
*                                 DONE                                  41944019
         BZ    SETM45             IF NOT, GO SET UP MESSAGE             41946019
*              IF YES, NEED TO MAKE SURE THAT, WHEN THE OUTPUT DCB IS   41948019
*              CLOSED, THE DSCB WILL SHOW ALL UNUSED SPACE FOLLOWING    41950019
*              THE DIRECTORY -                                          41952019
         MVC   READNEXT(L4),BCB   SET POINTER FOR READ                  41953019
         MVI   SENSE,SENSE4       SET TO READ WITH NO DATA XFR          41954019
         MVI   STATUS,STAT2       INDIC READING OUTPUT DIRECTORY FROM   41956019
*                                 OUTPUT DATA SET                       41958019
         BAL   R2,RDLNK           GO TO CALL IEBDRD TO READ THE DIR.    41960019
         LA    R1,OUTDCB          POINT TO THE OUTPUT DCB JUST USED     41962019
         USING IHADCB,R1                                                41964019
         MVC   OUTFDAD(LEN8),DCBFDAD SAVE LAST RECORD'S FULL DISK ADDR  41965019
         LA    R2,FDAD(R1)        POINT TO DCBFDAD FIELD WITHIN THE DCB 41966019
         DROP  R1                                                       41968019
         L     R15,VCCOTT                                               41970019
         BALR  R14,R15            GO TO CONVERT THE MBBCCHHR OF THE EOF 41972019
*                                 OF THE OUTPUT DIRECTORY TO A TTR      41974019
         MVC   OUTDS1(L4),WKA1    SAVE TTR OF EOF OF OUTPUT DIRECTORY   41975019
         MVC   OUTPTTR(LEN8),OUTDS1 ALSO SAVE TTR AND TRKBALANCE AGAIN  41976019
         NI    FLG2,FF-RDEOF      RESET 'EOF REACHED' BIT               41978019
SETM45   EQU   *                                                        41980019
         MVI   MSG1+P1,M45        MSG CODE                              42000019
         MVI   NAMEDISP,OFF140I   OFFSET IN MSG IEB140I FOR NAME        42020019
NOMSETUP EQU   *                                                        42040019
         OI    FLG7,SUPPRMSG+NOPRNBDB  SET INDICATORS TO SUPPRESS PRIN- 42045019
*                                 TING OF MEMBERNAMES AND UNUSED DIREC- 42050019
*                                 TORY BLOCKS MSGS BY THE IEBVTM ROUT.  42055019
         TM    FLG4,NEWODS        HAS A DIRECTORY MERGE OCCURED         42055719
*                                   TO CURRENT OUTPUT DATA SET          42056419
         BO    LEAVESET           NO, LEAVE FLG7 AS SET                 42057119
         NI    FLG7,FF-NOPRNBDB   RESET DON'T PRINT UNUSED              42057819
*                                   DIRECTORY BLOCKS MSG SWITCH         42058519
LEAVESET EQU   *                                                        42059219
         L     R1,NXTINDS                                               42060019
         MVC   NAMEFLD(LEN8),NMDISP(R1) DDNAME TO BE PUT INTO MSG       42080019
         MVI   PARAMS,NAME                                              42100019
         MVI   MSG1,LASTMSG+PBIT                                        42140019
         B     EXWRM              WRT MSG AND EXIT TO IEBVTM            42150019
NOMBRSCP EQU   *                  NO MBRS COPIED FROM INPUT DATA SET    42160019
*                                 REFERENCED BY (DDNAME)                42170019
         MVI   MSG1+P1,NOMBCPDM   MSG CODE                              42190019
         MVI   NAMEDISP,OFF159I   OFFSET FOR NAME IN MSG                42210019
         B     NOMSETUP           GO SET UP REST OF MSG INDICATORS      42240019
         EJECT                                                          42960019
PRETTR   NI    FLG5,OSCAN+NSP     RESET DEFSW, NMUP, OSW1 BITS          43020019
         L     R15,VIEBVTT        ADDR OF TTR SORT ROUTINE              43080019
         BALR  R14,R15            GO SORT VALID CTLTAB ENTRIES BY TTR   43140019
* UPON RETURN, THOSE CTLTAB ENTRIES WHICH WERE FLAGGED AS FOUND (SEBIT5 43200019
* ON) AND NOT NEWNAME (SEBIT1) OR DONTCOPY (SEBIT4) WILL BE SORTED SUCH 43260019
* THAT EACH ENTRY HAS ONE DE-POINTER IN ALPHAMERIC SEQUENCE AND ANOTHER 43320019
* DE-POINTER IN TTR SEQUENCE.                                           43380019
         TM    COMDCDSW,COMPRESS  IS THIS A COMPRESS-IN-PLACE           43400019
         BO    CMPRSS             IF SO, GO TO EXIT TO IEBMCM           43420019
         TM    FLG6,OIC           WAS ALL OUTPUT DIR RETAINED IN CORE   43440019
         BZ    GFCT               IF NOT, GO PREPARE TO GET NEXT IDE    43500019
         LA    R6,OUTDCB          POINT TO OUTPUT DCB                   43510019
         USING IHADCB,R6                                                43520019
         TM    DCBRECFM,TKOFLO    IS TRACK OVERFLOW SPECIFIED ON OUTPUT 43530019
         BO    GFCT               IF SO, DONT CHANGE BUFFER ALLOCATION  43540019
         DROP  R6                                                       43550019
         SPACE 2                                                        43560019
SPLITBUF EQU   *        SUBRTNE TO ATTEMPT TO ALLOC SECOND BFR AREA     43620019
         L     R5,ICPT            ADDR OF CTLTAB ENTRY FOR MOST RECENT  43680019
*                                 INPUT DIR ENTRY SAVED IN CORE         43740019
         MVC   WKA1(L4),X6(R5)    PUT ADDR OF DE (FROM ALPHABETICALLY   43800019
*                                 SEQUENCED SIDE OF CTLTAB) INTO WKAREA 43860019
         L     R5,WKA1            GET POINTER TO THE DIRECTORY ENTRY    43920019
         L     R6,ALO             ADDR+1 OF END OF LAST OUTPUT DIR      43980019
*                                 BLOCK SAVED IN CORE                   44040019
         SR    R5,R6              DIFFERENCE = AMT OF AVAILABLE CORE    44100019
         L     R7,BUFSIZ          LENGTH OF 1/2 BUFFER (ORIGINAL ALLOC) 44160019
         AR    R7,R7              MPLY BY 2 TO GET ENTIRE LENGTH        44220019
         CR    R5,R7              IS AVAILABLE CORE LESS THAN THIS AMT  44280019
         BL    GFCT               IF SO, DON'T ALLOCATE                 44340019
         MVC   ENDFST1(L4),END2ND2 SET PTR TO END OF 1ST BUFFER EQ TO   44400019
*                                 THE ADDR WHICH HAD BEEN USED (UNTIL   44460019
*                                 NOW) AS THE ADDR OF THE END OF THE    44520019
*                                 2ND BUFFER.                           44580019
         MVC   BEGFST2(L4),ALO    SET PTR TO START OF NEW 2ND BUFFER    44640019
         AR    R6,R5              ADD LENGTH OF AREA TO BEGINNING ADDR  44700019
         BCTR  R6,R0              SUBTR 1 TO PREVENT OVLAYING INPUT DES 44760019
         ST    R6,END2ND2         SET ADDR OF END OF AREA               44820019
         OI    FLG1,P2FLG1        SET 2-BUFFER-AREAS FLAG IN BCB        44880019
* END OF SUBROUTINE ''SPLITBUF''                                        44940019
         SPACE 2                                                        45000019
GFCT     EQU   *                                                        45060019
         OI    FLG7,COP           SET TO GET INPUT DE'S IN TTR SEQUENCE 45420019
*                                 DURING COPY PHASE                     45480019
         MVI   OUTSCTOR,ZERO      SET OUTPUT SECTOR VALUE TO 0   S20201 45490020
*                                   (USED ONLY IF ON AN RPS      S20201 45500020
*                                   DEVICE)                      S20201 45510020
         XC    SWITCH1(L2),SWITCH1 RESET 'SWITCH1' AND 'UTTRFLAG' BYTES 45520019
         MVC   WRTNEXT+P1(L3),BEGFST1  INIT WHERE TO WRITE FROM         45560019
         MVC   READNEXT(L4),WRTNEXT    INIT WHERE TO READ INTO          45600019
RDNXTOK  EQU   *                                                        45660019
         L     R15,VIEBMGI        SUBRTNE TO GET ADDR OF INPUT DE       45720019
         BALR  R14,R15            LINK TO RTNE                          45780019
         TM    SWITCH1,MGINODE    WAS NO IDE RETURNED DUE TO UT3 ERROR  45784019
         BZ    GOTIDE1            NO - AN IDE WAS RETURNED              45788019
         NI    SWITCH1,FF-MGINODE RESET 'NO-IDE' SWITCH                 45792019
         TM    FLG4,LE            WAS THIS THE ONLY/LAST IDE TO TRY TO  45796019
*                                 GET                                   45800019
         BO    NOMBRSCP           YES - WRT NO MBRS COPIED MSG          45804019
         L     R8,TABAD           NO                                    45808019
         SH    R8,TENCON          POINT TO CTLTAB ENTRY FOR THE IDE     45812019
*                                 WHICH WAS NOT RETRIEVABLE FROM SYSUT3 45816019
         OI    X0(R8),SEBIT4      SET 'DONT-COPY' INDICATOR             45820019
         B     RDNXTOK            TRY FOR ANOTHER IDE                   45824019
GOTIDE1  EQU   *                                                        45828019
         L     R6,IDEAD           GET ADDR OF 1ST IDE                   45840019
         NI    NAMLEN+P3(R6),FF-ALIAS  ASSURE THAT THIS DE ISNT FLAG-   45920019
*                                 GED AS AN ALIAS                       46000019
MVMTTR   MVC   OLDTTR(L3),NAMLEN(R6)   MOVE MEMBER TTR FOR COMPARING    46070019
         LA    R1,INDCB           SET UP PARAM REGS TO CONVERT INPUT    46140019
         MVC   WKA1(L3),OLDTTR    GET TTR OF NEXT MEMBER TO BE READ     46200019
         MVI   WKA1+P3,ZERO       CLEAR LOW ORDER BYTE                  46260019
         L     R0,WKA1            PUT INTO PARAMETER REG                46320019
         LA    R3,SETRDNXT        SET RETURN REG TO NSI AFTER CONVERT   46380019
LKTTOCC  LA    R2,FDAD(R1)        ADDR TO PUT MBBCCHHR (DCBFDAD)        46440019
         L     R15,VTTOCC                                               46500019
         BALR  R14,R15            GO LINK TO CONVERT TTR TO MBBCCHHR    46560019
         IC    R6,REC(R2)         GET 'R' FROM MBBCCHHR IN DCBFDAD      46620019
         BCTR  R6,R0              SUBTRACT 1 FROM 'R'                   46680019
         STC   R6,REC(R2)         PUT BACK DECREMENTED 'R'              46740019
         BR    R3                 EXIT TO NSI OR TO CALLER              46800019
SETRDNXT EQU   *                                                        46860019
         NI    STATUS,STAT5+STAT7+STAT8                                 46920019
         OI    STATUS,STAT4       INDICATE READING INPUT MEMBER         46980019
         NI    FLG2,FF-RDEOF      TURN OFF EOF-REACHED SWITCH           47040019
         NI    TAG,TAG5+TAG6+TAG8 RESET TAG1,2,3,4, AND 7               47100019
         OI    TAG,TAG2           INDICATE COPYING MBR TO OUTPUT DS     47160019
         OI    WSFLAG,FRSTMREC    SET FIRST RECORD OF A MEMBER   A34431 47170020
*                                  SWITCH                        A34431 47180020
         NI    WSFLAG,FF-USERTTR  RESET POSSIBLE NOTELIST/USERTTR SW    47190019
         L     R6,IDEAD           ADDR OF CURRENT IDE                   47220019
         TM    C1DECT(R6),USERMASK  ANY USER OR NOTE-LIST TTRN'S        47280019
         BZ    TSTRB              IF NOT, TEST FOR RE/DE-BLOCKING       47340019
         OI    WSFLAG,USERTTR     INDICATE PRESENCE OF NOTELIST AND/OR  47470019
*                                 USER TTRN(S)                          47480019
         SR    R7,R7              SET INDICATOR REG TO 0                47490019
         IC    R2,C1DECT(R6)      GET 'C' BYTE FROM DIRECTORY ENTRY     47520019
         SLL   R2,LFT25           ISOLATE NBR OF NOTE-LIST/USER TTR'S   47580019
         SRL   R2,RT30            USE THIS NBR AS LOOP CONTROL          47640019
         LA    R6,C1DECT+P1(R6)   POINT TO 1ST TTRN IN THIS DIR ENTRY   47700019
NLPREP   CLI   X3(R6),ZERO        IS 'N' EQUAL TO '0'                   47760019
         BE    NLSETUP            IF SO, GET NEXT TTRN (IF ANY MORE)    47820019
         LA    R7,P1              SET INDICATOR REG TO 1                47880019
         MVC   WKA1(L3),X0(R6)    SAVE TTR OF THIS NOTE-LIST            47940019
*                                 (ASSUMES ONLY ONE NOTE-LIST PER MBR)  48000019
         MVI   WKA1+P3,ZERO       CLEAR LOW ORDER BYTE FOR CONVERSION   48040019
NLSETUP  LA    R6,X4(R6)          POINT TO 'N' FIELD OF NEXT TTRN       48080019
         BCT   R2,NLPREP          LOOP IF MORE TO CHECK                 48120019
         LTR   R7,R7              IS ANY NOTE LIST TTRN PRESENT         48180019
         BZ    GONOMODS           IF NOT, GO PROCESS THIS MEMBER NOW    48240019
         L     R0,WKA1            ELSE GET INPUT TTR OF NOTE-LIST REC   48300019
         LA    R1,INDCB           ADDR OF DCB TO BE USED                48420019
         MVC   WKA1+P8(LEN8),FDAD(R1)  SAVE CURRENT MEMBER'S MBBCCHHR   48480019
         BAL   R3,LKTTOCC         GO TO LINK TO CONVERT TTR TO MBBCCHHR 48540019
         MVI   SENSE,SENSE2+SENSE3 INDIC TO READ 1 NOTE-LIST RECORD     48600019
         L     R3,READNEXT        SAVE CURRENT BUFFER-POINTER           48660019
         MVC   READNEXT(L4),ADNL  SET TO READ INTO NOTE-LIST BUFFER     48720019
         L     R15,VIEBDRD        ADDR OF READ ROUTINE                  48780019
         BALR  R14,R15            GO TO READ NOTE-LIST INTO CORE        48840019
         ST    R3,READNEXT        RESTORE SAVED BUFFER-POINTER          48900019
         LA    R1,INDCB                                                 48960019
         MVC   FDAD(LEN8,R1),WKA1+P8   RESTORE MEMBER'S MBBCCHHR TO DCB 49020019
         B     GONOMODS           NOW GO TO PROCESS MEMBER              49080019
CMPRSS   EQU   *                                                        49140019
         L     R15,VIEBMCM        ADDR OF COMPRESS-IN-PLACE ROUTINE     49380019
         BALR  R14,R15            LINK TO PERFORM COMPRESS              49440019
         B     *+P4(R15)          UPON RETURN FROM IEBMCM, R15 HAS A    49500019
*                                 COMPLETION CODE IN IT -               49560019
         B     SETRDNXT           R15 = 0, SO SET UP TO COPY     A34431 49600020
*                                   THIS MEMBER                  A34431 49640020
         B     MRGDONE            R15 = 4, SO BYPASS DIRECTORY MERGE    49680019
TSTRB    TM    FLG3,REBLK         WAS RE/DE-BLOCKING SPECIFIED          49920019
         BZ    GONOMODS           IF NOT, GO TO 'NORMAL' COPY ROUTINE   49980019
         MVI   INSCTOR,ZERO       SET INPUT SECTOR VALUE TO 0    S20201 49990020
*                                   (USED ONLY IF ON AN RPS      S20201 50000020
*                                   DEVICE)                      S20201 50010020
         L     R15,VIEBDRB        ADDR OF RE/DE-BLOCKING ROUTINE        50040019
         BALR  R14,R15            LINK TO ROUTINE                       50080019
         B     UPDATR             CLEAN-UP AND SEE IF MORE              50130019
GONOMODS MVI   SENSE,ZERO         RESET SWITCHES USED BY I/O ROUTINES   50160019
         L     R15,VIEBMNM        ADDR OF ROUTINE TO COPY A MEMBER -    50190019
*                                 NO RE/DE-BLOCKING OF THIS MEMBER WILL 50220019
*                                 BE DONE.  THE MEMBER MAY HAVE USER    50250019
*                                 TTRN'S AND/OR A NOTE LIST.            50280019
         BALR  R14,R15            LINK TO ROUTINE                       50340019
UPDATR   EQU   *                                                        50370019
         L     R6,IDEAD           LOCATE CURRENT DIR ENTRY              50406019
         MVC   NAMLEN(L3,R6),SVTTR PUT INCREMENTED TTR INTO DIR ENTRY   50439019
TSTUT3   EQU   *                                                        50452019
         L     R8,TABAD           GET CTLTAB PTR                        50456019
         SH    R8,TENCON          ADJUST TO POINT TO CURRENT ELEMENT    50460019
         NI    TAG,TAG5+TAG6+TAG8 RESET POSSIBLE UNWANTED BITS          50480019
         OI    TAG,TAG2           INDICATE WRITING OUTPUT MEMBER DATA   50500019
         CLI   X2(R8),ONE         WAS THIS DE ON SYSUT3                 50530019
         BE    PUTBACK            IF SO, WRITE UPDATED DE BACK IN       50560019
*                                 PLACE ONTO SYSUT3                     50600019
TLSTCPYD TM    FLG4,LE            HAS LAST CTLTAB ENTRY BEEN PROCESSED  50640019
         BO    MBRSCPYD           IF SO, ALL MBRS ARE NOW COPIED        50700019
         L     R6,IDEAD           LOCATE CURRENT UPDATED DE             50760019
         MVI   UTTRFLAG,ZERO      RESET TTRN/NOTELIST FLAG FOR IEBVWS   50790019
         L     R7,ADNL            ADDR OF WORK AREA                     50860019
         MVC   X0(MAXDE,R7),X0(R6) MOVE DE (+ ANYTHING) TO AREA         50940019
GOTOGI2  EQU   *                                                        51030019
         L     R15,VIEBMGI        ELSE GO LOCATE NXT MEMBER'S DIR ENTRY 51060019
         BALR  R14,R15            LINK TO ROUTINE                       51090019
         TM    SWITCH1,MGINODE    WAS NO IDE RETURNED DUE TO UT3 ERROR  51123019
         BZ    GOTIDE2            NO - AN IDE WAS RETURNED              51126019
         NI    SWITCH1,FF-MGINODE RESET 'NO-IDE' SWITCH                 51129019
         TM    FLG4,LE            ANY MORE IDE'S TO TRY TO GET          51132019
         BO    MBRSCPYD           NO - ALL MEMBERS WHOSE IDE'S WERE AC- 51135019
*                                 CESSIBLE HAVE NOW BEEN COPIED         51138019
         B     GOTOGI2            YES - TRY FOR NEXT IDE                51141019
GOTIDE2  EQU   *                                                        51144019
         MVI   SENSE,ZERO         RESET BITS POSSIBLY USED TO READ UT3  51150019
         L     R8,IDEAD           GET POINTER TO DIR ENTRY              51180019
         LR    R6,R8              SET UP POINTER IN CASE 'BZ' TAKEN     51240019
         TM    NAMLEN+P3(R8),ALIAS DOES THIS DE REFERENCE AN ALIAS      51300019
         BZ    MVMTTR             IF NOT, CANT BE SAME AS PREVIOUS MBR, 51360019
*                                 SO GO SAVE IT AND COPY                51420019
         CLC   NAMLEN(L3,R8),OLDTTR IS THIS INPUT MEMBER TTR SAME AS    51450019
*                                 THE INPUT MEMBER TTR OF THE MEMBER    51480019
*                                 JUST NOW COPIED                       51510019
         BE    PROCAL             IF SO, THEN MAIN-MBR DIR ENTRY HAS    51540019
*                                 BEEN PROCESSED, SO MERGE FIELDS       51600019
*        IF NOT EQUAL, CURRENT MEMBER'S TTR MUST BE GREATER THAN THE    51660019
*        TTR OF THE MEMBER JUST COPIED.                                 51720019
         NI    NAMLEN+P3(R8),FF-ALIAS  IF THIS INPUT MBR-TTR IS G.T.    51780019
*              THE PRECEEDING MBR-TTR, AND IS AN ALIAS, THEN NO MAIN-   51840019
*              MEMBER DIRECTORY ENTRY IS PRESENT.  THIS DIRECTORY ENTRY 51900019
*              IS THUS MADE TO BE A MAIN-MEMBER ENTRY.                  51960019
         B     MVMTTR             GO PROCESS AS IF IT WERE NOT AN ALIAS 52020019
         SPACE 2                                                        52080019
* IF MEMBER TTR EQ OLDTTR, AN ALIAS HAS BEEN OR IS BEING PROCESSED.     52140019
* THE MEMBER TTR AND UP TO 3 USER TTRN'S WILL BE MERGED FROM THE DIREC- 52200019
* TORY ENTRY WHICH WAS ''SAVED'' TO THE CURRENT DIRECTORY ENTRY.        52260019
PROCAL   EQU   *                                                        52320019
         MVC   NAMLEN(L3,R8),NAMLEN(R7) OVLAY MBR-TTR IN CURRENT D.E.   52380019
         IC    R5,C1DECT(R8)      GET 'C' BYTE FROM ALIAS DE            52440019
         SLL   R5,LFT25           SHIFT OUT 'ALIAS' BIT                 52500019
         SRL   R5,RT30            ISOLATE USER-TTRN COUNT BITS          52560019
         LA    R6,C1FXL(R8)       SET PTR TO CURRENT TTRN'S             52620019
         LA    R3,C1FXL(R7)       SET PTR TO PREVIOUS DE'S TTRN'S       52680019
         LTR   R5,R5              ANY USER/NOTELIST TTRN TO BE REPLACED 52740019
         BZ    TSTUT3             IF NOT, GO SEE WHERE CURR DE CAME FRM 52800019
MVLOOP   EQU   *                                                        52830019
         MVC   X0(L4,R6),X0(R3)   MOVE TTRN FROM PREVIOUS DE TO CURR DE 52880019
         LA    R3,P4(R3)          BUMP POINTERS TO PREVIOUS             52930019
         LA    R6,P4(R6)               AND CURRENT TTRN'S               52980019
         BCT   R5,MVLOOP          DECREM TTRN COUNT BY 1 AND LOOP       53040019
         B     TSTUT3             NOW SEE IF NEED TO WRT THIS DE TO UT3 53070019
* SINCE THERE CAN BE (AT MOST) ONLY 2 LOW ORDER BITS ON IN R5, 'MERGE'  53100019
* WILL BE DONE FOR A MAXIMUM OF THREE FIELDS OF USER TTRN'S.            53160019
         SPACE 2                                                        53190019
PUTBACK  EQU   *                                                        53220019
         NI    TAG,TAG5+TAG6      RESET SWITCHES USED BY WRITE RTNE     53400019
         OI    TAG,TAG4           INDICATE 'WRITING TO SYSUT3'          53460019
         L     R15,ADWK           ADDR OF IDE TO BE RE-WRITTEN (-12)    53465019
         LA    R14,UT3DCB                                               53470019
         MVC   X1(LEN8,R15),FDAD(R14) PUT MBBCCHHR OF SYSUT3 REC TO BE  53475019
*                                 WRITTEN INTO AREA PRECEEDING RECORD   53480019
         MVI   X0(R15),ENDPROC    INDICATE THAT THIS IS THE 'LAST' REC  53485019
*                                 TO BE WRITTEN OUT (ALSO IS ONLY REC,  53490019
*                                 SINCE ONLY ONE REC BEING WRITTEN BACK 53495019
*                                 AT A TIME).  IT WILL BE WRITTEN BACK  53500019
*                                 TO SAME PLACE IT WAS READ FROM, USING 53505019
*                                 WRITE KEY-DATA CCW TO AVOID FORMAT-   53510019
*                                 TING REST OF TRACK AFTER THIS RECORD. 53515019
         L     R15,VIEBDWR        GET ADDR OF WRITE ROUTINE             53520019
         BALR  R14,R15            GO TO WRITE PREVIOUSLY READ SPILLED   53580019
*                                 DIR ENTRY WHICH HAS NOW BEEN UPDATED  53640019
         B     TLSTCPYD           GO SEE IF MORE MEMBERS TO BE COPIED   53740019
MBRSCPYD EQU   *                                                        53840019
         TM    WSFLAG,NOWRT       WAS LAST BFR-FULL OF MBR DATA WRITTEN 53940019
         BZ    SKPURGE            IF SO, DONT TRY TO PURGE BUFFER       54000019
         NI    TAG,TAG5+TAG6      RESET ALL BUT TAG5,6                  54020019
         OI    TAG,TAG2           INDICATE WRITING MEMBER DATA          54040019
         OI    WSFLAG,FORCEWRT    ELSE INDIC NEED TO PURGE I/O BUFFER   54060019
         L     R15,VIEBVWS                                              54120019
         BALR  R14,R15            GO VIA IEBVWS TO EMPTY OUT BUFFER     54180019
SKPURGE  NI    FLG7,FF-COP        RESET INDICATOR BIT USED BY IEBMGI    54240019
         MVC   OUTPTTR(LEN8),OUTDS1 SAVE LAST RECORD'S TTRN AND TRKBAL  54260019
         MVI   SWITCH1,ZERO       RESET IEBMGI SWITCHES                 54295019
         L     R15,VIEBVDM        ADDR OF DIRECTORY MERGE RTNE          54300019
         BALR  R14,R15            GO TO MERGE DIRECTORY                 54360019
MRGDONE  L     R15,VIEBVTM        ADDR OF TERMINATION ROUTINE           54420019
         BALR  R14,R15            EXIT TO TERMINATE INDD/STEP/OPER/JOB  54480019
         EJECT                                                          54900019
IEBMNM   EQU   *                                                        54960019
* SUBROUTINE TO COPY THE MEMBER WITH NO MODIFICATIONS (I.E., NO RE/DE-  55020019
* BLOCKING).  THERE MAY OR MAY NOT BE A NOTE-LIST RECORD AND/OR USER    55080019
* TTRN'S SPECIFIED FOR THIS MEMBER.                                     55140019
IEBDSCNM EQU   IEBMNM                                                   55180019
         ENTRY IEBDSCNM                                                 55220019
         ST    R14,SV14           SAVE EXIT REG CONTENTS                55260019
         NI    TAG,TAG5+TAG6+TAG8 RESET TAG1,2,3,4, AND 7               55320019
         OI    TAG,TAG2           INDIC COPYING MBR TO OUTPUT DATA SET  55380019
         NI    STATUS,STAT5+STAT7+STAT8                                 55440019
         OI    STATUS,STAT4+STAT8 INDIC READING 1ST REC OF INPUT MEMBER 55530019
         MVI   INSCTOR,ZERO       SET INPUT SECTOR VALUE TO 0    S20201 55550020
*                                   (USED ONLY IF ON AN RPS      S20201 55570020
*                                   DEVICE)                      S20201 55590020
RDMORDTA L     R15,VIEBDRD        ADDR OF READ ROUTINE                  55620019
         BALR  R14,R15            LINK TO READ A BUFFER-FULL            55680019
         L     R15,VIEBVWS        GO TO WRITE WHAT WAS JUST READ        55740019
         BALR  R14,R15            LINK TO ROUTINE                       55840019
TRDEOF   TM    FLG2,RDEOF         WAS ALL OF MEMBER READ AND WRITTEN    56040019
         BZ    RDMORDTA           IF NOT, GO READ MORE MEMBER DATA      56100019
         NI    FLG2,FF-RDEOF      RESET EOF-READ INDICATOR              56160019
         L     R14,SV14           RESTORE EXIT REG                      56220019
         BR    R14                GO BACK TO MAINFLOW                   56280019
SV14     DC    F'0'               SVAREA FOR LINK REG                   56340019
         SPACE 2                                                        57000019
RDLNK    EQU   *             LINKAGE TO IEBDRD - USED WHEN READING INTO 57040019
*                            ''1ST'' I/O BUFFER AREA                    57080019
         MVC   READNEXT+P1(L3),BEGFST1 SET ADDR WHERE TO READ INTO      57130019
         L     R15,VIEBDRD        ADDR OF READ SUBROUTINE               57180019
         BALR  R14,R15            LINK TO READ                          57240019
         BR    R2                 RETURN TO CALLER                      57300019
*              IF AN EOF OCCURRED, IEBDRD WILL HAVE SET RDEOF SWITCH    57360019
         SPACE 2                                                        57420019
*        SYSIN EODAD INTERFACE                                          57480019
IEBEOF   EQU   *                                                        57540019
IEBDSCEF EQU   IEBEOF                                                   57580019
         ENTRY IEBDSCEF                                                 57620019
         L     R15,VIEBSEF        ADDR OF ENTRY POINT IN IEBSCN         57660019
         BR    R15                EXIT TO HANDLE SYSIN EOF              57720019
         EJECT                                                          57780019
IEBCER   EQU   *                                                        58580019
IEBDSCCE EQU   IEBCER                                                   58880019
         ENTRY IEBDSCCE                                                 59180019
* THIS IS THE ENTRY POINT FOR SYSIN SYNAD EXIT                          59580019
*                                                                       59640019
         USING IEBCER,R15                                               59760019
         SYNADAF   ACSMETH=QSAM                                         59780019
         ST    R6,SAV6X           SAVE REG USED IN THIS ROUTINE         59880019
         SR    R6,R6              SET REG TO 0 TO INDIC SYSIN SYNAD     59980019
         B     SYNRLS             GO SET UP MSG IN BUFFER               60080019
         SPACE 2                                                        60360019
IEBPER   EQU   *                                                        60420019
IEBDSCPE EQU   IEBPER                                                   60460019
         ENTRY IEBDSCPE                                                 60500019
* THIS IS THE ENTRY POINT FOR SYSPRINT SYNAD EXIT                       60540019
*                                                                       60600019
         USING IEBPER,R15                                               60720019
         SYNADAF   ACSMETH=QSAM                                         60740019
         L     R15,AIOE2          GET ADDR OF PRIMARY ENTRY POINT       60780019
         DROP  R15                                                      60840019
         USING IEBCER,R15                                               60880019
         ST    R6,SAV6X           SAVE REG USED IN THIS ROUTINE         60920019
         LA    R6,ONE             SET REG TO +1 FOR SYSPRINT SYNAD IND  60960019
         B     SYNRLS             GO SET UP MSG IN BUFFER               61000019
         SPACE 1                                                        61040019
AIOE2    DC    A(IEBCER)          ADDR OF PRIMARY SYNAD EXIT E.P.       61080019
         SPACE 2                                                        61140019
SYNRLS   EQU   *                                                        61260019
         MVI   MSGBUF,BLNK        CLEAR MSG BUFFER                      61330019
         MVC   MSGBUF+P1(MBLEN),MSGBUF                                  61400019
         LTR   R6,R6              WAS ERROR ON SYSPRINT                 61480019
         BP    PRTMSG             YES - SET UP MSG FOR WTO/WTP          61580019
         MVC   MSGBUF+SYN1(LSYN1),SYNMT(R1) NO- SET UP SYSIN SYNAD MSG  61680019
         MVC   MSGBUF+SYN2(LSYN2),RFSYS MOVE IN MSG PREFIX              61780019
         CLI   RCBUF,CH8          IS COMPLETION CODE 8 OR HIGHER A44144 61830000
         BNL   SETCODES           YES- DON'T SET RETURN CODE     A44144 61880000
         MVI   RCBUF,CH8          SET COMPLETION CODE            A44144 61930000
SETCODES EQU   *                                                        62080019
         MVI   MSG1,LASTMSG+IOERF  SET INDICATORS FOR IEBVMS            62180019
         MVC   MSGBUF+P1(PRFXLEN),IEBPRFX                               62480019
         L     R6,SAV6X           RESTORE REG USED BY THIS ROUTINE      62840019
         SYNADRLS                                                       62870019
         BR    R8                 EXIT TO SYNAD RETURN POINT IN CALLER  62930019
PRTMSG   EQU   *                                                        62970019
         MVC   MSGBUF+SYN1(LSYN1),SYNMT(R1) SET UP SYSPRINT SYNADAF MSG 63010019
         MVC   MSGBUF+SYN3(LSYN3),WTPRT                                 63050019
         OI    IOEF2,SPRNOPN      INDICATE TO NOP PRINTING OF MESSAGES  63090019
         CLI   RCBUF,CH4          IS COMPLETION CODE 4 OR HIGHER A44144 63140000
         BNL   SETCODES           YES- DON'T SET RETURN CODE     A44144 63190000
         MVI   RCBUF,CH4          NO - SET IT TO 4               A44144 63210000
         B     SETCODES           GO SET IEBVMS INDICATORS              63270019
SAV6X    DS    F                  AREA FOR SAVING CALLERS REG           63340019
* THE FOLLOWING 3 DC'S ARE USED IN SETTING UP SYNADAF MSG TEXT          63360019
RFSYS    DC    C'READING FROM SYSIN - '                                 63380019
WTPRT    DC    C'WRITING TO SYSPRINT - '                                63420019
IEBPRFX  DC    C'IEB139I'                                               63510019
         DROP  R15                                                      63600019
         DROP  R11                                                      63660019
         SPACE 2                                                        63720019
         DS    0H                                                       63750019
IEBSCX   EQU   *             ENTRY POINT IN MAINFLOW                    63780019
* THIS ENTRY POINT IS USED BY THE TERMINATION ROUTINE (IEBVTM) WHEN     63840019
* IT IS NECESSARY TO EXIT TO THE CONTROL-CARD SCAN ROUTINE (IEBSCN).    63900019
* THE ENTRY POINT IS IN MAINFLOW IN ORDER TO AVOID AN EXCLUSIVE CALL    63960019
* IF THIS UTILITY PROGRAM IS IN OVERLAY STRUCTURE.                      64020019
IEBDSCSX EQU   IEBSCX                                                   64060019
         ENTRY IEBDSCSX                                                 64100019
         L     R15,VIEBSCN        ADDR OF CONTROL-CARD SCAN ROUTINE     64140019
         BR    R15                EXIT TO IEBSCN                        64170019
         SPACE 2                                                        64203019
         DS    0H                                                       64206019
IEBM04   EQU   *                  ENTRY POINT IN MAIN PROGRAM           64209019
* THIS ENTRY POINT IS USED BY THE DIRECTORY MERGE ROUTINE (IEBVDM) WHEN 64212019
* IT IS NECESSARY FOR IT TO CALL THE VALIDATION ROUTINE (AT ENTRY POINT 64215019
* IEBDV4) TO OPEN AND VALIDATE SYSUT4.  THIS ENTRY POINT IS IN THE MAIN 64218019
* PROGRAM IN ORDER TO AVOID AN EXCLUSIVE CALL IF THIS UTILITY PROGRAM   64221019
* IS LINK-EDITED IN OVERLAY.                                            64224019
IEBDSCM4 EQU   IEBM04                                                   64226019
         ENTRY IEBDSCM4                                                 64228019
         L     R15,VIEBDV4        E.P. IN IEBDV1 CSECT                  64230019
         BALR  R14,R15            EXIT TO OPEN/VALIDATE SYSUT4 DCB      64233019
         L     R15,VIEBRTM        RETURN POINT IN IEBVDM CSECT          64236019
         BR    R15                RETURN TO DIRECTORY MERGE ROUTINE     64239019
         SPACE 1                                                 A33288 64239120
IEBDSRE  EQU   *                                                 A33288 64239220
         ENTRY IEBDSRE                                           A33288 64239320
* THIS ENTRY POINT IS TO AVOID AN EXCLUSIVE CALL BETWEEN IEBDRD  A33288 64239420
* AND IEBIOE                                                     A33288 64239520
         SPACE 1                                                 A33288 64239620
         L     R15,VIEBIOE        ADDR OF IEBIOE                 A33288 64239720
         BALR  R14,R15            LINK TO IEBIOE                 A33288 64239820
         L     R15,VIEBDRDR       ADDR OF RETURN POINT IN IEBDRD A33288 64239920
         BR    R15                RETURN                         A33288 64240020
         SPACE 1                                                 A33288 64240120
IEBDSWE  EQU   *                                                 A33288 64240220
         ENTRY IEBDSWE                                           A33288 64240320
* THIS ENTRY POINT IS TO AVOID AN EXCLUSIVE CALL BETWEEN IEBDWR  A33288 64240420
* AND IEBIOE                                                     A33288 64240520
         SPACE 1                                                 A33288 64240620
         L     R15,VIEBIOE        ADDR OF IEBIOE                 A33288 64240720
         BALR  R14,R15            LINK TO IEBIOE                 A33288 64240820
         L     R15,VIEBDWRR       ADDR OR RETURN POINT IN IEBDWR A33288 64240920
         BR    R15                RETURN                         A33288 64241020
         SPACE 1                                                 A33288 64241120
         SPACE 1                                                        64242019
         DS    0F                                                       64245019
PATCHLN  EQU   (*-MAINFLOW)/20    5 PER-CENT PATCH AREA LENGTH          64248019
PATCH    DC    XL(PATCHLN)'00'    PATCH AREA FOR THIS CSECT      A41780 64251021
         EJECT                                                          64260019
IEBDSCP2 CSECT                                                          64320019
         SPACE 2                                                        64380019
*                                                                       64440019
* THIS CSECT CONSISTS OF SUBROUTINES WHICH WILL REMAIN WITHIN THE       64500019
* ROOT SEGMENT IF THIS PROGRAM IS IN OVERLAY STRUCTURE.                 64560019
*                                                                       64620019
         SPACE 2                                                        64680019
         USING IEBMCA,RG4                                               64740019
* SUBROUTINE TO EFFECT LINKAGE TO SYSTEM ROUTINE WHICH CONVERTS TTR TO  64770019
* MBBCCHHR                                                              64800019
*                                                                       64830019
* INPUT TO ROUTINE - R1 = ADDR OF DCB, R0 = TTR TO BE CONVERTED,        64860019
* R2 POINTS TO LOCATION FOR ROUTINE TO PUT MBBCCHHR, R13 = SVAREA ADDR, 64920019
* R14 = RETURN REG.  NOTE--R15 MIGHT NOT HAVE ADDR OF ROUTINE IN IT...  64980019
* THIS WILL NOT MATTER.                                                 65040019
TTOCC    EQU   *                                                        65100019
IEBDSTOC EQU   TTOCC                                                    65140019
         ENTRY IEBDSTOC                                                 65180019
         SAVE  (14,12)            STANDARD LINKAGE CONVENTIONS          65220019
*                                 (EXCEPT FOR USE OF REG 15)            65280019
         ST    R13,SV4+CHAINBK                                          65340019
         LA    R9,SV4                                                   65400019
         ST    R9,CHAINTHS(R13)                                         65460019
         LR    R13,R9                                                   65520019
         L     R15,ADCVT          ADDR OF CVT                           65580019
         L     R15,TPCNVT(R15)    ADDR OF TTR-TO-MBBCCHHR CONVERT RTNE  65640019
         USING IHADCB,R1          SET DCB BASE REG                      65700019
         L     R1,DCBDEBAD        ADDR OF DEB FROM DCB                  65760019
         LA    R1,X0(R1)          CLEAR HI ORDER BYTE                   65820019
         BALR  R14,R15            LINK TO CONVERT ROUTINE               65880019
         L     R13,SV4+CHAINBK                                          65940019
         RETURN (14,12),RC=(15)                                         66000019
         DROP  R1                                                       66060019
         EJECT                                                          66120019
* SUBROUTINE TO EFFECT LINKAGE TO SYSTEM ROUTINE WHICH CONVERTS         66150019
* MBBCCHHR TO TTR                                                       66180019
*                                                                       66210019
* INPUT TO ROUTINE - R1 = ADDR OF DCB, R2 = POINTER TO MBBCCHHR         66240019
* R14 = RETURN REG.  OUTPUT = TTRN STORED IN ''WKA1''.                  66300019
CCOTT    EQU   *                                                        66360019
IEBDSCOT EQU   CCOTT                                                    66400019
         ENTRY IEBDSCOT                                                 66440019
         SAVE  (14,12)            STANDARD LINKAGE CONVENTIONS          66480019
*                                 (EXCEPT FOR USE OF REG 15)            66540019
         ST    R13,SV4+CHAINBK                                          66600019
         LA    R9,SV4                                                   66660019
         ST    R9,CHAINTHS(R13)                                         66720019
         LR    R13,R9                                                   66780019
         L     R15,ADCVT          ADDR OF CVT                           66840019
         L     R15,TPRLTV(R15)    ADDR OF ABSOL TO REL TTR CONVERT RTNE 66900019
         USING IHADCB,R1                                                66960019
         L     R1,DCBDEBAD        ADDR OF DEB FROM DCB                  67020019
         LA    R1,X0(R1)          CLEAR HI ORDER BYTE                   67080019
         SR    R0,R0              CLEAR ANSWER REG                      67140019
         BALR  R14,R15            LINK OUT TO CONVERT MBBCCHHR TO TTR   67200019
         ST    R0,WKA1            TTRN TO CORE                          67260019
         L     R13,SV4+CHAINBK                                          67320019
         RETURN (14,12)                                                 67380019
         DROP  R1                                                       67440019
         EJECT                                                          67500019
IEBMGD   EQU   *                  SUBRTNE TO LOCATE NEXT DE IN I/O BFR  67560019
IEBDSCGD EQU   IEBMGD                                                   67600019
         ENTRY IEBDSCGD                                                 67640019
         SAVE  (14,12)            SAVE CALLER'S REGS                    67680019
         LR    R3,R15             ESTAB ADDRESSIBILITY                  67740019
         USING IEBMGD,R3                                                67800019
         ST    R13,SV3+CHAINBK    STD LINKAGE                           67860019
         LA    R12,SV3                                                  67920019
         ST    R12,CHAINTHS(R13)                                        67980019
         LR    R13,R12                                                  68040019
         TM    FLG5,DEFSW         IS SUBRTNE INITIALIZATION DONE        68100019
         BO    DVSC               IF SO, GO COMPARE ADDR OF THIS DE     68160019
         OI    FLG5,DEFSW         TURN ON INITIALIZATION SW.            68220019
* THIS SUBROUTINE TAKES ADVANTAGE OF ''KNOWING'' THAT IT IS GETTING     68280019
* DIR. ENTRIES FROM THE 'FIRST' BUFFER AREA POINTED TO BY THE BCB.      68340019
SDEPTR   MVC   DEPTR+P1(L3),BEGFST1 POINT TO 1ST BLOCK IN BUFFER        68400019
CKCT     EQU   *                                                        68460019
         L     R5,DEPTR           ADDR OF DE                            68520019
         TM    FLG2,RDEOF         WAS AN EOF READ YET                   68580019
         BZ    SVKEY              IF NOT, DONT TEST FOR EOD YET         68640019
         CLC   C1DL(L2,R5),ZROS   DOES DATA LENGTH = 0 (EOF RECORD)     68700019
         BNE   SVKEY              GO SAVE KEY IF NOT                    68760019
DE0      XC    DEPTR(L4),DEPTR    CLEAR PTR TO DE, INDICATING ALL DONE  68820019
DEX      EQU   *                                                        68880019
         NI    FLG5,FF-DEFSW      TURN OFF INITIALIZATION SWITCH        68940019
         L     R13,CHAINBK(R13)   RESTORE ADDR OF CALLER'S SAVE AREA    69000019
         RETURN (14,12)           RETURN TO CALLER+0, INDIC NO DE FOUND 69060019
DVSC     L     R5,DEPTR           GET ADDR OF CURRENT DIR ENTRY         69120019
         CLC   X0(NAMLEN,R5),DBKEY IS THIS THE LAST DE IN THE BLOCK     69180019
         BE    BMP1               IF SO, FIND THE NEXT BLOCK            69240019
         SR    R6,R6                                                    69300019
         IC    R6,C1DECT(R5)      GET COUNT BYTE OF CURRENT DE          69360019
         SLL   R6,LFT27           CLEAR HI ORDER 3 BITS                 69420019
         SRL   R6,RT26            MPLY WHATS LEFT BY 2 = NBR USER BYTES 69480019
         LA    R6,C1FXL(R6)       ADD FIXED LENGTH (12) TO FIND NEXT DE 69540019
         A     R6,DEPTR           ADD THIS LENGTH TO ADDR OF CURR DE    69600019
CKFFS    EQU   *                                                        69630019
         CLI   X0(R6),FF          IS THIS AN END-OF-DIRECTORY NAME      69670019
         BE    DE0                IF SO, GO TO ZERO DEPTR AND EXIT      69720019
         ST    R6,DEPTR           SET AS ADDR OF NEXT ENTRY IN BLOCK    69780019
         B     RTCAL              GO TO EXIT                            69840019
SVKEY    MVC   DBKEY(LEN8),CON12(R5) SAVE THIS DIRECTORY BLOCK'S KEY    69900019
         ST    R5,BLKAD           BLKAD = DEPTR                         69960019
         LA    R6,FDEOFF(R5)      POINT TO NAME OF 1ST DE IN BLOCK      70060019
         B     CKFFS              SEE IF ITS NAME IS 'FF'S              70160019
BMP1     L     R6,BLKAD           BUMP POINTER TO ADDR OF NEXT BLOCK    70320019
         TM    X0(R6),LASTREC+ENDPROC  IS THIS LAST BLOCK IN THE BUFFER 70380019
         BC    NOT0,RDMOR         IF SO, SEE IF CAN READ MORE INTO BFR  70440019
         LA    R6,KBLEN+CON12(R6) ADD TOTAL LENGTH                      70500019
         ST    R6,BLKAD           SAVE ADDR                             70560019
         ST    R6,DEPTR           SET AS ADDR OF NEXT DE                70620019
         B     CKCT               GO CHECK FOR COUNT OF ZERO (EOF REC)  70680019
RDMOR    TM    FLG5,OSW1          IS OUTPUT PRE-SCAN BEING DONE         70740019
         BO    DEX                IF SO, LEAVE 'DEPTR' AS IS, AND GO TO 70860019
*                                 LET CALLER ISSUE HIS OWN 'READ'.      70920019
         TM    FLG7,DM            IS DIRECTORY MERGE BEING DONE         70940019
         BO    DEX                YES - LET CALLER READ MORE OUTPUT DES 70960019
         MVC   READNEXT+P1(L3),BEGFST1 SET ADDR WHERE TO READ INTO      71000019
         L     R15,VIEBDRD        ADDR OF READ SUBROUTINE               71040019
         BALR  R14,R15            LINK TO READ                          71100019
         B     SDEPTR             GO SET POINTER TO 1ST REC IN BUFFER   71220019
RTCAL    L     R13,CHAINBK(R13)   RESTORE ADDR OF CALLER'S SAVE AREA    71260019
         LM    R14,R12,X12(R13)   RESTORE CALLERS REGS                  71300019
         B     X4(R14)            EXIT TO CALLER'S RETURN POINT + 4,    71340019
*                                 INDICATING THAT A POINTER TO A D.E.   71380019
*                                 IS IN 'DEPTR'                         71420019
         EJECT                                                          71460019
         DS    0H                                                       71490019
IEBMBT   EQU   *                                                        71510019
*                  SUBROUTINE TO BUILD CTLTAB ENTRIES AND EITHER RE-    71530019
*              TAIN OR SPILL (TO SYSUT3) THE NEEDED INPUT DE'S          71550019
IEBDSCBT EQU   IEBMBT                                                   71580019
         ENTRY IEBDSCBT                                                 71610019
* THIS SUBROUTINE GETS CONTROL FROM MAINFLOW WHENEVER A CONTROL TABLE   71640019
* ENTRY IS TO BE ''BUILT''.  THIS SUBROUTINE WILL BUILD THE ENTRY, AND  71700019
* IF CORE IS AVAILABLE, SAVE THE DE IN CORE.  IF NOT ENOUGH SPACE RE-   71760019
* MAINS FOR THE CTLTAB, PREVIOUSLY RETAINED DE'S ARE SPILLED TO SYSUT3, 71820019
* AS WELL AS ANY AND ALL FURTHER NEEDED DE'S FROM THIS DATA SET.        71880019
* IF THERE ARE NO DE'S LEFT TO BE SPILLED, AND THERE IS NOT ENOUGH      71940019
* SPACE FOR THIS CTLTAB ENTRY, THEN AN ERROR MSG IS WRITTEN BY MAINFLOW 72000019
* (NOROOM). IF THE CTLTAB ENTRY IS SUCCESSFULLY BUILT, RETURN IS MADE   72060019
* TO CALLER VIA R14.                                                    72120019
         SAVE  (14,12)            SET UP SVAREA LINKAGE                 72180019
         LR    R10,R15                                                  72240019
         USING IEBMBT,R10                                               72300019
         ST    R13,SV3+CHAINBK                                          72360019
         LA    R12,SV3                                                  72420019
         ST    R12,CHAINTHS(R13)                                        72480019
         LR    R13,R12                                                  72540019
*              INITIALIZE REGS                                          72600019
         L     R5,HICOR           ADDR OF HIGHEST UNUSED BYTE IN CORE   72660019
         L     R6,DEPTR           ADDR OF CURRENT DE                    72720019
         L     R1,BUMP            ADDR OF NXT SLOT IN CTLTAB (OR SETAB) 72780019
         TM    FLG3,REBLK         WAS RE/DE-BLOCKING SPECIFIED          72840019
         BZ    TSPL               IF NOT, SEE IF ANY SPILL HAS OCCURRED 72900019
         TM    C1DECT(R6),USERMASK  ANY NOTE-LIST OR USER TTRN'S        72960019
         BC    NOT0,SETM46        IF SO, CANT ALSO BE RE/DE-BLOCKING    73020019
TSPL     EQU   *                                                        73080019
         TM    FLG6,SPL           HAS ANY SPILL OCCURRED YET            73140019
         BO    C1TSPC             IF SO, GO TEST FOR CORE SPACE         73200019
         IC    R7,C1DECT(R6)      GET COUNT BYTE                        73260019
         SLL   R7,LFT27           CLEAR HI ORDER 3 BITS                 73320019
         SRL   R7,RT26            MPLY WHATS LEFT BY 2 = NBR USER BYTES 73380019
         LA    R7,C1FXL(R7)       ADD LENGTH OF FIXED PORTION OF DE     73440019
* R7 NOW CONTAINS LENGTH IN BYTES OF DIR ENTRY TO BE SAVED              73500019
         LR    R8,R7              SAVE LENGTH IN R8                     73560019
         TM    COMDCDSW,SELECTSC  IS THIS A SELECTIVE COPY              73620019
         BO    C1TSTHI            IF SO, DONT ADD CTLTAB ENTRY LENGTH   73680019
         LA    R7,C1CTEL(R7)      ELSE ADD LENGTH OF ENTRY              73740019
         SR    R5,R7              CALC HICOR MINUS LENGTH               73800019
         C     R5,BUMP            IS RESULTING ADDR LESS THAN ADDR      73860019
*                                 WHERE CTLTAB ENTRY SHOULD GO          73920019
         BL    C1SETSP            IF SO, GO SET SPILL SW                73980019
         XC    X0(C1CTEL,R1),X0(R1) CLEAR NEXT 10 BYTES OF CTLTAB       74040019
*              R6 CONTAINS ADDR OF DE TO BE MOVED                       74100019
*              R8 CONTAINS ACTUAL LENGTH OF DE                          74160019
C1MVDE   L     R5,HICOR           GET ADDR OF HIGHEST UNUSED CORE       74220019
         SR    R5,R8              SUBTR LENGTH OF DE TO BE MOVED        74280019
         BCTR  R8,R0              DECREMENT LENGTH BY 1 FOR EXECUTE     74340019
         EX    R8,C1MOVE                                                74400019
         ST    R5,WKA1            SAVE ADDR WHERE MOVED TO              74460019
         ST    R5,HICOR                                                 74520019
         LH    R8,CDCT            ADD 1 TO COUNT OF IN-CORE INPUT DE'S  74580019
         LPR   R8,R8              ASSURE POSITIVE SIGN                  74640019
         LA    R8,X1(R8)                                                74700019
         STH   R8,CDCT                                                  74760019
*              R1 CONTAINS ADDR OF NXT ENTRY IN CTLTAB                  74820019
         MVC   X3(L3,R1),WKA1+P1  PUT 3-BYTE ADDR OF IN-CORE D.E. INTO  74860019
*                                 TABLE                                 74900019
         MVI   X2(R1),ZERO        INDICATE THAT THIS IS AN IN-CORE PTR  74940019
         ST    R1,ICPT            SAVE ADDR OF THIS CTLTAB ENTRY AS THE 75000019
*                                 MOST RECENT ONE REFERENCING AN IN-    75060019
*                                 CORE DIR ENTRY                        75120019
C1MVTTR  MVC   X7(L3,R1),NAMLEN(R6) MOVE MBR TTR FROM DE TO CTLTAB      75180019
         MVI   X6(R1),ZERO        CLEAR INDICATOR BYTE                  75240019
         TM    NAMLEN+P3(R6),ALIAS DOES THIS DE REFERENCE AN ALIAS      75300019
         BZ    INCFCT             IF NOT, GO UPDATE FCT                 75360019
         MVI   X1(R1),ALIAS       ELSE INDICATE ALIAS IN CTLTAB ENTRY   75420019
INCFCT   EQU   *                                                        75480019
         TM    X0(R1),SEBIT4      WAS 'DONT-COPY' SET WHILE THIS CTLTAB 75490019
*                                 ENTRY WAS BEING BUILT                 75500019
         BO    ADDEL              IF SO, DONT INCREMENT FOUND-COUNT     75510019
         LH    R8,FCT             ADD 1 TO COUNT OF ''FOUND'' MBRS      75540019
         LPR   R8,R8              ASSURE POSITIVE SIGN                  75600019
         LA    R8,X1(R8)                                                75660019
         STH   R8,FCT                                                   75720019
         OI    X0(R1),SEBIT5      INDICATE 'FOUND' IN CTLTAB ENTRY      75760019
ADDEL    EQU   *                                                        75810019
         LA    R1,C1CTEL(R1)      ADD ELEMENT LENGTH TO POINTER         75840019
         ST    R1,BUMP            UPDATE POINTER FOR NEXT TIME THRU     75900019
         TM    COMDCDSW,SELECTSC  IS THIS A SELECTIVE COPY              75960019
         BO    C1RETRN            IF SO, GO EXIT                        76020019
         ST    R1,LOCOR           ELSE UPDATE ADDR OF LOWEST UNUSED COR 76080019
C1RETRN  L     R13,CHAINBK(R13)   RESTORE PTR TO CALLER'S SAVE AREA     76140019
         RETURN (14,12)           RESTORE REGS AND EXIT TO CALLER       76200019
C1TSTHI  SR    R5,R7              CALC HICOR MINUS LENGTH OF DE         76260019
         C     R5,LOCOR           WILL THIS DE FIT                      76320019
         BNL   C1MVDE             IF SO, GO MOVE IT INTO CORE AREA      76380019
         OI    FLG6,SPL           ELSE INDIC NEED TO SPILL              76440019
         B     C1CVCC             GO SPILL THIS DIRECTORY ENTRY         76500019
C1TSPC   TM    COMDCDSW,SELECTSC  IS THIS A SELECTIVE COPY              76560019
         BO    C1CVCC             IF SO, GO TO SPILL THIS IDE           76620019
         B     C1GEL              ELSE SEE IF ENUF SPACE FOR CTLTAB ENT 76680019
C1SETSP  OI    FLG6,SPL           SET SPILL SWITCH                      76740019
C1GEL    LA    R11,C1CTEL         GET LENGTH OF CTLTAB ENTRY            76800019
         L     R5,HICOR           GET ADDR OF HIGHEST UNUSED CORE       76860019
         SR    R5,R11             HICOR = HICOR - 10                    76920019
         CR    R5,R1              IS THERE ENOUGH ROOM FOR NEXT         76980019
*                                 ENTRY IN CTLTAB                       77040019
         BNL   C1ZR10             IF SO, GO WRITE THE DE TO SYSUT3      77100019
         LH    R11,CDCT           GET CT OF NBR OF IN-CORE INPUT DE'S   77160019
         LTR   R11,R11            ARE THERE ANY                         77220019
         BZ    TSTMBUSE           IF NOT, GO SEE IF BFR CAN BE SQUEEZED 77280019
         L     R11,ICPT           GET ADDR OF CTLTAB ENTRY FOR MOST     77340019
*                                 RECENTLY SAVED-IN-CORE DE             77400019
         MVC   WKA1(L4),X2(R11)   PUT ADDR OF DE INTO WORK AREA         77460019
         L     R3,WKA1            ADDR OF DE INTO R3                    77520019
         LA    R9,C1RET1          SET UP EXIT ADDR FOR USE WHEN PRE-    77580019
*                                 VIOUSLY SAVED DE IS SPILLED TO SYSUT3 77640019
         IC    R2,C1DECT(R3)      CALC LENGTH OF THIS DE IN R2          77700019
         SLL   R2,LFT27                                                 77760019
         SRL   R2,RT26                                                  77820019
         LA    R2,C1FXL(R2)       ADD LENGTH OF FIXED PORTION OF DE     77880019
         ST    R2,WKA1+P24        SAVE LENGTH OF DE BEING SPILLED       77940019
C1SETUT3 LA    R2,UT3DCB                                                78000019
         USING IHADCB,R2                                                78060019
         TM    DCBOFLGS,OPEN      WAS SYSUT3 OPENED YET                 78120019
         BO    C1GOWS             IF SO, DONT TRY TO RE-OPEN IT         78180019
         DROP  R2                                                       78240019
         L     R15,VIEBDV3        ADDR OF VALIDATION ROUTINE FOR SYSUT3 78300019
         BALR  R14,R15            GO TO OPEN AND CHECK OUT SYSUT3 -     78360019
*                                 ONLY RETURN IF OPENED OKAY AND VALID  78420019
C1GOWS   L     R12,ADWK           ADDR OF WORK AREA CONTAINING DE       78480019
         MVI   X0(R12),ENDPROC    INDIC THIS IS LAST REC IN ANY BUFFER  78540019
         MVI   C1KL(R12),ZERO     SET KEYLEN TO ZERO                    78600019
         MVC   C1DL(L2,R12),C180  SET FIXED LENGTH OF 80 IN COUNT FIELD 78660019
*                                 OF RECORD TO BE SPILLED TO SYSUT3     78720019
         LA    R12,C1FXL(R12)     SAVE 12 BYTES FOR FLG, MBB, AND COUNT 78780019
         MVC   X0(SPILLEN,R12),X0(R3)  PUT IDE TO BE SPILLED INTO BFR   78840019
         L     R2,ADWK            GET ADDRESS OF BUFFER AREA            78900019
         LA    R2,X1(R2)          ADDR OF MBBCCHHR (IN UT3 BFR + 1)     78960019
         NI    TAG,TAG5+TAG6+CTOUT RESET ANY EXTRANEOUS BITS            79020019
         OI    TAG,TAG4           SET INDIC FOR SYSUT3 WRITING          79080019
         L     R15,VIEBVWS                                              79140019
         BALR  R14,R15            LINK TO PLUG IN CCHHR AND WRITE REC   79200019
         SPACE 2                                                        79202019
* NOW NEED TO SET UP TO CALL SYSTEM ROUTINE TO CONVERT MBBCCHHR TO TTR  79252019
         LA    R1,UT3DCB                                                79320019
         L     R15,VCCOTT         GET ADDR OF LINKAGE TO CONVERT TTR    79380019
         BALR  R14,R15            GO TO CONVERT MBBCCHHR TO TTR         79440019
* ADDR OF CTLTAB ENTRY REFERENCING THE DE JUST SPILLED IS IN R11        79500019
         MVC   X3(L3,R11),WKA1    TTR INTO CTLTAB, OVERLAYING CORE ADDR 79560019
         MVI   X2(R11),ONE        SET OFFSET BYTE TO INDIC THIS IS TTR  79620019
         BR    R9                 GO TO CALLER OF C1SETUT3 OR TO NSI    79680019
C1RET1   LA    R9,C1CTEL          LENGTH OF CTLTAB ENTRY                79740019
         SR    R11,R9                                                   79800019
         ST    R11,ICPT           SET ICPT TO ADDR OF PREVIOUS CTLTAB   79860019
*                                 ENTRY WH. REF. AN IN-CORE DE          79920019
         LH    R11,CDCT                                                 79980019
         LPR   R11,R11            ASSURE POSITIVE SIGN                  80040019
         BCTR  R11,R0             SUBTR 1 FROM COUNT OF IN-CORE IDE'S   80100019
         STH   R11,CDCT                                                 80160019
         L     R5,WKA1+P24        GET LENGTH OF SPILLED DE              80220019
         A     R5,HICOR           ADD TO PREVIOUS ADDR OF HIGHEST UN-   80280019
*                                 UTILIZED CORE                         80340019
         ST    R5,HICOR           HICOR = HICOR + LENGTH OF SPILLED DE  80400019
         L     R1,BUMP            RE-INITIALIZE REGS                    80460019
         L     R6,DEPTR                                                 80520019
         B     C1TSPC             GO TO TEST FOR SPACE FOR NXT CTLTAB   80580019
*                                 ENTRY                                 80610019
C1ZR10   XC    X0(C1CTEL,R1),X0(R1) CLEAR NEXT SLOT FOR CTLTAB ENTRY    80650019
C1CVCC   L     R3,DEPTR           NOW GET ADDR OF CURR DE TO BE SPILLED 80700019
         L     R11,BUMP           PT TO SETAB/CTLTAB SLOT BEING USED    80730019
         BAL   R9,C1SETUT3        GO WRITE TO SYSUT3 AND PUT ADDRESS,   80760019
*                                 IN TTR FORM, INTO SETAB/CTLTAB        80790019
         L     R1,BUMP            RE-INIT POINTER TO CTLTAB SLOT        80880019
         L     R6,DEPTR           RE-INIT POINTER TO DIRECTORY ENTRY    80940019
         B     C1MVTTR            GO SAVE MEMBER TTR AND EXIT           81000019
TSTMBUSE EQU   *                                                        81060019
         TM    FLG2,MBUSED        IS MINIMUM BUFFER-SIZE NOW ALLOCATED  81120019
         BO    NOROOM1            IF SO, CANT SQUEEZE IT DOWN           81180019
         L     R11,END2ND2        GET ADDR OF HI END OF 2ND I/O BFR     81184019
         S     R11,BCB            CALC CURRENT LENGTH OF ENTIRE BFR     81188019
*                                 AREA                                  81192019
         S     R11,MINSIZ         SUBTR AMOUNT OF CORE WHICH WOULD BE   81196019
*                                 DE-ALLOCATED                          81200019
         C     R11,MINSIZ         IS AT LEAST AN EQUAL AMOUNT OF CORE   81204019
*                                 STILL AVAILABLE AFTER DE-ALLOCATION   81208019
         BL    NOROOM1             NO - CANNOT DE-ALLOCATE I/O BUFFER   81212019
         BH    DEALLOC            IF HI, OKAY TO DEALLOCATE             81216019
         OI    FLG2,MBUSED        IF AMT LEFT = AMT TO BE DEALLOCATED,  81220019
*                                 INHIBIT FURTHER DEALLOCATION          81224019
DEALLOC  EQU   *                                                        81228019
         L     R5,BCB             ADDR OF START OF IO BUFFER            81240019
         A     R5,MINSIZ          ADD MINIMUM BUFFER-LENGTH             81300019
         ST    R5,BCB             SET ADJUSTED ADDR AS START OF IO BFR  81540019
*                                 NO BCB FLGS WILL BE SET AT THIS POINT 81600019
*                                 SO DONT NEED TO WORRY ABOUT RESET-    81660019
*                                 TING THEM INADVERTENTLY.              81720019
         ST    R5,HICOR           SET NEW HI ADDR OF UNUSED CORE        81780019
         L     R5,ENDFST1         ADDR OF END OF 1ST BUFFER             81840019
         A     R5,MAXBLK          ADD LENGTH OF 1/2 OF MINIMUM TOTAL    81900019
*                                 BFR-LENGTH TO GET NEW ENDING ADDR     81960019
         ST    R5,ENDFST1         SET ADJUSTED POINTER INTO BCB         82020019
         LA    R5,X1(R5)          ADD 1 TO GET STARTING ADDR OF 2ND BFR 82080019
         ST    R5,BEGFST2         SET ADJUSTED POINTER INTO BCB         82140019
* I/O BUFFER HAS NOW BEEN 'SQUEEZED' BY SUBTRACTING THE MINIMUM SIZE    82200019
* WHICH COULD POSSIBLY BE ALLOCATED FROM THE ACTUAL SIZE ALLOCATED.     82260019
         NI    FLG2,FF-TRKS2      RESET 2-TRACKS-ALLOCATED SWITCH       82320019
         B     C1GEL              AND CONTINUE BUILDING CTLTAB          82740019
NOROOM1  MVI   MSG1+P1,M47        MSG CODE                              82800019
         MVI   MSG1,LASTMSG       INDIC LAST MSG IN LIST                82870019
         OI    FLG7,SUPPRMSG      SUPPRESS MEMBERNAME PRINTING BY VTM   82910019
STOPBLDT EQU   *                                                        82950019
         CLI   RCBUF,CH8          IS COMPLETION CODE 8 OR HIGHER A44144 83100000
         BNL   DONOTSET           YES- DON'T SET RETURN CODE     A44144 83110000
         MVI   RCBUF,CH8          SET COMPLETION CODE            A44144 83120000
DONOTSET EQU   *                                                 A44144 83130000
         MVI   VTMFLG1,UNUSEND    INDIC UNUSUAL END OF COPY OPERATION   83150019
         L     R15,VIEBVMS        ADDR OF MSG-WRITER ROUTINE            83280019
         BALR  R14,R15            EXIT TO ROUTINE                       83340019
         L     R15,VIEBVTM        ADDR OF TERMINATION ROUTINE           83360019
         BR    R15                EXIT TO TERMINATE THIS COPY OPERATION 83380019
SETM46   MVI   MSG1+P1,M46        MSG CODE                              83420019
         L     R1,DEPTR           POINT TO MBRNAME FOR ERROR MSG A44336 83460021
         MVI   MSG1,LASTMSG+PBIT  INDICATORS FOR IEBVMS                 83470019
         MVI   PARAMS,NAME                                              83480019
         MVC   NAMEFLD(LEN8),X0(R1) EXTRACT MEMBERNAME FROM DIR ENTRY   83500019
         MVI   NAMEDISP,OFF141I   OFFSET FOR NAME IN MSG                83520019
         B     STOPBLDT           SET INDICATORS, WRT MSG, EXIT TO VTM  83540019
C1MOVE   MVC   X0(L1,R5),X0(R6)   EXECUTED TO MOVE IDE FROM I/O BFR     83570019
C180     DC    H'80'              LENGTH OF AN IDE TO BE SPILLED TO UT3 83610019
         EJECT                                                          83640019
         DS    0H                                                       83690019
IEBMGI   EQU   *                                                        83720019
IEBDSCGI EQU   IEBMGI                                                   83730019
         ENTRY IEBDSCGI                                                 83740019
*                   SUBROUTINE TO LOCATE THE NEXT APPROPRIATE CTLTAB    83750019
*              ENTRY AND ACCESS THE ADDRESS OF THE PROPER INPUT DIR ENT 83790019
*              DEPENDING UPON THE PHASE OF PROCESSING.  IF THE IDE IS   83840019
*              ON SYSUT3, THIS ROUTINE CALLS IEBDRD TO READ IT INTO     83890019
*              CORE.  IF THE ATTEMPT TO READ FAILS (DUE TO AN I/O ERROR 83940019
*              ON SYSUT3), THE BIT NAMED 'MGINODE' IS SET IN 'SWITCH1'. 83990019
*              WHEN A POINTER TO THE IDE IS ACQUIRED, IT IS PASSED BACK 84040019
*              TO THE CALLER IN THE LOCATION NAMED 'IDEAD', IN THE COM- 84090019
*              MUNICATION AREA.  IF THE IDE BEING ACCESSED IS THE LAST  84140019
*              ONE WHICH CAN BE REQUESTED BY THE CALLER, THE BIT NAMED  84190019
*              'LE' IS SET IN 'FLG4'.                                   84240019
* REGISTER DEFINITIONS -                                                84340019
RG0      EQU   0                                                        84390019
RG1      EQU   1                                                        84440019
RG2      EQU   2                                                        84490019
RG3      EQU   3                                                        84540019
RG4      EQU   4                  ADDRESS OF COMMUNICATION AREA         84590019
RG5      EQU   5                                                        84640019
RG6      EQU   6                                                        84690019
RG7      EQU   7                                                        84740019
RG8      EQU   8                                                        84790019
RG9      EQU   9                                                        84840019
RG10     EQU   10                                                       84890019
RG11     EQU   11                 BASE REGISTER                         84940019
RG12     EQU   12                                                       84990019
RG13     EQU   13                                                       85040019
RG14     EQU   14                                                       85090019
RG15     EQU   15                                                       85140019
         SAVE  (14,12)                                                  85260019
         BALR  RG11,RG0            ESTABLISH ADDRESSABILITY             85320019
         USING *,RG11                                                   85380019
         LA    RG12,SV2           LINKAGE CONVENTIONS                   85440019
         ST    RG12,CHAINTHS(RG13) STD LINKAGE                          85500019
         ST    RG13,CHAINBK(RG12)                                       85560019
         LR    RG13,RG12                                                85620019
         TM    SWITCH1,TIME1                                            85680019
         BO    LTABAD             DONT INITIALIZE AGAIN IF 'TIME1' ON   85740019
         MVC   GIFCT(L2),FCT      SET UP INTERNAL COUNT OF THE NUMBER   85800019
*                                 OF MEMBERS 'FOUND' ON THE CURRENT     85860019
*                                 INPUT DATA SET                        85920019
         MVC   TABAD(L4),CTAD     INIT PTR TO CTLTAB                    85980019
         MVC   NNTABAD(L4),ADNNPTRT INIT PTR TO NEWNAME POINTER TABLE   86040019
         OI    SWITCH1,TIME1                                            86100019
LTABAD   L     RG2,TABAD                                                86160019
TESTDC   TM    X0(RG2),SEBIT4     IS 'DONT-COPY' INDICATOR ON           86200019
         BZ    TESTF              IF NOT, CHECK FOR NEWNAME OR 'FOUND'  86250019
         TM    X0(RG2),SEBIT1     IS THIS A NEWNAME ENTRY               86270019
         BZ    GETNEXT            NO                                    86300019
         L     RG8,NNTABAD        SET POINTER TO NNPTRTAB FOR NEXT SLOT 86310019
         LA    RG8,X4(RG8)        BUMP POINTER                          86320019
         ST    RG8,NNTABAD                                              86330019
GETNEXT  LA    RG2,TABLEN(RG2)    POINT TO NEXT CTLTAB ENTRY            86360019
         B     TESTDC             SEE IF 'DONT COPY' BIT IS SET         86400019
TESTF    TM    X0(RG2),SEBIT1     IS THIS A NEWNAME ENTRY               86460019
         BO    NEWENT             YES                                   86520019
         TM    X0(RG2),SEBIT5     WAS THIS MEMBER 'FOUND'               86580019
         BZ    GETNEXT            NO, GO LOOK FOR NEXT CTLTAB ENTRY     86640019
         TM    FLG7,COP           IS PGM NOW IN THE COPY PHASE          86740019
         BO    LEFTHALF           IF SO, WANT RENAMED ENTRY NOW, NOT    86840019
*                                 NEWNAME                               86940019
RENAME   TM    X0(RG2),SEBIT2     WAS THIS MEMBER RENAMED               87040019
         BO    GETNEXT            ENTRY IS RENAMED AND IT IS NOT        87300019
*                                 THE COPY PHASE                        87360019
         TM    FLG5,OSW1          IS OUTPUT DIR PRESCAN BEING DONE      87420019
         BO    LEFTHALF           IF PRESCAN ACCESS LEFT HALF OF        87480019
*                                 CTLTAB                                87540019
RTHALF   SR    RG3,RG3            IF DIRECTORY MERGE ACCESS             87600019
*                                 RIGHT HALF OF CTLTAB                  87660019
         IC    RG3,X6(RG2)        GET INDICATOR BYTE                    87740019
         MVC   FULLWD+P1(L3),X7(RG2) PUT POINTER INFO INTO WK AREA      87820019
         L     RG5,FULLWD                                               87900019
         LTR   RG3,RG3            IF NON-ZERO, DE POINTED TO IS ON UT3  87930019
         BZ    STIDEAD            RETURN A PTR TO THE IDE IN CORE       87960019
         LR    RG0,RG5            IDE IS NOT IN CORE                    88020019
         SLL   RG0,LFT8           SET UP 'TTR0' FOR CONVERSION          88100019
         B     NOTCORE            GO GET IDE INTO CORE FROM UT3         88180019
RETNAME  LA    RG5,X2(RG2)        IF DOING OUTPUT DIR PRE-SCAN, SET PTR 88260019
*                                 TO THE NEWNAME                        88340019
         L     RG8,NNTABAD                                              88440019
         L     RG7,X0(RG8)        GET ADDR OF CTLTAB ENTRY WHICH WAS    88470019
*                                 RENAMED                               88500019
         LA    RG8,X4(RG8)        BUMP POINTER                          88530019
         ST    RG8,NNTABAD        UPDATE NNPTRT TO NEXT ENTRY           88560019
         TM    X0(RG7),SEBIT4     IS RENAMED ENTRY FLAGGED AS 'DONTCPY' 88570019
         BZ    TSTBFV             NO, GO SEE IF IT WAS FOUND            88580019
         OI    X0(RG2),SEBIT4     YES, SO SET 'DONTCOPY' IN NEWNAME ENT 88590019
         B     GETNEXT            GO LOOK FOR NEXT CTLTAB ENTRY         88600019
TSTBFV   TM    X0(RG7),SEBIT5     WAS THIS OLDNAME FOUND                88610019
         BZ    GETNEXT            NO, GO LOOK FOR NEXT CTLTAB ENTRY     88620019
         B     STIDEAD            YES, GO SET ADDRESS OF NEWNAME INTO   88630019
*                                 IDEAD AND RETURN TO CALLER            88640019
LEFTHALF SR    RG3,RG3                                                  88680019
         IC    RG3,X2(RG2)        GET INDICATOR BYTE                    88740019
         LTR   RG3,RG3                                                  88800019
         BP    GISPTTR            IF NON-ZERO, IDE MUST BE ON SYSUT3    88860019
         MVC   IDEAD+P1(L3),X3(RG2) SET UP ADDR OF IDE                  88920019
         B     ENDFND             SEE IF THIS IS LAST ENTRY TO BE TRIED 88990019
GISPTTR  EQU   *                                                        89070019
         MVC   FULLWD1(L3),X3(RG2) PUT TTR OF SPILLED DE INTO WK AREA   89140019
         L     RG0,FULLWD1        PLACE TTR IN RG0 FOR CONVERSION       89220019
         B     NOTCORE            GO GET IDE INTO CORE FROM UT3         89270019
NEWENT   TM    FLG5,OSW1          IS OUTPUT DIRECTORY PRESCAN BEING     89320019
*                                 DONE NOW                              89370019
         BO    RETNAME            IF SO, SET UP POINTER TO THE NEWNAME  89420019
         TM    FLG7,COP           IS THIS FOR USE DURING COPY PHASE     89500019
         BO    GETNEXT            IF COPY PHASE, DONT USE NEWNAME ENTRY 89660019
         L     RG6,NNTABAD        GET ADDR OF PTR TO RENAMED CTLTAB ENT 89710019
         L     RG7,X0(RG6)        GET ADDR OF RENAMED ENTRY ITSELF      89760019
         LA    RG6,X4(RG6)        POINT TO NXT NNPTRTAB SLOT            89810019
         ST    RG6,NNTABAD        SAVE UPDATED POINTER                  89860019
         TM    X0(RG7),SEBIT4     IS THE CTLTAB ENTRY FOR THE ''OLD-    89900019
*                                 NAME'' FLAGGED AS 'DONTCOPY'          89940019
         BZ    NNRTHALF           NO                                    89980019
         OI    X0(RG2),SEBIT4     YES, SET 'DONTCOPY' IN NEWNAME ENTRY  90020019
         B     GETNEXT            LOOK FOR NEXT DESIRED CTLTAB ENTRY    90060019
NNRTHALF TM    X0(RG7),SEBIT5     WAS OLDNAME 'FOUND'                   90120019
         BZ    GETNEXT            NOT YET- GO GET NEXT CTLTAB ENTRY     90180019
         SR    RG3,RG3            SET UP TO GET INDICATOR BYTE          90210019
         IC    RG3,X6(RG7)        INDICATOR BYTE FROM RENAMED CTLTAB    90280019
         MVC   FULLWD(L4),X6(RG7) POINTER INFO INTO WORK AREA           90350019
         L     RG5,FULLWD                                               90420019
         LR    RG0,RG5                                                  90440019
         SLL   RG0,LFT8           SET UP 'TTR0' FOR CONVERSION          90460019
         OI    SWITCH1,ENTERNN    INDICATES THAT NEW NAME WILLL BE      90480019
*                                 PLUGGED INTO THE DIRECTORY ENTRY      90540019
         LTR   RG3,RG3            IS RENAMED DE IN CORE (INDIC NON-0)   90570019
         BP    NOTCORE            NO, GO READ IT FROM SYSUT3            90600019
         MVC   X0(LEN8,RG5),X2(RG2) NEWNAME INTO IN-CORE INPUT DIREC-   90640019
*                                 TORY ENTRY, OVERLAYING OLDNAME        90680019
         B     STIDEAD            GO SET 'IDEAD' POINTER FOR CALLER     90730019
NOTCORE  LA    RG1,UT3DCB                                               90780019
         LR    RG10,RG2           SAVE POINTER TO CTLTAB ENTRY          90840019
         LA    RG2,FDAD(RG1)      PTR TO DCBFDAD                        90900019
         L     RG15,VTTOCC                                              90960019
         BALR  RG14,RG15          GO CONVERT TTR TO MBBCCHHR            91020019
         TM    UT3CHAR+P1,RPS     IS UT3 ON AN RPS DEVICE        S20201 91022020
         BNO   NOTRPS             NO, GO AROUND SECTOR CODE      S20201 91024020
         SPACE 1                                                 S20201 91026020
*   IF SYSUT3 IS ON AN RPS DEVICE, MUST GO TO SECTOR CONVERT     S20201 91028020
* ROUTINE TO GET SECTOR VALUE                                    S20201 91030020
         SPACE 1                                                 S20201 91032020
         STM   RG0,RG15,SV4       SAVE ALL REGS                  S20201 91034020
         IC    RG3,UT3CHAR+P3     INSERT UCB UNIT TYPE CODE      S20201 91036020
         SLL   RG3,S24            SHIFT TO HIGH ORDER BYTE       S20201 91038020
         LA    RG2,UT3SCTOR       LOAD PTR TO SECTOR SLOT        S20201 91040020
         OR    RG2,RG3            OR IN UCB UNIT CODE            S20201 91042020
*   PARAMETER REGISTER 2 IS NOW SET UP FOR CONVERT ROUTINE       S20201 91044020
         LH    RG0,UT3LRECL       LOAD UT3 RECORD LENGTH         S20201 91046020
         SLL   RG0,S16            SHIFT RECORD SIZE TO HIGH      S20201 91048020
*                                   ORDER TWO BYTES              S20201 91050020
         IC    RG0,SV4+P2         INSERT RECORD NUMBER (TTR0     S20201 91052020
*                                   WAS IN REG0 BEFORE ABOVE     S20201 91054020
*                                   STM INSTRUCTION EXECUTED     S20201 91056020
         SPACE 1                                                 S20201 91058020
*   PARAMETER REGISTER 0 IS NOW SET UP FOR CONVERT ROUTINE       S20201 91060020
         SPACE 1                                                 S20201 91062020
         L     RG15,ADCVT         ADDR OF CVT                    S20201 91064020
         USING CVT,RG15                                          S20201 91066020
         L     RG15,CVT0SCR1      ADDR OF SECTOR CONVERT ROUTINE S20201 91068020
         DROP  RG15                                              S20201 91070020
         BALR  RG14,RG15          LINK TO CONVERT ROUTINE        S20201 91072020
         SPACE 1                                                 S20201 91074020
         LM    RG0,RG15,SV4       RESTORE REGISTERS              S20201 91076020
NOTRPS   EQU   *                                                 S20201 91078020
         MVC   XWKA1(LEN8),X0(RG2) SAVE MBBCCHHR FROM SYSUT3 DCB        91080019
         MVI   SENSE,SENSE1+SENSE3 TURN ON SENSE1 AND SENSE3            91140019
         L     RG15,VIEBDRD                                             91320019
         BALR  RG14,RG15          GO TO READ SPILLED IDE FROM SYSUT3    91350019
         TM    IOEF1,ERF8         DID AN I/O ERROR OCCUR WHILE READING  91380019
         BZ    NOIOER3            IF NOT, RESTORE UT3 MBBCCHHR          91410019
         OI    SWITCH1,MGINODE    ELSE SET 'NO IDE' BIT                 91440019
         B     RETPTR             GO TO RET TO CALLER WITH NO IDE       91470019
NOIOER3  EQU   *                                                        91500019
         MVC   X0(LEN8,RG2),XWKA1 RESTORE MBBCCHHR TO SYSUT3 DCB        91530019
*                                 TO ALLOW TO BE WRITTEN BACK           91560019
*                                 FROM WHERE IT WAS READ DURING         91620019
*                                 COPY PHASE                            91680019
         LR    RG2,RG10           RESTORE RG2                           91740019
         TM    SWITCH1,ENTERNN                                          91800019
         BZ    RETPTR             IF NO NEED TO PUT NEWNAME INTO THIS   91830019
*                                 IDE, PREPARE TO SET UP 'IDEAD' NOW    91860019
         L     RG10,ADWK                                                91900019
         MVC   SPIDEOFF(NAMLEN,RG10),X2(RG2) PUT NEWNAME INTO UT3 IDE-  91940019
*                                 THIS IS DURING DIRECTORY MERGE PHASE. 91980019
RETPTR   L     RG5,ADWK                                                 92040019
         LA    RG5,SPIDEOFF(RG5)  POINT TO 1ST BYTE OF SPILLED DE       92100019
STIDEAD  ST    RG5,IDEAD          SET POINTER TO IDE FOR CALLER USE     92130019
         NI    SWITCH1,FF-ENTERNN RESET INDIC TO PLUG IN NEWNAME        92160019
*                                 (DOESNT MATTER IF IT WAS OFF ALREADY) 92190019
ENDFND   CLC   GIFCT(L2),ONE1     ANY MORE CTLTAB ENTRIES TO BE SEARCH- 92220019
*                                 ED AFTER THIS                         92250019
         BE    LAST               IF NOT, INDICATE NO MORE TO BE SOUGHT 92290019
         LH    RG3,GIFCT                                                92340019
         BCT   RG3,RETURN         DECREMENT INTERNAL COUNT OF NBR OF    92380019
*                                 ENTRIES TO BE SOUGHT                  92420019
LAST     OI    FLG4,LE            SET 'LAST-ENTRY-PROCESSED' INDICATOR  92460019
         NI    SWITCH1,FF-TIME1   RESET 1ST-TIME INTERNAL SWITCH        92520019
RETURN   LA    RG2,TABLEN(RG2)    BUMP CTLTAB POINTER                   92580019
         ST    RG2,TABAD                                                92640019
         STH   RG3,GIFCT               SET DECREMENTED COUNT            92700019
         L     RG13,SV2+CHAINBK                                         92760019
         RETURN  (14,12)                                                92820019
         SPACE 2                                                        92840019
XWKA1    DS    2F                 AREA TO SAVE SYSUT3 MBBCCHHR          92860019
FULLWD   DC    F'0'               WORK AREA                             92900019
FULLWD1  DC    F'0'               AREA FOR USE IN TTR-MBBCCHHR CONVERT  92940019
GIFCT    DC    H'0'               INTERNAL CT OF NBR OF ENTRIES TO TRY  93040019
ONE1     DC    H'1'               COMPARAND VALUE                       93140019
         EJECT                                                          93300019
         DS    0H                                                       93340019
IEBMKO   EQU   *                                                        93380019
IEBDSCKO EQU   IEBMKO                                                   93390019
         ENTRY IEBDSCKO                                                 93400019
* INPUT TO ROUTINE -                                                    93420019
*        ALO = ADDR WHERE TO BEGIN SAVING OUTPUT DIR BLKS (CALLER ONLY  93480019
*              INIT. ONCE PER INPUT DD, SUBRTNE UPDATES THEREAFTER)     93540019
*        NSP, ODIC AND OIC SWITCHES MUST ALL BE OFF (ZERO=OFF)          93600019
*        OBCT MUST BE INIT TO ZERO PRIOR TO 1ST CALL FOR CURR. INPUT DD 93660019
         SPACE 2                                                        93720019
         SAVE  (14,12)            SAVE CALLER'S REGS                    93840019
         BALR  R10,R0             ESTAB ADDRESSIBILITY                  93900019
         USING *,R10                                                    93960019
         ST    R13,SV3+CHAINBK    SAVE AREA LINKAGE                     94020019
         LA    R12,SV3                                                  94080019
         ST    R12,CHAINTHS(R13)                                        94140019
         LR    R13,R12                                                  94200019
         TM    FLG5,NSP           IS NO-SPACE SWITCH ON                 94260019
         BO    C3BK1              IF SO, DON'T SAVE ANY MORE            94320019
         L     R5,BCB                                                   94380019
         LA    R5,X0(R5)          ADDR OF 1ST BLOCK IN BUFFER           94440019
C3GALO   L     R6,ALO             ADDR WHERE THIS BLOCK IS TO BE PUT    94500019
         LA    R7,KBLEN+CON12(R6) ADD LENGTH OF FMBB+CT+KEY+DIR BLOCK   94560019
         C     R7,HICOR           IS THIS ADDR G.T. HIGHEST AVAIL LOC.  94620019
         BH    C3CKOB             IF SO, GO SEE IF ANY BLOCKS SAVED     94680019
         MVC   X0(KL+CON12,R6),X0(R5) MOVE FMBB+COUNT+KEY TO CORE AREA  94740019
         MVC   KL+CON12(BL,R6),KL+CON12(R5) MOVE DIRECTORY BLK TO CORE  94800019
         LH    R8,OBCT            GET CT OF NBR BLKS SAVED IN CORE      94860019
         LPR   R8,R8                                                    94920019
         LA    R8,X1(R8)          ADD 1 TO COUNT                        94980019
         STH   R8,OBCT            SAVE UPDATED COUNT                    95040019
         ST    R6,SVLSTO          SAVE ADDR OF LAST IN-CORE BLOCK       95100019
         ST    R7,ALO             SET ADDR OF LOWEST AVAIL CORE         95160019
         CLI   CON12(R5),FF       IS KEYNAME = TO 'FF' (LAST USEFUL BK) 95220019
         BNE   C1TEP              IF NO, SEE IF THIS IS LAST BLK IN BFR 95280019
         OI    FLG6,OIC           ELSE SET ALL-ODES-SAVED-IN-CORE SW.   95340019
C3BK1    L     R13,CHAINBK(R13)   RESTORE CALLER'S SAVE AREA ADDR       95400019
         RETURN (14,12)           RETURN TO CALLER                      95460019
C1TEP    EQU   *                                                        95520019
         TM    X0(R5),ENDPROC     IS THIS LAST REC IN BFR               95580019
         BO    C3BK1              IF SO, GO RETURN TO CALLER            95640019
         LA    R5,KBLEN+CON12(R5) POINT TO NEXT BLOCK IN BFR            95700019
         B     C3GALO             GET NXT LOC WHERE TO PUT NXT BLOCK    95760019
C3CKOB   OI    FLG5,NSP           INDIC NO MORE SPACE LEFT FOR OUT DIR  95820019
         SR    R8,R8              SET COMPARAND REG TO ZEROES           95880019
         CH    R8,OBCT            ARE THERE ANY OUT DIR BLKS SAVED      95940019
         BE    C3BK1              IF NOT, GO EXIT TO CALLER             96000019
         OI    FLG6,ODIC          INDICATE SOME-BUT-NOT-ALL BLKS SAVED  96060019
         MVC   OUTDAD1(LEN8),X1(R5) MBBCCHHR OF 1ST UN-RETAINED OD BLK  96120019
         B     C3BK1              GO TO EXIT TO CALLER                  96180019
         DS    0F                                                       96190019
PATCHL2  EQU   (*-IEBDSCP2)/20    5 PER-CENT PATCH AREA LENGTH          96200019
PATCH2   DC    XL(PATCHL2)'00'    PATCH AREA FOR THIS CSECT      A41780 96210021
         EJECT                                                          96240019
         DS    0D                                                       96300019
IEBDSMCA CSECT                                                          96340019
IEBMCA   EQU   IEBDSMCA                                                 96380019
         IEBMCA                                                         96420019
         EJECT                                                          96480019
         DCBD  DSORG=PO                                                 96540019
FDAD     EQU   DCBFDAD-IHADCB     OFFSET TO DCBFDAD FIELD               96600019
         EJECT                                                          96660019
CVT      DSECT                                                          96720019
         CVT                                                            96780019
TPCNVT   EQU   CVTPCNVT-CVTTCBP   DISPLACEMENT TO TTR-MBBCCHHR CONVERT  96840019
TPRLTV   EQU   CVTPRLTV-CVTTCBP   DISPLACEMENT TO MBBCCHHR-TTR CONVERT  96900019
         EJECT                                                          96960019
IECDSECT DSECT                                                          97020019
         IECDSECT                                                       97080019
TAOFF    EQU   DXDAADDR-DXIOB     OFFSET FROM START OF IOB TO MBBCCHHR  97140019
         END                                                            97200019
