         TITLE 'IEBVTM - INTERMEDIATE AND FINAL TERMINATION PROCESSOR'  00300019
IEBVTM   CSECT                                                          00400019
*C751000                                                         A41780 00450021
*A678500                                                         A37881 00450121
*C147000                                                         A41828 00450221
*A051500,655092-655095                                           A44144 00452222
*A558540-558552                                                  A48762 00454222
*A666500,674500,710500-710700                                    A48806 00456222
*********************************************************************** 00460222
*                                                                       00500019
*        FUNCTION -                                                     00600019
*            - CLOSE AND/OR RE-INITIALIZE APPROPRIATE DCB'S             00700019
*            - IF NECESSARY, COPIES 'SPILLED' MERGED OUTPUT DIRECTORY   00800019
*              FROM SYSUT4 TO OUTPUT DATA SET                           00900019
*            - WRITES APPROPRIATE TERMINATION MSGS                      01000019
*                                                                       01100019
*        INPUT - R15 = ADDR OF IEBVTM                                   01200019
*              - R13 = CALLER'S SAVE AREA                               01300019
*              - R4  = POINTER TO COMMUNICATION AREA                    01400019
*                                                                       01500019
*        SUBROUTINES CALLED -                                           01600019
*              IEBVMS - MESSAGE WRITER                                  01700019
*              IEBDRD - READ ROUTINE                                    01800019
*              IEBDWR - WRITE ROUTINE                                   01900019
*                                                                       02000019
*        EXITS -                                                        02100019
*            - TO 'IEBSCN' IF NECESSARY TO READ MORE CONTROL CARDS      02200019
*            - TO 'IEBMNI' IF NECESSARY TO PROCESS ''THE NEXT'' INPUT   02300019
*              DATA SET IN THE CURRENT ''INDD-GROUP''                   02400019
*            - TO THE CALLER/SYSTEM IF AT END-OF-JOB                    02500019
*                                                                       02600019
*        REGISTER DEFINITION                                            02700019
*                                                                       02800019
R0       EQU   0                  WORK/PARAM REG                        02900019
R1       EQU   1                  WORK/PARAM REG                        03000019
R2       EQU   2                  USED INTERNALLY TO POINT TO DCB       03100019
R3       EQU   3                  WORK REG                              03200019
R4       EQU   4                  ADDR OF IEBMCA                        03300019
R5       EQU   5                  INTERNAL SUBROUTINE LINKAGE REG       03400019
R6       EQU   6                  WORK REG                              03500019
R7       EQU   7                  WORK REG                              03600019
R8       EQU   8                  WORK REG                              03700019
R9       EQU   9                  WORK REG                              03800019
R10      EQU   10                 BASE REG                              03900019
R11      EQU   11                 WORK REG                              04000019
R12      EQU   12                 WORK REG                              04100019
R13      EQU   13                 ADDR OF REG SAVE AREA                 04200019
R14      EQU   14                 PARAM/LINK REG                        04300019
R15      EQU   15                 PARAM/LINK REG                        04400019
ZERO     EQU   0                                                        04500019
ONE      EQU   1                                                        04600019
OPEN     EQU   X'10'              FOR TESTING DCBOFLGS                  04700019
LWR      EQU   X'80'              TO SET DCBOFLGS IN OUTDCB, INDICATING 04800019
*                                 LAST OPERATION WAS A WRITE            04900019
PAMDIR   EQU   X'80'              FOR SETTING BPAM DCB - OUTPUT         05000019
FF       EQU   X'FF'                                                    05100019
RTCD     EQU   C'4'                                              A44144 05150022
RCRFRSH  EQU   C'0'               TO REFRESH RETURN CODE IN IEBMCA      05200019
D8       EQU   8                  LENGTH OR DISPLACEMENT OF 8           05204019
D2       EQU   2                                                        05208019
D4       EQU   4                                                        05212019
D0       EQU   0                                                        05216019
MS7      EQU   7                                                        05220019
D10      EQU   10                                                       05224019
X00      EQU   X'00'                                                    05228019
D3       EQU   3                                                        05232019
D1       EQU   1                                                        05236019
X01      EQU   X'01'                                                    05240019
D5       EQU   5                                                        05244019
D12      EQU   12                                                       05248019
MS8      EQU   8                                                        05252019
D6       EQU   6                                                        05256019
MS1      EQU   1                                                        05260019
O33      EQU   33             OFFSET IN MSG TEXT FOR OUTDD NAME  A36049 05262000
M61      EQU   61                 OFFSET IN MSG TEXT FOR NAME           05264019
D7       EQU   7                                                        05268019
D9       EQU   9                                                        05272019
D16      EQU   16                                                       05276019
C0       EQU   C'0'                                                     05280019
X0A      EQU   X'0A'              DISP IN MSG FOR NBR OF TRKS           05284019
X41      EQU   X'41'              DISP IN MSG FOR OUTDD NAME            05288019
X0F      EQU   X'0F'              RETURN CODE BITS (HIGH ORDER)         05292019
D48      EQU   48                 LENGTH OF DDLIST                      05296019
         EJECT                                                          05300019
* CALLER'S REGS ARE NOT SAVED, AS CALLER IS NOT RETURNED TO             05400019
         LR    R10,R15            ADDRESSIBILITY                        05500019
         USING IEBVTM,R10                                               05600019
         USING IEBMCA,R4                                                05700019
         LA    R13,RSA            ADDR OF SAVE AREA FOR CALLED RTNES    05800019
         NI    FLG7,NOPRNBDB+SUPPRMSG  RESET SEVERAL BITS               05900019
         LA    R2,INDCB                                                 06100019
         USING IHADCB,R2                                                06200019
         TM    DCBOFLGS,OPEN      IS THE INPUT DCB OPEN                 06300019
         BZ    TSTTER             IF NOT, DONT TRY TO CLOSE IT          06400019
         CLOSE ((R2))             CLOSE INPUT DATA SET                  06500019
         SPACE 2                                                        06600019
TSTTER   EQU   *                                                        06700019
         TM    VTMFLG1,NOMAIN     WAS GETMAIN NOT SATISFACTORY          06800019
         BO    WEJFTM             YES - WRITE EOJ MSGS AND TERMINATE    06900019
         TM    VTMFLG1,UNUSEND    DID A NON-I/O ERROR OCCUR             07000019
         BO    TSTVAL             YES - SEE IF IT WAS IN IEBDV1         07100019
         TM    VTMFLG1,IOERROR    DID A NON-FATAL I/O ERROR OCCUR       07200019
         BO    TSTERFS            YES - SEE WHAT TYPE OF ERROR          07300019
         SPACE 2                                                        07400019
* NORMAL END OF INPUT DATA SET PROCESSING HAS OCCURRED -                07500019
         BAL   R5,RESUT34         LINK TO RESET UT3/4 DCB'S IF REQUIRED 07600019
         SR    R8,R8                                                    07700019
         CH    R8,INDDCT          ANY MORE INPUT DATA SETS IN THE CUR-  07800019
*                                 RENT 'INDD-GROUP'                     07900019
         BNE   GETNXTIN           YES - SET UP TO PROCESS NEXT ONE      08000019
         TM    CCSWITCH,SYSINEOF  EOF ON SYSIN (NO MORE CONTROL STMTS)  08100019
         BO    NORMTALT           YES - SEE IF NEED TO RE-COPY FROM UT4 08200019
         TM    PARMSWCH,COPYNOW   NO - IS NXT CTL STATEMENT A 'COPY'    08300019
         BZ    PRNIGRP            NO - GO TO PREPARE TO PROCESS NEXT    08400019
