         TITLE 'IEBTCR03 - JFCB ANALYZER - INTRODUCTORY COMMENTARY'     00100019
*                                                                     * 00200019
*TITLE 'IEBTCR03' - JOB FILE CONTROL BLOCK ANALYZER                   * 00300019
*                                                                     * 00400019
*STATUS: CHANGE LEVEL 000                                             * 00500019
*                                                                     * 00600019
*FUNCTION/OPERATION:  IEBTCR03 PERFORMS FIVE FUNCTIONS:               * 00700019
*                                                                     * 00800019
*   1) INSERTION OF ALTERNATIVE DDNAMES IN DCB'S                      * 00900019
*                                                                     * 01000019
*   2) CHECKING OF THE TIOT FOR MISSING DD STATEMENTS                 * 01100019
*                                                                     * 01200019
*   3) EXTRACTION OF DEVICE, VOLUME, AND JOB IDENTIFICATION FROM      * 01300019
*      SYSTEM CONTROL BLOCKS                                          * 01400019
*                                                                     * 01500019
*   4) ANALYSIS OF JOB FILE CONTROL BLOCKS (JFCB'S) TO DETERMINE      * 01600019
*      MISSING DCB PARAMETERS                                         * 01700019
*                                                                     * 01800019
*   5) ASSIGNMENT OF DEFAULTS TO MISSING PARAMETERS                   * 01900019
*                                                                     * 02000019
*   THE JOB FILE CONTROL BLOCK ANALYZER USES THE TASK INPUT/OUTPUT    * 02100019
*   TABLE (TIOT) AND THE UNIT CONTROL BLOCK (UCB) TABLE TO DETERMINE  * 02200019
*   THE DEVICE ALLOCATED TO THE TASK FOR THE SYSUT1 (TCR INPUT) DATA  * 02300019
*   SET.  IT EXTRACTS FROM THE JOB FILE CONTROL BLOCK (JFCB) ANY      * 02400019
*   EXTERNAL IDENTIFICATION ASSOCIATED WITH THE DATA SET BY MEANS OF  * 02500019
*   THE VOLUME=SER=XXXXXX DD STATEMENT PARAMETER. IT REMOVES JOB      * 02600019
*   AND STEP IDENTIFICATION FROM THE TIOT. IT STORES ALL OF THIS      * 02700019
*   INFORMATION IN THE COMMON COMMUNICATION REGION FOR LATER USE BY   * 02800019
*   THE DRIVER (IEBTCRIN) MOUNT ROUTINE.                              * 02900019
*                                                                     * 03000019
*   IF THE ANALYZER DETECTS A MISSING DD STATEMENT (OTHER THAN SYSUT1), 03100019
*   IT SETS A DUMMY FILE INDICATOR FOR THIS DATA SET, SETS AN APPRO-  * 03200019
*   PRIATE MESSAGE INDICATOR, AND ASSIGNS A RETURN CODE OF 4.  IF THE * 03300019
*   DATA SET IS SYSUT1, THE ANALYZER SETS MESSAGE INDICATORS, ESTA-   * 03400019
*   BLISHES A RETURN CODE OF 12, AND RETURNS CONTROL TO THE DRIVER    * 03500019
*   WITH A REQUEST FOR TERMINATION.                                   * 03600019
*                                                                     * 03700019
*   IF THE ANALYZER DETERMINES THAT DCB PARAMETERS WERE OMITTED,      * 03800019
*   IT DEVELOPS COMPLETE OR PARTIAL DEFAULTS DEPENDING UPON THE       * 03900019
*   DATA SET INVOLVED.   FOR SYSIN AND SYSPRINT, COMPLETE DEFAULTS    * 04000019
*   ARE DEVELOPED.  FOR SYSUT2 AND SYSUT3, A RECORD FORMAT INCREMENT  * 04100019
*   IS ASSIGNED AS A BASIC DEFAULT FOR LRECL AND BLKSIZE WITH AN      * 04200019
*   INDICATION THAT MAXLN MUST BE ADDED BY THE DRIVER. FOR VARIABLE   * 04300019
*   LENGTH RECORDS THE INCREMENTS ARE 4 AND 8 BYTES FOR LRECL AND     * 04400019
*   BLKSIZE. FOR UNDEFINED OR FIXED-LENGTH RECORDS, THE INCREMENT IS  * 04500019
*   ZERO.  THE DEFAULTS ARE INSERTED AT OPEN TIME BY THE DRIVER.      * 04600019
*                                                                     * 04700019
*   IF THE USER INCLUDES SOME PARAMETERS (E.G., RECFM) BUT OMITS      * 04800019
*   OTHERS, THE JFCB ANALYZER ATTEMPTS TO SET DEFAULTS WHICH ARE      * 04900019
*   CONSISTENT WITH THE PARAMETERS THAT HAVE BEEN SUPPLIED.  IF       * 05000019
*   THE USER PROVIDES A PARAMETER WHICH IS NOT CONSISTENT WITH        * 05100019
*   DEFAULTS ESTABLISHED FOR KEYWORDS WHICH ARE MISSING, THE JFCB     * 05200019
*   ANALYZER WILL ISSUE A REQUEST FOR TERMINATION.                    * 05300019
         EJECT                                                          05400019
*ENTRY POINTS:                                                        * 05500019
*                                                                       05600019
*        IEBTCR03 - JOB FILE CONTROL BLOCK ANALYZER                   * 05700019
*                                                                     * 05800019
*   THIS MODULE IS LINKED TO BY THE DRIVER MODULE (IEBTCRIN):         * 05900019
*                                                                     * 06000019
*        LINK  EP=IEBTCR03,PARAM=TCRCOM                               * 06100019
*                                                                     * 06200019
*   PARAMETER DATA IS PASSED BY NAME VIA THE COMMON COMMUNICATION     * 06300019
*   REGION AND CONSISTS OF DCB EXIT LISTS, DCB PARAMETER DEFAULT      * 06400019
*   TABLES, AND MISCELLANEOUS DATA STORAGE AREAS.                     * 06500019
*                                                                     * 06600019
*INPUT:                                                               * 06700019
*                                                                     * 06800019
*   1) THE TASK INPUT/OUTPUT TABLE (TIOT)                             * 06900019
*                                                                     * 07000019
*   2) JOB FILE CONTROL BLOCKS (JFCB'S) FOR ALL DATA SETS             * 07100019
*                                                                     * 07200019
*   3) UNIT CONTROL BLOCK (UCB) ASSOCIATED WITH THE SYSUT1 DEVICE     * 07300019
*                                                                     * 07400019
*   ALL OF THESE CONTROL BLOCKS ARE READ THROUGH USE OF STANDARD      * 07500019
*   SYSTEM MACROS.                                                    * 07600019
*                                                                     * 07700019
*OUTPUT:  DCB PARAMETER DEFAULT TABLES                                * 07800019
*                                                                     * 07900019
*   THESE TABLES ARE CONSTRUCTED IN THE COMMON COMMUNICATION REGION   * 08000019
*                                                                     * 08100019
*EXTERNAL ROUTINES:  NONE                                             * 08200019
*                                                                     * 08300019
*EXITS-NORMAL:  NONE                                                  * 08400019
*     -ERROR:   NONE                                                  * 08500019
*                                                                     * 08600019
*TABLES/WORK AREAS:                                                   * 08700019
*                                                                     * 08800019
*   1) DCB EXIT LIST TABLES - INEXLST, PREXLST, UT1EXLST, UT2EXLST,   * 08900019
*      UT3EXLST - THESE TABLES CONTAIN JFCB WORK AREA ADDRESS ENTRIES * 09000019
*      WHICH ARE USED DURING EXECUTION OF THE RDJFCB MACRO INSTRUC-   * 09100019
*      TION.                                                          * 09200019
*                                                                     * 09300019
*   2) DCB DEFAULT TABLES - INLRECL, PRTLRECL, UT2LRECL, UT3LRECL     * 09400019
*      THESE TABLES ARE USED FOR CONSTRUCTING DEFAULTS FOR THE DCB    * 09500019
*      RECFM, LRECL, AND BLKSIZE PARAMETERS.                          * 09600019
*                                                                     * 09700019
*ATTRIBUTES:  NON-REENTRANT AND NON-REUSABLE.                         * 09800019
*                                                                     * 09900019
*NOTES:  THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTI-   * 10000019
*   CULAR INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.      * 10100019
         TITLE 'IEBTCR03 - JFCB ANALYZER - REGISTER DEFINITIONS'        10200019
