IEBUPXIT CSECT                                                          00100017
*A145500-146632,536500,536600                                    SM5212 00110021
*D140000-141000                                                  SM5212 00120021
* 107000-108000,110000-112600,113800-115000,115700-118000,127000 A27716 00150019
* 501100-501700                                                  A34107 00160021
* 183000                                                         A36139 00170021
*A196900,210400                                                  A41838 00180000
*D200000                                                         A41838 00182000
*C209000                                                         A41838 00184000
*C285500                                                         A41838 00190021
*A116600                                                         A48819 00195000
*A100500                                                        SA54852 00197021
*C101000                                                        SA54852 00199021
*A158500                                                       @SA67471 00199221
 SPACE 4                                                                00200017
*********************************************************************** 00300017
*                  *****         ITE B U P X I T       *****          * 00400017
* STATUS. CHANGE LEVEL 000.                                           * 00500017
*                                                                     * 00600017
* FUNCTION/OPERATION.                                                 * 00700017
*        THIS CSECT CONTAINS ALL ASYNCHRONOUS DCB EXIT SUBROUTINES    * 00800017
*        FOR  SYSIN,SYSUT1 AND SYSUT2. THIS CSECT CONTAINS THE        * 00900017
*        FOLLOWING EXIT ROUTINES FOR EACH DATA SET.                   * 01000017
*                                                                     * 01100017
*        1.    DCB EXIT ROUTINE.                                      * 01200017
*        2.    SYNAD ROUTINE.                                         * 01300017
*        3.    EODAD ROUTINE.      *** EXCEPT SYSUT2 ***              * 01400017
*        4.    USER HEADER LABEL ROUTINE.                             * 01500017
*        5.    USER TRAILER LABEL ROUTINE.                            * 01600017
*                                                                     * 01700017
* ENTRY POINTS.                                                       * 01800017
*        ENTERED FROM QSAM OR BSAM AT ANY ONE OF 14 POINTS.           * 01900017
*                                                                     * 02000017
*        OLD MASTER (SYSUT1) DATA SET ENTRY POINTS ARE:               * 02100017
*        1.    OMDCBEX                                                * 02200017
*        2.    OMERROUT;                                              * 02300017
*        3.    OMEOD;                                                 * 02400017
*        4.    OMHDREXT;                                              * 02500017
*        5.    OMTRLEXT.                                              * 02600017
*                                                                     * 02700017
*        NEW MASTER (SYSUT2) DATA SET ENTRY POINTS ARE:               * 02800017
*        1.    NMDCBEX;                                               * 02900017
*        2.    NMERROUT;                                              * 03000017
*        3.    NMHDREXT;                                              * 03100017
*        4.    NMTRLEXT.                                              * 03200017
*                                                                     * 03300017
*        SYSIN DATA SET ENTRY POINTS ARE:                             * 03400017
*        1.    CTDCBEX;                                               * 03500017
*        2.    CTERROUT;                                              * 03600017
*        3.    EODCT;                                                 * 03700017
*        4.    CTHDREXT;                                              * 03800017
*        5.    CTTRLEXT.                                              * 03900017
*                                                                     * 04000017
*********************************************************************** 04100017
 EJECT                                                                  04200017
         SPACE 4                                                        04300017
*********************************************************************** 04400017
*                                                                     * 04450017
*        THE FOLLOWING NAMES ARE ENTRY POINTS INTO THIS MODULE        * 04500017
*                                                                     * 04550017
*********************************************************************** 04600017
         ENTRY      OMHDREXT                                          * 04700017
         ENTRY      OMTRLEXT                                          * 04800017
         ENTRY      OMDCBEX                                           * 04900017
         ENTRY      OMERROUT                                          * 05000017
         ENTRY      OMEOD                                             * 05100017
         ENTRY      NMHDREXT                                          * 05200017
         ENTRY      NMTRLEXT                                          * 05300017
         ENTRY      NMDCBEX                                           * 05400017
         ENTRY      NMERROUT                                          * 05500017
         ENTRY      CTHDREXT                                          * 05600017
         ENTRY      CTTRLEXT                                          * 05700017
         ENTRY      CTDCBEX                                           * 05800017
         ENTRY      CTERROUT                                          * 05900017
         ENTRY      EODCT                                             * 06000017
         ENTRY     SPSYNAD                                       A27716 06050019
*********************************************************************** 06100017
         SPACE 4                                                        06200017
*********************************************************************** 06300017
*                                                                     * 06350017
*        SYMBOLIC REGISTER NOTATION     GR0--GR15                     * 06400017
*                                                                     * 06450017
*********************************************************************** 06500017
GR0      EQU   0                                                      * 06600017
GR1      EQU   1                                                      * 06700017
GR2      EQU   2                                                      * 06800017
GR3      EQU   3                                                      * 06900017
GR4      EQU   4         BASE REGISTER FOR THIS CSECT                 * 07000017
GR5      EQU   5                                                      * 07100017
GR6      EQU   6                                                      * 07200017
GR7      EQU   7                                                      * 07300017
GR8      EQU   8                                                      * 07400017
GR9      EQU   9                                                      * 07500017
GR10     EQU   10                                                     * 07600017
GR11     EQU   11                                                     * 07700017
GR12     EQU   12        BASE REGISTER FOR IEBUPCON                   * 07800017
GR13     EQU   13                                                     * 07900017
GR14     EQU   14                                                     * 08000017
GR15     EQU   15                                                     * 08100017
*********************************************************************** 08200017
         EJECT                                                          08300017
 SPACE 2                                                                08400017
*********************************************************************** 08500017
*                   *****         W A R N I N G        *****          * 08600017
*        REGISTER  4 CONTAINS THE BASE ADDRESS OF THIS MODULE.        * 08700017
*        REGISTER  12 CONTAINS THE BASE ADDRESS OF IEBUPCON.          * 08800017
*        NO CSECT  SHOULD ALTER THE CONTENTS OF EITHER REGISTER       * 08900017
*                                                                     * 09000017
*********************************************************************** 09100017
 SPACE 4                                                                09200017
         USING *,GR4                                                    09300017
         USING IEBUPCON,GR12                                            09400017
*********************************************************************** 09500017
*        END OF DATA ROUTINES FOR SYSIN AND SYSUT1 DATA SETS          * 09600017
*********************************************************************** 09700017
EODCT    MVI   EODCTSW,X'0F'            SET EOF ON SYSIN  SWITCH        09800017
         MVI   LABEL2SW,X'00'          RESET LABEL PROCESSING SWITCH    09850017
         B     ENTRNEXT                 INFORM NEXT CSECT OF EOF        09900017
OMEOD    MVI   OMEND,X'0F'              SET EOF ON SYSUT1 SWITCH        10000017
         MVI   REPROSW,X'00'      RESET REPRO SWITCH AT         SA54852 10050021
*                                  REPRO END                    SA54852 10100021
ENTRNEXT L     GR15,PROCESS                                             10200017
         BR    GR15                     ENTER NEXT STAGE- NO RETURN     10300017
         SPACE 2                                                        10400017
