SCAN     TITLE 'IEBCOPY  CONTROL CARD SCAN- IEBSCN'                     00080019
IEBSCN   CSECT                                                          00160019
*C946800                                                         A41780 00170021
*A481000-481080                                                  A41802 00170100
*C464200                                                         A45150 00180021
*A464220-464260,466100                                           A45150 00190021
*D464700                                                         A45150 00192021
*C481700                                                         A45174 00194022
*A481720-481780                                                  A45174 00196022
*A114500-115100,639900-640900,649800-749300,770100-770400        A48742 00196422
*D145060-145260                                                  A48742 00196522
*C768800                                                         A48742 00196822
*A474100                                                         A45185 00198022
*A642600-642632,064620                                           A44144 00198122
*C642520,632500,754910                                           A44144 00198222
*D754850-754880,754970-755030                                    A44144 00198322
*A116500-116700                                                  A48800 00198722
*C471800,472200,473600,498690                                    A48799 00199122
*D366860-367040                                                  A48799 00199222
*A581500-582200,366860,471900-472120                             A48799 00199522
*A041300,374120-374140                                           A52038 00209521
**********************************************************************  00210022
         ENTRY IEBSCF                                                   00220022
         SPACE 1                                                        00240019
*                                                                     * 00260019
*TITLE- IEBCOPY CONTROL CARD SCAN AND ANALYSIS CSECT- IEBSCN          * 00280019
*                                                                     * 00320019
*STATUS- CHANGE LEVEL 001                                             * 00400019
*                                                                     * 00480019
*FUNCTION/OPERATION-  THIS MODULE SCANS CONTROL CARDS AND GIVES       * 00560019
*       MESSAGES FOR SYNTAX OR SEQUENCE ERRORS. IT BUILDS AN INDD     * 00640019
*       TABLE OF DD NAMES OF INPUT DATA SETS WHICH CONTAIN MEMBERS    * 00720019
*       TO BE COPIED. IT BUILDS AN SE TABLE OF MEMBER NAMES TO BE     * 00800019
*       SELECTED OR EXCLUDED IN THE COPY. IT STORES THE NAME OF       * 00880019
*       THE OUTPUT DD STATEMENT IN BUFFER 'OUTNAME'.                  * 00960019
*                                                                     * 01040019
*ENTRY POINTS- ENTERED AT IEBSCN.                                     * 01120019
*        ENTERED AT IEBSEF ON EOF ON SYSIN                            * 01140019
*                                                                     * 01200019
*INPUT- SYSIN WHICH CONSISTS OF CONTROL STATEMENTS.                   * 01280019
*                                                                     * 01360019
*OUTPUT- SYSPRINT WHICH CONTAINS THE DIAGNOSTIC MESSAGES AND THE      * 01440019
*        CONTENTS OF SYSIN                                            * 01520019
*                                                                     * 01600019
*EXITS-  ERROR- IF AN ERROR OCCURS, A CODE IS STORED, A MESSAGE IS    * 01680019
*        GIVEN TO THE USER EXPLAINING THE ERROR CONDITION AND A       * 01760019
*        RETURN TO THE CALLING PROGRAM IS GIVEN.                      * 01840019
*                                                                     * 02240019
*EXTERNAL ROUTINES- READ CARD (GET), PRINT CARD OR ERROR MESSAGE (PUT)* 02320019
*                                                                     * 02400019
*TABLES/WORK AREAS-                                                   * 02480019
*      -KEYTAB-    LIST OF VALID KEYWORDS                             * 02560019
*      -COMDTABL-  LIST OF VALID COMMAND WORDS                        * 02640019
*      -CCIMAGE-   BUFFER CONTAINING CONTROL CARD IMAGE               * 02720019
*      -INDD TABLE-POINTED TO BY INBEGIN                              * 02800019
*      -SE TABLE-  POINTED TO BY SEBEGIN                              * 02880019
*      -CTAD-      POINTER TO CONTROL TABLE BUILT WHEN SELECTIVE COPY * 02960019
*      -PARMSWCH-  INTERNAL SCAN SWITCHES                             * 03040019
*      -CCSWITCH-  EXTERNAL SCAN SWITCHES                             * 03120019
*      -COMDCDSW-  EXTERNAL SCAN SWITCHES                             * 03200019
*      -CPARAMSW-  INTERNAL SCAN SWITCHES                             * 03280019
*      -SV2-       REGISTER SAVE AREA                                 * 03360019
*                                                                     * 03440019
*ATTRIBUTES- SERIAL REUSABLE                                          * 03520019
*                                                                     * 03600019
         EJECT                                                          03680019
         SPACE 1                                                        03740019
*                                                                     * 03760019
*                    SCAN ROUTINE CONSTANTS                           * 03840019
*                                                                     * 03920019
ANAT     EQU   C'@'                    NATIONAL SYMBOL- OKAY IN MEMBER  03960019
APOUND   EQU   C'#'                    NATIONAL SYMBOL- OKAY IN MEMBER  04000019
ADOLLAR  EQU   C'$'                    NATIONAL SYMBOL- OKAY IN MEMBER  04040019
AC       EQU   C'C'                                                     04080019
ANUNDRSC EQU   C'_'                                              A52038 04130021
ANA      EQU   X'C0'                   START OF VALID CHARACTER         04160019
EQUAL    EQU   C'='                    HEX 'EQUAL'                      04240019
COMMA    EQU   C','                    HEX 'COMMA'                      04320019
BLANKCOL EQU   C' '                    HEX 'BLANK'                      04400019
PARENLFT EQU   C'('                    LEFT PARENTHESIS                 04480019
PARENRGT EQU   C')'                    RIGHT PARENTHESIS                04560019
CRESET0  EQU   X'00'                   RESETS SWITCHES                  04640019
         SPACE 1                                                        04720019
*                                                                     * 04800019
*                      SYMBOLIC REGISTER FOR SCAN                     * 04880019
         SPACE 1                                                        04960019
LENGTH   EQU   9                       LENGTH OF PARAMETER REGISTER 9   05040019
SCANADR  EQU   1                       ADDRESS OF PARAMETER REGISTER 1  05120019
GR0      EQU   0                                                        05200019
GR1      EQU   1                                                        05280019
GR2      EQU   2                                                        05360019
GR3      EQU   3                                                        05440019
GR4      EQU   4                       COMMUNICATION AREA POINTER       05520019
GR5      EQU   5                                                        05600019
GR6      EQU   6                                                        05680019
GR7      EQU   7                                                        05760019
GR8      EQU   8                                                        05840019
GR9      EQU   9                                                        05920019
GR10     EQU   10                                                       06000019
GR11     EQU   11                                                       06080019
GR12     EQU   12                      REGISTER USED FOR BASE ADDRESS   06160019
GR13     EQU   13                                                       06240019
GR14     EQU   14                                                       06320019
GR15     EQU   15                                                       06400019
FF       EQU   X'FF'              ALL BITS ON                           06403019
LEN8     EQU   8                  LENGTH OF COMMAND OR KEYWORD          06406019
LEN12    EQU   12                 LENGTH OF ENTRY                       06409019
SAV4     EQU   4                  OLD SAVE AREA                         06412019
SAV8     EQU   8                  SAVE                                  06415019
TABLE0   EQU   0                  ZERO TABLE DISPLACEMENT               06418019
INDD1    EQU   1                  ENTRIES IN INDD TABLE                 06421019
LEN10    EQU   10                 LENGTH OF  10                         06424019
LEN2     EQU   2                  LENGTH OF  2                          06427019
LEN4     EQU   4                  LENGTH OF  4                          06430019
COL71    EQU   71                 COLUMN 72                             06433019
COL70    EQU   70                 COLUMN 71                             06436019
SCAN0    EQU   0                  COLUMN BEING SCANNED                  06439019
UP1      EQU   1                  COLUMN UPDATE                         06442019
PARCNT   EQU   X'01'              PARENTHESIS COUNT                     06445019
MS7      EQU   7                  MASK OF 7                             06448019
MS5      EQU   5                  MASK OF 5                             06451019
EX       EQU   C'E'               E FOR EXCLUDE                         06454019
IN       EQU   C'I'               I FOR INCLUDE                         06457019
COMPCD   EQU   C'4'               COMPLETION CODE                       06460019
COMPCDE  EQU   C'8'               COMPLETION CODE                A44144 06462022
MS8      EQU   8                  MASK OF 8                             06463019
LEN3     EQU   3                  LENGTH OF 3                           06466019
MS2      EQU   2                  MASK OF 2                             06469019
         EJECT                                                          06480019
         SAVE  (14,12),,*                                               06560019
*                                                                       06640019
*                    BASE ADDRESS REGISTER GR12-- COMMUNICATION AREA 4  06720019
*                                                                       06800019
         BALR  GR12,GR0           ESTABLISH ADDRESSABILITY              06880019
         USING NEXT,GR12                                                06960019
         USING IEBMCA,4                                                 07040019
         SPACE 1                                                        07120019
NEXT     EQU   *                                                        07200019
         ST    GR13,SV2+SAV4      SAVE POINTER TO OLD SAVE AREA         07300019
         LA    GR15,SV2                NEW SAVE AREA THIS CSECT         07440019
         ST    GR15,SAV8(GR13)    POINTER TO NEW SAVE AREA IN OLD       07540019
         LR    GR13,GR15               POINTER TO THIS CSECT SAVE AREA  07680019
         SPACE 1                                                        07760019
         TM    CCSWITCH,SYSINEOF       END OF FILE ON LAST READ         10880019
         BO    TERMS              YES- TERMINATE JOB-- SYSIN DONE       10930019
         TM    PARMSWCH,FLUSHSW        FLUSHING                         10980019
         BO    IGNORE             YES- GET NEXT CARD                    11010019
         TM    CCSWITCH,IEBCOPYC       HAVE IEBCOPY CONTROL CARDS       11040019
         BO    SCANERRM           YES- MIXED CODES                      11100019
         NI    COMDCDSW,FF-SELECTSC-EXCLUDES-MEMBRCD1 RESET SWITCHES    11160019
         B     TOSCAN                  CONTINUE                         11240019
         SPACE 1                                                        11340019
IGNORE   EQU   *                                                        11440019
         TM    CPARAMSW,COL72BLK       IS THIS CARD CONTINUED    A48742 11450022
         BO    IGNRENXT                NO                        A48742 11460022
         NI    SCANSWCH,FF-NOCMMEXP    RESET BYPASS SCAN SWITCH  A48742 11470022
         B     IGNOREON                AND CONTINUE              A48742 11480022
IGNRENXT EQU   *                                                 A48742 11490022
         OI    SCANSWCH,NOCMMEXP       SET BYPASS SCAN SWITCH    A48742 11500022
IGNOREON EQU   *                                                 A48742 11510022
         MVI   COMDCDSW,CRESET0                                         11520019
         MVI   CCDELIM2,CRESET0                                         11600019
         TM    CCSWITCH,CARDPRTD  WAS THE CARD PRINTED           A48800 11650022
         BO    GOONSC             YES                            A48800 11660022
         BAL   GR9,PRNTCRD        NO, PRINT THE CARD             A48800 11670022
         SPACE 1                                                        11680019
GOONSC   EQU   *                                                        11760019
         MVI   CCSWITCH,CRESET0        CLEAR SWITCHES FIRST TIME THRU   11840019
GOONS    EQU   *                                                        11920019
         MVI   CPARAMSW,READ1          FORCE READ FIRST CONTROL CARD    12000019
         SPACE 1                                                        12080019
TOSCAN   EQU   *                                                        12160019
         BAL   GR14,RDCARD             GO TO CONTROL CARD SCAN          12240019
RETRTOSC EQU   *                                                        12280019
         L     LENGTH,CSTOREG          LENGTH OF PARAMETER              12320019
         L     SCANADR,CSTOREG+SAV4 START OF PARAMETER                  12400019
         LTR   LENGTH,LENGTH           IS SCAN LENGTH ZERO              12480019
         BZ    BADPARM                 BAD PARAMETER                    12560019
         TM    CCSWITCH,COMDNOW        IS COMMAND SWITCH ON             12640019
         BO    OPRLUP             YES- CHECK COMMAND WORDS              12720019
*                                                                     * 12800019
*   KEYWORD LOOKUP ROUTINE                                              12880019
         LA    GR5,KEYTAB              START OF KEY WORD TABLE          12960019
         LA    GR7,KEYEND              END OF KEY WORD TABLE            13040019
         B     SCANTBL                 SEARCH FOR KEY WORD              13120019
         SPACE 1                                                        13200019
*   COMMAND WORD LOOKUP TABLE                                           13280019
OPRLUP   LA    GR5,COMDTABL            START OF COMMAND TABLE           13360019
         LA    GR7,COMDEND             END OF COMMAND TABLE             13440019
SCANTBL  EQU   *                                                        13520019
         LA    GR6,LEN8           MAXIMUM LENGTH OF KEYWORD OR COMMAND  13600019
         CR    LENGTH,GR6              TEST IF LENGTH EXCEEDS 8         13680019
         BH    PRTBAD                  PRINT BAD CARD                   13760019
         LA    GR6,LEN12          INCREMENT VALUE- 12 BYTE ENTRIES      13840019
         MVC   SARG(LEN8),BLANKS8 MOVE BLANKS TO SEARCH ARGUMENT        13920019
         BCTR  LENGTH,GR0         DECREMENT FOR EXECUTE COUNT           14000019
         EX    LENGTH,OPRLUP3          MOVE PARAMETER TO 'SARG'         14080019