IEBTCR03 START 0                                                        10300019
         SPACE 2                                                        10400019
*        REGISTER DEFINITIONS                                           10500019
         SPACE 2                                                        10600019
PARMREG  EQU   1                       PARAMETER LIST REGISTER          10700019
COMMREG  EQU   2                       COMMUNICATION REGION             10800019
UCBREG   EQU   6                       UCB REGISTER                     10900019
INCREG   EQU   9                       TIOT INCREMENT                   11000019
TIOTREG  EQU   11                      TIOT REGISTER                    11100019
BASEREG  EQU   12                      BASE REGISTER                    11200019
SAVEREG  EQU   13                      SAVE AREA REGISTER               11300019
RETREG   EQU   14                      RETURN REGISTER                  11400019
LNKREG15 EQU   15                      LINK REGISTER                    11500019
R0       EQU   0                       REGISTER 0                       11600019
R1       EQU   1                       REGISTER 1                       11700019
R3       EQU   3                       REGISTER 3                       11800019
R4       EQU   4                       REGISTER 4                       11900019
R5       EQU   5                       REGISTER 5                       12000019
R6       EQU   6                       REGISTER 6                       12100019
R15      EQU   15                      REGISTER 15                      12200019
         TITLE 'IEBTCR03 - JFCB ANALYZER - PROCESSING ROUTINES'         12300019
*        THIS SECTION SAVES THE CALLING MODULE'S GENERAL REGISTERS,     12400019
*        SETS UP A SAVEAREA ADDRESS, AND ESTABLISHES BASE REGISTERS     12500019
*        FOR THIS MODULE AND FOR THE COMMON COMMUNICATION REGION.       12600019
         SPACE 2                                                        12700019
         SAVE  (14,12),T,IEBTCR03      SAVE REGISTERS                   12800019
         BALR  BASEREG,R0              ESTABLISH BASE REGISTER          12900019
         USING *,BASEREG               INDICATE BASE REGISTER           13000019
         LR    R15,SAVEREG             SET UP SAVE AREA POINTERS        13100019
         ST    R15,SAVEAREA+4                                           13200019
         LA    SAVEREG,SAVEAREA                                         13300019
         ST    SAVEREG,8(R15)                                           13400019
         XR    R15,R15                                                  13500019
         ST    R15,0(SAVEREG)                                           13600019
         L     COMMREG,0(PARMREG)      LOAD COMMUNICATION REGION ADDR   13700019
         USING TCRCOM,COMMREG          INDICATE COMM. REG. BASE REG     13800019
         EJECT                                                          13900019
*        DDNAME INSERTION ROUTINE                                       14000019
         SPACE 1                                                        14100019
*        THIS ROUTINE TESTS AN  INDICATOR IN THE COMMON COMMUNICATION   14200019
*        REGION TO DETERMINE WHETHER OR NOT ALTERNATIVE DDNAMES HAVE    14300019
*        BEEN PROVIDED BY THE USER. IF THEY HAVE BEEN, THIS ROUTINE     14400019
*        INSERTS THEM IN THE RESPECTIVE DCB'S, REPLACING THE STANDARD   14500019
*        NAMES.                                                         14600019
         SPACE 2                                                        14700019
TCR100   TM    MISCIND,DDON            TEST ALTERNATIVE DDNAMES PRESENT 14800019
         BNO   TCR102                  BRANCH NO                        14900019
         USING IHADCB,R3               INDICATE DCB DSECT REG           15000019
         LA    R3,SYSINDCB             LOAD SYSIN DCB ADDRESS           15100019
         MVC   DCBDDNAM(DDLENGTH),NAMETAB  STORE ALTER. SYSIN DDNAME    15200019
         LA    R3,TCRDCB               LOAD SYSUT1 DCB ADDRESS          15300019
         MVC   DCBDDNAM(DDLENGTH),NAMETAB+SYS1DISP  STORE ALTERNATE     15400019
*                                      SYSUT1 DDNAME                    15500019
         LA    R3,SYSPRDCB             LOAD SYSPRINT DCB ADDRESS        15600019
         MVC   DCBDDNAM(DDLENGTH),NAMETAB+SYSPDISP  STORE ALTERNATE     15700019
*                                      SYSPRINT DDNAME                  15800019
         LA    R3,UT2DCB               LOAD SYSUT2 DCB ADDRESS          15900019
         MVC   DCBDDNAM(DDLENGTH),NAMETAB+SYS2DISP  STORE ALTERNATE     16000019
*                                        SYSUT2 DDNAME                  16100019
         LA    R3,UT3DCB               LOAD SYSUT3 DCB ADDRESS          16200019
         MVC   DCBDDNAM(DDLENGTH),NAMETAB+SYS3DISP  STORE ALTERNATE     16300019
*                                      SYSUT3 DDNAME                    16400019
         EJECT                                                          16500019
*        JFCB WORK AREA CORE ALLOCATION ROUTINE                         16600019
         SPACE 1                                                        16700019
*        THIS ROUTINE GETMAINS ONE BLOCK OF CORE FOR ALL OF THE         16800019
*        JFCB WORK AREAS. IT THEN APPORTIONS IT AMONG THE DCB'S         16900019
*        AND STORES THE ADDRESSES IN THE RESPECTIVE EXIT LISTS.         17000019
         SPACE 2                                                        17100019
TCR102   LA    R1,JFCBLN(0,0)          LOAD TOTAL LENGTH - 720 BYTES    17200019
         ST    R1,GETMREQ              STORE MINIMUM LENGTH             17300019
         ST    R1,GETMREQ+4            STORE MAXIMUM LENGTH             17400019
         GETMAIN   VC,LA=GETMREQ,A=GETMADD                              17500019
         L     R1,GETMADD              LOAD STORAGE ADDRESS             17600019
         LTR   R15,R15                 TEST RETURN CODE                 17700019
         BZ    TCR103                  BR IF STORAGE ALLOCATED          17800019
         OI    ERRIND,ALLOCERR         SET ERROR INDICATOR              17900019
         MVI   MSG19,MSGON             SET MSG INDICATOR                18000019
         MVI   RETCODE,CODE16          SET RETURN CODE                  18100019
         B     TCR199                  BR TO RETURN                     18200019
         SPACE 1                                                        18300019
TCR103   ST    R1,JFCBAREA             SAVE STORAGE ADDRESS             18400019
         ST    R1,UT1EXLST             STORE CORE ADDRESS IN SYSUT1     18500019
         MVI   UT1EXLST,UT1JFCB        EXIT LIST                        18600019
         ST    R1,INEXLST              STORE ADDRESS OF CORE IN         18700019
         MVI   INEXLST,JFCBCODE          SYSIN EXLST                    18800019
         LA    R1,JFCBINCR(R1)         INCREMENT TO NEXT STORAGE AREA   18900019
         ST    R1,PREXLST              STORE ADDR OF NEXT AREA IN       19000019
         MVI   PREXLST,JFCBCODE          SYSPRINT EXLST                 19100019
         LA    R1,JFCBINCR(R1)         INCREMENT TO NEXT STORAGE AREA   19200019
         ST    R1,UT2EXLST             STORE ADDR OF NEXT AREA IN       19300019
         MVI   UT2EXLST,JFCBCODE         SYSUT2 EXLST                   19400019
         LA    R1,JFCBINCR(R1)         INCREMENT TO NEXT STORAGE AREA   19500019
         ST    R1,UT3EXLST             STORE ADDR OF NEXT AREA IN       19600019
         MVI   UT3EXLST,JFCBCODE         SYSUT3 EXLST                   19700019
         EJECT                                                          19800019
