         TITLE 'IEHDANAL DISK/DRUM ANALYSIS AND FORMAT MODULE.'         00081016
         COPY  LCGASMSW                                                 00081100
*          RELEASE 21 DELETIONS/CHANGES                                 00081321
*                                                               XM4389  00083403
* 1251136400-136560                                             A46360  00086703
*                                                                A44094 00088803
*1251878880-879040                                               A43248 00090903
*1251                                                            M0137  00093003
*304320 - 304360                                                 M0967  00095103
*        RELEASE 20 DELETIONS                                         * 00097203
*3463954400                                                      M4683  00099303
*3463                                                            A35813 00101403
*3463953600-954400                                               M3966  00103503
*3463825000                                                      M5900  00105603
*3463000820,924000,954400                                        JUDITH 00107703
*3463275320                                                      M5723  00109803
*3463275800                                                      A35837 00111903
*3463084000-084800,275800                                        S20201 00114003
*3463953600-954400                                               S20201 00116103
*                                                                M4682  00118203
*        RELEASE 18 DELETIONS                                           00120303
*1453152800,238400,240800                                        1352   00122403
*                                                                       00124503
*STATUS CHANGE LEVEL 003                                                00126603
*FUNCTION/OPERATION- THIS ROUTINE PERFORMS SURFACE ANALYSIS AND         00128703
*   FORMATTING OF ALL OS 360 SUPPORTTED DIRECT ACCESS DEVICES EXCEPT  * 00130803
*   THE 2321 DATA CELL. (DATA CELL ANALYSIS IS PERFORMED BY IEHDCELL) * 00132903
*   SURFACE ANALYSIS CONSISTS OF WRITING AND READING A SERIES OF BIT  * 00135003
*   PATTERNS. THREE DIFFERENT BIT PATTERNS ARE WRITTEN AND READ ON  A * 00137103
*   TRACK. FOR DISK THESE PATTERNS ARE 1) A FULL TRACK OF X'55'S,     * 00139203
*   2) A FULL TRACK OF X'00'S AND 3) A STANDARD 16 BYTE R0. FOR A     * 00141303
*   DRUM DEVICE ONLY THE FIRST PATTERN IS DIFFERENT WHICH IS X'5A'S.  * 00143403
*   THIS ROUTINE CAN ANALYZE BOTH PRE-ANALYZED AND UNANALYZED DEVICES * 00145503
*   FOR UNANALYZED DEVICES,DRUMS AND PREFLAGGED TRACK TESTING  SUP-   * 00147603
*   PRESSED THE FIRST CCW IN SURFACE ANALYSIS CHANNEL PROGRAM IS      * 00149703
*   MODIFIED FROM A SERACH HOME ADDRESS TO A WRITE HOME ADDRESS.      * 00151803
*   THIS ROUTINE ALSO WRITES AND READ STANDARD R0 WITHOUT PERFORMING  * 00153903
*   SURFACE WHENEVER FORMAT IS REQUESTED.                             * 00156003
*                                                                     * 00158103
*ENTRY POINTS- THE ONLY ENTRY POINT IS IEHDANAL AND CONTROL IS ALWAYS * 00160203
*   RECEIVED FROM THE MONITOR (IEHDASDS).                             * 00162303
*                                                                     * 00164403
*INPUTS- UPON ENTRY REGISTER 10 POINTS TO A FUNCTION BLOCK, REGISTER  * 00166503
*   12 POINTS TO A COMMUNICATION WORKAREA,REGISTER 13 HAS A POINTER   * 00168603
*   TO A REGISTER SAVE AREA,AND REGISTER 14 HAS THE RETURN ADDRESS.   * 00170703
*EXITS-NORMAL- A SUCCESSFUL COMPLETION RESULTS IN A RETURN TO THE     * 00172803
*   MONITOR(IEHDASDS) WITH A 0 RETURN CODE AND A COMPLETE MESSAGE IN  * 00174903
*   THE MESSAGE DATA SET.                                             * 00177003
*                                                                     * 00179103
*EXITS-ERROR- ANY UNSUCCESSFUL COMPLETION RESULTS IN A RETURN TO THE  * 00181203
*   MONITOR(IEHDASDS) WITH THE APPROPRIATE MESSAGE(S) DESCRIBING THE  * 00183303
*   ERROR CONDITIONS.                                                 * 00185403
*                                                                       00187503
*EXTERNAL ROUTINES- THIS ROUTINE IS ALWAYS INVOKED BY THE MONITOR.    * 00189603
*   IT IN TURN INVOKES THE FOLLOWING EXTERNAL ROUTINES.               * 00191703
*        1) THE RESIDENT CONVERT ROUTINES(CVTPCNVT AND CVTPRLTV) TO   * 00193803
*           CONVERT TTR TO MBBCCHHR AND VICE VERSA.                   * 00195903
*        2) IEHDPASS TO PERFORM PASSWORD PROTECTION CHECKS.           * 00198003
*        3) IEHDCELL TO PERFORM SURFACE ANALYSIS ON THE 2321 DATA CELL* 00200103
*        4) IEHDVTOC TO FORMAT AND WRITE THE VTOC,IPL TEXT,AND TRACK  * 00202203
*           ZERO.                                                     * 00204303
*        5) IEHDMSGB TO CONSTRUCT MESSAGES IN A MESSAGE BUFFER.       * 00206403
*        6  IEHDPRNT TO WRITE MESSAGES IN A MESSAGE DATA SET          * 00208503
*        7) SVC 82 TO ASSIGN ALTERNATE TRACKS,POST UCB'S AND CONSTRUCT* 00210603
*           DEB FOR UNANALYZED DEVICES.                               * 00212703
*TABLES/WORKAREAS- REGISTER 10 AND 12 POINT TO A FUNCTION BLOCK AND A * 00214803
*   WORKAREA RESPECTIVELY.                                            * 00216903
*        1) IODEVCON- DEVICE CONSTANT TABLE,DESCRIBED BY CONSTANT     * 00219003
*           DSECT.                                                    * 00221103
*        2) FUNCTION BLOCK- DESCRIBED BY FUNCBLK DSECT                * 00223203
*        3) COPY BLOCK- DESCRIBED BY COPYBLK DSECT.                   * 00225303
*        4) COMMUNICATION VECTOR TABLE- DESCRIBED BY CVT DSECT        * 00227403
*        5) COMMUNCATION WORK AREA- DESCRIBED BY WORK DSECT.          * 00229503
*        6) IEHDANAL WORK AREA- DESCRIBED BY WORKAREA DSECT.          * 00231603
*        7) TRACK ANALYSIS BUFFER- DESCRIBED BY BUFFCORE DSECT.       * 00233703
         EJECT                                                          00235803
REG0     EQU   0                                                        00237903
REG1     EQU   1                  PARAMETER LIST POINTER REG.           00240016
REG2     EQU   2                  UCB POINTER REG.                      00320016
REG3     EQU   3                  COPY BLOCK POINTER REG.               00400016
REG4     EQU   4                  I/O DEV CON TABLE POINTER.            00480016
REG5     EQU   5                                                        00560016
REG7     EQU   7                  BUFFER CORE POINTER.                  00640016
REG8     EQU   8                  CVT POINTER.                          00720016
REG9     EQU   9                                                        00800016
REGA     EQU   10                                                       00880016
REGB     EQU   11                                                       00960016
REGC     EQU   12                 COMMON WORK AREA BASE.                01040016
REGD     EQU   13                 SAVE AREA REGISTER.                   01120016
REGE     EQU   14                 RETURN REGISTER.                      01200016
REGF     EQU   15                 ENTRY POINT REG/CONTROL BLOCK PTR.    01280016
BASEREG  EQU   6                  PROGRAM BASE REGISTER.                01360016
WORKREG  EQU   5                                                        01440016
FBLKREG  EQU   10                 FUNCTION BLOCK BASE.                  01520016
IEHDANAL CSECT                                                          01600016
* 276000                                                           O122 01640019
         USING *,BASEREG                                                01680016
         USING WORKAREA,WORKREG                                         01760016
         USING WORK1,REGC                                               01840016
         USING BUFFCORE,REG7                                            01920016
         USING FUNCBLK,FBLKREG                                          02000016
         USING CVT,REG8                                                 02080016
         USING CONSTANT,REG4                                            02160016
         USING COPYBLK,REG3                                             02240016
         SAVE  (14,12),T,*        SAVE REGISTER FOR CALLING ROUTINE.    02320016
         LR    BASEREG,REGF       ESTABLISH PROGRAM ADDRESSABILITY.     02400016
         L     REG4,PTRCFUNC      GET POINTER TO CURRENT FUNCTION.      02480016
         TM    0(REG4),PROCESS    WAS THIS FUNCTION PREVIOUSLY STARTED. 02560016
         BZ    GETUCB             NO-BR AND CONTINUE INIALIZATION.      02640016
         L     REGD,SAVEPTR       YES-GET POINTER TO MY SAVE AREA.      02720016
         LM    REGE,REGC,12(REGD) RESTORE MY REGISTERS.                 02800016
         B     RETURNAD                                                 02880016
         EJECT                                                          02930003
*                                                                       02960016
**********************************************************************  03040016
*                                                                       03120016
*   THIS ROUTINE PERFORM THE FOLLOWING FUNCTIONS:                       03200016
*              1. TEST TO SEE IF THE DEVICE CAN BE ANALYZED/FORMATTED.  03280016
*              2. CONVERTS THE EXTENTS FROM UNPACKED DECIMAL TO BINARY. 03360016
*              3. GETS CORE FOR A WORK AREA.                            03440016
*                                                                       03520016
**********************************************************************  03600016
*                                                                       03680016
         USING UCBOB,REG2                                               03760016
GETUCB   EQU   *                                                        03840016
         XC    RETCODE,RETCODE          CLEAR RETURN CODE.      SA59746 03890021
         GETMAIN R,LV=SIZE                                              03920016
         LR    WORKREG,REG1       SET UP REGISTER FOR WORK AREA.        04000016
         XC    WKBUFPTR(8),WKBUFPTR  CLEAR PTR & SIZE OF COND WKAREA.   04080016
         ST    REGD,OLDSAPTR      SAVE POINTER TO OLD SAVE AREA         04160016
         LA    REGF,SAVEAREA                                            04240016
         ST    REGF,8(REGD)       SAVE POINTER TO THIS SAVE AREA        04320016
         LR    REGD,REGF          IN CALLING PROGRAM SAVE AREA.         04400016
         L     REG2,TUCBPTR       GET UCB OF DEVICE TO BE PROCESSED.    04480016
         AIF   ('&LIB' EQ 'LIB2').X227202                       XL03912 04530003
         CLI   UCBID,X'FF'        IS THIS A 2321                        04560016
         BE   NOTDCELL            NO-BYPASS MAIN UCB CALCULATION        04640016
         MVI   FUNCSW,ANALYSIS    SET ANALYZE INDICATOR ON.             04720016
         LA    REG0,SRTEUSER-UCBOB     GET SIZE OF MAIN UCB             04800016
         DROP  REG2                                                     04880016
         USING DATACELL,REG2                                            04960016
         LH    REGF,DCELBBNR      GET BIN NUMBER                        05040016
         SLL   REGF,4             GET LENGTH OF SUB UCBS                05120016
         ALR   REGF,REG0                                                05200016
         SR    REG2,REGF          GET POINTER TO MAIN UCB               05280016
         DROP  REG2                                                     05360016
         USING UCBOB,REG2                                               05440016
NOTDCELL EQU   *                                                        05520016
.X227202 ANOP                                                   XL03912 05560003
         TM    UCBTBYT3,UCB3DACC  IS THIS A DIRECT ACCESS DEVICE.       05600016
         BZ    BADEVICE           NO-PREPARE FOR ERROR RETURN.          05680016
         TM    SRTESTAT,SRTESYSR  IS THIS VOLUME SYSTEM RESIDENT.       05760016
         BO    VOLUMERR           YES-SET UP ERROR MSG.                 05840016
         TM    UCBTBYT2,UCB2OPT3   DO WE HAVE CARNY             XM4389  05850003
         BZ    CARNOT              NO                            S20201 05860020
         OI    SEQSW+D1,RPS                                     XM4389  05870003
CARNOT   EQU   *                        *                        S20201 05880020
         NI    FVTOCPTR+4,X'CF'   SET PROPER SIGN IN VTOC BEGIN.        05920016
         PACK  PRGSAVE(8),FVTOCPTR(5)  PACK INPUT VTOC RTA.             06000016
         CVB   REG0,PRGSAVE       CONVERT PACKED RTA TO BINARY          06080016
         ST    REG0,RTAVTOCS      SAVE RTA OF BEGIN OF VTOC.            06160016
         LA    REG3,1                                                   06240016
         LTR   REG0,REG0          TRACK REQUESTED FOR VTOC.             06320016
         BZ    BADTRADD           YES-SET UP ERROR CONDITION.           06400016
         AIF   ('&LIB' EQ 'LIB2').X227203                       XL03912 06440003
         TM    SEQSW,IPLDD        WAS IPL TEXT REQUESTED.               06480016
         BZ    TRAKOKAY         NO-CONTINUE PROCESSING.                 06560016
         CR    REG0,REG3        VTOC STARTING TRACK GREATER THAN ONE.   06640016
         BH    TRAKOKAY           YES-CONTINUE PROCESSING.              06720016
         CLI   UCBTBYT4,1         IS THIS A2311.                        06800016
         BE    BADTRADD           YES-SET UP ERROR CONDITION.           06880016
         CLI   UCBTBYT4,3         IS THIS A 2303.                       06960016
         BE    BADTRADD           YES-SET UP ERROR CONDITION.           07040016
TRAKOKAY EQU   *                                                        07120016
.X227203 ANOP                                                   XL03912 07160003
         BAL   REG3,CONVERT       CONVERT RTA TO CCHH.                  07200016
         MVC   MBBCCHH1(4),MBBCCHH2+3  SAVE BEGIN CCHH.                 07280016
         NI    FEXTENT+4,X'CF'    SIGN PROPER SIGN IN VTOC LENGTH.      07360016
         PACK  PRGSAVE(8),FEXTENT(5)  PACK INPUT VTOC LENGTH.           07440016
         CVB   REG0,PRGSAVE       CONVERT CTOC LENGTH TO BINARY.        07520016
         ST    REG0,WKBUFPTR       SAVE NUMBER OF TRACKS IN VTOC.       07600016
         LTR   REG0,REG0          ZERO NUMBER OF TRACKS IN VTOC.        07620016
         BZ    BADTRADD           YES-SET UP ERROR CONDITION.           07640016
         A     REG0,RTAVTOCS      COMPUTE ENDING RTA OF VTOC.           07680016
         BCTR  REG0,0             DECREMENT UPPER EXTENT.               07760016
         ST    REG0,RTAVTOCE      SAVE RTA OF END OF VTOC.              07840016
         LR    REG1,REG5          PASS POINTER TO WORKAREA TO IEHDVTOC. 07920016
         STM   REG9,REG2,PRGSAVE  SAVE REGS FOR CONVERT ROUTINE.        08000016
         BAL   REG3,CONVERT2      CONVERT VTOC END RTA TO CCHH.         08080016
         MVC   MBBCCHH1+4(4),MBBCCHH2+3                                 08160016
         L     REG9,LASTORIG                                            08240016
         A     REG9,CONVCYL       GET CCHH OF 1ST ALTERNATE TRACK.      08320016
         AIF   ('&LIB' EQ 'LIB2').X227204                       XL03912 08360003
         CLI   UCBTBYT4,X05            IS THIS A 2321.           S20201 08400020
         BNE   NO2321              NO                            S20201 08480020
         MVC   PRGSAVE(3),LASTORIG     SET UP LAST PRIMARY CONSTANT.    08560016
         LA    REG9,256                                                 08640016
         STC   REG9,PRGSAVE+3      SET TO START OF NEXT CYL.            08720016
         CLI   PRGSAVE+2,4        TEST FOR LAST CYLINDER ON STRIP.      08800016
         BL    ADDCONST           NO-INCREMENT TO NEXT CYL.             08880016
         STC   REG9,PRGSAVE+2      START OF NEXT STRIP.                 08960016
         SLL   REG9,8              SHIFT CONSTANT TO UP STRIP.          09040016
         CLI   PRGSAVE+1,9        TEST FOR LAST STRIP ON SUBCELL.       09120016
         BL    ADDCONST           NO- INCREMENT TO NEXT STRIP.          09200016
         STC   REG9,PRGSAVE+1     YES-SET TO START OF SUBCELL           09280016
         SLL   REG9,8             SHIFT CONSTANT TO UP SUBCELL.         09360016
ADDCONST EQU   *                                                        09440016
         A     REG9,PRGSAVE       INCREMENT PROPER FIELD IN CCHH.       09520016
NO2321   EQU   *                                                        09600016
.X227204 ANOP                                                   XL03912 09640003
         ST    REG9,PRGSAVE       SAVE CCHH FOR LATER USE IN BLDIOBLK.  09680016
         L     REG4,IODEVCON      GET PTR TO DEVICE CONSTANT TABLE.     09760016
         ST    REG9,FALTDATA      INSERT START ALTERNATE TRACK          09840016
         MVC   FALTDATA+4(2),TOTALALT  AND TOTAL NO OF ALTERNATE TRKS.  09920016
