 TITLE 'IEBISAM - IEBISAM UTILITY PROGRAM - ROOT SEGMENT'               00200016
*STATUS-CHANGE LEVEL 000                                                00400016
*FUNCTION-OPERATION- THE ROOT SEGMENT OF THE IEBISAM UTILITY PROGRAM    00600016
*   GETS CORE FOR THE COMMON WORK AREA, CHAINS THE SAVE AREAS TO THE    00800016
*   SUPERVISOR. THIS MODULE PICKS UP ANY INVOKING PARAMETERS- OPTIONS,  01000016
*   DDNAMES, AND/OR PAGE NUMBER. FROM THE OPTIONS GIVEN, THE OPERATION  01200016
*   TO BE PERFORMED IS DETERMINED.  DEPENDING UPON THE CONTROL          01400016
*   PARAMETER, A MASK IS SET IN THE CONTROL BYTE FIELD OF THE COMMON    01600016
*   WORK AREA.  A CHECK IS MADE TO DETERMINE IF REPLACEMENT DDNAMES     01800016
*   FOR SYSPRINT,SYSUT1,AND SYSUT2 ARE PRESENT. IF SO THESE DD NAMES    02000016
*   ARE PLACED IN THE COMMON WORK AREA, OTHERWISE THE ASSUMED DDNAMES   02200016
*   SYSPRINT,SYSUT1,AND SYSUT2 ARE USED. IF A PAGE NUMBER IS PROVIDED,  02400016
*   IT IS USED OTHERWISE AN ASSUMED NUMBER (1) IS USED. CONTROL IS      02600016
*   THEN PASSED TO THE MODULE REQUIRED TO PERFORM THE REQUESTED         02800016
*   OPERATION.                                                          03000016
*                                                                       03200016
*ENTRY POINTS- IEBISR- TO PROVIDE COMMON WORK AREA, HANDLE INVOKING     03400016
*   PARAMETERS, AND DETERMINE OPERATION.                                03600016
*                                                                       03800016
*INPUT - ADDRESS OF INVOKING PARAMETERS IN REGISTER 1, SAVE AREA        04000016
*   ADDRESS IN REGISTER 13, RETURN ADDRESS OF CALLING PROGRAM IN        04200016
*   REGISTER 14, ADDRESS OF THIS MODULE IN REGISTER 15.                 04400016
*                                                                       04600016
*OUTPUT - COMMON WORK AREA ESTABLISHED- DEFINED BY THE DSECT IEBWORK-   04800016
*   POINTED TO BY REGISTER 11.                                          05000016
*                                                                       05200016
*                                                                       05400016
*                                                                       05600016
* WORK AREA FIELDS SET UP FOR NORMAL EXIT                               05800016
*        ISINVOK -  ADDRESS OF PARM LIST FROM INVOCATION                06000016
*        ISPRINT -  NAME FOR PRINT DD                                   06200016
*        ISUT1 -    NAME FOR INPUT DD                                   06400016
*        ISUT2 -    NAME FOR OUTPUT DD                                  06600016
*        ISPAGE -   PAGE NUMBER TO BE USED                              06800016
*        ISCNTRL -  SET TO INDICATE OPTIONS REQUESTED                   07000016
*        XCTLAREA - SET FOR XCTL TO NEXT MODULE- IEBISL,IEBISU,IEBISC,  07200016
*                   IEBISPL,IEBISPP                                     07400016
*        EXITADDR - USER'S MODULE NAME                                  07600016
*                                                                       07800016
*WORKAREA FIELDS SET UP FOR ERROR EXIT                                  08000016
*        ISINVOK  - ADDRESS OF PARM LIST FROM INVOCATION                08200016
*        ISCOMP   - COMPLETION CODE TO BE RETURNED                      08400016
*        ISMESS   - MESSAGE NUMBER TO BE USED TO SELECT MESSAGE         08600016
*        ISPAGE  -  PAGE NUMBER TO BE USED                              08800016
*        XCTLAREA & WHICH -  SET FOR XCTL TO IEBISF                     09000016
*                                                                       09200016
*                                                                       09400016
*                                                                       09600016
*EXTERNAL ROUTINES - NA                                                 09800016
*                                                                       10000016
*EXITS-NORMAL                                                           10200016
*   IEBISL- CONTROL PARAMETER SPECIFIED LOAD OPERATION                  10400016
*   IEBISU- CONTROL PARAMETER SPECIFIED UNLOAD OPERATION                10600016
*   IEBISC- CONTROL PARAMETER SPECIFIED COPY OPERATION                  10800016
*   IEBISPL- CONTROL PARAMETER SPECIFIED PRINT LOGICAL OPERATION        11000016
*   IEBISPP- CONTROL PARAMETER SPECIFIED PRINT PHYSICAL OPERATION       11200016
*                                                                       11400016
*ATTRIBUTES- REENTRANT                                                  11600016
*                                                                       11800016
*REGISTER ASSIGNMENTS                                                   12000016
PAREG0   EQU   0                                                        12200016
PAREG1   EQU   1                                                        12400016
CONS     EQU   2                                                        12600016
WK3      EQU   3                                                        12800016
WK4      EQU   4                                                        13000016
WK5      EQU   5                                                        13200016
WK6      EQU   6                                                        13400016
OPREG    EQU   7                                                        13600016
IRETREG  EQU   8                                                        13800016
GOREG    EQU   9                                                        14000016
BASEREG  EQU   10                                                       14200016
WORKAREA EQU   11                                                       14400016
PTREG    EQU   12                                                       14600016
SAVREG   EQU   13                                                       14800016
RETREG   EQU   14                                                       15000016
ADDR     EQU   15                                                       15200016
         EJECT                                                          15400016
