     TITLE 'IEBPPCH1-IEBPTPCH MAIN PROCESSOR'                           00020014
*                                                                       00040000
*                                                                       00060000
* TITLE  - IEBPPCH1 ---RELEASE SEVENTEEN                                00080017
*                                                                       00100000
*                                                                       00120000
* FUNCTION/OPERATION - THIS IS THE MAIN PROCESSING MODULE OF THE PRINT/ 00140000
* PUNCH UTILITY. IT OPERATES ON A TABLE BUILT BY IEBPPAL1. IT FUNCTIONS 00160000
* AS FOLLOWS:                                                           00161017
*        THE TABLE IS STORED, AND PROCESSING PARAMATERS ARE             00162017
*  ESTABLISHED.                                                         00163017
* THE INPUT IS OPENED THE FIRST TIME, THE OUTPUT IS OPENED, AND IF      00164021
* NECESSARY THE INPUT IS OPENED THE SECOND TIME. THE INPUT DATA SET IS  00164821
* OPENED AS A BSAM FILE. THE INPUT CAN BE PHYSICAL SEQUENTIAL OR        00165621
* PARTITIONED. A DCB EXIT IS TAKEN BY THE UTILITY WHEREUPON IT IS       00166421
* DETERMINED IF THE INPUT CONSISTS OF VARIABLE SPANNED RECORDS(VALID IN 00167221
* PS ORGANIZATION ONLY). IF VS/VBS,AND THE RECORD LENGTH DOES NOT       00168021
* EXCEED 32K, THE INPUT DATA SET IS CLOSED, AND THEN REOPENED FOR       00169017
* QSAM IO. IF VARIABLE AND >32K, THE FILE IS PROCESSED BLOCK BY         00170017
* BLOCK WITH BSAM.                                                      00171017
*       DURING THE FIRST (OR ONLY) INPUT OPEN, THE UTILITY TAKES        00172017
* A HEADER LABEL EXIT(IF SUL HAS BEEN SPECIFIED FOR SYSUT1). IT         00173017
* INTERROGATES THE TABLE FROM PAL1 FOR USER LABEL PROCESSING            00174017
* INSTRUCTIONS AND EXIT ADDRESS. IF NONE, THE DEFAULT OPTION OF         00175017
* PROCESSING ALL USER HEADER AND TRAILER LABELS AS DATA IS EXCER-       00176017
* CISED. IF A USER EXIT EXISTS, IT IS ACCESSED AND THE LABELS ARE       00177017
* PROCESSED ACCORDING TO THE 'LABELS' STATEMENT,DEPENDENT ON USER       00178017
* SUPPLIED RETURN CODES.                                                00179017
*        UPON RETURN TO THE UTILITY FROM OPEN, THE STORED LABELS        00180017
* ARE OUTPUTTED UNLESS THE USER HAS SPECIFIED OTHERWISE.                00181017
*                                                                       00200000
*      IF THE INPUTDATA SET, SYSUT1, IS PARTITIONED AND THE ENTIRE      00220000
* DATA SET IS TO BE READ AND PROCESSED, THE PROGRAM READS THE DIRECTORY 00240000
* AND EXTRACTS THE NAME AND LOCATION OF EACH ENTRY. THE ENTRIES ARE     00260000
* THEN SORTED BY TTR AND ALIAS SO THAT MEMBERS CAN BE WRITTEN IN THE    00280000
* ORDER OF THEIR PHYSICAL OCCURRENCE ON THE DIRECT ACCESS DEVICE.       00300000
*                                                                       00320000
*                                                                       00420000
*      IF THE INPUT DATA SET IS PARTITIONED, THE NAME AND LOCATION OF   00440000
* THE MEMBER THAT IS TO BE PROCESSED IS OBTAINED AND THE DATA SET IS    00460000
* POSITIONED SO THAT THE MEMBER CAN BE READ.                            00480000
*                                                                       00500000
*      ANY USER-SUPPLIED TITLES ARE WRITTEN AT THIS TIME. IF THE INPUT  00520000
* IS PARTITIONED, THE MEMBER CURRENTLY BEING PROCESSED IS IDENTIFIED.   00540000
* A NEW PAGE IS STARTED FOR PRINTED OUTPUT OR A NEW SEQUENCE NUMBER IS  00560000
* INITIATED FOR PUNCHED OUTPUT. THE PROGRAM THEN DETERMINES WHETHER     00580000
* THERE ARE USER WRITTEN RECORD GROUPS AND PERFORMS INITIALIZATION      00600000
* ACCORDINGLY. IF THERE IS NO EDITING, INITIALIZATION IS PERFORMED TO   00620000
* PROCESS THE SEQUENTIAL DATA SET OR MEMBER IN THE STANDARD FORMAT.     00640000
*                                                                       00660000
*      THE  R D C H  ROUTINE READS A PHYSICAL RECORD AND DETERMINES IF  00680000
* A NOTE LIST IS PRESENT. IF THE PHYSICAL RECORD IS A NOTE LIST AND IT  00700000
* IS TO BE OMITTED, THE NEXT PHYSICAL RECORD IS READ.                   00720000
*                                                                       00740000
*      AT THIS TIME THE  P R E F O R M  ROUTINE TAKES CONTROL IF,       00760000
* PREFORM WAS SPECIFIED AND DEBLOCKS THE INPUT AND WRITES THE OUTPUT.   00780000
* THE OUTPUT MAY BE EITHER PRINTED OR PUNCHED.                          00800000
*                                                                       00820000
*      THE  R E C L O C 1  ROUTINE DEBLOCKS THE PHYSICAL RECORD AND     00840000
* OBTAINS THE LENGTH AND LOCATION OF THE NEXT LOGICAL RECORD. WHEN NO   00860000
* LOGICAL RECORDS REMAIN IN A BLOCK, THE  R E C L O C 1  ROUTINE        00880000
* RETURNS TO THE  R D C H  ROUTINE, AND ANOTHER PHYSICAL RECORD IS      00900000
* READ.                                                                 00920000
*                                                                       00940000
*      A USER EXIT CAN BE TAKEN AT THIS POINT TO PROCESS A LOGICAL      00960000
* RECORD BEFORE IT IS PROCESSED BY THE PROGRAM.                         00980000
*                                                                       01000000
*      THE PROCESSING OF A LOGICAL RECORD INCLUDES CHECKING THE RECORD  01020000
* ID TO DETERMINE IF IT IS THE LAST RECORD IN A RECORD GROUP AND        01040000
* TESTING THE RECORD COUNT TO SEE IF THE RECORD SHOULD BE SKIPPED. IF   01060000
* THE RECORD IS THE LAST RECORD OF A RECORD GROUP, A SWITCH IS SET FOR  01080000
* SUBSEQUENT TESTING. IF THE RECORD IS SKIPPED, CONTROL IS PASSED TO    01100000
* THE END OF RECORD GROUP TEST.                                         01120000
*                                                                       01140000
*      NEXT, THE OUTPUT FORMAT OF THE LOGICAL RECORD IS TESTED TO       01160000
* DETERMINE IF IT IS TO BE STANDARD OR USER DEFINED. THE  F O R M S     01180000
* ROUTINE WRITES A LOGICAL RECORD IN THE STANDARD FORMAT AND WHEN       01200000
* NECESSARY, SEGMENTS THE INPUT RECORD INTO MULTIPLE OUTPUT RECORDS.    01220000
* THE  F O R M U  ROUTINE EDITS A LOGICAL RECORD ACCORDING TO USER      01240000
* SPECIFICATIONS. A USER EXIT MAY BE TAKEN BEFORE THE RECORD IS WRITTEN 01260000
* TO ALLOW THE USER TO PERFORM ADDITIONAL EDITING.                      01280000
*                                                                       01300000
*      AFTER THE LAST RECORD IN EACH RECORD GROUP IS WRITTEN, THE       01320000
* N E X T G R  ROUTINE PERFROMS REINITIALIZATION TO ALLOW THE NEXT      01340000
* RECORD GROUP TO BE PROCESSED.                                         01360000
*                                                                       01380000
*    WHEN THE END OF DATA FOR A MEMBER OF A PO DATA SET IS REACHED      01400017
* THE NAME AND LOCATION OF THE NEXT MEMBER IS OBTAINED AND THE DATA SET 01420000
* IS POSITIONED TO THE NEXT MEMBER.                                     01450017
*        WHEN THE END OF DATA IS REACHED, OR THE USER'S SPECIFIC        01480017
*    DATA REQUEST HAS BEEN FULFILLED,                                   01510017
*                                                                       01540000
*      THE TASK IS TERMINATED AND CONTROL IS RETURNED TO THE CALLING    01560000
* PROGRAM.                                                              01580000
*                                                                       01600000
*                                                                       01620000
* ENTRY POINT - IEBPPCH1 IS ENTERED BY IEBPPUN1 BY A CALL MACRO.        01640000
* REGISTER ONE POINTS TO THE 'DTABLE'.                                  01660000
*                                                                       01680000
*                                                                       01700000
* INPUT - ANY SEQUENTIAL OR PARTITIONED DATA SET WITH FIXED, FIXED      01720000
* BLOCKED, VARIABLE, VARIABLE BLOCKED OR UNDEFINED RECORD FORMATS.      01740000
*                                                                       01760000
*                                                                       01780000
*OUTPUT----                                                             01788017
*    IF PRINTED, CAN BE ANY SIZE SPECIFIED BY THE USER IN THE           01796017
* SYSUT2 DD STATEMENT. IT IS THE USER'S RESPONSIBILITY TO SUPPLY        01804017
* THE CORRECT OUTPUT SIZE, DEPENDENT ON THE CAPABILITIES OF THE         01812017
* DEVICE BEING USED. IF NO OUTPUT SIZE IS SPECIFIED, PRINT/PUNCH        01820017
* SETS THE DEFAULT SIZE OF 121 BYTES. PUNCHED OUTPUT IS 81 BYTES        01828017
* AND BOTH ARE FIXED LENGTH RECORDS, THE FIRST CHARACTER OF             01836017
* WHICH IS A CONTROL CHARACTER FOR THE OUTPUT DEVICE.                   01844017
*  OUTPUT MUST BE RECORD LENGTH PLUS 1 BYTE FOR CONTROL CHARACTER.      01852017
*                                                                       01860000
*                                                                       01880000
* EXTERNAL ROUTINES - USES A BALR TO GO TO TWO ROUTINES IN IEBPPUN1 --  01900000
* PPMSGWRT AND PPMNMSG -- WHICH DECIDES WHAT MESSAGE TO PRINT AND THEN  01920000
* CONTROL IS GIVEN TO THE ZZPR ROUTINE, ALSO OF THE SAME MODULE, WHICH  01940000
* IS THE MESSAGE WRITER.                                                01960000
*                                                                       01980000
*                                                                       02000000
* EXITS - N O R M A L -- A RETURN TO THE USER OF THE PROGRAM.           02020000
*                                                                       02040000
*                        A LINK TO A USER EXIT THAT MANIPULATES LOGICAL 02060000
*                        RECORDS BEFORE PROCESSING(INREC).              02080000
*                                                                       02100000
*                        A LINK TO A USER EXIT THAT MANIPULATES LOGICAL 02120000
*                        RECORDS BEFORE THEY ARE OUTPUTED(OUTREC).      02140000
*                                                                       02160000
*                       A LOAD OF A USER EXIT ROUTINE THAT              02170017
*                       PROCESSES INPUT HDR LABELS(UHIN).               02180017
*                                                                       02190017
*                       A LOAD OF A USER EXIT ROUTINE THAT              02200017
*                       PROCESSES INPUT TLR LABELS(UTIN).               02210017
*   NO TRAILER LABEL EXIT CAN BE TAKEN, IF THE 'STOPAFT' PARAMETER      02220017
* CAUSES  THE UTILITY TO TERMINATE PRIOR TO END OF INPUT.               02230017
*                                                                       02280000
*         E R R O R S -- TO THE ABOVE MENTIONED EXTERNAL ROUTINES WITH  02300000
* IT RETURNING TO THIS MODULES END OF JOB ROUTINE. A MESSAGE LOCATED IN 02320000
* IEBPPMSG MAY ALSO BE EXTERNALLY REFERENCED AND FILLED IN WITH A       02340000
* DDNAME.                                                               02360000
*                                                                       02380000
*                                                                       02400000
* TABLES & WORK AREAS:                                                  02410017
*    STORAGE IS DYNAMICALLY ALLOCATED FOR INPUT AND OUTPUT BUFFERS.     02420017
*  INPUT IS BLOCK SIZE PLUS KEY LENGTH PLUS 4 BYTES FOR SEGMENT         02430017
* DESCRIPTOR WORDS, IF VRE.                                             02440017
*  LABEL PROCESSING REQUIRES 640 BYTES OF FIXED STORAGE                 02450017
* IMBEDDED IN THIS MODULE.                                              02460017
*                                                                       02520000
*                                                                       02540000
* ATTRIBUTES - NON-REUSABLE                                             02560000
*                                                                       02580000
*                                                                       02600000
         EJECT                                                          02620000
*                                                                       02640000
*********************************************************************** 02660000
* EXAMINE PARAMETERS AND PREFORM INITIALIZATION BASED UPON THOSE      * 02680000
* PARAMETERS.                                                         * 02700000
*********************************************************************** 02720000
*                                                                       02740000
IEBPPCH1 CSECT                                                          02780000
*3315050000                                                        4055 02786016
*3315249400-250000,251000,253800-254200                            2461 02792016
*3315248400-248600,250200-250400,252600,255400-255800,263400       VS0H 02794017
*3392271600,271800,351600                                        A23458 02796018
*3392057160,305200                                               A23836 02798018
*182600,196800                                                    24304 02802019
*285810-285950,325660,325720,351000,351600                        27715 02804019
*350207,350235,350239                                             29059 02806019
*143800,144000                                                    29305 02808019
*175200                                                           29475 02810019
*351500                                                           30004 02812019
*393800                                                                 02814019
*350326                                                  PTM4866=A38702 02814520
*039000,039200                                                     2642 02815020
*142000,143200-143600,145200                                     A34102 02815520
*292260,292320                                                   A35453 02815921
*174200                                                          A36088 02821921
*079400-079600,301200                                            A36098 02823921
*057050-057120,350342-350344,351500,821800-827000                A38762 02825921
*A059300,177100,177120                                           A41759 02827921
*C176600                                                         A41759 02829921
*A180700-180760,181000-181320                                    A41816 02834121
*D180700,181000,182720                                           A41816 02834821
*A116020-116192,149580                                           A44337 02835521
*D116400-116600,149600                                           A44337 02836321
*C149800                                                         A44337 02838321
*A228100,228200,229020-221000,229400-229800,351965,829700-829740 A45134 02844100
*D228200,229400-229800                                           A45134 02845000
*A035500-035584,055300-055360,06500,057020-057040,057144-057342  A45135 02845900
*A063420,063440,084700-084780,097304-097388,111900-111997,       A45135 02846800
*A283500-283540,287668-287696,305300,311500,316900,347775-347828 A45135 02847700
*A350221,350277-350280,351937,825320,827900-829600,830300-830800 A45135 02849221
*D038800-041200,053200,057150-057180,057200,287657-287666,       A45135 02851221
*D350277,350278,836300                                           A45135 02853221
*C042600,055400,057371,065140,097400,287692,292260,292320,       A45135 02853621
*C305200,393900,825300                                           A45135 02853721
*A051400,051500,055320-055500,056300                            AS12988 02853821
*D051400,055320-055400                                          AS12988 02854000
*A284320,284350,285840-285845,350050                             A48732 02855900
*D063540-063800,064000,284350,285840                             A48732 02857900
*C351000                                                         A48793 02860421
*A161200-161783,240950,285840-285845,347780-348003,350216,       A48796 02860800
*A350218,350224,350228,351000                                    A48796 02861200
*D161200-161600,240950,285840,347775-347828,350216,350218,       A48796 02861600
*D350221,350223,350301,351000                                    A48796 02862000
*A237800-238200,239100-239160                                    A50923 02862421
*C237800-238200,239000                                           A50923 02864421
*D239200-239600                                                  A50923 02866421
*A276300-276392,837900-838800                                    A52039 02866821
*C305200,305300,827600,827700,827900,828300,829500               A52039 02867221
*D275400,275600,276000,350600-351000                             A52039 02867321
*A028715,116180,116392,116592                                    A55773 02867521
*D028675,116180                                                  A55773 02869521
*A036700,058850,063620-063720                                   SA57755 02870121
*C036400,058600                                                 SA57755 02870721
         SAVE  (14,12),T,IEBPPCH109-JULY-66 RENUMBER THE STMNT   A55773 02871521
         BALR  BASER,R0                SET BASIC CSECT ADDRESSABILITY   02874021
         USING *,BASER,BASER2          TWO BASE REGISTERS FOR MODULE    02880521
         USING DTABLE,R1               BASE FOR DTABLE DSECT            02887021
         LA    BASER2,4095(BASER)      SET SECOND BASE ADDRESSABILITY   02893521
         LA    BASER2,1(BASER2)        BUMP SECOND BASE TO 4096         02900000
         ST    R13,PERM13              SAVE REGISTER 13                 02920000
         ST    R13,SAVEADD+4            SAVE ADDRESS OF SAVE AREA       02940000
         LA    R1,SAVEADD               GET PTR TO SAVE AREA            02960000
         ST    R1,8(R13)                STORE PTR TO S.A. IN SAVE AREA  02980000
         L     R1,24(R13)               RESTORE R1                      03000000
         ST    R1,TABLEADD                                         UL0H 03010017
         LA    R13,SAVEADD             LOAD ADDRESS OF THIS SAVE AREA   03020000
*                                                                       03040000
*          EXAMINE TABLE PREPARED BY ROOT SEGMENT                       03060000
*            INDICATE EXIT LIST ADDRESSES IN DCB                        03080000
*                                                                       03100000
         SR    R2,R2                   CLEAR REGISTER TWO               03120000
         C     R2,DDN1                 IS THERE A SYSUT1                03140000
         BE    PRPUN2                  NO --- BRANCH                    03160000
         LA    DCBREG,INSET            YES - GET ADDRESS OF INPUT DCB   03180000
         MVC   DDNAM(8,DCBREG),DDN1    MOVE SYSUT1 TO DCB DDNAME        03200000
PRPUN2   C     R2,DDN2                 IS THERE A SYSUT2                03220000
         BE    PRPUN3                  NO --- BRANCH                    03240000
         LA    DCBREG,OUTSET           YES - GET ADDRESS OF OUTPUT DCB  03260000
         MVC   DDNAM(8,DCBREG),DDN2    MOVE SYSUT2 TO DCB DDNAME        03280000
PRPUN3   C     R2,DEXLSTA              IS THERE AN EXIST LIST           03300000
         BE    PRPUN4                  NO --- BRANCH                    03320000
         L     R4,DEXLSTA              YES -- LOAD EXIT LIST ADDRESS    03340000
         MVC   EXLIST(EXLEN),0(R4)     MOVE LIST TO BREAK IT UP         03360000
         CLI   INHDR,C' '              IS THERE AN INPUT HEADER LAB RTE 03380000
         BE    PRPUN3A                 NO --- BRANCH                    03400000
         LOAD  EPLOC=INHDR                                         UL0H 03406017
         ST    R0,UHIN                                             UL0H 03412017
         OI    UHIN,X'01'              YES -- SET INDICATOR BYTE IN LST 03420000
         MVI   PPHINEX,X'01'      ACTIVATE HEADER LABEL EXIT     A35453 03430021
PRPUN3A  CLI   INTLR,C' '              IS THERE A INPUT TRAILER LAB RTE 03440000
         BE    PRPUN4                  NO EXIT --- BRANCH               03460000
         LOAD  EPLOC=INTLR                                         UL0H 03466017
         ST    R0,UTIN                                             UL0H 03472017
         OI    UTIN,X'03'              YES -- SET INDICATOR BYTE IN LST 03480000
         MVI   PPTINEX,X'03'      ACTIVATE TRAILER LABEL EXIT    A35453 03482021
PRPUN4   L     R1,TABLEADD             RESTORE DTABLE BASE         UL0H 03490017
         MVC   TABLE(TBLEN),DTBLE      MOVE TCBS & SWTCHS TO BRK   UL0H 03500017
*                                      THEM UP FOR PROCESSING           03520000
         DROP  R1                      DROP BASE FOR DTABLE             03540000
         CLI   PROCKY,X'40'        NO LABEL PRINTING ?           A45135 03550021
         BE    CONTIN              YES, SKIP INIT. OF LAB. EX.   A45135 03552021
         MVI   PPHINEX,X'01'       INIT HEADER LAB. EXIT         A45135 03552421
         CLI   PROCKY,X'10'        ONLY LABEL PRINTING ?         A45135 03554021
         BE    CONTIN              YES, SKIP INIT. OF TR. LAB.EX.A45135 03556021
         MVI   PPTINEX,X'03'       INIT. TRAILER LAB  EXIT       A45135 03558021
CONTIN   EQU   *                                                 A45135 03558421
         OC    CDINCRB(4),CDINCRB       CARD INCREMENT SPECIFIED        03560000
         BNE   PRPUN5A                  YES, INCREMENT SPECIFIED        03580000
         MVI   CDINCRB+3,10             NO,DEFAULT OPTION IS 10         03600000
PRPUN5A  CLC   PMAXLINE(2),PHZERO      IS ASSUMED LINES/PAGE COUNT ZERO 03620000
         BNE   WHATTYPE      NO -- BRANCH -- USER SUPPLIED      SA57755 03640021
         MVI   PMAXLINE+1,60           YES -- INITIALIZE IT             03660000
         B     WHATTYPE                OPEN INPUT(SYSUT1) FIRST SA57755 03670021
         EJECT                                                          03680000
*                                                                       03700000
*          OPEN DCBS                                                    03720000
*            INITIALIZE FOR PRINT                                       03740000
*              OR PUNCH OPERATION                                       03760000
*                                                                       03780000
PPOPEN   TM    PPSW1,1                 TEST SWITCH FOR PUNCH OPERATION  03800000
         BZ    PPOPEN4                 OFF -- BRANCH PRINT OPERATION    03820000
*          P U N C H    I N I T I A L I Z A T I O N                     03840000
         LA    DCBREG,OUTSET           LOAD ADDRESS OF OUTPUT DCB       03860000
         LA    CTLREG,STACK2           GET STACKER 2 CTL CHARACTER ADR  04140000
         CLI   CNTRL,X'02'             CHECK CTL CHAR PASSED AS PARAM   04160000
         BE    PPOPEN6                 IF EQUAL USE STACKER TWO         04180000
         BCT   CTLREG,PPOPEN6          IF NOT EQUAL USE STACKER ONE     04200000
*          P R I N T    I N I T I A L I Z A T I O N                     04220000
PPOPEN4  CLI   CNTRL,X'02'             CHECK CTL CHAR PASSED AS PARAM   04240000
         BL    ISITFMT                 IF LOWER SNGLE SPACE OUTP A45135 04260021
         LA    TEMP1,3                 LOAD LINE INCREMENT - TRI SPACE  04280000
         LA    CTLREG,SPTRIPLE         GET ADR OF TRIPLE SPACE CTL CHAR 04300000
         BH    PPOPEN5                 TRIPLE SPACE IF COMPARES HIGHER  04320000
         BCTR  TEMP1,R0                DOUBLE SPACE IF EQUAL COMPARE    04340000
         BCTR  CTLREG,R0               REDUCE PTR TO DOUB SPACE CTL CHR 04360000
PPOPEN5  STH   TEMP1,LINEINCR          INITIALIZE LINE INCREMENT TO A   04380000
*                                      2 OR 3 -- ASSEMBLY TIME SET TO 1 04400000
PPOPEN6  MVC   PPCTL(1),0(CTLREG)      MOVE CTL CHAR TO OUTPUT BUFFER   04420000
ISITFMT  TM    PREFORMT,X'81'          IS IT PREFORMATTED INPUT         04540000
         BZ    CHKDCBS                                             7034 04560000
         TM    PREFORMT,X'80'          IS IT IN ASA CONTROL CHARACTER   04580000
         BO    CHKDCBS                                             1591 04600014
         NI    OUTSET+36,X'F9'         CLEAR OUT CTL CHAR BITS IN DCB   04620000
         OI    OUTSET+36,X'02'         SET CTL CHAR TO MACHINE CODE     04640000