*********************************************************************** 10500017
*        THE FOLLOWING ARE SYNAD ERROR ROUTINES FOR SYSIN,            * 10600017
*        SYSUT1, SYSUT2 AND SYSPRINT DCB'S.  THEY PRINT ERROR         * 10700019
*        MESSAGES PRODUCED DYNAMICALLY BY THE SYNADAF ROUTINE         * 10800019
*********************************************************************** 10900017
CTERROUT STM   GR14,GR1,SYNSAVER       SAVE SYNAD PARAMETERS     A27716 10930019
         SYNADAF    ACSMETH=QSAM                                 A27716 10960019
SYNAD2   L     GR7,MACROMSG    ADDRESS OF AREA FOR SYNADAF MSG   A27716 10990019
         MVC   0(78,GR7),50(GR1)                                 A34086 11000020
SYNAD3   LA    GR11,IOERR              NUMBER OF I/O ERROR MSG   A27716 11020019
         MVI   SYNADSW,X'0F'                                     A27716 11050019
         B     ALMOSTZ                                           A27716 11080019
NMERROUT STM   GR14,GR1,SYNSAVER       SAVE SYNAD PARAMETERS     A27716 11110019
         SYNADAF    ACSMETH=BSAM                                 A27716 11140019
         L     GR7,MACROMSG     ADDRESS OF AREA FOR SYNAD MSG    A27716 11170019
         MVC   0(78,GR7),50(GR1)                                 A27716 11200019
         SYNADRLS                                                A27716 11230019
         LM    GR14,GR1,SYNSAVER       RESTORE SYNAD PARAMETERS  A27716 11260019
         CLI   TOTALSW,X'FE'           IS TOTALING EXIT ACTIVE   A27716 11290019
         BNL   LASTOTAL                 IF SO,ENTER FOR LAST TIME  000I 11320018
         B     SYNAD3                                            A27716 11410019
LASTOTAL ST    GR0,TOTLPARM+8           SAVE STATUS INFO ADDRESS   000I 11510018
         MVI   TOTLPARM+8,X'80'         FLAG AS I/O ERROR          000I 11520018
         LA    GR1,TOTLPARM             ADDRESS OF PARMLIST             11530018
         ST    GR9,TOTLPARM             BUFFER ADDRESS OF I/O ERROR000I 11540018
         L     GR15,TOTALADR            USER TOTAL ROUTINE ADDR    000I 11550018
         BALR  GR14,GR15                GIVE ROUTINE CONTROL       000I 11560018
         B     SYNAD3                                            A27716 11580019
OMERROUT STM   GR14,GR1,SYNSAVER       SAVE SYNAD PARAMETERS     A27716 11600019
         SYNADAF    ACSMETH=BSAM                                 A27716 11620019
         B     SYNAD2                                            A27716 11640019
SPSYNAD  STM   GR14,GR1,SYNSAVER       SAVE SYNAD PARAMETERS     A27716 11660019
         LA    GR15,12            GET RETURN CODE FOR THIS ERROR A48819 11663000
         CH    GR15,HICONCDE      IS THIS THE HIGHEST SO FAR     A48819 11666000
         BNH   SPSYNAD1           NO.. DON'T CHANGE              A48819 11669000
         STH   GR15,HICONCDE      SAVE HIGEST SO FAR             A48819 11672000
SPSYNAD1 EQU   *                                                 A48819 11675000
         SYNADAF    ACSMETH=QSAM                                 A27716 11680019
         MVC   WTOMSG1+23(25),50(GR1)                            A27716 11700019
         MVC   WTOMSG2+12(53),75(GR1)                            A27716 11720019
         SYNADRLS                                                A27716 11740019
         LA    GR1,WTOMSG1                                       A27716 11760019
         WTO   MF=(E,(1))                                        A27716 11780019
         LA    GR1,WTOMSG2                                       A27716 11800019
         WTO   MF=(E,(1))                                        A27716 11820019
         LM    GR14,GR1,SYNSAVER       RESTORE SYNAD PARAMETERS  A27716 11840019
         L     GR15,LOGFINSH                                     A27716 11860019
         BR    GR15                                              A27716 11880019
         SPACE 2                                                        11900017
ALMOSTZ  LA    GR15,12                  PUT RETURN CODE INTO REGISTER   12000017
         LA    GR14,CLOSENOW            RETURN HERE FROM MSG ROUTINE    12100017
SETCNCD  CH    GR15,HICONCDE            COMPARE AGAINST HIGHEST CODE    12200017
         BNH   FINERRT                  PREVIOUS CODE HIGH OR EQUAL     12300017
         STH   GR15,HICONCDE            STORE NEW HIGHEST CODE          12400017
FINERRT  L     GR15,PRIMEWRT            ADDRESS OF MESSAGE WRITER       12500017
         BR    GR15                                                     12600017
CLOSENOW L     GR2,CLOSEALL                                      A27716 12650019
         BALR  GR3,GR2                                           A27716 12700019
         MVI   QUITALL,X'0E'  FORCE CONDITION MSG AND EOJ MSG    A27716 12750019
         L     GR15,PRIMEWRT                                            12800017
         BR    GR15                     ENTER MESSAGE ROUTINE           12900017
         SPACE 4                                                        13000017
         SPACE 2                                                        13100017
*********************************************************************** 13200017
*        DCB EXIT ROUTINES FOR SYSIN, SYSUT1 AND SYSUT2               * 13300017
*********************************************************************** 13400017
         SPACE 2                                                        13500017
OMDCBEX  L     GR11,DCBOM               ADDRESS OF OLD MASTER DCB       13600017
         LA    GR7,OMBLOCKP             BLOCKING FACTOR BUFFER OM       13700017
         LA    GR6,OMBLKERR             INCORRECT BLOCKSIZE SWITCH      13800017
CHKSIZE  LH    GR9,BBLKSI(GR11)         PICK UP BLOCKSIZE FROM DCB      13900017
         SR    GR8,GR8                  SET BLOCKING FACTOR             14200017
         LH    GR3,BLRECL(GR11)         OBTAIN LOGICAL RECORD LENGTH    14300017
         LTR   GR3,GR3                  IS LOGICAL RECORD LENGTH ZERO   14400017
         BZ    NOSIZE                   YES-ASSUME 80                   14500017
         TM    BRECFM(GR11),X'80'       RECFM FIXED, UNDEFINED   SM5212 14550021
         BO    NOTVAR                   YES, MAXSIZE IS 80       SM5212 14560021
         TM    BRECFM(GR11),X'40'       RECORD VARIABLE          SM5212 14570021
         BZ    NOTVAR                   NO, NOT VARIABLE, BRNCH  SM5212 14580021
         CH    GR3,MAXSIZEV             VARIABLE LONGER THAN 84  SM5212 14590021
         BH    NOSIZE                   PLUG IN DEFAULTS         SM5212 14592021
         LTR   GR9,GR9                  IS BLOCKSIZE ZEROS       SM5212 14594021
         BZ    NOSIZE                   YES, PICK UP DEFAULTS    SM5212 14596021
         STH   GR3,LRECL                SAVE RECORD LENGTH       SM5212 14598021
         STH   GR9,FLBLK                SAVE ORIGINAL BLOCKSIZE  SM5212 14598421
         STH   GR9,SHRTBLK              FOR UPDATE-INPLACE       SM5212 14598821
         SH    GR9,VAR4                 DECREASE BY 4            SM5212 14599221
         DR    GR8,GR3                  OBTAIN BLOCKING FACTOR   SM5212 14599621
         STH   GR9,0(GR7)               BLOCKING FACTOR          SM5212 14599721
         STH   GR9,0(GR7)               LOGICAL RECORD COUNT     SM5212 14599821
         LTR   GR8,GR8                  ANY REMAINDER            SM5212 14599921
         BZ    RRRET                    BLOCKSIZE-LRECL OK       SM5212 14633221
         B     NOSIZE                   CANNOT HANDLE            SM5212 14643221
