 TITLE 'IEBPPAL1-IEBPTPCH CONTROL CARD ANALYZER'                   1769 00020014
*                                                                       00040000
*    IEBPPAL1        CONTROL CARD ANALYZER OF PRINT/PUNCH               00060000
*                                                                       00080000
*                                                                       00100000
*                                                                       00120000
*RECEIVES CONTROL FROM THE ROOT SEGMENT AND CALLS THE CONTROL CARD SCAN 00140000
*MODULE (IEBCCS02). THE CONTROL CARDS ARE READ AND SCANNED IN IEBCCS02, 00160000
*BUT THEIR VALIDITY IS CHECKED IN IEBPPAL1.                             00180000
*IF AN ERROR OCCURS,IEBPPAL1 LOADS THE ERROR MESSAGE NUMBER IN REGISTER 00200000
*ZERO,AND THE OFFSET IN REGISTER ONE. A BRANCH IS TAKEN TO THE MESSAGE  00220000
*WRITER IN IEBPPUN1.                                                    00240000
*THE CONDITION CODE IS SET ACCORDING TO THE SEVERITY OF THE ERROR, AND  00260000
*THE REMAINDER OF THE CONTROL CARDS ARE SCANNED. THE CONDITION CODE IS  00280000
*EXAMINED ON RETURN TO IEBPPUN1. IF IT IS TWELVE OR HIGHER, THE REQUEST 00300000
*IS TERMINATED.                                                         00320000
*WHEN IEBCCS02 SENDS IEBPPAL1 AN END OF FILE INDICATION,A DIAGNOSTIC IS 00340000
*PERFORMED. A CHECK IS MADE WHETHER THE MAXLINE PARAMETER WAS SPECIFIED 00360000
*IF IT WAS,WE CHECK THAT THE BASIC SPACING AND TITLE PARAMETERS EXCEED  00380000
*THIS COUNT AT THE START.                                               00400000
*                                                                       00420000
*        ENTRY POINT    IEBPPAL1                                        00440000
*                                                                       00460000
*        INPUT          CONTROL STATEMENTS, READ AND PASSED TO THIS     00480000
*                       MODULE BY THE CONTROL SCAN ROUTINE. ALSO        00500000
*                       PASSED TO THIS MODULE ARE CONTROL BYTES SET     00520000
*                       BY THE SCAN ROUTINE.                            00540000
*                                                                       00560000
*        OUTPUT         ERROR DIAGNOSTICS ARE INITIATED BY THIS         00580000
*                       ROUTINE. THE CONTROL TABLE IS BUILT AND         00600000
*                       PASSED TO THE MAIN PROCESSOR.                   00620000
*                                                                       00640000
*        EXTERNAL RTNS  CALLS THE SCAN ROUTINE, WHICH READS THE         00660000
*                       CONTROL STATEMENTS AND PASSES PARAMETER         00680000
*                       INFORMATION.  GOES TO ZZPR,WHICH PRINTS         00700000
*                       DIAGNOSTICS AND INFORMATIONAL MESSAGES.         00720000
*                       THE LINK IS DONE BY A BALR.                     00740000
*                                                                       00760000
*        EXITS          NOT APPLICABLE.                                 00780000
*                                                                       00800000
*        WORK AREAS     AREA FOR MEMBER NAME TABLE OF A PARTIAL         00820000
*                       PDS  IS REQUESTED.  TABLE FOR  RECORD           00840000
*                       STATEMENT INFORMATION (IDENTS-FIELDS).          00860000
         EJECT                                                          00880000
*                                                                       00900000
*                  FORMAT OF MEMBER NAME TABLE                          00920000
*                                                                       00940000
*              *                                                        00960000
*              *4 BYTES * 8 BYTES        *4 BYTES *                     00980000
*              ************************************                     01000000
*              *MEMBERCT*MEMBER NAME     *MCB ADDR*                     01020000
*              ************************************    ***************  01040000
*                       *MEMBER NAME     *MCB ADDR*    TOTAL AREA =     01060000
*                       ***************************    (MEMCOUNT X 12)  01080000
*                       *MEMBER NAME     *MCB ADDR*    +4               01100000
*                       ***************************    ***************  01120000
*                                                                       01140000
*                                                                       01160000
*        FORMAT OF GETMAIN AREA FOR GROUP CONTROL BLOCKS (GCB)     1769 01164014
*        AND FIELD CONTROL BLOCKS (FCB)                            1769 01168014
*                                                                  1769 01172014
*                                                                  1769 01176014
* 2 BYTES- NUMBER OF GCB'S FOLLOWING                               1769 01180014
*                                                                  1769 01184014
*                                                                  1769 01188014
* 8 BYTES- FIRST GCB                                               1769 01192014
*          2 BYTES- NUMBER OF FCB'S FOR THIS GCB                   1769 01196014
*          2 BYTES- LENGTH OF CURRENT IDENT LITERAL                1769 01200014
*          2 BYTES- DISPLACEMENT OF CURRENT IDENT IN LITERAL POOL  1769 01204014
*          2 BYTES- INPUT LOCATION MINUS 1 OF CURRENT IDENT        1769 01208014
*                                                                  1769 01212014
* 8 BYTES- FIRST FCB FOR FIRST GCB                                 1769 01216014
*          2 BYTES- LENGTH OF FIELD                                1769 01220014
*          2 BYTES- INPUT LOCATION MINUS 1                         1769 01224014
*          2 BYTES- CONVERSION CODE                                1769 01228014
*          2 BYTES- OUTPUT LOCATION MINUS 1                        1769 01232014
*                                                                  1769 01236014
* 8 BYTES- SECOND FCB FOR FIRST GCB                                1769 01240014
*    *                                                             1769 01244014
*    *                                                             1769 01248014
*    *                                                             1769 01252014
* 8 BYTES- N'TH FCB FOR FIRST GCB                                  1769 01256014
*                                                                  1769 01260014
*                                                                  1769 01264014
* 8 BYTES- SECOND GCB                                              1769 01268014
*                                                                  1769 01272014
* 8 BYTES- FIRST FCB FOR SECOND GCB                                1769 01276014
*    *                                                             1769 01280014
*    *                                                             1769 01284014
*    *                                                             1769 01288014
* 8 BYTES- N'TH FCB FOR SECOND GCB                                 1769 01292014
*                                                                  1769 01296014
*                                                                  1769 01300014
*  *                                                               1769 01304014
*  *                                                               1769 01308014
*  *                                                               1769 01312014
*                                                                  1769 01316014
*                                                                  1769 01320014
* 8 BYTES- N'TH GCB                                                1769 01324014
*    *                                                             1769 01328014
*    *                                                             1769 01332014
*    *                                                             1769 01336014
*                                                                  1769 01340014
*                                                                       01360000
*                                                                       01380000
*        ATTRIBUTES     NON-REUSABLE                                    01400000
*                                                                       01420000
*********************************************************************** 01440000
         EJECT                                                          01460000
*                                                                       01480000
IEBPPAL1 CSECT                                                          01520000
* 120650                                                          M3306 01520818
* 109120-109240,214700                                            M3310 01521618
* 167420-167520                                                   M3311 01522418
* 150402-150404,165420-165440                                     M3312 01523218
* 109140-109220,214700                                           A25956 01524018
*3416079600,075400-075600                                        A21407 01525018
*3416082460,082640                                               A21407 01531018
*3416016200-016600,023200,024200,024600,025800,026000,026250,      SA0I 01537118
*027000,027800,028600,029400,030200,031000,031600,032200,032800,   SA0I 01537218
*033400,034000,035600,036200,                                      SA0I 01537318
*037200,038000,038800,039600,040400,041200,                        SA0I 01537418
*042600,042800,043400,044200-044400,046200,053000,064400-065600,   SA0I 01537518
*067000,067400,067600,068000,068200,068600,069000,069600,070000,   SA0I 01537618
*071000,071450,071550,071600,075400-075600,076000-076200,077400,   SA0I 01537718
*077800,079600,086400-086600,089800-090800,100800,101200,105200,   SA0I 01537818
*105400,106600,106800,106920,                                      SA0I 01537918
*107600,108000,108400,109200,110400,112600,                        SA0I 01538018
*114600,114680,117600,120800,121050,121600,122400,123200,124000,   SA0I 01538118
*124200,125000,125400,125800,126200,128200-128800,130600,130800,   SA0I 01538218
*132400,132600,132800,133400,133800,134200,138000,139000-139200,   SA0I 01538318
*139400,142208,142228,142240,142248,142260,142300-142310,142316,   SA0I 01538418
*142328,142336,142344,143400,143520,146000,149000,149200,149600,   SA0I 01538518
*149800,151200,152400,152600,153000,154400,154800,160200,166200,   SA0I 01538618
*166600,169000,169600,170000,173400,                               SA0I 01538718
*177400-177600,177700,178400,182000-                               SA0I 01538818
*182200,187600-188700,189600-192200,192300-192350,193000,193800-   SA0I 01538918
*194000,194800,195600-196200,208400                                SA0I 01539018
*082440-082620                                                    M4118 01539318
*056200                                                           24304 01540319
*101800                                                           29476 01541319
*085200,085400                                                    25790 01542319
*073720-073380,225204-225216                                      27715 01545319
*120600,020650,127400                                             28397 01548319
*142201-142204,142206,142324,142332,142340,142348                 29608 01551319
* 130500,130600,131000,137000,137200,143020                      A35450 01552320
*                                                                A36048 01552721
*130850-130950                                                   A36082 01553121
*                                                                A36090 01553521
*163800                                                          A36097 01553921
*084000                                                          A38738 01554021
*A135700                                                         A45130 01554121
*A041400,041700-041760,135700,19300,229300                       A45135 01554221
*D041400                                                         A45135 01560621
*A043720-043760                                                  A41815 01562621
*C043200                                                         A41815 01564621
*A077624,113900-114200,214720                                    A52039 01566621
*C101600,102000,109000,109060,113400,114000,114520,114640,114800,A52039 01567021
*C218600                                                         A52039 01567121
*D110200,110400,112400,112600,113600-114200                      A52039 01573621
*A092900,092920,135100,135120,178440                             A52055 01575621
*C093600,178400                                                  A52055 01577621
*C073160,073320                                                  A54086 01579621
         SAVE  (14,12),T,IEBPPAL1-JULY-66                               01580521
*                                                                       01587021
         TM    0(R1),X'80'         TEST FOR ERROR                       01593521
         BO    0(R14)              ERROR-IMMEDIATE EXIT                 01600000
         BALR  BASER,R0            SET UP ADDRESSABILITY           SA0I 01610018
         USING HOWIE3,BASER,BASE                                   SA0I 01620018
HOWIE3   L     BASE,BASEADDR                                       SA0I 01630018
         B     PKUP                                                SA0I 01640018
BASEADDR DC    A(HOWIE3+4096)                                      SA0I 01650018
PKUP     ST    R13,SAVEADD+4       STORE SAVE REG                  SA0I 01660018
         LA    R1,SAVEADD               GET PTR TO SAVE AREA            01680000
         ST    R1,8(R13)                STORE PTR TO S.A. IN SAVE AREA  01700000
         L     R1,24(R13)               RESTORE R1                      01720000
         LA    R13,SAVEADD         OWN SAVE AREA IN SAVE REGISTER       01740000
         ST    R1,PARMADR          SAVE ADDRESS IN REG 1           4304 01744019
         L     R1,4(R1)            GET FREE ADDR FROM PARM PASSED  4304 01748019
         MVC   FREEA(4),0(R1)      GET ADDR OF FREECORE TABLE      4304 01752019
         L     R1,PARMADR          RESTORE REG 1                   4304 01756019
         L     R1,0(R1)            GET DDNAME FOR SYSIN -ADDRESS OF     01760000
         MVC   PPSYSI(8),0(R1)    MOVE DDNAME FOR SYSIN                 01780000
*                                                                       01800000
*                                                                       01820000
         MVI   PPWORK,0           ZERO TO WORK AREA                     01840000
         MVC   PPWORK+1(WORKLEN-1),PPWORK    ZERO WORK AREA             01860000
         MVC   SKIPSW(2),PH1                 TURN OFF SKIP SWITCH       01880000
         MVC   PLANT(2),PH1        TURN OFF SWITCH                      01900000
*                                                                       01920000
         LA    RZ,DLEN             ADDRESS OF DTABLE LENGTH INDICATOR   01940000
         ST    TEMP3,TEMPSAVE          SAVE CONTENTS OF REG 3      4304 01943019
         L     TEMP3,FREEA             USE REG 3 TO ESTAB ADDRESS  4304 01946019
         USING FREECOR,TEMP3           FOR FREECOR DSECT           4304 01949019
         ST    RZ,DTBL                 STORE TBLE LENG TO FREE     4304 01952019
         MVI   MAIN1,X'10'             TURN ON GET MAIN SWTCH      4304 01955019
         GETMAIN R,LV=(0)                                               01960000
         ST    R1,DTBA             STORE DTBLE ADDR FOR FREE       4304 01965019
         L     TEMP3,TEMPSAVE          RESTORE REG 3 CONTENTS      4304 01970019
         DROP  3                                                   4304 01975019
         LR    TREG,R1             ADDRESS OF GETMAIN AREA              01980000
         USING DTABLE,TREG         GETMAIN BASE FOR DSECT               02000000
         MVI   DBEGIN,0            ZERO TO FIRST BYTE OF DTABLE         02020000
         MVC   DBEGIN+1(DLEN-1),DBEGIN       ZERO OUT DTABLE            02040000
         MVI   EXLST,C' '          BLANK FIRST BYTE EXIT LIST           02060000
         MVC   EXLST+1(EXLEN-1),EXLST        BLANK EXIT LIST            02080000
*                                                                       02100000
         MVI   RECSW,X'00'        CLEAR RECORD BYPASS SWITCH            02110020
         MVC   TABLE(TABLEN),TABLE-1         ZERO SWITCHES,POINTERS     02120000
         LA    TEMP1,120                     LOAD REGISTER WITH 12/     02140000
         STH   TEMP1,MAXOUT                  MAXIMUM PRINT LINE LENGTH  02160000
         MVI   INITPG+1,1          FIRST PAGE NUMBER DEFAULT=1          02180000
         EJECT                                                          02200000
*                                                                       02220000
*********************************************************************** 02240000
*              RETURN FROM INITIAL CALL TO SCANNER SHOULD BE COMMAND    02260000
*              TO PRINT OR PUNCH.                                       02280000
*                                                                       02300000
         LA    ERREG,PPERRC        LOAD ADDRESS OF MESSAGE ROUTINE      02340000
         BAL   BREG,CALLSCAN       BRANCH AND LINK TO CALL MACRO        02360000
PTCOM    OI    BIT,X'01'           TURN OFF FIRST CARD BIT         SA0I 02370018
         TM    PPWORK,COMM        TEST FOR COMMAND                      02380000
         BZ    0(ERREG)            NO,TERMINATE                         02400000
         CLC   CPRINT(6),0(R1)    DOES COMMAND=PRINT               SA0I 02420018
         BE    PPCOM              COMMAND IS PRINT                      02440000
         CLC   CPUNCH(6),0(R1)    DOES COMMAND=PUNCH               SA0I 02460018
         BNE   0(ERREG)            NEITHER PRINT NOR PUNCH-TERMINATE    02480000
*                                                                       02500000
         MVI   PPSW1,X'01'         SET PPSW1 FOR PUNCH                  02520000
         LA    TEMP1,80            LOAD REGISTER WITH 80                02540000
         STH   TEMP1,MAXOUT        MAXIMUM PUNCH CARD CAPACITY          02560000
PPCOM    LA    ERREG,PPERRH        ADDRESS OF MSG RTN              SA0I 02580018
         BAL   BREG,CALLSCAN       BRANCH TO CCS02                 SA0I 02590018
PPCOM1   TM    PPWORK,PAR          TEST FOR PARAMETER              0033 02605015
         BZ    PPK0                NO, B AROUND PARAM CHECK        0033 02610015
         LTR   RZ,RZ               IS PARAM LENGTH ZERO            0033 02615015
         BE    PPCOM               YES, B TO SCAN AGAIN            0033 02620015
         B     PPERRH              BRANCH TO ERROR MESSAGE         SA0I 02625018
PPK0     TM    PPWORK,KEYW         TEST FOR KEYWORD                0033 02630015
         BZ    GETSTOR            NO,END OF CARD                        02640000
*                                                                       02660000
*              COMMAND IS PRINT OR PUNCH. TEST FOR VALID KEYWORD        02680000
*                                                                       02700000
         NI    PPWORK+81,X'FD'     SET OFF KEYWORD REQUIRED BIT    SA0I 02710018
         MVC   PPCSW1(1),PDZERO    ZERO TO SWITCH                       02720000
         LA    BREG,PPSCANP        ADDRESS OF PARAM CHECK               02740000
         LA    KREG,PPSETPB        ADDRESS OF CVB ROUTINE               02760000
         CLC   KTYPORG(7),0(R1)   COMPARE FOR KEYWORD TYPORG       SA0I 02780018
         BNE   PPK1                NOT TYPORG KEYWORD                   02800000
         LA    KREG,TYPORGP        ADDRESS OF TYPORG VALIDITY CHECK     02820000
         BR    BREG                BRANCH TO PARAM CHECK                02840000
PPK1     CLC   KTOTCONV(8),0(R1)  COMPARE FOR TOTCONV KEYWORD      SA0I 02860018
         BNE   PPK2A               NOT TOTCONV KEYWORD                  02880000
         LA    KREG,TOTCONVP       ADDR OF TOTCONV TYPE CHECK           02900000
         BR    BREG                BRANCH TO PARAM CHECK                02920000