IEBISAM  CSECT                                                          15600016
* STANDARD LINKAGE CONVENTION                                           15800016
         SAVE  (14,12),T,ISR-67-V1      SAVE CALLING PROGRAM'S REGS     16000016
         USING IEBISAM,BASEREG          ESTABLISH ADDRESSABILITY        16200016
         LR    BASEREG,ADDR                                             16400016
         LR    OPREG,PAREG1             SAVE PARAMETER LIST POINTER     16600016
*                                          WHILE OBTAINING WORK AREA    16800016
         SPACE 1                                                        17000016
         GETMAIN R,LV=1536              GET WORK AREA                   17200016
* CLEAR THE ENTIRE WORK AREA TO ZEROS                                   17400016
         LR    WORKAREA,PAREG1          SET UP ADDRESSABILITY TO WORK   17600016
*                                          AREA                         17800016
         USING IEBWORK,WORKAREA         SET UP ADDRESSABILITY TO WORK   18000016
*                                          AREA                         18200016
         MVI   SAVE1BK,X'00'                                            18400016
         MVC   SAVE1BK+1+0*255(255),SAVE1BK+0*255                       18600016
         MVC   SAVE1BK+1+1*255(255),SAVE1BK+1*255                       18800016
         MVC   SAVE1BK+1+2*255(255),SAVE1BK+2*255                       19000016
         MVC   SAVE1BK+1+3*255(255),SAVE1BK+3*255                       19200016
         MVC   SAVE1BK+1+4*255(255),SAVE1BK+4*255                       19400016
         MVC   SAVE1BK+1+5*255(255),SAVE1BK+5*255                       19600016
         MVI   EXITADDR,X'40'           SET EXIT ADDRESS TO BLANKS      19800016
         MVC   EXITADDR+1(7),EXITADDR                                   20000016
         ST    OPREG,ISINVOK            SAVE POINTER TO INVOCATION LIST 20200016
         SPACE 1                                                        20400016
         ST    SAVREG,SAVE1BK           SET BACK CHAIN POINTER          20600016
         LR    SAVREG,WORKAREA         UPDATE TO NEW SAVE AREA          20800016
         LA    WK3,SAVE2                SET UP FORWARD CHAIN POINTER    21000016
         ST    WK3,SAVE1FD                 TO NEXT SAVE AREA            21200016
*THIS SECTION CHECKS FOR THE EXISTENCE OF AN OPTION,OBTAINS THE LENGTH  21400016
*OF THIS OPTION AND ITS ADDRESS IS SAVED.                               21600016
OPTION   L     GOREG,0(0,OPREG)         GET ADDRESS OF OPTIONS          21800016
         OC    0(2,GOREG),0(GOREG)      ANY OPTIONS SPECIFIED           22000016
         BZ    LABELUN                  NO, ASSUME UNLOAD               22200016
         MVC   ALIGN(2),0(GOREG)        YES, GET LENGTH OF OPTIONS -    22400016
         LH    WK6,ALIGN                   MOVE TO HALF-WORD BOUNDARY   22600016
         LA    WK5,2(0,GOREG)           GET OPTION ADDRESS              22800016
*                                                                       23000016
         EJECT                                                          23200016
* THIS SECTION CHECKS THE OPTION CODE FOR A LEGAL OPERATION.            23400016
         CLI   ALIGN+1,X'06'            CHECK FOR LENGTH LESS THAN SIX  23600016
         BNL   CKOTHER                  NO, CHECK FOR UNLOAD,PRINT      23800016
         CLI   ALIGN+1,X'04'            CHECK FOR LENGTH OF FOUR        24000016
         BNE   ASSUMECY                 NO, GO TO SET ERROR CONDITION   24200016
         CLC   0(4,WK5),OPCOPY          CHECK FOR A COPY REQUEST        24400016
         BE    SETCOPY                  YES, SET CONTROL BYTE FOR COPY  24600016
         CLC   0(4,WK5),OPLOAD          CHECK FOR A LOAD REQUEST        24800016
         BNE   ASSUMECY                 NO, GO TO SET ERROR CONDITION   25000016
         MVI   ISCNTRL,ISSWL            SET CONTROL BYTE FOR LOAD       25200016
         MVC   WHICH(8),LODCON          MOVE SYMBOLIC ENTRY POINT FOR   25400016