*                                                                  7034 04660000
*    CHECK ...ARE BOTH SYSPRINT AND SYSUT2  USING  SAME  U.C.B.    7034 04680000
*                                                                  7034 04700000
CHKDCBS  STM   R4,R6,KEEPR4R6   SAVE R4 R5  R6                     7034 04720000
         LA    R6,OUTSET    D C B  ADDRESS                         7034 04740000
         SR    R5,R5                                               7034 04760000
         L     R5,16(R5)      GET POINTER TO TCB FROM CVT          7034 04780000
         L     R5,0(R5)   POINTS TO POINTER OF T C B               7034 04800000
         L     R5,4(R5)       POINTER TO CURRENT TCB               7034 04820000
         L     R5,12(R5)      POINTER TO TIOT                      7034 04840000
         ST    R5,STARTIOT    SAVE POINTER TO START OF TIOT        7034 04860000
         LA    R5,28(R5)      FIRST DDNAME ENTRY                   7034 04880000
         MVC   SISUT2(8),DDNAM(R6)   GET SYSUT2 DDNAME             7034 04900000
FINDIT   CLC   0(8,R5),SISUT2      IS THIS ENTRY SYSUT2 T          7034 04920000
         BC    8,GETUCB       YES...GO FIND UCB                    7034 04940000
         LA    R4,4          ADDRESS CORECTION                     4055 04947016
         SR    R5,R4         GET BEGINNING OF DD ENTRY             4055 04954016
         IC    R4,0(R5)      GET LENGTH OF DD ENTRY                4055 04961016
         AR    R5,R4         UPDATE POINTER TO NEXT DD ENTRY       4055 04968016
         TM    0(R5),X'FF'   IS TIOT ENDED                         4055 04975016
         BZ    NOENTRY       YES...ERROR    NO...CONTINUE          4055 04982016
         LA    R5,4(R5)      GET ADDRESS OF NEXT DDNAME            4055 04989016
         B     FINDIT         SEARCH SOME MORE                     7034 05020000
*                                                                  7034 05040000
*              GET SYSUT2   UCB ...TEST IT FOR TAPE                7034 05060000
*                                                                  7034 05080000
GETUCB   L     R5,12(R5)       POINTER TO UCB                      7034 05100000
         LA    R5,0(R5)       CLEAR HIGH ORDER BYTE                7034 05120000
         LTR   R4,R5              TST UCB ADDR.  FOR ZERO       AS12988 05140021
         BZ    PPOPOUT1           ZERO, OPEN SYSUT2             AS12988 05150021
         TM   18(R5),X'80'     IS IT TAPE                          7034 05160000
         BO    CHKSYSPR     GO GET SYSPRINT U C B                  7034 05180000
         LM    R4,R6,KEEPR4R6      NO...                           7034 05200000
         B     PPOPOUT          GO TO NORMAL OPEN FOR SYSUT2       7034 05220000
*                                                                  7034 05240000
*        FIND  SYSPRINT UCB AND COMPARE IT WITH SYSUT2 UCB         7034 05260000
*                                                                  7034 05280000
CHKSYSPR L     R5,SYSPRPTR    GET ADDRESS OF VCON PPOUT            7034 05300000
         LH    R5,40(R5)    GET T I O T   OFFSET                   7034 05320000
         L     R6,STARTIOT    BEGINNING OF T I O T  TABLE          7034 05340000
         AR    R5,R6      ADD OFFSET TO START OF T I O T           7034 05360000
         L     R5,16(R5)    GET U C B    ADDRESS                   7034 05380000
         LA    R5,0(R5)       CLEAR THE HIGH ORDER BYTE            7034 05400000
         CR    R4,R5          COMPARE UCB ADDRESSES                7034 05420000
         BC    8,SETTAPES     EQUAL...DONT OPEN DCB FOR SYSUT2     7034 05440000
         LM    R4,R6,KEEPR4R6     RESTORE R4  R5  R6               7034 05460000
         B     PPOPOUT        DO NORMAL SYSUT2 OPEN                7034 05480000
SETTAPES MVI   NOTOPEN,X'F0'  SET SWITCH FOR WRITE                 7034 05500000
         TM    PPSW1,1             PUNCHED OUTPUT ?              A45135 05530021
         BO    NOENTRY            YES,SEND ERR. MSG. IEB411I    AS12988 05532021
         TM    OUTSET+36,X'02'    IS RECFM FBM ?                AS12988 05541021
         BNO   INSEGTST           NO,DONT OPEN UT2 AND CONT.    AS12988 05550021
NOENTRY  LM    R4,R6,KEEPR4R6  RESTORE R4 R5 R6                    7034 05560000
         LA    TEMP1,OUTSET       DCB OF DDNAME NOT FOUND IN TIOT  7034 05580000
         B     DDERROR                                             7034 05600000
*          O P E N    O U T P U T    D C B                              05620000
PPOPOUT1 LM    R4,R6,KEEPR4R6     RESTORE R4,R5,R6              AS12988 05630021
PPOPOUT  OPEN  (OUTSET,OUTPUT)                                          05640000
         STM   R4,R6,KEEPR4R6                                           05650021
         LA    TEMP1,OUTSET            GET ADR OF SYSUT2 DCB - OUTPUT   05660000
         TM    OFLGS(TEMP1),X'10'      HAS IT BEEN OPENED               05680000
         BZ    DDERROR                 NO - PRINT ERROR MESSAGE         05700000
         TM    ERRDCB,X'80'   WRONG LRECL OR BLKSIZE PARAM ?     A45135 05702021
         BO    DCBERROR       YES, PRINT ERROR MESS.             A45135 05704021
         LH    R5,82(TEMP1)  CHECK FOR MAX LRECL                 A38762 05705021
         SH    R5,PH1                                              VS0H 05714017
         STH   R5,MAXOUT           STORE LRECL-1                 A45135 05714421
         TM    PPSW1,1             PUNCH OPERATION ?             A45135 05714521
         BZ    PRINTBUF            NO, TEST PRINTBUFF. LENGTH    A45135 05714621
SEQCHECK TM    PPSW1,X'03'         CARDS TO BE SEQUENCED ?       A45135 05714821
         BNO   *+8            NO, SET SPECIF. VALUES             A45135 05714921
         LA    R5,72               LOAD DATA FIELD LENGTH        A45135 05715021
         STH   R5,INSEG            INSERT SEGMENT LENGTH         A45135 05715421
         STH   R5,OUTSEG           SET OUTPUT SEGM. LENGTH       A45135 05715521
         LA    R5,1                LOAD ONE FOR MAXSEG           A45135 05715721
         STH   R5,MAXSEG           STORE ONE IN MAXSEG           A45135 05715821
INSEGTST TM    TOTCONV,1           CONVERSION OF DATA ?          A45135 05716421
         BZ   FINISH               NO, LEAVE THE INSEG VALUE     A45135 05716621
         LH    TEMP1,INSEG         LOAD CHAR. COUNT PER OUTP. GR A45135 05716821
         SRL   TEMP1,1             DIVIDE COUNT IN HALF          A45135 05717021
         STH   TEMP1,INSEG         STORE IT BACK                 A45135 05717221
         B     FINISH              END INITIAL. OF OUTPUT FORMAT A45135 05717421
PRINTBUF SR    R4,R4               ZERO REG 4 FOR DIV PURP.      A45135 05718421
         LH    R5,MAXOUT           LOAD MAXOUT PARAMETER         A45135 05718821
         CH    R5,=H'10'           LRECL-1 SMALLER TH TEN ?      A45135 05718921
         BH    TMAXSEG             NO, DETECT MAXSEG             A45135 05719021
         STH   R5,INSEG            SET INSEG AND                 A45135 05719121
         STH   R5,OUTSEG           OUTSET EQ TO MAXOUT           A45135 05722021
         LA    R5,1                SET NUMBER OF                 A45135 05724021
         STH   R5,MAXSEG           SEGMENTS TO ONE               A45135 05724421
         B     INSEGTST            SCAN FOR CONVERTING           A45135 05724821
TMAXSEG  LA    R6,10               CALCULATE THE                 A45135 05725521
         DR    R4,R6               NUMBER OF                     A45135 05728421
         STH   R5,MAXSEG           SEGMENTS                      A45135 05731321
         B     INSEGTST            TEST FOR CONVERTING           A45135 05733321
FINISH   LM    R4,R6,KEEPR4R6      LOAD REG 4 TO R6              A45135 05734221
FINISHUP CLC   INITSKIP(2),PHZERO                                A45135 05737121
         BE    PPOPEN10                YES -- BRANCH                    05740000
         LH    TEMP1,INITSKIP          NO -- LOAD RECORD NUMBER TO SKIP 05760000
         BCTR  TEMP1,R0                REDUCE IT BY ONE                 05780000
         STH   TEMP1,INITSKIP          STORE IT BACK                    05800000
         OI    INSW,SKIP               SET SWITCH TO ONE                05820000
PPOPEN10 CLC   INITSTOP(2),PHZERO      DO ALL RECORDS GET PROCESSED     05840000
         BE    POSTOPEN                OPEN HAS BEEN DONE FOR   SA57755 05860021
*                                       SYSUT1 (FIRST TIME) AND SA57755 05866021
*                                       SYSUT2                  SA57755 05872021
         OI    INSW,STOP               NO -- SET SWITCH TO TWO          05880000
         B     POSTOPEN                OPEN HAS BEEN DONE FOR   SA57755 05885021
*                                       SYSUT1(FIRST TIME) AND  SA57755 05890021
*                                       SYSUT2                  SA57755 05895021
WHATTYPE TM    TYPORG,3                WHAT TYPE DATA SET IS THE INPUT  05900000
         BZ    PREOPEN                 BITS OF = SEQ.              VS0H 05920017
         MVI   SDSEOD+1,X'00'      MARK INPUT NOT EMPTY          A41759 05930021
         BO    PREOP1                  ONLY PROCESS SOME MEMBERS OF PDS 05940000
         OI    POSTOPEN+1,X'F0'        TOTAL PDS, READ DIRECTORY FIRST  05960000
*                                      SET UNCONDITIONAL BRANCH ALSO    05980000
         B     PREOPEN                                             VS0H 06000017
PREOP1   LA    DCBREG,INSET            LOAD ADDRESS OF INPUT DCB        06020000
         MVI   DSORG(DCBREG),X'02'     MOVE PDS ORGANIZATION TO DCB     06040000
*          O P E N    I N P U T    D C B    T W I C E                   06060000
*             F I R S T    R E A D    D I R E C T O R Y                 06080000
*                T H E N    R E A D    M E M B E R S                    06100000
PREOPEN  LA    DCBREG,INSET                                        VS0H 06106017
         MVC   BSAMACRF(2,DCBREG),BSAMSPEC                         VS0H 06112017
         OI    OPENSW,X'10'            SET SW TO INDICATE VOL 1    UL0H 06116017
PPOPENIN OPEN  (INSET,INPUT)                                            06120000
*                                                                       06140000
*********************************************************************** 06160000
* CHECK TO SEE IF SYSUT1 DCB HAS BEEN OPENED. IF NOT PRINT AN ERROR   * 06180000
* MESSAGE STATING THAT SYSUT1 OR A CORRESPONDING DDNAME COULD NOT BE  * 06200000
* OPENED. A RETURN CODE OF 12 IS GIVEN. THE SAME PROCEDURE IS FOLLOWED* 06220000
* WHEN SYSUT2 COULD NOT BE OPENED.                                    * 06240000
*********************************************************************** 06260000
*                                                                       06280000
         LA    TEMP1,INSET             GET ADR OF SYSUT1 DCB - INPUT    06300000
         TM    OFLGS(TEMP1),X'10'      HAS IT BEEN OPENED               06320000
         BZ    DDERROR                 NO, PRINT AN ERROR MESSAGE       06340000
         TM    ERRDCB,X'80'      OPEN ERROR  ?                   A45135 06342021
         BO    DCBERROR          YES, PRINT MESS. AND TERM. EXEC.A45135 06344021
TESTRC   CLI   MSGWS,00                SEE IF  ANY MSG FROM OPEN   VS0H 06346017
         BNE   OPENMSG                                             VS0H 06352017
         TM    OUTSET+OFLGS,X'10'      IS OUTPUT (SYSUT2) OPEN? SA57755 06362021
         BZ    PPOPEN                  NO, OPEN IT              SA57755 06372021
*                                                                       06382017
*****************************************************************  UL0H 06384017
*   SEE IF CONDITIONS HAVE BEEN ESTABLISHED TO PRINT INPUT HDR  *  UL0H 06386017
*   LABELS. GO TO COMMON RTNE FOR HDR & TRLR LABEL PRINTING     *  UL0H 06388017
*****************************************************************  UL0H 06390017
         EJECT                                                          06420000
POSTOPEN NOP   TOTAL                   SWITCH TO READ DIRECTORY AND     06440000
*                                      SORT ENTRIES (BRANCH TAKEN) OR   06460000
*                                      READ MEMBERS (FALL THROUGH)      06480000
POSTMSG  LA    TEMP1,INSET             GET ADDR. OF INPUT DCB      VS0H 06500017
         TM    QSBRNOP+1,X'F0'                                     VS0H 06507017
         BO    QSSWSET                 CONT VBS PROCESS.         A45135 06514021
REALLYOP BAL   R8,LBLPRNT                                          UL0H 06521017
         NI    OPENSW,X'00'            SET VOL1 SWITCH OFF         UL0H 06522017
         CLI   PROCKY,X'10'                                        UL0H 06523017
         BE    ONLYIHL                 'ONLY' SPECIFIED,GO TO EOJ  UL0H 06525017
         TM    DEVT(TEMP1),X'20'                                   UL0H 06528017
         BO    PPSDS                   YES -- BRANCH                    06540000
         MVC   KEYLEN(2),PHZERO        SET KEYLEN TO ZERO FOR TAPE      06560000
PPSDS    LH    R0,BLKLEN               LOAD INPUT DATA SET BLOCK LENGTH 06580000
         AH    R0,KEYLEN               ADD KEY LENGTH TO BLOCK LENGTH   06600000
         ST    R0,LENGTHSV             SAVE INPUT RECORD LENGTH         06620000
*          G E T    I N P U T    B U F F E R                            06640000
         GETMAIN R,LV=(0)              GET CORE FOR THAT SIZE RECORD    06660000
         ST    R1,INBUFF               SAVE INPUT BUFFER ADDRESS        06680000
         ST    R1,LENGTHAD             SAVE INPUT BUFFER ADDRESS        06700000
GOTMAIN  TM    PREFORMT,X'81'          IS IT PREFORMATTED INPUT    VS0H 06720017
         BM    RDCH                    YES - BRANCH                     06740000
         TM    TYPORG,3                TEST FOR SELECTED MEMBERS OF PDS 06760000
         BO    PDPART                  YES --- BRANCH                   06780000
         L     MCBR,MNTADD             LOAD MEMBER NAME TABLE ADDRESS   06800000
         LTR   MCBR,MCBR               TEST FOR AN ADDRESS TO MNT       06820000
         BZ    NOPTR                   ZERO -- BRANCH -- NO ADDRESS     06840000
         L     MCBR,12(MCBR)           GET MCBADD FROM MNT - PTR TO GCB 06860000
         ST    MCBR,MCBRWS                                         VS0H 06870017
NOPTR    TM    TYPORG,1                IS THIS A TOTAL PDS OPERATION    06880000
         BZ    PPSDSH                  NO --- BRANCH                    06900000
         L     LISTR,DIRADD            YES -- GET ADR OF MEMBER NAMES   06920000
PDT1     LA    TEMP1,1                 TO ACCOUNT FOR TRUE NAME         06940000
         CH    TEMP1,MEMBCT            EXCEEDED TOTAL - CK MEMBER COUNT 06960000
         BE    PDT3                    YES -- BRANCH                    06980000
         LR    TEMP2,LISTR             MOVE POINTER TO MEMBER ADDRESSES 07000000
PDT2     AH    TEMP2,LISTLEN           BUMP PTR TO NEXT MEMBER          07020000
         TM    11(TEMP2),X'80'         IS THIS AN ALIAS                 07040000
         BZ    PDT3                    NO -- BRANCH                     07060000
         CLC   8(3,LISTR),8(TEMP2)     IS THIS ALIAS FOR THIS MEMBER    07080000
         BNE   PDT3                    NO IT IS NOT - BRANCH            07100000
         AH    TEMP1,PH1               INCREMENT MEMBER NAME COUNT BY 1 07120000
         CH    TEMP1,MEMBCT            HAS TOTAL BEEN EXCEEDED          07140000
         BNE   PDT2                    NO -- LOOP                       07160000
PDT3     BCTR  TEMP1,R0                REDUCE TRUE MEMBER NAME COUNT    07180000
         STH   TEMP1,ALIASCT           STORE ALIAS NAME COUNT FOR MEMBR 07200000
         LH    TEMP2,MEMBCT            SUBTRACT ALIASES FROM TOTAL CT   07220000
         SR    TEMP2,TEMP1                                              07240000
         STH   TEMP2,MEMBCT            UPDATE MEMBER NAME COUNT         07260000
         B     MEMBLOC                 LOCATE MEMBER                    07280000
PDPART   L     LISTR,MNTADD            LOAD MEMBER NAME TABLE ADDRESS   07300000
         L     LISTCT,0(LISTR)         LOAD MEMBER COUNT                07320000
         STH   LISTCT,MEMBCT           STORE MEMBER NAME COUNT          07340000
         LA    LISTR,4(LISTR)          POINT TO NAMED MEMBER            07360000
         ST    LISTR,DIRADD            STORE LOCATION OF TABLE          07380000
PDP1     L     MCBR,8(LISTR)           LOAD POINTER TO GCB              07400000
         ST    MCBR,MCBRWS                                         VS0H 07410017
*                                                                       07420000
*********************************************************************** 07440000
* BLDL WITH A MEMBER NAME TO SEE IF THIS MEMBER EXISTS IN THE PDS.    * 07460000
* PRECEDING THE MEMBER NAME IS ONE FULL WORD OF BLDL INFORMATION CON -* 07480000
* SISTING OF A HALF WORD FOR THE NUMBER OF ENTRIES IN THE BLDL LIST   * 07500000
* AND THE SECOND HALF WORD IS THE LENGTH OF THE ENTRY. THE MAXIMUM    * 07520000
* LENGTH FOR A DIRECTORY ENTRY IS 74 BYTES. IF ENTRIES ARE SHORTER    * 07540000
* ONLY THE ACTUAL LENGTH IS RETUREND. THE MAIN ITEM RETURNED IS THE   * 07560000
* TTR FOR THE MEMBER WHICH IS TAKEN FROM THE DIRECTORY AND USED IN    * 07580000
* THE 'FIND' MACRO.                                                   * 07600000
*********************************************************************** 07620000
*                                                                       07640000
MEMBLOC  LA    R1,BLDLADD              GET ADDRESS OF BLDL LIST         07660000
         MVC   4(8,R1),0(LISTR)        MOVE MEMBER NAME TO BLDL LIST    07680000
         BLDL  INSET,BLDLADD           IS MEMBER NAME IN DIRECTORY      07700000
         CH    R15,PH4                 CHECK RETURN CODE AGAINST A 4    07720000
         BL    FINDMEM                 CODE 0 -- BRANCH -- FOUND MEMBER 07740000
         BE    MEMBNO                  CODE 4 -- BRANCH -- NOT FOUND    07760000
         B     IOERRIN                 CODE 8 -- BRANCH -- I/O ERROR    07780000
*                                                                       07800000
QSSWSET  MVC   QSSW+1(1),=X'F0'                                    VS0H 07807017
         CLI   PROCKY,X'10'                                        UL0H 07807617
         BE    REALLYOP                'ONLY' WAS SPECIFIED        UL0H 07808217
         BAL   R8,LBLPRNT                                          UL0H 07809217
         NI    OPENSW,X'00'            SET VOL1 SWITCH OFF         UL0H 07809317
         LH    R0,LRECL                                            VS0H 07809417
         ST    R0,LENGTHSV                                         VS0H 07809517
         AH    R0,KEYLEN                                           VS0H 07809617
         GETMAIN R,LV=(0)                                          VS0H 07809817
         ST    R1,INBUFF                                           VS0H 07810017
         ST    R1,LENGTHAD                                         VS0H 07810117
         B     GOTMAIN                                             VS0H 07814117
*********************************************************************** 07820000
* THE FIND MACRO USES THE TTR GIVEN BY BLDL, THIS POINTS TO THE FIRST * 07840000
* RECORD OF THE MEMBER. THE ABSOLUTE DISK ADDRESS OF THE MEMBER IS    * 07860000
* PLACED IN THE SYSUT1 DCB AS A RESULT OF THE FIND MACRO.             * 07880000
*********************************************************************** 07900000
*                                                                       07920000
FINDMEM  FIND  INSET,BLDTTR,C     CALCULATE TTR OF THE MEMBER    A36098 07940021
PPSDSH   BAL   BREG,PPHEAD                                         VS0H 07970017
         L     MCBR,MCBRWS                                         VS0H 07990017
         EJECT                                                          08000000
*                                                                       08020000
*********************************************************************** 08040000
* THIS ROUTINE DETERMINES IF EDITING OR SKIPPING IS TO TAKE PLACE     * 08060000
* AND INITIALIZES ACCORDINGLY.                                        * 08080000
*********************************************************************** 08100000
*                                                                       08120000
         LTR   MCBR,MCBR               IS THERE A MEMBER NAME TABLE     08140000
         BC    13,NOMCB                NO - BRANCH                      08160000
         LH    TEMP1,0(MCBR)                                            08180000
         LTR   TEMP1,TEMP1             ARE THERE USER DEFINED RECD GRPS 08200000
         BP    PPSDS2                  YES, POINT TO RECD GROUP DESCRIP 08220000
NOMCB    LA    TEMP1,1                 NO, SET SWITCHES FOR STAND. OUT. 08240000
         STH   TEMP1,GRCT              STORE RECORD GROUP COUNT         08260000
PPSI     MVI   IDSW,0                  SET INPUT GROUP SWITCH TO ZERO   08280000
PPSF     MVI   FORMATSW,0              SET OUTPUT FORMAT SWITCH TO ZERO 08300000
*                                      FOR STANDARD FORMAT OUTPUT       08320000
         B     PPSDS4                                                   08340000
PPSDS2   STH   TEMP1,GRCT              STORE RECORD GROUP COUNT         08360000
         LR    GCBR,MCBR               MOVE PTR TO MEMBER NAME TABLE    08380000
         AH    GCBR,PH2                POINT TO FIRST GROUP             08400000
         BAL   BREG,SETGCBSW           SET RECORD GROUP SWITCHES        08420000
PPSDS4   XC    CURSKIP(2),CURSKIP      CLEAR WORK AREAS                 08440000
         XC    CURSTOP(2),CURSTOP                                       08460000
         LH    TEMP1,STRTAFT      WAS STRTAFT NBR                A45135 08470021
         LTR   TEMP1,TEMP1        SPECIFIED?                     A45135 08472021
         BZ    RDCH               NO,READ A PHYS. RECORD         A45135 08474021
         XC    CURSTRT(2),CURSTRT YES, CLEAR WORKAREA            A45135 08476021
         OI    INSW,X'04'         SET STRT NBR SWITCH            A45135 08478021
         B     RDCH                    READ A PHYSICAL RECORD           08480000
*                                                                       08500000
*          SET RECORD GROUP SWITCHES                                    08520000
*                                                                       08540000
SETGCBSW LA    TEMP2,1                 LOAD A 'ONE' BIT                 08560000
         LH    TEMP1,0(GCBR)           LOAD PTR TO RECORD GROUP         08580000
         LTR   TEMP1,TEMP1             ARE THERE USER DEFINED FIELDS    08600000
         BP    SETG1                   YES - BRANCH - FORMAT SW IS 1    08620000
         SR    TEMP2,TEMP2             NO - CLEAR REG - FORMAT SW IS 0  08640000
SETG1    EX    TEMP2,PPSF              SET OUTPUT FORMAT SWITCH         08660000
         LA    TEMP2,1                 RELOAD A 'ONE' BIT               08680000
         LH    TEMP1,2(GCBR)           LOAD GROUP IDENTIFIER            08700000
         LTR   TEMP1,TEMP1             IS THERE A GROUP IDENTIFIER      08720000
         BP    SETG2                   YES - BRANCH - ID SW WILL BE 1   08740000
         SR    TEMP2,TEMP2             NO CLEAR REG - ID SW WILL BE 0   08760000
SETG2    EX    TEMP2,PPSI              SET ID SWITCH                    08780000
         BR    BREG                    RETURN TO MAIN LINE OF CODE      08800000
         EJECT                                                          08820000