OPRCMP   CLC   SARG(LEN8),TABLE0(GR5) TEST IF SEARCH ARGUMENT IN TABLE  14160019
         BNE   OPRLUP2                 NO- CONTINUE SCAN OF TABLE       14240019
         LA    GR5,LEN8(GR5)      ENTRY ADDRESS OF ROUTINE              14320019
         BR    GR5                     ENTER PROPER ROUTINE             14400019
OPRLUP2  BXLE  GR5,GR6,OPRCMP          LOOP TO CONTINUE SCAN            14480019
PRTBAD   EQU   *                                                        14500019
         LA    GR2,INALCNTR            INVALID COMMAND OR KEYWORD       14560019
         B     GIVESCNE           PRT CARD, SET RC TO 4, WRT MSG        14860019
         EJECT                                                          15200019
*     COMMAND LOOKUP TABLE                                              15280019
* FORMAT OF TABLE -                                                     15300019
*     1) KEYWORD OR ABBREVIATION (ALWAYS AN 8-BYTE 'DC')                15320019
*     2) BRANCH TO ANALYZER SUBROUTINE                                  15340019
COMDTABL DS    0F                      START OF VALID COMMAND TABLE     15360019
         DC    C'COPY    '        KEYWORD                               15420019
         B     CHKCOPY            BRANCH TO ANALYZER                    15480019
         DC    C'C       '        ABBREVIATION                          15540019
         B     CHKCOPY            BRANCH TO ANALYZER                    15600019
* SUBSEQUENT TABLE ELEMENTS ARE IN SAME FORMAT AS THE ABOVE             15660019
         DC    C'EXCLUDE '                                              15760019
         B     CHKEXCLD           CHECK EXCLUDE                         15840019
         DC    C'E       '                                              15920019
         B     CHKEXCLD           CHECK EXCLUDE                         16000019
         DC    C'MEMBER  '                                              16080019
         B     CHKMEMB            MEMBER COMMAND                        16130019
* NOTE - NO ABBREVIATION ALLOWED FOR 'MEMBER' WHEN USED AS A COMMAND,   16180019
*        BECAUSE THIS CONTEXT IS FOR PREVIOUS VERSIONS OF IEBCOPY.      16200019
         DC    C'SELECT  '                                              16240019
         B     CHKSELCT           CHECK SELECT                          16320019
COMDEND  DC    C'S       '             END OF COMMAND WORD TABLE        16400019
         B     CHKSELCT           CHECK SELECT                          16480019
         EJECT                                                          16560019
*     KEYWORD LOOKUP TABLE                                              16640019
* FORMAT OF TABLE -                                                     16680019
*     1) KEYWORD OR ABBREVIATION (ALWAYS AN 8-BYTE 'DC')                16720019
*     2) BRANCH TO ANALYZER SUBROUTINE                                  16760019
KEYTAB   DS    0F                 START OF KEY WORD TABLE               16800019
         DC    C'MEMBER  '        KEYWORD                               16840019
         B     MEMBRANL           BRANCH TO ANALYZER                    16880019
         DC    C'M       '        ABBREVIATION                          16920019
         B     MEMBRANL           BRANCH TO ANALYZER                    16960019
* SUBSEQUENT TABLE ELEMENTS ARE IN SAME FORMAT AS THE ABOVE             17000019
         DC    C'OUTDD   '                                              17120019
         B     OUTDDANL           CHECK OUTDD                           17200019
         DC    C'O       '                                              17280019
         B     OUTDDANL           CHECK OUTDD                           17360019
         DC    C'INDD    '                                              17440019
         B     INDDANL            CHECK INDD                            17520019
         DC    C'I       '                                              17600019
         B     INDDANL            CHECK INDD                            17680019
         DC    C'LIST    '                                              17760019
         B     LISTANL            CHECK LIST KEYWORD                    17840019
         DC    C'L       '                                              17920019
         B     LISTANL            CHECK LIST KEYWORD                    17970019
* NOTE - THE FOLLOWING 3 KEYWORDS ARE FOR COMPATIBILITY WITH PREVIOUS   18020019
*        VERSIONS, AND HAVE NO ABBREVIATION                             18040019
         DC    C'NAME    '                                              18080019
         B     NAMEANL            NAME KEYWORD                          18160019
         DC    C'TYPCOPY '                                              18240019
         B     TYPCPANL           TYPCOPY KEYWORD                       18320019
KEYEND   DC    C'MAXNAME '             END OF TABLE OF KEYWORDS         18400019
         B     NOPMAX             MAXNAME KEYWORD                       18480019
         EJECT                                                          18560019
CHKMEMB  EQU   *                                                        18640019
         BAL   GR9,PRNTCRD             PRINT THE CARD                   18720019
         TM    CCSWITCH,IEBCOPYC       WITH IEBCOPY CONTROL CARDS       18800019
         BZ    SCANERRM           NO- MIXING CONTROL CARDS              18880019
         TM    COMDCDSW,EXCLUDES+SELECTSC  WITH SELECT OR EXCLUDE       18960019
         BZ    SCANSEQR           NO- CARD MAYBE OUT OF SEQUENCE        19000019
         TM    COMDCDSW,MEMBRCD1       ALREADY HAD A MEMBER CARD        19050019
         BZ    ARNDS              NO                                    19060019
         OI    CCSWITCH,MULTSE         FLAG AS MULTIPLE MEMBER CARDS    19070019
ARNDS    EQU   *                                                        19080019
         OI    COMDCDSW,MEMBRCD1       SET MEMBER COMMAND SWITCH        19120019
         B     TOSCAN                  CONTINUE SCANNING                19200019
         SPACE 1                                                        19280019
NOPMAX   EQU   *                                                        19360019
         TM    PARMSWCH,COPYNOW        ON COPY STATEMENT                19440019
         BZ    SCANSEQR           NO- SEQUENCE ERROR                    19490019
         TM    CCSWITCH,FIRSTSCN       FIRST ENTRY                      19540019
         BZ    SCANERRM           NO, MIXED CODE                        19570019
         OI    CCSWITCH,IEBCOPYC       FLAG AS IEBCOPY CONTROL CARDS    19600019
         BAL   GR14,RDCARD             GET PARAMETER AFTER EQUAL SIGN   19680019
         SPACE 1                                                        19760019
CHLAST   EQU   *                                                        19840019
         TM    CCSWITCH,LASTPARM       LAST PARAMETER ON CARD SCANNED   19920019
         BZ    TOSCAN             NO- CONTINUE SCANNING CARD            20000019
         MVI   PARMSWCH,CRESET0        RESET 'COPYNOW' SWITCH           20080019
         OI    COMDCDSW,COPYDONE       SET AS COPY CARD SCANNED         20120019
         B     GOONS                   GET NEXT CARD                    20160019
         SPACE 1                                                        20240019
NAMEANL  EQU   *                                                        20320019
         TM    CCSWITCH,IEBCOPYC       WITH IEBCOPY CONTROL CARDS       20400019
         BZ    SCANERRM           MIXED CONTROL CARDS                   20480019
         TM    COMDCDSW,MEMBRCD1       WITH MEMBER STATEMENT            20560019
         BZ    SCANERR            NO- ERROR                             20610019
         TM    CCSWITCH,MULTSE         MULTIPLE MEMBER CARDS            20660019
         BO    STRMEMBS           ADD THESE NAMES TO TABLE              20690019
         LA    GR9,STRMEMBS            RETURN FROM SET4OLDC ROUTINE     20720019
         SPACE 1                                                        20800019
SET4OLDC EQU   *                                                        20880019
         L     GR8,INBEGIN             START OF INDD TABLE              20960019
         LA    GR6,INDD1          COUNT OF ENTRIES                      21040019
         STH   GR6,INDDCT              MAKE INDD COUNT 1                21120019
         MVC   TABLE0(LEN10,GR8),FLAGBYTS CLEAR FLAG BYTES AND NAME     21180019
         LA    GR6,INDCB               INPUT DATA SET DCB ADDRESS       21250019
         MVC   LEN2(LEN8,GR8),DDNAME1(GR6) MAKE INDD ENTRY INDCB-SYSUT1 21280019
         LA    GR6,OUTDCB              OUTPUT DATA SET DCB ADDRESS      21310019
         MVC   OUTNAME(LEN8),DDNAME1(GR6) OUTPUT DATA SET SYSUT2        21350019
         LA    GR8,LEN10(GR8)     UP TABLE POINTER                      21390019
         ST    GR8,SEBEGIN             STORE START AND END OF SETABLE   21440019
         ST    GR8,SESTOP                                               21520019
         BR    GR9                     RETURN                           21680019
         SPACE 1                                                        21760019
OUTDDANL EQU   *                                                        21840019
         TM    PARMSWCH,FLUSHSW        DOING A FLUSH                    21920019
         BO    IGNORE             YES- SKIP THIS CARD                   22000019
         TM    PARMSWCH,COPYNOW        ON COPY STATEMENT                22080019
         BZ    INVALODL           ERROR- OUTDD NOT ON COPY CARD         22120019
         TM    COMDCDSW,COMPRESS       PARM= COMPRESS ON EXEC CARD      22170019
         BO    COMPEXEC           YES- MEANINGLESS IN IEBDSCPY          22180019
         SPACE 1                                                        22190019
COMPRETN EQU   *                       RETURN POINT AFTER MESSAGE       22200019
         OI    COMDCDSW,NEWOUT         SET OUTDD SCANNED SWITCH         22240019
         OI    FLG4,NEWODS+NEWCOPOP    SET SWITCHES TO INDICATE A NEW   22290019
*                                        COPY OPERATION HAS BEEN FOUND  22340019
         TM    CPARAMSW,DELIMEND       NAME ON NEXT CARD (= IN COL 71)  22400019
         BZ    PICKNAME           NO- NORMAL PROCESSING                 22480019
         BAL   GR10,GETPARM            GET NEXT CARD- POSITION TO PARM  22560019
         SPACE 1                                                        22640019
PICKNAME EQU   *                                                        22720019
         BAL   GR14,RDCARD             GET PARAMETER                    22800019
         L     SCANADR,CSTOREG+SAV4 START OF PARAMETER                  22880019
         L     LENGTH,CSTOREG          SIZE OF PARAMETER                22960019
         LA    GR6,LEN8           MAXIMUM LENGTH OF NAME                23040019
         CR    GR6,LENGTH                                               23120019
         BL    BADPARM                 NAME GREATER THAN 8 BYTES        23200019
         LA    GR6,OUTDCB              OUTPUT DATA SET DCB ADDRESS      23250019
         MVC   DDNAME1(LEN8,GR6),BLANKS8 CLEAR DCB DDNAME FIELD         23300019
         BCTR  LENGTH,GR0         DECREMENT FOR EXECUTE COUNT           23350019
         EX    LENGTH,MOVEOUTD         MOVE OUTDD NAME TO OUTPUT DCB    23410019
         MVC   OUTNAME(LEN8),DDNAME1(GR6) MOVE OUTDD NAME TO COMMON     23440019
*                                         AREA                          23470019
         TM    CCSWITCH,LASTPARM       LAST PARAMETER ON CARD           23520019
         BZ    TOSCAN             NO- CHECK FOR LIST OPTION             23620019
         B     CHKCOMSC                CHECK FOR CONTINUED COMMENTS     23800019
         SPACE 1                                                        24080019
LISTANL  EQU   *                                                        24160019
         TM    PARMSWCH,FLUSHSW        FLUSHING                         24180019
         BO    IGNORE             YES- IGNORE THIS CARD                 24210019
         TM    PARMSWCH,COPYNOW        ON COPY STATEMENT                24240019
         BZ    INVALODL           NOT ON COPY STATEMENT                 24320019
         TM    CPARAMSW,DELIMEND       NAME ON NEXT CARD (= IN COL 71)  24400019
         BZ    ONTHISC            NO- NORMAL PROCESSING                 24480019
         BAL   GR10,GETPARM            GET NEXT CARD- POSITION TO PARM  24560019
         SPACE 1                                                        24720019
ONTHISC  EQU   *                                                        24800019
         BAL   GR14,RDCARD             GET PARAMETER                    24880019
         L     SCANADR,CSTOREG+SAV4 START OF PARAMETER                  24960019
         L     LENGTH,CSTOREG          LENGTH OF PARAMETER              25040019
         LA    GR6,LEN2                                                 25120019
         CR    LENGTH,GR6                                               25200019
         BNE   BADPARM                 PARAMETER LARGER THAN 'NO'       25280019
         CLC   SCAN0(LEN2,SCANADR),LISTALLC  IS PARAMETER 'NO'          25360019
         BNE   BADPARM                 ERROR                            25440019
         TM    CCSWITCH,IEBCOPYC       WITH IEBCOPY STATEMENTS          25520019
         BO    SCANERRM           YES- MIXING STATEMENT TYPES           25600019
         OI    COMDCDSW,LISTSW         SET TO NOT LIST MEMBERS COPIED   25680019
         TM    CCSWITCH,LASTPARM       LAST PARAMETER ON CARD           25760019
         BZ    TOSCAN             NO- CONTINUE                          25840019
         TM    COMDCDSW,NEWOUT         HAVE OUTDD ALREADY               25920019
         BZ    NOINDDSP           INDD/LIST WITHOUT OUTDD               25940019
