         COPY  LCGASMSW                                          X02912 00090402
IEHDASDS CSECT                                                          00091002
*                                                               OX01789 00093026
*1261327700,327800                                               A46608 00097002
*                                                                A42499 00098002
* MOST OF FIX IS FLAGED A50288                                   M0913  00099002
*1915                                                            A27508 00100002
*                                                                A50288 00101002
*1251835200                                                      A32162 00102002
*                                                                       00103002
*                                                                M5310  00104002
*                                                                       00105002
*                                                                M6350  00106002
*                                                                       00106421
* 76500016,76590016,76680016                     YM5770=XA03918=SA68162 00106821
*                                                                       00106921
*STATUS CHANGE LEVEL 004                                                00107002
*                                                                       00110002
*FUNCTION/OPERATION- THIS ROUTINE IS THE SECOND LOAD MODULE OF THE    * 00111002
*   IEHDASDR SYSTEM UTILITY PROGRAM AND IS IN CORE FOR THE ENTIRE     * 00112002
*   EXECUTION TIME. AFTER RECEIVING CONTROL FROM THE -IEHDASDR-       * 00113002
*   ROUTINE, THIS ROUTINE WILL ATTEMPT TO OPEN THE SYSOUT AND         * 00114002
*   SYSIN DATA SETS. IF SUCCESSFUL, IT WILL LINK TO -IEHDPRNT- TO     * 00115002
*   FORMAT AND PRINT THE HEADING, AND THEN CALL -IEHDSCAN- TO         * 00116002
*   SCAN AND SYNTAX CHECK THE SYSIN DATA SET. FOR EACH VALID REQUEST  * 00117002
*   AN ENTRY IS MADE IN THE FUNCTION QUEUE(FIFO SCHEDULING), MAIN     * 00118002
*   STORAGE ACQUIRED FOR THE FUNCTION BLOCK AND COPY BLOCKS, IF ANY,  * 00119002
*   AND CONTROL IS THEN PASSED TO THE APPROPRIATE FUNCTIONAL ROUTINE. * 00120002
*   WHEN AN ERROR IS DETECTED IN THE SYSIN DATA SET, THIS ROUTINE     * 00121002
*   WILL PLACE THE APPROPRIATE DIAGNOSTIC MESSAGE IN THE MESSAGE      * 00122002
*   DATA SET, STORE A RETURN CODE OF EIGHT, AND CONTINUE THE SCAN.    * 00123002
*                                                                     * 00124002
*   THE -IEHDASDS- ROUTINE WILL ATTEMPT TO INITIATE EXECUTION OF UP   * 00125002
*   TO SIX LIKE FUNCTIONS IF DEVICES AND CORE ARE AVAILABLE. THE      * 00126102
*   INDIVIDUAL FUNCTIONAL ROUTINES, FOR CERTAIN WAITS ON I/O          * 00127102
*   OPERATIONS, WILL RETURN CONTROL TO THE MONITOR ALLOWING THIS      * 00128102
*   ROUTINE TO INITIATE ANOTHER LIKE FUNCTION-CONCURRENT PROCESSING.  * 00129102
*                                                                     * 00130002
*   WHEN A FUNCTION COMPLETES, ITS ENTRY IS REMOVED FROM THE QUEUE,   * 00131102
*   AND ALL SUBSEQUENT ENTRIES MOVED UP. UPON COMPLETION OF ALL       * 00132102
*   REQUESTS, -IEHDASDS- FREES ALL MAIN STORAGE IT OBTAINED,          * 00133102
*   CLOSES THE SYSIN, SYSOUT DATA SETS, AND RETURNS TO THE CALLER     * 00134102
*   WITH THE HIGHEST RETURN CODE ENCOUNTERED DURING EXECUTION.        * 00135102
*                                                                     * 00136102
*ENTRY POINTS- THE ONLY ENTRY POINT IS -IEHDASDS-, AND CONTROL IS     * 00137102
*   ALWAYS RECEIVED FROM -IEHDASDR-.                                  * 00138102
*                                                                     * 00139102
*INPUT- REGISTER 1 WILL POINT TO THE WORK AREA IN WHICH THE SYSIN     * 00140102
*   AND SYSOUT DDNAMES, LINE COUNT, AND FUNCTION QUEUE SIZE ARE       * 00141102
*   ALREADY SET UP.                                                   * 00142102
*                                                                     * 00143102
*EXITS-NORMAL- SUCCESSFUL COMPLETION OF ALL REQUESTED FUNCTIONS       * 00144102
*   RESULTS IN A RETURN TO THE CALLER WITH A RETURN CODE OF ZERO.     * 00145102
*                                                                     * 00146102
*EXITS-ERROR- ANY ERRORS ENCOUNTERED ARE DESCRIBED BY APPROPRIATE     * 00147102
*   MESSAGES IN THE MESSAGE DATA SET AND A RETURN TO THE CALLER WITH  * 00148102
*   THE HIGHEST RETURN CODE ENCOUNTERED.                              * 00149102
*                                                                     * 00150102
*EXTERNAL ROUTINES- THIS ROUTINE ALWAYS RECEIVES CONTROL FROM THE     * 00151102
*   -IEHDASDR- ROUTINE. THREE CSECTS ARE USED AS UTILITY ROUTINES.    * 00152102
*   THE HEADING AND ANY MESSAGES USSUED WILL BE WRITTEN OUT BY        * 00153102
*   -IEHDPRNT- WITH MESSAGES BEING SET UP BY -IEHDMSGB-.              * 00154102
*   THE -IEHDSCAN- ROUTINE IS USED TO READ IN AND SCAN THE SYSIN      * 00155102
*   DATA SET. ALL DEVICE DEPENDENT INFORMATION IS CONTAINED IN THE    * 00156102
*   -IEHDCONS- CSECT. A POINTER TO THIS CSECT IS PROVIDED IN EACH     * 00157102
*   FUNCTION BLOCK BUILT. THE FOLLOWING ARE THE ENTRY POINTS FOR      * 00158102
*   THE FUNCTIONAL ROUTINES, LOADED INTO CORE FOR EXECUTION AND       * 00159102
*   THEN DELETED UPON COMPLETION, WHICH RECEIVE CONTROL FROM          * 00160102
*   -IEHDASDS-                                                        * 00161102
*              IEHDREST                                               * 00162102
*              IEHDANAL                                               * 00163102
*              IEHDLABL                                               * 00164102
*              IEHDGETA                                               * 00165102
*              IEHDDUMP.                                              * 00166102
*                                                                     * 00167102
*TABLES/WORK AREAS- BEFORE PASSING CONTROL TO A FUNCTIONAL ROUTINE,   * 00168102
*   -IEHDASDS- WILL POINT TO THE FUNCTION BLOCK AND THE WORK          * 00169102
*   AREA IN REGISTERS 10 AND 12 RESPECTIVELY. THEY ARE DESCRIBED      * 00170102
*   IN THE DSECTS CALLED -FUNCBLK- AND -WORK-.                        * 00171102
*                                                                     * 00172102
*ATTRIBUTES- SERIALLY REUSABLE, RELOCATABLE.                          * 00173102
*                                                                     * 00174102
*NOTE- THE VERSION LEVEL FOR THE IEHDASDR SYSTEM UTILITY              * 00175102
*   PROGRAM IS MAINTAINED IN THE -IEHDPRNT- ROUTINE AND SHOULD BE     * 00176102
*   UPDATED AS RELEASE LEVELS AND VERSIONS CHANGE.                    * 00177102
*                                                                     * 00178102
 TITLE 'IEHDASDS --- MONITOR FOR IEHDASDR UTILITY PROGRAM'              00179102
*   THE FOLLOWING ARE REGISTER ASSIGNMENTS.                             00180016
GR0      EQU   0                                                        00270016
GR1      EQU   1                                                        00360016
GR2      EQU   2                                                        00450016
GR3      EQU   3                                                        00540016
GR4      EQU   4                                                        00630016
GR5      EQU   5                                                        00720016
GR6      EQU   6                                                        00810016
GR7      EQU   7                                                        00900016
GR8      EQU   8                                                        00990016
GR9      EQU   9                                                        01080016
GR10     EQU   10                                                       01170016
GR11     EQU   11                                                       01260016
GR12     EQU   12                                                       01350016
GR13     EQU   13                                                       01440016
GR14     EQU   14                                                       01530016
GR15     EQU   15                                                       01620016
SCANADR  EQU   1                                                        01710016
LENGTH   EQU   2                                                        01800016
ROOTBASE EQU   11                                                       01890016
WORKBASE EQU   12                                                       01980016
         SPACE 1                                                        02070016
         SPACE 1                                                        02160016
*   MESSAGE REFERENCES.                                                 02170016
*********************************************************************** 02180016
MESS0    EQU   0                       MESSAGE NUMBER(800).             02190016
MESS1    EQU   1                       MESSAGE NUMBER(801).             02200016
MESS2    EQU   2                       MESSAGE NUMBER(802).             02210016
MESS3    EQU   3                       MESSAGE NUMBER(803).             02220016
MESS4    EQU   4                       MESSAGE NUMBER(804).             02230016
MESS5    EQU   5                       MESSAGE NUMBER(805).             02240016
MESS12   EQU   12                      MESSAGE NUMBER(812).             02252001
MESS13   EQU   13                      MESSAGE NUMBER(813).             02260016
MESS18   EQU   18                      MESSAGE NUMBER(818).             02270016
MESS20   EQU   20                      MESSAGE NUMBER(820).     YM5582  02272001
MESS24   EQU   24                      MESSAGE NUMBER(824).             02280016
MESS26   EQU   26                      MESSAGE NUMBER(826).             02290016
MESS39   EQU   39                      MESSAGE NUMBER(839).             02295016
MESS51   EQU   51                      MESSAGE NUMBER(851).     XM7053  02297002
*********************************************************************** 02300016
         EJECT                                                          02310016
SENS     EQU   X'F1'                    SVC 82 FUNCTION BYTE    XL03130 02312003
DA2321   EQU   X'05'                   2321 DEVICE TYPE CODE.           02320016
BLANK    EQU   C' '                                                     02610016
ONE      EQU   X'01'                    UCB USER COUNT          XM7053  02660002
SYSINOUT EQU   X'C0'                    SYSIN/SYSOUT UCBWGT VAL YM5582  02662001
L8       EQU   8                        DDNAME LENGTH           YM5582  02664001
K0       EQU   0                        DISPL CONSTANT          YM5582  02666001
DASDI    EQU   X'20'                    UCB BYTE 3 TYPE CODE    XM7053  02670002
COND0    EQU   8                        CONDITION ZERO          SA68162 02672021
DISP0    EQU   0                        AT THE ORIGAN           SA68162 02674021
LASTCTCB EQU   4                        LAST CURRENT TCB        SA68162 02674421
ADD1     EQU   1                        INCREMENT BY ONE        SA68162 02674821
         AIF  ('&LIB' EQ 'LIB1').ARONDA   THIS ASSEM FOR OS      X02912 02675002
IPLSIZE  EQU   6496                     VS IPLTXT BUFFER SIZE    X02912 02680002
         AGO   .ARONDB                  BRCH AROUND OS VALUE     X02912 02685002
.ARONDA  ANOP                           BRCH POINT FOR OS CODE   X02912 02690002
IPLSIZE  EQU   3640                    BUFFER SIZE FOR IPL PROGRAM.     02700016
.ARONDB  ANOP                           BRCH POINT FOR VS CODE   X02912 02750002
         SPACE 1                                                        02790016
         USING WORK,12                 SET UP BASE FOR WORK AREA        02880016
         USING COPYBLK,GR8                                              02970016
         USING IEHROOT,ROOTBASE                                         03060016
         USING FUNCBLK,GR10                                             03150016
         SPACE 1                                                        03240016