NOTVAR   LTR   GR9,GR9                  IS BLOCKSIZE ZERO        SM5212 14653221
         BZ    NOSIZE                   YES, SET ERROR FLAG      SM5212 14663221
         CH    GR3,MAXSIZEL             MAXIMUM RECORD SIZE EXCEEDED    14666721
         BH    NOSIZE                   YES-ASSUME 80                   14700017
         STH   GR3,LRECL                SAVE RECORD LENGTH              14800017
         STH   GR9,FLBLK                SAVE ORIGINAL BLOCKSIZE IN CASE 14900017
         STH   GR9,SHRTBLK              UPDATE=INPLACE IS SPECIFIED     15000017
         DR    GR8,GR3                  OBTAIN BLOCKING FACTOR          15100017
         STH   GR9,0(GR7)               BLOCKING FACTOR                 15200017
         STH   GR9,2(GR7)               LOGICAL RECORD COUNT            15300017
         LTR   GR8,GR8                  ANY REMAINDER                   15400017
         BZ    RRRET                    NO-RETURN BLOCKSIZE-LRECL OK    15500017
NOSIZE   MVI   0(GR6),X'01'             BLOCKSIZE OR LRECL IN ERROR     15600017
         MVC   BBLKSI(2,GR11),EIGHTY    MAKE BLOCKSIZE 80               15700017
         MVC   BLRECL(2,GR11),EIGHTY    MAKE LRECL 80                   15800017
         B     CHKSIZE                                         @SA67471 15850021
RRRET    TM    BRECFM(GR11),X'40'       RECFM V OR U             A48750 15900021
         BO    DEFAUL                   YES,DEFAULT RECFM TO F/B A48750 16000021
         TM    BRECFM(GR11),X'80'       RECFM IS FIXED           A48750 16050021
         BO    RETRNS                   YES,RETURN               A48750 16060021
DEFAUL   LH    GR3,BBLKSI(GR11)         BLOCKSIZE IN DCB         A48750 16100021
         MVI   BRECFM(GR11),FIXED       SET RECFM TO FIXED       A48750 16200021
         CH    GR3,LRECL                BLOCKSIZE AND LRECL EQUAL       16300017
         BE    RETRNS                   YES,FIXED RECORDS DCB SET UP OK 16400017
         MVI   BRECFM(GR11),FIXEDBLK    SET RECFM TO FIXED BLOCK A48750 16500000
RETRNS   RETURN                                                         16600017
NMDCBEX  L     GR11,DCBNM               ADDRESS OF NEW MASTER DCB       16700017
         LA    GR7,NMBLOCKP             BLOCKING FACTOR BUFFER          16800017
         LA    GR6,NMBLKERR             INCORRECT BLOCKSIZE SWITCH      16900017
         B     CHKSIZE                  CHECK BLOCKING FACTOR           17000017
CTDCBEX  L     GR11,DCBCT               ADDRESS OF SYSIN DCB            17100017
         USING IHADCB,GR11                                              17200017
         LH    GR7,DCBBLKSI             LOAD BLOCKSIZE                  17300017
         LTR   GR7,GR7                  CHECK FOR MULTIPLE OF 80        17400017
         BC    8,SETBLOK                IF NO BLKSIZ GIVEN,INSERT 80    17500017
         SR    GR6,GR6                  ZERO OUT REMAINDER REGISTER     17600017
         LA    GR5,80                   BLOCK SIZE MUST BE A            17700017
         DR    GR6,GR5                  MULTIPLE OF 80                  17800017
         LTR   GR6,GR6                  IS BLKSIZ A MULTIPLE OF 80      17900017
         BCR   8,GR14                   IF SO,RETURN                    18000017
         MVI   BLOKSW,X'10'             OTHERWISE SET FLAG              18100017
SETBLOK  MVI   DCBBLKSI+1,X'50'         ISNERT BLOCKSIZE                18400017
         BR    GR14                     RETURN                          18500017
         DROP  GR11                                                     18600017
         EJECT                                                          18700017
         SPACE 2                                                        18800017
*********************************************************************** 18900017
*        USER LABEL HEADER EXITS FOR SYSIN                            * 19000017
*********************************************************************** 19100017
CTHDREXT STM   GR0,GR14,LABLSAVE       SAVE ENTRY REGISTERS             19190017
         LA    GR13,USERSAVE            SAVE AREA                       19280017
         CLI   IOBADSW,X'0F'            I/O ERROR                       19370017
         BE    TERMZER0                 IF SO,TERMINATE                 19460017
         CLI   EOVSWTCH,X'0F'           FIRST ENTRY TO EXIT ROUTINE     19550017
         BE    CTENTER                  IF NOT,DO NOT INITCONSTANTS     19640017
         MVI   EOVSWTCH,X'0F'           SET FIRST ENTRY SWITCH   A41838 19690000
         MVC   USERRTN(12),CTHDR        MOVE USER ROUTINE NAME/ADDR     19730017
         MVI   USERRTN+8,X'04'         FLAG AS HEADER ROUTINE      000H 19820017
CTCOMMON MVI   USERCONT,X'00'           RESET NO. OF LABELS COUNT       19910017
         BAL   GR14,PRNTENTM           PRNT 'USER ROUTINE PROCESS'      20090017
CTENTER  BAL   GR14,COMONLBL           PASS CONTROL TO USER RUTINE      20180017
         LM    GR0,GR14,LABLSAVE                                        20270017
         BR    GR14                     RETURN                          20360017
         SPACE 3                                                        20450017
CTTRLEXT STM   GR0,GR14,LABLSAVE       SAVE ENTRY REGISTERS             20540017
         LA    GR13,USERSAVE            SAVE AREA                       20630017
         CLI   IOBADSW,X'0F'            I/O ERROR                       20720017
         BE    TERMZER0                IF SO, TERMINATE            UL0H 20810017
         CLI   EOVSWTCH,X'FF'           FIRST ENTRY TO TRL. RTN  A41838 20900000
         BE    CTENTER                  IF NOT,DO NOT INIT. CONS        20990017
         MVI   EOVSWTCH,X'FF'           SET SW. FIRST TRAILER    A41838 21040000
         MVC   USERRTN(12),CTTRLR       MOVE USER ROUTINE NAME/ADDR     21080017
         MVI   USERRTN+8,X'08'         FLAG AS TRAILER ROUTINE     000H 21170017
         B     CTCOMMON                 INITIALIZE CONSTANTS.           21260017
