IEHDCELL CSECT                                                          00100016
*1230502000                                                      A41472 00100521
*                                                                     * 00101016
*STATUS CHANGE LEVEL 003                                                00102021
*                                                                     * 00103016
*FUNCTION/OPERATION- THIS ROUTINE, USED AS A SUBROUTINE BY            * 00104016
*   -IEHDANAL-, PERFORMS ALL SURFACE ANALYSIS AND FORMATTING OF A     * 00105016
*   DATA CELL VOLUME. IT WILL WRITE HOME ADDRESS, A STANDARD          * 00106016
*   LENGTH(8 BYTES) R0, AND A MAXIMUM LENGTH R1 ON EACH TRACK OF      * 00107016
*   A CYLINDER, AND THEN READ BACK CHECK THE ENTIRE CYLINDER.         * 00107416
*   FOR EACH TRACK CHECKED, THE HOME ADDRESS WILL BE READ IN          * 00107816
*   AND ADDRESS COMPARED. EACH NON-COMPARE WILL RESULT IN THE         * 00108216
*   BLANK TRACK DIAGNOSTIC MESSAGE BEING GIVEN.                       * 00108616
*                                                                     * 00109016
*   READ BACK CHECKING OCCURS IN THE FOLLOWING PATTERN-               * 00109416
*        READ BACK CHECK EACH TRACK AT END OF CYLINDER                * 00109816
*        READ BACK CHECK FIRST TRACK EACH CYLINDER AT END OF STRIP    * 00110216
*        READ BACK CHECK FIRST TRACK EACH STRIP AT END OF SUBCELL     * 00110616
*        READ BACK CHECK FIRST TRACK EACH SUBCELL AT END OF CELL.     * 00111016
*                                                                     * 00111416
*   UPON COMPLETION OF ALL WRITING AND VERIFYING, CONTROL IS          * 00111816
*   RETURNED TO -IEHDANAL- FOR FINAL PROCESSING (VOLUME LABEL         * 00112216
*   WRITING AND VTOC BUILDING).                                       * 00112616
*                                                                     * 00113016
*   MOST ERRORS ENCOUNTERED WILL BE HANDLED BY IOS ERROR RECOVERY     * 00114016
*   PROCEDURES. THE EXCEPTION IS-                                     * 00114816
*        DATA CHECKS- RESULTS IN THIS ROUTINE RETRYING THE            * 00115616
*              CHANNEL PROGRAM UP TO 113 TIMES. LACKING ONE           * 00116416
*              SUCCESSFUL COMPLETION, A DIAGNOSTIC MESSAGE            * 00117216
*              WILL BE GIVEN DESCRIBING THE DEFECTIVE TRACK           * 00118016
*              AND THE ALTERNATE TRACK THEN ASSIGNED.                 * 00118816
*                                                                     * 00119616
*        IOS WILL HANDLE NO RECORD FOUND AND MISSING ADDRESS          * 00120416
*              MARKER CONDITIONS. FOR A HARD ERROR IN THIS CASE,      * 00121216
*              THE BLANK TRACK DIAGNOSTIC MESSAGE WILL BE GIVEN.      * 00122016
*                                                                     * 00123016
*ENTRY POINTS- THE ONLY ENTRY POINT IS -IEHDCELL-, AND CONTROL IS     * 00124016
*   ALWAYS RECEIVED FROM -IEHDANAL-.                                  * 00125016
*                                                                     * 00126016
*INPUT- POINTERS TO A WORK AREA(REGISTER 12) AND TO THE FUNCTION      * 00127016
*   BLOCK(REGISTER 10).                                               * 00128016
*                                                                     * 00129016
*EXITS-NORMAL- SUCCESSFUL COMPLETION OF ALL I/O OPERATIONS RESULTS    * 00130016
*   IN RETURN TO -IEHDANAL- WITH A RETURN CODE OF 0.                  * 00131016
*                                                                     * 00132016
*EXITS-ERROR- A RETURN TO -IEHDANAL- WITH A RETURN CODE OF 8          * 00133016
*   WILL RESULT FOR THE FOLLOWING CONDITIONS-NO MORE AVAILABLE        * 00134016
*   ALTERNATE TRACKS, AN INCORRECTABLE I/O ERROR, OR 3 BLANK TRACKS.  * 00135016
*                                                                     * 00136016
*EXTERNAL ROUTINES- ALL MESSAGES WILL BE WRITTEN OUT BY THE           * 00137016
*   MESSAGE WRITER ROUTINE(IEHDPRNT) AFTER BEING SET UP BY THE        * 00138016
*   MESSAGE BUILDER ROUTINE(IEHDMSGB). TWO DCB APPENDAGES ARE         * 00139016
*   ALSO USED-IGG019P8(END OF EXTENT), AND IGG019P9(ABNORMAL END).    * 00140016
*   SVC 82(IGC0008B) IS USED FOR ALTERNATE TRACK ASSIGNMENT.          * 00141016
*   ALL DEVICE DEPENDENT INFORMATION IS CONTAINED IN THE CSECT        * 00142016
*   CALLED -IEHDCONS-.                                                * 00143016
*                                                                     * 00144016
*TABLES/WORK AREAS- REGISTER 10 AND 12 WILL POINT TO THE FUNCTION     * 00145016
*   BLOCK AND THE WORK AREA RESPECTIVELY. THEY ARE DESCRIBED BY       * 00146016
*   THE DSECTS CALLED -FUNCBLK- AND -WORK-.                           * 00147016
*                                                                     * 00148016
*ATTRIBUTES- SERIALLY REUSABLE, RELOCATABLE.                          * 00149016
 TITLE   'IEHDCELL --- 2321 ANALYSIS FOR IEHDASDR UTILITY'              00150016
* REGISTER DEFINITIONS                                                  00200016
REG0     EQU   0                   REG0                                 00300016
REG1     EQU   1                                                        00400016
IOBREG   EQU   2                  ADDR-REG. OF IOB                      00500016
CONREG1  EQU   3                  CONSTANT REG 1                        00600016
CCWREG   EQU   4                   CCW ADDRESS                          00700016
DATAREG  EQU   5                  ADDR-REG. OF DATA                     00800016
BASEREG  EQU   6                                                        00900016
REG7     EQU   7                                                        01000016
LOOPREG  EQU   7                   LOOP COUNT REGISTER                  01100016
LNKREG3  EQU   LOOPREG             LINK REG. 3                          01200016
LNKREG2  EQU   8                  LINK REG. 2                           01300016
LNKREG   EQU   9                   LINK REGISTER                        01400016
FBLKREG  EQU   10                                                       01500016
WKREG1   EQU   11                 WORK REGISTER                         01600016
REG12    EQU   12                 IEHDWORK POINTER                      01700016
CONREG2  EQU   13                 CONSTANT REG2                         01800016
REG13    EQU   13                                                       01900016
REG14    EQU   14                 RETURN REGISTER                       02000016
LNKREG14 EQU REG14            LINK REGISTER FOR BLANK TRACK CONDTION    02100016
REG15    EQU   15                                                       02200016
         SPACE 2                                                        02300016
TRKSW    EQU   X'10'               HA ERROR SW. WITHIN CYLINDER         02400016
CYLSW    EQU   X'20'               HA ERROR SW. WITHIN STRIP            02500016
STRSW    EQU   X'40'               HA ERROR SW. WITHIN SUBCELL          02600016
SCSW     EQU   X'80'               HA ERROR SW. WITIN CELL              02700016
T3       EQU   3                   MAX. HAERR. PER TRACK AND STRP.      02800016
T3C      EQU   48                  MAX. HAERR. IN CYL = 3               02900016
         SPACE 2                                                        02950016
*******************************************************************     03000016
WHACMD   EQU   X'19'                                                    03100016
WR0CMD   EQU   X'15'               WRITE R0 COMMAND                     03200016
WR1CMD   EQU   X'1D'               WRITE R1 COMMAND                     03300016
RHACMD   EQU   X'1A'               READ  HA COMMAND                     03400016
RR0CMD   EQU   X'16'               READ  R0 COMMAND                     03500016
RR1CMD   EQU   X'1E'               READ  R1 COMMAND                     03600016
FSEEKCMD EQU   X'07'              FULL SEEK COMMAND                     03700016
TICCMD   EQU   X'08'              TIC COMMAND                           03800016
         SPACE 2                                                        03850016