IEHROOT  LR    GR0,GR1                 WORKAREA ADDRESS.                03300016
         L     GR1,PRINT1-WORK(GR1)    PARM  LIST POINTER.              03360016
         SAVE  (14,12),T                                                03420016
         LR    GR12,GR0                WORKAREA ADDRESS.                03480016
         LR    ROOTBASE,GR15           LOAD THE BASE REGISTER.          03540016
         SPACE                                                          03600016
         LA    GR7,ROOTSAVE            SAVE AREA ADDRESS.               03690016
         ST    GR7,8(GR13)             ADDRESS OF NEW AREA TO OLD.      03780016
         ST    GR13,4(GR7)             ADDRESS OF OLD AREA TO NEW.      03870016
         LR    GR13,GR7                SAVE AREA ADDRESS.               03960016
         MVI   RETCODE,0               INSURE RETURN CODE IS ZERO.      04000016
         EJECT                                                          04050016
*********************************************************************** 04140016
*   THIS SECTION OPENS SYSIN AND SYSOUT DCBS.                         * 04230016
*     AND THEN LINKS TO THE PRINT ROUTINE TO                          * 04320016
*     WRITE OUT A HEADER RECORD.                                      * 04410016
*********************************************************************** 04500016
HEADPRIN EQU   *                                                        04590016
         USING IHADCB,GR4                                               04680016
         LA    GR4,PRINT               SYSOUT DCB ADDRESS.              04770016
         ST    GR4,PRINT1              DCB ADDRESS TO WORK AREA.        04860016
         MVC   DCBDDNAM(8),SYSOUTDD    SYSPRINT DDNAME TO DCB.          04950016
         MVI   PRNTSW,0                CLEAR EXIT ROUTINE SWITCH.       05040016
         LA    GR1,OPNLST1             ADDRESS OF OPEN LIST.            05130016
         BAL   GR9,OPENDATA            OPEN SYSPRINT.                   05220016
         TM    DCBOFLGS,X'10'          WAS OPEN SUCCESSFUL.             05310016
         BZ    SETCODE                 NO--GO SET RETURN CODE.          05400016
         BAL   GR9,ERRPRINT            GO WRITE OUT HEADER MESSAGE.     05490016
         TM    PRNTSW,X'01'            YES-IS BLOCKSIZE VALID.          05580016
         BZ    HEADP2                  YES-GO OPEN SYSIN.               05670016
         LA    GR1,38                  NO--ERROR MESSAGE NUMBER.        05760016
         BAL   GR9,BUILD               LOAD BUFFER WITH ERROR MESSAGE.  05850016
         MVC   0(8,GR1),SYSOUTDD       PLACE DDNAME INTO MESSAGE.       05940016
         BAL   GR9,ERRPRINT            WRITE OUT ERROR MESSAGE.         06030016
         MVI   RETCODE,4               SET RETURN CODE.                 06120016
         SPACE                                                          06210016
HEADP2   EQU   *                                                        06300016
         LA    GR4,READ                SYSIN DCB ADDRESS.               06390016
         ST    GR4,READ1               DCB ADDRESS TO WORK AREA.        06480016
         MVC   DCBDDNAM(8),SYSINDD     SYSIN DDNAME TO DCB.             06570016
         MVI   PRNTSW,0                CLEAR EXIT ROUTINE SWITCH.       06660016
         LA    GR1,OPNLST2             ADDRESS OF OPEN LIST.            06750016
         BAL   GR9,OPENDATA            OPEN SYSIN.                      06840016
         TM    DCBOFLGS,X'10'          WAS OPEN SUCCESSFUL.             06930016
         BZ    DCBERROR                NO--GO PRINT ERROR MESSAGE.      07020016
         TM    PRNTSW,X'01'            YES-IS BLOCKSIZE VALID.          07110016
         BZ    SCANA                   YES-BEGIN SCANNING CARDS.        07200016
         LA    GR1,38                  NO--ERROR MESSAGE NUMBER.        07290016
         BAL   GR9,BUILD               PLACE MESSAGE IN BUFFER.         07380016
         MVC   0(8,GR1),SYSINDD        PLACE DDNAME IN MESSAGE.         07470016
         BAL   GR9,ERRPRINT            PRINT OUT THE MESSAGE.           07560016
         MVI   RETCODE,16              SET RETURN CODE.                 07650016
         B     ENDALL                  RETURN CONTROL TO CALLLER.       07740016
         EJECT                                                          07830016
OPENDATA EQU   *                                                        07920016
         OPEN  MF=(E,(1))              OPEN SPECIFIED DATA SET.         08010016
         BR    GR9                     RETURN TO CALLLER.               08100016
         SPACE 2                                                        08190016
OPNLST1  OPEN  (PRINT,(OUTPUT)),MF=L                                    08280016
OPNLST2  OPEN  (READ,(INPUT)),MF=L                                      08370016
         SPACE 2                                                        08460016
DCBEXIT1 EQU   *                                                        08550016
         SR    GR0,GR0                 CLEAR TEST REGISTER.             08640016
         LH    GR1,DCBBLKSI            PICK UP BLOCKSIZE.               08730016
         LH    GR2,DCBLRECL            GET LOGICAL RECORD SIZE.         08820016
         CLR   GR0,GR1                 WAS BLOCKSIZE SPECIFIED.         08910016
         BE    DCBEX2                  NO--GO MOVE IN BLOCKSIZE.        09000016
         DR    GR0,GR2                 YES-IS BLOCKSIZE VALID.          09090016
         LTR   GR0,GR0                 ANY REMAINDER.                   09180016
         BCR   8,GR14                  A OK/RETURN TO OPEN.             09270016
         STH   GR2,DCBBLKSI            NO--OVERRIDE BLKSIZE FOR SYSPRIN 09360016
         OI    PRNTSW,X'01'            INDICATE INVALID BLKSIZE.        09450016
         BR    GR14                    RETURN TO OPEN.                  09540016
DCBEX2   STH   GR2,DCBBLKSI            PLACE LRECL IN BLOCKSIZE.        09630016
         BR    GR14                    RETURN TO OPEN.                  09720016
         DROP  GR4                                                      09810016
         EJECT                                                          09900016
SCANA    MVI   SWITCHRD,0         RESET CONTROL SWITCH                  09990016
         SR    GR10,GR10               INDICATE NO FUNCTION BLOCK BUILT 10080016
SCAN     EQU   *                        GO SCAN CARD IMAGE              10130021
         XC    GOTOBR,GOTOBR            CLEAR GO TO BRANCH VALUE        10140021
         LINK  EP=IEHDSCAN             GO SCAN A CARD IMAGE.            10170021
         SPACE 1                                                        10260016
* ADDITIONAL INSTRUCTIONS TO HANDLE THE REPACK FROM DASDS TO DSCAN      10310021
         LA    GR3,GOTAB                GET BRANCH TABLE ADDRESS        10320021
         A     GR3,GOTOBR               ADD VALUE DETERMINED BY DSCAN   10330021
         BR    GR3                      BRANCH TO LOCATION SPECIFIED    10340021
* THE SEQUENCE OF THIS TABLE ID DEPENDENT ON VALUES SET BY DSCAN        10342021
GOTAB    EQU   *                        START OF TABLE                  10344021
         B     NORM                     GO TO OLD DASDS CODE            10346021
         B     CHECK                    GO SEE IF FINISHED              10348421
         B     SCAN1                    START PROCESSING                10348821
         B     OPRLUP                   TEST COMMAND VALIDITY           10349221
         B     GETCOPY                  PROCESS TODD COPIES             10349621
         B     MSGWRT2                  GO WRITE MESSAGE                10349721
* END OF TABLE                                                          10382221
NORM     EQU   *                        END OF TABLE.RESUME NORMAL      10395021
         TM    SWITCHRD,ERROR          WAS THERE AN ERROR.              10417521
         BO    MSGPRT                  YES,GO GIVE A MESSAGE.           10440016
         SPACE 1                                                        10530016
         TM    SWITCHRD,COMD           IS THIS A COMMAND.               10620016
         BO    OPRLUP                   YES-TEST VALIDITY & PROCESS     10670021
         SPACE                                                          11070016
         TM    SWITCHRD,EOF            WAS AN EOF READ.                 11160016
         BO    CHECK                   YES-GO SEE IF FINISHED.          11250016
         SPACE                                                          11340016
SCAN2    TM    SWITCHRD,PARM           THIS A PARAMETER.                11430016
         BC    8,SCAN3                 NO--GO MAKE MORE TESTS.          11450016
         TM    SW1,DD1OK               MULTIPLE PARMS ALLOWED.          11470016
         BCR   1,GR9                   YES-PROCESS PARAMETER.           11490016
         TM    SW1,PARMXY              NO--ANY PREVIOUS PARMS.          11510016
         BO    INVALP1                 YES-THEN THIS PARAMETER INVALID. 11530016
         OI    SW1,PARMXY              REMEMBER THIS PARAMETER.         11550016
         BR    GR9                     PROCESS THIS PARAMETER.          11570016
         SPACE                                                          11610016
SCAN3    TM    SWITCHRD,BYPASS         IS THIS CARD FINISHED.           11700016
         BZ    SCAN                    NO--CONTINUE SCAN//THIS CARD.    11790016
         SPACE                                                          11880016
SCAN1    SR    GR7,GR7                 CLEAR.                           11970016
         IC    GR7,FUNCSW              FUNCTION CODE AS MULTIPLE OF 16. 12060016
         SRA   GR7,4                   CODE AS MULTIPLE OF 1.           12150016
         LA    GR3,KCODES              ADDRESS OF KEYWORD TABLE         12240000
         LA    GR3,0(GR7,GR3)          INDEX TO PROPER SLOT IN TABLE.   12330016
         IC    GR7,0(GR3)              PICK UP PROPER VALUE FROM TABLE. 12420016
         SR    GR8,GR8                 CLEAR.                           12510016
         IC    GR8,SEQSW               CURRENT KEYWORD SEQUENCE SWITCH. 12600016
         NR    GR8,GR7                 'AND' KEYWORD CODE INTO SEQSW.   12690016
         CR    GR8,GR7                 ARE REQUIRED KEYWORDS PRESENT.   12780016
         BNE   KEYMISS                 NO--GO GIVE A MESSAGE.           12870016
         CLI   DDNAME2,BLANK           IS THIS AN UNLABELED VOLUME.     12960016
         BC    7,CHECK2                NO--MAKE MORE CHECKS.            13050016
         TM    SEQSW,NEWVOLID          YES-WAS NEW SERIAL GIVEN.        13140016
         BZ    KEYMISS                 NO--REQUIRED KEYWORDS MISSING.   13230016
         SPACE                                                          13280021
CHECK2   CLI   FUNCSW,ANALYSIS          THIS ANALYSIS?                  13410000
         BE    CHECK2A                  YES, BRANCH.                    13460000
         CLI   FUNCSW,FORMAT            THIS FORMAT?                    13510000
         BNE   CHECK1                   NO - START PROCESSING.          13560000
CHECK2A  TM    SEQSW,IPLDD              WAS IPL TEXT REQUESTED?         13610000
         BZ    CHECK1                  NO--START PROCESSING.            13680016
         CLC   DDNAME1(8),SYSINDD      INPUT VIA SYSIN.                 13770016
         BNE   CHECK1                  NO--START PROCESSING.            13860016
         OC    WIPLPTR+1(3),WIPLPTR+1  IPLTEXT POSSIBLY IN CORE ALREADY 13890016
         BC    7,CHECK1                YES-GO SET UP THIS FUNCTION.     13920016
         OI    SW1,TEXTIN              INDICATE LOOKING FOR TEXT/SYSIN. 13950016
         B     SCAN                    GO GET IPL PROGRAM.              14040016
         SPACE                                                          14130016
CHECK    TM    SW1,TEXTIN              ARE WE LOOKING FOR IPL TEXT.     14220016
         BO    NOIPLMSG                YES-GO GIVE ERROR MESSAGE.       14310016
         CLI   QCOUNT+1,0              MORE ON QUEUE YET.               14400016
         BH    MORE                    YES-GO START  AT TOP OF QUEUE.   14490016
         B     ENDALL                  NO--GO CLOSE ALL-FREE ALL.       14580016
         EJECT                                                          14850016