PRNT#LBL LA   GR11,LBLENTMS                                             21350017
         L     GR15,PRIMEWRT            LOG ROUTINE                     21440017
         BR    GR15                     PRINT MESSAGE                   21530017
PRNTENTM LA    GR11,USRLBLMS            LOAD MESSAGE CONSTANT.          21620017
         L     GR15,PRIMEWRT            ADDRESS OF IEBUPLOG             21710017
         BR    GR15                     PRINT MESSAGE,RETURN TO         21800017
*                                       CALLER VIA REG.14               21890017
   SPACE 4                                                              21980017
*********************************************************************** 22070017
*        USER LABEL SUBROUTINES USED BY ALL LABEL EXIT ROUTINES.      * 22160017
*        THIS ROUTINE GIVES CONTROL TO USER ROUTINES AND  CHECKS      * 22250017
*        FOR MOST TERMINATING CONDITIONS.                             * 22340017
*********************************************************************** 22430017
COMONLBL STM   GR14,GR1,TEMPSAVE        SAVE LINKAGE REGISTERS.         22520017
         L     GR15,USERRTN+8           GET ADDR OF USER LBL RUTINE     22610017
         BALR  GR14,GR15                GIVE CONTROL TO USER RUTINE     22700017
         STC   GR15,LBLRETCD            STORE USER RETURN CODE.         22790017
         L     GR1,TEMPSAVE+12          PICK UP POINTER TO PARM LIS     22880017
         CLI   8(GR1),X'80'             I/O ERROR?                      22970017
         BE    IOERROR                  IF SO,PRINT MSG AND RETURN      23060017
         IC    GR8,USERCONT            LOAD NO. LABELS PROCESSED        23150017
         LA    GR8,1(GR8)              ADD ONE TO THAT COUNT            23240017
         STC   GR8,USERCONT            AND RESTORE IT FOR REFERENC      23330017
         CLI   LBLRETCD,X'10'          IS USER RETURN CODE=16?          23420017
         BE    RETCDE16                 IF SO,PRINT MSG & LET RC=0.     23510017
         CLI   LBLRETCD,X'00'          IS USER RETURN CODE=0?           23600017
         BE    RETCDEND                 IF SO,PRINT MSG&RETURN.         23690017
         CLI   USERCONT,X'08'           HAVE EIGHT LABELS BEEN PROC     23780017
         BE    RETCDEND                 IF SO,TREAT AS RC=0.            23870017
         CLI   LBLRETCD,X'04'          IS RETURN CODE EQU TO 4     000H 23880017
         BE    RETRNLBL                IF SO, IT IS VALID          000H 23890017
         CLI   LBLRETCD,X'08'          IS RETURN CODE EQU TO 4     000H 23900017
         BE    RETRNLBL                IF SO, IT IS VALID          000H 23910017
         CLI   LBLRETCD,X'0C'          IS RETURN CODE EQU TO 4     000H 23920017
         BE    RETRNLBL                IF SO, IT IS VALID          000H 23930017
         B     RETCDEND                ELSE IT DEFAULTS TO ZERO    000H 23940017
RETRNLBL L     GR14,TEMPSAVE            LOAD CALLERS RETURN ADDRESS     23960017
         BR    GR14                     RETURN TO CALLER                24050017
         SPACE                                                          24140017
IOERROR MVI   IOBADSW,X'0F'                                             24230017
         LA    GR11,LBLERMSG            LOAD I/O ERROR MSG CON.         24320017
         L     GR15,PRIMEWRT            ADDRESS OF IEBUPLOG.            24410017
         BALR  GR14,GR15                PRINT I/O ERROR MSG             24500017
         B     RETRNLBL                 PREPARE TO RETURN               24590017
RETCDE16 SR    GR15,GR15                FORCE RETURN CODE TO ZERO.      24680017
RETCDEND STC   GR15,TEMPSAVE+4          SAVE RETURN CODE.               24770017
         LA    GR11,LSTRCMSG            LOAD LAST RET CD MSGCON.        24860017
         L     GR15,PRIMEWRT            ADDRESS OF IEBUPLOG.            24950017
         BALR  GR14,GR15                PRINT LAST RET CD MSG.          25040017
         LA    GR11,LBLENTMS            LOAD NO.OF ENTRANCES MSGCON     25130017
         L     GR15,PRIMEWRT            ADDRESS OF IEBUPLOG.            25220017
         BALR  GR14,GR15                PRINT NO. ENTR. MSG.            25310017
         IC    GR15,TEMPSAVE+4          RELOAD RETURN CODE.             25400017
         B     RETRNLBL                 PREPARE TO RETURN.              25490017
   SPACE 2                                                              25580017
*********************************************************************** 25670017
*        HEADER LABEL EXIT ROUTINE ON SYSUT1 UPDATE=INPLACE           * 25760017
*        IS REQUESTED.                                                  25850017
*********************************************************************** 25940017
UPDATEXT CLI   OMOPENSW,X'0F'          ENTERED DURING OPEN              26030017
         BNE   OMENTER                 IF NOT,PASS CONTROL DIRECT UUL0H 26120017
         CLC   0(4,GR1),ZERO            IS THERE A LABEL                26210017
         BE    OMENTERX                IF NOT,PASS CONTROL DIRECT  UL0H 26300017
         L     GR3,0(GR1)               LOAD POINTER TO USER LABEL      26390017
         CLI   3(GR3),C'1'              IS IT FIRST OF LABEL GROUP      26480017
         BE    INITDOM                  IF SO,INITIALIZE POINTERS       26570017
MVDOMLBL L     GR9,OMLBLPTR             LOAD ADDR OF LABEL SAVE ARA     26660017
         IC    GR5,OMLBLCNT            PICK UP NO. OF LABELS PROCES     26750017
         LA    GR5,1(GR5)              ADD ONE TO THE COUNT             26840017
         STC   GR5,OMLBLCNT            STORE IN IN COMMUN REGION        26930017
         ST    GR9,UPDTPARM             ADDR OF LABEL IN PARM FELD      27020017
         MVC   UPDTPARM+16(4),0(GR1)    MOVE LABEL PTR TO PARMS         27110017
         MVC   UPDTPARM+4(12),4(GR1)    MOVE PARMS TO UPDATE PARMS      27200017
         LA    GR9,80(GR9)              ADDR IN OMLBLPTR NOW POINTS     27290017
         ST    GR9,OMLBLPTR             TO NEXT AVAILABLE LABEL         27380017
         CLI   OMHDRSW,X'0F'            IS THERE A USER HEADER RTN      27470017
         BE    OMENTER                 IF NOT,PASS CONTROL DIRECT  UL0H 27560017
         LM    GR0,GR14,LABLSAVE                                        27650017
         LA    GR15,12                  LOAD RET CD TO PROCESS NEXT     27740017
         BR    GR14                     RETURN CONTROL TO OPEN          27830017
