         TITLE 'IEHATLAS - UTILITY'                              S20201 00080020
         COPY  LCGASMSW                                                 00160003
IEHATLAS CSECT                                                          00210003
*                                                                       00240020
*                                                                       00320020
*          RELEASE 22 DELETIONS/CHANGES                                 00400020
*          RELEASE 21 DELETIONS/CHANGES                                 00480020
*485300,941300                                                OX02345   00530003
*          RELEASE 20 DELETIONS/CHANGES                                 00560020
*0700000800-001600,590400                                        S20201 00600020
*                                                                       00640020
*STATUS CHANGE LEVEL 002                                                00720020
*                                                                       00800020
*        TITLE 'IEHATLAS-UTILITY'                                       00880020
*FUNCTION/OPERATION                                                   * 00960020
*    THIS MODULE IS THE UTILITY PORTION OF THE PROGRAM IEHATLAS, THE  * 01040020
*SYSTEM UTILITY THAT ATTEMPTS RECOVERY FROM HARD READ/WRITE ERRORS.   * 01120020
*UPON ENTRY IT ESTABLISHES ITS OWN ADDRESSABILITY AND THAT OF THE     * 01200020
*WORK AREA WHICH IT GETS.  ITS MAIN FUNCTIONS ARE THE FOLLOWING-      * 01280020
*                                                                     * 01360020
*    1.  TO GET DDNAMES AND PAGE NUMBER PARAMETERS IF THE             * 01440020
*        UTILITY IS INVOKED.                                          * 01520020
*    2.  TO CHECK DCB PARAMETERS OF SYSIN AND SYSPRINT FOR            * 01600020
*        BLOCKSIZE A MULTIPLE OF LRECL                                * 01680020
*    3.  TO GET A CONTROL CARD AND CHECK FOR VALIDITY                 * 01760020
*    4.  TO GET CORE FOR THE INPUT RECORD, GET THE RECORD, AND        * 01840020
*        PRINT IT ON THE MESSAGE DATA SET                             * 01920020
*    5.  TO EXECUTE THE CHANNEL PROGRAM WHICH IT BUILDS IN AN         * 02000020
*        ATTEMPT TO WRITE THE RECORD WHERE THE ERROR OCCURRED         * 02080020
*    6.  TO INSURE AN ERROR ACTUALLY EXISTS IF THE INPUT RECORD       * 02160020
*        IS THE VTOC BY ATTEMPTING TO READ THE ERROR RECORD           * 02240020
*    7.  TO GIVE CONTROL TO THE SVC IF AN ALTERNATE TRACK             * 02320020
*        MUST BE ASSIGNED                                             * 02400020
*    8,  TO PRINT DIAGNOSTIC MESSAGES INDICATING RESULTS OF           * 02480020
*        EXECUTION                                                    * 02560020
*                                                                     * 02640020
*ENTRY POINTS                                                         * 02720020
*    IEHATLAS - ATTEMPTS RECOVERY FROM A HARD READ/WRITE ERROR.       * 02800020
*                                                                     * 02880020
*INPUT                                                                * 02960020
*    CONSISTS OF THE FOLLOWING-                                       * 03040020
*                                                                     * 03120020
*    1.  A PARAMETER LIST INCLUDING DDNAME-OVERRIDES AND PAGE         * 03200020
*        NUMBER (REGISTER 1 CONTAINS A POINTER TO THE ADDRESSES       * 03280020
*        OF THE PARAMETERS)                                           * 03360020
*    2.  CONTROL INFORMATION SPECIFYING TYPE OF RECORD TO BE          * 03440020
*        REPLACED (VTOC OR TRACK), THE LOCATION OF THE RECORD         * 03520020
*        ON THE DEIVCE, THE LENGTH OF THE RECORD, AND AN              * 03600020
*        INDICATION IF WRITE SPECIAL IS REQUIRED                      * 03680020
*    3.  THE RECORD IN HEXADECIMAL                                    * 03760020
*    4.  RETURN CODES FROM THE SVC --                                 * 03840020
*          0 - SUCCESS                                                * 03920020
*          4 - WRONG DEVICE TYPES                                     * 04000020
*          8 - NO MORE ALTERNATES                                     * 04080020
*         12 - CORE NOT AVAILABLE                                     * 04160020
*         16 - I/O ERROR IN ALTERNATE TRACK ASSIGNMENT                * 04240020
*         20 - INVALID I/O SENSE INDICATION                           * 04320020
*         24 - FORMAT 4 IN ERROR                                      * 04400020
*         28 - USER'S RECORD IS FORMAT 4                              * 04480020
*         32 - ERROR IN COUNT FIELD OF LAST RECORD ON TRACK           * 04560020
*         36 - R0-HOME ADDRESS ERRORS                                 * 04640020
*         40 - -ERROR/ERRORS ENCOUNTERED BUT AN ALTERNATE HAS         * 04720020
*              BEEN ASSIGNED                                          * 04800020
*         44 - ERROR/ERRORS ENCOUNTERED  NO ALTERNATE ASSIGNED        * 04880020
*         48 - NO ERRORS FOUND, NO ALTERNATE ASSIGNED                 * 04960020
*         52 - CAN NOT RE-EXECUTE CALLER'S CHANNEL PROGRAM            * 05040020
*         56 - SYSTEM DOES NOT SUPPORT TRACK OVERFLOW                 * 05120020
*         60 - TRACK ADDRESS PROVIDED DOES NOT BELONG TO DATASET      * 05200020
*                                                                     * 05280020
*OUTPUT                                                               * 05360020
*    CONSISTS OF THE FOLLOWING-                                       * 05440020
*                                                                     * 05520020
*    1.  A MESSAGE DATA SET INCLUDING THE CONTROL INFORMATION         * 05600020
*        SUPPLIED BY THE USER, THE INPUT RECORD, AND DIAGNOSTICS      * 05680020
*    2.  UPDATED PAGE NUMBER                                          * 05760020
*    3.  CORRECT FORM OF RECORD IN ERROR EITHER ON THE ORIGINAL       * 05840020
*        TRACK OR ON AN ALTERNATE TRACK                               * 05920020
*                                                                     * 06000020
*EXTERNAL ROUTINES                                                    * 06080020
*    SVC 86 ASSIGNS AN ALTERNATE TRACK, TRANSFERS DATA FROM THE BAD   * 06160020
*TRACK, RE-EXECUTES THE CHANNEL PROGRAM TO WRITE THE CORRECTED RECORD,* 06240020
*AND UPDATES THE FORMAT4 DSCB.  A TWO-WORD PARAMETER LIST INCLUDING   * 06320020
*THE ADDRESSES OF THE IOB AND THE COUNT ARE POINTED TO BY REGISTER 1  * 06400020
*WHEN THE SVC IS INVOKED  A ONE WORD PARAMETER LIST IS RETURNED WHICH * 06480020
*INDICATES THE RECORD NUMBERS OF A MAXIMUM OF THREE ERROR RECORDS IF  * 06560020
*AN UNRECOVERABLE CONDITION OCCURS IN ASSIGNING AN ALTERNATE          * 06640020
*                                                                     * 06720020
*EXITS                                                                * 06800020
*    RETURNS CONTROL TO THE CALLING PROGRAM                           * 06880020
*                                                                     * 06960020
*TABLES/WORK AREAS                                                    * 07040020
*    A GETMAIN IS ISSUED FOR THE SIZE OF THE INPUT RECORD AND ANOTHER * 07120020
*FOR A WORK AREA OF 1300 BYTES.  THE WORK AREA PROVIDES SPACE FOR     * 07200020
*BUILDING THE CHANNEL PROGRAM, MESSAGES, COUNT FIELDS, DCB'S, AND     * 07280020
*LIST FORMS OF THE MACROS.                                            * 07360020
*                                                                     * 07440020
*ATTRIBUTES                                                           * 07520020
*    REENTRANT, REFRESHABLE                                           * 07600020
*********************************************************************** 07680020
*        EQUATES                                                     *  07760020
*********************************************************************** 07840020
TBIT1    EQU   X'40'                    *                               07920020
TBIT2    EQU   X'20'                    *                               08000020
TBIT3    EQU   X'10'                    *                               08080020
TBIT5    EQU   X'04'                    *                               08160020
TBIT6    EQU   X'02'                    *                               08240020
TBIT7    EQU   X'01'                    *                               08320020
BITS67   EQU   X'03'                    *                               08400020
ALLBITS  EQU   X'FF'                    *                               08480020
ATLASSVC EQU   86                       ATLAS SVC NUMBER         S20201 08520020
*********************************************************************** 08560020
*        CONSTANTS                                                   *  08640020
*********************************************************************** 08720020
C00      EQU   X'00'                    *                               08800020
C03      EQU   X'03'                    *                               08880020
C0D      EQU   X'0D'                    *                               08960020
C16      EQU   X'10'                    *                               09040020
C28      EQU   X'28'                    *                               09120020
C30      EQU   X'30'                    *                               09200020
C40      EQU   X'40'                    *                               09280020
C41      EQU   X'41'                    *                               09360020
C42      EQU   X'42'                    *                               09440020
C80      EQU   X'80'                    *                               09520020
DBLZERO  EQU   X'00'                    *                               09600020
DUMMY    EQU   X'10'                    *                               09680020
OHFOUR   EQU   X'04'                    *                               09760020
ZEROFOX  EQU   X'0F'                    *                               09840020
ELEVEN   EQU   X'11'                    *                               09920020
TWENTY   EQU   X'20'                    *                               10000020
EIGHTY   EQU   X'80'                    *                               10080020
EIGHTY7  EQU   X'87'                    *                               10160020
FOXZERO  EQU   X'F0'                    *                               10240020
SKIPAGE  EQU   X'F1'                    *                               10320020
BLANK    EQU   C' '                     *                               10400020
PRINTERR EQU   C'R'                     *                               10480020
SPECIALW EQU   C'S'                     *                               10560020
EQUALS   EQU   C'='                     *                               10640020
SLASH    EQU   C'/'                     *                               10720020
X0       EQU   0                        *                               10800020
*********************************************************************** 10880020
*        CONDITION CODE EQUATES                                       * 10960020
*********************************************************************** 11040020
CC00     EQU   X'00'                    *                               11120020
CC16     EQU   X'10'                    *                               11200020
*********************************************************************** 11280020
*        DISPLACEMENT CONSTANTS                                      *  11360020
*********************************************************************** 11440020
D0       EQU   0                        *                               11520020
D1       EQU   1                        *                               11600020
D2       EQU   2                        *                               11680020
D3       EQU   3                        *                               11760020
D4       EQU   4                        *                               11840020
D6       EQU   6                        *                               11920020
D7       EQU   7                        *                               12000020
D8       EQU   8                        *                               12080020
D12      EQU   12                       *                               12160020
D14      EQU   14                       *                               12240020
D26      EQU   26                       *                               12320020
D34      EQU   34                       *                               12400020
D42      EQU   42                       *                               12480020
D49      EQU   49                       *                               12560020
D58      EQU   58                       *                               12640020
D75      EQU   75                       *                               12720020
*********************************************************************** 12800020
*        FULLWORD AND HALFWORD EQUATES                                * 12880020
*********************************************************************** 12960020
FW1      EQU   1                        *                               13040020
FW2      EQU   2                        *                               13120020
FW3      EQU   3                        *                               13200020
FW10     EQU   10                       *                               13280020
FW18     EQU   18                       *                               13360020
FW19     EQU   19                       *                               13440020
FW29     EQU   29                       *                               13520020
FW59     EQU   59                       *                               13600020
*********************************************************************** 13680020
*        LENGTH CONSTANTS                                            *  13760020
*********************************************************************** 13840020
L1       EQU   1                        *                               13920020
L2       EQU   2                        *                               14000020
L3       EQU   3                        *                               14080020
L4       EQU   4                        *                               14160020
L5       EQU   5                        *                               14240020
L6       EQU   6                        *                               14320020
L7       EQU   7                        *                               14400020
L8       EQU   8                        *                               14480020
L9       EQU   9                        *                               14560020
L12      EQU   12                       *                               14640020
L13      EQU   13                       *                               14720020
L16      EQU   16                       *                               14800020
L20      EQU   20                       *                               14880020
L24      EQU   24                       *                               14960020
L26      EQU   26                       *                               15040020
L36      EQU   36                       *                               15120020
L40      EQU   40                       *                               15200020
L43      EQU   43                       *                               15280020
L44      EQU   44                       *                               15360020
L48      EQU   48                       *                               15440020
L53      EQU   53                       *                               15520020
L76      EQU   76                       *                               15600020
L79      EQU   79                       *                               15680020
L80      EQU   80                       *                               15760020
L117     EQU   117                      *                               15840020
L118     EQU   118                      *                               15920020
L119     EQU   119                      *                               16000020
L120     EQU   120                      *                               16080020
L255     EQU   255                      *                               16160020
*********************************************************************** 16240020
*        MESSAGE CODES                                               *  16320020
*********************************************************************** 16400020
MC00     EQU   X'00'                    *                               16480020
MC01     EQU   X'01'                    *                               16560020
MC02     EQU   X'02'                    *                               16640020
MC03     EQU   X'03'                    *                               16720020
MC04     EQU   X'04'                    *                               16800020
MC05     EQU   X'05'                    *                               16880020
MC06     EQU   X'06'                    *                               16960020
MC07     EQU   X'07'                    *                               17040020
MC08     EQU   X'08'                    *                               17120020
MC09     EQU   X'09'                    *                               17200020
MC0A     EQU   X'0A'                    *                               17280020
MC0B     EQU   X'0B'                    *                               17360020
MC0C     EQU   X'0C'                    *                               17440020
MC0D     EQU   X'0D'                    *                               17520020
MC0E     EQU   X'0E'                    *                               17600020
MC0F     EQU   X'0F'                    *                               17680020
MC10     EQU   X'10'                    *                               17760020
MC11     EQU   X'11'                    *                               17840020
MC12     EQU   X'12'                    *                               17920020
MC13     EQU   X'13'                    *                               18000020
MC14     EQU   X'14'                    *                               18080020
MC15     EQU   X'15'                    *                               18160020
MC16     EQU   X'16'                    *                               18240020
MC17     EQU   X'17'                    *                               18320020
*********************************************************************** 18400020
*        SWITCH EQUATES                                               * 18480020
*********************************************************************** 18560020
SW3      EQU   X'10'                    *                               18640020
SW4      EQU   X'08'                    *                               18720020
SW7      EQU   X'01'                    *                               18800020
*                                                                     * 18880020
*REGISTER ASSIGNMENTS                                                   18960020
PARMA    EQU   0                        PARAMETER REGISTER ZERO         19040020
PARMB    EQU   1                        PARAMETER REGISTER ONE          19120020
WORKE    EQU   2                        EVEN WORK REGISTER              19200020
WORKO    EQU   3                        ODD WORK REGISTER               19280020
FOUR     EQU   4                        WORK REGISTERS                  19360020
FIVE     EQU   5                        *                               19440020
SIX      EQU   6                        *                               19520020
SEVEN    EQU   7                        *                               19600020
EIGHT    EQU   8                        *                               19680020
NINE     EQU   9                        *                               19760020
TEN      EQU   10                       *                               19840020
AREAREG  EQU   11                       WORKAREA POINTER                19920020
BASEREG  EQU   12                       BASE REGISTER                   20000020
SAVEREG  EQU   13                       SAVE AREA POINTER               20080020
RETREG   EQU   14                       RETURN REGISTER                 20160020
ADDREG   EQU   15                       ADDRESSABILITY REGISTER AND     20240020
*                                          RETURN CODE REGISTER         20320020
         EJECT                                                          20400020