CHKCOMSC EQU   *                                                        25968019
         TM    CPARAMSW,COL72BLK       CONTINUED CARD                   25976019
         BZ    COPYALLD           FINISH UP COPY CARD SCAN              25984019
         BAL   GR9,CHK4COMT            CHECK FOR CONTINUED COMMENTS     25992019
COPYALLD EQU   *                                                        26000019
         OI    COMDCDSW,COPYDONE       SET DONE WITH COPY CARD SWITCH   26040019
         MVI   PARMSWCH,CRESET0        RESET ALL, ESPECIALLY 'COPYNOW'  26080019
         B     GOONSC                  GET NEXT CARD                    26120019
         SPACE 1                                                        26160019
CHKEXCLD EQU   *                                                        26240019
         TM    PARMSWCH,FLUSHSW        FLUSHING                         26250019
         BO    IGNORE             YES- IGNORE THIS CARD                 26260019
         TM    COMDCDSW,SELECTSC       SELECT CARD AHEAD                26270019
         BO    MULTS              YES- ERROR TO HAVE BOTH               26280019
         LA    GR7,RETRNEV             RETURN ADDRESS                   26290019
         TM    COMDCDSW,EXCLUDES       MULTIPLE EXCLUDES                26300019
         BZ    TESTCSE            NO                                    26310019
         B     MULTSET                 SET MULTIPLE S/E SWITCH          26320019
         SPACE 1                                                        26330019
RETRNEV  EQU   *                                                        26340019
         OI    COMDCDSW,EXCLUDES       SET EXCLUDE SWITCH               26400019
         NI    COMDCDSW,FF-MEMBRCD1    INDIC MEMBER KEYWORD FOR  A38724 26420021
*           THIS EXCLUDE COMMAND NOT YET FOUND                   A38724 26430021
         B     TOSCAN                  CONTINUE                         26480019
         SPACE 1                                                        26560019
CHKSELCT EQU   *                                                        26640019
         LA    GR7,SELCTOK             RETURN FROM FOLLOWING ROUTINE    26720019
         TM    PARMSWCH,FLUSHSW        DOING A FLUSH                    26880019
         BO    IGNORE             YES- SKIP THIS CARD                   26920019
         TM    COMDCDSW,EXCLUDES       EXCLUDE CARD AHEAD OF SELECT     26970019
         BO    MULTS              YES- ERROR TO MIX THEM                26980019
         TM    COMDCDSW,SELECTSC       PREVIOUS SELECT                  26990019
         BZ    TESTCSE            ONLY ONE SELECT                       27000019
MULTSET  EQU   *                                                        27010019
         OI    CCSWITCH,MULTSE         MULTIPLE SELECT/EXCLUDE          27020019
TESTCSE  EQU   *                                                        27030019
         TM    PARMSWCH,COMDPART       PART OF COMMAND ON NEXT CARD     27040019
         BZ    NOGOON             NO- GO ON AND PRINT CARD              27120019
         MVI   PARMSWCH,CRESET0        RESET ENTIRE SWITCH              27200019
         B     AFTRPRT                 DO NOT PRINT CARD                27280019
         SPACE 1                                                        27360019
NOGOON   EQU   *                                                        27440019
         BAL   GR9,PRNTCRD             PRINT THE CARD                   27520019
AFTRPRT  EQU   *                                                        27600019
         TM    COMDCDSW,NEWINDD        HAVE AN INDD                     27840019
         BZ    NOINDDSP           NO- SEQUENCE ERROR                    28040019
         TM    CCSWITCH,LASTPARM       MORE PARAMETERS ON CARD          28320019
         BO    NULLP              NO- MUST HAVE MEMBER KEYWORD          28400019
         NI    CCSWITCH,FF-COMDNOW RESET COMMAND WORD SWITCH            28480019
         BR    GR7                     RETURN                           28560019
         SPACE 1                                                        28640019
SELCTOK  EQU   *                                                        28720019
         OI    COMDCDSW,SELECTSC       SET SELECT SWITCH                28800019
         NI    COMDCDSW,FF-MEMBRCD1    INDIC MEMBER KEYWORD FOR  A38724 28820021
*           THIS EXCLUDE COMMAND NOT YET FOUND                   A38724 28830021
         B     TOSCAN                  CONTINUE                         28880019
         SPACE 1                                                        28960019
INDDANL  EQU   *                                                        29040019
         TM    PARMSWCH,FLUSHSW        DOING A FLUSH                    29120019
         BO    IGNORE             YES- SKIP THIS CARD                   29200019
         TM    CCSWITCH,IEBCOPYC       IEBCOPY STATEMENTS               29280019
         BO    SCANERRM           YES- MIXED MODES                      29330019
         TM    PARMSWCH,COPYNOW        INDD ON COPY CARD                29380019
         BO    NEXTI              YES                                   29410019
         TM    COMDCDSW,SELECTSC+EXCLUDES  JUST GOT SELECT OR EXCLUDE   29450019
         BM    RESETIN            YES- DO A COPY                        29470019
         BAL   GR9,PRNTCRD             PRINT INDD CARD                  29490019
         TM    COMDCDSW,NEWINDD        JUST HAD AN INDD                 29510019
         BO    STRMEMBS           ADD THESE NAMES TO TABLE              29550019
         NI    CCSWITCH,FF-MULTSE RESET MULTIPLE S/E SWITCH             29590019
         B     GOGOGO                  GO BUILD THE INDD TABLE          29630019
         SPACE 1                                                        29680019
NEXTI    EQU   *                                                        29730019
         TM    COMDCDSW,NEWINDD        INDD ON COPY CARD ALREADY        29780019
         BO    SCANERR            YES- ONLY ONE INDD PER COPY CARD      29830019
GOGOGO   EQU   *                                                        29880019
         OI    COMDCDSW,NEWINDD        FLAG AS HAVE AN INDD             29930019
         NI    COMDCDSW,FF-SELECTSC-EXCLUDES-MEMBRCD1 RESET SWITCHES    29980019
         SPACE 1                                                        30030019
**********                                                   ********** 30080019
**********         BUILD TABLE OF INDD NAMES                 ********** 30160019
**********                                                   ********** 30240019
         SPACE 1                                                        30320019
         XC    COUNT(LEN2),COUNT  CLEAR COUNT                           30400019
         XC    ENCT(LEN2),ENCT    CLEAR SE TABLE ENTRY COUNT            30480019
         XC    NNCT1(LEN2),NNCT1  CLEAR NEW NAME COUNT                  30560019
         XC    INDDCT(LEN2),INDDCT CLEAR INDD COUNT                     30640019
         MVC   SESTOP(LEN4),INBEGIN NO SE OR INDD ENTRIES YET           30720019
STRMEMBS EQU   *                                                        30800019
         TM    CPARAMSW,DELIMEND       NAME ON NEXT CARD (= IN 71)      30880019
         BZ    CONTSC             NO- CONTINUE NORMAL PROCESSING        30960019
GETNEXTC EQU   *                                                        31040019
         LA    GR10,SCANSOME           RETURN FROM FOLLOWING ROUTINE    31120019
         SPACE 1                                                        31200019
*  ROUTINE 'GETPARM' READS NEXT CARD AND POSITIONS TO CONTINUATION      31280019
*   PARAMETER. GR10 SET ON ENTRY TO ROUTINE WITH RETURN ADDRESS.        31360019
         SPACE 1                                                        31440019
GETPARM  EQU   *                                                        31520019
         BAL   GR9,READCC              GET NEXT CARD                    31600019
         BAL   GR9,PRNTCRD             PRINT THE CARD                   31680019
         MVI   CPARAMSW,CRESET0        CLEAR PARAMETER SWITCH           31760019
         CLI   CCIMAGE+COL71,BLANKCOL COL 72 BLANK                      31840019
         BE    ARNDNXT                 YES- NOT CONTINUED               31920019
         OI    CPARAMSW,COL72BLK       SET COLUMN 72 NOT BLANK SWITCH   32000019
ARNDNXT  EQU   *                                                        32080019
         LA    GR6,CCIMAGE+COL70  END OF CARD PARAMETER COLUMN          32180019
         BAL   GR9,NAMESCAN            SCAN OVER NAME IF ANY            32440019
         SPACE 1                                                        32720019
LOOP2    EQU   *                                                        32800019
         CLI   SCAN0(GR3),BLANKCOL COLUMN BLANK                         32880019
         BNE   STRTPARM                NO- START OF PARAMETER           32960019
LOOPPARM EQU   *                                                        33040019
         LA    GR3,UP1(GR3)       UPDATE TO NEXT COLUMN                 33120019
         CR    GR3,GR6                                                  33200019
         BNH   LOOP2                   SCAN TO COLUMN 71                33300019
         B     GETPARM                 GET NEXT CARD                    33400019
         SPACE 1                                                        33760019
STRTPARM EQU   *                                                        33840019
         ST    GR3,CSTOREG+SAV8   STORE START OF PARAMETER              33940019
         NI    PARMSWCH,FF-COMDPART RESET PARAMETER CONTINUED SWITCH    34040019
         OI    CPARAMSW,PARMCOME       SET TO EXPECT PARAMETER          34240019
         BR    GR10                    RETURN                           34320019
         SPACE 1                                                        34400019
CONTSC   EQU   *                                                        34480019
         L     GR3,CSTOREG+SAV8   COLUMN TO START SCAN                  34500019
         NI    CCSWITCH,FF-UNECPARN RESET PARENTHESIS SWITCH            34520019
         XC    LEFTPCNT(LEN4),LEFTPCNT CLEAR PARENTHESIS COUNT BUFFER   34540019
         CLI   SCAN0(GR3),PARENLFT  START WITH LEFT PAREN               34560019
         BNE   SCANSOME                GET NEXT PARAMETER               34581019
         OI    CCSWITCH,UNECPARN       SET PARENTHESIS SWITCH           34588019
         LA    GR3,UP1(GR3)       UP TO ACTUAL NAME- SET 4 BCTR         34668019
         MVI   LEFTPCNT+UP1,PARCNT MAKE LEFT PAREN COUNT 1              34748019
SCANSOME EQU   *                                                        34850019
         NI    PARMSWCH,COPYNOW        RESET ALL BUT COPY NOW SWITCH    34900019
         SR    GR7,GR7                 CLEAR PARAMETER SIZE             34930019
         BCTR  GR3,GR0            BACK UP POINTER                       34950019
         SPACE 1                                                        34970019
*********************************************************************** 34980019
*** START OF GENERAL INDD OR MEMBER NAME SCAN ROUTINE AT INDDLOOP.  *** 34990019
*********************************************************************** 35000019
         SPACE 1                                                        35040019
INDDLOOP EQU   *                                                        35120019
         LA    GR3,UP1(GR3)       UP TO NEXT COLUMN                     35160019
         TM    CPARAMSW,DELIMEND       UP TO 71                         35210019
         BZ    NOGET              NO                                    35220019
         BAL   GR10,GETPARM            GET PARAMETER FROM NEXT CARD     35230019
NOGET    EQU   *                                                        35240019
         BAL   GR9,TESTLAST            CHECK IF UP TO COLUMN 71         35280019
         CLI   SCAN0(GR3),COMMA   COMMA                                 35360019
         BH    TRYNAME                 NO- HIGHER THAN COMMA            35440019
         BE    CHKCOMMA                YES- DELIMITER                   35520019
         CLI   SCAN0(GR3),PARENLFT     LEFT PARENTHESIS                 35600019
         BE    CHKPARNL                YES                              35680019
         CLI   SCAN0(GR3),PARENRGT     RIGHT PARENTHESIS                35760019
         BE    CHKPARNR                YES                              35840019
         CLI   SCAN0(GR3),ADOLLAR      IS IT A NATIONAL SYMBOL '$'      35860019
         BE    STRNAME                 YES- OKAY                        35880019
         CLI   SCAN0(GR3),BLANKCOL     BLANK                            35940019
         BNE   BADPARM                 BAD PARAMETER                    36000019
         TM    PARMSWCH,SCANNAME       BEEN SCANNING NAME               36080019
         BO    BLNKSTP                 YES- STOP NAME SCAN              36160019
         SPACE 1                                                        36240019
SET4READ EQU   *                                                        36320019
         CLC   LEFTPCNT(LEN2),RGHTPCNT EQUAL NUMBER LEFT AND RIGHT PARE 36400019
         BNE   MISSPARN                ERROR- MISSING PARENTHESIS       36480019
         TM    CPARAMSW,COL72BLK       CARD CONTINUED                   36560019
         BZ    GOONS                   NO GET NEXT CARD                 36569019
         BAL   GR9,CHK4COMT            CHECK FOR CONTINUED COMMENTS     36578019
         B     GOONS                   GET NEXT CARD                    36587019
         SPACE 1                                                        36596019
CHK4COMT EQU   *                                                        36605019
         ST    GR9,SARG                SAVE RETURN ADDRESS              36614019
         LA    GR6,CCIMAGE+COL71       COLUMN 72                        36623019
LOOPCOM  EQU   *                                                        36632019
         CLI   SCAN0(GR3),BLANKCOL     NEXT COLUMN BLANK                36641019
         BNE   ACOMMENT                NO- START OF COMMENT             36650019
         LA    GR3,UP1(GR3)                                             36659019
         CR    GR3,GR6                 END OF CARD NO COMMENT FOUND     36668019
         BNE   LOOPCOM                 CONTINUE COMMENT SCAN            36677019
         B     CONTINV                 INVALID CONTINUATION      A48799 36686022
         SPACE 1                                                        36713019