INITDOM  LA    GR5,OMLABELS             LOAD START ADDR OF SAVE BUF     27920017
         ST    GR5,OMLBLPTR             INIT SAVE AREA POINTER          28010017
         MVI   USERCONT,X'00'           INIT NO. ENTRANCES COUNT        28100017
         MVI   OMLBLCNT,X'00'           INIT NO. LABELS PROCESSED       28190017
         MVI   OMSYSNLB,X'F0'          SET LABELS TO BE COPIED SW  000H 28210017
         CLI   LABELSW,X'10'           ARE THERE LABELS IN INPUT   000H 28230017
         BNE   OMHDRDMP                IF NOT,SWITCH IS PROPERLY ST000H 28250017
         MVI   OMSYSNLB,X'0F'          SET TO ACCEPT LABELS IN SYSM000H 28270017
         MVC   OMLBLPTR(4),LABELBUF    MOVE GETMAIN POINTER        000H 28290017
         MVC   OMLBLCNT(1),LABELCNT    MOVE LABEL COUNT TO COUNTER 000H 28310017
OMHDRDMP CLI   OMHDRSW,X'0F'           IS THERE A USER ROUTINE     000H 28330017
         BNE   MVDOMLBL                 IF NOT, PREPARE TO SAVE LBL     28370017
         BAL   GR14,PRNTENTM        PRINT USER RTN PROCESS MSG   A41838 28550021
         B     MVDOMLBL                 PREPARE TO SAVE LABELS          28640017
*********************************************************************** 29360017
*        OLD MASTER (SYSUT1) USER HEADER LABEL ROUTINE.               * 29450017
*********************************************************************** 29540017
OMHDREXT STM   GR0,GR14,LABLSAVE       SAVE ENTRY REGISTERS             29630017
         LA    GR13,USERSAVE                                            29720017
         L     GR3,0(GR1)              ADDRESS OF LABEL BUFFER          29810017
         CLI   IOBADSW,X'0F'           I/O ERROR DURING LABEL PROC UL0H 29900017
         BE    TERMZER0                IF SO, THEN TERMINATE       UL0H 29990017
         MVC   USERRTN(12),OMHDR        MOVE USER ROUTINE NAME/ADDR     30080017
         MVI   USERRTN+8,X'04'         FLAG AS HEADER ROUTINE      000H 30170017
         CLI   INPLCSW,X'0F'            OPEN FOR UPDAT?                 30260017
         BE    UPDATEXT                 IF SO,GO TO UPDATE EXIT.        30350017
         CLI   OMOPENSW,X'0F'           ENTERED DURING OPEN?            30440017
         BNE   OMENTER                  IF NOT,PASS CONTROL DIRECT      30530017
*                                       TO USER LABEL ROUTINE           30620017
         CLC   0(4,GR1),ZERO            IS THERE A LABEL?               30710017
         BE    OMENTERX                IF NONE, CHECK FOR USER ROUTUL0H 30800017
         CLI   3(GR3),C'1'             IS THIS THE FIRST LABEL     UL0H 30890017
         BE    INITOM                   IF SO,INITIALIZE POINTERS       30980017
MVEOMLBL CLI   LABELSW,X'10'           LABELS IN INPUT STREAM           31020017
         BE    LABLUSER                THEN DO NOT SAVE LABELS          31060017
         L     GR9,OMLBLPTR            ADDRESS OF OM LABEL SAVE AREA    31100017
         IC    GR5,OMLBLCNT                                             31160017
         LA    GR5,1(GR5)                                               31250017
         STC   GR5,OMLBLCNT                                             31340017
         MVC   0(80,GR9),0(GR3)        MOVE LABEL TO SAVE AREA          31430017
         LA    GR9,80(GR9)             ADDR IN OMLBLPTR NOW POINTS      31520017
         ST    GR9,OMLBLPTR            TO NEXT AVAILABLE SLOT           31610017
LABLUSER  CLI   OMHDRSW,X'0F'          IS THERE A USER ROUTINE          31700017
         BE    OMENTER                  IF SO,PASS CONTROL DIRECTLY     31790017
         LA    GR15,4                   LOAD RET CD TO PROCESS NEXT     31880017
         LM    GR0,GR14,LABLSAVE                                        31970017
         BR    GR14                     RETURN CONTROL TO OPEN          32060017
         SPACE                                                          32150017
INITOM   LA    GR5,OMLABELS             LOAD START ADDR OF SAVE BUF     32240017
         ST    GR5,OMLBLPTR             INITIALIZE SAVE AREA POINT      32330017
         MVI   USERCONT,X'00'           INIT NO. ENTRANCE CONSTANT      32420017
         MVI   OMLBLCNT,X'00'           INIT NO. LABELS PROCESSED       32510017
         MVI   OMSYSNLB,X'F0'          FLAG FOR LABELS IN OM       UL0H 32610017
         CLI   LABELSW,X'10'           ANY LABELS IN INPUT STREAM  UL0H 32710017
         BNE   OMHDRCMP                IF NOT FLAGS ARE SET        UL0H 32810017
         MVI   OMSYSNLB,X'0F'          FLAGAS LABELS IN INPUT      UL0H 32910017
OMHDRCMP CLI   OMHDRSW,X'0F'           IS THERE A USER ROUTINE     UL0H 33010017
         BNE   MVEOMLBL                 IF NOT,PREPARE TO SAVE A LB     33230017
         BAL   GR14,PRNTENTM           PRINT USER RTN PROCESS MSG       33320017
         B     MVEOMLBL                 PREPARE TO SAVE LABEL.          33410017
         SPACE 2                                                        33500017
OMENTERX BAL   GR14,TERMZER2           PRINT USER ROUTINE MESSAGE  UL0H 33590017
         CLI   OMHDRSW,X'0F'           IS THERE A USER ROUTINE     UL0H 33680017
          BNE   OMENTER                GIVE CONTROL TO USER        UL0H 33770017
         BAL   GR14,PRNTENTM           PRINT USER PROCEE MSG       UL0H 33860017
OMENTER CLI   LBLRETCD,X'10'           IS USER RETURN CODE =16?         33950017
         BNE   OMENTER1                 IF SO,SHOULD TERMINATE NO.      34040017
TERMZER0 LA    GR15,0                  LOAD TERNINATE RETURN CODE.      34130017
         LM    GR0,GR14,LABLSAVE                                        34220017
         BR    GR14                     RETURN TO OPEN                  34310017
         SPACE                                                          34400017
OMENTER1 CLI   OMHDRSW,X'0F'            IS THERE A USER ROUTINE?        34490017
         BNE   TERMZER0                 IF NOT,TERMINATE LABEL PROC     34580017
         BAL   GR14,COMONLBL            PASS CONTROL TO USER ROUTIN     34670017
OMCOMMON CLC   0(4,GR1),ZERO                                       000H 34760017
         BNE   RETOM                   IF SO,IT MAY NOT BE THE LAST000H 34850017
         LA    GR14,RETOM              PICK UP ADDRESS OF EXIT CODE000H 34940017
         ST    GR14,TEMPSAVE           SAVE ADDRESS IN COMMON'S AREA00H 35030017
         LA    GR15,0                  CODE IS SET FOR LAST ENTRY  A00H 35120017
         B     RETCDEND                GO TO MESSAGE ROUTINES      000H 35210017
