 TITLE 'IEBISPL - IEBISAM UTILITY PROGRAM - PRINT LOGICAL ROUTINE'      00200016
*STATUS AND CHANGE LEVEL 000                                            00400016
*FUNCTION/OPERATION-THIS MODULE PRINTS THE DATA RECORDS OF AN           00600016
*   INDEXED SEQUENTIAL DATA SET USING THE QUEUED INDEX SEQUENTIAL       00800016
*   ACCESS METHOD TO READ THE RECORDS AND THE QUEUED SEQUENTIAL ACCESS  01000016
*   METHOD TO WRITE THE RECORDS. THE RECORDS ARE RETRIEVED IN LOGICAL   01200016
*   SEQUENCE FROM THE PRIME AND OVERFLOW AREAS                          01400016
*                                                                       01600016
*                                                                       01800016
*                                                                       02000016
*                                                                       02200016
*                                                                       02400016
*                                                                       02600016
*                                                                       02800016
*ENTRY POINTS - IEBISPL - TO OPEN THE INPUT AND THE PRINT DATA SETS,    03000016
*   TO GET THE ISAM RECORDS, BUFFER THEM, PASS CONTROL TO A USER'S EXIT 03200016
*   PRINT THE RECORDS, CLOSE THE DATA SETS AND GIVE CONTROL TO IEBISF.  03400016
*                                                                       03600016
*INPUT - COMMON WORK AREA SET UP                                        03800016
*                                                                       04000016
*        ISINVOK  - ADDRESS OF PARM LIST FOR INVOCATION                 04200016
*        ISPRINT  - DDNAME FOR PRINT DATA SET                           04400016
*        ISUT1    - DDNAME FOR INPUT                                    04600016
*        ISUT2    - DDNAME FOR OUTPUT                                   04800016
*        ISPAGE   - PAGE NUMBER TO BE USED                              05000016
*        ISCNTRL  - ISSWD                                               05200016
*                   OPTIONALLY - ISSWN                                  05400016
*WORK AREA SET UP                                                       05600016
*   REGISTER 13 CONTAINS THE ADDRESS OF THE CALLING PROGRAM'S SAVE AREA 05800016
*   REGISTER 14 CONTAINS THE RETURN ADDRESS, AND REGISTER 15 CONTAINS   06000016
*   THE ADDRESS OF THIS MODULE FOR EVERY ENTRY TO THIS MODULE.          06200016
*                                                                       06400016
*OUTPUT- LOGICAL PRINT OUT OF AN INDEXED SEQUENTIAL DATA SET,MESSAGE    06600016
*   NUMBER/COMPLETION CODE                                              06800016
*                                                                       07000016
*        ISINVOK  - ADDRESS OF PARM LIST FOR INVOCATION                 07200016
*        ISPRINT  - DDNAME FOR SYSPRINT                                 07400016
*        ISUT1    - DDNAME FOR INPUT                                    07600016
*        ISUT2    - DDNAME FOR OUTPUT                                   07800016
*        ISCOMP   - COMPLETION CODE TO BE RETURNED                      08000016
*        ISMESS   - MESSAGE NUMBER OF MESSAGE TO BE PRINTED             08200016
*        ISPAGE   - PAGE NUMBER TO BE USED                              08400016
*        XCTLAREA & WHICH - SET UP FOR XCTL TO IEBISF                   08600016
*                                                                       08800016
*                                                                       09000016
*EXTERNAL ROUTINES - NONE                                               09200016
*                                                                       09400016
*EXITS- NORMAL - IEBISF - AFTER THE DATA SET HAS BEEN PRINTED           09600016
*     - ERROR  - IEBISF - WHENEVER ANY ERROR CONDITION IS ENCOUNTERED   09800016
*   WITH A MESSAGE NUMBER AND/OR A COMPLETION CODE.                     10000016
*                                                                       10200016
*ATTRIBUTES - REENTRANT                                                 10400016
*                                                                       10600016
*TABLES/WORKAREAS                                                       10800016
*                                                                       11000016
*REGISTER ASSIGNMENTS                                                   11200016
*                                                                       11400016
PAREG0   EQU   0                        PARMETER REGISTER               11600016
PAREG1   EQU   1                        PARAMETER REGISTER              11800016
CONS     EQU   2                                                        12000016
WK3      EQU   3                        WORK REGISTER                   12200016
WK4      EQU   4                        WORK REGISTER                   12400016
WK5      EQU   5                        WORK REGISTER                   12600016
WK6      EQU   6                        WORK REGISTER                   12800016
OPREG    EQU   7                        POINTER REGISTER                13000016
IRETREG  EQU   8                        INTERNAL RETURN REGISTER        13200016
GOREG    EQU   9                        POINTER REGISTER                13400016
BASEREG  EQU   10                       BASE REGISTER                   13600016
WORKAREA EQU   11                       WORK AREA REGISTER              13800016
PTREG    EQU   12                                                       14000016
SAVREG   EQU   13                       SAVE AREA REGISTER              14200016
RETREG   EQU   14                       RETURN AREA REGISTER            14400016
ADDR     EQU   15                       BASS ADDRESSABILITY/RETURN CODE 14600016
         EJECT                                                          14800016