PPK2A    CLC   KPREFRM(8),0(R1)   TEST FOR KEYWORD PREFORM         SA0I 02940018
         BNE   PPK2                NOT PREFORM KEYWORD                  02960000
         LA    KREG,FORMATED       ADDRESS OF FORMAT CHECK              02980000
         BR    BREG                BRANCH TO PARAM CHECK                03000000
PPK2     CLC   KCNTRL(6),0(R1)    COMPARE FOR CNTRL KEYWORD        SA0I 03020018
         BNE   PPK3                NOT CNTRL KEYWORD                    03040000
         LA    KREG,CNTRLP         ADDRESS OF CNTRL CHECK               03060000
         BR    BREG                BRANCH TO PARAM CHECK                03080000
PPK3     CLC   KINITPG(7),0(R1)   COMPARE FOR INITPG KEYWORD       SA0I 03100018
         BNE   PPK4                NOT INITPG KEYWORD                   03120000
         TM    PPSW1,X'01'         TEST FOR PUNCH                       03140000
         BO    PPERRH              INITPG VALID ONLY FOR PRINT     SA0I 03160018
         LA    PARLOC,INITPG       ADDRESS OF INITIAL PAGE NO INDICATOR 03180000
         BR    BREG                BRANCH TO PARAM CHECK                03200000
PPK4     CLC   KMAXLINE(8),0(R1)  COMPARE FOR MAXLINE KEYWORD      SA0I 03220018
         BNE   PPK5                NOT MAXLINE KEYWORD                  03240000
         TM    PPSW1,X'01'         TEST FOR PUNCH                       03260000
         BO    PPERRH              MAXLINE VALID ONLY FOR PRINT    SA0I 03280018
         LA    PARLOC,PMAXLINE     ADDR OF MAX LINES PER PAGE INDICATOR 03300000
         BR    BREG                BRANCH TO PARAM CHECK                03320000
PPK5     CLC   KCDSEQ(6),0(R1)    COMPARE FOR CDSEQ KEYWORD        SA0I 03340018
         BNE   PPK6                NOT CDSEQ KEYWORD                    03360000
         TM    PPSW1,X'01'         TEST FOR PUNCH                       03380000
         BZ    PPERRH              CDSEQ INVALID IF NOT PUNCH      SA0I 03400018
         OI    PPCSW1,X'02'        ( SET SWITCH)                        03420000
         OI    PPSW1,X'02'                                              03440000
         OI    PPWORK+140,X'01'                                         03460000
         LA    PARLOC,CDNOB        ADDRESS OF INITIAL SEQUENCE NUMBER   03480000
         LA    KREG,FPSETPB             ADDR BIN CONV ROUTINE FOR       03500000
*                                        FULLWORD COUNTER               03520000
         BR    BREG                BRANCH TO PARAM CHECK                03540000
PPK6     CLC   KCDINCR(7),0(R1)   COMPARE FOR CDINGR KEYWORD       SA0I 03560018
         BNE   PPK7                NOT CDINCR KEYWORD                   03580000
         TM    PPSW1,X'01'         TEST FOR PUNCH                       03600000
         BZ    PPERRH              CDINCR INVALID IF NOT PUNCH     SA0I 03620018
         LA    PARLOC,CDINCRB      ADDRESS OF INCREMENT                 03640000
         LA    KREG,FPSETPB             ADDR BIN CONV ROUTINE FOR       03660000
*                                        FULLWORD COUNTER               03680000
         BR    BREG                BRANCH TO PARAM CHECK                03700000
PPK7     CLC   KSTOPAFT(8),0(R1)  COMPARE FOR STOPAFT KEYWORD      SA0I 03720018
         BNE   PPK8                NO STOPAFT KEYWORD                   03740000
         LA    PARLOC,INITSTOP     ADDRESS OF STOP DATA                 03760000
         BR    BREG                BRANCH TO PARAM CHECK                03780000
PPK8     CLC   KSKIP(5),0(R1)     COMPARE FOR SKIP KEYWORD         SA0I 03800018
         BNE   PPK9                NOT SKIP KEYWORD                     03820000
         LA    PARLOC,INITSKIP     ADDRESS OF SKIP DATA                 03840000
         BR    BREG                BRANCH TO PARAM CHECK                03860000
PPK9     CLC   KMAXNAME(8),0(R1)  COMPARE FOR MAXNAME KEYWORD      SA0I 03880018
         BNE   PPK10               NOT MAXNAME KEYWORD                  03900000
         LA    PARLOC,MAXNAME      ADDRESS OF MAXIMUM MEMBER STATEMENTS 03920000
         BR    BREG                BRANCH TO PARAM CHECK                03940000
PPK10    CLC   KMAXFLDS(8),0(R1)  COMPARE PUR MAXFLDS KEYWORD      SA0I 03960018
         BNE   PPK11               NOT MAXFLDS KEYWORD                  03980000
         LA    PARLOC,MAXFLDS      ADDRESS OF MAXIMUM FIELD PARAMETERS  04000000
         BR    BREG                BRANCH TO PARAM CHECK                04020000
PPK11    CLC   KMAXGPS(7),0(R1)   COMPARE FOR MAXGPS KEYWORD       SA0I 04040018
         BNE   PPK12               NOT MAXCPS KEYWORD                   04060000
         LA    PARLOC,MAXGPS       ADDRESS OF MAXIMUM IDENT PARAMETERS  04080000
         BR    BREG                BRANCH TO PARAM CHECK                04100000
PPK12    CLC   KMAXLITS(8),0(R1)  COMPARE FOR MAXLITS KEYWORD      SA0I 04120018
         BNE   PPK13               NOT MAXLITS KEYW, GO TO NEXT  A45135 04140021
         LA    PARLOC,MAXLITS      ADDR OF MAX IDENT LITERAL CHARACTERS 04160000
         BR    BREG               BRANCH TO PARAMETER CHECK      A45135 04170021
PPK13    CLC   KSTRTAFT,0(R1)      COMPARE FOR STARTAT KEYWORD   A45135 04172021
         BNE   0(ERREG)           ERROR, INVALID KEYWORD         A45135 04174021
         LA    PARLOC,STRTAFT     ADDR OF START NBR              A45135 04176021
         EJECT                                                          04180000
*                                                                       04200000
*              EXAMINE PRINT/PUNCH PARAMETERS                           04220000
*                                                                       04240000
PPSCANP  LA    ERREG,PPERRJ        ADDRESS OF MSG ROUTINE          SA0I 04250018
         OI    PPWORK+81,X'01'     SET ON PARAMETER REQUIRED BIT   SA0I 04260018
         BAL   BREG,CALLSCAN       BRANCH TO CCS02                 SA0I 04270018
         NI    PPWORK+81,X'FE'     SET OFF PARAMETER REQUIRED BIT  SA0I 04280018
         TM    PPWORK,PAR          HAVE A PARAMETER?                    04300000
         BO    PARTEST             YES, TEST FOR PARAM. LENGTH   A41815 04320021
         LA    ERREG,PPERRH        ADDRESS OF MSG RTN              SA0I 04340018
         B     PPCOM1              BACK TO KEYWORD CHECK                04360000
PARTEST  LTR   RZ,RZ               PARAM. LENGTH ZERO ?          A41815 04372021
         BE    PPERRJ              YES, PRINT MESS. IEB432I      A41815 04374021
         B     0(KREG)             NO, CONT PARAM CHECKING       A41815 04376021
*                                                                       04380000
TYPORGP  CLC   PPS(2),0(R1)        COMPARE FOR TYPORG PARAM PHYS SEQ    04400000
         BNE   DENNIS              NO-CONTINUE                     SA0I 04410018
         CH    RZ,PH2              IS PARAM LENGTH=2?              SA0I 04420018
         BNE   PPERRJ              NO-BRANCH TO ERROR MSG          SA0I 04430018
         B     PPCOM               PHYS SEQ ORG- TO SCAN                04440018
DENNIS   CLC   PPO(2),0(R1)        COMPARE FOR TYPORG PARTITIONED  SA0I 04450018
         BNE   0(ERREG)            IF NEITHER PS NOR PO,INVALID PARAM   04460000
         CH    RZ,PH2              IS PARAM LENGTH=2?              SA0I 04466018
         BNE   PPERRJ              NO-B TO ERR MSG                 SA0I 04472018
         OI    TYPORG,X'01'        RESET TYPORG TO PO                   04480000
         B     PPCOM               BRANCH TO SCAN                       04500000
*                                                                       04520000
TOTCONVP CLC   PHE(2),0(R1)        COMPARE FOR PARAMETER HE             04540000
         BE    ORR                 TREATED AS HEX PARAMETER XE          04560000
         CLC   PXE(2),0(R1)        COMPARE FOR HEX PARAMETER XE         04580000
         BNE   TOTCP5              NOT HE OR XE - BRANCH TO RZ TEST     04600000
ORR      CH    RZ,PH2              IS PARAM LENGTH=2?              SA0I 04610018
         BNE   PPERRJ              NO-BRANCH TO ERROR MSG          SA0I 04620018
         OI    TOTCONV,X'01'       RESET TOTCONV FOR HEX           SA0I 04630018
         B     PPCOM               BRANCH TO SCAN                       04640000
TOTCP5   CLC   PPZ(2),0(R1)        COMPARE FOR UNPACKED DECIMAL PARAM   04660000
         BNE   0(ERREG)            NONE OF ABOVE-INVALID PARAMETER      04680000
         CH    RZ,PH2              IS PARAM LENGTH=2?              SA0I 04686018
         BNE   PPERRJ              NO-BRANCH TO ERROR MSG          SA0I 04692018
         OI    TOTCONV,X'03'       SET TOTCONV FOR UNPACKED DECIMAL     04700000
         B     PPCOM               BRANCH TO SCAN                       04720000
*                                                                       04740000
CNTRLP   BAL   BREG,SETPBIN        CONVERT PARAMETER TO BINARY          04760000
         LA    TEMP1,3                                                  04780000
         TM    PPSW1,1             TEST FOR PUNCH                       04800000
         BZ    CP5                 NOT PUNCH,THEREFORE PRINT            04820000
         BCTR  TEMP1,R0            SUBTRACT ONE FOR PUNCH               04840000
CP5      CR    PREG,TEMP1          TEST PARAM AGAINST 2(PUN) OR 3(PR)   04860000
         BCR   2,ERREG            BRANCH IF PARAM ABOVE MAXIMUM         04880000
         LTR   PREG,PREG           TEST FOR ZERO PARAMETER              04900000
         BNH   0(ERREG)            ONLY ABOVE ZERO VALID                04920000
         STC   PREG,PPCTL          SET CONTROL FOR GIVEN PARAMETER      04940000
         B     PPCOM               BRANCH TO SCAN                       04960000
*                                                                       04980000
*  BRANCH TO CONVERT TO BINARY ROUTINE FOR THE FOLLOWING PARAMETERS     05000000
*   CDSEQ (VALUE CARD SEQUENCE NUMBER IS TO BEGIN WITH)                 05020000
*   CDINCR (VALUE CARD SEQUENCE NUMBER IS TO BE INCREMENTED)            05040000
*   USE OF FULLWORD COUNTERS ALLOWS SEQUENCE NUMBERS TO 99,999,999 DEC  05060000
*                                                                       05080000
FPSETPB  BAL   BREG,SETPBIN             GO TO CONVERT ROUTINE           05100000
         ST    PREG,0(PARLOC)           PLACE CONV. VALUE IN DTABLE     05120000
         B     PPCOM                    FINISHED WITH THIS PARAMETER    05140000
*                                                                       05160000
*  BRANCH TO CONVERT TO BINARY ROUTINE FOR PARAMETERS WITH HALFWORD CTR 05180000
*                                                                       05200000
FORMATED CLI   0(R1),C'A'          TEST FOR CONTROL CHARACTER           05220000
         BE    SLIPDOWN            YES-BRANCH TO SWITCH SET             05240000
         CLI   0(R1),C'M'          TEST FOR CONTROL CHARACTER      SA0I 05246018
         BNE   PPERRJ              BRANCH TO ERROR MESSAGE         SA0I 05252018
         OI    PREFMTP,X'01'       SET FORMAT SWITCH                    05260000
         B     PPCOM               BRANCH TO SCAN                       05280000
SLIPDOWN CH    RZ,PH1              IS PARAM LENGTH =1?             SA0I 05290018
         BNE   PPERRJ              NO-BRANCH TO ERROR MSG          SA0I 05300018
         OI    PREFMTP,X'80'       SET FORMAT SWITCH               SA0I 05310018
         B     PPCOM               BRANCH TO SCAN                       05320000
*              CONVERT PARAMETER TO BINARY                              05340000
PPSETPB  BAL   BREG,SETPBIN       CONVERT TO BINARY                     05360000
         STH   PREG,0(PARLOC)     STORE PARAMETER                       05380000
         B     PPCOM               BRANCH TO SCAN                       05400000
*                                                                       05420000
*              GET STORAGE FOR TABLES                                   05440000
*                                                                       05460000
GETSTOR  TM    TYPORG,1            TEST TYPE OF ORGANIZATION            05480000
         BZ    GS5                 SDS,NO MEMBER NAME TABLE             05500000
         LH    RZ,MAXNAME          TEST FOR                             05520000
         LTR   RZ,RZ               NAMED MEMBERS                        05540000
         BE    GS5A                NO NAMED MEMBERS                     05560000
         MH    RZ,LISTLEN          MULT MEMBER NUMBER OF LENGTH CONST   05580000
         AH    RZ,PH4              TOTAL TAB LENGTH=ABOVE PLUS FOUR     05600000
GS1      ST    TEMP3,TEMPSAVE          SAVE CONTENTS OF REG 3      4304 05604019
         L     TEMP3,FREEA             USE REG 3 TO ESTAB ADDRESS  4304 05608019
         USING FREECOR,TEMP3           FOR FREECOR DSECT           4304 05612019
         ST    RZ,GS1L                 STORE MNT LENG FOR FREE     4304 05616019
         MVI   MAIN2,X'10'             TURN ON MNT GET MAIN SWTCH  4304 05620019
         GETMAIN  R,LV=(0)             GET CORE FOR MEMBER TBLE    4304 05624019
         ST    R1,MNTA                 STORE MNT ADDRESS           4304 05628019
         L     TEMP3,TEMPSAVE          RESTORE REG 3 CONTENTS      4304 05632019
         DROP  3                                                   4304 05636019
         ST    R1,MNTADD           STORE TABLE ADDRESS                  05640000
         LA    MNTPTER,4(R1)       ADDRESS OF SECOND WORD OF TABLE      05660000
         ST    MNTPTER,CURRMNT    STORE THIS ADDRESS                    05680000
         MVC   8(4,MNTPTER),PDZERO ZERO FOURTH WORD OF MNT              05700000
         LH    RZ,MAXNAME          TEST FOR                             05720000
         LTR   RZ,RZ               NAMED MEMBERS                        05740000
         BE    GS6                 NO NAMED MEMBERS                     05760000
         MH    RZ,PH10                  DOUBLE MEMBER NAME              05780000
         B     GS8                 TO USER DEFINED GROUP CHECK          05800000
GS5A     MVC   MASK(2),PH12        CAUSE BRANCH AT CSCAN7               05820000
GS5      LA    RZ,16              MNT LENGTH-NO MEMBERS                 05840000
         B     GS1                BUILD TABLE-NO MEMBERS                05860000
GS6      LH    RZ,PH10      SET REG TO CONSTANT OF 10              7827 05880000
GS8      LH    R1,MAXGPS           TEST FOR                             05900000
         LTR   R1,R1               USER DEFINED GROUPS                  05920000
         BNE   OVERFLDS            YES - USER DEFINED GROUPS            05940000
         LH    R1,MAXFLDS         TEST FOR                              05960000
         LTR   R1,R1               USER FORMATTED OUTPUT                05980000
         BE    GSMCBNO             NO USER FORMATTED OUTPUT             06000000
         LH    R1,MAXGPS          LOAD NO OF IDENTS                     06020000
OVERFLDS MH    R1,GCBLEN          MULTIPLY IDENTS BY 8 FOR LENGTH       06040000
         AR    RZ,R1               ADD 2 TO LENGTH                      06060000
         LH    R1,MAXFLDS          LOAD MAXIMUM FIELD STATEMENTS        06080000
         MH    R1,FCBLEN           MULTIPLY BY STATEMENT LENGTH 8       06100000
         AR    RZ,R1               TOTAL LENGTH FOR GETMAIN             06120000
         ST    RZ,MCBLEN           STORE MEMBER CONTROL BLOCK LENGTH    06140000
         ST    RZ,MCBREM           STORE IN MCB REMAINING               06160000
         ST    TEMP3,TEMPSAVE          SAVE CONTENTS OF REG 3      4304 06163019
         L     TEMP3,FREEA             USE REG 3 TO ESTAB ADDRESS  4304 06166019
         USING FREECOR,TEMP3           FOR FREECOR DSECT           4304 06169019
         ST    RZ,MCBL                 STORE LENGTH OF MCB AREA    4304 06172019
         MVI   GETMA,X'10'                                       A36090 06174021
         MVI   MAIN3,X'10'             SET GET MAIN SWITCH FOR MCB 4304 06175019
         GETMAIN R,LV=(0)                                               06180000
         ST    R1,MCBADD           STORE ADDRESS OF MEMBER CONTROL BLK  06200000
         ST    R1,MCBA                 STORE MCB ADDR FOR FREE     4304 06205019
         L     TEMP3,TEMPSAVE          RESTORE REG 3 CONTENTS      4304 06210019
         DROP  3                                                   4304 06215019
         LR    MCBPTER,R1          LOAD POINTER TO MEMBER CONTROL BLOCK 06220000
         MVC   0(2,MCBPTER),PDZERO ZERO FIRST HALFWORD OF MCB           06240000
         LH    RZ,MAXLITS          TEST FOR                             06260000
         LTR   RZ,RZ               LITERALS                             06280000
         BE    GSEND              NONE-DON'T GET MAIN                   06300000
         ST    TEMP3,TEMPSAVE          SAVE CONTENTS OF REG 3      4304 06303019
         L     TEMP3,FREEA             USE REG 3 TO ESTAB ADDRESS  4304 06306019
         USING FREECOR,TEMP3           FOR FREECOR DSECT           4304 06309019
         ST    RZ,LITS                 STORE LIT LENG FOR FREE     4304 06312019
         MVI   MAIN4,X'10'             TURN LIT GET MAIN SWTCH     4304 06315019
         GETMAIN R,LV=(0)                                               06320000
         ST    R1,LITADD           STORE LITERAL POOL ADDRESS           06340000
         ST    R1,LITA                 SAVE LITS FOR FREEMAIN      4304 06345019
         L     TEMP3,TEMPSAVE          RESTORE REG 3 CONTENTS      4304 06350019
         DROP  3                                                   4304 06355019
