  TITLE 'IEBTCRIN - DRIVER MODULE - INTRODUCTORY COMMENTARY'            00050019
*                                                                     * 00100019
*TITLE 'IEBTCRIN' - TCR DATA SET UTILITY - DRIVER MODULE              * 00150019
*                                                                     * 00200019
*STATUS:  CHANGE LEVEL 000                                            * 00250019
*                                                                     * 00300019
*FUNCTION/OPERATION:                                                  * 00350019
*                                                                     * 00400019
*   IEBTCRIN IS THE DRIVER MODULE OF THE IEBTCRIN DATA SET UTILITY.   * 00450019
*   IT IS THE FIRST AND ONLY MODULE BROUGHT INTO CORE UPON INVOCATION * 00500019
*   OF THE UTILITY.  IT REMAINS RESIDENT THROUGHOUT OPERATION OF THE  * 00550019
*   UTILITY.  IT CONSISTS OF THREE CSECTS - IEBTCRIN, TCR220, AND     * 00600019
*   TCRCOM.                                                           * 00650019
*                                                                     * 00700019
*   IEBTCRIN IS THE GENERAL PROCESSING ROUTINE.  IT PROCESSES THE     * 00750019
*   USER DDNAME PARAMETER LIST, LOADS THE MESSAGE MODULE (IEBTCR02),  * 00800019
*   LINKS TO THE JFCB ANALYZER (IEBTCR03), OPENS THE SYSPRINT DATA    * 00850019
*   SET AND ALLOCATES PRINT AREA STORAGE, OPENS THE SYSIN DATA SET    * 00900019
*   IF ONE HAS BEEN PROVIDED AND LINKS TO THE CONTROL CARD ANALYZER   * 00950019
*   (IEBTCR04), SETS CONTROL CARD DEFAULTS IF NO SYSIN DATA SET WAS   * 01000019
*   PROVIDED, LOADS THE USER TRANSLATE TABLE AND EXIT ROUTINES, INCRE-* 01050019
*   MENTS DATA CONTROL BLOCK (DCB) DEFAULTS BY MAXLN, OPENS THE       * 01100019
*   SYSUT1 DCB AND ISSUES A MOUNT MESSAGE, LINKS TO THE READ AND      * 01150019
*   EDIT PROCESSOR (IEBTCR05), ISSUES SYNAD MESSAGES TO SYSPRINT FOR  * 01200019
*   PERMANENT I/O ERRORS, AND RETURNS A COMPLETION CODE TO THE CALL-  * 01250019
*   ING TASK.                                                         * 01300019
*                                                                     * 01350019
*   TCR220 IS THE MESSAGE WRITER FOR THE UTILITY.  IT CONTAINS TWO    * 01400019
*   PROCESSING OPTIONS - 1) CONSECUTIVE OUTPUTTING OF ALL IEB9XXX     * 01450019
*   MESSAGES AND  2) SINGLE LINE SYSPRINT OUTPUTTINE OF CONTROL       * 01500019
*   STATEMENT IMAGES, PAGE HEADINGS, SYNAD MESSAGES, ETC.             * 01550019
*                                                                     * 01600019
*   TCRCOM IS THE COMMON COMMUNICATION REGION OF THE UTILITY.  IT     * 01650019
*   CONTAINS TABLES, INDICATORS, STORAGE AREAS, AND CONSTANT DATA     * 01700019
*   AREAS THAT ARE USED BY TWO OR MORE MODULES.                       * 01750019
*                                                                     * 01800019
*ENTRY POINTS:                                                        * 01850019
*                                                                     * 01900019
*        IEBTCRIN - UTILITY ENTRY POINT                               * 01950019
*                                                                     * 02000019
*   MAY BE CALLED BY MEANS OF ATTACH, LINK, OR LOAD AND CALL MACRO-   * 02050019
*   INSTRUCTIONS.  THE ADDRESS OF A PARAMETER LIST COMPLYING WITH     * 02100019
*   STANDARD OS CONVENTIONS MUST BE PASSED IN REGISTER 1. THIS        * 02150019
*   PARAMETER LIST MUST BE OF THE FORM:                               * 02200019
*                                                                     * 02250019
*                   OPTLIST ADDRESS                                   * 02300019
*                   DDNAME LIST ADDRESS                               * 02350019
*                                                                     * 02400019
*   THE SIGN BIT OF THE LAST FULL WORD OF THE LIST MUST BE SET TO     * 02450019
*   ONE TO INDICATE THE END OF THE LIST.  UNUSED ENTRIES MUST BE SET  * 02500019
*   TO ZERO.  POSSIBLE INVOKING OPTIONS:                              * 02550019
*                                                                     * 02600019
*        //       EXEC  PGM=IEBTCRIN                                  * 02650019
*                                                                     * 02700019
*                 ATTACH EP=IEBTCRIN,PARAM=(OPTLIST,DDLIST),VL=1,    X* 02750019
*                                                                     * 02800019
*                 LINK  EP=IEBTCRIN,PARAM=(OPTLIST,DDLIST),VL=1       * 02850019
*                                                                     * 02900019
*                 LOAD  EP=IEBTCRIN                                   * 02950019
*                 CALL  IEBTCRIN,(OPTLIST,DDLIST),VL                  * 03000019
*                                                                     * 03050019
*        TCR220 - MESSAGE WRITER                                      * 03100019
*                                                                     * 03150019
*   PARAMETER DATA IS PASSED BY NAME BY ONE OF TWO OPTIONS:           * 03200019
*                                                                     * 03250019
*   1)  BY MEANS OF THE COMMON COMMUNICATION REGION TABLE MSGPTRS     * 03300019
*       WHICH CONTAINS ONE ENTRY FOR EACH IEB-TYPE MESSAGE (EXCLUDING * 03350019
*       SYNAD MESSAGES).  THIS OPTION IS USED TO SUCCESSIVELY OUTPUT  * 03400019
*       IEBXXXX MESSAGES WHICH HAVE BEEN REQUESTED BY VARIOUS PHASES  * 03450019
*       OF THE UTILITY.                                               * 03500019
*                                                                     * 03550019
*   2)  BY MEANS OF MESSAGE ADDRESS AND MESSAGE LENGTH INDICATORS     * 03600019
*       IN THE COMMON COMMUNICATION REGION (MSGAD AND MSGLN,          * 03650019
*       RESPECTIVELY).                                                * 03700019
*                                                                     * 03750019
*   THE SECOND OPTION IS REQUESTED BY SETTING BIT 6 OF THE COMMON     * 03800019
*   COMMUNICATION REGION INDICATOR PRTRTN TO 1.  BIT 6 SET TO ZERO    * 03850019
*   INDICATES OPTION 1.                                               * 03900019
*                                                                     * 03950019
*   CALLING SEQUENCE IS AS FOLLOWS:                                   * 04000019
*                                                                     * 04050019
*               L     R15,ATCR220                                     * 04100019
*               BALR  R14,R15                                         * 04150019
*               .                                                     * 04200019
*               .                                                     * 04250019
*               .                                                     * 04300019
*      ATCR220  DC    A(TCR220)                                       * 04350019
*                                                                     * 04400019
*INPUT:                                                               * 04450019
*                                                                     * 04500019
*   1)  STANDARD PARAMETER LIST PASSED VIA REGISTER 1.                * 04550019
*                                                                     * 04600019
*   2)  SYSIN DATA SET CONTAINING UTILITY CONTROL STATEMENTS.  THE    * 04650019
*       DATA SET IS OPENED AND CLOSED BY THE DRIVER.  READING AND     * 04700019
*       PROCESSING OF THE STATEMENTS IS PERFORMED BY THE CONTROL      * 04750019
*       CARD ANALYZER MODULE (IEBTCR04).                              * 04800019
*                                                                     * 04850019
*   3)  SYSUT1 TAPE CARTRIDGE READER DATA SET.  THE DATA SET IS       * 04900019
*       OPENED BY THE DRIVER.  READING AND EDITING IS PERFORMED BY    * 04950019
*       THE READ AND EDIT MODULE (IEBTCR05).                          * 05000019
*                                                                     * 05050019
*OUTPUT:                                                              * 05100019
*                                                                     * 05150019
*   1)  SYSPRINT DATA SET.  DATA CONSISTS OF CONTROL STATEMENT        * 05200019
*       IMAGES, UTILITY COMPLETION MESSAGES, AND IEBXXXX MESSAGES.    * 05250019
*       OUTPUT IS PERFORMED BY MEANS OF THE QSAM ACCESS METHOD.       * 05300019
*                                                                     * 05350019
*   2)  CONSOLE MESSAGES.  CONSISTS OF A MOUNT MESSAGE AND CERTAIN    * 05400019
*       IEB9XXX ERROR MESSAGES.                                       * 05450019
*                                                                     * 05500019
*EXTERNAL ROUTINES:                                                   * 05550019
*                                                                     * 05600019
*        IEBTCR02 - MESSAGE MODULE                                    * 05650019
*                                                                     * 05700019
*   CONTAINS IEBXXXX MESSAGES, A SYSPRINT PAGE HEADING, AND A         * 05750019
*   UTILITY COMPLETION MESSAGE.                                       * 05800019
*                                                                     * 05850019
*        IEBTCR03 - JFCB ANALYZER                                     * 05900019
*                                                                     * 05950019
*   ANALYZES AND EXTRACTS INFORMATION FROM THE DATA SET JOB FILE      * 06000019
*   CONTROL BLOCKS AND FROM THE TASK INPUT/OUTPUT TABLE (TIOT).       * 06050019
*   IT ATTEMPTS TO SET DEFAULTS FOR THOSE DCB PARAMETERS THAT HAVE    * 06100019
*   BEEN OMITTED.                                                     * 06150019
*                                                                     * 06200019
*        IEBTCR04 - CONTROL CARD ANALYZER                             * 06250019
*                                                                     * 06300019
*   READS AND ANALYZES CONTROL STATEMENTS PROVIDED BY THE USER. IT    * 06350019
*   VALIDATES THE STATEMENT CONTENT AND FORMAT AND SETS OPTIONS IN THE* 06400019
*   COMMON COMMUNICATION REGION FOR USE OF THE DRIVER (IEBTCRIN)      * 06450019
*   AND THE READ/EDIT MODULE (IEBTCR05).                              * 06500019
*                                                                     * 06550019
*        IEBTCR05 - READ/EDIT MODULE                                  * 06600019
*                                                                     * 06650019
*   THIS MODULE READS DATA FROM THE SYSUT1 TAPE CARTRIDGE READER      * 06700019
*   DATA SET, EDITS IT, AND OUTPUTS IT TO THE SYSUT2 AND SYSUT3       * 06750019
*   DATA SETS.                                                        * 06800019
*                                                                     * 06850019
*EXITS-NORMAL:  TCR720 - DCB EXIT                                     * 06900019
*   A DCB EXIT IS TAKEN FOR EACH DATA SET AT OPEN.  DEFAULTS ARE SET  * 06950019
*   FOR MISSING DCB PARAMETERS AND A COMPARISON IS MADE OF ALL PARA-  * 07000019
*   METERS TO DETERMINE INCONSISTENCIES.                              * 07050019
*                                                                     * 07100019
*     -ERROR:                                                         * 07150019
*                                                                     * 07200019
*   1)  TCR740 - QSAM SYNAD ROUTINE.  THIS ROUTINE IS ENTERED WHENEVER* 07250019
*       A PERMANENT I/O ERROR OCCURS ON THE SYSIN, SYSPRINT, SYSUT2,  * 07300019
*       OR SYSUT3 DATA SET.  THE ROUTINE ISSUES A SYSNADAF MACRO-     * 07350019
*       INSTRUCTION AND OUTPUTS THE RESULTING MESSAGE TO THE SYSPRINT * 07400019
*       DATA SET.  IF THE ERROR OCCURRED ON SYSPRINT, THE SYNAD       * 07450019
*       MESSAGE IS OUTPUT TO THE CONSOLE.  IF THE MESSAGE BEING OUTPUT* 07500019
*       AT THE TIME OF THE ERROR IS AN IEB-TYPE MESSAGE, IT IS ALSO   * 07550019
*       WRITTEN ON THE CONSOLE.  THE ADDRESS OF THE MESSAGE IS STORED * 07600019
*       IN THE COMMON COMMUNICATION REGION FULL-WORD CURMSGAD.        * 07650019
*                                                                     * 07700019
*   2)  TCR800 - STAE EXIT ROUTINE.   THIS ROUTINE IS ENTERED WHENEVER* 07750019
*       AN ABEND OCCURS DURING EXECUTION OF ANY PHASE OF THE UTILITY. * 07800019
*       AT ENTRY THE ABEND COMPLETION CODE IS PRESENT EITHER IN A STAE* 07850019
*       WORK AREA OR IN REGISTER 1, DEPENDING UPON WHETHER OR NOT A   * 07900019
*       WORK AREA WAS PROVIDED.  REGISTER 0 IS SET TO ZERO IF A WORK  * 07950019
*       AREA HAS BEEN PROVIDED; TWELVE, IF ONE HAS NOT.  THE ROUTINES * 08000019
*       DETERMINE WHETHER THE ABEND WAS CAUSED BY A USER ROUTINE LOAD * 08050019
*       ERROR.  IF IT WAS THEY REQUEST THAT A RETRY ROUTINE BE LOADED * 08100019
*       WHICH SETS INDICATORS AND RETURNS TO THE ABEND-ING MODULE     * 08150019
*       AT A POINT SPECIFIED BY MEANS OF THE STORAGE AREA RETPT.      * 08200019
*       IF THE ERROR WAS NOT A USER ROUTINE LOAD ERROR, THE EXIT      * 08250019
*       ROUTINE ALLOWS ABEND PROCESSING TO CONTINUE.                  * 08300019
*                                                                     * 08350019
*TABLES/WORK AREAS:                                                   * 08400019
*                                                                     * 08450019
*   1)  OPTABLE - CONTAINS CONTROL CARD OPTIONS.  IT IS CONSTRUCTED   * 08500019
*       BY THE CONTROL CARD ANALYZER FOR USE BY THE DRIVER AND THE    * 08550019
*       READ/EDIT MODULE.                                             * 08600019
*                                                                     * 08650019
*   2)  ADDRTAB - CONTAINS ADDRESSES OF USER EXIT AND TRANSLATE       * 08700019
*       ROUTINES AND OF THE MESSAGE MODULE.                           * 08750019
*                                                                     * 08800019
*   3)  NAMETAB - CONTAINS DDNAMES AND EXIT NAMES.                    * 08850019
*                                                                     * 08900019
*   4)  MSGPTRS - CONTAINS ONE ENTRY FOR EACH IEB-TYPE MESSAGE CON-   * 08950019
*       TAINED IN THE MESSAGE MODULE.  EACH ENTRY CONTAINS A REQUEST  * 09000019
*       BYTE, A NAME INSERT BYTE, AN INSERT LOCATION BYTE, AND AN     * 09050019
*       OUTPUT LOCATION BYTE.  IT IS USED FOR REQUESTING OUTPUT OF    * 09100019
*       IEB-TYPE MESSAGES.  A DIRECT ONE-TO-ONE CORRESPONDENCE        * 09150019
*       EXISTS BETWEEN THIS TABLE AND THE MESSAGE MODULE TABLE.       * 09200019
*                                                                     * 09250019
*   5)  INLRECL, PRTLRECL, UT2LRECL, UT3LRECL - DCB DEFAULT TABLES    * 09300019
*       USED BY IEBTCRIN AND IEBTCR03 FOR CONSTRUCTING DEFAULTS       * 09350019
*                                                                     * 09400019
*   6)  USERNAME - CONTAINS USER ROUTINE NAMES                        * 09450019
*                                                                     * 09500019
*ATTRIBUTES:  NON-REENTRANT AND NON-REUSABLE.                         * 09550019
*                                                                     * 09600019
*NOTES:  IEBTCR03, IEBTCR04, AND IEBTCR05 ALL USE THE COMMON          * 09650019
*   COMMUNICATION REGION SET UP WITHIN THE DRIVER MODULE.             * 09700019
*                                                                     * 09750019
*   CONTROL PASSES TO THE DRIVER MODULE FOR INSERTION OF DCB          * 09800019
*   PARAMETERS AT OPEN, FOR CONSTRUCTION OF A SYNAD MESSAGE FOLLOWING * 09850019
*   A PERMANENT I/O ERROR, AND DURING ABEND PROCESSING.               * 09900019
*                                                                     * 09950019
*   A DOM MACRO-INSTRUCTION IS ISSUED BY THE READ/EDIT MODULE         * 10000019
*   (IEBTCR05) TO ERASE THE MOUNT MESSAGE ISSUED BY THE DRIVER ROUTINE* 10050019
*   TCR180.                                                           * 10100019
*                                                                     * 10150019
*   THIS MODULE CONTAINS TYPE C CHARACTER CODE DEPENDENCIES.  THE     * 10200019
*   OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL REPRESENTATION  * 10250019
*   OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT TO THE ONE USED * 10300019
*   AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED SO THAT REDEFINI- * 10350019
*   TION OF CHARACTER CONSTANTS, BY RE-ASSEMBLY, WILL RESULT IN A     * 10400019
*   CORRECT MODULE FOR THE NEW DEFINITIONS.  CHARACTER CONSTANTS      * 10450019
*   INVOLVED ARE AS FOLLOWS:                                          * 10500019
*                                                                     * 10550019
*   1)  COMMA AND HEXSPACE WHICH ARE USED BY ROUTINE TCR180 FOR CON-  * 10600019
*       STRUCTING THE MOUNT MESSAGE                                   * 10650019
*                                                                     * 10700019
*   2)  SYNUR, SYNTA, AND SYNDA WHICH ARE USED FOR DETERMINING THE    * 10750019
*       TYPE OF MESSAGE PROVIDED BY THE QSAM SYNADAF INSTRUCTION      * 10800019
*       (UNIT RECORD, TAPE, OR DIRECT ACCESS).                        * 10850019
*                                                                     * 10900019
*   3)  SYNMSGUR, SYNMSGTA, AND SYNMSGDA WHICH CONTAIN MESSAGE        * 10950019
*       IDENTIFIERS (IEB920I, IEB921I, IEB922I)                       * 11000019
*                                                                     * 11050019
*                                                                     * 11100019
*   IF WORLD TRADE REQUIREMENTS NECESSITATE MODIFICATION OF THE       * 11150019
*   MESSAGE TEXT CONTAINED IN THE MESSAGE MODULE, IT MAY BE NECESSARY * 11200019
*   TO CHANGE THE INSERT LOCATION DISPLACEMENTS CONTAINED IN THE      * 11250019
*   MESSAGE POINTER TABLE MSGPTRS PRESENT IN THE COMMON COMMUNICATION * 11300019
*   REGION CSECT TCRCOM.  INSTRUCTIONS ARE PROVIDED FOR MAKING THIS   * 11350019
*   MODIFICATION.                                                     * 11400019
*                                                                     * 11450019
*   IF CHANGES ARE MADE TO THE MESSAGE IDENTIFIERS CONTAINED IN THE   * 11500019
*   MESSAGE MODULE, IT MAY ALSO BE NECESSARY TO CHANGE THE IDENTIFIERS* 11550019
*   IEB920I, IEB921I, AND IEB922I WHICH ARE DEFINED BY THE DC'S       * 11600019
*   SYNMSGUR, SYNMSGTA, AND SYNMSGDA CONTAINED IN THIS MODULE.        * 11650019
*   COMMENTS ARE PROVIDED.                                            * 11700019
  TITLE 'IEBTCRIN - DRIVER MODULE - REGISTER DEFINITIONS'               11750019