*******************************************************************     03900016
*    IOB DEFINITIONS                                                    04000016
*********************************************************************** 04100016
IOBSNS   EQU   2                  IOB SENSE FIELD                       04200016
IOBECB   EQU   4                  ECB POINTER                           04300016
IOBCSW   EQU   8                  CSW IN IOB                            04400016
IOBSRT   EQU   16                 START CCW ADDR                        04500016
IOBSEEK  EQU   32                 IOB-SEEK ADDR                         04600016
UC       EQU   X'02'              UNIT CHECK                            04700016
DC       EQU   X'08'              DATA CHECK                            04800016
NRFMAM   EQU   X'0A'              NO-REC. FOUND0MISS. ADDR. MARKER      04900016
NRF      EQU   X'08'                   NO RECORD FOUND CONDITION.       04950016
ECBERR   EQU   X'20'              ERROR CONDITION                       05000016
BADTRK   EQU    X'80'                  DEFECTIVE HA-R0 FIELDS.          05050016
IOBDCB   EQU   20                 DCB POINTER                           05100016
DCBDEB   EQU   44            DEB POINTER                                05200016
DEBBIN   EQU   37            BIN NUMBER                                 05300016
HAFORM   EQU   16             ADDRESS OF HA FORMAT                      05400016
R1FORM   EQU   32             ADDRESS OF R1 FORMAT                      05500016
HAREADIN EQU   8                  READ IN AREA FOR HA                   05600016
MAXTRK   EQU   X'13'         LIMIT OF TRACKS                            05700016
MAXCYL   EQU   X'04'         LIMIT OF CYLINDERS                         05800016
MAXSTRP  EQU   X'09'              MAX. NO. OF STRIPS                    05900016
MAXSCL   EQU   X'13'              MAX. NO. OF SUB-CELLS                 06000016
MAXDC    EQU   113                MAX. NO OF DATA CHECKS                06100016
CMDCH    EQU   X'40'              COMMAND CHAIN FLAG                    06200016
M16      EQU   X'0F'              MULTIPLE OF 16 RETRIES                06300016
         SPACE 2                                                        06350016
**  DEFINITION OF BITS USED IN PASSCOUNT BYTES INFBLOCK                 06400016
****     BYTE 1   ***********                                           06500016
REGINT   EQU   X'80'              REGULAR TRACK INITIALISATION          06600016
ERPPRC   EQU   X'40'               ERROR PROCEDURE BIT                  06700016
         SPACE 2                                                        06750016
*  REFERANCE TO MESSAGES                                                06800016
*********************************************************************** 06900016
MES13    EQU   13                 PERMANENT I/O ERROR MESSAGE           07000016
MES31    EQU   31                 INDEX TO MESSAGES FOR DC ERROR        07100016
MES27    EQU   27                      NO ALTERNATES MESSAGE.           07120016
MESS29   EQU   29                      MESSAGE FOR DEFECTIVE HA-R0(829) 07130016
MES32    EQU   32                      ALTERNATE TRACK MESSAGE.         07140016
MES33    EQU   33                  MESS. FOR 3 BLANK TRK. OR CMP. ERR.  07160016
*********************************************************************** 07200016
         SPACE 2                                                        07250016
* THE AREAS IN FCCWS IN THE FUNCTION BLOCK ARE RESERVED AS FOLLOWS    * 07300016
*********************************************************************** 07400016
CCW1     EQU   0                  WRT. HA CCW                           07500016
CCW2     EQU   8                  WRT. R0 CCW                           07600016
CCW3     EQU   16                 WRT. R1                               07700016
CCW4     EQU   24                 RD. HA                                07800016
CCW5     EQU   32                 RD. R0                                07900016
CCW6     EQU   40                 RD. R1                                08000016
CCW7     EQU   48                 SWEEP/SEEK TO                         08100016
CCW8     EQU   56                 NOP CCW                               08200016
PARMLIST EQU   72                      PARAMETER LIST PASSED TO SVC.    08210016
UCBPTR   EQU   72                      POINTER TO UCB.                  08220016
DEFCCHH  EQU   76                      CCHH OF DEFECTIVE TRACK.         08230016
ALTPTR   EQU   80                      ALTERNATE TRACK INFORMATION PTR. 08240016
ZERO     EQU   84                      USED FOR 4-BYTE ZERO COMPARE.    08250016
ERRSEEK  EQU   94                  6 BYTES SAVEA. FOR SEEK ERR.         08300016
ERRHA    EQU   100                 4 BYTES SAVEAREA FOR HA ON HAERR     08400016
SAVESEEK EQU   104                6 BYTES SAVE AREA OF OLD SEEK         08500016
SAVEHAF  EQU   110                SAVEAREA OF 4 BYTES HA FORM.          08600016
SWEEPAD  EQU   114                6 BYTES FOR NEW SEEK ADDR.            08700016
*********************************************************************** 08800016
ALTRNATE EQU   82                      SVC CODE FOR ALTERNATE TRACKS.   08850016
         SPACE 2                                                        08900016
         USING *,BASEREG                                                09000016
         USING FUNCBLK,FBLKREG                                          09100016
         USING WORK,REG12                                               09200016
         SAVE  (14,12),T          SAVE REGISTERS                        09300016
         LR    BASEREG,REG15      ESTABLISH BASE                        09400016
         ST    REG1,8(REG13)           ADDR. OF NEW TO OLD              09440016
         ST    REG13,4(REG1)      ADDR. OF OLD TO NEW                   09480016
         ST    REG1,NEWSAVE       SAVE ADDR< OF NEW SAVE AREA           09520016
         L     REG1,TUCBPTR            UCB ADDRESS.                     09560016
         LA    REG1,0(REG1)            INSURE HIGH ORDER BYTE IS CLEAR. 09600016
         ST    REG1,FCCWS+UCBPTR       UCB ADDRESS TO PARAMETER LIST.   09640016
         LA    REG1,FALTDATA         ALTERNATE TRACK INFORMATION.       09680016
         ST    REG1,FCCWS+ALTPTR       STORE ADDRESS IN PARM LIST.      09720016
         MVI   FCCWS+ALTPTR,X'80'      SET LAST ENTRY BIT.              09760016
         L     WKREG1,PTRCFUNC    GET ADDR. OFF CURRENT FUNCTION        09800016
         TM    0(WKREG1),PROCESS  TEST IF ALREADY IN PROCESS            09900016
         BC    1,REINIT           YES- TO RECOVER SAVED REGISTERS       10000016
         OI    0(WKREG1),PROCESS  INDICATE FUNCTION IN PROCESS          10100016
         USING IHADCB,WKREG1                                            10200016
         LA    WKREG1,FBLOCKS                                           10300016
         LA    IOBREG,WKAIOB       GET IOB ADDR.                        10400016
         DROP  WKREG1                                                   10500016
         L     WKREG1,IOBDCB(IOBREG) GET DCB FROM IOB                   10600016
**************              ***********      ******                     10700016
         L     WKREG1,DCBDEB(WKREG1) GET DEB VIA DCB                    11000016
         IC    WKREG1,DEBBIN(WKREG1) GET BIN NO FROM DEB                11100016
         STC   WKREG1,IOBSEEK+2(IOBREG)  STORE BIN NO. IN IOB           11200016
         MVC   IOBSEEK+3(4,IOBREG),FALTDATA MOVE IN 1ST SEEK ADDR.      11300016