GSEND    B     CSCANZ              B TO MESS-SAVE LOAD ROUTINE          06360000
GSMCBNO  MVC   PLANT(2),PH12       CAUSE BRANCH AT CSCAN12              06380000
         B     CSCANZ              BRANCH TO MESS-SAVE LOAD ROUTINE     06400000
*              MESSAGE SET-UP                                           06420000
PPERRH   ST    R14,REGSAV          SAVE RETURN POINT               SA0I 06425018
         BAL   R14,TISTIC          CALCULATE COLUMN NUMBER         SA0I 06430018
         L     R14,REGSAV          RESTORE CALLERS ADDRESS         SA0I 06435018
         LA    RZ,31               MESSAGE DISPLACEMENT            SA0I 06440018
         LA    R1,PPIK             MESSAGE POINTER                 SA0I 06445018
         MVC   SEYLE(4),VPPIKM     MOVE IN MESSAGE LOCATION        SA0I 06450018
         B     HOWIE1              PUT COLUMN NUMBER IN MSG        SA0I 06455018
PPERRI   ST    R14,REGSAV          SAVE RETURN POINT               SA0I 06460018
         BAL   R14,TISTIC          CALCULATE COLUMN NUMBER         SA0I 06465018
         L     R14,REGSAV          RESTORE CALLERS ADDRESS         SA0I 06470018
         LA    RZ,33               MESSAGE DISPLACEMENT            SA0I 06475018
         LA    R1,PPMK             MESSAGE POINTER                 SA0I 06480018
         MVC   SEYLE(4),VPPMKM     MOVE IN MESSAGE LOCATION        SA0I 06485018
         B     HOWIE1              PUT COLUMN NUMBER IN MSG        SA0I 06490018
PPERRJ   ST    R14,REGSAV          SAVE RETURN POINT               SA0I 06495018
         BAL   R14,TISTIC          CALCULATE COLUMN NUMBER         SA0I 06500018
         L     R14,REGSAV          RESTORE CALLERS ADDRESS         SA0I 06505018
         LA    RZ,32               MESSAGE DISPLACEMENT            SA0I 06510018
         LA    R1,PPIP             MESSAGE POINTER                 SA0I 06515018
         MVC   SEYLE(4),VPPIPM     MOVE IN MESSAGE LOCATION        SA0I 06520018
         B     HOWIE1              PUT COLUMN NUMBER IN MSG        SA0I 06525018
PPERRL   ST    R14,REGSAV          SAVE RETURN POINT               SA0I 06530018
         BAL   R14,TISTIC          CALCULATE COLUMN NUMBER         SA0I 06535018
         L     R14,REGSAV          RESTORE CALLERS ADDRESS         SA0I 06540018
         LA    RZ,34               MESSAGE DISPLACEMENT            SA0I 06545018
         LA    R1,PPMP             MESSAGE POINTER                 SA0I 06550018
         MVC   SEYLE(4),VPPMPM     MOVE IN MESSAGE LOCATION        SA0I 06555018
         B     HOWIE1              PUT COLUMN NUMBER IN MSG        SA0I 06560018
         EJECT                                                          06580000
*                                                                       06600000
*              EXAMINE COMMAND WORD                                     06620000
*                                                                       06640000
CDSKIP   OI    PPWORK,BYPASS       SET BYPASS SWITCH-NO COMMAND         06660000
*                                                                       06680000
CSCAN    LA    ERREG,PPERRQ        ADDRESS OF MSG RTN              SA0I 06700018
         MVI   COMMSW,X'0'         SET COMMAND SWITCH                   06720000
         BAL   BREG,CALLSCAN       BRANCH TO CCS02                 SA0I 06740018
CSCAN1   OI    BITS,X'01'          TURN OFF SECOND CARD SWITCH     SA0I 06750018
         TM    PPWORK,COMM         TEST FOR COMMAND                SA0I 06760018
         BZ    CDSKIP              NOT COMMAND - SKIP REST OF CARD      06780000
PKUP5    CLC   CTITLE(6),0(R1)    TEST FOR TITLE COMMAND           SA0I 06810018
         BE    TITLEC             HAVE TITLE COMMAND                    06840000
         CLC   CEXITS(6),0(R1)    TEST FOR EXITS COMMAND           SA0I 06860018
         BE    EXITSC              HAVE EXITS COMMAND                   06880000
         CLC   CMEMBER(7),0(R1)   TEST FOR MEMBER COMMAND          SA0I 06900018
         BNE   CSCAN8              NOT MEMBER COMMAND                   06920000
         CLC   MASK(2),PH12        TEST IF BRANCH SPECIFIED             06940000
         BE    PICK                YES-NO MEMBERS                  SA0I 06960018
         B     MEMBERC             SKIP TO MSG WHEN MNT FULL            06980000
CSCAN8   CLC   CRECORD(7),0(R1)   TEST FOR RECORD COMMAND          SA0I 07000018
         BNE   TSTLBLS                                             UL0H 07020017
         CLC   SKIPSW(2),PH12      TEST IF BRANCH SPECIFIED             07040000
         BE    CDSKIP             YES-SKIP RECORD SWITCH                07060000
         CLC   PLANT(2),PH12      TEST IF BRANCH SPECIFIED              07080000
         BE    PPERRQ              BRANCH TO ERROR MSG             SA0I 07100018
         B     RECORDC            HAVE RECORD COMMAND                   07120000
*                                                                       07140000
TSTLBLS  CLC   CLABELS(7),0(R1)   TEST FOR LABELS COMMAND          SA0I 07145018
         BE    LABLSC                                              UL0H 07150017
         B     PPERRQ              BRANCH TO ERROR MSG             SA0I 07155018
CSCANZ   LA    ERREG,PPERRQ        ADDRESS OF MSG RTN              SA0I 07165018
         L     RZ,LENSAVE          LOAD TABLE LENGTH                    07180000
         L     R1,LOCSAVE          LOAD TABLE ADDRESS                   07200000
         B     CSCAN1              BRANCH TO COMMAND TEST               07220000
*                                                                       07240000
*                                                                       07260000
CALLSCAN CALL  IEBCCS02,(PPWORK,PPSYSI)                                 07280000
*                                                                       07300000
*                                                                       07302019
*      I / O   E R R O R   H A N D L I N G   F O R   S Y S I N     7715 07304019
*                                                                  7715 07306019
         TM    PPWORK+144,X'02'   TEST FOR I/O ERROR ON SYSIN      7715 07308019
         BZ    NOERR              BRANCH IF NO TO NORMAL PROCESSING7715 07310019
         LA    R7,MSGSYNDF        GET ADDRESS OF MSG AREA          7715 07312019
         LA    R7,18(R7)          INCREMENT ADDR PAST MSG ID       7715 07314019
         MVC   0(79,R7),0(R1)     MOVE SYNAD. MSG TO AREA TO PR. A54086 07316021
         ST    R1,FREESYND        SAVE ADDR OF SYNADAF MSG TO FREE 7715 07318019
         LA    R1,MSGSYNDF        LOAD REG 1 WITH AREA ADDR        7715 07320019
         LA    R0,96              LOAD REG 0 WITH AREA LENGTH      7715 07322019
         MVI   PPCONCD,X'0C'      SET RETURN CODE                  7715 07324019
         L     R15,VZZPR          GET ADDR OF MSG WRITER IN PPUN1  7715 07326019
         BALR  R14,R15            GO WRITE SYNADAF I/O ERROR INFO  7715 07328019
         L     R1,FREESYND        GET ADDR OF MSG IN DYNAMIC CORE  7715 07330019
         LA    R0,79              GET MESS. LENGTH TO FREE CORE  A54086 07332021
         FREEMAIN  R,LV=(0),A=(1)                                  7715 07334019
         B     PPRET              GO TO RETURN ROUTINE             7715 07336019
NOERR    ST    RZ,LENSAVE         SAVE TABLE LENGTH TO REFERENCE   7715 07338019
         ST    R1,LOCSAVE         SAVE TABLE ADDRESS                    07340000
         TM    PPWORK+WORKLEN-1,NEWCD   TEST FOR NEW CARD               07360000
         BZ    CALLS4                   NO-BRANCH AROUND CARD WRITE     07380000
         LA    R1,PPWORK+1         ADDRESS OF WRITE AREA                07400000
         L     R15,CDWRT           LOAD ADDRESS OF CARD WRITER          07420000
         BALR  R14,R15             BRANCH TO CARD WRITE EXTERN          07440000
         L     R1,LOCSAVE          RELOAD TABLE ADDRESS                 07460000
         L     RZ,LENSAVE          RELOAD TABLE LENGTH                  07480000
CALLS4   TM    PPWORK+WORKLEN-1,RIO     TEST FOR I/O ERROR ON SYSIN     07500000
         BO    IOERRIN             I/O ERROR ON SYSIN                   07520000
         TM    PPWORK,ERROR        TEST FOR ERROR                       07580000
         BO    TESTO               BRANCH TO ERROR BIT ANALYSIS    SA0I 07586018
         TM    PPWORK,EOF          TEST FOR END OF FILE                 07587018
         BO    PPEOF               YES-BRANCH TO EOF RTN                07588018
         MVI   SYSIN,X'FF'         SW TO INDICATE SYSIN NOT EMPTY       07589018
         TM    PPWORK,BYPASS       IS BYPASS BIT ON                SA0I 07592018
         BCR   8,BREG                                                   07602018
HOWIE    TM    PPWORK,X'01'        IS END PARAMETER ON?            SA0I 07622018
         BZ    CALLSCAN            BRANCH TO CALL RTN              SA0I 07628018
         BR    BREG                RETURN TO LINK POINT            SA0I 07634018
*                                                                       07640000
PPERRC   LA    RZ,1                MESSAGE DISPLACEMENT                 07660000
         LA    R1,PTERM1           MESSAGE POINTER                      07680000
PPERR    BAL   R14,PREMSG          BRANCH TO MESSAGE WRITER             07700000
         MVI   PPCONCD,X'0C'       SET CONDITION CODE TO TWELVE         07720000
         TM    PPWORK+WORKLEN-1,RIO TEST FOR I/O ERROR ON SYSIN    9989 07726013
         BO    PPRET              IF ERROR, BR TO RETURN ROUTINE   9989 07732013
         LA    BREG,CSCAN1         ADDR COMMAND TEST               SA0I 07741018
         OI    BIT,X'01'           TURN OFF FIRST CARD BIT(IF ON)  SA0I 07750018
ERRENDA  OI    PPWORK,BYPASS       SET BYPASS SWITCH                    07760000
         NI    PPWORK+81,X'FC'       TURN OFF KEYWORD AND PARAMETER     07761018
*                                  REQUIRED BITS                   SA0I 07762018
         NI    PPWORK+129,X'00'    SET PARENTH COUNTER TO ZERO   A52039 07762421
         B     CALLSCAN            BRANCH TO CCS02                 SA0I 07763018
TESTO    TM    PPWORK+130,X'02'    IS  MISSING END OF PARENTHESIS       07764018
*                                  BIT ON?                         SA0I 07765018
         BO    PPERRY              YES-WRITE ERROR MSG             SA0I 07766018
         TM    PPWORK,BYPASS       IS BYPASS ON                    SA0I 07767018
         BZ    PPERRS              WRITE ERROR MSG                 SA0I 07768018
HAHA1    TM    PPWORK,COMM         IS COMMAND ON                   SA0I 07769018
         BO    HAHA                YES-BRANCH                      SA0I 07770018
         TM    PPWORK,KEYW         IS KEYWORD ON                   SA0I 07771018
         BZ    HAHA2               NO-CONTINUE                     SA0I 07772018
         B     PPERRH              WRITE ERROR MSG                 SA0I 07773018
HAHA2    TM    PPWORK,PAR          IS PARAMETER ON                 SA0I 07774018
         BZ    HAHA3               NO-CONTINUE                     SA0I 07775018
         B     PPERRJ              WRITE ERROR MSG                 SA0I 07776018
HAHA3    TM    PPWORK+81,X'02'     IS KEYWORD EXPECTED ON?         SA0I 07777018
         BZ    HAHA4               NO-CONTINUE                     SA0I 07778018
         B     PPERRI              WRITE ERROR MSG                 SA0I 07779018
HAHA4    TM    PPWORK+81,X'01'     IS PARAMETER EXPECTED ON?       SA0I 07780018
         BZ    PPERRT              NO-CONTINUE                     SA0I 07781018
         B     PPERRL              WRITE ERROR MSG                 SA0I 07782018
HAHA     TM    PPWORK,PAR          IS PARAMETER ON                 SA0I 07783018
         BO    PPERRN              YES-BRANCH                      SA0I 07784018
         TM    PPWORK,KEYW         IS KEYWORD ON                   SA0I 07785018
         BO    PPERRN              YES-BRANCH                      SA0I 07786018
         B     PPERRQ              WRITE ERROR MSG                 SA0I 07787018
         EJECT                                                          07800000
*                                                                       07820000
*********************************************************************** 07840000
*WRAP-UP ROUTINE FOR THE ANALYZER. PRINTS EOF ON SYSIN MESSAGE. CHECKS* 07860000
*THAT MAX LINES NOT EXCEEDED. PLACES IN MEMBER NAME TABLE THE NUMBER  * 07880000
*OF MEMBERS TO BE PRINTED OR PUNCHED. RETURNS TO THE ROOT SEGMENT.    * 07900000
*********************************************************************** 07920000
*                                                                       07940000
PPEOF    TM    SYSIN,X'FF'         IS SYSIN EMPTY                A21407 07944018
         BZ    USERROR             YES, USER ERROR               A21407 07950018
         CLI   PPCONCD,X'0C'           IS RETURN CODE=12           SA0I 07956018
         BE    SYSMS               YES,END OF ANALYSIS             SA0I 07960018
         TM    COMMSW,RCOMM        TEST IF LAST COMMAND WAS RCD    SA0I 07970018
         BZ    PPEOFA              NO - BRANCH TO MAXLINE TEST          07980000
         TM    RECORDSW,FIRSTR     HAS MCB ADDRESS BEEN ENTERED IN MNT  08000000
         BO    PPEOFA1             HAS BEEN ENTERED                     08020000
         LH    TEMP1,0(MCBPTER)    LOAD MCB                             08040000
         AH    TEMP1,PH1           ADD ONE TO MCB LEN                   08060000
         STH   TEMP1,0(MCBPTER)    STORE IN MCB                         08080000
         L     MNTPTER,CURRMNT     LOAD MEMBER NAME TABLE ADDRESS       08100000
         ST    MCBPTER,8(MNTPTER)  STORE ADDRESS OF MCB IN MNT          08120000
         B     PPEOFA              BRANCH TO MAXLINE TEST               08140000
PPEOFA1  TM    TYPORG,1      PARTITIONED ORGANIZED ?             A36048 08160021
         BNZ   PPEOFA        YES                                 A36048 08170021
         LH    RZ,RECDCNT    NO, STORE GCB NUMBER FOR DATA SET   A36048 08172021
         LTR   RZ,RZ               IDENT KEYWORD                        08180000
         BE    PPEOFA              NONE-BRANCH TO MAXLINE TEST          08200000
         L     R1,MCBADD           LOAD MEMBER CONTROL BLOCK ADDRESS    08220000
         STH   RZ,0(R1)            STORE IDENT IN MCB                   08240000
PPEOFA   LH    R1,PMAXLINE         DO TEST FOR                    M4118 08260018
         LTR   R1,R1               MAXLINE KEYWORD                      08280000
         BZ    PPEOFA9             MAXLINE NOT SPECIFIED                08300000
         TM    TITLESW,X'01'       TEST FOR TITLE                       08320000
         BO    ADDONE              HAVE TITLE - BRANCH TO TITLE ROUTINE 08340000
         CLC   PPCTL(1),PMAXLINE+1  COMPARE SPACING TO MAXIMUM LINES    08360000
         BL    PPEOFA9             SPACE INCREMENT LESS THAN MAX LINES  08380000
         L     R1,MAXMSG     LOAD ERROR MSG ROUT. ADDRESS        A38738 08400021
         MVC   0(7,R1),KMAXLINE  MOVE MAXLINE IN MESSAGE         A38738 08410021
         B     MAXERROR                                          A38738 08412021
ADDONE   SR    R1,R1               ZERO OUT REGISTER                    08420000
         SR    RZ,RZ               ZERO OUT REGISTER                    08440000
         IC    RZ,PPCTL            LOAD SPACE FACTOR                    08460000
         LA    R1,1(R1)            ALLOW ONE SPACE FOR HEADER           08480000
         AR    R1,RZ               ADD SPACES BETWEEN HEADERS           08500000
         CLI   TITLESW,X'03'       TEST FOR SUBTITLE ALSO          5790 08520019
         BNE   COMPARE1            BRANCH IF NO SUBTITLE           5790 08540019
         LA    R1,1(R1)            ADD ONE SPACE FOR SUBTITLE           08560000
         AR    R1,RZ               ADD SPACES FOLLOWING SUBTITLE        08580000