IEBTCRIN START 0                                                        11800019
         SPACE 2                                                        11850019
*        REGISTER DEFINITIONS                                           11900019
         SPACE 2                                                        11950019
LNKREG0  EQU   0                       LOAD MODULE LINKAGE REGISTER     12000019
PARMREG  EQU   1                       PARAMETER LIST REGISTER          12050019
NAMEREG  EQU   3                       USER NAME TABLE PTR              12100019
ADDREG   EQU   4                       USER RTN ADDR TABLE PTR          12150019
DCBREG   EQU   5                       DCB REGISTER                     12200019
INDREG   EQU   5                       INDICATOR MASK REGISTER          12250019
MSGCTR   EQU   6                       MSG INSERT INDICATOR             12300019
COMMREG  EQU   11                      COMMUNICATION REGION             12350019
BASEREG  EQU   12                      BASE REGISTER                    12400019
SAVEREG  EQU   13                      SAVEAREA REGISTER                12450019
RETREG   EQU   14                      RETURN REGISTER                  12500019
LNKREG15 EQU   15                      SUBROUTINE LINKAGE REGISTER      12550019
BASE15   EQU   15                      BASE REGISTER                    12600019
         SPACE 1                                                        12650019
R0       EQU   0                       REGISTER   0                     12700019
R1       EQU   1                       REGISTER   1                     12750019
R2       EQU   2                       REGISTER   2                     12800019
R3       EQU   3                       REGISTER   3                     12850019
R4       EQU   4                       REGISTER   4                     12900019
R5       EQU   5                       REGISTER   5                     12950019
R6       EQU   6                       REGISTER   6                     13000019
R7       EQU   7                       REGISTER   7                     13050019
R8       EQU   8                       REGISTER   8                     13100019
R9       EQU   9                       REGISTER   9                     13150019
R10      EQU   10                      REGISTER  10                     13200019
R12      EQU   12                      REGISTER  12                     13250019
R14      EQU   14                      REGISTER  14                     13300019
R15      EQU   15                      REGISTER  15                     13350019
  TITLE 'IEBTCRIN - DRIVER MODULE - MAINLINE'                           13400019
*        THIS SECTION SAVES THE CALLING MODULE'S BASE REGISTERS,        13450019
*        SETS UP A SAVEAREA ADDRESS, AND ESTABLISHES BASE REGISTERS     13500019
*        FOR THE MAIN CSECT AND FOR THE COMMUNICATION REGION CSECT.     13550019
         SPACE 2                                                        13600019
         SAVE  (14,12),T,IEBTCRIN      SAVE REGISTERS                   13650019
         BALR  BASEREG,R0              ESTABLISH BASE REGISTER          13700019
         USING *,BASEREG               INDICATE BASE REGISTER           13750019
TCR050   LR    R15,SAVEREG             SET UP SAVEAREA POINTERS         13800019
         ST    R15,SAVEAREA+4                                           13850019
         LA    SAVEREG,SAVEAREA                                         13900019
         ST    SAVEREG,8(R15)                                           13950019
         SR    R15,R15                                                  14000019
         ST    R15,0(SAVEREG)                                           14050019
         ST    PARMREG,SAVEPARM        SAVE PARAMETER LIST POINTER      14100019
         ST    BASEREG,DRIVBASE        STORE DRIVER BASE ADDRESS        14150019
         STAE TCR800,CT,PARAM=USERLIST,XCTL=NO  ESTABLISH STAE          14200019
*                                      ENVIRONMENT                      14250019
         LTR   LNKREG15,LNKREG15       SUCCESSFUL CREATION              14300019
         BZ    TCR060                  BR YES                           14350019
         MVI   USERLIST+1,STAEFAIL     INDICATE FAILURE                 14400019
TCR060   L     COMMREG,ATCRCOM         LOAD BASE REG FOR COMMON AREA    14450019
         USING TCRCOM,COMMREG          INDICATE COMM. REGION BASE REG   14500019
         EJECT                                                          14550019
*        DRIVER MAINLINE                                                14600019
         SPACE 1                                                        14650019
*        THIS ROUTINE CONTROLS THE FLOW OF THE ENTIRE UTILITY. IT       14700019
*        CALLS THE FOLLOWING PROCESSING ROUTINES AND MODULES:           14750019
         SPACE 1                                                        14800019
*              TCR120 - PARAMETER LIST PROCESSOR                        14850019
*              TCR130 - MESSAGE MODULE LOADER                           14900019
*            IEBTCR03 - JOB FILE CONTROL BLOCK ANALYZER                 14950019
*              TCR140 - SYSPRINT OPEN AND ALLOCATION                    15000019
*              TCR150 - CONTROL CARD ANALYZER INTERFACE                 15050019
*              TCR160 - USER ROUTINE LOADER                             15100019
*              TCR170 - DCB DEFAULT COMPLETION                          15150019
*              TCR180 - SYSUT1 OPEN ROUTINE                             15200019
*            IEBTCR05 - READ/EDIT MODULE                                15250019
*              TCR190 - SYSUT1 SYNAD ROUTINE                            15300019
*              TCR220 - MESSAGE WRITER                                  15350019
         SPACE 1                                                        15400019
*        FOLLOWING EXECUTION OF EACH CALLED ROUTINE OR MODULE,          15450019
*        THE DRIVER MAINLINE ROUTINE TESTS WHETHER OR NOT EXECUTION     15500019
*        SHOULD CONTINUE.                                               15550019
         SPACE 2                                                        15600019
TCR100   BAL   RETREG,TCR120           LOAD ADDR PARAM PROC ROUTINE     15650019
         BAL   RETREG,TCR130           LOAD ADDR MSG MODULE LOAD RTN    15700019
TCR102   LINK  EP=IEBTCR03,PARAM=TCRCOM  LINK TO JFCB ANALYZER          15750019
         DELETE  EP=IEBTCR03           DELETE JFCB ANALYZER             15800019
         BAL   RETREG,TCR140           OPEN SYSPRINT DCB, ALLOCATE      15850019
*                                        STORAGE                        15900019
         TM    ERRIND,ALLONE           ANY ERROR                        15950019
         BNZ   TCR108                  BR YES                           16000019
         BAL   RETREG,TCR150           CONTROL CARD ANALYZER INTERFACE  16050019
         TM    ERRIND,ALLONE           CONTROL CD ERROR?                16100019
         BNZ   TCR108                  BR - YES                         16150019
         BAL   RETREG,TCR160           LOAD USER EXIT RTN LOADER ADDR   16200019
         TM    ERRIND,LOADERR          ERROR LOADING USER EXIT ROUTINES 16250019
         BO    TCR108                  BR - YES                         16300019
         BAL   RETREG,TCR170           COMPLETE DCB DEFAULTS WITH MAXLN 16350019
*                                        INCREMENT                      16400019
         TM    ERRIND,ALLONE           ANY ERROR                        16450019
         BNZ   TCR108                  BR YES                           16500019
         BAL   RETREG,TCR180           OPEN TCR AND ISSUE MOUNT MSG     16550019
         LINK  EP=IEBTCR05,PARAM=TCRCOM   LINK TO READ/EDIT MODULE      16600019
         TM    MSG14+1,UT2             SYSUT2 DCB PARAMETERS MISSING    16650019
         BO    TCR105                  BR NO                            16700019
         PACK  MSG14+1(1),MSG14+1(1)   SWITCH THE TWO INSERT DIGITS     16750019
TCR105   TM    ERRIND,IORDERR          PERMANENT I/O ERROR SYSUT1       16800019
         BNO   TCR107                  BR NO                            16850019
         TM    DUMMYIND,DUMSYSP        SYSPRINT DUMMY                   16900019
         BO    TCR107                  BR YES                           16950019
         BAL   RETREG,TCR190           ISSUE SYNAD MESSAGE FOR SYSUT1   17000019
TCR107   CLOSE  (TCRDCB)               CLOSE SYSUT1 DCB                 17050019
         DELETE  EP=IEBTCR05           DELETE READ/EDIT MODULE          17100019
         TM    ERRIND,RDEDERR          ERROR IN READ & EDIT             17150019
         BO    TCR1073                 BR YES                           17200019
         TM    ERRIND,CONFLERR         INCONSISTENT DCB PARAMETERS      17250019
         BNO   TCR108                  BR NO                            17300019
TCR1073  MVI   RETCODE,CODE16          SET RETURN CODE 16               17350019
TCR108   MVI   CARRCTRL,DOUBLESP       SET DOUBLE SPACE                 17400019
         L     LNKREG15,ATCR220        LOAD MESSAGE WRITER ADDRESS      17450019
         BALR  RETREG,LNKREG15         DISPLAY MESSAGES                 17500019
TCR1083  TM    DUMMYIND,DUMSYSP        SYSPRINT DUMMY                   17550019
         BO    TCR109                  BR YES                           17600019
         MVI   CARRCTRL,DOUBLESP       DOUBLE SPACE                     17650019
         L     R5,MSGADDR              LOAD MSG TABLE ADDRESS           17700019
         L     R6,COMPMSG(R5)          LOAD MSG ADDRESS                 17750019
         LA    R6,0(R6)                CLEAR LENGTH BYTE                17800019
         ST    R6,MSGAD                STORE MSG ADDRESS                17850019
         MVC   MSGLN(1),COMPMSG(R5)    STORE MSG LENGTH                 17900019
         OI    PRTRTN,RTN310           SET SINGLE MSG INDICATOR         17950019
         L     LNKREG15,ATCR220        LOAD MESSAGE WRITER ADDRESS      18000019
         BALR  RETREG,LNKREG15         DISPLAY MESSAGE                  18050019
         CLOSE (SYSPRDCB)              CLOSE SYSPRINT                   18100019
         TM    ERRIND,ALLOCERR         GETMAIN ALLOCATION ERROR         18150019
         BO    TCR109                  BR YES                           18200019
         L     R1,PRTAREA              LOAD ADDR PRINT STORAGE          18250019
         L     R0,PRTLNGTH             LOAD STORAGE LENGTH              18300019
         FREEMAIN  R,LV=(0),A=(1)      FREE SYSPRINT AREA               18350019
TCR109   STAE  0                                                        18400019
         XR    R15,R15                 CLEAR RETURN CODE REGISTER       18450019
         IC    R15,RETCODE             INSERT RETURN CODE               18500019
         L     SAVEREG,4(SAVEREG)                                       18550019
         RETURN (14,12),T,RC=(15)                                       18600019
  TITLE 'IEBTCRIN - DRIVER MODULE - PARAMETER LIST PROCESSOR'           18650019
*        PARAMETER LIST PROCESSOR                                       18700019
         SPACE 1                                                        18750019
*        THIS ROUTINE STORES ANY ALTERNATE DDNAMES THAT MAY HAVE        18800019
*        BEEN PROVIDED BY THE INVOKING MODULE.                          18850019
         SPACE 2                                                        18900019
TCR120   ST    RETREG,SAVE100          SAVE RETURN REGISTER             18950019
         L     R4,SAVEPARM             LOAD ADDR PARAMETER LIST         19000019
         TM    OPTLIST(R4),LASTPARM    PARAMETER LIST VOID?             19050019
         BO    TCR129                  BR IF YES                        19100019
         L     R5,DDLIST(R4)           LOAD ADDR DDLIST                 19150019
         LTR   R5,R5                   LOAD AND TEST DDLIST ADDR        19200019
         BZ    TCR129                  BR IF ADDRESS ZERO               19250019
         LH    R9,0(R5)                LOAD COUNT                       19300019
         LA    R5,DSYSIN-6(R5)         SET AT FIRST DD ENTRY MINUS 8    19350019
         LA    R6,NAMETAB-DDLNGTH      LOAD ZERO ENTRY OF DDTABLE       19400019
         LA    R7,DSYSIN               INITIALIZE REGISTER TO ZERO      19450019
         LA    R8,DDINCR               LOAD INCREMENT                   19500019
         LA    R3,DSYSPRT+DDINCR       SET BYPASS INDICATOR             19550019
TCR122   BXH   R7,R8,TCR126            BR WHEN ALL ENTRIES TESTED       19600019
         LA    R5,DDINCR(R5)           INCREMENT INPUT DDLIST ADDR      19650019
         LA    R6,DDINCR(R6)           INCREMENT OUTPUT DDLIST ADDR     19700019
         CLC   0(DDLNGTH,R5),ZEROES    DDNAME EQUAL TO HEX ZEROES       19750019
         BE    TCR124                  BR IF YES                        19800019
         MVC   0(DDLNGTH,R6),0(R5)     MOVE NEW DDNAME                  19850019