*  BUILD CCW   FOR FORMAT & READ CHECK                                  11400016
         MVC   FCCWS+CCW1(64),CCWWRD  MOVE IN CCW STRING                11500016
         L     DATAREG,FBUFFPTR   GET ADDR OF DATA-AREA                 11600016
         LA    WKREG1,15(DATAREG) ADDR OF DATA FOR HA                   11700016
         ST    WKREG1,FCCWS+CCW1  STORE ADDR OF HA IN CCW               11800016
         MVI   FCCWS+CCW1,WHACMD  SET WRT. HA CMD.                      11900016
         LA    WKREG1,1(WKREG1)   ADDR OF DATA FOR R0                   12000016
         ST    WKREG1,FCCWS+CCW2     STORE ADDR. OR R0 IN CCW           12100016
         MVI   FCCWS+CCW2,WR0CMD  SET R-R0 CMD.                         12200016
         LA    WKREG1,16(WKREG1)  ADDR OF DATA FOR R1                   12300016
         ST    WKREG1,FCCWS+CCW3  STORE DATA ADDR. IN R1 CCW            12400016
         MVI   FCCWS+CCW3,WR1CMD  SET WRT. CKD-CMD.                     12500016
         USING CONSTANT,WKREG1                                          12600016
         L     WKREG1,IODEVCON    GET ADDR. TO DEVICE CONSTANT TABLE    12700016
         LH    WKREG1,SACAP       GET MAX. DATA LENGHT                  12800016
         DROP  WKREG1              DROP WKREG1 AS BASE                  12900016
         LA    WKREG1,8(WKREG1)   INCLUDE COUNT FIELD IN LENGHT         13000016
         STH   WKREG1,FCCWS+CCW3+6  STORE LENGHT IN WRT. CCW            13100016
         STH   WKREG1,FCCWS+CCW6+6  STORE LENGHT IN READ CCW            13200016
         LA    WKREG1,FLAGREAD           GET ADDR. TO INPUT AREA        13300016
         ST    WKREG1,FCCWS+CCW4                                        13400016
         MVI   FCCWS+CCW4,RHACMD  SET COMMAND TO R-HA                   13500016
         SPACE 1                                                        13600016
         BC    15,STRTWRT         TO SET UP FOR EXCP                    13700016
START    ST    CCWREG,IOBSRT(IOBREG)  STORE ADDR IN START               13800016
         LR    REG1,IOBREG        SET UP FOR EXCP                       13900016
         SVC   0                                                        14000016
         LA    WKREG1,PTRCFUNC                                          14100016
         TM    0(WKREG1),MULTIPLE  TEST FOR MORE THAN 1 FUNCTION        14200016
         BC    1,RETURN           YES- GO BACK TO MONITOR               14300016
TWAIT    LA    REG0,1(0,0)        SET UP FOR WAIT                       14400016
         L     REG1,IOBECB(IOBREG)                                      14500016
         SVC   1                                                        14600016
         L     WKREG1,IOBECB(IOBREG)   GET ECB POINTER                  14700016
         TM    0(WKREG1),ECBERR   TEST FOR ERROR                        14800016
         BC    8,IOERR            YES-CONTINUE TEST                     14900016
         TM    PASSCNT,ERPPRC  TEST FOR ERROR PROCEDURE                 15000016
         BCR   1,LNKREG2           RETURN TO ERROR ROUTINE              15100016
         BCR   15,LNKREG           BACK TO REQUESTOR                    15200016
         SPACE 2                                                        15300016
STRTWRT  LA    CCWREG,FCCWS+CCW1   GET ADDR. OF START CCW               15400016
         BAL   LNKREG,START        TO EXCP EXIT                         15500016
         CLI   IOBSEEK+6(IOBREG),MAXTRK TEST FOR LAST TRACK             15600016
         BC    2+8,READCK1         LAST TRACK- WRITTEN-TO READ CHK      15700016
         LA    LNKREG,STRTWRT     SET RETURN ADDR.                      15800016
UPDTDATA L     CONREG1,TRKCON1    GET TRACK CONSTANT                    15900016
         L     CONREG2,TRKCON2    GET TRACK CONSTANT FOR SEEK           16000016
UPDATE   L     WKREG1,HAFORM(DATAREG)  GET ADDR. ODATA                  16100016
         AR    WKREG1,CONREG1     SET UP FOR NEXT FORMAT                16200016
         ST    WKREG1,HAFORM(DATAREG) STORE NEW FORMATINHA.             16300016
         ST    WKREG1,R1FORM(DATAREG) SORE NEW FORMAT IN R1             16400016
UPDTSEEK L     WKREG1,IOBSEEK+4(IOBREG)  GET CURRENT SEEK ADDR.         16500016
         AR    WKREG1,CONREG2     SET UP FOR NEW SEEK                   16600016
         ST    WKREG1,IOBSEEK+4(IOBREG) STORE NEW SEEK ADDR. IN IOB     16700016
         BCR   15,LNKREG           BACK TO CALLER                       16800016
*******************************************************************     16900016
*  START VERIFY TACKS WRITTEN ON LAST CYLINDER                          17000016
*******************************************************************     17100016
READCK1  MVI   IOBSEEK+6(IOBREG),X'00' START WITH TRACH 0               17200016
STARTR   MVI   FCCWS+CCW4+4,CMDCH  SET CMD. CHAIN                       17300016
         LA    CCWREG,FCCWS+CCW4   GET ADDR. OF START CCW               17400016
         LA    LNKREG14,HAERR1  SET RETURN ADDR. IN CASE OFF BLANK TRK. 17500016
         BAL   LNKREG,START        TO EXCP EXIT                         17600016
         SPACE 1                                                        17700016
         CLC   FLAGREAD+1(4),IOBSEEK+3(IOBREG)         TEST FOR OK HA   17800016
         BC    7,HAERR1            NO-TO ERROR TEST                     17900016
         CLI   IOBSEEK+6(IOBREG),MAXTRK LAST TRACK                      18000016
         BC    2+8,WRTNEXT         YES-TO WRITE NEXT CYL.               18100016
         L     CONREG2,TRKCON2    GET TRACK CONSTANT FOR SEEK           18200016
         LA    LNKREG,STARTR      SET RETURN ADDR.                      18300016
         BC    15,UPDTSEEK        TO UPDATE SEEK ADDR.                  18400016
WRTNEXT  TM    COUNT,TRKSW+CYLSW+STRSW+SCSW FIRST TEST FOR HA ERR.      18500016
         BC    7,HAERR1C           YES-CONTINUE TEST                    18600016
WRTNEXT1 CLI   IOBSEEK+5(IOBREG),MAXCYL TEST FOR LAST CYLINDER          18700016
         BC    2+8,CYLTEST        TO CYLINDER TEST                      18800016
*******************************************************************     18900016
*** SET UP TO WRITE NEXT CYLINDER***                                    19000016
*******************************************************************     19100016
UPDCYL   L     CONREG1,CYLCON1    GET CONSTANT TO UPDATE DATA           19200016
         L     CONREG2,CYLCON2    GET CONSTANT TO UPDATE SEEK           19300016
         LA    LNKREG,STRTWRT     SET RETURN ADDR.                      19400016
         BC    15,UPDATE          TO UPDATE CCWS DATA AREA              19500016
*******************************************************************     19600016
** SET UP FORCYLINDER READ CHECK TEST                                   19700016
*******************************************************************     19800016
CYLTEST  MVC   IOBSEEK+5(2,IOBREG),CLEAR   SET -HH- TO ZERO             19900016
CYLTESTA LA    CCWREG,FCCWS+CCW4  GET CCW ADDR.                         20000016
         NI    FCCWS+CCW4+4,X'FF'-CMDCH  TURN OFF COM . CHAIN           20100016
CYLTEST1 LA    LNKREG14,HAERR2  SET RETURN ADDR. IN CASE OFF BLANK TRK. 20200016
         BAL   LNKREG,START       TO SET UP FOR EXCP                    20300016
         CLC   FLAGREAD+1(4),IOBSEEK+3(IOBREG)         TEST FOR OK HA   20400016
         BC    7,HAERR2            YES- TO ERROR TEST                   20500016
CYLTEST2 CLI   IOBSEEK+5(IOBREG),MAXCYL   LAST CYLINDER                 20600016
         BC    2+8,WRTSTRP        YES-TO WRITE NEXT STRIP               20700016
**** TEST NEXT CYLINDER                                                 20800016
         IC    WKREG1,IOBSEEK+5(IOBREG) GET CURRENT CYL. NO.            20900016
         LA    WKREG1,1(WKREG1)  UPDATE CYL. NO.                        21000016
         STC   WKREG1,IOBSEEK+5(IOBREG) SET UP FOR NEXT CYL.            21100016
         BC    15,CYLTESTA        TO VERIFY                             21200016