RETOM    LM    GR0,GR14,LABLSAVE                                   000H 35300017
         BR    GR14                                                000H 35390017
         SPACE 3                                                        35480017
*********************************************************************** 35570017
*        OLD MASTER (SYSUT1) USER TRAILER LABEL ROUTINE.              * 35660017
*********************************************************************** 35750017
OMTRLEXT STM   GR0,GR14,LABLSAVE       SAVE ENTRY REGISTERS             35840017
         LA    GR13,USERSAVE                                            35930017
         L     GR3,0(GR1)              ADDRESS OF LABEL BUFFER          36020017
         CLI   IOBADSW,X'0F'           I/O ERROR DURING LABEL PROC UL0H 36110017
         BE    TERMZER0                IF SO, THEN TERMINATE       UL0H 36200017
         MVC   USERRTN(12),OMTRLR       MOVE USER ROUTINE NAME/ADDR     36290017
         MVI   USERRTN+8,X'08'         FLAG AS TRAILER ROUTINE     000H 36380017
         CLC   0(4,GR1),ZERO           ARE TERE ANY LABELS              36650017
         BE    OMENT1                  IF NONE, CHECK FOR USER     UL0H 36740017
         CLI   3(GR3),C'1'              IS IT THE 1ST LABEL             36830017
         BE    INITOMTR                 IF SO,INITIALIZE CONSTANTS      36920017
MVEOMTRL L     GR9,OMLBLPTR            LOAD ADDR OF LABEL SAVE AREA     37010017
         IC    GR5,OMLBLCNT                                             37100017
         LA    GR5,1(GR5)                                               37190017
         STC   GR5,OMLBLCNT                                             37280017
         MVC   0(80,GR9),0(GR3)        MOVE LABEL TO SAVE AREA          37370017
         LA    GR9,80(GR9)             ADDR IN OMLBLPTR NOW POINTS      37460017
         ST    GR9,OMLBLPTR            TO NEXT AVAILABLE SLOT           37550017
         CLI   OMTRLRSW,X'0F'           IS THERE A USER HEADER RTN?     37640017
         BE    OMENTTRL                 IF SO,PASS CONTROL DIRECTLY     37730017
         LA    GR15,4                   LOAD RET CD TO PROCESS NEXT     37820017
         LM    GR0,GR14,LABLSAVE                                        37910017
         BR    GR14                     RETURN CONTROL TO EOV.          38000017
INITOMTR LA    GR5,OMLABELS             LOAD START ADDR OF SAVE BUF     38090017
         ST    GR5,OMLBLPTR             INITIALIZE SAVE AREA POINTR     38180017
         MVI   USERCONT,X'0'            INIT NO. ENTRANCE CONSTANT      38270017
         MVI   OMLBLCNT,X'0'            INIT # LABELS PROCESSED         38360017
         MVI   NMSYSNLB,X'F0'          FLAG AS COPY OLD MASTER LABEUL0H 38460017
         CLI   LABELSW,X'20'           ARE THERE INPUT LABELS TO PRUL0H 38560017
         BNE   OMTRLCMP                THEN FLAGS ARE SET          UL0H 38660017
         MVI   NMSYSNLB,X'0F'          FLAG AS LABELS IN INPUT     UL0H 38760017
OMTRLCMP CLI   OMTRLRSW,X'0F'          IS THERE A USER ROTINE      UL0H 38860017
         BNE   MVEOMTRL                IF NOT, COPY OM LABELS      UL0H 38960017
         BAL   GR14,PRNTENTM           PRINT USER HEADER MESSAGE   UL0H 39060017
         B     MVEOMTRL                PREPARE TO GENERATE LABELS  UL0H 39160017
OMENT1  BAL    GR14,TERMZER2           GIVE NO LABELS MESSAGE      UL0H 39260017
         CLI   OMTRLRSW,X'0F'          IS THERE A USER ROUTINE     UL0H 39360017
         BNE   OMENTTRL                IF NOT PREPARE TO RETURN    UL0H 39460017
         BAL   GR14,PRNTENTM           I PRINT USER ENETER MESS    UL0H 39560017
OMENTTRL CLI   OMTRLRSW,X'0F'           IS THERE A USER ROUTINE?        39710017
         BNE   TERMZER0                 IF NOT TERMINATE LABEL PROC     39800017
         BAL   GR14,COMONLBL            PASS CONTROL TO USER ROUTIN     39890017
         B     OMCOMMON                PREPARE TO RETURN TO SYSTEM 000H 39980017
         SPACE 2                                                        40880017
*********************************************************************** 40970017
*        NEW MASTER (SYSUT2) USER HEADER LABEL ROUTINE.               * 41060017
*********************************************************************** 41150017
NMHDREXT STM   GR0,GR14,LABLSAVE       SAVE ENTRY REGISTERS             41240017
         LA    GR13,USERSAVE                                            41330017
         L     GR3,0(GR1)              ADDRESS OF LABEL BUFFER          41420017
         CLI   IOBADSW,X'0F'           I/O ERROR DURING LABEL PROC UL0H 41510017
         BE    TERMZER0                IF SO, THEN TERMINATE       UL0H 41600017
         MVC   USERRTN(12),NMHDR        MOVE USER RTN NAME/ADDR         41690017
         MVI   USERRTN+8,X'0C'         FLAG AS TRAEADER OUTINE     000H 41780017
         CLI   NMOPNSWT,X'0F'           ENTERED DURING OPEN?            41870017
         BL    NMVOL2HD                HANDLING MULTIVOLUME D.S.   UL0H 41900017
         CLI   OMSYSNLB,X'00'           HAS A LABLE BEEN SAVED TO       41940017
*                                       OUTPUT TO NEW MASTER            42010017
         BE    NMENTERP                PREPARE TO ENTER USER ROUTINUL0H 42080017
         CLI   NMOPNSWT,X'1F'           IS THIS THE FIRST ENTRY?        42150017
         BE    NMINIT                   IF SO,INITIALIZE POINTERS.      42220017
MVENMLBL L     GR9,OMLBLPTR            LOAD ADDR OF LABEL SAVE AREA     42290017
         MVC   0(80,GR3),0(GR9)        MOVE SAVED LABEL TO BUFFER       42360017
         LA    GR9,80(GR9)             ADDR IN OMLBLPTR NOW POINTS      42430017
         ST    GR9,OMLBLPTR            TO NEXT AVAILABLE SLOT           42500017
         SR    GR8,GR8                 PREPARE FOR LTR INSTRUCTION 000H 42570017
         IC    GR8,OMLBLCNT            LOAD NO. LABELS TO BE PROCES     42640017
         BCTR  GR8,0                   DECREMENT COUNT BY ONE           42710017
         STC   GR8,OMLBLCNT            STORE NO LABELS REMAINING        42780017
         CLI   NMHDRSW,X'0F'            IS THERE A USER ROUTINE?        42850017
         BE    NMENTERS                IF SO,CHECK FOR LABEL GENERATION 42920017
         LTR   GR8,GR8                 HAS LAST LABEL BEEN GENERATD     42990017
         LA    GR15,4             MEANS PUT THIS LABEL,LAST RETURN000H 43060017
         BE    NMRETN             PREPARE TO RETURN FOR LAST TIME  000H 43130017
         LA    GR15,8                   RET CODE=CONT.PROCESSLABELS     43200017
         LM    GR0,GR14,LABLSAVE                                        43270017
         BR    GR14                     RETURN TO OPEN ROUTINE          43340017