COMPARE1 CH    R1,PMAXLINE         TEST IF AT OR OVER MAXIMUM LINES     08600000
         BL    PPEOFA9             NO - OK                              08620000
PPEOFA8  ST    R14,REGSAV          SAVE RETURN POINT               SA0I 08626018
         BAL   R14,TISTIC          CALCULATE COLUMN NUMBER         SA0I 08632018
         L     R14,REGSAV          RESTORE CALLERS ADDRESS         SA0I 08638018
         LA    RZ,31               MESSAGE DISPLACEMENT            SA0I 08644018
         LA    R1,PPIK             MESSAGE POINTER                 SA0I 08650018
         LA    TEMP4,30            LOAD DISPLACEMENT               SA0I 08656018
         A     TEMP4,VPPIKM        POSITION FOR INSERTING COLUMN   SA0I 08662018
         MVC   0(2,TEMP4),FULL+2   MOVE TO COLUMN NUMBER           SA0I 08668018
PPTERM   BAL   R14,PREMSG               PRINT MESSAGE                   08680017
         MVI   PPCONCD,X'0C'       SET CONDITION CODE TO TWELVE         08700000
PPEOFA9  LA    RZ,EOFCDE           MESSAGE CODE                         08720000
         LA    R1,PEOF             MESSAGE POINTER                      08740000
         LA    R14,PPEND           RETURN ADDRESS FROM PRINT = WRAPUP   08760000
         B     PREMSG              BRANCH TO MESSAGE WRITE              08780000
*                                                                       08800000
USERROR  LA    RZ,NOSYSIN          MESSAGE CODE                  A21407 08801018
         LA    R1,42               MESSAGE OFFSET                A21407 08802018
         BAL   R14,PREMSG          BRANCH TO MESSAGE WRITER      A21407 08803018
         MVI   PPCONCD,X'0C'       SET CONDITION CODE TO TWELVE  A21407 08804018
         B     PPRET               BRANCH TO RETURN ROUTINE      A21407 08805018
*                                                                     * 08806018
*                                                                     * 08812018
IOERRIN  LA    RZ,7                MESSAGE CODE FOR I/O ERROR ON SYSIN  08820000
         LA    R1,PEOJIO           MESSAGE POINTER                      08840000
         B     PPERR               BRANCH TO WRITE LINK                 08860000
*                                                                       08880000
PPERRCD  LA    RZ,9                MESSAGE CODE                         08900000
         LA    R1,SYNTMSG          MESSAGE POINTER                      08920000
         B     PPERR               BRANCH TO WRITE LINK                 08940000
*                                                                       08960000
PPERRN   ST    R14,REGSAV          SAVE RETURN POINT               SA0I 08963018
         BAL   R14,TISTIC          CALCULATE COLUMN NUMBER         SA0I 08966018
         L     R14,REGSAV          RESTORE CALLERS ADDRESS         SA0I 08969018
         LA    RZ,35               MESSAGE DISPLACEMENT            SA0I 08972018
         LA    R1,PPMC             MESSAGE POINTER                 SA0I 08975018
         MVC   SEYLE(4),VPPMCM     MOVE IN MESSAGE LOCATION        SA0I 08978018
HOWIE1   LA    TEMP4,30            LOAD DISPLACEMENT               SA0I 08981018
         A     TEMP4,SEYLE         POSITION FOR INSERTING COLUMN   SA0I 08984018
         MVC   0(2,TEMP4),FULL+2   MOVE TO COLUMN NUMBER           SA0I 08987018
         B     PPERR               BRANCH TO WRITE LINK            SA0I 08990018
PPERRQ   LA    RZ,36               MESSAGE DISPLACEMENT            SA0I 08993018
         LA    R1,PPIC             MESSAGE POINTER                 SA0I 08996018
         B     PPERR               BRANCH TO WRITE LINK            SA0I 08999018
PPERRR   LA    RZ,37               MESSAGE DISPLACEMENT            SA0I 09002018
         LA    R1,PPIL             MESSAGE POINTER                 SA0I 09005018
         B     PPERR               BRANCH TO WRITE LINK            SA0I 09008018
PPERRS   LA    RZ,38               MESSAGE DISPLACEMENT            SA0I 09011018
         LA    R1,PPIN             MESSAGE POINTER                 SA0I 09014018
         BAL   R14,PREMSG          BRANCH TO MSG WRITER            SA0I 09017018
         TM    PPWORK+WORKLEN-1,RIO TEST FOR I/O ERROR ON SYSIN    SA0I 09020018
         BO    PPRET               IF ERROR,RETURN                 SA0I 09023018
         CLI   BIT,X'01'           IS THIS THE FIRST CARD?         SA0I 09026018
         BE    GOB                 NOT FIRST CARD-BRANCH           SA0I 09029018
         LA    BREG,PTCOM          ADDR COMMAND TEST-PT OR PCH     SA0I 09032018
         B     CALLSCAN            BRANCH TO CCS02                 SA0I 09035018
GOB      CLI   BITS,X'01'          IS THIS THE SECOND CARD?        SA0I 09038018
         BE    GOA                 NOT SECOND CARD-BRANCH          SA0I 09041018
         BAL   BREG,CALLSCAN       BRANCH TO CCS02                 SA0I 09044018
         B     GETSTOR             GET STORAGE FOR TABLES          SA0I 09047018
GOA      LA    BREG,CSCAN1         ADDR COMMAND TEST               SA0I 09050018
         B     CALLSCAN            BRANCH TO CCS02                 SA0I 09053018
PPERRT   LA    RZ,39               MESSAGE DISPLACEMENT            SA0I 09056018
         LA    R1,PPBC             MESSAGE POINTER                 SA0I 09059018
         B     PPERR               BRANCH TO WRITE LINK            SA0I 09062018
PPERRU   LA    RZ,41               MESSAGE DISPLACEMENT            SA0I 09065018
         LA    R1,41               MESSAGE POINTER                 SA0I 09068018
         B     PPERR               BRANCH TO WRITE LINK            SA0I 09071018
PPERRY   LA    RZ,40               MESSAGE DISPLACEMENT            SA0I 09074018
         LA    R1,40               MESSAGE POINTER                 SA0I 09077018
         B     PPERR               BRANCH TO WRITE LINK            SA0I 09080018
SYSMS    LA    RZ,EOFCDE           MESSAGE CODE                    SA0I 09083018
         LA    R1,PEOF             MESSAGE POINTER                 SA0I 09086018
         LA    R14,PPRET           RETURN ADDRESS                  SA0I 09089018
         B     PREMSG              BRANCH TO MSG WRITE             SA0I 09092018
*                                                                       09100000
PPEND    TM    TYPORG,1            TEST FOR PARTITIONED ORGANIZATION    09120000
         BZ    PPENDA              NO-BRANCH AROUND MEMBER TEST         09140000
         TM    GETMA,X'10'   GETM. FOR FI AND REC PARAM. ?       A36090 09142021
         BNO   SKIPLCO       NO, SKIP                            A36090 09144021
         LH    R1,RECDCNT    LAST COUNT WAS NOT                  A36090 09150021
         STH   R1,0(MCBPTER) NOT FILLED IN                       A36090 09152021
SKIPLCO  LH    MEMCT,MEMBCT  LOAD MEMBERCOUNT                    A36090 09160021
         LTR   MEMCT,MEMCT         TEST FOR NAMED MEMBERS               09180000
         BE    PPENDA              NO NAMED MEMBERS                     09200000
         L     MNTPTER,MNTADD      LOAD ADDRESS OF MEMBER NAME TABLE    09220000
         ST    MEMCT,0(MNTPTER)    STORE MEMBER COUNT IN MEMB NAME TAB  09240000
         B     PPRET               BRANCH TO RESTORE-RETURN ROUTINE     09260000
PPENDA   L     MCBPTER,MCBADD      LOAD ADDRESS OF MEMBER CONTROL BLOCK 09280000
         TM    GETMA,X'10'         GETM. FOR FI AND REC PARAM. ? A52055 09290021
         BNO   MNTZERO             NO, SKIP                      A52055 09292021
         LH    R1,0(MCBPTER)       LOAD MEMBER COUNT                    09300000
         LTR   R1,R1               TEST FOR RECORD GROUPS               09320000
         BH    PPRET               HAVE RECORD GROUPS - BRANCH TO EXIT  09340000
MNTZERO  MVC   MNTADD(4),PDZERO    REMOVE PNTER TO MNT-NO REC GR A52055 09360021
PPRET    SR    R15,R15             ZERO RETURN CODE REGISTER            09380000
         IC    R15,PPCONCD         INSERT RETURN CODE                   09400000
         L     R13,SAVEADD+4       LOAD SAVE REGISTER                   09420000
         ST    TREG,24(R13)        SAVE DSECT BASE                      09440000
         RETURN   (14,12),RC=(15)                                       09460000
*                                                                       09480000
*                                                                       09500000
*        CONVERT PARAMETER TO BINARY                                    09520000
SETPBIN  LR    TEMP1,RZ            LOAD PARAMETER LENGTH                09540000
         LR    TEMP2,R1            LOAD PARAMETER ADDRESS               09560000
         LTR   TEMP1,TEMP1         TEST  PARAMETER LENGTH               09580000
         BH    SETPB2              HAVE PARAMETER                       09600000
         SR    PREG,PREG           SET LENGTH INDICATOR TO ZERO         09620000
         BR    BREG                BRANCH BACK                          09640000
SETPB2   CLI   0(TEMP2),C'0'       TEST FOR NUMERIC CHARACTER           09660000
         BL    0(ERREG)            PARAMETER IS NON-NUMERIC             09680000
         CLI   0(TEMP2),C'9'       TEST AGAINST HIGHEST NUMERIC         09700000
         BH    0(ERREG)            HIGH NON-NUMERIC                     09720000
         AH    TEMP2,PH1           INCREMENT LOCATION BY ONE            09740000
         BCT   TEMP1,SETPB2        CONTINUE THROUGH PARAMETER           09760000
         BCTR  RZ,RZ               SUBTRACT ONE FROM PARAMETER LENGTH   09780000
         STC   RZ,SETPB4+1                                              09800000
         OI    SETPB4+1,X'70'                                           09820000
SETPB4   PACK  DBLWD(8),0(1,R1)    PACK INTO CONVERSION AREA            09840000
         CVB   PREG,DBLWD          CONVERT PARAMETER TO BINARY          09860000
         LTR   PREG,PREG           TEST FOR NEGATIVE VALUE              09880000
         BL    0(ERREG)            NEGATIVE IS ERROR                    09900000
         BR    BREG                BRANCH BACK                          09920000
         EJECT                                                          09940000
*                                                                       09960000
*                                                                       09980000
*        COMMAND = TITLE                                                10000000
*                                                                       10020000
*                                                                       10040000
TITLEC   LA    ERREG,CDSKIP        ADDRESS OF CARD SKIP ROUT            10060000
         OI    PPWORK+81,X'02'     SET ON KEYWORD REQUIRED BIT     SA0I 10070018
         BAL   BREG,CALLSCAN       BRANCH TO CCS02                 SA0I 10080018
         NI    PPWORK+81,X'FD'     SET OFF KEYWORD REQUIRED BIT    SA0I 10090018
         TM    PPWORK,KEYW         TEST FOR KEYWORD                     10100000
         BZ    PPERRI              ERROR IF NO KEYWORD AFTER TITLE SA0I 10130018
         GETMAIN R,LV=144              FOR MAX POSS. LRECL-1     A52039 10160021
         ST    TEMP3,TEMPSAVE          SAVE CONTENTS OF REG 3      4304 10162019
         L     TEMP3,FREEA             USE REG 3 TO ESTAB ADDRESS  4304 10164019
         USING FREECOR,TEMP3           FOR FREECOR DSECT           4304 10166019
         TM    MAIN5,X'10'             TEST FRST TITLE SWTCH ON?   4304 10168019
         BZ    TITLE1                  NO-THIS MUST BE FIRST       4304 10170019
         MVI   MAIN6,X'10'              SET SWITCH FOR A SUBTITLE  4304 10172019
         ST    R1,SUBTITA              SAVE SUBTITLE ADDRESS       4304 10174019
         B     SKIPTITL                MISS FIRST TITLE SETTING    4304 10176019
TITLE1   MVI   MAIN5,X'10'             SET FIRST TITLE SWTCH       4304 10178019
         ST    R1,TITLA                SAVE TITLE ADDRESS          4304 10180019
SKIPTITL L     TEMP3,TEMPSAVE          RESTORE REG 3 CONTENTS      4304 10182019
         DROP  3                                                   4304 10184019
         MVI   0(R1),C' '              BLANK FIRST BYTE OF TITLE   4304 10186019
         MVC   1(143,R1),0(R1)     BLANK TITLE AREA              A52039 10200021
         TM    TITLESW,X'01'       TEST FOR FIRST TITLE                 10220000
         BO    SUBTC               NOT FIRST, THEREFORE SUBTITLE        10240000
         OI    TITLESW,X'01'       SET TITLE SWITCH FOR SUBTITLE        10260000
         LA    TCBR,TCB1           ADDRESS OF TITLE CONTROL BLOCK       10280000
         B     TITLEADD            SKIP SUBTITLE ROUTINE                10300000
SUBTC    TM    TITLESW,X'02'       TEST FOR FORMATTED SUBTITLT          10320000
         BO    TMULT               SUBTITLE ALREADY FORMATTED           10340000
         LA    TCBR,TCB2           ADDRESS OF SUBTITLE CONTROL BLOCK    10360000
         OI    TITLESW,X'02'       SET TITLE SWITCH FOR FORMATTED SUBT  10380000
TITLEADD ST    R1,4(TCBR)          STORE ADDRESS OF TITLE IN TCB        10400000
         MVC   0(4,TCBR),PDZERO    ZERO FIRST WORD OF TCB               10420000
         L     RZ,LENSAVE          LOAD LIST LENGTH                     10440000
         L     R1,LOCSAVE          LOAD LIST ADDRESS                    10460000
         B     TITLEK1             BRANCH TO ITEM TEST                  10480000
*              SCAN FOR FIELD KEYWORD                                   10500000
TITLEK   LA    ERREG,PPERRH        ADDRESS OF MSG RTN              SA0I 10520018
         BAL   BREG,CALLSCAN       BRANCH TO CCS02                 SA0I 10540018
         TM    PPWORK,KEYW         TEST FOR KEYWORD                     10560000
         BZ    TKEYNO              NO-BRANCH TO NO KEYWORD ROUTINE      10580000
*                                                                       10600000
*              COMMAND = TITLE,IS KEYWORD FIELD                         10620000
*                                                                       10640000
         NI    PPWORK+81,X'FD'     SET OFF KEYWORD REQUIRED BIT    SA0I 10650018
TITLEK1  CLC   KITEM(5),0(R1)     TEST FOR ITEM KEYWORD            SA0I 10660018
         BNE   PPERRH              NO-BRANCH TO MSG RTN            SA0I 10670018
         CLI   5(R1),X'4D'        TEST FOR LEFT PARENTHESIS      13695  10686015
         BNE   PPERRY                                             M3311 10693018
*                                                                       10700000
*              GET PARAMETERS FOR TITLE FIELD                           10720000
*                                                                       10740000
         LA    ERREG,PPERRJ        ADDRESS OF MESSAGE ROUTINE      SA0I 10760018
         LA    PARLIST,TITLEP2     ADDRESS OF LITERAL TEST              10780000
TITLEP   OI    PPWORK+81,X'01'     SET ON PARAMETER REQUIRED BIT   SA0I 10790018
         BAL   BREG,CALLSCAN       BRANCH TO CALL RTN              SA0I 10800018
         NI    PPWORK+81,X'FE'     SET OFF PARAMETER REQUIRED BIT  SA0I 10810018
         TM    PPWORK,PAR          TEST FOR PARAMETER                   10820000
         BZ    PPERRL              MISSING PARAMETER               SA0I 10840018
         BR    PARLIST             EVALVATE PARAMETER                   10860000
*                                                                       10880000
TITLEP2  CH    RZ,PH3              IS LITTERAL SMALLER TH 3 ?    A52039 10900021
         BL    PPERRJ              YES,BRANCH TO ERROR MSG SA0I  A52039 10906021
         CH    RZ,LIT42            IS LITERAL GT 42 ALLOWING FOR A25956 10914018
*                                  END QUOTES                    A25956 10922018
         BH    PPERRR              YES-BRANCH TO ERROR MSG         SA0I 10930018
         LA    PARLOC,1            LOAD 1                               10940000
         AR    PARLOC,R1           LOCATION OF LITERAL                  10960000
         LR    RLIT,RZ             LOAD LENGTH                          10980000
         SH    RLIT,PH2            LITERAL LENGTH                       11000000
         TM    PPWORK,PARP         TEST IF LAST PARAMETER               11060000
         BO    TP5                 BRANCH TO LENGTH SET                 11080000
         LA    PARLIST,TITLEP3     ADDRESS OF LITERAL ROUTINE           11100000
         B     TITLEP              TEST FURTHER PARAMETERS              11120000
*                                                                       11140000
TITLEP3  LTR   RZ,RZ               TEST OUTPUT LOCATION                 11160000
         BE    TP5                 ZERO = FIRST LOCATION                11180000
         BAL   BREG,SETPBIN        BRANCH TO CVB ROUTINE                11200000
         BE    TP4                                                      11220000
         BCTR  PREG,RZ             SUBTRACT ONE FROM LENGTH             11280000