WRTSTRP  TM    COUNT,CYLSW+STRSW+SCSW  TEST FOR PREVIOUS HA ERR.        21300016
         BC    7,HAERR2C          YES-CONTINUE TEST                     21400016
WRTSTRPA TM    PASSCNT,REGINT     PROCESSING REG. TRACKS                21500016
       BC      8,WRTSTRP1          NO-CONTINUE TEST                     21600016
         CLC   IOBSEEK+3(2,IOBREG),LASTREG  TEST FOR LAST REGULAR       21700016
         BC    2+8,STRPTEST       YES TO STRP TEST                      21800016
WRTSTRP1 CLI   IOBSEEK+4(IOBREG),MAXSTRP  TEST FOR LAST STRIP           21900016
         BC    2+8,STRPTEST       YES- TO STRIP TEST                    22000016
****SET UP TO WRITE NEXT STRIP                                          22100016
         L     CONREG1,STRPCON1   GET STIP UPDATE CONSTANT              22200016
         L     CONREG2,STRPCON2    ET STIP UPDATE CONSTANT              22300016
         LA    LNKREG,STRTWRT      SET RETURN ADDR.                     22400016
         BC    15,UPDATE           TO UPDATE DATA AND SEEK ADDR.        22500016
*** SET UP FOR STRIP TEST                                               22600016
*********************************************************************** 22700016
STRPTEST TM    PASSCNT,REGINT     PROCESSING REGULAR TRACK>             22800016
         MVC   IOBSEEK+4(3,IOBREG),CLEAR  SET -CHH- TO ZERO             22900016
         BC    1,STRTEST2         YES- BYPASS ALTERNATE SETUP           23000016
         MVI   IOBSEEK+4(IOBREG),X'06'  SET STIP TO FIRST ALTERNATE     23100016
STRTEST2 LA    CCWREG,FCCWS+CCW4  GET CCW ADDR.                         23200016
         NI    FCCWS+CCW4+4,X'FF'-CMDCH  TURN OFF COM . CHAIN           23300016
STRTEST1 LA    LNKREG14,HAERR3  SET RETURN ADDR. IN CASE OFF BLANK TRK. 23400016
         BAL   LNKREG,START       TO SET UP FOR EXCP                    23500016
         CLC   FLAGREAD+1(4),IOBSEEK+3(IOBREG)         TEST FOR OK HA   23600016
         BC    7,HAERR3                                                 23700016
         TM    PASSCNT,REGINT     PROCESSING REG. TRACKS                23800016
         BC    8,STRTEST3         NO                                    23900016
         CLC   IOBSEEK+3(2,IOBREG),LASTREG  TEST FOR LAST REGULAR       24000016
         BC    2+8,SUBCTST        YES-TO TEST SUB SELL                  24100016
STRTEST3 CLI   IOBSEEK+4(IOBREG),MAXSTRP  TEST FOR LAST STRIP           24200016
         BC    2+8,WRTSCL         YES-TO WRITE NEXT SUB-CELL            24300016
         IC    WKREG1,IOBSEEK+4(IOBREG)                                 24400016
         LA    WKREG1,1(WKREG1)                                         24500016
         STC   WKREG1,IOBSEEK+4(IOBREG)                                 24600016
         BC    15,STRTEST2                                              24700016
WRTSCL   TM    COUNT,STRSW+SCSW    FIRST TEST FOR PRE. HA ERRORS        24750016
         BC    7,HAERR3C           YES- CONTINUE TEST                   24800016
WRTSCLA  CLI   IOBSEEK+3(IOBREG),MAXSCL  LAST SUB-CELL                  24850016
         BC    2+8,SUBCTST        TO START SUB-CELL TEST                24900016
** SET UP TO WRITE NEXR SUB CELL                                        25000016
         MVC   IOBSEEK+4(3,IOBREG),CLEAR  SET C-H-H TO 0                25100016
         IC    WKREG1,IOBSEEK+3(IOBREG)  GET CURRENTSUB CELL            25200016
         LA    WKREG1,1(WKREG1)   UPDATE SUB CELL NO.                   25300016
         STC   WKREG1,IOBSEEK+3(IOBREG) UPDATE SEEK ADDR.               25400016
         STC   WKREG1,HAFORM(DATAREG)  UPDATE HA FORMAT                 25500016
         STC   WKREG1,R1FORM(DATAREG)  UDATE DATA FORMAT                25600016
         MVC   HAFORM+1(3,DATAREG),CLEAR INIT. -CHH- TO 0               25700016
         MVC   R1FORM+1(3,DATAREG),CLEAR INIT. -CHH- TO 0               25800016
         BC    15,STRTWRT      TO START WRT. NEXT SUB CELL              25900016
SUBCTST  TM    PASSCNT,REGINT     PROCESSING REGULAR TRACK>             26000016
         MVC   IOBSEEK+3(4,IOBREG),CLEAR INIT. -CCHH- TO 0              26100016
         BC    1,SUBCTST2         YES- BYPASS ALTERNATE SETUP           26200016
         MVI   IOBSEEK+3(IOBREG),X'13'  SET SCELL TO FIRST ALTERNATE    26300016
SUBCTSTA MVI   IOBSEEK+4(IOBREG),X'06' SET STRIP TO FIRST ALTERNATE     26400016
SUBCTST2 LA    CCWREG,FCCWS+CCW4     GET ADDR. OF CCW                   26500016
         NI    FCCWS+CCW4+4,X'FF'-CMDCH  TURN OFF COM . CHAIN           26600016
SUBCTST1 LA    LNKREG14,HAERR4  SET RETURN ADDR. IN CASE OFF BLANK TRK. 26700016
         BAL   LNKREG,START         TO SET UP FOR EXCP                  26800016
         CLC   FLAGREAD+1(4),IOBSEEK+3(IOBREG)         TEST FOR OK HA   26900016
         BC    7,HAERR4                                                 27000016
SUBCTST3 CLI   IOBSEEK+3(IOBREG),MAXSCL   TEST FOR LAST SUBCELL         27100016
         BC    2+8,LASTSC         YES- TO CONTINUE TEST                 27200016
         IC    WKREG1,IOBSEEK+3(IOBREG)  GET CURRENT SEEK ADDR.         27300016
         LA    WKREG1,1(WKREG1)  UPDATE SEEK ADDR. AND                  27400016
         STC   WKREG1,IOBSEEK+3(IOBREG)    STORE IN IOB                 27500016
         BC    15,SUBCTST2      TO SET UP FOR EXCP                      27600016
         SPACE 1                                                        27700016
LASTSC   TM    PASSCNT,REGINT      FINISHED WITH REG. TRACKS            27800016
         BC    1,EOJ               YES-                                 27900016
*******************************************************************     28000016
*  SET UP TO ANALIZE REGULAR TRACKS. START AT -CCHH-V 0-0-0-0           28100016
* STOP AT  CCHH = 19-5-4-19                                             28200016
*******************************************************************     28300016
         NI    PASSCNT+1,X'FF'-T3C RESET IN CASE OF PRIV. ERRORS        28330016
         NI    COUNT,X'FF'-SCSW           IN ALTERNATE AREA             28360016
         OI    PASSCNT,REGINT      INDICATE REG. TRACK                  28400016
         MVC   IOBSEEK+3(4,IOBREG),CLEAR  SET UP TO START AT 0          28500016
         MVC   HAFORM(4,DATAREG),IOBSEEK+3(IOBREG) SET UP PROPER HA     28600016
         MVC   R1FORM(4,DATAREG),IOBSEEK+3(IOBREG) SET UP R1 DATA       28700016
         BC    15,STRTWRT          TO SET UP FOR EXCP                   28800016
         SPACE 1                                                        28900016
*      RESTORE SAVED REGISTERS                                          29000016
REINIT   L     REG1,NEWSAVE       GET OWN SAVEAREA                      29060016
         LM    14,12,12(REG1)     RESTORE REGISTERS                     29120016
         BC    15,TWAIT           TO TEST I/O OPERATION                 29200016
         SPACE 2                                                        29300016