*        THIS ROUTINE EXTRACTS THE JOB NAME AND STEP NAME FROM THE      19900019
*        TIOT AND STORES IT IN THE COMMON COMMUNICATION REGION FOR      20000019
*        LATER INSERTION IN THE MOUNT MESSAGE BY THE DRIVER. IT ALSO    20100019
*        TESTS WHETHER THE SYSUT1 DD STATEMENT HAS BEEN PROVIDED.       20200019
*        IF IT HAS NOT, IT SETS MSG AND ERROR INDICATORS AND SETS THE   20300019
*        RETURN CODE TO 12. IF IT HAS BEEN, IT EXTRACTS THE DEVICE NAME 20400019
*        FROM THE UCB AND STORES IT IN THE COMMON COMMUNICATION         20500019
*        REGION.                                                        20600019
         SPACE 2                                                        20700019
         EXTRACT  TIOTADR,FIELDS=TIOT  GET TIOT ADDRESS                 20800019
         L     TIOTREG,TIOTADR         LOAD TIOT ADDRESS                20900019
         MVC   JOBNAME(8),TIOCNJOB(TIOTREG)  STORE JOB NAME             21000019
         MVC   STEPNAME(8),TIOCSTP(TIOTREG)  STORE STEP NAME            21100019
         MVC   NAMEHOLD,NAMETAB+16     LOAD SYSUT1 DDNAME               21200019
         MVI   TIOTDDNM,HEXZERO        CLEAR INDICATOR                  21300019
         BAL   RETREG,TCR720           LOAD ADDR COMPARE RTN            21400019
         TM    TIOTDDNM,NAMEFND        SYSUT1 FOUND                     21500019
         BO    TCR105                  BR IF FOUND                      21600019
         OI    ERRIND,JFCBERR          SET ERROR INDICATOR              21700019
         MVI   MSG10,MSGON             SET  MSG INDICATOR               21800019
         MVI   RETCODE,CODE12          SET RETURN CODE  12              21900019
         B     TCR107                  BR TO CONTINUE PROC              22000019
         SPACE 1                                                        22100019
TCR105   L     UCBREG,UCBDISP(TIOTREG) LOAD ADDR OF UCB                 22200019
         LA    UCBREG,0(UCBREG)        CLEAR HIGH-ORDER BYTE            22300019
         MVC   TCRDEV(DEVLNGTH),DEVDISP(UCBREG)  MOVE DEVICE NAME       22400019
         EJECT                                                          22500019
*        THIS ROUTINE TESTS WHETHER OR NOT THE SYSPRINT AND SYSIN       22600019
*        DD STATEMENTS HAVE BEEN PROVIDED.  IF EITHER OR BOTH HAVE      22700019
*        NOT, MESSAGE INDICATORS ARE SET AND THE RETURN CODE IS SET     22800019
*        TO 04.                                                         22900019
         SPACE 2                                                        23000019
TCR107   MVC   NAMEHOLD,NAMETAB+8      LOAD SYSPRINT DDNAME             23100019
         MVI   TIOTDDNM,HEXZERO        CLEAR INDICATOR                  23200019
         BAL   RETREG,TCR720           LOAD ADDR COMPARE RTN            23300019
         TM    TIOTDDNM,NAMEFND        SYSPRINT FOUND                   23400019
         BO    TCR109                  BR IF FOUND                      23500019
         OI    DUMMYIND,DUMSYSP        SET SYSPRINT DUMMY INDICATOR     23600019
         MVI   MSG12,MSGON             SET MSG INDICATOR                23700019
         CLI   RETCODE,CODE04          CURRENT RETURN CODE GREATER      23800019
*                                        THAN 04                        23900019
         BNL   TCR109                  BR HIGH OR EQUAL                 24000019
         MVI   RETCODE,CODE04          SET RETURN CODE 04               24100019
*                                                                       24200019
TCR109   MVC   NAMEHOLD,NAMETAB        LOAD SYSIN DDNAME                24300019
         MVI   TIOTDDNM,HEXZERO        CLEAR INDICATOR                  24400019
         BAL   RETREG,TCR720           LOAD ADDR COMPARE RTN            24500019
         TM    TIOTDDNM,NAMEFND        SYSIN FOUND                      24600019
         BO    TCR111                  BR IF FOUND                      24700019
         OI    DUMMYIND,DUMSYSIN       SET SYSIN DUMMY INDICATOR        24800019
         MVI   MSG11,MSGON             SET MSG INDICATOR                24900019
         CLI   RETCODE,CODE04          CURRENT RETURN CODE GREATER      25000019
*                                        THAN 04                        25100019
         BNL   TCR111                  BR HIGH OR EQUAL                 25200019
         MVI   RETCODE,CODE04          SET RETURN CODE 04               25300019
         EJECT                                                          25400019
*        THIS ROUTINE TESTS WHETHER SYSUT2 AND SYSUT3 DD STATEMENTS     25500019
*        HAVE BEEN PROVIDED. IF THEY HAVE NOT BEEN, MESSAGE INDI-       25600019
*        CATORS ARE SET AND THE RETURN CODE IS SET TO 04.               25700019
         SPACE 2                                                        25800019
*                                                                       25900019
TCR111   MVC   NAMEHOLD,NAMETAB+24     LOAD SYSUT2 DDNAME               26000019
         MVI   TIOTDDNM,HEXZERO        CLEAR INDICATOR                  26100019
         BAL   RETREG,TCR720           LOAD ADDR COMPARE RTN            26200019
         TM    TIOTDDNM,NAMEFND        SYSUT2 FOUND                     26300019
         BO    TCR113                  BR IF FOUND                      26400019
         OI    DUMMYIND,DUMSYS2        SET SYSUT2 DUMMY INDICATOR       26500019
         MVI   MSG13,MSGON             SET MSG INDICATOR                26600019
         MVI   MSG13+1,INSUT2          SET MSG INSERT POINTER           26700019
         CLI   RETCODE,CODE04          CURRENT RETURN CODE GREATER      26800019
*                                        THAN 04                        26900019
         BNL   TCR113                  BR HIGH OR EQUAL                 27000019
         MVI   RETCODE,CODE04          SET RETURN CODE 04               27100019
*                                                                       27200019
TCR113   MVC   NAMEHOLD,NAMETAB+32     LOAD SYSUT3 DDNAME               27300019
         MVI   TIOTDDNM,HEXZERO        CLEAR INDICATOR                  27400019
         BAL   RETREG,TCR720           LOAD ADDR COMPARE RTN            27500019
         TM    TIOTDDNM,NAMEFND        SYSUT3 FOUND                     27600019
         BO    TCR119                  BR IF FOUND                      27700019
         OI    DUMMYIND,DUMSYS3        SET SYSUT3 DUMMY INDICATOR       27800019
         MVI   MSG13,MSGON             SET MSG INDICATOR                27900019
         CLI   RETCODE,CODE04          CURRENT RETURN CODE GREATER      28000019
*                                        THAN 04                        28100019
         BNL   TCR115                  BR HIGH OR EQUAL                 28200019
         MVI   RETCODE,CODE04          SET RETURN CODE 04               28300019
TCR115   CLI   MSG13+1,HEXZERO         SYSUT2 INSERT SET                28400019
         BE    TCR117                  BR  NO                           28500019
         MVI   MSG13+1,INSUT23         SET BOTH INSERTS                 28600019
         B     TCR119                  BR TO CONTINUE PROCESSING        28700019
TCR117   MVI   MSG13+1,INSUT3          SET SYSUT3 INSERT ONLY           28800019
         EJECT                                                          28900019
*        JFCB READ ROUTINE                                              29000019
         SPACE 1                                                        29100019
*        THIS ROUTINE READS THE JFCBS INTO THE GETMAINED STORAGE        29200019
*        AREAS.                                                         29300019
         SPACE 2                                                        29400019