*                                          XCTL                         25600016
         B     ONWARD                                                   25800016
SETCOPY  MVI   ISCNTRL,ISSWC            SET CONTROL BYTE FOR COPY       26000016
         MVC   WHICH(8),CPYCON          MOVE SYMBOLIC ENTRY POINT FOR   26200016
*                                          XCTL                         26400016
         B     ONWARD                                                   26600016
CKOTHER  CLC   0(5,WK5),OPPRNT          CHECK FOR A PRINT REQUEST       26800016
         BE    CKPRNT                   YES, DETERMINE WHETHER LOGICAL  27000016
*                                          OR PHYSICAL                  27200016
         CLI   ALIGN+1,X'06'            CHECK FOR LENGTH EQUAL TO SIX   27400016
         BNE   ASSUMECY                 NO,SET ERROR CONDITION          27600016
         CLC   0(6,WK5),OPUNLD          CHECK FOR AN UNLOAD REQUEST     27800016
         BNE   ASSUMECY                 NO, GO TO SET ERROR CONDITION   28000016
LABELUN  MVI   ISCNTRL,ISSWU            SET CONTROL BYTE FOR UNLOAD     28200016
         MVC   WHICH(8),UNLCON          MOVE SYMBOLIC ENTRY POINT NAME  28400016
*                                          FOR XCTL                     28600016
         B     ONWARD                                                   28800016
*THIS SECTION CHECKS FOR LEGAL PARAMETERS ON A PRINT REQUEST            29000016
CKPRNT   CLI   5(WK5),C'L'        CHECK FOR A LOGICAL PRINT             29200016
*                                          REQUEST                      29400016
         BE    SETLOG                   YES, SET CONTROL BYTE           29600016
         CLI   5(WK5),C'P'        CHECK FOR A PHYSICAL PRINT            29800016
*                                          REQUEST                      30000016
         BNE   ASSUMECY                 NO, SET ERROR CONDITION         30200016
         MVC   WHICH(8),PRTPCON         MOVE IN SYMBOLIC ENTRY NAME     30400016
*                                          FOR XCTL                     30600016
         B     PRINTSET                                                 30800016
SETLOG   MVC   WHICH(8),PRTLCON         MOVE IN SYMBOLIC ENTRY NAME     31000016
*                                          FOR XCTL                     31200016
PRINTSET MVI   ISCNTRL,ISSWP            SET CONTROL BYTE FOR PRINT      31400016
         LR    WK3,WK5                  PICK UP POINTER TO LIST         31600016
         AR    WK3,WK6                  ADD LENGTH OF LIST TO OBTAIN    31800016
*                                          END POINTER                  32000016
         SH    WK6,=H'6'                SUBTRACT 6 FROM LENGTH OF LIST  32200016
         LA    WK5,6(0,WK5)             POINT TO NEXT CHARACTER TO BE   32400016
*                                          SCANNED                      32600016
         CR    WK5,WK3                  CHECK FOR END OF LIST           32800016
         BNL   CKONWARD                 YES, CHECK FOR NEED OF DEFAULT  33000016
*                                          VALUES                       33200016
         CLI   0(WK5),C','              CHECK FOR LEGAL DELIMITER       33400016
         BNE   ASSUMECY                 NO, GO TO SET ERROR CONDITION   33600016
         LA    WK5,1(0,WK5)             UPDATE POINTER BEYOND DELIMITER 33800016
         LR    WK4,WK5                  SET MOVING POINTER TO INITIAL   34000016
*                                          VALUE                        34200016
         SR    CONS,CONS                CLEAR BYTE COUNTER              34400016
         CR    WK4,WK3                  CHECK FOR END OF LIST           34600016
         BNL   ASSUMECY                 YES, GO TO GET ERROR CONDITION  34800016
SCANBEG  CLI   0(WK4),C','              CHECK FOR DELIMITER             35000016
         BE    ASSUMECY                 YES, GO TO SET ERROR CONDITION  35200016