*STANDARD LINKAGE CONVENTION                                            20480020
         SAVE  (14,12),T,--A-68-V1      SAVE CALLING PROGRAM'S REG'S    20560020
         USING IEHATLAS,BASEREG         ESTABLISH ADDRESSABILITY        20640020
         LR    BASEREG,ADDREG                                           20720020
         EXTRN MESSTBL                                                  20800020
* PRIMARY WORK AREA WILL CONTAIN DCB'S,IOB,ECB,CHANNEL PROGRAM,         20880020
* MESSAGE AREA AND SWITCHES                                             20960020
         LR    FOUR,PARMB                                               21040020
         GETMAIN R,LV=1300                                              21120020
* CLEAR THE ENTIRE WORKAREA TO ZEROS                                    21200020
         LR    AREAREG,PARMB            SET UP ADDRESSABILITY TO THE    21280020
         USING IEHWORK,AREAREG             WORK AREA                    21360020
         MVI   SAVE1,DBLZERO            ZERO PROPAGATION OF SAVE AREA   21440020
         MVC   SAVE110(L255),SAVE10     *                               21520020
         MVC   SAVE111(L255),SAVE11     *                               21600020
         MVC   SAVE112(L255),SAVE12     *                               21680020
         MVC   SAVE113(L255),SAVE13     *                               21760020
         MVC   SAVE114(L255),SAVE14     *                               21840020
         MVC   SAVE115(L24),SAVE15      *                               21920020
         ST    SAVEREG,SAVE1BK          CHAIN SAVE AREA TO NEW SAVE     22000020
         LR    SAVEREG,AREAREG             AREA                         22080020
         MVI   HEADER,BLANK             CLEAR HEADING TO BLANKS         22160020
         MVC   HEADER1(L119),HEADER                                     22240020
         MVI   MESSAGE,BLANK            SET MESSAGE AREA TO BLANKS      22320020
         MVC   MESSAGE1(L119),MESSAGE                                   22400020
* INVOCATION                                                            22480020
         CLI   D0(FOUR),C80             WAS UTILITY INVOKED BY PROBLEM  22560020
*                                          PROGRAM                      22640020
         BE    SETDCBS                  NO, PREPARE DCB'S               22720020
* PICK UP DDNAMES IF USER SUPPLIES THEM                                 22800020
         L     FIVE,D4(X0,FOUR)         LOAD SECOND PARAMETER           22880020
         CLI   D0(FIVE),C00             IS DDNAME LIST LONG ENOUGH TO   22960020
*                                          INCLUDE SYSUT1 DDNAME        23040020
         BNE   CHKALL                   YES, CHECK FOR NAMES            23120020
         CLI   D1(FIVE),C40             LIST LONG ENOUGH TO INCLUDE     23200020
*                                          SYSUT1 DDNAME                23280020
         BL    CHK2                     NO, TEST FOR OTHERS             23360020
         SPACE                                                          23440020
CHKALL   OC    D58(L8,FIVE),D58(FIVE)   IS SYSUT1 DDNAME GIVEN          23520020
         BZ    CHKPRT                   NO                              23600020
         MVC   SYSUT1DD(L8),D58(FIVE)   YES, SAVE IN WORK AREA          23680020
         SPACE                                                          23760020
CHKPRT   OC    D42(L8,FIVE),D42(FIVE)   IS SYSPRINT DDNAME GIVEN        23840020
         BZ    CHKIN                    NO                              23920020
         MVC   PRINTDD(L8),D42(FIVE)    YES,SAVE IN WORK AREA           24000020
         SPACE                                                          24080020
CHKIN    OC    D34(L8,FIVE),D34(FIVE)   IS SYSIN DDNAME GIVEN           24160020
         BZ    CHKFLG                   NO                              24240020
         MVC   SYSINDD(L8),D34(FIVE)    YES, SAVE IN WORK AREA          24320020
         SPACE                                                          24400020
CHKFLG   CLI   D4(FOUR),C80             WAS DDNAME THE LAST PARAMETER   24480020
         BE    SETDCBS                  YES, PREPARE DCB'S              24560020
         B     GETPG                    CHECK PAGE PARAMETER            24640020
         SPACE                                                          24720020
CHK2     CLI   D1(FIVE),C30             IS LIST LONG ENOUGH TO INCLUDE  24800020
*                                          SYSPRINT                     24880020
         BNL   CHKPRT                   YES                             24960020
         CLI   D1(FIVE),C28             IS LIST LONG ENOUGH TO INCLUDE  25040020
*                                          SYSIN                        25120020
         BNL   CHKIN                    YES                             25200020
         B     CHKFLG                   CHECK FOR PAGE PARAMETER        25280020
         SPACE                                                          25360020
* DETERMINE PAGE NUMBER                                                 25440020
GETPG    L     FIVE,D8(X0,FOUR)         LOAD PAGE NUMBER ADDRESS        25520020
         ST    FIVE,SAVEPAR             SAVE ADDRESS                    25600020
         OC    D0(L2,FIVE),D0(FIVE)     IS PAGE NUMBER GIVEN            25680020
         BZ    SETDCBS                  NO,PREPARE DCB'S                25760020
         SPACE                                                          25840020
* THIS SECTION MOVES THE PAGE NUMBER TO THE WORK AREA AND CONVERTS      25920020
* IT TO HEXADECIMAL                                                     26000020
         XC    DOUBLE(L8),DOUBLE        CLEAR WORK AREA                 26080020
         MVC   CONVERT(L4),D2(FIVE)     MOVE PAGE NO TO WORK AREA       26160020
         PACK  DOUBLE5(L3),CONVERT(L4)  CONVERT PAGE NO TO BINARY       26240020
         SR    SIX,SIX                                                  26320020
         CVB   SIX,DOUBLE                                               26400020
         BCTR  SIX,X0                   DECREMENT BY ONE                26480020
         ST    SIX,PAGENO               STORE CONVERTED PAGE NUMBER     26560020
         SPACE                                                          26640020
* PREPARE DCB'S AND OPEN MACRO                                          26720020
SETDCBS  MVC   REENTAR(CLOSELS-OPENLS),OPENLS   MOVE L FORM TO WORKAREA 26800020
         MVC   DCBSYP(DCBXLST-DCBPRINT),DCBPRINT  MOVE DCB TO WKAREA    26880020
         LA    EIGHT,DCBSYP             ESTABLISH DCB ADDRESSABILITY    26960020
         USING IHADCB,EIGHT                                             27040020
         OC    PRINTDD(L8),PRINTDD      WAS SYSPRINT DDNAME             27120020
*                                          USER SUPPLIED                27200020
         BZ    OPENPRNT                 *                               27280020
         MVC   DCBDDNAM(L8),PRINTDD     MOVE DDNAME TO DCB              27360020
OPENPRNT OPEN  ((8),OUTPUT),MF=(E,REENTAR)                              27440020
         TM    DCBOFLGS,TBIT3           WAS OPEN SUCCESSFUL FOR         27520020
