 TITLE 'IEBVCT - ALPHA SORT OF SETAB / BLD NEWNAME PTRTAB - IEBDSCPY'   00200019
IEBVCT   CSECT                                                          00400019
*C912000                                                         A41780 00410000
*C094000,303000                                                  A44144 00420000
*A301500-302000,303500                                           A44144 00422000
**********************************************************************  00450019
*TITLE IEBVCT - IEBCOPY S/E TABLE SORT                                * 00500019
*                                                                     * 00550019
*STATUS  CHANGE LEVEL 001                                             * 00600019
*                                                                     * 00650019
*FUNCTION/OPERATION -SORTS THE S/E TABLE ALPHABETICALLY                 00700019
*                  BUILDS THE NEWNAME POINTER TABLE WHEN NEWNAMES     * 00750019
*                  HAVE BEEN SPECIFIED.                               * 00800019
*ENTRY POINTS - IEBVCT                                                * 00850019
*                                                                     * 00900019
*INPUT - A POINTER TO UNSORTED S/E TABLE                              * 00950019
*        A COUNT OF THE NUMBER OF ENTRIES IN THE S/E TABLE              01000019
*        A COUNT OF THE NUMBER OF NEW NAMES                             01050019
*        A POINTER TO LOWEST CURRENTLY AVAILABLE CORE -(TO BE USED    * 01100019
*        AS THE BEGINNING OF THE NEWNAME POINTER TABLE)                 01150019
*                                                                     * 01200019
*OUTPUT - AN ALPHABETICALLY SORTED S/E TABLE                          * 01250019
*        A NEWNAME POINTER TABLE(IF THERE ARE NEWNAMES)               * 01300019
*        A POINTER TO THE LOWEST CURRENTLY AVAILABLE CORE - (NOW POINT* 01350019
*        TO ONE BYTE AFTER THE END OF THE NEWNAME POINTER TABLE - IF  * 01400019
*        THERE ARE NEWNAMES5                                          * 01450019
*EXITS - NORMAL - RETURN TO CALLER                                      01480019
*      - ERROR  - ISSUE ERROR MSG AND LINK TO IEBVTM (NO RETURN)        01510019
*                                                                     * 01550019
*EXTERNAL ROUTINES - NONE                                             * 01600019
*                                                                     * 01650019
*TABLES WORK ARES - S/E TABLE,NEWNAME POINTER TABLE                   * 01700019
*                                                                     * 01750019
*ATTRIBUTES - SERIALLY REUSEABLE                                      * 01800019
**********************************************************************  01850019
FF       EQU   X'FF'                                                    02800019
REG0     EQU   0                                                        03200019
REG1     EQU   1                                                        03600019
REG2     EQU   2                                                        04000019
REG3     EQU   3                                                        04400019
REG4     EQU   4                                                        04800019
REG5     EQU   5                                                        05200019
REG6     EQU   6                                                        05600019
REG7     EQU   7                                                        06000019
REG8     EQU   8                                                        06400019
REG9     EQU   9                                                        06800019
REG10    EQU   10                                                       07200019
REG11    EQU   11                                                       07600019
REG12    EQU   12                                                       08000019
REG13    EQU   13                                                       08400019
REG14    EQU   14                                                       08800019
REG15    EQU   15                                                       09200019
SAV8     EQU   8                       SAVE AREA DISPLACEMENT           09220019
SAV4     EQU   4                       SAVE AREA DISPLACEMENT           09240019
LEN10    EQU   10                      DISPLACEMENT                     09260019
OFF      EQU   X'00'                   OFF SETTING OF INTERNAL SWITCHES 09280019
LEN2     EQU   2                       LENGTH OF 2                      09300019
LEN8     EQU   8                       LENGTH OF 8                      09320019
LEN4     EQU   4                       LENGTH OF 4                      09340019
DUPNAM   EQU   X'46'                   OFFSET IN MESSAGE FOR DUP NAME   09360019
LEN1     EQU   1                       DISPLACEMENT OF 1                09380019
RCD8     EQU   C'8'                    COMPLETION CODE           A44144 09400000
DISP0    EQU   0                       0 DISPLACEMENT                   09420019
LEN16    EQU   16                      LENGTH OF 16                     09440019
LEN0     EQU   0                       LENGTH OF 0                      09460019
         SAVE  (14,12),,*                                               09500019
         BALR  REG11,REG0         ESTABLISH ADDRESSIBILITY              09800019
         USING *,REG11                                                  10100019
         USING IEBMCA,4                                                 10400019
         LA    REG12,SV3                                                10700019
         ST    REG12,SAV8(REG13)       SAVE ADDRESS OF CALLEDROUTINES   11000019
*                                      SAVE AREA                        11300019
         ST    REG13,SAV4(REG12)       SAVE ADDRESS OF CALLERS SAVE     11600019
*                                      AREA                             11900019
         LR    REG13,REG12                                              12400019
         LA    REG2,LEN10                                               13200019
         ST    REG2,INCRE                                               14000019
         ST    REG2,LEN                                                 14200019
         MVI   SWITCH,OFF              INITIALIZE ALL INTERNAL SWITCHES 14300019
         L     REG2,SEBEGIN       ADDRESS OF SETAB                      14400019
         LH    REG7,COUNT         NUMBER OF ENTRIES IN SETAB            14800019
         LTR   REG7,REG7                                                15200019
         BZ    RETURN             FULL COPY, SO NO NEED TO SORT         15600019
         BCTR  REG7,REG0               SUBTRACT 1 FROM NO. ENTRIES      15900019
         LA    REG8,LEN10         MULTIPLY NUMBER OF CTLTAB ENTRIES-1   16200019
*                                 BY 10                                 16500019
         SR    REG6,REG6                                                17000019
         MR    REG6,REG8                                                17200019
         AR    REG7,REG2          ADD PRODUCT TO ADDRESS OF CTLTAB      17600019
         ST    REG7,ENDPTR                                              18000019
         CLC   COUNT(LEN2),ONE    ONLY ONE ENTRY IN SETAB               18100019
         BNH   PROCNN             YES - NO NEED TO SORT SETAB           18200019
         ST    REG2,ENTRY1        ENTRY1=SEBEGIN                        18600019
         ST    REG2,TABBEGIN      TABBEGIN=SEBEGIN                      19000019
         LA    REG2,LEN10(REG2)                                         19500019
         ST    REG2,ENTRY2        ENTRY2=SEBEGIN+10                     20000019
TWOLAST  CLC   ENDPTR,ENTRY2       IS ENTRY2 THE LAST ENTRY             21200019
         BH    COMPARE            IF NOT DON'T SET INDICATOR            21600019
         OI    SWITCH,ENDSORT      TURN ON ENDSORT                      22000019
COMPARE  L     REG5,ENTRY1                                              22400019
         L     REG6,ENTRY2                                              22800019
         TM    SWITCH,BUFSORT      IS BUFFER SORT BEING DONE            23200019
         BO    SKIPIN             BRANCH IF YES                         23600019
         CLC   LEN2(LEN8,REG5),LEN2(REG6) COMPARE ENTRY1 + 2 FOR SETAB  23800019
*                                         SORT                          24000019
         B     RESULT             GO CHECK RESULT                       24400019
SKIPIN   CLC   LEN8(LEN8,REG5),LEN8(REG6) COMPARE ENTRY1+2 FOR OLDNAME  24800019
*                                         NEWNAME PAIR SORT             25200019
RESULT   BNL   PREPUSH            IF ENTRY1 NOT LOW, SEE IF ENT1 = ENT2 25600019
NEXTPAIR TM    SWITCH,ENDSORT      ENDSORT SET                          26000019
         BO    PROCNN             IF SO, SEE ABOUT OLD/NEW-NAME PAIRS   26400019
         MVC   ENTRY1(LEN4),ENTRY2     ENTRY1=ENTRY2                    26800019
         L     REG2,ENTRY2                                              27200019
         A     REG2,INCRE          ENTRY2=ENTRY2+INCRE                  27600019
         ST    REG2,ENTRY2                                              28000019
         B     TWOLAST            SEE IF ENTRY2 IS LAST ENTRY           28300019
PREPUSH  BNE   CARRYON            BRANCH IF ENTRY1 GT ENTRY2            28600019
SETERMS  MVC   NAMEFLD(LEN8),LEN2(REG5) PUT DUP NAME IN PARAM AREA      28800019
SETERMS1 MVI   VTMFLG1,UNUSEND    INDICATE UNUSUAL END OF OPERATION     29000019
         MVI   MSG1,LASTMSG+PBIT  LAST MESSAGE PLUS PARAMETER           29200019
         MVI   NAMEDISP,DUPNAM    OFFSET IN MSG FOR DUPE NAME           29300019
         MVI   PARAMS,NAME        INDIC NAME TO BE PRINTED              29400019
         MVI   MSG1+LEN1,M42           MSG CODE                         29700019
* CANNOT SPECIFY DUPLICATE MEMBERNAMES FOR SEL/EXCL/RENAME              30000019
SETCODE  EQU   *                                                        30100019
         CLI   RCBUF,RCD8         IS COMPLETION CODE 8 OR HIGHER A44144 30150000
         BNL   DONTSET            YES-DON'T SET RETURN CODE      A44144 30200000
         MVI   RCBUF,RCD8         SET COMPLETION CODE TO 8       A44144 30300000
DONTSET  EQU   *                                                 A44144 30350000
         L     REG15,VIEBVMS      ADDR OF MSG WRITER                    30600019
         BALR  REG14,REG15        LINK TO WRITE ERROR MSG               30900019
         L     REG15,VIEBVTM      ADDR OF TERMINATION ROUTINE           31200019
         BALR  REG14,REG15        EXIT TO TERMINATE OPERATION -         31500019
*                                 NO RETURN IS MADE TO HERE BY IEBVTM   31800019
CARRYON  MVC   SAVED(LEN4),ENTRY2      SAVED=ENTRY2                     32400019
         MVC   NEWENT(LEN4),ENTRY1     NEWENT=ENTRY1                    33000019
         L     REG2,NEWENT                                              33600019
         L     REG3,SAVED                                               34000019
COMPENT  TM    SWITCH,BUFSORT      IS BUFFER SORT BEINGDONE             34400019
         BO    SKIPIT             BRANCH IF YES                         34800019
         CLC   LEN2(LEN8,REG2),LEN2(REG3) COMPARE 'SAVED' VS 'NEWENT'   35200019
*                                         FOR CTLTAB SORT               35600019
         B     CONDCODE           GO CHECK RESULTS OF COMPARISON        36000019
SKIPIT   CLC   LEN8(LEN8,REG2),LEN8(REG3) COMPARE SAVED AND NEWENT FOR  36400019
*                                         ON NN PAIR SORT               36800019
CONDCODE BL    NEXTPAIR           SAVED LT NEWENT                       37200019
         BNE   CONTINUE           NEWENT LT SAVED                       37600019
         MVC   NAMEFLD(LEN8),LEN2(REG2) PUT DUP NAME IN PARAM AREA      38000019
         B    SETERMS1            GO SET UP ERROR MESSAGE               38400019
CONTINUE L     REG7,LEN                                                 38800019
         BCTR  REG7,REG0          SUBTR 1 FOR EXECUTION                 39200019
         EX    REG7,EX1            EXCHANGE SAVED AND NEWENT            39600019
         EX    REG7,EX2            EXCHANGE SAVED AND NEWENT            40000019
         EX    REG7,EX1                                                 40400019
SUBINCRE CLC   TABBEGIN,NEWENT                                          40800019
         BE    NEXTPAIR           BRANCH IF NEWENT NOW AT TOP OF TABLE  41200019
         L     REG2,NEWENT                                              41600019
         ST    REG2,SAVED         SAVED=NEWENT                          42000019
         S     REG2,INCRE         NEWENT=NEWENT-INCRE                   42400019
         ST    REG2,NEWENT                                              42800019
         L     REG3,SAVED                                               43200019
         B     COMPENT            GO COMPARE SAVED AND NEWENT           43600019
PROCNN   OI    FLG3,SORTDONE       TURN ON SORTDONE                     44000019
         TM    SWITCH,BUFSORT     ARE OLD/NEW NAME PR'S IN BFR SORTED   44100019
         BO    BLDNNTAB           YES - GO SEARCH SETAB FOR OLDNAMES    44200019
         L     REG10,ENDPTR                                             44400019
         OI    DISP0(REG10),SEBIT6     TURN ON LAST ENTRY BIT           44800019
         CLC   NNCT1(LEN2),ZROS        ANY NEWNAMES                     45200019
         BE    RETURN              NO NEWNAMES-RETURN TO CALLER         45600019
         LA    REG2,LEN10                                               46000019
         CL    REG2,INCRE         IS 10 THE CURRENT INCREMENT FACTOR    46500019
         BNE   BLDNNTAB           IF NOT, BUFFER SORT HAS BEEN DONE     47000019
         LA    REG2,LEN16                                               47500019
         ST    REG2,INCRE          INCRE=16                             48000019
         ST    REG2,LEN                                                 48400019
         MVI   SWITCH,BUFSORT     INDIC SORTING OLD/NEW NAME PRS IN     48600019
*                                 BFR                                   48800019
         LH    REG5,NNCT1         GET NN COUNT                          49000019
         BCTR  REG5,REG0          DECREM BY 1                           49200019
         LTR   REG5,REG5          IS COUNT NOW 0                        49400019
         BZ    BLDNNTAB           YES - NO NEED TO SORT NAMES IN BFR    49600019
*                                 BY NEWNAME                            49800019
         SLL   REG5,LEN4          MPLY NBR OF NEW NAMES-1 BY 16         50300019
         L    REG2,BCB            PTR TO BUFFER                         50800019
         ST    REG2,TABBEGIN                                            51200019
         AR    REG5,REG2          ADD PRODUCT TO ADDRESS OF BUFFER1     51600019
         ST    REG5,ENDPTR        PTR TO LAST ENTRY                     52000019
         ST    REG2,ENTRY1         ENTRY1= PTR BUFFER 1                 52400019
         LA    REG2,LEN16(REG2)                                         52800019
         ST    REG2,ENTRY2         ENTRY2= PTR BUFFER+16                53200019
         B     TWOLAST            SEE IF ENTRY2 LAST NAME IN BUFFER     53600019
BLDNNTAB L     REG2,BCB                                                 54000019
         LA    REG2,X0(REG2)      CLEAR HIGH ORDER BYTE                 54200019
         LA    REG15,X4           PUT 4 INTO REG                        54400019
         SR    REG2,REG15         GET POINTER TO BUFFER-4               54600019
         ST    REG2,BUFAD         SAVE POINTER                          54800019
         AR    REG2,REG15         RESTORE BUFFER POINTER                55000019
         L     REG3,LOCOR                                               55200019
         SRL   REG3,LEN2                                                56000019
         SLL   REG3,LEN2                                                56800019
         LA    REG3,LEN4(REG3)    ASSURE FULLWORD BOUNDARY FOR          57600019
*                                 NEWNAME POINTER TABLE                 58400019
         ST    REG3,ADNNPTRT      ESTAB ADDR OF NEWNAME PTR TABLE       59200019
         LH    REG6,NNCT1         NBR OF NEWNAMES                       60000019
STRTIT   L     REG5,SEBEGIN       ADDR OF START OF SETAB                60800019
* AT THIS POINT, R2 HAS ADDR OF 1ST OLDNAME OR 'NEXT' OLDNAME IN BFR    61600019
         B     TRYBIT2            DONT BUMP POINTER 1ST TIME            62600019
LOOP2    LA    REG5,LEN10(REG5)   BUMP POINTER TO NEXT CTLTAB ENTRY     63600019
TRYBIT2  TM    DISP0(REG5),SEBIT2 IS THIS RENAMED                       64600019
         BZ    LOOP2              NO - LOCATE NEXT ENTRY                66400019
         CLC   LEN2(LEN8,REG5),DISP0(REG2) IS THIS RENAMED OLDNAME      67200019
*                                      ENTRY THE ONE NOW BEING SOUGHT   68000019
         BNE   LOOP2              NO - LOCATE NEXT SETAB ENTRY          68800019
         C     REG3,BUFAD         WILL THIS ENTRY FIT                   68870019
         BNH   BUILDIT            YES, GO ON AND BUILD NNPTRTAB ENTRY   68940019
         SPACE 1                                                        69010019
         MVI   MSG1+P1,M43        SET CANNOT PROCESS ALL OLD NEW NAMES  69080019
*                                    SPECIFIED MSG                      69150019
         MVI   MSG1,LASTMSG       SET LAST MSG SWITCH                   69220019
         MVI   VTMFLG1,UNUSEND    INDICATE UNUSUAL END                  69290019
         B     SETCODE            SET RETURN CODE AND ISSUE MSG         69360019
         SPACE 1                                                        69430019
BUILDIT  EQU   *                                                        69500019
         ST    REG5,WKA1          YES - SET SETAB ADDR INTO NNPTRTAB    69600019
         MVC   DISP0(LEN4,REG3),WKA1                                    70400019
         LA    REG3,LEN4(REG3)    POINT TO NEXT NNPTRTAB SLOT           71200019
         LA    REG2,LEN16(REG2)   POINT TO NEXT POSSIBLE OLDNAME        72000019
         BCT   REG6,STRTIT        LOOP TO LOCATE NXT ENTRY              72800019
         ST    REG3,LOCOR         NO MORE TO LOCATE - REINIT LOCOR ADDR 73600019
         LH    REG6,NNCT1         NUMBER OF NEWNAMES                    73700019
         L     REG2,SEBEGIN       ADDR OF SETAB                         73800019
         L     REG3,ADNNPTRT      ADDR OF NEWNAME POINTER TABLE         73900019
         B     TRYNNBIT           DONT BUMP POINTER THIS TIME           74000019
ADD10    LA    REG2,LEN10(REG2)                                         74100019
TRYNNBIT TM    DISP0(REG2),SEBIT2 IS THIS A NEWNAME                     74200019
         BZ    ADD10              NO - POINT TO NXT SETAB ENTRY         74300019
         TM    DISP0(REG2),SEBIT4      IS IT FLAGGED AS DON'T COPY      74400019
         BZ    BUMP3              NO - SET TO GET NEXT PTR IN           74500019
*                                 NNPTRTAB                              74600019
         L     REG5,DISP0(REG3)   YES - GET POINTER TO OLDNAME ENTRY    74700019
         OI    DISP0(REG5),SEBIT4      SET IT AS DON'T COPY             74800019
BUMP3    LA    REG3,LEN4(REG3)         POINT TO NEXT POSSIBLE NNPTRTAB  74900019
*                                 SLOT                                  75000019
         BCT   REG6,ADD10         LOOP FOR NEXT NEWNAME SEARCH          75200019
RETURN   EQU   *                                                        75400019
         L     REG13,LEN4(DISP0,REG13)                                  77400019
         RETURN  (14,12)                                                79800019
         DS    0F                                                       80400019
INCRE    DC    F'0'               INCREMENT FACTOR                      80800019
LEN      DC    F'0'               LENGTH FACTOR                         81200019
SAVED    DC    F'0'                ENTRY BEING COMPARED FOR EXCHANGE    81600019
NEWENT   DC    F'0'                ENTRY BEING COMPARED FOR EXCHANGE    82000019
ENTRY1   DC    F'0'                MOST RECENT ENTRY IN TABLE TO BE     82400019
*                                  COMPARED                             82800019
ENTRY2   DC    F'0'                MOST RECENT ENTRY IN TABLE TO BE     83200019
*                                  COMPARED                             83600019
BUFAD    DC    F'0'               INTERNAL POINTER AREA                 84600019
TABBEGIN DC    F'0'               INTERNAL POINTER AREA                 85600019
EX1      XC    DISP0(LEN0,REG2),DISP0(REG3) EXCHANGE SAVED AND NEWENT   86600019
EX2      XC    DISP0(LEN0,REG3),DISP0(REG2) EXCHANGE SAVED AND NEWENT   87600019
ONE      DC    XL2'01'             COMPARED TO ENCT                     89600019
SWITCH   DC    X'00'              INTERNAL SWITCH                       89700019
ENDSORT  EQU   X'80'              ON = SETAB IS SORTED NOW              89800019
BUFSORT  EQU   X'40'              ON = BUFFER SORT IS BEING DONE        89900019
*              LO ORDER 6 BITS NOT USED                                 90000019
X0       EQU   0                  CONSTANT OF 0                         90100019
X4       EQU   4                  CONSTANT OF 4                         90200019
P1       EQU   1                  CONSTANT OF 1                         90300019
ENDPTR   DC    F'0'                PTR LAST ENTRY IN TABLE BEING        90400019
*                                  SORTED                               90800019
PATCHLEN EQU   (*-IEBVCT)/20      LENGTH OF 5 PER CENT PATCH AREA       91000019
PATCH    DC    XL(PATCHLEN)'00'   5 PER CENT PATCH AREA          A41780 91200000
         EJECT                                                          91500019
         DS    0D                                                       91800019
IEBMCA   DSECT                                                          92000019
         IEBMCA                                                         92400019
         END                                                            92800019