TP4      LR    TEMP1,PREG          LOAD LENGTH                          11300000
         AR    TEMP1,RLIT          ADD LITERAL LENGTH                   11320000
         CH    TEMP1,MAXOUT1       COMPARE TO MAXIMUM OUTP.LNG.  A52039 11340021
         BH    PPERRR              PRINT ERRMSG IEB437I          A52039 11390021
         CH    TEMP1,2(TCBR)       LARGEST END OF BOUNDARY ?     A52039 11400021
         BL    SKPSTOR             NO, DON'T SAVE THE LENGTH     A52039 11410021
         STH   TEMP1,2(TCBR)       STORE END OF LITT. LOC.       A52039 11420021
SKPSTOR  A     PREG,4(TCBR)        ADD TITLE ADDRESS             A52039 11440021
TMVC     MVC   0(1,PREG),0(PARLOC) MOVE LITERAL TO TITLE           3718 11444015
         CLI   0(PARLOC),X'7D'     COMPARE FOR QUOTE               3718 11448015
         BNE   HOWIE8              NOT A QUOTE,BRANCH AROUND     A52039 11452021
         LA    PARLOC,1(0,PARLOC)  ADD ONE                         3718 11456015
         BCT   RLIT,HOWIE7         SUBTRACT ONE FROM LENGTH        SA0I 11460018
         B     PPERRR              ONE LITTERAL -- ERROR         A52039 11464021
HOWIE8   LA    PARLOC,1(0,PARLOC)  ADD ONE                         SA0I 11468018
         LA    PREG,1(0,PREG)      ADD ONE                         3718 11472015
         BCT   RLIT,TMVC           SUBTRACT ONE FROM LENGTH & LOOP 3718 11476015
         MVC   0(2,TCBR),MAXOUT1   MAXIMUM OUTPUT LENGTH TO TCB  A52039 11480021
         B     TITLEK              CONTINUE                             11500000
HOWIE7   CLI   0(PARLOC),X'7D'     COMPARE FOR QUOTE               SA0I 11505018
         BNE   PPERRR              INVALID LITERAL MSG             SA0I 11510018
         B     HOWIE8              CONTINUE THROUGH LITERAL        SA0I 11515018
*                                                                       11520000
*                                                                       11540000
TP5      SR    PREG,PREG           ZERO PARAM LENGTH INDIC              11560000
         B     TP4                 BRANCH TO LENGTH TEST                11580000
*                                                                       11600000
*                                                                       11620000
*                                                                       11660000
TKEYNO   TM    PPWORK,PAR          TEST FOR PARAMETER                   11680000
         BZ    CSCANZ              NO PARAMETER - BRANCH TO SCAN        11700000
         LTR   RZ,RZ               TEST FOR PARAMETER LENGTH            11720000
         BE    TITLEK              LENGTH ZERO,BRANCH TO FIELD SCAN     11740000
         B     PPERRJ              BRANCH TO ERROR MSG             SA0I 11760018
*                                                                       11780000
TMULT    LA    RZ,PTMULT           MESSAGE CODE                         11800000
         LA    R1,3                MESSAGE OFFSET                       11820000
         B     PPERR               BRANCH TO WRITE LINK                 11840000
TCDPERR  LA    RZ,5                MESSAGE CODE                         11860000
         LA    R1,PPAR             MESSAGE OFFSET                       11880000
         B     PPERR               BRANCH TO WRITE LINK                 11900000
TCDKERR  LA    RZ,4                MESSAGE CODE                         11920000
         LA    R1,PKEY             MESSAGE OFFSET                       11940000
         B     PPERR               BRANCH TO WRITE LINK                 11960000
TISTIC   LA    TEMP3,1             LOAD DISPLACEMENT FACTOR        SA0I 11962018
         AR    TEMP3,R1            ADD CCS02 POINTER LOCATION      SA0I 11964018
         LA    TEMP4,PPWORK+1      LOAD ADDRESS WORK AREA          SA0I 11966018
         SR    TEMP3,TEMP4         CALCULATE COLUMN NUMBER         SA0I 11968018
         CVD   TEMP3,DOUBLE        CONVERT TO DECIMAL              SA0I 11970018
         OI    DOUBLE+7,X'03'      SET FIELD                       SA0I 11972018
         UNPK  FULL,DOUBLE+4(4)    SET UP FOR EBCDIC PRINTOUT      SA0I 11974018
         BCR   15,R14              RETURN TO CALLER                SA0I 11976018
         EJECT                                                          11980000
*                                                                       12000000
*              COMMAND = EXITS                                          12020000
*                                                                       12040000
EXITSC   OI    PPWORK+81,X'02'     TURN ON KEYWORD REQ BIT         8397 12050019
EXITSCN  LA    ERREG,CDSKIP        ADDRESS OF SKIP ROUTINE         8397 12060019
         BAL   BREG,CALLSCAN       BRANCH TO CCS02                 SA0I 12070018
         TM    PPWORK,PAR          TEST FOR PARAMETER              0033 12085015
         BZ    EK0                 NO, B AROUND PARAM CHECK        0033 12090015
         LTR   RZ,RZ               IS PARAM LENGTH ZERO            0033 12095015
         BE    EXITSC              YES, B TO SCAN AGAIN            0033 12100015
         B     PPERRH              BRANCH TO ERROR MSG             SA0I 12105018
EK0      TM    PPWORK,KEYW         TEST FOR KEYWORD                0033 12110015
         BZ    CSCAN1              NOT KEYWORD,BRANCH TO COMMAND TEST   12120000
*        TEST FOR VALID KEYWORD                                         12140000
         NI    PPWORK+81,X'FD'     SET OFF KEYWORD REQUIRED BIT    SA0I 12150018
         CLC   KINHDR(6),0(R1)    TEST FOR INPUT HEADER KEYWORD    SA0I 12160018
         BNE   EK1                 NO-TRY INTLR KEYWD                   12180000
         LA    PARLOC,EX1          ADDRESS OF INHDR EXIT                12200000
         B     EXSCANP             BRANCH TO EXIT NAME ROUTINE          12220000
EK1      CLC   KINTLR(6),0(R1)    TEST FOR INPUT TRAILER KEYWORD   SA0I 12240018
         BNE   EK3                 NO-TRY INREC KEYWORD                 12260000
         LA    PARLOC,EX3          ADDRESS OF INTLR EXIT                12280000
         B     EXSCANP             BRANCH TO EXIT NAME ROUTINE          12300000
EK3      CLC   KINREC(6),0(R1)    TEST IF INPUT RECORD RTN KEYWORD SA0I 12320018
         BNE   EK5                 NO-TRY OUTREC KEYWORD                12340000
         LA    PARLOC,EXIN         ADDRESS OF INREC EXIT                12360000
         B     EXSCANP             BRANCH TO EXIT NAME ROUTINE          12380000
EK5      CLC   KOUTREC(7),0(R1)   TEST FOR OTPT REC RTN KYWD       SA0I 12400018
         BNE   PPERRH              NO-INVALID KEYWORD              SA0I 12420018
         LA    PARLOC,EXOUT        ADDRESS OF OUTREC EXIT               12440000
*                                                                       12460000
*              VALID KEYWORD-GET NAME OF EXIT ROUTINE                   12480000
EXSCANP  OI    PPWORK+81,X'01'     SET ON PARAMETER REQUIRED BIT   SA0I 12490018
         BAL   BREG,CALLSCAN       BRANCH TO CCS02                 SA0I 12500018
         NI    PPWORK+81,X'FE'     SET OFF PARAMETER REQUIRED BIT  SA0I 12510018
         TM    PPWORK,PAR          TEST FOR PARAMETER                   12520000
         BZ    PPERRL              NO-BRANCH TO MSG RTN            SA0I 12540018
         LTR   RZ,RZ               TEST NAME LENGTH FOR ZERO            12560000
         BE    PPERRJ              LENGTH ZERO-BRANCH TO MSG RTN   SA0I 12580018
         CH    RZ,PH8              TEST NAME LENFTH FOR EIGHT           12600000
         BH    PPERRJ              TOO LONG-BRANCH TO MSG RTN      SA0I 12620018
         LR    TEMP2,RZ            LOAD REGISTER WITH NAME LENGTH       12640000
         BCTR  TEMP2,RZ            SUBTRACT ONE (RESTORED IN EX-MVC)    12660000
         EX    TEMP2,EXPMOV        EXECUTE MOVE INSTRUCTION             12680000
         LA    TEMP2,EXLST         ADDRESS OF EXIT LIST                 12700000
         ST    TEMP2,EXLSTADD      STORE ADDRESS OF EXIT LIST           12720000
         B     EXITSCN             CONTINUE EXIT TEST              8397 12740019
*                                                                       12760000
*                                                                       12940000
EXPMOV   MVC   0(1,PARLOC),0(R1)   MOVE EXIT ROUTINE NAME TO EXIT LIST  12960000
         EJECT                                                          12980000
*                                                                       13000000
*              COMMAND = MEMBER                                         13020000
*                                                                       13040000
MEMBERC  LH    MEMCT,MEMBCT            LOAD MEMBER CNT                  13047020
          AH    MEMCT,PH1              INCREMENT MEM CNT                13054020
          STH   MEMCT,MEMBCT           STORE MEM CNT                    13061020
         MVC   RECDCNT(2),PDZERO  FOR LAST MEMB.WITHOUT REC.STAT.A36090 13063021
         TM    TYPORG,X'01'        TEST FOR PARTITIONED DATA SET   SA0I 13070018
         BZ    PPERRU              NOT PARTITIONED-MEMBER INVALID  SA0I 13080018
         CLI   RECSW,X'03'   REC. COMM.PREC.FRST MEMBER COMM.    A36082 13082021
         BE    PPERRQ        YES,'INVALID COMMAND' MSG           A36082 13084021
         OI    RECSW,X'08'   PUT MEMBER COMM.ON                  A36082 13084421
          BCTR  MEMCT,0                DECR MEM CNT BY 1                13105020
         CH    MEMCT,MAXNAME       COMPARE COUNT TO MAXIMUM ALLOWED     13120000
         BL    ERRMESS                                             1769 13130014
         L     R1,MAXMSG               ADDRESS OF ERROR MESSAGE    1769 13140014
PICK     L     R1,MAXMSG           ADDRESS  OF ERROR MESSAGE       SA0I 13145018
         MVC   0(7,R1),KMAXNAME        MOVE 'MAXNAME' TO MESSAGE   1769 13150014
         B     MAXERROR                GO TO PRINT OUT MESSAGE     1769 13160014
ERRMESS  LA    ERREG,MEMBERNO          ADDRESS OF MESSAGE ROUTINE  1769 13170014
*                                                                       13180000
         OI    PPWORK+81,X'02'     SET ON KEYWORD REQUIRED BIT     SA0I 13190018
         BAL   BREG,CALLSCAN       BRANCH TO CALL ROUTINE               13200000
         NI    PPWORK+81,X'FD'     SET OFF KEYWORD REQUIRED BIT    SA0I 13210018
         TM    PPWORK,KEYW         TEST FOR KEYWORD                     13220000
         BZ    PPERRI              NOT KEYWORD-WRITE MESSAGE       SA0I 13240018
         CLC   KNAME(5),0(R1)     TEST FOR NAME KEYWORD            SA0I 13260018
         BNE   PPERRH              NOT NAME-INVALID-WRITE MESSAGE  SA0I 13270018
         OI    PPWORK+81,X'01'     SET ON PARAMETER REQUIRED BIT   SA0I 13280018
         BAL   BREG,CALLSCAN       BRANCH TO CALL ROUTINE               13300000
         NI    PPWORK+81,X'FE'     SET OFF PARAMETER REQUIRED BIT  SA0I 13310018
         TM    PPWORK,PAR          TEST FOR PARAMETER                   13320000
         BZ    MEMBHDM2            NOT PARAM-MSG RTN               SA0I 13340018
         CH    RZ,PH8              TEST FOR NAME LENGTH EIGHT           13360000
         BH    PPERRJ              TOO LONG-BRANCH TO MSG RTN      SA0I 13380018
         LTR   RZ,RZ               TEST FOR NAME LENGTH ZERO            13400000
         BE    MEMBHDM1            LENGTH ZERO-MSG RTN             SA0I 13410018
         CLI   PPCONCD,X'0C'       IS CONDITION CODE =12?          SA0I 13420018
         BE    TESTO1              BRANCH TO COMMAND TEST          SA0I 13430018
         L     MNTPTER,CURRMNT     ADDRESS OF MEMBER NAME TABLE         13440000
         LTR   MEMCT,MEMCT         TEST FOR MEBER COUNT ZERO            13460000
         BE    MS5                 COUNT ZERO-BRANCH TO MNT CLEAR       13480000
         AH    MNTPTER,LISTLEN     UPDATE MNT POINTER                   13500000
         TM    GETMA,X'10'         GETM. FOR FI AND REC PARAM. ? A52055 13510021
         BNO   MS5                 NO, SKIP                      A52055 13512021
         CLC   0(2,MCBPTER),PDZERO TEST MEMBER CONTROL BLOCK PTR TO 0   13520000
         BE    MS5                 POINTER = 0,BRANCH TO MNT CLEAR      13540000
         A     MCBPTER,CURRMCB     UPDATE MCB POINTER                   13560000
         MVC   CURRMCB(4),PDZERO   RESET CURRENT MCB PTR TO ZERO A45130 13570021
MS5      MVC   0(8,MNTPTER),PDBLANK     BLANK SPACE IN MNT              13580000
         MVC   8(4,MNTPTER),PDZERO      ZERO MEMBER COUNT               13600000
         ST    MNTPTER,CURRMNT          STORE MNT ADDRESS               13620000
         LR    TEMP2,RZ            LOAD NAME LENGTH                     13640000
         BCTR  TEMP2,RZ            SUBTRACT ONE (RESTORED IN EX-MVC)    13660000
         EX    TEMP2,NAMEMOV       EXECUTE MOVE INSTRUCTION             13680000
         OI    TYPORG,X'02'        SET TYPORG                           13740000
         MVC   SKIPSW(2),PH1      SET SWITCH TO READ RECORDS            13760000
         NI    RECORDSW,NEWR       SET RECORD SWITCH                    13780000
TESTO1   BAL   BREG,CALLSCAN       BRANCH TO CCS02                 SA0I 13788018
         TM    PPWORK,COMM         WAS A COMMAND FOUND?            SA0I 13796018
         BZ    PPERRJ              NO-WRITE ERROR MSG              SA0I 13804018
         B     PKUP5               CONTINUE WITH COMMAND TEST      SA0I 13812018
*                                                                       13820000
NAMEMOV  MVC   0(1,MNTPTER),0(R1)  MOVE NAME TO MEMBER NAME TABLE       13840000
*                                                                       13860000
*              MESSAGE ROUTINES                                         13880000
MEMBHDM1 ST    R14,REGSAV          SAVE RETURN POINT               SA0I 13883018
         BAL   R14,TISTIC          CALCULATE COLUMN NUMBER         SA0I 13886018
         L     R14,REGSAV          RESTORE CALLERS ADDRESS         SA0I 13889018
         LA    RZ,32               MESSAGE DISPLACEMENT            SA0I 13892018
         LA    R1,PPIP             MESSAGE POINTER                 SA0I 13895018
         MVC   SEYLE(4),VPPIPM     MOVE IN MSG  LOCATION           SA0I 13898018
HOWIE2   LA    TEMP4,30            LOAD DISPLACEMENT               SA0I 13901018
         A     TEMP4,SEYLE         POSITION FOR INSERTING COLUMN   SA0I 13904018
         MVC   0(2,TEMP4),FULL+2   MOVE IN COLUMN NUMBER           SA0I 13907018
         B     MIKEH               BRANCH TO WRITE LINK            SA0I 13910018
MEMBHDM2 ST    R14,REGSAV          SAVE RETURN POINT               SA0I 13913018
         BAL   R14,TISTIC          CALCULATE COLUMN NUMBER         SA0I 13916018
         BAL   R14,REGSAV          RESTORE CALLERS ADDRESS         SA0I 13919018
         LA    RZ,34               MESSAGE DISPLACEMENT            SA0I 13922018
         LA    R1,PPMP             MESSAGE POINTER                 SA0I 13925018
         MVC   SEYLE(4),VPPMPM     MOVE IN MSG LOCATION            SA0I 13928018
         B     HOWIE2              PUT COLUMN NUMBER IN MSG        SA0I 13931018
MIKEH    BAL   R14,PREMSG          BRANCH TO MSG LINK              SA0I 13940018
         MVI   PPCONCD,X'0C'       SET CONDITION CODE TO 12        SA0I 13949018
         B     RECORDNO            BRANCH TO SWITCH SET                 13960000
MEMBERNO LA    RZ,MERR             MESSAGE CODE                         14060000
         LA    R1,PMEMBNO          MESSAGE OFFSET                       14080000
         BAL   R14,PREMSG          BRANCH TO MESSAGE LINK               14100000
         CLI   PPCONCD,X'0C'       IS CONDITION CODE =12?          SA0I 14106018
         BE    RECORDNO            BRANCH TO SWITCH SET            SA0I 14112018
         MVI   PPCONCD,X'08'       SET CONDITION CODE TO EIGHT          14120000
RECORDNO MVC   SKIPSW(2),PH12      SET TO SKIP RECORDS                  14140000
         B     CDSKIP              BRANCH TO SKIP ROUTINE               14160000
MEMBNO   LA    RZ,5                MESSAGE CODE                         14180000
         LA    R1,PPAR             MESSAGE OFFSET                       14200000
         B     PPERR               BRANCH TO WRITE LINK                 14220000