*                                          SYSPRINT                     27600020
         BO    TESTUT1                  YES, SUCCESSFUL OPEN            27680020
         MVI   COMPCODE,CC16            SET COMPLETION CODE TO 16       27760020
         B     ENDEXIT                  BRANCH TO EXIT ROUTINE          27840020
TESTUT1  TM    COMPCODE,ALLBITS         CHECK FOR ERROR IN DCB EXIT     27920020
         BM    WRAPUP                   YES, ERROR FOUND                28000020
         SPACE                                                          28080020
*THIS SECTION PUTS OUT A HEADING WITH UTILITY NAME, DATE, AND PAGE      28160020
*NUMBER                                                                 28240020
         MVI   HEADERC,SKIPAGE          SET TO SKIP TO A NEW PAGE       28320020
         MVC   HEADER(L8),UTNAME        MOVE IN UTILITY NAME            28400020
         MVC   HEADR105(L4),PAGEEQ      MOVE IN PAGE NUMBER             28480020
DA000    TIME                                                           28560020
         LR    PARMA,PARMB              PICK UP DATE                    28640020
         SRDL  PARMA,L16                SEPARATE YEARS AND DAYS         28720020
         SRL   PARMB,L16                PUT DAYS LOW ORDER              28800020
         LR    FOUR,PARMA               SAVE YEAR                       28880020
         SR    PARMA,PARMA              CLEAR REGISTER                  28960020
         LA    WORKO,FW19               DOES YEAR(IN DECIMAL) HAVE AN   29040020
         NR    WORKO,FOUR                  EVEN FIRST DIGIT AND A       29120020
*                                          SECOND DIGIT OF 0, 4, OR 8   29200020
         BZ    DA010                    YES, LEAP YEAR                  29280020
         LA    WORKE,FW18               DOES YEAR(IN DECIMAL) HAVE AN   29360020
         XR    WORKO,WORKE                 ODD FIRST DIGIT AND A SECOND 29440020
*                                          DIGIT OF 2, OR 6             29520020
         BZ    DA010                    YES, LEAP YEAR                  29600020
         LA    WORKO,FW1                SET SWITCH TO INDICATE THAT     29680020
*                                          THIS IS NOT A LEAP YEAR      29760020
*                                                                       29840020
DA010    STM   PARMA,PARMB,DOUBLE                                       29920020
         CVB   WORKE,DOUBLE             CONVERT DAYS TO BINARY          30000020
         SR    PARMB,PARMB                                              30080020
         LR    FIVE,PARMB                                               30160020
*                                                                       30240020
DA020    LA    PARMB,D1(X0,PARMB)       INCREMENT MONTH                 30320020
         IC    FIVE,XTMN-D1(PARMB)      DAYS MONTH                      30400020
         SR    WORKE,FIVE               SUBTRACT FROM DAYS LEFT         30480020
         LA    SIX,FW3                  CONSTANT FOR THIRD MONTH        30560020
         CLR   SIX,PARMB                IS THIS MARCH                   30640020
         BNE   DA030                    NO                              30720020
         LTR   WORKO,WORKO              YES, IS IT LEAP YEAR            30800020
         BP    DA030                    NO                              30880020
         BCTR  WORKE,X0                 YES, REDUCE DAYS BY ONE         30960020
*                                                                       31040020
DA030    LTR   WORKE,WORKE              ARE DAYS COUNTED DOWN TO ZERO   31120020
         BP    DA020                    NO, REPEAT LOOP                 31200020
         AR    WORKE,FIVE               YES,RESTORE SUBTRACTED VALUE    31280020
         LTR   WORKE,WORKE              TEST FOR ZERO.(FEBRUARY 29TH)   31360020
         BNZ   DA040                    NO                              31440020
         LA    WORKE,FW29               YES, SET FOR DAY 29             31520020
         BCTR  PARMB,X0                 DECREMENT TO FEBRUARY           31600020
*                                                                       31680020
DA040    LA    WORKO,FW2                LOOP COUNT                      31760020
DA050    CVD   PARMB,DOUBLE             CHANGE MONTH TO DECIMAL         31840020
         L     FIVE,DOUBLE4             MONTH TO LOWER HALF             31920020
         SLL   FIVE,L20                                                 32000020
         SLDL  FOUR,L8                  SHIFT UP TO YEAR OR MONTH       32080020
         LR    PARMB,WORKE                                              32160020
         BCT   WORKO,DA050              REPEAT UNTIL DONE               32240020
         SLL   FOUR,L8                  POSITION DATE FOR STORING       32320020
         ST    FOUR,DOUBLE              CONVERT FOR PRINTING            32400020
         UNPK  CONVERT(L7),DOUBLE(L4)   POSITION DATE FOR STORING       32480020
         MVC   HEADER90(L2),CONVERT2    MOVE IN MONTH OF YEAR           32560020
         MVI   HEADER92,SLASH                                           32640020
         MVC   HEADER93(L2),CONVERT4    MOVE IN DAY OF MONTH            32720020
         MVI   HEADER95,SLASH                                           32800020
         MVC   HEADER96(L2),CONVERT     MOVE IN YEAR                    32880020
         EJECT                                                          32960020
         MVC   DCBSYSIN(DCBPRINT-DCBIN),DCBIN  MOVE SYSIN DCB TO        33040020
*                                              WORKAREA                 33120020
         MVC   DCBSYS1(DCBIN-DCBDATA),DCBDATA  MOVE SYSUT1 DCB TO       33200020
*                                              WORKAREA                 33280020
         MVC   REENTAR(CLOSEL-OPENL1),OPENL1   MOVE L FORM TO           33360020
*                                              WORKAREA                 33440020
         LA    NINE,DCBSYS1             PICK UP ADDRESSES OF THE DCB'S  33520020
         LA    TEN,DCBSYSIN                                             33600020
         DROP  EIGHT                                                    33680020
         USING IHADCB,TEN                                               33760020
         OC    SYSINDD(L8),SYSINDD      WAS SYSIN DDNAME USER-SUPPLIED  33840020
         BZ    OPENDCB                  NO, OPEN SYSIN DCB              33920020
         MVC   DCBDDNAM,SYSINDD         MOVE DDNAME TO DCB              34000020
OPENDCB  OPEN  ((10),INPUT),MF=(E,REENTAR)                              34080020
         TM    DCBOFLGS,TBIT3           WAS OPEN SUCCESSFUL FOR SYSIN   34160020
         BZ    SETNO                    NO, OPEN NOT SUCCESSFUL         34240020
READSYS  MVC   REENTAR(OPENLS-READJL),READJL   MOVE L FORM TO           34320020
*                                              WORKAREA                 34400020
         LA    WORKE,JFCBADR            LOAD POINTER TO JFCB AREA       34480020
         ST    WORKE,CONVERT                                            34560020
         MVC   SECONDX1(L3),CONVERT1    SET UP DCB EXIT                 34640020
         MVI   SECONDEX,EIGHTY7         FLAG FOR JFCB EXIT              34720020
         LA    WORKE,SECONDEX           PICK UP READJ DCB EXIT LIST     34800020
*                                          ADDRESS                      34880020
         ST    WORKE,CONVERT                                            34960020
         DROP  TEN                                                      35040020
         USING IHADCB,NINE                                              35120020
         OC    SYSUT1DD(L8),SYSUT1DD    WAS SYSUT1 DDNAME USER-SUPPLIED 35200020
         BZ    MOVEEXIT                 NO, BRANCH AROUND               35280020
         MVC   DCBDDNAM(L8),SYSUT1DD    MOVE IN SYSUT1 DDNAME           35360020
MOVEEXIT MVC   DCBEXLST+D1(L3),CONVERT1 MOVE EXIT ADDRESS INTO DCB      35440020
         RDJFCB (DCBSYS1),MF=(E,REENTAR)  READ JFCB FOR SYSUT1          35520020
         MVC   NAMESLOT(L44),JFCBADR    SAVE DSNAME FROM SYSUT1 JFCB    35600020
PAGEING  L     FOUR,PAGENO              UPDATE PAGE NUMBER              35680020
         LA    FOUR,D1(X0,FOUR)                                         35760020
         ST    FOUR,PAGENO              RETURN UPDATED PAGE NUMBER      35840020
         CVD   FOUR,DOUBLE              CONVERT PAGE NUMBER FOR         35920020
         UNPK  DOUBLE8(L3),DOUBLE6(L2)     PRINTING                     36000020
         OI    DOUBLE10,FOXZERO                                         36080020
         MVC   HEADR110(L3),DOUBLE8     MOVE IN PAGE NUMBER             36160020
         LA    FOUR,FW59                ESTABLISH LINE COUNT            36240020
         STH   FOUR,LINECT                                              36320020
         PUT   DCBSYP,HEADERC           WRITE OUT MESSAGE DATA SET      36400020
*                                          HEADER                       36480020
         TM    MESSCODE,BITS67          CHECK FOR MISSING DD            36560020
         BO    WRITEMES                 YES, WRITE APPROPRIATE MESSAGE  36640020
         TM    COMPCODE,ALLBITS         CHECK FOR AN ERROR DURING OPEN  36720020
*                                          EXIT                         36800020
         BM    ERRIN                    YES, GO TO CLOSE                36880020
         EJECT                                                          36960020
ANOTHER  GET   DCBSYSIN                 GET ANOTHER CONTROL RECORD      37040020
         DROP  NINE                                                     37120020
         USING IHADCB,TEN                                               37200020
         LA    FOUR,EODAD               CHANGE EODAD                    37280020
         ST    FOUR,DCBEODAD               FOR DATA CARDS               37360020
         DROP  TEN                                                      37440020
         USING IHADCB,NINE                                              37520020
         MVC   MESSAGE(L80),D0(PARMB)   MOVE CONTROL CARD TO WORKAREA   37600020
         BAL   RETREG,WRITECD           GO TO PRINT CONTROL CARD        37680020
         CLI   MESSAGE,BLANK            CHECK FOR BLANK IN COLUMN ONE   37760020
         BNE   INVALID                  NO, INVALID CONTROL CARD        37840020
         LA    FOUR,MESSAGE1            SET UP SCAN FOR TRACK OR VTOC   37920020
         LA    FIVE,MESSAG61               KEYWORDS                     38000020
CHECKKEY CLI   D0(FOUR),BLANK           START OF CONTROL CARD           38080020
         BE    GOON                     NO                              38160020
         CLC   D0(L6,FOUR),TRACK        CHECK FOR TRACK KEYWORD         38240020
         BE    PICKCNT                  YES, FOUND KEYWORD              38320020
         CLC   D0(L5,FOUR),VTOC         CHECK FOR VTOC KEYWORD          38400020
         BE    VTOCFND                  YES, VTOC FOUND                 38480020
         B     INVALID                  INVALID CONTROL CARD            38560020
GOON     CR    FOUR,FIVE                AT END OF CONTROL CARD          38640020
         BNL   INVALID                  YES, AT END OF CONTROL CARD     38720020
         LA    FOUR,D1(X0,FOUR)         BUMP POINTER                    38800020
         B     CHECKKEY                 RETURN TO LOOP                  38880020
INVALID  MVI   COMPCODE,CC16            SET COMPLETION CODE=16          38960020
         MVI   MESSCODE,MC05            SET MESSAGE CODE TO INDICATE    39040020
*                                          MISSING OR INVALID CONTROL   39120020
*                                          CARD KEYWORD                 39200020
         B     FLUSH                    GO TO FLUSH INPUT               39280020