*                                                                       10000016
         LA    REG9,WORKBUFF      GET SIZE OF WORK BUFFER               10080016
         AH    REG9,SACAP         ADD SIZE OF TRACK                     10160016
         SRL   REG9,3                                                   10240016
         SLL   REG9,3                                                   10320016
         LA    REG9,16(REG9)      ALIGN SIZE TO A DOUBLE WORD           10400016
         ST    REG9,WKBUFSI                                             10480016
         LA    REG7,FBUFFPTR      POINTER TO AREA TO STORE BUFFER ADDR  10560016
         GETMAIN EC,LV=(REG9),A=(REG7)                                  10640016
         LTR   REGF,REGF          WAS THE DESIRED CORE AVAILABLE        10720016
         BNE   NOCORIND           NO-INDICATE CORE WAS NOT AVAILABLE    10800016
         L     REG7,FBUFFPTR      GET POINTER TO BUFFER WORKAREA        10880016
         EJECT                                                          10930003
**********************************************************************  10960016
*                                                                       11040016
*    HERE WE DETERMINE IF COPIES ARE TO BE MADE.                        11120016
*                                                                       11200016
**********************************************************************  11280016
*                                                                       11360016
         L     REG3,COPYPTR       PICK UP POINTER TO THE COPY BLOCK     11440016
NEXTCOPY EQU   *                                                        11520016
         LTR   REG3,REG3      ARE THERE MORE COPIES TO BE MADE.         11600016
         BNZ   COPYES             YES- TEST FOR LIKE DEVICE TYPE.       11680016
         L     REG3,COPYPTR       POINT TO THE 1ST COPY BLOCK.          11760016
MVEBLOKS EQU   *                                                        11840016
         USING IHADCB,REGF                                              11920016
         LA    REGF,FBLOCKS       POINT TO THE FUNCTION BLOCK AREA.     12000016
         BAL   REGE,BLDIOBLK      BUILD I/O BLOCKS IN FUNCTION BLOCK.   12080016
         MVC   DCBDDNAM(8),DDNAME2     INSERT DDNAME.                   12160016
         L     REG3,COPYPTR                                             12240016
BLDCOPY  EQU   *                                                        12320016
         LTR   REG3,REG3          TEST FOR MORE COPIES.                 12400016
         BZ    LASTCOPY       NO-GO TEST FOR A NEW VOLUME.              12480016
         LA    REGF,CIOBLOCK      SET UP BASE FOR CONTROL BLOCKS.       12560016
         BAL   REGE,BLDIOBLK      BUILD I/O BLOCKS IN COPY BLOCKS.      12640016
         MVC   DCBDDNAM(8),DDNAME3     PLACE DDNAME INTO COPY DCB.      12720016
         L     REG3,CCOPYPTR      GET POINTER TO NEXT COPY BLK.         12800016
         B     BLDCOPY                                                  12880016
BLDIOBLK EQU   *                  THIS SUBR CONSTRUCTS ECB,IOB AND DCB. 12960016
         MVC   0(72,REGF),DCBCONST     RELOCATE CONTROL BLOCKS.         13040016
         MVC   SEEKADDR+3(4),PRGSAVE SET 1ST ALTERNATE TRK IN IOB.      13120016
         ST    FBLKREG,DCBIOBAD   STORE POINTER TO FBLOCK IN DCB.       13200016
         XC    WKAECB(40),WKAECB  INITIALIZE ECB/IOB.                   13280016
         MVI   WKAIOB,X'42'       SET CMND CHN UNRELATED REQ.           13360016
         LA    REG0,WKAECB                                              13440016
         ST    REG0,ECBADD        ECB POINTER INTO COPY BLK.            13520016
         ST    REGF,DCBADD        DCB POINTER INTO COPY BLK.            13600016
         TM    SEQSW+D1,RPS        IS CARN HERE                 XM4389  13608003
         BZ    NOTCARN             NO                            S20201 13616020
          LA    REG0,CCWSECON           SET UP POINTER TO SET    A46360 13624021
*                                       SECTOR                   A46360 13628021
         ST    REG0,CCWPTR         PUT IN IOB                    S20201 13632020
         B     CARNY                   CONTINUE PROCESS.         S20201 13664020
NOTCARN  EQU   *                        *                        S20201 13672020
         LA    REG0,CCW1CONS                                            13680016
         ST    REG0,CCWPTR        CCW POINTER INTO IOB.                 13760016
CARNY    EQU   *                        *                        S20201 13800020
         MVI   BLKERRCT+1,X'01'                                         13840016
         BR    REGE               RETURN.                               13920016
         EJECT                                                          13970003
*                                                                       14000016
**********************************************************************  14080016
*                                                                       14160016
COPYES   EQU   *   THIS ROUTINE IS ENTERED WHEN COPIES ARE REQUESTED,   14240016
*                  TO DETERMINE IF THE DEVICES ARE ALIKE AND USEABLE.   14320016
*                                                                       14400016
**********************************************************************  14480016
*                                                                       14560016
         L     REG9,CUCBPTR       GET COPY BLOCK UCB POINTER.           14640016
         AIF   ('&LIB' EQ 'LIB2').X227205                       XL03912 14680003
         CLI   UCBID-UCBOB(REG9),X'FF' IS THIS A DATA CELL.             14720016
         BE    NON2321            NO-CHECK FOR LIKE DEVICES             14800016
         LA    REG1,21                                                  14880016
         B     SETMSG             SET UP ERROR MSG IN OUTPUT BUFFER.    14980016
NON2321  EQU   *                                                        15200016
.X227205 ANOP                                                   XL03912 15240003
         CLC   UCBTBYT3(2),UCBTBYT3-UCBOB(REG9)  ARE DEVICES ALIKE.1352 15280018
         BNE   BADCOPY            NO-SET ERROR MSG.                     15360016
         AIF   ('&LIB' EQ 'LIB1').X227200                       XL03130 15370003
         CLI   UCBTBYT4,WIN             IS THIS A 3340?          XM3782 15372003
         BNE   NOTWIN                   NO, SKIP DEV MOD TEST.   XM3782 15374003
         CLC   ODEVMOD,CDEVMOD          ARE DEVICE MODELS SAME? XL03130 15380003
         BNE   BADCOPY                  NO, SET ERROR MSG.      XL03130 15390003
NOTWIN   EQU   *                                                 XM3782 15392003
.X227200 ANOP                                                   XL03130 15400003
         TM    SRTESTAT-UCBOB(REG9),SRTESYSR  IS THIS SYSTEM RESIDENCE. 15440016
         BO    VOLUMERC           SET UP ERROR MSG.                     15520016
LIKEDEV  EQU   *                                                        15600016
         MVC   CALTDATA(6),FALTDATA  SET UP ALTERNATE DATA IN COPYBLKS. 15680016
         L     REG3,CCOPYPTR      PICK UP POINTER TO NEXT COPY BLOCK    15760016
         B     NEXTCOPY           TEST UCB OF THE COPY FUNCTION         15840016
         EJECT                                                          15890003
*                                                                       15920016
**********************************************************************  16000016
*                                                                       16080016
*  CONSTRUCT DUMMY DEB FOR THE RESIDENT CONVERT ROUTINE (CVTPCNVT)      16160016
*        WHEN THIS ROUTINE IS ENTERED REG0 CONTAINS TT IN RIGHT HALF.   16240016
*        THIS SECTION PERFORM THE INITILIZATION BEFORE CALLING CVTPCNVT 16320016
*                                                                       16400016
**********************************************************************  16480016
*                                                                       16560016
CONVERT  STM   REG9,REG2,PRGSAVE  SAVE VOLATILE REG'S                   16640016
         LA    REG9,KDEVSIZE      PICK UP SIZE OF ENTRIES IN DEVCON TBL 16720016
         L     REG4,IODEVCON      GET POINTER TO THE DEVICE CON TABLE   16800016
         SR    REG8,REG8                                                16880016
         IC    REG8,UCBTBYT4      PICK UP INIT TYPE TO COMPUTE INDEX.   16960016
         AIF   ('&LIB' EQ 'LIB1').X227201                       XL03130 16970003
         CLI   UCBTBYT4,WIN             IS THIS A 3340?         XL03130 16980003
         BNE   GETCON                   NO, GET DEVICE CONSTANT XL03130 16990003
         IC    REG8,ODEVMOD             YES, USE DEV MOD NO.    XL03130 17000003
GETCON   EQU   *                                                XL03130 17010003
.X227201 ANOP                                                   XL03130 17020003
         BCTR  REG8,0                                                   17040016
         MR    REG8,REG8          COMPUTE THE DISPLACEMENT INDEX.       17120016
         AR    REG4,REG9          POINT TO PROPER DEVICE CON ENTRY.     17200016
         ST    REG4,IODEVCON      STORE POINTER TO DEV CON ENTRY.       17280016
CONVERT2 EQU   *                                                        17360016
         SLL   REG0,16            POSITON TT IN HIGH ORDER TWO BYTES.   17440016
         ST    REG2,DUCBPTR       SET UP UCB POINTER.                   17520016
         MVI   DEXTNTNO,1           **   EXTENT NUMBER.                 17600016
         XC    DEXTNTS(4),DEXTNTS  **  BEGIN CCHH.                      17680016
         MVC   DEXTNTE(4),LASTORIG  **   END CCHH                       17760016
         MVC   DEXTNTR(2),TOTALPRM  **   TOTAL PRIMARY TRK              17840016
         LA    REG1,DDEB            **   DUMMY DEB POINTER              17920016
         LA    REG2,MBBCCHH2        **   MBBCCHHR AREA                  18000016
         L     REG8,CVTPTR               RESTORE CVT BASE               18080016
         L     REGF,CVTPCNVT        GET ENTRY POINT.                    18160016
         BALR  REGE,REGF            CALL CONVERT                        18240016
         LM    REG9,REGE,PRGSAVE    RESTORE PART OF VOLATILE REG        18320016
         LTR   REGF,REGF            IS THIS A VALID EXTENT FOR THE VTOC 18400016
         BNZ   BADTRKAD                NO-SET UP ERROR MSG.             18480016
         LM    REGF,REG2,PRGSAVE+24    RESTORE REMAINING REGS.          18560016
         BR    REG3               RETURN.                               18640016
SETUPR0S EQU   *                                                        18720016
         XC    STNDR0(WORKBUFF),STNDR0 CLEAR R0 CONUT AREAS,            18800016
         L     REG0,PRGSAVE       GET CCHH OF TRACK TO BE PROCESSED.    18880016
         LH    REG1,SACAP         GET DATA LENGTH FOR SURFACE ANALYSIS. 18960016
         STM   REG0,REG1,MAXLTHR0 SET MAXIMUM LENGTH R0 COUNT.          19040016
         STM   REG0,REG1,MAXR0BIT SET UP MAXIMUN COUNT FOR BIT PATTERN. 19120016
         LA    REG1,8                                                   19200016
         STM   REG0,REG1,STNDR0 SET UP R0 COUNT (STANDARD).             19280016
         BR    REGE               RETURN TO CALLER.                     19360016
         EJECT                                                          19410003
LASTCOPY EQU   *                                                        19440016
         CLI   DDNAME2,X'40'      IS THIS A NEW VOLUME.                 19520016
         BE    NUVOLUME           YES-TEST FRO VOLUME OFFLINE.          19600016
         LA    REGF,FBLOCKS                                             19680016
OPEN1    EQU   *                                                        19760016
         LA    REG0,RDAREA1       GET ADDRESS OF JFCB READ IN AREA.     19840016
         ST    REG0,LIST          PLACE ADDR IN RDJFCB LIST             19920016
         MVI   LIST,X'87'         SET RDJFCB AND LAST ENTRY INDICATOR.  20000016
         LA    REGE,LIST                                                20080016
         ST    REGE,DCBEXLST      STORE EXIT LIST ADDRESS INTO DCB.     20160016
         BAL   REG8,READJFCB      READ JFCB AND OPEN VTOC.              20240016
         L     REG3,COPYPTR       GET POINTER TO COPY BLOCK             20320016
COPYOPEN EQU   *                                                        20400016
         LTR   REG3,REG3          ANOTHER COPY REQUESTED                20480016
         BZ    NOCOPIES           NO-TEST FOR 2321                      20560016
         LA    REGF,CIOBLOCK      POINT TO DCB.                         20640016
         LA    REGE,LIST          GET POINTER TO DCB EXIT LIST.         20720016
         ST    REGE,DCBEXLST      STORE EXIT LIST ADDR INTO COPY DCB.   20800016
         BAL   REG8,READJFCB      READ JFCB AND OPEN COPY VTOC.         20880016
         L     REG3,CCOPYPTR      GET NEXT COPY BLOCK POINTER           20960016
         B     COPYOPEN           LOOP UNTIL FINISH                     21040016
         EJECT                                                          21090003
*                                                                       21120016
**********************************************************************  21200016
*                                                                       21280016
READJFCB EQU   *        HERE THE JFCB'S ARE READ AND VTOC ARE OPENED.   21360016
*                                                                       21440016
**********************************************************************  21520016
*                                                                       21600016
         DROP  REGF                                                     21680016
         USING IHADCB,REG9                                              21760016
         MVI   OPENLD,X'8F'       SET UP OUTPUT INDICATOR.              21840016
         LR    REG9,REGF          SET UP TEMPORARY CONTROL BLOCKS BASE. 21920016
         RDJFCB  ((REG9)),MF=(E,OPENLD) READ JFCB INTO CORE.            22000016
         L     REGF,LIST          GET POINT TO JFCB .                   22080016
         USING JFCB,REGF                                                22160016
         OI    JFCBTSDM,X'08'     STOP JFCB REWRITE                     22240016
         MVI   JFCBDSNM,X'04'                                           22320016
         MVC   JFCBDSNM+1(43),JFCBDSNM  SET UP DATA SET NAME            22400016
         OPEN  MF=(E,OPENLD),TYPE=J    OPEN PRIMARY DCB                 22480016
         LR    REGF,REG9               RESTORE PERMANENT BASE           22560016
         TM    DCBOFLGS,X'10'          TEST FOR SUCCESSFUL OPEN         22640016
         BZ    NOTOPEN                 BR ON UNSUCCESFUL OPEN           22720016
         NI    DCBMACRF+1,X'F3'   PREVENT TTR UPDATE AND EOF WRITE      22800016
         DROP  REG9                                                     22880016
         DROP  REGF                                                     22960016
         USING IHADCB,REGF                                              23040016
         BR    REG8               RETURN.                               23120016
         EJECT                                                          23170003
*                                                                       23200016
**********************************************************************  23280016
*                                                                       23360016
NUVOLUME EQU   *        THIS ROUTINE IS ENTERED WHEN AN UNLABELED       23440016
*                       VOLUME IS TO BE PROCESSED.                      23520016
*                                                                       23600016
**********************************************************************  23680016
*                                                                       23760016
         L     REG9,TUCBPTR            POINT TO UCB.               1352 23810018
         TM    SRTESTAT-UCBOB(REG9),SRTEONLI     IS DEVICE ONLINE. 1352 23860018
         BO    ONLINERR           YES SET UP ERROR MESSAGE.             23920016
         LA    REGF,FBLOCKS       GET DCB POINTER.                      24000016
         BAL   REG8,BLDDEB        BUILD PARM LIST FOR DEB BUILDER.      24160016
         L     REG3,COPYPTR       GET POINTER TO COPY BLOCK.            24240016
COPYLOOP EQU   *                                                        24320016
         LTR   REG3,REG3          ANOTHER COPY REQUESTED.               24400016
         BZ    PASSOKAY                NO-SET UP R0 COUNT FIELD.        24480016
         LA    REGF,CIOBLOCK      GET COPY DCB POINTER.                 24560016
         L     REG9,CUCBPTR       GET COPY UCBPTR                       24640016
         TM    SRTESTAT-UCBOB(REG9),SRTEONLI  IS DEVICE ONLINE.         24720016
         BO    ONLINERC           SET UP ERROR MSG.                     24800016
         BAL   REG8,BLDDEB                                              24880016
         L     REG3,CCOPYPTR      GET NEXT COPY BLOCK POINTER.          24960016
         B     COPYLOOP           LOOP UNTIL FINISH                     25040016
         EJECT                                                          25090003
*                                                                       25120016
**********************************************************************  25200016
*                                                                       25280016
BLDDEB   EQU   *             HERE THE PARM LIST FOR DEB BUILDER IS      25360016
*                            CONSTRUCT AND A DEB IS BUILT IN PROTECTED  25440016
*                            CORE.                                      25520016
*                                                                       25600016
**********************************************************************  25680016
*                                                                       25760016
         ST    REG9,PARMUCB       STORE PROPER UCB POINTER              25840016
         ST    REGF,PARMDCB       STORE PROPER DCB POINTER              25920016
         MVI   PARMUCB,X'8F'      SET UP DEB CONSTRUCTION INDICATOR.    26000016
         MVI   PARMDCB,X'80'      SET LAST ENTRY INDICATOR.             26080016
         LA    REG1,PARMLST       GET POINTER TO PARM LIST              26160016
         SVC   82                 CONSTRUCT DEB IN PROTECTED CORE.      26240016
         LTR   REGF,REGF          WAS DEB SUCCESSFULLY BUILT.           26250016
         BCR   8,REG8             YES-CONTINUE PROCESSING.              26260016
         L     REG1,PARMDCB       PICK UP POINTER TO CURRENT DCB.       26270016
         LA    REG1,0(REG1)       CLEAR HIGH ORDER BYTE.                26280016
         LA    REG8,FBLOCKS       GET ADDRESS TO FUNCTION BLOCK DCB.    26290016
         CR    REG8,REG1          IS THIS FUNCTION BLOCK DCB.           26305016
         BE    ONLINERR           YES-SET UP AND PRINT ERROR MSG.       26310016
         B     ONLINERC           NO-SET UP AND PRINT COPY ERROR MSG.   26320016