*******************************************************************     29400016
RETURN   L     REG1,NEWSAVE       GET ADDR. OF OWN SAVEAREA             29460016
         STM   14,12,12(REG1)     SAVE REGISTERS                        29520016
         BC    15,FINAL                                                 29600016
         SPACE 2                                                        29700016
*********************************************************************** 29800016
* ALL PERMANENT ERRORS POSTED BY IOS WILL BE ROUTED HERE.               29900016
*   ALL ERRORS EXCEPT DATA CHECK ERRORS WILL BE LOGGED AS PERMANENT     30000016
*   ERRORS.  DATA CHECK ERROR WILL BE RETRIED AS PER STANDARDS.         30100016
         SPACE 1                                                        30200016
IOERR    TM    IOBCSW+4(IOBREG),UC TEST FOR UNIT CHECK                  30300016
         BC    8,WRTMES13         NO- TO PERMANENT ERROR MESSAGE        30400016
         TM    IOBSNS+1(IOBREG),NRFMAM  TEST FOR BLANK TRACK            30500016
         BC    1,BLANKT            YES- TO FUTHER TEST                  30600016
*   THE FOLLOWING TEST GIVES ADDITIONAL ERROR RECOVERY SUPPORT BEYOND   30610016
*     THE MINIMUM SPECIFIED IN THE STANDARDS FOR A NO-RECORD-FOUND      30620016
*     CONDITION.                                                        30630016
         TM    IOBSNS+1(IOBREG),NRF    NO RECORD FOUND CONDITION.       30640016
         BC    1,IOERR1                YES-GO DO ERROR RECOVERY.        30650016
         TM    IOBSNS(IOBREG),DC   TEST FOR DATA CHECK                  30700016
         BC    8,WRTMES13              NO--SET UP MESSAGE.              30800016
IOERR1   IC    WKREG1,RETRYCNT         GET CURRENT NO. OF RETRIES.      30900016
         LA    WKREG1,1(WKREG1)    UPDATE COUNT                         31000016
         STC   WKREG1,RETRYCNT     STORE UPDATED COUNT                  31100016
         TM    PASSCNT,ERPPRC      IS ERROR CORRECTION IN PROCCESS      31200016
         BC    1,ERP1              YES-BYPASS SETUP                     31300016
         MVC   FCCWS+SAVEHAF(4),HAFORM(DATAREG)  SAVE OLD HA.           31400016
         MVC   FCCWS+SAVESEEK(6),IOBSEEK+1(IOBREG) SAVE SEEK ADDR.      31500016
         MVC   FCCWS+SWEEPAD(6),IOBSEEK+1(IOBREG)  SET UP SWEEP ADDR.   31600016
         OI    PASSCNT,ERPPRC      SET ERP. IN CONTROL                  31700016
ERP1     CLI   RETRYCNT,MAXDC      MAX. NO. OF RETRY                    31800016
         BH    PERMDC                  YES-PERMANENT ERROR.             31900016
         TM    RETRYCNT,X'FE'      IS THIS FIRST DATA CHECK             32000016
         BC    8,ERP2              YES-TO WRITE AND RE-READ             32100016
         TM    RETRYCNT,M16        TEST FOR MULTIPLE OF 16 RETRIES      32200016
         BC    1,ERP3             TO SET UP TO SEEK TO NEXT STRIP       32300016
***  SET UP TO SWEEP FROM  X-X-X-4-19 TO X-X-X-0-0  8 TIMES             32400016
         MVC   IOBSEEK+5(2,IOBREG),LASTSTRP  SET SEEK TO LAST STRIP     32500016
         MVC   FCCWS+SWEEPAD+4(2),CLEAR  SET SEEK TO 1ST CYL            32600016
         LA    WKREG1,FCCWS+SWEEPAD  GET ADDR. OF DATA                  32700016
         ST    WKREG1,FCCWS+CCW7   STORE ADDR. IN SEEK CCW              32800016
         MVI   FCCWS+CCW7,FSEEKCMD SET SEEK COMMAND                     32900016
         LA    CCWREG,FCCWS+CCW7   GET START CCW                        33000016
         LA    LOOPREG,8           SET UP LOOP                          33100016
ERP6     BAL   LNKREG2,START       TO SET UP FOR EXCP                   33200016
         BCT   LOOPREG,ERP6        NOT END OF SWEEP                     33300016
         SPACE 1                                                        33400016
*  SET UP TO RE WRITE AND RE READ                                       33500016
ERP7     MVC   IOBSEEK+1(6,IOBREG),FCCWS+SAVESEEK RESTORE ORIG. SEEK    33600016
ERP2     OI    FCCWS+CCW3+4,CMDCH  SET CMD. CHAIN BIT IN WRT. R1 CMD.   33700016
         MVC   HAFORM(4,DATAREG),IOBSEEK+3(IOBREG) RESTORE IN HA DATA   33800016
         MVC   R1FORM(4,DATAREG),IOBSEEK+3(IOBREG) RESTORE IN R1 DATA   33900016
         LA    CCWREG,FCCWS+CCW1   GET START CCW                        34000016
         BAL   LNKREG2,START       TO SET UP FOR EXCP                   34100016
**  RETURN HERE IF RETRY IS CORRECT                                     34200016
         B     TWOGOOD                  MUST NOW GET TWO         A41472 34230021
*                                       STRAIGHT GOOD RETRYS            34260021
ERP8     MVC   HAFORM(4,DATAREG),FCCWS+SAVEHAF  RESET TO ORIG. HA       34300016
         MVC   R1FORM(4,DATAREG),FCCWS+SAVEHAF  RESET TO ORIG. HA       34400016
*   CEAN UP BEFORE RETUN TO MAIN LINE                                   34500016
         MVI   RETRYCNT,X'00'          SET ERROR CNT TO ZERO            34600016
         NI    PASSCNT,X'FF'-ERPPRC    SET ERROR PROCEDURE TO 0         34700016
         NI    FCCWS+CCW3+4,X'FF'-CMDCH  TURN COM. CHAIN OFF            34800016
         BCR   15,LNKREG               BACK TO MAIN LINE                34900016
         SPACE 1                                                        35000016
*********************************************************************** 35100016
*  SET UP FOR PICK NEXT STRIP/ AND RETRY ORIGINAL COMMAND.              35200016
ERP3     LA    WKREG1,1           SET UP STRIP ADDR. TO 1               35300016
         CLI   IOBSEEK+4(IOBREG),X'00'  TEST FOR STRIP ZERO             35400016
         BC    8,ERP5              YES- USE STRIP ADDR. 1               35500016
         IC    WKREG1,IOBSEEK+4(IOBREG) GET CURRENT STRIP ADDR.         35600016
         SH    WKREG1,ONE          GET NEXT LOWER STRIP ADDR.           35700016
ERP5     STC   WKREG1,IOBSEEK+4(IOBREG)  STORE NEW STRIP ADDR.          35800016
         LA    CCWREG,FCCWS+CCW8   SET CCW START ADDR.                  35900016
         BAL   LNKREG2,START       TO SET UP FOR EXCP                   36000016
         BC    15,ERP7              TO SET UP FOR RE/WRITE              36100016
         SPACE 2                                                        36200016
BLANKT   TM    PASSCNT,ERPPRC      IS ERP. IN CONTROL                   36300016
         BC    8,BLANK1            NO- BYPASS HOUSEKEEPING              36400016
         LR    WKREG1,LNKREG       SAVE LINK-REG.                       36500016
         BAL   LNKREG,ERP8         TO HOUSE KEEPING                     36600016
         LR    LNKREG,WKREG1       RESTORE LINK-REG                     36700016
BLANK1   BCR   15,LNKREG14         TO TRKCK/CYLCK/STRIPCK OR SUBCELLCK  36800016
         SPACE 2                                                        36900016
HAERR1   LA    LNKREG2,HAERR1B     SET RETURN ADDR.                     37000016
HAERR1A  TM    COUNT,TRKSW+CYLSW+STRSW+SCSW       PREVIOUS HA ERR.      37100016
         BCR   7,LNKREG2           YES BYPASS SETUP                     37200016