VTOCFND  BCTR  FOUR,X0                  DECREMENT POINTER               39360020
         OI    TRKOVFL,SW7              SET FOR VTOC                    39440020
PICKCNT  LA    FIVE,FW10                SET COUNTER FOR 20              39520020
         TR    D6(L20,FOUR),TABLE       CONVERT TO 20 BYTES             39600020
CHECK    CLI   D6(FOUR),C16             CHECK FOR INVALID CHARACTER     39680020
         BE    WRONG                    YES,INVALID CHARACTER           39760020
         CLI   D7(FOUR),C16             CHECK FOR INVALID CHARACTER     39840020
         BE    WRONG                    YES,INVALID CHARACTER           39920020
         LA    FOUR,D2(X0,FOUR)         BUMP POINTER                    40000020
         BCT   FIVE,CHECK               CHECK FOR ALL BYTES CONVERTED   40080020
         SH    FOUR,HW20                ADJUST POINTER TO BEGINNING     40160020
*                                          OF COUNT                     40240020
         MVC   DOUBLE(L8),D6(FOUR)      MOVE BBBBCCCC TO WORK AREA      40320020
         PACK  DOUBLE4(L5),DOUBLE(L9)   REMOVE EXTRA ZONE BYTES         40400020
         MVC   TRACKAD2(L4),DOUBLE4     MOVE BBCC TO SEEK ADDRESS       40480020
         MVC   COUNT(L2),DOUBLE6        MOVE CC TO COUNT FIELD          40560020
         MVC   DOUBLE(L12),D14(FOUR)    MOVE HHHHRRKKDDDD TO WORK AREA  40640020
         PACK  DOUBLE6(L7),DOUBLE(L13)  REMOVE EXTRA ZONE BYTES         40720020
         MVC   TRACKAD6(L2),DOUBLE6     MOVE HH TO SEEK ADDRESS         40800020
         MVC   COUNT2(L6),DOUBLE6       MOVE HHRKDD TO COUNT FIELD      40880020
         SR    FIVE,FIVE                                                40960020
         IC    FIVE,COUNT5              PICK UP KEY LENGTH              41040020
         STH   FIVE,KEYSIZE             SAVE THIS KEY LENGTH            41120020
         AH    FIVE,COUNT6              ADD THE DATA FIELD LENGTH       41200020
         STH   FIVE,KEYDATA             SAVE THIS KEY-DATA LENGTH       41280020
         LA    FIVE,D8(X0,FIVE)         ADD COUNT FIELD LENGTH OF 8     41360020
         STH   FIVE,CCWCOUNT            SAVE COUNT+KEY+DATA LENGTH      41440020
CHEKSPEC CLI   D26(FOUR),SPECIALW       CHECK FOR WRITE SPECIAL         41520020
*                                          COMMAND REQUIRED             41600020
         BNE   GETBUFF                  NO, GO GET RECORD BUFFER        41680020
         DEVTYPE  DCBDDNAM,DEVFEAT      GET DEVICE CHARACTERISTICS      41760020
         TM    DEVFEAT1,TBIT1           DOES THE SYSTEM SUPPORT TRACK   41840020
*                                          OVERFLOW                     41920020
         BO    SETSW                    YES, TRACK OVERFLOW IS          42000020
*                                          SUPPORTED                    42080020
         MVI   MESSCODE,MC14            THE SYSTEM DOES NOT SUPPORT     42160020
*                                          TRACK OVERFLOW               42240020
         B     COMPSET                  SET COMPLETION CODE             42320020
SETSW    OI    TRKOVFL,SW3              SET FOR WRITE SPECIAL           42400020
GETBUFF  MVC   GETLS(L16),GETL          MOVE LIST FORM TO WORK AREA     42480020
         ST    FIVE,GETLS               PUT NUMBER BYTES REQUIRED       42560020
         LA    PARMB,GETLS              GET ADDRESS OF WHERE AREA       42640020
         ST    PARMB,GETLS4                ADDRESS IS TO BE RETURNED    42720020
         GETMAIN EC,MF=(E,(1))          GETMAIN FOR RECORD SIZE         42800020
         LTR   ADDREG,ADDREG            CHECK FOR GOTTEN CORE           42880020
         BNZ   NOCORE                   CORE NOT AVAILABLE              42960020
         L     PARMB,GETLS              PICK UP ADDRESS OF GOTTEN CORE  43040020
         ST    PARMB,GOTCORE            SAVE POINTER TO GOTTEN CORE     43120020
         LR    FOUR,PARMB               PICK UP POINTER TO GOTTON CORE  43200020
         LA    SIX,D8(X0,FOUR)          ADJUST MOVING POINTER BEYOND    43280020
*                                          COUNT                        43360020
         MVC   D0(L8,FOUR),COUNT        MOVE IN COUNT                   43440020
         S     FIVE,FW8                 ACCOUNT FOR COUNT FIELD LENGTH  43520020
         LTR   FIVE,FIVE                IS DATA + KEY LENGTH=0          43600020
         BZ    GOGETUM                  YES, MAKE SURE NO MORE CONTROL  43680020
*                                          CARDS ARE IN INPUT STREAM    43760020
GETSYS   GET   DCBSYSIN                                                 43840020
         MVC   MESSAGE(L80),D0(PARMB)   MOVE IN USER'S DATA INTO OUTPUT 43920020
*                                          AREA TO PRINT                44000020
         LR    WORKE,PARMB                                              44080020
         BAL   RETREG,WRITECD           GO TO WRITE DATA CARD           44160020
         C     FIVE,FW40                MORE THAN 40 BYTES LEFT         44240020
         BH    MOVE40                   YES, MORE THAN 40               44320020
         LR    SEVEN,FIVE               SET UP BYTE COUNTER             44400020
         SR    FIVE,FIVE                                                44480020
         B     TRANSLAT                 TRANSLATE PROPER NUMBER         44560020
*                                          OF BYTES                     44640020
MOVE40   LA    SEVEN,L40                SET COUNTER FOR 40              44720020
         S     FIVE,FW40                SUBTRACT 40 FOR OUTPUT          44800020
TRANSLAT TR    D0(L80,WORKE),TABLE      CONVERT TO 80 BYTES             44880020
VALIDCK  CLI   D0(WORKE),C16            CHECK FOR INVALID CHARACTER     44960020
         BE    WRONG                    YES, INVALID CHARACTER          45040020
         CLI   D1(WORKE),C16            CHECK FOR INVALID CHARACTER     45120020
         BE    WRONG                    YES, INVALID CHARACTER          45200020
         IC    EIGHT,D0(WORKE)          PICK UP FIRST BYTE OF 2 BYTE    45280020
*                                          CHARACTER                    45360020
         SLL   EIGHT,L4                 SHIFT OUT HIGH ORDER DIGIT      45440020
         STC   EIGHT,D0(SIX)            STORE FIRST HALF OF DIGIT       45520020
         OC    D0(L1,SIX),D1(WORKE)     OR THE FIRST AND SECOND DIGITS  45600020
         LA    SIX,D1(X0,SIX)           BUMP OUTPUT POINTER             45680020
         LA    WORKE,D2(X0,WORKE)       BUMP INPUT POINTER              45760020
         BCT   SEVEN,VALIDCK            CHECK FOR ALL BYTES ON THIS     45840020
*                                          CARD CONVERTED               45920020
         LTR   FIVE,FIVE                CHECK FOR ALL BYTES IN RECORD   46000020
*                                       CONVERTED                       46080020
         BNZ   GETSYS                   NO, ALL BYTES NOT CONVERTED     46160020
* GET AGAIN FROM SYSIN TO FORCE EODAD                                   46240020
GOGETUM  GET   DCBSYSIN                                                 46320020
         B     TOOFEW                   SHOULD NOT BE HERE UNLESS SYSIN 46400020
*                                          CONTAINS MORE CONTROL OR     46480020
*                                          DATA CARDS THAN REQUIRED     46560020
         EJECT                                                          46640020
EODAD    LTR   FIVE,FIVE                TEST FOR CORRECT NUMBER OF      46720020
*                                          BYTES FOR OUTPUT             46800020
         BNZ   TOOFEW                   CHARACTERS RECEIVED IS LESS     46880020
*                                          THAN COUNT SPECIFIED         46960020
         MVC   CCWAR1(L48),CCW1         MOVE CCWS TO WORK AREA          47040020
         L     FOUR,GOTCORE             RESTORE WORK AREA POINTER       47120020
         ST    FOUR,CONVERT                                             47200020
         MVC   CCWAR11(L3),CONVERT1     ESTABLISH POINTER TO COUNT FOR  47280020
*                                          SEARCH EQUAL ID              47360020
         MVC   CCWAR41(L3),CONVERT1                                     47440020
         LA    FIVE,CCWAR1              ESTABLISH ADDRESS OF FIRST CCW  47520020
         ST    FIVE,CONVERT                FOR TIC                      47600020
         MVC   CCWAR21(L3),CONVERT1                                     47680020
         LA    FIVE,CCWAR4              ESTABLISH ADDRESS OF FOURTH CCW 47760020
         ST    FIVE,CONVERT                FOR TIC                      47840020
         MVC   CCWAR51(L3),CONVERT1                                     47920020
         MVC   CCWAR3A2(L2),KEYDATA     INSERT LENGTH OF KEY AND DATA   48000020
         LA    FIVE,D8(X0,FOUR)         PICK UP POINTER TO RECORD       48080020
         ST    FIVE,CONVERT                                             48160020
         MVC   CCWAR31(L3),CONVERT1     ESTABLISH ADDRESS FROM WHICH    48240020
*                                          DATA IS TO BE WRITTEN        48320020
         MVC   CCWAR61(L3),CONVERT1     ESTABLISH ADDRESS INTO WHICH    48400020
*                                       DATA IS TO BE READ              48480020
         MVC   CCWAR6A2(L2),KEYDATA     MOVE LENGTH OF KEY/DATA OX02345 48530003
         SPACE                                                          48560020
* INSERT TEST HERE TO CHANGE WRITE KEY DATA TO WRITE(SPECIAL) COUNT,KEY 48640020
* DATA                                                                  48720020
         TM    TRKOVFL,TBIT3              WRITE SPECIAL REQUIRED        48800020
         BZ    BUILDECB                 NO, WRITE SPECIAL NOT REQUIRED  48880020
         MVI   CCWAR3,SW7               SET WRITE FOR TRACK OVERFLOW    48960020
         MVC   CCWAR31(L3),CCWAR11      MOVE ADDRESS OF COUNT IN FOR    49040020
*                                          WRITE(SPECIAL) COUNT, KEY,   49120020
*                                          DATA                         49200020
         MVC   CCWAR3A2(L2),CCWCOUNT    INSERT LENGTH OF KEY+DATA+COUNT 49280020
         L     FIVE,CCWAR1              LOAD POINTER TO COUNT FIELD     49360020
*                                          FOR SEARCH ID EQUAL CCW      49440020
         MVC   ID(L4),D0(FIVE)          MOVE INTO NEW COUNT FIELD       49520020
         XR    FOUR,FOUR                                                49600020
         IC    FOUR,D4(FIVE)            LOAD OLD SEARCH RECORD NUMBER   49680020
         BCTR  FOUR,X0                  DECREMENT BY 1                  49760020
         STC   FOUR,ID4                 STORE R IN NEW COUNT FIELD      49840020
         LA    FOUR,ID                  OBTAIN POINTER TO NEW COUNT     49920020