*                                                                       26400016
**********************************************************************  26480016
*                                                                       26560016
*   TEST FOR PROTECTED AND UNEXPIRED DATA SETS HERE.                    26580003
*                                                                       26600003
**********************************************************************  26640016
NOCOPIES EQU   *                                                        26720016
         LR    REG1,REG7          SET UP POINTER TO BUFFER WORK AREA    26800016
         LINK  EP=IEHDPASS        CHECK FOR PASSWORD DATA SETS          26880016
         LA    REGD,SAVEAREA      RESTORE MY SAVEAREA POINTER.          26920016
         LTR   REGF,REGF          WAS PASSWORD CHECK OKAY               26960016
         BZ    PASSOKAY           YES-CONTINUE PROCESSING               27040016
ABNORMN  EQU   *                                                        27120016
         LR    REG2,REGF          NO-SAVE RETURN CODE                   27200016
         LA    REG8,RETRNABN      PICK UP RETURN ADDRESS.               27280016
         LA    REGB,FBLOCKS       POINT TO I/O CONT*OL BLOCKS           27360016
         B     CLOSENXT           CLOSE OPEN DCBS                       27440016
         EJECT                                                          27490003
PASSOKAY EQU   *                                                        27520016
         AIF   ('&LIB' EQ 'LIB1').X227206                       XL03145 27520803
         CLI   UCBTBYT4,WIN            IS THIS A 3340?           XM5465 27521203
         BNE   NO3340                  NO, CHECK OTHER DEVICES.  XM5465 27521303
         MVI   PASSCNT+D1,ONE          FORCE ONE PASS ON 3340.   XM5465 27521403
         TM    SEQSW,FLAGTEST          IS FLAGTEST = NO?         XM5465 27521503
         BO    NO3330                  YES, TEST FOR PASSES.     XM5465 27521603
NO3340   EQU   *                                                 XM5465 27523903
         CLI   UCBTBYT4,FACTPACK        UCB TYPE GREATER THAN 9 XL03145 27526403
         BL    NO3330                   NO, PASS COUNT IS OK.   XL03145 27528803
         XC    PASSCNT(2),PASSCNT       MUST HAVE PASSES EQ 0.  XL03145 27531203
         AGO   .X227207                                         XL03145 27533603
.X227206 ANOP                                                   XL03145 27536003
         CLI   UCBTBYT4,FACTPACK   IS THIS MERLIN                S20201 27538403
         BNE   NO3330                   NO CONTINUE              M5723  27540803
         XC    PASSCNT(2),PASSCNT       3330 MUST HAVE PASSES EQ M0137  27543203
*                                       0                        M0137  27545603
.X227207 ANOP                                                   XL03145 27548003
         CLI   FUNCSW,FORMAT            IS THIS A FORMAT         M5723  27550403
         BNE   BLDVTOC                  NO - QUICK DASDI         M5723  27552803
NO3330   EQU   *                                                 M5723  27555203
         TM    SEQSW,PASSES             IS PASS SPECIFIED          O122 27557603
         BZ    HERE                     IF NOT, CONTINUE           O122 27560019
         CLC   PASSCNT(2),ZERO     DOES PASSES =0                S20201 27580020
         BE    BLDVTOC                  IF YES, CREATE VTOC        O122 27600019
         EJECT                                                          27610003
HERE     EQU   *                                                   O122 27620019
         BAL   REGE,SETUPR0S            CONSTRUCT R0 COUNT         O122 27640019
         TM    FUNCSW,FORMAT      IS THIS A FORMAT FUNCTION             27680016
         BO    BITBYPAS           NO-BYPASS BIT CONSTRUCTION            27760016
         LA    REGE,BITBUFF       GET POINTER TO START OF BIT PATTERN   27840016
         AIF   ('&LIB' EQ 'LIB1').X227208                       XL03912 27850003
         CLI   UCBTBYT4,WIN            IS THIS A 3340?           XM5465 27852003
         BNE   USEFIVE                 NO, USE FIVES AS PATTERN. XM5465 27854003
         MVC   BITBUFF(L8),TEST3340    GET 3340 TEST PATTERN.    XM5465 27856003
         B     PATSET                  PATTERN IS READY.         XM5465 27858003
USEFIVE  EQU   *                                                 XM5465 27858403
         MVC   BITBUFF(L8),PATTERN     FIVES USED AS PATTERN.    XM5465 27860003
PATSET   EQU   *                                                 XM5465 27862003
         XC    HALFWD,HALFWD           CLEAR ONE HALFWORD.       XM5465 27864003
         LH    REGF,SACAP              GET S/A TRACK CAPACITY.   XM5465 27866003
         LA    REG8,K9                 GET A NUMBER NINE.        XM5465 27866403
         SR    REGF,REG8               DECR LNGTH BY FIRST MOVE. XM5465 27866803
         STC   REGF,HALFWD+D1          SAVE LAST BYTE OF LENGTH. XM5465 27868003
         SRL   REGF,B8                 NUMBER OF MOVES - ONE.    XM5465 27868403
         LA    REG8,MAXBYTE            GET NUMBER FOR MAX MOVE.  XM5465 27868803
BITLOOP  EQU   *                                                 XM5465 27869203
         EX    REG8,MOVEBITS           FILL BUFFER WITH PATTERN. XM5465 27869603
         LA    REGE,MAXBYTE+D1(REGE)   INCR BUFF ADDR BY 256.    XM5465 27869703
         BCT   REGF,BITLOOP            LOOP UNTIL FINISHED.      XM5465 27869803
         LH    REG8,HALFWD             GET REMAINING LENGTH.     XM5465 27869903
         LTR   REG8,REG8               ANY LENGTH LEFT?          XM5465 27873203
         BNP   BITBYPAS                NO, BUFFER IS FULL.       XM5465 27875203
         EX    REG8,MOVEBITS           FILL REMAINING BUFFER.    XM5465 27875603
         B     BITBYPAS                START BUILDING CCWS.      XM5465 27875703
         SPACE                                                          27875803
*********************************************************************** 27875903
         SPACE                                                          27878703
MOVEBITS MVC   B8(NULL,REGE),BITBUFF   OBJECT OF EX INSTRUCTION. XM5465 27880703
         SPACE                                                          27881103
*********************************************************************** 27881503
         EJECT                                                          27887903
BITBYPAS EQU   *                                                 XM5465 27894403
         L     REG2,TUCBPTR             PICK UP UCB POINTER     XL03912 27900803
         AGO   .X227211                                         XL03912 27907203
.X227208 ANOP                                                   XL03912 27913603
         MVI   0(REGE),X'55'      ASSUME DEVICE IS NOT 2301 OR 2321     27920016
         L     REG2,TUCBPTR       PICK UP UCB POINTER.                  28000016
         CLI   UCBID,X'FF'        IS THIS A 2321                        28080016
         BNE   SETE5              YES MODIFY BIT PATTERN TO E5          28160016
         CLI   UCBTBYT4,X'03'     IS THIS A 2301                        28240016
         BNE   BLDPATTN           NO-BUILD PATTERN FOR 55               28320016
         MVI   0(REGE),X'5A'      YES-SET PATTERN FOR 5A                28400016
BLDPATTN EQU   *                                                        28480016
         MVI   HALFWD,0           SET FIRST BYTE OF HALD WORD TO ZERO   28560016
         LH    REGF,SACAP         GET BIT PATTERN LENGTH                28640016
         STC   REGF,HALFWD+1      SAVE LENGTH OF FIELD TO BE MOVED      28720016
         BCTR  REGF,0             DECREMENT FOR PROPER EX LENGTH        28800016
         EX    REGF,MOVEBITS      MOVE PROPER NUMBER OF BYTES           28880016
         AH    REGE,HALFWD        UPDATE FIELD POINTER                  28960016
         SRL   REGF,8             GET NUMBER OF BITS TO BE MOVED        29040016
         LTR   REGF,REGF          IS BIT PATTERN COMPLETE               29120016
         BE    BITBYPAS           YES-TEST FOR 2321                     29200016
BITLOOP  EQU   *                                                        29280016
         LA    REG8,255           GET LENGTH OF NEXT MOVE               29360016
         EX    REG8,MOVEBITS      SET UP MORE BITS IN OUTPUT BUFFER     29440016
         LA    REGE,256(REGE)     UPDATE FIELD POINTER                  29520016
         BCT   REGF,BITLOOP       LOOP UNTIL FINISH                     29600016
         B     BITBYPAS                                                 29680016
MOVEBITS EQU   *                                                        29760016
         MVC   1(1,REGE),0(REGE)  *THIS IS OBJECT OF EX INSTRUCTION     29840016
SETE5    EQU   *                                                        29920016
         MVI   BITBUFF,X'E5'      SET UP BIT PATTERN FOR 2321           30000016
         B     BLDPATTN           GO COMPLETE BIT PATTERN.              30080016
BITBYPAS EQU   *                                                        30160016
         CLI   UCBID,X'FF'        IS THIS A 2321                        30240016
         BNE   IS2321             YES-SET UP LINKAGE FOR IEHDCELL       30320016
.X227211 ANOP                                                   XL03912 30360003
         LA    REGF,FBLOCKS       SET UP CONTROL BLOCK BASE.            30400016
         TM    SEQSW+D1,RPS        DO WE HAVE RPS               XM4389  30410003
         BZ    NOGOT               NO                            S20201 30420020
         MVC   CCWSECON(K136),SETSECCW YES                       S20201 30430020
         LA    REG0,CCW1CONS           SET TIC ADDR              M0967  30432021
         ST    REG0,TEMP                                         M0967  30434021
         MVC   TICSEC+D1(K3),TEMP+D1   POINT TIC                 M0967  30436021
         B     GO                      BUILD CCWS.               S20201 30440020
NOGOT    EQU   *                        *                        S20201 30450020
         MVC   CCW1CONS(120),CCWORD1   MOVE CCWS TO FUNCTION BLOCK.     30480016
GO       EQU   *                        *                        S20201 30520020
         TM    FUNCSW,FORMAT      IS THIS A FORMAT FUNCTION.            30560016
         BO    FORMATF            YES-BYPAS THE ANALYZE CCW CREATION.   30640016
**********************************************************************  30800016
*                                                                       30880016
* THIS IS THE ANALYZE FUNCTION WITH NO PREVIOUSLY FLAGGED TRACK TEST.   30960016
*                                                                       31040016
**********************************************************************  31120016
         LA    REG1,FLAGREAD      HOME ADDRESS AREA PTR IN FUNCBLOCK.   31280016
         BAL   REGE,BLDACCW       BUILD CCWS FOR ANALYZE FUNCTION.      31360016
         L     REG3,COPYPTR       GET ADDRESS OF THE FIRST COPY BLOCK.  31440016
**********************************************************************  31600016
*                                                                       31680016
*                  HERE WE CALL BLDACCW SUBR TO CONSTRUCT ANAL CHNL PRG 31760016
*                                                                       31840016
**********************************************************************  31920016
ACCWLOOP EQU   *                                                        32080016
         LTR   REG3,REG3          TEST FOR COPIES.                      32160016
         BZ    ENDCCWS            EXIT AFTER CHNL PRGS ARE BUILT.       32240016
         LA    REGF,CIOBLOCK      GET BASE FOR COPY BLOCK.              32320016
         TM    SEQSW+D1,RPS              DO WE HAVE RPS         XM4389  32330003
         BZ    NOGOT1                  NO-CONTINUE.              S20201 32340020
         MVC   CCWSECON(136),SETSECCW                            S20201 32350020
          LA    REG0,CCW1CONS           SET TIC                  A46360 32352021
          ST    REG0,TEMP               ADDRESS                  A46360 32354021
          MVC   TICSEC+1(K3),TEMP+D1                             A46360 32356021
         B     GO1                     CONTINUE CCWS.            S20201 32360020
NOGOT1   EQU   *                        *                        S20201 32370020
         MVC   CCW1CONS(120),CCWORD1 MOVE CCWS TO COPY BLOCK.           32400016
GO1      EQU   *                        *                        S20201 32440020
         LA    REG1,CFLGREAD      HOME ADDRESS AREA PTR IN COPYBLOCK.   32480016
         BAL   REGE,BLDACCW       CONSTRUCT A COPY CHANNEL PROGRAM.     32560016
         L     REG3,CCOPYPTR      POINT TO NEXT COPY BLOCK.             32640016
         B     ACCWLOOP           LOOP UNTIL ALL COPIES ARE COMPLETE.   32720016
         EJECT                                                          32770003
*                                                                       32800016
**********************************************************************  32880016
*                                                                       32960016
* HERE WE CALL BLDFCCW SUBR TO CONSTRUCT FORMAT CHNL PRGS.              33040016
*                                                                       33120016
**********************************************************************  33200016
*                                                                       33280016
FORMATF  EQU   *                                                        33360016
         MVI   UNASGBT,X'FF'            FORMAT DO NOT SET ALT    M4682  33400020
         LA    REG1,FLAGREAD      HOME ADDRESS AREA PTR IN FUNCBLOCK.   33440016
         BAL   REGE,BLDFCCWF      BUILD CCWS AND UPDATE CCWPTR IN IOB.  33520016
         AIF   ('&LIB' EQ 'LIB1').X227212                       XL03130 33528003
         CLI   UCBTBYT4,ZEU1            IS THIS A 2305-1?       XL03130 33536003
         BE    WRHA                     YES, SET WRITE HA CCW.  XL03130 33544003
         CLI   UCBTBYT4,ZEU2            IS THIS A 2305-2?               33552003
         BNE   CCWSOKAY                 NO, CCWS ALREADY SET.   XL03130 33560003
WRHA     EQU   *                        WRITE HA IS SET HERE.   XL03130 33568003
         AGO   .X227213                                         XL03130 33576003
.X227212 ANOP                                                   XL03130 33584003
         TM    UCBTBYT4,X'02'     IS THIS A DRUM DEVICE.                33600016
         BZ    CCWSOKAY           NO-CCWS ARE ALREADY SET PROPERLY.     33680016
.X227213 ANOP                                                   XL03130 33720003
         MVI   CCWBCONS,X'19'     SET CCW TO WRITE HOME ADDRESS.        33760016
         L     REG0,CCWBCONS                                            33840016
         BCTR  REG0,0                                                   33920016
         ST    REG0,CCWBCONS      SET UP PTR FOR READ HOMEADDR          34000016
         LA    REG0,CCWDCONS      UPDATE TIC                            34080016
         ST    REG0,CCWCCONS       UPDATE TIC ADDR .                    34160016
         MVI   CCWCCONS,X'08'     RESTORE TIC OP CODE.                  34240016
CCWSOKAY EQU   *                                                        34320016
         L     REG3,COPYPTR                                             34400016
FCCWLOOP EQU   *                                                        34480016
         LTR   REG3,REG3                                                34560016
         BZ    ENDCCWS            EXIT HERE AFTER ALL COPIES ARE BUILT. 34640016
         LA    REGF,CIOBLOCK      POINT TO COPY I/O BLOCK.              34720016
         MVC   CCWBCONS(40),CCWORDB MOVE CCWS TO COPY BLOCK.            34800016
         TM    SEQSW+D1,RPS           IS THIS RPS               XM4389  34850003
         BZ    NOGOT2                  NO                        XM6030 34860000
         MVC   CCWSECON(K16),SETSECCW  YES, MOVE SS & TIC        XM6030 34870000
NOGOT2   EQU   *                       CONTINUE                  XM6030 34872000
         AIF   ('&LIB' EQ 'LIB1').X227214                       XL03130 34872803
         CLI   UCBTBYT4,ZEU1            IS THIS A 2305-1?       XL03130 34873603
         BE    CHANGE                   YES, SET WR HA CCW.     XL03130 34874403
         CLI   UCBTBYT4,ZEU2            IS THIS A 2305-2?       XL03130 34875203
         BNE   NOCHANGE                 NO, CHECK FLAGGED TRKS. XL03130 34876003
         EJECT                                                          34876403
CHANGE   EQU   *                        CHANGE OP TO WRITE HA.  XL03130 34876803
         AGO   .X227215                                         XL03130 34877603
.X227214 ANOP                                                   XL03130 34878403
         TM    UCBTBYT4,X'02'     IS TIS A DRUM DEVICE.                 34880016
         BZ    NOCHANGE           NO-CHECK FOR PREV FLAGGED TRKS.       34960016
