  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - INTRODUCTORY COMMENTARY'  * 00050019
*                                                                     * 00100019
*TITLE 'IEBTCR04' - CONTROL CARD ANALYZER                             * 00150019
*                                                                     * 00200019
*STATUS:  CHANGE LEVEL 000                                            * 00250019
*                                                                     * 00300019
*FUNCTION/OPERATION:  THE CONTROL CARD ANALYZER PERFORMS THE          * 00350019
*   FOLLOWING FUNCTIONS:                                              * 00400019
*                                                                     * 00450019
*   1)  READS UTILITY CONTROL STATEMENTS INPUT VIA THE SYSIN          * 00500019
*       DATA SET                                                      * 00550019
*                                                                     * 00600019
*   2)  SCANS THE CONTROL CARDS FOR FORMAT ERRORS                     * 00650019
*                                                                     * 00700019
*   3)  VALIDATES THE NAME, OPERATION, AND OPERAND FIELDS OF EACH     * 00750019
*       STATEMENT                                                     * 00800019
*                                                                     * 00850019
*   4)  SETS OPTIONS (INCLUDING DEFAULTS FOR MISSING PARAMETERS)      * 00900019
*                                                                     * 00950019
*   5)  TESTS THE CONSISTENCY OF THE OPTIONS THAT IT HAS JUST SET     * 01000019
*                                                                     * 01050019
*   THE CONTROL CARD ANALYZER PROCESSES EACH CONTROL STATEMENT ONE    * 01100019
*   CHARACTER AT A TIME.  IT ASSEMBLES EACH OPERATOR, KEYWORD, OR     * 01150019
*   PARAMETER IN AN 8-POSITION HOLD AREA.  WHEN A COMPLETE WORD HAS   * 01200019
*   BEEN ASSEMBLED, THE ANALYZER PERFORMS ONE OF THE FOLLOWING SETS   * 01250019
*   OF OPERATIONS, DEPENDING UPON THE CLASS IN WHICH THE WORD FALLS:  * 01300019
*                                                                     * 01350019
*   NAME FIELD - CHECKS THAT THE FIRST CHARACTER IS ALPHABETIC        * 01400019
*                                                                     * 01450019
*   OPERATOR - COMPARES THE WORD TO THE IDENTIFIER ATTACHED TO EACH   * 01500019
*        OPERATOR TABLE (TCRGEN OR EXITS). IF A MATCH IS FOUND,       * 01550019
*        POINTERS ARE SET TO EACH OF THE TABLES CORRESPONDING TO THIS * 01600019
*        OPERATOR. (SEE TABLES/WORK AREAS.)                           * 01650019
*                                                                     * 01700019
*   KEYWORD - COMPARES THE WORD TO EACH KEYWORD ENTRY OF THE SELECTED * 01750019
*        OPERATOR TABLE.  IF A MATCH IS FOUND, POINTERS ARE SET TO THE* 01800019
*        LIST OF PARAMETERS CORRESPONDING TO THIS KEYWORD.            * 01850019
*                                                                     * 01900019
*   PARAMETER - COMPARES THE WORD TO EACH ENTRY OF THE PARAMETER LIST * 01950019
*        ASSOCIATED WITH THE PREVIOUSLY IDENTIFIED OPERATOR AND KEY-  * 02000019
*        WORD.  IF A MATCH IS FOUND, THE CORRESPONDING DATA TABLE     * 02050019
*        ENTRIES ARE USED TO SET THE PROPER OPTION BYTES. (SEE        * 02100019
*        TABLES/WORK AREAS.)                                          * 02150019
*                                                                     * 02200019
*   WHEN ALL STATEMENTS HAVE BEEN PROCESSED, THE ANALYZER SETS        * 02250019
*   DEFAULTS FOR THOSE OPTIONS WHICH WERE NOT SPECIFIED AND TESTS     * 02300019
*   THE CONSISTENCY OF ALL APPLICABLE OPTIONS.  IF ANY CONFLICTING    * 02350019
*   OPTIONS ARE DETECTED, THE ANALYZER SETS THE RETURN CODE TO 12     * 02400019
*   AND REQUESTS TERMINATION.                                         * 02450019
*                                                                     * 02500019
         EJECT                                                        * 02550019
*ENTRY POINTS:                                                        * 02600019
*                                                                     * 02650019
*        IEBTCR04 - ANALYZE CONTROL CARDS AND SET OPTION INDICATORS   * 02700019
*                                                                     * 02750019
*   THIS MODULE IS LINKED  TO BY THE DRIVER MODULE (IEBTCRIN):        * 02800019
*                                                                     * 02850019
*        LINK EP=IEBTCR04,PARAM=TCRCOM                                * 02900019
*                                                                     * 02950019
*   PARAMETER DATA IS PASSED BY NAME VIA THE COMMON COMMUNICATION     * 03000019
*   REGION AND CONSISTS OF CONTROL CARD OPTION TABLES, A MESSAGE      * 03050019
*   REQUEST TABLE, DATA CONTROL BLOCKS, ADDRESS CONSTANTS, DATA       * 03100019
*   CONSTANTS, AND INDICATORS.                                        * 03150019
*                                                                     * 03200019
*INPUT:  SYSIN DATA SET.  THIS DATA SET IS OPENED AND CLOSED BY THE   * 03250019
*   DRIVER MODULE (IEBTCRIN).  INPUT IS PERFORMED BY THE CONTROL CARD * 03300019
*   ANALYZER THROUGH USE OF THE QSAM ACCESS METHOD.                   * 03350019
*                                                                     * 03400019
*OUTPUT:                                                              * 03450019
*                                                                     * 03500019
*   1)  UPDATED CONTROL CARD OPTION TABLES (WHICH ARE CONTAINED       * 03550019
*       IN THE COMMON COMMUNICATION REGION).                          * 03600019
*                                                                     * 03650019
*   2)  UPDATED MESSAGE REQUEST TABLE (CONTAINED IN THE COMMON        * 03700019
*       COMMUNICATION REGION).                                        * 03750019
*                                                                     * 03800019
*EXTERNAL ROUTINES:                                                   * 03850019
*                                                                     * 03900019
*        TCR220 - MESSAGE WRITER                                      * 03950019
*                                                                     * 04000019
*   THIS ROUTINE IS A SEPARATE  CSECT WITHIN THE DRIVER MODULE        * 04050019
*   (IEBTCRIN).  IT PERFORMS TWO FUNCTIONS:                           * 04100019
*                                                                     * 04150019
*   1)  OUTPUTTING OF CONTROL STATEMENT IMAGES TO THE SYSPRINT DATA   * 04200019
*       SET (IF PROVIDED)                                             * 04250019
*                                                                     * 04300019
*   2)  OUTPUTTING OF IEBXXXX MESSAGES TO THE SYSPRINT DATA SET       * 04350019
*       AND/OR THE SYSTEM CONSOLE                                     * 04400019
*                                                                     * 04450019
*   OPTION 1 IS REQUESTED BY SETTING BIT 6 OF THE COMMUNICATION       * 04500019
*   REGION INDICATOR PRTRTN TO ONE AND PASSING THE CONTROL STATEMENT  * 04550019
*   ADDRESS AND LENGTH VIA THE COMMUNICATION REGION COMPONENTS MSGAD  * 04600019
*   AND MSGLN.                                                        * 04650019
*                                                                     * 04700019
*   OPTION 2 IS REQUESTED BY SETTING PRTRTN BIT 6 TO ZERO.  THE       * 04750019
*   COMMUNICATION REGION MESSAGE POINTER TABLE MUST INDICATE THE      * 04800019
*   MESSAGES REQUIRED.                                                * 04850019
*                                                                     * 04900019
*   EXITS-NORMAL:  NONE                                               * 04950019
*        -ERROR:   NONE                                               * 05000019
*                                                                     * 05050019
        EJECT                                                         * 05100019
*TABLES/WORK AREAS:                                                   * 05150019
*                                                                     * 05200019
*   1)  TCRGEN TABLE (TCRGENOP)                                       * 05250019
*                                                                     * 05300019
*   *********************                                             * 05350019
*   *TCRGEN  *  *  *    *                                             * 05400019
*   *********************                                             * 05450019
*                                                                  * 05500019
*   OPERATOR        DATA TABLE END ADDRESS                           * 05550019
*                                                                    * 05600019
*          NAME TABLE ENTRY LENGTH                                    * 05650019
*                                                                     * 05700019
*                                                                     * 05750019
*    KEYWORD  DEFAULT    ALTERNATIVES                                 * 05800019
*   *************************************                             * 05850019
*   *TYPE    *MTDI    *MTST    *        *          NAME TABLE         * 05900019
*   *************************************          **********         * 05950019
*   *TRANS   *STDUC   *STDLC   *NOTRAN  *                             * 06000019
*   *************************************                             * 06050019
*   *EDIT    *EDITD   *EDITR   *NOEDIT  *                             * 06100019
*   *************************************                             * 06150019
*   *VERCHK  *NOCHK   *VOKCHK  *        *                             * 06200019
*   *************************************                             * 06250019
*   *ERROPT  *NORMAL  *NOERR   *        *                             * 06300019
*   *************************************                             * 06350019
*   *MINLN   *        *        *        *                             * 06400019
*   *************************************                             * 06450019
*   *MAXLN   *        *        *        *                             * 06500019
*   *************************************                             * 06550019
*   *REPLACE *X'19'   *        *        *                             * 06600019
*   *************************************                             * 06650019
*                                                                 * 06700019
*                                                                 * 06750019
*   *************************************                             * 06800019
*   *00* 0* 0*  0140  *  0180  *  0000  *         DATA TABLE          * 06850019
*   *************************************         **********          * 06900019
*   *04* 0* 0*  0110  *  0108  *  0102  *                             * 06950019
*   *************************************                             * 07000019
*   *00* 0* 0*  0280  *  0240  *  0220  *                             * 07050019
*   *************************************                             * 07100019
*   *00* 0* 0*  0208  *  0210  *  0000  *                             * 07150019
*   *************************************                             * 07200019
*   *00* 0* 0*  0204  *  0202  *  0000  *                             * 07250019
*   *************************************                             * 07300019
*   *08* 0* 0*  0400  *  0000  *  0000  *                             * 07350019
*   *************************************                             * 07400019
*   *08* 0* 0*  0600  *  0000  *  0000  *                             * 07450019
*   *************************************                             * 07500019
*   *0C* 0* 0*  0300  *  0000  *  0000  *                             * 07550019
*   *************************************                             * 07600019
*                  ------------                                  * 07650019
*   BRANCH  KEYWORD           OPTION TABLE BYTE                       * 07700019
*   TABLE   PROCESSED              AND                                * 07750019
*   DISP-   INDICATOR         'ON' MASK                               * 07800019
*   PLACEMENT                                                         * 07850019
*                                                                     * 07900019
*   2)  EXITS TABLE (EXITSOP)                                         * 07950019
*                                                                     * 08000019
*                                                                     * 08050019
*   *********************                                             * 08100019
*   *EXITS   *  *  *    *                                             * 08150019
*   *********************                                             * 08200019
*                                                                  * 08250019
*    OPERATOR       NAME TABLE END ADDRESS                           * 08300019
*                                                                    * 08350019
*           NAME TABLE ENTRY LENGTH                                   * 08400019
*                                                                     * 08450019
*                                                                     * 08500019
*                                                                     * 08550019
*    NAME TABLE                   DATA TABLE                          * 08600019
*                                                                     * 08650019
*    **********               *******************                     * 08700019
*    *OUTHDR2 *  - - - - - -  *04*00*00*80*00*00*                     * 08750019
*    **********               *******************                     * 08800019
*    *OUTTLR2 *  - - - - - -  *04*00*00*40*00*08*                     * 08850019
*    **********               *******************                     * 08900019
*    *OUTHDR3 *  - - - - - -  *04*00*00*20*00*10*                     * 08950019
*    **********               *******************                     * 09000019
*    *OUTTLR3 *  - - - - - -  *04*00*00*10*00*18*                     * 09050019
*    **********               *******************                     * 09100019
*    *OUTREC  *  - - - - - -  *04*00*00*08*00*20*                     * 09150019
*    **********               *******************                     * 09200019
*    *ERROR   *  - - - - - -  *04*00*00*04*00*28*                     * 09250019
*    **********               *******************                     * 09300019
*                                     -----                      * 09350019
*     KEYWORD             BRANCH  OPTION                           * 09400019
*                         TABLE   TABLE    NAME                     * 09450019
*                         DISP     DISP   TABLE                     * 09500019
*                                            DISP                   * 09550019
*                           KEYWORD      ON                           * 09600019
*                         PROCESSED     MASK                          * 09650019
*                         INDICATOR                                   * 09700019
*                                                                     * 09750019
*   EACH OPERATOR TABLE IS CONSTRUCTED IN SUCH A WAY THAT A COMMON    * 09800019
*   ROUTINE CAN BE USED TO PROCESS BOTH OF THE TABLES.                * 09850019
*                                                                     * 09900019
*   EACH TABLE CONTAINS THREE SECTIONS:                               * 09950019
*                                                                     * 10000019
*   A)  A 16-BYTE TABLE CONTAINING THE OPERATOR NAME, NAME TABLE      * 10050019
*       ENTRY LENGTH, AND NAME TABLE ENDING ADDRESS                   * 10100019
*                                                                     * 10150019
*   B)  A NAME TABLE CONTAINING ALL POSSIBLE KEYWORDS AND THEIR       * 10200019
*       RELATED PARAMETERS. (IF THE PARAMETERS ARE SPECIAL VALUES     * 10250019
*       WHICH MUST BE INTERPRETED BY A SEPARATE ROUTINE, SUCH AS      * 10300019
*       THE MINLN VALUE, THEY ARE NOT CONTAINED IN THE TABLE.)        * 10350019
*                                                                     * 10400019
*   C)  A DATA TABLE CONTAINING BRANCH TABLE DISPLACEMENTS FOR        * 10450019
*       LOCATING SPECIAL PROCESSING ROUTINES AND OPTION TABLE DIS-    * 10500019
*       PLACEMENTS AND 'ON' MASKS FOR SETTING OPTIONS.                * 10550019
*                                                                     * 10600019
*   THERE IS A ONE-TO-ONE CORRESPONDENCE BETWEEN THE NAME TABLE         10650019
*   AND DATA TABLE ENTRIES.                                             10700019
*                                                                       10750019
*                                                                     * 10800019
*   3)  COMMUNICATION REGION OPTION TABLE                             * 10850019
*                                                                     * 10900019
*                                                                     * 10950019
*                                                                     * 11000019
*   **********************************************************        * 11050019
*   * BYTES  *     BYTE 0    *    BYTE 1     *     BYTE 2    *        * 11100019
*   **********************************************************        * 11150019
*   *        *               *     *         *     *VER*ERR* *        * 11200019
*   *        *     EXITS     *TYPE *  TRANS  *EDIT *CHK*OPT* *        * 11250019
*   *        *************************************************        * 11300019
*   *        *OOOOOEU *MM *SSUN *EEN*VN*NN* *        * 11350019
*   *        *UUUUURS *TT *TTSO *DDO*OO*OO* *        * 11400019
*   *        *TTTTTRE *SD *DDET *IIE*KC*RE* *        * 11450019
*   *        *HTHTROR *TI *ULRR *TTD*CH*MR* *        * 11500019
*   *        *DLDLERT *   *CCNA *DRI*HK*AR* *        * 11550019
*   *        *RRRRC A *   *  AN *  T*K *L * *        * 11600019
*   *        *2233  B *   *  M  *   *  *  * *        * 11650019
*   *        *        *   *  E  *   *  *  * *        * 11700019
*   **********************************************************        * 11750019
*   *DEFAULT *0000000 *01 *0000 *100*01*10* *        * 11800019
*   **********************************************************        * 11850019
*                                                                     * 11900019
*                                                                     * 11950019
*                                                                     * 12000019
*   *********************************                                 * 12050019
*   *    BYTE 3     *  4-5  *  6-7  *                                 * 12100019
*   *********************************                                 * 12150019
*   *               *  MIN  *  MAX  *                                 * 12200019
*   *    REPLACE    *  LN   *  LN   *                                 * 12250019
*   *********************************                                 * 12300019
*   *               *       *       *                                 * 12350019
*   *               *       *       *                                 * 12400019
*   *               *       *       *                                 * 12450019
*   *               *       *       *                                 * 12500019
*   *********************************                                 * 12550019
*   *0*0*0*1*1*0*0*1* 0 * 0 *X'0078'*                                 * 12600019
*   *********************************                                 * 12650019
*                                                                     * 12700019
*                                                                     * 12750019
*                                                                     * 12800019
*   4)  OPERATOR, KEYWORD, PARAMETER HOLD AREA (HOLDAREA)             * 12850019
*                                                                     * 12900019
*   THIS WORK AREA IS USED TO ASSEMBLE EACH OPERATOR, KEYWORD,        * 12950019
*   AND PARAMETER PRESENTED IN THE INPUT STREAM.                      * 13000019
*                                                                     * 13050019
*   5)  INVALID TRANSLATE REPLACE PARAMETER CHARACTERS (TRANRPTB)     * 13100019
*                                                                     * 13150019
*   6)  INVALID EDIT REPLACE PARAMETER CHARACTERS (EDITRPTB)          * 13200019
*                                                                     * 13250019
*ATTRIBUTES:  NOT RE-ENTRANT.  NOT RE-USABLE.                         * 13300019
*                                                                     * 13350019
*NOTES:  THIS MODULE USES VARIOUS COMPONENTS OF THE COMMON COMMUNICA- * 13400019
*   TION REGION CONTAINED IN THE DRIVER MODULE (IEBTCRIN).            * 13450019
*                                                                     * 13500019
*   THIS MODULE CONTAINS TYPE C CHARACTER CODE DEPENDENCIES.  THE     * 13550019
*   OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL REPRESENTATION  * 13600019
*   OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT TO THE ONE USED * 13650019
*   AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED SO THAT REDEFINI- * 13700019
*   TION OF CHARACTER CONSTANTS, BY RE-ASSEMBLY, WILL RESULT IN A     * 13750019
*   CORRECT MODULE FOR THE NEW DEFINITIONS.  CHARACTER CONSTANTS      * 13800019
*   INVOLVED ARE AS FOLLOWS:                                          * 13850019
*                                                                     * 13900019
*   1)  DELIMITERS COMMA, SPACE, EQUALSN, PARENL, AND PARENR USED BY  * 13950019
*       THE OPERAND VALIDATION ROUTINE TCR260                         * 14000019
*                                                                     * 14050019
*   2)  REPLACE PARAMETER CHARACTER X (ALPHAX)                        * 14100019
*                                                                     * 14150019
*   3)  OPERATOR, KEYWORD, AND PARAMETER TABLES TCRGENOP,             * 14200019
*       TCRGENTB, TCRDATA, EXITSOP, EXITSTB, AND EXITDATA             * 14250019
*                                                                     * 14300019
*   THIS MODULE ALSO CONTAINS TYPE E CHARACTER CODE DEPENDENCIES.     * 14350019
*   THE OPERATION OF THIS MODULE DEPENDS UPON THE FOLLOWING PROPER-   * 14400019
*   TIES OF THE INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER     * 14450019
*   SET:  PARTICULAR BIT PATTERN REPRESENTATION OF EBCDIC CHARACTERS  * 14500019
*   AND A PARTICULAR COLLATING SEQUENCE OF THE INTERNAL REPRESENTATION* 14550019
*   OF THE CHARACTER SET.  THE SPECIFIC INSTRUCTION SEQUENCES, TABLES,* 14600019
*   AND CONSTANTS WHICH REQUIRE MODIFICATION IF THESE PROPERTIES OF   * 14650019
*   THE CHARACTER SET ARE CHANGED MAY BE IDENTIFIED BY:               * 14700019
*                                                                     * 14750019
*   1)  TCR520-TCR528 (MINLN-MAXLN VALIDATION ROUTINE) ASSUMES THAT   * 14800019
*       THE NUMERIC DIGITS 0-9 ARE IN ASCENDING COLLATING SEQUENCE    * 14850019
*       AND HAVE NO INTERSPERSED CONTROL CHARACTERS.                  * 14900019
*                                                                     * 14950019
*   2)  TCR240-TCR249 (NAME VALIDATION ROUTINE) ASSUMES THAT THE ALPHA- 15000019
*       BETIC CHARACTERS A-Z ARE IN ASCENDING COLLATING SEQUENCE AND  * 15050019
*       HAVE NO INTERSPERSED CONTROL CHARACTERS.                      * 15100019
*                                                                     * 15150019
*  3)  TCR530-TCR542 (REPLACE PARAMETER VALIDATION AND CONVERSION)    * 15200019
*      ASSUMES                                                        * 15250019
*                                                                     * 15300019
*      A)  THAT THE EBCDIC CHARACTERS A-F AND 0-9 ARE REPRESENTED     * 15350019
*          INTERNALLY BY X'C1' - X'CF' AND X'F0' - X'F9', RESPECT-    * 15400019
*          IVELY.  THIS PARAMETER IS USED TO SPECIFY THE HEXADECIMAL  * 15450019
*          REPRESENTATION OF THE CHARACTERS TO BE USED FOR REPLACING  * 15500019
*          DATA CHECK BYTES.  FOR EXAMPLE, THE EBCDIC INPUT CHARACTERS* 15550019
*          'D9', REPRESENTED INTERNALLY AS THE TWO BYTES              * 15600019
*          '11000100''11111001', WOULD BE CONVERTED TO THE ONE BYTE   * 15650019
*          '11011001'.                                                * 15700019
*                                                                     * 15750019
*      B)  THAT THE CHARACTERS A-Z AND 0-9 ARE IN ASCENDING COLLATING * 15800019
*          SEQUENCE AND HAVE NO CONTROL CHARACTERS INTERSPERSED AMONG * 15850019
*          EITHER GROUP.                                              * 15900019
*                                                                     * 15950019
*   4)  TCR290 (INVALID REPLACE PARAMETER VALIDATION) ASSUMES THAT THE* 16000019
*       PL CODES ARE REPRESENTED BY '01' TO '08' AND ARE IN ASCENDING * 16050019
*       COLLATING SEQUENCE.  IT ALSO ASSUMES THAT HEXADECIMAL CODES   * 16100019
*       '80' TO 'FF' ARE INVALID WITH TRANSLATION AND ARE IN          * 16150019
*       ASCENDING COLLATING SEQUENCE.                                 * 16200019
*                                                                     * 16250019
*   COMMENTS ARE PROVIDED TO INDICATE THE CONSIDERATIONS INVOLVED AND * 16300019
*   THE MECHANISM FOR CHANGING THE CODE.                              * 16350019
*                                                                     * 16400019
*                                                                     * 16450019
*   TO MEET WORLD TRADE REQUIREMENTS, ALL STANDARD OPERATORS, KEY-    * 16500019
*   WORDS, AND PARAMETER NAMES HAVE BEEN PLACED IN THE TABLES         * 16550019
*   TCRGENOP, TCRGENTB, TCRDATA, EXITSOP, EXITSTB, AND EXITDATA.      * 16600019
*   THESE TABLES MAY BE REPLACED IN ENTIRETY.                         * 16650019
*                                                                     * 16700019
*   IF THE MEANS OF SPECIFYING THE MINLN, MAXLN, OR REPLACE PARA-     * 16750019
*   METER VALUES IS CHANGED, MODIFICATIONS TO THE VALIDATION ROUTINES * 16800019
*   TCR290, TCR520, AND TCR530 MAY BE REQUIRED.                       * 16850019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - REGISTER DEFINITIONS'       16900019
IEBTCR04 START 0                                                        16950019
         SPACE 2                                                        17000019