NMENTERP CLI   NMHDRSW,X'0F'                                            43410017
         BNE   NMENTERQ                IF NOT PREPARE TO RETURN    000H 43480017
         CLI   NMOPNSWT,X'1F'          IS THIS THE FIRST ENTRY     000H 43550017
         BNE   NMENTER                 IF SO, PRINT HEADER MESSAGE 000H 43620017
         BAL   GR14,PRNTENTM           IF SO,GO TO PRINT ROUTINR   000H 43690017
         MVI   NMOPNSWT,X'0F'          SET ALREADY ENTERED SWITCH  000H 43720017
         B     NMENTER                 THEN GIVE HIS ROUTINE CNTRL 000H 43760017
NMENTERQ CLI   NMOPNSWT,X'1F'          IS THIS ENTRY DUE TO OPEN   000H 43830017
         BNE   TERMZER0                RETURN WITH CC=0            UL0H 43920017
         B     TERMZER1                PRINT NO LABELS EXIST MSG   UL0H 44010017
NMVOL2HD CLI   VOLSWTCH,X'04'          IS THIS FIRST ENTRY         UL0H 44110017
         BE    NMENTER                 IF NOT,GIVE CONTROL TO USER UL0H 44180017
         CLI   NMHDRSW,X'0F'           IS THERE A USER ROUTINE     UL0H 44250017
         BNE   TERMZER0                IF NOT RETURN TO D.M.       UL0H 44320017
         MVI   VOLSWTCH,X'04'          SET INITIALIZED SWITCH      UL0H 44390017
NMVOLCOM BAL   GR14,PRNTENTM           PRINT ROUTINE HAS BEEN ENTERUL0H 44460017
         MVI   USERCONT,X'00'          RESET NO. OF ENTRANCES SWTCHUL0H 44530017
         B     NMENTER                 PREPARE TO GIVE CONTROL     UL0H 44600017
TERMZER1 LA    GR11,NOULCRTM           PRINT NO USER LABELS EXIST  UL0H 44690017
         LA    GR14,TERMZER0           RETURN TO SET CC=0          UL0H 44780017
         L     GR15,PRIMEWRT           ADDRESS OF LOG MODULE       UL0H 44870017
         BR    GR15                    PRINT MESSAGE               UL0H 44960017
TERMZER2 LA    GR11,NOULXSTM           PRINT NO USER LABELS EXIST MUL0H 45050017
         L     GR15,PRIMEWRT           PRINT ROUTINE ADDRESS      MUL0H 45140017
         BR    GR15                    GO PRINT MESSAGE    S      MUL0H 45230017
NMRET04  LA    GR15,4                   RET CODE=LAST LABEL TO PROC     45320017
         MVC    TEMPSAVE(4),LABLSAVE+56                                 45410017
         B     RETCDEND                 PRINT MESSAGES AND RETURN       45500017
NMRET04X LA    GR15,4                                                   45590017
         MVC   TEMPSAVE(4),LABLSAVE+56                                  45680017
         B     RETRNLBL                PREPARE TO RETURM           UL0H 45770017
NMINIT   MVI   NMOPNSWT,X'0F'           RESET FIRST ENTRY PORTION       45860017
         MVI   USERCONT,X'00'           RESET NO. ENTRANCES COUNT       45950017
         LA    GR5,OMLABELS                                             46040017
         ST    GR5,OMLBLPTR                                             46130017
         CLI   OMSYSNLB,X'0F'          ANY LABELS SAVED FROM INPUT UL0H 46220017
         BNE   NMUSER                  IF NOT TEST FOR USER ROUTINEUL0H 46310017
         MVC   OMLBLCNT(1),LABELCNT    MOVE NO. OF LABELS SAVED    UL0H 46400017
NMUSER   CLI   NMHDRSW,X'0F'            IS THERE A USERLABEL ROUTIN     46890017
         BNE   MVENMLBL                 IF NOT,BEGIN PROCESSING LBL     46980017
         BAL   GR14,PRNTENTM           PRNT 'USER ROUTINE PROCESS'      47070017
         B     MVENMLBL                 BEGIN PROCESSING LABELS.        47160017
NMENTERS LTR   GR8,GR8                 ANY MORE LABELS TO CREATE        47170017
         BNE   NMENTER                 IF MORE, GIVE CONTROL DIRECT     47180017
         MVI   OMSYSNLB,X'00'          IF NO MORE, FLAG AS NO MORE      47190017
         B     NMENTER                 THEN ENTER USER ROUTINE          47200017
NMTNTERS LTR    GR8,GR8                ANY MORE LABELS TO CREATE        47210017
         BNE   NMENTER                 IF MORE,DO NOT FLAG AS LAST      47220017
         MVI   NMSYSNLB,X'00'          IF NO MORE,FLAG AS NONE SAVED    47230017
         B     NMENTER                 THEN ENTER USER ROUTINE          47240017
NMENTER  CLI   LBLRETCD,X'10'          IS USER RETURN CODE=16?          47250017
         BE    TERMZER0                 IF SO, PREPARE TO TERMINATE     47340017
         BAL   GR14,COMONLBL            PASS CONTROL TO USER RUTINE     47430017
         CLI   LBLRETCD,X'04'           IS RETURN CODE,EQUAL TO 4       47520017
         BE    NMRET04                  IF SO,PRINT TERMINATION MSG     47610017
NMRETN   LM    GR0,GR14,LABLSAVE                                        47700017
         BR    GR14                    RETURN CONTROL TO SYSTEM    UL0H 47790017
         SPACE                                                          47880017
*********************************************************************** 47970017
*        NEW MASTER (SYSUT2) USER TRAILER LABEL  ROUTINE              * 48060017
*********************************************************************** 48150017
NMTRLEXT STM   GR0,GR14,LABLSAVE       SAVE ENTRY REGISTERS             48240017
         LA    GR13,USERSAVE                                            48330017
         L     GR3,0(GR1)              ADDRESS OF LABEL BUFFER          48420017
         CLI   IOBADSW,X'0F'           I/O ERROR DURING LABEL PROC UL0H 48510017
         BE    TERMZER0                IF SO, THEN TERMINATE       UL0H 48600017
         MVC   USERRTN(12),NMTRLR       MOVE USER RTN NAME/ADDR         48690017
         MVI   USERRTN+8,X'10'         FLAG AS TRAILERR OUTINE     000H 48780017
         CLI   NMCLSESW,X'0F'           ENTERED DURING OPEN?            48870017
         BL    NMVOL2TR                CHECK FOR USER ROUTINE      UL0H 48970017
         CLI   NMSYSNLB,X'00'           HAS A LABEL BEEN SAVED?         49030017
         BE    NMTENTRP                PREPARE TO RETURN TO USER   UL0H 49090017
         CLI   NMCLSESW,X'1F'           IS THIS THE FIRST ENTRY?        49150017
         BE    NMTINIT                  IF SO,INITIALIZE POINTERS       49210017