.X227215 ANOP                                                   XL03130 35000003
         MVI   CCWBCONS,X'19'                                           35040016
         LA    REG0,CCWDCONS                                            35120016
         ST    REG0,CCWCCONS      UPDATE TIC ADDRESS.                   35200016
         MVI   CCWCCONS,X'08'     RESTORE TIC OP CODE.                  35280016
NOCHANGE EQU   *                                                        35360016
         LA    REG1,CFLGREAD      HOME ADDRESS AREA PTR IN COPYBLOCK.   35440016
         BAL   REGE,BLDFCCWF      BUILD CCWS AND UPDATE CCWPTR IN IOB.  35520016
         CLI   CCWBCONS,X'39'     IS THIS A SEARCH COMMAND.             35600016
         BE    DONTCHNG           YES- BYPASS ADDRESS CHANGE.           35680016
         L     REG0,CCWBCONS                                            35760016
         BCTR  REG0,0                                                   35840016
         ST    REG0,CCWBCONS      SET UP PTR FOR READ HOMEADDR          35920016
DONTCHNG EQU   *                                                        36000016
         L     REG3,CCOPYPTR                                            36080016
         B     FCCWLOOP                                                 36160016
         EJECT                                                          36210003
BLDFCCWF EQU   *                                                        36240016
         TM    SEQSW+D1,RPS        DO WE HAVE CARNY             XM4389  36248003
         BZ    NOCARN              NO                            S20201 36256020
          LA    REG0,CCWSECON           SET UP SECTOR OP         A46360 36264021
         ST    REG0,CCWPTR         PUT IN IOB                    S20201 36272020
         LA    REG0,CCWBCONS       PUT TIC                       S20201 36280020
         ST    REG0,TEMP           ADDRESS                       S20201 36288020
          MVC   TICSEC+1(K3),TEMP+D1                             A46360 36296021
         B     BLDFCCW                 BUILD CCWS.               S20201 36304020
NOCARN   EQU   *                        *                        S20201 36312020
         LA    REG0,CCWBCONS                                            36320016
         ST    REG0,CCWPTR        UPDATE CCW PTR IN IOB FOR FORMAT FUNC 36400016
BLDFCCW  EQU   *                                                        36480016
         LR    REG0,REG1          GET CORRECT HOME ADDRESS AREA.        36560016
         A     REG0,CCWBCONS                                            36640016
         ST    REG0,CCWBCONS      POINT SHA TO SEARCH ARGUMENT.         36720016
         BCTR  REG0,0                                                   36800016
         ST    REG0,CCWECONS      POINT RHA TO LOC INTO WHICH HA IS RD. 36880016
         MVI   CCWECONS,X'1A'     RESTORE OP CODE TO READ HOME ADDRESS. 36960016
         LA    REG0,CCW1CONS                                            37040016
         A     REG0,CCWCCONS                                            37120016
         ST    REG0,CCWCCONS      RELOCATE TIC TO POINT TO CCWBCONS.    37200016
         LA    REG0,STNDR0                                              37280016
         A     REG0,CCWDCONS                                            37360016
         ST    REG0,CCWDCONS      POINT WRITE RO CCW TO A STANDARD R0.  37440016
         ST    REG0,CCWFCONS      RELOCATE CCW15                        37520016
         MVI   CCWFCONS,X'16'     RESTORE READ R0 OP CODE.              37600016
         BR    REGE               RETURN.                               37680016
*                                                                       37760016
         EJECT                                                          37810003
*********************************************************************** 37840016
*                                                                       37920016
* THIS SUBROUTINE CONSTRUCTS A CHANNEL PROGRAM THAT IS TO BE USED BY    38000016
* THE ANALYZE FUNCTION.                                                 38080016
* THE FIRST TEN CCWS ARE RELOCATED IN THIS SUBROUTINE .THEN BLDFCCW     38160016
* IS CALLED TO RELOCATE THE LAST FIVE.                                  38240016
*                                                                       38320016
*********************************************************************** 38400016
*                                                                       38480016
BLDACCW  EQU   *                                                        38560016
         LR    REG0,REG1          GET READ IN AREA               XM5465 38610003
         A     REG0,CCW1CONS                                            38720016
         ST    REG0,CCW1CONS      RELOCATE CCW1                         38800016
         ST    REG0,CCW6CONS      RELOCATE CCW6                         38880016
         BCTR  REG0,0                                                   38960016
         ST    REG0,CCW4CONS      SET UP PTR FOR READ HOMEADDR          39040016
         ST    REG0,CCW9CONS      RELOCATE CCW9                         39120016
         LA    REG0,CCW1CONS                                            39200016
         A     REG0,CCW2CONS                                            39280016
         ST    REG0,CCW2CONS      RELOCATE CCW2CONS.                    39360016
         MVI   CCW4CONS,X'1A'     RESTORE OP CODE IN CCW4               39440016
         MVI   CCW9CONS,X'1A'     RESTORE OP CODE IN CCW9               39520016
         LA    REG0,MAXR0BIT      GET ADDRESS OF BIT PATTERN.           39600016
         A     REG0,CCW3CONS                                            39680016
         ST    REG0,CCW3CONS      RELOCATE CCW3                         39760016
         LA    REG0,MAXLTHR0                                            39840016
         A     REG0,CCW8CONS      RELOCATE CCW8                         39920016
         ST    REG0,CCW8CONS      RELOCATE CCW8                         40000016
         ST    REG0,CCWACONS      RELOCATE CCW10                        40080016
         MVI   CCWACONS,X'16'     RESTORE OP CODE.                      40160016
         LA    REG0,CCW1CONS                                            40240016
         A     REG0,CCW7CONS                                            40320016
         ST    REG0,CCW7CONS      RELOCATE CCW7.                        40400016
         LA    REG0,8                                                   40480016
         AH    REG0,SACAP                                               40560016
         A     REG0,CCW3CONS+4                                          40640016
         ST    REG0,CCW3CONS+4    SET MAXIMUM R0 COUNT IN               40720016
         LH    REG0,PASSCNT       GET REQUESTED PASS COUNT.             40800016
         BCTR  REG0,0                                                   40880016
         LTR   REG0,REG0          TEST FOR MULTIPLE PASSES.             40960016
         BNP   ONEPASS            BRANCH ON SINGLE PASS REQUEST.        41040016
         NI    CCWACONS+4,X'20'   SET CMND CHAIN OFF SILI FLAG ON.      41120016
ONEPASS  EQU   *                                                        41200016
         CLI   DDNAME2,X'40'          IS THIS A NEW VOLUME.             41220016
         BE    SETWRTHA           YES-SET UP WRITE HOME ADDRESS.        41240016
         AIF   ('&LIB' EQ 'LIB1').X228000                       XL03912 41245003
         CLI   UCBTBYT4,ZEU1            IS THIS A 2305-1?       XL03130 41250003
         BE    SETWRTHA                 YES, SET WR HA CCW.     XL03130 41255003
         CLI   UCBTBYT4,ZEU2            IS THIS A 2305-2?       XL03130 41260003
         BE    SETWRTHA                 YES, SET WR HA CCW.     XL03130 41265003
         AGO   .X228001                                         XL03912 41270003
.X228000 ANOP                                                   XL03912 41275003
         TM    UCBTBYT4,X'02'     IS THIS A DRUM TYPE DEVICE.           41280016
         BO    SETWRTHA           YES-SET UP WRITE HOME ADDRESS OP      41360016
.X228001 ANOP                                                   XL03912 41400003
         TM    SEQSW,FLAGTEST     IS FLAG TEST BYPASS REQUESTED.        41440016
         BZ    BLDFCCW            NO-BUILD REMAINING CCWS.              41520016
SETWRTHA MVI   CCW1CONS,X'19'     MODIFY CCW TO WRITE HOME ADDRESS.     41600016
         LA    REG0,CCW3CONS                                            41680016
         ST    REG0,CCW2CONS                                            41760016
         MVI   CCW2CONS,X'08'     MODIFY TIC ADDRESS FOR CCW3.          41840016
         AIF   ('&LIB' EQ 'LIB1').X326000                        XM5465 41890003
         CLI   UCBTBYT4,WIN            IS THIS A 3340?           XM5465 41890403
         BNE   NOSD                    NO, SOME OTHER DEVICE.    XM5465 41890803
         EJECT                                                          41891203
*****************************************************************XM5465 41892003
*                                                                XM5465 41892403
*    THE FOLLOWING ROUTINE WILL EDIT THE ANALYZE CCWS            XM5465 41892803
*    SUCH THAT ONLY TRACKS WITH BIT SIX ON IN THE HOME           XM5465 41893203
*    ADDRESS WILL BE ANALYZED SO AS TO DETERMINE THEIR           XM5465 41893603
*    USEFULLNESS FOR POSSIBLE RECLAIMATION FROM DEFECTIVE        XM5465 41893703
*    STATUS. THIS IS APPLICABLE TO 3340 ONLY.                    XM5465 41893803
*                                                                XM5465 41893903
*****************************************************************XM5465 41902003
         SPACE                                                          41904003
         MVC   SDCCW1,CCWORD4          GET A READ HA CCW.        XM5465 41910403
         LR    REG0,REG1               GET READ IN AREA.         XM5465 41910803
         A     REG0,SDCCW1             COMBINE ADDR AND CCW.     XM5465 41911203
         ST    REG0,SDCCW1             RD HA CMD SET.            XM5465 41911603
         LA    REG0,SDSNS              GET SENSE AREA.           XM5465 41911703
         ST    REG0,SDCCW2             SET IN SENSE CCW.         XM5465 41911803
         MVI   SDCCW2,SENSE            SET SENSE COMMAND.        XM5465 41911903
         LA    REG0,L24                LENGTH OF SENSE INFO.     XM5465 41912903
         ST    REG0,SDCCW2+D4          SET COUNT OF SENSE CCW.   XM5465 41914903
         LA    REG0,CCWBCONS           GET ADDDRESS              XM5465 41915003
         ST    REG0,SDTIC              STORE IN CCW              XM5465 41915103
         MVI   SDTIC,TICCMD            SET TO TIC                XM5465 41915203
         MVI   SDCCW2+D4,CHAIN         TURN ON CMD CNING         XM5465 41916803
         MVI   CCW1CONS+L7,L7          SET COUNT OF 7 FOR WR HA. XM5465 41920003
         MVC   CCWSHCON(L8),CCWORD6    GET A SEARCH CCW.         XM5465 41923703
         LR    REG0,REG1               GET HA POINTER.           XM5465 41925703
         A     REG0,CCWSHCON           ADDR TO SEARCH CCW.       XM5465 41927703
         ST    REG0,CCWSHCON           SEARCH CCW NOW COMPLETE.  XM5465 41929703
         LA    REG0,CCWSHCON           ADDR OF SEARCH FOR TIC.   XM5465 41931703
         ST    REG0,TICSEC             SET ADDR IN TIC.          XM5465 41932103
         MVI   TICSEC,TICCMD           SET TIC CCW.              XM5465 41932503
         LA    REG0,SDBYTES            ADDR OF 3340 HA.          XM5465 41932803
         ST    REG0,CCW1CONS           CHANGE CCW ADDRESS.       XM5465 41941203
         MVI   CCW1CONS,WRITE          RESET WRITE COMMAND.      XM5465 41949603
         B     BLDFCCW                 BUILD REMAINING CCWS.     XM5465 41958003
         EJECT                                                          41960003
NOSD     EQU   *                                                 XM5465 41966403
.X326000 ANOP                                                    XM5465 41974803
         LR    REG0,REG1          GET CORRECT HOME ADDRESS AREA.        41983203
         L     REG0,CCW1CONS                                            41991603
         BCTR  REG0,0                                                   42000016
         ST    REG0,CCW1CONS      SET UP PTR FOR READ HOMEADDR          42080016
         B     BLDFCCW            CONSTRUCT REMAINING CCWS.             42160016
         SPACE                                                          42160403
UNASGZUS EQU   *                                                 M4682  42162020
         TM    UNASGBT,X'FF'            DO WE NEED TO  UNASSIGN  M4682  42164020
         BO    UNRET                    RETURN IF NOT            M4682  42166020
         L     REGB,TUCBPTR             GET UCB POINTER          M4682  42168020
         USING UCBOB,REGB                                        M4682  42170020
         CLI   UCBTBYT4,X'06'           ZEUS 1                   M4682  42172020
         BE    ZEUS1                    YES - GO PROSESS         M4682  42174020
         CLI   UCBTBYT4,X'07'           ZEUS I                   M4682  42176020
         BE    ZEUS2                    YES - GO PROCESS         M4682  42178020
         B     UNRET                    NO RETURN                M4682  42180020
ZEUS1    MVI   ZCCHH+2,X'30'            SET ZEUS 1 ALT           M4682  42182020
         DROP  REGB                                              M4682  42184020
         B     COMZ                     GO TO COMMON RTN         M4682  42186020
ZEUS2    MVI   ZCCHH+2,X'60'            ST A ZEUS 2 ALT          M4682  42188020
COMZ     EQU   *                                                 M4682  42190020
         MVC   SAVCCHHR(4),SEEKADDR+3   SAVE SEEK ADDRESS        M4682  42192020
         MVC   SAVCCWPT(4),CCWPTR       SAVE CCW POINTER         M4682  42194020
         LA    REGB,ZALTCCW             LOAD CCW CHAIN TO        M4682  42196020
*                                       U4NASSIGN                M4682  42198020
         ST    REGB,CCWPTR              STORE TEMP CCW POINTER   M4682  42200020
         MVC   SEEKADDR+3(4),ZEUSALT    SET SEEKADDR FOR ZERO    M4682  42202020
         MVI   WKAECB,0                 ZERO ECB                 M4682  42204020
         DROP  REGF                                              M4682  42206020
         USING IHADCB,REGB                                       M4682  42208020
         LR    REGB,REGF                LOAD IOBLOCKS ADDRESS    M4682  42210020
         EXCP  WKAIOB                                            M4682  42212020
         WAIT  ,ECB=WKAECB                                       M4682  42214020
         DROP  REGB                                              M4682  42216020
         USING IHADCB,REGF                                       M4682  42218020
         LR    REGF,REGB                RESET IOB PTR            M4682  42220020
         CLI   WKAECB,X'7F'             GOOD COMPLETE            M4682  42222020
         BNE   IOERROR                                           M4682  42224020
         MVC   SEEKADDR+3(4),SAVCCHHR   RESTORR SEEK ADDRESS     M4682  42226020
         MVC   CCWPTR(4),SAVCCWPT       RESTORE CCW POINTER      M4682  42228020
         B     UNRET                    RETURN                   M4682  42230020
         EJECT                                                          42232003
ENDCCWS  EQU   *                                                        42240016
         MVC   TRACKCTL(4),LASTALT  SET UP STOPPING TRACK COUNT.        42320016
         MVI   FLAGREAD,1         SET ALTERNATE TRACK INDICATOR.        42360016
ENDOFCCW EQU   *                                                        42400016
         LA    REGF,FBLOCKS       GET I/O BLOCKS BASE.                  42480016
         L     REG3,COPYPTR       GET BASE FOR COPY BLOCK.              42560016
         L     REG1,PTRCFUNC                                            42640016
         OI    0(REG1),PROCESS    INDICATE FUNCTION IS PROCESSING.      42720016
         XC    RETRYCNT(2),RETRYCNT    INITIALIZE PRIMARY RETRY COUNT.  42800016
         MVC   SEEKADDR+3(4),PRGSAVE   SET UP SEEK ADDRESS IN IOB.      42960016
         MVC   FLAGREAD+1(4),PRGSAVE   SET UP HOME ADDR IN FUNCBLK.     43040016
TESTALT  EQU   *                                                        43120016
         CLC   STNDR0(4),TRACKCTL IS THIS LAST ALTERNATE TRACK.         43200016
         BNH   EXCHNPRO           NO-EXECUTE CHANNEL PROGRAM.           43280016
         AIF ('&LIB' EQ 'LIB1').X328000                          XM5465 43290003
         MVI   SDCCW2+D4,NULL          UNCHAIN CCW               XM5465 43330003
.X328000 ANOP                                                    XM5465 43340003
         XC    SEEKADDR+3(5),SEEKADDR+3  SET UP FIRST PRIMARY TRACK.    43360016
         SR    REG0,REG0                                                43440016
         ST    REG0,STNDR0        SET STANDARD R0 TO TRACK ZERO.        43520016
         ST    REG0,PRGSAVE       SET COUNT SAVE TO TRACK ZERO.         43600016
         XC    FLAGREAD(5),FLAGREAD    SET  HOME ADDRESS TO TRACK ZERO. 43680016
EXCHNPRO EQU   *                                                        43760016
         DROP  REGF                                                     43840016
         USING IHADCB,REGB                                              43920016
         B     UNASGZUS                 TRY TO UNASSIGN 2305 ALT M4682  43940020
         EJECT                                                          43950003