IEBISPL  CSECT                                                          15000016
*1770272100-272800                                                 IV0I 15100018
*A417700,417800                                                  A41745 15150021
*A215620-215660,406100,406500,411500,470000-470500,472000,       A41801 15170021
*A474000-475500,478100-478400,490500,634804-634848,634850-634870 A41801 15180021
*A634520-634560                                                  A41801 15182021
*D468000,470000,472000,474000,634850                             A41801 15190021
*STANDARD LINKAGE CONVENTION                                            15200016
         SAVE  (14,12),T,ISPL-67-V1     SAVE CALLING PROGRAMS REGISTERS 15400016
         USING IEBISPL,BASEREG          ESTABLISH ADDRESSABILITY        15600016
         LR    BASEREG,ADDR                                             15800016
         LR    WORKAREA,PAREG1          PICK UP WORK AREA POINTER       16000016
         USING IEBWORK,WORKAREA                                         16200016
         ST    SAVREG,SAVE1BK           SET BACK CHAIN POINTER          16400016
         LR    SAVREG,WORKAREA          UPDATE TO NEW SAVE AREA         16600016
         LA    WK4,SAVE2                SET UP FORWARD CHAIN POINTER    16800016
         ST    WK4,SAVE1FD                 TO NEXT SAVE AREA            17000016
         LA    GOREG,DCBAR1             POINT TO INPUT DCB              17200016
         LA    PTREG,DCBAR2             POINT TO OUTPUT DCB             17400016
         USING IHADCB,GOREG                                             17600016
*THIS SECTION MOVES THE DCB'S AND THE OPENL FORMS TO THE WORK AREA TO   17800016
*MAINTAIN REENTRABILITY                                                 18000016
         MVC   DCBAR1(DCBOUT-DCBIN),DCBIN                               18200016
         MVC   DCBAR2(OPENINL-DCBOUT),DCBOUT                            18400016
         MVC   DCBDDNAM(8),ISUT1        MOVE INTO DCB THE OUTPUT DDNAME 18600016
         DROP  GOREG                                                    18800016
         USING IHADCB,PTREG                                             19000016
         MVC   DCBDDNAM(8),ISUT2        MOVE INTO DCB THE OUTPUT DDNAME 19200016
         MVC   REENTAR(CLOSEL-OPENINL),OPENINL  MOVE L FORM OF OPEN TO  19400016
*                                          WORK AREA                    19600016
         OPEN  (DCBAR1,(INPUT),DCBAR2,(OUTPUT)),MF=(E,REENTAR)          19800016
         TM    DCBOFLGS,X'10'           WAS OPEN SUCCESSFUL FOR OUTPUT  20000016
         BZ    SETSW                    NO, SET FOR ERROR EXIT          20200016
         LH    WK6,DCBLRECL             PICK UP OUTPUT RECORD LENGTH    20400016
         DROP  PTREG                                                    20600016
         USING IHADCB,GOREG                                             20800016
         TM    DCBOFLGS,X'10'           WAS OPEN SUCCESSFUL FOR INPUT   21000016
         BZ    SETSW                    NO, SET FOR ERROR EXIT          21200016
         TM    ISCOMP+1,X'FF'           CHECK FOR INVALID DCB           21260016
         BC    4,CLOSEOUT               INVALID DCB, CLOSE AND QUIT     21320016
         TM    DCBRECFM,X'01'           CHECK FOR BLOCKED RECORDS       21330016
         BC    1,LOADL                  YES, BLOCKED RECORDS            21340016
         OC    DCBRKP(2),DCBRKP         CHECK FOR RKP=0                 21350016
         BZ    LOADL                    YES, RKP=0                      21360016
         SETL  DCBAR1,BD                SET FOR RETRIEVING DATA PORTION 21370016
LOADL    LH    WK4,DCBLRECL             PICK UP LOGICAL RECORD LENGTH   21380016
         CLC   DCBRKP(2),=H'00'         CHECK FOR RELATIVE KEY          21408016
*                                           POSITION OF ZERO            21416016
          BNE   SETSKIP                  NO,NOT ZERO                    21424016
          SR    WK5,WK5                                                 21432016
         TM    DCBRECFM,X'10'           CHECK FOR BLOCKED RECORDS       21434016
         BC    1,SETSKIP                YES,BLOCKED REOCRDS             21436016
          IC    WK5,DCBKEYLE             PICK UP KEYLENGTH              21440016
          AR    WK4,WK5                  ADD TO PROVIDED LRECL          21448016
SETSKIP   MVI   HEADERC,X'F1'            SET FOR SKIP TO NEW PAGE       21456016
         MVI   HEADERT,C' '             SET HEADER TO BLANKS            21464016
         MVC   HEADERT+1(143),HEADERT                                   21472016
         SR    CONS,CONS                                                21480016
         CH    WK6,=H'11'               CHECK FOR OUTPUT TO BE LESS     21488016