*                                          FIELD                        50000020
         ST    FOUR,TEMP                                                50080020
         MVC   CCWAR11(L3),TEMP1        MOVE POINTER INTO SEARCH CCW    50160020
         EJECT                                                          50240020
* THIS SECTION BUILDS THE REQUIRED ECB AND IOB AND ATTEMPTS TO WRITE    50320020
* THE REPLACEMENT RECORD                                                50400020
BUILDECB LA    FIVE,ECB                 PUT ECB ADDRESS INTO IOB        50480020
         ST    FIVE,IOBECB                                              50560020
         OC    KEYDATA(L2),KEYDATA      KEY/DATA LENGTH = ZERO.         50640020
         BNZ   NONZERO                  NO, GO ON                       50720020
         LA    FIVE,CCWAR4              PUT ADDRESS OF FOURTH CCW INTO  50800020
*                                          IOB                          50880020
         B     MARCHON                  CONTINUE                        50960020
NONZERO  LA    FIVE,CCWAR1              PUT ADDRESS OF FIRST CCW AND    51040020
MARCHON  LA    SIX,DCBSYS1                 DCB ADDRESS INTO IOB         51120020
         STM   FIVE,SIX,IOBSTART                                        51200020
         MVC   SEEK1(L6),TRACKAD2       MOVE IN SEEK ADDRESS            51280020
         LA    NINE,DCBSYS1                                             51360020
PREPDCB  MVC   REENTAR(OPENL1-OPENL2),OPENL2   MOVE L FORM TO WORKAREA  51440020
         XC    DCBEXLST+D1(L3),DCBEXLST+D1 CLEAR DCBEXIT                51520020
         TM    TRKOVFL,TBIT7            CHECK FOR VTOC                  51600020
         BZ    REGOPEN                  NO, NOT VTOC                    51680020
         MVI   JFCBADR,OHFOUR           SET 44 BYTES TO X'04'           51760020
         MVC   JFCBADR1(L43),JFCBADR                                    51840020
         LA    FIVE,DOUBLE                                              51920020
         ST    FIVE,DCBEXLST            STORE POINTER TO DCB EXIT LIST  52000020
         LA    FIVE,JFCBADR             SET UP POINTER TO JFCB TO BE    52080020
         ST    FIVE,DOUBLE                 USED                         52160020
         MVI   DOUBLE,EIGHTY7           SET FOR JFCB BEING USED         52240020
         OI    JFCBTSDM,SW4             TURN ON FLAG SO JFCB WILL       52320020
*                                          NOT BE WRITTEN BACK          52400020
         OPEN  ((9),INOUT),TYPE=J,MF=(E,REENTAR)  OPEN SYSUT1 FOR VTOC  52480020
         B     HERE                     GO ON                           52560020
REGOPEN  OPEN  ((9),INOUT),MF=(E,REENTAR)         OPEN SYSUT1           52640020
HERE     TM    DCBOFLGS,TBIT3           CHECK FOR SUCCESSFUL OPEN       52720020
         BZ    SETNOS                   NO, MISSING DD CARD             52800020
         EJECT                                                          52880020
* THIS SECTION DETERMINES WHICH EXTENT OF THE SYSUT1 DATA SET INCLUDES  52960020
* THE GIVEN BAD TRACK                                                   53040020
         L     SEVEN,DCBDEBAD           LOAD PTR TO DEB                 53120020
         XR    FIVE,FIVE                ZERO REGISTER                   53200020
         LR    SIX,FIVE                 SET M=0                         53280020
         IC    FIVE,DEBNMEXT(SEVEN)     LOAD NUMBER OF EXTENTS          53360020
         TM    DEBOFLGS(SEVEN),TBIT5    CHECK FOR SPLIT CYL             53440020
         BNO   NOSPLIT                  BRANCH AROUND IF NOT SPLIT      53520020
         MVI   SPLIT,ALLBITS            SET SPLIT SWITCH                53600020
NOSPLIT  LA    SEVEN,DEBDASD(SEVEN)     BUMP PTR TO FIRST EXTENT        53680020
*                                          DESCRIPTION                  53760020
STARTEST CLC   TRACKAD4(L4),DEBSTRCC(SEVEN) IS GIVEN BAD TRACK LOWER    53840020
*                                       THAN START OF EXTENT            53920020
         BL    DECREMNT                 YES, CONTINUE TESTING           54000020
         CLC   TRACKAD4(L4),DEBENDCC(SEVEN) IS GIVEN BAD TRACK HIGHER   54080020
*                                          THAN END OF EXTENT           54160020
         BH    DECREMNT                 YES, CONTINUE TESTING           54240020
         CLI   SPLIT,ALLBITS            SPLIT SWITCH ON                 54320020
         BNE   STOREM                   NO, STORE M                     54400020
         CLC   TRACKAD6(L2),DEBSTRHH(SEVEN) IS GIVEN BAD TRACK HH       54480020
*                                       LOWER THAN EXTENT               54560020
         BL    DECREMNT                 YES, CONTINUE TESTING           54640020
         CLC   TRACKAD6(L2),DEBENDHH(SEVEN) IS GIVEN BAD TRACK HH       54720020
*                                          HIGHER THAN EXTENT           54800020
         BH    DECREMNT                 YES,CONTINUE TESTING            54880020
         B     STOREM                   STORE M                         54960020
DECREMNT BCT   FIVE,INCREMNT            DECREMENT NUMBER OF EXTENTS AND 55040020
*                                          CONTINUE                     55120020
         B     INVALIDS                 OUT OF EXTENT                   55200020
INCREMNT LA    SIX,D1(SIX)              INCREMENT M                     55280020
         LA    SEVEN,NEXTEXT(SEVEN)     BUMP POINTER TO NEXT DEB EXTENT 55360020
         B     STARTEST                 CHECK NEXT EXTENT               55440020
STOREM   STC   SIX,SEEK                 STORE M INTO IOB SEEK ADDRESS   55520020
         EJECT                                                          55600020
         TM    TRKOVFL,TBIT7            CHECK FOR VTOC                  55680020
         BO    TESTVTOC                 YES, VTOC, TRY TO READ RECORD   55760020
GOODSEEK EQU   *                                                        55840020
         XC    ECB(L4),ECB              CLEAR ECB                       55920020
         EXCP  IOB                      ATTEMPT TO WRITE RECORD         56000020
         WAIT  1,ECB=ECB                WAIT FOR I/O TO COMPLETE        56080020
         TM    ECB,TBIT2                CHECK FOR I/O SUCCESSFUL        56160020
         BO    NOALT                    YES, I/O SUCCESSFUL             56240020
         CLI   ECB,C42                  OUT OF EXTENT                   56320020
         BE    INVALIDS                 YES, WRITE ERROR MESSAGE        56400020
         CLI   ECB,C41                  ARE CSW CONTENTS VALID          56480020
         BNE   WRONGERR                 NO, CAN'T HANDLE ERROR          56560020
         CLI   IOBCSWST,C0D             END OF FILE                     56640020
         BE    NOALT                    YES, KEYDATA LENGTH =0          56720020
         TM    IOBCSWST,TBIT6           DID USER CHECK OCCUR            56800020
         BNO   WRONGERR                 NO, CAN'T HANDLE ERROR          56880020
         B     GETSET                   SET UP PARAMETER LIST           56960020
TESTVTOC LA    SIX,CCWAR4               GET NEW ADDRESS TO READ RECORD  57040020
         ST    SIX,IOBSTART             STORE IN IOBSTART               57120020
         EXCP  IOB                      ATTEMPT TO READ                 57200020
         WAIT  1,ECB=ECB                WAIT FOR I/O TO COMPLETE        57280020
         TM    ECB,TBIT2                I/O SUCCESSFUL                  57360020
         BO    PREPMESS                 YES, CAN'T HANDLE REQUEST       57440020
         LA    SIX,CCWAR1               RESTORE IOBSTART FIELD WITH     57520020
         ST    SIX,IOBSTART                ADDRESS OF WRITE PROGRAM     57600020
         MVI   DCBIFLGS,DBLZERO         RESET ERROR FLAGS               57680020
         B     GOODSEEK                 EXECUTE WRITE CHANNEL PROG      57760020
GETSET   MVI   DCBIFLGS,DBLZERO         RESET ERROR FLAGS               57840020
         DROP  NINE                                                     57920020
         EJECT                                                          58000020
         LA    PARMB,IOB                SET UP POINTER TO IOB           58080020
         ST    PARMB,PARMLIST                                           58160020
         LA    PARMB,COUNT              SET UP POINTER TO COUNT         58240020
         ST    PARMB,PARMLIS4                                           58320020
         MVI   PARMLIS4,EIGHTY          TURN ON UTILITY FLAG FOR SVC    58400020
         TM    TRKOVFL,TBIT3            WAS USER RECORD AN OVERFLOW     58480020
*                                          SEGMENT                      58560020
         BZ    NOVFL                    NO,WRITE SPECIAL NOT REQUIRED   58640020
         OI    PARMLIS4,TWENTY          YES, TURN ON WRITE SPECIAL FOR  58720020
*                                          SVC                          58800020
NOVFL    LA    PARMB,PARMLIST           SET UP PARAMETER REGISTER TO    58880020
*                                          POINT TO PARAMETER LIST      58960020
         SVC   ATLASSVC                 ISSUE SVC 86             S20201 59040020
         SPACE                                                          59120020
* BRANCH TABLE BASED ON SVC RETURN CODES. GO TO APPROPRIATE ROUTINE TO  59200020
* SET COMPLETION AND MESSAGE CODES.                                     59280020
         B     BRANCH(ADDREG)           B                               59360020
BRANCH   B     SUCCESS                   R                              59440020
         B     WRONGDEV                   A                             59520020
         B     NOMORE                   F  N                            59600020
         B     NOCORE                    O  C                           59680020
         B     IOERROR                    R  H                          59760020
         B     WRONGERR                    -                            59840020
         B     F4NOT                        E  T                        59920020
         B     USERF4                        R  A                       60000020
         B     LASTCNT                        R  B                      60080020
         B     R0HA                            O  L                     60160020
         B     DATAERR                          R  E                    60240020
         B     USERSREC                          -                      60320020
         B     NOERR                              M                     60400020
         B     NOREEX                              S                    60480020
         B     NOTRKOVF                             G                   60560020
         B     TRKOUT                                S                  60640020
*                                                                       60720020
SUCCESS  MVI   MESSCODE,MC00            MESSAGE FOR SUCCESS             60800020
         B     WRITEMES                 WRITE SUCCESSFUL MESSAGE        60880020
WRONGDEV MVI   MESSCODE,MC07            WRONG DEVICE TYPES              60960020
         B     COMPSET                  SET COMPLETION CODE             61040020
NOMORE   MVI   MESSCODE,MC08            NO MORE ALTERNATES              61120020
         B     COMPSET                  SET COMPLETION CODE             61200020
NOCORE   MVI   MESSCODE,MC09            CORE NOT AVAILABLE              61280020
         B     COMPSET                  SET COMPLETION CODE             61360020
IOERROR  MVI   MESSCODE,MC02            I/O ERROR                       61440020
         B     COMPSET                  SET COMPLETION CODE             61520020
WRONGERR MVI   MESSCODE,MC0D            NO DATA CHECK OR MISSING        61600020
*                                          ADDRESS MARKER               61680020
         B     COMPSET                  SET COMPLETION CODE             61760020
