 TITLE 'IEBISF-IEBISAM UTILITY PROGRAM - MESSAGE WRITER'                00500016
*STATUS & CHANGE LEVEL 0                                                01000016
*                                                                       01500016
*FUNCTION - THIS MODULE OPENS THE SYSPRINT DATA SET AND THE APPROPRIATE 02000016
*           MESSAGE WRITTEN,AND THE DATA SET CLOSED. THE APPROPRIATE    02500016
*           CONDITION CODE IS RETURNED.                                 03000016
*                                                                       03500016
*ENTRY POINTS- THE ONLY ENTRY POINT TO THIS MODULE IS IEBISF. ENTRY IS  04000016
*              MADE FROM ANY MODULE OF THE IEBISAM UTILITY PROGRAM      04500016
*                                                                       05000016
*INPUT - AT ENTRY TO THIS MODULE REGISTER 13 POINTS TO A REGISTER SAVE  05500016
*        AREA, REGISTER 14 CONTAINS THE FINAL RETURN ADDRESS, REGISTER  06000016
*        1 POINTS TO THE COMMON WORK AREA.                              06500016
*        THE WORK AREA CONTAINS-                                        07000016
*        ISINVOK - ADDRESS OF PARAMETER LIST FOR INVOCATION             07500016
*        ISPRINT - DDNAME FOR SYSPRINT DATA SET                         08000016
*        ISCOMP - COMPLETION CODE TO BE RETURNED                        08500016
*        ISMESS  - MESSAGE NUMBER OF MESSAGE TO BE WRITTEN              09000016
*        ISPAGE  - PAGE NUMBER TO BE USED FOR MESSAGE DATA SET          09500016
*        MESSAGE - IF ERROR WAS ENCOUNTERED DURING I/O THE INFORMATION  10000016
*                  RETURNED FROM SYNADAF WILL BE PRESENT.               10500016
*                                                                       11000016
*OUTPUT - A MESSAGE IS WRITTEN ON THE 'SYSPRINT' DATA SET.              11500016
*                                                                       12000016
*EXTERNAL ROUTINES - NONE                                               12500016
*                                                                       13000016
*EXITS - CONTROL IS RETURNED TO THE CALLER                              13500016
*                                                                       14000016
*CONDITION CODES -                                                      14500016
*                                                                       15000016
*        0     SUCCESSFUL COMPLETION                                    15500016
*                                                                       16000016
*        8     ERROR OTHER THAN ABSENCE OF SYSUT1 OR SYSUT2 DD CARD     16500016
*                                                                       17000016
*        16    ABSENCE OF SYSUT1 &/OR SYSUT2 DD CARD                    17500016
*                                                                       18000016
*A490100-490500,500000                                           A41745 18050021
*C577000                                                         A41801 18100021
*REGISTER USAGE                                                         18500016
PAREG0   EQU   0                        PARAMETER REGISTER              19000016
PAREG1   EQU   1                        PARAMETER REGISTER              19500016
CONS     EQU   2                        WORK REGISTER                   20000016
WK3      EQU   3                        WORK REGISTER                   20500016
WK4      EQU   4                        WORK REGISTER                   21000016
WK5      EQU   5                        WORK REGISTER                   21500016
BASEREG  EQU   10                       BASE REGISTER                   22000016
WORKAREA EQU   11                       WORK AREA REGISTER              22500016
SAVREG   EQU   13                       SAVE AREA REGISTER              23000016
RETREG   EQU   14                       RETURN AREA REGISTER            23500016
ADDR     EQU   15                       BASE ADDRESSABILITY/RETURN CODE 24000016
         EJECT                                                          24500016
IEBISF   CSECT                                                          25000016
         SAVE  (14,12),T                                                25500016
         LR    BASEREG,ADDR             ESTABLISH ADDRESSABILITY        26000016
         USING IEBISF,BASEREG                                           26500016
         LR    WORKAREA,PAREG1          ESTABLISH WORK AREA ADDRESSA-   27000016