*  SAVE INFORMATION FOR RETURN AFTER ERROR CORRECTION                   37300016
         MVC   FCCWS+ERRHA(4),HAFORM(DATAREG) SAVE HA FORMAT            37400016
         MVC   FCCWS+ERRSEEK(6),IOBSEEK+1(IOBREG) SAVE LAST SEEK ADDR.  37500016
         BCR   15,LNKREG2          RETURN                               37600016
HAERR1B  TM    COUNT,T3            TEST FOR MAX. HA ERR./TRACK          37700016
         BC    1,WRTMES33          YES-TO WRITE ERROR MESSAGE           37800016
         IC    WKREG1,COUNT        UPDATE                               37900016
         LA    WKREG1,1(WKREG1)      TRACK                              38000016
         STC   WKREG1,COUNT           HA ERROR COUNT                    38100016
         OI    COUNT,TRKSW         SET HA ERR TRACK SWITCH              38200016
         SPACE 1                                                        38300016
** SET UP TO REWRITE BAD TRACK                                          38400016
         MVC   HAFORM(4,DATAREG),IOBSEEK+3(IOBREG) SET UP PROPER HA     38500016
         MVC   R1FORM(4,DATAREG),IOBSEEK+3(IOBREG) SET UP R1 DATA       38600016
         NI    FCCWS+CCW3+4,X'FF'-CMDCH  RESET COM.CHAIN                38700016
         LA    CCWREG,FCCWS+CCW1   GET ADR. OF START CCW                38800016
         BAL   LNKREG,START        TO SET UP FOR EXCP                   38900016
** RETURN AFTER THE TRACK HAS BEEN REWRITTEN                            39000016
         BC    15,READCK1          TO RE-READ ENTIER CYL                39100016
         SPACE 1                                                        39200016
HAERR1C NI COUNT,X'FF'-TRKSW-T3 RESET TRACK SW AND COUNT TO 0           39300016
         MVC   HAFORM(4,DATAREG),IOBSEEK+3(IOBREG) SET UP PROPER HA     39400016
         MVC   R1FORM(4,DATAREG),IOBSEEK+3(IOBREG) SET UP R1 DATA       39500016
         CLI   COUNT,CYLSW         TEST FOR CYL. ERR. ONLY              39600016
         BC    7,WRTNEXT1          NO- CONTINUE WRITING                 39700016
         NI    IOBSEEK+6(IOBREG),X'00'  SET TRACK ADDR. TO 0            39800016
         BC    15,CYLTESTA         CONTINUE STRIP TEST                  39900016
         SPACE 1                                                        40000016
HAERR2   BAL   LNKREG2,HAERR1A     TO COMMEN TEST                       40100016
         OI    COUNT,CYLSW         SET HAERR< SWITCH                    40200016
*******************************************************************     40300016
*  SET UP TO REWRITE AND RE-READ THE CYLINDER                           40400016
*******************************************************************     40500016
         MVC   HAFORM(4,DATAREG),IOBSEEK+3(IOBREG) SET UP PROPER HA     40600016
         MVC   R1FORM(4,DATAREG),IOBSEEK+3(IOBREG) SET UP R1 DATA       40700016
         TM    COUNT+1,T3C         TEST FOR 3 HA/ERRORS                 40800016
         BC    1,WRTMES33          YES-TO WRITE ERROR MESSAGE           40900016
         IC    WKREG1,COUNT+1      UPDATE                               41000016
         LA    WKREG1,16(WKREG1)     HA ERROR                           41100016
         STC   WKREG1,COUNT+1             COUNT.                        41200016
         BC    15,STRTWRT          TO SET UP FOR EXCP                   41300016
         SPACE 1                                                        41400016
HAERR2C  NI    COUNT,X'FF'-CYLSW  TURN OFF CYLINDER SWITCH              41500016
         NI    COUNT+1,X'FF'-T3C  ZERO CYLINDER COUNT                   41600016
         MVC   HAFORM(4,DATAREG),IOBSEEK+3(IOBREG) SET UP HA-FORMAT     41700016
         MVC   R1FORM(4,DATAREG),IOBSEEK+3(IOBREG) SET UP R1-FORMAT     41800016
         MVI   HAFORM+3(DATAREG),MAXTRK  SET UP TO LAST TRACK           41900016
         MVI   R1FORM+3(DATAREG),MAXTRK  SET UP TO LAST TRACK           42000016
         CLI   COUNT,STRSW        TEST FOR STRIP SWITCH ALONE           42100016
         BC    7,WRTSTRPA         NO- CONTINUE NORMAL                   42200016
         MVC   IOBSEEK+5(2,IOBREG),CLEAR TO CONTINUE                    42300016
         BC    15,STRTEST2                        STRIP TEST            42400016
HAERR3   BAL   LNKREG2,HAERR1A     TO COMMON TEST                       42500016
         OI    COUNT,STRSW         SET STRIP SWITCH                     42600016
         TM    COUNT+1,T3          TEST FOR 3 HAERR. IN STRIP           42700016
         BC    1,WRTMES33          YES-TO WRITE ERROR MESSAGE           42800016
         IC    WKREG1,COUNT+1      UPDATE                               42900016
         LA    WKREG1,1(WKREG1)      AND                                43000016
         STC   WKREG1,COUNT+1        STORE NEW COUNT                    43100016
*******************************************************************     43200016
**  SET UP TO RE-WRITE AND RE-READ STRIP                                43300016
*******************************************************************     43400016
         MVI   IOBSEEK+5(IOBREG),X'00'  START WITH CYL. 0               43500016
         MVC   HAFORM(4,DATAREG),IOBSEEK+3(IOBREG) SET UP PROPER HA     43600016
         MVC   R1FORM(4,DATAREG),IOBSEEK+3(IOBREG) SET UP R1 DATA       43700016
         BC    15,STRTWRT          TO SET UP FOR EXCP                   43800016
         SPACE 2                                                        43807016
HAERR3C  NI    COUNT,X'FF'-STRSW   SET STRIP SWITCH OFF                 43814016
         NI    COUNT+1,X'FF'-T3    ZERO STRIP ERR. CNT.                 43821016
         MVC   HAFORM(4,DATAREG),IOBSEEK+3(IOBREG) SET UP FORMAT        43828016
         MVC   R1FORM(4,DATAREG),IOBSEEK+3(IOBREG)    TO CONTINUE       43835016
         MVC   HAFORM+2(2,DATAREG),LASTSTRP   SET H-H TO 4-13           43842016
         MVC   R1FORM+2(2,DATAREG),LASTSTRP   SET H-H TO 4-13           43849016
         CLI   COUNT,SCSW          TEST IF IN SB-CELL TEST              43856016
         BC    7,WRTSCLA           NO- CONTINUE NORMAL                  43863016
         MVC   IOBSEEK+4(3,IOBREG),CLEAR  SET C-H-H TO ZERO             43870016
         TM    PASSCNT,REGINT      PROCESSING REGULAR TRACKS            43877016
         BC    1,SUBCTST2          YES                                  43884016
         SPACE 1                                                        43900016
HAERR4   BAL   LNKREG2,HAERR1A     TO COMMON TEST                       44000016
         OI    COUNT,SCSW          SET SUB-CELL SWITCH                  44100016
         TM    PASSCNT+1,T3C       TEST FOR MAX. HA-ERR.                44200016
         BC    1,WRTMES33          YES-TO WRITE ERROR MESSAGE           44300016
         IC    WKREG1,PASSCNT+1    UPDATE                               44400016
         LA    WKREG1,16(WKREG1)         AND                            44500016
         STC   WKREG1,PASSCNT+1         SORE NEW COUNT                  44600016
*******************************************************************     44700016
** SET UP TO RE-WRITE AND RE-READ  SUB CELL                             44800016
         TM    PASSCNT,REGINT      IS REG. TRACK BEING INIT.            44900016
         MVI   IOBSEEK+4(IOBREG),X'00'     SET TO FIRST STRIP           45000016
         BC    1,HAERR4A           YES- BYPASS ALTENATE SETUP           45100016
         MVI   IOBSEEK+4(IOBREG),X'06' SET UP TO START WITH STRP 6      45200016
