*********************************************************************** 00003017
*                   *****        I E B U P N I T       *****          * 00006017
* TITLE.  IEBUPNIT. INITIALIZATION CSECT                              * 00009017
*                                                                     * 00012017
* STATUS. CHANGE LEVEL 000                                            * 00015017
*                                                                     * 00018017
* FUNCTION/OPERATION.                                                 * 00021017
*        THIS CSECT (IEBUPNIT) WILL PERFORM THE FOLLOWING FUNCTIONS   * 00024017
*        IN THE ORDER INDICATED.                                      * 00027017
*                                                                     * 00030017
*        1.    INITIALIZE THE COMMUNICATION REGION IEBUPCON, THE      * 00033017
*              DCB'S AND THE ASSOCIATED EXIT LISTS.                   * 00036017
*                                                                     * 00039017
*        2.    ANALYZE THE INVOCATION OR EXECUTION PARAMETERS.        * 00042017
*                                                                     * 00045017
*        3.    OPEN THE INPUT DATA SET SYSIN.                         * 00048017
*                                                                     * 00051017
* ENTRY POINTS.                                                       * 00054017
*        ENTERED FROM IEBUPDTE AT 'IEBUPNIT'.                         * 00057017
*                                                                     * 00060017
* INPUT.                                                              * 00063017
*        THE INPUT PARAMETERS ASSOCIATED WITH THE INPUT DATA SET      * 00066017
*        SYSIN.                                                       * 00069017
*                                                                     * 00072017
* OUTPUT.                                                             * 00075017
*        CONTROL IS PASSED TO IEBUPLOG TO PRINT THE INITIAL HEADING,  * 00078017
*        THE INITIALIZED COMMUNICATION REGION IEBUPCON.               * 00081017
*                                                                     * 00084017
* EXITS-NORMAL-.                                                      * 00087017
*        1.    DCB AND USER HEADER LABEL EXITS ARE TAKEN WHEN THE     * 00090017
*              SYSIN DATA SET IS OPENNED.                             * 00093017
*                                                                     * 00096017
*        2.    CONTROL IS RETURNED TO IEBUPDTE AFTER SYSIN HAS BEEN   * 00099017
*              OPENNED.                                               * 00102017
*                                                                     * 00105017
* EXITS-ERROR-.                                                       * 00108017
*        IF AN ERROR OCCURRES DURING PARAMETER ANALYSIS OR OPEN A     * 00111017
*        MESSAGE IS GIVEN TO THE USER EXPLAINING THE ERROR AND A      * 00114017
*        RETURN TO THE OPERATING IS GIVEN WITH AN APPROPRIATE         * 00117017
*        RETURN CODE.                                                 * 00120017
*                                                                     * 00123017
*        RETURN CODES ISSUED BY THIS CSECT ARE:                       * 00126017
*              12   UNRECOVERABLE  ERROR-TERMINATION OF JOB.          * 00129017
*              16   ERROR IN LABEL HANDLING INDICATED BY USER-        * 00132017
*                   TERMINATION OF JOB.                               * 00135017
*                                                                     * 00138017
* EXTERNAL ROUTINES.                                                  * 00141017
*        IEBUPLOG- WHICH PRINTS HEADINGS AND ERROR MESSAGES.          * 00144017
*                                                                     * 00147017
*        IEBUPXIT- WHICH CONTAINS THE DCB AND USER HEADER LABEL       * 00150017
*              EXIT ROUTINES.                                         * 00153017
*                                                                     * 00156017
* TABLES/WORK AREAS.                                                  * 00159017
*        IEBUPCON- THE COMMUNICATION REGION.                          * 00162017
*                                                                     * 00165017
* ATTRIBUTES.                                                         * 00168017
*        SERIALLY REUSABLE AND BLOCK LOADS.                           * 00171017
*                                                                     * 00174017
*********************************************************************** 00177017
IEBUPNIT CSECT                                                          00200017
         EXTRN OMERROUT                                                 00400017
         EXTRN NMERROUT                                                 00600017
         EXTRN CTERROUT                                                 00800017
         EXTRN OMEOD                                                    01000017
         EXTRN EODCT                                                    01200017
         EXTRN OMHDREXT                                                 01220017
         EXTRN OMTRLEXT                                                 01240017
         EXTRN OMDCBEX                                                  01260017
         EXTRN NMHDREXT                                                 01280017
         EXTRN NMTRLEXT                                                 01300017
         EXTRN NMDCBEX                                                  01320017
         EXTRN CTHDREXT                                                 01340017
         EXTRN CTTRLEXT                                                 01360017
         EXTRN CTDCBEX                                                  01380017
         EJECT                                                          01400017