*                                          THAN 11 BYTES                21496016
         BL    SETNONE                  YES, LESS THAN 11 - NO HEADING  21504016
         CH    WK6,=H'80'               CHECK FOR OUTPUT TO BE LESS     21512016
*                                          THAN 80 BYTES                21520016
         BNL   PUTINALL                 NO, NOT LESS THAN EIGHTY        21528016
PAGEINST LR    WK5,WK6                  PICK UP SPECIFIED OUTPUT LENGTH 21536016
         SH    WK5,=H'10'               BACK UP 10 BYTES FROM END OF    21544016
*                                          OUTPUT TO PUT OUT PAGE       21552016
*                                          NUMBER                       21560016
         CH    WK5,=H'135'         LRECL LESS THAN 145 ?         A41801 21562000
         BNH   NORMPROC             YES, CONT NORM. PROCC.       A41801 21564000
         LA    WK5,135              NO, SET PAGE NBR 135 FURTH   A41801 21566000
NORMPROC LA    WK3,HEADERT              PICK UP HEADER ADDRESS   A41801 21568000
         AR    WK3,WK5                  CALCULATE ADDRESS WHERE PAGE    21576016
*                                          NUMBER IS TO BEGIN           21584016
         MVC   0(4,WK3),PAGE            MOVE IN 'PAGE'                  21592016
         LA    WK3,5(0,WK3)             UPDATE POINTER                  21600016
         ST    WK3,PAGEPTR              SAVE POINTER TO PAGE NUMBER     21608016
         ST    CONS,PAGENO              INITIALIZE PAGE NUMBER          21616016
         B     CHEKEXIT                                                 21624016
SETNONE  ST    CONS,PAGEPTR             SET PAGE POINTER TO ZERO TO     21632016
*                                          INDICATE NO HEADING IS TO BE 21640016
*                                          PRINTED                      21648016
         B     CHEKEXIT                                                 21656016
PUTINALL MVC   HEADERT+2(7),PROGNAME    MOVE IN PROGRAM NAME            21664016
         MVC   HEADERT+58(8),TARGET     MOVE IN MONTH OF YEAR           21672016
         MVC   REENTAR(MOVEDATA-READJL),READJL   FOR REENTRABILITY      21680016
         LA    WK3,RECADDR              PICK UP DCB EXIT ADDRESS        21688016
         ST    WK3,QISAM                                                21696016
         MVC   DCBEXLST+1(3),QISAM+1                                    21704016
         LA    WK3,QISAM                POINT TO AREA TO BE USED        21712016
         ST    WK3,RECADDR              SET UP EXIT LIST                21720016
         MVI   RECADDR,X'87'            SET FOR LAST EXIT               21728016
         RDJFCB (DCBAR1),MF=(E,REENTAR)                                 21736016
         XC    DCBEXLST+1(3),DCBEXLST+1                                 21744016
         MVC   HEADERT+12(44),QISAM     MOVE IN DSNAME                  21752016
         B     PAGEINST                                                 21760016
CHEKEXIT CLI   EXITADDR,C' '            CHECK FOR A USER EXIT           21768016
         BE    DOGET                    NO, GO AROUND LOAD              21800016
         LOAD  EPLOC=EXITADDR                                           22000016
         ST    PAREG0,ALIGN             SAVE USER'S ROUTINE ADDRESS     22200016
DOGET    BCTR  WK6,0                    REDUCE LENGTH OF OUTPUT RECORD  22600016
*                                          BY ONE TO ACCOUNT FOR THE    22800016
*                                          ASA BYTE                     23000016
         SPACE 3                                                        23600016
         GETMAIN R,LV=(4)               GET BUFFER AREA FOR LOGICAL     23800016
*                                          RECORD OF INPUT DATA SET     24000016
         ST    WK4,XCTLAREA+4           SAVE GOTTEN CORE LENGTH         24100016
         LR    CONS,PAREG1              PICK UP ADDRESS OF BUFFER       24200016
         LR    IRETREG,CONS                                             24400016
         PUT   DCBAR2                   GET BUFFER ADDRESS              24600016
         LR    PTREG,PAREG1        MOVE BUFFER ADDRESS FOR THE GET      24800016
         XC    REENTAR(4),REENTAR       CLEAR RECORD # HOLD AREA        25000016
         BAL   RETREG,PRTHDR            GO TO PRINT HEADER              25100016
GETNEXT  GET   DCBAR1,(2)               GET ISAM RECORD AND MOVE TO     25200016
*                                          WORK AREA                    25400016
GOTO     L     WK5,REENTAR                                              25720016
         A     WK5,=F'1'                UPDATE RECORD NUMBER            25800016
         ST    WK5,REENTAR              SAVE NEW RECORD NUMBER          26000016
         CVD   WK5,DOUBLE                                               26200016
         MVI   0(PTREG),C' '            BLANK PRINT FIELD               26400016
         BCTR  WK6,0                                                    26600016
         EX    WK6,MOVEBLNK                                             26800016
         LA    WK6,1(0,WK6)                                             27000016
         DROP  GOREG                                                    27030016
         LA    WK3,DCBAR1               PICK UP INPUT DCB ADDR          27070016
         USING IHADCB,WK3                                               27140016
         TM    DCBRECFM,X'40'          TEST FOR V-TYPE RECORD      IV0I 27160018
         BZ    FIXRECFM                NO-FIXED RECFM-BRANCH       IV0I 27180018
         LH    WK4,0(CONS)             RECFM=V-GET LENGTH OF THIS  IV0I 27200018