ACOMMENT EQU   *                                                        36722019
         BAL   GR9,READCC              READ NEXT CARD                   36731019
         BAL   GR9,PRNTCRD             PRINT THE COMMENT CARD           36740019
         CLI   CCIMAGE+COL71,BLANKCOL  COMMENT CONTINUED                36749019
         BNE   ACOMMENT                YES- GET NEXT COMMENT CARD       36758019
         NI    CPARAMSW,FF-COL72BLK    RESET CONTINUED SWITCH           36762019
         L     GR9,SARG                LOAD RETURN ADDRESS              36767019
         BR    GR9                     RETURN TO CALLER                 36776019
         SPACE 1                                                        36800019
CHKIFSTP EQU   *                                                        36880019
         LA    GR3,UP1(GR3)                                             36920019
         TM    PARMSWCH,COMDPART       UP TO COL 71 PARM CONTINUED      36960019
         BO    GETNEXTC                YES- GET NEXT CARD               37000019
         CLI   SCAN0(GR3),BLANKCOL     NEXT COLUMN BLANK                37040019
         BNE   SCANSOME                NO- SCAN SOME MORE               37080019
         B     CHKCONTY                CHECK IF CARD CONTINUED          37120019
         SPACE 1                                                        37200019
TRYNAME  EQU   *                                                        37280019
         CLI   SCAN0(GR3),ANA                                           37320019
         BNL   STRNAME                 OKAY- ALPHABETIC OR NUMERIC      37365019
         SPACE 1                                                        37370019
*  THREE NATIONAL SYMBOLS ALLOWED IN MEMBER NAMES- 'AT' SIGN, POUND     37375019
*    SIGN, AND DOLLAR SIGN. CHECK BEFORE FOR DOLLAR SIGN MUST CHECK     37380019
*    HERE FOR 'AT' AND POUND SYMBOL.                                    37385019
         SPACE 1                                                        37390019
         CLI   SCAN0(GR3),ANAT         IS IT AN 'AT' SIGN               37395019
         BE    STRNAME                 YES- OKAY                        37400019
         CLI   SCAN0(GR3),APOUND       IS IT A 'POUND' SIGN             37405019
         BE    STRNAME            YES - OKAY                            37410019
         CLI   SCAN0(GR3),ANUNDRSC     AN UNDER SCORE            A52038 37412021
         BE    STRNAME                 YES,OKAY                  A52038 37414021
         CLI   SCAN0(GR3),EQUAL        COULD IT BE AN EQUAL SIGN        37415019
         BNE   BADPARM            IF ITS NOT, ITS INVALID               37420019
         TM    COMDCDSW,MEMBRCD1       EQUAL SIGN IN MEMBER NAME SCAN   37425019
         BO    BADPARM                 YES- NOT ALLOWED                 37430019
         TM    PARMSWCH,COPYNOW        EQUAL SIGN WITH INDD ON COPY     37435019
         BZ    BADPARM                 NO- NOT ALLOWED IF NOT ON COPY   37440019
         TM    PARMSWCH,COMDPART       DELIMITER IN COLUMN 71           37446019
         BZ    TSTDLM                  NOT IN 71                        37448019
         OI    CPARAMSW,DELIMEND       SET IN 71 SWITCH                 37450019
TSTDLM   EQU   *                                                        37452019
         TM    CPARAMSW,CONTINY        PARAMETER WAS CONTINUED          37454019
         BZ    SETRETOK                NO                               37456019
         NI    CCSWITCH,FF-COMDNOW     RESET COMMAND SWITCH             37458019
         BAL   GR9,KCREATE             RECREATE KEYWORD                 37460019
         OI    CPARAMSW,PARMCOME  SET BIT                               37462019
         SPACE 1                                                        37464019
*          NAME NOT SCANNED, IF AN EQUAL SIGN IS A KEYWORD, POINTERS    37470019
*   ALL SET,   GO TO KPASS AND WILL RETURN TO CHECK KEYWORD JUST AS IF  37475019
*   RDCARD ROUTINE HAD SCANNED THE KEYWORD.                             37480019
         SPACE 1                                                        37485019
SETRETOK EQU   *                                                        37490019
         LA    GR14,RETRTOSC           RETURN FROM INITIALIZED 'KPASS'  37495019
         ST    GR14,SARG               STORE RETURN SO RDCARD CAN FIND  37500019
         B     KPASS                   SET UP AS IF 'RDCARD' SCANNED    37505019
         SPACE 1                                                        37510019
STRNAME  EQU   *                                                        37515019
         LA    GR7,UP1(GR7)            UP COUNT OF CHARACTERS IN NAME   37522019
         TM    PARMSWCH,SCANNAME       ALREADY SCANNING NAME            37530019
         BO    ALLSCAN                 YES                              37540019
         OI    PARMSWCH,SCANNAME       SET NAME SCANNING SWITCH         37550019
         LR    GR1,GR3                 LOAD POINTER TO START OF NAME    37560019
ALLSCAN  EQU   *                                                        37570019
         TM    PARMSWCH,COMDPART       CONTINUED NAME                   37600019
         BZ    SAMECARD                NO- CARD COMPLETE                37680019
         OI    CPARAMSW,CONTINY        SET TO CONTINUE ON NEXT CARD     37760019
         LA    GR14,INDDLOOP           RETURN ADDRESS                   37840019
         ST    GR14,SARG               STORE RETURN ADDRESS FOR SCAN    37920019
         B     KPART                   SET UP FIRST PART OF PARAMETER   38000019
         SPACE 1                                                        38080019
SAMECARD EQU   *                                                        38160019
         TM    CPARAMSW,DELIMEND       CHARACTER IN 71, NOT CONTINUED   38260019
         BZ    INDDLOOP                NO- CONTINUE SCAN                38360019
         B     ENDNAME                 STORE NAME                       38460019
         SPACE 1                                                        38640019
CHKPARNL EQU   *                                                        38720019
*                                                                       38800019
*    NAMES ON MEMBER STATEMENT ONLY IN () IF RENAME OR REPLACE OPTION   38880019
*   WAS SPECIFIED.  HOWEVER, FOR COMPATIBILITY, ALSO ALLOW LIST OF      38930019
*   MBR NAMES WITHIN PARENS.                                            38980019
*                                                                       39040019
         TM    CCSWITCH,IEBCOPYC       IEBCOPY CONTROL CARDS            39120019
         BZ    TSTRGHT                 NO                               39200019
         NI    PARMSWCH,FF-ONELEFT     RESET LEFT PARENTHESIS SWITCH    39280019
         B     CONTCPPY           ADD 1 TO LEFT-PAREN COUNT             39360019
         SPACE 1                                                        39440019
TSTRGHT  EQU   *                                                        39520019
         TM    COMDCDSW,EXCLUDES       REPLACE/RENAME ON EXCLUDE        39600019
         BO    NORENAME           IF SO, ITS INVALID                    39680019
         TM    PARMSWCH,ONELEFT   WAS A LEFT PAREN ALREADY SCANNED      39760019
         BO    BADREPLC                YES- INVALID REPLACE SPECIFIED   39840019
         OI    PARMSWCH,SET4REPL+ONELEFT  SET SWITCHES FOR REPLACE      39920019
         SPACE 1                                                        40000019
CONTCPPY EQU   *                                                        40080019
         LH    GR6,LEFTPCNT                                             40160019
         LA    GR6,UP1(GR6)            UP COUNT BY 1                    40240019
         STH   GR6,LEFTPCNT            STORE NEW COUNT                  40320019
         TM    PARMSWCH,SCANNAME       LEFT PAREN WHILE SCAN OF NAME    40400019
         BO    BADREPLC                YES- INVALID REPLACE SPECIFIED   40480019
         B     INDDLOOP                CONTINUE SCAN                    40560019
         SPACE 1                                                        40570019
CHKDUPC  EQU   *                                                        40580019
         TM    CPARAMSW,DELIMEND       COMMA IN COLUMN 71               40583019
         BO    ENDNAME                 YES- END SCAN OF NAME            40588019
         CLI   UP1(GR3),COMMA          NEXT CHARACTER ALSO A COMMA      40593019
         BE    NULLP                   YES- NULL PARAMETER ERROR        40600019
         CLI   UP1(GR3),PARENRGT       IS COMMA FOLLOWED BY RIGHT PAREN 40603019
         BE    NULLP              YES - NULL PARAMETER                  40607019
         B     ENDNAME                 CONTINUE                         40610019
         SPACE 1                                                        40640019
BLNKSTP  EQU   *                                                        40720019
         MVI   CCDELIM,BLANKSGN        SET AS DELIMITER A BLANK         40800019
ENDNAME  EQU   *                                                        40880019
         TM    CPARAMSW,CONTINY        PARM CONTINUED                   40960019
         BZ    NOCONT                  NO                               41010019
         NI    CCSWITCH,FF-COMDNOW     RESET COMMAND SWITCH             41060019
         BAL   GR9,KCREATE             YES- RECREATE PARAMETER          41120019
NOCONT   EQU   *                                                        41200019
         LA    GR9,LEN8                                                 41280019
         CR    GR7,GR9                                                  41360019
         BH    BADPARM                 BAD PARAMETER                    41440019
         L     GR8,SESTOP              NEXT SLOT IN INDD TABLE          41520019
         LR    GR6,GR8            SAVE NEXT SLOT ADDRESS                41540019
         LA    GR8,LEN10(GR8)     SEE IF ENOUGH ROOM FOR THIS ENTRY     41560019
         C     GR8,HICOR               EXCEEDING TABLE SPACE            41600019
         BNL   OUTOFCOR                YES- ERROR                       41680019
         LR    GR8,GR6            RESTORE NEXT SLOT ADDRESS             41720019
         MVC   TABLE0(LEN10,GR8),FLAGBYTS  CLEAR FLAGS, BLANK NAME      41760019
         BCTR  GR7,GR0                 DECREMENT COUNT FOR EXECUTE      41840019
         EX    GR7,MOVEDDNM            MOVE DD NAME TO TABLE            41920019
         NI    PARMSWCH,FF-SCANNAME    RESET SCANNING NAME SWITCH       42220019
         TM    COMDCDSW,MEMBRCD1       MEMBER STATEMENT                 42560019
         BO    MEMBRCD                 YES- HANDLE DATA SET NAMES       42640019
         TM    PARMSWCH,SET4REPL       THIS NAME A REPLACE              42720019
         BZ    REGNAME                 NO- CONTINUE                     42800019
         OI    TABLE0(GR8),REPLACOP    SET REPLACE OPTION BIT           42880019
         NI    PARMSWCH,FF-SET4REPL-HASNEWNM  RESET SWITCHES            42960019
         SPACE 1                                                        43040019
REGNAME  EQU   *                                                        43120019
         LH    GR6,INDDCT                                               43200019
         LA    GR6,UP1(GR6)            UP DD COUNT                      43280019
         STH   GR6,INDDCT              STORE NEW COUNT                  43360019
         LA    GR8,LEN10(GR8)          NEXT SLOT IN INDD BUFFER         43440019
         ST    GR8,SESTOP              END OF SE TABLE                  43520019
         SR    GR7,GR7                 CLEAR COUNT REGISTR              43600019
         TM    CCDELIM,BLANKSGN        END OF NAMES REACHED             43680019
         BZ    INDDLOOP                NO- SCAN FOR MORE NAMES          43760019
         CLI   SCAN0(GR3),COMMA        REALLY STOPPED AT A COMMA        43840019
         BE    CHKCONTY                YES                              43920019
ISDONE   EQU   *                                                        43970019
         NI    PARMSWCH,FF-COPYNOW     RESET COPY CARD SCAN SWITCH      44040019
         TM    COMDCDSW,NEWOUT         HAD AN OUTDD ON COPY CARD        44120019
         BZ    NOINDDSP                NO OUTDD SPECIFIED               44220019
         OI    COMDCDSW,COPYDONE+NEWOUT+NEWINDD BE SURE ALL ARE SET     44320019
         B     SET4READ                GET NEXT CARD                    44560019
         SPACE 1                                                        44640019
RESETIN  EQU   *                                                        44720019
         NI    COMDCDSW,FF-NEWINDD     RESET HAVE AN INDD SWITCH        44800019
         LA    GR3,CCIMAGE             START OF CARD                    44880019
         NI    CPARAMSW,COL72BLK       RESET ALL BUT CONTINUATION PUNCH 44960019
         ST    GR3,CSTOREG+SAV8        STORE COLUMN TO SCAN NEXT        45040019
         NI    CCSWITCH,CRESET0        CLEAR SWITCH                     45120019
         B     GETOUT                  RETURN TO MAINSTREAM             45200019
         SPACE 1                                                        45280019
TESTLAST EQU   *                                                        45360019
         LA    GR5,CCIMAGE+COL70       LAST COLUMN (71)                 45440019
         CR    GR3,GR5                 UP TO COLUMN 71                  45520019
         BCR   MS7,GR9                 NO- CONTINUE                     45580019
         OI    CPARAMSW,DELIMEND       CHARACTER IN COLUMN 71           45640019
         TM    CPARAMSW,COL72BLK       CONTINUATION PUNCH IN COLUMN 72  45680019
         BO    SETCONT                 SET FOR CONTINUED PARAMETER      45740019
         MVI   CCDELIM,BLANKSGN        SET TO STOP SCAN                 45800019
         BR    GR9                     RETURN                           45860019