HAERR4A  MVC   HAFORM(4,DATAREG),IOBSEEK+3(IOBREG) SET UP PROPER HA     45300016
         MVC   R1FORM(4,DATAREG),IOBSEEK+3(IOBREG) SET UP R1 DATA       45400016
         BC    15,STRTWRT          TO SET UP FOR EXCP                   45500016
         SPACE 2                                                        45503016
*  SET UP MESSAGE FOR 3 BLANK TRACKS OR 3 COMPARE ERRORS                45506016
WRTMES33 LA    REG1,MES33          GET INDEX TO MESSAGE                 45509016
         L     REG13,NEWSAVE       GET ADDR. OF OWN SAVE AREA           45512016
         BAL   LNKREG2,LINKTO      TO BUILD MESSAGE ROUTINE             45515016
         SPACE 1                                                        45518016
* TO CALCULATE WHICH TEST THE ERROR WAS DETECTED IN.                    45521016
         TM    COUNT,TRKSW         ERROR IN TRACK CHECK                 45524016
         LA    WKREG1,0            SET UP INDEX IN ANY CASE             45527016
         BC    1,WRTM33A           YES-TO MOVE MESSAGE TO BUFFER        45530016
         TM    COUNT,CYLSW         TEST IF ERROR IN CYLINDER TEST       45533016
         LA    WKREG1,8            SET UP INDEX IN ANY CASE             45536016
         BC    1,WRTM33A           YES-TO MOVE MESSAGE TO BUFFER        45539016
         TM    COUNT,STRSW         TEST IF ERROR IN STRIP TEST          45542016
         LA    WKREG1,16           SET UP INDEX IN ANY CASE             45545016
         BC    1,WRTM33A           YES-TO MOVE MESSAGE TO BUFFER        45548016
         LA    WKREG1,24           SET INDEX TO SUBCELL MESSAGE.        45551016
WRTM33A  LA    REG0,MESS33X                                             45554016
         AR    WKREG1,REG0                                              45557016
         MVC   0(8,REG1),0(WKREG1)                                      45560016
         SPACE 1                                                        45563016
         UNPK  21(9,REG1),IOBSEEK+3(5,IOBREG)   GET CCHH.               45566016
         TR    21(8,REG1),TRTAB-240    TRANSLATE CCHH.                  45569016
         MVI   29(REG1),C','           SET ZONE TO COMMA.               45572016
         MVC   30(8,REG1),DDNAME2      MOVE DDNAME TO MESSAGE.          45575016
         LA    LNKREG3,FINALERR    SET RETURN ADDR.                     45581016
         BC    15,LINK2            TO WRITE MESSAGE.                    45584016
         SPACE 2                                                        45587016
         SPACE 1                                                        45600016
WRTMES13 LA    REG1,MES13         GET INDEX TO I/O ERROR MESSAGE        45700016
         L     REG13,NEWSAVE           SAVE AREA ADDRESS.               45760016
         BAL   LNKREG2,LINKTO          GO BUOLD MESSAGE.                45820016
         B     SYNAD                   GO ISSUE SYNADAF                 45880016
         SPACE                                                          45940016
LINK1    BAL   LNKREG2,LINKTO    TO GET MESSAGE BUILDER                 46000016
         MVC   0(8,REG1),DDNAME2  MOVE DD-NAME TO MESS. BUFFER          46100016
         UNPK  13(9,REG1),IOBSEEK+3(5,IOBREG)   GET CCHH.               46200016
         TR    13(8,REG1),TRTAB-240    TRANSLATE CCHH.                  46300016
         MVI   21(REG1),C' '           SET ZONE TO BLANK.               46400016
         BCR   15,LNKREG3         RETURN TO REQUESTOR                   46500016
         SPACE 1                                                        46600016
SYNAD    SYNADAF  ACSMETH=EXCP,PARM1=(2)                                46700016
         MVC   MESS+19(78),49(REG1)    MOVE SYNAD INFO TO MSG. BUFFER.  46800016
         SYNADRLS                                                       46900016
         SPACE 1                                                        47000016
         LA    LNKREG3,FINALERR   SET RETURN CODE TO 8                  47100016
LINK2    LINK  EP=IEHDPRNT        TO PRINT ROUTINE                      47200016
         SPACE 1                                                        47300016
         BCR   15,LNKREG3         RETURN TO REQUESTOR                   47400016
*   FINAL RETURN TO THE MONITOR.                                        47500016
FINALERR LA    REG15,8             SET ERROR RETURN CODE                47550016
         BC    15,FINAL1           TO RETURN                            47600016
FINAL    LA    REG15,0             SET RETURN CODE TO 0                 47650016
FINAL1   L     REG13,NEWSAVE       GET ADDR. OF OWN SAVE AREA           47700016
         L     REG13,4(REG13)      GET OLD SAVE AREA                    47750016
         RETURN (14,12),T,RC=(15)                                       47800016
         SPACE 1                                                        47900016
LINKTO   LINK  EP=IEHDMSGB        TO BUILD MESSAGE                      48000016
         BCR   15,LNKREG2         RETURN TO CALLER                      48100016
         SPACE 2                                                        48200016
*  TO SET UP MESSAGE ON PERMANENT D/C AFTER ERP. CORRECTION FAILS.      48300016
PERMDC   LA    REG1,MES31        INDEX TO DC ERROR MESSAGE              48400016
         L     REG13,NEWSAVE           SAVE AREA AADRESS.               48500016
         BAL   LNKREG3,LINK1      TO BUILD ERROR MESSAGE                48600016
         BAL   LNKREG3,LINK2       TO PRINT ERROR MESSAGE               48700016
          LA   REG1,FBLOCKS            I/O BLOCKS ADDRESSING(DCB).      48707016
         USING IHADCB,REG1                                              48714016
          TM    DCBIOBAD,BADTRK        DEFECTIVE HA-R0 FIELDS.          48721016
          BZ    PERMDC1                NO--                             48728016
          DROP 1                                                        48735016
         SPACE                                                          48742016
         LA     REG1,MESS29            MESSAGE NUMBER.                  48749016
         L      REG13,NEWSAVE          SAVE AREA.                       48756016
          BAL   LNKREG3,LINKTO         BUILD THE ERROR MESSAGE.         48763016
          MVC   0(8,REG1),DDNAME2      DDNAME TO MESSAGE.               48770016
          BAL   LNKREG3,LINK2          WRITE OUT THE ERROR MESSAGE.     48777016
PERMDC1   EQU   *                                                       48784016
         SPACE 1                                                        48800016
*  HOUSE KEEP AND SET UP TO ASSIGN ALTERNATE TRACK                      48900016
         MVI   RETRYCNT,X'00'          SET ERROR CNT TO ZERO            49000016
         NI    PASSCNT,X'FF'-ERPPRC    SET ERROR PROCEDURE TO 0         49100016
         NI    FCCWS+CCW3+4,X'FF'-CMDCH  TURN COM. CHAIN OFF            49200016
         MVC   HAFORM(4,DATAREG),FCCWS+SAVEHAF  RESET TO ORIG. HA       49300016
         MVC   R1FORM(4,DATAREG),FCCWS+SAVEHAF  RESET TO ORIG. HA       49400016
*  SVC ALTERNATE TO COME IN HERE                                        49500016
         MVC   FCCWS+DEFCCHH(4),IOBSEEK+3(IOBREG)  DEFECTIVE TRACK.     49507016
         LA    REG1,FCCWS+PARMLIST     PARAMETER LIST ADDRESS.          49514016
         SVC   ALTRNATE                GO ASSIGN AN ALTERNATE TRACK.    49521016
         B     *+4(REG15)              TO BRANCH TABLE.                 49528016
         B     GOOD                    ALTERNATE ASSIGNED.              49535016
         B     *                       SHOULD NOT OCCUR///HANG.         49542016
         B     *                       SHOULD NOT OCCUR///HANG.         49549016
         B     IOERROR                 I/O ERROR DURING SVC.            49556016
         B     NOALT                   ALTERNATES DEPLETED.             49563016