TCR124   CLR   R7,R3                   SECOND DDNAME?                   19900019
         BNE   TCR122                  BR IF NO                         19950019
         LA    R5,DDLNGTH(R5)          BYPASS NEXT TABLE ENTRY          20000019
         LA    R7,DDLNGTH(R7)          BYPASS NEXT TABLE ENTRY          20050019
         B     TCR122                  BR TO LOOP                       20100019
TCR126   OI    MISCIND,DDON            SET DDNAME SWAP IND ON           20150019
TCR129   L     RETREG,SAVE100          LOAD RETURN ADDRESS              20200019
         BR    RETREG                  RETURN                           20250019
  TITLE 'IEBTCRIN - DRIVER MODULE - MESSAGE MODULE LOADER'              20300019
*        MESSAGE MODULE LOADER                                          20350019
         SPACE 2                                                        20400019
TCR130   ST    RETREG,SAVE100          SAVE RETURN ADDRESS              20450019
         MVI   USERLIST,MSGMODL        INDICATE MSG MODULE              20500019
         LOAD  EP=IEBTCR02             LOAD MESSAGE MODULE              20550019
TCR137   ST    LNKREG0,MSGADDR         SAVE MSG MODULE ADDR             20600019
TCR139   L     RETREG,SAVE100          LOAD RETURN ADDRESS              20650019
         BR    RETREG                  RETURN                           20700019
  TITLE 'IEBTCRIN - DRIVER MODULE - SYSPRINT OPEN ROUTINE'              20750019
*        SYSPRINT OPEN AND STORAGE ALLOCATION                           20800019
         SPACE 1                                                        20850019
*        THIS ROUTINE OPENS THE SYSPRINT DATA SET, ALLOCATES            20900019
*        STORAGE FOR A WORKAREA, AND OUTPUTS A SYSPRINT PAGE HEADING.   20950019
         SPACE 2                                                        21000019
TCR140   ST    RETREG,SAVE100          SAVE RETURN ADDRESS              21050019
         TM    DUMMYIND,DUMSYSP        SYSPRINT DUMMY                   21100019
         BO    TCR149                  BR YES                           21150019
         LA    R2,SYSPRDCB             LOAD DCB ADDRESS                 21200019
         USING IHADCB,R2               INDICATE DCB DSECT REGISTER      21250019
         OPEN  (SYSPRDCB,(OUTPUT))     OPEN SYSPRINT                    21300019
         TM    ERRIND,CONFLERR         INCONSISTENT DCB PARAMETERS      21350019
         BO    TCR149                  BR YES                           21400019
         TM    DCBOFLGS,DCBOPEN        OPEN SUCCESSFUL                  21450019
         BO    TCR1403                 BR YES                           21500019
         MVI   MSG15,MSGREQ            SET MSG INDICATOR                21550019
         MVI   MSG15+1,PRT             SET SYSPRINT INSERT              21600019
         MVI   RETCODE,CODE16          SET RETURN CODE 16               21650019
TCR1403  LH    R1,DCBLRECL             LOAD LRECL                       21700019
         LA    R1,8(R1)                ADD 8 BYTES                      21750019
         ST    R1,PRTLNGTH             STORE NEW LENGTH                 21800019
         LR    R0,R1                   SET UP PARAMETER REGISTER        21850019
         BAL   RETREG,TCR420           GETMAIN STORAGE                  21900019
         TM    ERRIND,ALLOCERR         ALLOCATION ERROR                 21950019
         BNO   TCR141                  BR NO                            22000019
         OI    DUMMYIND,DUMSYSP        SET SYSPRINT DUMMY               22050019
         B     TCR149                  BR TO RETURN                     22100019
TCR141   MVC   PRTAREA(8),GETMADD      STORE ADDRESS AND LENGTH         22150019
         L     R1,PRTAREA              LOAD PRINT AREA ADDRESS          22200019
         B     TCR145                  BYPASS CLEAR INSTRUCTION         22250019
         SPACE 1                                                        22300019
TCR142   MVC   1(0,R1),0(R1)           CLEAR PRINT AREA                 22350019
         SPACE 1                                                        22400019
TCR145   LH    R2,DCBLRECL             FIND PRTAREA LENGTH              22450019
         LA    R2,6(R2)                INCREMENT 6 BYTES                22500019
         EX    R2,TCR142               CLEAR PRINT AREA                 22550019
         MVI   CARRCTRL,NEWPAGE        SET NEW PAGE CARRIAGE CONTROL    22600019
         L     R5,MSGADDR              LOAD MSG TABLE ADDRESS           22650019
         L     R6,HDGMSG(R5)           LOAD MSG ADDRESS                 22700019
         LA    R6,0(R6)                CLEAR LENGTH BYTE                22750019
         ST    R6,MSGAD                STORE MSG ADDRESS                22800019
         MVC   MSGLN(1),HDGMSG(R5)     STORE MSG LENGTH                 22850019
         OI    PRTRTN,RTN310           SET SINGLE MSG INDICATOR         22900019
         L     LNKREG15,ATCR220        LOAD MESSAGE WRITER ADDRESS      22950019
         BALR  RETREG,LNKREG15         DISPLAY MESSAGE                  23000019
         MVI   CARRCTRL,DOUBLESP       INDICATE DOUBLESPACING FOR       23050019
*                                      NEXT MESSAGE                     23100019
TCR149   L     RETREG,SAVE100          LOAD RETURN ADDRESS              23150019
         BR    RETREG                  RETURN                           23200019
  TITLE 'IEBTCRIN - DRIVER MODULE - CTRL CARD ANALYZER INTERFACE'       23250019
*        CONTROL CARD ANALYZER INTERFACE                                23300019
         SPACE 1                                                        23350019
*        THIS ROUTINE OPENS THE SYSIN DATA SET IF ONE HAS BEEN          23400019
*        PROVIDED, ALLOCATES CORE FOR A WORK AREA, CALLS THE MESSAGE    23450019
*        WRITER TO OUTPUT ANY ERROR MESSAGES DEVELOPED UP TO THIS       23500019
*        POINT, LINKS TO THE CONTROL CARD ANALYZER, AND CLOSES THE      23550019
*        SYSIN DATA SET.                                                23600019
*        IF NO SYSIN DD STATEMENT WAS PROVIDED, THE ROUTINE SETS        23650019
*        DEFAULT OPTIONS.                                               23700019
         SPACE 2                                                        23750019
TCR150   ST    RETREG,SAVE100          SAVE RETURN ADDRESS              23800019
         TM    DUMMYIND,DUMSYSIN       SYSIN DUMMY                      23850019
         BO    TCR156                  BR TO SET DEFAULTS               23900019
         OPEN  (SYSINDCB,(INPUT))      OPEN SYSIN                       23950019
         TM    ERRIND,CONFLERR         INCONSISTENT DCB PARAMETERS      24000019
         BO    TCR159                  BR YES                           24050019
         LA    R2,SYSINDCB             LOAD SYSIN DCB ADDRESS           24100019
         TM    DCBOFLGS,DCBOPEN        OPEN SUCCESSFUL                  24150019
         BO    TCR151                  BR YES                           24200019
         MVI   MSG15,MSGREQ            SET MSG INDICATOR                24250019
         MVI   MSG15+1,IN              SET SYSIN INSERT                 24300019
         MVI   RETCODE,CODE16          SET RETURN CODE 16               24350019
TCR151   LA    R1,CARDLN(0,0)          LOAD LENGTH 80                   24400019
         BAL   RETREG,TCR420           GET REQUESTED STORAGE            24450019
         TM    ERRIND,ALLOCERR         ALLOCATION ERROR                 24500019
         BO    TCR159                  BR YES                           24550019
         MVI   CARRCTRL,DOUBLESP       SET DOUBLE SPACE                 24600019
         L     LNKREG15,ATCR220        PRINT MESSAGES REQUESTED UP      24650019
         BALR  RETREG,LNKREG15           TO THIS POINT                  24700019
         L     R1,GETMADD              LOAD GETMAINED STORAGE ADDRESS   24750019
TCR152   ST    R1,CARDAREA             STORE WORK AREA ADDRESS          24800019
         LA    R1,8(R1)                SET AT COLUMN 9                  24850019
         ST    R1,COLUMN9              STORE COLUMN 9 ADDRESS           24900019
         LA    R1,INC63(R1)            SET AT COLUMN 72                 24950019
         ST    R1,CARDEND              STORE COLUMN 72 ADDRESS          25000019
         LINK  EP=IEBTCR04,PARAM=TCRCOM   LINK TO CONTROL CD ANALYZER   25050019
         DELETE  EP=IEBTCR04           DELETE CONTROL CD ANALYZER       25100019
         L     R1,CARDAREA             LOAD GETMAINED STORAGE ADDRESS   25150019
         FREEMAIN  R,LV=80,A=(1)       FREE STORAGE                     25200019
         TM    ERRIND,QSAMERR          PERMANENT I/O ERROR SYSIN        25250019
         BO    TCR159                  BR YES                           25300019
         CLOSE (SYSINDCB)              CLOSE SYSIN                      25350019
         B     TCR159                  BR TO RETURN                     25400019
         SPACE 1                                                        25450019
*        SET DEFAULTS                                                   25500019
         SPACE 1                                                        25550019
TCR156   MVC   OPTABLE+1(2),MTDIDEFT   SET PARM1 AND PARM2 OPTIONS      25600019
         MVI   MSG11,MSGREQ            SET MSG INDICATOR                25650019
         MVI   RETCODE,CODE04          SET RETURN CODE                  25700019
TCR159   L     RETREG,SAVE100          LOAD RETURN ADDRESS              25750019
         BR    RETREG                  RETURN                           25800019
  TITLE 'IEBTCRIN - DRIVER MODULE - USER ROUTINE LOADER'                25850019
*        USER ROUTINE LOADER                                            25900019
         SPACE 1                                                        25950019
*        THIS ROUTINE USES THE CONTROL CARD OPTION TABLE (IEXITS)       26000019
*        AND THE USER ROUTINE NAME TABLE (USERNAME) TO LOAD THE         26050019
*        SPECIFIED USER EXIT ROUTINES AND TRANSLATE TABLE.  IT          26100019
*        STORES THE ADDRESSES OF THE LOADED MODULES IN THE COMMON       26150019
*        COMMUNICATION REGION ADDRESS TABLE (USERADDR).                 26200019
*        IF IT FAILS TO FIND A ROUTINE, THE STAE EXIT ROUTINE           26250019
*        (TCR800) IS SCHEDULED DURING THE RESULTING ABEND PROCESSING.   26300019
*        IF THE STAE EXIT ROUTINE DETERMINES THAT THE ABEND WAS         26350019
*        CAUSED BY LOADING A NON-EXISTENT USER MODULE, IT REQUESTS      26400019
*        THAT THE STAE RETRY ROUTINE (TCR810) BE SCHEDULED.  THIS       26450019
*        ROUTINE RESTORES BASE REGISTERS, SETS ERROR AND MESSAGE        26500019
*        INDICATORS, AND RETURNS CONTROL TO THE LOADER AT TCR165.       26550019
         SPACE 2                                                        26600019
TCR160   ST    RETREG,SAVE100          SAVE RETURN ADDRESS              26650019
         LA    MSGCTR,HDR2IND-1        INITIALIZE MSG INDICATOR         26700019
         SR    INDREG,INDREG           ZERO REGISTER                    26750019
         LH    INDREG,INDMSK           LOAD INDICATOR MASK              26800019
         LA    NAMEREG,USERNAME-8      LOAD USER ROUTINE NAME TABLE AD  26850019
         LA    ADDREG,USERADDR-4       LOAD USER ROUT ADDR TABLE ADDR   26900019
TCR162   CLC   TCR164+1(1),LASTROUT    LAST POSS ROUTINE LOADED?        26950019
         BE    TCR168                  BR IF YES                        27000019
         SRL   INDREG,SHIFTLN          SHIFT MASK ONE BIT               27050019
         STC   INDREG,TCR164+1         STORE MASK IN TEST MSK INST      27100019
         LA    NAMEREG,8(NAMEREG)      INCR TO NEXT NAME ENTRY          27150019
         LA    ADDREG,4(ADDREG)        INCR TO NEXT ADDR ENTRY          27200019
         LA    MSGCTR,1(MSGCTR)        INCREMENT MSG INDICATOR          27250019
TCR164   TM    IEXITS,HEXZERO          MUST THIS ROUTINE BE LOADED      27300019
         BZ    TCR162                  BR IF NO                         27350019
         MVC   ENTPT(8),0(NAMEREG)     SET UP ROUTINE NAME              27400019
         STC   MSGCTR,USERLIST         STORE ROUTINE INDICATOR          27450019
         LOAD  EPLOC=ENTPT             LOAD NEXT MODULE                 27500019
         SPACE 1                                                        27550019
*        STAE PROCESSING RETURN POINT                                   27600019
         SPACE 1                                                        27650019
TCR165   TM    ERRIND,LOADERR          ERROR INDICATOR SET              27700019
         BO    TCR169                  BR YES                           27750019
         LTR   LNKREG0,LNKREG0         ADDRESS STORED                   27800019
         BZ    TCR169                  BR NO                            27850019
TCR167   ST    LNKREG0,0(ADDREG)       STORE USER ROUTINE ADDR          27900019
         B     TCR162                  BR TO LOOP                       27950019
         SPACE 1                                                        28000019
*        SET USER TRANSLATE TABLE ADDRESS TO ZERO IF TABLE NOT          28050019
*        PROVIDED BY USER                                               28100019
         SPACE 1                                                        28150019
TCR168   TM    IEXITS,USERTAB          USER TRANSLATE TABLE PRESENT     28200019
         BO    TCR169                  BR YES                           28250019
         MVC   USERADDR+24(4),ZEROES   SET ADDRESS TO ZERO              28300019
TCR169   L     RETREG,SAVE100          LOAD RETURN ADDRESS              28350019
         BR    RETREG                  RETURN                           28400019
  TITLE 'IEBTCRIN - DRIVER MODULE - DCB DEFAULT COMPLETION'             28450019
*        DCB DEFAULT COMPLETION                                         28500019
         SPACE 1                                                        28550019
*        THIS ROUTINE INCREMENTS THE BASIC DEFAULTS DEVELOPED BY        28600019
*        THE JFCB ANALYZER FOR THE SYSUT2 AND SYSUT3 DCB'S BY THE       28650019
*        MAXLN VALUE IF ONE OR MORE PARAMETERS WERE OMITTED BY THE      28700019
*        USER.                                                          28750019
*        IF EDITING WAS SPECIFIED BY THE USER, AN ADDITIONAL FOUR       28800019
*        BYTES ARE ADDED TO THE SYSUT3 DEFAULTS TO ACCOMODATE THE       28850019
*        ERROR DESCRIPTOR WORD.                                         28900019
         SPACE 1                                                        28950019
TCR170   ST    RETREG,SAVE100                                           29000019
         SPACE 1                                                        29050019
*        SET UP MAXLN                                                   29100019
         SPACE 1                                                        29150019
         CLC   MAXLN(2),ZEROES         MAXLN EQUALS ZERO?               29200019
         BNE   TCR172                  BR NO                            29250019
         MVI   MAXLN+1,DEF120          MOVE DEFAULT TO MAXLN            29300019
         SPACE 1                                                        29350019
TCR172   TM    MISCIND,UT2LRLMX        DOES SYSUT2 LRECL REQUIRE MAXLN  29400019
         BNO   TCR173                  BR NO                            29450019
         LH    R2,UT2LRECL             ADD MAXLN TO LRECL               29500019
         AH    R2,MAXLN                                                 29550019
         STH   R2,UT2LRECL             REPLACE LRECL                    29600019
         SPACE 1                                                        29650019