*                                           BILITY                      27500016
         USING IEBWORK,WORKAREA                                         28000016
         LA    WK3,DCBAR1               SET UP ADDRESSABILITY TO DCB    28500016
         USING IHADCB,WK3                                               29000016
         EXTRN MESSTBL                                                  29500016
         ST    SAVREG,SAVE1BK           SET BACK CHAIN POINTER          30000016
         LR    SAVREG,WORKAREA          UPDATE TO NEW SAVE AREA         30500016
         LA    WK4,SAVE2                SET UP FORWARD CHAIN POINTER    31000016
         ST    WK4,SAVE1FD                 TO NEXT SAVE AREA            31500016
         MVC   DCBAR1(HEADER-DCBPRINT),DCBPRINT MOVE DCB TO WORK AREA   32000016
*                                       TO MAINTAIN REENTRABILITY       32500016
         MVC   DCBDDNAM(8),ISPRINT      MOVE IN DDNAME FOR SYSPRINT     33000016
         MVC   REENTAR(CLOSEL-OPENL),OPENL  MOVE OPEN L-FORM TO WORK    33500016
*                                          AREA TO MAINTAIN REENTRA-    34000016
*                                          BILITY                       34500016
         OPEN  (DCBAR1,(OUTPUT)),MF=(E,REENTAR)                         35000016
         TM    DCBOFLGS,X'10'           CHECK FOR SUCCESSFUL OPEN       35500016
         BZ    SETSWOT                  NO, SET CONDITION CODE          36000016
         CLI   EXITADDR,X'01'           CHECK FOR INVALID DCB PARAMETER 36100016
*                                       IN SYSPRINT DCB                 36200016
         BE    CLOSEOUT                 YES, TO TO CLOSE                36300016
* THIS SECTION SETS UP THE HEADER AND WRITES IT                         36500016
         MVI   HEADERC,X'F1'            SET TO SKIP TO NEXT PAGE        37000016
         MVC   HEADERT(120),HEADER      MOVE IN  HEADER                 37500016
         LH    WK5,ISPAGE               PICK UP PAGE NUMBER IN BINARY   38000016
         CVD   WK5,DOUBLE                  AND CONVERT TO DECIMAL       38500016
         UNPK  HEADERT+110(3),DOUBLE+6(2)                               38900016
         OI    HEADERT+112,X'F0'                                        39300016
         MVC   HEADERT+90(8),TARGET     MOVE IN DATE                    39700016
         PUT   DCBAR1,HEADERC                                           40100016
*THIS SECTION SETS UP MESSAGE                                           40500016
         LH    WK3,ISMESS               PICK UP MESSAGE NUMBER          41000016
*THIS SECTION MOVES THE MESSAGE NUMBER FOR I/O ERRORS INTO THE MESSAGE  41500016
*AREA. THE MESSAGE TEXT IS PROVIDED BY THE SYNADAF MACRO                42000016
         CH    WK3,=H'2'                CHECK FOR I/O ERROR MESSAGE     42500016
         BE    SPECIAL                  YES, PICK UP SPECIAL MESSAGE    43000016
*                                          NUMBER                       43500016
         SLL   WK3,2                    MULTIPLY BY 4                   44000016
         L     WK4,MESSTBLA             PICK UP BEGINNING ADDRESS OF    44500016
*                                          MESSAGE TABLE                45000016
         AR    WK3,WK4                  INDEX INTO TABLE                45500016
         L     WK3,0(0,WK3)             PICK UP MESSAGE ADDRESS         46000016
         MVC   MESSAGE(120),0(WK3)      MOVE IN MESSAGE                 46500016
PUTOUT   MVI   MESSAGER,X'40'           SET TO SKIP A LINE AND PRINT    47000016
         PUT   DCBAR1,MESSAGER                                          47500016