*                                 ''INDD-GROUP''                        08500019
         SPACE 2                                                        08600019
NORMTALT EQU   *                  THE FOLLOWING CODE WILL BE EXECUTED   08670019
*                                 WHEN ''NORMAL'' END OF COPY STEP/OP-  08740019
*                                 ERATION HAS OCCURRED                  08810019
         TM    FLG4,ODALT         IS THE MERGED DIRECTORY ON SYSUT4     08900019
         BZ    NRC1               IF NOT, DONT TRY TO RE-COPY IT        09000019
         BAL   R5,RCPY            IF MERGED OUTPUT DIRECTORY IS ON SYS- 09100019
*                                 UT4, RE-COPY IT TO THE OUTPUT DATASET 09200019
NRC1     EQU   *                                                        09300019
         BAL   R5,PRTMBRS         PRINT NAMES OF MEMBERS COPIED         09400019
         BAL   R5,PS0             SEE IF A SELECTIVE COPY               09450019
         BAL   R5,PUDUT           PRT UNUSED TRACKS/BLOCKS MSGS         09500019
         BAL   R5,PREDASD     SEE IF OUTPUT PDS HAD TOO MANY     A36049 09530000
*                      DIRECTORY BLOCKS PER TRACK                A36049 09560000
         BAL   R5,COUTDCB         CLOSE OUTPUT DCB IF IT IS OPEN        09600019
         TM    CCSWITCH,SYSINEOF  DID EOF ON SYSIN OCCUR                09700019
         BZ    RMISC              IF NOT, GO TO EXIT TO IEBSCN          09800019
         TM    VTMFLG1,NOMAIN     WAS IT NECESSARY FOR CORE TO BE FREED 09900019
         BZ    EOJMS              NO, WRITE EOJ MSG AND END JOB         10000019
         BAL   R5,RESODS          YES, LINK TO SET UP BPAM DCB          10100019
         B     EOJMS              WRITE EOJ COMPLETION CODE MSG, CLOSE  10200019
*                                 ALL OPEN DCB'S, FREE CORE, AND RETURN 10300019
*                                 TO SYSTEM/INVOKER                     10400019
         SPACE 2                                                        10500019
PRNIGRP  EQU   *                  THIS CODE EXECUTED WHEN AN INPUT DATA 10600019
*                   SET'S MEMBERS HAVE BEEN ''NORMALLY'' COPIED, AND    10700019
*                   THIS WAS THE LAST INPUT DATA SET IN THE CURRENT     10800019
*                   INDD-GROUP, AND THE NEXT CONTROL STATEMENT TO BE    10900019
*                   PROCESSED IS NOT A 'COPY' STATEMENT.                11000019
         BAL   R5,RESOUT          RESET OUTDCB FOR USE WITH NEXT INDD   11100019
         BAL   R5,PRTMBRS         IF DIRECTORY NOT ON SYSUT4, PRINT     11200019
*                                 NAMES OF MEMBERS JUST COPIED          11300019
         BAL   R5,PS0             SEE IF A SELECTIBE COPY               11350019
         B     RMISC              SET UP AND EXIT TO IEBMNI IN MAIN     11400019
*                                 CSECT OF PROGRAM                      11500019
         SPACE 2                                                        11600019
GETNXTIN EQU   *                  THIS CODE EXECUTED WHEN AN INPUT DATA 11700019
*                   SET'S MEMBERS HAVE BEEN ''NORMALLY'' COPIED, AND    11800019
*                   THERE IS ANOTHER INPUT DATA SET TO BE PROCESSED IN  11900019
*                   THE CURRENT ''INDD-GROUP''.                         12000019
         BAL   R5,RESOUT          RESET OUTDCB FOR USE WITH NEXT INDD   12100019
         BAL   R5,PRTMBRS         PRT NAMES OF MBRS JUST COPIED UNLESS  12200019
*                                 OUTPUT DIRECTORY IS ON SYSUT4         12300019
         B     SLOCOR             RESET POINTERS AND EXIT TO IEBMNI     12400019
         SPACE 2                                                        12500019
TSTVAL   EQU   *                                                        12600019
         OI    FLG7,SUPPRMSG      SET SWITCH SO THAT MEMBSERS COPIED    12630019
*                                 MSGS WILL NOT BE ISSUED               12660019
         TM    IOEF2,NOSYSIN      WAS THERE A PROBLEM EITHER OPENING OR 12700019
*                                 USING SYSIN                           12800019
         BZ    TVFL               NEITHER - HANDLE AS ANY OTHER NON-I/O 12900019
*                                 ERROR                                 13000019
         TM    FLG4,NEWODS        WAS ANYTHING WRITTEN TO THE OUTPUT    13100019
*                                 DATA SET                              13200019
         BO    WEJFTM             NO - WRT EOJ MSGS AND TERMINATE JOB   13300019
         TM    FLG4,ODALT         IS MERGED DIRECTORY ON SYSUT4         13400019
         BO    T03RCPY            YES - RECOPY AND RESET OUTDCB         13500019
         BAL   R5,CLODS           NO - SET OUTDCB TO PREVIOUS VALID EOF 13600019
         B     WEJFTM             WRT EOJ MSGS AND TERMINATE JOB STEP   13700019
T03RCPY  EQU   *                                                        13800019
         BAL   R5,RCPY            RE-COPY DIRECTORY FROM SYSUT4 TO OUT- 13900019
*                                 PUT DATA SET                          14000019
         LA    R2,OUTDCB                                                14100019
         TM    DCBOFLGS,OPEN      IS OUTPUT DCB OPEN                    14200019
         BZ    WEJFTM             NO - WRT MSGS AND TERMINATE JOB STEP  14300019
         MVC   DCBFDAD(D8),ERPLMFD4    POINT TO PREVIOUS VALID EOF FOR  14400019
*                                      WHEN DIR WAS WRITTEN TO SYSUT4   14500019
         MVC   DCBTRBAL(D2),ERPTB4     SET PREVIOUS VALID TRACK BALANCE 14600019
         MVC   DCBRELAD(D4),ERPTTR4  SET PREV VAL LAST REC TTRN  A41828 14700021
         BAL   R5,CLODCB          CLOSE OUTPUT DCB                      14800019
         B     WEJFTM             WRT EOJ MSGS AND TERMINATE JOB STEP   14900019
         SPACE 2                                                        15000019
TVFL     EQU   *                                                        15100019
         TM    FLG4,NEWODS        WAS ANYTHING WRITTEN TO THE OUTPUT    15200019
*                                 DATA SET YET                          15300019
         BO    RSUTS              NO - SET UP TO FLUSH                  15400019
ERF7ON   EQU   *                  I/O ERROR WRITING TO SYSUT3           15500019
ERF8ON   EQU   *                  I/O ERROR READING FROM SYSUT3         15600019
         TM    FLG4,ODALT         IS MERGED DIRECTORY ON SYSUT4         15700019
         BZ    SKR9               NO                                    15800019
         BAL   R5,RCPY            RE-COPY DIRECTORY FROM UT4 TO OUTDCB  15900019
SKR9     EQU   *                                                        16000019
         BAL   R5,PRTMBRS         PRINT NAMES OF MEMBERS JUST COPIED    16100019
         BAL   R5,PAMSETUP        SET UP FOR BPAM CLOSE                 16150019
         BAL   R5,COUTDCB         SET OUTDCB TO ''CURRENT'' EOF STATUS  16200019
         SPACE 2                                                        16300019