*                                      RECORD FROM DESCRIPTOR WORD IV0I 27220018
         B     FIXAVAR                 CONTINUE                    IV0I 27240018
FIXRECFM LH    WK4,DCBLRECL            RECFM=F - GET LENGTH OF     IV0I 27260018
*                                      OF THIS RECORD FROM THE DCB IV0I 27280018
FIXAVAR  CLC   DCBRKP(2),=H'00'        CHECK FOR RELATIVE KEY      IV0I 27300018
*                                        POSITION OF ZERO               27350016
         BNE   TESTEXIT                 NO, NOT ZERO                    27420016
         TM    DCBRECFM,X'10'           CHECK FOR BLOCKED RECORDS       27440016
         BC    1,TESTEXIT               YES,BLOCKED REOCRDS             27460016
         SR    WK5,WK5                                                  27490016
          IC    WK5,DCBKEYLE             PICK UP KEYLENGTH              27560016
          AR    WK4,WK5                  ADD TO PROVIDED LRECL          27630016
         DROP  WK3                                                      27700016
TESTEXIT CLI   EXITADDR,C' '            CHECK FOR USER EXIT             27800016
         BNE   SETUPEX                  YES SET UP FOR EXIT             28000016
RETEXIT  CLI   LENSW,X'FF'             LRECL LESS THAN 18        A36104 28200021
         BE    MOVEHEAD                YES,BYPASS PRINT REC #    A36104 28250021
         UNPK  13(5,PTREG),DOUBLE+4(4)  CONVERT 5 DIGITS FOR PRINT36104 28300021
         OI    17(PTREG),X'F0'                                          28600016
         MVI   0(PTREG),X'40'           SET FOR A SKIP OF ONE LINE      28800016
         MVC   6(6,PTREG),RECORD        MOVE IN HEADING TEXT            29500016
         PUT   DCBAR2                                                   30200016
         LR    PTREG,PAREG1             SAVE BUFFER POINTER             30400016
         BCTR  GOREG,0                  REDUCE LINE COUNT               30460016
         LTR   GOREG,GOREG              CHECK FOR NEW PAGE              30520016
         BC    7,MOVEHEAD               NO, NO NEW PAGE                 30580016
         BAL   RETREG,PRTHDR            GO TO PRINT HEADER              30640016
MOVEHEAD TM    ISCNTRL,ISSWN            CHECK FOR NO CONVERT            30700016
         BC    1,MOREDATA              NO,PICK UP REGULAR LENGTHS       30800016
         SLL   WK4,1                   DOUBLE NUMBER OF INPUT           31000016
*                                         CHARACTERS                    31200016
MOREDATA CR    WK4,WK6                  WHICH LOGICAL RECORD LENGTH     31400016
*                                          GREATER                      31600016
         BH    USEPRT                   PRINT LENGTH LESS               31800016
         MVI   0(PTREG),C' '       BLANK PRINT FIELD                    32000016
          BCTR WK6,0                                                    32200016
         EX    WK6,MOVEBLNK                                             32400016
          LA    WK6,1(0,WK6)                                            32600016
         LR    OPREG,WK4                USE LENGTH FROM INPUT SIDE      32800016
         SR    WK4,WK6                  SET LENGTH TO ZERO OR NEGATIVE  33000016
         B     TESTCVRT                                                 33200016
USEPRT   LR    OPREG,WK6                USE LENGTH FROM OUTPUT SIDE     33400016
         SR    WK4,WK6                  REDUCE LENGTH OF INPUT LEFT     33600016
TESTCVRT TM    ISCNTRL,ISSWN            CHECK FOR NO CONVERT            33800016
         BC    8,CONVERT                YES GO TO CONVERT               34000016
          BCTR OPREG,0                                                  34100016
          EX    OPREG,MOVEDATA           MOVE IN DATA                   34200016
          LA    OPREG,1(0,OPREG)                                        34300016
         AR    IRETREG,OPREG            UPDATE POINTER TO BUFFER        34400016
PRINTLIN MVI   0(PTREG),X'40'           SET TO PRINT ONE LINE           35800016
NEXTLINE PUT   DCBAR2                   PUT OUT RECORD AND GET NEXT     36000016
*                                          BUFFER ADDRESS               36200016
         LR    PTREG,PAREG1        MOVE BUFFER ADDRESS FOR THE GET      36400016
         BCTR  GOREG,0                  REDUCE LINE COUNT               36500016
         LTR   GOREG,GOREG              CHECK FOR NEW PAGE              36600016
         BC    7,CHEKNEXT               NO, NO NEW PAGE                 36700016
         BAL   RETREG,PRTHDR            PRINT NEW PAGE HEADING          36800016