F4NOT    MVI   MESSCODE,MC0E            FORMAT 4 DSCB COULD NOT BE READ 61840020
         B     COMPSET                  SET COMPLETION CODE             61920020
USERF4   MVI   MESSCODE,MC0F            ERROR ON LAST COUNT FIELD       62000020
*                                          RECORD                       62080020
         B     COMPSET                  SET COMPLETION CODE             62160020
LASTCNT  MVI   MESSCODE,MC10            ERROR ON LAST COUNT FIELD       62240020
         B     COMPSET                  SET COMPLETION CODE             62320020
R0HA     MVI   MESSCODE,MC11            R0 AND HA ERRORS                62400020
         B     COMPSET                  SET COMPLETION CODE             62480020
DATAERR  MVI   MESSCODE,MC12            ERROR/ERRORS ENCOUNTERED        62560020
*                                          AN ALTERNATE HAS BEEN        62640020
*                                          ASSIGNED                     62720020
         B     COMPSET                  SET COMPLETION CODE             62800020
NOERR    MVI   MESSCODE,MC17            NO ERRORS FOUND ON TRACK        62880020
*                                          NO ALTERNATE ASSIGNED        62960020
         B     COMPSET                  SET COMPLETION CODE             63040020
NOREEX   MVI   MESSCODE,MC13            CHANNEL PROGRAM NOT RE-         63120020
*                                          EXECUTABLE                   63200020
         B     COMPSET                  SET COMPLETION CODE             63280020
NOTRKOVF MVI   MESSCODE,MC14            MESSAGE FOR SYSTEM DOES NOT     63360020
*                                          SUPPORT TRACK OVERFLOW       63440020
         B     COMPSET                  SET COMPLETION CODE             63520020
TRKOUT   MVI   MESSCODE,MC0B            TRACK IS OUT OF EXTENTS         63600020
         B     COMPSET                  SET COMPLETION CODE             63680020
USERSREC MVI   MESSCODE,MC16            CAN'T HANDLE ERROR              63760020
*                                          NO ALTERNATE ASSIGNED        63840020
COMPSET  MVI   COMPCODE,CC16            SET COMPLETION CODE TO 16       63920020
         ST    PARMA,RETPARM            SAVE ERROR RECORD NUMBERS       64000020
* THIS ROUTINE WRITES OUT ALL MESSAGES                                  64080020
WRITEMES EQU   *                                                        64160020
         SR    WORKO,WORKO                                              64240020
         IC    WORKO,MESSCODE           PICK UP MESSAGE NUMBER          64320020
         CH    WORKO,HW10               CHECK FOR SYNAD ENTERED FOR     64400020
*                                          SYSIN                        64480020
         BE    SPECIAL                  YES, SYNAD ENTERED FOR SYSIN    64560020
CONTWRT  SLL   WORKO,L2                 MULTIPLY MESSAGE NUMBER BY 4    64640020
         L     FOUR,MESSTBLA            PICK UP BEGINNING ADDRESS OF    64720020
*                                          MESSAGE TABLE                64800020
         AR    WORKO,FOUR               INDEX INTO ADDRESS TABLE        64880020
         L     WORKO,D0(X0,WORKO)       MOVE IN MESSAGE                 64960020
         MVC   MESSAGE(L120),D0(WORKO)                                  65040020
         LA    FIVE,CHKMESS             LOAD RETURN ADDRESS             65120020
PUTOUT   PUT   DCBSYP,MESSAGEC          PUT OUT MESSAGE                 65200020
         BR    FIVE                     GO TO NEXT ROUTINE              65280020
CHKMESS  CLI   MESSCODE,C03             IS MESSAGE CODE FOR MISSING DD  65360020
         BNE   NEXTEST                  NO, GO ON TO NEXT TEST          65440020
         USING IHADCB,TEN                                               65520020
         TM    DCBOFLGS,TBIT3           IS SYSIN DCB OPEN               65600020
         BO    ENDCARD                  YES, IT IS OPEN                 65680020
         B     WRAPUP                   BRANCH TO EXIT ROUTINE          65760020
         DROP  TEN                                                      65840020
NEXTEST  EQU   *                                                        65920020
         CLI   MESSCODE,C00             WAS MESSAGE FOR SUCCESSFUL      66000020
*                                          COMPLETION                   66080020
         BE    ORCORE                   YES,NO NEED TO PRINT ERROR      66160020
*                                          RECORD NUMBERS               66240020
         CLI   RETPARM,C00              ARE THERE ANY ERROR RECORDS TO  66320020
*                                          BE PRINTED OUT               66400020
         BE    ORCORE                   NO,GO TO WRAP UP                66480020
         XR    WORKE,WORKE              CLEAR REGISTER                  66560020
         LA    FOUR,MESSAGE                                             66640020
         MVI   MESSAGE,PRINTERR         SET UP PRINTOUT FOR ERROR       66720020
         MVI   MESSAGE1,EQUALS             RECORDS                      66800020
         MVI   MESSAGE2,ELEVEN          MOVE IN DUMMY CODE FOR BLANKS   66880020
         MVC   MESSAGE3(L117),MESSAGE2  PROPAGATE THRU MESSAGE AREA     66960020
         LA    WORKO,RETPARM                                            67040020
         XR    SIX,SIX                                                  67120020
         IC    SIX,RETPARM              PICK UP NUMBER OF ERROR RECORDS 67200020
MOVIT    IC    WORKE,D1(X0,WORKO)       PICK UP ERROR RECORD NUMBER     67280020
         SRL   WORKE,L4                 SHIFT OUT RIGHT DIGIT           67360020
         STC   WORKE,D2(X0,FOUR)        PLACE LEFT DIGIT IN ONE BYTE    67440020
*                                          OF MESSAGE AREA              67520020
         MVC   D3(L1,FOUR),D1(WORKO)    MOVE SAME RECORD NUMBER TO      67600020
*                                          NEXT BYTE IN MESSAGE AREA    67680020
         NI    D3(FOUR),ZEROFOX         SET LEFT HALF OF BYTE TO ZERO   67760020
         MVI   D4(FOUR),DUMMY           MOVE IN DUMMY COMMA             67840020
         LA    FOUR,D3(FOUR)            INCREMENT MESSAGE AREA          67920020
*                                          POINTER                      68000020
         LA    WORKO,D1(WORKO)          INCREMENT PARAMETER LIST        68080020
*                                          POINTER                      68160020
         BCT   SIX,MOVIT                REDUCE NUMBER OF ERROR RECORDS  68240020
*                                          BY ONE AND TEST FOR ZERO     68320020
         TR    MESSAGE2(L118),TRANSTB   IF ALL RECORD NUMBERS MOVED TO  68400020
*                                          MESSAGE AREA-TRANSLATE FOR   68480020
*                                          PRINTOUT                     68560020
         LA    FIVE,ORCORE              LOAD RETURN ADDRESS             68640020
         B     PUTOUT                   BRANCH TO PUT ROUTINE           68720020
ORCORE   OC    GOTCORE(L4),GOTCORE      HAS CORE BEEN GOTTEN FOR THE    68800020
*                                          RECORD                       68880020
         BZ    ENDCARD                  NO, CLOSE DCB'S                 68960020
FREE     LH    FIVE,CCWCOUNT                                            69040020
         L     FOUR,GOTCORE             RESTORE WORK AREA POINTER       69120020
         FREEMAIN R,LV=(5),A=(4)        FREE BUFFER                     69200020
         B     ENDCARD                  CLOSE OUT DCB'S                 69280020
SPECIAL  MVC   MESSAGE(L8),IONUMBER     MOVE IN SPECIAL MESSAGE NUMBER  69360020
         MVC   MESSAG96(L24),COMPMESS   MOVE COMPLETION CODE TO MESSAGE 69440020
         PUT   DCBSYP,MESSAGEC                                          69520020
         B     CONTWRT                  PUT OUT ANOTHER MESSAGE         69600020
NOALT    MVI   COMPCODE,CC00            SET COMPLETION CODE TO ZERO     69680020
         MVI   MESSCODE,MC01            SET MESSAGE CODE TO ONE         69760020
         B     WRITEMES                 WRITE SUCCESSFUL MESSAGE        69840020
WRITECD  LR    FOUR,RETREG              SAVE RETURN POINTER             69920020
         PUT   DCBSYP,MESSAGEC          WRITE CONTROL CARD              70000020
         LH    EIGHT,LINECT                                             70080020
         BCT   EIGHT,SUBTRACT           CHECK LINE COUNT                70160020
         L     EIGHT,PAGENO             NEED NEW PAGE                   70240020
         LA    EIGHT,D1(X0,EIGHT)       UPDATE PAGE NUMBER              70320020
         ST    EIGHT,PAGENO                                             70400020
         CVD   EIGHT,DOUBLE             CONVERT PAGE NUMBER FOR         70480020
         UNPK  DOUBLE8(L3),DOUBLE6(L2)     PRINTING                     70560020
         OI    DOUBLE10,FOXZERO                                         70640020
         MVC   HEADR110(L3),DOUBLE8     MOVE IN PAGE NUMBER             70720020
         PUT   DCBSYP,HEADERC           WRITE OUT HEADER ON MESSAGE     70800020
*                                          DATA SET                     70880020
         LA    EIGHT,FW59                                               70960020
         STH   EIGHT,LINECT             RE-ESTABLISH LINE COUNT         71040020
         LR    RETREG,FOUR              RESTORE RETURN POINTER          71120020
         BR    RETREG                   RETURN TO CALLER                71200020
SUBTRACT STH   EIGHT,LINECT             RETURN UPDATED LINE COUNT       71280020
         LR    RETREG,FOUR              RESTORE RETURN POINTER          71360020
         BR    RETREG                   RETURN TO CALLER                71440020
         EJECT                                                          71520020
ENDCARD  MVC   REENTAR(DCBDATA-CLOSEL),CLOSEL  MOVE L FORM TO WORKAREA  71600020
         USING IHADCB,NINE                                              71680020
         XC    DCBDSORG(L2),DCBDSORG    ZERO OUT DSORG IN SYSUT1 DCB    71760020
         DROP  NINE                                                     71840020
         CLOSE ((9),,(10)),MF=(E,REENTAR)      CLOSE SYSIN & SYSUT1     71920020
         FREEPOOL DCBSYSIN              FREE BUFFER FOR SYSIN           72000020
WRAPUP   MVC   REENTAR(OPENL2-CLOSELS),CLOSELS  MOVE L FORM TO WORKAREA 72080020
         LA    EIGHT,DCBSYP             RESTORE DCB POINTER             72160020
         CLOSE ((8)),MF=(E,REENTAR)                                     72240020
         FREEPOOL DCBSYP                FREE BUFFERS FOR SYSPRINT       72320020
ENDEXIT  L     SAVEREG,D4(SAVEREG)      RESTORE SAVE AREA POINTER       72400020
         SR    FOUR,FOUR                                                72480020
         OC    SAVEPAR(L4),SAVEPAR      WAS PAGE PARAMETER GIVEN        72560020
         BZ    FREECORE                 NO, ISSUE FREEMAIN              72640020
         L     FIVE,SAVEPAR             LOAD ADDRESS OF PARAMETER       72720020
         L     SIX,PAGENO                                               72800020
         CVD   SIX,DOUBLE               CONVERT PAGE NUMBER TO DECIMAL  72880020
         UNPK  CONVERT(L4),DOUBLE5(L3)                                  72960020
         MVC   D2(L4,FIVE),CONVERT      RESTORE PAGE NUMBER PARAMETER   73040020