*              REGISTER DEFINITIONS                                     17050019
         SPACE 1                                                        17100019
PARMREG  EQU   1                       PARAMETER LIST REGISTER          17150019
CHARCT   EQU   4                       PARAMETER CHARACTER COUNT        17200019
COLUMNRG EQU   4                       CARD INPUT AREA                  17250019
HOLDREG  EQU   5                       HOLD AREA                        17300019
PARMTAB1 EQU   6                       PARAMETER TABLE 1                17350019
PARMTAB2 EQU   7                       PARAMETER TABLE 2                17400019
WKREG    EQU   7                       WORK REGISTER                    17450019
KEYRG    EQU   8                       KEYWORD-PARAMETER POINTER        17500019
TABREG   EQU   8                       REPLACE TABLE                    17550019
DATARG   EQU   9                       PARAMETER DATA POINTER           17600019
CNTREG   EQU   9                       COUNT REGISTER                   17650019
COMMREG  EQU   10                      COMMUNICATION REGION             17700019
DATAHOLD EQU   11                      KEYWORD DATA ENTRY POINTER       17750019
BASEREG  EQU   12                      BASE REGISTER                    17800019
SAVEREG  EQU   13                      SAVE REGISTER                    17850019
RETREG   EQU   14                      RETURN REGISTER                  17900019
LNKREG15 EQU   15                      LINK REGISTER                    17950019
R0       EQU   0                       REGISTER 0                       18000019
R1       EQU   1                       REGISTER 1                       18050019
R2       EQU   2                       REGISTER 2                       18100019
R3       EQU   3                       REGISTER 3                       18150019
R4       EQU   4                       REGISTER 4                       18200019
R7       EQU   7                       REGISTER 7                       18250019
R15      EQU   15                      REGISTER 15                      18300019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - MAINLINE'                   18350019
*        THIS SECTION SAVES THE DRIVER'S GENERAL REGISTERS,             18400019
*        SETS UP A SAVEAREA ADDRESS, AND ESTABLISHES BASE REGISTERS     18450019
*        FOR THIS MODULE AND FOR THE COMMON COMMUNICATION REGION.       18500019
         SPACE 2                                                        18550019
         ENTRY IEBTCR04                                                 18600019
         SAVE  (14,12),T,IEBTCR04      SAVE REGISTERS                   18650019
         BALR  BASEREG,R0              ESTABLISH BASE REGISTER          18700019
         USING *,BASEREG               INDICATE BASE REGISTER           18750019
         LR    R15,SAVEREG             ESTABLISH SAVE AREA              18800019
         ST    R15,SAVEAREA+4                                           18850019
         LA    SAVEREG,SAVEAREA                                         18900019
         ST    SAVEREG,8(R15)                                           18950019
         XR    R15,R15                                                  19000019
         ST    R15,0(SAVEREG)                                           19050019
         L     COMMREG,0(PARMREG)      LOAD COMMUNICATION REGION ADDR   19100019
         USING TCRCOM,COMMREG          INDICATE COMM. REG. BASE REG     19150019
         SPACE 3                                                        19200019
*        SYSIN EOF ADDRESS INSERTION                                    19250019
         SPACE 1                                                        19300019
*        THIS ROUTINE COMPLETES THE EODAD PARAMETER OF THE SYSIN DCB    19350019
         SPACE 2                                                        19400019
TCR100   LA    R2,SYSINDCB             LOAD SYSIN DCB ADDRESS           19450019
         USING IHADCB,R2               INDICATE DCB DSECT REG           19500019
         MVC   DCBEODAD+1(3),SYSEODAD  SET EOF ADDRESS TO TCR714        19550019
         EJECT                                                          19600019
*        CONTROL CARD ANALYZER MAINLINE                                 19650019
         SPACE 1                                                        19700019
*        THIS ROUTINE CALLS THE FOLLOWING ROUTINES FOR PROCESSING       19750019
*        OF EACH CONTROL STATEMENT                                      19800019
         SPACE 1                                                        19850019
*              TCR230 - NEW STATEMENT FETCH                             19900019
*              TCR240 - NAME VALIDATION                                 19950019
*              TCR250 - OPERATOR VALIDATION                             20000019
*              TCR250 - OPERAND VALIDATION                              20050019
         SPACE 1                                                        20100019
*        FOLLOWING VALIDATION OF EACH CONTROL STATEMENT, IT             20150019
*        CALLS THE MESSAGE WRITER (TCR220) CONTAINED IN THE             20200019
*        DRIVER.  FOLLOWING VALIDATION OF ALL CONTROL STATEMENTS        20250019
*        IT CALLS ROUTINE TCR270, WHICH TESTS THE CONSISTENCY OF ALL    20300019
*        OPTIONS AND SETS THESE OPTIONS IN THE COMMON COMMUNICATION     20350019
*        REGION OPTION TABLE.  IT ALSO CALLS ROUTINE TCR290 WHICH       20400019
*        TESTS FOR INVALID EDIT AND TRANSLATE REPLACE PARAMETERS.       20450019
         SPACE 2                                                        20500019
TCR101   BAL   RETREG,TCR230           LOAD ADDR NEW STMT FETCH RTN     20550019
         TM    STATUS,EOFSYSIN         EOF SYSIN                        20600019
         BO    TCR107                  BR YES                           20650019
         BAL   RETREG,TCR240           LOAD ADDR NAME VALIDATION RTN    20700019
         TM    STATUS,INVTERM          INVALID STATEMENT TERMINATION    20750019
         BO    TCR103                  BR YES                           20800019
         BAL   RETREG,TCR250           LOAD ADDR OPERATOR VALIDATION    20850019
         TM    STATUS,INVTERM          INVALID TERMINATION              20900019
         BO    TCR103                  BR YES                           20950019
         TM    OPTIND,INVOP            INVALID OPERATOR                 21000019
         BO    TCR103                  BR YES                           21050019
         BAL   RETREG,TCR260           LOAD ADDR OPERAND VALIDATION     21100019
         TM    STATUS,INVTERM+INVSTMT  INVALID STATEMENT                21150019
         BZ    TCR105                  BR NO                            21200019
TCR103   L     LNKREG15,VTCR220        LOAD MESSAGE WRITER ADDR         21250019
         BALR  RETREG,LNKREG15         DISPLAY MESSAGES                 21300019
TCR105   TM    STATUS,EOFSYSIN         EOF SYSIN                        21350019
         BNO   TCR101                  BR NO                            21400019
TCR107   TM    ERRIND,SYSINERR         PERMANENT I/O ERROR SYSIN        21450019
         BO    TCR1085                 BR YES                           21500019
         TM    STATUS,INVSTMT+INVTERM  ALL STATEMENTS VALID             21550019
         BNZ   TCR108                  BR NO                            21600019
         BAL   RETREG,TCR270           SET OPTIONS, TEST CONSISTENCY    21650019
         TM    STATUS,INCONOPT         OPTIONS CONSISTENT               21700019
         BO    TCR1075                 BR NO                            21750019
         BAL   RETREG,TCR290           CHECK FOR DISALLOWED REPLACE     21800019
*                                        PARAMETERS                     21850019
         TM    STATUS,INVSTMT          INVALID REPLACE PARAMETER        21900019
         BNO   TCR109                  BR NO                            21950019
TCR1075  L     LNKREG15,VTCR220        LOAD MESSAGE WRITER ADDRESS      22000019
         BALR  RETREG,LNKREG15         WRITE MESSAGES                   22050019
TCR108   MVI   RETCODE,CODE12          SET RETURN CODE 12               22100021
TCR1085  OI    ERRIND,ANALERR          SET ERROR INDICATOR              22150019
TCR109   L     SAVEREG,4(SAVEREG)                                       22200019
         RETURN (14,12),T,RC=(15)      RETURN                           22250019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - NEW STATEMENT FETCH'        22300019
*        NEW STATEMENT FETCH ROUTINE                                    22350019
         SPACE 1                                                        22400019
*        THIS ROUTINE CALLS THE SYSIN DATA SET READ ROUTINE, CHECKS     22450019
*        WHETHER END OF FILE HAS BEEN PRESENTED, AND INITIALIZES        22500019
*        POINTERS AND INDICATORS.                                       22550019
         SPACE 2                                                        22600019
TCR230   ST    RETREG,SAVE200          SAVE RETURN ADDRESS              22650019
         MVI   CARRCTRL,DOUBLESP       SET DOUBLE SPACE                 22700019
         BAL   RETREG,TCR710           READ SYSIN DATA SET              22750019
         TM    STATUS,EOFSYSIN         END OF SYSIN DATA SET            22800019
         BO    TCR239                  BR YES                           22850019
         NI    STATUS,STATINIT         INITIALIZE STATUS INDICATORS     22900019
         L     COLUMNRG,CARDAREA       SET COLUMN REGISTER AT COL 1     22950019
         L     HOLDREG,AHOLD           INITIALIZE HOLD AREA POINTER     23000019
         NI    OPTIND,OPTINIT          INITIALIZE OPTION INDICATOR      23050019
         MVI   SVCHAR,SPACE            SET SAVE CHAR TO SPACE           23100019
TCR239   L     RETREG,SAVE200          LOAD RETURN ADDRESS              23150019
         BR    RETREG                  RETURN                           23200019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - NAME VALIDATION'            23250019
*        NAME VALIDATION ROUTINE                                        23300019
         SPACE 1                                                        23350019
*        THIS ROUTINE TESTS WHETHER OR NOT A NAME FIELD HAS BEEN        23400019
*        PROVIDED.  IF ONE HAS, THE ROUTINE CHECKS THAT IT IS EIGHT     23450019
*        CHARACTERS OR LESS AND THAT THE FIRST CHARACTER IS ALPHA-      23500019
*        BETIC.  IF THE NAME FIELD IS INVALID, THE ROUTINE SETS         23550019
*        MESSAGE AND ERROR INDICATORS AND CALLS THE CHARACTER FLUSH     23600019
*        ROUTINE (TCR620) TO LOCATE THE FIRST BLANK FOLLOWING THE       23650019
*        NAME FIELD.  IF THE NAME FIELD EXTENDS OVER THE ENTIRE         23700019
*        CARD, THE ROUTINE CALLS THE STATEMENT FLUSH ROUTINE (TCR630)   23750019
*        TO FLUSH ANY RECOGNIZABLE CONTINUATION CARDS.                  23800019
         SPACE 1                                                        23850019