CHEKNEXT LTR   WK4,WK4                  CHECK FOR ALL DATA MOVED        37000016
         BC    2,MOREDATA               NO, MOVE MORE DATA              37100016
         CLI   ISMESS+1,X'05'           CHECK FOR CLOSE REQUESTED       37260016
         BE    EODADIN                  YES, GO TO CLOSE                37320016
         LR    IRETREG,CONS             RESET BUFFER POINTER            37400016
         B     GETNEXT                                                  37600016
SETUPEX  L     ADDR,ALIGN               PICK UP USER ROUTINE ADDRESS    37800016
         LR    PAREG1,CONS              PASS POINTER TO INPUT BUFFER    38000016
         LR    PAREG0,PTREG             PASS POINTER TO HEADER          38200016
         BALR  RETREG,ADDR              PASS CONTROL TO USER'S ROUTINE  38400016
         LR    CONS,PAREG1              RESTORE BUFFER POINTERS         38600016
         C     ADDR,=F'0'                CHECK FOR ZERO RETURN CODE     38700016
         BE    RETEXIT                   PRINT THIS ONE                 38800016
         C     ADDR,=F'4'                CHECK FOR RETURN CODE 4        38900016
         BE    SETOFF                    PRINT THIS ONE AND CLOSE       39000016
         C     ADDR,=F'8'               CHECK FOR RETURN CODE 8         39100016
         BE    GETNEXT                  DON'T PRINT THIS ONE            39200016
         C     ADDR,=F'12'              CHECK FOR RETURN CODE 12        39300016
         BE    SETOFFA                  DON'T PRINT THIS ONE AND CLOSE  39400016
ILLEGAL   MVI   ISMESS+1,X'06'           SET MESSAGE NUMBER TO 6        40200016
         MVI   ISCOMP+1,X'0C'           SET CONDITION CODE              40400016
EODADIN  MVI   0(PTREG),C' '       MOVE BLANK IN FOR PROPOGATION        40600016
         BCTR   WK6,0              SUBTR. ONE FOR EX STATM.      A41801 40610021
         CLI   LENSW,X'00'         LRECL GREATER THAN 18 ?       A41801 40650021
         BE    NORMALMS                YES,GIVE NORMAL MESSAGE   A36104 40850021
         EX    WK6,MOVEBLNK            BLANK OUT BUFFER          A36104 40860021
         MVC   1(3,PTREG),ENDOUT+3      ONLY 'END' AS MSG        A36104 40870021
         B    BRANCHSW                 GO TO CLOSE RTN           A36104 40880021
NORMALMS EX    WK6,MOVEBLNK            BLANK OUT BUFFER          A36104 40890021
         MVC   1(16,PTREG),ENDOUT       MOVE IN MESSAGE                 40900016
BRANCHSW MVC   REENTAR(READJL-CLOSEL),CLOSEL                            41100016
         LA    WK6,1(WK6)          RESET CORRECT LRECL-1         A41801 41150021
*                                          MAINTAIN REENTRABILITY       41400016
CLOSEOUT CLOSE (DCBAR1,,DCBAR2,LEAVE),MF=(E,REENTAR)                    41600016
         CLI   ISMESS+1,X'07'           CHECK FOR MISSING DD            41660016
         BE    COMEBCK                  YES, BYPASS FREEMAIN            41720016
         CLI   ISMESS+1,X'01'           CHECK FOR DCB ERROR             41740016
         BE    COMEBCK                  YES,A DCB ERROR                 41760016
         FREEPOOL DCBAR1                FREEPOOL INPUT BUFFER    A41745 41770021
         FREEPOOL DCBAR2                FREEPOOL OUTPUT BUFFER   A41745 41780021
*                                                                       41800016
         L     PAREG0,XCTLAREA+4        PICK UP LENGTH FOR FREEMAIN     42000016
         LR    PAREG1,CONS              SET UP POINTER TO AREA          42200016
         FREEMAIN R,LV=(0),A=(1)                                        42400016
*                                                                       42600016
         CLI   EXITADDR,C' '            CHECK FOR USER EXIT             42650016
         BE    COMEBCK                  NO, NO USER EXIT                42700016
         DELETE EPLOC=EXITADDR                                          42750016
COMEBCK  SR    WK6,WK6                  SET UP XCTL AREA                42800016
         ST    WK6,XCTLAREA+4                                           43000016
         MVI   WHICH+6,C' '                                             43200016
         MVI   WHICH+5,C'F'             MOVE INTO XCTLAREA NAME OF NEXT 43400016
*                                          MODULE-IEBISF                43600016
         LR    PAREG1,WORKAREA          SAVE WORKAREA POINTER           43800016
         L     SAVREG,4(0,SAVREG)       POP UP SAVE AREA                44000016
         L     RETREG,12(0,SAVREG)      RESTORE REGISTER FOURTEEN       44200016
         XCTL  (2,12),MF=(E,(1)),SF=(E,XCTLAREA)                        44400016