*     SYMBOLIC REGISTER NOTATION   GR0 - GR15                           01600017
GR0      EQU   0                                                        01800017
GR1      EQU   1                                                        02000017
GR2      EQU   2                                                        02200017
GR3      EQU   3                                                        02400017
GR4      EQU   4              REGISTER RESERVED FOR IEBUPXIT            02600017
GR5      EQU   5                                                        02800017
GR6      EQU   6                                                        03000017
GR7      EQU   7                                                        03200017
GR8      EQU   8                                                        03400017
GR9      EQU   9                                                        03600017
GR10     EQU   10                                                       03800017
GR11     EQU   11                                                       04000017
GR12     EQU   12             REGISTER RESERVED FOR IEBUPCON            04200017
GR13     EQU   13                                                       04400017
GR14     EQU   14                                                       04600017
GR15     EQU   15                                                       04800017
         SPACE 1                                                        05000017
         SAVE  (14,12)                                                  05200017
         BALR  GR2,0                                                    05400017
         USING *,GR2                                                    05600017
         USING IEBUPCON,GR12           POINTER TO DSECT AREA            05800017
         L     GR4,IEBEXITS   ESTABLISH ADDRESSABILITY FOR              05900017
*                                     IEBUPXIT                          06000017
         SPACE 1                                                        06200017
         ST    GR4,36(13)    STORE FOR PERMANEMT USE FOR IEBUPXIT BASE  06600017
         LR    GR10,GR1                                                 07000017
         ST    GR13,SAVE13X                                             07300017
         LA    GR13,SAVEREG            ADDRESS OF THIS CSECT SAVE AREA  07600017
         MVC   MAXSIZEL(2),EIGHTY      INITIALIZE RECORD SIZE (LRECL)   07800017
         MVI   LOGOUTAR,C' '                                            08000017
         MVC   LOGOUTAR+1(119),LOGOUTAR BLANKS INTO LOG OUT AREA        08200017
*                                                                       08400017
*    RESET SWITCHES AND WORK AREAS, SET FIRST ENTRY SWITCH              08600017
*                                                                       08800017
         LA    GR6,SIZETAB             SIZE OF SWITCH TABLE TO CLEAR    09000017
         MVC   PAGENO(4),ONEHEX        CLEAR PAGE NUMBER           3628 09200017
         EX    GR6,XCINSTR             RESET ALL SWITCHES TO ZERO       09400017
         MVI   FIRSENTR,BIT10          SET FIRST ENTRY SWITCH           09600017
         MVI   SOURCECD,X'FF'          INITIALIZE SOURCE BUFFER         09800017
         MVC   LRECL(2),MAXSIZEL       INITIALIZE LRECL TO 80 IN CASE   10000017
         MVI   LEVELXX,C'0'            INITIALIZE LEVEL BUFFER          10200017
         XC    DELTSEQ1(32),DELTSEQ1   CLEAR DELETE AND NUMBER SEQ      10400017
         XC    NMWRITEP(4),NMWRITEP  CLEAR NM BUFFER ADDRESS     PTM223 10460017
         XC    OMREADP(4),OMREADP  CLEAR OM BUFFER ADDRASS       PTM223 10520017
         LA    GR3,USERHDR             ADDRESS OF USER HEADER BUFFER    10600017
         ST    GR3,USRHDPTR            STORE POINTER IN COMMON AREA     10800017
         LA    GR5,USERTLR             ADDRESS OF USER TRAILER BUFFER   11000017
         ST    GR5,USRTRPTR            STORE POINTER IN COMMON AREA     11200017
         SPACE 1                                                        11400017