SETCONT  EQU   *                                                        45920019
         OI    PARMSWCH,COMDPART       SET AS CONTINUED PARAMETER       46000019
         BR    GR9                     RETURN                           46080019
         SPACE 1                                                        46160019
CHKCOMMA EQU   *                                                        46240019
         TM    PARMSWCH,SCANNAME       SCANNING NAME                    46320019
         BZ    CHKIFSTP                NO- CHECK IF CAN STOP (N,R),NAME 46360019
         TM    CPARAMSW,DELIMEND       COMMA IN COLUMN 71               46410019
         BO    CHKCONT                 YES                       A45150 46420021
         CLI   UP1(GR3),BLANKCOL       NEXT COLUMN BLANK         A45150 46422021
         BNE   NOCMBLNK                NO                        A45150 46424021
CHKCONT  EQU   *                                                 A45150 46426021
         TM    PARMSWCH,SET4REPL+HASNEWNM REPLACE/RENAME SPECIFIED      46430019
         BC    MS5,CONTINV             YES ILLEGAL TO CONTINUE          46440019
         TM    CPARAMSW,COL72BLK       PUNCH IN COLUMN 72               46450019
         BZ    CONTINV                 NO- CONTINUATION ERROR           46460019
         CLI   UP1(GR3),BLANKCOL       NEXT COLUMN BLANK                46510019
         BE    BLNKSTP                 YES                              46560019
NOCMBLNK EQU   *                                                 A45150 46610021
         TM    PARMSWCH,SET4REPL       REPLACE EXPECTED                 46640019
         BZ    CHKDUPC            NO - CHECK NEXT COLUMN FIRST          46720019
         NI    PARMSWCH,FF-ONELEFT     RESET LEFT PARENTHESIS SWITCH    46800019
         TM    COMDCDSW,MEMBRCD1       DOING MEMBER SCAN                46880019
         BO    REPMEMB                 YES CHECK RENAME REPLACE         46960019
         SPACE 1                                                        47040019
ON2TST   EQU   *                                                        47120019
         TM    CPARAMSW,DELIMEND                                        47140019
         BO    CONTINV            INVALID TO CONTINUE REPLACE    A48799 47180022
         LA    GR3,UP1(GR3)       UP SCAN POINTER                A48799 47190022
         BAL   GR9,TESTLAST       CHECK IF UP TO COLUMN 71       A48799 47200022
         TM    CPARAMSW,DELIMEND  UP TO COLUMN 71                A48799 47210022
         BO    CONTINV            INVALID TO CONTINUE REPLACE    A48799 47212022
         CLC   SCAN0(LEN2,GR3),RPARN  DOES 'R)' FOLLOW           A48799 47220022
         BNE   BADREPLC           IF NOT, ITS INVALID                   47280019
         LA    GR3,UP1(GR3)       UP SCAN POINTER                A48799 47360022
         BAL   GR9,TESTLAST            CHECK IF UP TO COLUMN 71  A45185 47410022
         SPACE 1                                                        47440019
CHKPARNR EQU   *                                                        47520019
         TM    PARMSWCH,ONELEFT        WAS SWITCH RESET                 47600019
         BO    BADREPLC           IF NOT, INVALID CTL CARD              47680019
         LH    GR6,RGHTPCNT                                             47760019
         LA    GR6,UP1(GR6)            UP COUNT RIGHT PARENS            47840019
         STH   GR6,RGHTPCNT            STORE NEW COUNT                  47920019
         CLC   LEFTPCNT(LEN2),RGHTPCNT COMPARE PARENTHESIS COUNT        47970019
         BNE   CHKIFUNC                CHECK IF STARTED WITH LEFT PAREN 48020019
         TM    CCSWITCH,UNECPARN       STARTED WITH PARENTHESIS         48040019
         BZ    ALLOK                   NO                               48050019
         CLI   UP1(GR3),BLANKCOL       NEXT COLUMN BLANK                48060019
         BNE   MORETEST           KEEP ON                               48082019
         TM    COMDCDSW,MEMBRCD1  MEMBER NAME                           48084019
         BO    ALLOK                   YES,STORE NAME                   48085019
         TM    PARMSWCH,SCANNAME  WAS A NAME BEING SCANNED              48086619
         BO    BLNKSTP                 IF SO, GO TO STORE THE NAME      48087319
         B     ISDONE             DD NAME STORED                        48088019
MORETEST EQU   *                                                        48090019
         CLI   UP1(GR3),PARENLFT       NEXT CHARACTER LEFT PAREN        48092019
         BE    MISSPARN                UNEQUAL PARENTHESIS              48094019
         CLI   UP1(GR3),PARENRGT       NEXT CHARACTER RIGHT PAREN       48096019
         BE    MISSPARN                UNEQUAL PARENTHESIS              48098019
         TM    PARMSWCH,COPYNOW        COPY CARD                 A41802 48100000
         BO    ALLOK                   YES                       A41802 48102000
         B     BADREPLC                INVALID CTL CARD          A41802 48108021
ALLOK    EQU   *                                                        48120019
         TM    PARMSWCH,SCANNAME       SCANNING NAME                    48160019
         BO    NAMEFND                 YES- NAME COMPLETE        A45174 48170022
         TM    CPARAMSW,DELIMEND       UP TO 71                  A45174 48172022
         BO    GOONS                   YES- GET NEXT CARD        A45174 48174022
         B     INDDLOOP                NO- CONTINUE SCAN         A45174 48176022
NAMEFND  EQU   *                                                 A45174 48178022
         TM    CPARAMSW,DELIMEND       UP TO 71                         48186019
         BO    BLNKSTP                 YES- SET AS IF BLANK STOPPED     48196019
         CLI   UP1(GR3),BLANKCOL       IS NEXT COLUMN BLANK             48206019
         BNE   ENDNAME                 NO- END SCAN OF THIS NAME        48220019
         B     BLNKSTP                 SET STOPPED ON BLANK SWITCH      48240019
         SPACE 1                                                        48260019
CHKIFUNC EQU   *                                                        48280019
         TM    CCSWITCH,UNECPARN       STARTED WITH PARENTHESIS         48300019
         BZ    MISSPARN                NO- UNEQUAL PAREN COUNT          48330019
         B     ENDNAME                 STORE NAME                       48360019
         SPACE 1                                                        48400019
MEMBRANL EQU   *                                                        48480019
         TM    COMDCDSW,SELECTSC+EXCLUDES   SELECT OR EXCLUDE           48560019
         BZ    BADMEMBS           IF NEITHER, CANT SAY 'MEMBER'         48640019
         TM    CCSWITCH,IEBCOPYC  IEBCOPY CONTROL STATEMENTS            48660019
         BO    SCANERRM           YES MIXED CODES                       48680019
         TM    COMDCDSW,MEMBRCD1  WAS MEMBER KEYWRD FOUND ALRDY  A38724 48690021
         BO    BADMEMBS           YES-CANT SAY 'MEMBER'          A38724 48700021
         OI    COMDCDSW,MEMBRCD1       SET MEMBER KEYWORD SWITCH        48720019
         TM    CCSWITCH,MULTSE         CONSECUTIVE S/E                  48740019
         BO    STRMEMBS                ADD NAMES TO TABLE               48780019
         MVC   SEBEGIN(LEN4),SESTOP    START OF SE TABLE                48820019
         B     STRMEMBS                START INTERNAL MEMBER NAME SCAN  48880019
         SPACE 1                                                        48960019
REPMEMB  EQU   *                                                        49040019
         LA    GR3,UP1(GR3)            UP TO NEXT NAME                  49120019
         BAL   GR9,TESTLAST            CHECK IF UP TO COLUMN 71         49200019
         CLI   SCAN0(GR3),ADOLLAR      VALID MEMBER NAME CHARACTER      49220019
         BE    OK4NAMEM                YES                              49240019
         CLI   SCAN0(GR3),COMMA        NEXT CHARACTER A COMMA           49300019
         BE    CHK4R                   YES- MUST BE R)                  49360019
         BL    BADPARM            IF LT COMMA, ITS AN INVALID CHARACTER 49420019
OK4NAMEM EQU   *                                                        49480019
         ST    GR3,CSTOREG+SAV4        SAVE POINTER START OF NEW NAME   49540019
         SR    GR10,GR10               SECOND PARAMETER COUNT REGISTER  49600019
         SPACE 1                                                        49680019
NAME2LOP EQU   *                                                        49760019
         LA    GR10,UP1(GR10)          UP NAME CHARACTER COUNT          49810019
         TM    CPARAMSW,DELIMEND                                        49860019
         BO    CONTINV               INVALID TO CONTINUE REPLACE A48799 49869022
         CLI   SCAN0(GR3),ANA          USUAL CHARACTERS IN NAME         49878019
         BNL   OKCHAR                  YES- VALID CHARACTER             49888019
         CLI   SCAN0(GR3),ADOLLAR      A DOLLAR SIGN                    49892019
         BE    OKCHAR                  YES, OK                          49896019
         CLI   SCAN0(GR3),ANAT         AN 'AT' SIGN                     49900019
         BE    OKCHAR                  YES- VALID CHARACTER             49904019
         CLI   SCAN0(GR3),APOUND       A 'POUND' SIGN                   49908019
         BNE   BADPARM                 WILL NOT BE , OR ) HERE          49912019
OKCHAR   EQU   *                                                        49916019
         LA    GR3,UP1(GR3)            POINT TO NEXT CHARACTER          49956019
         BAL   GR9,TESTLAST            TEST IF IN COLUMN 71             50000019
         CLI   SCAN0(GR3),COMMA        COMMA                            50080019
         BL    CHKRTPAR                CHECK IF RIGHT PARENTHESIS       50160019
         BH    NAME2LOP                SCAN TO END OF NAME              50240019
         OI    PARMSWCH,SET4REPL+HASNEWNM  SET REPLACE-NEW NAME SWITCH  50320019
         B     ON2TST                  UP POINTER AND RIGHT PAREN COUNT 50400019
         SPACE 1                                                        50480019
CHKRTPAR EQU   *                                                        50560019
         CLI   SCAN0(GR3),ADOLLAR      VALID MEMBER NAME CHARACTER      50580019
         BE    NAME2LOP                YES                              50600019
         CLI   SCAN0(GR3),PARENRGT     RIGHT PARENTHESIS                50660019
         BNE   BADPARM            IF NOT, ITS AN INVALID CHARACTER      50720019
         NI    PARMSWCH,FF-SET4REPL    RESET REPLACE SWITCH             50800019
         OI    PARMSWCH,HASNEWNM       SET NEW NAME- NO REPLACE         50880019
         B     CHKPARNR                UP RIGHT PAREN COUNT             51040019
         SPACE 1                                                        51120019
CHK4R    EQU   *                                                        51200019
         OI    PARMSWCH,SET4REPL       SET REPLACE- NO NEW NAME SW      51520019
         B     ON2TST                  UP POINTERS                      51620019
         SPACE 1                                                        51760019
MEMBRCD  EQU   *                                                        51840019
         TM    PARMSWCH,HASNEWNM       HAVE A NEW NAME                  51920019
         BZ    ONLYOLD                 NO                               52000019
         OI    TABLE0(GR8),SEBIT2      FLAG AS HAS A NEW NAME           52080019
ONLYOLD  TM    PARMSWCH,SET4REPL       REPLACE OPTION                   52160019
         BZ    NOREPL                  NO REPLACE                       52240019
         OI    TABLE0(GR8),REPLACOP    SET REPLACE OPTION               52320019
NOREPL   EQU   *                                                        52400019
         TM    PARMSWCH,HASNEWNM       NEW NAME                         52480019
         BZ    NAMEDONE           NO                                    52560019
         LA    GR9,LEN8                                                 52640019
         LA    GR8,LEN10(GR8)          UP SE TABLE POINTER              52720019
         CR    GR10,GR9                NEW NAME GREATER THAN 8 BYTES    52800019
         BH    BADPARM            IF SO, ITS TOO LONG                   52880019
         MVC   TABLE0(LEN10,GR8),FLAGBYTS CLEAR FLAGS, BLK NAME SE TAB  52960019
         L     GR1,CSTOREG+SAV4        GET START OF NEW NAME            53040019
         BCTR  GR10,GR0                DECREMENT LENGTH FOR EXECUTE     53120019
         EX    GR10,MOVEDDNM           MOVE MEMBER NAME TO SE TABLE     53200019
         OI    TABLE0(GR8),SEBIT1      FLAG AS THIS IS NEW NAME         53280019
         LH    GR6,ENCT                                                 53360019
         LA    GR6,UP1(GR6)                                             53440019
         STH   GR6,ENCT                UP SE ENTRY COUNT                53520019
         LH    GR6,NNCT1                                                53600019
         LA    GR6,UP1(GR6)            INCREMENT NEW NAME COUNT         53680019
         STH   GR6,NNCT1               STORE UPPED NEW NAME COUNT       53760019
         TM    PARMSWCH,SET4REPL       REPLACE OPTION                   53840019
         BZ    NAMEDONE                NO REPLACE                       53920019
         OI    TABLE0(GR8),SEBIT3      FLAG AS MEMBER REPLACE OPTION    54000019
         SPACE 1                                                        54080019