UNRET    EQU   *                                                 M4682  43960020
         LR    REGB,REGF          SET UP TEMPORARY CONTROL BLOCKS BASE. 44000016
         AIF   ('&LIB' EQ 'LIB1').X326104                        XM5465 44050003
         CLI   FUNCSW,FORMAT           IS THIS A FORMAT?         XM5465 44060003
         BE    STARTIO                 YES, START CHAN PROG.     XM5465 44070003
         CLI   UCBTBYT4,WIN            IS THIS A 3340?           XM5465 44072003
         BNE   STARTIO                 NO, START CHAN PROG.      XM5465 44074003
         LA    REG0,SDCCW1             GET DEFECT FIND CCW.      XM5465 44076003
         ST    REG0,CCWPTR             USE AS IOBSTART ADDR.     XM5465 44078003
         SPACE                                                          44080003
*****************************************************************XM5465 44088003
*     ON 3340 ONLY, THE FOLLOWING EXCP WILL SCAN THE PACK FOR    XM5465 44091603
*     TRACKS THAT ARE FLAGGED DEFECTIVE.                         XM5465 44101603
*****************************************************************XM5465 44103603
         SPACE                                                          44113603
STARTIO  EQU   *                                                 XM5465 44119203
.X326104 ANOP                                                    XM5465 44132803
         MVI   WKAECB,0           CLEAR ECB FLAGS.                      44146403
         EXCP  WKAIOB           INITIATE CHANNEL PROGRAM.               44160016
         DROP  REGB                                                     44240016
         USING IHADCB,REGF                                              44320016
         LR    REGF,REGB          RESTORE CONTROL BLOCKS BASE.          44400016
         LTR   REG3,REG3          IS THERE ANOTHER COPY OPERATION.      44480016
         BZ    CHKCONC            NO-TEST FOR CONCURRENT OPERATIONS.    44560016
         XC    CRTRYCNT(2),CRTRYCNT    INITIALIZE PRIMARY RETRY COUNT.  44640016
         MVC   CFLGREAD(1),FLAGREAD  SET PROPER INDICATION IN COPY HA.  44720016
         MVC   CFLGREAD+1(4),PRGSAVE   SET UP HOME ADDR IN COPYBLK.     44800016
         LA    REGF,CIOBLOCK      YES-BR AND INITIATE NEXT COPY.        44880016
         MVC   SEEKADDR+3(4),PRGSAVE  SET UP SEEK ADDRESS IN IOB.       44960016
         L     REG3,CCOPYPTR      GET POINTER TO NEXT COPY BLOCK.       45040016
         B     TESTALT            BR AND TEST FOR LAST ALTERNATE.       45120016
CHKCONC  EQU   *                                                        45200016
         MVI   UNASGBT,X'FF'           FINISHED COPIES SET BYTE  M4682  45240020
         TM    SW1,MULTIPLE       IS THIS ACONCURRENT OPERATION.        45280016
         BO    CONCUR             BRANCH IF YES.                        45360016
RETURNAD EQU   *                                                        45440016
         LA    REGF,FBLOCKS       RESTORE FUNCTION I/O BLOCK PTR.       45520016
         L     REG3,COPYPTR       POINT TO 1ST COPY BLOCK.              45600016
         L     REG2,TUCBPTR       GET CURRENT UCB POINTER.              45680016
         AIF   ('&LIB' EQ 'LIB2').X227216                       XL03912 45720003
         CLI   UCBID,X'FF'        WAS THIS A 2321 DATA CELL.            45760016
         BNE   LINK2321           YES-RECALL IEHDCELL.                  45840016
.X227216 ANOP                                                   XL03912 45880003
         EJECT                                                          45890003
REWAITF  EQU   *                                                        45920016
         BAL   REG8,WAITLOOP      WAIT FOR I/O COMPLETION.              46000016
         AIF   ('&LIB' EQ 'LIB1').X327500                        XM5465 46050003
         MVC   SDHA,FLAGREAD           SAVE HA FOR POSSIBLE S/A. XM5465 46060003
.X327500 ANOP                                                    XM5465 46070003
         TM    FLAGREAD,X'02'     WAS THE TRACK PREFLAGGED.             46080016
         BO    PREFLAG            BRANCH IF YES.                        46160016
         LH    REGB,RETRYCNT      GET RETRY COUNT.                      46240016
         LTR   REGB,REGB          RETRY COUNT EQUAL ZERO.               46320016
         BZ    TESTWAIT           YES-BRANCH AND TEST FOR OTHER REQ'S.  46400016
         BCTR  REGB,0             NO DECREMENT RETRY COUNT.             46480016
         STH   REGB,RETRYCNT      SAVE NEW RETRY COUNT.                 46560016
RESTARTF LR    REGB,REGF          SAVE CONTROL BLOCK POINTER.           46640016
         EXCP  WKAIOB             RESTART CHANNEL PROGRAM.              46720016
         LR    REGF,REGB          RESTORE CONTROL BLOCK POINTER.        46800016
         B     REWAITF            LOOP UNTIL THERE ARE 10 SUCCESSES.    46880016
TESTWAIT EQU   *                                                        46960016
         LTR   REG3,REG3          ARE THERE OUTSTANDING REQUESTS.       47040016
         BZ    TESTPASS           NO-GO AND TEST PASSCNT.               47120016
         L     REG2,CUCBPTR            GET POINTER TO COPY UCB.         47200016
REWAITC  EQU   *                                                        47280016
         LA    REGF,CIOBLOCK      POINT TO COPY CONTROL BLOCKS.         47360016
         BAL   REG8,WAITLOOP      WAIT FOR I/O COMPLETION.              47440016
         AIF   ('&LIB' EQ 'LIB1').X327501                        XM5465 47490003
         MVC   SDHA,CFLGREAD           SAVE HA FOR POSSIBLE S/A. XM5465 47500003
.X327501 ANOP                                                    XM5465 47510003
         TM    CFLGREAD,X'02'     WAS TRACK PREFLAGGED.                 47520016
         BO    PREFLAGC           YES-ASSIGN ALTERNATE TRACK.           47600016
         LH    REGB,CRTRYCNT      GET RETRY COUNT.                      47680016
         LTR   REGB,REGB          RETRY COUNT EQUAL ZERO.               47760016
         BZ    CTSTWAIT           YES-TEST FOR OTHER OUTSTANDING REQS.  47840016
         BCTR  REGB,0             DECREMENT AND SAVE                    47920016
         STH   REGB,CRTRYCNT      RETRY COUNT.                          48000016
RESTARTC EQU   *                                                        48080016
         LR    REGB,REGF          SAVE I/O CONTROL BLOCKS REG.          48160016
         EXCP  WKAIOB             RETRY TRACK ANALYSIS.                 48240016
         LR    REGF,REGB          RESTORE I/O CONRROL BLOCKS REGS.      48320016
         B     REWAITC            LOOP  UNTIL FINISH OR BAD TRACK.      48400016
CTSTWAIT EQU   *                                                        48480016
         L     REG3,CCOPYPTR      GET POINTER TO NEXT COPY BLOCK.       48560016
         B     TESTWAIT           LOOP THROUGH UNTIL FINISH OR ERROR.   48640016
         EJECT                                                          48690003
*                                                                       48720016
**********************************************************************  48800016
*                                                                       48880016
WAITLOOP EQU   *                                                        49120016
         TM    WKAECB,COMPLETE    WAS I/O COMPLETE.                     49200016
         BO    IOCMPLTE           YES-BYPASS WAIT .                     49280016
         LR    REGB,REGF          SAVE CONTROL BLOCK REGISTERS.         49360016
         DROP  REGF                                                     49380016
         USING IHADCB,REGB                                              49400016
         WAIT  ,ECB=WKAECB        WAIT FOR I/O COMPLETION.              49440016
         LR    REGF,REGB          RESTORE CONTROL BLOCK POINTERS.       49520016
         DROP  REGB                                                     49600016
         USING IHADCB,REGF                                              49680016
IOCMPLTE EQU   *                                                        49760016
         CLI   WKAECB,X'7F'        WAS I/O SUCCESSFUL .                 49840016
         BCR   8,REG8             RETURN ON SUCCESSFUL COMPLETION.      49920016
         CLI   FUNCSW,FORMAT            IS IT A FORMAT OPERATION M4682  49925020
         BNE   IOERROR                  NO - MUST BE ERROR       M4682  49930020
         CLC   SEEKADDR+3(4),TRACKCTL   IS THIS THE LAST ALT     M4682  49935020
         BNE   IOERROR                  NO - LEGIT ERROR         M4682  49940020
         L     REGB,TUCBPTR             LOAD UCB POINTER         M4682  49945020
         MVC   STNDR0(4),ZCCHH+1        DUMMY UP HA              M4682  49950020
         MVI   ZCCHH+4,X'01'            SET BEYOND LAST 2305 HH  M4682  49955020
         MVC   FALTDATA(6),ZCCHH+1      SET NO ALTS LEFT         M4682  49960020
*                                       CONDITION                M4682  49965020
         CLI   19(REGB),X'06'           IS IT 2305-1             M4682  49970020
         BE    0(REG8)                  YES ALT ASSIGNED NO      M4682  49975020
*                                       ERROR                    M4682  49980020
         CLI   19(REGB),X'07'           IS IT 2305-2             M4682  49985020
         BE    0(REG8)                  YES ALT ASSIGNED NO      M4682  49990020
*                                       ERROR                    M4682  49995020
         EJECT                                                          49997003
IOERROR  EQU   *                                                        50000016
         LA    REGB,FBLOCKS       GET ADDRESS OF FUNCTION CONTROL BLKS. 50080016
         CR    REGF,REGB          TEST FOR PRIMARY OR COPY OPERATION.   50160016
         BNE   COPYOPER           BRANCH IF COPY OPERATION.             50240016
         TM    CSWORD+4,X'02'     WAS THERE A UNIT CHECK.               50320016
         BZ    SYNADERR           NO-I/O ERROR TERMINATE.               50400016
         TM    WKAIOB+2,X'08'     WAS ERROR A DATA CHECK.               50480016
         BZ    BADTRAKF           NO BRANCH                             50560016
RETRYF   EQU   *                                                        50640016
         CLI   RETRYCNT+1,0       IS THIS INITIAL ERROR ENTRY.          50720016
         BNE   BDTRKERF           NO-SET UP MESSAGE                     50800016
         MVI   RETRYCNT+1,10           YES-SET UP COUNT FOR 10 RETRIES  50880016
         B     RESTARTF           TRY FOR 10 SUCCESSES.                 50960016
COPYOPER EQU   *                                                        51040016
         TM    CSWORD+4,X'02'     WAS THERE A UNIT CHECK.               51120016
         BZ    SYNADERR           NO-I/O ERROR TERMINATE.               51200016
         TM    WKAIOB+2,X'08'     WAS ERROR A DATA CHECK.               51280016
         BZ    BADTRAKC           NO-BRANCH                             51360016
RETRYC   EQU   *                                                        51440016
         CLI   CRTRYCNT+1,0       IS THIS 1ST TIME IN ERROR SECTION.    51520016
         BNE   BDTRKERC           NO-PREPARE TO ASSIGN ALTERNATE        51600016
         MVI   CRTRYCNT+1,10           INITIALIZE RETRY COUNTER         51680016
         B     RESTARTC           LOOP                                  51760016
         EJECT                                                          51810003
*                                                                       51840016
**********************************************************************  51920016
*                                                                       52000016
*        THIS ROUTINE DETERMINES IF MULTIPLE SURFACE ANALYSIS PASSES    52080016
*        WERE REQUESTED,OR IF THIS WAS THE LAST PASS MODIFIES THE       52160016
*        CHANNEL PROGRAM TO WRITE STANDARD HOME ADDRESS AND R0.         52240016
*                                                                       52320016
**********************************************************************  52400016
*                                                                       52480016
TESTPASS EQU   *                                                        52560016
         LA    REG0,1                                                   52640016
         CH    REG0,PASSCNT       WERE MULTIPLE PASSES REQUESTED.       52720016
         BNL   TSTPRIME            NO-TEST FOR LAST PRIMARY TRACK.      52800016
         LH    REG0,COUNT                                               52880016
         LTR   REG0,REG0           YES-TEST FOR LAST PASS COMPLETED.    52960016
         BZ    TSTPRIME            NO-TEST FOR LAST PRINARY.            53040016
         BCTR  REG0,0              DECREMENT PASS COUNT.                53120016
         STH   REG0,COUNT          STORE UPDATED COUNT .                53200016
         LTR   REG0,REG0           IS THIS THE LAST PASS REQUESTED.     53280016
         BP    ENDOFCCW            NO-RESTART CHANNEL PROGRAM.          53360016
         LA    REGF,FBLOCKS        POINT TO PRIMARY CONTROL BLOCKS.     53440016
         L     REG3,COPYPTR        GET COPY BLOCK POINTER .             53520016
RESETCCW EQU   *                                                        53600016
         OI    CCWACONS+4,X'40'   SET COMMAND CHAIN ON.                 53680016
         LTR   REG3,REG3           IS THIS THE FINAL COPY REQUESTED.    53760016
         BZ    ENDOFCCW            YES-START ANALYSIS ON FINAL DEVICE.  53840016
         LA    REGF,CIOBLOCK       POINT TO COPY CONTROL BLOCKS.        53920016
         L     REG3,CCOPYPTR       POINT TO NEXT COPY BLOCK.            54000016
         B     RESETCCW            LOOP UNTIL ALL COPIES ARE COMPLETE.  54080016
*                                                                       54160016
**********************************************************************  54240016
         EJECT                                                          54290003
*                                                                       54320016
**********************************************************************  54400016
*                                                                       54480016
TSTPRIME EQU   *                                                        54560016
*                                                                       54640016
**********************************************************************  54720016
*                                                                       54800016
         MVC   COUNT(2),PASSCNT   RESET NUMBER OF PASSES COUNTER.       54880016
         L     REG9,STNDR0         GET R0 OF LAST TRACK ANALYZED.       54960016
         C     REG9,LASTORIG       WAS THIS LAST PRIME TRACK.           55040016
         BE    BLDVTOC             YES-CREATE A VTOC FOR THIS VOL.      55120016
         LA    REG0,1              NO                                   55200016
         AR    REG9,REG0                                                55280016
         CLC   STNDR0+3(1),LASTORIG+3 WAS THIS LAST TRACK TRACK ON CYL. 55360016
         BL    CLRFLAGS            NO-BYPASS CYLINDER CONVERSION.       55440016
         BCTR  REG9,0                                                   55520016
         A     REG9,CONVCYL        GET TO NEXT CYLINDER.                55600016
CLRFLAGS EQU   *                                                        55680016
         ST    REG9,STNDR0        UPDATE CCHH OF STANDARD R0.           55760016
         ST    REG9,MAXLTHR0      UPDATE CCHH OF MAXIMUM LENGTH 0 R0.   55840016
         ST    REG9,PRGSAVE       SAVE CCHH TO STORED INTO IOB.         55920016
         ST    REG9,MAXR0BIT      UPDATE CCHH OF MAXIMUM LTG BIT R0.    56000016
         B     ENDOFCCW           LOOP AND START ANAL/FORMAT NEXT TRK.  56080016
*                                                                       56160016
         EJECT                                                          56210003
**********************************************************************  56240016
*                                                                       56320016
BLDVTOC  EQU   *                                                        56400016
*                                                                       56480016
**********************************************************************  56560016
*                                                                       56640016
         DROP  REGF                                                     56720016
         USING IHADCB,REGB                                              56800016
         LA    REGB,FBLOCKS       SET UP TEMPORARY BASE.                56880016
*********************************************************************** 56960016
*        LINK  TO BUILD VTOC.                                           57040016
         XC    DEXTNTS-2(6),DEXTNTS-2 CLEAR BB OF BBCCHH.               57080016
         L     REG4,IODEVCON      RESTORE I/O DEVICE CONSTANT PTR.      57120016
         STM   REG9,REG2,PRGSAVE  SAVE VOLATILE REGISTERS.              57200016
         LA    REG1,DDEB          POINT TO DUMMY DEB.                   57280016
         LA    REG2,RDAREA1       POINT TO AREA CONTAINING CCHH.        57360016
         USING CVT,REGF                                                 57440016
         L     REGF,CVTPTR        GET CVT BASE.                         57520016
         XC    RDAREA1(8),RDAREA1                                       57600016
         MVC   RDAREA1+3(4),LASTORIG   SET UP MBBCCHHR.                 57680016
         L     REGF,CVTPRLTV      GET ENTRY POINT TO CONVERT ROUTINE.   57760016
         BALR  REGE,REGF          LINK TO CONVERT ROUTINE.              57840016
         SRL   REG0,16                                                  57920016
         STH   REG0,RTAVTOCS      SAVE RTA FOR IEHDVTOC.                58000016
         LM    REG9,REG2,PRGSAVE  RESTORE VOLATILE REGISTERS.           58080016
         LR    REG1,REG5          PASS POINTER TO MY WORKAREA.          58160016
         LINK  EP=IEHDVTOC        CONSTRUCT VTOC FOR THIS VOLUME.       58240016
*********************************************************************** 58320016
         LA    REGD,SAVEAREA      RESTORE MY SAVEAREA POINTER.          58360016
         L     REG3,COPYPTR       GET POINTER TO COPY BLOCK.            58380002
         LTR   REGF,REGF          WAS VTOC CONSTRUCTION SUCCESSFUL.     58400016
         BNZ   MSGBUILD           NO GIVE CORRECT DIAGNOSTIC.           58480016
         LA    REG8,RETRNORM                                            58640016
         EJECT                                                          58690003