SCANBEGA CLI   0(WK4),C'N'              CHECK FOR NO CONVERT OPTION     35400016
         BE    SETN                     YES, NO CONVERT SPECIFIED       35600016
         CLI   0(WK4),C'I'              CHECK FOR INDEX TO BE PRINTED   35800016
         BE    SETI                     YES, INDEX SPECIFIED            36000016
         CLI   0(WK4),C'P'              CHECK FOR PRIME TO BE PRINTED   36200016
         BE    SETP                     YES,PRIME SPECIFIED             36400016
         CLI   0(WK4),C'O'              CHECK FOR OVERFLOW PRINTED      36600016
         BE    SETO                     YES, OVERFLOW SPECIFIED         36800016
         C     WK6,=F'6'                CHECK FOR LENGTH OF AT LEAST 6  37000016
         BL    ASSUMECY                 NO, GO TO SET ERROR CONDITION   37200016
         CLC   0(5,WK4),EXITCON         CHECK FOR EXIT=                 37400016
         BNE   ASSUMECY                 NO, GO TO SET  ERROR CONDITION  37600016
         SH    WK6,=H'5'                SUBTRACT 5 FROM LIST LENGTH     37800016
         LA    WK4,5(0,WK4)             UPDATE MOVING POINTER TO USER'S 38000016
*                                          MODULE NAME                  38200016
         LR    WK5,WK4                  SET BEGINNING POINTER           38400016
SCANSTRT CLI   0(WK4),X'5B'             CHECK FOR DOLLAR SIGN           38600016
         BE    GOAHEAD                  YES, CHECK FOR SECOND CHARACTER 38800016
         CLI   0(WK4),X'7C'             CHECK FOR A COMMERCIAL  AT      39000016
*                                          SIGN                         39200016
         BE    GOAHEAD                  YES, CHECK FOR SECOND CHARACTER 39400016
         CLI   0(WK4),X'7B'             CHECK FOR A POUND SIGN          39600016
         BE    GOAHEAD                  YES, CHECK FOR SECOND CHARACTER 39800016
         CLI   0(WK4),X'C1'             CHECK FOR CHARACTER FROM A TO I 40000016
         BL    ASSUMECY                 NO,GO TO SET ERROR CONDITION    40200016
         CLI   0(WK4),X'C9'             CHECK FOR CHARACTER FROM A TO I 40400016
         BNH   GOAHEAD                  YES, CHECK FOR SECOND CHARACTER 40600016
         CLI   0(WK4),X'D1'             CHECK FOR CHARACTER FROM J TO R 40800016
         BL    ASSUMECY                 NO, GO  TO SET ERROR CONDITION  41000016
         CLI   0(WK4),X'D9'             CHECK FOR CHARACTER FROM J TO R 41200016
         BNH   GOAHEAD                  YES, CHECK SECOND CHARACTER     41400016
         CLI   0(WK4),X'E2'             CHECK FOR CHARACTER FROM S TO Z 41600016
         BL    ASSUMECY                 NO, GO TO SET ERROR CONDITION   41800016
         CLI   0(WK4),X'E9'             CHECK FOR CHARACTER FROM S TO Z 42000016
         BNH   GOAHEAD                  YES, CHECK FOR SECOND CHARACTER 42200016
         B     ASSUMECY                 NO, GO TO SET ERROR CONDITION   42400016
GOAHEAD  LA    CONS,1(0,CONS)           UPDATE BYTE COUNTER             42600016
         LA    WK4,1(0,WK4)             UPDATE MOVING POINTER TO NEXT   42800016
*                                          CHARACTER                    43000016
         CR    WK4,WK3                  CHECK FOR END OF LIST           43200016
         BNL   SCANDONE                 YES, SET UP MODULE NAME         43400016
         CLI   0(WK4),C','              CHECK FOR DELIMITER             43600016
         BE    SCANDONE                 YES, GO BACK                    43800016
         CLI   0(WK4),X'F9'             CHECK FOR CHARACTER FROM 0 TO 9 44000016
         BH    ASSUMECY                 NO,SET ERROR CONDITION          44200016
         CLI   0(WK4),X'F0'             CHECK FOR CHARACTER FROM 0 TO 9 44400016
         BNL   GOAHEAD                  YES, CHECK NEXT CHARACTER       44600016
         B     SCANSTRT                                                 44800016
SCANDONE C     CONS,=F'8'               CHECK FOR MODULE NAME LENGTH    45000016
*                                          BEING LESS THAN OR EQUAL TO  45200016
*                                          EIGHT                        45400016
         BH    ASSUMECY                 NO,GO TO SET UP ERROR CONDITION 45600016
         BCTR  CONS,0                   REDUCE CHARACTER NUMBER BY ONE  45800016
         EX    CONS,MOVENAME            MOVE MODULE NAME INTO HOLD AREA 46000016
         CR    WK4,WK3                  CHECK FOR END OF LIST           46200016
         BNL   CKONWARD                 YES, CHECK FOR NEED OF DEFAULT  46400016
*                                          VALUES                       46600016
         CLI   0(WK4),C','              CHECK FOR A DELIMITER           46800016
         BNE   ASSUMECY                 NO, GO TO SET ERROR CONDITION   47000016