RSUTS    EQU   *                                                        16400019
         BAL   R5,RESUT34         RESET SYSUT3 AND SYSUT4 DCB'S         16500019
         TM    VTMFLG1,NOMAIN     WAS IT NECESSARY FOR CORE TO BE FREED 16600019
         BZ    TSEOF              NO, DONT SET UP BPAM DCB              16700019
         BAL   R5,RESODS          YES, LINK TO SET UP BPAM DCB          16800019
TSEOF    EQU   *                                                        16900019
         TM    CCSWITCH,SYSINEOF  DID EOF OCCUR ON SYSIN                17000019
         BO    WEJFTM             YES- WRT EOJ MSGS AND TERMINATE JOB   17100019
         NI    IOEF2,SPRNOPN      RESET ALL BUT POSSIBLY THIS BIT       17200019
         XC    INDDCT(D2),INDDCT  SET COUNT OF PENDING INDD'S TO ZERO   17300019
         BAL   R5,CLODS           CLOSE OUTPUT DCB TO PREVIOUS VALID    17330019
*                                   EOF                                 17360019
         OI    FLG4,NEWODS        SET INDICATION THAT (NEXT) OUTPUT DA- 17400019
*                                 TA SET HAS NOT BEEN WRITTEN TO        17500019
         TM    PARMSWCH,COPYNOW   IS NEXT CONTROL STMT A 'COPY'         17600019
         BO    RMISC              YES - SET TO EXIT TO IEBSCN           17700019
         OI    PARMSWCH,FLUSHSW   NO - SET TO CAUSE IEBSCN TO 'FLUSH'   17800019
*                                 TO NEXT 'COPY' COMMAND OR TO '/*'     17900019
         B     RMISC              NOW SET TO EXIT TO IEBSCN             18000019
         SPACE 2                                                        18100019
TSTERFS  EQU   *                  THIS CODE EXECUTED WHEN A ''HARD''    18200019
*                                 I/O ERROR HAS OCCURRED                18300019
         TM    IOEF1,ERF2         I/O ERROR READING INPUT DIRECTORY     18400019
         BO    ERF2ON             YES - SEE IF SELECT WAS BEING DONE    18500019
         TM    IOEF1,ERF3         I/O ERROR READING MEMBER DATA         18600019
         BO    ERF3ON             YES - SEE IF ANY DATA WRITTEN TO OUT- 18700019
*                                 PUT DATA SET                          18800019
         TM    IOEF1,ERF4         I/O ERROR READING OUTPUT DIRECTORY    18900019
         BO    ERF4ON             YES - CHECK FOR ERF10 ON              19000019
         TM    IOEF1,ERF5         I/O ERROR WRITING DIRECTORY TO OUTDCB 19100019
         BO    ERF5ON             YES - CLOSE OUTPUT DCB                19200019
         TM    IOEF1,ERF6         I/O ERROR WRITING MEMBER DATA         19300019
         BO    ERF6ON             YES                                   19400019
         TM    IOEF1,ERF7         I/O ERROR WRITING TO SYSUT3           19500019
         BO    ERF7ON             YES                                   19600019
         TM    IOEF1,ERF8         I/O ERROR READING FROM SYSUT3         19700019
         BO    ERF8ON             YES                                   19800019
         TM    IOEF2,ERF9         I/O ERROR WRITING DIRECTORY TO UT4DCB 19900019
         BO    ERF9ON             YES                                   20000019
         TM    IOEF2,ERF10        I/O ERROR READING DIRECTORY FROM UT4  20100019
         BO    ERF10ON            YES - CHECK FOR ERF4 ON               20200019
***** NOTE - THE FOLLOWING CODE SHOULD NEVER GET EXECUTED -             20300019
         B     WEJFTM             WRITE EOJ ERROR MESSAGE, EOJ COMPLE-  20400019
*                                 TION CODE MSG, CLOSE ALL OPEN DCB'S,  20500019
*                                 FREE CORE, AND RETURN TO SYSTEM/CALLR 20600019
         SPACE 2                                                        20700019
ERF2ON   EQU   *                  I/O ERR READING INPUT PDS DIRECTORY   20800019
         TM    COMDCDSW,SELECTSC  WAS A SELECTIVE COPY BEING DONE       20900019
         BZ    ERF3ON             NO, SEE IF ANY OUTPUT WAS WRITTEN YET 21000019
         L     R6,SEBEGIN         ADDR OF SETAB                         21100019
ERF2L1   EQU   *                                                        21200019
         TM    D0(R6),SEBIT1+SEBIT4  IS DONTCOPY OR NEWNAME BIT ON      21300019
         BC    MS7,ERF2L2         YES- SEE IF THIS IS THE LAST ENTRY    21400019
         TM    D0(R6),SEBIT5      NO- WAS THIS MEMBERNAME ''FOUND''     21500019
         BO    ERF2L3             YES - GET MEMBERNAME FROM THE IDE     21600019
ERF2L2   EQU   *                                                        21700019
         TM    D0(R6),SEBIT6      IS THIS THE LAST ENTRY IN THE SETAB   21800019
         LA    R6,D10(R6)         BUMP POINTER IN CASE IT ISNT          21900019
         BZ    ERF2L1             NOT LAST ENTRY - CHECK NEXT           22000019
         B     ERF3ON             NOW SEE IF ANY OUTPUT WAS WRITTEN YET 22100019
ERF2L3   EQU   *                                                        22200019
         MVI   WKA1,X00                                                 22300019
         MVC   WKA1+D1(D3),D3(R6) SET POINTER TO IDE INTO WORK AREA (ON 22400019
*                                 FULL-WORD BOUNDARY) - POINTER MAY BE  22500019
*                                 AN IN-CORE ADDRESS OR A SYSUT3 TTR.   22600019
         TM    D2(R6),X01         IS THE IDE ON SYSUT3                  22700019
         BO    ERF2RUT3           YES - SET TO READ IT FROM SYSUT3      22800019
         L     R7,WKA1            NO - GET POINTER TO MBRNAME IN IDE    22900019
ERF2SM   EQU   *                                                        23000019
         MVI   MSG1+D1,MFBNC      MSG CODE- MBR FOUND BUT NOT COPIED    23100019
         MVI   MSG1,LASTMSG+PBIT  LAST MSG+BUILD                        23200019
         MVI   PARAMS,NAME                                              23300019
         MVC   NAMEFLD(D8),D0(R7) NAME OF MEMBER TO MSG PARAMETER AREA  23400019
         L     R15,VIEBVMS        ADDR OF MSG WRITING ROUTINE           23500019
         BALR  R14,R15            LINK TO WRITE MSG                     23600019
         B     ERF2L2             SEE IF MORE MEMBERNAMES               23700019
ERF2RUT3 EQU   *                                                        23800019
         L     R0,WKA1            GET SYSUT3 TTR OF SPILLED IDE         23900019
         LA    R1,UT3DCB          SET TO CONVERT                        24000019
         LA    R2,D5(R1)          POINT TO FDAD FIELD OF SYSUT3 DCB     24100019
         L     R15,VTTOCC                                               24200019
         BALR  R14,R15            LINK TO CONVERT TTR TO MBBCCHHR       24300019
         MVI   SENSE,SENSE1+SENSE3 SET TO READ FROM SYSUT3              24400019
         L     R15,VIEBDRD                                              24500019
         BALR  R14,R15            LINK TO READ THE SPILLED IDE          24600019
         L     R7,ADWK            ADDR OF WHERE IDE WAS READ INTO       24700019
         LA    R7,D12(R7)         POINT TO IDE WITHIN WORK BUFFER       24800019
         B     ERF2SM             GO TO PUT MEMBERNAME FROM THE SPILLED 24900019
