 TITLE 'IEBISU-IEBISAM UTILITY PROGRAM-UNLOAD ROUTINE'                  00300016
*STATUS: CHANGE LEVEL 000                                             * 00600016
*FUNCTION/OPERATION: THIS MODULE RETRIEVES LOGICAL RECORDS OF AN IN-  * 00900016
*   DEXED SEQUENTIAL DATASET AND PASSES THE LENGTH OF DATA RECORD AND * 01200016
*   THE ADDRESS OF THE RECORD TO IEHISSO.                             * 01500016
*ENTRY POINTS                                                         * 01800016
*   IEBISU-TO RETRIEVE A LOGICAL RICORD FROM AN ISAM DATASET          * 02100016
*   DATA IS PASSED BY LOCATION                                        * 02400016
*INPUT: ADDRESS OF IEHISR COMMON WORKAREA.                            * 02700016
*   FIELDS NEED:                                                      * 03000016
*       ISUT1  DDNAME FOR SYSUT1                                      * 03300016
*       ISUT2  DDNAME FOR SYSUT2                                      * 03600016
*       ISCOMP COMPLETION CODE                                        * 03900016
*       ISMESS MESSAGE NUMBER                                         * 04200016
*                                                                     * 04500016
*   REGISTER 13 MUST CONTAIN THE ADDRESS OF THHE CALLING PROGRAM'S    * 04800016
*   SAVE AREA,REGISTER 15 MUST CONTAIN THE ADDRESS OF THIS MODULE     * 05100016
*   FOR EVERY ENTRY TI THIS MODULE(EXCEPT FROM IEBISSO).                05400016
*OUTPUT: MODIFICATION OF IEBISR WORK AREA                             * 05700016
*EXTERNAL ROUTINES:                                                   * 06000016
*   IEBISSO: OUTPUT SUBROUTINE - TO OUTPUT AN UNLOAD ED RECORD        * 06300016
*EXITS-NORMAL:                                                        * 06600016
*   TO IEBISSO WHEN A LOGICAL RECORD HAS BEEN RETRIEVED AN PROCESSED  * 06900016
*    THE ADDRESS OF THE RECORD IN REGISTER1,ITS LENGTH IN REGISTER 0. * 07200016
*   TO IEBISF WITH A COMPLETION CODE OF ZERO IF MODULE WAS ABLE TO COM* 07500016
*    PLETE ITS OPERATION WITHOUT ENCOUNTERING ANY ERROR CONDITIONS.   * 07800016
*     -ERROR                                                          * 08100016
*   TO IEBISF WITH THE FOLLOWING COMPLETION CODES                     * 08400016
*     COMPLETION CODE = 8  PROGRAM UNABLE TO COMPLETE ITS OPERATION F * 08700016
*     OR EITHER OF THE FOLLOWING REASONS:                             * 09000016
*     INPUT OR OUTPUT SYNCHRONOUS ERROR                               * 09300016
*                                                                     * 09600016
*     COMPLETION CODE = 16 SYSUT1 OR SYSUT2 DD STATEMENT OMITTED      * 09900016
*                                                                     * 10200016
*ATTRIBUTES-REENTRANT                                              000G 10500016
*                                                                     * 10800016
*  REGISTER ASSIGNMENTS                                               * 11100016
*                                                                     * 11400016
BASE     EQU   10                  BASE REGISTER                        11700016
SAVERG   EQU   13                  SAVE AREA ADDRESS REGISTER           12000016
ADDREG   EQU   15                  ADDRESSIBILITY REGISTER              12300016
PARA1    EQU   1                   PARAMETER REGISTER                   12600016
WORKAREA EQU   11                       WORKAREA REGISTER          000G 12900016
WK2      EQU   2                   DCB ADDRESSING REGISTER              13200016
PARA0    EQU   0                   PARAMETER REGISTER                   13500016
LINKRG   EQU   15                  LINKAGE REGISTER TO  IEHISSO         13800016
RETREG   EQU   14                  RETURN REGISTER FOR IEHISSO          14100016
RCODE    EQU   15                  RETURN CODE REGISTER FOR IEHISSO     14400016
WK3      EQU   3                   MESSAGE NUMBER REGISTER              14700016
GETREG   EQU   1                   RECORD ADDRESS REGISTER              15000016
WK5      EQU   5                   WORK REGISTER                        15300016
*                                                                     * 15600016
IEBISU   CSECT                                                          15900016
*1770528000-540000                                                 IV0I 16900018
*A384100-387000                                                  A41745 16950021
         SAVE  (14,12),T,ISU-66-V1           SAVE REGISTERS             18600016
         USING IEBISU,BASE                   ESTABLISH BASE REGISTER    18900016
         LR    BASE,ADDREG                    BASE REGISTER             19200016
         LR    WORKAREA,PARA1           PICK UP WORK AREA POINTER  000G 19500016
         USING IEBWORK,WORKAREA                                    000G 19800016
         ST    SAVERG,SAVE1BK           SET BACK CHAIN POINTER     000G 20100016
         LR    SAVERG,WORKAREA          UPDATE TO NEW SAVE AREA    000G 20400016
         LA    WK2,SAVE2                SET UP FORWARD CHAIN POINTR000G 20700016
         ST    WK2,SAVE1FD                 TO NEXT SAVE AREA       000G 21000016