*THIS SECTION CHECKS FOR THE LRECL BEING 121,133,145 AND THE BLKSIZE    44600016
*BEING A MULTIPLE OF THE LRECL                                          44800016
DCBEXIT  SR    WK4,WK4                                                  45000016
         USING IHADCB,PTREG                                             45200016
         LA    PTREG,DCBAR2                                             45400016
CHECKLR  OC    DCBLRECL(2),DCBLRECL     CHECK FOR  RECORD SIZE   A41801 46400021
         BZ    CHECKBLK                 NO  RECORD SIZE PROVIDED A41801 46600021
         OC    DCBBLKSI(2),DCBBLKSI     CHECK FOR  BLOCK SIZE    A41801 47000021
         BNZ   CHECK121                 BLOCK SIZE PROVIDED      A41801 47010021
         MVC   DCBBLKSI(2),DCBLRECL     SET UP BLOCKSIZE         A41801 47020021
         B     CHECK121             CHECK FOR VALID LRECL/BLKSI  A41801 47030021
CHECKBLK OC    DCBBLKSI(2),DCBBLKSI     CHECK FOR  BLOCK SIZE    A41801 47050021
         BZ    SETDFLT                  NO  BLOCK SIZE PROVIDED  A41801 47200021
         MVC   DCBLRECL(2),DCBBLKSI     SET UP LRECL             A41801 47400021
         B     CHECK121             CHECK FOR VALID LRECL/BLKSI  A41801 47450021
SETDFLT  MVI   DCBBLKSI+1,X'79'     TAKE DEF. VALUE OF 121       A41801 47500021
         MVI   DCBLRECL+1,X'79'     TAKE DEF. VALUE OF 121       A41801 47550021
CHECK121 LH    WK5,DCBBLKSI             PICK UP BLOCK SIZE              47600016
         LH    WK6,DCBLRECL             PICK UP LOGICAL RECORD LENGTH   47800016
         C     WK6,=F'255'         SPECIF LRECL GR. THAN 255 ?   A41801 47810021
         BH    DCBERR              YES, PRINT ERROR              A41801 47820021
         C     WK6,=F'04'          SPECIF LRECL SM. THAN 4   ?   A41801 47830021
         BL    DCBERR              YES, PRINT ERROR              A41801 47840021
         C     WK6,=F'18'              LRECL LESS THEN 18        A36104 47850021
         BNL   CHECK                   NO BRANCH                 A36104 47900021
         MVI   LENSW,X'FF'             SET SWITCH FOR SHORT MSG  A36104 47950021
CHECK    DR    WK4,WK6                  DIVIDE BLKSIZE BY LRECL         48000016
         LTR   WK4,WK4                  CHECK FOR NO REMAINDER          48200016
         BNE   DCBERR                   NO, GO SET FOR DCB ERROR        48400016
         RETURN                                                         48600016
DCBERR   MVI   ISMESS+1,X'01'          SET MESSAGE NUMBER TO 1          48800016
         MVI   ISCOMP+1,X'08'           SET COMPLETION CODE TO 8        49000016
         MVC   DCBBLKSI(2),DCBLRECL   TO PREVENT OPEN FROM ABEND A41801 49050021
         RETURN                                                         49200016
*THIS SECTION SETS THE MESSAGE NUMBER AND RETURN CODE TO INDICATE THAT  49400016
*A REQUIRED DD STATEMENT IS MISSING                                     49600016
SETSW    MVI   ISMESS+1,X'07'          SET MESSAGE NUMBER TO 7          49800016
         MVI   ISCOMP+1,X'10'           SET CONDITION CONDE             50000016
         B     BRANCHSW                                                 50900016
*THIS SYNAD ROUTINE USES THE SVC 68 AND ITS ASSOCIATED MACROS FOR       51800016
*DETERMINING THE ERROR CONDITION                                        52000016
SYNADIN  SYNADAF ACSMETH=QISAM,PARM1=DCBAR1,PARM2=(0)                   52200016
MOVEMESS MVC   MESSAGE+8(79),49(PAREG1) MOVE IN PRINTABLE DATA FROM     52400016
*                                          BUFFER FOR MESSAGE           52600016
         MVI   ISMESS+1,X'02'          SET FOR SYNAD ERROR MESSAGE      52800016
*                                         NUMBER =2                     53000016
         MVI   ISCOMP+1,X'08'          SET COMPLETION CODE TO 8         53200016
         SYNADRLS                                                       53400016
         B     EODADIN                                                  53600016
SYNADOUT SYNADAF ACSMETH=QSAM,PARM1=DCBAR2,PARM2=(0)                    53800016
         B     MOVEMESS                                                 54000016
*MARK THIS RECORD TO BE PRINTED AND THE DATA SET TO BE CLOSED           54200016
SETOFF   MVI   ISCOMP+1,X'04'           SET COMPLETION CODE TO 4        54400016
         MVI   ISMESS+1,X'05'          SET MESSAGE NUMBER TO 5          54600016
         B     RETEXIT                                                  54800016