NAMEDONE EQU   *                                                        54160019
         LA    GR8,LEN10(GR8)          UP TO NEXT SLOT SE TABLE         54240019
         LH    GR6,ENCT                                                 54320019
         LA    GR6,UP1(GR6)                                             54400019
         STH   GR6,ENCT                UP SE ENTRY COUNT                54480019
         NI    PARMSWCH,FF-SET4REPL-HASNEWNM  RESET SWITCHES            54560019
         ST    GR8,SESTOP              END OF SE TABLE                  54640019
         SR    GR7,GR7                                                  54720019
         TM    CCDELIM,BLANKSGN        JUST REACHED A BLANK             54800019
         BZ    INDDLOOP                NO- SCAN TILL BLANK              54880019
         CLI   SCAN0(GR3),COMMA        REALLY STOPPED AT COMMA          54960019
         BNE   SET4READ                NO- ALL DONE                     55040019
         SPACE 1                                                        55120019
CHKCONTY EQU   *                                                        55200019
         TM    CPARAMSW,COL72BLK       PUNCH IN CONTINUE COLUMN 72      55280019
         BZ    CONTINV            IF NOT, SET UP INVALID CONTINUE MSG   55340019
         MVI   CCDELIM,CRESET0         RESET STOPPED ON BLANK SWITCH    55400019
         LA    GR10,SCANSOME           RETURN FROM READING NEXTCARD     55440019
         B     GETPARM                 GET NEXT CARD                    55480019
         SPACE 1                                                        55520019
TYPCPANL EQU   *                                                        55600019
         TM    PARMSWCH,COPYNOW        ON COPY STATEMENT                55680019
         BZ    SCANSEQR                NO- SEQUENCE ERROR               55730019
         TM    CCSWITCH,FIRSTSCN       FIRST ENTRY                      55780019
         BZ    SCANERRM                NO, MIXED MODE                   55810019
         OI    CCSWITCH,IEBCOPYC       FLAG AS IEBCOPY CONTROL CARDS    55840019
         BAL   GR14,RDCARD             GET PARAMETER                    55920019
         CLI   CSTOREG+LEN3,PARCNT  PARAMETER COUNT GREATER THAN 1      56000019
         BNE   BADPARM            IF SO, INVALID CTL STMT               56080019
         L     SCANADR,CSTOREG+SAV4    START OF PARAMETER               56160019
         CLI   SCAN0(SCANADR),EX       E FOR EXCLUDE                    56240019
         BNE   CHKIS                   CHECK IF INCLUSIVE (SELECT)      56320019
         OI    COMDCDSW,EXCLUDES       SET EXCLUDE SWITCH               56400019
         B     CHLAST                  CHECK IF LAST PARAMETER SCANNED  56480019
         SPACE 1                                                        56560019
CHKIS    EQU   *                                                        56640019
         CLI   SCAN0(SCANADR),IN       I FOR SELECT                     56720019
         BNE   BADPARM                 BAD PARAMETER                    56800019
         OI    COMDCDSW,SELECTSC       SET SELECT SWITCH                56880019
         B     CHLAST                  CHECK IF LAST PARAMETER          56960019
         SPACE 1                                                        57040019
BADPARM  EQU   *                                                        57120019
         LA    GR2,INVALSPR                                             57200019
         B     GIVESCNE           PRT CARD, SET RC TO 4, WRT MSG        57300019
         SPACE 1                                                        57440019
INVALODL EQU   *                                                        57520019
         LA    GR2,INVALIST            OUTDD NOT ON COPY CARD           57600019
         B     GIVESCNE           PRT CARD, SET RC TO 4, WRT MSG        57700019
         SPACE 1                                                        57840019
BADMEMBS EQU   *                                                        57920019
         LA    GR2,MEMNOSE                                              58000019
         B     GIVESCNE           PRT CARD, SET RC TO 4, WRT MSG        58100019
         SPACE 1                                                        58150022
CONTINV  EQU   *                                                 A48799 58200022
         LA    GR2,INVALCON            INVALID CONTINUATION      A48799 58210022
         B     GIVESCNE                GIVE MESSAGE              A48799 58220022
         SPACE 1                                                        58240019
BADREPLC EQU   *                                                        58320019
         LA    GR2,INVALREP                                             58400019
         B     GIVESCNE           PRT CARD, SET RC TO 4, WRT MSG        58500019
         SPACE 1                                                        58640019
NORENAME EQU   *                                                        58720019
         LA    GR2,NORREN                                               58800019
         B     GIVESCNE           PRT CARD, SET RC TO 4, WRT MSG        58900019
         SPACE 1                                                        59040019
MISSPARN EQU   *                                                        59120019
         LA    GR2,ONEQPARN       MESSAGE CODE                          59200019
         B     GIVESCNE           PRT CARD, SET RC TO 4, WRT MSG        59500019
         SPACE 1                                                        59840019
PRTNULL1 EQU   *                                                        59860019
         TM    PARMSWCH,FLUSHSW        FLUSHING                         59880019
         BO    IGNORE                  YES- GET NEXT CARD               59910019
NULLP    EQU   *                                                        59940019
         LA    GR2,NULLPARM            NULL PARAMETER MESSAGE           60000019
         B     GIVESCNE           PRT CARD, SET RC TO 4, WRT MSG        60100019
         SPACE 1                                                        60240019
NOINDDSP EQU   *                                                        60320019
         LA    GR2,NOINDD                                               60400019
         B     GIVESEQS                GIVE MESSAGES                    60560019
         SPACE 1                                                        60640019
OUTOFCOR EQU   *                                                        60720019
         LA    GR2,COREGONE                                             60820019
         B     ERRSTOP                 GIVE MESSAGE AND QUIT            60960019
         SPACE 1                                                        61440019
SCANERRM EQU   *                                                        61680019
         LA    GR2,MODEERR                                              61760019
         B     ERRSTOP                 GIVE MESSAGE                     61840019
         SPACE 1                                                        61920019
MULTS    EQU   *                                                        62000019
         LA    GR2,MULTSSEE                                             62080019
         SPACE 1                                                        62240019
GIVESEQS EQU   *                                                        62320019
         BAL   GR11,WRITEOUT      PRT CARD, SET RC TO 4, WRT MSG        62380019
SCANSEQR EQU   *                                                        62440019
         LA    GR2,SEQERROR            STATEMENT SEQUENCE ERROR         62480019
         B     ERRSTOP                 GIVE MESSAGE                     62520019
         SPACE 1                                                        62560019
MSSEQER  EQU   *                                                        62640019
         LA    GR2,SEQERROR                                             62740019
         BAL   GR11,WRITEOUT      PRT CARD, SET RC TO 4, WRT MSG        62760019
         B     NEWSCAN                 SCAN THIS COPY- DON'T FLUSH IT   62780019
         SPACE 1                                                        62800019
COMPEXEC EQU   *                                                        63000019
         LA    GR2,PARMEXEC            MESSAGE NUMBER                   63220019
         LA    GR11,COMPRETN           RETURN TO OUTDD ANAL             63230019
         NI    COMDCDSW,FF-COMPRESS    RESET COMPRESS SWITCH            63240019
         B     SETC4                   GIVE MESSAGE              A44144 63250022
         SPACE 1                                                        63260019
GIVESCNE EQU   *                                                        63280019
         BAL   GR11,WRITEOUT      PRT CARD, SET RC TO 4, WRT MSG        63360019
SCANERR  EQU   *                                                        63440019
         LA    GR2,SCANMSG                                              63540019
ERRSTOP  EQU   *                                                        63680019
         TM    PARMSWCH,FLUSHSW        STATEMENT ERROR WHILE FLUSHING   63760019
         BO    IGNORE             YES                                   63850019
         MVI   PARMSWCH,FLUSHSW        SET FLUSH SWITCH                 63940019
         TM    CPARAMSW,COL72BLK       IS THIS CARD CONTINUED    A48742 63990022
         BZ    WRITEOUT                NO                        A48742 64040022
         OI    SCANSWCH,NOCMMEXP       SET BYPASS SCAN SWITCH    A48742 64090022
         SPACE 1                                                        64160019
WRITEOUT EQU   *                                                        64240019
         TM    CCSWITCH,CARDPRTD       WAS CARD PRINTED                 64246019
         BO    SETC8                   YES                       A44144 64252022
         BAL   GR9,PRNTCRD             PRINT THE CARD                   64258019
SETC8    EQU   *                                                 A44144 64260022
         CLI   RCBUF,COMPCDE           IS RETURN CODE 8 OR MORE  A44144 64262022
         BNL   STRMESS                 YES- DO NOT CHANGE IT     A44144 64262422
         MVI   RCBUF,COMPCDE           SET CODE TO 8             A44144 64262822
         B     STRMESS                 AND STORE MSG NUMBER      A44144 64263222
SETC4    EQU   *                                                        64264019
         CLI   RCBUF,COMPCD            IS COMPLETION CODE 4 OR MORE     64284019
         BNL   STRMESS                 YES- DO NOT CHANGE IT            64320019
         MVI   RCBUF,COMPCD            SET CODE TO 4                    64360019
STRMESS  EQU   *                                                        64400019
         STH   GR2,MSGLIST             STORE MESSAGE NUMBER             64440019
         MVI   MSGLIST,LASTMSG         FLAG AS LAST MESSAGE             64480019
KEEPCODE EQU   *                                                        64660019
         L     GR15,VIEBVMS            MESSAGE WRITER                   64730019
         BALR  GR14,GR15               GIVE THE MESSAGE                 64800019
         TM    PARMSWCH,FLUSHSW        ERROR                            64870019
         BCR   MS8,GR11                RETURN CARD OR MESSAGE PRINTED   64920019
         NI    PARMSWCH,FF-FLUSHSW     RESET FLUSH SWITCH               64970019
         NI    SCANSWCH,FF-NOCMMEXP    RESET BYPASS SCAN SWITCH  A48742 64980022
         MVI   VTMFLG1,UNUSEND         SET SWITCH FOR VTM               65020019
         L     GR15,VIEBVTM            ADDRESS OF TERMINATE ROUTINE     65060019
         BALR  GR14,GR15               ENTER TERMINATE-- NO RETURN      65160019
         SPACE 1                                                        65520019
IEBSEF   EQU   *                       SYSIN EODAD ROUTINE              65600019
IEBSCF   EQU   IEBSEF                                                   65640019
         OI    CCSWITCH,SYSINEOF       FLAG AS END OF FILE SYSIN        65680019
         TM    CPARAMSW,COL72BLK  EOF AFTER CONTINUED CARD              65700019
         BO    CONTINV            YES- INVALID CONTINUATION             65720019
         TM    PARMSWCH,FLUSHSW        EOF WHILE FLUSHING CARDS         65760019
         BO    TERMS                   GIVE EOF MESSAGE AND QUIT        65840019
         TM    COMDCDSW,COPYDONE       HAD A COPY STATEMENT             65920019
         BZ    FULLCOPY                NO- IEBCOPY FULL COPY            66000019
         TM    CCSWITCH,IEBCOPYC       IEBCOPY CONTROL CARDS            66080019
         BO    CHKSMEM                 YES- CHECK IF HAVE ALL CARDS     66160019
         TM    COMDCDSW,NEWOUT+NEWINDD HAD AN OUTDD AND AN INDD         66240019
         BO    GETOUT                  BEGIN COPY                       66320019
         BM    NOINDDSP                NO- SET TO ISSUE ERROR MESSAGE   66400019
         SPACE 1                                                        66480019
FULLCOPY EQU   *                                                        66560019
         OI    CCSWITCH,IEBCOPYC       FLAG AS IEBCOPY STATEMENT        66640019
         BAL   GR9,SET4OLDC            SET UP INDD TABLE ENTRY SYSUT1   66720019
         TM    CCSWITCH,SYSINEOF       LAST CARD AN EOF                 66730019
         BO    SETODS                  YES- DON'T READ ANY MORE CARDS   66740019
         OI    COMDCDSW,COPYDONE       SET AS COPY CARD SCANNED         66750019
         BAL   GR9,READCC              READ ANOTHER CARD                66760019
         SPACE 1                                                        66800019
SETODS   EQU   *                                                        66880019
         OI    FLG4,NEWODS+NEWCOPOP    SET SWITCHES TO INDICATE A NEW   66930019
*                                        COPY OPERATION HAS BEEN FOUND  66980019
         SPACE 1                                                        67040019
GETOUT   EQU   *                                                        67120019
         MVC   COUNT(LEN2),ENCT        NEED SE COUNT EXCLUDE/SELECT     67200019
         TM    COMDCDSW,SELECTSC       SELECT OPERATION                 67280019
         BZ    TESTEX                  NO- EXCLUDE OR FULL COPY         67480019
         MVC   CTAD(LEN4),SEBEGIN      STORE CTAD FOR SELECT COPY       67680019
         B     DOCOPY                  CONTINUE                         68000019
         SPACE 1                                                        68080019
TESTEX   EQU   *                                                        68160019
         XC    NNCT1(LEN2),NNCT1       CLEAR NEW NAME COUNT             68240019
         XC    ENCT(LEN2),ENCT         CLEAR FOR EXCLUDE/FULL           68320019
         MVC   CTAD(LEN4),SESTOP       SET TO SESTOP ON FULL/EXCLUDE    68400019
         TM    COMDCDSW,EXCLUDES       EXCLUSIVE COPY                   68480019
         BO    DOCOPY                  YES- FINISH UP                   68560019
         XC    COUNT(LEN2),COUNT       CLEAR SE COUNT ON FULL COPY      68640019
         MVC   SEBEGIN(LEN4),SESTOP    FULL COPY NO ENTRIES IN SE TABLE 68720019
         SPACE 1                                                        68800019