TCR119   LA    R3,SYSINDCB                                              29500019
         LA    R4,SYSPRDCB                                              29600019
         LA    R5,UT2DCB                                                29700019
         LA    R6,UT3DCB                                                29800019
         RDJFCB  ((R3),,(R4),,(R5),,(R6))                               29900019
         EJECT                                                          30000019
*        THE FOLLOWING ROUTINES SET DEFAULTS WHERE REQUIRED.            30100019
*        IN THE CASE OF SYSUT2 AND SYSUT3 ONLY PARTIAL DEFAULTS         30200019
*        ARE CREATED IF LRECL HAS BEEN OMITTED.  THIS DEFAULT           30300019
*        CONSISTS OF 4 AND 8 BYTES FOR LRECL AND BLKSIZE, RESP.,        30400019
*        IF THE RECORD FORMAT IS VARIABLE.  IF THE FORMAT IS            30500019
*        FIXED OR UNDEFINED, THE DEFAULT IS ZERO.                       30600019
         SPACE 2                                                        30700019
*        SYSIN DEFAULT ROUTINE                                          30800019
         SPACE 1                                                        30900019
         TM    DUMMYIND,DUMSYSIN       SYSIN DUMMY                      31000019
         BO    TCR121                  BR IF YES                        31100019
         LA    R4,INLRECL              LOAD SYSIN DEFAULT LIST ADDR     31200019
         L     R5,INEXLST              LOAD JFCB ADDRESS                31300019
         LA    R5,0(R5)                                                 31400019
         BAL   RETREG,TCR210           LOAD ADDR DEFAULT RTN            31500019
         SPACE 1                                                        31600019
*        SYSPRINT DEFAULT ROUTINE                                       31700019
         SPACE 1                                                        31800019
TCR121   TM    DUMMYIND,DUMSYSP        SYSPRINT DUMMY                   31900019
         BO    TCR123                  BR IF YES                        32000019
         LA    R4,PRTLRECL             LOAD SYSPRINT DEFAULT LIST ADDR  32100019
         L     R5,PREXLST              LOAD JFCB ADDRESS                32200019
         LA    R5,0(R5)                                                 32300019
         BAL   RETREG,TCR210           LOAD ADDR DEFAULT RTN            32400019
         SPACE 1                                                        32500019
*        SYSUT2 DEFAULT ROUTINE                                         32600019
         SPACE 1                                                        32700019
TCR123   TM    DUMMYIND,DUMSYS2        SYSUT2 DUMMY                     32800019
         BO    TCR125                  BR YES                           32900019
         LA    R4,UT2LRECL             LOAD SYSUT2   DEFAULT LIST ADDR  33000019
         L     R5,UT2EXLST             LOAD JFCB ADDRESS                33100019
         LA    R5,0(R5)                                                 33200019
         BAL   RETREG,TCR210           LOAD ADDR DEFAULT RTN            33300019
         TM    MAXIND,MAXLRECL         MAXLN REQUIRED                   33400019
         BNO   TCR1235                 BR NO                            33500019
         OI    MISCIND,UT2LRLMX        SET UT2 MAXLN INDICATOR          33600019
TCR1235  TM    MAXIND,MAXBLK           MAXLN REQUIRED                   33700019
         BNO   TCR125                  BR NO                            33800019
         OI    MISCIND,UT2BLKMX        SET UT2 MAXLN INDICATOR          33900019
         SPACE 1                                                        34000019
*        SYSUT3 DEFAULT ROUTINE                                         34100019
         SPACE 1                                                        34200019
TCR125   TM    DUMMYIND,DUMSYS3        SYSUT3 DUMMY                     34300019
         BO    TCR130                  BR YES                           34400019
         LA    R4,UT3LRECL             LOAD SYSUT3  DEFAULT LIST ADDR   34500019
         L     R5,UT3EXLST             LOAD JFCB ADDRESS                34600019
         LA    R5,0(R5)                CLEAR HIGH-ORDER BYTE            34700019
         BAL   RETREG,TCR210           LOAD ADDR DEFAULT RTN            34800019
         TM    MAXIND,MAXLRECL         MAXLN REQUIRED                   34900019
         BNO   TCR127                  BR NO                            35000019
         OI    MISCIND,UT3LRLMX        SET UT3 MAXLN INDICATOR          35100019
TCR127   TM    MAXIND,MAXBLK           MAXLN REQUIRED                   35200019
         BNO   TCR130                  BR NO                            35300019
         OI    MISCIND,UT3BLKMX        SET UT3 MAXLN INDICATOR          35400019
         EJECT                                                          35500019
*        THIS ROUTINE STORES THE VOLUME SERIAL NUMBER IF ONE HAS BEEN   35600019
*        PROVIDED                                                       35700019
         SPACE 2                                                        35800019
TCR130   LA    R3,TCRDCB               LOAD ADDRESS SYSUT1 DCB          35900019
         RDJFCB  ((R3))                READ SYSUT1 JFCB                 36000019
         L     R5,JFCBAREA             LOAD GETMAINED STORAGE ADDRESS   36100019
         USING JFCBD,R5                INDICATE JFCB DSECT REG          36200019
         CLI   JFCBNVOL,HEXZERO        TEST VOLUME SERIALS PRESENT      36300019
         BE    TCR132                  BR IF NO VOLUME SERIALS          36400019
         MVC   VOLSER,JFCBVOLS         STORE FIRST VOLUME SERIAL        36500019
         B     TCR199                  BR TO RETURN                     36600019
*                                                                       36700019
TCR132   MVC   VOLSER,DEFVOL           STORE DEFAULT VOLUME SERIAL      36800019
         SPACE 2                                                        36900019
*        THIS ROUTINE FREES THE JFCB WORK AREAS AND RETURNS CONTROL     37000019
*        TO THE DRIVER AFTER RELOADING THE GENERAL REGISTERS            37100019
         SPACE 2                                                        37200019
TCR199   L     R1,JFCBAREA                                              37300019
         FREEMAIN  R,LV=720,A=(1)                                       37400019
         L     SAVEREG,4(SAVEREG)                                       37500019
         RETURN (14,12),T,RC=(15)      RETURN                           37600019
         EJECT                                                          37700019
*        DCB PARAMETER DEFAULT CONSTRUCTION SUBROUTINE                  37800019
         SPACE 1                                                        37900019
*        PARAMETERS PASSED ARE AS FOLLOWS:                              38000019
         SPACE 1                                                        38100019
*              REG 4 - DCB DEFAULT LIST ADDRESS                         38200019
*              REG 5 - JFCB WORK AREA ADDRESS                           38300019
         SPACE 1                                                        38400019
*        THIS ROUTINE FIRST LOOKS AT THE JFCB RECFM PARAMETER TO        38500019
*        DETERMINE WHETHER OR NOT THIS PARAMETER WAS SUPPLIED BY THE    38600019
*        USER. IF IT WAS SUPPLIED, IT REPLACES THE DEFAULT PARAMETER    38700019
*        IN THE DEFAULT TABLE WITH THE JFCB  PARAMETER.  IT THEN TESTS  38800019
*        WHETHER THE RESULTING RECORD FORMAT IS VARIABLE.  IF IT IS,    38900019
*        IT INCREMENTS THE DEFAULT LRECL PARAMETER BY FOUR BYTES AND    39000019
*        THE BLKSIZE PARAMETER BY EIGHT BYTES.  NO MATTER WHAT RECORD   39100019
*        FORMAT HAS BEEN REQUESTED, IT NEXT TESTS WHETHER THE LRECL     39200019
*        PARAMETER WAS PROVIDED.  IF IT WAS, IT REPLACES THE DEFAULT    39300019
*        LRECL AND BLKSIZE PARAMETERS WITH THIS VALUE AND CLEARS THE    39400019
*        MAXLN REQUIRED INDICATORS.  IF VARIABLE-LENGTH  RECORDS WERE   39500019
*        SPECIFIED, IT INCREMENTS THIS BLKSIZE VALUE BY FOUR BYTES.     39600019
*        IT THEN TESTS WHETHER OR NOT THE BLKSIZE PARAMETER WAS         39700019
*        PROVIDED.  IF IT WAS PROVIDED, IT REPLACES THE DEFAULT         39800019
*        VALUE WITH THE JFCB VALUE AND CLEARS THE MAXLN REQUIRED        39900019
*        INDICATOR.   IT NEXT TESTS WHETHER UNDEFINED RECORDS           40000019
*        WERE SPECIFIED. IF THEY WERE, THE ROUTINE ZEROES OUT THE       40100019
*        LRECL FIELD.                                                   40200019
         SPACE 2                                                        40300019