TCR173   TM    MISCIND,UT2BLKMX        SYSUT2 BLKSIZE REQUIRE MAXLN?    29700019
         BNO   TCR174                  BR NO                            29750019
         LH    R2,UT2BLK               ADD MAXLN TO BLKSIZE             29800019
         AH    R2,MAXLN                                                 29850019
         STH   R2,UT2BLK               REPLACE BLKSIZE                  29900019
         SPACE 1                                                        29950019
TCR174   TM    MISCIND,UT3LRLMX        SYSUT3 LRECL REQUIRE MAXLN?      30000019
         BNO   TCR176                  BR NO                            30050019
         LH    R2,UT3LRECL             ADD MAXLN TO LRECL               30100019
         AH    R2,MAXLN                                                 30150019
         TM    IPARM2,EDITSPEC         EDIT SPECIFIED                   30200019
         BZ    TCR175                  BR NO                            30250019
         LA    R2,4(R2)                ADD 4-BYTE ERROR DESCRIPTOR      30300019
TCR175   STH   R2,UT3LRECL             REPLACE LRECL                    30350019
         SPACE 1                                                        30400019
TCR176   TM    MISCIND,UT3BLKMX        DOES SYSUT3 BLKSIZE REQUIRE      30450019
         BNO   TCR179                    MAXLN -  BR NO                 30500019
         LH    R2,UT3BLK               LOAD BLKSIZE                     30550019
         AH    R2,MAXLN                ADD MAXLN TO BLKSIZE             30600019
         TM    IPARM2,EDITSPEC         EDIT SPECIFIED                   30650019
         BZ    TCR178                  BR NO                            30700019
         LA    R2,4(R2)                ADD 4-BYTE ERROR DESCRIPTOR      30750019
TCR178   STH   R2,UT3BLK               REPLACE BLKSIZE                  30800019
TCR179   L     RETREG,SAVE100          LOAD RETURN ADDRESS              30850019
         BR    RETREG                  RETURN TO MAINLINE               30900019
  TITLE 'IEBTCRIN - DRIVER MODULE - SYSUT1 OPEN ROUTINE'                30950019
*        SYSUT1 OPEN ROUTINE                                            31000019
         SPACE 1                                                        31050019
*        THIS ROUTINE OPENS THE SYSUT1 DATA SET, ESTABLISHES THE        31100019
*        BUFFER SIZE, AND ISSUES THE MOUNT MESSAGE.                     31150019
         SPACE 2                                                        31200019
TCR180   ST    RETREG,SAVE100          SAVE RETURN ADDRESS              31250019
         OPEN  (TCRDCB,(INPUT))        OPEN SYSUT1 DATA SET             31300019
         LA    R2,TCRDCB               LOAD DCB ADDRESS                 31350019
         XR    R10,R10                 ZERO WKREG                       31400019
         LH    R10,DCBBUFL             INSERT BUFFER LENGTH             31450019
         LTR   R10,R10                 LENGTH ZERO                      31500019
         BNZ   TCR182                  BR NOT ZERO                      31550019
         LA    R10,DEFBUFL             LOAD DEFAULT BUF LENGTH          31600019
TCR182   STH   R10,TCRBUFL             STORE BUFFER LENGTH              31650019
         L     R10,MSGADDR             LOAD  ADDR OF MSG MODULE         31700019
         L     R9,0(R10)               LOAD  PTR TO MOUNT MSG           31750019
         LA    R9,0(R9)                CLEAR LENGTH                     31800019
         MVC   14(3,R9),TCRDEV         MOVE DEVICE TYPE                 31850019
         MVC   18(6,R9),VOLSER         MOVE DATA SET EXTERNAL NAME      31900019
         MVI   25(R9),HEXSPACE         MOVE SPACE                       31950019
         MVC   26(16,R9),25(R9)        CLEAR MSG AREA                   32000019
         MVC   25(8,R9),JOBNAME        MOVE  JOB NAME                   32050019
         LA    R5,24(R9)               SET POINTER TO JOB START         32100019
         LA    R6,ONE                  LOAD INCREMENT                   32150019
         LA    R7,32(R9)               LOAD ENDING ADDRESS              32200019
TCR184   BXH   R5,R6,TCR186            BR ALL EIGHT CHARACTERS NON-BLK  32250019
         CLI   0(R5),HEXSPACE          SPACE                            32300019
         BNE   TCR184                  BR NO                            32350019
TCR186   MVI   0(R5),COMMA             INSERT COMMA                     32400019
         MVC   1(8,R5),STEPNAME        INSERT STEP NAME                 32450019
         WTO   MF=(E,(R9))             ISSUE MOUNT WTO                  32500019
         ST    R1,MOUNTID              STORE MOUNT MSG ID               32550019
TCR189   L     RETREG,SAVE100          LOAD RETURN ADDRESS              32600019
         BR    RETREG                  RETURN                           32650019
  TITLE 'IEBTCRIN - DRIVER MODULE - SYSUT1 SYNAD ROUTINE'               32700019
*        SYSUT1 SYNAD ROUTINE                                           32750019
         SPACE 1                                                        32800019
*        THIS ROUTINE ISSUES THE SYNADAF MACRO-INSTRUCTION FOR          32850019
*        THE SYSUT1 DATA SET AND OUTPUTS THE MESSAGE CONSTRUCTED        32900019
         SPACE 2                                                        32950019
TCR190   ST    RETREG,SAVE100          SAVE RETURN ADDRESS              33000019
         TM    DUMMYIND,DUMSYSP        SYSPRINT DUMMY                   33050019
         BO    TCR199                  BR YES                           33100019
         L     R2,IOBADDR              LOAD IOB ADDRESS                 33150019
TCR192   SYNADAF  ACSMETH=EXCP,PARM1=(R2)   ISSUE SYNADAF               33200019
         L     R3,PRTAREA              LOAD PRTAREA ADDRESS             33250019
         MVC   SYNIDENT(8,R1),SYNMSGUR MOVE MSG IDENT                   33300019
         LA    R4,SYNLNGTH             STORE MSG LENGTH                 33350019
         STC   R4,MSGLN                STORE LENGTH                     33400019
         LA    R5,SYNIDENT(R1)         STORE MSG ADDRESS                33450019
         ST    R5,MSGAD                STORE MSG LENGTH                 33500019
         OI    PRTRTN,RTN310           SET SINGLE MSG INDICATOR         33550019
         MVI   CARRCTRL,DOUBLESP       INDICATE DOUBLE-SPACING          33600019
         L     LNKREG15,ATCR220        LOAD MESSAGE WRITER ADDR         33650019
         BALR  RETREG,LNKREG15         DISPLAY MESSAGE                  33700019
         SYNADRLS                      RELEASE SYNAD MESSAGE AREA       33750019
TCR199   L     RETREG,SAVE100          LOAD RETURN ADDRESS              33800019
         BR    RETREG                  RETURN                           33850019
  TITLE 'IEBTCRIN - DRIVER MODULE - STORAGE ALLOCATION ROUTINE'         33900019
*        STORAGE ALLOCATION ROUTINE                                     33950019
         SPACE 1                                                        34000019
*        THIS ROUTINE GETMAINS STORAGE FOR ALL DRIVER ROUTINES.         34050019
*        PARAMETERS ARE AS FOLLOWS:                                     34100019
         SPACE 1                                                        34150019
*              REGISTER 1 - NUMBER OF BYTES REQUESTED                   34200019
*                 GETMADD - ADDRESS OF ALLOCATED STORAGE                34250019
*                  ERRIND - ALLOCATION ERROR  (BIT 1 SET TO 1 INDICATES 34300019
*                           ERROR)                                      34350019
         SPACE 1                                                        34400019
TCR420   ST    RETREG,SAVE400          SAVE RETURN REGISTER             34450019
         ST    R1,GETMREQ              STORE MINIMUM LENGTH             34500019
         ST    R1,GETMREQ+4            STORE MAXIMUM LENGTH             34550019
         GETMAIN   VC,LA=GETMREQ,A=GETMADD  GETMAIN STORAGE             34600019
         LTR   R15,R15                 TEST RETURN CODE                 34650019
         BZ    TCR429                  BR IF STORAGE ALLOCATED          34700019
         OI    ERRIND,ALLOCERR         SET ERROR INDICATOR              34750019
         MVI   MSG19,MSGREQ            SET MSG INDICATOR                34800019
         MVC   RETCODE,CODE16          SET RETURN CODE                  34850019
TCR429   L     RETREG,SAVE400          LOAD RETURN ADDRESS              34900019
         BR    RETREG                  RETURN                           34950019
  TITLE 'IEBTCRIN - DRIVER MODULE - DCB DEFAULT INSERTION'              35000019
*        DCB DEFAULT INSERTION                                          35050019
         SPACE 1                                                        35100019
*        THIS ROUTINE INSERTS DEFAULTS FOR ANY DCB PARAMETERS           35150019
*        WHICH WERE NOT SUPPLIED BY THE USER VIA EITHER THE DSCB        35200019
*        OR THE JFCB.                                                   35250019
*        THE ROUTINE CALLS TCR730 FOLLOWING INSERTION OF DEFAULTS       35300019
*        TO TEST FOR CONSISTENCY.                                       35350019
         SPACE 2                                                        35400019
         DROP  BASEREG                  DROP ORIGINAL BASE REG          35450019
         USING *,BASE15                 INDICATE NEW BASE REG           35500019
TCR720   L     BASEREG,DRIVBASE        LOAD BASE REGISTER               35550019
         DROP  BASE15                  DROP NEW BASE REGISTER           35600019
         USING TCR050,BASEREG          INDICATE ORIGINAL BASE REG       35650019
         L     COMMREG,ATCRCOM         LOAD BASE REGISTER               35700019
         ST    R14,SAVE700             SAVE RETURN ADDRESS              35750019
         DROP  R2                      DROP LAST DCB DSECT REG          35800019
         USING IHADCB,R1               INDICATE NEW DCB DSECT REG       35850019
         L     R2,DCBEXLST             LOAD EXIT LIST ADDR              35900019
         LA    R2,0(R2)                CLEAR HIGH-ORDER BYTE            35950019
         L     R3,8(R2)                LOAD DEFAULT TABLE ADDRESS       36000019
         TM    DCBRECFM,ALLONE         TEST RECFM ZERO                  36050019
         BNZ   TCR722                  BR NO                            36100019
         MVC   DCBRECFM,4(R3)          MOVE RECFM DEFAULT               36150019
TCR722   CLC   DCBLRECL(2),ZEROES      TEST LRECL ZERO                  36200019
         BNE   TCR724                  BR NO                            36250019
         MVC   DCBLRECL(2),0(R3)       MOVE LRECL DEFAULT               36300019
         TM    DCBRECFM,UNDEF          TEST UNDEFINED                   36350019
         BO    TCR724                  BR YES                           36400019
         BAL   RETREG,TCR728           SET DEFAULT MSG INDICATORS       36450019
TCR724   CLC   DCBBLKSI(2),ZEROES      TEST BLKSIZE ZERO                36500019
         BNE   TCR726                  BR NO                            36550019
         MVC   DCBBLKSI(2),2(R3)       MOVE BLKSIZE DEFAULT             36600019
         BAL   RETREG,TCR728           SET DEFAULT MSG INDICATORS       36650019
TCR726   BAL   RETREG,TCR730           COMPARE LRECL AND BLKSIZE        36700019
*                                      PARAMETERS                       36750019
         L     R14,SAVE700             LOAD RETURN ADDRESS              36800019
         RETURN  RC=0                  RETURN                           36850019
         SPACE 1                                                        36900019
*        SET DEFAULT MESSAGE INDICATORS IF SYSUT2 OR SYSUT3             36950019
         SPACE 1                                                        37000019
TCR728   CLC   5(1,R3),INIDENT         SYSIN                            37050019
         BE    TCR729                  BR YES                           37100019
         CLC   5(1,R3),PRTIDENT        SYSPRINT                         37150019
         BE    TCR729                  BR YES                           37200019
         MVI   MSG14,MSGREQ            SET REQUEST                      37250019
         MVI   RETCODE,CODE04          SET RETURN CODE 04               37300019
         CLC   5(1,R3),UT2IDENT        SYSUT2                           37350019
         BNE   TCR7283                 BR NO                            37400019
         OI    MSG14+1,UT2             SET SYSUT2 INSERT                37450019
         B     TCR729                  BR TO RETURN                     37500019
TCR7283  OI    MSG14+1,UT32            SET SYSUT3 INSERT                37550019
TCR729   BR    RETREG                  RETURN                           37600019
  TITLE 'IEBTCRIN - DRIVER MODULE - DCB PARAMETER COMPARISON'           37650019
*        DCB PARAMETER COMPARISON                                       37700019
         SPACE 1                                                        37750019
*        THIS ROUTINE TESTS THE DCB PARAMETERS FOR INCONSISTENCIES.     37800019
*        IF IT FINDS ANY INCONSISTENCY, IT SETS MSG AND ERROR           37850019
*        INDICATORS AND INSERTS DUMMY PARAMETERS IN THE FAULTY DCB      37900019
*        TO PREVENT THE OPEN ROUTINE FROM ABEND-ING.                    37950019
         SPACE 2                                                        38000019
TCR730   ST    RETREG,SAVE730          SAVE RETURN ADDRESS              38050019
         TM    DCBRECFM,VARFM          TEST VARIABLE                    38100019
         BO    TCR732                  BR IF NO                         38150019
         LH    R6,DCBLRECL             INCREMENT LRECL BY 4 BYTES       38200019
         LA    R6,4(R6)                                                 38250019
         STH   R6,DCBWORK              STORE IN WORK AREA               38300019
         CLC   DCBBLKSI(2),DCBWORK     COMPARE BLKSIZE WITH LRECL       38350019
         BNL   TCR739                  BR BLKSIZE HIGH OR EQUAL         38400019
         B     TCR734                  SET ERROR INDICATORS             38450019
TCR732   TM    DCBRECFM,UNDEF          TEST UNDEFINED                   38500019
         BO    TCR739                  BR IF YES                        38550019
         LH    R7,DCBBLKSI             LOAD DIVIDEND WITH BLKSIZE       38600019
         XR    R6,R6                                                    38650019
         LH    R8,DCBLRECL             LOAD DIVISOR WITH LRECL          38700019
         DR    R6,R8                   DIVIDE BLKSIZE BY LRECL          38750019
         LTR   R6,R6                   TEST REMAINDER                   38800019
         BZ    TCR739                  BR IF ZERO                       38850019
         SPACE 1                                                        38900019
*        ERROR PROCESSING                                               38950019
         SPACE 1                                                        39000019
TCR734   OI    ERRIND,CONFLERR         SET ERROR INDICATOR              39050019
         MVI   MSG16,MSGREQ            SET INCONSISTENT MSG POINTER     39100019
         MVC   MSG16+1(1),5(R3)        SET MSG INSERT                   39150019
         MVI   RETCODE,CODE16          SET RETURN CODE 16               39200019
TCR736   MVI   DCBRECFM,DUMRECFM       SET DUMMY RECORD FORMAT          39250019
         MVC   DCBBLKSI,DUMLRBLK       SET DUMMY BLKSIZE                39300019
         MVC   DCBLRECL,DUMLRBLK       SET DUMMY LRECL                  39350019
         CLC   5(1,R3),PRTIDENT        SYSPRINT DATASET                 39400019
         BNE   TCR739                  BR NO                            39450019
         OI    DUMMYIND,DUMSYSP        SET SYSPRINT DUMMY INDICATOR     39500019
TCR739   L     RETREG,SAVE730          LOAD RETURN ADDR                 39550019
         BR    RETREG                  RETURN                           39600019
  TITLE 'IEBTCRIN - DRIVER MODULE - QSAM SYNAD ROUTINE'                 39650019
*        QSAM SYNAD ROUTINE                                             39700019
         SPACE 1                                                        39750019