*        THIS ROUTINE ASSUMES THAT THE ALPHABETIC CHARACTERS A-Z        23900019
*        ARE IN ASCENDING COLLATING SEQUENCE AND HAVE NO INTERSPERSED   23950019
*        CHARACTERS.  ANY REDEFINITION OF THESE VALUES MAY NECESSI-     24000019
*        TATE MODIFICATION TO THIS ROUTINE.                             24050019
         SPACE 2                                                        24100019
TCR240   ST    RETREG,SAVE200          SAVE RETURN ADDRESS              24150019
         CLI   0(COLUMNRG),BLANK       COLUMN 1 BLANK                   24200019
         BE    TCR249                  BR YES                           24250019
         CLI   0(COLUMNRG),ALPHAA      TEST ALPHABETIC                  24300019
         BL    TCR244                  BR LOWER THAN A                  24350019
         CLI   0(COLUMNRG),ALPHAZ                                       24400019
         BH    TCR244                  BR HIGHER THAN Z                 24450019
         SPACE 1                                                        24500019
TCR242   LA    COLUMNRG,1(COLUMNRG)    INCREMENT TO NEXT COLUMN         24550019
         CLI   0(COLUMNRG),BLANK       COLUMN BLANK                     24600019
         BE    TCR249                  BR  YES                          24650019
         CL    COLUMNRG,COLUMN9        COLUMN 9                         24700019
         BL    TCR242                  BR NO                            24750019
         SPACE 1                                                        24800019
TCR244   OI    MSG02,MSGREQ            SET MSG INDICATOR                24850019
         OI    STATUS,INVSTMT          SET INVALID STMT INDICATOR       24900019
         MVI   SRCHCHAR,BLANK          SET SEARCH CHARACTER TO BLANK    24950019
         BAL   RETREG,TCR620           FLUSH CHARACTERS TO BLANK        25000019
         TM    STATUS,INVTERM          INVALID STMT TERMINATION         25050019
         BNO   TCR249                  BR NO                            25100019
         BAL   RETREG,TCR630           FLUSH CARDS THIS STMT            25150019
TCR249   L     RETREG,SAVE200          LOAD RETURN ADDRESS              25200019
         BR    RETREG                  RETURN                           25250019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - OPERATOR VALIDATION'        25300019
*        OPERATOR VALIDATION ROUTINE                                    25350019
         SPACE 1                                                        25400019
*        THIS ROUTINE FIRST CALLS THE CHARACTER FLUSH ROUTINE           25450019
*        (TCR620) TO LOCATE THE FIRST CHARACTER OF THE OPERATION        25500019
*        FIELD. IT THEN TRANSFERS EACH CHARACTER OF THE OPERATION       25550019
*        FIELD TO AN 8-CHARACTER HOLD AREA UNTIL IT REACHES EITHER      25600019
*        THE NINTH CHARACTER OR A BLANK.                                25650019
*        IF EIGHT OR FEWER CHARACTERS ARE TRANSFERRED, THE ROUTINE      25700019
*        COMPARES THESE CHARACTERS TO EACH OF THE ALLOWABLE             25750019
*        OPERATORS (TCRGEN  AND EXITS).  IF IT IS ONE OF THESE          25800019
*        OPERATORS AND  THE OPERATOR HAS NOT BEEN PRESENTED PRE-        25850019
*        VIOUSLY, THE ROUTINE SETS INDICATORS AND POINTERS TO THE       25900019
*        KEYWORD AND DATA TABLES.                                       25950019
*        IF THE OPERATOR IS NOT VALID, THE ROUTINE SETS MESSAGE AND     26000019
*        ERROR INDICATORS.                                              26050019
         SPACE 2                                                        26100019
TCR250   ST    RETREG,SAVE200          SAVE RETURN ADDRESS              26150019
         MVC   HOLDAREA(8),BLANKS      CLEAR HOLD AREA                  26200019
         MVI   SRCHCHAR,NONBLANK       SET SEARCH CHARACTER TO NON-BLK  26250019
         BAL   RETREG,TCR620           FLUSH TO NON-BLANK CHARACTER     26300019
         TM    STATUS,INVTERM          INVALID TERMINATION              26350019
         BO    TCR258                  BR YES                           26400019
TCR252   CL    HOLDREG,AHOLD9          9TH POSITION HOLD AREA           26450019
         BNL   TCR258                  BR YES                           26500019
         MVC   0(1,HOLDREG),0(COLUMNRG)  TRANSFER NEXT CHARACTER TO     26550019
*                                          HOLD AREA                    26600019
         LA    HOLDREG,1(HOLDREG)      INCREMENT HOLD AREA POINTER      26650019
         LA    COLUMNRG,1(COLUMNRG)    INCREMENT INPUT AREA POINTER     26700019
         CLI   0(COLUMNRG),BLANK       NEXT INPUT CHAR BLANK            26750019
         BNE   TCR252                  BR NO                            26800019
         L     HOLDREG,AHOLD           LOAD HOLD AREA ADDRESS           26850019
         CLC   0(8,HOLDREG),TCRGENOP   OPERATOR  TCRGEN                 26900019
         BNE   TCR255                  BR NO                            26950019
         TM    OPTIND,TCRGNPR          PREVIOUS TCRGEN STATEMENT        27000019
         BO    TCR254                  BR YES                           27050019
         LA    PARMTAB1,TCRGENOP       LOAD PARAMETER TABLE ADDR        27100019
         LA    PARMTAB2,TCRDATA        LOAD DATA TABLE ADDRESS          27150019
         OI    OPTIND,GEN2             SET TCRGEN INDICATORS            27200019
         B     TCR256                  BR TO CONTINUE PROCESSING        27250019
         SPACE 1                                                        27300019
TCR254   MVI   MSG06,MSGREQ            SET INVALID STMT MSG INDICATOR   27350019
TCR2543  OI    STATUS,INVSTMT          SET INVALID STMT INDICATOR       27400019
         OI    OPTIND,INVOP            SET INVALID OPERATOR INDICATOR   27450019
         BAL   RETREG,TCR630           FLUSH CARDS THIS STMT            27500019
         B     TCR257                  BR TO RETURN                     27550019
         SPACE 1                                                        27600019
TCR255   CLC   0(8,HOLDREG),EXITSOP    OPERATOR EXITS                   27650019
         BNE   TCR258                  BR NO                            27700019
         TM    OPTIND,EXITSPR          PREVIOUS EXITS  STATEMENT        27750019
         BO    TCR254                  BR YES                           27800019
         LA    PARMTAB1,EXITSOP        LOAD KEYWORD TABLE ADDRESS       27850019
         LA    PARMTAB2,EXITDATA       LOAD DATA TABLE ADDRESS          27900019
         OI    OPTIND,EXITS2           SET  EXITS  INDICATORS           27950019
TCR256   MVI   SVCHAR,COMMA            SET SAVE CHARACTER TO COMMA      28000019
         SPACE 1                                                        28050019
TCR257   L     RETREG,SAVE200          LOAD RETURN ADDRESS              28100019
         BR    RETREG                  RETURN                           28150019
TCR258   MVI   MSG03,MSGREQ            SET INVALID OPERATOR MSG IND     28200019
         B     TCR2543                 BR TO CONTINUE PROCESSING        28250019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - OPERAND VALIDATION'         28300019
*        OPERAND VALIDATION                                             28350019
         SPACE 1                                                        28400019
*        THIS ROUTINE FIRST CALLS THE CHARACTER FLUSH ROUTINE           28450019
*        (TCR620) TO LOCATE THE FIRST KEYWORD.  IF IT DOES NOT FIND     28500019
*        ONE ON THE FIRST CARD OF THE STATEMENT, THE ROUTINE CALLS      28550019
*        THE STATEMENT FLUSH ROUTINE (TCR630) TO BYPASS ANY RECOG-      28600019
*        NIZABLE CONTINUATION CARDS.                                    28650019
*        IF IT DOES FIND ONE, IT TRANSFERS EACH CHARACTER OF THE KEY-   28700019
*        WORD TO THE HOLD AREA UNTIL IT REACHES EITHER THE NINTH        28750019
*        CHARACTER,   A VALID DELIMITER (COMMA, SPACE, OR EQUAL SIGN),  28800019
*        OR COLUMN 72.                                                  28850019
*        IF IT REACHES THE NINTH CHARACTER, IT SETS INVALID PARAMETER   28900019
*        AND STATEMENT INDICATORS AND CALLS THE CHARACTER FLUSH ROUTINE 28950019
*        (TCR620) TO FLUSH CHARACTERS TO THE NEXT COMMA (NEXT           29000019
*        PARAMETER) OR THE NEXT BLANK (END OF STATEMENT).  IF THE       29050019
*        FLUSH ROUTINE DOES NOT FIND EITHER OF THESE CHARACTERS, THE    29100019
*        OPERAND VALIDATION ROUTINE CALLS THE STATEMENT FLUSH ROUTINE   29150019
*        TO FLUSH ANY RECOGNIZABLE CONTINUATION CARDS.                  29200019
*        IF IT FINDS A VALID DELIMITER, IT CALLS THE ASSOCIATED         29250019
*        VALIDATION ROUTINE.                                            29300019
*        IF IT REACHES COLUMN 72, IT CALLS THE END OF CARD VALIDA-      29350019
*        TION ROUTINE.  IF THE STATEMENT IS TERMINATED AT THIS POINT,   29400019
*        THE ROUTINE RETURNS TO THE MAINLINE ROUTINE.  IF THE STATE-    29450019
*        MENT IS NOT TERMINATED AT THIS POINT, THE ROUTINE CALLS THE    29500019
*        SYSIN READ ROUTINE TO READ AND VALIDATE THE NEXT CONTINUATION  29550019
*        CARD.  IF ANY ERRORS HAVE OCCURRED UP TO THIS POINT WHICH      29600019
*        ALLOW PROCESSING TO CONTINUE, THE ROUTINE CALLS THE MESSAGE    29650019
*        WRITER TO PRINT ERROR MESSAGES BEFORE CALLING THE READ         29700019
*        ROUTINE.                                                       29750019
         SPACE 2                                                        29800019
TCR260   ST    RETREG,SAVE200          SAVE RETURN ADDRESS              29850019
TCR2601  MVC   HOLDAREA(8),BLANKS      CLEAR HOLD AREA                  29900019
         MVI   SRCHCHAR,NONBLANK       SET SEARCH CHARACTER TO NON-BLK  29950019
         BAL   RETREG,TCR620           FLUSH TO NON-BLANK               30000019
         TM    STATUS,INVTERM          INVALID TERMINATION              30050019
         BNO   TCR261                  BR NO                            30100019
         L     COLUMNRG,CARDEND        SET POINTER TO COLUMN 72         30150019
         MVI   SVCHAR,SPACE            MOVE SPACE TO SAVE CHARACTER     30200019
TCR2603  BAL   RETREG,TCR630           FLUSH CARDS THIS STMT            30250019
         B     TCR262                  BR TO RETURN                     30300019
TCR261   CL    COLUMNRG,CARDEND        COLUMN 72                        30350019
         BL    TCR263                  BR NO                            30400019
         BAL   RETREG,TCR330           VALIDATE END OF CARD             30450019
         TM    STATUS,STMTTERM         STATEMENT TERMINATED             30500019
         BNZ   TCR262                  BR YES                           30550019
         TM    STATUS,INVSTMT          ALL STATEMENTS VALID             30600019
         BNO   TCR2613                 BR YES                           30650019
         L     LNKREG15,VTCR220        LOAD MESSAGE WRITER ADDRESS      30700019
         BALR  RETREG,LNKREG15         DISPLAY MESSAGES                 30750019
TCR2613  BAL   RETREG,TCR610           READ AND VALIDATE NEW CARD       30800019
         TM    STATUS,STMTTERM         STATEMENT TERMINATED             30850019
         BZ    TCR2601                 BR NO                            30900019
TCR262   L     RETREG,SAVE200          LOAD RETURN ADDRESS              30950019
         BR    RETREG                  RETURN                           31000019
         SPACE 1                                                        31050019
*        CHECK FOR DELIMITER                                            31100019
         SPACE 1                                                        31150019
TCR263   CLI   0(COLUMNRG),COMMA       COMMA?                           31200019
         BNE   TCR264                  BR NO                            31250019
         BAL   RETREG,TCR350           PROCESS PRECEDING PARAMETER      31300019
         B     TCR268                  IF ANY                           31350019
TCR264   CLI   0(COLUMNRG),SPACE       SPACE?                           31400019
         BNE   TCR265                  BR NO                            31450019
         BAL   RETREG,TCR360           PROCESS PRECEDING PARAMETER      31500019
         B     TCR261                  IF ANY                           31550019
TCR265   CLI   0(COLUMNRG),EQUALSN     EQUAL SIGN                       31600019
         BNE   TCR266                  BR NO                            31650019
         BAL   RETREG,TCR370           PROCESS PRECEDING KEYWORD IF ANY 31700019
         TM    STATUS,STMTTERM         STATEMENT TERMINATED             31750019
         BZ    TCR2653                 BR NO                            31800019
         MVI   SVCHAR,SPACE            MOVE SPACE TO SAVE CHARACTER     31850019
         B     TCR261                  BR TO CONTINUE PROCESSING        31900019
TCR2653  CLI   0(COLUMNRG),SPACE       LAST CHARACTER SPACE             31950019
         BNE   TCR268                  BR NO                            32000019
         L     COLUMNRG,CARDEND        SET AT COLUMN 72                 32050019
         MVI   SVCHAR,SPACE            MOVE SPACE TO SAVE CHARACTER     32100019
         B     TCR261                  BR TO CONTINUE PROCESSING        32150019
TCR266   CLI   0(COLUMNRG),PARENL                                       32200019
         BE    TCR267                  BYPASS LEFT PAREN                32250019
         CLI   0(COLUMNRG),PARENR                                       32300019
         BE    TCR267                  BYPASS RIGHT PAREN               32350019
         CL    HOLDREG,AHOLD9          9TH POSITION HOLD AREA           32400019
         BNL   TCR269                  BR YES                           32450019
         SPACE 1                                                        32500019
*        TRANSFER CHARACTER TO HOLD AREA                                32550019
         SPACE 1                                                        32600019
         MVC   0(1,HOLDREG),0(COLUMNRG) TRANSFER NEXT CHARACTER         32650019
TCR267   LA    HOLDREG,1(HOLDREG)      INCREMENT HOLD AREA POINTER      32700019
TCR268   MVC   SVCHAR(1),0(COLUMNRG)   TRANSFER CHARACTER TO SAVEAREA   32750019
         LA    COLUMNRG,1(COLUMNRG)    INCREMENT INPUT AREA POINTER     32800019
         B     TCR261                  BR TO CONTINUE PROCESSING        32850019
         SPACE 1                                                        32900019
*        INVALID PARAMETER OR KEYWORD                                   32950019
         SPACE 1                                                        33000019
TCR269   OI    MSG05,MSGREQ            INVALID PARAMETER OR KEYWORD     33050019
         OI    STATUS,INVSTMT          SET INVALID STMT INDICATOR       33100019
         MVI   PARMCNT+1,HEXZERO       CLEAR PARAMETER COUNT            33150019
         MVI   SRCHCHAR,COMMA          SET SEARCH CHARACTER TO COMMA    33200019
         MVI   SRCHCHAR+1,SPACE        SET SECOND SEARCH CHARACTER      33250019
*                                        TO SPACE                       33300019
         OI    OPTIND,TWOCHAR          SET TWO CHARACTER SEARCH IND     33350019
         BAL   RETREG,TCR620           FLUSH TO COMMA                   33400019
         TM    STATUS,STMTTERM         STATEMENT TERMINATED             33450019
         BNZ   TCR2603                 BR YES                           33500019
         B     TCR261                  BR TO CONTINUE PROCESSING        33550019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - TEST FOR CONSISTENCY'       33600019
*        SET OPTIONS - TEST CONSISTENCY                                 33650019
         SPACE 1                                                        33700019
*        THIS ROUTINE SETS OPTIONS IN THE COMMON COMMUNICATION          33750019
*        REGION OPTION TABLES AND TESTS FOR CONSISTENCY.  IF AN         33800019
*        OPTION WAS NOT SPECIFIED BY THE USER, THE ROUTINE SETS         33850019
*        AN APPROPRIATE DEFAULT.                                        33900019
         SPACE 2                                                        33950019
TCR270   ST    RETREG,SAVE200          SAVE RETURN ADDRESS              34000019
         SPACE 1                                                        34050019
*        MAXLN                                                          34100019
         SPACE 1                                                        34150019
         CLC   TEMPOP+6(2),ZEROS       MAXLN SPECIFIED                  34200019
         BE    TCR272                  BR NO                            34250019
         MVC   MAXLN(2),TEMPOP+6       SET MAXLN VALUE                  34300019
         SPACE 1                                                        34350019