*   COMMAND LOOKUP ROUTINE                                              14940016
         SPACE 1                                                        15030016
OPRLUP   LA    GR3,COMDTABL            START OF COMMAND TABLE.          15120016
         LA    GR5,COMDEND             END OF COMMAND TABLE.            15210016
         OI    SW1,COMMAND             INDICATE LOOKING FOR COMMAND.    15300016
SCANTBL  STC   LENGTH,SAVLGTH          STORE LENGTH.                    15390016
         CLI   SAVLGTH,8               IS LENGTH EIGHT OR LESS.         15480016
         BH    MSGPRT                  YES-CONTROL STATEMENT ERROR.     15570016
         LA    GR4,12                  TABLE INCREMENTING VALUE.        15660016
         MVI   WURK,C' '               CLEAR SEARCH AREA.               15750021
         MVC   WURK+1(7),WURK          CLEAR REMAINING ARGUMENT AREA.   15840021
         BCTR  LENGTH,0                DECREMENT LENGTH FOR EXECUTE.    15930016
         EX    LENGTH,OPRLUP3          MOVE PARAMETER TO STORAGE AREA.  16020016
OPRCMP   CLC   WURK(8),0(GR3)          CHK IF SEARCH ARGUMENT IN TABLE. 16110021
         BNE   OPRLUP2                 NO--CONTINUE SCAN OF TABLE.      16200016
         LA    GR3,8(GR3)              POINT TO BRANCH ADDRESS.         16290016
         NI    SW1,X'FF'-COMMAND-SPEC1   RESET INDICATORS.              16380016
         BR    GR3                     ENTER PROPER ROUTINE.            16470016
OPRLUP2  BXLE  GR3,GR4,OPRCMP          LOOP TO CONTINUE SEARCH.         16560016
         TM    SW1,COMMAND             ERROR WHILE LOOKING FOR COMMAND. 16650016
         BZ    INVALKEY                YES--INVALID KEYWORD.            16740016
         NI    SW1,X'FF'-COMMAND       RESET COMMAND INDICATOR.         16830016
         B     INVALCOM                MUST BE INVALID COMMAND.         16920016
OPRLUP3  MVC   WURK(1),0(SCANADR)      MOVE IN ARGUMENT.                17010021
         SPACE 1                                                        17100016
         EJECT                                                          17730016
*   COMMAND LOOKUP TABLE                                                17820016
         SPACE                                                          17910016
         DS    0F                                                       18000016
COMDTABL DC    C'DUMP    '             START OF COMMAND WORD TABLE.     18090016
         B     DUMPCOMD                ADDRESS OF COMMAND ANALYSIS.     18180016
         DC    C'RESTORE '                                              18270016
         B     RESTCOMD                                                 18360016
         DC    C'ANALYZE '                                              18450016
         B     ANALCOMD                                                 18540016
         DC    C'FORMAT  '                                              18630016
         B     FORMCOMD                                                 18720016
         DC    C'LABEL   '                                              18810016
         B     LABLCOMD                                                 18900016
         DC    C'IPLTXT  '                                              18990016
         B     TEXTCOMD                                                 19080016
         DC    C'PUTIPL  '                                              19110000
         B     IPLPCOMD                                                 19140000
COMDEND  DC    C'GETALT  '             END OF COMMAND WORD TABLE.       19170016
         B     GETLCOMD                                                 19260016
         SPACE 3                                                        19350016
DUMPCOMD LA    GR0,DFUNSIZE            DUMP FUNCTION BLOCK SIZE.        22230016
         LA    GR5,DUMP                DUMP FUNCTION CODE.              22320016
         B     BUILDF                  GO BUILD A FUNCTION BLOCK.       22410016
         SPACE 1                                                        22500016
RESTCOMD LA    GR0,RFUNSIZE            RESTORE FUNCTION BLOCK SIZE.     22590016
         LA    GR5,RESTORE             RESTORE FUNCTION CODE            22680016
         B     BUILDF                  GO BUILD A FUNCTION BLOCK.       22770016
         SPACE 1                                                        22860016
ANALCOMD LA    GR0,AFUNSIZE            ANALYSIS FUNCTION BLOCK SIZE.    22950016
         LA    GR5,ANALYSIS            ANALYSIS FUNCTION CODE.          23040016
         B     BUILDF                  GO BUILD A FUNCTION BLOCK.       23130016
         SPACE 1                                                        23220016
FORMCOMD LA    GR0,FFUNSIZE            FORMAT FUNCTION BLOCK SIZE.      23310016
         LA    GR5,FORMAT              FORMAT FUNCTION CODE.            23400016
         B     BUILDF                  GO BUILD A FUNCTION BLOCK.       23490016
         SPACE 1                                                        23580016
LABLCOMD LA    GR0,LFUNSIZE            LABEL FUNCTION BLOCK SIZE.       23670016
         LA    GR5,LABEL               LABEL FUNCTION CODE.             23760016
         B     BUILDF                  GO BUILD A FUNCTION BLOCK.       23850016
         SPACE 1                                                        23940016
GETLCOMD LA    GR0,GFUNSIZE            GETALT FUNCTION BLOCK SIZE.      24030016
         LA    GR5,GETALT              GETALT FUNCTION CODE             24120016
         B     BUILDF                  GO BUILD A FUNCTION BLOCK.       24210016
IPLPCOMD LA    GR0,IFUNSIZE            IPLPROG FUNCTION SIZE            24230000
         LA    GR5,IPLPROG             IPLPROG FUNCTION CODE            24250000
         B     BUILDF                  GO BUILD A FUNCTION BLOCK        24270000
         EJECT                                                          24300016
TEXTCOMD CLI   FUNCSW,ANALYSIS         THIS FOLLOW FORMAT OR ANALYZE.   24390016
         BL    INVALCOM                NO--INVALID COMMAND.             24480016
         TM    SEQSW,IPLDD             WAS THERE A DDNAME GIVEN.        24570016
         BZ    INVALCOM                NO--INVALID COMMAND.             24660016
         SPACE                                                          24750016
         CLC   DDNAME1(8),SYSINDD      THIS DDNAME SAME AS FOR SYSIN.   24840016
         BNE   INVALCOM                NO--ERROR.                       24930016
         SPACE                                                          25020016
         GETMAIN R,LV=0+IPLSIZE        GET CORE TO STORE TEXT DATA.     25110016
         LR    GR4,GR1                 SAVE BUFFER ADDRESS.             25200016
         AIF  ('&LIB' EQ 'LIB1').ARONDC  THIS ASSEM FOR OS, BRCH X02912 25250002
         L     GR3,IPLMAX               GET MAX BUFFER SIZE      X02912 25260002
         AGO   .ARONDD                  BRCH AROUND OS VALUE     X02912 25270002
.ARONDC  ANOP                           BRCH POINT FOR OS CODE   X02912 25280002
         LA    GR3,IPLSIZE             SIZE OF BUFFER.                  25290016
.ARONDD  ANOP                           BRCH POINT FOR VS CODE   X02912 25340002
         BAL   GR14,CLEAR              CLEAR BUFFER TO ZERO.            25380016
         LA    GR9,CARDBUFF            ADDRESS OF IPL PROGRAM CARDS.    25470016
         USING IPLCARD,GR9                                              25560016
         LA    GR7,READ                DCB ADDRESS.                     25650016
         USING IHADCB,GR7                                               25660016
         LA    GR2,NOIPL               RETURN IF EOF ENCOUNTERED.       25670016
         ST    GR2,DCBEODAD            SET IN QSAM DCB.                 25680016
         DROP  GR7                                                      25690016
         SR    GR2,GR2                 CLEAR BYTE COUNT REGISTER.       25740016
         LR    GR5,GR4                 BUFFER ADDRESS.                  25830016
         LA    GR4,8(GR4)              SAVE ROOM FOR COUNT FIELD.       25920016
         AIF  ('&LIB' EQ 'LIB1').ARONDE  THIS ASSEM FOR OS, BRCH X02912 25970002
         LR    GR8,GR5                  GET BUFFER ADDR          X02912 25980002
         LA    GR8,0(GR8)               CLEAR HIGH BYTE          X02912 25982002
         A     GR8,IPLMAX               ADD BUFFER SIZE          X02912 25984002
         AGO   .ARONDF                  BRCH AROUND OS VALUE     X02912 25990002
.ARONDE  ANOP                           BRCH POINT FOR OS CODE   X02912 26000002
         LA    GR8,IPLSIZE(GR5)        END OF BUFFER.                   26010016
.ARONDF  ANOP                           BRCH POINT FOR VS CODE   X02912 26060002
         EJECT                                                          26100016
REREAD   GET   (GR7),(GR9)             READ IN AN IPL PROGRAM.          26190016
         SPACE                                                          26280016
         CLC   CARDTYPE,END1           THIS AN END CARD.                26370016
         BE    THEEND                  YES-DO FINAL WIND-UP.            26460016
         CLC   CARDTYPE,TXT            THIS A TEXT CARD.                26550016
         BNE   REREAD                  NO--GET NEXT CARD.               26640016
         SPACE                                                          26730016
         IC    GR2,CARDBYTE+1          BYTES//THIS CARD.                26820016
         LR    GR3,GR2                 SAVE BYTE COUNT.                 26910016
         MVC   WURK(4),CARDADDR-1      MOVE FOR ALIGNMENT.              26920021
         L     GR4,WURK                DATA ADDRESS//THIS CARD.         26930021
         AR    GR4,GR5                 ADD TO BUFFER START.             26940016
         LA    GR4,8(GR4)              COUNT FIELD LENGTH.              26950016
         AR    GR4,GR3                 UPDATE BUFFER PTR.          5567 26960018
         CLR   GR4,GR8                 END OF BUFFER REACHED.      5567 26970018
         BH    NOIPLMSG                YES-MSG/IPLTXT NO GOOD.     5567 26980018
         SR    GR4,GR3                 DECREMENT BUFF PTR FOR MOVE.5567 26990018
         BCTR  GR2,0                   DECREMENT FOR EXECUTE.           27000016
         EX    GR2,TXTMOVE             MOVE DATA TO BUFFER AREA.        27090016
         AR    GR4,GR3                 UPDATE MOVE-TO ADDRESS.          27180016
         B     REREAD                  GO GET NEXT TXT CARD.       5567 27280018
         SPACE                                                          27540016
THEEND   ST    GR5,WIPLPTR             TEXT ADDRESS TO WORK AREA.       27630016
         ST    GR5,FIPLPTR             TEXT ADDRESS TO FUNCTION BLOCK.  27720016
         NI    SW1,X'FF'-TEXTIN        SWITCH OFF//TEXT FOUND.          27810016
         B     CHECK1                  START PROCESSING THIS FUNCTION.  27900016
         SPACE                                                          27990016
TXTMOVE  MVC   0(1,GR4),CARDTEXT       USED TO MOVE IPL TEXT TO BUFFER. 28080016
         EJECT                                                          28170016
*********************************************************************** 28260016
*                                                                     * 28350016
*   THE FOLLOWING TABLE IS A LIST OF THE REQUIRED KEYWORDS            * 28440016
*     FOR EACH FUNCTION.                                              * 28530016
*                                                                     * 28620016
*********************************************************************** 28710016
KCODES   EQU   *                                                        28800000
         DC    AL1(0)                  DUMMY                            28830000
         DC    AL1(FROMDD+TODD)        DUMP                             28860000
         DC    AL1(FROMDD+TODD)        RESTORE                          28890016
         DC    AL1(TRACK+TODD)         GETALT                           28980016
         DC    AL1(NEWVOLID+TODD)      LABEL                            29070016
         DC    AL1(TODD+EXTENT+VTOC)   ANALYZE                          29160016
         DC    AL1(TODD+EXTENT+VTOC)   FORMAT                           29250016
         DC    AL1(FROMDD+TODD)        IPLPROG                          29280000
         DC    AL1(0)                                                   29310000
         SPACE 3                                                        29340016