CLOSEOUT MVC   REENTAR(MESSTBLA-CLOSEL),CLOSEL  MOVE CLOSE TO WORK AREA 48000016
*                                          TO MAINTAIN REENTRABILITY    48500016
         CLOSE (DCBAR1,LEAVE),MF=(E,REENTAR)                            49000016
         CLI   ISCOMP+1,X'10'           WAS OPEN  CORRECT        A41745 49010021
         BE    BYPASS                   OPEN INCORRECT SO NO FRE A41745 49020021
         FREEPOOL  DCBAR1  FREE BUFFERS                          A41745 49050021
*SET UP TO RETURN CONTROL TO THE CALLER                                 49500016
BYPASS   L     SAVREG,4(SAVREG)         RESTORE SAVE AREA POINTERA41745 50000021
         L     WK3,ISINVOK              REESTABLISH POINTER TO PARA-    50500016
*                                          METERS FOR INVOCATION        51000016
         SR    WK4,WK4                  INSERT COMPLETION CODE          51500016
         IC    WK4,ISCOMP+1                                             52000016
         FREEMAIN R,LV=1536,A=(11)                                      52500016
         LR    PAREG1,WK3                                               53000016
         LR    ADDR,WK4                 PICK UP COMPLETION CODE         53100016
         L     RETREG,12(0,SAVREG)      RESTORE RETURN ADDRESS          53300016
         RETURN (2,12),T                                                53500016
SPECIAL  MVC   MESSAGE(8),IONUMBER      MOVE IN SPECIAL MESSAGE NUMBER  54000016
         MVC   MESSAGE+96(24),COMPCODE  MOVE COMPLETION CODE TO MESSAGE 54200016
         B     PUTOUT                                                   54500016
         EJECT                                                          55000016
*THIS SECTION IS THE SYNAD ROUTINE FOR THE SYSPRINT DATA SET            55500016
ERROR    MVI   ISCOMP+1,X'08'           SET COMPLETION CODE TO 8        56000016
         B     CLOSEOUT                                                 56500016
SETSWOT  MVI   ISCOMP+1,X'10'           SET COMPLETION CODE             57000016
         B     CLOSEOUT                                                 57500016
DCBEXIT  LA    WK3,DCBAR1               SET UP ADDRESSABILITYTO DCB     57520016
         MVI   EXITADDR,X'00'           SET SWITCH FOR SUCCESS          57530016
         OC    DCBBLKSI(2),DCBBLKSI     BLOCK SIZE SPECIFIED            57540016
         BZ    MOVELREC                 NO, NO BLOCKSIZE SPECIFIED      57560016
         SR    WK4,WK4                                                  57580016
         LH    WK5,DCBBLKSI             PICK UP PROVIDED BLOCKSIZE      57600016
         LH    CONS,DCBLRECL            PICK UP LRECL                   57620016
         DR    WK4,CONS                                                 57640016
         LTR   WK4,WK4                  CHECK FOR BLOCKSIZE NOT A       57660016
*                                          MULTIPLE OF LRECL            57680016
         BNE   MOVELREC      ERROR, SET DEFAULT                  A41801 57700021
         RETURN                                                         57720016
MOVELREC MVC   DCBBLKSI(2),DCBLRECL     USE DCB LRECL FOR BLOCK SIZE    57740016
         RETURN                                                         57760016
SETCODE  MVI   ISMESS+1,X'01'           SET UP MESSAGE CODE             57780016
         MVI   ISCOMP+1,X'08'           SET UP COMPLETION CODE          57800016
         MVI   EXITADDR,X'01'           SET FOR CHECK AFTER OPEN        57810016
         RETURN                                                         57820016
OPENL    OPEN  (,OUTPUT),MF=L                                           58000016
CLOSEL   CLOSE (,LEAVE),MF=L                                            58500016
MESSTBLA DC    A(MESSTBL)                                               59000016
DCBPRINT DCB   DSORG=PS,MACRF=(PM),DDNAME=SYSPRINT,RECFM=FBA,LRECL=121,*59300016
               SYNAD=ERROR,EXLST=DCBEX                                  59600016
DCBEX    DS    0F                                                       59900016
         DC    X'85'                                                    60200016
         DC    AL3(DCBEXIT)                                             60500016