MVTNMLBL L     GR9,OMLBLPTR                                             49270017
         MVC   0(80,GR3),0(GR9)        MOVE SAVED LABEL TO BUFFER       49330017
         LA    GR9,80(GR9)              OMLBLPTR NOW POINTS TO NEXT     49390017
         ST    GR9,OMLBLPTR             LABEL TO BE PROCESSED.          49450017
         SR    GR8,GR8                 PREPARE FOR LTR INSTRUCTION 000H 49510017
         IC    GR8,OMLBLCNT             LOAD NO. LABELS TO PROCESS      49570017
         BCTR  GR8,0                    DECREMENT THAT COUNT BY ONE     49630017
         STC   GR8,OMLBLCNT             STORE NO. OF LABELS REMAING     49690017
         CLI   NMTRLRSW,X'0F'           IS THERE A USER ROUTINE?        49750017
         BE    NMTNTERS                IF SO CHECK FOR LABEL GENERATION 49810017
         LTR   GR8,GR8                  HAS LAST LABEL BEEN CREATED     49870017
         LA    GR15,4             MEANS PUT THIS LABEL,LAST RETURN000H 49930017
         BE    NMRETN             PREPARE TO RETURN FOR LAST TIME  000H 49990017
         LA    GR15,8                   RET CD= CONT PROCESS LABLES     50050017
         B     NMRETN             RETURN                         A34107 50110021
NMTENTRP CLI   NMTRLRSW,X'0F'                                           50230017
         BNE   NMTENTRQ                IF NOT,PREPARE TO RETURN    000H 50290017
         CLI   NMCLSESW,X'1F'           IS THIS THE FIRST ENTRY    000H 50350017
         BNE   NMENTER                 GIVE CONTROL TO USER ROUTINE     50410017
         BAL   GR14,PRNTENTM           IF SO,GO OT PRINT ROUTINE   000H 50470017
         MVI   NMCLSESW,X'0F'          SET ALREADY ENETERED SWITCH 000H 50500017
         B     NMENTER                 GIVE CONTROL TO USER ROUTINE     50540017
NMTENTRQ CLI   NMCLSESW,X'1F'          IS THIS ENTRY DUE TO CLOSE  000H 50590017
         BNE   TERMZER0                RETURN A CC=0               UL0H 50650017
         B     TERMZER1                PRINT NO LABELS EXIST MSG   UL0H 50710017
NMVOL2TR CLI   VOLSWTCH,X'08'          FIRST ENTRY TO THIS ROUTINE UL0H 50770017
         BE    NMENTER                 IF NOT,GO DIRECT TO USER         50830017
         CLI   NMTRLRSW,X'0F'          IS THERE A USER ROUTINE     UL0H 50890017
         BNE   TERMZER0                TERMINATE THIS LABEL PROCESSUL0H 50950017
         MVI   VOLSWTCH,X'08'          SET AS ALREADY ENTERED      UL0H 51010017
         B     NMVOLCOM                COMMON VOLUME SWTCH RTN     UL0H 51070017
NMTINIT  MVI   NMCLSESW,X'0F'           RESET FIRST ENTRY PORTION  000I 51400017
         MVI   USERCONT,X'00'           RESET NO. ENTRANCES COUNT  000I 51500017
         LA    GR5,OMLABELS                                             51600017
         ST    GR5,OMLBLPTR                                             51700017
         CLI   NMSYSNLB,X'0F'           CHECK FOR SYSIN LABELS     000I 51800017
         BNE   NMTUSER                  IF NONE,CHECK FOR USER RTN 000I 51900017
         MVC   OMLBLPTR(4),LABELBUF     MOVE ADDR OF SAVED LABELS  000I 52000017
         MVC   OMLBLCNT(1),LABELCNT     MOVE NO.OF LABELS TO COUNTR000I 52100017
NMTUSER  CLI   NMTRLRSW,X'0F'           IS THERE A USER LBL ROUTINE000I 52200017
         BNE   MVTNMLBL                 IF NOT,BEGIN PROCESS LABELS000I 52300017
         BAL   GR14,PRNTENTM            PRNT 'USER RUTINE NOW PROC'000I 52400017
         B     MVTNMLBL                 BEGIN PROCESSING LABELS    000I 52500017
PROCESS  DC    V(IEBUPDT2)              ENTRY POINT OF MAIN PROCESSOR   53300017
PRIMEWRT DC    V(IEBUPLOG)              ENTRY POINT OF LOG ROUTINE      53400017
CLOSEALL DC    V(DEACTV)  ENTRY PT IN IEBUPDT2 TO CLOSE SYSUT1,  A27716 53408019
*                                      SYSUT2, AND SYSIN         A27716 53416019
MACROMSG DC    V(SYNADMSG)   ADDRESS OF SYNAD ERROR MSG IN IEBUPLOG     53424019
*                                                                A27716 53432019
SYNSAVER DS    4F                                                A27716 53440019
LOGFINSH DC    V(CLOSEPRT)             ENTRY PT IN IEBUPLOG TO CLOSE    53448019
*                                      SYSPRINT AND RETURN       A27716 53456019
WTOMSG1  WTO   'IEB802I  I/O ERROR                            ',MF=L,  X53464019
               ROUTCDE=11,DESC=7                                 A27716 53472019
WTOMSG2  WTO   'IEB802I                                                X53480019
                                   ',MF=L,ROUTCDE=11,DESC=7      A27716 53488019
ZERO     DC    F'0'                                                     53500017
EIGHTY   DC    H'80'                                                    53600017
MAXSIZEV DC    H'84'                                             SM5212 53650021
VAR4     DC    H'4'                                              SM5212 53660021
UPDTPARM DS    5F                                                       53700017
VOLSWTCH DC    X'00'                   USED TO INDICATE MULTIVOLUMEUL0H 53730017
*                                      PROCESSING FOR LABEL ROUTINEUL0H 53760017
LABLSAVE DS    18F                                                      53800017
USERSAVE DS    18F                                                      53900017
TEMPSAVE DS    4F                                                       54000017
BIT80    EQU   X'80'                                                    54100017
FIXED    EQU   X'80'                                                    54200017
FIXEDBLK EQU   X'90'                                                    54300017
         IEBUPCON                                                       54400017
         DCBD  DSORG=PS                                                 54500017
BLRECL   EQU   DCBLRECL-IHADCB                                          54600017
BBLKSI   EQU   DCBBLKSI-IHADCB                                          54700017
BRECFM   EQU   DCBRECFM-IHADCB                                          54800017
         END   IEBUPXIT                                                 54900017