*********************************************************************** 29430016
*                                                                     * 29520016
*   THE FOLLOWING TABLE INDICATES THE BIT SWITCH SETTINGS FOR THE     * 29610016
*     -SEQSW-. ALL THE VARIOUS KEYWORDS ARE LISTED WITH THE           * 29700016
*     SUPPORTED FUNCTIONS.                                            * 29790016
*                                                                     * 29880016
*********************************************************************** 29970016
****                                                               **** 30060016
* (BITS) *   0    .  1 .   2    .  3  .  4  .   5   .   6    .  7     * 30150016
* DUMP   * FROMDD .TODD.CPYVOLID.BEGIN. END .       .        .        * 30240016
*        *        .    .        .     .     .       .        .        * 30330016
* RESTORE* FROMDD .TODD.CPYVOLID.     .     .       .        .        * 30420016
*        *        .    .        .     .     .       .        .        * 30510016
* GETALT * TRACK  .TODD.        .     .     .       .        .        * 30600016
*        *        .    .        .     .     .       .        .        * 30690016
* LABEL  *NEWVOLID.TODD.        .     .     .OWNERID.        .        * 30780016
*        *        .    .        .     .     .       .        .        * 30870016
* ANALYZE*NEWVOLID.TODD.EXTENT  .VTOC .IPLDD.OWNERID.FLAGTEST.PASSES  * 30960016
*        *        .    .        .     .     .       .        .        * 31050016
* FORMAT *NEWVOLID.TODD.EXTENT  .VTOC .IPLDD.OWNERID.        .        * 31140016
*        *        .    .        .     .     .       .        .        * 31230016
* IPLPROG* FROMDD .TODD.        .     .     .       .        .        * 31260000
*        *        .    .        .     .     .       .        .        * 31290000
*********************************************************************** 31320016
         EJECT                                                          31410016
         SPACE                                                          33570016
         DS    0H                       FORCE ALIGNMENT                 33620021
GETCOPY  EQU   *                       PROCESS TODD COPIES HERE.        33670016
         CLI   FUNCSW,RESTORE          THIS DUMP OR RESTORE.            33840016
         BNH   GETCOPY2                YES-COPIES ALLOWED.              33930016
         CLI   FUNCSW,ANALYSIS         THIS FORMAT OR ANALYZE.          34020016
         BL    MSGPRT                  NO--MUST BE ERROR.               34110016
GETCOPY2 LA    GR0,COPYSIZE            SIZE OF COPY BLOCK.              34200016
        LR     GR5,GR1                 SAVE POINTER TO PARAMETER.       34290016
         B     GETCOPY1                GO BUILD A COPY BLOCK.           34380016
         SPACE                                                          34470016
*   GET CORE FOR A FUNCTION BLOCK AND INITIALIZE IT TO ZERO HERE.       46800016
BUILDF   LA    GR6,PTRFUNC1            ADDRESS OF FIRST FUNCTION.       46890016
         TM    SW1,TEXTIN              WERE WE LOOKING FOR IPL TEXT.    46920016
         BO    NOIPLMSG                YES--MUST BE ERROR.              46950016
         SPACE 1                                                        46980016
BUILDF1 TM     0(GR6),ACTIVE           IS THIS SLOT AVAILABLE.          47070016
         BZ    BUILDF2                 YES-NOT ACTIVE OR WAITING.       47160016
         LA    GR6,CSIZE(GR6)          POINT TO NEXT ENTRY.             47250016
         B     BUILDF1                 GO FIND AN EMPTY SLOT.           47340016
         SPACE 1                                                        47430016
BUILDF2  LR    GR3,GR0                 FUNCTION BLOCK SIZE.             47520016
         GETMAIN R,LV=(0)                                               47610016
         LR    GR10,GR1                FUNCTION BLOCK ADDRESS.          47700016
         ST    GR1,0(GR6)              FUNCTION BLOCK ADDRESS TO LIST.  47790016
         LR    GR4,GR3                 SAVE THE FUNCTION BLOCK SIZE.    47880016
         BAL   GR14,CLEAR              CLEAR FUNCTION BLOCK TO ZERO.    47970016
         STH   GR4,FSIZE               SAVE SIZE OF FUNCTION BLOCK.     48060016
         MVI   DDNAME1,BLANK           BLANK 1ST BLANK OF DDNAME SLOTS. 48150016
         MVC   DDNAME1+1(15),DDNAME1   BLANK REMAINING PORTION.         48240016
         MVI   0(GR6),ACTIVE           SET ACTIVE STATUS THIS FUNCTION. 48330016
         SPACE 1                                                        48420016
         STC   GR5,FUNCSW              INDICATE WHICH FUNCTION THIS IS. 48510016
         L     GR5,KONSTANT            ADDRESS OF DEVICE CONSTANTS.     48600016
         ST    GR5,IODEVCON            INSERT ADDRESS IN FUNCTION BLOCK 48690016
         LH    GR5,QCOUNT              CURRENT QUEUE COUNT              48780016
         LA    GR5,1(GR5)              INCREMENT BY ONE.                48870016
         STH   GR5,QCOUNT              SAVE THIS VALUE.                 48960016
         B     SCAN3                   COMPLETE SCAN OF CARD.           49050016
         EJECT                                                          49140016
* GET CORE FOR A COPY BLOCK AND INITIALIZE IT TO ZERO                   49230016
         SPACE 1                                                        49320016
GETCOPY1 GETMAIN R,LV=(0)                                               49410016
         LR    GR8,GR1                 POINTER TO COPY BLOCK.           49500016
         LA    GR3,COPYSIZE            SIZE OF COPY BLOCK.              49590016
         LR    GR4,GR2                 SAVE CONTENTS OF GR2.            49680016
         BAL   GR14,CLEAR              CLEAR COPY BLOCK TO ZERO.        49770016
        LR     GR1,GR5                 RESTORE POINTER TO PARAMETER.    49860016
         LR    GR2,GR4                 RESTORE REGISTER.                49950016
         SPACE 1                                                        50040016
         L     GR5,COPYPTR             ADDRESS OF COPY BLOCK, IF ANY.   50130016
         LTR   GR5,GR5                 IS THERE A PREVIOUS COPY BLOCK.  50220016
         BZ    NOCOPY                  NO--THIS IS THE FIRST COPY BLOCK 50310016
TESTCOPY CLC   CDISP(4,GR5),ZERO       THIS LAST COPY BLOCK IN CHAIN.   50400016
         BE    OKCOPY                  YES-GO SET UP POINTERS.          50490016
         L     GR5,CDISP(GR5)          NO--STEP TO NEXT COPY BLOCK.     50580016
         B     TESTCOPY                REPEAT UNTIL LAST IS FOUND.      50670016
         SPACE 1                                                        50760016
OKCOPY   ST    GR8,CDISP(GR5)          ADDRESS OF NEXT COPY TO PRIOR.   50850016
         ST    GR5,CFUNPTR-COPYBLK(GR8) ADDRESS OF PRIOR TO NEXT.       50940016
OKCOPY1  OI    0(GR6),COPIES           INDICATE COPIES INVOLVED.        51030016
         MVI   DDNAME3,BLANK           BLANK 1ST BYTE DDNAME SLOT.      51120016
         MVC   DDNAME3+1(7),DDNAME3    BLANK REMAINING PORTION.         51210016
         LA    GR4,DDNAME3             DDNAME SLOT ADDRESS.             51300016
         TM    SW1,SPEC1               THIS AN SPECIAL REQUEST.         51330016
         BO    ALLSET1                 YES--MOVE IN ON OFF-SET.         51360016
         B     MOVEP                   GO MOVE IN THE DDNAME.           51390016
         SPACE                                                          51480016
NOCOPY   ST    GR8,COPYPTR             COPY ADDRESS TO FUNCTION BLOCK.  51570016
         ST    GR10,CFUNPTR            FUNCTION BLOCK ADDRESS/1ST COPY. 51660016
         B     OKCOPY1                 GO COMPLETE COPY BLOCK.          51750016
         SPACE 1                                                        51800021
ALLSET1  LA    GR4,1(GR4)               PARAMETER MOVE TO ADDRESS       51810021
MOVEP    EX    GR2,PMOVE                MOVE DDNAME TO FUNCTION BLOCK   51820021
         B     SCAN3                    CONTINUE SCAN                   51830021
         EJECT                                                          51840016
CHECK1   TM    SW1,TEXTIN              WAS REQUIRED IPL TEXT FOUND.     51930016
         BO    NOIPLMSG                NO--GO GIVE ERROR MESSAGE.       52020016
         CLI   FUNCSW,RESTORE          IS THERE A FROM DDNAME.          52110016
         BNH   TESTFROM                 YES, GET FROMDD INFORMATION     52200000
         CLI   FUNCSW,IPLPROG           IS THERE A FROMDD?              52260000
         BNE   TODEVICE                 NO- GO CHECK TODD               52320000
TESTFROM LA    GR3,DDNAME1              YES-ADDRESS OF FROM-DDNAME.     52380000
         BAL   GR14,UCBFIND            FIND THE UCB ADDRESS.            52470016
         AIF   ('&LIB' EQ 'LIB1').WIN01 BRCH IF OS ASSEM        XL03130 52480003
         BAL   GR14,DEVTST              TEST UCB DEV TYPE       XL03130 52520003
         STC   GR3,IDEVMOD              STORE WINCHESTR MOD NO. XL03130 52530003
.WIN01   ANOP                           BRCH POINT FOR OS ASSEM XL03130 52540003
         ST    GR9,FUCBPTR             SAVE IT IN THE FUNCTION BLOCK.   52560016
         SPACE                                                          52650016
TODEVICE LA    GR3,DDNAME2             ADDRESS OF TO-DDNAME.            52740016
         BAL   GR14,UCBFIND            FIND THE UCB ADDRESS.            52830016
         AIF   ('&LIB' EQ 'LIB1').WIN02 BRCH IF OS ASSEM        XL03130 52880003
         BAL   GR14,DEVTST              TEST UCB DEV TYPE       XL03130 52890003
         STC   GR3,ODEVMOD              STORE WINCHESTR MOD NO. XL03130 52900003
.WIN02   ANOP                           BRCH POINT FOR OS ASSEM XL03130 52910003
         ST    GR9,TUCBPTR             SAVE IT IN THE FUNCTION BLOCK.   52920016
         LA   GR3,DDNAME2               LOAD ADDR OF TODD-NAME  XL03130 52930003
         BAL   GR14,TESTUSR             TEST IF OTHER USERS     XM7053  52970002
         TM    0(GR6),COPIES           ARE THERE COPIES INVOLVED.       53010016
         BZ    TOD2                    NO--NO NEED TO LOOK UP UCB'S.    53100016
         L     GR8,COPYPTR             COPY BLOCK ADDRESS.              53190016
TOD1     LA    GR3,DDNAME3             COPY DDNAME ADDRESS.             53280016
         BAL   GR14,UCBFIND            LOCATE ADDRESS OF UCB.           53370016
         AIF   ('&LIB' EQ 'LIB1').WIN03 BRCH IF OS ASSEM        XL03130 53420003
         BAL   GR14,DEVTST              TEST UCB DEV TYPE       XL03130 53430003
         STC   GR3,CDEVMOD              STORE WINCHESTR MOD NO. XL03130 53440003
.WIN03   ANOP                           BRCH POINT FOR OS ASSEM XL03130 53450003
         ST    GR9,CUCBPTR             SAVE ADDRESS IN COPY BLOCK.      53460016
         LA    GR3,DDNAME3              COPY DDNAME ADDR        XL03130 53470003
         BAL   GR14,TESTUSR             TEST IF OTHER USERS     XM7053  53510002
         OC    CCOPYPTR(4),CCOPYPTR    ARE THERE MORE COPIES.           53550016
         BZ    TOD2                    NO--GO START PROCESSING.         53640016
         L     GR8,CCOPYPTR            YES-ADDRESS OF NEXT COPY.        53730016
         B     TOD1                    REPEAT COPY UCB LOOK UP.         53820016
         USING UCB,GR9                                          XL03130 53820403
         AIF   ('&LIB' EQ 'LIB1').WIN04 BRCH IF OS ASSEM        XL03130 53822003
         EJECT                                                  XL03130 53830003