*     DATA IS LAST OR ONLY KEYWORD ON LABELS CARD                  9608 14220119
*     IF CONV IS SPECIFIED FOR LABELS THE DATA KEYWORD MUST BE     9608 14220219
*     PRESENT AFTER IT.                                            9608 14220319
LABLSC   OI    PPWORK+81,X'02'         SET KEYWORD REQ BIT        S9608 14220419
LABLSCN  LA    ERREG,CDSKIP            GET ADR OF CARD SKIP ROUT   9608 14220619
         BAL   BREG,CALLSCAN       BRANCH TO CCS02                 SA0I 14220818
         TM    PPWORK,PAR                                          UL0H 14221217
         BZ    LKO                      NO,TEST KEYWORD            UL0H 14221617
         LTR   RZ,RZ                    IS PARAM LNGTH ZERO        UL0H 14222017
         BE    LABLSC                                              UL0H 14222417
         B     PPERRH              BRANCH TO ERROR MESSAGE         SA0I 14222818
LKO      TM    PPWORK,KEYW                                         UL0H 14223217
         BZ    CSCAN1                                              UL0H 14223617
         NI    PPWORK+81,X'FD'     SET OFF KEYWORD REQUIRED BIT    SA0I 14223818
TSTLBLKW CLC   KDATA(5),0(R1)     TEST FOR DATA KEYWORD            SA0I 14224118
         BE    TSTDATAP                                            UL0H 14224417
         CLC   KCONV(5),0(R1)     TEST FOR CONV KEYWORD            SA0I 14224818
         BE    LABCONV                  *                          UL0H 14225217
         MVI   LBLCONSW,X'00'                                      UL0H 14225617
         B     PPERRH              BRANCH TO ERROR MESSAGE         SA0I 14226018
TSTDATAP BAL   KREG,PPSCANP                                        UL0H 14226417
         CLC   PNO,0(R1)                                           UL0H 14226817
         BE    PARNO                                               UL0H 14227217
         CLC   PALL,0(R1)                                          UL0H 14227617
         BE    PARALL                                              UL0H 14228017
         CLC   PONLY,0(R1)                                         UL0H 14228417
         BE    PARONLY                                             UL0H 14228817
         CLC   PYES,0(R1)                                          UL0H 14229217
         BE    PARYES                                              UL0H 14229617
         B     PPEOFA8             BRANCH TO WRITE MESSAGE         SA0I 14230618
PARNO    CH    RZ,PH2              IS PARAM LENGTH=2?              SA0I 14230918
         BNE   PPERRJ              NO-WRITE ERROR MESSAGE          SA0I 14231218
         MVZ   LBLPRTSW,=X'00'     SET LABEL PRINT SW OFF          SA0I 14231518
         MVI   PROCKY,X'40'                                        UL0H 14232017
         B     LABLSCN                 GO TO SCAN NEXT CARD        9608 14232319
PARALL   CH    RZ,PH3              IS PARAM LENGTH=3?              SA0I 14232618
         BNE   PPERRJ              NO-WRITE ERROR MESSAGE          SA0I 14232818
         MVC   PROCKY,X'20'                                        SA0I 14233018
         B     LABLSCN                 GO TO SCAN NEXT CARD        9608 14233219
PARONLY  CH    RZ,PH4              IS PARAM LENGTH =4?             SA0I 14233418
         BNE   PPERRJ              NO-WRITE ERROR MESSAGE          SA0I 14233618
         MVI   PROCKY,X'10'                                        SA0I 14233818
         B     LABLSCN                 GO TO SCAN NEXT CARD        9608 14234019
PARYES   CH    RZ,PH3              IS PARAM LENGTH=3?              SA0I 14234218
         BNE   PPERRJ              NO-BRANCH TO ERROR MESSAGE      SA0I 14234418
         MVI   PROCKY,X'80'                                        SA0I 14234618
         B     LABLSCN                 GO TO SCAN NEXT CARD        9608 14234919
LABCONV  BAL   KREG,PPSCANP                                        UL0H 14235217
         CLC   PXE,0(R1)                                           UL0H 14235617
         BE    SETHXLB                                             UL0H 14236017
         CLC   PPZ,0(R1)                                           UL0H 14236417
         BNE   0(ERREG)                                            UL0H 14236817
LABLZ    OI    LBLCONSW,X'03'                                      UL0H 14237217
         B     LABLSC                                              UL0H 14237617
SETHXLB  OI    LBLCONSW,X'01'                                      UL0H 14238017
         B     LABLSC                                              UL0H 14238417
         EJECT                                                          14240000
*                                                                       14260000
*              COMMAND = RECORD,EXAMINE KEYWORDS                        14280000
*                                                                       14300000
RECORDC  DS    0H                                                       14301020
          XI    RECSW,X'03'                                             14302020
         CLC   COMPMEM(2),MEMBCT       COMPARE MEMBER NBS               14303020
         BE    COUNTREC            IF SAME MEMBER BRANCH          M4118 14304018
         MVC   COMPMEM(2),MEMBCT   UPDATE MEMBER TO NEW COUNT     M4118 14306018
         MVC   RECDCNT(2),PH1      RESET RECORD COUNT TO ONE      M4118 14308018
         XC    IDENTCON(2),IDENTCON  ID SW. ZERO FOR NEXT MEMBER A36090 14308421
         XC    COUNTID(2),COUNTID    ID.CNT. ZERO FOR NEXT MEM.  A36090 14308821
         XC    COMPREC(2),COMPREC RECD GRP.NUMB, 0 FOR NEXT MEM. A36090 14309221
         B     RECD2               CONTINUE PROCESSING            M4118 14310018
*                                                                       14312018
*  CHECK FOR ERROR WHEN MULTIPLE RECORD CARDS WITHOUT IDENTS    PTM4118 14314018
COUNTREC LH    TEMP1,RECDCNT       GET RECORD COUNT FOR THIS      M4118 14316018
         AH    TEMP1,PH1            MEMBER OR PS DATA SET         M4118 14318018
         STH   TEMP1,RECDCNT        AND INCREMENT BY ONE          M4118 14320018
         LH    TEMP1,COUNTID       GET COUNT OF RECORDS WITH      M4118 14322018
         AH    TEMP1,PH1            IDS TO ADD TEMPORARY ONE      M4118 14324018
         CH    TEMP1,RECDCNT       IF IDS+1 EQUAL TOTAL RECORDS   M4118 14326018
         BE    RECD2                THEN BRANCH TO CONTINUE       M4118 14328018
         B     MEMBNO               ERROR IF NO IDENT BETWEEN REC M4118 14330018
RECD2    OI    PPWORK+81,X'02'     TURN ON KEYWORD REQUIRED BIT   SAOI  14332018
         BAL   BREG,CALLSCAN       BRANCH TO CCS02                 SA0I 14338018
         TM    PPWORK,PAR          TEST FOR PARAMETER              0033 14346015
         BO    PPERRH              YES,WRITE ERROR MESSAGE         SA0I 14353018
         TM    PPWORK,KEYW         TEST FOR KEYWORD                     14360000
         BZ    CDSKIP              NO KEYWORD-BRANCH TO CARD SKIP       14380000
         NI    PPWORK+81,X'FD'     SET OFF KEYWORD REQUIRED BIT    SA0I 14390018
         OI    COMMSW,RCOMM        SET COMMAND SWITCH FOR RECORD        14400000
         CLI   PPCONCD,X'0C'       IS CONDITION CODE =12?          SA0I 14406018
         BE    RECDKEY1            YES-BRANCH AROUND PROCESSING    SA0I 14412018
         TM    RECORDSW,FIRSTR     TEST IF FIRST GROUP                  14420000
         BO    RECD3               NOT FIRST GROUP                      14440000
         SR    TEMP1,TEMP1         ZERO WORK REGISTER                   14460000
         STH   TEMP1,0(MCBPTER)    ZERO IN MCB COUNT                    14480000
         LH    TEMP1,PH2           LOAD WORK REGISTER WITH 2 (MCB LEN)  14500000
         ST    TEMP1,CURRMCB       STORE IN MCB LENGTH INDICATOR        14520000
RECD3    L     TEMP1,CURRMCB       LOAD MCB LENGTH                      14540000
         AH    TEMP1,GCBLEN        ADD GROUP CONTROL BLOCK LENGTH       14560000
         C     TEMP1,MCBREM        COMPARE TO MCB SPACE REMAINING       14580000
         BH    PPERRJ              INSUFFICIENT SPACE IN MCB TABLE SA0I 14600018
         LR    GCBPTER,MCBPTER     LOAD GROUP CONTROL BLOCK POINTER     14620000
         A     GCBPTER,CURRMCB     ADD MCB LENGTH                       14640000
         LA    FCBPTER,FCBL        LOAD CONSTANT EIGHT-FCB LENGTH       14660000
         ST    FCBPTER,CURRGCB     STORE FCB LENGTH                     14680000
*              SET POINTER FOR FCB                                      14700000
         LR    FCBPTER,GCBPTER          LOAD FCB ADDRESS                14720000
         MVC   0(GCBL,GCBPTER),PDZERO   ZERO 8 BYTES OF GCB             14740000
         B     RECDKEY1                 BRANCH TO KEYWORD CHECK         14760000
*                                                                       14780000
*              EXAMINE RECORD KEYWORDS                                  14800000
*                                                                       14820000
RECDKEY  BAL   BREG,CALLSCAN       BRANCH TO CALL                       14840000
RECDKEY1 TM    PPWORK,KEYW         TEST FOR KEYWORD                     14860000
         BZ    RKEYNO              NO KEYWORD-BRANCH TO PARAM CHECK     14880000
         NI    PPWORK+81,X'FD'     SET OFF KEYWORD REQUIRED BIT    SA0I 14890018
         LA    ERREG,PPERRJ        ADDRESS OF MSG RTN              SA0I 14900018
         CLC   KIDENT(6),0(R1)    TEST FOR IDENT KEYWORD           SA0I 14920018
         BE    IDKEY               YES-BRANCH TO IDENT PARAM CHECK      14940000
         CLC   KFIELD(6),0(R1)    TEST FOR FIELD KEYWORD           SA0I 14960018
         BNE   PPERRH              INVALID KEYWORD-BRANCH TO MSG   SA0I 14980018
*                                                                       15000000
*              KEYWORD = FIELD,EXAMINE PARAMETER LIST                   15020000
*                                                                       15040000
         CLI   6(R1),X'4D'         IS LEFT PAREN PRESENT          M3312 15040218
         BNE   PPERRY              NO-WRITE ERR MSG               M3312 15040418
         CLI   PPCONCD,X'0C'       IS CONDITION CODE =12?          SA0I 15040618
         BE    PKUP1               YES-BRANCH AROUND PROCESSING    SA0I 15041218
         LH    TEMP1,FIELDCNT    COUNT OF FLD PARAM'S FOUND SO FAR 1769 15042014
         LA    TEMP1,1(TEMP1)          INCREMEMT COUNT BY 1        1769 15044014
         CH    TEMP1,MAXFLDS           COMPARE NO. OF FIELDS FOUND 1769 15046014
*                                         TO NUMBER ALLOWED        1769 15048014
         BNH   CONTINUE                MAXIMUM NOT EXCEEDED, BRANCH1769 15050014
         L     R1,MAXMSG               TOO MANY FLD PARAM'S        1769 15052014
         MVC   0(7,R1),KMAXFLDS        PREPARE TO WRITE ERROR MSG  1769 15054014
         B     MAXERROR                                            1769 15056014
CONTINUE STH   TEMP1,FIELDCNT          UPDATE FLD PARAM COUNT      1769 15058014
         L     TEMP1,CURRMCB       LOAD MCB LENGTH                      15060000
         AH    TEMP1,FCBLEN        ADD FIELD CONT BLOCK LENGTH          15080000
         C     TEMP1,MCBREM        COMPARE TO MCB SPACE REMAINING       15100000
         BH    PPERRJ              NO ROOM IN MCB TABLE            SA0I 15120018
         L     TEMP2,CURRGCB       ADDRESS OF GROUP CONTROL BLOCK       15140000
         LA    TEMP2,8(0,TEMP2)    INCREMENT BY NAME LENGTH             15160000
         ST    TEMP2,CURRGCB       STORE INCREMENTED ADDRESS            15180000
         AH    FCBPTER,FCBLEN      ADD FCB LENGTH TO FCB ADDRESS        15200000
         MVC   0(FCBL,FCBPTER),PDZERO   ZEROS TO UPDATED FCB            15220000
PKUP1    LA    PARLIST,FLDP1       ADDRESS OF FIELD LENGTH CHECK   SA0I 15240018
FLDPAR   OI    PPWORK+81,X'01'     SET ON PARAMETER REQUIRED BIT   SA0I 15250018
         BAL   BREG,CALLSCAN       BRANCH TO CALL                  SA0I 15260018
         NI    PPWORK+81,X'FE'     SET OFF PARAMETER REQUIRED BIT  SA0I 15270018
         TM    PPWORK,PAR          TEST FOR PARAMETER                   15280000
         BZ    PPERRL              NO-BRANCH TO MSG RTN            SA0I 15300018
         BR    PARLIST             BRANCH TO PARAM CHECK                15320000
*                                                                       15340000
*              FIRST PARAMETER IS FIELD LENGTH                          15360000
*                                                                       15380000
FLDP1    LA    PARLIST,FLDP2       ADDRESS OF INPUT LOCATION CHECK      15400000
         LTR   RZ,RZ               TEST FOR FIELD LENGTH                15420000
         BE    PPERRJ              NO LENGTH SPEC-BRANCH MSG RTN   SA0I 15440018
         BAL   BREG,SETPBIN        BRANCH TO CVB ROUTINE                15460000
         BE    PPERRJ              LENGTH=0,BRANCH TO MESSAGE RTN  SA0I 15470018
         CLI   PPCONCD,X'0C'       IS CONDITION CODE =12?          SA0I 15480018
         BE    FPNEXT              CONTINUE THROUGH THE PARAMETERS SA0I 15490018
         STH   PREG,0(FCBPTER)     STORE LENGTH IN FIELD CONTROL BLOCK  15500000
         B     FPNEXT              CONTINUE THROUGH PARAMETERS          15520000
*                                                                       15540000
*              SECOND PARAMETER IS RELATIVE INPUT LOCATION              15560000
*                                                                       15580000
FLDP2    LA    PARLIST,FLDP3       ADDRESS OF CONVERSION CHECK          15600000
         LTR   RZ,RZ               TEST IF RILOC SPEC                   15620000
         BE    FPNEXT              NO-CONTINUE THROUGH PARAMETERS       15640000
         BAL   BREG,SETPBIN        BRANCH TO CVB ROUTINE                15660000
         BE    FPNEXT              RILOC=0,CONTINUE THROUGH PARAMETERS  15680000
         CLI   PPCONCD,X'0C'       IS CONDITION CODE =12?          SA0I 15686018
         BE    FPNEXT              CONTINUE THROUGH THE PARAMETERS SA0I 15692018
         BCTR  PREG,RZ             DECREMENT LENGTH BY ONE              15700000
         STH   PREG,2(FCBPTER)      STORE INPUT LOCATION IN FCB         15720000
         B     FPNEXT              CONTINUE THROUGH PARAMETERS          15740000
*                                                                       15760000
*              THIRD PARAMETER IS CONVERSION CODE                       15780000
*                                                                       15800000
FLDP3    LA    PARLIST,FLDP4       ADDRESS OF OUTPUT LOCATION TEST      15820000
         LTR   RZ,RZ               TEST IF CONVERSION SPECIFIED         15840000
         BE    FPNEXT              NO CONVERSION-CONTINUE THRU PARAMS   15860000
         CLC   PHE(2),0(R1)        TEST FOR PRINTABLE HEX PARAMETER     15880000
         BE    FLDPOR              YES-BRANCH TO FCB OR                 15900000
         CLC   PXE(2),0(R1)        TEST FOR PRINTABLE HEX PARAMETER     15920000
         BNE   FLDP3A              NOT HEX-BRANCH TO UNPACK TEST        15940000
         CLI   PPCONCD,X'0C'       IS CONDITION CODE =12?          SA0I 15946018
         BE    FPNEXT              CONTINUE THROUGH THE PARAMETERS SA0I 15952018
FLDPOR   OI    4(FCBPTER),X'01'    SET CONVERSION FOR PRINTABLE HEX     15960000
         B     FPNEXT              CONTINUE THROUGH PARAMETERS          15980000
FLDP3A   CLC   PPZ(2),0(R1)        TEST FOR PACKED TO UNPACKED CONVERS  16000000
         BNE   PPERRJ              INVALID PARAM-BRANCH TO MSG RTN      16010018
         CLI   PPCONCD,X'0C'       IS CONDITION CODE =12?          SA0I 16020018
         BE    FPNEXT              CONTINUE THROUGH THE PARAMETERS SA0I 16030018
         OI    4(FCBPTER),X'03'    SET CONVERSION FOR UNPACK DECIMAL    16040000
*                                                                       16060000
FPNEXT   TM    PPWORK,PARP         TEST FOR END OF PARAMETER LIST       16080000
         BO    FLDPEND             END-BRANCH TO PARAM END ROUTINE      16100000
         B     FLDPAR              CONTINUE THROUGH PARAMETERS          16120000
*                                                                       16140000
*              FOURTH PARAMETER IS RELATIVE OUTPUT LOCATION             16160000
*                                                                       16180000
FLDP4    LTR   RZ,RZ               TEST IF OUTPUT LOCATION SPECIFIED    16200000
         BE    FLDPEND             NOT SPEC-BRANCH TO PARAM END RTN     16220000
         BAL   BREG,SETPBIN        BRANCH TO CVB ROUTINE                16240000
         BE    FLDPEND             PARAM ZERO-BRANCH TO END ROUTINE     16260000
         CLI   PPCONCD,X'0C'       IS CONDITION CODE =12?          SA0I 16266018
         BE    FLDPEND             BRANCH TO END ROUTINE           SA0I 16272018
         BCTR  PREG,RZ             DECREMENT LOC BY ONE                 16280000
         STH   PREG,6(FCBPTER)     STORE OUTPUT LOCATION IN FCB         16300000