*        THIS ROUTINE ISSUES THE SYNADAF MACRO-INSTRUCTION FOR          39800019
*        THE SYSIN, SYSPRINT, SYSUT2, OR SYSUT3 DATA SET UPON           39850019
*        OCCURRENCE OF A PERMANENT I/O ERROR AND OUTPUTS THE            39900019
*        MESSAGE CONSTRUCTED.                                           39950019
         SPACE 2                                                        40000019
         DROP  BASEREG                 DROP ORIGINAL BASE REG           40050019
         USING *,BASE15                INDICATE NEW BASE REG            40100019
TCR740   L     BASEREG,DRIVBASE        LOAD BASE REGISTER               40150019
         DROP  BASE15                  DROP NEW BASE REG                40200019
         USING TCR050,BASEREG          INDICATE ORIGINAL BASE REG       40250019
         L     COMMREG,ATCRCOM         LOAD COMM REGION ADDRESS         40300019
         ST    RETREG,SAVE740          SAVE RETURN ADDRESS              40350019
         TM    DUMMYIND,DUMSYSP        SYSPRINT DUMMY                   40400019
         BO    TCR749                  BR YES                           40450019
         SYNADAF  ACSMETH=QSAM         REQUEST SYNAD MESSAGE            40500019
         CLC   75(8,R1),NAMETAB+8      SYSPRINT DATA SET                40550019
         BNE   TCR7416                 BR NO                            40600019
         ST    R1,SYNADSAV             SAVE SYNAD AREA ADDRESS          40650019
         OI    DUMMYIND,DUMSYSP        SET SYSPRINT DUMMY               40700019
         TM    PRTRTN,RTN310           SINGLE REQUEST                   40750019
         BO    TCR7413                 BR YES                           40800019
         L     R6,CURMSGAD             LOAD MSG WTO ADDRESS             40850019
         WTO   MF=(E,(R6))                                              40900019
TCR7413  L     R1,SYNADSAV             RESTORE SYNAD AREA POINTER       40950019
TCR7416  L     R3,PRTAREA              LOAD PRINTAREA ADDR              41000019
         CLC   DSUNIT(2,R1),SYNUR      TEST UR                          41050019
         BNE   TCR742                  BR NO                            41100019
         MVC   SYNIDENT(8,R1),SYNMSGUR                                  41150019
TCR742   CLC   DSUNIT(2,R1),SYNTA      TEST TA                          41200019
         BNE   TCR744                  BR NO                            41250019
         MVC   SYNIDENT(8,R1),SYNMSGTA MOVE IDENT                       41300019
TCR744   CLC   DSUNIT(2,R1),SYNDA      TEST DA                          41350019
         BNE   TCR746                  BR NO                            41400019
         MVC   SYNIDENT(8,R1),SYNMSGDA MOVE IDENT                       41450019
TCR746   LA    R4,SYNLNGTH             STORE MSG LENGTH                 41500019
         STC   R4,MSGLN                STORE MSG LENGTH                 41550019
         LA    R5,SYNIDENT(R1)         STORE MSG ADDRESS                41600019
         ST    R5,MSGAD                STORE MSG ADDRESS                41650019
TCR747   CLC   DSNAME(8,R1),NAMETAB+8  SYSPRINT DATA SET                41700019
         BNE   TCR7473                 BR NO                            41750019
         L     R4,MSGADDR              LOAD MSG TABLE ADDRESS           41800019
         L     R6,SYNWTO(R4)           LOAD MSG ADDRESS                 41850019
         LA    R6,0(R6)                CLEAR LENGTH INDICATOR           41900019
         EX    R4,TCR751               MOVE MESSAGE                     41950019
         WTO   MF=(E,(R6))             ISSUE WTO                        42000019
         B     TCR748                  BYPASS SYSPRINT PROC             42050019
TCR7473  OI    PRTRTN,RTN310           SET SINGLE MSG INDICATOR         42100019
         MVI   CARRCTRL,DOUBLESP       INDICATE DOUBLESPACING           42150019
         L     LNKREG15,ATCR220        LOAD MESSAGE WRITER ADDR         42200019
         BALR  RETREG,LNKREG15         DISPLAY MESSAGE                  42250019
TCR748   SYNADRLS                                                       42300019
TCR749   L     RETREG,SAVE740          LOAD RETURN ADDRESS              42350019
         OI    ERRIND,QSAMERR          SET QSAM ERROR INDICATOR         42400019
         MVI   RETCODE,CODE16          SET RETURN CODE 16               42450019
         RETURN  RC=16                                                  42500019
TCR751   MVC   4(0,R6),0(R5)           MOVE MSG                         42550019
  TITLE 'IEBTCRIN - DRIVER MODULE - STAE EXIT ROUTINE'                  42600019
*        STAE EXIT ROUTINE                                              42650019
         SPACE 1                                                        42700019
*        THIS ROUTINE IS SCHEDULED BY THE ABEND/STAE INTERFACE          42750019
*        ROUTINE WHENEVER AN ABEND IS SCHEDULED AND A VALID STAE        42800019
*        ENVIRONMENT IS IN EXISTENCE (WHEN A STAE CONTROL BLOCK         42850019
*        WAS SUCCESSFULLY CREATED).                                     42900019
         SPACE 1                                                        42950019
*        THE ROUTINE CHECKS WHETHER OR NOT THE ABEND WAS CAUSED         43000019
*        BY ATTEMPTING TO LOAD A NON-EXISTENT USER ROUTINE.  IF         43050019
*        IT WAS, IT REQUESTS THAT A STAE RETRY ROUTINE BE SCHEDULED.    43100019
*        IF IT WAS CAUSED BY SOME OTHER ERROR, THE ROUTINE ALLOWS       43150019
*        ABEND PROCESSING TO CONTINUE.                                  43200019
         SPACE 2                                                        43250019
         DROP  BASEREG                 DROP ORIGINAL BASE REG           43300019
         USING *,BASE15                INDICATE NEW BASE REG            43350019
TCR800   L     BASEREG,DRIVBASE        LOAD BASE REGISTER               43400019
         DROP  BASE15                  DROP NEW BASE REGISTER           43450019
         USING TCR050,BASEREG          INDICATE ORIGINAL BASE REG       43500019
         L     COMMREG,ATCRCOM         LOAD ADDR COMMUNICATION REGION   43550019
         LA    R3,CODE12               LOAD RETURN CODE 12              43600019
         CLR   LNKREG0,R3              WORK AREA AVAILABLE              43650019
         BE    TCR802                  BR NO                            43700019
         MVC   COMPCODE(2),5(PARMREG)  SAVE COMPLETION CODE             43750019
         B     TCR803                  BYPASS NO WORK AREA PROCESSING   43800019
TCR802   ST    PARMREG,COMPCODE        STORE COMPLETION CODE            43850019
         MVC   COMPCODE(2),COMPCODE+1  SHIFT CODE                       43900019
TCR803   NI    COMPCODE+1,USERCLR      CLEAR USER CODE                  43950019
         CLC   COMPCODE(2),CODE806     LOAD ERROR                       44000019
         BNE   TCR808                  BR NO                            44050019
TCR804   CLI   USERLIST,MSGMODL        MSG MODULE                       44100019
         BE    TCR808                  BR YES                           44150019
TCR806   LA    LNKREG15,CODE4          REQUEST STAE RETRY ROUTINE       44200019
         LA    LNKREG0,TCR810          LOAD RETRY ROUTINE ADDRESS       44250019
         BR    RETREG                  RETURN                           44300019
TCR808   XR    LNKREG15,LNKREG15       ALLOW ABEND TO CONTINUE          44350019
         BR    RETREG                  RETURN                           44400019
  TITLE 'IEBTCRIN - DRIVER MODULE - STAE RETRY ROUTINE'                 44450019
*        STAE RETRY ROUTINE                                             44500019
         SPACE 2                                                        44550019
*        THIS ROUTINE IS SCHEDULED WHENEVER THE STAE EXIT               44600019
*        ROUTINE DETERMINES THAT AN ABEND WAS CAUSED BY THE             44650019
*        FAILURE TO FIND A USER EXIT ROUTINE OR TRANSLATE TABLE.        44700019
         SPACE 1                                                        44750019
*        IT SETS MESSAGE AND ERROR INDICATORS, RESTORES BASE            44800019
*        REGISTERS, AND RETURNS CONTROL TO THE INSTRUCTION FOLLOW-      44850019
*        ING THE ABEND-ING LOAD INSTRUCTION.  IT FREES THE STAE         44900019
*        WORKAREA IF ONE WAS PROVIDED AND RESTORES I/O USING THE        44950019
*        THE RESTORE MACRO-INSTRUCTION.                                 45000019
         SPACE 2                                                        45050019
         DROP  BASEREG                 DROP ORIGINAL BASE REG           45100019
         USING *,BASE15                INDICATE NEW BASE REG            45150019
TCR810   L     BASEREG,DRIVBASE        LOAD  BASE REGISTER              45200019
         DROP  BASE15                  DROP NEW BASE REG                45250019
         USING TCR050,BASEREG          INDICATE ORIGINAL BASE REG       45300019
         ST    PARMREG,PARMADDR        STORE PARAMETER REG              45350019
         ST    LNKREG0,REG0SAVE        STORE REG 0                      45400019
         LA    SAVEREG,SAVEAREA        LOAD SAVEAREA ADDRESS            45450019
         L     COMMREG,ATCRCOM         LOAD ADDR COMMUNICATION REGION   45500019
         CLI   REG0SAVE+3,CODE12       WORK AREA AVAILABLE              45550019
         BE    TCR8103                 BR NO                            45600019
         L     R2,PARMADDR             LOAD WORKAREA ADDRESS            45650019
         L     PARMREG,IOBREST(R2)     LOAD RESTORE CHAIN POINTER       45700019
         B     TCR8106                 BYPASS NO WORK AREA PROC         45750019
TCR8103  ST    R2,SVRESTOR             SET UP IOB CHAIN POINTER         45800019
         LA    PARMREG,SVRESTOR        SET UP PARAMETER REGISTER        45850019
TCR8106  RESTORE   (PARMREG)           RESTORE I/O                      45900019
         CLI   REG0SAVE+3,CODE12       WORK AREA AVAILABLE              45950019
         BE    TCR811                  BR NO                            46000019
         L     PARMREG,PARMADDR        LOAD PARAMETER REGISTER          46050019
         FREEMAIN R,LV=104,A=(PARMREG)                                  46100019
TCR811   CLC   COMPCODE(2),CODE806     LOAD ERROR                       46150019
         BE    TCR812                  BR YES                           46200019
         B     TCR819                  BR TO RETURN                     46250019
TCR812   MVI   MSG17,MSGREQ            SET MSGIND                       46300019
         MVC   MSG17+1(1),USERLIST SET INSERT                           46350019
         OI    ERRIND,LOADERR          SET ERROR INDICATOR              46400019
         MVI   RETCODE,CODE16          SET RETURN CODE 16               46450019
         B     TCR819                  BR TO RETURN                     46500019
TCR819   L     RETREG,RETPT            LOAD RETURN POINT ADDRESS        46550019
         L     R12,DRIVBASE            LOAD DRIVER BASE REGISTER        46600019
         BR    RETREG                  RETURN                           46650019
  TITLE 'IEBTCRIN - DRIVER MODULE - LITERALS AND STORAGE AREAS'         46700019
*        LITERALS                                                       46750019
         SPACE 2                                                        46800019
NULL     EQU   *                       NULL LABEL FOR COMPILATION       46850019
*                                      OF DCB'S                         46900019
HEXSPACE EQU   X'40'                   HEX SPACE                        46950019
NAMELN   EQU   8                       INSERT NAME LENGTH               47000019
NEWPAGE  EQU   X'F1'                   SKIP TO CHANNEL 1                47050019
SINGLESP EQU   X'40'                   SINGLE SPACE CONTROL CHARACTER   47100019
DOUBLESP EQU   X'F0'                   DOUBLE SPACE CONTROL CHARACTER   47150019
MSGREQ   EQU   X'FF'                   MESSAGE REQUIRED                 47200019
INSREQ   EQU   X'FF'                   MESSAGE INSERT REQUIRED          47250019
VARFM    EQU   X'80'                   NOT VARIABLE IF ON               47300019
IN       EQU   X'01'                   SYSIN                            47350019
PRT      EQU   X'02'                   SYSPRINT                         47400019
INPRT    EQU   X'03'                   SYSPRINT OR SYSIN                47450019
EDITSPEC EQU   X'C0'                   EDIT SPECIFICATION               47500019
UT32     EQU   X'50'                   SYSUT3 INSERT                    47550019
UT2      EQU   X'04'                   SYSUT2                           47600019
UT3      EQU   X'05'                   SYSUT3                           47650019
ALLONE   EQU   X'FF'                   ANY ERROR INDICATOR              47700019
STAEFAIL EQU   X'FF'                   STAE ENVIRONMENT NOT CREATED     47750019
MSGMODL  EQU   X'0D'                   MESSAGE MODULE                   47800019
USERTAB  EQU   X'02'                   USER TABLE SPECIFIED             47850019
DEF120   EQU   X'78'                   MAXLN DEFAULT                    47900019
SHIFTLN  EQU   1                       SHIFT NO.OF BITS                 47950019
DDINCR   EQU   8                       DDNAME LENGTH                    48000019
TABLNG   EQU   76                      MESSAGE POINTER TABLE LENGTH     48050019
DDLNGTH  EQU   8                       DDNAME TABLE INCREMENT           48100019
DEFBUFL  EQU   2000                    DEFAULT BUFFER LENGTH            48150019
PTRLNG   EQU   4                       MESSAGE POINTER TABLE            48200019
*                                      ENTRY LENGTH                     48250019
DDON     EQU   X'01'                   ALTERNATE DDNAMES                48300019
RTN310   EQU   X'02'                   SINGLE MESSAGE INDICATOR         48350019
UNDEF    EQU   X'C0'                   UNDEFINED RECORD FORMAT          48400019
HDR2IND  EQU   6                       OUTHDR2 MSG INDICATOR            48450019
USERCLR  EQU   X'F0'                   USER COMPLETION CODE CLEAR       48500019
DUMRECFM EQU   X'90'                   DUMMY RECORD FORMAT              48550019
DCBOPEN  EQU   X'10'                   DCBOFLAGS OPEN INDICATOR         48600019
CODE4    EQU   4                       RETRY ROUTINE REQUEST            48650019
COMMA    EQU   C','                    COMMA                            48700019
SYNLNGTH EQU   68                      SYNAD MESSAGE LENGTH             48750019
COMPMSG  EQU   84                      COMPLETION MESSAGE               48800019
HDGMSG   EQU   80                      HEADING MESSAGE                  48850019
CARDLN   EQU   80                      CARD AREA LENGTH                 48900019
IOBREST  EQU   100                     IOB RESTORE POINTER              48950019
SYNIDENT EQU   60                      SYNAD MSG IDENT                  49000019
DSUNIT   EQU   72                      DEVICE TYPE                      49050019
DSNAME   EQU   75                      DATA SET NAME                    49100019
SYNWTO   EQU   76                      SYNAD MSG WTO LOCATION           49150019
INC63    EQU   63                      SIXTY-THREE                      49200019
HEXZERO  EQU   X'00'                   HEXADECIMAL 0                    49250019
HEX72    EQU   X'48'                   HEXADECIMAL 72                   49300019
ONE      EQU   1                       ONE                              49350019
THREE    EQU   3                       THREE                            49400019
         EJECT                                                          49450019
*        MESSAGE LOCATION DESCRIPTORS                                   49500019
         SPACE 1                                                        49550019
MSGSYSP  EQU   X'01'                   MESSAGE OUTPUT TO SYSPRINT       49600019
MSGCONS  EQU   X'02'                   MESSAGE OUTPUT TO CONSOLE        49650019
MSGAVAIL EQU   X'04'                   MESSAGE OUTPUT TO SYSPRINT       49700019
*                                      IF AVAILABLE OTHERWISE TO        49750019
*                                      THE CONSOLE                      49800019
         SPACE 1                                                        49850019