CLOSENXT EQU   *                                                        58720016
         TM    DCBOFLGS,X'10'     WAS THIS DCB OPENED.                  58800016
         BCR   8,REG8             NO  BRANCH TO FREECORE.               58880016
         CLOSE ((REGB))           CLOSE ALL OPENED DCBS.                58960016
         LR    REGF,REGB          RESTORE PERMANENT BASE.               59040016
         DROP  REGB                                                     59120016
         USING IHADCB,REGF                                              59200016
         LTR   REG3,REG3          ARE THERE MORE OPEN DCBS.             59280016
         BCR   8,REG8             RETURN TO MONITOR.                    59360016
         LA    REGB,CIOBLOCK      GET POINTER TO COPY DCB.              59440016
         L     REG3,CCOPYPTR      POINT TO NEXT COPY BLOCK.             59520016
         B     CLOSENXT                                                 59600016
         EJECT                                                          59650003
*                                                                       59680016
**********************************************************************  59760016
*                                                                       59840016
*  THIS ROUTINE IS ENTERED WHENEVER CONCURRENT OPERATION IS REQUESTED.  59920016
*                                                                       60000016
**********************************************************************  60080016
*                                                                       60160016
CONCUR   EQU   *                                                        60240016
         ST    REGD,SAVEPTR       SAVE POINTER TO MY SAVE AREA.         60320016
         STM   REGE,REGC,RETADREG SAVE MY REG ON CONCURRENT OPERATIONS. 60400016
         SR    REGF,REGF          CLEAR RETURN CODE REGS.               60480016
RELOADRG EQU   *                                                        60520016
         L     REGD,OLDSAPTR RESTORE SAVE AREA POINTER.                 60560016
         B     RETURNCO           RETURN TO MONITOR.                    60640016
NOCORIND EQU   *                                                        60720016
         L    REG1,PTRCFUNC      GET SLOT FOR CURRENT FUNCTION.         60800016
         OI    0(REG1),NOCORE+WAITING SET NOCORE/WAITING IND.           61200016
         L     REGD,OLDSAPTR           RELOAD REG 13.                   61210016
         FREEMAIN R,LV=SIZE,A=(REG5)    FREE MY WORK AREA.              61220016
         LA    REGF,4                  SET UP RETURN CODE.              61240016
         B     RETURNCO           RETURN TO MONITOR.                    61260016
RETRNABN EQU   *                                                        61287016
         L     REG1,PTRCFUNC      GET POINTER TO CURRENT FUNCTION SLOT. 61294016
         LTR   REGF,REGF          IS THIS A SUCCESSFUL COMPLETION.      61301016
         BZ    FREECORE           YES-BYPAS UNUSEABLE MSG.              61308016
         TM    0(REG1),PROCESS         WAS A WRITE OPERATION STARTED.   61315016
         BZ    FREECORE           NO-BYPASS NONUSEABLE MSG.             61322016
         LA    REG1,30                                                  61329016
         BAL   REG8,BUILDMSG      PRINT UNUSEABLE MSG.                  61336016
         MVC   0(8,REG1),DDNAME2      INSERT DDNAME INTO MSG.           61343016
         L     REG3,COPYPTR       GET POINTER TO 1ST COPYBLK.           61350016
ERRLOOP  EQU   *                                                        61357016
         BAL   REG8,PRNTLINK      PRINT MSG .                           61364016
         LTR   REG3,REG3          IS THIS END OF COPIES.                61371016
         BZ    FREECORE           YES-SET COMPLETE AND TERMINATE.       61378016
         LA    REG1,30                                                  61385016
         BAL   REG8,BUILDMSG      SET MSG FOR COPY.                     61392016
         MVC   0(8,REG1),DDNAME3      INSERT DDNAME INTO MSG.           61399016
         L     REG3,CCOPYPTR      GET ADDRESS OF NEXT COPYBLK.          61406016
         B     ERRLOOP            LOOP UNTIL ALL COPIES ARE COMPLETE.   61413016
         EJECT                                                          61415003
RETCOMP  EQU   *                                                        61420016
         L     REG1,PTRCFUNC      GET PTR TO CURRENT FUNCTION SLOT.     61427016
         MVI   0(REG1),COMPLETE   MARK CURRENT FUNCTION COMPLETE.       61440016
RETURNCO EQU   *                                                        61520016
         RETURN (14,12),T,RC=(15) RETURN TO CALLER.                     61600016
*                                                                       61680016
**********************************************************************  61760016
*                                                                       61840016
RETRNORM EQU   *                                                        61920016
         DROP  REGF                                                     62000016
         USING IHADCB,REGB                                              62080016
         LA    REGB,FBLOCKS       SET PRIMARY CONTROL BLOCKS BASE.      62160016
         L     REG2,TUCBPTR       GET PRIMARY FUNCTION UCB POINTER.     62240016
         LA    REG9,FUNCNAM1      ASSUME ANALYZE FUNCTION.              62320016
         CLI   FUNCSW,FORMAT      CHECK FOR FORMAT FUNCTION.            62400016
         BNE   FUNCOKAY           BRANCH IF ANALYZE.                    62480016
         LA    REG9,FUNCNAM2      POINT TO FORMAT FUNCTION.             62560016
FUNCOKAY EQU   *                                                        62640016
         LA    REG4,DDNAME2       POINT TO NAME IN FUNCBLK.             62720016
         L     REG3,COPYPTR       POINT TO FIRST COPY BLOCK.            62800016
         EJECT                                                          62850003
POSTLOOP EQU   *                                                        62880016
         LA    REG1,6                                                   62960016
         BAL   REG8,BUILDMSG      BUILD 'COMPLETE' MSG INTO MSG BUFFER. 63040016
         MVC   40(6,REG1),FSERNO  ASSUME NEWVOLID WAS SPECIFIED.        63120016
         MVC   0(8,REG1),0(REG4)  INSERT DDNAME INTO MSG BUFFER.        63200016
         MVC   MESS+9(10),0(REG9) INSERT FUNCTION INTO MSG BUFFER.      63280016
         TM    SEQSW,NEWVOLID     WAS NEWVOLID REQUESTED.               63360016
         BO    MSGCOMPL           YES-MSG IS COMPLETE IN BUFFER.        63440016
         AIF   ('&LIB' EQ 'LIB2').X227217                       XL03912 63480003
         CLI   UCBID,X'FF'        IS THIS A DATA CELL.                  63520016
         BNZ   MSG2321            YES-GET VOLID FROM SUBUCB.            63600016
.X227217 ANOP                                                   XL03912 63640003
         MVC   40(6,REG1),SRTEVOLI INSERT OLD VOLID INTO MSG BUFFER.    63680016
MSGCOMPL EQU   *                                                        63760016
         BAL   REG8,PRNTLINK      PRINT 'COMPLETE MSG FOR TODD.         63840016
         BAL   REG8,POSTUCB       POST THE UCB.                         63920016
         LTR   REG3,REG3          IS THERE ANOTHER COPY.                64000016
         BZ    POSTEND            NO-PREPARE TO EXIT.                   64080016
         LA    REG4,DDNAME3       POINT TO COPY TODD.                   64160016
         L     REG2,CUCBPTR       YES- GET PTR TO COPY UCB.             64240016
         LA    REGB,CIOBLOCK      GET POINTER TO  COPY DCB              64290016
         L     REG3,CCOPYPTR      POINT TO NEXT COPY BLOCK.             64340016
         B     POSTLOOP           LOOP UNTOL ALL UCBS ARE POSTED.       64400016
POSTUCB  EQU   *                                                        64480016
         SR    REG1,REG1          ASSUME OLD VOLID REQ'TD.              64560016
         ST    REG2,PARMUCB       STORE UCB PTR INTO PARM LIST.         64640016
         MVI   PARMUCB,X'08'      SET UP POST UCB INDICATOR.            64720016
         TM    SEQSW,NEWVOLID     WAS NEW VOLID REQUESTED.              64800016
         BZ    REG1OKAY           NO-SET REMAINER OF PARM LIST.         64880016
         LA    REG1,FSERNO        YES-GET ADDR OF NEW VOLID.            64960016
REG1OKAY EQU   *                                                        65040016
         ST    REG1,PARMCCHH      STORE VOLID PTR OR ZERO IN PARN LIST. 65120016
         MVC   SEEKADDR+3(4),VVTOCPTR  MOVE VTOC ADDRESS TO IOB SEEK.   65200016
         MVI   SEEKADDR+7,1       INSERT RECORD NO INTO  IOB.           65240016
         LA    REG1,SEEKADDR      GET PTR TO VTOC ADDRESS.              65280016
         ST    REG1,PARMALTD      STORE VTOC PTR INTO PARM LIST.        65360016
         LA    REG1,PARMALTD      ASSUME THIS IS LAST ENTRY IN LIST     65370016
         CLI   DDNAME2,X'40'      WAS THIS A NEW VOLUME REQUEST.        65380016
         BNE   POSTOKAY           NO-PARM LIST IS OKAY TO POST UCB.     65390016
         OI    PARMUCB,X'80'      YES-SET UP NEW VOLUME INDICATOR.      65400016
ONEPARM  EQU   *                                                 YM3475 65405002
         MVC   PARMDEB(4),DCBDEBAD     INSERT DEB ADDR INTO LIST.       65410016
         LA    REG1,PARMDEB       GET NEW LAST ENTRY ADDR.              65420016
POSTOKAY EQU   *                                                        65430016
         MVI   0(REG1),X'80'      INSERT LAST ENTRY INDICATOR INTO LIST 65440016
         LA    REG1,PARMLST       POINT TO PARM LIST.                   65520016
         SVC   82                 POST UCB.                             65600016
         BR    REG8               RETURN TO TEST FOR MORE UCBS.         65680016
POSTEND  EQU   *                                                        65760016
         DROP  REGB                                                     65840016
         USING IHADCB,REGF                                              65920016
         LH    REG2,RETCODE             GET COMPLETION CODE.    SA59746 66000021
         EJECT                                                          66050003
FREECORE EQU   *                                                        66080016
         L     REG9,WKBUFSI       GET SIZE OF WORKAREA TO BE FREED.     66160016
         LA    REG7,FBUFFPTR      GET ADDRESS OF AREA TO BE FREED.      66240016
         FREEMAIN E,LV=(REG9),A=(REG7)                                  66320016
FREEWKA  EQU   *                                                        66400016
         L     REGD,OLDSAPTR      GET SAVE AREA ADDRESS.                66480016
         FREEMAIN  R,LV=SIZE,A=(REG5)     FREE UNCONDITIONAL CORE.      66560016
         LR    REGF,REG2          GET PROPER RETURM CODE.               66640016
         B     RETCOMP                                                  66720016
**********************************************************************  66800016
**********************************************************************  66880016
**********************************************************************  66960016
*                                                                       67040016
BADEVICE EQU   *                                                        67120016
         LA    REG1,10            GET MESSAGE NUMBER.                   67200016
LINKAGE  EQU   *                                                        67280016
         BAL   REG8,BUILDMSG      GET DESIRED MSG.                      67360016
         MVC   0(8,REG1),DDNAME2    INSERT PROPER DDNAME                67440016
PRINTLNK EQU   *                                                        67480016
         LA    REG2,8             SET.UP REURN CODE                     67520016
         BAL   REG8,PRNTLINK          PRINT PROPER MSG.                 67680016
         LA    REG8,FREEWKA       SET UP RETURN ADRESS IN REG8.         67760016
         B     CLOSENXT           CLOSE ALL OPENED DATA SETS.           67840016
BADTRKAD EQU   *                                                        68320016
         LM    REG9,REG2,PRGSAVE  RESTORE REGS SAVED FOR CONVERT RTNE.  68400016
BADTRADD EQU   *                                                        68480016
         LA    REG1,25                                                  68560016
         L     REG3,COPYPTR       RESTORE COPY BLOCK BASE.              68640016
         B     LINKAGE                                                  68720016
         AIF   ('&LIB' EQ 'LIB2').X227218                       XL03912 68760003
IS2321   EQU   *                                                        68800016
         LOAD  EP=IEHDCELL        LOAD DCELL LOAD MODULE INTO CORE.     68820016
         ST    REG0,DCELADDR      SAVE ADDRESS OF LOAD MODULE IN FBLK.  68840016
         MVI   MAXR0BIT+4,1       SET UP R1 FOR IEHDCELL.               68880016
         LA    REG0,8                                                   68960016
         ST    REG0,MAXLTHR0+4    SET STANDARD R0 COUNT.                69040016
LINK2321 EQU   *                                                        69080016
         LA    REG1,SAVEVTOC      GET SAVEAREA PTR FOR IEHDCELL         69120016
         L     REGF,DCELADDR      GET ADDRESS OF LOAD MODULE.           69160016
         BALR  REGE,REGF          CALL IEHDCELL.                        69200016
         LA    REGD,SAVEAREA      RESTORE MY SAVEAREA POINTER.          69240016
         LTR  REGF,REGF                                                 69280016
         BNZ   ABNORMN                                                  69360016
         L     REG1,PTRCFUNC                                            69440016
         TM    0(REG1),COMPLETE   IS CURRENT COMPLETE.                  69520016
         BZ    CONCUR             NO-RETURN TO MONITOR.                 69600016
         DELETE  EP=IEHDCELL      REDUCE RESPONSIBILITY COUNT.          69640016
         B     BLDVTOC            OTHERWISE CONSTRUCT VTOC.             69680016
.X227218 ANOP                                                   XL03912 69720003
         EJECT                                                          69730003
BADTRAKF EQU   *                                                        69760016
         TM    WKAIOB+3,X'0A'     WAS ER NO RCD FOUND/MISSING AM.       69840016
         BO    RETRYF             YES-RETRY AND USE STANDARD ERROR REC. 69920016
         CLI   UCBTBYT4,X'08'     IS THIS A 2314.                       70000016
         BNE   SYNADERR         NO-IO ERROR TERMINATE.                  70080016
         TM    WKAIOB+3,X'40'     IS THIS TRACK OVER RUN.               70160016
         BZ    SYNADERR           NO-SYNAD ERROR EXIT.                  70240016
PREFLAG  EQU   *                                                        70400016
         AIF   ('&LIB' EQ 'LIB1').X326202                        XM5465 70410003
         BAL   REG1,SDFLAG             CHECK FOR 3340.           XM5465 70430003
.X326202 ANOP                                                    XM5465 70440003
BDTRKERF EQU   *                                                        70450003
         LA    REG1,FALTDATA                                            70480016
         LA    REG9,DDNAME2       GET PTR TO PROPER BDNAME.             70560016
         AIF   ('&LIB' EQ 'LIB1').X227110                       XL03130 70580003
         LA    REG0,ODEVMOD             GET DEV MOD NO.         XL03130 70600003
.X227110 ANOP                                                   XL03130 70620003
         BAL   REG7,BUILDLST      BUILD LIST FOR SVC 82.                70640016
         L     REG7,FBUFFPTR      RESTORE BUFFER POINTER                70720016
         SR    REG0,REG0          SET CURRENT PASS TO LAST PASS.        70740016
         STH   REG0,COUNT                                               70760016
         B     TESTWAIT           WAIT FOR OUTSYANDING I/O REQ'S.       70800016
BADTRAKC EQU   *                                                        70880016
         TM    WKAIOB+3,X'0A'     WAS ER NO RCD FOUND/MISSING AM.       70960016
         BO    RETRYC             YES-RETRY AND USE STANDARD ERROR REC. 71040016
         CLI   UCBTBYT4,X'08'     IS THIS A 2314.                       71120016
         BNE   SYNADERR         NO-IO ERROR TERMINATE.                  71200016
         TM    WKAIOB+3,X'40'     IS THIS TRACK OVER RUN.               71280016
         BZ    SYNADERR           NO-SYNAD ERROR EXIT.                  71360016
PREFLAGC EQU   *                                                        71520016
         AIF   ('&LIB' EQ 'LIB1').X326103                        XM5465 71530003
         BAL   REG1,SDFLAG             CHECK FOR 3340.           XM5465 71550003
.X326103 ANOP                                                    XM5465 71560003
BDTRKERC EQU   *                                                        71570003
         LA    REG1,CALTDATA      GET PTR TO ALTERNATE TRACK INFO.      71600016
         LA    REG9,DDNAME3       GET PTR TO PROPER DDNAME.             71680016
         AIF   ('&LIB' EQ 'LIB1').X227111                       XL03130 71700003
         LA    REG0,CDEVMOD             GET DEV MOD NO.         XL03130 71720003
.X227111 ANOP                                                   XL03130 71740003
         BAL   REG7,BUILDLST      BUILD PARAMETER LIST FOR SVC 82.      71760016
         L     REG7,FBUFFPTR      RESTORE BUFFER POINTER                71840016
         SR    REG0,REG0          SET CURRENT PASS TO LAST PASS.        71860016
         STH   REG0,COUNT                                               71880016
         B     CTSTWAIT           WAIT FOR OUTSTANDING I/O REQ'S.       71920016
         EJECT                                                          71930003
         AIF   ('&LIB' EQ 'LIB1').X326400                        XM5465 71970003