*                                 IDE INTO THE MESSAGE                  25000019
         SPACE 1                                                        25100019
ERF3ON   EQU   *                  I/O ERROR READING MEMBER DATA         25200019
         TM    FLG4,NEWODS        ANYTHING WRITTEN TO OUTPUT DATA SET   25300019
         BO    ERF5ON             IF NOT, DONT PRINT TRKS/BLKS MESSAGES 25400019
         BAL   R5,PUDUT           WRITE UNUSED TRKS / UNUSED BLKS MSGS  25500019
ERF5ON   EQU   *                  I/O ERROR WRITING DIRECTORY TO OUTDCB 25600019
ERF6ON   EQU   *                  I/O ERROR WRITING MEMBER DATA         25700019
ERF9ON   EQU   *                  I/O ERROR WRITING DIRECTORY TO UT4DCB 25800019
ERF10ON  EQU   *                  I/O ERROR READING DIRECTORY FROM UT4  25900019
         BAL   R5,CLODS                SET OUTDCB TO PREVIOUS VALID EOF 26000019
         B     RSUTS              GO TO RESET UT3/UT4 DCB'S AND FLUSH   26100019
         SPACE 2                                                        26200019
ERF4ON   EQU   *                  I/O ERR READING OUTPUT DIRECTORY      26300019
         TM    IOEF2,ERF10        DID ERROR OCCUR WHILE READING FROM    26400019
*                                 SYSUT4                                26500019
         BZ    ERF5ON             NO                                    26600019
*                                 YES - MUST HAVE BEEN DURING OUTPUT    26700019
*                                 PRESCAN, SINCE ERF4 AND ERF10 BOTH ON 26800019
         B     ERF3ON             SEE IF COPYING HAS BEEN DONE TO THE   26900019
*                                 OUTPUT DATA SET                       27000019
         SPACE 2                                                        40600019
*********************************************************************** 40700019
RESUT34  LA    R2,UT3DCB                                                40800019
         TM    DCBOFLGS,OPEN      IS SYSUT3 DCB OPEN                    40900019
         BZ    RPT1               IF NOT, SEE IF UT4 DCB IS OPEN        41000019
         MVC   UT3DS1(D8),SYS3TTR RE-INIT PTR TO CURRENT UT3 TTR + TB   41100019
         MVC   DCBFDAD(D8),UT3FDAD SET DCB TO ADDR OF WHERE TO PUT DATA 41200019
RPT1     LA    R2,UT4DCB                                                41300019
         TM    DCBOFLGS,OPEN      IS UT4DCB OPEN                        41400019
         BCR   MS8,R5             IF NOT, RETURN TO CALLER              41500019
         MVC   UT4DS1(D8),SYS4TTR RE-INIT PTR TO CURRENT UT4 TTR + TB   41600019
         MVC   DCBFDAD(D8),UT4FDAD SET DCB TO ADDR OF WHERE TO PUT DATA 41700019
         BR    R5                 NOW RETURN TO CALLER                  41800019
*********************************************************************** 41900019
         SPACE 2                                                        42000019
*********************************************************************** 42100019
RCPY     EQU   *                  RE-COPY MERGED OUTPUT DIRECTORY FROM  42200019
*                   SYSUT4 TO OUTPUT DATA SET                           42300019
         ST    R5,SAV5            SAVE CALLER'S LINKREG                 42400019
         BAL   R5,RESOUT          RESET OUTDCB FOR RECOPYING OUTPUT DIR 42500019
         BAL   R5,RESUT34         RESET SYSUT3 AND SYSUT4 DCB'S         42600019
         TM    COMDCDSW,SELECTSC  WAS A SELECTIVE COPY DONE             42700019
         BZ    CMPUTECT           IF NOT, NEED TO COMPUTE WHERE TO SET  42800019
*                                 BCB FOR I/O USE                       42900019
         MVC   BCB(D4),SESTOP     SET UP TO USE ALL OF CORE HIGHER THAN 43000019
*                                 SETAB AS AN I/O BUFFER                43100019
BCBSET   EQU   *                                                        43200019
         XC    OUTDS1(D4),OUTDS1  SET TTRN TO ZEROES, FOR DIRECTORY     43300019
         MVC   OUTDS1+D4(D2),TRBALBUF  SET TRK BAL TO= TRK CAPACITY     43400019
         MVI   UT4SCTOR,X00       SET UT4 AND OUTPUT SECTOR      S20201 43420020
         MVI   OUTSCTOR,X00         VALUES TO 0 (USED ONLY IF    S20201 43440020
*                                   THEY ARE ON RPS DEVICES)     S20201 43460020
         NI    TAG,TAG5+TAG6                                            43500019
         OI    TAG,TAG1           INDIC WRT'G OUTPUT DIRECTORY TO OUTDS 43600019
         NI    STATUS,STAT7                                             43700019
         OI    STATUS,STAT3       INDIC READ'G DIRECTORY FROM UT4       43800019
         MVI   SENSE,X00                                                43900019
         MVI   FLG2,X00           RESET EOF-REACHED SWITCH              44000019
RWLOOP   MVC   READNEXT(D4),BCB   SET POINTER FOR IEBDRD                44100019
         L     R15,VIEBDRD                                              44200019
         BALR  R14,R15            GO TO READ SPILLED, MERGED OUTPUT     44300019
*                                 DIRECTORY FROM SYSUT4                 44400019
         MVC   WRTNEXT,BCB        SET POINTER FOR IEBDWR                44500019
         L     R15,VIEBVWS                                              44600019
         BALR  R14,R15            GO TO WRITE MERGED OUTPUT DIRECTORY   44700019
*                                 (WHICH WAS JUST READ FROM SYSUT4)     44800019
*                                 ONTO OUTPUT DATA SET.                 44900019
         TM    FLG2,RDEOF         WAS EOF READ/WRITTEN                  45000019
         BZ    RWLOOP             IF NOT, LOOP TO READ AND WRITE MORE   45100019
         LA    R2,UT4DCB                                                45200019
         MVC   DCBFDAD(D8),UT4FDAD RESET SYSUT4 DCBFDAD POINTER         45300019
         MVC   OUTDS1(D6),OUTPTTR  RESET OUTPUT TTRN AND TRBAL          45400019
         NI    FLG4,FF-ODALT      RESET INDICATOR - MERGED OUTPUT DI-   45500019
*                                 RECTORY IS NO LONGER ON SYSUT4        45600019
         CLC   FCT(D2),ZROS       WERE ANY CTLTAB ENTRIES BUILT FOR THE 45700019
*                                 CURRENT INPUT DATA SET JUST PROCESSED 45800019
         BNE   SOMEFD             IF SO, GO ON                          45900019
         MVI   FCT+D1,ONE         ELSE SET FCT TO FAKE OUT PRINTING OF  46000019
*                               NAMES OF MEMBERS 'JUST' COPIED          46100019
SOMEFD   EQU   *                                                        46200019
         L     R5,SAV5            RESTORE CALLER'S LINK REG             46300019
         BR    R5                 RETURN TO CALLER                      46400019
         SPACE 1                                                        46500019
CMPUTECT EQU   *                                                        46600019
         LA    R9,D10             LENGTH OF 1 CTLTAB ENTRY              46700019
         MH    R9,ENCT            MPLY BY NUMBER OF CTLTAB ENTRIES      46900019
         A     R9,CTAD            ADD LENGTH TO STARTING ADDR OF CTLTAB 47100019
         ST    R9,BCB             SET UP RESULTANT ADDR FOR START OF    47200019