DOCOPY   EQU   *                                                        69600019
         NI    CCSWITCH,FF-FIRSTSCN    TURN OFF FIRST ENTRY SWITCH      69900019
         L     GR13,LEN4(GR13)         SAVE AREA POINTER                70200019
         RETURN (14,12)                RETURN TO CALLER                 70600019
         SPACE 1                                                        70700019
TERMS    EQU   *                                                        70800019
         LA    GR2,ENDMESS             SYSIN EOF MESSAGE                70900019
         OI    PARMSWCH,FLUSHSW        SET TO RETURN TO TERMINATE       70950019
         OI    IOEF2,NOSYSIN           SET SWITCH FOR VTM               70970019
         B     STRMESS                 GIVE MESSAGE- NO RETURN          71000019
         SPACE 1                                                        71600019
READCC   EQU   *                                                        71680019
         LA    GR0,CCIMAGE             CONTROL CARD BUFFER              71760019
         LA    GR1,CARDCB              SYSIN DCB                        71840019
         LA    GR8,SYSINERX            SYSIN ERROR RETURN ADDRESS       71880019
         GET   (GR1),(GR0)             GET NEXT STATEMENT               71890019
         NI    CCSWITCH,FF-CARDPRTD    RESET CARD PRINTED SWITCH        71910019
         BR    GR9                     RETURN                           71930019
         SPACE 1                                                        71940019
SYSINERX EQU   *                                                        71950019
         MVI   VTMFLG1,UNUSEND         SET SWITCH FOR VTM               71952019
         OI    IOEF2,NOSYSIN                                            71954019
         OI    CCSWITCH,SYSINEOF       FAKE AN EOF READ                 71958019
         OI    PARMSWCH,FLUSHSW        SET FLUSH SWITCH                 71998019
         B     KEEPCODE                GIVE SYNAD MESSAGE               72038019
         SPACE 1                                                        72080019
PRNTCRD  EQU   *                                                        72160019
         MVI   MSGLIST,LASTMSG+CTLCD   SET TO PRINT CONTROL CARD        72460019
         MVI   MSGLIST+UP1,CRESET0     CLEAR MSG NUMBER                 72480019
         L     GR15,VIEBVMS            MESSAGE WRITER                   72510019
         BALR  GR14,GR15               PRINT THE CARD                   72560019
         OI    CCSWITCH,CARDPRTD       SET CARD PRINTED SWITCH          72610019
         BR    GR9                     RETURN- CARD IS PRINTED          72660019
         SPACE 1                                                        72760019
CHKCOPY  EQU   *                       ANALYSE COPY COMMAND             73440019
         TM    PARMSWCH,FLUSHSW        DOING A FLUSH                    73520019
         BO    NEWSCAN                 YES- RESET COMMAND SWITCHES      73600019
         NI    CCSWITCH,FF-COMDNOW-MULTSE  RESET SWITCHES               73680019
         TM    COMDCDSW,COPYDONE       PREVIOUS COPY DONE               73760019
         BZ    NEWSCAN                 NO- SCAN REST OF CARD            73840019
         SPACE 1                                                        73920019
*  NOW MUST ENTER MAINFLOW TO FINISH UP PREVIOUS COPY OPERATION         74000019
         SPACE 1                                                        74080019
KEEPCOPY EQU   *                                                        74120019
         TM    CCSWITCH,IEBCOPYC       HAVE IEBCOPY CONTROL CARDS       74160019
         BO    CHKSMEM                 YES- CHECK IF HAVE ALL CARDS     74240019
         TM    COMDCDSW,NEWINDD        INDD KEYWORD BEFORE COPY         74320019
         BZ    MSSEQER                 NO- SEQUENCE ERROR COPY FOLLOWS  74400019
         NI    COMDCDSW,SELECTSC+EXCLUDES+COMPRESS+LISTSW RESET REST    74480019
         NI    CPARAMSW,COL72BLK       KEEP FLAG COLUMN 72 NOT BLANK ON 74560019
         MVI   CCSWITCH,CRESET0        RESET SWITCH                     74640019
         OI    PARMSWCH,COPYNOW        SET SWITCH TO SHOW COPY PENDING  74680019
         B     GETOUT                  FINISH THIS COPY STEP            74720019
         SPACE 1                                                        74800019
NEWSCAN  EQU   *                                                        74880019
         MVI   PARMSWCH,COPYNOW        SET FOR SCAN, RESET FLUSH        74920019
         NI    SCANSWCH,FF-NOCMMEXP    RESET BYPASS SCAN SWITCH  A48742 74930022
         TM    CCSWITCH,CARDPRTD       IF CONTINUED WAS PRINTED         74960019
         BO    PRNTDONE                ALREADY PRINTED                  75000019
         MVI   LINECT,CRESET0          RESET LINE COUNT TO FORCE HEADER 75040019
         BAL   GR9,PRNTCRD             PRINT HEADER AND COPY CARD       75080019
PRNTDONE EQU   *                                                        75120019
         NI    COMDCDSW,COMPRESS       SAVE COMPRESS FLAG               75200019
         NI    CPARAMSW,FF-PARTPARM-CONTINY  RESET SOME SWITCHES        75240019
         TM    CCSWITCH,LASTPARM       LAST PARAMETER SCANNED           75280019
         BZ    TOSCAN                  NO- GET PARAMETERS               75310019
         TM    CCSWITCH,FIRSTSCN       FIRST ENTRY                      75340019
         BZ    SCANERRM                NO, MIXED CODE                   75370019
         B     FULLCOPY                DO FULL COPY ONLY                75400019
         SPACE 1                                                        75443019
CHKSMEM  EQU   *                                                        75446019
         TM    COMDCDSW,EXCLUDES+SELECTSC  SELECT OR EXCLUDE            75449019
         BZ    SETODS                  NO                               75452019
         TM    COMDCDSW,MEMBRCD1       HAVE MEMBER CARD                 75455019
         BO    SETODS                  YES                              75458019
         TM    COMDCDSW,EXCLUDES       EXCLUSIVE COPY- NO MEMBER NAMES  75461019
         BO    DOFULLY                 DEFAULT TO FULL COPY             75464019
         LA    GR2,NOCOPY              WILL NOT COPY                    75467019
         B     ERRSTOP                 GIVE MESSAGE AND QUIT            75470019
         SPACE 1                                                        75473019
DOFULLY  EQU   *                                                        75476019
         NI    COMDCDSW,FF-EXCLUDES    RESET EXCLUSIVE COPY INDICATOR   75479019
         LA    GR2,DOFULLCP                                             75482019
         BAL   GR11,SETC4              GIVE MESSAGE              A44144 75491022
         BAL   GR9,SET4OLDC            SET UP INDD TABLE                75494019
         B     SETODS                  CONTINUE                         75506019
         EJECT                                                          75520019
*********************************************************************** 75600019
*                      CONTROL STATEMENT ANALYSIS ROUTINES            * 75680019
*********************************************************************** 75760019
         SPACE 1                                                        75840019
RDCARD   EQU   *                                                        75920019
         MVI   CCDELIM,CRESET0         RESET DELIMITER SWITCH           76080019
         ST    GR14,SARG               SAVE RETURN REGISTER             76160019
         TM    CPARAMSW,READ1          IS READ CARD SWITCH ON           76240019
         BZ    GOTCARD                 DON'T READ ANOTHER CARD YET      76320019
         SPACE 1                                                        76400019
KGTCD    EQU   *                                                        76480019
         NI    CPARAMSW,PARTPARM+CONTINY+COL72BLK SAVE ALL CONT SWITS.  76530019
         BAL   GR9,READCC              GET NEXT CARD FROM SYSIN         76640019
         NI    CPARAMSW,FF-COL72BLK    RESET CONTINUED CARD SWITCH      76720019
         CLI   CCIMAGE+COL71,BLANKCOL  COLUMN 72 BLANK                  76800019
         BE    SCANCHK                 YES                       A48742 76880022
         OI    CPARAMSW,COL72BLK       COLUMN 72 NOT BLANK              76960019
SCANCHK  EQU   *                                                 A48742 77010022
         TM    SCANSWCH,NOCMMEXP       SCAN NEEDED               A48742 77020022
         BO    IGNORE                  NO                        A48742 77030022
         B     KPFOL                   START SCAN                A48742 77040022
         SPACE 1                                                        77120019
GOTCARD  EQU   *                                                        77200019
         L     GR3,CSTOREG+SAV8        LOAD ADDRESS OF LAST PASS        77280019
         TM    CPARAMSW,PARMCOME       DOES A PARAMETER FOLLOW          77360019
         BO    SCANCARD                YES- SCAN THE CARD               77440019
         SPACE 1                                                        77520019
KPFOL    EQU   *                                                        77600019
         LA    GR9,KOMMD               RETURN ADDRESS                   77620019