*        REPLACE                                                        34400019
         SPACE 1                                                        34450019
TCR272   TM    OPTIND,REPLZERO         REPLACE EQUAL TO X'00'           34500019
         BO    TCR2723                 BR YES                           34550019
         CLC   TEMPOP+3(1),ZEROS       REPLACE SPECIFIED                34600019
         BE    TCR273                  BR NO                            34650019
TCR2723  MVC   REPL(1),TEMPOP+3        SET REPLACE CHARACTER            34700019
         SPACE 1                                                        34750019
*        MINLN                                                          34800019
         SPACE 1                                                        34850019
TCR273   CLC   TEMPOP+4(2),ZEROS       MINLN SPECIFIED                  34900019
         BE    TCR2732                 BR NO                            34950019
         MVC   MINLN(2),TEMPOP+4       SET MINLN                        35000019
         SPACE 1                                                        35050019
*        EDIT, VERCHK, ERROPT                                           35100019
         SPACE 1                                                        35150019
TCR2732  MVC   IPARM2,TEMPOP+2         SET EDIT, VERCHK, ERROPT OPTIONS 35200019
         TM    IEXITS,ERREXIT          ERROR EXIT                       35250019
         BNO   TCR2735                 BR NO                            35300019
         TM    IPARM2,ERROP            ERROPT SPECIFIED                 35350019
         BZ    TCR274                  BR NO                            35400019
         NI    IPARM2,X'FF'-ERROP      CLEAR ERROPT OPTION              35450019
         B     TCR274                  BR TO CONTINUE PROCESSING        35500019
         SPACE 1                                                        35550019
TCR2735  TM    IPARM2,ERROP            ERROPT SPECIFIED                 35600019
         BNZ   TCR274                  BR YES                           35650019
         OI    IPARM2,ERRDEF           SET ERROPT=NORMAL DEFAULT        35700019
         SPACE 1                                                        35750019
*        SET AND TEST MTST OPTIONS                                      35800019
         SPACE 1                                                        35850019
TCR274   TM    TEMPOP+1,MTSTDEF        MTST?                            35900019
         BNO   TCR276                  BR NO                            35950019
         MVC   IPARM1,TEMPOP+1         SET MTST OPTION                  36000019
         TM    TEMPOP+2,NOED           ALL EDIT OPTIONS OFF             36050019
         BNZ   TCR284                  BR NO                            36100019
         CLC   TEMPOP+4(2),ZEROS       MINLN SPECIFIED                  36150019
         BNE   TCR284                  BR YES                           36200019
         TM    TEMPOP+1,USERTAB1       USER TRANSLATE TABLE             36250019
         BO    TCR289                  BR YES                           36300019
         TM    TEMPOP+1,TRANSOP        ANY TRANSLATE OPTION SPECIFIED   36350019
         BNZ   TCR289                  BR YES                           36400019
         OI    IPARM1,TRANDEF          SET TRANS=STDUC DEFAULT          36450019
         B     TCR289                  BR TO RETURN                     36500019
         SPACE 1                                                        36550019
*        SET AND TEST MTDI OPTIONS                                      36600019
         SPACE 1                                                        36650019
TCR276   OI    IPARM1,MTDIDEF          SET MTDI OPTION                  36700019
         TM    TEMPOP+1,TRANSOP        ALL TRANSLATE OPTIONS OFF        36750019
         BNZ   TCR284                  BR NO                            36800019
         TM    TEMPOP+2,NOEDIT         NOEDIT SPECIFIED                 36850019
         BO    TCR279                  BR YES                           36900019
         TM    TEMPOP+2,VEROP          VERCHK SPECIFIED                 36950019
         BNZ   TCR278                  BR YES                           37000019
         OI    IPARM2,VERDEF           SET VERCHK=NOCHK DEFAULT         37050019
TCR278   TM    TEMPOP+2,EDITOP         ANY EDIT OPTION                  37100019
         BNZ   TCR289                  BR YES                           37150019
         OI    IPARM2,EDDEF            SET EDIT=EDITD DEFAULT           37200019
         B     TCR289                  BR TO RETURN                     37250019
TCR279   CLC   TEMPOP+4(2),ZEROS       MINLN SPECIFIED                  37300019
         BNE   TCR284                  BR YES                           37350019
         TM    TEMPOP+2,VEROP          VERCHK SPECIFIED                 37400019
         BZ    TCR289                  BR YES                           37450019
         SPACE 1                                                        37500019
*        SET ERROR INDICATORS                                           37550019
         SPACE 1                                                        37600019
TCR284   MVI   MSG08,MSGREQ            SET INCONSISTENT OPTIONS MSG     37650019
*                                        INDICATOR                      37700019
         OI    STATUS,INCONOPT         SET INVALID STMT INDICATOR       37750019
         MVI   RETCODE,CODE12          SET RETURN CODE 12               37800019
         SPACE 1                                                        37850019
TCR289   L     RETREG,SAVE200          LOAD RETURN ADDRESS              37900019
         BR    RETREG                  RETURN                           37950019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - TEST INVALID REPLACE PARM.' 38000019
*        REPLACE PARAMETER VALIDATION - INVALID SPECIFICATION WITH      38050019
*        EDITING OR TRANSLATION                                         38100019
         SPACE 1                                                        38150019
*        THIS ROUTINE COMPARES THE REPLACE PARAMETER WHICH HAS PREV-    38200019
*        IOUSLY BEEN VALIDATED FOR FORMAT ERRORS TO ONE OF TWO TABLES   38250019
*        (TRANRPTB OR EDITRPTB)  WHICH CONTAIN HEXADECIMAL CHARACTERS   38300019
*        WHICH MAY NOT BE USED WITH TRANSLATION OR EDITING. IT ALSO     38350019
*        DOES A HIGH-LOW COMPARISON ON THE HEXADECIMAL CHARACTERS       38400019
*        '80'-'FF' WITH TRANSLATION AND '71'-'78' WITH EDITING.         38450019
         SPACE 1                                                        38500019
*        THIS ROUTINE ASSUMES THAT THE PL CODES ARE REPRESENTED         38550019
*        BY '01' TO '08' AND ARE IN ASCENDING COLLATING SEQUENCE.       38600019
*        IT ALSO ASSUMES THAT HEXADECIMAL CODES '80' TO 'FF' ARE        38650019
*        INVALID WITH TRANSLATION AND ARE IN ASCENDING COLLATING        38700019
*        SEQUENCE.  ANY REDEFINITION OF THESE VALUES MAY NECESSITATE    38750019
*        MODIFICATION TO THIS ROUTINE.                                  38800019
         SPACE 2                                                        38850019
TCR290   ST    RETREG,SAVE200          SAVE RETURN ADDRESS              38900019
         TM    IPARM1,TRANSPEC         TRANSLATE SPECIFIED              38950019
         BZ    TCR294                  BR NO                            39000019
         SPACE 1                                                        39050019
*        TRANSLATE TEST                                                 39100019
         SPACE 1                                                        39150019
         CLI   REPL,SRC                COMPARE TO SRC CODE              39200019
         BNL   TCR296                  BR HIGH OR EQUAL                 39250019
TCR291   LA    TABREG,TRANRPTB         LOAD ADDRESS OF INVALID          39300019
*                                        TRANSLATE REPLACE CHARACTERS   39350019
         XR    CNTREG,CNTREG                                            39400019
         IC    CNTREG,TRANRPLN         INSERT COUNT                     39450019
         SPACE 1                                                        39500019
*        TABLE COMPARISON                                               39550019
         SPACE 1                                                        39600019
TCR292   CLC   REPL(1),0(TABREG)       INVALID CHARACTER                39650019
         BE    TCR296                  BR YES                           39700019
         LA    TABREG,1(TABREG)        INCREMENT TO NEXT ENTRY          39750019
         BCT   CNTREG,TCR292           BR IF ALL ENTRIES NOT TESTED     39800019
         B     TCR298                  BR TO RETURN                     39850019
         SPACE 1                                                        39900019
*        EDIT TEST                                                      39950019
         SPACE 1                                                        40000019
TCR294   TM    IPARM2,EDITSPEC         EDIT SPECIFIED                   40050019
         BZ    TCR298                  BR NO                            40100019
         CLI   REPL,P1                 COMPARE TO P1 CODE               40150019
         BL    TCR295                  BR LOW                           40200019
         CLI   REPL,P8                 COMPARE TO P8 CODE               40250019
         BNH   TCR296                  BR LOW OR EQ                     40300019
TCR295   LA    TABREG,EDITRPTB         LOAD ADDRESS OF INVALID EDIT     40350019
*                                        REPLACE CHARACTERS             40400019
         XR    CNTREG,CNTREG           CLEAR COUNT REGISTER             40450019
         IC    CNTREG,EDITRPLN         INSERT COUNT                     40500019
         B     TCR292                  BRANCH TO TABLE COMPARISON       40550019
         SPACE 1                                                        40600019
*        SET ERROR INDICATORS                                           40650019
         SPACE 1                                                        40700019
TCR296   MVI   MSG07,MSGREQ            SET INCONSISTENT REPLACE         40750019
*                                        PARAMETER INDICATOR            40800019
         OI    STATUS,INVSTMT          SET INVALID STATEMENT INDICATOR  40850019
TCR298   L     RETREG,SAVE200          LOAD RETURN ADDRESS              40900019
         BR    RETREG                  RETURN                           40950019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - END OF CARD VALIDATION'     41000019
*        END OF CARD VALIDATION ROUTINE                                 41050019
         SPACE 1                                                        41100019
*        THIS ROUTINE VALIDATES THE END OF A CARD.  IT CALLS            41150019
*        VALIDATION ROUTINES FOR ANY PARAMETERS THAT MAY NOT HAVE       41200019
*        HAVE BEEN VALIDATED.   IF THE SAVE CHARACTER WAS A COMMA OR    41250019
*        IF COLUMN 72    CONTAINS A NON-BLANK CHARACTER, THE ROUTINE    41300019
*        SETS CONTINUATION EXPECTED INDICATORS.  IF COLUMN 72 IS        41350019
*        NON-BLANK AND THE LAST SAVE CHARACTER WAS NOT A COMMA,         41400019
*        COMMENTS ARE EXPECTED.                                         41450019
         SPACE 2                                                        41500019
TCR330   ST    RETREG,SAVE300          STORE RETURN ADDRESS             41550019
         CLI   SVCHAR,COMMA            SAVE CHARACTER COMMA             41600019
         BE    TCR334                  BR YES                           41650019
         CLI   0(COLUMNRG),BLANK       COLUMN 72 BLANK                  41700019
         BNE   TCR336                  BR NO                            41750019
         CLI   SVCHAR,SPACE            SAVE CHARACTER SPACE             41800019
         BE    TCR332                  BR YES                           41850019
         LH    R2,PARMCNT              LOAD COUNT                       41900019
         LA    R2,2(R2)                ADD PARAMETER VALUE              41950019
         STH   R2,PARMCNT              REPLACE COUNT                    42000019
         BAL   RETREG,TCR410           VALIDATE LAST PARAMETER          42050019
TCR332   OI    STATUS,VALTERM          SET VALID STMT TERMINATION       42100019
*                                        INDICATOR                      42150019
TCR333   L     RETREG,SAVE300          LOAD RETURN ADDRESS              42200019
         BR    RETREG                  RETURN                           42250019
TCR334   OI    STATUS,CONTCD           SET CONTINUATION EXPECTED        42300019
*                                        INDICATOR - NO COMMENTS        42350019
         B     TCR333                  BR TO RETURN                     42400019
TCR336   CLI   SVCHAR,SPACE            SAVE CHARACTER SPACE             42450019
         BE    TCR337                  BR YES                           42500019
         LH    R2,PARMCNT              LOAD VALIDATION COUNT            42550019
         LA    R2,2(R2)                ADD PARAMETER VALUE              42600019
         STH   R2,PARMCNT              REPLACE COUNT                    42650019
         BAL   RETREG,TCR410           VALIDATE LAST PARAMETER          42700019
TCR337   OI    STATUS,CONTCOMM         SET CONTINUATION EXPECTED        42750019
*                                        INDICATOR - COMMENTS           42800019
         B     TCR333                  BRANCH TO RETURN                 42850019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - COMMA ROUTINE'              42900019
*        COMMA ROUTINE - PARAMETER VALIDATION                           42950019
         SPACE 1                                                        43000019
*        THIS ROUTINE TESTS WHETHER THE LAST PARAMETER HAS BEEN         43050019
*        VALIDATED PREVIOUSLY.  IF IT HAS NOT, IT CALLS THE PARAMETER   43100019
*        VALIDATION ROUTINE (TCR410) AND THEN SETS THE SAVE CHARACTER   43150019
*        TO COMMA.                                                      43200019
         SPACE 1                                                        43250019
TCR350   ST    RETREG,SAVE300          STORE RETURN ADDRESS             43300019
         CLI   SVCHAR,COMMA            PARAMETER FOUND                  43350019
         BE    TCR359                  BR NO                            43400019
         LH    R2,PARMCNT              LOAD VALIDATION COUNT            43450019
         LA    R2,2(R2)                ADD  COMMA INDICATOR VALUE       43500019
         STH   R2,PARMCNT              REPLACE COUNT                    43550019
         BAL   RETREG,TCR410           VALIDATE PARAMETER               43600019
         MVI   SVCHAR,COMMA            TRANSFER COMMA TO SAVE CHARACTER 43650019
TCR359   L     RETREG,SAVE300          LOAD RETURN ADDRESS              43700019
         BR    RETREG                  RETURN                           43750019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - SPACE ROUTINE'              43800019
*        SPACE ROUTINE - PARAMETER VALIDATION                           43850019
         SPACE 1                                                        43900019
*        THIS ROUTINE CALLS THE PARAMETER VALIDATION ROUTINE            43950019
*        (TCR410) IF THE LAST PARAMETER WAS NOT VALIDATED.  IT          44000019
*        SETS THE SAVE CHARACTER TO BLANK AND SETS THE INPUT AREA       44050019
*        POINTER TO COLUMN 72 TO BYPASS ANY INTERVENING COMMENTS.       44100019
         SPACE 2                                                        44150019
TCR360   ST    RETREG,SAVE300          SAVE RETURN ADDRESS              44200019
         CLI   SVCHAR,COMMA            PARAMETER FOUND?                 44250019
         BE    TCR362                  BR NO                            44300019
         LH    R2,PARMCNT              LOAD VALIDATION COUNT            44350019
         LA    R2,2(R2)                ADD COMMA INDICATOR VALUE        44400019
         STH   R2,PARMCNT              STORE COUNT                      44450019
         BAL   RETREG,TCR410           VALIDATE PARAMETER               44500019
         MVI   SVCHAR,SPACE            TRANSFER SPACE TO SAVE CHARACTER 44550019
TCR362   L     COLUMNRG,CARDEND        SET INPUT AREA POINTER TO        44600019
*                                        COLUMN 72                      44650019
         L     RETREG,SAVE300          LOAD RETURN ADDRESS              44700019
         BR    RETREG                  RETURN                           44750019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - EQUAL SIGN ROUTINE'         44800019
*        EQUAL SIGN ROUTINE - KEYWORD VALIDATION                        44850019
         SPACE 1                                                        44900019
*        THIS ROUTINE COMPARES THE KEYWORD WHICH HAS JUST BEEN          44950019
*        ASSEMBLED TO EACH ENTRY OF THE KEYWORD-PARAMETER TABLE         45000019
*        ASSOCIATED WITH THE PREVIOUSLY IDENTIFIED OPERATOR.            45050019
*        IF IT DOES NOT FIND A MATCH, IT SETS MESSAGE AND ERROR         45100019
*        INDICATORS AND FLUSHES ANY PARAMETER FOLLOWING THIS KEYWORD.   45150019
         SPACE 2                                                        45200019
TCR370   ST    RETREG,SAVE300          SAVE RETURN ADDRESS              45250019
         CLI   PARMCNT+1,HEXZERO       COUNT ZERO                       45300019
         BNE   TCR376                  BR NO                            45350019
         MVI   PARMCNT+1,HEXONE        SET COUNT EQUAL TO ONE           45400019
         LR    KEYRG,PARMTAB1          LOAD PARAMETER TABLE ADDRESS     45450019
         LA    KEYRG,16(KEYRG)         SET KEYWORD-PARAMETER TABLE      45500019
*                                        POINTER AT FIRST KEYWORD       45550019
         LR    DATARG,PARMTAB2         LOAD PARAMETER TABLE ADDRESS     45600019
         LA    DATARG,8(DATARG)        SET DATA TABLE POINTER AT FIRST  45650019
*                                        KEYWORD                        45700019
TCR372   CL    KEYRG,12(PARMTAB1)      TABLE END                        45750019
         BNL   TCR376                  BR YES                           45800019
         CLC   HOLDAREA(8),0(KEYRG)    KEYWORD FOUND                    45850019
         BE    TCR374                  BR YES                           45900019
         AH    KEYRG,10(PARMTAB1)      INCREMENT KEYWORD TABLE POINTER  45950019
         AH    DATARG,2(PARMTAB2)      INCREMENT DATA TABLE POINTER     46000019
         B     TCR372                  LOOP                             46050019