*                                                                       21300016
*  THIS SECTION LOADS THE ADDRESS OF THE IEHISR COMMON WORK AREA,MOVES* 21600016
*THE DDNAME FROM THE ISUT1 FIELD OF IEBISR WORK AREA TO THE INPUT DCB-* 21900016
*DDNAME FIELD. DURING OPEN A DCB EXIT IS TAKEN. IF OPEN WAS SUCCESSFU-* 22200016
*LY COMPLETED AND THE DATASET IS OF INDEXED SEQUENTIAL ORGANIZATION,  * 22500016
*THE RECORD FORMAT IS CHECKED FOR FIXED OR VARIABLE FORMAT. A SWITCH  * 22800016
*IS SET TO INDICATE THE FORMAT ,ZERO IS PLACED IN REGISTER ZERO AND A * 23100016
*BRANCH IS MADE OT THE SUBROUTINE IEBISSO.                            * 23400016
         MVC   DCBAR1(LABEL-DCBISU),DCBISU                         000G 23700016
         USING IHADCB,WK2                                               24000016
         LA    WK2,DCBAR1                                          000G 24300016
         MVC   DCBDDNAM(8),ISUT1        MOVE DDNAME FROM ISUT1     000G 24600016
         MVC   REENTAR(CLOSEL-OPENL),OPENL   MOVE L FORM OF OPEN TO000G 24900016
*                                               WORKAREA           000G 25200016
         XC    DOUBLE(8),DOUBLE                                         25500016
         XC    EXITADDR(8),EXITADDR                                     25800016
         OPEN  (DCBAR1,(INPUT)),MF=(E,REENTAR)                     000G 26100016
         TM    DCBOFLGS,X'10'                WAS OPEN SUCCESSFUL        26400016
         BZ    SETAL                         IF NOT,BRANCH              26700016
         TM    DCBRECFM,X'80'                YES,RECORD FORMAT FIXED    27000016
         BZ    VARY                          NO,BRANCH                  27300016
         TM    DCBRECFM,X'10'                BLOCKED RECORDS?           27600016
         BO    VARY+4                        YES,BRANCH                 27900016
         MVI   DOUBLE+6,X'01'          SET FORMAT SWITCH = 01           28200016
         LH    WK3,DCBRKP                    LOAD RELATIVE KEY POSITIO  28500016
         LTR   WK3,WK3                       RKP=0                      28800016
         BNE   VARY+4                        NO, BRANCH                 29100016
         OI    DOUBLE+6,X'10'           FORMAT SWITCH = X'11'      000G 29400016
         MVI   DOUBLE,X'FF'             INDICATE UNBLOCKED         000G 29700016
         MVC   DOUBLE+4(1),DCBKEYLE     SAVE KEY LENGTH            000G 30000016
         B     VARY+4                                                   30300016
VARY     MVI   DOUBLE+6,X'02'           SET FORMAT SWITCH = '02'   000G 30600016
         SR    PARA0,PARA0                                              30900016
         LR    PARA1,WORKAREA           LOAD ADDRESS OF WORKAREA   000G 31200016
OUSE     L     LINKRG,VSSO                   LOAD ADDRESS OF IEHISSO    31500016
         BALR  RETREG,LINKRG                 BRANCH TO IEHISSO          31800016