*                                                                       11600017
*    ROUTINE TO INITIALIZE DCB'S FOR RE-USABILITY                       11800017
* INCLUDING DDNAMES, SYSIN BLOCKSIZE, DATA SET TYPE AND USER TRLR EXIT  12000017
*                                                                       12200017
         MVC   SYSINNM(32),SYSINDC     MOVE DD NAMES TO BUFFER          12400017
         LA    GR11,DCBCTR             ADDRESS OF SYSIN DCB             12600017
         ST    GR11,DCBCT              POINTER TO SYSIN DCB             12800017
         MVC   BDDNAM(8,GR11),SYSINDC  MOVE DDNAME INTO DCB (SYSIN)     13000017
         MVC   BBLKSI(2,GR11),ZERO     CLEAR BLOCKSIZE IN DCB           13200017
         MVI   CTEXITS,X'00'            DEACTIVATE SYSIN HEADER EXT000I 13400017
         MVI   CTEXITS+4,X'00'          DEACTIVATE SYSIN TRALER EXT000I 13600017
         MVI   CTEXITS+8,X'85'          SYSIN DCB EXIT ALWAYS ACTVE000I 13800017
         LA    GR11,DCBOMR             ADDRESS OF SYSUT1 DCB            14000017
         ST    GR11,DCBOM              POINTER TO SYSUT1 DCB            14200017
         MVC   BBLKSI(2,GR11),ZERO     CLEAR BLOCKSIZE IN DCB           14400017
         MVC   BDSORG(2,GR11),ZERO     CLEAR DATA SET CHARACTERISTICS   14600017
         MVC   BLRECL(2,GR11),ZERO     CLEAR LOGICAL RECORD LENGTH DCB  14800017
         MVC   BDDNAM(8,GR11),SYSUT1DC MOVE DDNAME INTO DCB (SYSUT1)    15000017
         MVI   OMEXITS,X'01'            ACTIVATE SYSUT1 HEADER EXIT000I 15200017
         MVI   OMEXITS+4,X'03'          ACTIVATE SYSUT1 TRALER EXIT000I 15400017
         MVI   OMEXITS+12,X'85'        SYSUT1 DCB EXIT=ACTV/LAST   000I 15600017
         MVI   OMEXITS+16,X'07'        ACTVATE SYSUT1 JFCB EXIT    000I 15800017
         LA    GR11,DCBNMR             ADDRESS OF SYSUT2 DCB            16000017
         ST    GR11,DCBNM              POINTER TO SYSUT2 DCB            16200017
         MVC   BDSORG(2,GR11),ZERO     CLEAR DATA SET CHARACTERISTICS   16400017
         MVC   BLRECL(2,GR11),ZERO     CLEAR LOGICAL RECORD LENGTH DCB  16600017
         MVC   BBLKSI(2,GR11),ZERO     CLEAR BLOCKSIZE IN DCB           16800017
         MVC   BDDNAM(8,GR11),SYSUT2DC MOVE DDNAME INTO DCB (SYSUT2)    17000017
         MVI   NMEXITS,X'02'            ACTIVATE SYSUT2 HEADER EXIT000I 17200017
         MVI   NMEXITS+4,X'04'          ACTIVATE SYSUT2 TRALER EXIT000I 17400017
         MVI   NMEXITS+8,X'00'          DEACTIVATE TOTALING EXIT   000I 17600017
         MVI   NMEXITS+12,X'85'         ACTIVATE/LAST SYSUT2 DCB EX000I 17800017
         MVI   NMEXITS+16,X'07'         ACTIVATE SYSUT2 JFCB EXIT  000I 18000017
         L     GR5,0(GR10)             LOAD ADDRESS OF FIRST POINTER    18200017
         LTR   GR5,GR5                 TEST FOR MORE THAN 1 POINTER     18400017
         BM    OPEN1                   ONLY 1 POINTER                   18600017
         L     GR5,4(GR10)             LOAD ADDRESS DDNAME LENGTH FIELD 18800017
         LH    GR6,0(GR5)              LOAD LENGTH OF LIST              19000017
         LTR   GR6,GR6                 TEST IF ANY DDNAMES              19200017
         BZ    OPEN1                   NO                               19400017
*                                                                       19600017
*    ANALYZE INVOCATION PARAMETERS - DDNAMES                            19800017
*                                                                       20000017
         ST    GR6,STOREG              STORE SIZE OF DDNAME LIST        20200017
         TM    STOREG+3,X'07'          TEST IF MULTIPLE OF 8            20400017
         BZ    IFANYDDS                YES - NAMES ARE 8 CHARACTERS     20600017
         MVI   NOT8SW,1                SET INVALID DDNAME SWITCH        20800017
         B     OPEN1                   OPEN OUTPUT LOG                  21000017
*                                                                       21200017
IFANYDDS CLI   1(GR5),NOUPDD           MORE THAN 8 DDNAMES SPECIFIED    21400017
         BNH   OPEN1                   NO - NONE OVERRIDE UPDATE NAMES  21600017
         CLI   SYINDD(GR5),X'00'       IF SLOT IS ZERO- NO DD NAME      21800017
         BE    DDNAM2                  YES- DUMMY SLOT - CHECK NEXT ONE 22000017
         LA    GR11,DCBCTR             ADDRESS OF SYSIN DCB             22200017
         ST    GR11,DCBCT              POINTER TO SYSIN DCB             22400017
         MVC   BDDNAM(8,GR11),SYINDD(GR5)   OVERRIDE SYSIN NAME         22600017
         MVC   SYSINNM(8),SYINDD(GR5)    SAVE NAME OPEN WILL CLOBBER IT 22800017
DDNAM2   CLI   1(GR5),ONEDD            SECOND DDNAME                    23000017
         BNH   OPEN1                   NO- PROCEED                      23200017
         CLI   SYPRNDD(GR5),X'0'       IF SLOT ZERO - NO DDNAME         23400017
         BE    DDNAM3                  YES- DUMMY SLOT                  23600017
         MVC   SYSPRNTN(8),SYPRNDD(GR5)  SAVE NAME OPEN WILL CLOBBER IT 23800017