TCR374   TM    1(DATARG),KEYFND        KEYWORD PROCESSED PREVIOUSLY?    46100019
         BO    TCR375                  BR YES                           46150019
         OI    1(DATARG),KEYFND        INDICATE KEYWORD FOUND           46200019
         L     HOLDREG,AHOLD           RE-INITIALIZE HOLD AREA POINTER  46250019
         MVC   HOLDAREA(8),BLANKS      CLEAR HOLD AREA                  46300019
         B     TCR379                  BR TO RETURN                     46350019
         SPACE 1                                                        46400019
*        SET ERROR INDICATORS                                           46450019
         SPACE 1                                                        46500019
TCR375   MVI   MSG08,MSGREQ            SET MSG INDICATOR                46550019
         B     TCR377                  BR TO CONTINUE PROCESSING        46600019
TCR376   MVI   MSG04,MSGREQ            SET INCONSISTENT OPTIONS         46650019
*                                        MSG INDICATOR                  46700019
TCR377   OI    STATUS,INVSTMT          SET INVALID STMT INDICATOR       46750019
         L     HOLDREG,AHOLD           RE-INITIALIZE HOLD AREA POINTER  46800019
         MVC   0(8,HOLDREG),BLANKS     CLEAR HOLD AREA                  46850019
         MVI   PARMCNT+1,HEXZERO       CLEAR PARAMETER COUNT            46900019
         MVI   SRCHCHAR,COMMA          TRANSFER COMMA TO SEARCH CHAR    46950019
         MVI   SRCHCHAR+1,SPACE        SET SECOND SEARCH CHARACTER      47000019
*                                        TO SPACE                       47050019
         OI    OPTIND,TWOCHAR          SET TWO CHARACTER SEARCH IND     47100019
         BAL   RETREG,TCR620           FLUSH TO COMMA                   47150019
TCR379   L     RETREG,SAVE300          LOAD RETURN ADDRESS              47200019
         BR    RETREG                  RETURN                           47250019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - PARAMETER VALIDATION'       47300019
*        PARAMETER VALIDATION                                           47350019
         SPACE 1                                                        47400019
*        THIS ROUTINE COMPARES THE PARAMETER WHICH HAS JUST BEEN        47450019
*        ASSEMBLED TO EACH OF THE PARAMETERS ASSOCIATED WITH THE        47500019
*        PREVIOUSLY IDENTIFIED OPERATOR AND KEYWORD.  IF IT FINDS       47550019
*        A MATCH, IT USES INFORMATION CONTAINED IN THE DATA TABLE       47600019
*        TO SET OPTIONS IN THE TEMPORARY OPTION TABLE (TEMPOP).         47650019
*        IF IT DOES NOT FIND A MATCH, IT CHECKS WHETHER OR NOT A        47700019
*        SPECIAL VALIDATION ROUTINE HAS BEEN INDICATED.  IF ONE         47750019
*        HAS, IT CALLS THIS ROUTINE TO CONTINUE VALIDATION.             47800019
         SPACE 2                                                        47850019
TCR410   ST    RETREG,SAVE400          SAVE RETURN ADDRESS              47900019
         CLI   PARMCNT+1,VALNO         ONE KEYWORD AND ONE PARAMETER    47950019
         BNE   TCR418                  BR NO                            48000019
         ST    R7,SAVEREG7             SAVE REGISTER                    48050019
         LR    WKREG,KEYRG             LOAD KEYWORD ADDRESS             48100019
         AH    WKREG,10(PARMTAB1)      DEVELOP ENTRY ENDING ADDRESS     48150019
         LR    DATAHOLD,DATARG         SAVE KEYWORD ADDRESS             48200019
TCR412   LA    KEYRG,8(KEYRG)          INCREMENT TO NEXT PARAMETER      48250019
         LA    DATARG,2(DATARG)        INCREMENT DATA TABLE POINTER     48300019
         CLR   KEYRG,WKREG             END OF TABLE ENTRY?              48350019
         BNL   TCR416                  BR YES                           48400019
         CLC   0(8,KEYRG),BLANKS       NEXT TABLE ENTRY BLANK           48450019
         BE    TCR416                  BR YES                           48500019
         CLC   0(8,KEYRG),HOLDAREA     COMPARE INPUT PARAMETER          48550019
         BNE   TCR412                  BR UNEQUAL                       48600019
         L     R7,SAVEREG7             RESTORE REGISTER                 48650019
         XR    R2,R2                   CLEAR INDEX REGISTER             48700019
         IC    R2,0(DATARG)            INSERT OPTION TABLE POINTER      48750019
         IC    R3,1(DATARG)            INSERT OPTION ON MASK            48800019
         XR    R1,R1                   CLEAR OR-ING REGISTER            48850019
         IC    R1,TEMPOP(R2)           INSERT OPTION TABLE BYTE         48900019
         OR    R3,R1                   OR CURRENT AND PREVIOUS IND'S    48950019
         STC   R3,TEMPOP(R2)           SET OPTION INDICATOR IN TABLE    49000019
TCR414   MVI   PARMCNT+1,HEXZERO       CLEAR PARAMETER COUNT            49050019
         L     HOLDREG,AHOLD           SET HOLD AREA POINTER AT         49100019
*                                        LOCATION 1                     49150019
         MVC   0(8,HOLDREG),BLANKS     CLEAR HOLD AREA                  49200019
         L     RETREG,SAVE400          LOAD RETURN ADDRESS              49250019
         BR    RETREG                  RETURN                           49300019
TCR416   L     R7,SAVEREG7             RESTORE REGISTER                 49350019
         CLI   0(DATAHOLD),HEXZERO     SPECIAL ROUTINE PRESENT          49400019
         BE    TCR418                  BR NO                            49450019
         LA    RETREG,TCR414           LOAD RETURN ADDRESS REGISTER     49500019
         XR    R2,R2                   CLEAR INDEX REGISTER             49550019
         IC    R2,0(DATAHOLD)          INSERT BRANCH TABLE DISP.        49600019
         B     TCR417(R2)              BRANCH TO REQUIRED ROUTINE       49650019
TCR417   B     TCR414                  NULL                             49700019
         B     TCR510                  USER TRANSLATE TABLE             49750019
         B     TCR520                  MINLN-MAXLN                      49800019
         B     TCR530                  REPLACE                          49850019
TCR418   MVI   MSG05,MSGREQ            SET INVALID PARAMETER MSG IND    49900019
         OI    STATUS,INVSTMT          SET INVALID STMT INDICATOR       49950019
         B     TCR414                  BR TO CONTINUE                   50000019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - USER RTN VALIDATION'        50050019
*        USER EXIT ROUTINE OR TRANSLATE TABLE NAME VALIDATION           50100019
         SPACE 1                                                        50150019
*        THIS ROUTINE SETS INDICATORS AND STORES ROUTINE NAMES.         50200019
         SPACE 2                                                        50250019
TCR510   TM    2(DATAHOLD),HEXONE      USER TRANSLATE TABLE             50300019
         BNO   TCR512                  BR NO                            50350019
         SPACE 1                                                        50400019
*        USER TRANSLATE TABLE                                           50450019
         SPACE 1                                                        50500019
         MVC   USERNAME+USERDISP(8),HOLDAREA  STORE ROUTINE NAME        50550019
         OI    OPTABLE,USERTAB         SET OPTION INDICATOR             50600019
         OI    TEMPOP+1,USERTAB1       SET OPTION INDICATOR             50650019
         BR    RETREG                  RETURN                           50700019
         SPACE 1                                                        50750019
*        USER EXIT ROUTINE                                              50800019
         SPACE 1                                                        50850019
TCR512   XR    R2,R2                   CLEAR INDEX REGISTER             50900019
         IC    R2,2(DATAHOLD)          INSERT INDEX VALUE               50950019
         LA    R3,OPTABLE              LOAD OPTION TABLE ADDRESS        51000019
         AR    R3,R2                   ADD INDEX VALUE BASE TABLE ADDR  51050019
         OC    0(1,R3),3(DATAHOLD)     SET INDICATOR ON                 51100019
         LH    R2,4(DATAHOLD)          LOAD USERNAME TABLE ENTRY        51150019
         LA    R3,USERNAME             LOAD NAME TABLE ADDRESS          51200019
         AR    R3,R2                   FIND NAME TABLE ENTRY            51250019
         MVC   0(8,R3),HOLDAREA        STORE ROUTINE NAME               51300019
         BR    RETREG                  RETURN                           51350019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - MINLN-MAXLN VALIDATION'     51400019
*        MINLN - MAXLN VALIDATION ROUTINES                              51450019
         SPACE 1                                                        51500019
*        THIS ROUTINE CHECKS THAT THE MINLN OR MAXLN PARAMETER          51550019
*        IS FIVE OR FEWER CHARACTERS AND IS NUMERIC.  IF IT IS,         51600019
*        IT CONVERTS IT FROM EBCDIC TO PACKED DECIMAL AND THEN          51650019
*        TO BINARY AND STORES IT IN THE OPTION TABLE.                   51700019
         SPACE 1                                                        51750019
*        THIS ROUTINE ASSUMES THAT THE NUMERIC DIGITS 0-9 ARE IN        51800019
*        ASCENDING COLLATING SEQUENCE AND HAVE NO INTERSPERSED          51850019
*        CONTROL CHARACTERS.  ANY REDEFINITION OF THESE VALUES MAY      51900019
*        NECESSITATE MODIFICATION TO THIS ROUTINE.                      51950019
         SPACE 2                                                        52000019
TCR520   ST    R4,SAVEREG4             SAVE REGISTER 4                  52050019
         XR    CHARCT,CHARCT           ZERO CHARACTER COUNT             52100019
         L     HOLDREG,AHOLD           INITIALIZE HOLD AREA POINTER     52150019
TCR522   CLI   0(HOLDREG),BLANK        NEXT CHARACTER BLANK             52200019
         BE    TCR523                  BR YES                           52250019
         CLI   0(HOLDREG),NINE         TEST NUMERIC                     52300019
         BH    TCR528                  BR NO                            52350019
         CLI   0(HOLDREG),ZERO                                          52400019
         BL    TCR528                  BR NO                            52450019
         LA    CHARCT,1(CHARCT)        INCREMENT CHARACTER COUNT        52500019
         CL    CHARCT,HEXSIX           SIXTH CHARACTER                  52550019
         BNL   TCR528                  BR YES                           52600019
         LA    HOLDREG,1(HOLDREG)      INCREMENT HOLD AREA POINTER      52650019
         B     TCR522                  LOOP                             52700019
TCR523   SH    CHARCT,ONE              DEVELOP LENGTH INDICATOR         52750019
         LA    CHARCT,PAKLN7(CHARCT)   INSERT PACKED LENGTH 7           52800019
         EX    CHARCT,TCR525           PACK MAXLN OR MINLN              52850019
         B     TCR526                  BYPASS PACK INSTRUCTION          52900019
         SPACE 1                                                        52950019
TCR525   PACK  WORK1(1),HOLDAREA(1)    PACK MAXLN OR MINLN              53000019
         SPACE 1                                                        53050019
TCR526   NI    WORK1,PLUS              CHANGE SIGN TO PLUS              53100019
         CVB   R2,WORK1                CONVERT MINLN OR MAXLN TO BINARY 53150019
         XR    R3,R3                   CLEAR INDEX REGISTER             53200019
         IC    R3,2(DATAHOLD)          INSERT DISPLACEMENT              53250019
         STH   R2,TEMPOP(R3)           STORE MINLN OR MAXLN IN TABLE    53300019
         L     R4,SAVEREG4             RESTORE REGISTER 4               53350019
         BR    RETREG                  BR TO RETURN                     53400019
TCR528   MVI   MSG05,MSGREQ            SET INVALID PARAMETER MSG        53450019
*                                        INDICATOR                      53500019
         OI    STATUS,INVSTMT          SET INVALID STATEMENT INDICATOR  53550019
         L     R4,SAVEREG4             RESTORE REGISTER 4               53600019
         BR    RETREG                  RETURN                           53650019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - REPLACE PARM. VALIDATION'   53700019
*        REPLACE PARAMETER VALIDATION                                   53750019
         SPACE 1                                                        53800019
*        THIS ROUTINE VERIFIES THAT THE REPLACE PARAMETER IS OF         53850019
*        THE FORM X'CC'  WHERE C IS EITHER 0-9 OR A-F.  IF IT IS, THE   53900019
*        ROUTINE CONVERTS IT FROM EBCDIC TO HEXADECIMAL AND STORES IT   53950019
*        IN THE OPTION TABLE.                                           54000019
         SPACE 1                                                        54050019
*        THIS ROUTINE ASSUMES                                           54100019
*                                                                       54150019
*             A) THAT THE EBCDIC CHARACTERS A-F AND 0-9 ARE REPRE-      54200019
*                SENTED INTERNALLY BY X'C1' - X'CF' AND X'F0' -         54250019
*                X'F9', RESPECTIVELY.  THIS PARAMETER IS USED TO        54300019
*                SPECIFY THE HEXADECIMAL REPRESENTATION OF THE CHAR-    54350019
*                ACTERS TO BE USED FOR REPLACING DATA CHECK BYTES.      54400019
*                FOR EXAMPLE, THE INPUT CHARACTERS 'D9', REPRESENTED    54450019
*                INTERNALLY AS THE TWO BYTES '11000100''11111001'       54500019
*                WOULD BE CONVERTED TO THE ONE BYTE '11011001'.         54550019
*                                                                       54600019
*             B) THAT THE CHARACTERS A-Z AND 0-9 ARE IN ASCENDING       54650019
*                COLLATING SEQUENCE AND HAVE NO CONTROL CHARACTERS      54700019
*                INTERSPERSED AMONG EITHER GROUP.                       54750019
         SPACE 1                                                        54800019
*        ANY REDEFINITION OF THE VALUES SPECIFIED IN A  ABOVE           54850019
*        WILL NECESSITATE DEVELOPMENT OF A DIFFERENT CONVERSION         54900019
*        ALGORITHM.                                                     54950019
*                                                                       55000019
*        REDEFINITION OF B ABOVE MAY REQUIRE DIFFERENT VALIDATION       55050019
*        PROCEDURES.                                                    55100019
         SPACE 2                                                        55150019
TCR530   ST    RETREG,SAVE500          SAVE RETURN ADDRESS              55200019
         L     HOLDREG,AHOLD           INITIALIZE HOLD AREA ADDRESS     55250019
         CLI   0(HOLDREG),ALPHAX       FIRST CHAR X?                    55300019
         BNE   TCR538                  BR NO                            55350019
         CLI   1(HOLDREG),QUOTE        SECOND CHARACTER QUOTE           55400019
         BNE   TCR538                  BR NO                            55450019
         LA    HOLDREG,2(HOLDREG)      SET POINTER TO 3RD CHARACTER     55500019
         BAL   RETREG,TCR540           TEST 0-9 OR A-F                  55550019
TCR532   LA    HOLDREG,1(HOLDREG)      SET POINTER TO 4TH CHARACTER     55600019
         BAL   RETREG,TCR540           TEST 0-9 OR A-F                  55650019
         CLI   1(HOLDREG),QUOTE        FIFTH CHARACTER QUOTE            55700019
         BNE   TCR538                  BR NO                            55750019
         SPACE 1                                                        55800019
*        TRANSLATE AND STORE REPLACE BYTE                               55850019
         SPACE 1                                                        55900019
         TM    HOLDAREA+3,HEXF         NUMERIC                          55950019
         BO    TCR535                  BR YES                           56000019
TCR534   LH    R2,CBASE                DEVELOP HEX VALUE FOR            56050019
         AH    R2,HOLDAREA+2             ALPHABETIC CHARACTER           56100019
         STC   R2,HOLDAREA+3                                            56150019
TCR535   TM    HOLDAREA+2,HEXF         NUMERIC                          56200019
         BO    TCR536                  BR YES                           56250019
         LH    R2,CBASE                DEVELOP HEX VALUE FOR            56300019
*                                        ALPHABETIC CHARACTER           56350019
         MVC   HALFST+1(1),HOLDAREA+2  MOVE TO HALF WORD STORE          56400019
         AH    R2,HALFST                                                56450019
         STC   R2,HOLDAREA+2                                            56500019