*                                                                     * 32100016
*  THIS SECTION DETERMINES THE RETURN CODE PASSED BY IEHISSO AND THEN * 32400016
*SETS THE APPROPRIATE COMPLETION CODE OR MESSAGE NUMBER, FOR ANY RE-  * 32700016
*TURN CODE DIFFERENT FROM ZERO AND CLOSES THE INPUT DATA SET BEFORE   * 33000016
*PASSING CONTROL TO IEBISF,                                           * 33300016
*                                                                     * 33600016
         STC   RCODE,DOUBLE+7           STORE RETURN CODE          000G 33900016
         CLI   DOUBLE+7,X'00'           IS RETURN CODE 0           000G 34200016
         BE    OBTAIN                        YES,BRANCH                 34500016
         CLI   DOUBLE+7,X'04'           IS RETURN CODE 4           000G 34800016
         BE    SETAS                         YES,BRANCH                 35100016
         CLI   DOUBLE+7,X'08'           IS RETURN CODE 8           000G 35400016
         BE    SETAL                                                    35700016
         LA    WK3,1                   DCB FIELDS INCONSISTENT     000G 36000016
EXIT     STH   WK3,REENTAR+32           INVALID RETURN CODE        000G 36300016
         MVC   ISMESS(2),REENTAR+32     MOVE IN MESSAGE NUMBER     000G 36600016
         LTR   WK3,WK3                       MESSAGE NUMBER = 0         36900016
         BZ    COMPLY                        YES,BRANCH                 37200016
         MVC   ISCOMP(2),EIGHT          SET COMPLETION CODE = 8    000G 37500016
COMPLY   MVC   REENTAR(EIGHT-CLOSEL),CLOSEL    MOVE L FORM OF CLOSE000G 37800016
*                                                 TO WORKAREA      000G 38100016
         CLOSE (DCBAR1),MF=(E,REENTAR)  CLOSE INPUT DATA SET       000G 38400016
         CLI   ISMESS+1,X'07'           OPEN NO GOOD             A41745 38410021
         BE    BYPASS                   NO OPEN SO BYPASS FREEP  A41745 38420021
         FREEPOOL DCBAR1                FREEPOOL INPUT BUFFER    A41745 38450021
BYPASS   SR    WK3,WK3                  SET UP XCTL AREA         A41745 38700021
         ST    WK3,XCTLAREA+4                                      000G 39000016
         MVI   WHICH+6,C' '             MOVE INTO XCTLAREA NAME OF 000G 39300016
         MVI   WHICH+5,C'F'                NEXT MODULE - IEBISF    000G 39600016
         L     SAVERG,4(SAVERG)              POPUP SAVE AREA            39900016
         L     14,12(0,SAVERG)               RESTORE REGISTER FOURTEEN  40200016
         LR    PARA1,WORKAREA           LOAD ADDRESS OF WORK AREA  000G 40500016
         XCTL  (2,12),MF=(E,(1)),SF=(E,XCTLAREA)   BRANCH TO IEHISF000G 40800016
SETAS    LA    WK3,2                   SYNAD ROUTINE ENTERED       000G 41100016
         B     EXIT                                                     41400016
SETAL    MVC   ISCOMP(2),H16            SET COMPLETION CODE OF 16  000G 41700016
         LA    WK3,7                   SET MESSAGE NUMBER = 7 FOR  000G 42000016
         STH   WK3,ISMESS                  MISSING SYSUT DD CARD   000G 42300016
         B     COMPLY                        BRANCH TO CLOSE            42600016
*                                                                     * 42900016
*  THIS SECTION PASSES THE LENGTH AND ADDRESS FO THE QISAM DCB TO THE * 43200016
*OUTPUT ROUTINE (IEHISSO) TO BE WRITTEN OUT                           * 43500016
*                                                                     * 43800016
OBTAIN   LTR   PARA0,PARA0                   INITIAL ENTRY FROM IEHISSO 44100016
         BNE   OBTAIN1                       NO, BRANCH                 44400016
         LA    WK3,154                       LOAD DCB LENTH             44700016
         STH   WK3,REENTAR+34           SAVE LENGTH                000G 45000016
         LA    WK3,DCBAR1              LOAD DCB ADDRESS            000G 45300016
         ST    WK3,RECADDR              SAVE ADDRESS OF RECORD     000G 45600016
         MVI   DOUBLE+5,X'11'          UNLOAD DCB INDICATOR        000G 45900016
         B     FXREC                                                    46200016