*                                          MOVE IN MODULE NAME          47200016
         LA    WK4,1(0,WK4)             UPDATE MOVING POINTER           47400016
         LR    WK5,WK4                  UPDATE BEGINNING POINTER        47600016
         B     SCANBEG                                                  47800016
CKONWARD TM    ISCNTRL,ALLMASK          CHECK FOR ANY OPTIONS SPECIFIED 48000016
*                                          FOR INDEX,PRIME,OVERFLOW     48200016
         BC    5,ONWARD                 YES, SOME SPECIFIED             48400016
         OI    ISCNTRL,ALLMASK          SET TO DEFAULT TO PRINT ALL     48600016
*                                          THREE AREAS                  48800016
         B     ONWARD                                                   49000016
SETN     OI    ISCNTRL,ISSWN            SET FOR NO CONVERT              49200016
UPDATE   LA    WK4,1(0,WK4)             UPDATE MOVING POINTER           49400016
         CR    WK4,WK3                  CHECK FOR END OF LIST           49600016
         BNL   CKONWARD                 YES, CHECK FOR DEFAULT OPTIONS  49800016
*                                          NEEDED                       50000016
         CLI   0(WK4),C','              CHECK FOR COMMA DELIMETER       50200016
         BNE   SCANBEGA                 NO, SCAN FOR OPTIONS            50400016
         B     UPDATE                                                   50600016
SETI     OI    ISCNTRL,ISSWPI           SET FOR INDEX PRINT             50800016
         B     UPDATE                                                   51000016
SETP     OI    ISCNTRL,ISSWPP           SET FOR PRIME PRINT             51200016
         B     UPDATE                                                   51400016
SETO     OI    ISCNTRL,ISSWPO           SET FOR OVERFLOW PRINT          51600016
         B     UPDATE                                                   51800016
         EJECT                                                          52000016
*THIS SECTION GETS THE ADDRESS OF THE DDNAMES IF ANY ARE PROVIDED,      52200016
*OTHERWISE THE STANDARD DDNAMES ARE USED.                               52400016
*                                                                       52600016
ONWARD   TM    0(OPREG),X'80'          IS A DELIMITER PRESENT           52800016
         BC    1,CONAME                YES, PICK UP ASSUMED DDNAMES     53000016
SUBST    L     GOREG,4(0,OPREG)         GET  DDNAME ADDRESS             53200016
         OC    0(2,GOREG),0(GOREG)     CHECK FOR DDNAMES SUPPLIED       53400016
         BE    CONAME                   NO USE ASSUMED DDNAMES          53600016
         MVC   ALIGN(2),0(GOREG)        PICK UP DDNAME LENGTH           53800016
         CLI   ALIGN,X'00'              CHECK FOR LENGTH OF DDNAME LIST 54000016
*                                          GREATER THAN 256 HEX         54200016
         BNE   TESTALL                  YES CHECK FOR ALL 3 DDNAMES     54400016
         CLI   ALIGN+1,X'48'            CHECK FOR LENGTH OF DDNAME LIST 54600016
*                                          SUFFICIENT FOR SYSUT2        54800016
         BL    TESTREST                 NO CHECK FOR SYSUT1 LENGTH      55000016
TESTALL  OC    66(8,GOREG),66(GOREG)   CHECK FOR SYSUT2 DDNAME          55200016
         BC    7,INVUT2                 YES PICK UP PROVIDED NAME       55400016
         MVC   ISUT2(8),NAMEUT2         MOVE ASSUMED NAME               55600016
         B     TESTTWO                                                  55800016
INVUT2   MVC   ISUT2(8),66(GOREG)      MOVE IN PROVIDED NAME FOR        56000016
*                                          SYSUT2                       56200016
TESTTWO  OC    58(8,GOREG),58(GOREG)   CHECK FOR SYSUT1 DDNAME          56400016
         BC    7,INVUT1                 YES PICK UP PROVIDED NAME       56600016
         MVC   ISUT1(8),NAMEUT1        MOVE ASSUMED NAME                56800016
         B     TESTONE                                                  57000016
INVUT1   MVC   ISUT1(8),58(GOREG)       MOVE IN PROVIDED NAME FOR       57200016
*                                          SYSUT1                       57400016
TESTONE  OC    42(8,GOREG),42(GOREG)    CHECK FOR SYSPRINT              57600016
         BC    7,INVPRT                 YES PICK UP PROVIDED NAME       57800016
USEPRINT MVC   ISPRINT(8),PRINT         MOVE ASSUMED NAME               58000016
         B     SUPPLY1                                                  58200016
INVPRT   MVC   ISPRINT(8),42(GOREG)     MOVE IN PROVIDED NAME FOR       58400016
*                                          SYSPRINT                     58600016
         B     SUPPLY1                                                  58800016