*                                 I/O BUFFER FOR RE-COPY FROM SYSUT4    47300019
         B     BCBSET             GO SET UP TO RECOPY                   47400019
*********************************************************************** 47500019
         SPACE 2                                                        47600019
*********************************************************************** 47700019
RESOUT   LA    R2,OUTDCB          POINT TO OUTPUT DCB                   47800019
         TM    DCBOFLGS,OPEN      IS THE DCB OPEN                       47900019
         BCR   MS8,R5             NO- DONT RESET IT                     48000019
         L     R3,DCBDEBAD        POINT TO OUTPUT DCB'S DEB             48100019
         LA    R3,D0(R3)                                                48200019
         USING DXDEB,R3                                                 48300019
         XC    DCBFDAD(D8),DCBFDAD ZERO OUT CURRENT FDAD                48400019
         MVC   DCBFDAD+D1(D6),DXDEBBIN PUT IN BBCCHH OF OUTPUT DIRECT.  48500019
         DROP  R3                                                       48600019
         MVC   OUTDS1(D6),OUTPTTR SET TTRN AND TRACK BALANCE TO REFLECT 48700019
*                                 STATUS OF OUTPUT DATA SET AFTER LAST  48800019
*                                 DATA RECORD WAS WRITTEN.              48900019
         BR    R5                 EXIT TO CALLER                        49000019
*********************************************************************** 49100019
         SPACE 2                                                        49200019
*********************************************************************** 49300019
COUTDCB  LA    R2,OUTDCB          POINT TO OUTPUT DCB                   49400019
         TM    DCBOFLGS,OPEN      IS THE DCB OPEN                       49500019
         BCR   MS8,R5             IF NOT, IT HASN'T BEEN WRITTEN TO     49600019
         MVC   DCBFDAD(D8),OUTFDAD SET DCB TO POINT TO EOF OF DATA SET  49700019
         MVC   DCBTRBAL(D2),OUTPTTR+D4  SET TRKBAL INTO DCB FOR CLOSE   49800019
         MVC   DCBRELAD(D4),OUTPTTR    PUT LAST REC'S TTRN INTO DCB     49900019
CLODCB   OI    DCBOFLGS,LWR       INDIC LAST OPERATION WAS WRITE        50000019
         CLOSE ((R2))             CLOSE OUTPUT DATA SET                 50100019
         BR    R5                 RETURN TO CALLER                      50200019
CLODS    LA    R2,OUTDCB                                                50300019
         TM    DCBOFLGS,OPEN      IS THE DCB OPEN                       50400019
         BCR   MS8,R5             IF NOT, IT HASN'T BEEN WRITTEN TO     50500019
         MVC   DCBFDAD(D8),ERPLMFD POINT TO PREVIOUS VALID EOF FOR WHEN 50600019
*                                 DIRECTORY WAS WRITTEN TO THE OUTPUT   50700019
*                                 DATA SET                              50800019
         MVC   DCBTRBAL(D2),ERPTB  SET PREVIOUS VALID TRACK BALANCE     50900019
         MVC   DCBRELAD(D4),ERPTTR SET PREVIOUS VALID LASTREC TTRN      51000019
         B     CLODCB             GO SET OFLGS AND CLOSE DCB            51100019
*********************************************************************** 51200019
         SPACE 2                                                        51300019
*********************************************************************** 51400019
PRTMBRS  EQU   *                  PRINT NAMES OF MEMBERS COPIED TO THE  51500019
*                                 OUTPUT DATASET                        52100019
         TM    FLG7,SUPPRMSG      ARE MBRNAMES TO BE PRINTED            52800019
         BCR   MS1,R5             IF SO, DONT PRINT MEMBERS COPIED MSGS 52900019
         CLC   FCT(D2),ZROS       WERE ANY CTLTAB ENTRIES BUILT FOR THE 53000019
*                                 CURRENT INPUT DATA SET                53100019
         BCR   MS8,R5             IF NOT, DONT TRY TO PRINT MBRNAMES    53150019
         TM    COMDCDSW,LISTSW    WAS ''LIST = NO'' SPECIFIED           53203019
         BO    TJCM4              YES - DONT PRINT MESSAGE              53206019
         MVI   MSG1,LASTMSG+PBIT  INDIC LAST MSG AND USE PARAMETER LIST 53215019
         MVI   MSG1+D1,FOLLMCPD   MESSAGE CODE                          53224019
         MVI   PARAMS,NAME        INDIC NAME TO BE PUT INTO MESSAGE     53233019
         MVI   NAMEDISP,M61       OFFSET IN MSG TEXT FOR NAME           53242019
         L     R3,NXTINDS         POINT TO INDD SLOT                    53251019
         MVC   NAMEFLD(D8),D2(R3) PUT INDD NAME INTO PARAMETER LIST     53260019
         L     R15,VIEBVMS        ADDR OF MSG WRITER                    53270019
         BALR  R14,R15            LINK TO WRITE MSG                     53280019
TJCM4    EQU   *                                                        53290019
         L     R3,CTAD            ADDRESS OF CTLTAB                     53300019
TJC      TM    D1(R3),JSTCPD      WAS THIS MEMBER 'JUST NOW' COPIED     53400019
         BO    PUTIT              YES, GO WRT MSG AND RESET 'JSTCPD'    53500019
TSTBIT6  TM    D0(R3),SEBIT6      IS THIS THE LAST CTLTAB ENTRY         53600019
         BCR   MS1,R5             YES, EXIT TO CONTINUE PROCESSING      53700019
         LA    R3,D10(R3)         NO, POINT TO NEXT CTLTAB ENTRY        53800019
         B     TJC                GO TEST TO SEE IF MBRNAME TO PRINT    53900019
PUTIT    EQU   *                                                        54000019
         TM    IOEF2,SPRNOPN      IS SYSPRINT USABLE                    54100019
         BO    NONAMPRT           IF NOT, DONT BOTHER TO SET UP MSG     54200019
         TM    COMDCDSW,LISTSW    WAS ''LIST=NO'' SPECIFIED             54300019
         BO    NONAMPRT           YES - DONT LIST NAMES OF MBRS COPIED  54400019
         TM    D0(R3),SEBIT1      IS THIS A NEWNAME                     54500019
         BZ    REGMSG             NO, SET UP 'NORMAL' MSG CODE          54600019
         MVI   MSG1+D1,RNMEMCOP   YES, SET UP 'NEWNAME' MSG CODE        54700019
         B     SLP                BRANCH AROUND 'NORMAL' MSG CODE       54800019
REGMSG   MVI   MSG1+D1,MEMCOP     SET UP NORMAL (NOT NEWNAME) MSG       54900019
SLP      MVC   NAMEFLD(D8),D2(R3) MEMBERNAME TO IEBVMS PARAM AREA       55000019
         MVI   MSG1,LASTMSG+PBIT  SET INDICATORS FOR IEBVMS INTERFACE   55100019
         MVI   PARAMS,NAME                                              55200019
         MVI   NAMEDISP,X00       OFFSET IN MSG FOR NAME                55300019
         L     R15,VIEBVMS                                              55400019
         BALR  R14,R15            LINK TO PRINT MSG                     55500019
NONAMPRT NI    D1(R3),FF-JSTCPD   RESET NEED-TO-PRINT-NAME BIT          55600019
         B     TSTBIT6            SEE IF DONE WITH CTLTAB SCAN          55700019
*********************************************************************** 55800019
  SPACE 2                                                               55804019
*********************************************************************** 55808019
PS0      TM    COMDCDSW,SELECTSC  WAS A SELECTIVE COPY BEING DONE       55812019
         BCR   D8,R5              IF NOT,DONT LOOK FOR UN-FOUNDS        55816019
         L     R3,SEBEGIN         POINT TO START OF SETAB               55820019