*        RETURN CODES                                                   49900019
         SPACE 1                                                        49950019
CODE04   EQU   4                       CODE  04                         50000019
CODE12   EQU   12                      CODE  12                         50050019
CODE16   EQU   16                      CODE  16                         50100019
         SPACE 2                                                        50150019
*        PARM LIST DEFINITION                                           50200019
         SPACE 1                                                        50250019
OPTLIST  EQU   0                       OPTION LIST                      50300019
DDLIST   EQU   4                       DDNAME LIST                      50350019
LASTPARM EQU   X'80'                   SIGN BIT ON                      50400019
         SPACE 2                                                        50450019
*        TERMINAL ERROR INDICATORS                                      50500019
         SPACE 1                                                        50550019
LOADERR  EQU   X'01'                   ERROR IN LOADING USER ROUTINES   50600019
QSAMERR  EQU   X'02'                   PERMANENT QSAM I/O ERROR         50650019
ANALERR  EQU   X'04'                   ERROR IN CONTROL CD ANALYZER     50700019
RDEDERR  EQU   X'08'                   ERROR IN READ AND EDIT MODULE    50750019
JFCBERR  EQU   X'10'                   ERROR IN READING JFCB OR MOUNT   50800019
IORDERR  EQU   X'28'                   SYSUT1 READ ERROR                50850019
ALLOCERR EQU   X'40'                   STORAGE ALLOCATION ERROR         50900019
CONFLERR EQU   X'80'                   CONFLICTING DCB PARAMETERS       50950019
         SPACE 2                                                        51000019
*        DCB MAXLN REQUIREMENTS                                         51050019
         SPACE 1                                                        51100019
UT2LRLMX EQU   X'10'                   SYSUT2 LRECL   REQUIRES MAXLN    51150019
UT2BLKMX EQU   X'08'                   SYSUT2 BLKSIZE REQUIRES MAXLN    51200019
UT3LRLMX EQU   X'04'                   SYSUT3 LRECL   REQUIRES MAXLN    51250019
UT3BLKMX EQU   X'02'                   SYSUT3 BKSIZE  REQUIRES MAXLN    51300019
         SPACE 2                                                        51350019
*        INPUT DDNAME LIST DEFINITION                                   51400019
         SPACE 1                                                        51450019
DSYSIN   EQU   32                      SYSIN                            51500019
DSYSPRT  EQU   40                      SYSPRINT                         51550019
DSYSUT1  EQU   56                      SYSUT1                           51600019
DSYSUT2  EQU   64                      SYSUT2                           51650019
DSYSUT3  EQU   72                      SYSUT3                           51700019
         SPACE 2                                                        51750019
*        MISSING DD STATEMENT INDICATORS                                51800019
         SPACE 1                                                        51850019
DUMSYSIN EQU   X'01'                   SYSIN                            51900019
DUMSYSP  EQU   X'02'                   SYSPRINT                         51950019
         EJECT                                                          52000019
*        CONSTANTS, HOLD AREAS                                          52050019
         SPACE 1                                                        52100019
GETMREQ  DS    D                       MINIMUM & MAXIMUM SIZE REQUIRED  52150019
GETMADD  DS    D                       GETMAINED STORAGE ADDRESS        52200019
*                                        AND LENGTH                     52250019
PARMADDR DC    F'0'                    PARAMETER REGISTER STORE         52300019
RETPT    DC    A(TCR165)               STAE RETRY RETURN POINT          52350019
ENTPT    DC    D'0'                    EXIT ROUTINE NAME                52400019
ATCRCOM  DC    A(TCRCOM)               COMMON COMMUNICATION REGION      52450019
*                                      ADDRESS                          52500019
COMPCODE DC    C'    '                 ABEND COMPLETION CODE            52550019
CODE806  DC    X'8060'                 LOAD ERROR COMPLETION CODE       52600019
INDMSK   DC    X'0100'                 USER INDICATOR TABLE MASK        52650019
USERLIST DC    X'0000'                 STAE NAME TABLE POINTER          52700019
*                                      X'NNFF' INDICATES STAE NOT       52750019
*                                      IN EFFECT                        52800019
DCBWORK  DC    X'0000'                 LRECL WORK AREA                  52850019
LASTROUT DC    X'02'                   ALL USER ROUTINES LOADED         52900019
ZEROES   DC    X'0000000000000000'     ZEROES                           52950019
         SPACE 1                                                        53000019
SYNUR    DC    CL2'UR'                 UNIT RECORD SYNADAF              53050019
SYNTA    DC    CL2'TA'                 TAPE  SYNADAF                    53100019
SYNDA    DC    CL2'DA'                 DIRECT ACCESS SYNADAF            53150019
         SPACE 2                                                        53200019
*        THE FOLLOWING CONSTANTS MAY NEED TO BE REPLACED IF WORLD TRADE 53250019
*        REQUIREMENTS NECESSITATE MODIFICATION OF THE MESSAGE IDEN-     53300019
*        TIFIERS.                                                       53350019
         SPACE 1                                                        53400019
SYNMSGUR DC    CL8'IEB920I '           UNIT RECORD SYNAD MSG IDENT      53450019
SYNMSGTA DC    CL8'IEB921I '           TAPE SYNAD MSG IDENT             53500019
SYNMSGDA DC    CL8'IEB922I '           DIRECT ACCESS SYNAD MSG IDENT    53550019
         SPACE 1                                                        53600019
         DS    0H                      FORCE HALF-WORD ALIGNMENT        53650019
MTDIDEFT DC    X'408C'                 MTDI DEFAULT                     53700019
DUMLRBLK DC    X'0050'                 DUMMY LRECL AND BLKSIZE VALUES   53750019
         SPACE 2                                                        53800019
*        SAVE AREAS                                                     53850019
         SPACE 1                                                        53900019
SAVE100  DS    F                       TCR1XX RETURN ADDRESS            53950019
SAVE400  DS    F                       TCR4XX RETURN ADDRESS            54000019
SAVE700  DS    F                       TCR700 RETURN ADDRESS            54050019
SAVE730  DS    F                       TCR730 RETURN ADDRESS            54100019
SAVE740  DS    F                       TCR740 RETURN ADDRESS            54150019
SYNADSAV DS    F                       SYNAD AREA SAVE ADDRESS          54200019
DRIVBASE DS    F                       DRIVER BASE REGISTER             54250019
REG0SAVE DS    F                       LNKREG0 SAVE AREA                54300019
SVRESTOR DS    F                       IOB RESTORE CHAIN                54350019
SAVEAREA DS    18F                     REGISTER SAVE AREA               54400019
SAVEPARM DC    F'0'                    PARAMETER REGISTER SAVE AREA     54450019
  TITLE 'IEBTCRIN - DRIVER MODULE -- TCR220 - MESSAGE WRITER'           54500019
*        TCR220 - MESSAGE WRITER                                        54550019
         SPACE 3                                                        54600019
*        THE MESSAGE WRITER OUTPUTS ALL MESSAGES FOR THE UTILITY.       54650019
*        IT CONTAINS TWO PROCESSING OPTIONS - 1) CONSECUTIVE            54700019
*        OUTPUTTING OF ALL IEB9XXX MESSAGES AND 2) SINGLE LINE          54750019
*        SYSPRINT OUTPUTTING OF CONTROL STATEMENT IMAGES, PAGE          54800019
*        HEADINGS, SYNAD MESSAGES, ETC.                                 54850019
         SPACE 1                                                        54900019
*        PARAMETERS ARE AS FOLLOWS:                                     54950019
*                                                                       55000019
*        OPTION 1:  COMMON COMMUNICATION REGION TABLE MSGPTRS           55050019
*                                                                       55100019
*                   THIS TABLE CONTAINS ONE FULL-WORD ENTRY FOR         55150019
*                   EACH IEB-TYPE MESSAGE (EXCLUDING SYNAD MESSAGES).   55200019
*                                                                       55250019
*                   BYTE 1 - MESSAGE REQUEST CODE                       55300019
*                                                                       55350019
*                            X'FF' - INDICATES REQUEST                  55400019
*                            X'00' - OTHERWISE                          55450019
*                                                                       55500019
*                   BYTE 2 - INSERT CODE                                55550019
*                                                                       55600019
*                            X'00' - NO INSERT                          55650019
*                            X'01' - SYSIN                              55700019
*                            X'02' - SYSPRINT                           55750019
*                            X'03' - SYSUT1                             55800019
*                            X'04' - SYSUT2                             55850019
*                            X'05' - SYSUT3                             55900019
*                            X'06' - OUTHDR2                            55950019
*                            X'07' - OUTTLR2                            56000019
*                            X'08' - OUTHDR3                            56050019
*                            X'09' - OUTTLR3                            56100019
*                            X'0A' - OUTREC                             56150019
*                            X'0B' - ERROR                              56200019
*                            X'0C' - USERTAB                            56250019
*                            X'54' - BOTH SYSUT2 AND SYSUT3             56300019
*                                                                       56350019
*                      NOTE:  IF X'54' IS SPECIFIED, THE MESSAGE IS     56400019
*                            OUTPUT TWICE, ONCE WITH SYSUT2 AND ONCE    56450019
*                            WITH SYSUT3.                               56500019
*                                                                       56550019
*        OPTION 2:  COMMUNICATION REGION DATA AREAS:                    56600019
*                                                                       56650019
*                       MSGAD - MESSAGE ADDRESS                         56700019
*                       MSGLN - MESSAGE LENGTH                          56750019
*                                                                       56800019
*                   COMMUNICATION REGION INDICATOR:                     56850019
*                                                                       56900019
*                       PRTRTN - BIT 6 SET TO ONE INDICATES OPTION 2    56950019
*                                BIT 6 SET TO ZERO INDICATES OPTION 1   57000019
         SPACE 1                                                        57050019
*        CALLING SEQUENCE:                                              57100019
*                                                                       57150019
*                   L     R15,ATCR220       LOAD CSECT ADDRESS          57200019
*                   BALR  R14,R15           BRANCH AND LINK             57250019
         SPACE 2                                                        57300019
         SPACE 3                                                        57350019
*        THIS SECTION SAVES THE CALLING MODULE'S GENERAL REGISTERS,     57400019
*        SETS UP A SAVEAREA ADDRESS, AND ESTABLISHES BASE REGISTERS     57450019
*        FOR THIS MODULE AND FOR THE COMMON COMMUNICATION REGION.       57500019
         SPACE 2                                                        57550019
IEBTCRMW CSECT                                                          57600019
         ENTRY TCR220                  MESSAGE WRITER ENTRY POINT       57650019
TCR220   SAVE  (14,12),T,TCR220        SAVE REGISTERS                   57700019
         BALR  BASEREG,R0              ESTABLISH BASE REGISTER          57750019
         USING *,BASEREG               INDICATE BASE REGISTER           57800019
         LR    R15,SAVEREG             SET UP SAVEAREA POINTERS         57850019
         ST    R15,SAVEAR2+4                                            57900019
         LA    SAVEREG,SAVEAR2                                          57950019
         ST    SAVEREG,8(R15)                                           58000019
         XR    R15,R15                                                  58050019
         ST    R15,0(SAVEREG)                                           58100019
         L     COMMREG,ATCRCOM1        LOAD COMMUNICATION REGION ADDR   58150019
         USING TCRCOM,COMMREG          INDICATE COMM. REG. BASE REG.    58200019
         EJECT                                                          58250019
*        THIS SECTION LOOPS THROUGH THE MESSAGE POINTER TABLE.          58300019
*        FOR EACH MESSAGE REQUESTED, IT FINDS THE RELATED MESSAGE       58350019
*        TEXT IN THE MESSAGE MODULE, INSERTS ANY NAME REQUESTED,        58400019
*        AND DEVELOPS A MESSAGE LENGTH AND MESSAGE ADDRESS.             58450019
         SPACE 2                                                        58500019
         TM    PRTRTN,RTN310           SINGLE MESSAGE REQUEST           58550019
         BO    TCR330                  BR YES                           58600019
         SR    R3,R3                   CLEAR INSERT LOCATION REG        58650019
         LA    R7,MSGPTRS-PTRLNG       LOAD ADDR MSG PTR TABLE-4        58700019
         L     R4,MSGADDR              LOAD ADDR MSG TABLE              58750019
         S     R4,FOUR                 SET AT MSG TABLE-4               58800019
         LA    R8,PTRLNG               LOAD INCREMENT                   58850019
         LA    R9,MSGPTRS+TABLNG       LOAD ENDING ADDRESS              58900019
TCR222   BXH   R7,R8,TCR228            BR WHEN ALL MSGS OUTPUT          58950019
         LA    R4,4(R4)                INCR VARIABLE TABLE ADDR         59000019
         TM    0(R7),MSGREQ            MESSAGE REQUIRED?                59050019
         MVI   0(R7),HEXZERO           CLEAR INDICATOR                  59100019
         BNO   TCR222                  BR NO                            59150019
         TM    1(R7),INSREQ            MSG INSERT REQUIRED              59200019
         BZ    TCR223                  BR NO                            59250019
         TM    1(R7),TWOINS            TWO INSERTS REQUIRED             59300019
         BNO   TCR2225                 BR NO                            59350019
         MVC   SAVEINS(1),1(R7)        SAVE INSERT                      59400019
TCR2223  NI    1(R7),CLEARLFT          CLEAR LEFT FOUR BITS             59450019
TCR2225  L     R6,0(R4)                LOAD MSG ADDRESS                 59500019
         IC    R3,2(R7)                INSERT MSG INSERT LOCATION       59550019
         AR    R6,R3                   ADD TO STARTING MSG ADDR         59600019
         IC    R3,1(R7)                LOAD INSERT NAME INDICATOR       59650019
         SH    R3,HFONE                DECREMENT BY ONE                 59700019
         SLL   R3,THREE                MULTIPLY BY EIGHT                59750019
         LA    R2,NAMETAB              LOAD ADDR OF NAME TABLE          59800019
         AR    R2,R3                   SET REG AT NAME TO BE INSERTED   59850019
         MVC   4(NAMELN,R6),0(R2)      MOVE NAME TO MSG                 59900019
TCR223   L     R6,0(R4)                LOAD MSG ADDRESS                 59950019
         LA    R6,0(R6)                REMOVE LENGTH INDICATION         60000019
         ST    R6,CURMSGAD             STORE WTO ADDRESS                60050019
         LH    R2,0(R6)                LOAD LENGTH                      60100019
         S     R2,FOUR                 REMOVE LENGTH OF CODES           60150019
         EJECT                                                          60200019
*        THIS SECTION DETERMINES THE OUTPUT LOCATION(S) FOR THE         60250019
*        MESSAGE AND BAL'S TO THE PROPER ROUTINE(S).                    60300019
         SPACE 2                                                        60350019
         TM    3(R7),MSGSYSP           SYSPRINT REQUIRED?               60400019
         BNO   TCR224                  BR IF NO                         60450019
         TM    DUMMYIND,DUMSYSP        SYSPRINT DUMMY?                  60500019
         BO    TCR224                  BR YES                           60550019
         LA    R6,4(R6)                BYPASS CODES                     60600019
         BAL   RETREG,TCR310           DISPLAY ON SYSPRINT              60650019
         S     R6,FOUR                 SET AT WTO START                 60700019
TCR224   TM    3(R7),MSGCONS           CONSOLE REQUIRED?                60750019
         BNO   TCR225                  BR - NO                          60800019
         BAL   RETREG,TCR320           DISPLAY ON CONSOLE               60850019
         SPACE 1                                                        60900019
*        DISPLAY ON CONSOLE IF BIT 5 OF THE LOCATION CODE IS SET TO     60950019
*        ONE AND SYSPRINT IS DUMMY.  DISPLAY ON SYSPRINT IF NOT DUMMY.  61000019
         SPACE 1                                                        61050019
TCR225   TM    3(R7),MSGAVAIL          CONSOLE IF SYSPRINT DUMMY?       61100019
         BNO   TCR227                  BR IF NO                         61150019