DDNAM3   CLI   1(GR5),TWODD            ANOTHER DDNAME                   24000017
         BNH   OPEN1                   NO - PROCEED                     24200017
         CLI   SYUT1DD(GR5),X'0'       IS SLOT ZERO                     24400017
         BE    DDNAM4                  YES - DUMMY SLOT                 24600017
         LA    GR11,DCBOMR             ADDRESS OF SYSUT1 DCB            24800017
         ST    GR11,DCBOM              POINTER TO SYSUT1 DCB            25000017
         MVC   BDDNAM(8,GR11),SYUT1DD(GR5)  OVERRIDE SYSUT1 NAME        25200017
         MVC   SYSUT1NM(8),SYUT1DD(GR5)  SAVE NAME OPEN WILL CLOBBER IT 25400017
DDNAM4   CLI   1(GR5),THREEDD          ANOTHER DD NAME                  25600017
         BNH   OPEN1                   NO - PROCEED                     25800017
         CLI   SYUT2DD(GR5),X'0'       IS SLOT ZERO                     26000017
         BE    OPEN1                   YES - DUMMY SLOT                 26200017
         LA    GR11,DCBNMR             ADDRESS OF SYSUT2 DCB            26400017
         ST    GR11,DCBNM              POINTER TO SYSUT2 DCB            26600017
         MVC   BDDNAM(8,GR11),SYUT2DD(GR5)  OVERRIDE SYSUT2 NAME        26800017
         MVC   SYSUT2NM(8),SYUT2DD(GR5)  SAVE NAME OPEN WILL CLOBBER IT 27000017
OPEN1    L     GR5,0(GR10)             LOAD PARAMETER POINTER           27200017
         LTR   GR5,GR5                 TEST IF LAST POINTER             27400017
         BM    WRTEHEAD                ONLY OPTION PARAMETERS           27600017
         L     GR5,4(GR10)             TEST FOR DDNAME POINTER          27800017
         LTR   GR5,GR5                 IS IT LAST POINTER          3628 28000017
         BM    WRTEHEAD                LAST ACTIVE POINTER              28200017
         L     GR5,8(GR10)             LOAD ADDRESS OF PAGE NUMBER      28400017
         LH    GR6,0(GR5)              LOAD LENGTH OF PAGE NUMBER       28600017
         LTR   GR6,GR6                 TEST IF LENGTH IS ZERO           28800017
         BZ    WRTEHEAD                YES- PAGE NUMBER NOT SPECIFIED   29000017
         C     GR6,FOUR                COUNT GREATER THAN 4             29200017
         BNH   AROUND                  NO- DO NOT HAVE TO TRUNCATE      29400017
INVA     MVI   PAGESW,X'01'                                        3628 29600017
         B     WRTEHEAD                START WITH ONE              3628 29800017
AROUND   LA    GR7,PAGENO+4       LOAD RIGHTMOST ADDRESS OF PAGENO 3628 30000017
         SR    GR7,GR6                 ADJUST ADDRESS BY GIVEN AMOUNT   30200017
         BCTR  GR6,0                   DECREMENT FOR MVC           3628 30400017
MVPAGE   EX    GR6,MOVEPAGE            PUT PAGE NUMBER IN TITLE         30600017
WRTEHEAD MVI   PRIMESW,X'0F'           SET WRITE HEADER SWITCH-OPEN LOG 30800017
         L     GR15,PRIMEWRT           ADDRESS OF MESSAGE WRITER        31000017
         BALR  GR14,GR15               ENTER MESSAGE ROUTINE            31200017
         CLI   LOGBADSW,X'0F'          WAS LOG DCB OPENED               31400017
         BE    ANERROR                 NO- COULD NOT OPEN PRINTER DCB   31600017
         CLI   PAGESW,X'0'             WAS PAGE PARAMETER INVALID       31800017
         BE    CHECK8SW                NO- CONTINUE                     32000017
         LA    GR11,PAGEMSG            ADDRESS OF ERROR MESSAGE         32200017
         LA    GR15,4                  SET UP CONDITION CODE            32400017
         BAL   GR14,SETCNCD            GO SET CONDITION CODE + MESSAGE  32600017
CHECK8SW CLI   NOT8SW,X'00'            WAS THERE AN ERROR IN DDNAMES    32800017
         BE    ANALPARM                NO- CONTINUE                     33000017
         LA    GR11,DDNAMEMG           ADDRESS OF ERROR MESSAGE         33200017
ALMOSTZ  LA    GR15,12                 PUT CONDITION CODE INTO REGISTER 33400017
         LA    GR14,CLOSENOW           RETURN FROM MESSAGE ROUTINE      33600017
SETCNCD  CH    GR15,HICONCDE           COMPARE AGAINST HIGHEST CODE YET 33800017
         BNH   FINERRT                 PREVIOUS CODE HIGH OR EQUAL      34000017
         STH   GR15,HICONCDE           STORE NEW HIGHEST CODE           34200017
FINERRT  L     GR15,PRIMEWRT           ADDRESS OF MESSAGE WRITER        34400017
         BR    GR15                    ENTER MESSAGE ROUTINE RETURN SET 34600017