FREECORE FREEMAIN R,LV=1300,A=(11)      FREE MAIN WORK AREA             73120020
         IC    FOUR,COMPCODE            INSERT COMPLETION CODE          73200020
         LR    ADDREG,FOUR                                              73280020
         L     RETREG,D12(X0,SAVEREG)   RESTORE RETURN ADDRESS          73360020
         RETURN (2,12),T                                                73440020
         EJECT                                                          73520020
*THIS IS THE SYNAD ROUTINE FOR SYSIN.  THE SYNADAF & SYNADRLS MACROS    73600020
*ARE USED.  THE COMPLETION CODE AND MESSAGE NUMBERS ARE SET.            73680020
SYSINSYN SYNADAF ACSMETH=QSAM,PARM1=DCBSYSIN,PARM2=(0)                  73760020
         MVC   MESSAGE8(L79),D49(PARMB) MOVE IN PRINTABLE DATA FROM     73840020
*                                          BUFFER FOR MESSAGE           73920020
         MVI   COMPCODE,CC16            SET COMPLETION CODE FOR 16      74000020
         MVI   MESSCODE,MC0A            SET MESSAGE CODE FOR 10         74080020
         SYNADRLS                                                       74160020
         B     WRITEMES                 PUT OUT MESSAGE                 74240020
         SPACE                                                          74320020
* THIS SECTION SETS MESSAGE AND COMPLETION CODES FOR MISSING DD         74400020
SETNO    MVI   COMPCODE,CC16            SET COMPLETION CODE TO SIXTEEN  74480020
         MVI   MESSCODE,MC03            SET MESSAGE CODE TO THREE       74560020
         B     READSYS                  GO BACK TO READJ FOR SYSUT1     74640020
SETNOS   MVI   MESSCODE,MC03            SET MESSAGE CODE TO THREE       74720020
         MVI   COMPCODE,CC16            SET COMPLETION CODE TO 16       74800020
         B     WRITEMES                 WRITE ERROR MESSAGE             74880020
         SPACE                                                          74960020
* THIS IS THE SYSIN DCB EXIT FOR DCB PARAMETER VALIDATION               75040020
         USING IHADCB,TEN                                               75120020
DCBEXIT  OC    DCBBLKSI(L2),DCBBLKSI    CHECK FOR NO BLKSIZE            75200020
         BNZ   CHECKM                   YES, BLOCKSIZE PRESENT          75280020
         MVC   DCBBLKSI(L2),DCBLRECL    SET UP BLOCKSIZE                75360020
CHECKM   LH    WORKO,DCBBLKSI           PICK UP BLOCKSIZE               75440020
         LH    FOUR,DCBLRECL            PICK UP LOGICAL RECORD SIZE     75520020
         SR    WORKE,WORKE                                              75600020
         DR    WORKE,FOUR               DIVIDE BLOCKSIZE BY LRECL       75680020
         LTR   WORKE,WORKE              CHECK FOR NO REMAINDER          75760020
         BNE   DCBERR                   NO, SET FOR ERROR IN DCB        75840020
         RETURN                                                         75920020
DCBERR   MVI   MESSCODE,MC04            SET MESSAGE NUMBER TO FOUR      76000020
         MVI   COMPCODE,CC16            SET COMPLETION CODE TO 16       76080020
         MVC   DCBBLKSI(L2),DCBLRECL    CHANGE BLOCKSIZE                76160020
         RETURN                                                         76240020
WRONG    MVI   MESSCODE,MC06            SET MESSAGE CODE FOR INVALID    76320020
*                                          CHARACTER IN THE USER'S      76400020
*                                          RECORD                       76480020
         MVI   COMPCODE,CC16            SET COMPLETION CODE TO 16       76560020
FLUSH    LA    EIGHT,WRITEMES           CHANGE SYSIN EODAD ADDRESS      76640020
         ST    EIGHT,CONVERT                                            76720020
         MVC   DCBEODAD+D1(L3),CONVERT1 MOVE IN NEW EODAD ADDRESS       76800020
FLUSHGET GET   DCBSYSIN                                                 76880020
         B     FLUSHGET                 FLUSH REMAINING CARDS           76960020
         DROP  TEN                                                      77040020
         USING IHADCB,EIGHT                                             77120020
PRINTCK  OC    DCBBLKSI(L2),DCBBLKSI    CHECK FOR NO BLKSIZE            77200020
         BNZ   CHECKPM                  YES, BLOCKSIZE PRESENT          77280020
         MVC   DCBBLKSI(L2),DCBLRECL    SET UP BLOCKSIZE                77360020
CHECKPM  LH    WORKO,DCBBLKSI           PICK UP BLOCKSIZE               77440020
         LH    FOUR,DCBLRECL            PICK UP LOGICAL RECORD SIZE     77520020
         SR    WORKE,WORKE                                              77600020
         DR    WORKE,FOUR               DIVIDE BLOCKSIZE BY LRECL       77680020
         LTR   WORKE,WORKE              CHECK FOR NO REMAINDER          77760020
         BNE   ERRDCB                   NO, SET FOR ERROR IN DCB        77840020
         RETURN                                                         77920020
ERRDCB   MVI   COMPCODE,CC16            SET COMPLETION CODE TO 16       78000020
         MVC   DCBBLKSI(L2),DCBLRECL    MOVE LRECL TO BLKSIZE           78080020
         RETURN                                                         78160020
ERRIN    MVI   COMPCODE,CC16            SET COMPLETION CODE TO 16       78240020
         MVI   MESSCODE,MC04            SET MESSAGE CODE FOR INVALID    78320020
*                                          DCB PARAMETERS FOR SYSIN     78400020
         B     WRITEMES                 GO TO WRITE MESSAGE             78480020
NOCARD   MVI   COMPCODE,CC16            SET COMPLETION CODE TO 16       78560020
         MVI   MESSCODE,MC05            SET MESSAGE CODE TO INDICATE    78640020
*                                          MISSING CONTROL CARD         78720020
         B     WRITEMES                 GO TO WRITE MESSAGE             78800020
         SPACE                                                          78880020
* THIS SECTION ISSUES A SYNADAF MACRO FOR AN I/O ERROR ON SYSPRINT      78960020
SYSSYNAD MVC   WTOLIST(L76),WTOLS       MOVE LIST FORM TO WORK AREA     79040020
         LR    FOUR,PARMA               SAVE REGISTER                   79120020
         LA    PARMB,WTOLIST            PREPARE TO ISSUE MACRO          79200020
         WTO   MF=(E,(1))                                               79280020
         LR    PARMA,FOUR               RESTORE REGISTER                79360020
         SYNADAF   ACSMETH=QSAM,PARM1=DCBSYP,PARM2=(0)                  79440020
         MVC   WTOLIS12(L26),D49(PARMB) MOVE IN FIRST PART OF MESSAGE   79520020
         MVC   MSGWTO(L53),D75(PARMB)   SAVE LAST PART OF MESSAGE       79600020
         MVI   WTOLIS38,BLANK           CLEAR REST OF MESSAGE AREA      79680020
         MVC   WTOLIS39(L36),WTOLIS38                                   79760020
         MVI   COMPCODE,CC16            SET COMPLETION CODE TO 16       79840020
         SYNADRLS                                                       79920020
         LA    PARMB,WTOLIST            PREPARE TO ISSUE MACRO          80000020
         WTO   MF=(E,(1))                                               80080020
         MVC   WTOLIS12(L53),MSGWTO     MOVE IN SECOND PART OF MESSAGE  80160020
         MVI   WTOLIS65,BLANK           CLEAR REST OF MESSAGE AREA      80240020
         MVC   WTOLIS66(L9),WTOLIS65                                    80320020
         LA    PARMB,WTOLIST            PREPARE TO ISSUE MACRO          80400020
         WTO   MF=(E,(1))                                               80480020
         B     ENDCARD                  GO TO CLOSE OUT                 80560020
INVALIDS MVI   COMPCODE,CC16            SET COMPLETION AND MESSAGE CODE 80640020
         MVI   MESSCODE,MC0B               FOR INVALID DEB EXTENTS      80720020
         B     WRITEMES                 WRITE ERROR MESSAGE             80800020
PREPMESS MVI   COMPCODE,CC00            SET COMPLETION CODE TO 00 -     80880020
*                                          THERE IS NO ERROR            80960020
         MVI   MESSCODE,MC15            RECORD NOT IN ERROR             81040020
         B     WRITEMES                 WRITE MESSAGE                   81120020
TOOFEW   MVI   COMPCODE,CC16            SET MESSAGE COMPLETION CODES    81200020
         MVI   MESSCODE,MC0C            FOR TO FEW CHARACTERS           81280020
         B     WRITEMES                 WRITE ERROR MESSAGE             81360020
READJL   RDJFCB (,),MF=L                READJ FOR SYSUT1                81440020
OPENLS   OPEN  (,OUTPUT),MF=L           OPEN FOR SYSPRINT               81520020
CLOSELS  CLOSE (,),MF=L                 CLOSE FOR SYSPRINT              81600020
OPENL2   OPEN  (,INOUT),MF=L            OPEN FOR SYSUT1                 81680020
OPENL1   OPEN  (,INPUT),MF=L            OPEN FOR SYSIN                  81760020
CLOSEL   CLOSE (,,,),MF=L               CLOSE FOR SYSIN, SYSUT1         81840020
GETL     GETMAIN  EC,MF=L               LIST FORM FOR GETMAIN           81920020
WTOLS    WTO   'IEH924I    MESSAGE TEXT PROVIDED BY SYNADAF MACRO  COMP*82000020
               LETION CODE = 16',MF=L,ROUTCDE=(11),DESC=(7)             82080020
DCBDATA  DCB   DSORG=PS,MACRF=(E),DDNAME=SYSUT1                         82160020
DCBIN    DCB   DSORG=PS,MACRF=GL,DDNAME=SYSIN,EODAD=NOCARD,            *82240020
               EXLST=DCBXLST,SYNAD=SYSINSYN,RECFM=FB,LRECL=80           82320020
DCBPRINT DCB   DSORG=PS,MACRF=PM,DDNAME=SYSPRINT,EXLST=DCBEX2,         *82400020
               SYNAD=SYSSYNAD,RECFM=FBA,LRECL=121                       82480020
DCBXLST  DS    0F                       SYSIN DCB                       82560020
         DC    X'85'                       EXIT                         82640020
         DC    AL3(DCBEXIT)                LIST                         82720020
DCBEX2   DS    0F                       SYSPRINT DCB                    82800020
         DC    X'85'                       EXIT                         82880020
         DC    AL3(PRINTCK)                LIST                         82960020