*                                                                     * 46500016
*  THIS SECTION GETS A LOGICAL RECORD,SAVES THE ADDRESS, AND THE LEN- * 46800016
*GTH OF THE RECORD.                                                   * 47100016
*                                                                     * 47400016
OBTAIN1  GET   DCBAR1                  GET RECORD ADDRESS          000G 47700016
         ST    GETREG,RECADDR           SAVE ADDRESS OF RECORD     000G 48000016
         XC    DOUBLE+5(1),DOUBLE+5     CLEAR DCB UNLOAD INDICATOR 000G 48300016
         ST    PARA0,DOUBLE                                        000G 48600016
         MVC   REENTAR+34(2),DCBLRECL   SAVE RECORD LENGTH         000G 48900016
*                                                                     * 49200016
*  THIS SECTION PROCESSES A RECORD ACCORDING TO THE RECORD FORMAT. THE* 49500016
*ADDRESS OF THE RECORD IS PLACED IN REGISTER ONE; THE LENGTH OF THE   * 49800016
*RECORD IN REGISTER ZERO FOR THE IEBISSO SUBROUTINE.                  * 50100016
*                                                                     * 50400016
         CLI   DOUBLE+6,X'01'           IS RECORD FORMAT FIXED     000G 50700016
         BE    FXREC                         YES,BRANCH                 51000016
         CLI   DOUBLE+6,X'11'           UNBLOCKED RECORDS          000G 51300016
         BE    ADDKEY                                                   51600016
         CLI   DOUBLE+6,X'00'           CHECK FOR FIXED BLOCKED         51900016
         BE    FXREC                    YES,FIXED BLOCKED               52200016
         L     WK3,RECADDR              GET RECORD ADDRESS         000G 52500016
         MVC   REENTAR+34(2),0(WK3)    SAVE CURRENT RECORD LENGTH  IV0I 53400018
         ST    WK3,RECADDR              SAVE ADDRESS OF RECORD     000G 54300016
FXREC    LH    PARA0,REENTAR+34         LOAD RECORD LENGTH         000G 54600016
         L     PARA1,RECADDR            LOAD RECORD ADDRESS        000G 54900016
         B     OUSE                                                     55200016
ADDKEY   SR    WK3,WK3                                                  55500016
         IC    WK3,DOUBLE+4             GET KEY LENGTH             000G 55800016
         AH    WK3,REENTAR+34           ADD KEY LENGTH TO          000G 56100016
         STH   WK3,REENTAR+34            RECORD LENGTH             000G 56400016
         B     FXREC                                                    56700016
OUT      LA    WK3,0                         SET MESSAGE NUMBER FOR OK  57000016
         LH    PARA0,EIGHT                                              57300016
         MVI   DOUBLE+5,X'FF'           INDICATE END OF INPUT      000G 57600016
         L     LINKRG,VSSO                   LOAD IEBISSO ADDRESS       57900016
         BALR  RETREG,LINKRG                 BRANCH TO IEBISSO          58200016
         LA    WK3,0                                                    58500016
         B     EXIT                          END OF INPUT DATA;GO CLOSE 58800016
RUIN     LA    WK3,2                   SYNAD ROUTINE ENTERED       000G 59100016
         TM    DCBEXCD2,X'20'                CLOSE BIT ON?              59400016
         BCR   7,RETREG                 RETURN TO CLOSE                 59500016
         SYNADAF ACSMETH=QISAM,PARM1=DCBAR1,PARM2=(0)              000G 59600016
         MVC   MESSAGE+8(79),49(PARA1)    MOVE IN MESSAGE          000G 59700016
         SYNADRLS                                                  000G 59800016
         MVC   REENTAR(EIGHT-CLOSEL),CLOSEL  MOVE L FORM OF CLOSE  000G 59900016
         CLOSE (DCBAR2),MF=(E,REENTAR)   CLOSE OUTPUT CATA SET     000G 60000016
         B     SETAS                    RETURN TO CLOSE OUT             60200016