CLOSENOW MVI   QUITALL,X'0E'           FORCE CONDITION MESSAGE AND EOJ  34800017
         L     GR15,PRIMEWRT           ADDRESS OF MESSAGE WRITER        35000017
         BR    GR15                    EOJ- CLOSE DCBLOGR- NO RETURN    35200017
ANERROR  L     GR13,SAVE13             RESTORE ORIGINAL CONTENTS OF 13  35400017
         LA    GR15,12                 SET CONDITION CODE OF 12         35600017
         RETURN (14,12),T,RC=(15)                                       35800017
         SPACE 1                                                        36000017
ANALPARM L     GR5,0(GR10)             LOAD PARAMETER POINTER           36200017
         LH    GR6,0(GR5)              LOAD PARAMETER COUNT             36400017
         LTR   GR6,GR6                 TEST FOR PARAMETERS              36600017
         BZ    OPENINPT                NO PARAMETERS- ASSUME MOD        36800017
         SR    GR8,GR8                 ZERO COUNT OF CHARACTER REGISTER 37000017
         LA    GR5,2(GR5)              UP TO ADDRESS OF PARAMETER FIELD 37200017
*                                                                     * 37400017
*   ANALYZE INPUT SPECIFICATIONS - CAN BE MOD OR NEW - DEFAULT IS MOD * 37600017
*                                                                     * 37800017
         CLI   0(GR5),COMMAEQ          IS COMMA FIRST CHARACTER         38000017
         BE    ASSUMMOD                YES- ASSUME DEFAULT OPTION MOD   38200017
         C     GR6,THREE               IS THERE ONLY ONE PARAMETER      38400017
         BE    INSPEC                  YES- ANALYZE INPUT SPECIFICATION 38600017
         CLI   3(GR5),COMMAEQ          IS 4TH CHARACTER A COMMA         38800017
         BNE   PMSG12                  NO- INVALID PARAMETER            39000017
INSPEC   CLC   0(3,GR5),NEW            IS PARAMETER 'NEW'               39200017
         BNE   GOON                    NO - CONTINUE TESTS              39400017
         MVI   CTONLYSW,X'01'          SET SWITCH ONLY NEW MASTER       39600017
         B     THRUINSP                DONE WITH PARAMETER ANALYSIS     39800017
ASSUMMOD LA    GR8,1(GR8)              UP COUNT OF CHARACTERS CHECKED   40000017
         LA    GR5,1(GR5)              ADJUST POINTER TO NEXT FIELD     40200017
         B     IFMORE                  TEST IF MORE FIELDS              40400017
GOON     CLC   0(3,GR5),MOD            IS PARAMETER 'MOD'               40600017
         BNE   PMSG12                  IS ERROR- GIVE MESSAGE, QUIT     40800017
THRUINSP LA    GR8,4(GR8)              INCREASE COUNT OF CHARACTERS     41000017
         LA    GR5,4(GR5)              ADJUST POINTER TO NEXT FIELD     41200017
IFMORE   CR    GR8,GR6                 MORE CHARACTERS TO ANALYZE       41400017
         BNL   OPENINPT                NO- COUNT IS FULFILLED           41600017
         ST    GR6,TEMPWA              SAVE COUNT OF CHARACTERS         41800017
*                                                                     * 42000017
*    TEST IF USER HEADER LABEL HANDLER SPECIFIED                      * 42200017
*                                                                     * 42400017
         BAL   GR3,GETNAME             GET SYSIN HEADER EXIT NAME       42600017
         L     GR6,DCBCT                                                42800017
         LA    GR3,CTHDR               ADDRESS OF CT HEADER NAME/AD000I 43000017
         LA    GR7,IFINTLR             RETURN FROM HEADER LABEL SETUP   43200017
         CLI   NONAMESW,X'01'          TEST IF NO NAME OR ERROR         43400017
         BE    NOINHDR                 SEE IF ERROR                     43600017
SETUPHDR C     GR9,EIGHT               TEST IF LABEL EXCEEDS 8 BYTES    43800017
         MVC   0(8,GR3),BLANKS8        CLEAR NAME FIELD                 44000017
         BH    TLRER                   ERROR IF MORE THAN 8             44200017
         BCTR  GR9,0                   DECREMENT FOR MVC COUNT          44400017
         EX    GR9,MVINHDEX            MOVE INHDR NAME TO BUFFER        44600017
         LOAD  EPLOC=(GR3)             LOAD ROUTINE BY NAME        000I 44800017
         ST    GR0,8(GR3)              STORE CORE ADDR AFTER NAME  000I 45000017
         MVI   CTHDRSW,X'0F'           FLAG AS CT HEADER RTN       000I 45200017
         MVI   CTEXITS,X'01'           ACTIVATE CT HEADER EXIT     000I 45400017
         BR    GR7                     RETURN                           45600017