TCR210   ST    RETREG,SAVE100                                           40400019
         USING JFCBD,R5                INDICATE JFCB DSECT REG          40500019
         MVI   MAXIND,MAXLB            SET MAXLN REQUIRED INDICATOR     40600019
         CLI   JFCRECFM,HEXZERO        TEST JFCB RECFM ZERO             40700019
         BE    TCR211                  BR IF YES                        40800019
         MVC   4(1,R4),JFCRECFM        STORE JFCB RECFM IN DEFAULT TABL 40900019
         SPACE 1                                                        41000019
TCR211   TM    4(R4),VARFM             TEST VARIABLE                    41100019
         BO    TCR213                  BR NOT VARIABLE                  41200019
         LH    R6,0(R4)                INCREMENT LRECL BY FOUR          41300019
         LA    R6,4(R6)                                                 41400019
         STH   R6,0(R4)                                                 41500019
         LA    R6,4(R6)                INCREMENT BLOCKSIZE BY EIGHT     41600019
         STH   R6,2(R4)                                                 41700019
         SPACE 1                                                        41800019
TCR213   CLC   JFCLRECL(2),HEXZEROS    TEST LRECL PRESENT               41900019
         BE    TCR215                  BR IF NO                         42000019
         NI    MAXIND,X'FF'-MAXLRECL-MAXBLK CLEAR MAXLN INDICATORS      42100019
         MVC   0(2,R4),JFCLRECL        MOVE LRECL TO DEFAULT LRECL      42200019
         MVC   2(2,R4),JFCLRECL        MOVE LRECL TO DEFAULT BLKSIZE    42300019
         TM    4(R4),VARFM             TEST VARIABLE                    42400019
         BO    TCR215                  BR NOT VARIABLE                  42500019
         LH    R6,2(R4)                INCREMENT BLOCKSIZE BY FOUR      42600019
         AH    R6,FOUR                                                  42700019
         STH   R6,2(R4)                                                 42800019
         SPACE 1                                                        42900019
TCR215   CLC   JFCBLKSI,HEXZEROS       TEST BLKSIZE PRESENT             43000019
         BE    TCR217                  BR IF NO                         43100019
         MVC   2(2,R4),JFCBLKSI        MOVE BLKSIZE TO DEFAULT BLKSIZE  43200019
         NI    MAXIND,X'FF'-MAXBLK     CLEAR MAXLN INDICATOR            43300019
TCR217   TM    4(R4),UNDEF             TEST UNDEF FORMAT                43400019
         BNO   TCR219                  BR IF NO                         43500019
         MVC   0(2,R4),HEXZEROS        MOVE ZEROES TO LRECL             43600019
         SPACE 1                                                        43700019
TCR219   L     RETREG,SAVE100          LOAD RETURN ADDRESS              43800019
         BR    RETREG                  RETURN                           43900019
         EJECT                                                          44000019
*        TIOT DDNAME CHECKING SUBROUTINE                                44100019
         SPACE 2                                                        44200019
*        PARAMETERS PASSED:                                             44300019
         SPACE 1                                                        44400019
*              1) DDNAME - VIA THE STORAGE AREA NAMEHOLD                44500019
*              2) FOUND/NOT FOUND INDICATOR - VIA THE STORAGE AREA      44600019
*                 TIOTDDNM                                              44700019
         SPACE 1                                                        44800019
*        THIS ROUTINE COMPARES THE DDNAME INDICATED TO EACH ENTRY OF    44900019
*        THE TASK INPUT/OUTPUT TABLE                                    45000019
         SPACE 2                                                        45100019
TCR720   ST    RETREG,SAVE100          SAVE RETURN ADDRESS              45200019
         L     TIOTREG,TIOTADR         LOAD TIOT ADDRESS                45300019
         LA    TIOTREG,24(TIOTREG)     ADDR OF FIRST DD ENTRY           45400019
         XR    INCREG,INCREG           ZERO INCR REGISTER               45500019
TCR722   CLC   NAMEHOLD,4(TIOTREG)     COMPARE DDNAMES                  45600019
         BNE   TCR724                  BR UNEQUAL                       45700019
         OI    TIOTDDNM,NAMEFND        SET FOUND INDICATOR              45800019
         B     TCR729                  BR TO RETURN                     45900019
         SPACE 1                                                        46000019
TCR724   IC    INCREG,0(TIOTREG)       INSERT INCREMENT                 46100019
         LA    TIOTREG,0(TIOTREG,INCREG)  ADDR OF NEXT DD ENTRY         46200019
         CLC   ZERO(ETLNG,TIOTREG),ENDTIOT  END OF TIOT?                46300019
         BNE   TCR722                  BR NO                            46400019
         SPACE 1                                                        46500019
TCR729   L     RETREG,SAVE100          LOAD RETURN ADDRESS              46600019
         BR    RETREG                  RETURN                           46700019
  TITLE 'IEBTCR03 - JFCB ANALYZER - LITERALS AND STORAGE AREAS'         46800019
*        LITERALS                                                       46900019
         SPACE 2                                                        47000019
NULL     EQU   *                       NULL LABEL                       47100019
NAMEFND  EQU   X'01'                   DDNAME FOUND IN TIOT             47200019
HEXZERO  EQU   X'00'                   HEXIDECIMAL ZERO                 47300019
ZERO     EQU   0                       ZERO                             47400019
ETLNG    EQU   4                       END TIOT INDICATOR LENGTH        47500019
MSGON    EQU   X'FF'                   MSG REQUIRED                     47600019
UCBDISP  EQU   16                      UCB DISPLACEMENT                 47700019
MAXLRECL EQU   X'01'                   LRECL MAY REQUIRE MAXLN          47800019
MAXBLK   EQU   X'02'                   BLKSIZE MAY REQUIRE MAXLN        47900019
MAXLB    EQU   X'03'                   BOTH MAY REQUIRE MAXLN           48000019
DDON     EQU   X'01'                   ALTERNATE DDNAMES                48100019
         SPACE 1                                                        48200019
JFCBCODE EQU   X'07'                   EXIT LIST JFCB CODE              48300019
JFCBINCR EQU   180                     JFCB STORAGE INCREMENT           48400019
JFCBLN   EQU   720                     TOTAL JFCB WORK AREA LENGTH      48500019
DDLENGTH EQU   8                       DDNAME LENGTH                    48600019
JFCBERR  EQU   X'10'                   ERROR IN READING JFCB            48700019
         SPACE 1                                                        48800019
UT3BLKMX EQU   X'02'                   UT3 BLKSIZE REQUIRES MAXLN       48900019
UT3LRLMX EQU   X'04'                   UT3 LRECL REQUIRES MAXLN         49000019
UT2BLKMX EQU   X'08'                   UT2 BLKSIZE REQUIRES MAXLN       49100019
UT2LRLMX EQU   X'10'                   UT2 LRECL REQUIRES MAXLN         49200019
         SPACE 1                                                        49300019
DUMSYSIN EQU   X'01'                   DUMMY SYSIN                      49400019
DUMSYSP  EQU   X'02'                   DUMMY SYSPRINT                   49500019
DUMSYS2  EQU   X'04'                   DUMMY SYSUT2                     49600019
DUMSYS3  EQU   X'08'                   DUMMY SYSUT3                     49700019
         SPACE 1                                                        49800019
INSUT2   EQU   X'04'                   INSERT SYSUT2                    49900019
INSUT3   EQU   X'05'                   INSERT SYSUT3                    50000019
INSUT23  EQU   X'54'                   INSERT SYSUT2 & 3                50100019
         SPACE 1                                                        50200019