TESTREST CLI   ALIGN+1,X'40'            CHECK FOR LENGTH OF DDNAME LIST 59000016
*                                          SUFFICIENT FOR SYSUT1        59200016
         BNL   TESTTWO                  YES CHECK FOR SYSUT1            59400016
         CLI   ALIGN+1,X'30'            CHECK FOR LENGTH OF DDNAME LIST 59600016
*                                          SUFFICIENT FOR SYSPRINT      59800016
         BNL   TESTONE                  YES CHECK FOR SYSPRINT          60000016
*USE ALL THREE ASSUMED NAMES                                            60200016
CONAME   MVC   ISUT2(8),NAMEUT2        PICK UP ASSUMED NAMES FOR        60400016
         MVC   ISUT1(8),NAMEUT1           SYSUT1,SYSUT2 AND SYSPRINT    60600016
         B     USEPRINT                                                 60800016
         EJECT                                                          61000016
*THIS SECTION CHECKS FOR THE EXISTENCE OF A PROVIDED PAGE NUMBER. IF    61200016
*ONE IS NOT PROVIDED ONE IS ASSUMED.                                    61400016
SUPPLY1  TM    0(OPREG),X'80'          CHECK FOR A DELIMITER ON FIRST   61600016
*                                          PARAMETER                    61800016
         BC    1,OTHER                  YES, ASSUME 1 AS PAGE NUMBER    62000016
         TM    4(OPREG),X'80'           CHECK FOR A DELIMITER ON THE    62200016
*                                          SECOND PARAMETER             62400016
         BC    1,OTHER                  YES, ASSUME 1 AS PAGE NUMBER    62600016
PAGE     L     GOREG,8(0,OPREG)         GET PAGE NUMBER ADDRESS         62800016
         OC    0(2,GOREG),0(GOREG)     CHECK FOR A PROVIDED PAGE NO     63000016
         BE    OTHER                    NO PROVIDE ONE                  63200016
*THIS SECTION MOVES THE PAGE NUMBER TO THE ISPAGE FIELD, UPDATES THE    63400016
*PAGE NUMBER AND RESTORES THE UPDATED PAGE NUMBER FOR THE CALLER.       63600016
         SR    WK6,WK6                                                  63800016
         XC    DOUBLE(8),DOUBLE                                         64000016
         MVC   ALIGN(4),2(GOREG)       GET PAGE NUMBER                  64200016
         PACK  DOUBLE+5(3),ALIGN       PUT IN PACKED FORMAT             64400016
         CVB   WK6,DOUBLE               CONVERT NUMBER TO BINARY        64600016
OKAY     STH   WK6,ISPAGE               MOVE PAGE NUMBER TO ISPAGE      64800016
         LA    WK6,1(0,WK6)             UPDATE PAGE NUMBER              65000016
         CVD   WK6,DOUBLE               CONVERT NUMBER TO DECIMAL       65200016
         UNPK  ALIGN(4),DOUBLE+5(3)     UNPACK THE PAGE NUMBER          65400016
         MVC   2(4,GOREG),ALIGN         RESTORE UPDATED PAGE NUMBER     65600016
         B     DA000                                                    65800016
*WHEN A PAGE NUMBER IS NOT PROVIDED BY THE CALLER ONE IS ASSUMED        66000016
OTHER    LA    WK6,1                    MOVE ASSUMED PAGE NUMBER        66200016
         STH   WK6,ISPAGE                                               66400016
         EJECT                                                          66600016
DA000    TIME                                                           66603016
         LR    PAREG0,PAREG1            PICK UP DATE                    66606016
         SRDL  PAREG0,16                SEPARATE YEARS AND DAYS         66609016
         SRL   PAREG1,16                DAYS PUT LOW ORDER              66612016
         LR    WK4,PAREG0               SAVE YEAR                       66615016
         SR    PAREG0,PAREG0            CLEAR REGISTER                  66618016
         LA    WK3,19                   TEST TO SEE IF YEAR(IN DECIMAL) 66621016
         NR    WK3,WK4                    IS DIVISABLE BY FOUR          66624016
         BZ    DA010                    NO--NOT DIVISABLE BY FOUR       66627016
         LA    CONS,18                                                  66630016
         XR    WK3,CONS                 IS THIS A LEAP YEAR ENDING IN   66633016
*                                          ZERO                         66636016
         BZ    DA010                                                    66639016
         LA    WK3,1                                                    66642016
*                                                                       66645016
DA010    STM   PAREG0,PAREG1,DOUBLE                                     66648016
         CVB   CONS,DOUBLE              CONVERT DAYS TO BINARY          66651016
         SR    PAREG1,PAREG1                                            66654016
         LR    WK5,PAREG1                                               66657016