DEVTST   EQU   *                                                XL03130 53850003
         SR   GR3,GR3                   ZERO REG FOR NON-WINCH  XM3782  53852003
         CLI   UCBTBYT4,WINC            THIS A WINCHESTER DEV ? XL03130 53860003
         BNE   NOWINC                   NO, ZERO ODEVMOD        XL03130 53862003
         LA    GR1,WURK                 LOAD SVC P.L. ADDR      XL03130 53872003
         XC    WURK,WURK                ZERO PARAM LIST         XL03130 53874003
         ST    GR9,WURK                 STORE UCB ADDR          XL03130 53876003
         MVI   WURK,SENS                SET P.L. FUNCTION TYPE  XL03130 53878403
         MVI   WURK+D4,ENDPL            SET END OF P.L.         XL03130 53879203
         SVC   82                       ISSUE SENSE FOR WINCH.  XL03130 53879403
         LTR   GR15,GR15                GOOD RETURN             XL03130 53879603
         BNZ   WINERR                   NO, PRINT SVC ERROR MSG XL03130 53879703
         L     GR3,WURK+D4              GET MODEL NO. FROM P.L. XL03130 53879803
         LA    GR3,D0(GR3)              CLEAR HIGH BYTE         XL03130 53880903
NOWINC   EQU   *                                                XL03130 53881303
         BR    GR14                     EXIT THIS RTNE.         XL03130 53882903
WINERR   EQU   *                                                XL03130 53885703
         LA    GR1,MESS13               LOAD ERR NO.            XL03130 53885803
         BAL   GR9,BUILD                GO BUILD MESSAGE        XL03130 53885903
         MVC   0(2,GR1),SVCTYP          MOVE SVC NO. TO MSG     XL03130 53888903
         B     MSGWRT                   GO WRITE MSG            XL03130 53891303
.WIN04   ANOP                                                   XL03130 53892003
TESTUSR  EQU   *                                                XM7053  53895003
         CLI   UCBTBYT3,DASDI           IS TODD A DASD?         XM7053  53898003
         BCR   7,GR14                   NO, RETURN              XM7053  53901003
         AIF   ('&LIB' EQ 'LIB1').OSCODE   BRCH IF OS ASSEM     XM7053  53916102
         CLI   FUNCSW,IPLPROG           THIS PUTIPL FUNCTION ?  XM0148  53916402
         BCR   8,GR14                   BRCH IF YES             XM7053  53916802
.OSCODE  ANOP                                                   XM7053  53917202
         CLI   FUNCSW,LABEL             THIS LABEL FUNCTION ?   XM7053  53917302
         BCR   8,GR14                   BRCH IF YES             XM7053  53917402
         CLC   SYSOUTDD(8),DDNAME2      TODD=SYSPRINT ?         XM7053  53917602
         BCR   8,GR14                   BRCH IF YES             XM7053  53917702
         TM    UCBWGT,SYSINOUT          THIS SYSIO UCB ?        YM5582  53917801
         BC    8,M851                   NO, TEST FOR OTHER USER YM5582  53955301
         B     ZEROUCB                  ISSUE ERROR MSG IEH810I YM5582  53975301
M851     EQU   *                                                YM5582  53985301
         CLC   SRTEUSER,ALLOCNT         ARE THERE OTHER SYSTEM  SA68162 53987321
*                                       USERS ON THIS PACK?     XM7053  53989301
         BCR   13,GR14                  BRCH IF NO OTHERS       XM7053  53991301
         DROP GR9                                               XM7053  53991701
         LA    GR1,MESS51               LOAD ERROR MSG NUMBER   XM7053  53993001
         BAL   GR9,BUILD                GO LOAD IEHDMSGB MODULE XM7053  54030401
         MVC   0(8,GR1),0(GR3)          MOVE DSNAME TO MSG      XM7053  54067801
         B     MSGWRT                   GO WRITE MSG            XM7053  54105201
TOD2     LA    GR6,PTRFUNC1            POINT TO FIRST FUNCTION ON Q.    54142601
         SPACE                                                          54180016
START1   OI    SW1,MULTIPLE            TRY FOR CONCURRENT PROCESSING.   54270016
START2   L     GR10,0(GR6)             ADDRESS OF FUNCTION BLOCK.       54360016
         LA    GR10,0(GR10)            INSURE HIGH ORDER BYTE CLEAR.    54400016
         IC    GR5,SW1                 TEMPORARY STORAGE OF SWITCH.     54450016
         ST    GR6,PTRCFUNC            ADDRESS OF CURRENT FUNCTION.     54540016
         STC   GR5,SW1                 RESTORE SWITCH SETTING.          54630016
         SR    GR7,GR7                 CLEAR.                           54720016
         IC    GR7,FUNCSW              FUNCTION CODE/MULTIPLE OF 16.    54810016
         SRA   GR7,1                   MULTIPLE OF 8.                   54900016
         LA    GR8,LINKADDR            BRANCH TABLE MINUS 8.            54990016
         LA    GR8,0(GR7,GR8)          ADDRESS OF MODULE NAME.          55080016
         CLC   0(8,GR8),LINKADDR       PREVIOUSLY LOADED?               55170016
         BNE   MUSTLOAD                NO--ROUTINE NOT IN CORE YET.     55260016
         L     GR15,LOADADDR           PICK UP ADDRESS OF ROUTINE.      55350016
         B     GOTO                    START PROCESSING OF FUNCTION.    55440016
         SPACE                                                          55530016
MUSTLOAD CLI   LINKADDR,0              NO--ANOTHER LOADED?              55620016
         BE    LOAD                    NO--GO LOAD DESIRED ROUTINE.     55710016
         SPACE                                                          55800016
         DELETE EPLOC=LINKADDR         YES-FREE THE SPACE.              55890016
LOAD     MVC   LINKADDR(8),0(GR8)      SET UP LOAD ADDRESS.             55980016
         LOAD  EPLOC=LINKADDR                                           56070016
         ST    GR0,LOADADDR            SAVE ADDRESS OF ROUTINE.         56160016
         LR    GR15,GR0                ADDRESS OF DESIRED LOAD.         56250016
GOTO     BALR  GR14,GR15                                                56340016
         SPACE                                                          56430016
         LTR   GR15,GR15               RETURN CODE EQUAL ZERO.          56520016
         BC    7,FERROR                NO--MUST BE SOMETHING UNUSUAL.   56610016
         SPACE                                                          56700016
         L     GR6,PTRCFUNC            POINTER TO QUEUE ENTRY.          56790016
        LA     GR6,0(GR6)              CLEAR HIGH ORDER BYTE.           56880016
         TM    0(GR6),COMPLETE         DID WE COMPLETE THIS FUNCTION.   56970016
         BZ    TESTMORE                NO--BETTER TEST FOR MORE ON Q.   57060016
         SPACE                                                          57150016
ENDFUNC1 SR    GR14,GR14               CLEAR.                           57240016
         IC    GR14,RETCODE            CURRENT HIGH RETURN CODE.        57330016
         CLR   GR14,GR15               IS OLD HIGHER THAN NEW.          57420016
         BNL   ENDFUNC                 YES-NO NEED TO SAVE.             57510016
         STC   GR15,RETCODE            SAVE RETURN CODE.                57600016
ENDFUNC  BAL   GR14,FREECORE           YES-FREE CORE ASSIGNED FUNCTION. 57690016
         SPACE                                                          57780016
         CLI   QCOUNT+1,0              MORE ON THE QUEUE                57870016
         BE    TESTEOF                 NO--GO TEST FOR END-OF-FILE.     57960016
         SPACE                                                          58050016
PUSHUP   CL    GR6,ENDCLIST            ARE THERE MORE ENTRIES.          58140016
         BE    TESTEOF1                NO--NO NEED TO UPDATE THE QUEUE. 58230016
         SPACE                                                          58320016
         TM    CSIZE(GR6),ACTIVE       ACTIVE FUNCTION ON NEXT SLOT.    58410016
         BZ    TESTEOF1                NO--NO NEED TO UPDATE THE QUEUE. 58500016
         MVC   0(CSIZE,GR6),CSIZE(GR6) SLIDE EVERYTHING ON THE QUEUE UP 58590016
*                                        ONE SLOT.                      58680016
         NI    0(GR6),X'FF'-NOCORE-WAITING  CLEAR ANY WAIT SWITCHES.    58770016
         LA    GR6,CSIZE(GR6)          INCREMENT TO THE NEXT ENTRY.     58860016
         B     PUSHUP                  GO TEST FOR MORE ENTRIES.        58950016
         SPACE                                                          59040016
TESTEOF  TM    SWITCHRD,EOF            PREVIOUS END-OF-FILE.            59130016
         BO    ENDALL                  YES-MUST BE ALL WOUND-UP.        59220016
         B     SCANA                   GO SCAN MORE CARDS.              59310016
         SPACE                                                          59400016
TESTMORE TM    CSIZE(GR6),ACTIVE       IS THE NEXT SLOT ACTIVE.         59490016
         BZ    CKSPACE                 NO--GO TEST FOR MORE SPACE.      59580016
         SPACE                                                          59670016
         TM    CSIZE(GR6),PROCESS      NEXT FUNCTION ALREADY IN PROCESS 59760016
         LA    GR6,CSIZE(GR6)          STEP TO NEXT QUEUE SLOT.         59850016
         BO    NEXTPROC                YES-GET READY TO CONTINUE IT.    59940016
         SPACE                                                          60030016
         TM    0(GR6),NOCORE           NEXT FUNCTION PREVIOUSLY         60120016
*                                        TERMINATED BECAUSE OF          60210016
*                                        INSUFFICIENT CORE.             60300016
         L     GR10,0(GR6)             POINTER TO NEXT FUNCTION BLOCK.  60390016
         BO    SETWAIT                 YES-DON'T TRY TO RESTART NOW.    60480016
         SPACE                                                          60570016
NOTFIRST LA    GR5,PTRFUNC1            ADDDRESS OF FIRST SLOT IN QUEUE. 60660016
REPEAT   L     GR3,0(GR5)              POINTER TO NEXT FUNCTION BLOCK.  60750016
         CLC   FUNCSW(1),FUNCSW-FUNCBLK(GR3)  NEXT FUNCTION SAME.       60840016
         BNE   SETWAIT                 NO--GO BACK TO TOP OF QUEUE.     60930016
*   CHECK FOR DEVICES BEING AVAILABLE HERE.                             61020016
*     IF YES, SET UP FOR NEXT FUNCTION AT 'NEXTPROC'.                   61110016
*     IF NOT, GO TO 'SETWAIT'.                                          61200016
         SPACE                                                          61290016
         L     GR4,FUCBPTR             NEXT 'FROM' DEVICE.              61380016
         LTR   GR4,GR4                 IS THERE ONE.                    61470016
         BZ    TESTTO                  NO--DO NOT COMPARE.              61560016
         BAL   GR14,TESTDEV            'FROM' VERSUS ALL OTHERS.        61650016
         SPACE                                                          61740016
TESTTO   L     GR4,TUCBPTR             NEXT 'TO' DEVICE                 61830016
         BAL   GR14,TESTDEV            TEST AVAILABILITY.               61920016
         SPACE                                                          62010016
         TM    0(GR6),COPIES           THIS NEXT FUNCTION HAVE COPIES.  62100016
         BZ    TESTEND1                NO--GO SEE IF ALL COMPARES DONE. 62190016
         SPACE                                                          62280016
         L     GR8,COPYPTR             ADDDRESS OF COPY BLOCK.          62370016
REPEAT1  L     GR4,CUCBPTR             'COPY' UCB ADDRESS.              62460016
         BAL   GR14,TESTDEV            GO TEST AVAILABILITY.            62550016
         L     GR8,CCOPYPTR            ADDRESS OF NEXT COPY BLOCK,      62640016
         LTR   GR8,GR8                 IS THERE A COPY.                 62730016
         BNZ   REPEAT1                 YES-REPEAT TESTS.                62820016
         SPACE                                                          62910016