SETOFFA  MVI   ISCOMP+1,X'04'           SET COMPLETION CODE TO 4        55000016
         MVI   ISMESS+1,X'05'     SET MESSAGE NUMBER TO FIVE            55200016
         B     EODADIN                                                  55400016
         EJECT                                                          55460016
*   CONVERSION ROUTINE                                                  55520016
CONVERT  LR    WK3,PTREG     SET UP BUFFER WORKING POINTER              55600016
         LA    WK3,1(0,WK3)                                             55800016
         LR    PAREG1,WK3               SET UP POINTER TO BUFFER END    56000016
*                               MINUS 12                                56200016
         AR    PAREG1,WK6    CALCULATE POINTER TO BUFFER END            56400016
         ST    GOREG,REENTAR+4                                          56800016
CHKN     C     OPREG,=F'1'              CHECK FOR ONE OR NONE LEFT      57100016
         BNH   BLANKOUT                                                 57400016
         UNPK  REENTAR+20(3),0(2,IRETREG)                               57700016
         TR    REENTAR+20(2),TABLE-240  CONVERT TWO BYTES               58000016
         MVC   0(2,WK3),REENTAR+20      MOVE TO OUT BUFFER              58300016
         S     OPREG,=F'2'              TWO LESS TO CONVERT             58600016
         LA    WK3,2(0,WK3)             UPDATE OUTPUT BUFFER POINTER    58900016
         LA    IRETREG,1(0,IRETREG)     UPDATE INPUT POINTER            59200016
         B     CHKN                     GO TO PICK UP MORE              59500016
BLANKOUT AR    WK4,OPREG                INCREMENT TO HANDLE THE ODD     59800016
*                                          BYTE                         60100016
CHECKEND CR    WK3,PAREG1               CHECK FOR END OF OUTPUT         60400016
         BNL   FIN1RECA                 YES, END OF OUTPUT              60700016
         MVI   0(WK3),C' '              BLANK REMAINING OUTPUT          61000016
         LA    WK3,1(0,WK3)             UPDATE OUTPUT POINTER           61300016
         B     CHECKEND                                                 61600016
FIN1RECA L     GOREG,REENTAR+4          RESET LINE COUNT                61900016
         B     PRINTLIN                                                 62600016
         EJECT                                                          63400016
PRTHDR   L     GOREG,PAGENO                                             63410016
         A     GOREG,=F'1'              UPDATE PAGE NUMBER              63420016
         ST    GOREG,PAGENO             SAVE UPDATED PAGE NUMBER        63425016
         CVD   GOREG,QISAM              CONVERT PAGE NUMBER FOR         63430016
         UNPK  QISAM+8(3),QISAM+6(2)       PRINTING                     63440016
         OI    QISAM+10,X'F0'                                           63450016
         LR    GOREG,WK6           SAVE LRECL-1 LENGTH           A41801 63452021
         CH    WK6,=H'10'          LRECL SMALLER THAN 11 ?       A41801 63454021
         BL    NORMOV              YES, PRINT NO PAGE AND P.NBR  A41801 63456021
         L     GOREG,PAGEPTR            PICK UP ADDRESS OF POSITION IN  63460016
*                                          HEADING FOR PGGE NUMBER      63470016
         MVC   0(3,GOREG),QISAM+8       MOVE IN PAGE NUMBER             63480016
         LR    GOREG,WK6           SAVE LRECL-1 LENGTH           A41801 63480421
         CH    WK6,=H'144'         LRECL LARGER THAN 145 ?       A41801 63482021
         BNH   NORMOV              NO, NORMAL MOVE               A41801 63484021
         BCTR  WK6,0               SUBTR. ONE FOR EX STATEM.     A41801 63484121
         EX    WK6,MOVEBLNK        YES, BLNK OUTP. BUFFER        A41801 63484421
         LA    WK6,144             SET MAXIM. HEADER LENGTH      A41801 63484821
NORMOV   EX    WK6,MOVEIN          MOVE IN HEADER                A41801 63485021
         LR    WK6,GOREG           RESTORE LRECL-1 VALUE         A41801 63487021
         LR    GOREG,RETREG             SAVE RETURN POINTER             63492016
         PUT   DCBAR2                   PUT OUT HEADER                  63500016
         LR    PTREG,PAREG1             SAVE BUFFER POINTER             63510016
         MVI   0(PTREG),X'40'           SET TO PRINT A LINE             63520016
         LR    RETREG,GOREG            RESTORE RETURN POINTER           63525016
         LA    GOREG,59                 SET NEW LINE COUNT              63530016
         BR    RETREG                                                   63535016
         EJECT                                                          63540016
SYSUT1   DC    CL8'SYSUT1  '                                            63600016
SYSUT2   DC    CL8'SYSUT2  '                                            63800016
INPUT    DC    CL8'INPUT   '                                            64000016
OUTPUT   DC    CL8'OUTPUT  '                                            64200016
RECORD   DC    CL6'RECORD'                                              64400016
PAGE     DC    CL4'PAGE'                                                64460016
PROGNAME DC    CL7'IEBISAM'                                             64520016
ENDOUT   DC    CL16'***END OF OUTPUT'                                   64560016
         DS    0F                                                       64600016