TCR2253  TM    DUMMYIND,DUMSYSP        SYSPRINT DUMMY                   61200019
         BO    TCR226                  BR YES                           61250019
         LA    R6,4(R6)                BYPASS CODES                     61300019
         BAL   RETREG,TCR310           DISPLAY ON SYSPRINT              61350019
         S     R6,FOUR                 SET AT WTO START                 61400019
         B     TCR227                  BYPASS CONSOLE ROUTINE           61450019
TCR226   BAL   RETREG,TCR320           DISPLAY ON CONSOLE               61500019
TCR227   CLI   SAVEINS,HEXZERO         TWO INSERTS                      61550019
         BE    TCR222                  BR NO                            61600019
         PACK  SAVEINS(1),SAVEINS      SWITCH INSERT DIGITS             61650019
         MVC   1(1,R7),SAVEINS         SET  IN MSG POINTER              61700019
         MVI   SAVEINS,HEXZERO         CLEAR SAVE AREA                  61750019
         B     TCR2223                 BR TO CONSTRUCT 2ND MSG          61800019
         SPACE 3                                                        61850019
*        THIS SECTION RELOADS THE CALLING MODULE'S REGISTERS            61900019
*        AND RETURNS TO THE CALLER                                      61950019
         SPACE 1                                                        62000019
TCR228   NI    PRTRTN,HEXZERO          CLEAR OPTION INDICATOR           62050019
         L     SAVEREG,4(SAVEREG)      RELOAD SAVEAREA ADDRESS          62100019
         RETURN  (14,12),T,RC=(15)     RELOAD REGISTERS AND RETURN      62150019
         EJECT                                                          62200019
*        SYSPRINT ROUTINE                                               62250019
         SPACE 1                                                        62300019
*        THIS ROUTINE DEVELOPS RECORDS FOR THE SYSPRINT DATA SET.       62350019
*        IF THE MESSAGE IS LONGER THAN THE SPACE AVAILABLE WITH THE     62400019
*        SPECIFIED DCB PARAMETERS, IT IS TRUNCATED TO FIT IN THE        62450019
*        SPACE AVAILABLE.                                               62500019
         SPACE 1                                                        62550019
*        PARAMETERS ARE AS FOLLOWS:                                     62600019
*                                                                       62650019
*                REGISTER 2 - MESSAGE LENGTH                            62700019
*                REGISTER 6 - MESSAGE ADDRESS                           62750019
         SPACE 2                                                        62800019
TCR310   ST    RETREG,SAVE300          SAVE RETURN ADDRESS              62850019
         LA    R1,SYSPRDCB             LOAD SYSPRINT DCB ADDRESS        62900019
         USING IHADCB,R1               INDICATE DCB DSECT REG           62950019
         L     R10,PRTAREA             LOAD ADDR PRTAREA                63000019
         LH    R5,DCBLRECL             LOAD SYSPRINT LRECL              63050019
         TM    DCBRECFM,VARFM          TEST VARIABLE LENGTH RECORDS     63100019
         BO    TCR312                  BR NO                            63150019
         SPACE 1                                                        63200019
*        DEVELOP LENGTH FOR VARIABLE-LENGTH RECORDS                     63250019
         SPACE 1                                                        63300019
         SH    R5,HFIVE                REMOVE COUNT AND CTRL CHAR LNGTH 63350019
         CLR   R5,R2                   COMPARE MAX AVAILABLE TO MSG LNG 63400019
         BH    TCR311                  BR HIGH                          63450019
         SPACE 1                                                        63500019
*        DEVELOP LENGTH FOR THOSE VARIABLE-LENGTH MESSAGES WHICH        63550019
*        ARE LONGER THAN THE SPECIFIED LRECL VALUE                      63600019
         SPACE 1                                                        63650019
         LR    R3,R5                   SET MSG LENGTH EQUAL TO LRECL-5  63700019
         LA    R5,5(R5)                ADD BACK                         63750019
         STH   R5,0(R10)               STORE COUNT IN SYSPRINT AREA     63800019
         SH    R5,HFIVE                REMOVE COUNT AND CTRL CHAR LNGTH 63850019
         B     TCR315                  BR TO OUTPUT THE MSG             63900019
         SPACE 1                                                        63950019
*        THIS SECTION DEVELOPS A LENGTH FOR THOSE VARIABLE-LENGTH       64000019
*        MESSAGES WHICH ARE SHORTER THAN OR EQUAL TO THE ALLOWABLE      64050019
*        LENGTH.                                                        64100019
         SPACE 1                                                        64150019
TCR311   LR    R3,R2                   LOAD MSG LENGTH                  64200019
         LA    R2,5(R2)                ADD 5 BYTES TO MSG LENGTH        64250019
         STH   R2,0(R10)               STORE COUNT IN SYSPRINT AREA     64300019
         B     TCR315                  BR TO OUTPUT THE MSG             64350019
         SPACE 1                                                        64400019
*        DEVELOP ALLOWABLE MESSAGE LENGTH FOR FIXED-LENGTH AND          64450019
*        UNDEFINED RECORDS.                                             64500019
         SPACE 1                                                        64550019
TCR312   SH    R5,HFONE                REMOVE CTRL CHAR COUNT           64600019
         CLR   R5,R2                   COMPARE MAX AVAILABLE TO MSG LNG 64650019
         BH    TCR313                  BR HIGH                          64700019
         LR    R3,R5                   SET MSG LENGTH EQUAL TO LRECL-1  64750019
         B     TCR315                  BR TO OUTPUT THE MSG             64800019
         EJECT                                                          64850019
*        THIS SECTION CLEARS THE PRINT AREA, MOVES THE MESSAGE TO       64900019
*        THE PRINT AREA, ENTERS A CARRIAGE CONTROL CHARACTER, AND,      64950019
*        IF THE DATA SET HAS BEEN SPECIFIED AS VARIABLE-LENGTH,         65000019
*        AFFIXES THE VARIABLE-LENGTH RECORD COUNT.                      65050019
         SPACE 1                                                        65100019
TCR313   LR    R3,R2                   LOAD MSG LENGTH                  65150019
TCR315   MVI   4(R10),HEXSPACE         MOVE SPACE TO PRINT AREA         65200019
         SH    R5,HFONE                DEVELOP CLEAR LENGTH             65250019
         SH    R3,HFONE                DEVELOP MOVE LENGTH              65300019
         EX    R5,TCR3183              CLEAR PRINT AREA                 65350019
         EX    R3,TCR318               LOAD MSG                         65400019
         MVC   4(1,R10),CARRCTRL       MOVE TO PRINT AREA               65450019
         TM    SYSPRDCB+36,VARFM       TEST VARIABLE LENGTH RECORDS     65500019
         BNO   TCR316                  BR YES                           65550019
         LA    R10,4(R10)              BYPASS VARIABLE COUNT            65600019
         SPACE 1                                                        65650019
*        THIS SECTION OUTPUTS THE MESSAGE AND RESTORES THE CARRIAGE     65700019
*        CONTROL TO SINGLE-SPACING.                                     65750019
         SPACE 1                                                        65800019
TCR316   PUT   SYSPRDCB,(R10)          WRITE MSG                        65850019
         MVI   CARRCTRL,SINGLESP       RESET CARRIAGE CONTROL TO        65900019
*                                        SINGLE SPACE                   65950019
         L     RETREG,SAVE300          LOAD RETURN ADDRESS              66000019
         BR    RETREG                  RETURN                           66050019
         SPACE 1                                                        66100019
TCR318   MVC   5(0,R10),0(R6)          MOVE MSG                         66150019
         SPACE 1                                                        66200019
TCR3183  MVC   5(0,R10),4(R10)         CLEAR PRINT AREA                 66250019
         EJECT                                                          66300019
*        CONSOLE DISPLAY ROUTINE                                        66350019
         SPACE 2                                                        66400019
TCR320   ST    RETREG,SAVE300          SAVE RETURN ADDRESS              66450019
         WTO   MF=(E,(R6))             ISSUE WTO                        66500019
TCR329   L     RETREG,SAVE300          LOAD RETURN ADDRESS              66550019
         BR    RETREG                  RETURN                           66600019
         SPACE 5                                                        66650019
*        SINGLE MESSAGE REQUEST INTERFACE                               66700019
         SPACE 2                                                        66750019
TCR330   TM    DUMMYIND,DUMSYSP        SYSPRINT DUMMY                   66800019
         BO    TCR228                  BR YES                           66850019
         XR    R2,R2                   CLEAR WORK REGISTER              66900019
         IC    R2,MSGLN                INSERT MSG LENGTH                66950019
         L     R6,MSGAD                LOAD MSG ADDRESS                 67000019
         BAL   RETREG,TCR310           DISPLAY ON SYSPRINT              67050019
         B     TCR228                  BR TO RETURN                     67100019
         EJECT                                                          67150019
*        LITERALS                                                       67200019
         SPACE 2                                                        67250019
TWOINS   EQU   X'40'                   TWO MSG INSERTS REQUIRED         67300019
CLEARLFT EQU   X'0F'                   INSERT CLEAR                     67350019
         SPACE 2                                                        67400019
*        DATA CONSTANTS AND STORAGE AREAS                               67450019
         SPACE 1                                                        67500019
SAVEAR2  DS    18F                     REGISTER SAVE AREA               67550019
ATCRCOM1 DC    A(TCRCOM)               COMMUNICATION REGION ADDRESS     67600019
SAVE300  DC    F'0'                    TCR3XX SAVE AREA                 67650019
FOUR     DC    F'04'                   BINARY FULL-WORD FOUR            67700019
HFONE    DC    X'0001'                 BINARY HALF-WORD ONE             67750019
HFIVE    DC    X'0005'                 BINARY HALF-WORD FIVE            67800019
SAVEINS  DC    X'00'                   MSG INSERT SAVE AREA             67850019
  TITLE 'IEBTCRIN - DRIVER MODULE -- TCRCOM - COMM. COMMUNICATION REG.' 67900019
*        COMMON COMMUNICATION REGION                                    67950019
         SPACE 1                                                        68000019
*        THIS CSECT CONTAINS TABLES, INDICATORS, CONSTANTS, WORK        68050019
*        AREAS, AND DCB'S THAT ARE USED BY TWO OR MORE MODULES.         68100019
         SPACE 2                                                        68150019
TCRCOM   CSECT                                                          68200019
         SPACE 1                                                        68250019
         DS    0F                      FORCE FULL-WORD ALIGNMENT        68300019
OPTABLE  DS    0CL8                    CONTROL CARD OPTION TABLE        68350019
         SPACE 1                                                        68400019
IEXITS   DC    X'00'                   USER ROUTINE INDICATORS          68450019
         SPACE 1                                                        68500019
*              BIT 0 - OUTHDR2                                          68550019
*                  1 - OUTTLR2                                          68600019
*                  2 - OUTHDR3                                          68650019
*                  3 - OUTTLR3                                          68700019
*                  4 - OUTREC                                           68750019
*                  5 - ERROR                                            68800019
*                  6 - USERTAB                                          68850019
*                  7 - NOT USED                                         68900019
         SPACE 1                                                        68950019
IPARM1   DC    X'00'                   TYPE AND TRANS INDICATORS        69000019
         SPACE 1                                                        69050019
*              BIT 0 - TYPE = MTST                                      69100019
*                  1 - TYPE = MTDI                                      69150019
*                  2 - UNUSED                                           69200019
*                  3 - TRANS = STDUC                                    69250019
*                  4 - TRANS = STDLC                                    69300019
*                  5 - TRANS = USERNAME                                 69350019
*                  6 - TRANS = NOTRAN                                   69400019
*                  7 - NOT USED                                         69450019
         SPACE 1                                                        69500019
IPARM2   DC    X'00'                   EDIT, VERCHK, AND ERROPT         69550019
*                                        INDICATORS                     69600019
         SPACE 1                                                        69650019
*              BIT 0 - EDIT = EDITD                                     69700019
*                  1 - EDIT = EDITR                                     69750019
*                  2 - EDIT = NOEDIT                                    69800019
*                  3 - VERCHK = VOKCHK                                  69850019
*                  4 - VERCHK = NOCHK                                   69900019
*                  5 - ERROPT = NORMAL                                  69950019
*                  6 - ERROPT = NOERR                                   70000019
*                  7 - UNUSED                                           70050019
         SPACE 1                                                        70100019
REPL     DC    X'19'                   REPLACE PARAMETER VALUE          70150019
MINLN    DC    X'0000'                 MINLN PARAMETER VALUE            70200019
MAXLN    DC    X'0000'                 MAXLN PARAMETER VALUE            70250019
         EJECT                                                          70300019
ADDRTAB  DS    0CL28                   USER ROUTINE ADDRESS TABLE       70350019
USERADDR DC    A(0,0,0,0,0,0,0)        TABLE                            70400019
         SPACE 1                                                        70450019
*              WORD 0 - OUTHDR2                                         70500019
*                   1 - OUTTLR2                                         70550019
*                   2 - OUTHDR3                                         70600019
*                   3 - OUTTLR3                                         70650019
*                   4 - OUTREC                                          70700019
*                   5 - ERROR                                           70750019
*                   6 - TRANSLATE TABLE                                 70800019
         SPACE 2                                                        70850019
MSGADDR  DC    A(0)                    MESSAGE MODULE ADDRESS           70900019
         SPACE 2                                                        70950019
*        NAME TABLE                                                     71000019
         SPACE 1                                                        71050019
*        THIS TABLE CONTAINS DDNAMES AND USER EXIT NAMES                71100019
         SPACE 1                                                        71150019
NAMETAB  DC    CL8'SYSIN',CL8'SYSPRINT',CL8'SYSUT1',CL8'SYSUT2'         71200019
         DC    CL8'SYSUT3',CL8'OUTHDR2',CL8'OUTTLR2'                    71250019
         DC    CL8'OUTHDR3',CL8'OUTTLR3',CL8'OUTREC',CL8'ERROR'         71300019
         DC    CL8'TRANS'                                               71350019
         SPACE 1                                                        71400019
*              WORDS 0-1   SYSIN                                        71450019
*                    2-3   SYSPRINT                                     71500019
*                    4-5   SYSUT1                                       71550019
*                    6-7   SYSUT2                                       71600019
*                    8-9   SYSUT3                                       71650019
*                   10-11  OUTHDR2                                      71700019
*                   12-13  OUTTLR2                                      71750019
*                   14-15  OUTHDR3                                      71800019
*                   16-17  OUTTLR3                                      71850019
*                   18-19  OUTREC                                       71900019
*                   20-21  ERROR                                        71950019
*                   22-23  TRANS                                        72000019
         EJECT                                                          72050019
*        MESSAGE POINTER TABLE                                          72100019
         SPACE 2                                                        72150019
*        THIS TABLE CONTAINS ONE FULL-WORD ENTRY FOR EACH IEB-TYPE      72200019
*        MESSAGE (EXCLUDING SYNAD MESSAGES).  MSG01 CORRESPONDS         72250019
*        TO IEB901; MSG02 CORRESPONDS TO IEB902; ETC.                   72300019
         SPACE 1                                                        72350019