*                                                                       16320000
*              END OF PARAMETER LIST                                    16340000
*                                                                       16360000
FLDPEND  CLI   PPCONCD,X'0C' IS COND. CODE = 12                  A36097 16370021
         BE    RECDKEY       YES, EXAMINE OTHER REC. KEYWORDS    A36097 16372021
         LA    TEMP1,1                                           A36097 16374021
         AH    TEMP1,0(GCBPTER)    INCREMENT FIELD COUNT                16400000
         STH   TEMP1,0(GCBPTER)    STORE NEW FIELD COUNT                16420000
         B     RECDKEY                                                  16440000
*                                                                       16460000
*                                                                       16480000
*        EXAMINE IDENT PARAMETERS                                       16500000
*                                                                       16520000
IDKEY    LA    PARLIST,IDP1        ADDRESS OF LITERAL TEST              16540000
         CLI   6(R1),X'4D'         IS LEFT PAREN PRESENT          M3312 16542018
         BNE   PPERRY              NO-WRITE ERR MSG               M3312 16544018
         CLI   PPCONCD,X'0C'       IS CONDITION CODE =12?          SA0I 16546018
         BE    IDPAR               BRANCH AROUND PROCESSING        SA0I 16552018
         CLC   COMPREC(2),RECDCNT  COMPARE RECORDS NUMBERS        M4118 16553018
         BE    IDPAR               EQUAL-NO COUNT MULTPLE IDENTS  M4118 16554018
         MVC   COMPREC(2),RECDCNT  UNEQUAL-UPDATE RECORD NUMBERS  M4118 16555018
         LH    BREG,COUNTID        GET COUNT OF RECORDS WITH      M4118 16556018
         AH    BREG,PH1              IDENT PARAMETERS             M4118 16557018
         STH   BREG,COUNTID         AND INCREMENT BY ONE          M4118 16558018
         LH    BREG,IDENTCON       LOAD NO OF IDENTS                    16560000
         LA    BREG,1(0,BREG)      ADD ONE FOR THIS IDENT               16580000
         STH   BREG,IDENTCON       STORE UPDATED IDENT NUMBER           16600000
         CH    BREG,MAXGPS             IS ACTUAL NO.OF IDENT STMTS 1769 16602014
*                                       GREATER THAN NO.SPECIFIED  1769 16604014
         BNH   IDPAR                   NO--CONTINUE.               1769 16606014
         L     R1,MAXMSG               ADDRESS OF ERROR MESSAGE    1769 16608014
         MVC   0(6,R1),KMAXGPS         MOVE'MAXGPS' TO MESSAGE     1769 16610014
         MVI   6(R1),X'40'             MOVE BLANK INTO LAST BYTE   1769 16612014
         B     MAXERROR                GO TO PRINT OUT MESSAGE     1769 16614014
IDPAR    OI    PPWORK+81,X'01'     SET ON PARAMETER REQUIRED BIT   SA0I 16620018
         BAL   BREG,CALLSCAN       BRANCH TO CALL                  SA0I 16626018
         NI    PPWORK+81,X'FE'     SET OFF PARAMETER REQUIRED BIT  SA0I 16632018
         TM    PPWORK,PAR          TEST FOR PARAMETER                   16640000
         BZ    PPERRL              NO-PARM-BRANCH TO MSG RTN       SA0I 16660018
         BR    PARLIST             BRANCH TO LIT TEST                   16680000
*              FIRST PARAMETER IS LENGTH OF LITERAL                     16700000
*                                                                       16720000
IDP1     LA    PARLIST,IDP2        ADDRESS OF LIT PARAM RTN             16740000
         CH    R0,PH1              IS LENGTH GT ONE               M3311 16742018
         BH    PPERRJ              YES-WRITE ERR MSG              M3311 16744018
         CLI   0(R1),X'F0'         IS CHAR NUMERIC                M3311 16746018
         BL    PPERRJ              NO-WRITE ERR MSG               M3311 16748018
         CLI   0(R1),X'F9'         IS CHAR NUMERIC                M3311 16750018
         BH    PPERRJ              NO-WRITE ERR MSG               M3311 16752018
         MVC   LITLEN+3(1),0(R1)   MOVE LENGTH OF LIT TO SAVE AREA      16760000
         NI    LITLEN+3,X'0F'      LENGTH NOT OVER FIFTEEN              16780000
         B     IDPAR               BRANCH TO CALL NEXT PARAM            16800000
*                                                                       16820000
*              SECOND PARAMETER IS A LITERAL                            16840000
*                                                                       16860000
IDP2     LTR   RZ,RZ               TEST FOR LITERAL PARAMETER           16880000
         BE    PPERRL              NONE-BRANCH TO MSG RTN          SA0I 16900018
         SH    RZ,PH2              SUBTRACT 2 (APOSTROPHES)FOR LIT LEN  16920000
         LTR   RZ,RZ               TEST FOR LITERAL LENGTH ZERO         16940000
         BE    PPERRJ              LENGTH ZERO,BRANCH TO MSG RTN   SA0I 16960018
         C     RZ,LITLEN           COMPARE ACTUAL TO STATED LENGTH      16980000
         BNE   PPERRJ              UNEQUAL-BRANCH TO MSG RTN       SA0I 16990018
         CLI   PPCONCD,X'0C'       IS CONDITION CODE =12?          SA0I 17000018
         BE    PKUP2               BRANCH AROUND PROCESSING        SA0I 17010018
         LH    TEMP2,CURRLIT       LOAD NO OF BYTES STORED IN LIT POOL  17020000
         LH    TEMP1,MAXLITS       LOAD MAXIMUM CHARACTERS              17040000
         LR    PREG,TEMP2          CURRENT NO OF LIT CHARACTERS         17060000
         AR    PREG,RZ             ADD LENGTH OF THIS LITERAL           17080000
         CR    PREG,TEMP1          COMPARE TO-DATE TOTAL TO MAXIMUM     17100000
         BNH   STORLIT                                             1769 17110014
         L     R1,MAXMSG               ADDRESS OF ERROR MESSAGE    1769 17120014
         MVC   0(7,R1),KMAXLITS        MOVE 'MAXLITS' TO MESSAGE   1769 17130014
         B     MAXERROR                GO TO PRINT OUT MESSAGE     1769 17140014
STORLIT  STH   PREG,CURRLIT            STORE NO, OF LIT CHAR USED. 1769 17150014
         STH   RZ,2(GCBPTER)       STORE LITERAL LENGTH IN GCB          17160000
         AH    R1,PH1              INCREMENT LIT LOC TO SKIP APOSTROPHE 17180000
         L     TEMP1,LITADD        ADDRESS OF LITERAL POOL              17200000
         AR    TEMP1,TEMP2         ADD CURRENT SPACE USED               17220000
         STH   TEMP2,4(GCBPTER)    STORE CURRENT SPACE IN GCB           17240000
         LR    TEMP2,RZ            LOAD LENGTH OF LITERAL               17260000
         BCTR  TEMP2,RZ            SUBTRACT ONE (RESTORED IN EX-MVC)    17280000
         EX    TEMP2,IDLITMOV      EXECUTE MOVE INSTRUCTION             17300000
*              TEST FOR END                                             17320000
PKUP2    TM    PPWORK,PARP         TEST FOR END OF LIST            SA0I 17340018
         BO    RECDKEY             END-BRANCH TO RECORD KEYWORD CHECK   17360000
         LA    PARLIST,IDP3        NOT END,CONTINUE THROUGH PARAMETERS  17380000
         B     IDPAR               BRANCH TO PARAMETER CHECK            17400000
*                                                                       17420000
*              THIRD PARAMETER IS RELATIVE INPUT LOCATION               17440000
*                                                                       17460000
IDP3     LTR   RZ,RZ               TEST FOR PARAMETER                   17480000
         BE    RECDKEY             BRANCH TO KEYWORD CHECK              17500000
         BAL   BREG,SETPBIN        BRANCH TO CVB ROUTINE                17520000
         BE    RECDKEY             PARAM ZERO-BRANCH TO KEYWORD CHECK   17540000
         CLI   PPCONCD,X'0C'       IS CONDITION CODE =12?          SA0I 17546018
         BE    RECDKEY             BRANCH AROUND PROCESSING        SA0I 17552018
         BCTR  PREG,RZ             SUBTRACT ONE FROM INPUT LOC (INCRD)  17560000
         STH   PREG,6(GCBPTER)     STORE REL INPUT LOCATION IN GCB      17580000
         B     RECDKEY             BRANCH TO KEYWORD CHECK              17600000
*                                                                       17620000
IDLITMOV MVC   0(1,TEMP1),0(R1)    MOVE LITERAL TO LIT POOL             17640000
*                                                                       17660000
*                                                                       17680000
RKEYNO   TM    PPWORK,PAR          TEST FOR PARAMETER                   17700000
         BZ    RECDEND             NOT PARAM-BRANCH TO REC CARD END     17720000
         B     PPERRJ              YES,WRITE ERROR MESSAGE         SA0I 17750018
*                                                                       17780000
*              RECORD CARD SUCCESSFULLY SCANNED                         17800000
*                                                                       17820000
RECDEND  CLI   PPCONCD,X'0C'       IS CONDITION CODE =12?          SA0I 17830018
         BE    CSCANZ              BRANCH AROUND PROCESSING        SA0I 17844021
         LH    TEMP1,0(MCBPTER)    LOAD GROUP COUNT                SA0I 17850018
         LTR   TEMP1,TEMP1         TEST GROUP COUNT FOR ZERO            17860000
         BH    REND5               THIS IS NOT FIRST GROUP              17880000
         OI    RECORDSW,FIRSTR     SET SWITCH FOR FIRST GROUP           17900000
         L     MNTPTER,CURRMNT     LOAD CURRENT MNT ADDRESS             17920000
         ST    MCBPTER,8(MNTPTER)  STORE MCB ADDRESS IN MNT             17940000
REND5    AH    TEMP1,PH1           INCREMENT GROUP COUNT                17960000
         STH   TEMP1,0(MCBPTER)    STORE UPDATED GROUP COUNT            17980000
         L     TEMP1,CURRGCB       LOAD GCB LENGTH                      18000000
         A     TEMP1,CURRMCB       ADD MCB LENGTH                       18020000
         ST    TEMP1,CURRMCB       STORE TOTAL LENGTH                   18040000
         B     CSCANZ              BRANCH TO SCAN                       18060000
IDLITNO  LA    RZ,RERR                  MESSAGE CODE                    18080000
         B     RCDNOSP1            BRANCH TO LOAD REGISTER ONE          18100000
RCDNOSP  LA    RZ,5                MESSAGE CODE                         18120000
RCDNOSP1 LA    R1,PPAR             MESSAGE OFFSET                       18140000
         B     PPERR               BRANCH TO MESSAGE LINK               18160000
*                                                                  0033 18180015
*                                                                  0033 18240015
MAXERROR LA    RZ,14                   MESSAGE CODE                1769 18283014
         LA    R1,23                   MESSAGE OFFSET              1769 18286014
         B     PPERR                   BRANCH TO MESSAGE LINK.     1769 18289014
         EXTRN MAXMSGS                                             1769 18292014
MAXMSG   DC    A(MAXMSGS)                                          1769 18295014
*                                                                       18300000
PREMSG   SLL   R1,8                SET UP REGISTERS                     18320000
         AR    R1,RZ               FOR MESSAGE WRITE                    18340000
         L     R15,PMSGWRTA        ADDRESS OF MESS WRITE RTN-EXTERN     18360000
         BR    R15                 BRANCH TO MESSAGE WRITE ROUTINE      18380000
*                                                                       18400000
         ENTRY BLKRTN                                              BS0H 18403017
BLKRTN   LA    RZ,7        MESSAGE CODE FOR I/O ERROR ON SYSIN     BS0H 18406017
         LA    R1,PEOJIO                MESSAGE POINTER            BS0H 18409017
         LA    R14,DDRTN1         RETURN ADDRESS AFTER PRINTING    BS0H 18412017
         B     PREMSG             BRANCH TO MESSAGE WRITE ROUTINE  BS0H 18415017
         ENTRY DDRTN                                                    18420000
DDRTN    LA    RZ,11               DDERROR1 MESSAGE NUMBER              18440000
         LA    R1,21               DDERROR1 MESSAGE OFFSET IN IEBPPMSG  18460000
         LA    R14,DDRTN1          RETURN ADDRESS AFTER PRINTING        18480000
         B     PREMSG              BRANCH TO MESSAGE EXIT               18500000
DDRTN1   MVI   PPCONCD,X'0C'       SET RETURN CODE TO TWELVE            18520000
         B     PPRET               BRANCH TO RETURN ROUTINE             18540000
*                                                                       18560000
         EJECT                                                          18580000