*                                                                     * 45800017
*    TEST IF USER TRAILER LABEL HANDLER SPECIFIED                     * 46000017
*                                                                     * 46200017
IFINTLR  BAL   GR3,GETNAME             GET INTLR EXIT NAME IF GIVEN     46400017
         L     GR6,DCBCT               ADDRESS OF SYSIN DCB             46600017
         LA    GR3,CTTRLR              ADDRESS OF CT TRALER NAME/AD000I 46800017
         LA    GR7,CHECKALL            RETURN ADDRESS                   47000017
         CLI   NONAMESW,X'01'          TEST IF NO NAME OR ERROR         47200017
         BE    NOINTLR                 SEE IF ERROR                     47400017
SETUPTLR C     GR9,EIGHT               TEST IF LABEL EXCEEDS 8 BYTES    47600017
         BH    TLRER                   YES- ERROR IN TRAILER NAME       47800017
         MVC   0(8,GR3),BLANKS8        CLEAR NAME FIELD                 48000017
         BCTR  GR9,0                   DECREMENT FOR EXECUTE MVC        48200017
         EX    GR9,MVINHDEX            MOVE LABEL TO CORRECT BUFFER     48400017
         LOAD  EPLOC=(GR3)             LOAD ROUTINE BY NAME        000I 48600017
         ST    GR0,8(GR3)              STORE CORE ADDR AFTER NAME  000I 48800017
         MVI   CTTRLRSW,X'0F'          FLAG AS CT TRAILER ROUTINE  000I 49000017
         MVI   CTEXITS+4,X'03'         ACTIVATE CT TRALER EXIT     000I 49200017
         BR    GR7                     RETURN                           49400017
*                                                                     * 49600017
*    ALL POSSIBLE FIELDS THRU - ARE THERE CHARACTERS NOT ANALYZED     * 49800017
*                                                                     * 50000017
CHECKALL C     GR8,TEMPWA              ANY MORE CHARACTERS TO ANALYSE   50200017
         BNL   OPENINPT                NO EVERYTHING ANALYSED           50400017
PMSG12   LA    GR11,BADPARMG           LOAD BAD PARAMETER MESSAGE       50600017
         B     ALMOSTZ                 NO NEED TO CONTINUE WILL NOT RUN 50800017
NOINHDR  CLI   ERRNAMSW,X'01'          TEST IF ERROR INHDR LABEL        51000017
         BNE   IFINTLR                 NO- GO TO INTLR ANALYSIS         51200017
         B     TLRER                   GIVE MESSAGE                     51400017
NOINTLR  CLI   ERRNAMSW,X'01'          TEST IF ERROR INTLR LABEL        51600017
         BNE   CHECKALL                NO- GO TO LENGTH ANALYSIS        51800017
TLRER    LA    GR11,PLUS8MSG           ADDRESS OF ERROR MESSAGE         52000017
         B     ALMOSTZ                 GIVE MESSAGE THEN QUIT           52200017
*                                                                     * 52400017
*    SUBROUTINE TO GET THE EXIT NAME SPECIFIED                        * 52600017
*                                                                     * 52800017
GETNAME  MVI   NONAMESW,X'01'          SET SWITCH FOR NO NAME FOUND     53000017
         MVI   ERRNAMSW,X'00'          RESET ERROR SWITCH               53200017
         C     GR8,TEMPWA              HAVE ALL CHARACTERS BEEN CHECKED 53400017
         BCR   8,GR3                   YES- RETURN SHOULD NOT BE HERE   53600017
         CLI   0(GR5),COMMAEQ          IS FIRST CHARACTER A COMMA       53800017
         BNE   LDNAMLOC                NO- PREPARE TO RETURN NAME       54000017
RET1     LA    GR8,1(GR8)              INCREMENT CHARACTER COUNT        54200017
         LA    GR5,1(GR5)              INCREMENT PARAMETER POINTER      54400017
         BR    GR3                     RETURN                           54600017
LDNAMLOC LR    GR10,GR5                LOAD ADDRESS OF NAME FIELD       54800017
         SR    GR9,GR9                 ZERO NAME SIZE REGISTER          55000017
         LA    GR15,CHCKNEXT           RETURN FROM VALIDITY CHECK       55200017
         TM    0(GR5),ALPHA            TEST IF FIRST CHARACTER A LETTER 55400017
         BO    TSLTGTNO                YES- CHECK SOME MORE             55600017
INVALCHR LA    GR11,PLUS8MSG           ADDRESS OF ERROR MESSAGE         55800017
         LR    GR7,GR15                SAVE RETURN REGISTER FOR NOW     56000017
         L     GR15,PRIMEWRT           ADDRESS OF MESSAGE WRITER        56200017
         BALR  GR14,GR15               GIVE MESSAGE                     56400017
         LR    GR15,GR7                RETORE RETURN REGISTER           56600017
         MVI   ERRNAMSW,X'01'          SET ERROR FOUND SWITCH           56800017
         BR    GR15                    RETURN                           57000017