*                                                                       08840000
*          FORMAT OF MEMBER NAME TABLE                                  08860000
*                                                                       08880000
*        *4 BYTES *8 BYTES         *4 BYTES                             08900000
*        ************************************    MEMBERCT EQUALS        08920000
*        *MEMBERCT*MEMBER NAME     *GCB ADDR*    12 X NO. OF ENTRIES    08940000
*        ************************************                           08960000
*                 *MEMBER NAME     *GCB ADDR*                           08980000
*                 ***************************                           09000000
*                 *MEMBER NAME     *GCB ADDR*                           09020000
*                 ***************************                           09040000
*                 *ETC.                     *                           09060000
*                 ***************************                           09080000
*                                                                       09100000
*                                                                       09120000
*        FORMAT OF GETMAIN AREA FOR GROUP CONTROL BLOCKS (GCB)     1591 09124014
*        AND FIELD CONTROL BLOCKS (FCB)                            1591 09128014
*                                                                  1591 09132014
*                                                                  1591 09136014
* 2 BYTES- NUMBER OF GCB'S FOLLOWING                               1591 09140014
*                                                                  1591 09144014
*                                                                  1591 09148014
* 8 BYTES- FIRST GCB                                               1591 09152014
*          2 BYTES- NUMBER OF FCB'S FOR THIS GCB                   1591 09156014
*          2 BYTES- LENGTH OF CURRENT IDENT LITERAL                1591 09160014
*          2 BYTES- DISPLACEMENT OF CURRENT IDENT IN LITERAL POOL  1591 09164014
*          2 BYTES- INPUT LOCATION MINUS 1 OF CURRENT IDENT        1591 09168014
*                                                                  1591 09172014
* 8 BYTES- FIRST FCB FOR FIRST GCB                                 1591 09176014
*          2 BYTES- LENGTH OF FIELD                                1591 09180014
*          2 BYTES- INPUT LOCATION MINUS 1                         1591 09184014
*          2 BYTES- CONVERSION CODE                                1591 09188014
*          2 BYTES- OUTPUT LOCATION MINUS 1                        1591 09192014
*                                                                  1591 09196014
* 8 BYTES- SECOND FCB FOR FIRST GCB                                1591 09200014
*    *                                                             1591 09204014
*    *                                                             1591 09208014
*    *                                                             1591 09212014
* 8 BYTES- N'TH FCB FOR FIRST GCB                                  1591 09216014
*                                                                  1591 09220014
*                                                                  1591 09224014
* 8 BYTES- SECOND GCB                                              1591 09228014
*                                                                  1591 09232014
* 8 BYTES- FIRST FCB FOR SECOND GCB                                1591 09236014
*    *                                                             1591 09240014
*    *                                                             1591 09244014
*    *                                                             1591 09248014
* 8 BYTES- N'TH FCB FOR SECOND GCB                                 1591 09252014
*                                                                  1591 09256014
*                                                                  1591 09260014
*  *                                                               1591 09264014
*  *                                                               1591 09268014
*  *                                                               1591 09272014
*                                                                  1591 09276014
*                                                                  1591 09280014
* 8 BYTES- N'TH GCB                                                1591 09284014
*    *                                                             1591 09288014
*    *                                                             1591 09292014
*    *                                                             1591 09296014
*                                                                  1591 09300014
*                                                                       09340000
**N O T E -- IF THERE ARE NO MEMBERS IN THE MEMBER NAME TABLE THE       09360000
**           MEMBER COUNT AND THE MCBADDR(GCB POINTER) ARE ZERO AND THE 09380000
**           MEMBER NAME SECTION CONTAINS BLANKS. IN THIS CASE THE      09400000
**           TABLE LENGTH IS SIXTEEN BYTES.                             09420000
*                                                                       09440000
         EJECT                                                          09460000
*                                                                       09480000
*********************************************************************** 09500000
* READ ONE PHYSICAL RECORD - MEMBER IF THE INPUT IS A PDS. IF A NOTE  * 09520000
* LIST IS PRESENT, AND NOTE LISTS ARE TO BE OMITTED, ANOTHER PHYSICAL * 09540000
* RECORD IS READ. A NOTE LIST IS PRESENT ONLY IN A PDS AND IT REFERS  * 09560000
* TO THE N BYTE OF THE TTRN'S IN THE USERS DATA FIELD. A NOTE LIST    * 09580000
* CONSISTS OF ADDITIONAL POINTERS TO BLOCKS WITHIN THE SAME MEMBER.   * 09600000
*********************************************************************** 09620000
*                                                                       09640000
RDCH     L     R3,INBUFF               LOAD ADDRESS OF INPUT BUFFER     09660000
         TM    QSSW+1,X'F0'                                        VS0H 09670017
         BO    QSGETREC                PERFORM QSAM GET            VS0H 09680017
         READ  DECBI,SF,INSET,(R3),'S' READ THE MEMBER                  09700000
         CHECK DECBI                   CHECK THE READ                   09720000
         MVI   SDSEOD+1,X'00'  MARK INPUT NOT EMPTY              A36088 09730021
         TM    RECFM,X'C0'        RECFM UNDEFINED ?              A45135 09730421
         BNO   TESTFORM           NO, TEST OUTPUT FORMAT         A45135 09730821
         L     TEMP1,DECBI+16     LOCFIRST LOG. RECD             A45135 09732021
         LH    TEMP2,14(TEMP1)    FROM DECB                      A45135 09734021
         LH    RLEN,BLKLEN        LOAD INPUT BLOCK LENGTH        A45135 09736021
         SR    RLEN,TEMP2         SUBTRACT RESIDUAL COUNT        A45135 09738021
         CH    RLEN,PHZERO        LENGTH READ OF ZERO ?          A45135 09738421
         BE    RDCH               YES, READ NEXT RECORD          A45135 09738821
TESTFORM TM    PREFORMT,X'81'     IS THIS PREFORMATTED INPUT?    A45135 09740021
         BM    PREFORM                 YES - BRANCH                     09760000
         TM    FORMATSW,1              STANDARD FORMAT INPUT            09780000
         BZ    RECDLOC1                YES - BRANCH TO DEBLOCK RECORD   09800000
         TM    TYPORG,1                NO - CHECK FOR NOTE LIST IF DATA 09820000
         BZ    RECDLOC1                SET IS PARTITIONED - BRANCH TO   09840000
*                                      DEBLOCK ROUTINE                  09860000
         TM    BLDC,X'60'              TEST FOR MORE THAN 1 TTR PRESENT 09880000
         BZ    RECDLOC1                NO NOTE LISTS FOR THIS MEMBER -  09900000
*                                      CHECKING BLDL RETURNED INFO      09920000
         NOTE  INSET                   GET TTR OF BLOCK JUST READ       09940000
         ST    R1,TEMBADD              STORE NOTE TTR RECEIVED          09960000
         LA    LISTR,BLDUSER           GET ADR OF USER DATA FIELD FROM  09980000
         LA    TEMP1,3                 BLDL - CK 12 BYTES OF USER DATA  10000000
NLT1     CLC   TEMBADD(3),0(LISTR)                                      10020000
         BE    NLT5                                                     10040000
         AH    LISTR,PH4               TTRS NOT EQUAL - CONTINUE SEARCH 10060000
         BCT   TEMP1,NLT1              REDUCE LOOP COUNTER              10080000
         B     RECDLOC1                GO TO RECORD DEBLOCK ROUTINE     10100000
NLT5     CLI   3(LISTR),0              TTRS EQUAL - IS THERE NOTE LIST  10120000
         BNE   RDCH                    YES, SKIP THIS RECORD            10140000
LOCREC   B     RECDLOC1                                            VS0H 10143017
QSGETREC GET   INSET,(R3)                                          VS0H 10146017
         MVI   SDSEOD+1,X'00'  MARK INPUT NOT EMPTY              A36088 10148021
GOTQSREC LR    RLOC,R1                                             VS0H 10153717
         LH    RLEN,0(RLOC)                                        VS0H 10154417
         TM    PREFORMT,X'81'                                      VS0H 10154617
         BM    QSPREFM                                             VS0H 10154817
         B     RECDLOC2                                            VS0H 10155117
         EJECT                                                          10160000
*                                                                       10180000
*********************************************************************** 10200000
* THIS ROUTINE DETERMINES WHAT TYPE RECORDS THE INPUT DATA SET HAS -- * 10220000
* VARIABLE, VARIABLE BLOCKED, UNDEFINED AND FIXED UNBLOCKED ARE ALL   * 10240000
* HANDLED BY THIS ROUTINE. HERE DEBLOCKING IS ALSO PERFORMED AND THE  * 10260000
* USER INPUT RECORD PROCESSING ROUTINE IS ENTERED.                    * 10280000
*********************************************************************** 10300000
*                                                                       10320000
RECDLOC1 L     TEMP1,DECBI+16          LOCATE FIRST LOG. RECD FROM DECB 10340000
         LH    TEMP2,14(TEMP1)                                          10360000
         LH    RLEN,BLKLEN             LOAD INPUT BLOCK LENGTH          10380000
         SR    RLEN,TEMP2              SUBTRACT RESIDUAL COUNT          10400000
         L     RLOC,INBUFF             LOAD ADDRESS OF INPUT BUFFER     10420000
         AH    RLOC,KEYLEN             ADD IN RECORD KEY LENGTH         10440000
         TM    RECFM,X'C0'             UNDEFINED TYPE RECORDS           10460000
         BO    RECPROC                 YES -- BRANCH                    10480000
         TM    RECFM,X'40'             VARIABLE BLOCKED-UNBLOCKED       10500000
         BO    BLKEDV                  YES -- BRANCH                    10520000
         TM    RECFM,X'10'             FIXED BLOCKED                    10540000
         BO    BLKEDF                  YES -- BRANCH                    10560000
         B     RECPROC                 NO - BRANCH - FIXED UNBLOCKED    10580000
BLKEDV   AH    RLOC,PH4                ADD 4 TO ADR OF INPUT BUFFER     10600000
         SH    RLEN,PH4                SUBTRACT 4 FROM ADJUSTED BLK LEN 10620000
BV1      SH    RLEN,PH4                DO IT AGAIN                      10640000
         STH   RLEN,PLEN               STORE REMAINING BYES OF BLKD REC 10660000
         MVC   TEMPHW1,0(RLOC)         GET LENGTH OF LOGICAL RECORD     10680000
         LH    RLEN,TEMPHW1            LOAD LENGTH OF LOGICAL RECORD    10700000
RECDLOC2 CH    RLEN,LRECL              IS IT  > RECORD LENGTH      VS0H 10720017
         BH    IOERRIN                 YES - PERMANENT I/O ERROR        10740000
         CH    RLEN,PH4                IS IT AT LEAST FIVE BYTES LONG   10760000
         BNH   IOERRIN                 NO IT ISN'T - I/O ERROR          10780000
         SH    RLEN,PH4                SUBTRACT 4 FROM LOGICAL RECD LEN 10800000
         AH    RLOC,PH4                BUMP PTR TO INPUT BUFFER         10820000
         B     RECPROC                                                  10840000
BLKEDF   STH   RLEN,PLEN               SAVE REMAINING BYTES OF BLKD REC 10860000
BF1      LH    RLEN,LRECL              LOAD LOGICAL RECORD LENGTH       10880000
         CH    RLEN,PLEN               COMPARE IT TO REMAINING BYTES    10900000
         BNH   RECPROC                 IF NOT HIGHER BRANCH             10920000
         LH    RLEN,PLEN               HIGHER -- LOAD REMAINING BYTES   10940000
         EJECT                                                          10960000
*                                                                       10980000
*********************************************************************** 11000000
* CHECK AN IDENTITY WITH EVERY INPUT RECORD UNTIL THE CONDITION IS MET* 11020000
* ONCE IT IS MET WE HAVE A RECORD GROUP. PROCESSING OF THE INPUT DATA * 11040000
* SET MAY STOP AT THIS POINT IF THIS WAS THE LAST RECORD STATEMENT OR * 11060000
* WILL CONTINUE IF MORE RECORD STATEMENTS ARE PRESENT. THE RECORD     * 11080000
* STATEMENT IS A CONTROL CARD TO THE UTILITY PROGRAM.                 * 11100000
*********************************************************************** 11120000
*                                                                       11140000
RECPROC  STH   RLEN,RECDLEN            STORE LENGTH OF CURRENT LOG. REC 11160000
         ST    RLOC,RECDLOC            STORE PTR  TO CURRENT LOGIC. REC 11180000
         TM    INSW,X'04'         STRTNBR SWITCH ON?             A45135 11190021
         BZ    NOSWON             NO                             A45135 11192021
         LH    TEMP1,CURSTRT      YES, CALCULATE RECORDS         A45135 11194021
         AH    TEMP1,PH1          ALREADY GET OR READ            A45135 11196021
         STH   TEMP1,CURSTRT      STORE UPDATED NBR.             A45135 11198021
         CH    TEMP1,STRTAFT      NBR OF REC TO BE SKIP. ALR HAD A45135 11198421
         BNE   RECRET             NO, SKIP THIS RECORD           A45135 11198821
         NI    INSW,X'FB'         YES, SET STRTNBR SWITCH OFF    A45135 11199221
         B     RECRET             SKIP THIS RECORD               A45135 11199621
NOSWON   EQU   *                  CONTINUE                       A45135 11199721
         MVI   RCP2+1,0                SET BRANCH TO A NOP              11200000
         CLI   INREC,C' '              TEST FOR USER EXIT FOR LOGICAL   11220000
*                                      RECORD PROCESSING ON INPUT       11240000
         BE    RECPROC1                NONE --- BYPASS LINK             11260000
*          G O    T O    U S E R    E X I T                             11280000
*             B E F O R E    P R O C E S S I N G    R E C O R D         11300000
         LINK  EPLOC=INREC,PARAM=((RLOC),(RLEN))                        11320000
         SR    R0,R0              CLEAR REGISTER ZERO              2044 11330020
         IC    R0,PPRETCDE             LOAD RETURN CODE                 11340000
         CR    R15,R0                  COMPARE AGAINST USER RETURN CODE 11360000
         BL    RECPROC1                IF LOWER - BRANCH - CONTINUE PGM 11380000
         SRL   R15,2                   CLEAR TWO LOW ORDER BITS         11400000
         SLL   R15,2                                                    11420000
         STC   R15,PPRETCDE            STORE USERS RETURN CODE          11440000
         LA    R0,12                   LOAD UTILITY RETURN CODE         11460000
         CR    R15,R0                  DOES USER REQUEST TERMINATION    11480000
         BL    RECPROC1                NO CONTINUE PGM                  11500000
         B     EXTERM1                 BRANCH TO MESSAGE WRITER - TERM. 11520000
RECPROC1 TM    IDSW,1                  IS AN ID TEST NECESSARY          11540000
         BZ    SKIPT                   NO - BYPASS ID TEST ROUTINE      11560000
         LA    TEMP1,INSET             GET ADDRESS OF INPUT DCB         11580000
         LH    TEMP2,GCBIDLOC(GCBR)    GET RELATIVE INPUT LOCAT. OF LIT 11600000
         AH    TEMP2,GCBIDLEN(GCBR)    ADD ID LENGTH TO IT       A44337 11602021
         CH    TEMP2,LRECL        DOES IDENT EXC. INIT. LRECL ?  A55773 11618021
         BH    PRERROR                 IF IT IS LARGER - ERROR - A44337 11619221
         CH    TEMP2,RECDLEN      DOES IDENT EXC. ACT. LRECL ?   A55773 11639221
         BH    SKIPT              YES, SKIP IDENT TEST           A55773 11659221
         AH    RLOC,GCBIDLOC(GCBR)     OK - ADD IT TO CURRENT RECD PTR  11680000
         L     RLIT,LITADD             LOAD ADDRESS OF LITERAL POOL     11700000
         AH    RLIT,GCBIDLIT(GCBR)                                      11720000
         LH    TEMP1,GCBIDLEN(GCBR)    LOAD LENGTH OF ID                11740000
IDT1     CH    TEMP1,PH256             DOES ID EXCEED 256 BYTES         11760000
         BNH   IDT2                    NO - BRANCH                      11780000
         CLC   0(256,RLOC),0(RLIT)     YES - COMPARE FIRST 256 BYTES    11800000
         BNE   IDT4                    NOT EQUAL - BRANCH               11820000
         SH    TEMP1,PH256             EQUAL - CONTINUE                 11840000
         LA    RLOC,256(RLOC)          ADD 256 TO CURRENT LOGIC REC PTR 11860000
         LA    RLIT,256(RLIT)          ADD 256 TO LITERAL POOL POINTER  11880000
         B     IDT1                    LOOP UNTIL COMPLETE              11900000
IDT2     BCTR  TEMP1,R0                PREPARE TO EXECUTE COMPARE       11920000
         EX    TEMP1,IDTCOMP           COMPARE ID'S                     11940000
IDT4     BNE  SKIPT                                                2885 11980015
         MVI   IDSW,X'03'         ID'S  ARE EQUAL                  2885 12020015
         EJECT                                                          12060000
*                                                                       12080000
*********************************************************************** 12100000
* IF A SKIP PARAMETER HAS BEEN SPECIFIED BY THE USER EVERY N'TH       * 12120000
* LOGICAL RECORD WILL BE PROCESSED. ALSO TEST FOR END OF PAGE AND     * 12140000
* DETERMINE THE OUTPUT FORMAT.                                        * 12160000
*********************************************************************** 12180000
*                                                                       12200000
SKIPT    TM    INSW,1                  TEST SKIP SWITCH                 12220000
         BZ    SKIPNO                  OFF - BRANCH TO END PAGE TEST    12240000
         LH    SKIPR,CURSKIP           LOAD SKIP COUNTER                12260000
         CH    SKIPR,INITSKIP          CHECK AGAINST RECD NO. TO PROCES 12280000
         BE    NOSKIP                  EQUAL - DON'T SKIP RECORD        12300000
         AH    SKIPR,PH1               NOT EQUAL - INCREMENT SKIP CTR   12320000
         STH   SKIPR,CURSKIP           STORE SKIP COUNTER               12340000
         B     NEXT1                   BRANCH TO GET NEXT RECORD        12360000
NOSKIP   SR    SKIPR,SKIPR             CLEAR WORK REGISTER              12380000
         STH   SKIPR,CURSKIP           CLEAR RECORD SKIP COUNTER        12400000
SKIPNO   TM    PPSW1,1                 IS OUTPUT PRINTED OR PUNCHED     12420000
         BO    PUNREC                  NO - PUNCH - BYPASS LINE TEST    12440000
*          E N D    O F    P A G E    T E S T                           12460000
         LH    TEMP1,LINECT            LOAD LINE CTR FOR END PAGE TEST  12480000
         CH    TEMP1,PMAXLINE          CHECK AGAINST USER OR ASSUMED    12500000
*                                      LINE PER PAGE MAXIMUM COUNT      12520000
         BL    PUNREC                  LOW - NOT END - BRANCH           12540000
         BAL   HDRET,PPHEAD            END - PUT HEADING ON PAGE        12560000
PUNREC   BAL   BREG,BLANKOUT           CLEAR OUTPUT AREA                12580000
*          D E T E R M I N E    O U T P U T    F O R M A T              12600000
RCP2     NOP   FS15                    SWITCH TO CONT WITH CURRENT RECD 12620000
         LH    RLEN,RECDLEN            LOAD CURRENT LOGICAL RECD LENGTH 12640000
         L     RLOC,RECDLOC            LOAD PTR TO CURRENT LOGICAL RECD 12660000
         TM    FORMATSW,1              IS OUTPUT TO BE USER FORMATTED   12680000
         BO    FORMU                   YES - BRANCH TO USE USERS SPECS  12700000
         EJECT                                                          12720000
*                                                                       12740000
*********************************************************************** 12760000
* THIS ROUTINE FORMATS THE OUTPUT IN THE STANDARD FORMAT, WHICH MEANS * 12780000
* 12 EIGHT CHARACTER GROUPS PER LINE WITH EACH GROUP SEPARATED BY TWO * 12800000
* BLANKS. THIS WILL PRINT OUT 96 CHARACTERS AND 24 BLANKS, PRINTING   * 12820000
* 120 CHARACTERS. IF THE CHARACTERS ARE TO BE CONVERTED TO HEX RE-    * 12840000
* PRESENTATIONS OR TO THE UNPACKED FORM THE OUTPUT NOW BECOMES DOUBLE * 12860000
* THE SIZE AND IT TAKES TWO CHARACTERS TO PRINT ONE CORE CHARACTER.   * 12880000
* THE FORMAT OF 12 EIGHT BYTE GROUPS STILL HOLDS TRUE BUT NOW ONLY 48 * 12900000
* CHARACTERS AND 24 BLANKS MAKE UP A LINE. THERE IS ALSO AN EXIT TO   * 12920000
* A USER ROUTINE TO PROCESS THE RECORDS BEFORE THEY ARE OUTPUTED.     * 12940000
*********************************************************************** 12960000
*                                                                       12980000
FORMS    LH    FLDCT,MAXSEG            LOAD NUMBER OF GROUPS PER LINE   13000000
         LH    INLEN,INSEG             LOAD NUMBER CHARACTERS PER GROUP 13020000
         LA    ROUT,OUTBUFF1           LOAD ADDRESS OF OUTPUT BUFFER    13040000
FS1      CR    INLEN,RLEN              COMPARE CHARACTERS PER GROUP TO  13060000
*                                      ACTUAL RECORD LENGTH             13080000
         BNH   FS2                     IF NOT HIGHER BRANCH             13100000
         OI    LASTSW,X'01'            SET LAST GROUP SWITCH            13120000
         LR    INLEN,RLEN              MOVE ACTUAL RECORD LENGTH        13140000
FS2      CR    INLEN,RLEN              IS IT EQUAL TO CHARACTERS/GROUP  13160000
         BNE   BYPASSSW                NO - BRANCH                      13180000
         OI    LASTSW,X'01'            SET LAST GROUP SWITCH            13200000
BYPASSSW SR    RLEN,INLEN              GET NUMBER BYTES LEFT TO OUTPUT  13220000
         TM    TOTCONV,1               DATA CONVERSION TO BE DONE       13240000
         BO    FS4                     YES - BRANCH                     13260000
         BCTR  INLEN,R0                NO - REDUCE COUNT FOR EXECUTE    13280000
         EX    INLEN,FMOVE             MOVE DATA TO OUTPUT BUFFER       13300000
         AH    INLEN,PH1               RESTORE CHARACTER COUNT          13320000
         B     FS10                    BYPASS DATA CONVERSION BRANCH    13340000
FS4      BAL   BREG,FLDCONV            MOVE AND CONVERT ONE SEGMENT     13360000
FS10     LTR   RLEN,RLEN               END OF INPUT RECORD TEST         13380000
         BZ    EORTEST                 END - BRANCH                     13400000
         AR    RLOC,INLEN              NO - BUMP PTR TO RECORD          13420000
         BCT   FLDCT,FS12              TEST FOR END OF OUTPUT RECORD    13440000
         OI    RCP2+1,X'F0'            END, SET SWITCH TO CONTINUE WITH 13460000
*                                      THIS INPUT RECORD                13480000
         STH   RLEN,FSLEN              STORE BYTES LEFT IN INPUT RECORD 13500000
         ST    RLOC,FSLOC              STORE PTR TO RECORD              13520000
         B     UFEND                   TEST FOR USER EXIT ON OUTPUT     13540000
FS12     AH    ROUT,OUTSEG             BUMP PTR TO OUTPUT BUFFER        13560000
         B     FS1                     CONTINUE OUTPUTING               13580000
EORTEST  TM    PPSW1,1                 TEST FOR PUNCH OPERATION         13600000
         BO    UFEND                   IF YES TEST FOR USER EXIT        13620000
         TM    TOTCONV,1               DATA CONVERSION NECESSARY        13640000
         BZ    NOCONV                  NO - BRANCH                      13660000
         AR    INLEN,INLEN             YES - DOUBLE RECORD LENGTH       13680000
NOCONV   AR    ROUT,INLEN              ADD RECD LENGTH TO OUTPUT BUF AD 13700000
         MVI   0(ROUT),EOB             MOVE ASTERISK TO OUTPUT AREA     13720000
         TM    RECFM,X'10'             IS INPUT BLOCKED                 13740000
         BZ    UFEND                   NO - TEST FOR USER EXIT          13760000
         CLC   RECDLEN(2),PLEN         YES, IS THIS END OF BLOCK        13780000
         BNE   UFEND                   TEST FOR USER EXIT               13800000
         MVI   1(ROUT),EOB             MOVE ASTERISK TO OUTPUT BUFFER   13820000
RECWRITE B     UFEND                   TEST FOR USER EXIT               13840000
         LTR   RLEN,RLEN               END OF INPUT RECORD TEST         13860000
         BZ    NEXT                    YES - GET NEXT LOGICAL RECORD    13880000
         B     SKIPNO                  NO - CONTINUE WITH CURRENT RECD  13900000
FS15     LH    RLEN,FSLEN              LOAD REMAINING BYTES OF IN. RECD 13920000
         L     RLOC,FSLOC              LOAD PTR TO INPUT AREA           13940000
         MVI   RCP2+1,0                TURN OFF RECD CONTINUATION SWITH 13960000
         B     FORMS                                                    13980000
         EJECT                                                          14000000