*                                                                       66660016
DA020    LA    PAREG1,1(PAREG1)         INCREMENT MONTH                 66663016
         IC    WK5,XTMN-1(PAREG1)       DAYS IN MONTH                   66666016
         SR    CONS,WK5                 SUBTRACT FROM DAYS LEFT         66669016
         LA    WK6,3                    CONSTANT FOR 3RD MONTH          66672016
         CLR   WK6,PAREG1               IS THIS MARCH                   66675016
         BC    7,DA030                  NO                              66678016
         LTR   WK3,WK3                  YES, IS IT LEAP YEAR            66681016
         BC    2,DA030                  NO                              66684016
         BCTR  CONS,0                   YES, REDUCE DAYS BY ONE         66687016
*                                                                       66690016
DA030    LTR   CONS,CONS                ARE DAYS COUNTED DOWN TO ZERO   66693016
         BC    2,DA020                  NO, REPEAT LOOP                 66696016
         AR    CONS,WK5                 YES, RESTORE SUBTRACTED VALUE   66699016
         LTR   CONS,CONS                TEST FOR ZERO (FEBRUARY 29)     66702016
         BNZ   DA040                    NO                              66705016
         LA    CONS,29                  YES, SET DAY FOR 29TH           66708016
         BCTR  PAREG1,0                 DECREMENT TO FEBRUARY           66711016
*                                                                       66714016
DA040    LA    WK3,2                    LOOP COUNT                      66717016
DA050    CVD   PAREG1,DOUBLE            CHANGE MONTH TO DECIMAL         66720016
         L     WK5,DOUBLE+4             MONTH TO LOWER HALF             66723016
         SLL   WK5,20                                                   66726016
         SLDL  WK4,8                    SHIFT UP TO YEAR OR MONTH       66729016
         LR    PAREG1,CONS              DAY                             66732016
         BCT   WK3,DA050                REPEAT UNTIL DONE               66735016
         SLL   WK4,8                    POSITION DATE FOR STORING       66738016
         ST    WK4,DOUBLE         CONVERT FOR PRINTING                  66741016
         UNPK  QISAM(7),DOUBLE(4)                                       66744016
         MVC   TARGET(2),QISAM+2        MOVE IN MONTH OF YEAR           66747016
         MVI   TARGET+2,C'/'                                            66750016
         MVC   TARGET+3(2),QISAM+4      MOVE IN DAY OF MONTH            66753016
         MVI   TARGET+5,C'/'                                            66756016
         MVC   TARGET+6(2),QISAM        MOVE IN YEAR                    66759016
         EJECT                                                          66762016
*THIS SECTION PERFORMS THE NECESSARY STEPS FOR EXIT FROM THIS INITIA-   66800016
*LIZATION ROUTINE TO THE MODULE REQUIRED TO PERFORM THE OPERATION       67000016
*REQUESTED.                                                             67200016
ONWARD1  LR    PAREG1,WORKAREA          SAVE WORKAREA POINTER           67400016
         SR    WK6,WK6                  CLEAR XCTLAREA                  67600016
         ST    WK6,XCTLAREA+4                                           67800016
         LA    WK6,WHICH                                                68000016
         ST    WK6,XCTLAREA             SET UP FOR XCTL                 68200016
         L     SAVREG,4(0,SAVREG)       POP UP SAVE AREA                68400016
         L     RETREG,12(0,SAVREG)      RESTORE REGISTER FOURTEEN       68600016
         XCTL  (2,12),MF=(E,(1)),SF=(E,XCTLAREA)                        68800016
         SPACE 1                                                        69000016
ASSUMECY MVI   ISMESS+1,X'08'           SET MESSAGE NUMBER TO 8 TO      69200016
*                                          INDICATE INVALID PARAMETERS  69400016
          MVI   ISCOMP+1,X'10'           SET COMPLETION CODE TO 16      69600016
*                                          INDICATE INVALID PARAMETERS  69800016
         MVC   WHICH(8),MESSCON         MOVE IN SYMBOLIC ENTRY POINT    70000016
*                                          FOR XCTL                     70200016
         B     ONWARD                                                   70400016
         EJECT                                                          70600016
*                             CONSTANTS                                 70800016
         SPACE 3                                                        71000016