TCR536   MVO   HOLDAREA+3(1),HOLDAREA+2(1)  INSERT FIRST DIGIT IN       56550019
*                                      LEFT FOUR BITS OF SECOND DIGIT   56600019
         XR    R2,R2                   CLEAR INDEX REGISTER             56650019
         IC    R2,2(DATAHOLD)          INSERT OPTION TABLE INDEX        56700019
         XR    R3,R3                   CLEAR WORK REGISTER              56750019
         IC    R3,HOLDAREA+3           MOVE REPLACE BYTE TO TEMPORARY   56800019
         STC   R3,TEMPOP(R2)             OPTION TABLE                   56850019
         XR    R2,R2                   SET REGISTER TO ZEROES           56900019
         CLR   R3,R2                   REPLACE EQUAL TO X'00'           56950019
         BNE   TCR539                  BRANCH NO                        57000019
         OI    OPTIND,REPLZERO         SET REPLACE EQUAL TO ZERO IND    57050019
         B     TCR539                  BR TO RETURN                     57100019
TCR538   MVI   MSG05,MSGREQ            SET INVALID PARAMETER MSG        57150019
*                                        INDICATOR                      57200019
         OI    STATUS,INVSTMT          SET INVALID STATEMENT INDICATOR  57250019
TCR539   L     RETREG,SAVE500          RETURN                           57300019
         BR    RETREG                  RETURN                           57350019
         SPACE 2                                                        57400019
*        TEST CHARACTER 0-9 OR A-F                                      57450019
         SPACE 1                                                        57500019
TCR540   CLI   0(HOLDREG),NINE         GREATER THAN 9                   57550019
         BH    TCR538                  BR YES                           57600019
         CLI   0(HOLDREG),ALPHAA       LOWER THAN A                     57650019
         BL    TCR538                  BR YES                           57700019
         CLI   0(HOLDREG),ZERO         LOWER THAN ZERO                  57750019
         BNL   TCR542                  BR NO                            57800019
         CLI   0(HOLDREG),ALPHAF       HIGHER THAN F                    57850019
         BH    TCR538                  BR YES                           57900019
TCR542   BR    RETREG                  RETURN                           57950019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - CONTINUATION CARD VALID.'   58000019
*        CONTINUATION CARD READ AND VALIDATION                          58050019
         SPACE 1                                                        58100019
*        THIS ROUTINE CALLS THE READ ROUTINE TO READ CONTINUATION       58150019
*        CARDS AND VALIDATES THEM FOR FORMAT ERRORS.                    58200019
         SPACE 2                                                        58250019
TCR610   ST    RETREG,SAVE610          SAVE RETURN ADDRESS              58300019
TCR611   BAL   RETREG,TCR710           READ A CARD                      58350019
         TM    STATUS,EOFSYSIN         EOF - SYSIN?                     58400019
         BO    TCR612                  BR YES                           58450019
         CLC   0(3,COLUMNRG),BLANKS    COLUMNS 1-3 BLANK                58500019
         BNE   TCR615                  BR NO                            58550019
         TM    STATUS,COMMIMMA         COMMENTS IMMATERIAL              58600019
         BO    TCR619                  BR YES                           58650019
         TM    STATUS,CONTCOMM         COMMENTS EXPECTED                58700019
         BO    TCR613                  BR YES                           58750019
         CLC   3(13,COLUMNRG),BLANKS   COLUMNS 4-16 BLANK               58800019
         BNE   TCR619                  BR NO                            58850019
         B     TCR615                  BR TO SET ERROR INDICATORS       58900019
TCR612   OI    STATUS,INVTERM          SET INVALID TERMINATION INDICATR 58950019
         MVI   MSG09,MSGREQ            SET INVALID CONTINUATION         59000019
*                                        INDICATOR                      59050019
         B     TCR617                  BR TO RETURN                     59100019
TCR613   CLI   COLUMN72(COLUMNRG),BLANK   COLUMN 72 BLANK               59150019
         BNE   TCR611                  BR NO                            59200019
         OI    STATUS,VALTERM          SET VALID TERMINATION            59250019
*                                        INDICATOR                      59300019
         B     TCR619                  BR TO RETURN                     59350019
TCR615   MVI   MSG09,MSGREQ            SET INVALID CONTINUATION         59400019
*                                        INDICATOR                      59450019
         BAL   RETREG,TCR630           FLUSH CARDS THIS STATEMENT       59500019
TCR617   OI    STATUS,INVSTMT          SET INVALID STMT INDICATOR       59550019
TCR619   L     RETREG,SAVE610          LOAD RETURN ADDRESS              59600019
         BR    RETREG                  RETURN                           59650019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - CHARACTER FLUSH ROUTINE'    59700019
*        CHARACTER FLUSH ROUTINE                                        59750019
         SPACE 1                                                        59800019
*        THIS ROUTINE FLUSHES CHARACTERS UNTIL IT FINDS THE             59850019
*        REQUESTED CHARACTER.  THE FOLLOWING REQUESTS MAY BE MADE:      59900019
         SPACE 1                                                        59950019
*        1)  ANY NON-BLANK  - INDICATED BY SETTING SRCHCHAR TO X'FF'    60000019
*        2)  ONE SEARCH CHARACTER - INDICATED BY SETTING BIT 2 OF       60050019
*            OPTIND TO ZERO AND MOVING THE REQUESTED CHARACTER TO       60100019
*            THE FIRST BYTE OF SRCHCHAR                                 60150019
*        3)  TWO SEARCH CHARACTERS - INDICATED BY SETTING BIT 2 OF      60200019
*            OPTIND TO ONE AND MOVING THE TWO REQUESTED CHARACTERS TO   60250019
*            BYTES ONE AND TWO OF SRCHCHAR.                             60300019
          SPACE 1                                                       60350019
*        IF THE ROUTINE DOES NOT FIND  THE REQUESTED CHARACTER(S), IT   60400019
*        SETS AN INVALID STATEMENT INDICATOR.                           60450019
         SPACE 2                                                        60500019
TCR620   ST    RETREG,SAVE620          SAVE RETURN ADDRESS              60550019
         MVI   PARMCNT+1,HEXZERO       CLEAR VALIDATION COUNT           60600019
         NI    OPTIND,X'FF'-NONBLIND   CLEAR NON-BLANK INDICATOR        60650019
         TM    SRCHCHAR,NONBLANK       SEARCH CHARACTER NON-BLANK       60700019
         BNO   TCR621                  BR NO                            60750019
         OI    OPTIND,NONBLIND         SET NON-BLANK INDICATOR          60800019
TCR621   CL    COLUMNRG,CARDEND        COLUMN 72                        60850019
         BNL   TCR628                  BR YES                           60900019
         TM    OPTIND,NONBLIND         NON-BLANK REQUESTED              60950019
         BO    TCR625                  BR YES                           61000019
         CLC   0(1,COLUMNRG),SRCHCHAR  SEARCH CHARACTER FOUND           61050019
         BE    TCR629                  BR YES                           61100019
         TM    OPTIND,TWOCHAR          TWO SEARCH CHARACTERS REQUESTED  61150019
         BNO   TCR623                  BR NO                            61200019
         CLC   0(1,COLUMNRG),SRCHCHAR+1  COMPARE TO SECOND SEARCH       61250019
*                                          CHARACTER                    61300019
         BE    TCR629                  BR EQUAL                         61350019
TCR623   LA    COLUMNRG,1(COLUMNRG)    INCREMENT TO NEXT CHARACTER      61400019
         B     TCR621                  LOOP                             61450019
TCR625   CLI   0(COLUMNRG),SPACE       CHARACTER NON-BLANK              61500019
         BE    TCR623                  BR NO                            61550019
         B     TCR629                  BR TO RETURN                     61600019
TCR628   OI    STATUS,INVTERM          SET INVALID TERMINATION IND      61650019
TCR629   NI    OPTIND,X'FF'-TWOCHAR    CLEAR TWO CHARACTER INDICATOR    61700019
         L     RETREG,SAVE620          LOAD RETURN ADDRESS              61750019
         BR    RETREG                  RETURN                           61800019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - STATEMENT FLUSH ROUTINE'    61850019
*        STATEMENT FLUSH ROUTINE                                        61900019
         SPACE 1                                                        61950019
*        THIS ROUTINE READS ALL RECOGNIZABLE CONTINUATION CARDS.        62000019
         SPACE 2                                                        62050019
TCR630   ST    RETREG,SAVE630          SAVE RETURN ADDRESS              62100019
         L     LNKREG15,VTCR220        LOAD MESSAGE WRITER ADDRESS      62150019
         BALR  RETREG,LNKREG15         WRITE MESSAGES                   62200019
         OI    STATUS,INVTERM          SET INVALID TERMINATION INDICATR 62250019
         OI    STATUS,INVSTMT          SET INVALID STMT INDICATOR       62300019
         L     COLUMNRG,CARDAREA       INITIALIZE INPUT AREA POINTER    62350019
TCR632   CLI   COLUMN72(COLUMNRG),BLANK   COLUMN 72 BLANK               62400019
         BE    TCR634                  BR YES                           62450019
         BAL   RETREG,TCR710           READ A CARD                      62500019
         TM    STATUS,EOFSYSIN         EOF - SYSIN                      62550019
         BNO   TCR632                  BR NO                            62600019
TCR634   L     RETREG,SAVE630          LOAD RETURN ADDRESS              62650019
         BR    RETREG                  RETURN                           62700019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - SYSIN DATA SET READ RTN'    62750019
*        SYSIN DATA SET READ ROUTINE                                    62800019
         SPACE 1                                                        62850019
*        THIS ROUTINE READS AND PRINTS EACH CONTROL CARD.  IT           62900019
*        CALLS THE MESSAGE WRITER SINGLE MESSAGE ROUTINE TO DO          62950019
*        THE PRINTING.                                                  63000019
*        IF A PERMANENT I/O ERROR OCCURS ON SYSIN, THE ROUTINE SETS     63050019
*        THE END OF FILE INDICATOR.  THIS CAUSES PROCESSING TO STOP     63100019
*        AT ALL CALLING LEVELS.                                         63150019
         SPACE 2                                                        63200019
TCR710   ST    RETREG,SAVE700          SAVE RETURN ADDRESS              63250019
         L     R2,CARDAREA             LOAD CARD AREA ADDRESS           63300019
         GET   SYSINDCB,(2)            READ CONTROL STATEMENT           63350019
         TM    ERRIND,SYSINERR         PERMANENT I/O ERROR SYSIN        63400019
         BO    TCR714                  BR YES                           63450019
         LR    COLUMNRG,R2             SET INPUT AREA POINTER TO        63500019
*                                        COLUMN 1                       63550019
         TM    DUMMYIND,DUMSYSP        SYSPRINT DUMMY                   63600019
         BO    TCR719                  BR YES                           63650019
         LA    R2,CDLENGTH             LOAD  CARD LENGTH                63700019
         STC   R2,MSGLN                STORE MSG LENGTH                 63750019
         MVC   MSGAD,CARDAREA          STORE MSG ADDRESS                63800019
         OI    PRTRTN,RTN310           SET SINGLE MSG INDICATOR         63850019
         L     LNKREG15,VTCR220        LOAD MSG WRITER ADDRESS          63900019
         BALR  RETREG,LNKREG15         PRINT CONTROL STATEMENT          63950019
         B     TCR719                  BR TO RETURN                     64000019
         SPACE 1                                                        64050019
*        END OF FILE                                                    64100019
         SPACE 1                                                        64150019
TCR714   OI    STATUS,EOFSYSIN         SET EOF INDICATOR                64200019
TCR719   L     RETREG,SAVE700          LOAD RETURN ADDRESS              64250019
         BR    RETREG                  RETURN                           64300019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - LITERALS AND WORK AREAS'    64350019
*        LITERALS                                                       64400019
         SPACE 2                                                        64450019