TESTEND1 LA    GR5,CSIZE(GR5)          STEP TO NEXT QUEUE SLOT.         63000016
         CLR   GR5,GR6                 ALL DEVICES TESTED.              63090016
         BNE   REPEAT                  NO--REPEAT TESTS VS NEXT SLOT.   63180016
         SPACE                                                          63270016
BYTES0   EQU   10000                   BUFFER SIZES//CONTROL BLOCKS.    63280016
         GETMAIN EC,LV=BYTES0,A=ANSWER                                  63290016
         LTR   GR15,GR15               IS THERE SUFFICIENT CORE.        63300016
         BNE   SETWAIT                 NO--CANN'T START NEXT FUNCTION.  63310016
         FREEMAIN  E,LV=BYTES0,A=ANSWER                                 63320016
NEXTPROC EQU   *                       OKAY TO START NEXT FUNCTION.     63360016
         B     START1                  GO START NEXT FUNCTION.          63450016
         SPACE                                                          63540016
FERROR   TM    0(GR6),NOCORE           INSUFFICIENT CORE FOR PREVIOUS   63630016
*                                        FUNCTION.                      63720016
         BZ    ENDFUNC1                NO--MUST HAVE ERROR CONDITION.   63810016
         LA    GR7,PTRFUNC1            ADDRESS OF FIRST QUEUE SLOT.     63990016
         CLR   GR6,GR7                 IS THIS FIRST FUNCTION OF QUEUE. 64080016
         BE    COREMSG                 YES-NO HOPE FOR THIS FUNCTION.   64170016
MORE     CLI   QCOUNT+1,1              MORE THAN ONE ON QUEUE.          64350016
         BH    STARTTOP                YES-GO START AT TOP OF QUEUE.    64440016
MORE1    NI    SW1,X'FF'-MULTIPLE      NO--ONLY ONE/TURN OFF MULTIPLE   64530016
*                                        SWITCH.                        64620016
STARTTOP LA    GR6,PTRFUNC1            TOP OF QUEUE ADDRESS.            64710016
         OC    PTRFUNC1(4),PTRFUNC1     IS THIS FUNCTION         A42499 64730021
*                                          SET TO ZERO                  64750021
         BZ    PUSHUP                   YES, GO TO PUSH UP QUEUE A42499 64770021
         B     START2                  GO START PROCESSING.             64800016
SETWAIT  OI    0(GR6),WAITING          SET EAIT FOR THIS FUNCTION.      64980016
        LA     GR7,PTRFUNC1            ADDRESS OF FIRST ENTRY ON QUEUE. 65070016
        CLR    GR6,GR7                 PREVIOUS FUNCTION THE ONLY ONE.  65160016
        BE     MORE1                   YES-CANNOT DO MORE THAN ONE NOW. 65250016
        B      MORE                 NO--GO START AT TOP OF QUEUE.       65340016
CKSPACE  L     GR7,ENDCLIST            END OF QUEUE POINTER.            65520016
         CLR   GR6,GR7                 IS THIS THE LAST SLOT.           65610016
         BE    MORE                    YES-CANNOT QUEUE UP ANY MORE.    65700016
         B     TESTEOF2                GO TEST FOR PREVIOUS END-OF-FILE 65790016
         SPACE                                                          65880016
TESTEOF1 XC    0(4,GR6),0(GR6)         INSURE THIS ENTRY CLEAR.         65970016
TESTEOF2 TM    SWITCHRD,EOF            EOF YET ON SYSIN.                66060016
         BZ    SCANA                   NO--GET NEXT CONTROL STATEMENT   66150016
*                                        AND PLACE IT ON THE QUEUE.     66240016
         B     MORE                    YES--GO FINISH THE FUNCTION WE   66330016
*                                        ARE WORKING ON.                66420016
*        TEST FOR SAME DEVICE AS PREVIOUSLY IN USE.                     66600016
TESTDEV  CL    GR4,FUCBPTR-FUNCBLK(GR3)  COMPARE 'NEW' FROM VS OLD FROM 66690016
         BE    SETWAIT                 SAME//CAN'T START FUNCTION NOW.  66780016
         CL    GR4,TUCBPTR-FUNCBLK(GR3)  COMPARE NEW VS PREVIOUS 'TO'.  66870016
         BE    SETWAIT                 SAME//CAN'T START FUNCTION NOW.  66960016
         SPACE                                                          67050016
         L     GR1,COPYPTR-FUNCBLK(GR3)  POINTER TO COPY BLOCK.         67100016
         DROP  8                                                        67150016
         USING COPYBLK,GR1                                              67200016
TESTCPYY LTR   GR1,GR1                 WAS THERE A COPY.                67250016
         BCR   8,GR14                  NO--RETURN.                      67320016
         SPACE                                                          67410016
         CL    GR4,CUCBPTR             COMPARE NEW DEVICE VS OLD COPY.  67500016
         BE    SETWAIT                 SAME//CAN'T START FUNCTION NOW.  67590016
         L     GR1,CCOPYPTR            POINTER TO NEXT COPY, IF ANY.    67630016
         DROP  1                                                        67670016
         USING COPYBLK,GR8                                              67710016
         B     TESTCPYY                REPEAT COMPARES.                 67770016
         SPACE 1                                                        67860016
ENDALL   LA    GR1,MESS39              MESSAGE NUMBER 839.              67950016
         BAL   GR9,BUILD               PLACE MESSAGE IN BUFFER.         68040016
         SR    GR15,GR15               CLEAR.                           68130016
         IC    GR15,RETCODE            RETURN CODE.                     68220016
         CVD   GR15,WORKD8             CONVERT TO DECIMAL.              68310021
         UNPK  1(2,GR1),WORKD8+6(2)    CONVERT TO GRAPHICS AND MOVE.    68400021
         OI    2(GR1),X'F0'            RESET ZONE.                      68490016
         BAL   GR9,ERRPRINT            GO WRITE OUT THE MESSAGE.        68580016
         CLOSE (READ,,PRINT)           CLOSE INPUT AND OUTPUT DATA SETS 68670016
         LA    GR1,READ                SYSIN DCB ADDRESS.               68690016
         BAL   GR9,FREEPOOL            FREE THE SYSIN BUFFER POOLS.     68700016
         LA    GR1,PRINT               SYSOUT DCB ADDRESS.              68710016
         BAL   GR9,FREEPOOL            FREE THE SYSOUT BUFFER POOLS.    68720016
         L     GR1,WIPLPTR             POINTER TO IPL BUFFER, IF ANY.   68726016
         LTR   GR1,GR1                 IS THERE AN IPL BUFFER.          68732016
         BZ    FREEWORK                NO--                             68738016
         AIF  ('&LIB' EQ 'LIB1').ARONDG  THIS ASSEM FOR OS, BRCH X02912 68740002
         L     GR0,IPLMAX               GET MAX BUFFER SIZE      X02912 68742002
         AGO   .ARONDH                  BRCH AROUND OS VALUE     X02912 68742402
.ARONDG  ANOP                           BRCH POINT FOR OS CODE   X02912 68742802
         LA    GR0,IPLSIZE             SIZE OF BUFFER.                  68744016
.ARONDH  ANOP                           BRCH POINT FOR VS CODE   X02912 68746002
         BAL   GR9,FREEBUFF            RELEASE THE CORE.                68750016
         SPACE 1                                                        68760016
FREEWORK EQU   *                       FREE WORK AREA//EXIT HERE.       69060016
         L     GR13,ROOTSAVE+4         RESTORE REGISTER 13.             69390016
         CLI   PAGESW,X'FF'            WAS PAGE NO. PASSED TO ROUTINE.  69480016
         BNE   RETURN1                 NO--RESTORE/RETURN.              69570016
         L     GR1,24(GR13)            YES-POINTER TO PASSED PARAMETERS 69660016
         L     GR1,8(GR1)              POINTER TO PAGE NUMBER.          69750016
         LH    GR6,PAGENO              CURRENT PAGE NO.                 69840016
         CVD   GR6,WORKD8              CONVERT TO DECIMAL.              69930021
         UNPK  3(3,GR1),WORKD8+6(2)    CONVERT TO GRAPHICS AND MOVE.    70020021
         OI    5(GR1),X'F0'            RESET ZONE.                      70110016
RETURN1  EQU   *                       EXIT FROM THE PROGRAM HERE.      70130016
         CLI   LINKADDR,0              ANY MODULES LOADED        A53137 70140000
         BE    RETURN2                 NO, GO RETURN             A53137 70142000
         DELETE EPLOC=LINKADDR         DELETE LAST MODULE        A53137 70144000
         MVI   LINKADDR,0              SET 'NO MODULES LOADED'.  A59759 70146021
         XC    LOADADDR(4),LOADADDR    CLEAR LOAD ADDRESS.       A59759 70148021
RETURN2  LR    GR1,WORKBASE            ADDRESS OF WORKAREA.      A53137 70150000
         LA    GR0,WORKSIZE            SIZE OF WORKAREA.                70170016
         BAL   GR9,FREEBUFF            FREE THE WORK AREA CORE.         70190016
         SR    GR15,GR15               CLEAR.                           70210016
         IC    GR15,RETCODE            HIGHEST RETURN CODE.             70230016
         RETURN (14,12),T,RC=(15)      RESTORE/RETURN W/PROPER CODE.    70250016
         SPACE 1                                                        70290016
         EJECT                                                          70380016
*********************************************************************** 70470016
*   THIS SECTION FREES THE CORE OF THE FUNTION BLOCK AND COPY BLOCKS,   70650016
*     IF ANY, FOR THE JUST COMPLETED FUNCTION.                          70740016
*                                                                     * 70830016
*   REGISTER 6 MUST POINT TO THE PROPER CONTROL LIST FOR THIS         * 70920016
*     FUNCTION UPON ENTRY.                                            * 71010016
*   REGISTER 14 IS THE RETURN REGISTER.                               * 71100016
*********************************************************************** 71280016
FREECORE LTR   GR10,GR10               IS THERE A FUNCTION BLOCK.       71370016
         BCR   8,GR14                  NO--RETURN.                      71460016
         TM    0(GR6),COPIES           ARE THERE COPIES INVOLVED.       71550016
         BZ    FREEFUNC                NO--GO FREE THE FUNCTION BLOCK.  71640016
BEGIN1   L     GR8,COPYPTR             POINTER TO COPY BLOCK.           71820016
TESTEND  CLC   CCOPYPTR(4),ZERO        IS THERE ANOTHER COPY BLOCK.     71910016
         BNE   TESTAGIN                YES-GO FIND THE LAST IN CHAIN.   72000016
         XC    COPYPTR(4),COPYPTR      NO--CLEAR POINTER TO FIRST COPY. 72090016
         BAL   GR9,FREECOPY            RELEASE COPY BLOCK CORE.         72180016
         B     FREEFUNC                GO FREE THE FUNCTION BLOCK.      72270016
FREECOPY LR    GR1,GR8                 ADDRESS OF COPY BLOCK.           72450016
         LA    GR0,COPYSIZE            SIZE OF COPY BLOCK.              72540016
FREEBUFF FREEMAIN R,LV=(0),A=(1)       RELEASE SOME CORE.               72630016
         BR    GR9                     RETURN.                          72720016
TESTAGIN LR    GR7,GR8                 SAVE POINTER TO CURRENT COPY.    72900016
         L     GR8,CCOPYPTR            ADDRESSING FOR NEXT COPY BLOCK.  72990016
         CLC   CCOPYPTR(4),ZERO        DOES IT POINT TO ANOTHER.        73080016
         BNE   TESTAGIN                YES-GO FIND LAST IN CHAIN.       73170016
         BAL   GR9,FREECOPY            NO--GO FREE LAST IN CHAIN.       73260016
         LR    GR8,GR7                 RESTORE POINTER TO PREVIOUS.     73350016
         XC    CCOPYPTR(4),CCOPYPTR    ZERO POINTER TO RELEASED BLOCK.  73440016
         B     BEGIN1                  REPEAT UNTIL ALL COPIES RELEASED 73530016