SYSPDISP EQU   8                       SYSPRINT DDNAME DISPLACEMENT     50300019
SYS1DISP EQU   16                      SYSUT1 DDNAME DISPLACEMENT       50400019
SYS2DISP EQU   24                      SYSUT2 DDNAME DISPLACEMENT       50500019
SYS3DISP EQU   32                      SYSUT3 DDNAME DISPLACEMENT       50600019
         SPACE 1                                                        50700019
UNDEF    EQU   X'C0'                   UNDEFINED RECORD FORMAT          50800019
ALLOCERR EQU   X'40'                   STORAGE ALLOCATION ERROR         50900019
DEVLNGTH EQU   3                       DEVICE LENGTH                    51000019
DEVDISP  EQU   13                      DEVICE DISPLACEMENT              51100019
VARFM    EQU   X'80'                   NOT VARIABLE IF ON               51200019
UT1JFCB  EQU   X'87'                   EXIT LIST CODE                   51300019
TIOCNJOB EQU   0                       TIOT JOB NAME FIELD              51400019
TIOCSTP  EQU   8                       TIOT STEP NAME FIELD             51500019
         SPACE 2                                                        51600019
*        RETURN CODES                                                   51700019
         SPACE 1                                                        51800019
CODE04   EQU   X'04'                   RETURN CODE 04                   51900019
CODE12   EQU   X'0C'                   RETURN CODE 12                   52000019
CODE16   EQU   X'10'                   RETURN CODE 16                   52100019
         SPACE 1                                                        52200019
*        CONSTANTS, WORK AREAS, SAVE AREAS, INDICATORS                  52300019
         SPACE 1                                                        52400019
GETMREQ  DS    D                       MINIMUM AND MAXIMUM LENGTH       52500019
GETMADD  DS    D                       STORAGE ADDRESS AND LENGTH       52600019
ENDTIOT  DC    F'0'                    END OF TIOT INDICATOR            52700019
TIOTADR  DS    F                       TIOT ADDRESS                     52800019
NAMEHOLD DS    CL8                     DDNAME HOLD AREA                 52900019
         SPACE 1                                                        53000019
SAVEAREA DS    18F                     REGISTER SAVE AREA               53100019
SAVE100  DS    F                       SAVE AREA                        53200019
         SPACE 1                                                        53300019
         DS    0H                      FORCE HALF-WORD ALIGNMENT        53400019
HEXZEROS DC    X'0000'                 HEX ZEROES                       53500019
FOUR     DC    X'0004'                 BINARY FOUR                      53600019
TIOTDDNM DC    X'00'                   TIOT DDNAME                      53700019
MAXIND   DC    X'00'                   INCREMENT BY MAXLN INDICATOR     53800019
DEFVOL   DC    CL6'TCRINP'             DEFAULT VOLUME IDENTIFICATION    53900019
  TITLE 'IEBTCR03 - JFCB ANALYZER - COMMON COMMUNICATION REGION DSECT'  54000019
*        COMMON COMMUNICATION REGION                                    54100019
         SPACE 1                                                        54200019
*        THIS CSECT CONTAINS TABLES, INDICATORS, CONSTANTS, WORK        54300019
*        AREAS, AND DCB'S THAT ARE USED BY TWO OR MORE MODULES.         54400019
         SPACE 2                                                        54500019
TCRCOM   DSECT                                                          54600019
         SPACE 1                                                        54700019
         DS    0F                      FORCE FULL-WORD ALIGNMENT        54800019
OPTABLE  DS    0CL8                    CONTROL CARD OPTION TABLE        54900019
         SPACE 1                                                        55000019
IEXITS   DC    X'00'                   USER ROUTINE INDICATORS          55100019
         SPACE 1                                                        55200019
*              BIT 0 - OUTHDR2                                          55300019
*                  1 - OUTTLR2                                          55400019
*                  2 - OUTHDR3                                          55500019
*                  3 - OUTTLR3                                          55600019
*                  4 - OUTREC                                           55700019
*                  5 - ERROR                                            55800019
*                  6 - USERTAB                                          55900019
*                  7 - NOT USED                                         56000019
         SPACE 1                                                        56100019
IPARM1   DC    X'00'                   TYPE AND TRANS INDICATORS        56200019
         SPACE 1                                                        56300019
*              BIT 0 - TYPE = MTST                                      56400019
*                  1 - TYPE = MTDI                                      56500019
*                  2 - UNUSED                                           56600019
*                  3 - TRANS = STDUC                                    56700019
*                  4 - TRANS = STDLC                                    56800019
*                  5 - TRANS = USERNAME                                 56900019
*                  6 - TRANS = NOTRAN                                   57000019
*                  7 - NOT USED                                         57100019
         SPACE 1                                                        57200019
IPARM2   DC    X'00'                   EDIT, VERCHK, AND ERROPT         57300019
*                                        INDICATORS                     57400019
         SPACE 1                                                        57500019
*              BIT 0 - EDIT = EDITD                                     57600019
*                  1 - EDIT = EDITR                                     57700019
*                  2 - EDIT = NOEDIT                                    57800019
*                  3 - VERCHK = VOKCHK                                  57900019
*                  4 - VERCHK = NOCHK                                   58000019
*                  5 - ERROPT = NORMAL                                  58100019
*                  6 - ERROPT = NOERR                                   58200019
*                  7 - UNUSED                                           58300019
         SPACE 1                                                        58400019
REPL     DC    X'19'                   REPLACE PARAMETER VALUE          58500019
MINLN    DC    X'0000'                 MINLN PARAMETER VALUE            58600019
MAXLN    DC    X'0000'                 MAXLN PARAMETER VALUE            58700019
         EJECT                                                          58800019
ADDRTAB  DS    0CL28                   USER ROUTINE ADDRESS TABLE       58900019
USERADDR DC    A(0,0,0,0,0,0,0)        TABLE                            59000019
         SPACE 1                                                        59100019
*              WORD 0 - OUTHDR2                                         59200019
*                   1 - OUTTLR2                                         59300019
*                   2 - OUTHDR3                                         59400019
*                   3 - OUTTLR3                                         59500019
*                   4 - OUTREC                                          59600019
*                   5 - ERROR                                           59700019
*                   6 - TRANSLATE TABLE                                 59800019
         SPACE 2                                                        59900019
MSGADDR  DC    A(0)                    MESSAGE MODULE ADDRESS           60000019
         SPACE 2                                                        60100019
*        NAME TABLE                                                     60200019
         SPACE 1                                                        60300019
*        THIS TABLE CONTAINS DDNAMES AND USER EXIT NAMES                60400019
         SPACE 1                                                        60500019
NAMETAB  DC    CL8'SYSIN',CL8'SYSPRINT',CL8'SYSUT1',CL8'SYSUT2'         60600019
         DC    CL8'SYSUT3',CL8'OUTHDR2',CL8'OUTTLR2'                    60700019
         DC    CL8'OUTHDR3',CL8'OUTTLR3',CL8'OUTREC',CL8'ERROR'         60800019
         DC    CL8'TRANS'                                               60900019
         SPACE 1                                                        61000019
*              WORDS 0-1   SYSIN                                        61100019
*                    2-3   SYSPRINT                                     61200019
*                    4-5   SYSUT1                                       61300019
*                    6-7   SYSUT2                                       61400019
*                    8-9   SYSUT3                                       61500019
*                   10-11  OUTHDR2                                      61600019
*                   12-13  OUTTLR2                                      61700019
*                   14-15  OUTHDR3                                      61800019
*                   16-17  OUTTLR3                                      61900019
*                   18-19  OUTREC                                       62000019
*                   20-21  ERROR                                        62100019
*                   22-23  TRANS                                        62200019
         EJECT                                                          62300019
*        MESSAGE POINTER TABLE                                          62400019
         SPACE 2                                                        62500019
*        THIS TABLE CONTAINS ONE FULL-WORD ENTRY FOR EACH IEB-TYPE      62600019
*        MESSAGE (EXCLUDING SYNAD MESSAGES).   MSG01 CORRESPONDS TO     62700019
*        IEB901; MSG02 CORRESPONDS TO IEB902; ETC.                      62800019
         SPACE 1                                                        62900019