*                                                                       14020000
*********************************************************************** 14040000
* THIS ROUTINE COMPUTES THE TOTALS OF THE LENGTH FIELDS IN THE RECORD * 14060000
* CARDS. IF THE FIELD IS TO BE CONVERTED THE LENGTH IS DOUBLED. IF THE* 14080000
* TOTAL OF ALL THESE LENGTHS ADD UP TO MORE THAN 120, THE REQUEST IS  * 14100000
* TERMINATED, AN ERROR MESSAGE IS PRINTED AND A RETURN CODE OF 12 IS  * 14120000
* RETURNED.                                                           * 14140000
*********************************************************************** 14160000
*                                                                       14180000
COMPUTEL LR    R0,FLDCT                LOAD NUMBER OF FIELDS     A34102 14200020
         LH    INLEN,0(FCBR)           GET LENGTH OF USER FORMAT FIELD  14220000
         TM    4(FCBR),1               IS DATA TO BE CONVERTED          14240000
         BO    DOUBLEL                 YES IT IS                        14260000
TRUEL    AH    INLEN,RECOUNT           INCREMENT USER FORMAT LENGTH     14280000
         STH   INLEN,RECOUNT           STORE LENGTH                     14300000
         BCT   R0,INCREL               NSI IF ALL FLDS PROCESSED A34102 14330020
         ST    R14,TEMPSAVE            SAVE BRANCH ADDRESS         9305 14370019
         LH    TEMP1,MAXOUT            GET MAX CHAR PER LINE       9305 14380019
         CH    TEMP1,RECOUNT           DOES IT EXCEED TOTAL FIELDS?9305 14397019
         BL    PRERROR                 IF NOT = OR > THEN ERROR    9305 14404019
         L     R14,TEMPSAVE            RESTORE BRANCH REGISTER     9305 14411019
         LA    FCBR,GCBL(GCBR)         NO, RESET STARTING POINT         14420000
         MVC   RECOUNT(2),PHZERO       RESET COUNTER TO ZERO            14440000
         BR    R14                     RETURN TO FORMU ROUTINE          14460000
         SPACE 2                                                        14480000
INCREL   AH    FCBR,FCBLEN             GO TO NEXT FIELD PARAMETER       14500000
         B     COMPUTEL+2              LOOP TO PROCESS NEW FLD   A34102 14520020
DOUBLEL  AR    INLEN,INLEN             DOUBLE OUTPUT LENGTH FOR CONVER. 14540000
         TM    4(FCBR),3               IS IT PACKED TO UNPACKED         14560000
         BM    TRUEL                   NO - BRANCH                      14580000
         BCTR  INLEN,R0                REDUCE DOUBLED LENGTH BY ONE     14600000
         B     TRUEL                                                    14620000
         EJECT                                                          14640000
*                                                                       14660000
*********************************************************************** 14680000
* THIS IS THE USER FORMATTED OUTPUT ROUTINE. THE OUTPUT IS DETERMINED * 14700000
* BY THE FIELD PARAMETERS OF THE RECORD STATEMENTS. THERE MAY BE MORE * 14720000
* THAN ONE FIELD PARAMETER PER RECORD STATEMENT BUT ONLY ONE IDENT    * 14740000
* PARAMETER IS ALLOWED. THERE IS ALSO A USER EXIT TO FURTHER PROCESS  * 14760000
* THE RECORDS BEFORE THEY ARE OUTPUTED.                               * 14780000
*********************************************************************** 14800000
*                                                                       14820000
FORMU    LH    FLDCT,0(GCBR)                                            14840000
         LA    FCBR,GCBL(GCBR)         POINT TO FIRST FIELD CONTROL BLK 14860000
         BAL   R14,COMPUTEL            COMPUTE USER FIELD LENGTHS       14880000
UF1      LA    TEMP1,INSET             GET ADDRESS OF INPUT DCB         14900000
         LH    INLEN,0(FCBR)           LENGTH OF FIELD TO BE EDITED     14920000
         AH    INLEN,2(FCBR)           ADD RELATIVE INPUT LOCATION      14940000
         CH    INLEN,LRECL          COMP INP WITH LRECL LEN      A44337 14958021
         BH    PRERROR                 IF IT IS LARGER - ERROR - A44337 14980021
         LH    INLEN,0(FCBR)           LOAD LENGTH OF FIELD TO BE EDIT. 15000000
         LTR   INLEN,INLEN             IS THERE A LENGTH                15020000
         BC    13,UF10                 BRANCH IF NO                     15040000
         LH    RLOC,2(FCBR)            LOAD RELATIVE INPUT LOCATION     15060000
         LTR   RLOC,RLOC                                                15080000
         BM    UF10                                                     15100000
         CH    RLOC,RECDLEN            COMPARE TO LENGTH OF CURRENT REC 15120000
         BNL   UF10          NO GO TO CHECK IF MORE FIELDS              15140000
         LR    TEMP1,INLEN             MOVE LENGTH OF FIELD             15160000
         AR    TEMP1,RLOC              ADD RELATIVE INPUT LOCATION      15180000
         CH    TEMP1,RECDLEN           COMPARE TO LENGTH OF CUR LOG REC 15200000
         BNH   UF3                                                      15220000
         LH    INLEN,RECDLEN           HIGHER - LOAD LENGTH OF CURR LEN 15240000
         SR    INLEN,RLOC              TRUNCATE FIELD                   15260000
UF3      LH    ROUT,6(FCBR)            REL. OUTPUT LOCATION             15280000
         LTR   ROUT,ROUT               TEST PTR TO OUTPUT BUFFER        15300000
         BL    UF10                     BRANCH ON MINUS                 15320000
         CH    ROUT,MAXOUT             COMPARE TO MAXIMUM LINE COUNT    15340000
         BNL   UF10                                                     15360000
         LR    TEMP1,ROUT              MOVE PTR TO OUTPUT BUFFER        15380000
         AR    TEMP1,INLEN                                              15400000
         CH    TEMP1,MAXOUT            COMPARE TO MAXIMUM LINE COUNT    15420000
         BL    UF4                                                      15440000
         LH    INLEN,MAXOUT            LOAD MAXIMUM OUTPUT LENGTH       15460000
         SR    INLEN,ROUT              TRUNCATE FIELD                   15480000
UF4      A     RLOC,RECDLOC                                             15500000
         A     ROUT,OUTBADD                                             15520000
         TM    4(FCBR),1               DATA CONVERSION                  15540000
         BO    UF5                     BRANCH IF SWITCH ON              15560000
         BCTR  INLEN,R0                REDUCE COUNT FOR EXECUTE         15580000
         EX    INLEN,FMOVE             MOVE FIELD TO OUTPUT AREA        15600000
         B     UF10                                                     15620000
UF5      OI    LASTSW,X'01'            SET LAST FIELD SWITCH            15640000
         BAL   BREG,FLDCONVU           USER FORMATTED DATA - BRANCH     15660000
UF10     BCT   FLDCT,UF12               ARE THERE ANY MORE FIELDS       15680000
         B     UFEND0                  NO - BRANCH                      15700000
UF12     AH    FCBR,FCBLEN             YES - CONTINUE                   15720000
         B     UF1                                                      15740000
UFEND0   OI    RECWRT+1,X'F0'          SET NOP SWITCH                   15760000
UFEND    CLI   OUTREC,C' '             TEST FOR USER EXIT FOR PROCESS-  15780000
*                                      ING OUTPUT RECORDS               15800000
         BE    RECWRT                  NONE --- BYPASS LINK             15820000
         ST    RLEN,HOLDRLEN           STORE CURRENT LOGICAL RECD LENG. 15840000
         LA    RLOC,OUTBUFF1           LOAD ADDRESS OF OUTPUT BUFFER    15860000
         LH    RLEN,MAXOUT        LOAD OUTPUT LRECL MINUS ONE   LETTER  15880021
*          G O    T O    U S E R    E X I T                             15900000
*             B E F O R E    O U T P U T I N G    R E C O R D           15920000
         LINK  EPLOC=OUTREC,PARAM=((RLOC),(RLEN))                       15940000
         L     RLEN,HOLDRLEN           RESTORE CURRENT LOGICAL REC LEN. 15960000
         LA    R0,4               SET REGISTER ZERO EQ 4         A48796 16120021
         CR    R15,R0             RETURN CODE 4                  A48796 16170021
         BE    NEXT               YES, SKIP THE RECORD           A48796 16172021
         LA    R0,12              SET REGISTER ZERO EQ 12        A48796 16174021
         CR    R15,R0             RETURN CODE 12 ?               A48796 16176021
         BE    EXTERM1            YES, TERMINATE PROCESSING      A48796 16178021
         LA    R0,16              SET REGISTER ZERO EQ 16        A48796 16178121
         CR    R15,R0             RETURN CODE 16 ?               A48796 16178221
         BE    EXTERM1            YES, TERMINATE PROCESSING      A48796 16178321
RECWRT   NOP   RECWRT1                 NOP SWITCH                       16180000
         LA    BREG,RECWRITE+4                                          16200000
         B     WRCH                    BRANCH TO WRITE OUTPUT ROUTINE   16220000
RECWRT1  BAL   BREG,WRCH               BRANCH TO WRITE OUTPUT ROUTINE   16240000
*                                                                       16260000
*          GET NEXT LOGICAL RECORD                                      16280000
*                                                                       16300000
NEXT     TM    INSW,2                  WAS THERE A 'STOP' PARAMETER     16320000
         BZ    NEXT1                   NO - BRANCH                      16340000
         LH    TEMP1,CURSTOP           YES, IS IT TIME TO STOP          16360000
         AH    TEMP1,PH1               ADD ONE TO STOP COUNTER          16380000
         CH    TEMP1,INITSTOP          DO WE STOP - CHECK USER PASSED   16400000
*                                      RECORD NUMBER                    16420000
         BNL   EODSTOP                 NOT LOWER - STOP FOR MEMBER OR   16440000
         STH   TEMP1,CURSTOP           SDS - NO, CONTINUE - STORE CTR   16460000
NEXT1    TM    IDSW,2                  IS THIS THE END OF A RECORD GRP. 16480000
         BZ    RECRET                  NO - BRANCH                      16500000
         LH    TEMP1,GRCT              YES, MORE GROUPS - LOAD GROUP CT 16520000
         BCT   TEMP1,NEXTGR            IF YES REDUCE COUNTER            16540000
         B     EODID                   IF NO DO NEXT MEMBER             16560000
*          R E I N I T I A L I Z A T I O N    T O                       16580000
*            P R O C E S S    N E X T    R E C O R D   G R O U P        16600000
NEXTGR   STH   TEMP1,GRCT              STORE RECORD GROUP COUNTER       16620000
         LH    TEMP1,0(GCBR)           POINT TO NEXT GROUP              16640000
         MH    TEMP1,FCBLEN            ALIGN PTR TO PROPER BOUNDARY     16660000
         AR    GCBR,TEMP1                                               16680000
         AH    GCBR,GCBLEN                                              16700000
         BAL   BREG,SETGCBSW           SET SWITCHES FOR THIS RECD GROUP 16720000
RECRET   TM    RECFM,X'10'             BLOCKED RECORDS FOR INPUT        16740000
         BZ    RDCH                    NO, READ NEXT RECORD             16760000
         TM    RCP2+1,X'F0'                  CONTINUE SAME RECORD? 1450 16766020
         BO    SKIPNO                        YES - BRANCH          1450 16772020
         LH    RLEN,PLEN               LOAD REMAINING BYTES IN CURR REC 16780000
         SH    RLEN,RECDLEN            END OF PHYSICAL RECD - SUBTRACT  16800000
*                                      LENGTH OF CURRENT LOGICAL RECD.  16820000
         BC    12,RDCH                 BRANCH IF ZERO OR NEGATIVE TO    16840000
*                                      READ NEXT PHYSICAL RECORD        16860000
         STH   RLEN,PLEN               STORE REMAINING BYTES IN CUR REC 16880000
         L     RLOC,RECDLOC            LOAD PTR TO CURRENT RECORD       16900000
         AH    RLOC,RECDLEN            ADD LENGTH OF LAST LOGICAL RECD. 16920000
         TM    RECFM,X'50'             CHECK RECORD FORMAT              16940000
         BO    BV1                     FORMAT IS BLOCKED VARIABLE       16960000
         B     BF1                     FORMAT IS BLOCKED FIXED          16980000
         EJECT                                                          17000000
*                                                                       17020000
*********************************************************************** 17040000
* THESE ARE THE END OF DATA ROUTINES. ALL TERMINATION MUST GO THROUGH * 17060000
* THIS ROUTINE. TERMINATION INCLUDES PRINTING A MESSAGE, CLOSING THE  * 17080000
* DCB'S, FREEING CORE AND RETURNING. IF THIS IS NOT THE LAST MEMBER   * 17100000
* OF A PARTITIONED DATA SET THE NAME AND LOCATION OF THE NEXT MEMBER  * 17120000
* IS OBTAINED AND THE NEXT MEMBER IS PROCESSED. A USER EXIT MAY BE    * 17140000
* TAKEN TO PROCESS THE INPUT TRAILER LABEL IF IT IS A SEQUENTIAL DATA * 17160000
* SET.                                                                * 17180000
*********************************************************************** 17200000
*                                                                       17220000
EODID    LA    R1,IDMSG                LOAD A 14 INTO R1                17240000
         SR    R0,R0                   CLEAR REGISTER 0                 17260000
         B     EODWRT                  BRANCH TO MESSAGE ROUTINE        17280000
BLKSZERR LA    R1,BLKSZMIS             LOAD ERROR MESSAGE DISPLACEMENT  17300000
         LA    R0,12                   LOAD IEB MESSAGE CODE            17320000
         B     DOIT                                                     17340000
EODSTOP  LA    R1,STPMSG               LOAD A 15 INTO R1                17360000
         SR    R0,R0                   CLEAR REGISTER 0                 17380000
         B     EODWRT                  BRANCH TO MESSAGE ROUTINE        17400000
SDSEOD   B     TEMPTY        TAKE BRANCH IF EMPTY                A36088 17420021
         LA    R1,EODMSG     GET EOD MESSAGE NUMBER              A36088 17430021
         SR    R0,R0                   CLEAR REGISTER 0                 17440000
EODWRT   SLL   R1,8                                                     17460000
         L     R15,PMSGWRTA            LOAD ADDR OF ROUTINE IN IEBPPUN1 17480000
*                                      THAT PRINTS MESSAGES             17500000
         BALR  R14,R15                 BRANCH TO MESSAGE WRITER         17520000
         LH    TEMP1,LINECT            INCREMENT LINE COUNT        9476 17525019
         AH    TEMP1,PH1               BY 1 FOR EACH EOF MESSAGE   9476 17530019
         STH   TEMP1,LINECT            STORE NEW VALUE             9476 17535019
SDSEND   TM    TYPORG,3                WAS THE INPUT A PDS              17540000
         BZ    CLOSEIO                 NO - CLOSE A SEQUENTIAL DATA SET 17560000
         LH    TEMP1,MEMBCT            LOAD PDS MEMBER COUNT            17580000
         BCT   TEMP1,NEXTMEMB          REDUCE COUNT AND BRANCH          17600000
         B     CLOSEIO                 NO MORE MEMBERS - CLOSE DCB'S    17620000
NEXTMEMB STH   TEMP1,MEMBCT            STORE NEW MEMBER COUNT           17640000
         L     LISTR,DIRADD            LOAD ADDR.OF MEMBER NAMES A41759 17660021
         BO    NEXTM                   TEST FOR ONLY NAMED PDS MEMBERS  17680000
*                                      IF THAT'S CASE BRANCH            17700000
         TM    MEMGET,X'10'            GETMAIN FOR MEMB NAMES ?  A41759 17710021
         BC    8,TEMPTY                NO, PDS IS EMPTY          A41759 17712021
         LH    TEMP2,ALIASCT           SKIP ALIASES FROM DIRECTORY FOR  17720000
         AH    TEMP2,PH1               TOTAL PDS - ADD 1 TO ALIAS COUNT 17740000
         MH    TEMP2,LISTLEN           MULTIPLY COUNT BY A 12           17760000
         AR    LISTR,TEMP2             ADD VALUE TO MEMBER PTR          17780000
         ST    LISTR,DIRADD            SAVE PTR TO MEMBER NAMES         17800000
         B     PDT1                                                     17820000
NEXTM    AH    LISTR,LISTLEN           POINT TO NEXT NAMED MEMBER       17840000
         ST    LISTR,DIRADD            STORE PTR TO MEMBER NAMES        17860000
         B     PDP1                                                     17880000
*          E N T E R E D    W H E N    O P E N    D C B    E R R O R    17900000
DDERROR  LA    TEMP2,DDNAM(TEMP1)      GET ADR OF DDNAME IN DCB IN ERR. 17920000
         L     TEMP1,VMSG              GET ADR OF ERROR MSG             17940000
         MVC   7(8,TEMP1),0(TEMP2)     MOVE DDNAME TO ERROR MESSAGE     17960000
         LA    R0,11                                                    17980000
         LA    R1,21                   GET NUMBER OF MSG IN MSG MODULE  18000000
DOIT     MVI   DDSWITCH,X'01'          SET SWITCH NOT TO FREE MAIN      18020000
         B     IOWRT                   PRINT MESSAGE                    18040000
*        C L O S E   I N P U T   D C B                             UL0H 18060017
CLOSEIO  LA    R1,INSET            LOAD ADDR. OF  INP. DCB       A41816 18070021
         TM    OFLGS(R1),X'10'     WAS DCB OPENED ?              A41816 18071021
         BZ    CLOSEOUT            NO, DO NOT CLOSE              A41816 18072021
         CLOSE (INSET)             YES,CLOSE OUTPUT DCB          A41816 18073021
         TM    QSBRNOP+1,X'F0'     INPUT QSAM OPENED             A41816 18074021
         BNO   INTLRPRT            NO, DON'T FREE INP. BUFFERS   A41816 18075021
         FREEPOOL  INSET           FREE INP BUFFERS              A41816 18076021
INTLRPRT BAL   R8,LBLPRNT                                          UL0H 18080017
*        C L O S E   O U T P U T   D C B                           UL0H 18090017
CLOSEOUT LA    R1,OUTSET           LOAD ADDR. OF OUTP. DCB       A41816 18100021
         TM    OFLGS(R1),X'10'     WAS DCB OPENED ?              A41816 18108021
         BZ    NOFREE              NO, DO NOT CLOSE              A41816 18116021
         CLOSE (OUTSET)            YES,CLOSE OUTP. DATA SET      A41816 18124021
         FREEPOOL  OUTSET          FREEPOOL OUTPUT CORE          A41816 18132021
         TM    DDSWITCH,X'01'          IS FREEMAIN SKIPPED              18140000
         BO    NOFREE                  YES - BRANCH                     18160000
         L     R0,LENGTHSV             RESTORE ALLOCATED CORE SIZE      18180000
         L     R1,LENGTHAD             RESTORE ALLOCATED CORE ADDRESS   18200000
*          F R E E    C O R E    F O R    I N P U T    B U F F E R      18220000
         FREEMAIN R,LV=(0),A=(1)                                        18240000
NOFREE   TM    MEMGET,X'10'            TEST FOR MEMBER GETMAIN     4304 18245019
         BC    8,NOFREE1               IF NONE THEN BRANCH         4304 18250019
         L     R0,MEMAREA              ELSE GET ADDR OF LENGTH     4304 18255019
         L     R1,MEMADDR              AND AREA ADDRESS            4304 18260019
         FREEMAIN   R,LV=(0),A=(1)                                 4304 18265019
         MVI   MEMGET,X'00'            RESET GETMAIN SWITCH        4304 18270019
NOFREE1  SR    R15,R15             ZERO OUT REG. 15              A41816 18272021
         IC    R15,PPRETCDE            LOAD RETURN CODE                 18280000
         L     R13,PERM13              RESTORE REGISTER 13              18300000
*          R E T U R N    T O    C A L L I N G    P R O G R A M         18320000
         RETURN (14,12),RC=(15)                                         18340000
         EJECT                                                          18360000
*                                                                       18380000
*********************************************************************** 18400000
* THIS IS THE ROUTINE THAT GETS CORE (264 BYTES) FOR THE DIRECTORY    * 18420000
* RECORD AND KEY IF THE INPUT DATA SET IS PARTITIONED, THEN IT READS  * 18440000
* THE WHOLE DIRECTORY AND COUNTS THE NUMBER OF MEMBERS IN IT. IT THEN * 18460000
* REREADS THE DIRECTORY, THIS TIME PLACING THE MEMBERS IN ALLOCATED   * 18480000
* CORE AND SORTING THEM BY TTR'S AND ALIAS BITS. THIS IS DONE SO THAT * 18500000
* THE MESSAGE MAY BE PRINTED IN THE ORDER OF THEIR PHYSICAL OCCURRENCE* 18520000
* ON THE DIRECT ACCESS STORAGE DEVICE.                                * 18540000
*********************************************************************** 18560000
*                                                                       18580000
TOTAL    LA    TEMP1,INSET             GET ADDRESS OF INPUT DCB         18600000
         TM    DEVT(TEMP1),X'20'       IS IT A DIRECT ACCESS DCB        18620000
         BO    CHGABC                                                   18640000
         MVI   DDSWITCH,X'01'          SET NOT FREEMAIN SWITCH          18660000
         B     IOERRIN                                                  18680000
CHGABC   LA    R0,DIRBLKL              LOAD DIRECTORY LENGTH            18700000
         ST    R0,LENGTHSV             SAVE DIRECTORY LENGTH            18720000
*          G E T    C O R E    F O R    D I R E C T O R Y               18740000
         GETMAIN R,LV=(0)                                               18760000
         ST    R1,DIRBUFF              STORE POINTER TO BUFFER          18780000
         ST    R1,LENGTHAD             SAVE PTR TO ALLOCATED AREA       18800000
TOTRD1   SR    MEMCT,MEMCT             CLEAR MEMBER COUNTER             18820000
         L     R3,INBUFF               LOAD POINTER TO DIRECTORY        18840000
*          R E A D    D I R E C T O R Y                                 18860000
TOTRD    READ  DECBI,SF,INSET,(R3),'S',MF=E                             18880000
         CHECK DECBI                   CHECK THE READ                   18900000
TOT5     NOP   TOT9                    SWITCH SET BELOW - NEVER RESET   18920000
         NOTE  INSET                   REMEMBER LOCATION OF BLOCK READ  18940000
         ST    R1,DADDSAV              SAVE BLOCK IDENTIFICATION        18960000
         OI    TOT5+1,X'F0'            SET NOP SWITCH TO 'NOTE' ONCE    18980000
TOT9     LH    CTR,0(R3)               COUNT OF DIRECTORY BLOCK         19000000
         CH    CTR,PH256               IS COUNT GREATER THAN 256        19020000
         BH    IOERRIN                 THIS IS AN ERROR                 19040000
         CH    CTR,PH14                IT MUST BE GREATER THAN 14       19060000
         BE    TOT15B                   EQUAL, RESET SWITCH             19080000
         BL    SDSEOD                  NO INPUT --- BRANCH              19100000
         SH    CTR,PH2                 SUBTRACT 2 FOR 2 BYTE COUNT      19120000
         LA    RLOC,2(R3)              GET ADDRESS OF FIRST MEMBER      19140000
TOT10    B     TOT14                                                    19160000
         MVC   0(LISTL,ROUT),0(RLOC)   MOVE DIRECTORY ENTRY             19180000
         AH    ROUT,LISTLEN            INCREMENT PTR TO OUTPUT BY       19200000
*                                      LENGTH OF DIRECTORY ENTRY        19220000
TOT14    AH    MEMCT,PH1               ADD ONE TO MEMBER COUNT          19240000
         SR    RLEN,RLEN               CLEAR REGISTER TO HOLD LENGTH    19260000
         IC    RLEN,11(RLOC)           GET LENGTH OF USER DATA IN       19280000
*                                      DIRECTORY ENTRY                  19300000
         N     RLEN,ANDCONST           'AND' OUT ALL BITS EXCEPT 3-7    19320000
         SLL   RLEN,1                  MULTIPLY BY 2 - USER DATA HALF   19340000
         AH    RLEN,PH12               WORDS - ADD LENGTH OF DIR. ENTRY 19360000
         SR    CTR,RLEN                TEST FOR END OF INPUT RECORD     19380000
         LTR   CTR,CTR                                                  19400000
         BZ    TOT15A                  END - BRANCH - HAVE ALL MEMBERS  19420000
         AR    RLOC,RLEN               NO, CONTINUE                     19440000
         CLI   0(RLOC),X'FF'           IS THIS THE END OF DIRECTORY     19460000
         BNE   TOT10                   NO, CONTINUE LOOP                19480000
         NI    TOT15+1,X'0F'           YES - NOP TOT15                  19500000