FREEFUNC CLI   FUNCSW,ANALYSIS          THIS ANALYZE ?                  73710000
         BE    FREEB                    YES-BRANCH.                     73760000
         CLI   FUNCSW,FORMAT            THIS FORMAT?                    73810000
         BNE   FREEF                    NO - GO FREE FUNCTION BLOCK     73860000
FREEB    L     GR1,FIPLPTR              IPL BUFFER ADDRESS              73910000
         LTR   GR1,GR1                 WAS THERE AN IPL BUFFER.         73980016
         BZ    FREEF                   NO--GO FREE FUNCTIOM BLOCK.      74070016
         CLC   FIPLPTR+1(3),WIPLPTR+1  ONLY ONE IPL BUFFER.             74100016
         BE    FREEF                   YES-WE WILL FREE IT LATER.       74130016
         AIF   ('&LIB' EQ 'LIB1').ARONDI THIS ASSEM FOR OS, BRCH X02912 74140002
         L     GR0,IPLMAX               GET MAX BUFFER SIZE      X02912 74150002
         AGO   .ARONDJ                  BRCH AROUND OS VALUE     X02912 74152002
.ARONDI  ANOP                           BRCH POINT FOR OS CODE   X02912 74154002
         LA    GR0,IPLSIZE             SIZE OF BUFFER.                  74160016
.ARONDJ  ANOP                           BRCH POINT FOR VS CODE   X02912 74210002
         BAL   GR9,FREEBUFF            GO FREE THE IPL BUFFER.          74250016
FREEF    LR    GR1,GR10                FUNCTION BLOCK ADDRESS.          74340016
         LH    GR0,FSIZE               SIZE OF FUNCTION BLOCK.          74430016
         BAL   GR9,FREEBUFF            RELEASE FUNCTION BLOCK CORE.     74520016
         XC    0(4,GR6),0(GR6)         CLEAR POINTER TO FUNCTION BLOCK. 74610016
         LH    GR9,QCOUNT              CURRENT NO.ENTRIES ON QUEUE.     74700016
         BCTR  GR9,0                   DECREMENT BY ONE.                74790016
         STH   GR9,QCOUNT              RESET SAVED VALUE.               74880016
         SR    GR10,GR10               CLEAR POINTER TO FUNCTION BLOCK. 74970016
         BR    GR14                    RETURN.                          75060016
         EJECT                                                          75150016
UCBFIND  EQU   *                                                        75190016
         L     GR9,CVTPTR              ADDRESS OF COMM. VECTOR TABL).   75230016
         USING CVT,GR9                                                  75270016
         CLI   0(GR3),BLANK            THIS A LEGIT DDNAME.             75310016
         BE    NEEDUCB                 NO--SPAECIAL CASE.               75350016
         L     GR4,CVTTCBP             TCB WORKD8 WORD.         SA68162 75420021
         L     GR4,LASTCTCB(GR4)       PICK UP TCB ADDRESS.     SA68162 75510021
         USING TCB,GR4                                          SA68162 75560021
         L     GR4,TCBTIO              PICK UP TIOT ADDRESS.    SA68162 75600021
         DROP  GR4                                              SA68162 75650021
         USING TIOT1,GR4                                        SA68162 75660021
         LA    GR15,TIOELNGH           PICK UP DD ENTRY ADDRESS SA68162 75690021
         SR    GR1,GR1                                                  75780016
FINDNAME IC    GR1,0(GR15)             LOAD DD ENTRY LENGTH.            75870016
         LTR   GR1,GR1                 TEST FOR END OF TIOT.            75960016
         BZ    BADCARD                 END OF TABLE/NO DDNAME.          76050016
         CLC   4(8,GR15),0(GR3)        CHECK DD ENTRY FOR NAME MATCH.   76140016
         LR    GR2,GR15                SAVE POINTER.                    76230016
         LA    GR15,0(GR1,GR15)        SET UP FOR NEXT ENTRY.           76320016
         BNE   FINDNAME                NO MATCH-RETURN TO CHECK MORE.   76410016
         L     GR9,16(GR2)             POINTER TO UCB.                  76770016
         LTR   GR9,GR9                  UCB ADDR ZERO ?         YM5582  76820001
         BZ    CHKPRINT                 YES, CHK SYSPRINT       SA68162 76830021
         LR    GR15,GR4                 GET TIOT                SA68162 76830421
         DROP  GR4                                              SA68162 76830521
         USING TIOT1,GR15                                       SA68162 76830621
         SR    GR4,GR4                  CLEAR                   SA68162 76830821
         LR    GR1,GR4                  *                       SA68162 76831221
TRYAGAIN EQU   *                                                SA68162 76831621
         C     GR9,TIOESTTB             SAME UCB ?              SA68162 76831721
         BNE   NXTIOT                   GO GET NEXT ENT         SA68162 76831821
         LA    GR4,ADD1(GR4)            INCREMENT UCB COUNT     SA68162 76831921
         STC   GR4,ALLOCNT              SAVE COUNT              SA68162 76836421
NXTIOT   EQU   *                                                SA68162 76838421
         IC    GR1,TIOELNGH             OBTAIN ENT LENGTH       SA68162 76840421
         LTR   GR1,GR1                  END OF TIOT?            SA68162 76840821
         BCR   COND0,GR14               YES, RETURN             SA68162 76840921
         LA    GR15,DISP0(GR1,GR15)     GET NEXT ENT            SA68162 76845921
         B     TRYAGAIN                 GO CHK ENT              SA68162 76847921
CHKPRINT EQU   *                                                SA68162 76851021
         CLC   SYSOUTDD,0(GR3)          DDNAME=SYSPRINT ?       OX01789 76856021
         BCR   8,GR14                   YES, EXIT               OX01789 76861026
         SPACE 2                                                        76866016
ZEROUCB  EQU   *                                                YM5582  76868001
         LA    GR1,MESS20               LOAD MSG NO.            YM5582  76870001
         BAL   GR9,BUILD                BRING MSG INTO BUFFER   YM5582  76870401
         MVC   K0(L8,GR1),K0(GR3)       MOVE DDNAME TO MSG      YM5582  76870801
         B     MSGWRT2                  GO PRINT MSG            YM5582  76871201
NEEDUCB  EQU   *                                                        76872016
         L     GR15,CVTILK2            UCB ADDRESS TABLE.               76878016
STARTEST LH    GR1,0(GR15)             PICK UP TABLE ENTRY.             76884016
         LTR   GR1,GR1                 THIS A VALID ENTRY.              76890016
         BZ    UPUCBPTR                NO--GO SEE IF MORE ENTRIES.      76896016
         USING UCB,GR1                                                  76902016
         TM    UCBTBYT3,UCB3DACC       THIS A DIRECT ACCESS DEVICE.     76908016
         BZ    UPUCBPTR                 NO--GO SEE IF MORE ENTRIES.     76914016
         CLC   1(3,GR3),UCBNAME         THIS THE DESIRED UCB.           76920016
         BNE   UPUCBPTR                 NO--GO SEE IF MORE ENTRIES.     76926016
         AIF  ('&LIB' EQ 'LIB2').NODC1  BRCH IF VS ASSEM        XL03912 76928003
         CLI   UCBTBYT4,DA2321          THIS A 2321                     76932016
         BE    PROC2321                 YES-SPECIAL CASE.               76938016
.NODC1   ANOP                                                   XL03912 76940003
UCBRET   LR    GR9,GR1                  ADDDRESS OF UCB.                76944016
         BR    GR14                     RETURN.                         76950016
         AIF  ('&LIB' EQ 'LIB2').NODC2  BRCH IF VS ASSEM        XL03912 76952003
         SPACE                                                          76956016
PROC2321 SR    GR4,GR4                  CLEAR.                          76962016
         IC    GR4,5(GR3)               PICK UP BIN NO.                 76968016
         N     GR4,MASK                 CLEAR ZONE BITS.                76974016
         SLA   GR4,4                    BIN NO. TIMES 16.               76980016
         LA    GR1,DATACELL(GR4)        SUB-UCB ADDRESS.                76986016
         B     UCBRET                   EXIT NOW.                       76992016
.NODC2   ANOP                                                   XL03912 76994003
         DROP  1,9                                                      76998016
UPUCBPTR LA    GR15,2(GR15)             STEP TO NEXT TABLE ENTRY.       77010016
         CLC   0(2,GR15),UCBLAST        ANY MORE ENTRIES.               77016016
         BNE   STARTEST                 YES--KEEP LOOKING.              77022016
         B     RMESS24                  NO--THIS UCB NOT IN SYSTEM.     77028016
         EJECT                                                          77040016
MSGPRT   EQU   *                                                        77070016
         TM    SW1,TEXTIN              ARE WE LOOKING FOR IPL TEXT.     77100016
         BO    NOIPLMSG                YES-GIVE PROPER MESSSAGE.        77130016
         LA    GR1,MESS0               MESSAGE NUMBER.                  77160016
         BAL   GR9,BUILD               GO MOVE MESSAGE TO BUFFER.       77220016
         L     GR3,STORGR3             LAST ADDRESS SCANNED.            77310016
         LA    GR4,CARDBUFF            START OF CONTROL STATEMENT.      77400016
         SR    GR3,GR4                 NO. OF COLUMNS SCANNED.          77490016
         CVD   GR3,WURK                CONVERT TO DECIMAL               77580021
         UNPK  WURK(2),WURK+6(2)       UNPACK FOR PRINTING.             77670021
         OI    WURK+1,X'F0'            SET PROPER ZONE.                 77760021
         TR    WURK(2),IOTAB-240       CONVERT TO EBCDIC FOR PRINTING.  77850021
         MVC   0(2,GR1),WURK           PLACE ANSWER IN MESSAGE.         77940021
         B     MSGWRT2                 GO WRITE OUT THE MESSAGE.        78030016
         SPACE                                                          78120016
INVALCOM LA    GR1,MESS1               MESSAGE NUMBER 801.              78210016
INV1     BAL   GR9,BUILD               GO MOVE MESSAGE TO BUFFER.       78300016
         MVC   0(8,GR1),WURK           MOVE INVALID PORTION TO MESSAGE. 78390021
         B     MSGWRT2                 GO WRITE OUT THE MESSAGE.        78480016
INVALKEY LA    GR1,MESS2               MESSAGE NUMBER 802.              78570016
         B     INV1                    BUILD AND WRITE OUT THE MESSAGE. 78660016
INVALP1  BCTR  GR2,0                   DECREMENT LENGTH FOR EXECUTE.    78750016
INVALPAR LR    GR5,GR1                 SAVE ADDRESS OF PARAMETER.       78840016
         LA    GR1,MESS3               MESSAGE NUMBER 803.              78930016
         BAL   GR9,BUILD               GO BUILD THE MESSAGE.            79020016
         LR    GR4,GR1                 ADDRESS TO MOVE IN PARAMETER.    79110016
         LR    GR1,GR5                 ADDRESS OF PARAMETER.            79200016
         EX    GR2,PMOVE               PARAMETER TO OUTPUT BUFFER.      79290016
         B     MSGWRT2                 GO WRITE OUT THE MESSAGE.        79380016
         SPACE                                                          79470016
KEYMISS  LA    GR1,MESS4               MESSAGE NUMBER 804.              79560016
         BAL   GR9,BUILD               GO MOVE MESSAGE TO BUFFER.       79650016
         B     MSGWRT2                 GO WRITE OUT THE MESSAGE.        79740016
         SPACE                                                          79830016
DCBERROR LA    GR1,MESS5               MESSAGE NUMBER 805.              79920016
         BAL   GR9,BUILD               GO MOVE MESSAGE TO BUFFER.       80010016
         LA    GR4,READ                SYSIN DCB ADDRESS.               80100016
         USING IHADCB,GR4                                               80190016
         MVC   0(8,GR1),DCBDDNAM       DDNAME TO MESSAGE.               80280016
         BAL   GR9,ERRPRINT            WRITE OUT THE MESSAGE.           80370016
         MVI   RETCODE,8               SET RETURN CODE.                 80460016
         B     ENDALL                  GO TERMINATE.                    80550016
         SPACE                                                          80640016
         SPACE                                                          80730016