*              BYTE  1 - MESSAGE REQUEST CODE                           63000019
*                                                                       63100019
*                        X'FF' = INDICATES REQUEST                      63200019
*                        X'00' = NO REQUEST                             63300019
*                                                                       63400019
*              BYTE  2 - INSERT CODE                                    63500019
*                                                                       63600019
*                        X'00' - NO INSERT                              63700019
*                        X'01' - SYSIN                                  63800019
*                        X'02' - SYSPRINT                               63900019
*                        X'03' - SYSUT1                                 64000019
*                        X'04' - SYSUT2                                 64100019
*                        X'05' - SYSUT3                                 64200019
*                        X'06' - OUTHDR2                                64300019
*                        X'07' - OUTTLR2                                64400019
*                        X'08' - OUTHDR3                                64500019
*                        X'09' - OUTTLR3                                64600019
*                        X'0A' - OUTREC                                 64700019
*                        X'0B' - ERROR                                  64800019
*                        X'0C' - USERTAB                                64900019
*                        X'54' - BOTH SYSUT2 AND SYSUT3                 65000019
*                                                                       65100019
*                    NOTE:  IF X'54' IS SPECIFIED, THE MESSAGE IS       65200019
*                        OUTPUT TWICE, ONCE WITH SYSUT2 AND ONCE        65300019
*                        WITH SYSUT3.                                   65400019
*                                                                       65500019
*              BYTE  3 - INSERT LOCATION  (MESSAGE DISPLACEMENT)        65600019
*                                                                       65700019
*              BYTE  4 - OUTPUT LOCATION                                65800019
*                                                                       65900019
*                        BIT 0 - UNUSED                                 66000019
*                            1 - UNUSED                                 66100019
*                            2 - UNUSED                                 66200019
*                            3 - UNUSED                                 66300019
*                            4 - UNUSED                                 66400019
*                            5 - SYSPRINT IF AVAILABLE, CONSOLE         66500019
*                                OTHERWISE                              66600019
*                            6 - CONSOLE                                66700019
*                            7 - SYSPRINT                               66800019
*                                                                       66900019
*                        NOTE - BITS 6 AND 7 MAY BE ON SIMULTANEOUSLY   67000019
         SPACE 1                                                        67100019
MSGPTRS  EQU   *                       ASSIGN MSGPTRS NAME TO TABLE     67200019
MSG01    DC    X'00000002'                                              67300019
MSG02    DC    X'00000001'                                              67400019
MSG03    DC    X'00000001'                                              67500019
MSG04    DC    X'00000001'                                              67600019
MSG05    DC    X'00000001'                                              67700019
MSG06    DC    X'00000001'                                              67800019
MSG07    DC    X'00000001'                                              67900019
MSG08    DC    X'00000001'                                              68000019
MSG09    DC    X'00000001'                                              68100019
MSG10    DC    X'00030B01'             INSERT LOC = 11                  68200019
MSG11    DC    X'00010B01'             INSERT LOC = 11                  68300019
MSG12    DC    X'00020B02'             INSERT LOC = 11                  68400019
MSG13    DC    X'00000B01'             INSERT LOC = 11                  68500019
MSG14    DC    X'00002501'             INSERT LOC = 37                  68600019
MSG15    DC    X'00000F04'             INSERT LOC = 15                  68700019
MSG16    DC    X'00001504'             INSERT LOC = 21                  68800019
MSG17    DC    X'00002201'             INSERT LOC = 34                  68900019
MSG18    DC    X'00001D01'             INSERT LOC = 29                  69000019
MSG19    DC    X'00000004'                                              69100019
MSG20    DC    X'00000002'                                              69200019
         SPACE 3                                                        69300019
MOUNTID  DS    F                       MOUNT MSG ID                     69400019
IOBADDR  DS    F                       SYSUT1 IOB ADDRESS               69500019
TCRBUFL  DC    X'0000'                 TCR BUFFER LENGTH                69600019
         SPACE 1                                                        69700019
ERRIND   DC    X'00'                   ABNORMAL TERMINATION INDICATORS  69800019
         SPACE 1                                                        69900019
*              BIT 0 - CONFLICTING DCB PARAMETERS                       70000019
*                  1 - STORAGE ALLOCATION ERROR                         70100019
*                  2 - I/O ERROR IN READ AND EDIT                       70200019
*                  3 - ERROR IN JFCB READ OR MOUNT                      70300019
*                  4 - ERROR DURING READ AND EDIT                       70400019
*                  5 - ERROR IN ANALYZING CONTROL CARDS                 70500019
*                  6 - PERMANENT I/O ERROR ON QSAM GET/PUT              70600019
*                  7 - ERROR IN LOADING UTILITY MODULE                  70700019
         SPACE 1                                                        70800019
DUMMYIND DC    X'00'                   DUMMY FILE INDICATORS            70900019
         SPACE 1                                                        71000019
*              BIT 0 - UNUSED                                           71100019
*                  1 - UNUSED                                           71200019
*                  2 - UNUSED                                           71300019
*                  3 - UNUSED                                           71400019
*                  4 - SYSUT3                                           71500019
*                  5 - SYSUT2                                           71600019
*                  6 - SYSPRINT                                         71700019
*                  7 - SYSIN                                            71800019
         EJECT                                                          71900019
*        DATA CONTROL BLOCK (DCB) EXIT LISTS                            72000019
         SPACE 2                                                        72100019
*        SYSIN EXIT LIST                                                72200019
         SPACE 1                                                        72300019
         DS    0F                      FORCE FULL-WORD ALIGNMENT        72400019
INEXLST  DC    X'07'                   JFCB EXIT                        72500019
         DC    AL3(0)                  WORK AREA ADDRESS                72600019
         DC    X'85'                   DCB EXIT                         72700019
         DC    AL3(0)                  DCB EXIT ROUTINE                 72800019
         DC    X'00'                   DUMMY ENTRY                      72900019
         DC    AL3(INLRECL)            DEFAULT TABLE ADDRESS            73000019
         SPACE 2                                                        73100019
*        SYSPRINT EXIT LIST                                             73200019
         SPACE 1                                                        73300019
PREXLST  DC    X'07'                   JFCB EXIT                        73400019
         DC    AL3(0)                  WORK AREA ADDRESS                73500019
         DC    X'05'                   DCB EXIT                         73600019
         DC    AL3(0)                  DCB EXIT ROUTINE                 73700019
         DC    X'00'                   DUMMY ENTRY                      73800019
         DC    AL3(PRTLRECL)           DEFAULT TABLE ADDRESS            73900019
         DC    X'00'                   OUTPUT HEADER LABEL (NULL)       74000019
         DC    AL3(0)                  NULL ADDRESS                     74100019
         DC    X'80'                   OUTPUT TRAILER LABEL (NULL)      74200019
         DC    AL3(0)                  NULL ADDRESS                     74300019
         SPACE 2                                                        74400019
*        SYSUT1 EXIT LIST                                               74500019
         SPACE 1                                                        74600019
UT1EXLST DC    X'87'                   JFCB EXIT                        74700019
         DC    AL3(0)                  JFCB EXIT ADDRESS                74800019
         SPACE 2                                                        74900019
*        SYSUT2 EXIT LIST                                               75000019
         SPACE 1                                                        75100019
         DS    0F                                                       75200019
UT2EXLST DC    X'07'                   JFCB EXIT                        75300019
         DC    AL3(0)                  WORK AREA ADDRESS                75400019
         DC    X'05'                   DCB EXIT                         75500019
         DC    AL3(0)                  DCB EXIT ROUTINE                 75600019
         DC    X'00'                   DUMMY ENTRY                      75700019
         DC    AL3(UT2LRECL)           DEFAULT TABLE ADDRESS            75800019
         DC    X'00'                   OUTPUT HEADER LABEL              75900019
         DC    AL3(0)                  NULL ADDRESS                     76000019
         DC    X'80'                   OUTPUT TRAILER LABEL             76100019
         DC    AL3(0)                  NULL ADDRESS                     76200019
         SPACE 2                                                        76300019