*              BYTE  1 - MESSAGE REQUEST CODE                           72400019
*                                                                       72450019
*                        X'FF' = INDICATES REQUEST                      72500019
*                        X'00' = NO REQUEST                             72550019
*                                                                       72600019
*              BYTE  2 - INSERT CODE                                    72650019
*                                                                       72700019
*                        X'00' - NO INSERT                              72750019
*                        X'01' - SYSIN                                  72800019
*                        X'02' - SYSPRINT                               72850019
*                        X'03' - SYSUT1                                 72900019
*                        X'04' - SYSUT2                                 72950019
*                        X'05' - SYSUT3                                 73000019
*                        X'06' - OUTHDR2                                73050019
*                        X'07' - OUTTLR2                                73100019
*                        X'08' - OUTHDR3                                73150019
*                        X'09' - OUTTLR3                                73200019
*                        X'0A' - OUTREC                                 73250019
*                        X'0B' - ERROR                                  73300019
*                        X'0C' - USERTAB                                73350019
*                        X'54' - BOTH SYSUT2 AND SYSUT3                 73400019
*                                                                       73450019
*                    NOTE:  IF X'54' IS SPECIFIED, THE MESSAGE IS       73500019
*                        OUTPUT TWICE, ONCE WITH SYSUT2 AND ONCE        73550019
*                        WITH SYSUT3.                                   73600019
*                                                                       73650019
*              BYTE  3 - INSERT LOCATION  (MESSAGE DISPLACEMENT)        73700019
*                                                                       73750019
*                    NOTE:  IF WORLD TRADE REQUIREMENTS NECESSITATE     73800019
*                        MODIFICATION OF THE MESSAGE TEXT CONTAINED     73850019
*                        IN THE MESSAGE MODULE (IEBTCR02), THESE VALUES 73900019
*                        MAY ALSO REQUIRE MODIFICATION.  THE DISPLACE-  73950019
*                        MENTS ARE GIVEN IN HEXADECIMAL REPRESENTATION  74000019
*                        AND REFERENCE THE START OF THE ACTUAL MESSAGE  74050019
*                        TEXT.                                          74100019
*                                                                       74150019
*                        EXAMPLE:  IF MESSAGE 10 WERE AS FOLLOWS:       74200019
*                        'IEB910I NO SYSUT1   DD CARD - JOB TERMINA-    74250019
*                        TED', THE 'I' OF 'IEB910' WOULD REPRESENT      74300019
*                        DISPLACEMENT 0 AND THE FIRST 'S' OF 'SYSUT1'   74350019
*                        WOULD REPRESENT DISPLACEMENT '11'.             74400019
*                                                                       74450019
*                                                                       74500019
*              BYTE  4 - OUTPUT LOCATION                                74550019
*                                                                       74600019
*                        BIT 0 - UNUSED                                 74650019
*                            1 - UNUSED                                 74700019
*                            2 - UNUSED                                 74750019
*                            3 - UNUSED                                 74800019
*                            4 - UNUSED                                 74850019
*                            5 - SYSPRINT IF AVAILABLE, CONSOLE         74900019
*                                OTHERWISE                              74950019
*                            6 - CONSOLE                                75000019
*                            7 - SYSPRINT                               75050019
*                                                                       75100019
*                        NOTE - BITS 6 AND 7 MAY BE ON SIMULTANEOUSLY   75150019
         SPACE 1                                                        75200019
MSGPTRS  EQU   *                       ASSIGN MSGPTRS NAME TO TABLE     75250019
MSG01    DC    X'00000002'                                              75300019
MSG02    DC    X'00000001'                                              75350019
MSG03    DC    X'00000001'                                              75400019
MSG04    DC    X'00000001'                                              75450019
MSG05    DC    X'00000001'                                              75500019
MSG06    DC    X'00000001'                                              75550019
MSG07    DC    X'00000001'                                              75600019
MSG08    DC    X'00000001'                                              75650019
MSG09    DC    X'00000001'                                              75700019
MSG10    DC    X'00030B01'             INSERT LOC = 11                  75750019
MSG11    DC    X'00010B01'             INSERT LOC = 11                  75800019
MSG12    DC    X'00020B02'             INSERT LOC = 11                  75850019
MSG13    DC    X'00000B01'             INSERT LOC = 11                  75900019
MSG14    DC    X'00002501'             INSERT LOC = 37                  75950019
MSG15    DC    X'00000F04'             INSERT LOC = 15                  76000019
MSG16    DC    X'00001504'             INSERT LOC = 21                  76050019
MSG17    DC    X'00002201'             INSERT LOC = 34                  76100019
MSG18    DC    X'00001D01'             INSERT LOC = 29                  76150019
MSG19    DC    X'00000004'                                              76200019
MSG20    DC    X'00000002'                                              76250019
         SPACE 3                                                        76300019
MOUNTID  DS    F                       MOUNT MSG ID                     76350019
IOBADDR  DS    F                       SYSUT1 IOB ADDRESS               76400019
TCRBUFL  DC    X'0000'                 TCR BUFFER LENGTH                76450019
         SPACE 1                                                        76500019
ERRIND   DC    X'00'                   ABNORMAL TERMINATION INDICATORS  76550019
         SPACE 1                                                        76600019
*              BIT 0 - CONFLICTING DCB PARAMETERS                       76650019
*                  1 - STORAGE ALLOCATION ERROR                         76700019
*                  2 - I/O ERROR IN READ AND EDIT                       76750019
*                  3 - ERROR IN JFCB READ OR MOUNT                      76800019
*                  4 - ERROR DURING READ AND EDIT                       76850019
*                  5 - ERROR IN ANALYZING CONTROL CARDS                 76900019
*                  6 - PERMANENT I/O ERROR ON QSAM GET/PUT              76950019
*                  7 - ERROR IN LOADING UTILITY MODULE                  77000019
         SPACE 1                                                        77050019
DUMMYIND DC    X'00'                   DUMMY FILE INDICATORS            77100019
         SPACE 1                                                        77150019
*              BIT 0 - UNUSED                                           77200019
*                  1 - UNUSED                                           77250019
*                  2 - UNUSED                                           77300019
*                  3 - UNUSED                                           77350019
*                  4 - SYSUT3                                           77400019
*                  5 - SYSUT2                                           77450019
*                  6 - SYSPRINT                                         77500019
*                  7 - SYSIN                                            77550019
         EJECT                                                          77600019
*        DATA CONTROL BLOCK (DCB) EXIT LISTS                            77650019
         SPACE 2                                                        77700019
*        SYSIN EXIT LIST                                                77750019
         SPACE 1                                                        77800019
         DS    0F                      FORCE FULL-WORD ALIGNMENT        77850019
INEXLST  DC    X'07'                   JFCB EXIT                        77900019
         DC    AL3(0)                  WORK AREA ADDRESS                77950019
         DC    X'85'                   DCB EXIT                         78000019
         DC    AL3(TCR720)             DCB EXIT ROUTINE                 78050019
         DC    X'00'                   DUMMY ENTRY                      78100019
         DC    AL3(INLRECL)            DEFAULT TABLE ADDRESS            78150019
         SPACE 2                                                        78200019
*        SYSPRINT EXIT LIST                                             78250019
         SPACE 1                                                        78300019
PREXLST  DC    X'07'                   JFCB EXIT                        78350019
         DC    AL3(0)                  WORK AREA ADDRESS                78400019
         DC    X'05'                   DCB EXIT                         78450019
         DC    AL3(TCR720)             DCB EXIT ROUTINE                 78500019
         DC    X'00'                   DUMMY ENTRY                      78550019
         DC    AL3(PRTLRECL)           DEFAULT TABLE ADDRESS            78600019
         DC    X'00'                   OUTPUT HEADER LABEL (NULL)       78650019
         DC    AL3(0)                  NULL ENTRY                       78700019
         DC    X'80'                   OUTPUT TRAILER LABEL (NULL)      78750019
         DC    AL3(0)                  NULL ADDRESS                     78800019
         SPACE 2                                                        78850019
*        SYSUT1 EXIT LIST                                               78900019
         SPACE 1                                                        78950019
UT1EXLST DC    X'87'                   JFCB EXIT                        79000019
         DC    AL3(0)                  NULL ADDRESS                     79050019
         SPACE 2                                                        79100019
*        SYSUT2 EXIT LIST                                               79150019
         SPACE 1                                                        79200019
         DS    0F                      FORCE FULL-WORD ALIGNMENT        79250019
UT2EXLST DC    X'07'                   JFCB EXIT                        79300019
         DC    AL3(0)                  WORK AREA ADDRESS                79350019
         DC    X'05'                   DCB EXIT                         79400019
         DC    AL3(TCR720)             DCB EXIT ROUTINE                 79450019
         DC    X'00'                   DUMMY ENTRY                      79500019
         DC    AL3(UT2LRECL)           DEFAULT TABLE ADDRESS            79550019
         DC    X'00'                   OUTPUT HEADER LABEL              79600019
         DC    AL3(0)                  NULL ADDRESS                     79650019
         DC    X'80'                   OUTPUT TRAILER LABEL             79700019
         DC    AL3(0)                  NULL ADDRESS                     79750019
         SPACE 2                                                        79800019
*        SYSUT3 EXIT LIST                                               79850019
         SPACE 1                                                        79900019
UT3EXLST DC    X'07'                   JFCB EXIT                        79950019
         DC    AL3(0)                  WORK AREA ADDRESS                80000019
         DC    X'05'                   DCB EXIT                         80050019
         DC    AL3(TCR720)             DCB EXIT ROUTINE ADDR            80100019
         DC    X'00'                   DUMMY ENTRY                      80150019
         DC    AL3(UT3LRECL)           DEFAULT TABLE ADDRESS            80200019
         DC    X'00'                   OUTPUT HEADER LABEL              80250019
         DC    AL3(0)                  NULL ADDRESS                     80300019
         DC    X'80'                   OUTPUT TRAILER LABEL             80350019
         DC    AL3(0)                  NULL ADDRESS                     80400019
         SPACE 2                                                        80450019
*        DCB PARAMETER DEFAULTS                                         80500019
         SPACE 1                                                        80550019
INLRECL  DC    X'0050'                 SYSIN LRECL  - 80                80600019
INBLK    DC    X'0050'                 SYSIN BLKSIZE - 80               80650019
INRECFM  DC    X'90'                   SYSIN - FIXED BLOCKED            80700019
INIDENT  DC    X'01'                   INTERNAL IDENTIFICATION CODE     80750019
         SPACE 1                                                        80800019
PRTLRECL DC    X'0079'                 SYSPRINT LRECL -  121            80850019
PRTBLK   DC    X'0079'                 SYSPRINT BLKSIZE - 121           80900019
PRTRECFM DC    X'94'                   SYSPRINT - FIXED BLOCKED ASA     80950019
PRTIDENT DC    X'02'                   INTERNAL IDENTIFICATION CODE     81000019
         SPACE 1                                                        81050019
UT2LRECL DC    X'0000'                 SYSUT2 LRECL                     81100019
UT2BLK   DC    X'0000'                 SYSUT2 BLKSIZE                   81150019
UT2RECFM DC    X'50'                   SYSUT2 RECFM - VARIABLE BLOCKED  81200019
UT2IDENT DC    X'04'                   INTERNAL IDENTIFICATION CODE     81250019
         SPACE 1                                                        81300019
UT3LRECL DC    X'0000'                 SYSUT3 LRECL                     81350019
UT3BLK   DC    X'0000'                 SYSUT3 BLKSIZE                   81400019
UT3RECFM DC    X'50'                   SYSUT3 RECFM - VARIABLE BLOCKED  81450019
UT3IDENT DC    X'05'                   INTERNAL IDENTIFICATION CODE     81500019
         EJECT                                                          81550019
*        DATA CONTROL BLOCKS (DCB'S)                                    81600019
         SPACE 3                                                        81650019
*        SYSUT1 (TCR) DCB                                               81700019
         SPACE 2                                                        81750019
TCRDCB   DCB   DSORG=PS,MACRF=(E),DDNAME=SYSUT1,DEVD=TA,RECFM=UA,      X81800019
               BFTEK=S,EXLST=UT1EXLST,IOBAD=NULL                        81850019
         EJECT                                                          81900019
*        SYSUT2 DCB                                                     81950019
         SPACE 2                                                        82000019
UT2DCB   DCB   DSORG=PS,DDNAME=SYSUT2,DEVD=DA,EXLST=UT2EXLST,          X82050019
               SYNAD=TCR740,EROPT=ABE,MACRF=(PM)                        82100019
         SPACE 3                                                        82150019
*        SYSUT3 DCB                                                     82200019
         SPACE 2                                                        82250019
UT3DCB   DCB   DSORG=PS,DDNAME=SYSUT3,DEVD=DA,EXLST=UT3EXLST,          X82300019
               EROPT=ABE,SYNAD=TCR740,MACRF=(PM)                        82350019
         SPACE 3                                                        82400019
*        SYSIN DCB                                                      82450019
         SPACE 2                                                        82500019
SYSINDCB DCB   DSORG=PS,DDNAME=SYSIN,DEVD=DA,EODAD=NULL,MACRF=(GM),    X82550019
               EXLST=INEXLST,EROPT=ACC,SYNAD=TCR740                     82600019
         SPACE 3                                                        82650019
*        SYSPRINT DCB                                                   82700019
         SPACE 2                                                        82750019
SYSPRDCB DCB   DSORG=PS,DDNAME=SYSPRINT,DEVD=DA,EXLST=PREXLST,         X82800019
               MACRF=(PM)                                               82850019
         EJECT                                                          82900019
*        GETMAINED STORAGE ADDRESSES                                    82950019
         SPACE 2                                                        83000019
CARDAREA DS    F                       CARD INPUT AREA                  83050019
JFCBAREA DS    F                       JFCB AREA ADDRESS                83100019
PRTAREA  DS    F                       SYSPRINT OUTPUT AREA             83150019
PRTLNGTH DS    F                       PRINT AREA LENGTH                83200019
COLUMN9  DS    F                       CARD INPUT COLUMN 9 ADDRESS      83250019
CARDEND  DS    F                       INPUT AREA ENDING ADDRESS        83300019
         SPACE 2                                                        83350019
USERNAME DC    7XL8'00'                USER ROUTINE NAME TABLE          83400019
           SPACE 1                                                      83450019
*              WORDS 0 & 1  - OUTHDR2 ROUTINE                           83500019
*                    2 & 3  - OUTTLR2 ROUTINE                           83550019
*                    4 & 5  - OUTHDR3 ROUTINE                           83600019
*                    6 & 7  - OUTTLR3 ROUTINE                           83650019
*                    8 & 9  - OUTREC  ROUTINE                           83700019
*                   10 & 11 - ERROR ROUTINE                             83750019
*                   12 & 13 - TRANSLATE TABLE                           83800019
           SPACE 2                                                      83850019
MISCIND  DC    X'00'                   MISCELLANEOUS INDICATORS         83900019
         SPACE 1                                                        83950019
*              BIT 0 - UNUSED                                           84000019
*                  1 - UNUSED                                           84050019
*                  2 - UNUSED                                           84100019
*                  3 - SYSUT2 LRECL REQUIRES MAXLN INCREMENT            84150019
*                  4 - SYSUT2 BLKSIZE REQUIRES MAXLN INCREMENT          84200019
*                  5 - SYSUT3 LRECL REQUIRES MAXLN INCREMENT            84250019
*                  6 - SYSUT3 BLKSIZE REQUIRES MAXLN INCREMENT          84300019
*                  7 - ALTERNATE DDNAMES FOUND                          84350019
             SPACE 2                                                    84400019
         SPACE 1                                                        84450019
RETCODE  DC    X'00'                   RETURN CODE                      84500019
TCRDEV   DC    CL3'000'                TCR DEVICE                       84550019
VOLSER   DC    CL6' '                  VOLUME SERIAL NUMBER             84600019
PRTRTN   DC    X'00'                   MESSAGE WRITER OPTION IND        84650019
CARRCTRL DC    X'40'                   CARRIAGE CONTROL                 84700019
         SPACE 1                                                        84750019
         DS    0F                      FORCE FULL-WORD ALIGNMENT        84800019
ATCR220  DC    A(TCR220)               MESSAGE DISPLAY                  84850019
CURMSGAD DS    F                       CURRENT SYSPRINT MSG ADDRESS     84900019
MSGAD    DS    F                       SINGLE MESSAGE ADDRESS           84950019
MSGLN    DS    F                       SINGLE MSG LENGTH                85000019
JOBNAME  DC    CL8' '                  JOB NAME                         85050019
STEPNAME DC    CL8' '                  STEPNAME                         85100019
  TITLE 'IEBTCRIN - DRIVER MODULE - IHADCB DSECT'                       85150019
         DCBD  DSORG=PS                                                 85200019
         END   IEBTCRIN                                                 85250019