TOT15    B     TOTRD                   END OF DIRECTORY SWITCH          19520000
         TM    TOT10+1,X'F0'           HAS DIRECTORY BEEN READ TWICE    19540000
         BZ    TOTCONT                 YES - BRANCH                     19560000
         NI    TOT10+1,X'0F'           NO -- RE-READ DIRECTORY          19580000
         OI    TOT15+1,X'F0'           RESET NOP SWITCH                 19600000
         LR    R0,MEMCT                HAVE READ DIRECTORY ONCE TO      19620000
         CH    R0,PHZERO                                           1244 19626014
         BE    TEMPTY                                              1244 19632014
         MH    R0,LISTLEN              COUNT ENTRIES, NOW GET SPACE FOR 19640000
*                                      MEMBERS                          19660000
         ST    R0,MEMAREA              SAVE AREA LENGTH            4304 19670019
         MVI   MEMGET,X'10'            SET GETMAIN SWITCH ON       4304 19680019
         GETMAIN R,LV=(0)                                               19700000
         ST    R1,DIRADD               STORE POINTER TO MEMBERS         19720000
         ST    R1,MEMADDR              SAVE MEMBER ADDRESS         4304 19730019
         LR    ROUT,R1                 SAVE POINTER TO MEMBERS          19740000
         POINT INSET,DADDSAV           POSITION DASD USING 'NOTE' PTR   19760000
         B     TOTRD1                                                   19780000
TOT15A   STH   MEMCT,MEMBCT            STORE MEMBER COUNT               19800000
         CH    MEMCT,PH1               IS THERE ONLY ONE MEMBER         19820000
         BE    SDSEOD                  YES - BRANCH TO END OF DATA ROUT 19840000
         CLI   0(RLOC),X'FF'           ARE WE AT THE END OF DATA        19860000
         BNE   TOT15                   NO -- BRANCH                     19880000
TOT15B   NI    TOT15+1,X'0F'            YES -- RESET NOP SWITCH         19900000
         B     TOT15                                                    19920000
TOTCONT  STH   MEMCT,MEMBCT            STORE PDS MEMBER COUNT           19940000
         L     R0,LENGTHSV             RESTORE LENGTH OF BUFFER         19960000
         L     R1,LENGTHAD             RESTORE POINTER TO BUFFER        19980000
*          F R E E    C O R E    F O R    D I R E C T O R Y             20000000
         FREEMAIN R,LV=(0),A=(1)                                        20020000
*          C L O S E    I N P U T    D C B                              20040000
*             F O R    D I R E C T O R Y    R E A D                     20060000
         CLOSE (INSET)                                                  20080000
*                                                                       20100000
*          SORT PARTITIONED DATA SET DIRECTORY                          20120000
*            ENTRIES BY TTR'S AND ALIAS BIT                             20140000
*                                                                       20160000
         LH    R1,PH1                  LOAD A ONE INTO REGISTER 1       20180000
         CH    R1,MEMBCT               IS THERE ONLY 1 MEMBER IN PDS    20200000
         BE    TOTEND                  YES -- BRANCH                    20220000
DSORT1   OI    DSORT10+1,X'F0'         NO -- SET SWITCH                 20240000
         L     LISTR,DIRADD            LOAD PTR TO MEMBER NAMES         20260000
         LR    LISTCT,R1               MOVE A ONE TO SORT COUNTER       20280000
DSORT3   CLC   8(3,LISTR),LISTL+8(LISTR) COMPARE TTR'S                  20300000
         BL    DSORT8                  IF LOW BRANCH                    20320000
         BH    DSORT5                  IF HIGH BRANCH                   20340000
         TM    ABITL(LISTR),X'80'      TTR'S ARE EQUAL, ONE MAY BE AN   20360000
         BZ    DSORT8                  ALIAS - IF NOT ALIAS BRANCH      20380000
         TM    ABITL+LISTL(LISTR),X'80' IF BOTH ARE ALIAS -             20400000
         BO    DSORT8                  DO NOTHING                       20420000
DSORT5   MVC   SAVE12(LISTL),0(LISTR)  MOVE NON-LOW MEMBER TO WORK AREA 20440000
         MVC   0(LISTL,LISTR),LISTL(LISTR) SWITCH MEMBER ENTRIES        20460000
         MVC   LISTL(LISTL,LISTR),SAVE12 MOVE OTHER MEMBER TO WORK AREA 20480000
         NI    DSORT10+1,X'0F'         SET SWITCH TO CONTINUE SORTING   20500000
DSORT8   AH    LISTR,LISTLEN           ADD LENGTH OF ENTRIES IN         20520000
*                                      DIRECTORY TO MEMBER NAME POINTER 20540000
         AR    LISTCT,R1               ADD ONE TO SORT COUNT            20560000
         CR    LISTCT,MEMCT            COMPARE SORT COUNT TO MEMBER CT. 20580000
         BL    DSORT3                  IF LOWER CONTINUE SORT           20600000
DSORT10  B     TOTEND                  SWITCH TO CONTINUE SORT          20620000
         BCT   MEMCT,DSORT1            REDUCE MEMBER COUNT AND CONTINUE 20640000
TOTEND   NI    POSTOPEN+1,X'0F'        SET SWITCH TO READ DATA SET      20660000
         B     PREOP1                                                   20680000
         EJECT                                                          20700000
*                                                                       20720000
*********************************************************************** 20740000
* MOVE AND CONVERT 'N' BYTES OF INPUT INTO '2N' BYTES OF OUTPUT.      * 20760000
* HEXIDECIMAL INPUT WILL BE CONVERTED TO EBCDIC, PACKED DECIMAL INPUT * 20780000
* WILL BE CONVERTED TO ZONED DECIMAL WITH THE SIGN OCCURING AS A      * 20800000
* SEPARATE CHARACTER.                                                 * 20820000
*                                                                     * 20840000
*       INLEN = NUMBER OF BYTES TO BE CONVERTED                       * 20860000
*       RLOC = THE INPUT LOCATION                                     * 20880000
*       ROUT = THE OUTPUT LOCATION                                    * 20900000
*                                                                     * 20920000
*********************************************************************** 20940000
*    L A B E L  C O N V.   E N T R Y   P O I N T                  *UL0H 20943017
FLDCONVL OI    LASTSW,81                                           UL0H 20946017
         TM    CONVSW,3                                            UL0H 20949017
         BO    FLDCONV1                                            UL0H 20952017
         B     FCHE                                                UL0H 20955017
*                                                                       20960000
*          S T A N D A R D    O U T P U T    E N T R Y    P O I N T     20980000
FLDCONV  CLC   CONVSW(1),TOTCONV                                        21000000
         BE    FLDCONV1                                                 21020000
         B     FCTEST                  CHANGE LIST                      21040000
*          U S E R    F O R M A T    E N T R Y    P O I N T             21060000
FLDCONVU CLC   CONVSW(1),4(FCBR)                                        21080000
         BE    FLDCONV1                                                 21100000
FCTEST   TM    CONVSW,3                TEST FOR PACKED TO ZONED DECIMAL 21120000
         BO    FCHE                    ON ALREADY - BRANCH              21140000
         MVC   FCPLUSA(6),FCSIGNS      SET UP CONVERSION LIST           21160000
         MVI   CONVSW,3                SET SWITCH - PACKED TO ZONED     21180000
         B     FLDCONV1                SKIP HEX TO EBCDIC SETUP         21200000
FCHE     MVC   FCPLUSA(6),FCHEX        SET UP CONVERSION LIST           21220000
         MVI   CONVSW,1                SET SW FOR HEX TO EBCDIC         21240000
*                                      THE TWO ABOVE SWITCH SETTINGS    21260000
*                                      SHOW THE CONVERSION LIST STATUS  21280000
FLDCONV1 CLI   CONVSW,X'03'            IS IT PACKED TO UNPACKED         21300000
         BNE   FLDCONV2                NO -- BRANCH                     21320000
         TM    LASTSW,X'01'            IS THIS THE LAST GROUP           21340000
         BZ    FLDCONV2                NO -- BRANCH                     21360000
         OI    LASTSW,X'80'            YES - SET LAST GROUP SW TO X'81' 21380000
         BCTR  INLEN,R0                REDUCE INPUT COUNT BY ONE        21400000
FLDCONV2 STH   INLEN,LENSAV            STORE INPUT COUNT                21420000
         ST    ROUT,OUTSAV             STORE PTR TO OUTPUT AREA         21440000
         ST    RLOC,LOCSAV             STORE PTR TO INPUT AREA          21460000
         LTR   INLEN,INLEN             IS INPUT COUNT ZERO              21480000
         BZ    FCRET                   YES - TEST FOR LAST GROUP        21500000
FC1      SR    TEMP1,TEMP1             CLEAR REGISTER                   21520000
         IC    TEMP1,0(RLOC)           LOAD CHARACTER TO CONVERT        21540000
         LR    TEMP2,TEMP1             MOVE CHARACTER TO CONVERT        21560000
         SRL   TEMP1,4                 REMOVE LOW ORDER 4 BITS          21580000
         STC   TEMP1,0(ROUT)           SEPARATE THE 4-BIT CHARACTERS    21600000
         STC   TEMP2,1(ROUT)           IN EACH BYTE                     21620000
         BCT   INLEN,FC2               REDUCE INPUT COUNT               21640000
         B     FC3                     BRANCH WHEN INPUT COUNT IS ZERO  21660000
FC2      AH    ROUT,PH2                INCREMENT PTR TO OUTPUT BY TWO   21680000
         AH    RLOC,PH1                INCREMENT PTR TO INPUT AREA BY 1 21700000
         B     FC1                     LOOP UNTIL INPUT COUNT IS ZERO   21720000
FC3      LH    INLEN,LENSAV            LOAD INPUT COUNT                 21740000
         L     ROUT,OUTSAV             RESTORE OUTPUT AREA POINTER      21760000
         SLL   INLEN,1                 MULTIPLY COUNT BY 2              21780000
         BCTR  INLEN,R0                REDUCE COUNT BY 1                21800000
         NI    0(ROUT),X'0F'           CLEAR HIGH ORDER 4 BITS EACH BYT 21820000
         BCTR  INLEN,R0                REDUCE INPUT LENGTH BY ONE       21840000
         EX    INLEN,FCMZ                                               21860000
         LA    INLEN,1(INLEN)          ADD ONE TO INPUT LENGTH          21880000
         EX    INLEN,FCTR                                               21900000
FCRET    LH    INLEN,LENSAV            LOAD INPUT COUNT                 21920000
         L     ROUT,OUTSAV             RESTORE OUTPUT AREA POINTER      21940000
         L     RLOC,LOCSAV             RESTORE PTR TO INPUT             21960000
         TM    LASTSW,X'81'            DID ROUTINE SET LAST GROUP SW    21980000
         BO    UNPKLAST                YES - BRANCH                     22000000
         BR    BREG                    NO - RETURN TO MAIN CODE         22020000
         SPACE 2                                                        22040000
UNPKLAST AR    RLOC,INLEN              GET TO LAST CHARACTER            22060000
         IC    R14,0(RLOC)             LOAD LAST CHARACTER              22080000
         SLL   R14,8                   MOVE IT OVER 1 BYTE              22100000
         IC    R14,0(RLOC)             LOAD LAST CHARACTER AGAIN        22120000
         SRL   R14,4                   SWITCHED - LOSE 4 LOW ORDER BITS 22140000
         SLL   INLEN,1                 MULTIPLY COUNT BY TWO            22160000
         AR    ROUT,INLEN              ADD IN OUTPUT LOCATION           22180000
         STC   R14,0(ROUT)             STORE CHARACTER IN OUTPUT AREA   22200000
         MVI   LASTSW,X'00'            CLEAR LAST SWITCH                22220000
         LH    INLEN,LENSAV            RESET LENGTH REG                 22240000
         L     ROUT,OUTSAV             RESET OUTPUT PTR                 22260000
         L     RLOC,LOCSAV             RESET INPUT PTR                  22280000
         LA    ROUT,1(ROUT)            ADD 1 TO OUTPUT PTR FOR EOR *    22300000
         BR    BREG                    RETURN TO MAIN CODE              22320000
         SPACE 3                                                        22340000
*          T R A N S L A T I O N    L I S T S                           22360000
FCLIST   DC    C'0123456789'                                            22380000
FCPLUSA  DC    C'ABCDEF'                                                22400000
FCHEX    DC    C'ABCDEF'                                                22420000
FCSIGNS  DC    C'+-+-++'                                                22440000
FCMZ     MVZ   1(1,ROUT),0(ROUT)       INSTRUCTION EXECUTED             22460000
         EJECT                                                          22480000
*                                                                       22500000
*********************************************************************** 22520000
* THIS ROUTINE INITIALLY BLANKS OUT THE OUTPUT BUFFER, PRINTS TITLES  * 22540000
* AND SETS UP FOR THE PRINTING OR PUNCHING OF A SEQUENTIAL DATA SET   * 22560000
* OR THE MEMBERS OF A PARTITIONED DATA SET.                           * 22580000
*********************************************************************** 22600000
*                                                                       22620000
PPHEAD   ST    BREG,PPHSAVE            SAVE RETURN REGISTER             22640000
         TM    PPSW1,1                 IS THIS A PRINT OR PUNCH OPERAT. 22660000
         BO    PU1                     PUNCH - BRANCH                   22680000
*          P R I N T I N G                                              22700000
         IC    CTLREG,PPCTL            SAVE CONTROL CHARACTER           22720000
         BAL   BREG,BLANKOUT           CLEAR OUTPUT BUFFER TO BLANKS    22740000
         MVI   PPCTL,C'1'              CTL TO EJECT PAGE AND PRINT LINE 22760000
         SR    TEMP1,TEMP1             CLEAR WORK REG                   22780000
         STH   TEMP1,LINECT            CLEAR OUTPUT LINE COUNTER        22800000
         TM    PAGEBYT,X'F0'       PAGE NBR TO BE PRINTED ?      A45134 22810021
         BO    TURNPAGE            NO, TURN TO NEXT PAGE         A45134 22820021
         LH    TEMP1,PGBIN             LOAD INITIAL PAGE NUMBER         22840000
         LR    TEMP2,TEMP1             MOVE PAGE NUMBER                 22860000
         AH    TEMP2,PH1               ADD ONE TO PAGE NUMBER           22880000
         STH   TEMP2,PGBIN             STORE NEXT PAGE NUMBER           22900000
         LA    TEMP2,OUTBUFF1      LOAD OUTPUT BUFF. ADDRESS     A45134 22902021
         AH    TEMP2,MAXOUT        ADD OUTPUT LENGTH-1           A45134 22904021
         SH    TEMP2,=H'10'        SUBTR 10 FOR PAGE NBR PURP.   A45134 22906021
         MVC   0(4,TEMP2),PAGE     MOVE 'PAGE' TO OUTPUT AREA    A45134 22910021
         CVD   TEMP1,DBLWD             CONVERT PAGE NUMBER TO DECIMAL   22920000
         UNPK  5(4,TEMP2),DBLWD+5(3)   UNPK PAGE NBR IN HEADER   A45134 22940021
         OI    8(TEMP2),X'F0'      RESET SIGN TO PRINTABLE CHAR. A45134 22960021
TURNPAGE BAL   BREG,WRCH               PRINT PAGE NUMBER         A45134 22980021
         STC   CTLREG,PPCTL            RESTORE CONTROL CHARACTER        23000000
         B     PPT                     SKIP OVER PUNCH ROUTINE          23020000
*          P U N C H I N G                                              23040000
PU1      TM    PPSW1,2                 ARE PUNCHED CARDS TO BE SEQUENCE 23060000
         BZ    PU3                     NO --- BRANCH                    23080000
         L     TEMP1,INITCDB            GET INIT.CARD SEQ NUMBER        23100000
         ST    TEMP1,CDNOB              SAVE SEQUENCE NUMBER            23120000
PU3      TM    PPSW1,4                 IS THIS THE FIRST MEMBER         23140000
         BO    PPNAME                  NO - BRANCH                      23160000
         OI    PPSW1,4                 YES - SET SWITCH                 23180000
*          T I T L E    P R I N T I N G                                 23200000
PPT      CLC   TCB1(2),PHZERO          IS THERE A TITLE                 23220000
         BNH   NOTITLE                 NO -- TEST FOR SUBTITLE          23240000
         LA    TCBR,TCB1               LOAD ADDRESS OF TITLE CTL BLOCK  23260000
         BAL   BREG1,TITLEMOV          WRITE AND CHECK TITLE            23280000
NOTITLE  CLC   TCB2(2),PHZERO          IS THERE A SUBTITLE              23300000
         BNH   PPNAME                  NO -- PERFORM WRITE SETUP        23320000
         LA    TCBR,TCBL(TCBR)         LOAD ADDRESS OF SUBTITLE CTL BLK 23340000
         BAL   BREG1,TITLEMOV          WRITE AND CHECK SUBTITLE         23360000
*          W R I T E    S E T U P                                       23380000
PPNAME   TM    TYPORG,1                IS THE INPUT A PDS               23400000
         BZ    PPHRET                  NO - BRANCH                      23420000
         L     LISTR,DIRADD            YES - HAVE TO WRITE MEMBER NAME  23440000
*                                      LOAD PTR TO MEMBER NAMES         23460000
         LA    OUTLOC,OUTBUFF1         LOAD PTR TO OUTPUT AREA          23480000
         BAL   BREG,BLANKOUT           BLANK OUT OUTPUT AREA            23500000
         MVC   0(11,OUTLOC),MBRNAMEA   MOVE 'MEMBER NAME' TO OUTPUT     23520000
         MVC   13(8,OUTLOC),0(LISTR)   MOVE ACTUAL NAME TO OUTPUT AREA  23540000
         BAL   BREG,WRCH               PRINT A LINE                     23560000
         TM    TYPORG,2                IS WHOLE PDS BEING PROCESSED     23580000
         BO    PPHRET                  NO - BRANCH - RETURN TO MAIN CDE 23600000
         NI    PPN7+1,X'0F'            YES - CLEAR NOP SWITCH           23620000
         LH    ALIASR,ALIASCT          LOAD ALIAS COUNT FOR THIS MEMBER 23640000
PPN6     LTR   ALIASR,ALIASR           ARE THERE ANY ALIASES            23660000
         BC    13,PPHRET               NO ALIASES - RETURN TO MAIN CODE 23680000
         LA    OUTLOC,OUTBUFF1                                          23700000
         BAL   BREG,BLANKOUT           CLEAR OUTPUT AREA TO BLANKS      23720000
PPN7     NOP   PPN8                    PRINT ALIASES SWITCH             23740000
         MVC   0(7,OUTLOC),ALIASA      MOVE 'ALIASES' TO OUTPUT AREA    23760000
PPN8     LH    FLDCT,MAXOUT        LOAD OUPUT LRECL MINUS ONE    A50923 23780021
         SRL   FLDCT,4             DIVIDE IT BY 16               A50923 23790021
PPN10    LA    OUTLOC,10(OUTLOC)   BUMP OUTPUT POINTER TEN       A50923 23820021
         AH    LISTR,LISTLEN           BUMP PTR TO MEMBER NAMES TO      23860000
*                                      ALIASES - ADD 12                 23880000
         MVC   3(8,OUTLOC),0(LISTR) MOVE ACT. ALIAS TO OUT. AREA A50923 23900021
         BCT   ALIASR,PPN11       ANY MORE ALIASES ?             A50923 23910021
         B     PPNWRT             NO, PRINT ALIASES AND RETURN   A50923 23912021
PPN11    BCT   FLDCT,PPN10        BRANCH WHEN ENOUGH SPACE       A50923 23914021
*                                 IN OUTPUT BUFF FOR NEXT ALIAS  A50923 23916021
PPN12    OI    PPN7+1,X'F0'            SET NO ALIAS NOP SWITCH          23980000
PPNWRT   BAL   BREG,WRCH               PRINT ALIAS NAME                 24000000
         B     PPN6                    TEST FOR MORE ALIASES            24020000
PPHRET   L     BREG,PPHSAVE            RESTORE RETURN REGISTER          24040000
         BR    BREG                    RETURN TO MAIN CODE              24060000
QSPREFM LH     R12,MAXOUT                                          VS0H 24061017
         STH   R12,OUTLRECL                                        VS0H 24062017
         LA    R6,1                                                VS0H 24064017
         MVI   OUTBUFF1,C' '                                       VS0H 24065017
         EX    R12,CLEAROUT                                        VS0H 24066017
         SH    R4,PH4                                              VS0H 24067517
         SR    R4,R6                   REDUCE BY 1 FOR EXEC&COMP   VS0H 24067717
         CR    R12,R4                                              VS0H 24068017
         BL    PREVRBA1                                            VS0H 24069017
         EX    R4,QSMOVE                                           VS0H 24071017
         BAL   BREG,WRCH                                           VS0H 24072017
         B     RDCH                                                VS0H 24073017
PTCHONE  CLC   LRECL,=X'7FF4'                                      VS0H 24075017
         BNH   TSTKEYS                 LESS THAN 32K               VS0H 24079017
         MVI   QSBRNOP+1,X'0'                                      VS0H 24083017
         B     TSTPREFM                                            VS0H 24087017
TSTKEYS  TM    KEYLEN+1,X'FF'                                      VS0H 24091017
         BZ    VRQSAM                  NO, SET QSAM ACC METH.    A48796 24095021
         MVI   QSBRNOP+1,X'00'                                     VS0H 24099017
         B     VSKEYS                  USE BSAM                    VS0H 24103017
PPHSAVE  DS    F                       HOLDS RETURN REG FOR PPHEAD ROUT 24107017
OPENSW   DC    X'0'                    ON DURING OPEN RTNE ONLY    UL0H 24111017
         EJECT                                                          24120000
*                                                                       24140000
*********************************************************************** 24160000
* THIS ROUTINE HANDLES THE 'PREFORM' UTILITY PROGRAM OPTION. THROUGH  * 24180000
* THIS OPTION THE USER MAY HAVE ALREADY BUILT AN INPUT DATA SET WITH  * 24200000
* AN IMBEDDED CONTROL CHARACTER WHICH WILL GOVERN THE OUTPUT CONTROL  * 24220000
* OF THE OUTPUT DATA SET. IF THE INPUT RECORDS ARE OF THE FIXED OR    * 24240000
* UNDEFINED FORMAT THE CONTROL CHARACTER IS IN THE FIRST BYTE; IF     * 24260000
* VARIABLE THE FIFTH BYTE. AN INPUT LOGICAL RECORD WHICH EXCEEDS 121  * 24280000
* BYTES CAUSES A MESSAGE TO BE PRINTED AND JOB TERMINATION. WHEN      * 24300000
* PREFORM IS SPECIFIED ALL OTHER CONTROL STATEMENT REQUESTS ARE       * 24320000
* IGNORED.                                                            * 24340000
*********************************************************************** 24360000
*                                                                       24380000
PREFORM  LA    R8,INSET                SET UP DSECT ADDRESSABILITY      24400000
         USING IHADCB,R8               USE DSECT FOR INPUT DCB          24420000
         LH    12,MAXOUT                                           VS0H 24430017
         STH   12,OUTLRECL                                         VS0H 24440017
NOTPUNCH L     R1,DECBI+16             IS THIS A TRUNCATED RECORD       24520000
         SH    R1,PH1                  GET TO RIGHT BYTE IN DECB -      24540000
         TM    0(R1),X'01'             SUBTRACT ONE - TEST FOR TRUNCAT. 24560000
         BO    COMPUTE                 YES IT'S A TRUNCATED RECD - BRAN 24580000
         TM    DCBRECFM,X'90'          IS INPUT BLOCKED RECORDS         24600000
         BO    BLOCKED                 YES - BRANCH                     24620000
         TM    DCBRECFM,X'C0'          IS IT A UNDEFINED LENGTH RECORD  24640000
         BO    URECORD                 YES IT IS - BRANCH               24660000
         TM    DCBRECFM,X'40'          IS IT A VARIABLE LENGTH RECORD   24680000
         BO    VBLOC                                               3173 24700015
         L     R1,INBUFF               LOAD ADDRESS OF INPUT AREA       24720000
         LA    R6,1                    LOAD ONE INTO A REG              24740000
         MVI   OUTBUFF1,C' '           CLEAR OUTPUT BUFFER              24760000
         EX    R12,CLEAROUT                                        VS0H 24780017
         LH    R4,DCBLRECL             LOAD LOGICAL RECORD LENGTH       24800000
         SR    R4,R6                   REDUCE BY 1 FOR EXEC&COMP   VS0H 24810017
         CR    R12,R4                   IS INPUT GREATER THAN MAX       24820000
         BL    PREVRBA1                                            VS0H 24850017
         EX    R4,MOVE                 MOVE INPUT CONTROL CHAR TO OUT.  24880000
         BAL   BREG,WRCH               WRITE(PRINT/PUNCH) RECORD        24900000
         B     RDCH                    READ ANOTHER PHYSICAL RECORD     24920000