TSLTGTNO TM    0(GR5),X'0F'            TEST IF LOW ORDER FOUR BITS ZERO 57200017
         BZ    INVALCHR                IF SO INVALID                    57400017
         TM    0(GR5),NUMERIC          FIRST CHARACTER CANNOT BE NUMBER 57600017
         BO    INVALCHR                IF SO INVALID                    57800017
         MVI   NONAMESW,X'00'          CLEAR SWITCH VALID NAME FOUND    58000017
         BR    GR15                    RETURN                           58200017
CHCKNEXT LA    GR5,1(GR5)              INCREMENT CHARACTER ADDRESS      58400017
         LA    GR8,1(GR8)              INCREMENT TOTAL ANALYZED COUNT   58600017
         LA    GR9,1(GR9)              INCREMENT NAME CHARACTER COUNT   58800017
         C     GR8,TEMPWA              TOTAL COUNT ANALYSED TEST        59000017
         BCR   8,GR3                   IF COUNT FULFILLED RETURN        59200017
         CLI   0(GR5),COMMAEQ          DELIMITER COMMA AFTER 1ST NAME   59400017
         BE    RET1                    YES- RETURN                      59600017
         B     CHCKNEXT                KEEP SCANNING                    59800017
OPENINPT L     GR13,SAVE13X       LOAD RETURN SAVE AREA ADDRESS    000I 61800017
         LM    14,12,12(13)                                             65600017
         BR    14                                                       65800017
*                                                                       67600017
*    OLD MASTER AND NEW MASTER AND SYSIN DCB EXIT ROUTINES              67800017
*                                                                       68000017
         DS    0F                                                       68200017
OMEXITS  DC    X'01'                                                    68400017
         DC    AL3(OMHDREXT)                                            68600017
         DC    X'03'                                                    68800017
         DC    AL3(OMTRLEXT)                                            69000017
         DC    A(0)                                                     69200017
         DC    X'85'                                                    69400017
         DC    AL3(OMDCBEX)                                             69600017
         DC    X'07'                                                    69800017
         DC    AL3(0)                                                   70000017
NMEXITS  DC    X'02'                                                    70200017
         DC    AL3(NMHDREXT)                                            70400017
         DC    X'04'                                                    70600017
         DC    AL3(NMTRLEXT)                                            70800017
         DC    X'00'                                                    71000017
         DC    AL3(0)                                                   71200017
         DC    X'85'                                                    71400017
         DC    AL3(NMDCBEX)                                             71500017
         DC    X'07'                                                    71600017
         DC    AL3(0)                                                   71800017
CTEXITS  DC    X'00'                                                    72000017
         DC    AL3(CTHDREXT)                                            72200017
         DC    X'00'                                                    72400017
         DC    AL3(CTTRLEXT)                                            72600017
         DC    X'85'                                                    72800017
         DC    AL3(CTDCBEX)                                             73000017
         EJECT                                                          73200017
*   SYSIN DCB   CONTROL CARD INPUT     REFERRED TO AS CT                73400017
         SPACE 1                                                        73600017
DCBCTR   DCB   DSORG=PS,MACRF=(GL),DDNAME=SYSIN,RECFM=FB,LRECL=80, 000H*73800017
               EODAD=EODCT,EXLST=CTEXITS,SYNAD=CTERROUT,BUFNO=1    000H 74000017
         EJECT                                                          74200017
*   SYSUT1 DCB  OLD MASTER             REFERRED TO AS OM                74400017
         SPACE 1                                                        74600017
DCBOMR   DCB   DSORG=PO,MACRF=R,DDNAME=SYSUT1,NCP=1,               2039C74800017
               EXLST=OMEXITS,EODAD=OMEOD,SYNAD=OMERROUT                 75000017
         EJECT                                                          75200017
*   SYSUT2 DCB  NEW MASTER             REFERRED TO AS NM                75400017
         SPACE 1                                                        75600017
DCBNMR   DCB   DSORG=PO,MACRF=W,DDNAME=SYSUT2,NCP=1,               2039C75800017
               EXLST=NMEXITS,SYNAD=NMERROUT                             76000017
         SPACE 1                                                        76200017
         EJECT                                                          76400017
         SPACE 1                                                        76600017
         SPACE 1                                                        76800017
         SPACE 1                                                        77000017
*   CONSTANTS FOR INITIALIZATION ROUTINE                                77200017
ZERO     DC    D'0'                    BUFFER OF ZEROS                  77400017
THREE    DC    F'3'                                                     77600017
FOUR     DC    F'4'                                                     77800017
EIGHT    DC    F'8'                                                     78000017
***   WARNING-- KEEP THE 4 NAMES BELOW IN THIS ORDER                    78200017
**               SYSIN, SYSPRINT, SYSUT1, SYSUT2                     ** 78400017
SYSINDC  DC    CL8'SYSIN'                                               78600017
SYSPRNDC DC    CL8'SYSPRINT'                                            78800017
SYSUT1DC DC    CL8'SYSUT1'                                              79000017
SYSUT2DC DC    CL8'SYSUT2'                                              79200017
         SPACE 1                                                        79400017