HEADER   DC    CL32'     DATA SET UTILITY - IEBISAM '                   61000016
         DC    CL32'                                '                   61500016
         DC    CL32'                                '                   62000016
         DC    CL24'                        '                           62500016
IONUMBER DC    CL8'IEB602I'                                             63000016
COMPCODE DC    CL24'COMPLETION CODE=08      '                           63200016
         LTORG                                                          63500016
         EJECT                                                          64000016
IEBWORK  DSECT                                                          64500016
SAVE1    DS    1F                                                       65000016
SAVE1BK  DS    1F                                                       65500016
SAVE1FD  DS    1F                                                       66000016
         DS    15F                                                      66500016
SAVE2    DS    1F                                                       67000016
SAVE2BK  DS    1F                                                       67500016
SAVE2FD  DS    1F                                                       68000016
         DS    15F                                                      68500016
SAVE3    DS    1F                                                       69000016
SAVE3BK  DS    1F                                                       69500016
SAVE3FD  DS    1F                                                       70000016
         DS    15F                                                      70500016
ISINVOK  DS    F                        ADDRESS OF PARAMETER LIST AT    71000016
*                                          INVOCATION                   71500016
ISPRINT  DS    2F                       DDNAME FOR SYSPRINT             72000016
ISUT1    DS    2F                       DDNAME FOR SYSUT1               72500016
ISUT2    DS    2F                       DDNAME FOR SYSUT2               73000016
ISCOMP   DS    H                        COMPLETION CODE                 73500016
ISMESS   DS    H                        MESSAGE NUMBER                  74000016
ISPAGE   DS    H                        PAGE NUMBER FOR SYSPRINT        74500016
ISCNTRL  DS    CL1                      CONTROL BYTE                    75000016
* MASKS FOR TESTING CONTROL BYTE - ISCONTRL                             75500016
ISSWC    EQU   X'80'                    COPY                            76000016
ISSWU    EQU   X'40'                    UNLOAD                          76500016
ISSWL    EQU   X'20'                    LOAD                            77000016
ISSWP    EQU   X'10'                    PRINT                           77500016
ISSWN    EQU   X'08'                    NO CONVERT REQUESTED            78000016
ISSWPI   EQU   X'04'                    PRINT INDEX                     78500016
ISSWPP   EQU   X'02'                    PRINT PRIME                     79000016
ISSWPO   EQU   X'01'                    PRINT OVERFLOW                  79500016
ALLMASK  EQU   X'07'                                                    80000016
ISSWITCH DS    CL1                      EXTRANEOUS SWITCHES             80500016
FIRSTTM  EQU   X'80'                    FIRST TIME SWITCH               81000016
*                                                                       81500016
XCTLAREA DS    2F                                                       82000016
WHICH    DS    2F                                                       82500016
ALIGN    DS    1F                                                       83000016
DOUBLE   DS    1D                                                       83500016
EXITADDR DS    2F                                                       84000016
REENTAR  DS    9F                                                       84500016
DCBAR1   DS    64F                                                      85000016
DCBAR2   DS    64F                                                      85500016
MESSAGER DS    CL1                                                      86000016
MESSAGE  DS    CL120                                                    86500016
RECADDR  DS    1F                                                  000F 86700016
         DS    0D                                                       86800016
QISAM    DS    CL250                    UNLOADED DCB WORK AREA          87000016
HEADERC  DS    CL1                                                      87070016
HEADERT  DS    CL144                    HEADER AREA                     87140016
TARGET   DS    2F                       AREA  TO HOLD DATE              87210016
PAGENO   DS    1F                       HOLD PAGE NUMBER FOR HEADING    87280016
PAGEPTR  DS    1F                       HOLD POINTER TO WHERE PAGE      87350016
*                                          NUMBER IS TO BE PLACED       87420016
* MACRO DEFINITIONS                                                     87500016
         DCBD  DSORG=(PS)                                               88000016
         END                                                            88500016