MESSTBLA DC    A(MESSTBL)               ADCON FOR MESSAGE CSECT         83040020
IONUMBER DC    CL8'IEH910I'             MESSAGE NUMBER FOR I/O ERROR    83120020
COMPMESS DC    CL24'COMPLETION CODE=16     ' SPECIAL MESSAGE            83200020
XTMN     DC    X'1F1C1F1E1F1E1F1F1E1F1E1F'   DAYS IN MONTH              83280020
ZONEMASK DC    8XL2'2020'               E ZONE TO C ZONE CONVERT        83360020
PAGEEQ   DC    CL4'PAGE'                HEADING                         83440020
UTNAME   DC    CL8'IEHATLAS'               CONSTANTS                    83520020
VTOC     DC    CL5'VTOC='               CONTROL CARD                    83600020
TRACK    DC    CL6'TRACK='                 KEYWORDS                     83680020
TRANSTB  DC    C'0123456789ABCDEF, '    TRANSLATE TABLE FOR CONVERSION  83760020
*                                          OF HEX TO PRINTABLE CHAR     83840020
         DS    0D                                                       83920020
CCW1     CCW   X'31',COUNT-SAVE1,X'40',5  SEARCH EQUAL ID               84000020
CCW2     CCW   X'08',CCWAR1-SAVE1,0,0    TIC BACK TO SEARCH             84080020
CCW3     CCW   X'0D',0,X'40',0          WRITE KEY DATA                  84160020
CCW4     CCW   X'31',COUNT-SAVE1,X'40',5  SEARCH EQUAL ID               84240020
CCW5     CCW   X'08',CCWAR4-SAVE1,0,0   TIC BACK TO SEARCH              84320020
CCW6     CCW   X'0E',0,X'30',1          READ KEY DATA                   84400020
TABLE    DC    193X'10'                 TABLE                           84480020
         DC    X'0A0B0C0D0E0F'             TO                           84560020
         DC    41X'10'                        CONVERT                   84640020
         DC    X'00010203040506070809'           TO                     84720020
         DC    6X'10'                               HEX                 84800020
DEBNMEXT EQU   16                       *                               84880020
DEBDASD  EQU   32                       *                               84960020
DEBSTRCC EQU   6                        *                               85040020
DEBENDCC EQU   10                       *                               85120020
DEBSTRHH EQU   8                        *                               85200020
DEBENDHH EQU   12                       *                               85280020
DEBOFLGS EQU   8                        *                               85360020
NEXTEXT  EQU   16                       *                               85440020
FW8      DC    F'8'                     *                               85520020
FW40     DC    F'40'                    *                               85600020
HW20     DC    H'20'                    *                               85680020
HW10     DC    H'10'                    *                               85760020
IEHWORK  DSECT                                                          85840020
SAVE1    DS    1F                       PL/1                            85920020
SAVE10   EQU   SAVE1+0*255              *                               86000020
SAVE11   EQU   SAVE1+1*255              *                               86080020
SAVE12   EQU   SAVE1+2*255              *                               86160020
SAVE13   EQU   SAVE1+3*255              *                               86240020
SAVE14   EQU   SAVE1+4*255              *                               86320020
SAVE15   EQU   SAVE1+5*255              *                               86400020
SAVE110  EQU   SAVE1+1+0*255            *                               86480020
SAVE111  EQU   SAVE1+1+1*255            *                               86560020
SAVE112  EQU   SAVE1+1+2*255            *                               86640020
SAVE113  EQU   SAVE1+1+3*255            *                               86720020
SAVE114  EQU   SAVE1+1+4*255            *                               86800020
SAVE115  EQU   SAVE1+1+5*255            *                               86880020
SAVE1BK  DS    1F                       BACK CHAIN POINTER              86960020
SAVE1FD  DS    1F                       FORWARD CHAIN POINTER           87040020
         DS    15F                      REGISTER SAVE AREA              87120020
TRACKADR DS    1D                       TRACK ADDRESS OF BAD RECORD     87200020
TRACKAD2 EQU   TRACKADR+2               *                               87280020
TRACKAD4 EQU   TRACKADR+4               *                               87360020
TRACKAD6 EQU   TRACKADR+6               *                               87440020
COUNT    DS    1D                       COUNT OF BAD RECORD             87520020
COUNT2   EQU   COUNT+2                  *                               87600020
COUNT5   EQU   COUNT+5                  *                               87680020
COUNT6   EQU   COUNT+6                  *                               87760020
GETLS    DS    2D                       FOR GETMAIN                     87840020
GETLS4   EQU   GETLS+4                  *                               87920020
DCBSYS1  DS    25F                      SYSUT1 DCB                      88000020
DCBSYSIN DS    25F                      SYSIN DCB                       88080020
DCBSYP   DS    25F                      SYSPRINT DCB                    88160020
REENTAR  DS    9F                       WORK AREA                       88240020
GOTCORE  DS    1F                       SAVE GOTTEN CORE POINTER        88320020
MESSAGEC DS    CL1                      MESSAGE CONTROL CHARACTER       88400020
MESSAGE  DS    CL120                    MESSAGE AREA                    88480020
MESSAGE1 EQU   MESSAGE+1                *                               88560020
MESSAGE2 EQU   MESSAGE+2                *                               88640020
MESSAGE3 EQU   MESSAGE+3                *                               88720020
MESSAGE8 EQU   MESSAGE+8                *                               88800020
MESSAG61 EQU   MESSAGE+61               *                               88880020
MESSAG96 EQU   MESSAGE+96               *                               88960020
HEADERC  DS    CL1                      HEADER CONTROL CHARACTER        89040020
HEADER   DS    CL30                     HEADER AREA                     89120020
HEADER1  EQU   HEADER+1                 *                               89200020
HEADER90 EQU   HEADER+90                *                               89280020
HEADER92 EQU   HEADER+92                *                               89360020
HEADER93 EQU   HEADER+93                *                               89440020
HEADER95 EQU   HEADER+95                *                               89520020
HEADER96 EQU   HEADER+96                *                               89600020
HEADR105 EQU   HEADER+105               *                               89680020
HEADR110 EQU   HEADER+110               *                               89760020
NAMESLOT DS    CL90                     DSNAME AREA FROM SYSUT1         89840020
TARGET   DS    1D                       DATE HOLDER                     89920020
CONVERT  DS    1D                       WORK AREA                       90000020
CONVERT1 EQU   CONVERT+1                *                               90080020
CONVERT2 EQU   CONVERT+2                *                               90160020
CONVERT4 EQU   CONVERT+4                *                               90240020
DOUBLE   DS    1D                       *                               90320020
DOUBLE4  EQU   DOUBLE+4                 *                               90400020
DOUBLE5  EQU   DOUBLE+5                 *                               90480020
DOUBLE6  EQU   DOUBLE+6                 *                               90560020
DOUBLE8  EQU   DOUBLE+8                 *                               90640020
DOUBLE10 EQU   DOUBLE+10                *                               90720020
SECONDEX DS    0F                       *                               90800020
         DS    1D                       *                               90880020
SECONDX1 EQU   SECONDEX+1               *                               90960020
JFCBADR  DS    CL176                    JFCB FOR SYSUT1                 91040020
JFCBADR1 EQU   JFCBADR+1                *                               91120020
JFCBTSDM EQU   JFCBADR+52               *                               91200020
ECB      DS    1F                       ECB FOR UTILITY                 91280020
IOB      DS    8F                       IOB FOR UTILITY                 91360020
IOBECB   EQU   IOB+4                    ADDRESS OF ECB                  91440020
IOBSTART EQU   IOB+16                   CHANNEL PROGRAM START ADDRESS   91520020
IOBSENS1 EQU   IOB+3                    *                               91600020
IOBCSWST EQU   IOB+12                   *                               91680020
SEEK     DS    2F                       SEEK ADDRESS FOR REPLACEMENT    91760020
*                                          RECORD                       91840020
SEEK1    EQU   SEEK+1                   *                               91920020
WTOLIST  DS    19F                      LIST FORM FOR WTO               92000020
WTOLIS12 EQU   WTOLIST+12               *                               92080020
WTOLIS38 EQU   WTOLIST+38               *                               92160020
WTOLIS39 EQU   WTOLIST+39               *                               92240020
WTOLIS65 EQU   WTOLIST+65                                               92320020
WTOLIS66 EQU   WTOLIST+66                                               92400020
MSGWTO   DS    14F                      MESSAGE AREA FOR WTO            92480020
         DS    0D                                                       92560020
CCWAR1   DS    1F                       SEARCH EQUAL ID                 92640020
CCWAR11  EQU   CCWAR1+1                                                 92720020
CCWAR1AD DS    1F                       *                               92800020
CCWAR2   DS    1F                       TIC TO SEARCH                   92880020
CCWAR21  EQU   CCWAR2+1                                                 92960020
CCWAR2AD DS    1F                       *                               93040020
CCWAR3   DS    1F                       WRITE                           93120020
CCWAR31  EQU   CCWAR3+1                                                 93200020
CCWAR3AD DS    1F                       *                               93280020
CCWAR3A2 EQU   CCWAR3AD+2                                               93360020
CCWAR4   DS    1F                       SEARCH EQUAL ID                 93440020
CCWAR41  EQU   CCWAR4+1                                                 93520020
CCWAR4AD DS    1F                       *                               93600020
CCWAR5   DS    1F                       TIC TO SEARCH                   93680020
CCWAR51  EQU   CCWAR5+1                                                 93760020
CCWAR5AD DS    1F                       *                               93840020
CCWAR6   DS    1F                       READ                            93920020
CCWAR61  EQU   CCWAR6+1                                                 94000020
CCWAR6AD DS    1F                       *                               94080020
CCWAR6A2 EQU   CCWAR6AD+2              LENGTH OF READ         OX02345   94130003
RECSIZE  DS    1F                       SIZE OF RECORD BEING REPLACED-  94160020
*                                          USED BY GET & FREEMAIN       94240020
KEYSIZE  DS    1H                       KEY SIZE AREA                   94320020
KEYDATA  DS    1H                       KEY + DATA SIZE AREA            94400020
CCWCOUNT DS    1H                       TOTAL SIZE-COUNT+KEY+DATA       94480020
COMPCODE DS    CL1                      COMPLETION CODE AREA            94560020
MESSCODE DS    CL1                      MESSAGE CODE                    94640020
TRKOVFL  DS    CL1                      TRACK OVERFLOW SWITCH           94720020
PAGENO   DS    1F                       PAGE NUMBER HOLD AREA           94800020
LINECT   DS    1H                       LINE COUNT HOLD AREA            94880020
PARMLIST DS    2F                       LIST FOR PARAMETERS FOR SVC     94960020
PARMLIS4 EQU   PARMLIST+4                                               95040020
SYSINDD  DS    1D                       USER-SUPPLIED SYSIN DDNAME      95120020
PRINTDD  DS    1D                       USER-SUPPLIED SYSPRINT DDNAME   95200020
SYSUT1DD DS    1D                       USER-SUPPLIED SYSUT1 DDNAME     95280020
SAVEPAR  DS    1F                       PAGENO PARAMETER ADDRESS        95360020
DEVFEAT  DS    2F                       DEVICE CHARACTERISTICS          95440020
DEVFEAT1 EQU   DEVFEAT+1                                                95520020
TEMP     DS    1F                       TEMPORARY STORAGE               95600020
TEMP1    EQU   TEMP+1                                                   95680020
RETPARM  DS    1F                       RETURN PARAMETER FORM SVC       95760020
ID       DS    5C                       SEARCH ID FIELD IF TRACK OVER-  95840020
ID4      EQU   ID+4                                                     95920020
*                                          FLOW IS USED                 96000020
SPLIT    DS    1C                       SPLIT CYLINDER SWITCH           96080020
         DCBD  DSORG=(PS)                                               96160020
         END   IEHATLAS                                                 96240020