PS1      TM    D0(R3),SEBIT1+SEBIT4+SEBIT5  WAS THIS MEMBER A NEWNAME   55824019
*                                 FOUND, OR FLAGGED AS DONT-COPY        55828019
         BC    D7,PS2             IF SO,SEE IF MORE TO BE TRIED         55832019
         MVI   NAMEDISP,D0        OFFSET IN MSG FOR NAME                55836019
         MVI MSG1,LASTMSG+PBIT  INDIC LAST MSG IN LIST + PARAMETER      55840019
         MVI   PARAMS,NAME        INDIC PARAMETER IS A NAME             55844019
         MVI   MSG1+D1,SMNF       SET UP MSG CODE                       55848019
         MVC   NAMEFLD(D8),D2(R3) PUT MBR NAME INTO PARAM LIST          55852019
         CLI   RCBUF,RTCD         IS RETURN CODE 4 OR HIGHER     A48762 55854022
         BNL   DONTSET            YES- DON'T SET                 A48762 55854422
         MVI   RCBUF,RTCD         SET RETURN CODE 4              A48762 55854822
DONTSET  EQU   *                                                 A48762 55855222
         L     R15,VIEBVMS                                              55856019
         BALR  R14,R15            WRT MBR SELECTED BUT NOT FOUND MSG    55860019
PS2      TM    D0(R3),SEBIT6      IS THIS THE LAST MBR NAME IN SETAB    55864019
         LA    R3,D10(R3)         BUMP PTR IN CASE NOT                  55868019
         BZ    PS1                LOOP IF NOT LAST NAME                 55872019
         BR    R5                 RETURN TO CALLER                      55876019
*********************************************************************** 55880019
         SPACE 2                                                        55900019
*********************************************************************** 56000019
PUDUT    EQU   *                  FORMAT AND PRINT UNUSED TRACKS & UN-  56100019
*                   USED DIRECTORY BLOCKS MESSAGES -                    56200019
         LA    R2,OUTDCB                                                56300019
         TM    DCBOFLGS,OPEN      IS THE OUTPUT DCB OPEN                56400019
         BCR   MS8,R5             IF NOT, CANT PRINT EITHER MESSAGE     56500019
         ST    R5,SAV5            ELSE SAVE CALLER'S LINK REG           56600019
         TM    IOEF2,SPRNOPN      IS SYSPRINT USABLE                    56700019
         BO    TMISSUED           IF NOT, DONT BOTHER TO SET UP MSG     56800019
* FORMAT MSG AS FOLLOWS-                                                56900019
* IEB574I XXX UNUSED TRACKS IN OUTPUT DATA SET REFERENCED BY (DDNAME)   57000019
* SET UP DDNAME AND NBR OF TRKS IN PARAMETER AREA FOR MSG WRITER        57100019
         L     R3,DCBDEBAD                                              57200019
         LA    R3,D0(R3)          POINT TO CORRESPONDING DEB            57300019
         USING DXDEB,R3                                                 57400019
         XR    R6,R6                   CLEAR WORK REGISTER              57500019
         IC    R6,DXDEBUSR             INSERT NUMBER OF EXTENTS         57600019
         BCTR  R6,R0              SUBTRACT ONE                          57700019
         STC   R6,DWORD2               STORE M OF LAST EXTENT           57800019
         SLL   R6,D4              MULTIPLY M BY 16                      57900019
         AR    R3,R6                   BUMP BASE REGISTER OF DEB TO     58000019
*                                        USE LAST EXTENT DESCRIPTION    58100019
*                                        WITH DSECT                     58200019
         MVC   DWORD2+D1(D2),DXDEBBIN  MOVE BIN NUMBER LAST EXTENT      58300019
         MVC   DWORD2+D3(D4),DXDEBECC  MOVE CCHH OF LAST TRACK          58400019
         MVI   DWORD2+D7,X00      SET  R=0                              58500019
         LA    R1,OUTDCB               POINTER TO DCB                   58600019
         BAL   R8,GETATTR              GET TTR                          58700019
         LH    R9,WKA1                 LOAD ENDING TT                   58800019
         MVC   DWORD2(D8),OUTFDAD  MOVE OUTFDAD FOR CONVERSION          58900019
         LA    R1,OUTDCB               POINTER TO DCB                   59000019
         BAL   R8,GETATTR              GET TTR                          59100019
         SH    R9,WKA1                 GET NUMBER OF UNUSED TRACKS      59200019
         CVD   R9,WKA1            MAKE THE RESULT PRINTABLE             59300019
         UNPK  WKA1+D8(D9),WKA1+D3(D5)                                  59400019
         OI    WKA1+D16,C0                                              59500019
         MVC   NOFLD(D7),WKA1+D10  PUT NBR OF TRKS IN MSG PARAM LIST    59600019
         MVC   NAMEFLD(D8),OUTNAME PUT OUTPUT DDNAME IN PARAMETER LIST  59700019
         MVI   PARAMS,NBR+NAME    INDICATE PRESENCE OF NUMBER AND NAME  59800019
*                                 TO IEBVMS (FOR INSERTION INTO MSG)    59900019
         MVI   NODISP,X0A         DISPLACEMENT IN MSG FOR NBR TRKS      60000019
         MVI   NAMEDISP,X41       DISPLACEMENT IN MSG FOR OUTDD NAME    60100019
         B     TRKSDONE           DONE                                  60200019
GETATTR  EQU   *                                                        60300019
         LA    R2,DWORD2               POINTER TO MBBCCHHR              60400019
         L     R15,VCCOTT              POINTER TO CCOTT                 60500019
         BALR  R14,R15                 GET TTR                          60600019
         BR    R8                      RETURN                           60700019
         SPACE                                                          60800019
TRKSDONE EQU   *                                                        60900019
         MVI   MSG1+D1,M49        MSG CODE - TRKS UNUSED                61000019
         MVI   MSG1,LASTMSG+PBIT                                        61100019
         L     R15,VIEBVMS                                              61200019
         BALR  R14,R15            LINK TO WRT MSG                       61300019
TMISSUED EQU   *                                                        61400019
         TM    FLG7,NOPRNBDB      NEED TO SUPPRESS THIS MSG             61700019
         BO    FM2                YES - DONT SET IT UP                  61800019
*              NOW FORMAT NEXT MESSAGE AS FOLLOWS -                     61900019
* IEB580I XXX UNUSED DIRECTORY BLOCKS IN OUTPUT DATA SET REFERENCED BY  62000019
* (DDNAME)                                                              62100019
*                                                                       62200019
         LH    R5,DIRBCNT         GET CT OF MAX POSSIBLE NBR OD BLKS    62300019
         LPR   R5,R5                                                    62400019
         LH    R6,DBCNT           ACTUAL NBR BLOCKS MERGED OUTPUT DIR   62500019
         LPR   R6,R6                                                    62600019
         SR    R5,R6              GET DIFFERENCE                        62700019
         TM    IOEF1,ERF5         DID AN I/O ERROR OCCUR WHILE WRITING  62800019