*****************************************************************XM5465 71970403
*                                                                XM5465 71970803
*    THIS ROUTINE IS ENTERED WHEN THE DEFECTIVE BIT IS FOUND     XM5465 71971203
*    TO BE ON IN THE HOME ADDRESS. IF THE FUNCTION IS ANALYZE    XM5465 71971603
*    WITH FLAGTEST=NO AND THE DEVICE IS A 3340, THE CCW          XM5465 71971703
*    POINTER IN THE IOB IS CHANGED TO POINT TO THE ANALYZE CCWS. XM5465 71971803
*    THE RETURN ADDRESS IS THEN IGNORED AND CONTROL IS PASSED    XM5465 71971903
*    TO THE ROUTINE WHICH WILL ATTEMPT TEN SUCCESSFUL  PASSES    XM5465 71976403
*    TO DETERMINE THE TRACK'S USEFULLNESS.                       XM5465 71978403
*                                                                XM5465 71980403
*****************************************************************XM5465 71980803
         SPACE                                                          71980903
SDFLAG   EQU   *                                                 XM5465 71981003
         CLI   FUNCSW,FORMAT           IS THIS A FORMAT?         XM5465 71985503
         BCR   EQ,REG1                 YES, ASSIGN ALTERNATE.    XM5465 71990003
         SPACE                                                          71990403
         CLI   UCBTBYT4,WIN            IS THIS A 3340?           XM5465 71992003
         BCR   NE,REG1                 NO, ASSIGN ALT.           XM5465 71994003
         SPACE                                                          71994403
         CLC   SDBYTES,ZERO            ARE SKIP BYTES ZERO?      XM5465 71996003
         BE    GETBACK                 ATTEMT RECLAIM.           XM5465 71998003
         SPACE                                                          71998103
         CLC   SDBYTES,HAR0SKIP        SKIP BYTES IND HA R0 SD?  XM5465 71998403
         BCR   LOW,REG1                YES, ASSIGN ALT.          XM5465 71998803
         SPACE                                                          71998903
GETBACK  EQU   *                                                 XM5465 71999203
         NI    SDHA,NODEFECT           REMOVE BIT 6 FROM HA.     XM5465 71999303
         LA    REG1,CCWSHCON           GET ANALYZE CCWS.         XM5465 71999403
         ST    REG1,CCWPTR             USE AS IOBSTART ADDRESS.  XM5465 71999503
         LA    REG1,FBLOCKS            ADDR OF PRIMARY BLOCKS.   XM5465 71999603
         CR    REG1,REGF               IS DEVICE A COPY?         XM5465 71999703
         BE    RETRYF                  NO, DO IT TO THE PRIMARY. XM5465 71999803
         B     RETRYC                  YES, DO IT TO A COPY.     XM5465 71999903
         EJECT                                                          72009903
.X326400 ANOP                                                    XM5465 72026603
*                                                                       72053303
**********************************************************************  72080016
*                                                                       72160016
BUILDLST EQU   *                                                        72240016
         LA    REG2,0(REG2)       CLEAR HIGH ORDER BYTE IN UCB REG.     73040016
         LR    REGB,REGF          SAVE I/O CONTROL BLOCKS PTR.          73120016
         MVC   PARMCCHH(4),SEEKADDR+3  SET UP CCHH OF BAD TRACK.        73200016
         ST    REG2,PARMUCB       SET UP PTR TO UCB IN PARMLST.         73280016
         ST    REG1,PARMALTD      SET UP PTR TO ALT DATA INFO.          73360016
         AIF   ('&LIB' EQ 'LIB1').X227112                       XL03130 73370003
         ST    REG0,PARMMOD             PUT DEV MOD PTR IN PARM.XL03130 73380003
         MVI   PARMMOD,LASTPARM         SET UP LAST PARM ENTRY  XL03130 73390003
         AGO   .X227113                                         XL03130 73400003
.X227112 ANOP                                                   XL03130 73410003
         MVI   PARMALTD,X'80'     SET UP LAST ENTRY INDICATOR.          73440016
.X227113 ANOP                                                   XL03130 73480003
         LA    REG1,31            PICK UP MESSAGE NUMBER.               73520016
         BAL   REG8,BUILDMSG      PLACE MESSAGE INTO OUTPUT BUFFER.     73600016
         MVC   0(8,REG1),0(REG9)  INSERT  DDNAME INTO MSG.              73680016
         UNPK  13(9,REG1),PARMCCHH(5)                                   73760016
         TR    13(8,REG1),TRTABLE-240  CONVERT CCHH TO PRINTABLE FORM.  73840016
         MVI   21(REG1),X'40'        BLANK OUT ZONED BYTE.              73920016
         BAL   REG8,PRNTLINK      PRINT DEFECTIVE TRACK MESSAGE.        74000016
         DROP  REGF                                                     74006016
         USING IHADCB,REGB                                              74012016
         CLC   SEEKADDR+3(4),CCWORD2+4 WAS THIS TRACK ZERO.             74012516
         BNE   NOTZERO            NO-BYPASS NOT IPLABLE MSG.            74013016
         LA    REG1,28            YES-BUILD NOT IPLABLE MSG.            74013516
         BAL   REG8,BUILDMSG                                            74014016
         MVC   0(8,REG1),0(REG9)      INSERT PROPER DDNAME INTO MSG.    74014516
         TM    SEQSW,IPLDD        WAS IPL TEXT REQUESTED.               74015016
         BO    LNKTOPRT           YES-PRINT MSG AND TERMINATE.          74015516
         BAL   REG8,PRNTLINK      NO-PRINT MSG AND CONTINUE.            74016016
NOTZERO  EQU   *                                                        74016516
         AIF   ('&LIB' EQ 'LIB2').X225900                       XL03130 74020503
         TM    UCBTBYT4,2         IS THIS A DRUM DEVICE.                74025402
         BO    DRUMMSG            YES- NO ALTERNATE ASSIGNED MSG.       74029302
OK2305   EQU   *                                                 M4682  74033202
.X225900 ANOP                                                   XL03130 74034203
         TM    DCBIOBAD,X'80'     IS THIS A BAD HA-R0                   74037102
         BZ    NOTDRUM            NO-ASSIGN ALTERNATE TRACK.            74041002
         LA    REG1,29            GET DEFECTIVE HA/R0 MSG.              74044902
         BAL   REG8,BUILDMSG      PLACE MSG INTO OUTPUT BUFFER.         74048802
         MVC   0(8,REG1),0(REG9)  INSERT DDNAME INTO MSG BUFFER.        74052702
         AIF   ('&LIB' EQ 'LIB1').X225902                       XL03130 74053403
         CLI   UCBTBYT4,WIN             IS THIS A 3340 DEVICE?  XL03130 74054103
         BE    PRTGET                   YES, PRT MSG, CALL SVC. XL03130 74054803
.X225902 ANOP                                                   XL03130 74055503
         CLI   UCBTBYT4,K2314     IS THIS A 2314 DEVICE.        XL03912 74056603
         BNE   LNKTOPRT           NO-PRINT MSG AND TERMINATE.           74060502
PRTGET   EQU   *                                                XL03130 74061503
         BAL   REG8,PRNTLINK      PRINT DEFECTIVE HA/R0 MSG.            74064402
         B     NOTDRUM                                                  74068302
         EJECT                                                          74070303
         DROP  REGB                                                     74072202
         USING IHADCB,REGF                                              74076102
         AIF   ('&LIB' EQ 'LIB2').X225901                       XL03130 74077103
DRUMMSG  EQU   *                                                        74080016
         CLI   UCBTBYT4,X'06'           IS IT A 2305-1           M4682  74083020
         BE    OK2305                   YES - THERE IS AN        M4682  74086020
*                                       ALTERNATE                M4682  74089020
         CLI   UCBTBYT4,X'07'           IS IT A 2305-2           M4682  74092020
         BE    OK2305                   YES - THERE IS AN        M4682  74095020
*                                       ALTERNATE                M4682  74098020
         LA    REG1,23            YES-SET UP MESSAGE AND TERMINATE.     74104016
         MVI   RETCODE+1,4              SET RETURN CODE TO 4.   SA59746 74108021
ALTLINK  EQU   *                                                        74112016
         BAL   REG8,BUILDMSG      BUILD MSG IN OUTPUT BUFFER.           74120016
INSDDNM  EQU   *                                                        74128016
         MVC   0(8,REG1),0(REG9)   INSERT DDNAME INTO MESSAGE.          74136016
         B     MSGPRINT                                                 74144016
.X225901 ANOP                                                   XL03130 74148003
NOTDRUM  EQU   *                                                        74152016
         LA    REG1,PARMLST       GET POINTER TO PARM LIST.             74156016
         SVC   82                 ASSIGN ALTERNARE TRACK.               74160016
         B     *+4(REGF)                                                74240016
         B     GOODRTRN      0 RETURN CODE-SUCCESSFUL COMPLETION.       74320016
         B     *            SHOULD NOT OCCUR IF SO HANG.                74400016
         B     *            SHOULD NOT OCCUR IF SO HANG.                74480016
         B     IOERRORF     12 RETURN CODE -I/O ERROR.                  74560016
         B     NOALTRKF     16 RETURN-NO MORE ALTERNATE TRACKS.         74640016
GOODRTRN EQU   *                                                        74720016
         L     REG0,PARMCCHH      GET CCHH OF ASSIGNED ALTERNATE TRACK. 74800016
         LTR   REG0,REG0          WAS ALTERNATE TRACK ASSIGNED.         74880016
         BZ    NOMESSGE           NO-BYPASS MESSAGE OUTPUT.             74960016
         LA    REG1,32            GET MESSAGE NUMBER.                   75040016
         BAL   REG8,BUILDMSG      PLACE MESSAGE INTO OUTPUT BUFFER.     75120016
         MVC   0(8,REG1),0(REG9)  INSERT  DDNAME INTO MSG.              75200016
         UNPK  13(9,REG1),PARMCCHH(5)                                   75280016
         TR    13(8,REG1),TRTABLE-240  CONVERT CCHH TO PRINTABLE FORM.  75360016
         MVI   21(REG1),X'40'                                           75440016
MSGPRINT EQU   *                                                        75480016
         BAL   REG8,PRNTLINK      PRINT ALTERNATE TRACK MESSAGE.        75520016
         BR    REG7               RETURN TO CALLER.                     75600016
NOMESSGE EQU   *                                                        75680016
         LA    REG1,32            GET MESSAGE NUMBER.                   75760016
         BAL   REG8,BUILDMSG      PLACE MESSAGE INTO OUTPUT BUFFER.     75840016
         MVC   0(8,REG1),0(REG9)  INSERT  DDNAME INTO MSG.              75920016
         BAL   REG8,PRNTLINK      PRINT ALTERNATE TRACK MESSAGE.        76000016
         LR    REGF,REGB          RESTORE I/O CONTROL BLOCKS BASE.      76080016
         BR    REG7                                                     76160016
IOERRORF EQU   *                                                        76240016
         LA    REG1,13            GET I/O ERROR MSG.                    76320016
         BAL   REG8,BUILDMSG      BUILD MSG IN OUTPUT AREA.             76400016
         MVC   0(3,REG1),SVCNUMBR  INSERT SVC NO THAT HAD I/O ERROR.    76480016
         MVC   3(8,REG1),0(REG9)     INSERT DDNAME INTO MSG.            76560016
         B     LNKTOPRT      PRINT MESSAGE AND TERMINATE.               76640016
NOALTRKF EQU   *                                                        76720016
         LA    REG1,27            GET NO MORE ALT TRKS MSG.             76800016
         BAL   REG8,BUILDMSG                                            76840016
         MVC   0(8,REG1),0(REG9)       INSERT DDNAME INTO MSG.          76880016
         B     LNKTOPRT           PRINT MSG AND TERMINATE.              76920016
         EJECT                                                          76930003
*                                                                       76960016
**********************************************************************  77040016
*                                                                       77120016
SYNADERR EQU   *                                                        77200016
         LR    REG4,REGF          SAVE I/O CONTROL BLOCKS BASE.         77280016
         DROP  REGF                                                     77360016
         USING IHADCB,REG4                                              77440016
         LA    REG1,13            GET I/O ERROR MSG NO.                 77520016
         BAL   REG8,BUILDMSG      PLACE MSG INTO PRINT BUFFER.          77600016
         SYNADAF  ACSMETH=EXCP,PARM1=WKAIOB                             77680016
         MVC   MESS+22(78),49(REG1)   SET UP MSG HDNG.           SM4350 77760021
         SYNADRLS                                                       77840016
         LR    REGF,REG4          RESTORE I/O CONTROL BLOCKS BASE.      77920016
         DROP  REG4                                                     78000016
         USING IHADCB,REGF                                              78080016
         B     LNKTOPRT           PRINT I/O ERROR MSG.                  78160016
ONLINERR EQU   *                                                        78240016
         LA    REG1,24                                                  78320016
         BAL   REG8,BUILDMSG      GET PROPER MSG.                       78400016
         MVC   0(8,REG1),DDNAME2                                        78480016
         B     LNKTOPRT                                                 78560016
ONLINERC EQU   *                                                        78640016
         LA    REG1,24                                                  78720016
SETMSG   EQU   *                                                        78760016
         BAL   REG8,BUILDMSG                                            78800016
         B     COPYMSG                                                  78880016
VOLUMERR EQU   *                                                        78960016
         LA    REG1,14            GET MSG NUMBER.                       79040016
         BAL   REG8,BUILDMSG      MOVE MSG TO OUTPUT BUFFER.            79050016
         MVC   0(8,REG1),DDNAME2  INSERT DDNAME INTO MSG BUFFER.        79060016
SYSRESER EQU   *                                                        79070016
         MVC   MESS+9(10),FUNCNAM1     INSERT FUNCTION NAME INTO MSG.   79080016
         CLI   FUNCSW,ANALYSIS    TEST FOR CORRECT FUNCTION.            79090016
         BE    PRINTLNK           PRINT MSG IF FUNCTION IS CORRECT.     79100016
         MVC   MESS+9(10),FUNCNAM2     INSERT FORMAT FUNCTION NAME.     79130016
         B     PRINTLNK           PRINT MSG AND TERMINATE.              79160016
         EJECT                                                          79170003
VOLUMERC EQU   *                                                        79200016
         LA    REG1,14                                                  79280016
SETUPCPY EQU   *                                                        79360016
         BAL   REG8,BUILDMSG                                            79440016
         MVC   0(8,REG1),DDNAME3                                        79520016
         B     SYSRESER           COMPLETE MSG AND PRINT/TERMINATE.     79620016
BADCOPY  EQU   *                                                        79760016
         LA    REG1,21                                                  79840016
         B     SETMSG             SET UP ERROR MSG IN OUTPUT BUFFER.    79920016
NOTOPEN  EQU   *                                                        80000016
         LA    REG1,5             GET MSG NUMBER.                       80080016
         LR    REG9,REGF          SAVE CURRENT POINTER.                 80160016
         BAL   REG8,BUILDMSG      GET PROPER MSG.                       80240016
         MVC   0(8,REG1),DDNAME2  ASSUME THIS WAS THE PRIMARY FUNC.     80320016
         LA    REGF,FBLOCKS                                             80400016
         CR    REG9,REGF          TEST FOR COPY FUNCTION.               80480016
         BE    LNKTOPRT           BRANCH IF PRIMARY FUNCTION.           80560016
         LR    REGF,REG9          POINT TO  CURRENT DCB.                80640016
COPYMSG  EQU   *                                                        80720016
         MVC   0(8,REG1),DDNAME3  INSERT COPY DDNAME INTO MSG.          80800016
LNKTOPRT EQU   *                                                        80880016
         BAL   REG8,PRNTLINK      PRINT CORRECT MSG.                    80960016
         LA    REGF,8             SET ABNORMAL COMPLETION CODE.         81000016
MSGBUILD EQU   *                                                        81040016
         LR    REG2,REGF          PICK UP RETURN CODE.                  81120016
         LA    REGB,FBLOCKS       POINT TO PRIMARY CONTROL BLOCKS.      81200016
         AIF   ('&LIB' EQ 'LIB1').X227300                        YM3475 81204002
         DROP  REGF                                                     81208002
         USING IHADCB,REGB                                              81212002
         CLI   DCBDDNAM,BLANK           IS THIS OFFLINE?         YM3475 81216002
         BNE   ONLINE                   NO, LET CLOSE DO IT.     YM3475 81220002
DELREQ   EQU   *                                                 YM1377 81222002
         CLC   DCBDEBAD(4),DDNAME2+4    IS DEB REMOVED?          YM3475 81224002
         BE    RETRNABN                  YES, GO FREE CORE.      YM3475 81228002
         MVI   PARMUCB,DELDEB           SET DEB DELETE REQUEST.  YM3475 81236002
         BAL   REG8,ONEPARM             GO DELETE DEB.           YM3475 81240002
         LTR   REG3,REG3                ANY COPIES?              YM3475 81244002
         BZ    RETRNABN                 NO, GO FREE CORE.        YM3475 81248002
         LA    REGB,CIOBLOCK            YES, GET COPY CNTL BLK.  YM3475 81252002
         L     REG3,CCOPYPTR            GET NEXT COPY POINTER.   YM3475 81256002
         B     DELREQ                   GO DELETE ANOTHER DEB.   YM3475 81260002
         EJECT                                                          81262003