NAMESCAN EQU   *                                                        77640019
         LA    GR3,CCIMAGE             START OF CONTROL STATEMENT       77680019
         CLC   SCAN0(LEN3,GR3),SLASHEOF  /* CARD                        77690019
         BE    IEBSEF                  YES- ENTER EODAD ROUTINE         77700019
         SR    GR7,GR7                 CLEAR COUNT BUFFER               77710019
         LA    GR1,LEN8                                                 77730019
KNAME    EQU   *                                                        77760019
         CLI   SCAN0(GR3),BLANKCOL     IS COLUMN BLANK                  77800019
         BCR   MS8,GR9                 FIRST COLUMN BLANK OR NAME ENDS  77840019
         LA    GR7,UP1(GR7)            UP CHARACTER COUNT               77880019
         CR    GR7,GR1                 NAME GREATER THAN 8 CHARACTERS   77930019
         BH    BADPARM                 YES- INVALID NAME                77960019
         LA    GR3,UP1(GR3)            GO TO NEXT COLUMN                78020019
         B     KNAME                   CHECK FOR BLANK                  78080019
         SPACE 1                                                        78160019
KOMMD    LA    GR3,UP1(GR3)            SPACE TO NEXT COLUMN AFTER NAME  78240019
         LA    GR5,CCIMAGE+COL70       LAST COLUMN (71)                 78320019
         OI    CCSWITCH,COMDNOW        SET COMMAND SWITCH               78400019
KABC     CLI   SCAN0(GR3),BLANKCOL     IS COLUMN BLANK                  78480019
         BNE   SCANCARD                NO- CHECK PARAMETERS             78560019
         CR    GR3,GR5                 IS THIS THE END COLUMN           78640019
         BE    PRTNULL1                YES- END OF CARD REACHED         78720019
         LA    GR3,UP1(GR3)            ADJUST POINTER TO NEXT COLUMN    78800019
         B     KABC                    CONTINUE SCAN                    78880019
         SPACE 1                                                        78960019
SCANCARD EQU   *                                                        79040019
         MVC   CCDELIM2(UP1),CCDELIM   SAVE DELIMETER SWITCH SETTING    79120019
         MVI   CCDELIM,CRESET0         RESET DELIMITER SWITCH           79200019
         LR    GR1,GR3                 SAVE POINTER TO PRESENT COLUMN   79280019
         ST    GR3,CSTOREG+SAV4        SAVE START OF PARAMETER          79320019
         SR    GR7,GR7                 CLEAR LENGTH REGISTER            79360019
         LA    GR5,CCIMAGE+COL70       LAST COLUMN (71)                 79440019
         TM    CPARAMSW,PARTPARM       PARTIAL PARAMETER                79520019
         BZ    KCONT                   NO- CONTINUE                     79620019
         TM    PARMSWCH,COMDPART       COMMAND WORD                     79760019
         BO    DONTRSTC                YES- KEEP COMDNOW SWITCH ON      79840019
         NI    CCSWITCH,FF-COMDNOW     RESET ANALYSING COMMAND SWITCH   79920019
DONTRSTC EQU   *                                                        80000019
         TM    CCSWITCH,CARDPRTD  WAS CARD PRINTED                      80030019
         BO    NOPR               IF SO, DONT PRINT IT AGAIN            80060019
         BAL   GR9,PRNTCRD        ELSE PRINT CONTINUED CARD             80090019
NOPR     EQU   *                                                        80120019
         L     GR1,CSTOREG+SAV4        RESTORE POINTER                  80220019
         TM    CPARAMSW,CONTINY        FROM MEMBER/INDD SCAN            80400019
         BZ    KOMPAR                  NO- CONTINUE SCAN                80480019
         BCTR  GR3,GR0                 BACK UP POINTER BY ONE           80560019
         NI    PARMSWCH,FF-COMDPART    RESET COMDPART SWITCH            80640019
         B     TESTRETN                STORE AND RETURN                 80720019
         SPACE 1                                                        80800019
KFORZRO  EQU   *                                                        80880019
         TM    CCDELIM,BLANKSGN        IS IT A BLANK                    80960019
         BZ    BADPARM                 INVALID NAME/PARAMETER           81040019
         B     NOTFIRST                NO FIRST PARAMETER PART FAKE IT  81120019
         SPACE 1                                                        81200019
KCONT    EQU   *                                                        81280019
         NI    CCSWITCH,FF-LASTPARM    RESET SWITCH                     81360019
         CR    GR3,GR5                 SCANNED BEYOND COLUMN 71         81440019
         BNH   KOMPAR                  NO- CHECK PARAMETERS             81520019
         SPACE 1                                                        81600019
NOTFIRST EQU   *                                                        81680019
         TM    CPARAMSW,COL72BLK       CONTINUATION PUNCH IN 72         81760019
         BZ    CONTINV            IF NOT, CONTINUATION IS INVALID       81840019
         SR    GR7,GR7                 NO COUNT FOR FIRST PARAMETER     81920019
         B     APARM0                  SET UP FOR PARTIAL PARAMETER     82000019
         SPACE 1                                                        82080019
KOMPAR   CLI   SCAN0(GR3),EQUAL        IS CHARACTER A DELIMITER         82160019
         BNH   DELIMIT                 YES-'EQUAL' CHARACTER OR LOWER   82240019
         LA    GR7,UP1(GR7)            ADD ONE TO LENGTH                82320019
         CR    GR3,GR5                 IS THIS THE END COLUMN           82400019
         BE    KPTERR                  YES- SAVE PARTIAL PARAMETER      82480019
         LA    GR3,UP1(GR3)            UP POINTER TO NEXT COLUMN        82560019
         B     KOMPAR                  CONTINUE SCANNING FOR DELIMITER  82640019
         SPACE 1                                                        82720019
KPTERR   EQU   *                                                        82800019
         TM    CCSWITCH,COMDNOW   SCANNING COMMAND WORD                 82880019
         BZ    NOTCOMD                 NO                               82920019
         CLI   SCAN0(GR1),AC           WORD STARTS WITH C               82960019
         BNE   PRTANDGO                NO                               83000019
         TM    COMDCDSW,COPYDONE       MIGHT BE COPY                    83020019
         BO    KEEPCOPY                NOT FIRST COPY                   83040019
         MVI   LINECT,CRESET0          RESET LINE COUNT TO FORCE HEADER 83060019
PRTANDGO EQU   *                                                        83080019
         BAL   GR9,PRNTCRD             PRINT COPY CARD                  83100019
         L     GR1,CSTOREG+SAV4        RESTORE POINTER TO START OF PARM 83150019
         OI    PARMSWCH,COMDPART       SET TO KEEP 'COMDNOW' SET        83200019
NOTCOMD  EQU   *                                                        83280019
         TM    CPARAMSW,COL72BLK       IS COLUMN 72 BLANK               83360019
         BZ    KETBYP                  YES- SET LAST PARM GET NEXT CARD 83440019
KPART    EQU   *                                                        83520019
         LR    GR2,GR7                                                  83600019
         BCTR  GR2,GR0                 DECREMENT FOR EXECUTE            83680019
         EX    GR2,MOVEP               SAVE PARTIAL PARAMETER           83760019
APARM0   EQU   *                                                        83840019
         OI    CPARAMSW,PARTPARM       SET PARTIAL PARAMETER SWITCH     83920019
         ST    GR7,CSTOREG             SAVE PARTIAL PARAMETER COUNT     84000019
         B     KGTCD                   GET NEXT CARD                    84080019
         SPACE 1                                                        84160019
KETBYP   EQU   *                                                        84240019
         OI    CCSWITCH,LASTPARM       NO MORE PARAMETERS               84320019
KPASS    LA    GR3,UP1(GR3)            UP POINTER TO NEXT COLUMN        84400019
KWENT    EQU   *                                                        84480019
         NI    CPARAMSW,FF-READ1-PARMZERO  RESET SWITCHES               84560019
         ST    GR7,CSTOREG             STORE LENGTH REGISTER            84640019
TESTRETN EQU   *                                                        84720019
         L     GR14,SARG               RESTORE RETURN REGISTER          84800019
         ST    GR1,CSTOREG+SAV4        STORE SCAN ADDRESS REGISTER      84880019
         ST    GR3,CSTOREG+SAV8        STORE ADDRESS REGISTER           84960019
         BR    GR14                    RETURN TO MAINSTREAM             85040019
         SPACE 1                                                        85120019
DELIMIT  CR    GR3,GR5                 IS THIS END COLUMN               85200019
         BE    SETCC2                  YES- SET INDICATOR               85280019
         TM    CPARAMSW,PARTPARM       IS PARTIAL PARAMETER SWITCH ON   85360019
         BO    KPPAR                   YES-COMPLETE PARAMETER           85440019
         B     TESTPAR                 CHECK PARAMETER                  85520019
         SPACE 1                                                        85600019
SETCC2   EQU   *                                                        85680019
         OI    CPARAMSW,DELIMEND       SET DELIMITER IN END COLUMN SW   85760019
         CLI   SCAN0(GR3),BLANKCOL     BLANK                            85780019
         BE    ABLNKCOL                YES                              85800019
         TM    CPARAMSW,COL72BLK       PUNCH IN COLUMN 72               85840019
         BZ    CONTINV            IF NOT, CTL STMT IS INVALID           85920019
         TM    CPARAMSW,PARTPARM       PARTIAL PARAMETER                86000019
         BO    CONTINV                 SECOND LEVEL CONTINUATION        86080019
         SPACE 1                                                        86160019
TESTPAR  LTR   GR7,GR7                 TEST IF LENGTH ZERO              86240019
         BC    MS2,DELIM               LENGTH NOT ZERO                  86320019
         OI    CPARAMSW,PARMZERO       SET LENGTH ZERO SWITCH           86400019
         SPACE 1                                                        86480019
DELIM    CLI   SCAN0(GR3),EQUAL        TEST IF DELIMITER IS AN EQUAL    86560019
         BE    KEY                     YES- GO TO KEY WORD ROUTINE      86640019
         CLI   SCAN0(GR3),COMMA        TEST FOR COMMA                   86720019
         BE    PARAMC                  YES- GO TO PARAMETER ROUTINE     86800019
         CLI   SCAN0(GR3),BLANKCOL     TEST FOR BLANK                   86880019
         BNE   BADPARM                 BAD PARAMETER                    86960019
ABLNKCOL EQU   *                                                        87000019
         TM    CCSWITCH,COMDNOW        IS COMMAND SWITCH ON             87040019
         BO    KPCMD                   YES-GO TO ADJUST POINTER         87120019
         MVI   CCDELIM,BLANKSGN        SET BLANK DELIMITER              87200019
DECID    TM    CPARAMSW,DELIMEND       IS DELIMITER IN END COLUMN       87280019
         BO    KWENT                   YES- SET UP COUNT OF FIRST PART  87360019
         TM    CPARAMSW,PARMZERO       LENGTH EQUAL ZERO                87440019
         BO    KFORZRO                 YES- SET UP ZERO LENGTH          87520019
         OI    CPARAMSW,PARMCOME       SET PARAMETER FOLLOWS SWITCH     87600019
         TM    CCDELIM,BLANKSGN        IS IT A BLANK                    87680019
         BZ    KPASS              NO- RETURN WITH POINTERS SET          87760019
         B     KETBYP                  CONTINUE                         87840019
         SPACE 1                                                        87920019
KEY      EQU   *                                                        88000019
         NI    CCSWITCH,FF-COMDNOW     RESET ANALYSING COMMAND SWITCH   88080019
         MVI   CCDELIM,EQUALSGN        SET DELIMITER AN EQUAL           88160019
         CLI   UP1(GR3),BLANKCOL       COLUMN AFTER = BLANK             88240019
         BNE   DECID                   GO TO CHECK DELIMITER            88320019
         TM    COMDCDSW,NEWOUT         HAD AN OUTDD                     88400019
         BZ    NULLP              IF NOT, SET UP NULL PARAMS MSG        88490019
         B     PRTNULL1                PRINT THE CARD                   88580019
         SPACE 1                                                        88720019
PARAMC   EQU   *                                                        88800019
         MVI   CCDELIM,COMMASGN        SET DELIMITER COMMA              88880019
         CLI   UP1(GR3),BLANKCOL       COLUMN AFTER COMMA BLANK         88960019
         BNE   DECID                   NO- CONTINUE                     89040019
         TM    CPARAMSW,COL72BLK       COLUMN 72 BLANK                  89120019
         BZ    CONTINV            IF NOT, CTL STMT IS INVALID           89200019
         B     DECID                   GO TO CHECK DELIMITER            89280019
         SPACE 1                                                        89360019
KPPAR    EQU   *                                                        89440019
        LA    GR9,DELIM               RETURN FROM PARAMETER CREATE      89520019
KCREATE  EQU   *                                                        89600019
         L     GR8,CSTOREG             SIZE OF FIRST PART OF PARAMETER  89680019
         LTR   GR7,GR7            IS LENGTH OF SECOND PART ZERO         89760019
         BC    MS8,KOMPL               YES- THE PARAMETER IS COMPLETE   89840019
         LA    GR6,SAVEPAPR            NO- ADDRESS OF FIRST PART        89920019
         AR    GR6,GR8                 ADDRESS TO MOVE IN SECOND PART   90000019
         LR    GR10,GR7                                                 90080019
         BCTR  GR10,GR0                DECREMENT COUNT FOR EXECUTE      90160019
         EX    GR10,MOVEPP             MOVE SECOND PART TO BUFFER       90240019
KOMPL    AR    GR7,GR8                 TOTAL LENGTH OF PARAMETER        90320019
         LA    GR1,SAVEPAPR            LOAD PARAMETER BUFFER ADDRESS    90400019
         MVC   CCDELIM2(UP1),CCDELIM   SAVE DELIMITER                   90480019
         MVI   CCDELIM,CRESET0         CLEAR DELIMITER SETTINGS         90560019
         NI    CPARAMSW,FF-CONTINY-PARTPARM  RESET CONTINUED SWITCHES   90640019
         NI    PARMSWCH,FF-COMDPART    RESET COMDPART SWITCH            90720019
         BR    GR9                     RETURN                           90800019
         SPACE 1                                                        90880019
KPCMD    LA    GR3,UP1(GR3)            ADJUST POINTER TO NEXT COLUMN    90960019
         CLI   SCAN0(GR3),BLANKCOL     IS COLUMN BLANK                  91040019
         BNE   KPCMA                   NO- CHECK FOR COMMA              91120019
         CR    GR5,GR3                 IS THIS THE LAST COLUMN          91200019
         BE    KETBYP                  YES- NO PARAMETER FOLLOWS        91280019
         B     KPCMD                   CONTINUE SCAN                    91360019
         SPACE 1                                                        91440019
KPCMA    CLI   SCAN0(GR3),COMMA        IS COMMA THE FIRST CHARACTER     91520019
         BE    KETBYP                  YES- NO PARAMETER FOLLOWS        91600019
         BCTR  GR3,GR0                 BACK UP REGISTER 3 TO PARAMETER  91680019
         OI    CPARAMSW,PARMCOME       SET PARAMETER FOLLOWS SWITCH     91760019
         B     KPASS                   GO TO RETURN                     91840019
         SPACE 1                                                        91920019
*                                                                       92000019
*                 EXECUTE STATEMENTS USED IN SCAN ROUTINE               92080019
*                                                                       92160019
         SPACE 1                                                        92240019
MOVEP    MVC   SAVEPAPR(UP1),SCAN0(GR1) STORE PARTIAL PARAMETER         92330019
MOVEPP   MVC   SCAN0(UP1,GR6),SCAN0(GR1) RECREATES PARAMETER            92420019
OPRLUP3  MVC   SARG(UP1),SCAN0(SCANADR)  MOVE TO SEARCH ARGUMENT        92510019
MOVEDDNM MVC   LEN2(UP1,GR8),SCAN0(GR1)  MOVE DD NAME TO INDD TABLE     92600019
MOVEOUTD MVC   DDNAME1(UP1,GR6),SCAN0(SCANADR) MOVE OUTDD NAME - OUTDCB 92690019
         SPACE 1                                                        92800019
LISTALLC DC    C'NO'                   DO NOT LIST MEMBERS COPIED       93360019
RPARN    DC    C'R)'                   FLAGS RENAME OR REPLACE          93520019
SLASHEOF DC    C'/* '                  SIGNALS EOF                      93560019
         SPACE 1                                                        93600019
FLAGBYTS DC    XL10'00004040404040404040'  INDD SE TABLE ENTRY FORM     93680019
BLANKS8  EQU   FLAGBYTS+2              DOUBLE WORD OF BLANKS            93760019
         SPACE 1                                                        93780019
         SPACE 1                                                        93840019
         SPACE 1                                                        94480019
PATCHLEN EQU   (*-IEBSCN)/20      LENGTH OF 5 PER CENT PATCH AREA       94580019
PATCH    DC    XL(PATCHLEN)'00'   5 PER CENT PATCH AREA          A41780 94680021
         EJECT                                                          94920019
         SPACE 1                                                        94960019
         SPACE 1                                                        95040019
         DCBD  DSORG=PS                                                 95340019
BOFLGS   EQU   DCBOFLGS-IHADCB         OPEN FLAGS IN DCB                95640019
DDNAME1  EQU   DCBDDNAM-IHADCB         DD NAME FIELD IN DCB             95940019
SYNADADR EQU   DCBSYNAD-IHADCB         SYNAD ADDRESS IN DCB             96240019
EOFADDRS EQU   DCBEODAD-IHADCB+1       EODAD ADDRESS IN DCB             96540019
         SPACE 1                                                        97120019
         EJECT                                                          97280019
IEBMCA   DSECT                                                          97360019
         IEBMCA                                                         97440019
         SPACE 1                                                        98240019
         END                                                            99040019