BLOCKED  MVC   STARTIN(4),INBUFF                                   2461 24930016
         L     R3,DECBI+16                                         2461 24940016
         LH    R3,14(R3)                                           2461 24950016
         LH    R4,DCBBLKSI                                         2461 24960016
         SR    R4,R3                                               2461 24970016
         STH   R4,BLCKREM                                          2461 24980016
TRUNCBLK DS    0H                                                  VS0H 25000017
THRUONCE LH    R1,BLCKREM              HOW MUCH OF INPUT BLOCK IS LEFT  25060000
         LTR   R1,R1                   IS BLOCK FINISHED                25080000
         BE    RDCH                                                2461 25100016
         SH    R1,DCBLRECL             TAKE LRECL FROM REMAINING BLKSIZ 25120000
         STH   R1,BLCKREM              STORE REMAINDER                  25140000
         L     R2,STARTIN              LOAD PTR TO INPUT BUFFER         25160000
         LA    R6,1                    LOAD A ONE IN REG                25180000
         MVI   OUTBUFF1,C' '           CLEAR OUTPUT BUFFER              25200000
         EX    R12,CLEAROUT                                        VS0H 25220017
         LH    R4,DCBLRECL             LOAD LOGICAL RECORD LENGTH       25240000
         SR    R4,R6                   REDUCE BY 1 FOR EXEC&COMP   VS0H 25243017
         CR    R12,R4                                              VS0H 25246017
         BL    SETBLKSW                                            VS0H 25252017
         EX    R4,MOVE2                MOVE CTL CHAR TO OUTPUT AREA     25280000
         AH    R2,DCBLRECL             ADD LRECL TO INPUT POINTER       25300000
         ST    R2,STARTIN              SAVE THIS ADDRESS IN SAVE AREA   25320000
         TM    BLKDSWCH+1,X'F0'                                    VS0H 25326017
         BO    BLKDLONG                                            VS0H 25333017
         BAL   BREG,WRCH               WRITE(PRINT/PUNCH) RECORD        25340000
         B     THRUONCE                DO NEXT RECORD                   25360000
RESETSW  MVC   STARTIN(4),INBUFF       RESET INPUT ADDRESS              25380000
         MVC   BLCKREM,DCBBLKSI        RESET BLOCK SIZE                 25400000
         B     RDCH                    READ ANOTHER PHYSICAL RECORD     25420000
COMPUTE  L     R1,DECBI+16             LOAD IOB+8 PTR                   25440000
         LH    R2,14(R1)               LOAD RESIDUAL COUNT FROM CSW     25460000
         LH    R3,DCBBLKSI             LOAD BLOCKSIZE FROM INPUT DCB    25480000
         SR    R3,R2                   GET NUMBER OF BYTES IN TRUNC REC 25500000
         ST    R3,BLCKREM              STORE NEW BLOCK SIZE             25520000
         B     TRUNCBLK                                            VS0H 25620017
URECORD  L     R1,INBUFF               LOAD ADDRESS OF INPUT AREA       25740000
         LH    R4,DCBBLKSI             LOAD BLOCK SIZE OF INPUT DCB     25760000
         L     R5,DCBIOBA              GET IOB ADDRESS FROM INPUT DCB   25780000
         LA    R5,0(R5)                CLEAR HIGH ORDER BYTE OF R5      25800000
         LH    R5,22(R5)               GET RESIDUAL COUNT FROM CSW      25820000
COMMON   MVI   OUTBUFF1,C' '           CLEAR OUTPUT BUFFER              25840000
         EX    R12,CLEAROUT                                        VS0H 25860017
         LA    R6,1                    LOAD A ONE FOR EXECUTE INSTRUCT. 25880000
         SR    R4,R5                   SUBTRACT RES COUNT FROM BLKSIZE  25900000
         CR    R12,R4                  IS INPUT GREATER THAN MAX        25920000
         BL    PREVRBA2                BREAK UP UNDEFINED RECORDS  VS0H 25940017
         SR    R4,R6                   SUBTRACT ONE MORE                25960000
         EX    R4,MOVE                 MOVE LENGTH TO OUTPUT BUFFER     25980000
         BAL   BREG,WRCH               WRITE(PRINT/PUNCH) RECORD        26000000
         B     RDCH                    READ ANOTHER PHYSICAL RECORD     26020000
VBLOC    LA    R4,1                    LOAD A ONE                       26040000
         LA    R5,4                    LOAD A FOUR                      26060000
         L     R3,INBUFF               LOAD ADDRESS OF INPUT BUFFER     26080000
         LH    R7,0(R3)                GET BLOCK SIZE                   26100000
         SR    R7,R5                   SUBTRACT 4 BYTES FROM BLKSIZE    26120000
         STH   R7,BLCKREM              STORE THAT IN HOLD AREA          26140000
         LA    R3,4(R3)                SKIP 4 BYTES OF VAR. BLK RECORD  26160000
         ST    R3,STARTIN              STORE INPUT AREA PTR+4           26180000
ONCE     LH    R1,BLCKREM              HOW MUCH INPUT BLOCK LEFT        26200000
         LTR   R1,R1                   IS IT ALL DONE                   26220000
         BZ    RDCH                    YES --- READ NEW PHYSICAL RECD   26240000
         L     R3,STARTIN               NO -- GET PTR TO LOGICAL REC    26260000
         MVC   HWD(2),0(R3)            MOVE LRECL TO HALF WORD BOUNDARY 26280000
         LH    R3,HWD                  LOAD LOGICAL RECORD LENGTH       26300000
         AR    R12,R5    ADD 4 BYTES TO ACCOUNT FOR LLBB           3173 26310015
         AH    R12,PH1       ADD 1 BYTE FOR ASA OR MC. BYTE      A38702 26315020
         CH    R12,HWD                  IS INPUT GREATER THAN MAX       26320000
         BL    SETVSW                                              VS0H 26330017
         SR    R12,R5    REINITIALIZE R12                          3173 26350015
         SH    R12,PH1                                           A38702 26355020
         SR    R1,R3                   SUBTRACT LOG. REC. LEN FROM BLKZ 26360000
         STH   R1,BLCKREM              STORE REST OF BLOCK SIZE         26380000
         L     R2,STARTIN              LOAD INPUT AREA POINTER          26400000
         LA    R2,4(R2)                BUMP IT BY 4                     26420000
         SR    R3,R5                   SUBTRACT 4 BYTES OF LRECL        26440000
         SR    R3,R4                   PREPARE FOR EXECUTE INSTRUCTION  26460000
         MVI   OUTBUFF1,C' '           CLEAR OUTPUT BUFFER              26480000
         EX    R12,CLEAROUT                                        VS0H 26500017
         EX    R3,MOVE2                                                 26520000
         AR    R3,R4                   RESET R3                         26540000
         AR    R2,R3                   BUMP UP INPUT PTR                26560000
         ST    R2,STARTIN              SAVE THIS NEW ADDRESS            26580000
         BAL   BREG,WRCH               WRITE(PRINT/PUNCH) RECORD        26600000
         B     ONCE                                                     26620000
         SPACE 3                                                        26640000
MOVE     MVC   OUTBUFF(1),0(R1)                                         26660000
MOVE2    MVC   OUTBUFF(1),0(R2)                                         26680000
MOVEPART MVC   OUTBUFF1,0(R2)                                      VS0H 26690017
HWD      DC    X'0000'                 HALF WORD WORK AREA              26700000
CLEAROUT MVC   OUTBUFF1+1,OUTBUFF1                                 UL0H 26705017
SAVLRECL DS    H                                                   VS0H 26710017
OUTLRECL DS    H                                                   VS0H 26715017
         DROP  R8                                                       26720000
         EJECT                                                          26740000
*                                                                       26760000
*********************************************************************** 26780000
* THIS ROUTINE WRITES(PRINT/PUNCH) ONE RECORD. THE LINE COUNT IS      * 26800000
* INCREMENTED BY ONE BEFORE IT IS PRINTED IF PRINTING IS REQUIRED OR  * 26820000
* THE CARD NUMBER IS INCREMENTED IF IT IS TO BE PUNCHED.              * 26840000
*********************************************************************** 26860000
*                                                                       26880000
WRCH     TM    PPSW1,X'03'             IS OUTPUT PRINTED OR PUNCHED     26900000
         BO    WCCDNO                  YES - PUNCH W/SEQUENCE - BRANCH  26920000
         BM    WRCH2                   NO - JUST PUNCHED - BRANCH       26940000
CGLPUNCH LH    TEMP1,LINECT            LOAD LINE COUNTER                26960000
         AH    TEMP1,LINEINCR          ADD ONE TO LINE COUNTER          26980000
         STH   TEMP1,LINECT            STORE LINE COUNTER               27000000
*          W R I T E    O U T P U T                                     27020000
WRCH2    ST    R8,KEEPR4R6         SAVE R8                         7034 27040000
         TM    NOTOPEN,X'F0'    SYSUT2 D C B NOT OPENED            7034 27060000
         BO    SYPRNDCB    USE SYSPRINT D C B                      7034 27080000
         LA    R8,OUTSET    ADDR OF SYSUT2  D C B                  7034 27100000
         B     WRCH3    GO ISSUE WRITE                             7034 27120000
SYPRNDCB L     R8,SYSPRPTR     USE SYSPRINT D C B                  7034 27140000
WRCH3    PUT   (R8),OUTBUFF                                      A23458 27170018
         L     R8,KEEPR4R6     RESTORE R 8                         7034 27200000
         BR    BREG                    RETURN TO MAIN CODE              27220000
         SPACE 2                                                        27240000
WCCDNO   L     TEMP2,CDNOB              LOAD CARD NUMBER                27260000
         LR    TEMP1,TEMP2              MOVE CARD NUMBER                27280000
         A     TEMP2,CDINCRB            INCREMENT CARD NUMBER           27300000
         ST    TEMP2,CDNOB             STORE CARD NUMBER                27320000
         CVD   TEMP1,DBLWD             CONVERT CARD NUMBER TO DECIMAL   27340000
         UNPK  PUCD(8),DBLWD+3(5)      ADD ZONE BITS TO CONVERTED NUMB. 27360000
         OI    PUCD+7,X'F0'            RESET SIGN TO PRINTABLE CHAR.    27380000
         B     WRCH2                   BRANCH TO WRITE MACRO TO PUNCH   27400000
*                                                                       27420000
*          MOVE AND WRITE TITLE                                         27440000
*                                                                       27460000
TITLEMOV LH    LEN,0(TCBR)             LOAD TITLE LENGTH                27480000
         BCTR  LEN,R0                  REDUCE LENGTH FOR EXECUTE INST.  27500000
         LA    ROUT,OUTBUFF1           LOAD ADDRESS TO OUTPUT FIELD     27520000
         L     RLOC,4(TCBR)            LOAD PTR TO TITLE                27580000
         EX    LEN,FMOVE               MOVE TITLE TO OUTPUT AREA        27620000
         LH    LEN,2(TCBR)         LOAD TITLE LENGTH             A52039 27630021
         LH    R12,MAXOUT          LOAD OUTPUT LRECL-1           A52039 27632021
         CR    LEN,R12             LITT. EXCEEDS OUTPUT ?        A52039 27634021
         BNH   TITLOKE             NO, CONTINUE                  A52039 27636021
         LA    R0,37               LOAD MSG NUMBER IEB437I       A52039 27638021
         LR    R1,R0               LOAD MSG DISPL OF MSG IEB437I A52039 27638421
         B     IOWRT               PRINT MSG AND STOP PROC.      A52039 27638821
TITLOKE  EQU   *                   CONT. PROCESSING              A52039 27639221
         LR    BREG,BREG1              MOVE RETURN PTR TO PPNAME        27640000
         B     WRCH                    WRITE AND CHECK TITLE            27660000
*                                                                       27680000
*          CLEAR OUTPUT AREA                                            27700000
*                                                                       27720000
BLANKOUT MVI   OUTBUFF1,C' '           CLEAR OUTPUT BUFFER TO BLANKS    27740000
         LH    R12,MAXOUT                                          UL0H 27750017
         EX    R12,CLEAROUT                                        UL0H 27760017
         BR    BREG                    RETURN TO MAIN CODE              27780000
         SPACE 3                                                        27800000
*                                                                       27820000
*          INSTRUCTIONS EXECUTED                                        27840000
*                                                                       27860000
IDTCOMP  CLC   0(1,RLOC),0(RLIT)                                        27880000
FMOVE    MVC   0(1,ROUT),0(RLOC)       USED TO MOVE TITLE AND OUTPUT    27900000
*                                      TO OUTPUT BUFFER                 27920000
FCTR     TR    0(1,ROUT),FCLIST        USED TO CONVERT CHARACTERS       27940000
QSMOVE   MVC   OUTBUFF(1),4(R1)                                    VS0H 27950017
         EJECT                                                          27960000
*                                                                       27980000
*********************************************************************** 28000000
*                 E R R O R    R O U T I N E S                        * 28020000
*                                                                     * 28040000
*          GO TO IEBPPUN1 - ROOT SEGMENT - TO PRINT MESSAGE           * 28060000
*********************************************************************** 28080000
*                                                                       28100000
*          B L D L    M A C R O    E R R O R                            28120000
MEMBNO   LA    R1,BLDENTRY             LOAD ADDRESS OF MEMBER NAME      28140000
         MVI   PPRETCDE,X'8'           SET RETURN CODE                  28160000
         LA    R0,8                    LOAD PTR TO APPROPRIATE MESSAGE  28180000
         L     R15,MNMSGA              LOAD ADDRESS OF MESSAGE ROUTINE  28200000
         LA    R14,SDSEND              LOAD RETURN REGISTER - IF        28220000
*                                      PROCESSING A SDS THE PROGRAM IS  28240000
*                                      TERMINATED - IF A PDS NEXT       28260000
*                                      MEMBER IS READ                   28280000
         BR    R15                     GO TO ROOT SEGMENT TO PRINT MSG  28300000
         SPACE 2                                                        28320000
*          T E R M I N A T I O N    E R R O R    R O U T N E            28340000
DCBERROR LA    R0,12             LOAD  IEB412I MESS.             A45135 28350021
         LA    R1,6              LOAD MESS. NUMBER               A45135 28352021
         MVI   DDSWITCH,X'01'    SET NOTFREEMAIN SWITCH          A45135 28352421
         B     IOWRT             SET C.C AND PRINT MESSAGE       A45135 28354021
PRERROR1 L     R10,SAVEAREA            RESTORE ADDRESSABILITY           28360000
PRERROR  LA    R0,10                   LOAD IEB CODE FOR MESSAGE        28380000
         LA    R1,20                   LOAD ONE LESS THAN MSG NUMBER    28400000
         B     IOWRT                   ARRANGE IEB CODE AND MSG NUMBER  28420000
TEMPTY   LA    R0,17                                               1244 28425014
         LA    R1,25                                               1244 28430014
         MVI   PPRETCDE,X'4'       SET RETURN CODE TO 4          A48732 28432021
         B     IOWRT1              PRINT MSG IEB417I             A48732 28435021
IOERRIN  LA    R0,7                    LOAD IEB CODE FOR MESSAGE        28440000
         LA    R1,IOMSG                LOAD ONE LESS THAN MSG NUMBER    28460000
IOWRT    MVI   PPRETCDE,X'C'           SET RETURN CODE TO 12            28480000
IOWRT1   SLL   R1,8                    MOVE MSG NUMBER OVER 2 BYTES     28500000
         AR    R1,R0                   PLACE IEB CODE IN SAME REG       28520000
         L     R15,PMSGWRTA            LOAD PTR TO MESSAGE WRITER       28540000
         LA    R14,CLOSEIO             LOAD PTR TO END OF JOB ROUTINE   28560000
         MVC   INTLRPRT,NOPLBLPR       BYPASS PRINT OF TLR         UL0H 28566017
*                                      LABELS ON IO ERROR ON OP    UL0H 28572017
         BR    R15                     GO TO ROOT SEGMENT TO PRINT MSG  28580000
*                                                                       28581019
*               I / O   E R R O R  H A N D L I N G   R O U T I N E      28582019
*                                                                       28583019
SYNADMSG TM    QSBRNOP+1,X'F0'     INPUT VARIABLE SPANNED ?      A48796 28584021
         BO    QSYNADAF            YES, TAKE QSAM SYSNADAF ROUT. A48796 28584121
         SYNADAF ACSMETH=BSAM      BSAM SYSNADAF                 A48796 28584221
         B     SKIPQSYN            SKIP QSAM SYSNADAF            A48796 28584321
QSYNADAF SYNADAF ACSMETH=QSAM      QSAM SYSNADAF                 A48796 28584421
SKIPQSYN EQU   *                   PRINT SYNADAF MESSAGE         A48796 28584521
         LA    R7,MSGSYNDF        GET MESSAGE BUFFER ADDR          7715 28585019
         LA    R7,18(R7)          GET ADDR OF BUFFER BEYOND ID     7715 28586019
         MVC   0(79,R7),49(R1)    MOVE MESSAGE TO BUF              7715 28587019
         SYNADRLS                                                  7715 28588019
         LA    R1,MSGSYNDF        GET MESSAGE ADDR FOR PRINT       7715 28589019
         LA    R0,96              SET LENGTH OF MSG TO BE WRITTEN  7715 28590019
         MVI   PPRETCDE,X'C'      SET RETURN CODE TO 12            7715 28591019
         LA    R14,CLOSEIO        LOAD PTR TO END OF PPCH1         7715 28592019
         L     R15,VZZPR          LOAD PTR TO MESSAGE WRITER RTN   7715 28593019
         MVC   INTLRPRT,NOPLBLPR  BYPASS TLR LABEL PRINT ON I/O ER 7715 28594019
         BR    R15                GO TO CLOSE INPUT & OUTPUT DCBS  7715 28595019
         SPACE 2                                                        28600000
EXTERM1  LA    R1,EOJUSM               LOAD 12 INTO REG 0 AND 1         28620000
         LA    R0,6                                                     28640000
         STC   R15,PPRETCDE            STORE RETURN CODE                28660000
         B     IOWRT1                  WRITE MESSAGE                    28680000
PREERR1  LA    R0,13                    LOAD ERROR MESSAGE CODE FOR IEB 28700000
         LA    R1,22                   LOAD ONE LESS THAN MESSAGE       28720000
*                                       NUMBER IN IEBPPMSG MODULE  UL0H 28728017
         B     IOWRT1                   ARRANGE CODES--PRINT MSG   UL0H 28736017
LBLPRNT  ST    R5,SAVER5                                           UL0H 28744017
         TM    IOSW+1,X'F0'                                        UL0H 28752017
         BO    IOLABERR                                            UL0H 28760217
         LA    R5,LABEL1                                           UL0H 28760317
         CL    R5,LBLSVPTR                                         UL0H 28760621
         BE    EXITULPR                                            UL0H 28760817
         TM    ULEXSW+1,X'F0'                                      UL0H 28761117
         BO    ULPROC                  GO TO USER LABEL PROC.      UL0H 28761317
YESLABLS B    LABELS                                               UL0H 28761517
ULPROC   CLI   USRTRMSW,X'F0'                                      UL0H 28761817
         BE    WRTUSTMS                                            UL0H 28762117
         B     LABELS                                              UL0H 28762717
WRTUSTMS LA    R0,6                                                UL0H 28763317
         LA    R1,12                    12 IS USTERM MSG # DIPSL.  UL0H 28763617
         B     IOWRT                                               UL0H 28763917
WRTIOMSG LA    R0,7                                                UL0H 28764217
         LA    R1,13                                               UL0H 28764517
         B     IOWRT                                               UL0H 28764817
LABELS   MVC   PRNTLIM,LBLSVPTR                                    UL0H 28765117
         ST    R5,LBLSVPTR                                         UL0H 28765417
         TM    PPSW1,1        PUNCH COMMAND ?                    A45135 28766821
         BNZ   PRINTLBL       YES, DO NOT PRINT PAGE HEADER      A45135 28766921
         BAL   BREG,PPHEAD    TURN PAGE AND PRINT PAGE NBR       A45135 28769221
         L     R5,LBLSVPTR    RESTORE PTR TO LABEL SAVE AREA     A45135 28769621
PRINTLBL BAL   BREG,BLANKOUT                                       UL0H 28770621
         LA    ROUT,OUTBUFF1                                       UL0H 28772021
         TM    LBLCONSW,1                                          UL0H 28773421
         BO    CONVLBLS            YES, BR TO CONVERT LBLS         UL0H 28774821
         MVC   0(80,ROUT),0(R5)                                    UL0H 28776221
         BAL   BREG,WRCH                                           UL0H 28777621
         L     R5,LBLSVPTR                                         UL0H 28779021
         AH    R5,=X'0050'         ADD  80 BYTES                   UL0H 28780421
         ST    R5,LBLSVPTR                                         UL0H 28781821
         C     R5,PRNTLIM                                          UL0H 28783221
         BE    LBLPRNTX            ALL DONE                        UL0H 28784621
         B     PRINTLBL                                            UL0H 28786021
LBLPRNTX LA    R5,LABEL1                                           UL0H 28787421
         ST    R5,LBLSVPTR             RESET PTR TO 1ST POS'N      UL0H 28788821
         MVC   LINECT,PMAXLINE          FORCE LINE COUNT TO ADV    UL0H 28790221
EXITULPR L     R5,SAVER5                                           UL0H 28791621
         BR    R8                                                  UL0H 28793021
IOLABERR LA    R0,22                                               UL0H 28794421
         LA    R1,30                                               UL0H 28795821
         B     DOIT                    TERM.RTNE ON IO LBL ERROR   UL0H 28797221
         EJECT                                                          28798621
*                                                                       28800000
*********************************************************************** 28820000
*      C O N S T A N T S    A N D    W O R K    A R E A S             * 28840000
*********************************************************************** 28860000
*                                                                       28880000
*                                                                       28900000
*          EXIT LIST FOR INPUT DATA SET                                 28920000
*              UHIN-USER INOUT HDR LABEL EXIT-ADDR.OBT'D           UL0H 28940017
*              UTIN-           TLR            BY LOAD MACROS       UL0H 28960017
*               DCBIN - DCB EXIT TAKEN AT OPEN TIME                     28980000
*                  DCBEXSW-WHEN DS CLOSED PRIOR TO REOPENING       VS0H 28990017
*                            WITH QSAM                             VS0H 29000017
         DS    0F                                                  7034 29020000
SAVER5   DS    F                                                   UL0H 29030017
DCBSAVE  DS    F                                                 A38762 29032021
KEEPR4R6 DS    3F                                                  7034 29040000
STARTIOT DS    F                                                   7034 29060000
SYSPRPTR DC    V(PPOUT)      ADDRESS OF SYSPRINT   D C B           7034 29080000
SISUT2   DC    CL8'        '                                       7034 29100000
NOTOPEN  DC    X'00'                                               7034 29120000
EXITSIN  DS    0F                                                       29140000
UHIN     DC    XL4'00C8C8C8'           WILL BE REPLACED BY INHDR   UL0H 29160017
UTIN     DC    XL4'00E3E3E3'           INTLR RTN IF ANY PASSED     UL0H 29180017
PPEXIN   DS    0F                                                  UL0H 29223017
PPHINEX  DC    X'00'                                             A45135 29226021
         DC    AL3(PPIHLEX)                                        UL0H 29229017
PPTINEX  DC    X'00'                                             A45135 29232021
         DC    AL3(PPITLEX)                                        UL0H 29235017
DDDEX    DC    X'85'         LABEL CHANGED BEC. OF AOS DSCB             29240021
DCBEXIN  DC    AL3(DCBIN)                                               29260000
DCBEXSW  DC    X'85'                                               VS0H 29265017
         DC    AL3(DCBRET)                                         VS0H 29270017