ONLINE   EQU   *                                                 YM3475 81264002
.X227300 ANOP                                                    YM3475 81268002
         LA    REG8,RETRNABN      PICK UP RETURN ADDRESS.               81280016
         B     CLOSENXT           CLOSE ALL OPENED DATA SETS.           81360016
BUILDMSG EQU   *                                                        81440016
         LINK  EP=IEHDMSGB                                              81520016
         BR    REG8                                                     81600016
PRNTLINK EQU   *                                                        81680016
         LINK  EP=IEHDPRNT                                              81760016
         BR    REG8                                                     81840016
         AIF   ('&LIB' EQ 'LIB2').X227219                       XL03912 81880003
         USING DATACELL,REG2                                            81920016
MSG2321  EQU   *                                                        82000016
         MVC   40(6,REG1),DCELVOLI INSERT OLD VOLID INTO MSG BUFFER.    82080016
         B     MSGCOMPL               PRINT MESSAGE.                    82160016
.X227219 ANOP                                                   XL03912 82200003
         EJECT                                                          82210003
*                                                                       82240016
*                                 CONSTANTS                             82320016
*                                                                       82400016
         SPACE                                                          82402003
FACTPACK EQU   9                                                 S20201 82407020
RPS      EQU   X'40'                    INDIC RPS DEVICE        XM4389  82409003
TWO      EQU   2                        DISPLACEMENT CONSTANT    X99204 82411002
D1       EQU   1                                                 S20201 82435020
X05      EQU   X'05'                   HEX CONSTANT.             S20201 82442020
K3       EQU   3                       DISPLACEMENT CONSTANT.    S20201 82449020
K16      EQU   16                                                XM6030 82451000
K136     EQU   136                                               S20201 82456020
K2314    EQU   X'08'                    UCB DEVICE TYPE 2314.   XL03912 82456803
RETCODE  DC    H'0'                     RETURN CODE SAVE AREA.  SA59746 82458002
         AIF   ('&LIB' EQ 'LIB1').X227220                       XL03912 82458103
ZEU1     EQU   X'06'                    UCB DEVICE TYEP 2305-1. XL03912 82458403
ZEU2     EQU   X'07'                    UCB DEVICE TYPE 2305-2. XL03912 82459203
WIN      EQU   X'0A'                    UCB DEVICE TYPE 3340.   XL03130 82460003
HAR0SKIP DC    H'286'                  SKIP DISPLACEMENT.        XM5465 82460103
TEST3340 DC    X'76B3BD1FAAAAFFFF'     3340 TEST PATTERN.        XM5465 82460403
PATTERN  DC    X'5555555555555555'     OTHER DEVICE PATTERN      XM5465 82460803
TICCMD   EQU   X'08'                   TRANS IN CHANNEL CMD      XM5465 82461203
SENSE    EQU   X'04'                   SENSE COMMAND.            XM5465 82461303
MAXBYTE  EQU   255                     MAX NUMBER IN ONE BYTE.   XM5465 82461403
NULL     EQU   0                       THE EMPTY SET.            XM5465 82461503
CHAIN    EQU   X'40'                   CHAINING CCWS             XM5465 82463503
B8       EQU   8                       LENGTH OF 8 BITS.         XM5465 82465503
D4       EQU   4                       DISPLACEMENT OF FOUR.     XM5465 82467503
D16      EQU   16                      DISPLACEMENT OF SIXTEEN.  XM5465 82467903
EQ       EQU   8                       EQUQL TO.                 XM5465 82468303
NE       EQU   7                       NOT EQUAL TO.             XM5465 82468703
LOW      EQU   4                       LESS THAN.                XM5465 82469103
K9       EQU   9                       CONSTANT OF 9.            XM5465 82469503
L7       EQU   7                       LENGTH OF SEVEN.          XM5465 82469903
L8       EQU   8                       LENGTH OF EIGHT.          XM5465 82470603
L24      EQU   24                      LENGTH OF TWENTY FOUR.    XM5465 82471003
ONE      EQU   1                       CONSTANT OF ONE.          XM5465 82471403
NODEFECT EQU   X'FD'                   MASK FOR ALL BUT DEFECT.  XM5465 82471503
WRITE    EQU   X'19'                   WRITE COMMAND.            XM5465 82471803
.X227220 ANOP                                                   XL03912 82472003
TEMP     DS    F                                                 S20201 82474003
F1       DC    F'1'                                              S20201 82478003
ZERO     EQU   F1                      1ST 2 BYTES OF F1 EQ 00. SA59746 82482003
         EJECT                                                          82484003
         DS    0D          ALIGN CCWS ON A DOUBLE WORD BOUNDARY.        82486003
SETSECCW EQU   *                        *                        S20201 82490020
         CCW   X'23',F1,X'40',1         SET SECTOR ZERO          M5900  82500020
TICCW    EQU   *                        *                        S20201 82510020
         DC    X'08'                                             S20201 82520020
TICADD   DC    AL3(0)                                            S20201 82530020
         DC    F'0'                                              S20201 82540020
CCWORD1  EQU   *                  SEARCH/WRITE HOME ADDRESS             82560016
         DC    X'39'                                                    82640016
         DC    AL3(1)                                                   82720016
         DC    X'60000005'                                              82800016
CCWORD2  EQU   *                                                        82880016
         DC    X'08'                                                    82960016
         DC    AL3(CCWORD1-CCWORD1)                                     83040016
         DC    F'0'                                                     83120016
CCWORD3  EQU   *                  WRITE R0MAXIMUM LENGTH                83200016
         DC    X'15'                                                    83280016
         DC    AL3(0)                                                   83360016
         DC    X'60000000'                                              83440016
CCWORD4  EQU   *                  READ HOME ADDRESS                     83520016
         DC    X'1A'                                                    83600016
         DC    AL3(0)                                                   83680016
         DC    X'60000005'                                              83760016
CCWORD5  EQU   *                  READ R0                               83840016
         DC    X'16'                                                    83920016
         DC    AL3(0)                                                   84000016
         DC    X'70000008'                                              84080016
CCWORD6  EQU   *                  SEARCH HOME ADDRESS                   84160016
         DC    X'39'                                                    84240016
         DC    AL3(1)                                                   84320016
         DC    X'60000004'                                              84400016
CCWORD7  EQU   *                  TIC TO CC6CONS                        84480016
         DC    X'08'                                                    84560016
         DC    AL3(CCWORD6-CCWORD1)                                     84640016
         DC    F'0'                                                     84720016
CCWORD8  EQU   *                  WRITE R0 MAXIMUM LENGTH.              84800016
         DC    X'15'                                                    84880016
         DC    AL3(0)                                                   84960016
         DC    X'60000010'                                              85040016
CCWORD9 EQU    *                  READ HOME ADDRESS                     85120016
         DC    X'1A'                                                    85200016
         DC    AL3(0)                                                   85280016
         DC    X'40000005'                                              85360016
CCWORDA  EQU   *                  READ R0                               85440016
         DC    X'16'                                                    85520016
         DC    AL3(0)                                                   85600016
         DC    X'60000010'                                              85680016
CCWORDB  EQU   *                  SEARCH HOME ADDRESS.                  85760016
         DC    X'39'                                                    85840016
         DC    AL3(1)                                                   85920016
         DC    X'60000004'                                              86000016
CCWORDC  EQU   *                  TIC TO CCWCONS                        86080016
         DC    X'08'                                                    86160016
         DC    AL3(CCWORDB-CCWORD1)                                     86240016
         DC    F'0'                                                     86320016
CCWORDD  EQU   *                  WRITE STANDARD R0.                    86400016
         DC    X'15'                                                    86480016
         DC    AL3(0)                                                   86560016
         DC    X'40000010'                                              86640016
CCWORDE  EQU   *                  READ HOME ADDRESS                     86720016
         DC    X'1A'                                                    86800016
         DC    AL3(0)                                                   86880016
         DC    X'60000005'                                              86960016
CCWORDF  EQU   *                  READ R0 SKIP DATA TRANSFER.           87040016
         DC    X'16'                                                    87120016
         DC    AL3(0)                                                   87200016
         DC    X'10000010'                                              87280016
ZALTCCW  CCW   X'19',ZCCHH,X'20',5      CLEAR ASSIGNED ALT       A43248 87330002
         AIF   ('&LIB' EQ 'LIB1').X227301                        YM3475 87332003
BLANK    EQU   X'40'                    OFFLINE INDICATION.      YM3475 87334003
DELDEB   EQU   X'F8'                    DEB DELETE REQUEST.      YM3475 87336003
.X227301 ANOP                                                    YM3475 87338003
FUNCNAM1 DC    C'ANALYZE OF'                                            87338403
FUNCNAM2 DC    C'FORMAT OF '                                            87338803
SVCNUMBR DC    C'82,'                                                   87339203
UNASGBT  DC    X'00'                    UNASSIGN RTN SW          M4682  87339603
SAVCCHHR DC    F'0'                                              M4682  87339703
SAVCCWPT DC    F'0'                                              M4682  87339803
ZCCHH    DC    X'0200000000'                                     M4682  87339903
ZEUSALT  DC    X'0000000000'                                     M4682  87346603
TRTABLE  DC    C'0123456789ABCDEF'                                      87348603
*                                                                       87350603
         EJECT                                                          87353303
         AIF   ('&LIB' EQ 'LIB1').OSDCB                                 87420000
DASDIDCB DCB   DSORG=PS,MACRF=(E),DEVD=DA,EOEA=P8,XENDA=P9,      M5431 F87440003
               SIOA=P7,PGFX=YES                                  M5431  87490000
         AGO   .C1                                                      87500000
.OSDCB   ANOP                                                           87510000
DASDIDCB DCB   DSORG=PS,MACRF=(E),DEVD=DA,EOEA=P8,XENDA=P9              87512003
.C1      ANOP                                                           87514000
DCBCONST EQU   DASDIDCB                                                 87520016
         EJECT                                                          87970003
**********************************************************************  88000016
         IEHDBLKS                                                       88080016
DCELADDR EQU   FCCWS+88                                                 88120016
         EJECT                                                          88130003
*                                                                       88160016
**********************************************************************  88240016
*                                                                       88320016
         IEHDWORK                                                       88400016
WORK1    EQU   WORK                                                     88480016
         EJECT                                                          88530003
*                                                                       88560016
**********************************************************************  88640016
CVT      DSECT                                                          88720016
         CVT   SYS=MIN                                                  88800016
         EJECT                                                          88850003
*                                                                       88880016
**********************************************************************  88960016
UCB      DSECT                                                          89040016
         IEFUCBOB                                                       89120016
         EJECT                                                          89170003
*                                                                       89200016
**********************************************************************  89280016
JFCB     DSECT                                                          89360016
         IEFJFCBN                                                       89440016
         EJECT                                                          89490003
*                                                                       89520016
**********************************************************************  89600016
         DCBD  DSORG=PS                                                 89680016
         EJECT                                                          89730003
DCBCON   EQU   IHADCB                                                   89760016
         ORG   IHADCB+72                                                89840016
WKAECB   DS    F                  ECB                                   89920016
WKAIOB   DS    F                  IOB                                   90000016
ECBADD   DS    F                  ECB POINTER.                          90080016
CSWORD   DS    F                                                        90160016
         DS    F                                                        90240016
CCWPTR   DS    F                  CHANNEL PROGRAM POINTER.              90320016
DCBADD   DS    F                  DCB POINTER.                          90400016
         DS    F                                                        90480016
BLKERRCT DS    F                  BLOCK AND ERR RETRY COUNT.            90560016
SEEKADDR DS    2F                 SEEK ADDRESS.                         90640016
         DS    F                                                        90720016
CWCONST  DS    0D                                                       90800016
CCWSECON DS    D                                                 S20201 90820020
TICSEC   DS    D                                                 S20201 90840020
CCW1CONS DS    D                                                        90880016
CCW2CONS DS    D                                                        90960016
CCW3CONS DS    D                                                        91040016
CCW4CONS DS    D                                                        91120016
CCW5CONS DS    D                                                        91200016
CCW6CONS DS    D                                                        91280016
CCW7CONS DS    D                                                        91360016
CCW8CONS DS    D                                                        91440016
CCW9CONS DS    D                                                        91520016
CCWACONS DS    D                                                        91600016
CCWBCONS DS    D                                                        91680016
CCWCCONS DS    D                                                        91760016
CCWDCONS DS    D                                                        91840016
CCWECONS DS    D                                                        91920016
CCWFCONS DS    D                                                        92000016
         AIF   ('&LIB' EQ 'LIB1').X326401                        XM5465 92050003
CCWSHCON EQU   CCWSECON                SEARCH ON 3340.           XM5465 92060003
SDCCW1   DS    D                       READ ON 3340.             XM5465 92070003
SDCCW2   DS    D                       SENSE ON 3340.            XM5465 92072003
SDTIC    DS    D                       TIC TO FMT CCW            XM5465 92072403
SDSNS    DS    CL24                    READIN AREA FOR SENSE.    XM5465 92074003
         ORG   SDSNS+22                                          XM5465 92076003
SDBYTES  DS    CL2                     SKIP DISPLACEMENT BYTES.  XM5465 92078003
SDHA     DS    CL5                     3340 HOME ADDRESS.        XM5465 92078403
.X326401 ANOP                                                    XM5465 92078803
         EJECT                                                          92079203
*                                                                       92080016
**********************************************************************  92160016
WORKAREA DSECT                                                          92240016
RDAREA1  EQU   *                                                        92320016
         DS    CL188                                             JUDITH 92400020
SAVEAREA  DS    0F                                                      92480016
PL1WORD  DS    F                  THIS WORD IS USED BY PL/1.            92560016
OLDSAPTR DS    F                  POINTER TO PREVIOUS SAVE AREA.        92640016
NEWSAPTR DS    F                  POINTER TO NEXT SAVE AREA.            92720016
RETADREG DS    F                  (REG14)-RETURN ADDRESS REGISTER.      92800016
ENTRYPTR DS    F                  (REG15)-ENTRY POINT REGISTER.         92880016
REG0TO12 DS    13F                REGISTERS 0 THROUGH 12.               92960016
SAVEVTOC DS    8F                                                       93040016
         DS    0D                                                JUDITH 93080020
PRGSAVE  DS    10F                                                      93120016
RTAVTOCS DS    F                                                        93200016
RTAVTOCE DS    F                                                        93280016
         ORG   *-16                                                     93360016
DDEB     DS    0F                 FAKE DEB FOR CONVERT ROUTINE.         93440016
         ORG   *+16                                                     93520016
DEXTNTNO DS    CL1                DUMMY EXTNT NUMBER.                   93600016
MBBCCHH1 DS    CL7                SAVE AREA FOR VTOC EXTENT.            93680016
MBBCCHH2 DS    CL8                                                      93760016
DUCBPTR  DS    F                  FAKE UCB POINTER.                     93840016
HALFWD   DS    H                  HALF WORD WORK SPACE.                 93920016
DEXTNTS  DS    HL4                DUMMY STARTING CCHH(000000)           94000016
DEXTNTE  DS    HL4                DUMMY ENDING CCHH.                    94080016
DEXTNTR  DS    H                  DUMMY NO TRACKS.                      94160016
WKBUFPTR DS    F                                                        94240016
WKBUFSI  DS    F                                                        94320016
PARMLST  DS    0F                                                       94400016
PARMUCB  DS    F                                                        94480016
PARMDCB  DS    F                                                        94560016
PARMCCHH EQU   PARMDCB                                                  94640016
PARMALTD DS    F                                                        94720016
PARMDEB  DS    F                                                        94760016
         AIF   ('&LIB' EQ 'LIB1').X228303                       XL03130 94768003
LASTPARM EQU   X'80'                    END OF PARAMETER LIST.  XL03130 94776003
PARMMOD  EQU   PARMDEB                  DEV MOD PTR.            XL03130 94784003
.X228303 ANOP                                                   XL03130 94792003
OPENLD   EQU   *                                                        94800016
         RDJFCB (,(INPUT)),MF=L                                         94880016
LIST     EQU   *                                                        94960016
         DC    X'87'              JFCB EXIT LIST CODE.                  95040016
         DC    AL3(0)                                                   95200016
WKAEND   DS    0D                                                       95240016
SIZE     EQU   WKAEND-RDAREA1                                           95280016
VOLSERL  EQU   RDAREA1+108                                       M3966  95360020
VVTOCPTR EQU   RDAREA1+119                                       M4683  95440020
*                                                                       95520016
**********************************************************************  95600016
*                                                                       95680016
BUFFCORE DSECT                                                          95760016
STNDR0   DS    CL16               LOCATION OF STANDARD R0 COUNT.        95840016
MAXLTHR0 DS    CL16               LOCATION OF MAXIMUM LENGTH R0 COUNT   95920016
MAXR0BIT DS    CL16               LOCATION R0 COUNT AND BIT PATTERN.    96000016
         DC    AL3(0)             JFCB READ IN AREA.                    96080016
BITBUFF  EQU   MAXR0BIT+8                                               96160016
WORKBUFF EQU   BITBUFF-STNDR0                                           96240016
         END                                                            96320016