GOOD     EQU   *                                                        49570016
         LA    REG1,MES32              ALTERNATE TRACK MESSAGE.         49577016
         BAL   LNKREG2,LINKTO          BUILD THE MESSAGE.               49584016
        MVC    0(8,REG1),DDNAME2       DDNAME TO MESSAGE.               49591016
         CLC   FCCWS+DEFCCHH(4),FCCWS+ZERO WAS THERE AN ALT. ASSIGNED.  49598016
         BE    GOOD1                   NO--WRITE OUT THE MESSAGE.       49605016
         UNPK  13(9,REG1),FCCWS+DEFCCHH(5)  CCHH OF ALTERNATE.          49612016
         TR    13(8,REG1),TRTAB-240    TRANSLATE CCHH.                  49619016
         MVI   21(REG1),C' '           SET ZONE TO BLANK.               49626016
GOOD1    BAL   LNKREG3,LINK2           WRITE OUT THE MESSAGE.           49633016
         BC    15,10(LNKREG)           RETURN TO CONTINUE TEST.         49640016
         SPACE 3                                                        49647016
NOALT    EQU   *                       NO MORE ALTERNATE TRACKS.        49654016
         LA    REG1,MES27              MESSAGE NUMBER.                  49661016
         L     REG13,NEWSAVE           SAVE AREA ADDRESS.               49668016
         BAL   LNKREG2,LINKTO          TO MESSAGE BUILDER.              49675016
         MVC   0(8,REG1),DDNAME2       DDNAME TO MESSAGE.               49682016
NOALT1   BAL   LNKREG3,LINK2           PRINT ERROR MESSAGE.             49689016
         B     FINALERR                RETURN TO REQUESTOR.             49696016
         SPACE 2                                                        49703016
IOERROR  EQU   *                       ERROR DURING SVC.                49710016
         LA    REG1,MES13              MESSAGE NUMBER.                  49717016
         L     REG13,NEWSAVE           SAVE AREA ADDRESS.               49724016
         BAL   LNKREG2,LINKTO          BUILD THE MESSAGE.               49731016
         MVC   0(2,REG1),SVC82         IDENTIFY THE SVC IN ERROR.       49738016
         MVI   2(REG1),C','            COMMA SEPARATOR.                 49745016
         MVC    3(8,REG1),DDNAME2       DDNAME TO MESSAGE.              49752016
         B     NOALT1                  WRITE OUT MESSAGE//RETURN.       49759016
         SPACE 1                                                        49800016
EOJ      L     WKREG1,PTRCFUNC     GET ADDR. OF CONTROL FIELD           49870016
         MVI   0(WKREG1),COMPLETE      SET COMPLETE BIT ON              49940016
         BC    15,FINAL           TO RETURN                             50010016
         EJECT                                                          50050016
         SPACE 2                                                        50100016
*                                                                       50106021
*******************                                                     50112021
*        THIS ROUTIN RETRYS A DC FAILURE TWO MORE TIMES                 50118021
*        AFTER THE INITIAL GOOD RETRY. IF BOTH COMPLETE GOOD            50124021
*        THE TRACK IS CONSIDERED GOOD. IF EITHER RETRY FAILS            50130021
*        THE TRACK IS FLAGGED BAD.                                      50136021
*******************                                                     50142021
*                                                                       50148021
TWOGOOD  EQU   *                                                 A41472 50154021
         MVI   GOODTRY+3,2              SET RETRY COUNT          A41472 50160021
ENTRY2   EQU   *                                                 A41472 50166021
         LR    REG1,IOBREG              PREPARE FOR I/O          A41472 50172021
         SVC   0                        ISSUE EXCP               A41472 50178021
         LA    REG0,1                   SET UP FOR WAIT          A41472 50184021
         L     REG1,IOBECB(IOBREG)      GET ECB ADDRESS          A41472 50190021
         SVC   1                        ISSUE WAIT               A41472 50196021
         L     WKREG1,IOBECB(IOBREG)    ECB ADDRESS              A41472 50202021
         CLI   0(WKREG1),X'7F'          GOOD COMPLETION          A41472 50208021
         BNE   NOGO                     NO - FLAG TRACK BAD      A41472 50214021
         L     REG1,GOODTRY             TRY NUMBER               A41472 50220021
         BCT   REG1,RESET               FALL TRU IF LAST TRY     A41472 50226021
         B     ERP8                     RESET AND CONTINUE       A41472 50232021
RESET    ST    REG1,GOODTRY             STORE RTRY CNT           A41472 50238021
         B     ENTRY2                   CONTINUE RETRYING        A41472 50244021
NOGO     MVI   RETRYCNT,MAXDC+1         SET AS BAD TRACK         A41472 50250021
         B     ERP1                     GO FLAG AS BAD           A41472 50256021
GOODTRY  DC    F'0'                     RETRY COUNT STORAGE      A41472 50262021
         EJECT                                                          50268021
*        CCWS                                                           50274021
CCWWRD   CCW   X'00',CCWWRD-CCWWRD,X'60',5  WRT. HA CMD                 50300016
         CCW   X'00',CCWWRD-CCWWRD,X'60',16  WRT. R0                    50400016
         CCW   X'00',CCWWRD-CCWWRD,X'20',0  WRT. R1 CCW                 50500016
         CCW   X'00',CCWWRD-CCWWRD,X'40',5   READ HA                    50600016
         CCW   X'16',CCWWRD-CCWWRD,X'70',16  READ R0 WITH SKIP          50700016
         CCW   X'1E',CCWWRD-CCWWRD,X'30',0  READ R1 WITH SKIP           50800016
         CCW   X'07',0,X'60',6       SWEEP CCW                          50900016
         CCW   X'03',0,X'20',1       NOP CCW                            51000016
NEWSAVE  DC    A(0)               ADDR. TO NEW SAVE AREA                51100016
TRKCON1  DC    A(1)                                                     51200016
TRKCON2  DC    A(256)                                                   51300016
CYLCON1  DC    X'000000ED'                                              51400016
CYLCON2  DC    X'0000ED00'                                              51500016
STRPCON1 DC    X'0000FBED'                                              51600016
STRPCON2 DC    X'00FC0000'         SEEK STRIP CONSTANT                  51700016
CLEAR    DC    X'00000000'                                              51800016
SCLCON1  DC    X'00F6FBED'                                              51900016
SCLCON2  DC    X'F6FBED00'                                              52000016
ONE      DC    AL2(1)             CONSTANT 1                            52100016
LASTSTRP DC    X'0413'             SWEEP SEEK                           52200016
LASTREG  DC    X'1305'            LAST REGULAR TRACK ADDR.              52300016
TRTAB    DC    C'0123456789ABCDEF'     TRANSLATE TABLE                  52400016
MESS33X  DC    C'  HEAD  '         MESSAGES                             52410016
         DC    C'CYLINDER'           FOR BLANK                          52420016
         DC    C' STRIP  '           TRACKS OR                          52430016
         DC    C'SUB-CELL'             COMPARE ERRORS.                  52440016
SVC82    DC    C'82'                   SVC IDENTIFIER.                  52450016
         EJECT                                                          52700016
         IEHDBLKS                                                       52800016
         EJECT                                                          52900016
         IEHDWORK                                                       53000016
         EJECT                                                          53100016
         DCBD  DSORG=PS                                                 53200016
DCBCON   EQU   IHADCB                                                   53300016
         ORG   IHADCB+72                                                53400016
WKAECB   DS    F                  ECB                                   53500016
WKAIOB   DS    F                  IOB                                   53600016
ECBADD   DS    F                  ECB POINTER.                          53700016
         DS    F                                                        53800016
CSWORD   DS    F                  CHANNEL STATUS WORD                   53900016
CCWPTR   DS    F                  CHANNEL PROGRAM POINTER.              54000016
DCBADD   DS    F                  DCB POINTER.                          54100016
         DS    F                                                        54200016
BLKERRCT DS    F                  BLOCK AND ERR RETRY COUNT.            54300016
SEEKADDR DS    2F                 SEEK ADDRESS.                         54400016
         END                                                            54500016