DCBEXITA DC    X'85'                    DCBEXIT LIST                    64800016
         DC    AL3(DCBEXIT)                                             65000016
DCBIN    DCB   DSORG=IS,MACRF=GM,DDNAME=SYSUT1,SYNAD=SYNADIN,          *65200016
               EODAD=EODADIN                                            65400016
DCBOUT   DCB   DSORG=PS,MACRF=PL,DDNAME=SYSUT2,SYNAD=SYNADOUT,         *65600016
               EXLST=DCBEXITA,RECFM=FBA                                 65800016
OPENINL  OPEN  (,(INPUT),,(OUTPUT)),MF=L                                66000016
CLOSEL   CLOSE (,,,LEAVE),MF=L                                          66200016
READJL   RDJFCB (,),MF=L                                                66300016
MOVEDATA MVC   1(0,PTREG),0(IRETREG)                                    66400016
MOVEBLNK MVC   1(0,PTREG),0(PTREG)                                      66600016
MVBLANKS MVC    1(1,WK3),0(WK3)                                         66800016
LENSW    DC    X'00'                                             A36104 66850021
TRANSLAT TR    1(1,PTREG),TABLE-240                                     67000016
MOVEIN   MVC   0(0,PTREG),HEADERC                                       67100016
TABLE    DC    C'0123456789ABCDEF'      TRANSLATE TABLE                 67200016
         LTORG                                                          67400016
         EJECT                                                          67600016
IEBWORK  DSECT                                                          67800016
SAVE1    DS    1F                                                       68000016
SAVE1BK  DS    1F                                                       68200016
SAVE1FD  DS    1F                                                       68400016
         DS    15F                                                      68600016
SAVE2    DS    1F                                                       68800016
SAVE2BK  DS    1F                                                       69000016
SAVE2FD  DS    1F                                                       69200016
         DS    15F                                                      69400016
SAVE3    DS    1F                                                       69600016
SAVE3BK  DS    1F                                                       69800016
SAVE3FD  DS    1F                                                       70000016
         DS    15F                                                      70200016
ISINVOK  DS    F                        ADDRESS OF PARAMETER LIST AT    70400016
*                                          INVOCATION                   70600016
ISPRINT  DS    2F                       DDNAME FOR SYSPRINT             70800016
ISUT1    DS    2F                       DDNAME FOR SYSUT1               71000016
ISUT2    DS    2F                       DDNAME FOR SYSUT2               71200016
ISCOMP   DS    H                        COMPLETION CODE                 71400016
ISMESS   DS    H                        MESSAGE NUMBER                  71600016
ISPAGE   DS    H                        PAGE NUMBER FOR SYSPRINT        71800016
ISCNTRL  DS    CL1                      CONTROL BYTE                    72000016
* MASKS FOR TESTING CONTROL BYTE - ISCONTRL                             72200016
ISSWC    EQU   X'80'                    COPY                            72400016
ISSWU    EQU   X'40'                    UNLOAD                          72600016
ISSWL    EQU   X'20'                    LOAD                            72800016
ISSWP    EQU   X'10'                    PRINT                           73000016
ISSWN    EQU   X'08'                    NO CONVERT REQUESTED            73200016
ISSWPI   EQU   X'04'                    PRINT INDEX                     73400016
ISSWPP   EQU   X'02'                    PRINT PRIME                     73600016
ISSWPO   EQU   X'01'                    PRINT OVERFLOW                  73800016
ALLMASK  EQU   X'07'                                               000F 73900016
ISSWITCH DS    CL1                      EXTRANEOUS SWITCHES             74000016
FIRSTTM  EQU   X'80'                    FIRST TIME SWITCH               74200016
*                                                                       74400016
XCTLAREA DS    2F                                                       74600016
WHICH    DS    2F                                                       74800016
ALIGN    DS    1F                                                       75000016
DOUBLE   DS    1D                                                       75200016
EXITADDR DS    2F                                                       75400016
REENTAR  DS    9F                                                       75600016
DCBAR1   DS    64F                                                      75800016
DCBAR2   DS    64F                                                      76000016
MESSAGER DS    CL1                                                      76200016
MESSAGE  DS    CL120                                                    76400016
RECADDR  DS    1F                                                  000F 76500016
         DS    0D                                                       76550016
QISAM    DS    CL250                    UNLOADED DCB WORK AREA          76600016
HEADERC  DS    CL1                                                      76620016
HEADERT  DS    CL144                    HEADER AREA                     76640016
TARGET   DS    2F                       DATE HOLD AREA                  76660016
PAGENO   DS    1F                       HOLD PAGE NUMBER FOR HEADING    76680016
PAGEPTR  DS    1F                       HOLD POINTER TO WHERE PAGE      76700016
*                                          NUMBER IS TO BE PLACED       76720016
         DCBD  DSORG=(PS,IS)                                            76800016
         END                                                            77000016