*                                 DIRECTORY TO OUTPUT DATA SET          62900019
         BO    NOBLKPRT           IF SO, DONT FORMAT OR PRINT MSG       63000019
         TM    IOEF2,SPRNOPN      IS SYSPRINT USABLE                    63100019
         BO    NOBLKPRT           IF NOT, DONT BOTHER TO SET UP MSG     63200019
         CVD   R5,WKA1                                                  63300019
         UNPK  WKA1+D8(D9),WKA1+D3(D5)                                  63400019
         OI    WKA1+D16,C0        MAKE NBR UNUSED BLOCKS PRINTABLE      63500019
         MVC   NOFLD(D7),WKA1+D10                                       63600019
         MVI   NODISP,X0A         DISPLACEMENT IN MSG FOR NBR BLKS      63700019
         MVI   PARAMS,NBR                                               63800019
         MVI   MSG1+D1,UNUSDDB    MSG CODE - DIRECTORY BLOCKS           63900019
         MVI   MSG1,LASTMSG+PBIT                                        64000019
         L     R15,VIEBVMS                                              64100019
         BALR  R14,R15            LINK TO WRT MSG                       64200019
NOBLKPRT EQU   *                                                        64300019
         LTR   R5,R5              WAS LAST OUTPUT DIRECTORY BLOCK WRIT- 64400019
*                                 TEN ON BY 'IEBVDM' ROUTINE            64500019
         BNZ   FM2                IF NOT, RETURN TO CALLER              64600019
DOFREE   EQU   *                                                        64640019
         LM    R1,R2,ADGOT        GET ADDR AND LENGTH OF ORIGINALLY     64680019
*                                 ACQUIRED CORE                         64760019
         S     R2,FREEAMT         SUBTRACT LENGTH INITIALLY FREED       64840019
         LR    R0,R2              PUT CORRECT LENGTH INTO PARAMETER REG 64920019
         FREEMAIN   R,LV=(0),A=(1) FREE ALL ACQUIRED CORE               65000019
         OI    VTMFLG1,NOMAIN     INDICATE FREEMAIN DONE                65080019
FM2      L     R5,SAV5            RESTORE CALLER'S LINK REG             65200019
         BR    R5                 RETURN TO CALLER                      65300019
PAMSETUP EQU   *                                                        65310019
         ST    R5,SAV5            SAVE RETURN REG                       65320019
         LH    R5,BPAMOUT+DIRCTDCB  LOAD COUNT OF BYTES USED IN         65330019
*                                     LAST DIRECTORY BLOCK              65340019
         LTR   R5,R5              HAS LAST BLOCK BEEN USED              65350019
         BZ    FM2                NO, RETURN                            65360019
         B     DOFREE             ISSUE FREEMAIN                        65370019
*********************************************************************** 65400019
         SPACE 2                                                        65500019
*********************************************************************** 65507019
PREDASD  EQU   *                                                 A36049 65507200
         TM    FLG4,REDASD        WAS INVALID NDBTR FOUND        A36049 65507400
         BCR   MS8,R5             NO, DON'T WRITE MSG            A36049 65507600
         TM    IOEF2,SPRNOPN      IS SYSPRINT USABLE             A36049 65507800
         BCR   MS1,R5             NO, DON'T WRITE MSG            A36049 65508000
         MVI   MSG1,LASTMSG+PBIT  INDIC LAST MSG AND USE PARAM   A36049 65508200
*                                 LIST                           A36049 65508400
         MVI   MSG1+D1,TMDBTR     MESSAGE CODE                   A36049 65508600
         MVI   PARAMS,NAME        INDIC NAME TO BE PUT INTO MSG  A36049 65508800
         MVI   NAMEDISP,O33       OFFSET IN MESSAGETEXT FOR NAME A36049 65509000
         MVC  NAMEFLD(D8),OUTNAME PUT OUTDD NAME INTO PARAM LIST A36049 65509122
         CLI   RCBUF,RTCD         IS RETURN CODE 4 OR HIGHER     A44144 65509222
         BNL   DONOTSET           YES- DON'T SET                 A44144 65509322
         MVI   RCBUF,RTCD         SET RETURN CODE 4              A44144 65509422
DONOTSET EQU   *                                                 A44144 65509522
         L     R15,VIEBVMS        ADDR OF MSG WRITER             A36049 65509622
         BALR  R14,R15            LINK TO WRITE MSG              A36049 65509722
         NI    FLG4,FF-REDASD     RESET INDIC TO WRITE WARNING   A36049 65509800
*                                  MESSAGE                       A36049 65510000
         BR    R5                 RETURN TO CALLER               A36049 65510200
*********************************************************************** 65510400
         SPACE 3                                                        65510600
*********************************************************************** 65510800
RESODS   EQU   *                  ROUTINE TO OPEN AND CLOSE BPAM        65512019
*                                   DCB WHEN THE LAST DIRECTORY         65517019
*                                   BLOCK HAS BEEN MODIFIED.  THIS      65522019
*                                   WILL UPDATE THE DSCB                65527019
         LA    R2,BPAMOUT         GET ADDR OF THE BPAM DCB              65535019
         ST    R5,SAV5            SAVE LINK REG                         65536019
         LH    R5,DCBDIRCT        SAVE COUNT OF BYTES USED IN LAST      65537019
*                                   DIRECTORY BLOCK                     65538019
         OPEN  ((R2),OUTPUT)                                            65542019
         MVI   DCBCIND2,PAMDIR    INDICATE THAT THE OUTPUT DIRECTORY    65549019
*                                 WAS MODIFIED                          65556019
         STH   R5,DCBDIRCT        RESTORE COUNT OF BYTES USED IN        65558019
*                                   LAST DIRECTORY BLOCK                65560019
         CLOSE ((R2))                                                   65563019
         L     R5,SAV5            RESTORE LINK REG                      65566019
         BR    R5                 RETURN TO THE CALLER                  65570019
*********************************************************************** 65577019
         SPACE 2                                                        65584019
*********************************************************************** 65600019
WEJFTM   MVI   MSG1+D1,M58        MSG CODE - ABNORMAL END               65700019
         MVI   MSG1,LASTMSG                                             65800019
         L     R15,VIEBVMS                                              65900019
         BALR  R14,R15            LINK TO WRT MSG                       66000019
EOJMS    MVI   MSG1+D1,M53        MSG CODE - EOJ MSG                    66100019
* FORMAT MSG AS FOLLOWS -                                               66200019
* IEB147I END OF JOB - X WAS HIGHEST COMPLETION CODE                    66300019
         MVI   MSG1,LASTMSG+RCODE                                       66400019
         L     R15,VIEBVMS                                              66500019
         BALR  R14,R15            GO WRT EOJ MSG                        66600019
         SR    R7,R7              INDICATE NO FREEPOOL NEEDED    A48806 66650022
         LA    R2,UT3DCB          POINT TO SYSUT3 DCB                   66900019
         BAL   R3,CLOSE           GO CLOSE IT IF ITS OPEN               67000019
         LA    R2,UT4DCB          POINT TO SYSUT4 DCB                   67100019
         BAL   R3,CLOSE           GO CLOSE IT IF ITS OPEN               67200019
         LA    R2,OUTDCB          POINT TO OUTPUT DCB                   67300019
         BAL   R3,CLOSE           GO CLOSE IT IF ITS OPEN               67400019
         LA    R2,PRTDCB          POINT TO SYSPRINT DCB                 67500019
         BCTR  R7,R0              INDICATE FREEPOOL TO BE DONE   A48806 67550022
         BAL   R3,CLOSE           GO CLOSE IT IF ITS OPEN               67600019
         LA    R2,CARDCB          POINT TO SYSIN DCB                    67700019
         BAL   R3,CLOSE           GO CLOSE IT IF ITS OPEN               67800019
         DELETE  EP=IGG019C8   THE I/O-APPENDAGE WAS PREMOUNTED  A37881 67850021
         TM    VTMFLG1,NOMAIN     NEED TO INHIBIT FREEMAIN              68000019
         BO    NOFREE             YES - DONT EXECUTE FREEMAIN SEQUENCE  68100019
         LM    R1,R2,ADGOT        GET ADDR AND LENGTH OF ORIGINALLY     68200019