USEREX   DC    BL4'0'                                              UL0H 29276017
*                                                                       29280000
*          USED FOR BUILDING OUTPUT LINE                                29300000
*            MODIFIED FOR PUNCHING OUTPUT                               29320000
*                                                                       29340000
MAXSEG   DC    H'12'                   NUMBER OF GROUPS PER LINE        29360000
INSEG    DC    H'8'                    NUMBER OF CHARACTERS PER GROUP   29380000
OUTSEG   DC    H'10'                   CHARACTERS PLUS BLANKS PER GROUP 29400000
*                                                                       29420000
*          RECORD GROUP SWITCHES                                        29440000
*                                                                       29460000
IDSW     DC    X'0'                    INPUT, 0 = NO ID, 1 = ID TEST,   29480000
*                                      3 = END OF GROUP                 29500000
FORMATSW DC    X'0'                    OUTPUT, 0 = STANDARD FORMAT      29520000
*                                              1 = USER DEFINED FORMAT  29540000
DBLWD    DS    D                       WORK AREA FOR CARD AND PAGE      29560000
*                                      NUMBER CONVERSION TO DECIMAL     29580000
TEMBADD  DS    F                       TTR FROM NOTE MACRO EXECUTION    29600000
DADDSAV  EQU   TEMBADD                 ADDRESS OF DIRECTORY             29620000
SAVE12   DS    12F                     USED TO SORT MEMBERS IN TOTAL RT 29640000
SAVEAREA DS    2F                      REGS 10 AND 2 SAVE AREA FOR      29660000
*                                      UF10 ROUTINE                     29680000
WORKAREA DS    F                       WORK AREA FOR UF10 ROUTINE       29700000
TEMPHW1  DC    H'0'                    LENGTH OF CURRENT LOGICAL RECD.  29720000
PERM13   DC    F'0'                    SAVE AREA FOR REG 13             29740000
RECOUNT  DC    H'0'                    TO COMPUTE LENGTH OF USER FORMAT 29760000
MEMGET   DC    X'00'         SWITCH FOR GET MAIN FOR MEMBERS       4304 29768019
MEMADDR  DC    F'0'          ADDR OF STORAGE FOR GET MAIN          4304 29776019
MEMAREA  DC    F'0'          LENG OF STORAGE FOR MEMBER GET MAIN   4304 29784019
LENGTHSV DC    F'0'          LENGTH OF ALLOCATED CORE              4304 29792019
LENGTHAD DC    F'0'                    POINTER TO ALLOCATED CORE        29800000
STARTIN  DC    F'0'                    POINTS TO INPUT AREA             29820000
BLCKREM  DC    H'0'                    HOLDS REMAINING BLOCK SIZE       29840000
*                                                                       29860000
*          HALF WORD INCREMENT VALUES                                   29880000
*                                                                       29900000
PHZERO   DC    H'0'                    USED TO CLEAR AREAS TO ZEROS     29920000
PH1      DC    H'1'                                                     29940000
PH2      DC    H'2'                                                     29960000
PH4      DC    H'4'                                                     29980000
PH8      DC    H'8'                                                     30000000
PH12     DC    H'12'                                                    30020000
PH14     DC    H'14'                                                    30040000
PH16     DC    H'16'                                                    30060000
*                                                                       30080000
ANDCONST DC    F'31'                   USED TO 'AND' OUT BITS, TOTAL RT 30100000
HOLDRLEN DC    F'0'                    HOLDS LENGTH OF CURRENT RECORD   30140000
PH256    DC    H'256'                  COMPARAND FOR RECORD SIZE        30160000
LASTSW   DC    X'00'                   USED TO INDICATE LAST OF GROUP   30180000
*                                                                       30200000
*          OUTPUT CONSTANTS                                             30220000
*                                                                       30240000
PAGE     DC    C'PAGE'                 USED FOR NUMBERING PAGES         30260000
MBRNAMEA DC    C'MEMBER NAME'          USED FOR PRINTING A PDS          30280000
ALIASA   DC    C'ALIASES'                                               30300000
EOB      EQU   C'*'                                                     30320000
*                                                                       30340000
*          OUTPUT BUFFER FOR SYSUT2                                     30360000
*                                                                       30380000
OUTBUFF  DS    0X                      NAMES BUFFER                     30400000
PPCTL    DC    C' '                    CONTROL CHAR. FOR SPACE/STACKER  30420000
OUTBUFF1 DS    72X                     START OF OUTPUT IMAGE            30440000
PUCD     DS    8X                      SEQUENCE NUMBER                  30460000
         DS    30X                                                      30480000
PRPG     DS    10X                     PAGE NUMBER                      30500000
         DC    24C' '            EXTENDED BUFFER FOR MAX BLOCK   A23836 30510018
ONE45    DC    H'145'            MAXIMUM OUTPUT LRECL WHEN PRINT A52039 30520021
EIGHTY1  DC    H'81'             MAX OUTP. LRECL WHEN PUNCH      A52039 30530021
*                                                                       30540000
*          INPUT DATA SET PARAMETERS                                    30560000
*                                                                       30580000
RECFM    DC    X'0'                    RECORD FORMAT                    30600000
KEYLEN   DC    H'0'                    KEY LENGTH                       30620000
BLKLEN   DC    H'0'                    BLOCK LENGTH                     30640000
LRECL    DC    H'0'                    LOGICAL RECORD LENGTH            30660000
TABLEADD DS    F                       DTABLE BASE ADDRESS         UL0H 30680017
*          TABLE BUILT BY IEBPPAL1                                      30700000
*            CONTAINS SWITCHES AND COUNTERS                             30720000
*              PERTINENT TO USERS REQUEST - INITIALLY                   30740000
*                REFERENCED BY DTABLE DSECT                             30760000
*                                                                       30780000
TABLE    DS    0F                                                       30800000
LITADD   DC    F'0'                    ADDRESS OF LITERAL POOL          30820000
MNTADD   DC    F'0'                    MEMBER NAME TABLE ADDRESS        30840000
TYPORG   DC    X'0'                    0 - PDS, 1 - TOTAL PDS, 3 -      30860000
*                                      NAMED PDS MEMBERS                30880000
TOTCONV  DC    X'0'                    CONVERSION SWITCH -- 0 = NO CONV 30900000
*                                      1 = HEX TO EBCDIC(HE)            30920000
*                                      3 = PACKED TO UNPACKED DEC.(PZ)  30940000
PPSW1    DC    X'00'                   0 - PRINT, 1 - PUNCH,            30960000
*                                      3 - SEQUENCE CARDS, 7 - NOT      30980000
*                                      FIRST TIME                       31000000
CNTRL    DC    X'1'                                                     31020000
INITCDB  DC    F'0'                                                     31040000
CDINCRB  DC    F'10'                    CARD INCREMENT,BINARY           31060000
PGBIN    DC    H'1'                    INITIAL PAGE NUMBER              31080000
PMAXLINE DC    H'60'                   LINES PER PAGE                   31100000
INITSTOP DC    H'0'                    RECORD NUMBER TO STOP AFTER      31120000
INITSKIP DC    H'0'                    RECORD NUMBER TO SKIP(PROCESS)   31140000
STRTAFT  DC    H'0'                    RECORD NBR TO START AT    A45135 31150021
TCB      DS    0F                      TITLE CONTROL BLOCK              31160021
TCB1     DC    H'0'                    LENGTH OF TITLE                  31180000
         DC    H'0'                    RELATIVE LOCATION OF OUTPUT AREA 31200000
*                                      WHERE ON CARD OR PAGE IT APPEARS 31220000
         DC    F'0'                    ADDRESS OF TITLE                 31240000
*                                      SUBTITLE CONTROL BLOCK           31260000
TCB2     DC    H'0'                    LENGTH OF TITLE                  31280000
         DC    H'0'                    RELATIVE OUTPUT LOCATION         31300000
         DC    F'0'                    ADDRESS OF TITLE                 31320000
PREFORMT DC    X'00'                   80 = ASA, 01 = MACHINE CODE      31340000
LPRSW    DC    X'00'                                               UL0H 31345017
PROCKY   DC    X'00'                                               UL0H 31350017
LBLCONSW DC    X'00'                                               UL0H 31355017
TBLEN    EQU   *-TABLE                 GET TABLE LENGTH                 31360000
*          E N D    O F    T A B L E                                    31380000
*                                                                       31400000
*                        COUNTERS FOR HDR & TRLR LABEL PROC        UL0H 31401017
*                                                                  UL0H 31402017
         DS    0D                                                  UL0H 31403017
UTINCT   DC    XL8'0'                                              UL0H 31404017
USERTNCT DC    XL4'0'                                              UL0H 31405017
ULABIN   DC    XL4'0'                                              UL0H 31406017
BYPASSED DC    XL4'0'                                              UL0H 31407017
CONVSAV  DS    XL1                                                 UL0H 31409017
*          SYMBOLIC NAMES OF USERS EXITS                                31420000
*                                                                       31440000
EXLIST   DS    0D                                                       31460000
INHDR    DC    CL8' '                  ROUTINE PROCESSES INPUT HDR LABL 31480000
INTLR    DC    CL8' '                  ROUTINE PROCESSES INPUT TLR LABL 31500000
INREC    DC    CL8' '                  ROUTINE PROCESSES LOGICAL RECORD 31520000
*                                      BEFORE BEING PROCESSED           31540000
OUTREC   DC    CL8' '                  ROUTINE PROCESSES LOGICAL RECORD 31560000
*                                      BEFORE BEING OUTPUTED            31580000
EXLEN    EQU   32                      LENGTH OF EXIT ROUTINE NAMES     31600000
*                                                                       31620000
*          COUNTERS                                                     31640000
*                                                                       31660000
CURSKIP  DC    H'0'                    SKIP RECORD COUNTER              31680000
CURSTRT  DC    H'0'                    NBR. OF REC. ALR. SKIPPED A45135 31690021
CURSTOP  DC    H'0'                    STOP RECORD COUNTER              31700000
LINECT   DC    H'0'                    OUTPUT LINE COUNTER              31720000
LINEINCR DC    H'1'                    LINE INCREMENT - MODIFIED        31740000
CDNOB    DC    F'0'                                                     31760000
PPRETCDE DC    X'0'                    USER RETURN CODE                 31780000
CONVSW   DC    X'01'                   CONVERSION SWITCH -- 1 = HE      31800000
*                                      3 = PZ                           31820000
*                                                                       31840000
*          A S A  CONTROL CHARACTERS FOR                                31860000
*            OUTPUT BUFFER - MUST BE POSITIONED AS IS                   31880000
*                                                                       31900000
         DC    C'0'                    DOUBLE SPACE BEFORE PRINTING     31920000
SPTRIPLE DC    C'-'                    TRIPLE SPACE BEFORE PRINTING     31940000
         DC    C'V'                    SELECT PUNCH POCKET 1            31960000
STACK2   DC    C'W'                    SELECT PUNCH POCKET 2            31980000
*                                                                       32000000
*          SKIP OR STOP SWITCH                                          32020000
*                                                                       32040000
SKIP     EQU   X'01'                                                    32060000
STOP     EQU   X'02'                                                    32080000
INSW     DC    X'0'                    1 - SKIP, 2 - STOP               32100000
*                                                                       32120000
INBUFF   DS    F                       ADDRESS OF INPUT BUFFER          32140000
DIRBUFF  EQU   INBUFF                  DIRECTORY INPUT AREA             32160000
SAVEADD  DS    18F                     MODULE SAVE AREA                 32180000
MEMBCT   DC    H'0'                    PDS MEMBER COUNT                 32200000
GRCT     DC    H'0'                    RECORD GROUP COUNT               32220000
ALIASCT  DC    H'0'                    NO. OF ALIASES FOR CURRENT MEMB. 32240000
*                                                                       32260000
GCBL     EQU   8                       LENGTH OF GROUP CONTROL BLOCK    32280000
GCBIDLEN EQU   2                                                        32300000
GCBIDLIT EQU   4                                                        32320000
GCBIDLOC EQU   6                                                        32340000
FCBLEN   EQU   PH8                     LENGTH OF FIELD CONTROL BLOCK    32360000
GCBLEN   EQU   PH8                     LENGTH OF GROUP CONTROL BLOCK    32380000
TCBL     EQU   8                       LENGTH OF TITLE CONTROL BLOCK    32400000
LISTLEN  EQU   PH12                    LENGTH OF EACH ENTRY IN DIRBUFF  32420000
LISTL    EQU   12                                                       32440000
ABITL    EQU   11                      LOCATION OF ALIAS BIT            32460000
DIRBLKL  EQU   264                                                      32480000
*                                                                       32500000
OUTBADD  DC    A(OUTBUFF1)             ADDRESS OF OUTPUT BUFFER         32520000
DIRADD   DS    A                       PTR TO ANY MEMBER NAMES          32540000
DTABPTR  DC    F'0'                    PTR TO DTABLE                    32560000
VZZPR    DC    V(ZZPR)                       ADDR OF MSG RTN       7715 32566019
MSGSYNDF DC    CL96'IEB421I I/O ERROR'       SYNAD I/O ERROR MSG   7715 32572019
*                                                                       32580000
*          BLDL LIST                                                    32600000
*                                                                       32620000
BLDLADD  DS    0F                      AREA USED FOR BLDL MACRO         32640000
         DC    H'01'                   NUMBER OF ENTRIES IN LIST        32660000
         DC    H'76'                   LENGTH OF ENTRY IN LIST          32680000
BLDENTRY DS    8X                      NAME OF MEMBER TO FIND           32700000
BLDTTR   DS    4X                      RELATIVE TRACK ADDRESS-RETURNED  32720000
         DS    1X                      FILLER BYTE - NOT USED           32740000
BLDC     DS    1X                      DESCRIBES USER DATA FIELD-RETURN 32760000
BLDUSER  DS    62X                     USER DATA IN DIRECTORY-RETURNED  32780000
*                                      MAXIMUM USER DATA SIZE - 62 BYTE 32800000
*                                      MAXIMUM DIRECTORY ENTRY-74 BYTES 32820000
*                                      MINIMUM DIRECTORY ENTRY-12 BYTES 32840000
*                                                                       32860000
PLEN     DC    H'0'                    REMAINING BYTES IN BLOCKED RECD  32880000
RECDLEN  DC    H'0'                    LENGTH OF CURRENT LOGICAL RECORD 32900000
RECDLOC  DC    F'0'                    LOCATION OF CURRENT LOGICAL RECD 32920000
FSLOC    DS    F'0'                    POINTER TO CURRENT INPUT RECORD  32940000
FSLEN    DS    H'0'                    REMAINING BYTES OF INPUT RECORD  32960000
*                                                                       32980000
*          STORAGE USED IN FLDCONV ROUTINE                              33000000
*                                                                       33020000
OUTSAV   DS    F                       OUTPUT LOCATION OF CURRENT FIELD 33040000
LOCSAV   DS    F                       INPUT LOCATION OF CURRENT FIELD  33060000
LENSAV   DS    H                       NUMBER OF BYTES TO CONVERT       33080000
MAXOUT   DC    H'120'                  MAXIMUM BYTES PER OUTPUT LINE    33100000
*                                                                       33120000
*          REGISTER EQUATES                                             33140000
*                                                                       33160000
R15      EQU   15                      USED TO TEST RETURN CODES        33180000
TEMP2    EQU   15                      TEMPORARY WORK REIGSTER          33200000
R14      EQU   14                      USED IN CONVERSION ROUTINE       33220000
TEMP1    EQU   14                      TEMPORARY WORK REGISTER          33240000
SKIPR    EQU   14                      RECORD SKIP COUNTER              33260000
R13      EQU   13                      PTR TO SAVE AREA                 33280000
R12      EQU   12                                                       33300000
MCBR     EQU   12                      PTR TO MEMBER NAME TABLE         33320000
R11      EQU   11                                                       33340000
BREG1    EQU   11                      RETURN REG FOR HANDLING TITLES   33360000
CTLREG   EQU   11                      POINTER TO OUTPUT CONTROL CHAR.  33380000
INLEN    EQU   11                      CONTAINS INPUT FIELD SIZE        33400000
R10      EQU   10                      WORK REG FOR UF10 ROUTINE        33420000
BASER2   EQU   10                      MODULE EXTRA BASE REGISTER       33440000
BASER    EQU   9                       MODULE BASE REGISTER             33460000
R8       EQU   8                                                        33480000
GCBR     EQU   8                       POINTER TO GROUP CONTROL BLOCK   33500000
CTR      EQU   8                       COUNTER FOR DIRECTORY ENTRIES    33520000
R7       EQU   7                       USED IN PREFORM ROUTINE          33540000
LISTR    EQU   7                       POINTS TO MEMBER NAMES           33560000
RLOC     EQU   7                       POINTS TO INPUT AREA             33580000
R6       EQU   6                       WORK REG IN PREFORM ROUTINE      33600000
BREG     EQU   6                       INTERNAL BAL RETURN REGISTER     33620000
HDRET    EQU   6                       INTERNAL BAL RETURN REGISTER     33640000
R5       EQU   5                       WORK REG IN PREFORM ROUTINE      33660000
MEMCT    EQU   5                       MEMBER COUNTER                   33680000
TCBR     EQU   5                       POINTS TO A TITLE CONTROL BLOCK  33700000
DCBREG   EQU   5                       POINTS TO A DCB                  33720000
ALIASR   EQU   5                       NUMBER OF ALIASES FOR THIS MEMB. 33740000
FCBR     EQU   5                       PTR TO FIELD CONTROL BLOCK       33760000
R4       EQU   4                       WORK REG IN PREFORM ROUTINE      33780000
LEN      EQU   4                       LENGTH OF TITLE                  33800000
RLEN     EQU   4                       INPUT BLOCK LENGTH               33820000
R3       EQU   3                       USED IN PREFORM ROUTINE          33840000
FLDCT    EQU   3                       NUMBER OF FIELDS                 33860000
RLIT     EQU   3                       ADDRESS OF LITERAL POOL          33880000
LISTCT   EQU   3                       MEMBER SORT COUNTER              33900000
R2       EQU   2                       WORK REG FOR PREFORM ROUTINE     33920000
ROUT     EQU   2                       POINTS TO OUTPUT AREA            33940000
OUTLOC   EQU   2                       POINTS TO OUTPUT AREA            33960000
R1       EQU   1                       WORK REGISTER                    33980000
R0       EQU   0                       WORK REGISTER                    34000000
*                                                                       34020000
*          CODES FOR MESSAGE WRITER                                     34040000
*                                                                       34060000
BLKSZMIS EQU   6                                                        34080000
EODMSG   EQU   11                                                       34100000
EOJUSM   EQU   12                                                       34120000
IOMSG    EQU   13                                                       34140000
IDMSG    EQU   14                                                       34160000
STPMSG   EQU   15                                                       34180000
*                                                                       34200000
PMSGWRTA DC    V(PPMSGWRT)                                              34220000
MNMSGA   DC    V(PPMNMSG)                                               34240000
DDSWITCH DC    X'00'                   ERROR FREEMAIN SWITCH            34260000
         EXTRN DDERROR1                                                 34280000
VMSG     DC    A(DDERROR1)             ADDRESS OF MESSAGE IN IEBPPMSG - 34300000
*                                      'DDNAME --- CANNOT BE OPENED'    34320000
         EXTRN RCERROR                                             UL0H 34326017
RCMSG    DC    A(RCERROR)                                          UL0H 34332017
         EJECT                                                          34340000
         EJECT                                                          34620000
*                                                                       34640000
*          INPUT DCB EXIT -                                             34660000
*            ENTERED AT OPEN TIME AFTER                                 34680000
*              THE JFCB HAS BEEN USED TO SUPPLY                         34700000
*                INFORMATION TO THE DCB                                 34720000
*                                                                       34740000
         USING IHADCB,DCBREG                                            34760000
DCBIN    ST    14,SYSSAVE               SAVE CTL PGM RETURN ADR    VS0H 34768017
         LA    DCBREG,INSET             LOAD BASE REG WITH DCBADR  VS0H 34776017
         TM    DCBRECFM,X'C0'     RECFM NOT U OR NOT DEF. ?      A48796 34778021
         BM    TSTRECF1           YES, SKIP DEF. ROUTINE         A48796 34780021
         OI    DCBRECFM,X'C0'     SET RECFM = U                  A48796 34782021
SETLDEF  MVC   DCBLRECL(2),DCBBLKSI SET LRECL = BLKSI            A48796 34782421
         B     TSTBLK1            BRANCH TO BLKSIZE TEST         A48796 34782821
TSTRECF1 TM    DCBRECFM,X'10'     BLOCKED RECORDS ?              A48796 34783221
         BO    TSTBLK1            YES, TEST BLKSI                A48796 34783621
         TM    DCBRECFM,X'80'     RECFM IS F                     A48796 34783721
         BO    SETLDEF            YES, SET LRECL = BLKSI         A48796 34783821
TSTBLK1  CLC   DCBBLKSI(2),=X'0000' BLKSI PRESENT ?              A48796 34783921
         BNE   TSTLREC1           YES, TEST LRECL PRESENCE       A48796 34788421
         OI    DCBBLKSI+1,X'0A'   SET BLKSI = 10                 A48796 34790421
SETDEF1  MVC   DCBLRECL(2),=X'0005' SET DEFAULT LRECL = 5        A48796 34792421
         OI    ERRDCB,X'80'       SET ERRBIT (MSG IEB412I )      A48796 34792821
         B     DCBINTST           TEST REST OF DCB VALUES        A48796 34792921
TSTLREC1 CLC   DCBLRECL(2),=X'0000' LRECL PRESENT ?              A48796 34798321
         BE    SETDEF1            NO, SET DEF. + ERR BIT         A48796 34800321
DCBINTST TM    DCBRECFM,X'48'          IS IT VRE                   VS0H 34803821
         BO    TSTDSORG                 RECFM  IS VARIABLE         VS0H 34809221
NOQSAM   MVC   KEYLEN+1(1),DCBKEYLE    SAVE KEY LENGTH FROM DCB    VS0H 34814621
         MVC   RECFM(1),DCBRECFM       SAVE RECORD FROMAT FROM DCB      34820000
         MVC   LRECL(2),DCBLRECL       SAVE LOGICAL RECORD LENGTH       34840000
         MVC   BLKLEN(2),DCBBLKSI      SAVE BLOCK SIZE                  34860000
         MVI   QSBRNOP+1,X'00'                                     VS0H 34870017
DCBDIR   TM    POSTOPEN+1,X'F0'         IS DIRECTPRY BEING READ    VS0H 34880017
         BZ    DCBRET                  YES -- RETURN TO CONTROL PROGRAM 34900000
         MVI   DCBKEYLE,X'00'          NO - ALTER DCB TO READ DIRECTORY 34920000
         MVI   DCBRECFM,X'81'                                           34940000
         LH    R1,PH256                LOAD 256 INTO REG 1              34960000
         STH   R1,DCBBLKSI             STORE SIZE OF DIRECT. IN BLKSIZE 34980000
*                                      RETURN TO CONTROL PROGRAM        35000000
         STH   R1,DCBLRECL         STORE IN LRECL FIELD          A48732 35005021
VRERET   L     R14,SYSSAVE                                         VS0H 35010017
DCBRET   RETURN                                                         35020000
TSTDSORG TM    TYPORG,3                                            VS0H 35020217
         BZ    TSTRECL                 NOT PDS                     VS0H 35020417
VREERR   MVC   MSGWS(4),VMSG18         ERROR- PDS SPECIFIED FOR VS 9059 35020719
         B     VRENG                                               VS0H 35021017
TSTRECL  MVI   QSBRNOP+1,X'F0'                                     VS0H 35021217
         MVI   RECFM,X'40'              SET REFCM=V IN WORK AREA   VS0H 35021417
         MVC   LRECL(2),DCBLRECL     SAV LRECL VAL.              A48796 35021621
         MVC   BLKLEN(2),DCBLRECL    SAVE BLKSI VAL.             A48796 35021821
         MVC   KEYLEN+1(1),DCBKEYLE                                VS0H 35022017
         B     PTCHONE                                             VS0H 35022317
VRQSAM   MVC   DCBMACRF(2),QSREOPMR  CHNG RECF FROM BSAM TO QSAM A48796 35022421
         B     VRERET             RETURN TO OPEN                 A48796 35022821
TSTPREFM TM    PREFORMT,X'81'                                      VS0H 35023621
         BM    VREPRFER                                            VS0H 35024021
VSKEYS   MVI   RECFM,X'C0'             SET RECFM=U IN WORK AREA    VS0H 35024421
         MVC   LRECL(2),DCBBLKSI  SAVE BLKSI VAL.                A48796 35024821
         MVC   BLKLEN(2),DCBBLKSI                                  VS0H 35025221
PHYSMSG  MVC   MSGWS(4),VMSG15         INFO- BLOCK PROCESSING      9059 35025621
         B     VRERET                                              VS0H 35026021
VREPRFER MVC   MSGWS(4),VMSG16         ERROR- PREFORM = A INVALID  9059 35026421
         B     VRENG                                               VS0H 35026821
CCTOLSTC MVC   LASTCCH,0(R1)            MOVE CC TO LASTCC          VS0H 35027221
         ST    R1,STARTIN                                          UL0H 35027621
         TM    PPSW1,1                                             VS0H 35028021
         BO    STCCTOIN                 STORE CC TO INTERCC        VS0H 35028421
         TM    PREFORMT,X'01'                                      VS0H 35028821
         BO    STPRSK                                              VS0H 35029221
         MVC   INTERCCH,=C' '                                      VS0H 35029621
         MVC   LASTCCH,=C' '                                       VS0H 35030021