BADCARD  LA    GR1,MESS12              MESSAGE NUMBER.                  80820016
BADCARD1 BAL   GR9,BUILD               GO MOVE MESSAGE TO BUFFER.       80910016
         MVC   0(8,GR1),0(GR3)         DDNAME TO MESSAGE                81000016
         B     MSGWRT                  GO WRITE OUT THE MESSAGE.        81090016
MSGWRT2  OI    SWITCHRD,BYPASS         INSURE SCAN KNOWS OF ERROR.      81130016
         SPACE                                                          81180016
MSGWRT   BAL   GR14,FREECORE           FREE CORE ASSIGNED THIS FUNCTION 81270016
MSGWRT1  BAL   GR9,ERRPRINT            GO WRITE OUT THE MESSAGE.        81360016
         MVI   RETCODE,8               SET RETURN CODE.                 81450016
         TM    SWITCHRD,EOF            PREVIOUS EOF.                    81570016
         BO    CHECK                   YES-GO SEE IF FINISHED.          81600016
         B     SCAN                    RESUME SCAN OF CARDS,            81630016
         SPACE                                                          81720016
*   WRITE OUT ALL MESSAGES HERE.                                        81810016
ERRPRINT EQU   *                                                        81900016
         LINK  EP=IEHDPRNT                                              81990016
         BR    GR9                     RETURN.                          82080016
         SPACE                                                          82170016
*   BUILD ALL MESSAGES HERE.                                            82260016
BUILD    LINK  EP=IEHDMSGB                                              82350016
         BR    GR9                     RETURN.                          82440016
         SPACE                                                          82530016
SETCODE  MVI   RETCODE,16              SET RETURN CODE.                 82620016
         B     FREEWORK                GO FREE THE WORK AREA.           82710016
         SPACE                                                          82800016
COREMSG  LA    GR1,MESS18              MESSAGE NUMBER 818.              82890016
         BAL   GR9,BUILD               GO MOVE MESSAGE TO BUFFER.       82980016
         B     MSGWRT                  GO WRITE OUT THE MESSAGE.        83070016
         SPACE                                                          83160016
NOIPL    MVI   SWITCHRD,EOF            INDICATE EOF ENCOUNTERED.        83220016
NOIPLMSG LA    GR1,MESS26              MESSAGE NUMBER 826.              83280016
         NI    SW1,X'FF'-TEXTIN        INSURE SWITCH IS OFF.            83340016
         BAL   GR9,BUILD               PLACE MESSAGE IN BUFFER.         83430016
         MVC   0(8,GR1),WORKD8         DDNAME TO MESSAGE.        A32162 83500021
         B     MSGWRT2                 GO WRITE OUT THE MESSAGE.        83570016
         SPACE                                                          83620016
RMESS24  LA    GR1,MESS24              MESSAGE NUMBER.                  83630016
         MVI   SWITCHRD,0              RESET CONTROL SWITCH      M2385  83632000
         B     BADCARD1                GO BUILD AND WRITE OUT MESSAE.  83640016
         EJECT                                                          83650016
FREEPOOL CLI   20(GR1),1               ARE THERE BUFFERS.        A53137 83655000
         BCR   4,GR9                   NO--RETURN.               A53137 83660000
         FREEPOOL (1)                  FREE QSAM BUFFER POOLS.          83665016
         BR    GR9                     RETURN.                          83670016
*********************************************************************** 83790016
*                                                                     * 83880016
*   THIS ROUTINE WILL CLEAR ANY BLOCK OF CORE TO ZERO.                * 83970016
*                                                                     * 84060016
*     REGISTER 1 MUST CONTAIN THE STARTING ADDRESS UPON ENTRY.        * 84150016
*     REGISTER 2 IS A WORK REGISTER.                                  * 84240016
*     REGISTER 3 MUST CONTAIN THE SIZE UPON ENTRY.                    * 84330016
*     REGISTER 14 IS THE RETURN REGISTER.                             * 84420016
*                                                                     * 84510016
*********************************************************************** 84600016
         SPACE                                                          84690016
CLEAR    LA    GR2,255                 SET FOR EXECUTE.                 84780016
         MVI   0(GR1),X'00'            PRIME FIRST BYTE FOR EXEC.       84870016
EXEC     CH    GR3,TWO56               WILL THIS BE THE LAST PASS.      84960016
         BNH   LASTTIME                YES-DO ONE MORE MOVE.            85050016
         EX    GR2,MVZO                CLEAR 256 BYTES.                 85140016
         LA    GR1,256(GR1)            INCREMENT ADDRESS.               85230016
         SH    GR3,TWO56               UPDATE BYTE COUNT.               85320016
         B     EXEC                    RETURN TO CHECKPOINT.            85410016
         SPACE 1                                                        85500016
LASTTIME BCTR  GR3,0                   DECREMENT FOR MVC.               85590016
         EX    GR3,MVZO                CLEAR REMAINING PORTION.         85680016
         BR    GR14                    RETURN.                          85770016
         EJECT                                                          85860016
LOADADDR DC    F'0'                    FUNCTION ROUTINE ADDRESS.        85950016
         DS    0F                                                       86040016
EXITLST1 DC    X'85'         SYSIN DCB EXIT LIST                        86130016
         DC    AL3(DCBEXIT1)                                            86220016
LINKADDR DC    1D'0'                   NAME OF ROUTINE TO LOAD.         86310016
         DC    C'IEHDDUMP'             DUMP MODULE.                     86400016
         DC    C'IEHDREST'             RESTORE MODULE.                  86490016
         DC    C'IEHDGETA'             GETALT MODULE.                   86580016
         DC    C'IEHDLABL'             LABEL MODULE.                    86670016
         DC    C'IEHDANAL'             ANALYZE MODULE.                  86760016
          DC    C'IEHDANAL'            FORMAT MODULE.                   86850016
         DC    C'IEHDIPLI'             IPLPROG MODULE                   86890000
         SPACE 1                                                        86940016
ENDPL    EQU   X'80'                    END OF PARAM. LIST FLG  XL03130 86960003
         AIF   ('&LIB' EQ 'LIB1').WIN05 BRCH IF OS ASSEM        XL03130 86990003
WINC     EQU   X'0A'                    WINCHESTER UCB TYPE     XL03130 87040003
SVCTYP   DC    C'82'                    DEVTYPE SVC NO.         XL03130 87150003
         DS    H                        UNUSED                          87204003
.WIN05   ANOP                                                   XL03130 87208003
D4       EQU   4                        DISPLACEMENT OF 4       XL03130 87208403
D0       EQU   0                        DISPLACEMENT OF 0       XL03130 87208803
ZERO     DC    F'0'                                                     87210016
ROOTSAVE DS    18F                     SAVE AREA FOR CALLED ROUTINES.   87300016
KONSTANT DC    V(IEHDCONS)             DEVICE CONSTANT MODULE ADDRESS.  87390016
ANSWER   DS    1F                      USED BY CONDITIONAL GETMAIN.     87430016
         SPACE 1                                                        87480016
MVZO     XC    0(1,GR1),0(GR1)         EXECUTED TO CLEAR CORE.          87570016
PMOVE    MVC   0(1,GR4),0(GR1)         USED TO MOVE DDNAME PARAMETERS.  87660016
CHKTODD  CLC   4(0,GR15),0(GR1)         EXECUTED COMPARE OF DDN  A50288 87750021
TWO56    DC    H'256'                  COMPARE CONSTANT.                87840016
EIGHT    DC    H'8'                                                     87930016
THREE    DC    H'3'                    COMPARE CONSTANT.                88020016
FIVE     DC    H'5'                     LENGTH OF TODD FOR 2321  A50288 88030021
*                                       OFFLINE                  A50288 88032021
         DS    0F                                                       88040016
         AIF   ('&LIB' EQ 'LIB1').ARONDK THIS ASSEM FOR OS, BRCH X02912 88050002
IPLMAX   DC    F'6496'                  MAX IPLTXT RECORD SIZE   X02912 88052002
.ARONDK  ANOP                                                    X02912 88054002
MASK     DC    X'0000000F'             MASK FOR 'AND'.                  88060016
UCBLAST  DC    XL2'FFFF'               LAST UCB IDENTIFIER.             88080016
RETCODE  DC    X'00'                   HIGHEST RETURN CODE, IF ANY.     88110016
SAVLGTH  DS    1C                      LENGTH SAVE AREA.                88200016
YES      DC    C'YES'                  PARAMETER COMPARISON.            88290016
NO       DC    C'NO'                   PARAMETER COMPARISON.            88380016
TXT      DC    C'TXT'                  TEXT CARD COMPARE.               88470016
END1     DC    C'END'                  END CARD COMPARE.                88560016
ALLOCNT  DC    XL1'0'                   UCB ALLOCATION COUNT    SA68162 88610021
CTOEMASK DC    X'2020202020202020'     USED TO CHANGE ZONES.            88650016
ALTTT    DC    X'0A0B0C0D0E0FDDDDDD'   TABLE FOR CONVERSION TO HEX.     88740016
         DC    X'DDDDDDDDDDDD'                                          88830016
         DC    X'00010203040506070809'                                  88920016
IOTAB    DC    C'0123456789ABCDEF'     TRANSLATE TABLE.                 89010016
         SPACE 1                                                        89100016
         EJECT                                                          89190016
PRINT    DCB   DSORG=PS,MACRF=PM,RECFM=FBSA,BFTEK=S,BFALN=F,           X89280016
               DDNAME=SYSPRINT,LRECL=121,EXLST=EXITLST1                 89370016
         SPACE                                                          89460016
READ     DCB   DSORG=PS,MACRF=GM,RECFM=FB,LRECL=80,BFTEK=S,            X89550016
               BUFNO=2,BFALN=F,DDNAME=SYSIN,EXLST=EXITLST1,EROPT=SKP    89640016
MAINT    DS    50F                     PATCH AREA.              US02496 89690000
         EJECT                                                          89730016
         IEHDWORK                                                       89820016
         SPACE                                                          89910016
         SPACE 1                                                        90000016
         IEHDBLKS                                                       90090016
         SPACE                                                          90180016
DEVMSK   DSECT                          MASKS DEVTYPE MACRO O/P XL03130 90230003
         DS    2F                                               XL03130 90240003
NOCYL    DS    H                        NO. OF CYLINDERS        XL03130 90250003
IPLCARD  DSECT                         CARD FORMAT//IPL PROGRAM.        90270016
CARDID   DS    CL1                                                      90360016
CARDTYPE DS    CL3                     TYPE OF CARD.                    90450016
         DS    CL1                                                      90540016
CARDADDR DS    CL3                                                      90630016
         DS    CL2                                                      90720016
CARDBYTE DS    CL2                     NO. OF BYTES//THIS CARD.         90810016
         DS    CL2                                                      90900016
         DS    CL2                                                      90990016
CARDTEXT DS    CL56                    TEXT DATA PORTION.               91080016
         DS    CL8                                                      91170016
         EJECT                                                          91190016
UCB      DSECT                                                          91210016
         IEFUCBOB                                                       91230016
         EJECT                                                          91260016
         DCBD  DSORG=PS                                                 91350016
         EJECT                                                          91440016
CVT      DSECT                                                          91530016
         CVT   SYS=MIN                                                  91620016
         EJECT                                                          91670021
         AIF   ('&LIB' EQ 'LIB1').OSTCB                         SA68162 91672021
         IKJTCB SYS=AOS1,DSECT=YES,LIST=YES                     SA68162 91680021
         AGO   .TCBEND                                          SA68162 91682021
.OSTCB   ANOP                                                   SA68162 91684021
         IKJTCB                                                 SA68162 91686021
.TCBEND  ANOP                                                   SA68162 91688021
         EJECT                                                          91690021
TIOT     DSECT                                                  SA68162 91700021
         IEFTIOT1                                               SA68162 91702021
         SPACE 1                                                        91710016
         END                                                            91800016