*                                 ACQUIRED CORE                         68300019
         S     R2,FREEAMT         SUBTRACT LENGTH INITIALLY FREED       68400019
         LR    R0,R2              PUT CORRECT LENGTH INTO PARAMETER REG 68500019
         FREEMAIN   R,LV=(0),A=(1) FREE ALL ACQUIRED CORE               68600019
         SPACE                                                          68700019
NOFREE   EQU   *                                                        68800019
         SR    R15,R15            CLEAR RETURN CODE REGISTER            68900019
         NI    RCBUF,X0F          TURN OFF HIGH ORDER RETURN CODE BITS  69000019
         IC    R15,RCBUF          SET UP RETURN CODE                    69100019
*                   THE FOLLOWING CODE RE-INITIALIZES THE COMMUNICATION 69200019
*                   AREA FOR RE-USE IN CASE THIS PROGRAM IS RE-INVOKED  69300019
*                   WITHOUT BEING RELOADED INTO CORE -                  69400019
         XC    BCB(EOREAD+D4-BCB),BCB                                   69500019
         XC    ADNL(OUTNAME+D8-ADNL),ADNL                               69600019
         XC    WKA1(SV1-WKA1),WKA1                                      69700019
         XC    OUTPTTR(INIDDCTS+D2-OUTPTTR),OUTPTTR              S20201 69800020
         XC    FLG3(NOFLD+D7-FLG3),FLG3                                 69900019
         MVI   LINECT,X00                                               70000019
         MVC   DDLIST(D48),DDLRFRSH RESET DDLIST IN CASE RE-INVOKED     70100019
         MVC   PGNO(D4),PGRFRSH   RESET PAGE NUMBER IN CASE RE-INVOKED  70200019
         MVI   RCBUF,RCRFRSH      RESET RETURN CODE IN CASE RE-INVOKED  70300019
         LA    R13,SV1            POINT TO PRIMARY SAVE AREA            70400019
         L     R13,D4(R13)                                              70500019
         RETURN (14,12),RC=(15)   RETURN TO INVOKER                     70600019
         SPACE 1                                                        70700019
CLOSE    TM    DCBOFLGS,OPEN      IS THIS DCB OPEN                      70800019
         BCR   MS8,R3             IF NOT, DONT CLOSE IT                 70900019
         CLOSE ((R2))             CLOSE THE OPEN DATA SET               71000019
         LTR   R7,R7              FREEPOOL TO BE DONE            A48806 71050022
         BCR   MS8,R3             NO,  EXIT TO CALLER            A48806 71060022
         FREEPOOL (R2)            YES, FREE BUFFER POOL          A48806 71070022
         BR    R3                 EXIT TO NSI OR TO CALLER              71100019
*********************************************************************** 71200019
         SPACE 2                                                        71300019
*********************************************************************** 71400019
SLOCOR   EQU   *                                                        71500019
         MVC   LOCOR(D4),SVLO     RESET POINTER TO LOWEST USABLE CORE   71580019
         MVI   FLG7,X00           RESET THIS SWITCH                     71660019
         NI    COMDCDSW,FF-COMPRESS RESET POSSIBLY-ON COMPRESS SWITCH   71750019
         XC    FCT(D2),FCT        RESET COUNT OF NBR OF CTLTAB ENTRIES  71820019
         LM    R11,R14,RESET1     RESTORE CRITICAL REGS                 71900019
         L     R15,VIEBMNI        ADDR OF ENTRY PT IN MAINFLOW          72000019
         BR    R15                EXIT                                  72100019
*********************************************************************** 72200019
         SPACE 2                                                        72300019
*********************************************************************** 72400019
RMISC    L     R5,SVHI            RE-INIT SEVERAL POINTERS IN IEBMCA    72500019
         ST    R5,HICOR                                                 72600019
         ST    R5,END2ND2                                               72700019
         L     R5,ADWK                                                  72800019
         LA    R5,WKLEN(R5)                                             72900019
         ST    R5,LOCOR                                                 73000019
         ST    R5,INBEGIN                                               73100019
         ST    R5,NXTINDS                                               73200019
         MVI   FLG7,X00           RESET THIS SWITCH                     73270019
         NI    COMDCDSW,FF-COMPRESS RESET POSSIBLY-ON COMPRESS SWITCH   73350019
         XC    FCT(D2),FCT        RESET COUNT OF NBR OF CTLTAB ENTRIES  73420019
         LM    R11,R14,RESET1     RESET CRITICAL REGS                   73500019
         TM    VTMFLG1,NOMAIN     WAS IT NECESSARY FOR CORE TO BE FREED 73510019
         BZ    CLRVTM             NO, DONT SET TO DO ANOTHER GETMAIN    73520019
         XC    VTMFLG1(D2),VTMFLG1 RESET VTMFLG1 AND IOEF1              73530019
         BAL   R5,RESODS          NOW LINK TO SET UP BPAM DCB           73540019
         L     R15,VIEBGME        ADDR OF E.P. TO RE-ISSUE GETMAIN      73550019
         BR    R15                EXIT TO MAIN PROGRAM                  73560019
CLRVTM   XC    VTMFLG1(D2),VTMFLG1 RESET VTMFLG1 AND IOEF1              73580019
         L     R15,VIEBSCX        ADDR OF CTL-CD SCAN MODULE LINKAGE    73600019
         BR    R15                EXIT TO MAINFLOW TO GO TO IEBSCN      73700019
*********************************************************************** 73800019
         SPACE 2                                                        73900019
*********************************************************************** 74000019
DDLRFRSH DC    CL8'SYSIN   '      DDNAMES USED TO REFRESH LIST IN MCA   74100019
         DC    CL8'SYSPRINT'                                            74200019
         DC    CL8'SYSUT1  '                                            74300019
         DC    CL8'SYSUT2  '                                            74400019
         DC    CL8'SYSUT3  '                                            74500019
         DC    CL8'SYSUT4  '                                            74600019
PGRFRSH  DC    C'0001'            TO REFRESH PAGE NO. IN IEBMCA         74700019
RSA      DC    18F'0'             REGISTER SAVE AREA                    74800019
SAV5     DC    F'0'               INTERNAL SAVE AREA FOR LINKREG        74900019
PTCHLEN  EQU   (*-IEBVTM)/20      LENGTH OF 5 PER CENT PATCH AREA       75000019
PATCH    DC    XL(PTCHLEN)'00'    5 PER CENT PATCH AREA          A41780 75100021
         EJECT                                                          75200019
IEBMCA   DSECT                                                          75300019
         IEBMCA                                                         75400019
         EJECT                                                          75500019
         DCBD  DSORG=PO                                                 75600019
DIRCTDCB EQU   DCBDIRCT-IHADCB    OFFSET IN DCB TO COUNT                75630019
*                                   OF BYTES USED IN LAST DIR BLOCK     75660019
IECDSECT DSECT                                                          75700019
         IECDSECT                                                       75800019
DWORD2   EQU   WKA1+8                  WORK AREA                        75900019
         END                                                            76000019
         EJECT                                                          86700019
IEBMCA   DSECT                                                          87000019
         IEBMCA                                                         87300019
         EJECT                                                          87600019
         DCBD  DSORG=PO                                                 87900019
IECDSECT DSECT                                                          88200019
         IECDSECT                                                       88500019
DWORD2   EQU   WKA1+8                  WORK AREA                        88800019
         END                                                            89100019