NULL     EQU   *                       NULL LABEL                       64500019
COMMA    EQU   C','                    COMMA                            64550019
SPACE    EQU   C' '                    SPACE                            64600019
EQUALSN  EQU   C'='                    EQUAL SIGN                       64650019
PARENL   EQU   C'('                    LEFT PARENTHESIS                 64700019
PARENR   EQU   C')'                    RIGHT PARENTHESIS                64750019
HEXZERO  EQU   X'00'                   HEXADECIMAL                      64800019
DOUBLESP EQU   X'F0'                   DOUBLE SPACE CONTROL CHARACTER   64850019
HEXONE   EQU   X'01'                   HEXADECIMAL ONE                  64900019
ZERO     EQU   X'F0'                   EBCDIC ZERO                      64950019
NINE     EQU   X'F9'                   EBCDIC NINE                      65000019
BLANK    EQU   X'40'                   BLANK                            65050019
QUOTE    EQU   C''''                   QUOTE                            65100019
ALPHAA   EQU   C'A'                    ALPHABETIC A                     65150019
ALPHAF   EQU   C'F'                    ALPHABETIC F                     65200019
HEXF     EQU   X'F0'                   HEXADECIMAL F                    65250019
PLUS     EQU   X'FC'                   PLUS SIGN                        65300019
ALPHAX   EQU   C'X'                    ALPHABETIC X                     65350019
ALPHAZ   EQU   C'Z'                    ALPHABETIC Z                     65400019
MTDIDEF  EQU   X'40'                   MTDI DEFAULT                     65450019
MTSTDEF  EQU   X'80'                   MTST DEFAULT                     65500019
CDLENGTH EQU   80                      CARD LENGTH                      65550019
KEYFND   EQU   X'01'                   KEY FOUND                        65600019
VALNO    EQU   X'03'                   CORRECT VALIDATION COUNT         65650019
USERTAB1 EQU   X'04'                   USER TRANSLATE TABLE INDICATED   65700019
NOEDIT   EQU   X'20'                   EDIT=NOEDIT                      65750019
EDITOP   EQU   X'E0'                   ALL EDIT OPTIONS                 65800019
VEROP    EQU   X'18'                   ALL VERCHK OPTIONS               65850019
ERREXIT  EQU   X'04'                   ERROR EXIT INDICATED             65900019
ERROP    EQU   X'06'                   ALL ERROPT OPTIONS               65950019
ANALERR  EQU   X'04'                   ERROR IN CONTROL ANALYZER        66000019
SYSINERR EQU   X'02'                   PERMANENT I/O ERROR SYSIN        66050019
DUMSYSP  EQU   X'02'                   DUMMY SYSPRINT                   66100019
MSGREQ   EQU   X'FF'                   MSG REQUIRED                     66150019
CODE12   EQU   X'0C'                   RETURN CODE 12                   66200019
NONBLANK EQU   X'FF'                   SEARCH FOR NON-BLANK CHARACTER   66250019
USERTAB  EQU   X'02'                   USER TRANSLATE TABLE INDICATED   66300019
RTN310   EQU   X'02'                   SINGLE MSG INDICATOR             66350019
EDDEF    EQU   X'80'                   EDIT DEFAULT                     66400019
VERDEF   EQU   X'08'                   VERCHK DEFAULT                   66450019
ERRDEF   EQU   X'04'                   ERROPT DEFAULT                   66500019
TRANDEF  EQU   X'10'                   TRANS DEFAULT                    66550019
NOED     EQU   X'F8'                   NO EDIT                          66600019
TRANSOP  EQU   X'1E'                   ALL TRANS OPTIONS                66650019
TRANSPEC EQU   X'1C'                   TRANSLATE                        66700019
EDITSPEC EQU   X'C0'                   EDIT                             66750019
P1       EQU   X'71'                   PROGRAM LEVEL 1 CODE             66800019
P8       EQU   X'78'                   PROGRAM LEVEL 8 CODE             66850019
SRC      EQU   X'80'                   SEARCH CODE                      66900019
USERDISP EQU   48                      TRANSLATE TABLE NAME DISP        66950019
USERDSP2 EQU   88                      TRANSLATE TABLE NAME DISP        67000019
COLUMN72 EQU   71                      COLUMN 71 POINTER                67050019
PAKLN7   EQU   112                     BINARY 7 IN LEFT HALF OF BYTE    67100019
         SPACE 1                                                        67150019
*        OPTIND INDICATORS                                              67200019
         SPACE 1                                                        67250019
REPLZERO EQU   X'80'                   REPLACE EQUALS ZERO              67300019
INVOP    EQU   X'40'                   INVALID OPERATOR                 67350019
TWOCHAR  EQU   X'20'                   TWO SEARCH CHARACTERS REQUESTED  67400019
NONBLIND EQU   X'10'                   NON-BLANK SEARCH INDICATOR       67450019
TCRGNPR  EQU   X'04'                   TCRGEN PROCESSED                 67500019
EXITSPR  EQU   X'08'                   EXITS PROCESSED                  67550019
GEN2     EQU   X'05'                   BOTH TCRGEN INDICATORS           67600019
EXITS2   EQU   X'0A'                   BOTH EXITS INDICATORS            67650019
OPTINIT  EQU   X'0C'                   OPTIND INITIALIZATION            67700019
         SPACE 1                                                        67750019
*        STATUS INDICATORS                                              67800019
         SPACE 1                                                        67850019
EOFSYSIN EQU   X'01'                   EOF - SYSIN                      67900019
INVTERM  EQU   X'02'                   INVALID STATEMENT END            67950019
CONTCD   EQU   X'08'                   CONTINUATION EXPECTED            68000019
CONTCOMM EQU   X'04'                   CONTINUATION EXPECTED - COMMENTS 68050019
INVSTMT  EQU   X'10'                   INVALID STATEMENT                68100019
INCONOPT EQU   X'20'                   INCONSISTENT OPTIONS             68150019
STATINIT EQU   X'10'                   STATUS BYTE INITIALIZATION       68200019
VALTERM  EQU   X'40'                   VALID STATEMENT TERMINATION      68250019
STMTTERM EQU   X'42'                   STATEMENT TERMINATION            68300019
COMMIMMA EQU   X'80'                   COMMENTS IMMATERIAL              68350019
         SPACE 1                                                        68400019
*        CONSTANTS                                                      68450019
         SPACE 1                                                        68500019
         DS    0H                      FORCE HALF-WORD ALIGNMENT        68550019
ONE      DC    X'0001'                 ONE                              68600019
CBASE    DC    X'0009'                 HEX C BASE                       68650019
ZEROS    DC    X'0000'                 ZEROES                           68700019
HEXSIX   DC    F'6'                    SIX                              68750019
HALFST   DC    X'0000'                 HALF WORD STORE                  68800019
BLANKS   DC    CL13' '                 BLANKS                           68850019
         SPACE 1                                                        68900019
*        SAVE AREAS                                                     68950019
         SPACE 1                                                        69000019
SAVEAREA DS    18F                     REGISTER SAVE AREA               69050019
SAVE200  DS    F                       RETURN ADDRESS SAVE AREA         69100019
SAVE300  DS    F                       RETURN ADDRESS SAVE AREA         69150019
SAVE400  DS    F                       RETURN ADDRESS SAVE AREA         69200019
SAVE500  DS    F                       RETURN ADDRESS SAVE AREA         69250019
SAVE610  DS    F                       RETURN ADDRESS SAVE AREA         69300019
SAVE620  DS    F                       RETURN ADDRESS SAVE AREA         69350019
SAVE630  DS    F                       RETURN ADDRESS SAVE AREA         69400019
SAVE700  DS    F                       RETURN ADDRESS SAVE AREA         69450019
SAVEREG4 DS    F                       REGISTER 4 SAVE AREA             69500019
SAVEREG7 DS    F                       REGISTER 7 SAVE AREA             69550019
         EJECT                                                          69600019
*        WORK AREAS                                                     69650019
         SPACE 1                                                        69700019
TEMPOP   DC    D'0'                    TEMPORARY OPTION TABLE           69750019
WORK1    DC    PL8'0'                  PACKED MINLN-MAXLN               69800019
PARMCNT  DC    X'0000'                 PARAMETER COUNT                  69850019
HOLDAREA DC    CL9' '                  KEYWOR-PARAMETER HOLD AREA       69900019
SRCHCHAR DC    X'0000'                 SEARCH CHARACTER                 69950019
SVCHAR   DC    X'00'                   SAVE CHARACTER                   70000019
         SPACE 2                                                        70050019
*        ADDRESS CONSTANTS                                              70100019
         SPACE 1                                                        70150019
AHOLD    DC    A(HOLDAREA)             HOLD AREA ADDRESS                70200019
AHOLD9   DC    A(HOLDAREA+8)           9TH CHARACTER HOLD AREA          70250019
SYSEODAD DC    AL3(TCR714)             SYSIN DCB EODAD ADDRESS          70300019
         SPACE 1                                                        70350019
*        INDICATORS                                                     70400019
         SPACE 1                                                        70450019
STATUS   DC    X'00'                   STATUS INDICATOR                 70500019
*                                                                       70550019
*              BIT 0 - COMMENTS IMMATERIAL                              70600019
*                  1 - VALID STMT TERMINATION                           70650019
*                  2 - INCONSISTENT OPTIONS                             70700019
*                  3 - INVALID  STATEMENT                               70750019
*                  4 - CONTINUATION EXPECTED - NO COMMENTS              70800019
*                  5 - CONTINUATION EXPECTED - COMMENTS                 70850019
*                  6 - INVALID STMT TERMINATION                         70900019
*                  7 - END OF FILE - SYSIN DATASET                      70950019
*                                                                       71000019
OPTIND   DC    X'00'                   OPTION INDICATORS                71050019
*                                                                       71100019
*              BIT 0 - REPLACE BYTE ZEROES                              71150019
*                  1 - INVALID OPERATOR                                 71200019
*                  2 - TWO SEARCH CHARACTERS                            71250019
*                  3 - NON-BLANK SEARCH INDICATOR                       71300019
*                  4 - EXITS PROCESSED                                  71350019
*                  5 - TCRGEN PROCESSED                                 71400019
*                  6 - EXITS STATEMENT                                  71450019
*                  7 - TCRGEN STATEMENT                                 71500019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - TABLES'                     71550019
*        TCRGEN KEYWORD-PARAMETER NAME TABLE                            71600019
         SPACE 1                                                        71650019
*        TO SATISFY WORLD TRADE REQUIREMENTS THE FOLLOWING TCRGEN       71700019
*        AND EXITS NAME TABLES MAY BE REPLACED IN ENTIRETY.             71750019
*                                                                       71800019
*                                                                       71850019
*                                                                       71900019
*              KEYWORD  DEFAULT    ALTERNATIVES                         71950019
*             *************************************                     72000019
*             *TYPE    *MTDI    *MTST    *        *                     72050019
*             *TRANS   *STDUC   *STDLC   *NOTRAN  *                     72100019
*             *EDIT    *EDITD   *EDITR   *NOEDIT  *                     72150019
*             *VERCHK  *NOCHK   *VOKCHK  *        *                     72200019
*             *ERROPT  *NORMAL  *NOERR   *        *                     72250019
*             *MINLN   *        *        *        *                     72300019
*             *MAXLN   *        *        *        *                     72350019
*             *REPLACE *        *        *        *                     72400019
*             *************************************                     72450019
*                                                                       72500019
*                                                                       72550019
         DS    0F                                                       72600019
TCRGENOP DC    CL8'TCRGEN'             OPERATION                        72650019
         DS    H                       NOT USED                         72700019
         DC    X'0020'                 TABLE ENTRY LENGTH - 32 BYTES    72750019
         DC    A(TAB1D)                TABLE END ADDRESS                72800019
*                                                                       72850019
TCRGENTB DC    CL8'TYPE',CL8'MTDI',CL8'MTST',CL8' '                     72900019
         DC    CL8'TRANS',CL8'STDUC',CL8'STDLC',CL8'NOTRAN'             72950019
         DC    CL8'EDIT',CL8'EDITD',CL8'EDITR',CL8'NOEDIT'              73000019
         DC    CL8'VERCHK',CL8'NOCHK',CL8'VOKCHK',CL8' '                73050019
         DC    CL8'ERROPT',CL8'NORMAL',CL8'NOERR',CL8' '                73100019
         DC    CL8'MINLN',CL24' '                                       73150019
         DC    CL8'MAXLN',CL24' '                                       73200019
         DC    CL8'REPLACE',CL24' '                                     73250019
*                                                                       73300019
TAB1D    EQU   *                       TABLE ENDING ADDRESS             73350019
*                                                                       73400019
*        TCRGEN DATA TABLE - EACH ENTRY CORRESPONDS TO ONE              73450019
*        ENTRY OF THE KEYWORD-PARAMETER TABLE                           73500019
*                                                                       73550019
*                                                                       73600019
*                 HALFWORD 1                                            73650019
*                    BYTE 1  - EXCEPTIONAL VALIDATION ROUTINE           73700019
*                              BRANCH TABLE DISPLACEMENT                73750019
*                                                                       73800019
*                    BYTE 2  - KEYWORD PROCESSED INDICATOR              73850019
*                      X'00' - NOT PROCESSED                            73900019
*                      X'01' - PROCESSED                                73950019
*                                                                       74000019
*                 HALFWORDS 2,3,4                                       74050019
*                    BYTE 1  - OPTION TABLE DISPLACEMENT                74100019
*                    BYTE 2  - 'ON' MASK                                74150019
*                                                                       74200019
TCRDATA  DS    H                       NOT USED                         74250019
         DC    X'0008'                 ENTRY LENGTH                     74300019
         DC    A(TAB2D)                TABLE END ADDRESS                74350019
         SPACE 1                                                        74400019
GENTB2   DC    X'0000',X'0140',X'0180',X'0000'    TYPE                  74450019
         DC    X'0400',X'0110',X'0108',X'0102'    TRANS                 74500019
         DC    X'0000',X'0280',X'0240',X'0220'    EDIT                  74550019
         DC    X'0000',X'0208',X'0210',X'0000'    VERCHK                74600019
         DC    X'0000',X'0204',X'0202',X'0000'    ERROPT                74650019
         DC    X'0800',X'0400',X'0000',X'0000'    MINLN                 74700019
         DC    X'0800',X'0600',X'0000',X'0000'    MAXLN                 74750019
         DC    X'0C00',X'0300',X'0000',X'0000'    REPLACE               74800019
         SPACE 1                                                        74850019
TAB2D    EQU   *                       TABLE ENDING ADDRESS             74900019
         EJECT                                                          74950019
*        EXITS KEYWORD NAME TABLE                                       75000019
         SPACE 1                                                        75050019
         DS    0F                      FORCE FULL-WORD BOUNDARY         75100019
EXITSOP  DC    CL8'EXITS'              OPERATION                        75150019
         DS    H                       NOT USED                         75200019
         DC    X'0008'                 ENTRY LENGTH                     75250019
         DC    A(TAB3D)                TABLE END ADDRESS                75300019
         SPACE 1                                                        75350019
EXITSTB  DC    CL8'OUTHDR2',CL8'OUTTLR2',CL8'OUTHDR3',CL8'OUTTLR3'      75400019
         DC    CL8'OUTREC',CL8'ERROR'                                   75450019
         SPACE 1                                                        75500019
TAB3D    EQU   *                       TABLE END ADDRESS                75550019
*                                                                       75600019
*        EXITS DATA TABLE - EACH ENTRY CORRESPONDS TO ONE               75650019
*        ENTRY OF THE KEYWORD TABLE                                     75700019
*                                                                       75750019
*                                                                       75800019
*                   BYTE 1  - EXCEPTIONAL VALIDATION ROUTINE BRANCH     75850019
*                             TABLE ADDRESS                             75900019
*                                                                       75950019
*                   BYTE 2  - KEYWORD PROCESSED INDICATOR               76000019
*                     X'00' - NOT PROCESSED                             76050019
*                     X'01' - PROCESSED                                 76100019
*                                                                       76150019
*                   BYTE 3  - COMMUNICATION TABLE LOCATION              76200019
*                                                                       76250019
*                   BYTE 4  - ON MASK                                   76300019
*                                                                       76350019
*              BYTES 5 & 6  - NAME TABLE DISPLACEMENT                   76400019
*                                                                       76450019
*                                                                       76500019
EXITDATA DS    H                       NOT USED                         76550019
         DC    X'0006'                 ENTRY LENGTH                     76600019
         DC    A(TAB4D)                TABLE END ADDRESS                76650019
         SPACE 1                                                        76700019
EXITTB   DC    X'0400',X'0080',X'0000'       OUTHDR2                    76750019
         DC    X'0400',X'0040',X'0008'       OUTTLR2                    76800019
         DC    X'0400',X'0020',X'0010'       OUTHDR3                    76850019
         DC    X'0400',X'0010',X'0018'       OUTTLR3                    76900019
         DC    X'0400',X'0008',X'0020'       OUTREC                     76950019
         DC    X'0400',X'0004',X'0028'       ERROR                      77000019
         SPACE 1                                                        77050019
TAB4D    EQU   *                       TABLE END ADDRESS                77100019
         EJECT                                                          77150019
*        INVALID TRANSLATE REPLACE PARAMETER TABLE                      77200019
         SPACE 1                                                        77250019
TRANRPTB DC    X'10'                   CODE 10                          77300019
         DC    X'11'                   CODE 11                          77350019
         DC    X'13'                   CODE 13                          77400019
         DC    X'14'                   CODE 14                          77450019
         DC    X'15'                   CODE 15                          77500019
         DC    X'17'                   CODE 17                          77550019
         DC    X'51'                   CODE 51                          77600019
         DC    X'55'                   CODE 55                          77650019
         SPACE 1                                                        77700019
TRANRPLN DC    AL1(TRANRPLN-TRANRPTB)  TABLE LENGTH                     77750019
         SPACE 1                                                        77800019
*        INVALID EDIT REPLACE PARAMETER TABLE                           77850019
         SPACE 1                                                        77900019
EDITRPTB DC    X'00'                   CODE 00                          77950019
         DC    X'11'                   CODE 11                          78000019
         DC    X'12'                   CODE 12                          78050019
         DC    X'18'                   CODE 18                          78100019
         DC    X'1D'                   CODE 1D                          78150019
         DC    X'1E'                   CODE 1E                          78200019
         DC    X'3C'                   CODE 3C                          78250019
         SPACE 1                                                        78300019
EDITRPLN DC    AL1(EDITRPLN-EDITRPTB)  TABLE LENGTH                     78350019
         SPACE 1                                                        78400019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - COMM. COMMUNICATION REGION' 78450019
*        COMMON COMMUNICATION REGION                                    78500019
         SPACE 1                                                        78550019
*        THIS CSECT CONTAINS TABLES, INDICATORS, CONSTANTS, WORK        78600019
*        AREAS, AND DCB'S THAT ARE USED BY TWO OR MORE MODULES.         78650019
         SPACE 2                                                        78700019
TCRCOM   DSECT                                                          78750019
         SPACE 2                                                        78800019
         DS    0F                      FORCE FULL-WORD ALIGNMENT        78850019
OPTABLE  DS    0CL8                    CONTROL CARD OPTION TABLE        78900019
         SPACE 1                                                        78950019
IEXITS   DC    X'00'                   USER ROUTINE INDICATORS          79000019
         SPACE 1                                                        79050019
*              BIT 0 - OUTHDR2                                          79100019
*                  1 - OUTTLR2                                          79150019
*                  2 - OUTHDR3                                          79200019
*                  3 - OUTTLR3                                          79250019
*                  4 - OUTREC                                           79300019
*                  5 - ERROR                                            79350019
*                  6 - USERTAB                                          79400019
*                  7 - NOT USED                                         79450019
         SPACE 1                                                        79500019
IPARM1   DC    X'00'                   TYPE AND TRANS INDICATORS        79550019
         SPACE 1                                                        79600019
*              BIT 0 - TYPE = MTST                                      79650019
*                  1 - TYPE = MTDI                                      79700019
*                  2 - UNUSED                                           79750019
*                  3 - TRANS = STDUC                                    79800019
*                  4 - TRANS = STDLC                                    79850019
*                  5 - TRANS = USERNAME                                 79900019
*                  6 - TRANS = NOTRAN                                   79950019
*                  7 - NOT USED                                         80000019
         SPACE 1                                                        80050019
IPARM2   DC    X'00'                   EDIT, VERCHK, AND ERROPT         80100019
*                                        INDICATORS                     80150019
         SPACE 1                                                        80200019
*              BIT 0 - EDIT = EDITD                                     80250019
*                  1 - EDIT = EDITR                                     80300019
*                  2 - EDIT = NOEDIT                                    80350019
*                  3 - VERCHK = VOKCHK                                  80400019
*                  4 - VERCHK = NOCHK                                   80450019
*                  5 - ERROPT = NORMAL                                  80500019
*                  6 - ERROPT = NOERR                                   80550019
*                  7 - UNUSED                                           80600019
         SPACE 1                                                        80650019
REPL     DC    X'19'                   REPLACE PARAMETER VALUE          80700019
MINLN    DC    X'0000'                 MINLN PARAMETER VALUE            80750019
MAXLN    DC    X'0000'                 MAXLN PARAMETER VALUE            80800019
         EJECT                                                          80850019
ADDRTAB  DS    0CL28                   USER ROUTINE ADDRESS TABLE       80900019
USERADDR DC    A(0,0,0,0,0,0,0)        TABLE                            80950019
         SPACE 1                                                        81000019
*              WORD 0 - OUTHDR2                                         81050019
*                   1 - OUTTLR2                                         81100019
*                   2 - OUTHDR3                                         81150019
*                   3 - OUTTLR3                                         81200019
*                   4 - OUTREC                                          81250019
*                   5 - ERROR                                           81300019
*                   6 - TRANSLATE TABLE                                 81350019
         SPACE 2                                                        81400019
MSGADDR  DC    A(0)                    MESSAGE MODULE ADDRESS           81450019
         SPACE 2                                                        81500019
*        NAME TABLE                                                     81550019
         SPACE 1                                                        81600019
*        THIS TABLE CONTAINS DDNAMES AND USER EXIT NAMES                81650019
         SPACE 1                                                        81700019
NAMETAB  DC    CL8'SYSIN',CL8'SYSPRINT',CL8'SYSUT1',CL8'SYSUT2'         81750019
         DC    CL8'SYSUT3',CL8'OUTHDR2',CL8'OUTTLR2'                    81800019
         DC    CL8'OUTHDR3',CL8'OUTTLR3',CL8'OUTREC',CL8'ERROR'         81850019
         DC    CL8'TRANS'                                               81900019
         SPACE 1                                                        81950019
*              WORDS 0-1   SYSIN                                        82000019
*                    2-3   SYSPRINT                                     82050019
*                    4-5   SYSUT1                                       82100019
*                    6-7   SYSUT2                                       82150019
*                    8-9   SYSUT3                                       82200019
*                   10-11  OUTHDR2                                      82250019
*                   12-13  OUTTLR2                                      82300019
*                   14-15  OUTHDR3                                      82350019
*                   16-17  OUTTLR3                                      82400019
*                   18-19  OUTREC                                       82450019
*                   20-21  ERROR                                        82500019
*                   22-23  TRANS                                        82550019
         EJECT                                                          82600019
*        MESSAGE POINTER TABLE                                          82650019
         SPACE 2                                                        82700019
*        THIS TABLE CONTAINS ONE FULL-WORD ENTRY FOR EACH IEB-TYPE      82750019
*        MESSAGE (EXCLUDING SYNAD MESSAGES).  MSG01 CORRESPONDS TO      82800019
*        IEB901; MSG02 CORRESPONDS TO IEB902; ETC.                      82850019
         SPACE 1                                                        82900019
*              BYTE  1 - MESSAGE REQUEST CODE                           82950019
*                                                                       83000019
*                        X'FF' = INDICATES REQUEST                      83050019
*                        X'00' = NO REQUEST                             83100019
*                                                                       83150019
*              BYTE  2 - INSERT CODE                                    83200019
*                                                                       83250019
*                        X'00' - NO INSERT                              83300019
*                        X'01' - SYSIN                                  83350019
*                        X'02' - SYSPRINT                               83400019
*                        X'03' - SYSUT1                                 83450019
*                        X'04' - SYSUT2                                 83500019
*                        X'05' - SYSUT3                                 83550019
*                        X'06' - OUTHDR2                                83600019
*                        X'07' - OUTTLR2                                83650019
*                        X'08' - OUTHDR3                                83700019
*                        X'09' - OUTTLR3                                83750019
*                        X'0A' - OUTREC                                 83800019
*                        X'0B' - ERROR                                  83850019
*                        X'0C' - USERTAB                                83900019
*                        X'54' - BOTH SYSUT2 AND SYSUT3                 83950019
*                                                                       84000019
*                    NOTE:  IF X'54' IS SPECIFIED, THE MESSAGE IS       84050019
*                        OUTPUT TWICE, ONCE WITH SYSUT2 AND ONCE        84100019
*                        WITH SYSUT3.                                   84150019
*                                                                       84200019
*              BYTE  3 - INSERT LOCATION  (MESSAGE DISPLACEMENT)        84250019
*                                                                       84300019
*              BYTE  4 - OUTPUT LOCATION                                84350019
*                                                                       84400019
*                        BIT 0 - UNUSED                                 84450019
*                            1 - UNUSED                                 84500019
*                            2 - UNUSED                                 84550019
*                            3 - UNUSED                                 84600019
*                            4 - UNUSED                                 84650019
*                            5 - SYSPRINT IF AVAILABLE, CONSOLE         84700019
*                                OTHERWISE                              84750019
*                            6 - CONSOLE                                84800019
*                            7 - SYSPRINT                               84850019
*                                                                       84900019
*                        NOTE - BITS 6 AND 7 MAY BE ON SIMULTANEOUSLY   84950019
         SPACE 1                                                        85000019
MSGPTRS  EQU   *                       ASSIGN MSGPTRS NAME TO TABLE     85050019
MSG01    DC    X'00000002'                                              85100019
MSG02    DC    X'00000001'                                              85150019
MSG03    DC    X'00000001'                                              85200019
MSG04    DC    X'00000001'                                              85250019
MSG05    DC    X'00000001'                                              85300019
MSG06    DC    X'00000001'                                              85350019
MSG07    DC    X'00000001'                                              85400019
MSG08    DC    X'00000001'                                              85450019
MSG09    DC    X'00000001'                                              85500019
MSG10    DC    X'00030B01'             INSERT LOC = 11                  85550019
MSG11    DC    X'00010B01'             INSERT LOC = 11                  85600019
MSG12    DC    X'00020B02'             INSERT LOC = 11                  85650019
MSG13    DC    X'00000B01'             INSERT LOC = 11                  85700019
MSG14    DC    X'00002501'             INSERT LOC = 37                  85750019
MSG15    DC    X'00000F04'             INSERT LOC = 15                  85800019
MSG16    DC    X'00001504'             INSERT LOC = 21                  85850019
MSG17    DC    X'00002201'             INSERT LOC = 34                  85900019
MSG18    DC    X'00001D01'             INSERT LOC = 29                  85950019
MSG19    DC    X'00000004'                                              86000019
MSG20    DC    X'00000002'                                              86050019
         SPACE 3                                                        86100019
MOUNTID  DS    F                       MOUNT MSG ID                     86150019
IOBADDR  DS    F                       SYSUT1 IOB ADDRESS               86200019
TCRBUFL  DC    X'0000'                 TCR BUFFER LENGTH                86250019
         SPACE 1                                                        86300019
ERRIND   DC    X'00'                   ABNORMAL TERMINATION INDICATORS  86350019
         SPACE 1                                                        86400019
*              BIT 0 - CONFLICTING DCB PARAMETERS                       86450019
*                  1 - STORAGE ALLOCATION ERROR                         86500019
*                  2 - I/O ERROR IN READ AND EDIT                       86550019
*                  3 - ERROR IN JFCB READ OR MOUNT                      86600019
*                  4 - ERROR DURING READ AND EDIT                       86650019
*                  5 - ERROR IN ANALYZING CONTROL CARDS                 86700019
*                  6 - PERMANENT I/O ERROR ON QSAM GET/PUT              86750019
*                  7 - ERROR IN LOADING UTILITY MODULE                  86800019
         SPACE 1                                                        86850019
DUMMYIND DC    X'00'                   DUMMY FILE INDICATORS            86900019
         SPACE 1                                                        86950019
*              BIT 0 - UNUSED                                           87000019
*                  1 - UNUSED                                           87050019
*                  2 - UNUSED                                           87100019
*                  3 - UNUSED                                           87150019
*                  4 - SYSUT3                                           87200019
*                  5 - SYSUT2                                           87250019
*                  6 - SYSPRINT                                         87300019
*                  7 - SYSIN                                            87350019
         EJECT                                                          87400019
*        DATA CONTROL BLOCK (DCB) EXIT LISTS                            87450019
         SPACE 2                                                        87500019
*        SYSIN EXIT LIST                                                87550019
         SPACE 1                                                        87600019
         DS    0F                      FORCE FULL-WORD ALIGNMENT        87650019
INEXLST  DC    X'07'                   JFCB EXIT                        87700019
         DC    AL3(0)                  WORK AREA ADDRESS                87750019
         DC    X'85'                   DCB EXIT                         87800019
         DC    AL3(0)                  DCB EXIT ROUTINE ADDRESS         87850019
         DC    X'00'                   DUMMY ENTRY                      87900019
         DC    AL3(INLRECL)            DEFAULT TABLE ADDRESS            87950019
         SPACE 2                                                        88000019
*        SYSPRINT EXIT LIST                                             88050019
         SPACE 1                                                        88100019
PREXLST  DC    X'07'                   JFCB EXIT                        88150019
         DC    AL3(0)                  WORK AREA ADDRESS                88200019
         DC    X'05'                   DCB EXIT                         88250019
         DC    AL3(0)                  DCB EXIT ROUTINE ADDRESS         88300019
         DC    X'00'                   DUMMY ENTRY                      88350019
         DC    AL3(PRTLRECL)           DEFAULT TABLE ADDRESS            88400019
         DC    X'00'                   OUTPUT HEADER LABEL (NULL)       88450019
         DC    AL3(0)                  NULL ADDRESS                     88500019
         DC    X'80'                   OUTPUT TRAILER LABEL (NULL)      88550019
         DC    AL3(0)                  NULL ADDRESS                     88600019
         SPACE 2                                                        88650019
*        SYSUT1 EXIT LIST                                               88700019
         SPACE 1                                                        88750019
UT1EXLST DC    X'87'                   JFCB EXIT                        88800019
         DC    AL3(0)                  JFCB WORK AREA ADDRESS           88850019
         SPACE 2                                                        88900019
*        SYSUT2 EXIT LIST                                               88950019
         SPACE 1                                                        89000019
         DS    0F                                                       89050019
UT2EXLST DC    X'07'                   JFCB EXIT                        89100019
         DC    AL3(0)                  WORK AREA ADDRESS                89150019
         DC    X'05'                   DCB EXIT                         89200019
         DC    AL3(0)                  DCB EXIT ROUTINE ADDRESS         89250019
         DC    X'00'                   DUMMY ENTRY                      89300019
         DC    AL3(UT2LRECL)           DEFAULT TABLE ADDRESS            89350019
         DC    X'00'                   OUTPUT HEADER LABEL              89400019
         DC    AL3(0)                  NULL ADDRESS                     89450019
         DC    X'80'                   OUTPUT TRAILER LABEL             89500019
         DC    AL3(0)                  NULL ADDRESS                     89550019
         SPACE 2                                                        89600019
*        SYSUT3 EXIT LIST                                               89650019
         SPACE 1                                                        89700019
UT3EXLST DC    X'07'                   JFCB EXIT                        89750019
         DC    AL3(0)                  WORK AREA ADDRESS                89800019
         DC    X'05'                   DCB EXIT                         89850019
         DC    AL3(0)                  DCB EXIT ROUTINE ADDRESS         89900019
         DC    X'00'                   DUMMY ENTRY                      89950019
         DC    AL3(UT3LRECL)           DEFAULT TABLE ADDRESS            90000019
         DC    X'00'                   OUTPUT HEADER LABEL              90050019
         DC    AL3(0)                  NULL ADDRESS                     90100019
         DC    X'80'                   OUTPUT TRAILER LABEL             90150019
         DC    AL3(0)                  NULL ADDRESS                     90200019
         SPACE 2                                                        90250019
*        DCB PARAMETER DEFAULTS                                         90300019
         SPACE 1                                                        90350019
INLRECL  DC    X'0050'                 SYSIN LRECL  - 80                90400019
INBLK    DC    X'0050'                 SYSIN BLKSIZE - 80               90450019
INRECFM  DC    X'90'                   SYSIN - FIXED BLOCKED            90500019
INIDENT  DC    X'01'                   INTERNAL IDENTIFICATION CODE     90550019
         SPACE 1                                                        90600019
PRTLRECL DC    X'0079'                 SYSPRINT LRECL -  121            90650019
PRTBLK   DC    X'0079'                 SYSPRINT BLKSIZE - 121           90700019
PRTRECFM DC    X'94'                   SYSPRINT - FIXED BLOCKED ASA     90750019
PRTIDENT DC    X'02'                   INTERNAL IDENTIFICATION CODE     90800019
         SPACE 1                                                        90850019
UT2LRECL DC    X'0000'                 SYSUT2 LRECL                     90900019
UT2BLK   DC    X'0000'                 SYSUT2 BLKSIZE                   90950019
UT2RECFM DC    X'50'                   SYSUT2 RECFM - VARIABLE BLOCKED  91000019
UT2IDENT DC    X'04'                   INTERNAL IDENTIFICATION CODE     91050019
         SPACE 1                                                        91100019
UT3LRECL DC    X'0000'                 SYSUT3 LRECL                     91150019
UT3BLK   DC    X'0000'                 SYSUT3 BLKSIZE                   91200019
UT3RECFM DC    X'50'                   SYSUT3 RECFM - VARIABLE BLOCKED  91250019
UT3IDENT DC    X'05'                   INTERNAL IDENTIFICATION CODE     91300019
         EJECT                                                          91350019
*        DATA CONTROL BLOCKS (DCB'S)                                    91400019
         SPACE 3                                                        91450019
*        SYSUT1 (TCR) DCB                                               91500019
         SPACE 2                                                        91550019
TCRDCB   DCB   DSORG=PS,MACRF=(E),DDNAME=SYSUT1,DEVD=TA,RECFM=UA,      X91600019
               BFTEK=S,EXLST=UT1EXLST,IOBAD=NULL                        91650019
         EJECT                                                          91700019
*        SYSUT2 DCB                                                     91750019
         SPACE 2                                                        91800019
UT2DCB   DCB   DSORG=PS,DDNAME=SYSUT2,DEVD=DA,EXLST=UT2EXLST,          X91850019
               SYNAD=NULL,EROPT=ABE,MACRF=(PM)                          91900019
         SPACE 3                                                        91950019
*        SYSUT3 DCB                                                     92000019
         SPACE 2                                                        92050019
UT3DCB   DCB   DSORG=PS,DDNAME=SYSUT3,DEVD=DA,EXLST=UT3EXLST,          X92100019
               SYNAD=NULL,EROPT=ABE,MACRF=(PM)                          92150019
         SPACE 3                                                        92200019
*        SYSIN DCB                                                      92250019
         SPACE 2                                                        92300019
SYSINDCB DCB   DSORG=PS,DDNAME=SYSIN,DEVD=DA,EODAD=NULL,MACRF=(GM),    X92350019
               EXLST=INEXLST,EROPT=ACC,SYNAD=NULL                       92400019
         SPACE 3                                                        92450019
*        SYSPRINT DCB                                                   92500019
         SPACE 2                                                        92550019
SYSPRDCB DCB   DSORG=PS,DDNAME=SYSPRINT,DEVD=DA,EXLST=PREXLST,         X92600019
               MACRF=(PM)                                               92650019
         EJECT                                                          92700019
*        GETMAINED STORAGE ADDRESSES                                    92750019
         SPACE 2                                                        92800019
CARDAREA DS    F                       CARD INPUT AREA                  92850019
JFCBAREA DS    F                       JFCB AREA ADDRESS                92900019
PRTAREA  DS    F                       SYSPRINT OUTPUT AREA             92950019
PRTLNGTH DS    F                       PRINT AREA LENGTH                93000019
COLUMN9  DS    F                       CARD INPUT COLUMN 9 ADDRESS      93050019
CARDEND  DS    F                       INPUT AREA ENDING ADDRESS        93100019
         SPACE 2                                                        93150019
USERNAME DC    7XL8'00'                USER ROUTINE NAME TABLE          93200019
           SPACE 1                                                      93250019
*              WORDS 0 & 1  - OUTHDR2 ROUTINE                           93300019
*                    2 & 3  - OUTTLR2 ROUTINE                           93350019
*                    4 & 5  - OUTHDR3 ROUTINE                           93400019
*                    6 & 7  - OUTTLR3 ROUTINE                           93450019
*                    8 & 9  - OUTREC  ROUTINE                           93500019
*                   10 & 11 - ERROR ROUTINE                             93550019
*                   12 & 13 - TRANSLATE TABLE                           93600019
           SPACE 2                                                      93650019
MISCIND  DC    X'00'                   MISCELLANEOUS INDICATORS         93700019
         SPACE 1                                                        93750019
*              BIT 0 - UNUSED                                           93800019
*                  1 - UNUSED                                           93850019
*                  2 - UNUSED                                           93900019
*                  3 - SYSUT2 LRECL REQUIRES MAXLN INCREMENT            93950019
*                  4 - SYSUT2 BLKSIZE REQUIRES MAXLN INCREMENT          94000019
*                  5 - SYSUT3 LRECL REQUIRES MAXLN INCREMENT            94050019
*                  6 - SYSUT3 BLKSIZE REQUIRES MAXLN INCREMENT          94100019
*                  7 - ALTERNATE DDNAMES FOUND                          94150019
             SPACE 2                                                    94200019
         SPACE 1                                                        94250019
RETCODE  DC    X'00'                   RETURN CODE                      94300019
TCRDEV   DC    CL3'000'                TCR DEVICE                       94350019
VOLSER   DC    CL6' '                  VOLUME SERIAL NUMBER             94400019
PRTRTN   DC    X'00'                   MESSAGE WRITER OPTION IND        94450019
CARRCTRL DC    X'40'                   CARRIAGE CONTROL                 94500019
         SPACE 1                                                        94550019
VTCR220  DS    F                       MESSAGE DISPLAY                  94600019
CURMSGAD DS    F                       CURRENT SYSPRINT MSG ADDRESS     94650019
MSGAD    DS    F                       SINGLE MESSAGE ADDRESS           94700019
MSGLN    DS    F                       SINGLE MSG LENGTH                94750019
JOBNAME  DC    CL8' '                  JOB NAME                         94800019
STEPNAME DC    CL8' '                  STEPNAME                         94850019
  TITLE 'IEBTCR04 - CONTROL CARD ANALYZER - IHADCB DSECT'               94900019
         DS    0F                      FORCE FULL-WORD ALIGNMENT        94950019
         DCBD  DSORG=PS                                                 95000019
         END   IEBTCR04                                                 95050019