MOVENAME MVC   EXITADDR(0),0(WK5)       INSTRUCTION TO BE EXECUTED TO   71200016
*                                       MOVE IN NAME OF USER EXIT       71400016
*                                          MODULE                       71600016
*SYMBOLIC ENTRY POINT NAMES OF OPERATION MODULES                        71800016
MESSCON  DC    CL8'IEBISF   '           MESSAGE MODULE                  72000016
PRTPCON  DC    CL8'IEBISPP '            PRINT PHYSICAL MODULE           72200016
PRTLCON  DC    CL8'IEBISPL '            PRINT LOGICAL MODULE            72400016
LODCON   DC    CL8'IEBISL  '            LOAD MODULE                     72600016
UNLCON   DC    CL8'IEBISU  '            UNLOAD MODULE                   72800016
CPYCON   DC    CL8'IEBISC  '            COPY MODULE                     73000016
*                                                                       73200016
*CONSTANTS FOR COMPARE OF CONTROL PARAMETER FOR OPTION LIST             73400016
*                                                                       73600016
OPCOPY   DC    CL4'COPY'                COPY                            73800016
OPUNLD   DC    CL6'UNLOAD'              UNLOAD                          74000016
OPLOAD   DC    CL4'LOAD'                LOAD                            74200016
OPPRNT   DC    CL5'PRINT'               PRINT                           74400016
EXITCON  DC    CL5'EXIT='               EXIT KEYWORD                    74600016
*                                                                       74800016
*ASSUMED DDNAME CONSTANTS                                               75000016
*                                                                       75200016
PRINT    DC    CL8'SYSPRINT'                                            75400016
NAMEUT1  DC    CL8'SYSUT1  '                                            75600016
NAMEUT2  DC    CL8'SYSUT2  '                                            75800016
XTMN     DC    X'1F1C1F1E1F1E1F1F1E1F1E1F'   DAYS IN MONTH              75900016
         LTORG                                                          76000016
         EJECT                                                          76200016
IEBWORK  DSECT                                                          76400016
SAVE1    DS    1F                                                       76600016
SAVE1BK  DS    1F                                                       76800016
SAVE1FD  DS    1F                                                       77000016
         DS    15F                                                      77200016
SAVE2    DS    1F                                                       77400016
SAVE2BK  DS    1F                                                       77600016
SAVE2FD  DS    1F                                                       77800016
         DS    15F                                                      78000016
SAVE3    DS    1F                                                       78200016
SAVE3BK  DS    1F                                                       78400016
SAVE3FD  DS    1F                                                       78600016
         DS    15F                                                      78800016
ISINVOK  DS    F                        ADDRESS OF PARAMETER LIST AT    79000016
*                                          INVOCATION                   79200016
ISPRINT  DS    2F                       DDNAME FOR SYSPRINT             79400016
ISUT1    DS    2F                       DDNAME FOR SYSUT1               79600016
ISUT2    DS    2F                       DDNAME FOR SYSUT2               79800016
ISCOMP   DS    H                        COMPLETION CODE                 80000016
ISMESS   DS    H                        MESSAGE NUMBER                  80200016
ISPAGE   DS    H                        PAGE NUMBER FOR SYSPRINT        80400016
ISCNTRL  DS    CL1                      CONTROL BYTE                    80600016
* MASKS FOR TESTING CONTROL BYTE - ISCONTRL                             80800016
ISSWC    EQU   X'80'                    COPY                            81000016
ISSWU    EQU   X'40'                    UNLOAD                          81200016
ISSWL    EQU   X'20'                    LOAD                            81400016
ISSWP    EQU   X'10'                    PRINT                           81600016
ISSWN    EQU   X'08'                    NO CONVERT REQUESTED            81800016
ISSWPI   EQU   X'04'                    PRINT INDEX                     82000016
ISSWPP   EQU   X'02'                    PRINT PRIME                     82200016
ISSWPO   EQU   X'01'                    PRINT OVERFLOW                  82400016
ALLMASK  EQU   X'07'                                                    82600016
ISSWITCH DS    CL1                      EXTRANEOUS SWITCHES             82800016
FIRSTTM  EQU   X'80'                    FIRST TIME SWITCH               83000016
*                                                                       83200016
XCTLAREA DS    2F                                                       83400016
WHICH    DS    2F                                                       83600016
ALIGN    DS    1F                                                       83800016
DOUBLE   DS    1D                                                       84000016
EXITADDR DS    2F                                                       84200016
REENTAR  DS    9F                                                       84400016
DCBAR1   DS    64F                                                      84600016
DCBAR2   DS    64F                                                      84800016
MESSAGER DS    CL1                                                      85000016
MESSAGE  DS    CL120                                                    85200016
RECADDR  DS    1F                                                  000F 85300016
         DS    0D                                                       85350016
QISAM    DS    CL250                    UNLOADED DCB WORK AREA          85400016
HEADERC  DS    CL1                                                      85420016
HEADERT  DS    CL144                    HEADER AREA                     85440016
TARGET   DS    2F                       DATE HOLD AREA                  85460016
PAGENO   DS    1F                       HOLD PAGE NUMBER FOR HEADING    85480016
PAGEPTR  DS    1F                       HOLD POINTER TO WHERE PAGE      85500016
*                                          NUMBER IS TO BE PLACED       85520016
         EJECT                                                          85600016
*   MACRO DEFINITIONS                                                   85800016
         DCBD  DSORG=(PS,IS)                                            86000016
         END                                                            86200016