PREVREWR EX    R12,MOVE                                            VS0H 35030421
         BAL   BREG,WRCH                                           VS0H 35030821
         LH    R6,PH1                                              VS0H 35031221
         SR    R12,R6                                              VS0H 35031621
         L     R2,STARTIN                                          VS0H 35032021
         AR    R2,R6                                               VS0H 35032421
         ST    R2,STARTIN                                          VS0H 35032821
NEXTPART LH    R6,SAVLRECL                                         VS0H 35033221
         CR    R12,R6                  COMPARE MAXOUT AND REST     0294 35033621
         BNL   FIX                     BRANCH IF MAXOUT NOT LESS   0506 35034021
         SR    R6,R12                  ELSE SUBTRACT ONE OUT REC   0294 35034421
FIX      SH    R6,PH1                  DECREMENT BY ONE            0506 35034821
         STH   R6,SAVLRECL             STORE REMAIDER OF IN.LRECL  VS0H 35035221
         L     R2,STARTIN              LOAD CURRENT POINTER        VS0H 35035621
         AR    R2,R12                  INCR. POINTER BY LINELENGTH VS0H 35036021
         AH    R2,PH1                                              VS0H 35036421
         ST    R2,STARTIN              STORE NEW POINTER           VS0H 35036821
         AH    R12,PH1       ADD ONE FOR TEST PURP.              A45135 35037221
         CR    R12,R6        COMP LINEL. AND REM INLRECL         A45135 35037621
         BNL   LASTOFRL      LINE LENGTH NOT LOW --BRANCH        A45135 35038021
         SH    R12,PH1       RESET R12 ON CORRECT VALUE          A45135 35038421
         MVC   PPCTL,INTERCCH          MOVE INTERM. CC TO OUTPUT   VS0H 35038821
         EX    R12,MOVEPART            MOVE DATA (OUTP.LNGTH-1)    VS0H 35039221
         BAL   BREG,WRCH               WRITE NEXT PART             VS0H 35039621
         B     NEXTPART                GET NEXT PART OF RECORD     VS0H 35040021
LASTOFRL BAL   BREG,BLANKOUT BLANK OUTPUT AREA                     VSOH 35040421
         MVC   PPCTL,LASTCCH MOVE STORED CC TO LAST OUT            VSOH 35040821
         LH    R12,SAVLRECL  MOVE LAST OF LOG. RECORD              VSOH 35041221
         CH    R12,PH2       WHEN SAVLRECL 1 OR LESS THAN        A38702 35041621
         BL    SKIPPUT       NO DATA HAS TO BE MOVED             A38702 35042021
         SH    R12,PH2       TWO SUBTR(1 FOR MVC,1 FOR ASA OR MC)  VSOH 35042421
         EX    R12,MOVEPART  MOVE IN OUTPUT BUFFER                 VSOH 35042821
         BAL   BREG,WRCH     PUT THE RECORD                        VSOH 35043221
SKIPPUT  TM    VSWITCH+1,X'F0' TEST VAR. SWITCH                  A38702 35043621
         BO    BIGONCE                                             VS0H 35044421
         TM    BLKDSWCH+1,X'F0'                                    VS0H 35044821
         BO    BIGONCE                                             VS0H 35045221
         B     RDCH                                                VS0H 35045621
STCCTOIN MVC   INTERCCH,0(R1)                                      VS0H 35046021
         B     PREVREWR                                            VS0H 35046421
STPRSK   MVC   INTERCCH,=X'09'                                     VS0H 35046821
         MVC   0(1,R1),=X'09'                                      VS0H 35047221
         B     PREVREWR                                            VS0H 35047621
SETBLKSW MVI   BLKDSWCH+1,X'F0'                                    VSOH 35048021
         B     BLKDLONG                                            VSOH 35048421
SETVSW   SR    R12,R5        RESET 12 TO LINE LENGTH               VSOH 35048821
         SH    R12,PH1                                           A38702 35049221
         SR    R1,R3                   DECR.REMAINING BLOCKLNGTH   VS0H 35049621
         STH   R1,BLCKREM    WITH CURRENT RECORD LENGTH          A38702 35050021
         SH    R3,PH4                  ADJUST RECD LNGTH FOR RDW   VS0H 35050421
         STH   R3,SAVLRECL             TO GET THE DATA LENGTH      VS0H 35050821
         L     R1,STARTIN                 SET POINTER TO           VS0H 35051221
         AH    R1,PH4                  TO FIRST DATA BYTE          VS0H 35051621
         ST    R1,STARTIN                                          VS0H 35052021
         MVI   VSWITCH+1,X'F0'                                     VS0H 35052421
         B     CCTOLSTC                                            VS0H 35052821
QSREOPMR DC    X'5000'                                             VS0H 35053221
         DS    0F                                                  VS0H 35053621
SYSSAVE  DS    CL4                                                 VS0H 35054021
VRENG    MVI   PPHINEX,X'80'                                       VS0H 35054421
         MVI  PPTINEX,X'80'                                        VS0H 35054821
         MVI   DDDEX,X'80'    LABEL CHANGED BEC. OF AOS DSCB            35055221
         MVI   DCBEXSW,X'80'                                       VS0H 35055621
         B     VRERET                                              VS0H 35056021
OPENMSG  SR    R0,R0                                               VS0H 35056421
         SR    R1,R1                   CLEAR OUT MSG REGS          VS0H 35056821
         IC    R0,MSGWS                                            VS0H 35057221
         IC    R1,MSGWS+1                                          VS0H 35057621
         CLI   MSGWS+2,X'00'                                       VS0H 35058021
         BE    MSGONLY                                             VS0H 35058421
         MVI   DDSWITCH,X'01'                                      VS0H 35058821
         B     IOWRT                                               VS0H 35059221
         EJECT                                                          35059621
         EJECT                                                          35120000
*          O U T P U T    D C B                                         35140000
* REF A.LYONS TO MR. CAMMACK E.T. ( 1 MARCH 1971 )                      35150021
*  SUBJECT: DESIGN PROBLEMS WITH RELEASE 20 AND TSO                     35152021
OUTSET   DCB   DDNAME=SYSUT2,DSORG=PS,MACRF=(PM),RECFM=FBA,            C35154021
               SYNAD=SYNADMSG,EXLST=PPEXOUT                        7715 35160019
PPIHLEX  MVI   HDTRLSW,X'F0'           SET HEADER IND.             UL0H 35173017
         CLC   USEREX+1(3),UHIN+1      CURRENT EXIT IS HEADER      UL0H 35176017
         BE    PPILEX                                              UL0H 35180217
         MVC   USEREX(4),UHIN                                      UL0H 35180317
         CLI   PROCKY,X'40'                                        UL0H 35180417
         BE    PRNTSWOF                                            UL0H 35180517
         B     PPILEX                                              UL0H 35180617
PPITLEX  MVI   HDTRLSW,X'0F'           SET TRAILER IND.            UL0H 35180717
         CLC   USEREX+1(3),UTIN+1      CIRRENT EXIT IS TRAILER EXITUL0H 35180817
         BNE   RESTLPTR                                            UL0H 35180917
         B     PPILEX                                              UL0H 35181217
PRNTSWOF MVZ   ULEXSW+1(1),=X'F0'            "          OFF-BR     UL0H 35181617
PPILEX   LH    R15,PH4                                             UL0H 35181717
         ST    R14,SYSSAVE                                         UL0H 35181817
PPILEXA  LA    R6,LABELAST                                         UL0H 35181917
         CL    R6,LBLSVPTR                                         UL0H 35182017
         BL    SETBYPSS                TOO MANY LABELS, BYPASS     UL0H 35182117
         B     TSTPBIT                 TEST FOR VOL1,EOV,IOERR     UL0H 35182217
NOLBLTST L     R7,0(R1)                                            UL0H 35182417
         LTR   R7,R7                                               UL0H 35182517
         BZ    SETNORC                                             UL0H 35182617
         L     R6,ULABIN                                           UL0H 35182717
         AH    R6,PH1                                              UL0H 35182817
         ST    R6,ULABIN                                           UL0H 35182917
         CLI   BYPLASW,X'F0'                                       UL0H 35183017
         BE    ADDBYPSD                                            UL0H 35183117
STORELBL L     R6,LBLSVPTR                                         UL0H 35183217
         MVC   0(80,R6),0(R7)           STORE LABEL                UL0H 35183317
         AH    R6,LABLINC               ADD 80 POSNS TO LBLSVPTR   UL0H 35183417
         ST    R6,LBLSVPTR                                         UL0H 35183517
TSTULSW  TM    USEREX,X'FF'                                        UL0H 35183617
         BZ    GOTOSYST                                            UL0H 35183717
         L     R5,USERTNCT                                         UL0H 35183817
         AH    R5,PH1                                              UL0H 35183917
         ST    R5,USERTNCT                                         UL0H 35184017
         L     R15,USEREX                                          UL0H 35184117
         BALR  R14,R15                                             UL0H 35184217
         B     TSTUSRC                                             UL0H 35184317
SETNORC  MVZ   NORCSW+1(1),=X'F0'                                  UL0H 35184417
         B     TSTULSW                                             UL0H 35184517
GOTOSYST L     R14,SYSSAVE             RETURN CONTROL TO SYSTEM    UL0H 35184717
         BR    R14                                                 UL0H 35184817
SETIOERR MVI   IOSW+1,X'F0'                                        UL0H 35185517
         B     NOLBLTST                                            UL0H 35185617
TSTUSRC  CH    R15,=X'0010'             TEST USER RC=16            UL0H 35185717
         BE    SETUSTRM                                            UL0H 35185817
         CH    R15,=X'0000'                                        UL0H 35185917
         BE    SETULPSF                                            UL0H 35186017
         CH    R15,=X'0004'                                        UL0H 35186117
         BE    GOTOSYST                                            UL0H 35186217
         TM    NORCSW+1,X'F0'                                      UL0H 35186317
         BO    GOTOSYST                NO RET. CODE EXPECTED       UL0H 35186417
         B     USERCERR                                            UL0H 35186517
SETUSTRM MVI   USEREX,X'00'             SET ULBLPROCSW OFF         UL0H 35186617
         MVZ   USRTRMSW,=X'F0'          SET TERMSW ON              UL0H 35186717
         B     GOTOSYST                                            UL0H 35186817
ADDBYPSD L     R5,BYPASSED                                         UL0H 35186917
         AH    R5,PH1                                              UL0H 35187017
         ST    R5,BYPASSED                                         UL0H 35187117
         B     GOTOSYST                                            UL0H 35187217
SETULPSF MVI   USEREX,X'00'             SET USER LBL PROC OFF      UL0H 35187317
         CLI   PROCKY,X'80'                                        UL0H 35187417
         BE    SETBYPSS                                            UL0H 35187517
         B     GOTOSYST                                            UL0H 35187617
SETBYPSS MVI   BYPLASW,X'F0'                                       UL0H 35187717
         B     GOTOSYST                                            UL0H 35187817
USERCERR L     R5,RCMSG                                            UL0H 35187917
         AH    R15,NUMZON              ADD HEX F0 FOR DISPLAY      UL0H 35188017
         STC   R15,19(R5)                                          UL0H 35188117
         SH    R15,NUMZON              REMOVE ZONE FOR PROCESSING  UL0H 35188217
         MVC   MSGWS,=X'151D0C00'                                  UL0H 35188317
         B     SETUSTRM                                            UL0H 35188417
CONVLBLS L     RLOC,LBLSVPTR                                       UL0H 35188817
         LA    INLEN,40                                            UL0H 35188917
         MVC   CONVSAV,CONVSW                                      UL0H 35189017
         MVC   CONVSW,LBLCONSW                                     UL0H 35189117
         BAL   BREG,FLDCONVL                                       UL0H 35189217
         BAL   BREG,WRCH                                           UL0H 35189317
         L     R5,LBLSVPTR                                         UL0H 35189417
         AH    R5,=X'0028'                                         UL0H 35189517
         ST    R5,LBLSVPTR                                         UL0H 35189617
         C     R5,PRNTLIM                                          UL0H 35189717
         BE    RELCONV                 RESTORE CONVSW FOR DATA     UL0H 35189817
         B     CONVLBLS                                            UL0H 35189917
         DS    0F                                                  UL0H 35190017
LABLINC  DC    X'0050'                                             UL0H 35190117
USRTRMSW DC    X'00'                                               UL0H 35190217
         DS    0D                                                  UL0H 35190317
LBELSAVE DS    0CL640                                              UL0H 35190417
LABEL1   DS    CL80                                                UL0H 35190517
LABELINT DS    CL480                                               UL0H 35190617
LABELAST DS    CL80                                                UL0H 35190717
LBLSVPTR DC    A(LBELSAVE)                                         UL0H 35190817
PRNTLIM  DC    X'00000000'                                         UL0H 35190917
BYPLASW  DC    X'00'                                               UL0H 35193317
ERRDCB   DC    X'00'         OPEN ERROR BIT                      A45135 35193721
         DS    0H                                                  UL0H 35194017
NUMZON   DC    X'00F0'                                             UL0H 35194717
BSAMSPEC DC    X'2400'                                             VS0H 35195417
HDTRLSW  DC    X'00'                                               UL0H 35196417
PAGEBYT  DC    X'00'         ZERO WHEN NO PAGE NBR TO BE WRITTEN A45134 35196521
VMSG15   DC    XL4'0F1A0000'           INFO MSG IEB415I            9059 35196619
VMSG16   DC    XL4'101B0C00'           ERROR MSG IEB416I           9059 35196819
VMSG18   DC    XL4'121C0C00'           ERROR MSG  IEB418I          9059 35197019
TEMPSAVE DC    F'0'                    SAVE BRANCH REGISTER        9305 35197219
NOPLBLPR B     CLOSEOUT                                            UL0H 35197417
VSWITCH  DC    XL2'0'                                              VS0H 35198217
BLKDSWCH DC    XL2'0'                                              VS0H 35198417
ULEXSW   DC    XL2'0'                                              UL0H 35198617
IOSW     DC    XL2'0'                                              UL0H 35198817
QSSW     DC    XL2'0'                                              VS0H 35199017
QSBRNOP  DC    XL2'0'                                              VS0H 35199217
NORCSW   DC    XL2'0'                                              UL0H 35199417
MCBRWS   DC    F'0'                                                VS0H 35199617
MSGWS    DC    XL4'0'                                              VS0H 35199817
         EJECT                                                          35200000
*                                                                       35220000
*          DUMMY DCB DSECT                                              35240000
*                                                                       35260000
         DCBD  DSORG=PO                                                 35280000
         EJECT                                                          35300000
*                                                                       35320000
*          GET DISPLACEMENT OF DCB AREAS                                35340000
*                                                                       35360000
DDNAM    EQU   DCBDDNAM-IHADCB         DDNAME FOR DCB                   35380000
BLKSI    EQU   DCBBLKSI-IHADCB         BLOCK SIZE OF DATA               35400000
DSORG    EQU   DCBDSORG-IHADCB         DATA SET ORGANIZATION            35420000
RECL     EQU   DCBLRECL-IHADCB         LOGICAL RECORD LENGTH OF DATA    35440000
OFLGS    EQU   DCBOFLGS-IHADCB         OPEN FLAGS                       35460000
DEVT     EQU   DCBDEVT-IHADCB          DEVICE TYPE                      35480000
RECINFM  EQU   DCBRECFM-IHADCB         RECORD FORM                 VS0H 35484017
BSAMACRF EQU   DCBMACR-IHADCB                                      VS0H 35488017
*                                      BE ALTERED TO QSAM          VS0H 35492017
*                                      FOR VRE RECORDS             VS0H 35496017
*                                                                       35500000
*          DTABLE DSECT                                                 35520000
*                                                                       35540000
DTABLE   DSECT                                                          35560000
DDN1     DS    CL8                     SYSUT1 DDNAME - INPUT            35580000
DDN2     DS    CL8                     SYSUT2 DDNAME - OUTPUT           35600000
DEXLSTA  DS    A                       ADDRESS OF EXIT LIST             35620000
DTBLE    DS    0X                      BEGINING OF 'TABLE' AREA         35640000
DLITA    DS    A                       ADDRESS OF USER LITERAL POOL     35660000
DMNTA    DS    A                       MEMBER NAME TABLE ADDRESS        35680000
DRCB     DS    0X                      16 BYTES OF SWITCHES DESCRIBED   35700000
         DS    20X                                                      35720000
DTCB     DS    0X                      TITLE CONTROL BLOCKS FOR TITLE   35740000
         DS    16X                     AND SUBTITLE DESCRIBED AT TCB    35760000
*                                                                       35780000
IEBPPCH1 CSECT                                                          38780017
TSTPBIT  TM    8(R1),X'80'                                         UL0H 38880017
         BO    SETIOERR                                            UL0H 38980017
         CLI   HDTRLSW,X'0F'           TRAILER IND.                UL0H 39010017
         BE    TSTPBIT1                 YES - BRANCH               UL0H 39040017
         TM    OPENSW,X'10'            IS THIS VOL 1 HDR LABEL     UL0H 39080017
         BO    NOLBLTST                YES,RETURN TO UL PROCESS    UL0H 39180017
         B     TSTULSW                 DO NOT STORE LABEL          UL0H 39240017
TSTPBIT1 TM    4(R1),X'80'             INTERMEDIATE TRAILER        UL0H 39300017
         BO   NOLBLTST                 NO, EOF REACH.,STORE LAB. A45135 39390021
         B     TSTULSW                 DO NOT STORE THE LABEL      UL0H 39480017
LASTCCH  DS    CL1                                                 VS0H 39780017
INTERCCH DS    CL1                                                 VS0H 40780017
MSGONLY  SLL   R1,8                                                VS0H 41780017
         AR    R1,R0                                               VS0H 44780017
         MVI   PPRETCDE,X'00'                                      VS0H 47780017
         L     R15,PMSGWRTA                                        VS0H 50780017
         LA    R14,POSTMSG                                         VS0H 53780017
         BR    R15                                                 VS0H 56780017
RESTLPTR MVC   LBLSVPTR,LABEL1AD                                   UL0H 59780017
         MVC   USEREX(4),UTIN                                      UL0H 62780017
         CLI   PROCKY,X'10'                                        UL0H 65780017
         BE    PRNTSWOF                                            UL0H 68780017
         B     PPILEX                                              UL0H 71780017
ONLYIHL  MVI   DDSWITCH,X'01'                                      UL0H 74780017
         MVC   INTLRPRT,NOPLBLPR                                   UL0H 77780017
         B     CLOSEIO                                             UL0H 80780017
PPEXOUT  DS    0F                      OUTPUT DCB EXIT             VS0H 80980017
DCBOUT   DC    X'85'                   WHEN SYSUT2 NOT = SYSPRINT  VS0H 81180017
         DC    AL3(SETOPBLK)                                       VS0H 81380017
         USING IHADCB,DCBREG                                       VS0H 81580017
SETOPBLK ST    R14,SYSSAVE                                         VS0H 81780017
         LA    DCBREG,OUTSET                                       VS0H 81980017
         CLC   DCBLRECL,=X'0000'  IS LRECL EQ ZERO ?             A38762 82180021
         BE    TESTBLK       YES,                                A38762 82230021
         CLC   DCBBLKSI,=X'0000'  IS BLKSI EQ ZERO ?             A38762 82280021
         BE    FILLREC            YES, TAKE LRECL AS BLKSI       A38762 82330021
         ST    DCBREG,DCBSAVE                                    A38762 82380021
         SR    R4,R4                   TEST                      A38762 82430021
         LH    R6,DCBLRECL             BLKSIZE                   A38762 82440021
         LH    R5,DCBBLKSI             MULTIPLE                  A38762 82450021
         DR    R4,R6                   OF                        A38762 82460021
         LTR   R4,R4                   LRECL                     A38762 82510021
         L     DCBREG,DCBSAVE          RELOAD DCB ADDRESS        A45135 82530021
         BZ    OUTBLKOK                YES, RETURN               A45135 82532021
         MVC   DCBBLKSI(2),DCBLRECL    MOVE LRECL IN BLKSI FLD   A38762 82540021
         B     OUTBLKOK                RETURN                    A38762 82590021
TESTBLK  CLC   DCBBLKSI,=X'0000'       IS BLKSI EQ ZERO ?        A38762 82600021
         BE    TESTPRPU                YES, TEST PRINT OR PUNCH  A38762 82610021
         MVC   DCBLRECL(2),DCBBLKSI    ELSE MOVE BLK IN LR FLD   A38762 82620021
         B     OUTBLKOK                RETURN                    A38762 82670021
FILLREC     MVC DCBBLKSI(2),DCBLRECL   MOVE LRECL IN BLKSI FLD   A38762 82680021
         B     OUTBLKOK                RETURN                    A38762 82690021
TESTPRPU TM    PPSW1,1                 PRINT COMMAND ?           A38762 82700021
         BZ    PRINTR                  YES                       A38762 82750021
         MVC   DCBBLKSI(2),EIGHTY1     SET DEF VALUE OF 81       A52039 82760021
         MVC   DCBLRECL(2),EIGHTY1     SET DEF VALUE OF 81       A52039 82770021
         B     OUTBLKOK           RETURN                         A38762 82772021
PRINTR   MVC   DCBBLKSI,=X'0079'  TAKE BLKSI = 121               A38762 82774021
         MVC   DCBLRECL,=X'0079'  TAKE LRECL = 121               A38762 82776021
OUTBLKOK L     R14,SYSSAVE                                         VS0H 82780017
         CLC   DCBLRECL(2),ONE45       LRECL PARAM GR THAN 145?  A52039 82790021
         BH    ERROUT                  YES, SET ERROR BIT        A45135 82800021
         CLC   DCBLRECL(2),EIGHTY1     IS LRECL LARGER THAN 81 ? A52039 82830021
         BCR   11,R14                  YES, RETURN TO OPEN       A45135 82880021
         CLI   PPSW1,X'03'             SHOULD CARDS BE SEQ ?     A45135 82930021
         BE    TESTPRPU                YES, SET DEF.: LR=BLK=81  A45135 82940021
         CLC   DCBLRECL(2),PH1         LRECL EQUAL 1 ?           A52039 82950021
         BE    ERROUT                  YES,ERR. NO PR OR PU POSS.A45135 82960021
         CLC   DCBLRECL(2),=H'11'      LRECL LESS THAN 11  ?     A45134 82970021
         BNL   *+8                     NO, SKIP PAGE BYTE        A45134 82972021
         MVI   PAGEBYT,X'F0'           YES, SET PAGE BYTE        A45134 82974021
         BR    R14                                                 VS0H 82980017
ERROUT   OI    ERRDCB,X'80'            SET LRECL PARAM ERROR BIT A45135 83030021
         BR    14                      RETURN TO OPEN            A45135 83080021
RELCONV  MVC   CONVSW,CONVSAV                                      UL0H 83180017
         B     LBLPRNTX                                            UL0H 83187017
         USING IHADCB,R8                                           VS0H 83190017
BLKDLONG LH    R4,DCBLRECL                                         VS0H 83194017
         L     R1,STARTIN                                          VS0H 83201017
PREVRBA2 STH   R4,SAVLRECL                                         VS0H 83210017
         CLI   QSBRNOP+1,X'F0'         IS IT QSAM ACCESS           VS0H 83240017
         BNE   CCTOLSTC                                            VS0H 83270017
         AH    R1,PH4                                              VS0H 83300017
         B     CCTOLSTC                                            VS0H 83330017
PREVRBA1 AH    R4,PH1                                              VS0H 83350017
         B     PREVRBA2                                            VS0H 83370017
BIGONCE  L     R2,STARTIN                  ADJUST POINTER TO       VSOH 83400017
         AH    R12,PH1                       RDW OF                VSOH 83470017
         AR    R2,R12                         NEXT                 VS0H 83540017
         ST    R2,STARTIN                     RECORD               VS0H 83610017
         LH    R12,MAXOUT                                          VS0H 83620017
         TM    BLKDSWCH+1,X'F0'                                    VS0H 83640017
         BO    THRUONCE                                            VS0H 83650017
         B     ONCE                                                VS0H 83680017
LABEL1AD DC    A(LABEL1)                                           UL0H 83780017
         LTORG         ,           ALIGN IMM OPERANDS            A52039 83790021
*          I N P U T    D C B                                    A52039 83800021
INSET    DCB   DDNAME=SYSUT1,DSORG=PS,MACRF=GM,EODAD=SDSEOD,     A52039X83830021
               EXLST=PPEXIN,SYNAD=SYNADMSG                       A52039 83880021
         END   IEBPPCH1                                                 86780017