*********************************************************************** 18600000
*                                                                       18620000
*              IEBPPAL1 - CONSTANTS                                     18640000
*                                                                       18660000
LITLEN   DC    F'0'                LENGTH OF LITERAL                    18680000
*                                                                       18700000
*        COMMAND LIST                                                   18720000
*                                                                       18740000
CPRINT   DC    C'PRINT '          INIT OPERATION- PT OR            SA0I 18750018
CPUNCH   DC    C'PUNCH '          PUNCH                            SA0I 18760018
CTITLE   DC    C'TITLE '          REQUESTS TITLE,SUBTITLE          SA0I 18770018
CEXITS   DC    C'EXITS '          IDENTIFIES EXIT ROUTINES         SA0I 18780018
CMEMBER  DC    C'MEMBER '         IDENTIFIES MEMBERS OF PDS        SA0I 18790018
CRECORD  DC    C'RECORD '         DEFINES RECORD GROUPS            SA0I 18800018
CLABELS  DC    C'LABELS '                                          SA0I 18810018
*                                                                       18880000
*                                                                       18900000
*        KEYWORD LIST - PRINT/PUNCH                                     18920000
*                                                                       18940000
KTYPORG  DC    C'TYPORG='         SPECIFIES DATA SET ORGANIZATION  SA0I 18950018
KTOTCONV DC    C'TOTCONV='        SPECIFIES OUTPUT CONVERSION      SA0I 18960018
KCNTRL   DC    C'CNTRL='          SPECIFIES CONTROL CHARACTER      SA0I 18970018
KINITPG  DC    C'INITPG='         SPECIFIES INIT PG NUMB-PT        SA0I 18980018
KMAXLINE DC    C'MAXLINE='        SPECIFIES MAX LINES/PAGE-PT      SA0I 18990018
KCDSEQ   DC    C'CDSEQ='          SPECIFIES INIT SEQ NO-PUNCH      SA0I 19000018
KCDINCR  DC    C'CDINCR='         SPECIFIES SEQ. INCR-PUNCH        SA0I 19010018
KSTOPAFT DC    C'STOPAFT='        SPECIFIES NO INPT RCDS TO BE PROCSA0I 19020018
KSKIP    DC    C'SKIP='           SPECIFIES PROC  INCREMENT        SA0I 19030018
KMAXNAME DC    C'MAXNAME='        SPECIFIES MAX MEMBER STS         SA0I 19040018
KMAXFLDS DC    C'MAXFLDS='        SPECIFIES MAX FLD PARMS          SA0I 19050018
KMAXGPS  DC    C'MAXGPS='         SPECIFIES MAX IDENT PARMS        SA0I 19060018
KMAXLITS DC    C'MAXLITS='        SPECIFIES MAX LIT CHARS          SA0I 19070018
KPREFRM  DC    C'PREFORM='        SPECIFIES FORMATTED OUTPUT       SA0I 19080018
KSTRTAFT DC    C'STRTAFT='        SPECIF. THE START NBR          A45135 19130021
*        KEYWORD LIST - LABELS                                     UL0H 19225017
KDATA    DC    C'DATA='                                            SA0I 19230018
KCONV    DC    C'CONV='                                            SA0I 19235018
*                                                                       19240000
*        KEYWORD - TITLE STATEMENT                                      19260000
*                                                                       19280000
KITEM    DC    C'ITEM='           SPEC TITLE OR SUBTITLE INFO      SA0I 19300018
*                                                                       19320000
*        KEYWORD LIST - RECORD STATEMENT                                19340000
*                                                                       19360000
KFIELD   DC    C'FIELD='          EDIT INFO-SPECIFIED PROCESSING   SA0I 19380018
KIDENT   DC    C'IDENT='          IDENTIFIES LAST RCD-FIELD PARM   SA0I 19400018
*                                                                       19420000
*        KEYWORD - MEMBER STATEMENT                                     19440000
*                                                                       19460000
KNAME    DC    C'NAME='           IDENTIFIES MEMBER BY NAME/ALIAS  SA0I 19480018
*                                                                       19500000
*        KEYWORD LIST - EXITS STATEMENT                                 19520000
*                                                                       19540000
KINHDR   DC    C'INHDR='          SPECIFIES NME INPT HDR RTN       SA0I 19547018
KINTLR   DC    C'INTLR='          SPECIFIES NME INPT TRLR RTN      SA0I 19554018
KINREC   DC    C'INREC='          SPECIFIES NME OF P9E796CESS RTN  SA0I 19561018
KOUTREC  DC    C'OUTREC='         SPECIFIES NME OF PREOUTPUT RTN   SA0I 19568018
*                                                                       19575018
*                                                                       19582018
*                                                                       19589018
DOUBLE   DS    D                   DOUBLE WORD FOR CVD             SA0I 19596018
FULL     DS    F                   FULL WORD TO STORE COLUMN NUMB  SA0I 19603018
REGSAV   DS    F                   FULL WORD TO SAVE REG CONTENTS  SA0I 19610018
SEYLE    DS    F                   FULL WORD TO SAVE ADDR MSG      SA0I 19617018
BIT      DC    X'00'               FIRST CARD INDICATOR            SA0I 19624018
BITS     DC    X'00'               SECOND CARD INDICATOR           SA0I 19631018
RECSW    DC    X'00'              TO TEST ORDER OF RECORD MEMBER COMM   19635020
GETMA    DC    X'00'                                             A36090 19637021
*                                                                       19640000
*                                                                       19660000
*        NON-NUMERIC PARAMETERS                                         19680000
*                                                                       19700000
PPS      DC    C'PS'               SPEC PHYSICAL SEQUENTIAL ORGANIZAT   19720000
PPO      DC    C'PO'               SPECIFIES PARTITIONED ORGANIZATION   19740000
PHE      DC    C'HE'               SPEC PRINTABLE HEX CONVERSION        19760000
PXE      DC    C'XE'               SPEC PRINTABLE HEX CONVERSION        19780000
PPZ      DC    C'PZ'               SPEC UNPACKED DECIMAL CONVERSION     19800000
*                                                                       19820000
PNO      DC    C'NO'                                               UL0H 19824017
PALL     DC    C'ALL'                                              UL0H 19828017
PONLY    DC    C'ONLY'                                             UL0H 19832017
PYES     DC    C'YES'                                              UL0H 19836017
SYSIN    DC    X'00'               SET TO 00 IND. SYSIN EMPTY    A21407 19837018
*              X'FF'               SET TO FF FOR SYSIN NOT EMPTY A21407 19838018
*                                                                       19840000
*                                                                       19860000
COMM     EQU   X'08'               INDICATES COMMAND                    19880000
KEYW     EQU   X'04'               INDICATED KEYWORD                    19900000
PAR      EQU   X'02'               INDICATES PARAMETER                  19920000
PARP     EQU   X'03'               INDICATES FINAL PARAMETER            19940000
EOF      EQU   X'20'               INDICATES END OF FILE                19960000
ERROR    EQU   X'80'               INDICATES ERROR                      19980000
BYPASS   EQU   X'40'               INDICATES SKIP RECORD STATEMENTS     20000000
BYPASSNO EQU   X'BF'               INDIC NO SKIP OF RECORD STATEMENTS   20020000
NEWCD    EQU   X'01'               INDICATES NEW CARD                   20040000
RIO      EQU   X'02'               INDICATES I/O ERROR ON SYSIN         20060000
FIRSTR   EQU   X'01'               INDICATES FIRST RECORD               20080000
NEWR     EQU   X'FE'               INDICATES NEW RECORD                 20100000
RCOMM    EQU   X'02'               INDICATES RECORD COMMAND             20120000
*                                                                       20140000
*                                                                       20160000
SAVEADD  DS    18F                 REGISTER SAVE AREA                   20180000
*                                                                       20200000
PPWORK   DS    145B                WORK AREA                            20220000
*                                                                       20240000
WORKLEN  EQU   145                 LENGTH OF WORK AREA                  20260000
*                                                                       20280000
*                                                                       20300000
*        MESSAGE CODES                                                  20320000
*                                                                       20340000
EOFCDE   EQU   0                   END OF FILE                          20360000
RERR     EQU   4                   RECORD ERROR                         20380000
MERR     EQU   5                   MEMBER ERROR                         20400000
IERR     EQU   14                  LITERAL ERROR                        20420000
*                                                                       20440000
PTERM1   EQU   1                   COMMAND ERROR                        20460000
PTERM2   EQU   2                   COMMAND ERROR                        20480000
PTMULT   EQU   3                   TITLE ERROR                          20500000
PKEY     EQU   4                   KEYWORD ERROR                        20520000
PPAR     EQU   5                   PARAMETER ERROR                      20540000
PMEMBNO  EQU   7                   MEMBER ERROR                         20560000
PEOF     EQU   10                  END OF FILE                          20580000
PEOJIO   EQU   13                  I/O ERROR ON SYSIN                   20600000
SYNTMSG  EQU   19                  ERROR INDICATOR ON                   20620000
NOSYSIN  EQU   20   *********TO BE CHECKED                       A21407 20621018
PPIK     EQU   31                  INVALID KEYWORD ER9OR           SA0I 20622018
PPIP     EQU   32                  INVALID PARAMETER ERROR         SA0I 20624018
PPMK     EQU   33                  MISSING KEYWORD ERROR           SA0I 20626018
PPMP     EQU   34                  MISSING PARAMETER ERROR         SA0I 20628018
PPMC     EQU   35                  MISSING COMMAND ERROR           SA0I 20630018
PPIC     EQU   36                  INVALID COMMAND ERROR           SA0I 20632018
PPIL     EQU   37                  INVALID LITERAL ERROR           SA0I 20634018
PPIN     EQU   38                  INVALID NAME ERROR              SA0I 20636018
PPBC     EQU   39                  CONTINUATION CARD ERROR         SA0I 20638018
*                                                                       20640000
*                                                                       20660000
*        REGISTER EQUATES                                               20680000
*                                                                       20700000
TEMP2    EQU   15                  WORK REGISTER                        20720000
R15      EQU   15                  EXTERN BRANCH,RETURN CODE            20740000
R14      EQU   14                  BAL RETURN                           20760000
TEMP1    EQU   14                  WORK REGISTER                        20780000
R13      EQU   13                  SAVE REGISTER                        20800000
ERREG    EQU   12                  ERROR BRANCH REGISTER                20820000
BASE     EQU   11                  BASE REGISTER                   SA0I 20840018
PARLIST  EQU   10                  INTERNAL BRANCH REGISTER             20860000
BASER    EQU   9                   BASE REGISTER                        20880000
PREG     EQU   8                   PARAMETER REGISTER                   20900000
PARLOC   EQU   7                   PARAMETER POINTER                    20920000
BREG     EQU   6                   INTERNAL BRANCH RETURN               20940000
TCBR     EQU   5                   POINTER TO TITLE CONTROL BLOCK       20960000
GCBPTER  EQU   5                   POINTER TO GROUP CONTROL BLOCK       20980000
TEMP4    EQU   5                                                   SA0I 20990018
MNTPTER  EQU   5                   POINTER TO MEMBER NAME TABLE         21000000
KREG     EQU   5                   INTERNAL BRANCH REGISTER             21020000
TREG     EQU   4                   DTABLE BASE REGISTER                 21040000
MEMCT    EQU   3                   MEMBER COUNT REGISTER                21060000
TEMP3    EQU   3                                                   SA0I 21070018
RLIT     EQU   3                   LITERAL LENGTH REGISTER              21080000
FCBPTER  EQU   3                   POINTER TO FCB                       21100000
MCBPTER  EQU   2                   POINTER TO MEMBER CONTROL BLOCK      21120000
R1       EQU   1                   MESSAGE POINTER                      21140000
RZ       EQU   0                   MESSAGE POINTER                      21160000
R0       EQU   0                                                        21180000
*                                                                       21200000
*                                                                       21220000
*                                                                       21240000
TEMPSAVE DC    F'0'                    REGISTER 3 SAVE AREA        4304 21245019
PARMADR  DC    F'0'                    PARAMETER SAVE AREA         4304 21250019
FREEA    DC    F'0'           FREECORE ADDR PASSED TO PPAL1        4304 21255019
IDENTCON DC    H'0'                IDENT SWITCH                         21260000
RECDCNT  DC    H'0'                                                0324 21270017
COMPMEM  DC    H'00'               COUNT TO COMPARE RECD GRP NUMB M4118 21272018
COMPREC  DC    H'00'               COUNT TO COMPARE MEMBER NUMB   M4118 21274018
COUNTID  DC    H'00'               COUNT OF REC CARDS WITH IDENTS M4118 21276018
PPSYSI   DC    D'0'                DDNAME FOR SYSIN                     21280000
SKIPSW   DC    H'0'                RECORD SKIP SWITCH                   21300000
MASK     DC    H'0'                NO MEMBER SWITCH                     21320000
PLANT    DC    H'0'                FULL MCB SWITCH                      21340000
PH1      DC    H'1'                COUNT INCREMENT                      21360000
PH2      DC    H'2'                INCREMENT                            21380000
PH3      DC    H'3'                                                SA0I 21390018
PH4      DC    H'4'                PRE-NAME MNT AREA                    21400000
PH8      DC    H'8'                NAME LENGTH                          21420000
PH10     DC    H'10'                                                    21440000
PH12     DC    H'12'               MNT AREA PER NAME                    21460000
LIT42    DC    H'42'                                             A25956 21470018
MAXOUT1  DC    H'144'              MAX OUTPUT LEN IS 144         A52039 21472021
PDBLANK  DC    CL8' '              DOUBLE WORD OF BLANKS (FOR BLANKING) 21480000
PDZERO   DC    D'0'                DOUBLE WORD OF ZEROES (FOR ZEROING)  21500000
*                                                                       21520000
*                                                                       21540000
*                                                                       21560000
TABLE    EQU   *                                                        21580000
*                                                                       21600000
*        COMMAND AND KEYWORD SWITCHES                                   21620000
*                                                                       21640000
PPCSW1   DC    X'0'                COMMAND SWITCH-PRINT/PUNCH           21660000
PPCSW2   DC    X'0'      NU                                             21680000
TITLESW  DC    X'0'                TITLESWITCH                          21700000
EXITSW   DC    X'0'      NU                                             21720000
MEMBERSW DC    X'0'      NU                                             21740000
RECORDSW DC    X'0'                RECORD SWITCH                        21760000
PLISTSW  DC    X'0'      NU                                             21780000
FIRSTSW  DC    X'0'      NU        FIRST TIME SWITCH                    21800000
COMMSW   DC    X'0'                COMMAND SWITCH                       21820000
PPCONCD  DC    X'0'                RETURN CODE                          21840000
MAXOUT   DC    H'144'              MAX OUTPUT LEN IS 144         A52039 21860021
MCBADD   DC    F'0'                ADDRESS OF MCB                       21880000
*                                                                       21900000
LENSAVE  DS    F                   LENGTH SAVE AREA                     21920000
LOCSAVE  DS    F                   LOCATION SAVE AREA                   21940000
DBLWD    DS    1D                 WORK AREA FOR CVB ROUTINE             21960000
*                                                                       21980000
*                                                                       22000000
FIELDCNT DC    H'0'         COUNT OF FLD PARAM'S FOUND SO FAR      1769 22010014
MAXNAME  DC    H'0'                MAX MEMBER STATEMENTS                22020000
MEMBCT   DC    H'0'                MEMBER COUNT                         22040000
MAXGPS   DC    H'0'                MAX IDENT PARAMETERS                 22060000
MAXLITS  DC    H'0'                MAX LITERAL CHARACTERS               22080000
MAXFLDS  DC    H'0'                MAX FIELD PARAMETERS                 22100000
CURRLIT  DC    H'0'                NO OF BYTES STORED IN LITERAL POOL   22120000
CURRGCB  DC    F'0'                LENGTH OF CURRENT GCB                22140000
CURRMCB  DC    F'0'                LENGTH OF CURRENT MCB                22160000
MCBREM   DC    F'0'                REMAINING STORAGE IN MCB             22180000
CURRMNT  DC    F'0'                POINTER TO MNT                       22200000
MCBLEN   DS    F                   MCB LENGTH                           22220000
TABLEN   EQU   *-TABLE             TABLE LENGTH                         22240000
*                                                                       22260000
FCBL     EQU   8                   LENGTH INDICATOR                     22280000
GCBL     EQU   8                  LENGTH INDICATOR                      22300000
*                                                                       22320000
*                                                                       22340000
LISTLEN  EQU   PH12                LENGTH INDICATOR                     22360000
FCBLEN   EQU   PH8                 LENGTH INDICATOR                     22380000
GCBLEN   EQU   PH8                 LENGTH INDICATOR                     22400000
*                                                                       22420000
*                                                                       22440000
*        EXTERNAL REFERENCES                                            22460000
*                                                                       22480000
CDWRT    DC    V(CCWRITE)          ADDRESS OF WRITE EXTERN              22500000
PMSGWRTA DC    V(PPMSGWRT)         ADDRESS OF MESSAGE WRITE EXTERN      22520000
R7    EQU    7                                                     7715 22520419
FREESYND DS    F                  ADDR OF DYNAMIC MSG AREA         7715 22520819
MSGSYNDF DC    CL96'IEB421I I/O ERROR'       SYNAD I/O ERROR MSG   7715 22521219
VZZPR    DC    V(ZZPR)               ADDR OF PRINT ROUTINE IN PPUN17715 22521619
*--------------------MESSAGE POINTERS------EXTERNAL-------------------* 22522018
VPPIKM   DC    V(PPIKM)            INVALID KEYWORD MESSAGE         SA0I 22524018
VPPIPM   DC    V(PPIPM)            INVALID PARAMETER MESSAGE       SA0I 22526018
VPPMKM   DC    V(PPMKM)            MISSING KEYWORD MESSAGE         SA0I 22528018
VPPMPM   DC    V(PPMPM)            MISSING PARAMETER MESSAGE       SA0I 22530018
VPPMCM   DC    V(PPMCM)            MISSING COMMAND MESSAGE         SA0I 22532018
*                                                                       22534018
*                                                                       22536018
*                                                                       22538018
*                                                                       22540000
*                                                                       22560000
DTABLE   DSECT                                                          22580000
DBEGIN   DS    0F                                                       22600000
DDN1     DS    CL8                 DDNAME FOR SYSUT1                    22620000
DDN2     DS    CL8                 DDNAME FOR SYSUT2                    22640000
EXLSTADD DS    A                   ADDRESS OF EXIT LIST                 22660000
LITADD   DC    F'0'                ADDRESS OF LITERAL POOL              22680000
MNTADD   DC    F'0'                ADDRESS OF MNT                       22700000
RCB      DS    0X                                                       22720000
TYPORG   DC    X'0'               DATA SET ORGANIZATION-DEFAULT=PS      22740000
TOTCONV  DC    X'0'                                                     22760000
PPSW1    DC    X'0'                                                     22780000
PPCTL    DC    X'0'                                                     22800000
CDNOB    DC    F'0'                                                     22820000
CDINCRB  DC    F'0'                                                     22840000
INITPG   DC    H'0'               INIT PAGE NUMBER-DEFAULT=1            22860000
PMAXLINE DC    H'0'               MAX LINES PER PAGE-DEFAULT=60         22880000
INITSTOP DC    H'0'               RECORDS TREATED IF STOPAFT SPECIFIED  22900000
INITSKIP DC    H'0'               NTH RECORD TREATED-DEFAULT=ALL        22920000
STRTAFT  DC    H'0'               RECORD     TO START AFT        A45135 22930021
TCB      DS    0F                 TITLE CONTROL BLOCK                   22940000
TCB1     DC    H'0'                    LENGTH                           22960000
         DC    H'0'                    ROLOC                            22980000
         DC    F'0'                    ADDR                             23000000
*                                 SUBTITLE                              23020000
TCB2     DC    H'0'                    LENGTH                           23040000
         DC    H'0'                    ROLOC                            23060000
         DC    F'0'                    ADDR                             23080000
PREFMTP  DC    X'00'               FORMATTED OUTPUT                     23100000
LBLPRTSW DC    X'F0'                    DEFAULT VALUES SET TO PRNT UL0H 23105017
PROCKY   DC    X'80'                    PROCESS =YES               UL0H 23110017
LBLCONSW DC    X'00'                    NO LABEL CONV.             UL0H 23115017
EXLST    DS    0X                 LIST OF USER EXITS                    23120000
EX1      DC    BL8'0'                                              UL0H 23140017
EX3      DC    BL8'0'                                              UL0H 23160017
EXIN     DS    CL8                     INREC                            23180000
EXOUT    DS    CL8                     OUTREC                           23200000
EXLEN    EQU   *-EXLST            EXIT LIST LENGTH                      23220000
DLEN     EQU   *-DBEGIN           DTABLE LENGTH                         23240000
*                                                                       23240819
*      FREECOR TABLE CONTAINS DATA FOR LATER  FREEMAINS FOR DTABLE 4304 23241619
*                                                                  4304 23242419
FREECOR  DSECT                                                     4304 23243219
DTBL     DS    F              DTABLE LENGTH                        4304 23244019
DTBA     DS    F              ADDRESS OF DTABLE                    4304 23244819
GS1L     DS    F              LENGTH OF MNT                        4304 23245619
MNTA     DS    F              ADDRESS OF MNT                       4304 23246419
MCBL     DS    F              LENGTH OF MCB                        4304 23247219
MCBA     DS    F              ADDRESS OF MCB                       4304 23248019
LITS     DS    F              LENGTH-COUNT  OF LITERALS            4304 23248819
LITA     DS    F              ADDRESS OF LITERALS                  4304 23249619
TITLA    DS    F              ADDRESS OF TITLE                     4304 23250419
SUBTITA  DS    F              ADDRESS OF SUBTITLE                  4304 23251219
*                                                                  4304 23252019
*        SWITCHES  TO INDICATE SPECIFIC GETMAINS DONE              4304 23252819
MAIN1    DS    XL1            DTABLE                               4304 23253619
MAIN2    DS    XL1            MEMBER NAMETABLE                     4304 23254419
MAIN3    DS    XL1            MCB                                  4304 23255219
MAIN4    DS    XL1            LITERALS                             4304 23256019
MAIN5    DS    XL1            TITLE                                4304 23256819
MAIN6    DS    XL1            SUBTITLE                             4304 23257619
         END   IEBPPAL1                                                 23260000