*  CONSTANTS                                                          * 60600016
*                                                                     * 60900016
OPENL    OPEN  (,INPUT),MF=L                                       000G 61200016
CLOSEL   CLOSE (,DISP),MF=L                                        000G 61500016
EIGHT    DC    H'8'                          COMPLETION CODE CONSTANT   61800016
VSSO     DC    V(IEBISSO)         IEBISSO SYMBOLIC ENTRY                62100016
H16      DC    H'16'                                                    62400016
DCBISU   DCB   DSORG=IS,MACRF=GL,DDNAME=SYSUT1,                        *62700016
               SYNAD=RUIN,EODAD=OUT                                     63000016
LABEL    DS    0F                                                  000G 63300016
         DCBD  DSORG=(IS)                                               63600016
IEBWORK  DSECT                                                          63900016
SAVE1    DS    1F                                                       64200016
SAVE1BK  DS    1F                                                       64500016
SAVE1FD  DS    1F                                                       64800016
         DS    15F                                                      65100016
SAVE2    DS    1F                                                       65400016
SAVE2BK  DS    1F                                                       65700016
SAVE2FD  DS    1F                                                       66000016
         DS    15F                                                      66300016
SAVE3    DS    1F                                                       66600016
SAVE3BK  DS    1F                                                       66900016
SAVE3FD  DS    1F                                                       67200016
         DS    15F                                                      67500016
*IEHISR WORKAREA                                                        67800016
ISINVOK  DS    F                        ADDRESS OF PARAMETER LIST AT    68100016
*                                          INVOCATION                   68400016
ISPRINT  DS    2F                       DDNAME FOR SYSPRINT             68700016
ISUT1    DS    2F                       DDNAME FOR SYSUT1               69000016
ISUT2    DS    2F                       DDNAME FOR SYSUT2               69300016
ISCOMP   DS    H                        COMPLETION CODE                 69600016
ISMESS   DS    H                        MESSAGE NUMBER                  69900016
ISPAGE   DS    H                        PAGE NUMBER FOR SYSPRINT        70200016
ISCNTRL  DS    CL1                      CONTROL BYTE                    70500016
* MASKS FOR TESTING CONTROL BYTE - ISCONTRL                             70800016
ISSWC    EQU   X'80'                    COPY                            71100016
ISSWU    EQU   X'40'                    UNLOAD                          71400016
ISSWL    EQU   X'20'                    LOAD                            71700016
ISSWP    EQU   X'10'                    PRINT                           72000016
ISSWN    EQU   X'08'                    NO CONVERT REQUESTED            72300016
ISSWPI   EQU   X'04'                    PRINT INDEX                     72600016
ISSWPP   EQU   X'02'                    PRINT PRIME                     72900016
ISSWPO   EQU   X'01'                    PRINT OVERFLOW                  73200016
ALLMASK  EQU   X'07'                                               000G 73500016
ISSWITCH DS    CL1                      EXTRANEOUS SWITCHES             73800016
FIRSTTM  EQU   X'80'                    FIRST TIME SWITCH               74100016
*                                                                       74400016
XCTLAREA DS    2F                                                       74700016
WHICH    DS    2F                                                       75000016
ALIGN    DS    1F                                                       75300016
DOUBLE   DS    1D                                                       75600016
EXITADDR DS    2F                                                       75900016
REENTAR  DS    9F                                                       76200016
DCBAR1   DS    64F                                                      76500016
DCBAR2   DS    64F                                                      76800016
MESSAGER DS    CL1                                                 000G 77100016
MESSAGE  DS    CL120                                                    77400016
RECADDR  DS    1F                                                  000G 77700016
         DS    0D                                                       78000016
QISAM    DS    CL250                    UNLOADED DCB WORK AREA          78300016
HEADERC  DS    CL1                                                      78600016
HEADERT  DS    CL144                    HEADER AREA                     78900016
TARGET   DS    2F                       DATE HOLD AREA                  79200016
PAGENO   DS    1F                       HOLD PAGE NUMBER FOR A HEADING  79500016
PAGEPTR  DS    1F                       HOLD POINTER TO WHERE PAGE      79800016
*                                       NUMBER IS TO BE PLACED          80100016
         END                                                            80400016