USERHDR  DC    CL8' '                  NAME OF USER HEADER LABEL EXIT   79600017
USERTLR  DC    CL8' '                  NAME OF USERTRAILER LABEL EXIT   79800017
ZEROHEX  DC    C'00000000'             DOUBLE WORD HEX ZEROS            80000017
ONEHEX   DC    C'0001'                 DEFAULT PAGE NUMBER         3628 80200017
BLANKS8  DC    CL8' '              DOUBLE WORD OF BLANKS                80400017
SAVE13X  DS    F                                                        80500017
SAVEREG  DS    18F                     SAVE AREA USED BY READ/WRITE     80600017
         SPACE 3                                                        80800017
         DS    0D                                                       81000017
DSECTLOC DC    F'0'                    COMMON AREA ADDRESS JUST IN CASE 81200017
SAVE14   DC    F'0'                    SAVE RETURN ADDRESS FOR OPEN     81400017
         SPACE 1                                                        81600017
PRIMEWRT DC    V(IEBUPLOG)             ENTRY POINT OF LOG ROUTINE       81800017
IEBEXITS  DC    V(IEBUPXIT)                                             81900017
         SPACE 1                                                        82200017
*                                                                       82400017
*                INSTRUCTIONS INVOKED BY EXECUTES                       82600017
*                                                                       82800017
MVINHDEX MVC   0(1,GR3),0(GR10)        MOVE HEADER OR TRAILER TO BUFFER 83000017
MOVEPAGE MVC   0(1,GR7),2(GR5)         MOVE IN PAGE NUMBER              83200017
XCINSTR  XC    STARTAB(1),STARTAB      CLEARS UP TO 256 BYTES SWITCHES  83400017
         SPACE 1                                                        83600017
EIGHTY   DC    H'80'                   DEFAULT LRECL                    83800017
NEW      DC    C'NEW'                  TEST FOR PARM=NEW                84000017
CTDC     DC    C'CT'                   IDENTIFIES SYSIN IN MESSAGE      84200017
MOD      DC    C'MOD'                  PARM SETTING FOR MODIFY          84400017
SIXTEEN  DC    H'16'                   CONSTANT FOR HIGHEST ERROR CODE  84600017
NOT8SW   DC    X'00'                   SET IF INPUT NAME IN ERROR       84800017
PAGESW   DC    X'00'                   SET IF PAGE NUMBER IN ERROR      85000017
NONAMESW DC    X'00'                   SET IF NO NAME OR ERROR          85200017
BIT01    EQU   X'01'                                                    85400017
BIT10    EQU   X'10'                                                    85600017
         EJECT                                                          85800017
         IEBUPCON                                                       86000017
         EJECT                                                          86200017
DDNAMSCT DSECT                                                          86400017
DDLENGTH DS    CL2                                                      86600017
SYSLINDD DS    CL8                                                      86800017
MEMBERDD DS    CL8                                                      87000017
SYSLMODD DS    CL8                                                      87200017
SYSLIBDD DS    CL8                                                      87400017
SYSINDD  DS    CL8                                                      87600017
SYSPRNDD DS    CL8                                                      87800017
SYSPUNDD DS    CL8                                                      88000017
SYSUT1DD DS    CL8                                                      88200017
SYSUT2DD DS    CL8                                                      88400017
SYSUT3DD DS    CL8                                                      88600017
         SPACE 3                                                        88800017
         DCBD  DSORG=PS                                                 89000017
*                             INSERT  EQUATE  STATEMENTS                89200017
NOUPDD   EQU   X'20'                                                    89400017
ONEDD    EQU   X'28'                                                    89600017
TWODD    EQU   X'38'                                                    89800017
THREEDD  EQU   X'40'                                                    90000017
COMMAEQ  EQU   X'6B'                                                    90200017
ALPHA    EQU   X'C0'                                                    90400017
NUMERIC  EQU   X'F0'               BITS 1111 0000                       90600017
BDDNAM   EQU   DCBDDNAM-IHADCB                                          90800017
BBLKSI   EQU   DCBBLKSI-IHADCB                                          91000017
BDSORG   EQU   DCBDSORG-IHADCB                                          91400017
BLRECL   EQU   DCBLRECL-IHADCB         LOGICAL RECORD LENGTH FIELD      91600017
SYUT1DD  EQU   SYSUT1DD-DDNAMSCT                                        92000017
SYUT2DD  EQU   SYSUT2DD-DDNAMSCT                                        92200017
SYPRNDD  EQU   SYSPRNDD-DDNAMSCT                                        92400017
SYINDD   EQU   SYSINDD-DDNAMSCT                                         92600017
         END   IEBUPNIT                                                 92800017