*        SYSUT3 EXIT LIST                                               76400019
         SPACE 1                                                        76500019
UT3EXLST DC    X'07'                   JFCB EXIT                        76600019
         DC    AL3(0)                  WORK AREA ADDRESS                76700019
         DC    X'05'                   DCB EXIT                         76800019
         DC    AL3(0)                  DCB EXIT ROUTINE                 76900019
         DC    X'00'                   DUMMY ENTRY                      77000019
         DC    AL3(UT3LRECL)           DEFAULT TABLE ADDRESS            77100019
         DC    X'00'                   OUTPUT HEADER LABEL              77200019
         DC    AL3(0)                  NULL ADDRESS                     77300019
         DC    X'80'                   OUTPUT TRAILER LABEL             77400019
         DC    AL3(0)                  NULL ADDRESS                     77500019
         SPACE 2                                                        77600019
*        DCB PARAMETER DEFAULTS                                         77700019
         SPACE 1                                                        77800019
INLRECL  DC    X'0050'                 SYSIN LRECL  - 80                77900019
INBLK    DC    X'0050'                 SYSIN BLKSIZE - 80               78000019
INRECFM  DC    X'90'                   SYSIN - FIXED BLOCKED            78100019
INIDENT  DC    X'01'                   INTERNAL IDENTIFICATION CODE     78200019
         SPACE 1                                                        78300019
PRTLRECL DC    X'0079'                 SYSPRINT LRECL -  121            78400019
PRTBLK   DC    X'0079'                 SYSPRINT BLKSIZE - 121           78500019
PRTRECFM DC    X'94'                   SYSPRINT - FIXED BLOCKED ASA     78600019
PRTIDENT DC    X'02'                   INTERNAL IDENTIFICATION CODE     78700019
         SPACE 1                                                        78800019
UT2LRECL DC    X'0000'                 SYSUT2 LRECL                     78900019
UT2BLK   DC    X'0000'                 SYSUT2 BLKSIZE                   79000019
UT2RECFM DC    X'50'                   SYSUT2 RECFM - VARIABLE BLOCKED  79100019
UT2IDENT DC    X'04'                   INTERNAL IDENTIFICATION CODE     79200019
         SPACE 1                                                        79300019
UT3LRECL DC    X'0000'                 SYSUT3 LRECL                     79400019
UT3BLK   DC    X'0000'                 SYSUT3 BLKSIZE                   79500019
UT3RECFM DC    X'50'                   SYSUT3 RECFM - VARIABLE BLOCKED  79600019
UT3IDENT DC    X'05'                   INTERNAL IDENTIFICATION CODE     79700019
         EJECT                                                          79800019
*        DATA CONTROL BLOCKS (DCB'S)                                    79900019
         SPACE 3                                                        80000019
*        SYSUT1 (TCR) DCB                                               80100019
         SPACE 2                                                        80200019
TCRDCB   DCB   DSORG=PS,MACRF=(E),DDNAME=SYSUT1,DEVD=TA,RECFM=UA,      X80300019
               BFTEK=S,EXLST=UT1EXLST,IOBAD=NULL                        80400019
         EJECT                                                          80500019
*        SYSUT2 DCB                                                     80600019
         SPACE 2                                                        80700019
UT2DCB   DCB   DSORG=PS,DDNAME=SYSUT2,DEVD=DA,EXLST=UT2EXLST,          X80800019
               SYNAD=NULL,EROPT=ABE,MACRF=(PM)                          80900019
         SPACE 3                                                        81000019
*        SYSUT3 DCB                                                     81100019
         SPACE 2                                                        81200019
UT3DCB   DCB   DSORG=PS,DDNAME=SYSUT3,DEVD=DA,EXLST=UT3EXLST,          X81300019
               SYNAD=NULL,EROPT=ABE,MACRF=(PM)                          81400019
         SPACE 3                                                        81500019
*        SYSIN DCB                                                      81600019
         SPACE 2                                                        81700019
SYSINDCB DCB   DSORG=PS,DDNAME=SYSIN,DEVD=DA,EODAD=NULL,MACRF=(GM),    X81800019
               EXLST=INEXLST,EROPT=ACC,SYNAD=NULL                       81900019
         SPACE 3                                                        82000019
*        SYSPRINT DCB                                                   82100019
         SPACE 2                                                        82200019
SYSPRDCB DCB   DSORG=PS,DDNAME=SYSPRINT,DEVD=DA,EXLST=PREXLST,         X82300019
               MACRF=(PM)                                               82400019
         EJECT                                                          82500019
*        GETMAINED STORAGE ADDRESSES                                    82600019
         SPACE 2                                                        82700019
CARDAREA DS    F                       CARD INPUT AREA                  82800019
JFCBAREA DS    F                       JFCB AREA ADDRESS                82900019
PRTAREA  DS    F                       SYSPRINT OUTPUT AREA             83000019
PRTLNGTH DS    F                       PRINT AREA LENGTH                83100019
COLUMN9  DS    F                       CARD INPUT COLUMN 9 ADDRESS      83200019
CARDEND  DS    F                       INPUT AREA ENDING ADDRESS        83300019
         SPACE 2                                                        83400019
USERNAME DC    7XL8'00'                USER ROUTINE NAME TABLE          83500019
           SPACE 1                                                      83600019
*              WORDS 0 & 1  - OUTHDR2 ROUTINE                           83700019
*                    2 & 3  - OUTTLR2 ROUTINE                           83800019
*                    4 & 5  - OUTHDR3 ROUTINE                           83900019
*                    6 & 7  - OUTTLR3 ROUTINE                           84000019
*                    8 & 9  - OUTREC  ROUTINE                           84100019
*                   10 & 11 - ERROR ROUTINE                             84200019
*                   12 & 13 - TRANSLATE TABLE                           84300019
           SPACE 2                                                      84400019
MISCIND  DC    X'00'                   MISCELLANEOUS INDICATORS         84500019
         SPACE 1                                                        84600019
*              BIT 0 - UNUSED                                           84700019
*                  1 - UNUSED                                           84800019
*                  2 - UNUSED                                           84900019
*                  3 - SYSUT2 LRECL REQUIRES MAXLN INCREMENT            85000019
*                  4 - SYSUT2 BLKSIZE REQUIRES MAXLN INCREMENT          85100019
*                  5 - SYSUT3 LRECL REQUIRES MAXLN INCREMENT            85200019
*                  6 - SYSUT3 BLKSIZE REQUIRES MAXLN INCREMENT          85300019
*                  7 - ALTERNATE DDNAMES FOUND                          85400019
             SPACE 2                                                    85500019
         SPACE 1                                                        85600019
RETCODE  DC    X'00'                   RETURN CODE                      85700019
TCRDEV   DC    CL3'000'                TCR DEVICE                       85800019
VOLSER   DC    CL6' '                  VOLUME SERIAL NUMBER             85900019
PRTRTN   DC    X'00'                   MESSAGE WRITER OPTION IND        86000019
CARRCTRL DC    X'40'                   CARRIAGE CONTROL                 86100019
         SPACE 1                                                        86200019
VTCR220  DS    F                       MESSAGE DISPLAY                  86300019
CURMSGAD DS    F                       CURRENT SYSPRINT MSG ADDRESS     86400019
MSGAD    DS    F                       SINGLE MESSAGE ADDRESS           86500019
MSGLN    DS    F                       SINGLE MSG LENGTH                86600019
JOBNAME  DC    CL8' '                  JOB NAME                         86700019
STEPNAME DC    CL8' '                  STEPNAME                         86800019
         EJECT                                                          86900019
         DCBD  DSORG=PS                                                 87000019
         EJECT                                                          87100019
JFCBD    DSECT                                                          87200019
         SPACE 1                                                        87300019
         IEFJFCBN                                                       87400019
*                                                                       87500019
         END   IEBTCR03                                                 87600019
