         COPY  LCGASMSW                                                 00050021
IEHDDOIO CSECT                                                          00100021
*                                                                     * 00150021
*                        PTM XM0208 IS FIXED UNDER OS APAR NO. SA53223  00160002
*                                                XM4417=YA03005=SA67332 00170003
*  PTM XM5476 DELETES CHANGES FOR SA67332                        XM5476 00180003
*STATUS CHANGE LEVEL 000                                                00200021
*                                                                     * 00250021
*FUNCTION/OPERATION- THIS ROUTINE HANDLES MOST OF THE I/O FOR THE     * 00300000
*   DUMP FUNCTION OF THE IEHDASDR UTILITY PROGRAM. ALL I/O INVOLVED   * 00350021
*   WITH DA AND/OR TAPE DEVICES IS AT THE EXCP LEVEL. THE FIRST       * 00400021
*   I/O OPERATION ON THE DIRECT ACCESS DEVICE RESULTS IN THE END OF   * 00450021
*   EXTENT APPENDAGE(IGG019P8) BEING ENTERED FROM IOS. THIS ROUTINE   * 00500021
*   WILL MODIFY THE DEB EXTENTS AND SET THE CORRECT FILE MASK.        * 00550021
*   PROCESSING WILL BE DONE ONE TRACK AT A TIME UNTIL EITHER THE      * 00600021
*   DUMP LIMITS OR THE VOLUME LIMITS ARE EXHAUSTED. CONTROL WILL BE   * 00650021
*   RETURNED TO -IEHDEXCP- AT THIS TIME.                              * 00700021
*                                                                     * 00750021
*ENTRY POINTS- THE ONLY ENTRY POINT IS -IEHDDOIO-, AND CONTROL IS     * 00800021
*   ALWAYS RECEIVED FROM THE -IEHDEXCP- ROUTINE.                      * 00850021
*                                                                     * 00900021
*INPUT- POINTERS TO A WORKAREA(REGISTER 12) AND TO A CONTROL BLOCK    * 00950021
*   (REGISTER 10).                                                    * 01000021
*                                                                     * 01050021
*OUTPUT TO DIRECT ACCESS- A COPY OF THE -FROM- DIRECT ACCESS          * 01100021
*   DEVICE WITH PREVIOUSLY UNOWNED TRACKS CLEANED UP.                 * 01150021
*                                                                     * 01200021
*OUTPUT TO TAPE-                                                      * 01250021
*   LIMITS RECORD- ALWAYS THE FIRST RECORD AFTER A TAPE MARK ON       * 01300021
*   EACH VOLUME OF TAPE. THIS RECORD IS 24 BYTES IN LENGTH AND        * 01350021
*   CONTAINS THE FOLLOWING INFORMATION.                               * 01400021
*                                                                     * 01450021
*        BYTES 0-3    CCHH OF THE FIRST TRACK DUMPED.                 * 01500021
*        BYTES 4-7    CCHH+1 OF THE LAST TRACK DUMPED.                * 01550021
*        BYTES 8-11   CCHH OF THE FIRST TRACK THIS VOLUME.            * 01600021
*        BYTES 12-19  CODE THAT IDENTIFIES THIS AS BEING A            * 01650021
*                     RESTORE TAPE.                                   * 01700021
*        BYTE  20     FULL DUMP SWITCH -X'F0'=FULL,X'00'=PARTIAL.     * 01750021
*        BYTE  21     DEVICE TYPE CODE AS FOLLOWS.                    * 01800021
*                        CODE 0    2321                               * 01850021
*                             1    2311                               * 01900021
*                             2    2314                               * 01950021
*                             3    2302                               * 02000021
*                             4    2303                               * 02050021
*                             5    2301                               * 02100021
*        BYTES 22-23  UNUSED.                                         * 02150021
*                                                                     * 02200021
*   CONTROL RECORD- THIS RECORD IS WRITTEN FOR EACH TRACK DUMPED      * 02250021
*   AND IMMEDIATELY PRECEDES THE DATA RECORD FOR EACH TRACK. IT       * 02300021
*   CONTAINS A CHANNEL PROGRAM USED BY RESTORE TO WRITE ONE TRACK.    * 02350021
*   THE LENGTH OF THIS RECORD DEPENDS ON THE NUMBER OF RECORDS ON     * 02400021
*   THE DUMPED TRACK.                                                 * 02450021
*                                                                     * 02500021
*   TRACK IMAGE RECORD- THIS RECORD CONTAINS THE DATA DUMPED FROM     * 02550021
*   A TRACK AND ALWAYS FOLLOWS A CONTROL RECORD.  IT IS WRITTEN AS    * 02600021
*   ONE MAXIMUM LENGTH PHYSICAL RECORD ON TAPE. IT CONTAINS THE       * 02650021
*   DATA FIELD OF RECORD ZERO AND ALL FIELDS OF OTHER RECORDS THAT    * 02700021
*   WERE ON THE TRACK THAT WAS DUMPED.                                * 02750021
*                                                                     * 02800021
*   TRAILER RECORD- THIS ALWAYS FOLLOWS THE TAPE MARK THAT WAS AT     * 02850021
*   THE END OF THE LAST TRACK IMAGE RECORD. IT IS 24 BYTES IN         * 02900021
*   LENGTH, OF WHICH ONLY THE FIRST 4 BYTES ARE USED. IT INDICATES    * 02950021
*   WHETHER THE RESTORE IS COMPLETE WHEN THE END OF THIS VOLUME       * 03000021
*   IS REACHED.                                                       * 03050021
*                                                                     * 03100021
*EXITS-NORMAL- SUCCESSFUL COMPLETION OF ALL I/O OPERATIONS RESULTS    * 03150021
*   IN A RETURN TO -IEHDEXCP- WITH A RETURN CODE OF ZERO.             * 03200021
*                                                                     * 03250021
*EXITS-ERROR-  ANY ERROR ENCOUNTERED WILL BE DESCRIBED BY AN          * 03300021
*   APPROPRIATE MESSAGE TO THE MESSAGE DATA SET. A RETURN CODE        * 03350021
*   GREATER THAN ZERO WILL ALSO BE PASSED TO -IEHDEXCP-.              * 03400021
*   ERROR MESSAGES WILL BE PRINTED BY IEHDEXCP VIA THE BRANCH   SA53223 03450000
*   TABLE EXIT LABELED 'MSGWRT'.                                SA53223 03460000
*                                                                     * 03470000
*EXTERNAL ROUTINES- THIS ROUTINE IS ALWAYS ENTERED FROM -IEHDEXCP-.   * 03500021
*   FIVE OTHER CSECTS ARE USED BY THE ROUTINE. ANY MESSAGES WILL      * 03550021
*   BE WRITTEN OUT BY THE MESSAGE WRITER ROUTINE(IEHDPRNT) AFTER      * 03600021
*   BEING SET UP BY THE MESSAGE ROUTINE(IEHDMSGB). THE END OF         * 03650021
*   EXTENT APPENDAGE(IGG019P8) HANDLES THE LIMITS AND EXTENTS IN      * 03700021
*   THE DEB FOR ALL DA DEVICES INVOLVED. ALL DEVICE DEPENDENT         * 03750021
*   CONSTANTS WILL BE CONTAINED IN THE -IEHDCONS- CSECT. IEHDEXCP     * 03800021
*   WILL LOAD BOTH -IEHDAOUT- AND -IEHDPRNT- WHEN DUMPING TO A        * 03850021
*  SYSTEM OUTPUT DEVICE.  IEHDRCVR WILL BE LINKED TO WHEN AN I/O   O122 03900021
*  ERROR (MISSING ADDRESS MARKER OR DATA CHECK) ARE ENCOUNTERED    O122 03950021
*  WHEN DUMPING TO SYSOUT.                                         O122 04000021
*  THIS ROUTINE WILL CLOSELY INTERFACE WITH IEHDEXCP VIA A      SA53223 04010000
*  BRANCH TABLE.                                                SA53223 04020000
*  BRANCHING FROM ONE MODULE TO ANOTHER WILL BE FACILITATED VIA SA53223 04030000
*  A BRANCHING VALUE IN A PREVIOUSLY UNUSED BYTE, BRCHVAL, IN   SA53223 04042000
*  THE FUNCTION BLOCK, IEHDBLKS.                                SA53223 04046000
*                                                                     * 04050021
*ATTRIBUTES- SERIALLY REUSABLE, RELOCATABLE, NON-PRIVILEGED.          * 04100021
*                                                                     * 04150021
 TITLE 'IEHDDOIO-3RD CSECT OF IEHDDUMP-IEHDASDR SYSTEM UTILITY PROGRAM' 04200021
*   THE FOLLOWING ARE REGISTER ASSIGNMENTS.                             04250021
GR0      EQU   0                                                        04300021
GR1      EQU   1                                                        04350021
GR2      EQU   2                                                        04400021
GR3      EQU   3                                                        04450021
GR4      EQU   4                                                        04500021
GR5      EQU   5                                                        04550021
GR6      EQU   6                                                        04600021
GR7      EQU   7                                                        04650021
GR8      EQU   8                                                        04700021
GR9      EQU   9                                                        04750021
GR10     EQU   10                                                       04800021
GR11     EQU   11                                                       04850021
GR12     EQU   12                                                       04900021
GR13     EQU   13                                                       04950021
GR14     EQU   14                                                       05000021
GR15     EQU   15                                                       05050021
RCVT     EQU   9                                                        05100021
UCBPTR   EQU   9                                                        05150021
BASEREG  EQU   11                                                       05200021
WORKBASE EQU   12                                                       05250021
         SPACE 2                                                        05300021
*    MISCELLANEOUS EQUATES                                              05310003
BIT7     EQU   1                                                        05320003
         SPACE 2                                                        05330003
         USING FUNCBLK,10                                               05350021
         USING IEHDDOIO,BASEREG                                         05400021
         USING WORK,12                                                  05450021
         SAVE  (14,12),T,*             SAVE THE REGISTERS.              05500021
         LR    BASEREG,GR15            LOAD THE BASE REGISTER.          05550021
         LA    GR7,EXCPSAVE            SAVE AREA ADDRESS.               05600021
         ST    GR7,8(GR13)             ADDRESS OF NEW AREA TO OLD.      05650021
         ST    GR13,4(GR7)             ADDRESS OF OLD AREA TO NEW.      05700021
         LR    GR13,GR7                SAVE AREA FOR CALLED ROUTINES.   05750021
         USING IOBLOCKS,9                                               05800021
         LA    GR9,BLOCKS              ADDRESS PRIMARY I/O BLOCKS.      05850021
         L     GR14,FRTNPTR            LOAD RETURN ADDRESS.             05890021
         LTR   GR14,GR14                WILL BE ZERO 1ST TIME   SA53223 05890421
         BZ    START                    BRCH IF ZERO            SA53223 05890821
         XC    FRTNPTR,FRTNPTR                                          05891201
         BR    GR14                    TAKE UP WHERE WE LEFT OFF.       05892021
START    EQU   *                                                SA53223 05894021
         SR    GR3,GR3                  ZERO WORK REG           SA53223 05900021
         IC    GR3,BRCHVAL              GET BRANCH TABLE VALUE  SA53223 05950021
         XC    BRCHVAL,BRCHVAL                                          05960001
         LA    GR2,BRCHTABL             LOAD BRCH TABLE ADDR    SA53223 06000021
         AR    GR2,GR3                  COMPUTE TABLE ENTRY     SA53223 06050021
         BR    GR2                      BRCH TO ENTRY           SA53223 06100021
BRCHTABL EQU   *                                                SA53223 06150021
         B     RDCNTS                   GO READ COUNT FLDS      SA53223 06200021
         B     WRTHAR0                  GO BUILD/EXECUTE        SA53223 06210021
*                                       WRITE HA, WRITE R0.     SA53223 06230021
RDCNTS   TM    SEQSW,RPSFEAT1           RPS ON FROM DEV          A42498 06250021
         BZ    RDCNTS1                  NO - CONTINUE            A42498 06300021
         L     GR2,RPSBUFPT             SET PROPPER ADDRESS IN   A42498 06350021
*                                       TIC                      A42498 06400021
         MVC   9(3,GR2),CCWBUFPT+1                               A42498 06450021
RDCNTS1  EXCP  OUTIOB                                            A42498 06500021
         CLI   DEVSW,X'F0'             DUMPING TO SYSOUT.               06550021
         BE    WAITOUT                 YES--DO NOT RETURN TO MONITOR.   06600021
*  LINK BACK TO MONITOR HERE.                                           06650021
         TM    SW1,MULTIPLE            ANY REASON TO GO BACK TO MONITOR 06700021
         BZ    WAITOUT                 NO--GO WAIT.                     06750021
         LA    GR3,WAITOUT             RETURN ADDRESS.                  06800021
         ST    GR3,FRTNPTR             SAVE IN RETURN POINTER.          06850021
         LA    GR15,0                  RETURN CODE FOR MONITOR.         06900021
         B     MULTPROC                RETURN.                  SA53223 06950021
WAITOUT  TM    OUTECB,COMPLETE         IS THE OPERATION COMPLETE.       07000021
         BO    WAITOUTA                YES--GO TEST THE STATUS.         07050021
         WAIT  ECB=OUTECB              NO---AWAIT COMPLETION OF I/O.    07100021
WAITOUTA EQU   *                                                   7343 07150021
         LA    GR2,RDCNTS              RETURN ADDRESS IF RECOVER   O122 07200021
         TM    OUTSTAT+4,X'02'         UNIT CHECK.                 7343 07250021
         BZ    WAITOUTX                NO-BRANCH.                  7343 07300021
         TM    OUTSENSE,DC             DATA CHECK.                 7343 07350021
         BO    IOERR                   YES-I/O ERROR.              7343 07400021
WAITOUTB TM    OUTSENSE+1,X'04'        CHECK FOR FILE PROTECT.          07450021
         BO    WAITOUTC                YES-GO CHECK FOR TRK OVERFLOW.   07500021
         TM    OUTSENSE,X'02'          CHECK FOR TRACK CONDITION.       07550021
         BZ    IOERR                   NO--MUST BE I/O ERROR.           07600021
WAITOUTC TM    OUTSENSE+1,X'01'        CHECK FOR OVERFLOW INCOMPLETE.   07650021
         BZ    CHEKSTAT                NO--                             07700021
         CLI   OUTECB,X'41'             PERMANENT I/O ERROR      A45281 07750021
         BE    CHEKSTAT                 YES, ACCEPT ERROR        A45281 07800021
         OI    SWITCH,TRKOVFL          SET TRACK OVERFLOW INDICATOR.    07850021
         B     HAR0R1                  R1 IS TRACK OVERFLOW.      0811  07900021
WAITOUTX EQU   *                                                   7343 07950021
         TM    OUTSTAT+4,X'01'         EOF ON RECORD ONE.          7343 08000021
         BZ    WAITOUTD                NO-CHECK IF ALL OK.         7343 08050021
         L     GR3,CCWBUFPT            YES-R1 IS EOF REC.          7343 08100021
         MVI   24(GR3),X'12'           SET OP CODE FOR READ COUNT. 7343 08150021
         B     RDCNTS                  RESTART CHANNEL PROGRAM.    7343 08200021
WAITOUTD EQU   *                                                   7343 08250021
         CLI   OUTECB,GOOD             ALL OK.                     7343 08300021
         BC    7,IOERR                 NO-I/O ERROR.               7343 08350021
         EJECT                                                          08400021
*********************************************************************** 08450021
*                                                                     * 08500021
*  TEST HERE TO SEE IF ONLY HOME ADDRESS,RECORD ZERO, OF HOME ADDRESS * 08550021
*  RECORD ZERO,RECORD ONE, OR RECORDS GREATER THAN RECORD ONE.        * 08600021
*                                                                     * 08650021
*********************************************************************** 08700021
         USING CCWS,2                                                   08750021
CHEKSTAT L     GR2,CCWBUFPT            RESET POINTER TO CCW BUFFER.     08800021
         LA    GR6,RDWRTCNT            COMPARE ADDR IF HA-R0 ONLY.      08850021
         ST    GR6,AREA                STORE FOR COMPARE.         0811  08900021
         CLC   AREA+1(3),OUTSTAT+1     IS CSW 8 BEYOND READ R0.   0811  08950021
         BE    HAR0                    YES--HAVE HA,R0 ONLY             09000021
         LA    GR6,8(GR6)              COMPARE ADDR. IF HA,R0,R1 ONLY.  09050021
         ST    GR6,AREA                STORE FOR COMPARE.         0811  09100021
         BAL   GR15,CHKCNTS             CHECK FOR BAD COUNT FLD SA53223 09110001
         CLC   AREA+1(3),OUTSTAT+1     IS CSW 8 BEYOND READ R1.   0811  09150021
         BE    HAR0R1                  YES--HAVE HA,R0-R1.              09200021
         B     CNGRDCKD                NO--HAVE HA,R0-RN.               09250021
WRTHAR0  L     GR6,DATBUFPT            ADDRESS OF DATA BUFFER.          09300021
         MVC   0(8,GR6),ZERO           ZERO FOR R0 DATA IF TRK NOT OWND 09350021
HAR0     CLI   DEVSW,X'FF'             DUMPING TO DIRECT ACCESS.        09400021
         BNE   ONTAPE                  NO--BRANCH.                      09450021
         LA    GR6,HAR0CCW1            GET ADDRESS OF HA-R0 CCWS        09500021
         LA    GR7,56                  SET NUMBER OF CCWS TO MOVE.      09550021
         BAL   GR14,SETUPCCW           GO TO PUT CCWS IN BUFFER.        09600021
         USING R0CCWS,8                                                 09650021
         MVC   WRITER0+1(3),DATBUFPT+1 RESET BUFFER ADDRESS             09700021
         MVC   READR0+1(3),DATBUFPT+1  RESET BUFFER ADDRESS             09750021
         LA    GR3,ZERO                SET ADDRESS OF ZEROES IN CCW     09800021
         ST    GR3,ERASEALL            TO ERASE REST OF TRACK.          09850021
         MVI   ERASEALL,X'11'          RESET OP CODE                    09900021
         B     CCWOUT                  GO TO WRITE R0-ERASE ON DA.      09950021
ONTAPE   LA    GR3,TAPECCW3                                             10000021
         ST    GR3,TOCCWAD             STORE CCW ADDRESS IN IOB.        10050021
         L     GR4,DATBUFPT            ADDRESS R0 DATA.                 10100021
         ST    GR4,8(GR3)              STORE INTO CCW.                  10150021
         MVI   8(GR3),X'01'            RESET OP CODE.                   10200021
         LA    GR4,8(GR4)              POINT TO END OF DATA.            10250021
         B     CCWOUT1                 GO TO PROCESS.                   10300021
HAR0R1   CLI   DEVSW,X'FF'             DUMPING TO DIRECT ACCESS.        10350021
         BNE   TOTAPE                  NO--BRANCH.                      10400021
         LA    GR6,CCWA                HA,R0,R1 CCWS.                   10450021
         LA    GR7,64                  LENGTH OF CCWS TO MOVE           10500021
         BAL   GR14,SETUPCCW           GO TO PUT CCWS IN BUFFER.        10550021
         USING R0CCWS,8                                                 10600021
         L     GR3,DATBUFPT            GET POINTER TO DATA BUFFER.      10650021
         LA    GR3,8(GR3)              POINT TO R1 DATA.                10700021
         ST    GR3,WRITER0             RESET ADDRESS IN WRT CKD.        10750021
         MVI   WRITER0,X'1D'           RESET WRT CKD OP CODE.           10800021
         TM    SWITCH,TRKOVFL          TRACK OVERFLOW.                  10850021
         BZ    HAR0R1A                 NO-DO NOT RESET CCW OP CODE.     10900021
         MVI   WRITER0,X'01'           RESET OP CODE FOR WRT SPECIAL.   10950021
HAR0R1A  SR    GR5,GR5                 CLEAR WORK REGISTER.             11000021
         IC    GR5,5(GR3)              KEY LENGTH FOR R1.               11050021
         AH    GR5,6(GR3)              ADD DATA LENGTH FOR R1.          11100021
         LA    GR5,8(GR5)              ADD COUNT FOR R1.                11150021
         STH   GR5,WRITER0+6           STORE TOTAL COUNT IN CCW.        11200021
         ST    GR3,ERASEALL            RESET ADDRESS IN READ BACK CHECK 11250021
         MVI   ERASEALL,X'1E'          RESET RD CKD OP CODE.            11300021
         LA    GR6,8                   SET UP COMPARE FOR EOF ON R1.    11350021
         CR    GR5,GR6                 COUNT FOR R1 EIGHT FOR EOF REC.  11400021
         BNE   HAR0R1B                 NO--DO NOT RESET OP CODE.        11450021
         MVI   ERASEALL,X'12'          YES--R1 IS EOF.RESET OP CODE.    11500021
HAR0R1B  MVC   READR0+1(3),DATBUFPT+1  RESET BUFFER ADDRESS.            11550021
         MVC   READREC0+1(3),DATBUFPT+1 RESET BUFFER ADDRESS.           11600021
         B     CCWOUT                  GO TO WRITE R0-R1 ON DA.         11650021
TOTAPE   LA    GR3,TAPECCW4            GET ADDRESS OF CCWS.             11700021
         ST    GR3,TOCCWAD             STORE CCW ADDRESS IN IOB.        11750021
         L     GR4,DATBUFPT            ADDRESS R0-R1 DATA.              11800021
         ST    GR4,8(GR3)              STORE INTO CCW.                  11850021
         MVI   8(GR3),X'01'            RESET OP CODE.                   11900021
         SR    GR5,GR5                 CLEAR OUT THE WORK REGISTER.     11950021
         IC    GR5,13(GR4)             KEY LENGTH FOR R1.               12000021
         AH    GR5,14(GR4)             ADD DATA LENGTH FOR R1.          12050021
         LA    GR5,16(GR5)             ADD DATA LENGTH R0, COUNT R1.    12100021
         STH   GR5,14(GR3)             STORE TOTAL COUNT IN CCW.        12150021
         AR    GR4,GR5                 POINT TO END OF DATA.            12200021
CCWOUT1  CLI   DEVSW,X'F0'             DUMPING TO SYSOUT.               12250021
         BNE   CCWOUT1A                NO-GO WRITE CCWS AND DATA. 0811  12300021
         BAL   GR8,LINKDOUT            YES--GO LINK TO IEHDAOUT.        12350021
         B     OUT4                    CONTINUE WITH NEXT TRACK.        12400021
CCWOUT1A EQU   *                                                  0811  12450021
         TM    SWITCH,TRKOVFL          TRACK OVERFLOW.            0811  12500021
         BZ    CCWOUT                  NO-DO NOT RESET OP CODE.   0811  12550021
         L     GR1,TAPECCW4            POINT TO CCWS TO BE WRITTEN.0811 12600021
         MVI   48(GR1),X'01'           WRITE SPECIAL OP CODE.     0811  12650021
CCWOUT   EXCP  TOIOB                   EXECUTE CHANNEL PROGRAM.         12700021
         OC    COPYPTR(4),COPYPTR      ARE THERE COPIES.                12750021
         BC    8,OUT3                  NO--GO TO AWAIT COMPLETION.      12800021
         L     GR3,TOCCWAD             ADDRESS OF CCWS.                 12850021
         L     GR8,COPYPTR             POINTER TO FIRST COPY BLOCK.     12900021
         USING COPYBLK,GR8                                              12950021
OUT1     LA    GR9,CIOBLOCK            ADDRESS THIS COPY I/O BLK.       13000021
         ST    GR3,TOCCWAD             CCW ADDR TO THIS COPY IOB.       13050021
         EXCP  TOIOB                   WRITE CCWS AND DATA ON TAPE.     13100021
         OC    CCOPYPTR(4),CCOPYPTR    ARE THERE MORE COPIES.           13150021
         BZ    OUT2                    NO--GO TO AWAIT COMPLETION.      13200021
         L     GR8,CCOPYPTR            YES-POINTER TO NEXT COPY BLOCK.  13250021
         B     OUT1                    GO WRITE ON THE NEXT DEVICE.     13300021
OUT2     LA    GR9,BLOCKS              ADDRESSING FOR PRIMARY DEVICES.  13350021
OUT3     BAL   GR14,WAITTO             GO TO AWAIT COMPLETION.          13400021
         B     OUT4                     RETURN TO IEHDEXCP              13410021
         EJECT                                                          13900021
*********************************************************************** 13950021
*   THIS SECTION MOVES EITHER THE HA,R0 ONLY CCWS OR THE HA,R0,R1     * 14000021
*   CCWS TO A BUFFER TO BE EXECUTED ON DIRECT ACCESS DEVICES.         * 14050021
*   ADDRESSES ARE RESET WHERE NECESSARY                               * 14100021
*********************************************************************** 14150021
SETUPCCW L     GR8,WRTBUFPT            ADDRESS OF CCW BUFFER.           14200021
         EX    GR7,MOVECCWS            MOVE NEEDED CCWS TO BUFFER.      14250021
         ST    GR8,TOCCWAD             STORE CCW ADDRESS IN IOB.        14300021
         TM    SEQSW+D1,RPSFEAT    RPS ON TODD                   S20201 14350021
         BZ    SETUP               NO                            S20201 14400021
         L     GR3,CCWBUFPT        PT TO CCW BUFR                S20201 14450021
         SH    GR3,SIXTEEN         PT TO RPS BUFR                S20201 14500021
         ST    GR8,D8(GR3)         RESET TIC ADDR                S20201 14550021
         MVI   D8(GR3),TICCODE     RESET TIC OP                  S20201 14600021
         ST    GR3,TOCCWAD         STORE RPS PTR IN IOB          S20201 14650021
SETUP    EQU   *                        *                        S20201 14700021
         USING R0CCWS,8                                                 14750021
         LA    GR3,TOSEEK+3            ADDRESS FOR SEARCH.              14800021
         ST    GR3,SEARCHR0            STORE INTO CCW.                  14850021
         LA    GR3,SEARCHR0            POINTER TO THIS CCW.             14900021
         MVI   0(GR3),X'31'            RESET OP CODE.                   14950021
         ST    GR3,TICBACK             STORE ADDRESS IN TIC.            15000021
         MVI   TICBACK,X'08'           RESET TIC OP CODE.               15050021
         LA    GR3,TOSEEK+3            ADDRESSS SEARCH ARGUMENT.        15100021
         ST    GR3,SEARCH1             STORE IN CCW.                    15150021
         LA    GR3,SEARCH1             ADDRESS SEARCH CCW.              15200021
         MVI   0(GR3),X'31'            RESET OP CODE.                   15250021
         ST    GR3,TICAGAIN            STORE ADDRESS IN TIC.            15300021
         MVI   TICAGAIN,X'08'          RESET TIC OP CODE.               15350021
         BR    GR14                    RETURN                           15400021
*********************************************************************** 15450021
* THIS SECTION BUILDS THE READ CKD CCWS WHEN HAVE MORE THAN R1 ON TRACK 15500021
*********************************************************************** 15550021
CNGRDCKD L     GR2,DATBUFPT            SET UP TO COMPUTE R1 TOTAL       15600021
         LA    GR2,8(GR2)              BUMP POINTER TO R1.              15650021
         LR    GR3,GR2                 SET 2ND REGISTER FOR ALIGN RTN.  15700021
         BAL   GR15,ALIGN              GO TO ALIGN ON DBLE WORD BDRY.   15750021
         L     GR3,CNTBUFPT            ADDRESS COUNT BUFFER.            15850021
         L     GR2,SAVESLOT            RESTORE ALIGNED POINTER.         15900021
         L     GR8,CCWBUFPT            CCW BUFF ADDRESS.                15950021
         MVC   0(8,GR2),0(GR3)         MOVE R2 COUNT FIELD TO DATA BUFF 16000021
         MVC   OUTSEEK+3(5),0(GR3) GET NEXT COUNT                A29477 16050021
         LA    GR2,8(GR2)              INCREMENT DATA BUFF PTR.         16100021
         OC    5(3,GR3),5(GR3)         IS R2 COUNT EQUAL TO ZERO.       16150021
         BC    7,NOTEOF                NO--R2 IS NOT AN EOF RECORD.     16200021
         MVC   16(8,GR8),8(GR8)        YES--MOVE IN TIC CCW.            16250021
         LA    GR6,24(GR8)             INCREMENT TO PTR TO 4TH CCW.     16300021
         ST    GR6,16(GR8)             STORE FORWARD TIC ADDRESS.       16350021
         MVI   16(GR8),X'08'           RESET TIC OP CODE.               16400021
         OI    SWITCH,R2EOF            SET R2=EOF SWITCH FOR LATER.     16450021
         LA    GR8,16(GR8)             POINT TO LAST CCW SET UP.        16500021
         LM    GR4,GR5,DMMYRCCW        DUMMY READ CCW.                  16550021
         LR    GR4,GR2                 SET DATA BUFF PTR IN CCW.        16600021
         B     CONTINUE                GO TO CHECK IF R3 THIS TRACK.    16650021
         EJECT                                                          16660021
**********************************************************************  16700021
*        FUNCTION: TEST COUNT FIELDS OF ALL RECORDS READ, TO DETERMINE  16750021
*              IF SAID COUNT FIELDS ARE IN ERROR. THAT IS, WILL THE     16800021
*              COUNT FIELDS CAUSE MORE DATA TO BE READ INTO CORE THAN   16850021
*              THE IEHDASDR BUFFER (DATBUFPT) WILL HOLD.                16900021
*              THE 'CCHH' PORTION OF COUNT FIELD WILL ALSO BE           16950021
*              CHECKED AGAINST THE INITIAL SEEK FIELD ARGUMENT, THEY    17000021
*              MUST MATCH OR IEH869I ERROR MESSAGE WILL BE ISSUED.      17050021
*              WORK REGISTERS: 1,2,3,5,6,8                              17060001
*              RETURN ON REG 15                                         17070001
**********************************************************************  17100021
         USING TESTCNT,GR3                                      SA53223 17102021
         USING CONSTANT,GR5                                     SA53223 17110021
CHKCNTS  EQU   *                                                SA53223 17120001
         SR    GR6,GR6                  ZERO WORK REG           SA53223 17130001
         L     GR3,DATBUFPT             LOAD ADDR R1 CNT        SA53223 17130401
         LA    GR3,8(GR3)               INCRE PAST R0 DATA      SA53223 17180401
         L     GR5,IODEVCON             LOAD DEVICE CONSTNT PTR SA53223 17350001
         L     GR1,OUTSTAT              GET IOBCSW CCW PTR      SA53223 17360001
         LA    GR1,0(GR1)               ZERO HIGH BYTE          SA53223 17370001
         SH    GR1,EIGHT                BACKUP TO FAILING CCW   SA53223 17380001
         L     GR1,0(GR1)               LOAD END OF CNT ADDR    SA53223 17382001
         LA    GR1,0(GR1)               ZERO HIGH BYTE          SA53223 17390001
         SR    GR8,GR8                  ZERO TRACK TOTAL REG    SA53223 17400021
COMPSK   EQU   *                                                SA53223 17450001
         SR    GR2,GR2                  ZERO RECORD-TOTAL REG   SA53223 17700021
         IC    GR2,TESTKEY              GET KEY LENGTH          SA53223 17750021
         LA    GR2,L8(GR2)              ADD CNT FLD LENGTH      SA53223 17800021
         MVC   HAFWD(L2),TESTDL         MOVE DATA-LENGTH FIELD  SA53223 17850021
         A     GR2,FULWD                ADD DATA LGTH TO        SA53223 17900021
*                                       KEY LGTH + CNT FLD LGTH SA53223 17950021
         AR    GR8,GR2                  ADD THIS RECORDS' LGTH  SA53223 18000021
*                                       TO ALL OTHER RECS ON    SA53223 18050021
*                                       THIS TRK .              SA53223 18100021
         CH    GR8,DATASIZE             IS TOTAL GT BUFFER SIZE SA53223 18150001
         BH    BADCNT                   IF HIGH, ISSUE MSG      SA53223 18200021
         CLC   CCHHONE(L4),TESTCNT      DOES THIS RECORDS'      SA53223 18210001
*                                       'CCHH' MATCH THIS TRKS' SA53223 18220001
*                                       'CCHH'  ?               SA53223 18230001
         BNE   BADCNT                   IF NOT, ISSUE MSG69     SA53223 18240001
         LTR   GR6,GR6                  FRIST TIME THRU ?       SA53223 18240401
         BNZ   CHKCNT                   NO, NOT 1ST TIME THRU   SA53223 18240801
         CLC   AREA+1(3),OUTSTAT+1      ONLY R1 THIS TRK ?      SA53223 18241201
         BE    LEAVE                    YES, EXIT               SA53223 18241601
         L     GR3,CNTBUFPT             LOAD COUNT FLD BUFF PTR SA53223 18242001
         LA    GR6,LEAVE                SET FIRST TIME SWT      SA53223 18242401
         B     COMPSK                   GO TOTAL R2-RN CNT FLDS SA53223 18242501
CHKCNT   EQU   *                                                SA53223 18242801
         LA    GR3,L8(GR3)              INCRE COUNT FIELD PTR   SA53223 18250021
         CR    GR3,GR1                  REACHED END OF COUNT    SA53223 18300001
*                                       FIELD BUFFER YET ?      SA53223 18350021
         BL    COMPSK                   IF NOT, CHK NEXT COUNT  SA53223 18400021
LEAVE    EQU   *                                                SA53223 18402001
         L     GR2,CCWBUFPT             RELOAD WORK REG         SA53223 18410001
         L     GR6,AREA                 RELOAD WORK REG         SA53223 18420001
         BR    GR15                     RETURN                  SA53223 18450021
BADCNT   EQU   *                                                SA53223 18500021
         LA    GR1,MSG69                SET MESSAGE NO.         SA53223 18550021
         BAL   GR8,SETUPMSG             GO LINK TO IEHDMSGB     SA53223 18560021
         L     GR8,CCHHONE              LOAD CURRENT TRK ADDR   SA53223 18560401
         ST    GR8,CONVAD               STORE CURRENT TRK ADDR  SA53223 18562021
         UNPK  CONVAD(9),CONVAD(5)      UNPACK CCHH IN ERROR    SA53223 18603701
         TR    CONVAD(L8),TRT-240       TRANSLATE CCHH          SA53223 18611521
         SH    GR1,OFFSET               ADJUST LINE PTR ADDR    SA53223 18619221
         MVC   D0(L8,GR1),CONVAD        MOVE CCHH TO MSG        SA53223 18626921
         MVC   18(L8,GR1),DDNAME1      MOVE DDNAME TO MSG       SA53223 18634600
         B     MSGWRT                   GO SET BRCH TABLE VALUE SA53223 18642321
*                                       FOR IEHDEXCP.           SA53223 18650021
TRT      DC    C'0123456789ABCDEF'      TRANSLATE TABLE         SA53223 18652002
SETUPMSG EQU   *                                                SA53223 18660021
         LINK  EP=IEHDMSGB                                      SA53223 18670021
         BR    GR8                      RETURN                  SA53223 18680021
         DROP  GR3                                              SA53223 18700021
         DROP  GR5                                              SA53223 18750021
         EJECT                                                          18760021
NOTEOF   LM    GR4,GR5,DMMYRCCW        DUMMY READ CCW.                  18800021
         IC    GR5,5(GR3)              R2 KEY LENGTH.                   18850021
         AH    GR5,6(GR3)              R2 DATA LENGTH.                  18900021
         LR    GR4,GR2                 SET DATA BUFF PTR IN CCW.        18950021
         LA    GR8,16(GR8)             POINT TO FIRST READ CCW.         19000021
         STM   GR4,GR5,0(GR8)          STORE RD KEY/DATA R2 CCW.        19050021
         MVI   0(GR8),X'0E'            RESET OP CODE.                   19100021
         MVI   4(GR8),X'40'            RESET FLAGS.                     19150021
CONTINUE LA    GR6,8                   SET UP INCREMENTING FACTOR.      19200021
         AR    GR3,GR6                 POINT TO NEXT COUNT FIELD.       19250021
         LA    GR5,0(GR5)              CLEAR HIGH ORDER BYTE.           19300021
         AR    GR4,GR5                 ADD R2 COUNT TO DATA PTR.        19350021
         L     GR7,OUTSTAT             LOAD ADDRESS LAST RD CNT CCW.    19400021
         LA    GR7,0(GR7)              CLEAR HIGH ORDER BYTE.           19450021
         SH    GR7,THIRTY2             POINT TO LAST CCW EXECUTED.      19500021
         CR    GR7,GR8                 JUST HA THRU R2 THIS TRACK.      19550021
         BE    CCOFF                   YES-GO TO READ IN R2 KEY/DATA.   19600021
         NI    SWITCH,X'BF'            SET R2=EOF SWITCH OFF.           19650021
         AR    GR2,GR5                 ADD R2 KEY/DATA LENGTH TO PTR.   19700021
         BAL   GR15,ALIGNA             PROCESS FOR DBLE WORD BOUNDARY.  19750021
         AR    GR8,GR6                 INCREMENT CCW POINTER.           19800021
NEWRDCKD L     GR4,SAVESLOT            POINTER INTO CCW.                19850021
         SR    GR5,GR5                 CLEAR WORK REGISTER.             19900021
         IC    GR5,5(GR3)              GET THE KEY LENGTH FROM CNT BUF. 19950021
         AH    GR5,6(GR3)              ADD THE DATA LENGTH.             20000021
         AR    GR5,GR6                 ADD COUNT LENGTH.                20050021
         O     GR5,MSKFLGON            SET THE FLAGS.                   20100021
         STM   GR4,GR5,0(GR8)          STORE CCW IN LIST.               20150021
         MVI   0(GR8),X'1E'            RESET OP CODE.                   20200021
         CLC   6(2,GR3),ZERO           IS DATA LENGTH = 0.              20250021
         BNE   ZEROFLG                 NO,NOT EOF RECORD.               20300021
         CLI   5(GR3),X'00'            IS KEY LENGTH = ZERO.            20350021
         BNE   ZEROFLG                 NO,NOT EOF RECORD.               20400021
         MVI   0(GR8),X'12'            EOF RECORD, CHANGE OP CODE.      20450021
ZEROFLG  LA    GR4,0(GR4)              CLEAR OUT OP CODE.               20500021
         LA    GR5,0(GR5)              CLEAR OUT FLAGS.                 20550021
         AR    GR4,GR5                 ADD COUNT TO ADDRESS.            20600021
         ST    GR4,SAVESLOT            STORE FOR ALIGNMENT ROUTINE.     20650021
         BAL   GR15,ALIGNB             GO TO CHECK DOUBLE WORD BNDRY.   20700021
         AR    GR3,GR6                 BUMP COUNT FIELD POINTER.        20750021
         BXLE  GR8,GR6,NEWRDCKD        UPDATE CCW ADDRESS POINTER.      20800021
CCOFF    ST    GR4,TOTAL               STORE END OF DATA POINTER.       20850021
         TM    SWITCH,R2EOF            IS R2=EOF SWITCH STILL ON.       20900021
         BO    EOFONR2                 YES--NO EXCP THIS TRACK.   0811  20950021
*        L     GR5,4(GR7)              COUNT FIELD OF LAST CCW. SA51474 21000021
*        LA    GR5,1(GR5)              INCREMENT COUNT TO FORCE SA51474 21050021
*                                      TRACK OVERFLOW IF TRUE.  SA51474 21100021
*        ST    GR5,4(GR7)              COUNT TO LAST RD CCW.    SA51474 21150021
CCOFF1   MVI   4(GR7),X'20'            SET CC OFF IN LAST CCW.          21200021
READCKD  EXCP  OUTIOB                  2ND PASS-READ IN CNT,KEY,DATA.   21250021
EOFONR2  CLI   DEVSW,X'FF'             DUMPING TO DIRECT ACCESS.        21300021
         L     GR1,WRTBUFPT            ADDR FOR WRT/RD CKD CCWS.        21350021
         L     GR6,CCWBUFPT            ADDR RD CKD CCWS.                21400021
         L     GR3,DATBUFPT            ADDRESS OF DATA BUFFER.          21450021
         BNE   TAPEOUT                 NO--TAPE--BRANCH.                21500021
         L     GR2,DATBUFPT            ADDR DATA BUFFER.                21550021
         BAL   GR14,RESET              GO TO SET UP WRT CKD CCWS.       21600021
         L     GR6,WRTBUFPT            ADDR. BEGINNING WRT CKD CCWS.    21650021
         L     GR3,DATBUFPT            INITIALIZE DATA POINTER.         21700021
         BAL   GR14,SKIPON             GO TO SET SKIP BIT ON.           21750021
         TM    SWITCH,R2EOF            WAS R2 EOF AND LAST REC THIS TRK 21800021
         BO    NOWAIT                  YES--NO WAIT TODAY.              21850021
         BAL   GR14,WAITDISK           GO TO WAIT COMPLETION ON RDCKD.  21900021
NOWAIT   L     GR3,WRTBUFPT            ADDR WRT/RD CKD CCWS.            21950021
         ST    GR3,TOCCWAD             STORE CCW ADD IN IOB.            22000021
         TM    SEQSW+D1,RPSFEAT    RPS ON TODD                   S20201 22050021
         BZ    NOWAIT1             NO                            S20201 22100021
         L     GR14,CCWBUFPT       PT TO CCW BUFR                S20201 22150021
         SH    GR14,SIXTEEN        PT TO RPS BUFR                S20201 22200021
         ST    GR14,TOCCWAD        PTR TO IOB                    S20201 22250021
         ST    GR3,D8(GR14)        RESET TIC ADDR                S20201 22300021
         MVI   D8(GR14),TICCODE    RESET TIC OP                  S20201 22350021
NOWAIT1  EQU   *                        *                        S20201 22400021
         TM    SWITCH,TRKOVFL          TRACK OVERFLOW.            0811  22450021
         BC    8,CKDOUT                NO-GO WRITE ON TO DEVICE.  0811  22500021
         BAL   GR15,SETWRTSP           YES-SET UP WRT SPECIAL CCW.0811  22550021
         B     CKDOUT                  GO EXEC WRT/RD CKD CCWS.         22600021
TAPEOUT  CLI   DEVSW,X'F0'             DUMPING TO SYSOUT.               22650021
         BNE   TAPEOUT1                NO--GO TO PROCESS FOR TAPE.      22700021
         TM    SWITCH,R2EOF            WAS SECOND PASS NECESSARY.       22750021
         BO    TAPEOUT2                NO---NO WAIT TODAY.              22800021
         BAL   GR14,WAITDISK           GO TO AWAIT COMPLETION.          22850021
TAPEOUT2 L     GR4,TOTAL               END OF DATA POINTER.             22900021
         BAL   GR8,LINKDOUT            LINK TO IEHDAOUT.                22950021
         B     PROC4                   CONTINUE WITH NEXT TRACK.        23000021
TAPEOUT1 LA    GR2,R0R1CCWS            ADDR. OF SEEK AND SFM CCWS.      23050021
         MVC   0(16,GR1),0(GR2)        MOVE INTO WRT BUFFER.            23100021
         LA    GR1,16(GR1)             RESET BUFFER POINTER.            23150021
         LH    GR2,BUFFADDR            S/A D/R BUFFER ADDRESS.          23200021
         BAL   GR14,RESET              GO TO RESET ADDR. AND OP CODES.  23250021
         L     GR6,WRTBUFPT            ADDR. BEGINNING WRT CKD CCWS.    23300021
         LA    GR6,16(GR6)             POINT TO SEARCH,TIC CCWS.        23350021
         LH    GR2,BUFFADDR            INITIALIZE S/A D/R BUFF ADDR.    23400021
         BAL   GR14,SKIPON             GO TO SET SKIP BIT ON.           23450021
         LA    GR3,TAPECCW2            ADDRESS OF WRITE CCW.            23500021
         L     GR2,WRTBUFPT            ADDR WRT/RD CKD CCWS.            23550021
         SH    GR2,SIXTEEN             PROVIDE PADDING FOR CCWS.        23600021
         SR    GR1,GR2                 GR1 HAS LENGTH WRT/RD CKD CCWS.  23650021
         ST    GR1,4(GR3)              STORE LENGTH OF CCW REC. IN CCW  23700021
         MVI   4(GR3),X'20'            RESET THE FLAGS.                 23750021
         ST    GR2,0(GR3)              STORE BUFF ADDR. IN CCW.         23800021
         MVI   0(GR3),X'01'            RESET WRITE OP CODE.             23850021
         ST    GR3,TOCCWAD             STORE ADDRESS IN IOB.            23900021
         NI    TOFLGS,X'02'            INDICATE NO CMD CHAINING.        23950021
         EXCP  TOIOB                   WRITE OUT CCW REC ON TAPE.       24000021
         OC    COPYPTR(4),COPYPTR      ARE THERE COPIES.                24050021
         BC    8,SETSW                 NO--GO TO AWAIT COMPLETION.      24100021
         L     GR8,COPYPTR             POINTER TO FIRST COPY BLOCK.     24150021
         USING COPYBLK,8                                                24200021
TAPEOUTA LA    GR9,CIOBLOCK                                             24250021
         ST    GR3,TOCCWAD             CCW ADDRESS TO COPY IOB.         24300021
         EXCP  TOIOB                   WRITE CCWS TO TAPE COPY.         24350021
         OC    CCOPYPTR(4),CCOPYPTR    ARE THERE MORE COPIES.           24400021
         BZ    TAPEOUTB                NO--GO TO AWAIT COMPLETION.      24450021
         L     GR8,CCOPYPTR            POINTER TO NEXT COPY BLOCK.      24500021
         B     TAPEOUTA                GO WRITE ON THE NEXT DEVICE.     24550021
TAPEOUTB LA    GR9,BLOCKS              ADDRESSING FOR PRIMARY DEVICES.  24600021
SETSW    BAL   GR14,WAITTO             GO TO AWAIT COMPLETION.          24650021
         TM    SWITCH,R2EOF            WAS R2 EOF AND LAST REC THIS TRK 24700021
         BO    NOWAIT2                 YES--NO WAIT TODAY.              24750021
         BAL   GR14,WAITDISK           WAIT ON READ CKD CCWS.           24800021
NOWAIT2  L     GR1,TOTAL               END OF DATA POINTER.             24850021
         L     GR2,DATBUFPT            BEGINNING OF DATA BUFFER.        24900021
         SR    GR1,GR2                 GR1 HAS LENGTH OF DATA.          24950021
         LA    GR3,TAPECCW2        ADDRESS OF WRITE CCW.           0161 25000021
         TM    SWITCH,TRKOVFL          TRACK OVERFLOW.            0811  25050021
         BC    8,NOWAIT3               NO-CONTINUE.               0811  25100021
         L     GR3,WRTBUFPT            POINT TO WRT/RD CCWS.      0811  25150021
         LA    GR3,16(GR3)             INDEX PAST SEEK,SFM CCWS.  0811  25200021
         BAL   GR15,SETWRTSP           YES-SET UP WRT SPECIAL CCW.0811  25250021
         OI    TOFLGS,X'42'            SET CMD. CHAINING IN IOB.  0811  25300021
         L     GR3,CNTBUFPT            BUFFER POINTER.            0811  25350021
         ST    GR3,TOCCWAD             STORE ADDRESS IN IOB.      0811  25400021
         MVI   0(GR3),X'0C'            SET OP CODE IN CCW.        0811  25450021
         MVC   1(3,GR3),CCWBUFPT+1     ADDRESS FOR READ BACKWARD. 0811  25500021
         MVI   4(GR3),X'70'            SET FLAGS IN CCW.           2920 25550021
         MVC   5(3,GR3),TAPECCW2+5     LENGTH OF CCW RECORD.      0811  25600021
         MVC   8(8,GR3),TAPECCW2       WRITE CCW RECORD CCW.      0811  25650021
         MVI   12(GR3),X'60'           CHAINING.                  0811  25700021
         MVC   16(8,GR3),TAPECCW2      WRITE DATA RECORD CCW.     0811  25750021
         LA    GR3,16(GR3)             POINT TO WRT DATA CCW.     0811  25800021
NOWAIT3  ST    GR1,4(GR3)              DATA LENGTH TO CCW.        0811  25850021
         MVI   4(GR3),X'20'            RESET THE FLAGS.                 25900021
         ST    GR2,0(GR3)              STORE BUFFER ADDR IN CCW.        25950021
         AIF   ('&LIB' EQ 'LIB1').OSASSEM  BRCH IF OS ASSSEMBLY Y02113  26410002
*        TIMESTAMP WILL BE PLACED INTO FORMAT 4 DSCB HERE.      Y02113  26420002
         TM    TIMESET,TIMECHK          HAS F4 DSCB BEEN UPDATED Y02113 26440002
         BO    TIMEOK                   YES, DON'T CHECK        Y02113  26442002
         CLC   OUTSEEK+D3(L4),TIMESTMP  IS THIS THE F4 DSCB     Y02113  26446002
         BNE   TIMEOK                   NO, DON'T STORE CLOCK   Y02113  26448402
         STCK  CLOCK(GR2)               PUT TIMESTAMP IN DSCB   Y02113  26449202
         OI    TIMESET,TIMECHK          SET TIME CHECK SWT      Y02113  26449602
TIMEOK   EQU   *                                                Y02113  26449702
.OSASSEM ANOP  BRCH POINT FOR OS ASSEM.                         Y02113  26449802
         MVI   0(GR3),X'01'            RESET OP CODE.                   26449902
         MVI   R,0                     SET SEARCH ARG. FOR REC ZERO.    26450021
CKDOUT   EXCP  TOIOB                   EXEC OR WRITE WRT/RD CKD CCWS.   26500021
         OC    COPYPTR(4),COPYPTR      ARE THERE COPIES.                26550021
         BC    8,PROC3                 NO--GO TO AWAIT COMPLETION.      26600021
         L     GR3,TOCCWAD             POINTER TO CCWS.                 26650021
         L     GR8,COPYPTR             POINTER TO FIRST COPY BLOCK.     26700021
         USING COPYBLK,GR8                                              26750021
PROC1    LA    GR9,CIOBLOCK                                             26800021
         ST    GR3,TOCCWAD             STORE CCW PTR. IN COPY IOB.      26850021
         EXCP  TOIOB                   EXEC OR WRT CCWS.                26900021
         OC    CCOPYPTR(4),CCOPYPTR    ARE THERE MORE COPIES.           26950021
         BZ    PROC2                   NO--GO TO AWAIT COMPLETION.      27000021
         L     GR8,CCOPYPTR            YES-POINTER TO NEXT COPY BLOCK.  27050021
         B     PROC1                   GO WRITE ON NEXT DEVICE.         27100021
PROC2    LA   GR9,BLOCKS               ADDRESSING FOR PRIMARY DEVICES.  27150021
         TM    SW1,MULTIPLE            ANY REASON TO GO BACK TO MONITOR 27200021
         BZ    PROC3                   NO--GO TO WAIT.                  27250021
         LA    GR3,PROC3               RETURN ADDRESS.                  27300021
         ST    GR3,FRTNPTR             SAVE IN RETURN POINTER.          27350021
         LA    GR15,0                  RETURN CODE FOR MONITOR.         27400021
         B     MULTPROC                RETURN.                          27450021
PROC3    BAL   GR14,WAITTO             GO TO AWAIT COMPLETION.          27500021
         CLI   DEVSW,X'FF'              IS THIS A DISK TO DISK   A37209 27550021
*                                       DUMP                     A37209 27600021
         BNE   PROC4                    NO, MUST BE TAPE         A37209 27650021
*        READ IN VOLUME ID IF FIRST ENTRY                             * 27700021
         CLI   IODEVCON,X'05'           IS THIS A 2321           A52430 27750021
         BE    PROC4                    YES, GO TO PROC4         A52430 27800021
         TM    FLGBYT1,BIT7             IS THIS THE FIRST ENTRY XL03130 27850003
         BO    PROC4                    YES, CONTINUE PROCESSING A37209 27900021
         OI    FLGBYT1,BIT7             SET FIRST ENTRY SWITCH  XL03130 27950003
         LA    GR3,SRCHKEYR             ADDR OF CCW TO READ IN   A37209 28000021
*                                         RECORD THREE                  28050021
         ST    GR3,TOCCWAD              SET UP IOB               A37209 28100021
         XC    TOSEEK+3(4),TOSEEK+3     CLEAR SEEK ADDR          A37209 28150021
         BAL   GR3,VOLIDCP              GO ISSUE CHANNEL PROGRAM A37209 28200021
*        REPLACE NEW VOLUME ID WITH THE ORIGINAL                      * 28250021
         L     GR3,TUCBPTR              GET PTR TO UCB           A37209 28300021
         MVC   RDVOLBUF+4(6),28(GR3)    PUT ORIGINAL IN BUFFER   A37209 28350021
         LA    GR3,SRCHKEYW             ADDR OF CCW TO WRITE OUT A37209 28400021
*                                         RECORD THREE                  28450021
         ST    GR3,TOCCWAD              SET UP IOB               A37209 28500021
         OC    COPYPTR(4),COPYPTR       ANY COPIES               A37209 28550021
         BZ    GOWRT                    NO, CONTINUE             A37209 28600021
*        SET UP COPY BLOCKS                                           * 28650021
         L     GR8,COPYPTR                                       A37209 28700021
         USING COPYBLK,8                                         A37209 28750021
LOOPWRT  EQU   *                                                 A37209 28800021
         LA    GR9,CIOBLOCK                                      A37209 28850021
         ST    GR3,TOCCWAD              POINT TO CHANNEL PROGRAM A37209 28900021
         OC    CCOPYPTR(4),CCOPYPTR     ANY COPIES               A37209 28950021
         BZ    GOWRT                    NO, GO WRITE COPIES      A37209 29000021
         L     GR8,CCOPYPTR             POINT TO NEXT COPY BLOCK A37209 29050021
         DROP  8                                                 A37209 29100021
         B     LOOPWRT                  GO SET UP NEXT COPY      A37209 29150021
*        EXECUTE CHANNEL PROGRAM TO WRITE OUT FIRST VOLUME ID         * 29200021
GOWRT    EQU   *                                                 A37209 29250021
         LA    GR9,BLOCKS               PRIMARY I/O BLOCKS       A37209 29300021
         BAL   GR3,VOLIDCP              GO ISSUE CHANNEL PROGRAM A37209 29350021
         MVC   TOSEEK+3(4),CCHHONE      CCHH OF FIRST TRACK      A37209 29400021
         OC    COPYPTR(4),COPYPTR       MORE COPIES              A37209 29450021
         BZ    ENDVOLID                 NONE LEFT                A37209 29500021
*        EXECUTE CHANNEL PROGRAM FOR COPIES                           * 29550021
         L     GR8,COPYPTR                                       A37209 29600021
         USING COPYBLK,GR8                                       A37209 29650021
COPYIT   LA    GR9,CIOBLOCK                                      A37209 29700021
         XC    TOSEEK+3(4),TOSEEK+3     CLEAR SEEK ADDR          A37209 29750021
         L     GR3,CUCBPTR              GET ADDR OF COPY UCB PTR A37209 29800021
         MVC   RDVOLBUF+4(6),28(GR3)    MOVE IN NEXT VOLID       A37209 29850021
         BAL   GR3,VOLIDCP              GO ISSUE CHANNEL PROGRAM A37209 29900021
         MVC   TOSEEK+3(4),CCHHONE      CCHH OF FIRST TRACK      A37209 29950021
         OC    CCOPYPTR(4),CCOPYPTR     MORE COPIES              A37209 30000021
         BZ    ENDVOLID                 NONE LEFT                A37209 30050021
         L     GR8,CCOPYPTR                                      A37209 30100021
         B     COPYIT                   MAKE NEXT COPY           A37209 30150021
*        SHARED EXCP, WAIT, AND TEST FOR I/O ERROR                    * 30200021
VOLIDCP  EQU   *                                                 A37209 30250021
         EXCP  TOIOB                                             A37209 30300021
         WAIT  ECB=TOECB                                         A37209 30350021
         CLI   TOECB,GOOD               CHECK FOR GOOD I/O       A37209 30400021
         BNE   IOTERR                   YES                      A37209 30450021
         BR    GR3                      RETURN TO                A37209 30500021
ENDVOLID LA    GR9,BLOCKS                                        A37209 30550021
         B     PROC4                    RETURN TO IEHDEXCP              30560021
         SPACE                                                    0811  30800021
SETWRTSP LA    GR3,24(GR3)             POINT TO WRT R1 CCW.       0811  30850021
         L     GR0,AREA                LENGTH OF CCW'S > R2.      0811  30900021
         AR    GR3,GR0                 POINT TO LAST WRT CCW.     0811  30950021
         MVI   0(GR3),X'01'            WRITE SPECIAL OP CODE.     0811  31000021
         BR    GR15                    RETURN TO CALLER.          0811  31050021
         EJECT                                                          31100021
*********************************************************************** 31150021
*                                                                     * 31200021
*   THIS SECTION BUILDS THE WRITE/READ COUNT/KEY/DATA CCWS TO BE      * 31250021
*        EXECUTED FOR DIRECT ACCESS OUTPUT OR WRITTEN OUT AS A CCW    * 31300021
*        RECORD FOR TAPE OUTPUT.                                      * 31350021
*                                                                     * 31400021
*        REGISTER 1 MUST CONTAIN POINTER TO THE WRT BUFF.             * 31450021
*        REGISTER 3 MUST CONTAIN POINTER TO THE DATA BUFF.            * 31500021
*        REGISTER 6 MUST CONTAIN POINTER TO THE CCW BUFF.             * 31550021
*        REGISTER 7 WILL CONTAIN ADDRESS OF LAST RD CKD CCW.          * 31600021
*                                                                     * 31650021
*********************************************************************** 31700021
RESET    LA    GR5,CCWA                ADDR SEARCH R0,TIC,WRT CKD R1.   31750021
         MVC   0(24,GR1),0(GR5)        MOVE THREE CCWS TO WRT BUFF.     31800021
         MVC   24(8,GR1),16(GR5)       MOVE IN 2ND WRT CKD CCW FOR R2.  31850021
         LA    GR4,2                   SET UP LOOP CONTROL.             31900021
         LA    GR3,8(GR3)              BUMP DATA POINTR TO REC ONE.     31950021
         CLI   DEVSW,X'FF'             DUMPING TO DIRECT ACCESS.        32000021
         BNE   RESET1                  NO-TAPE-DO NOT RESET ADDRESS.    32050021
         LA    GR0,TOSEEK+3            ADDRESS FOR SEARCH.              32100021
         ST    GR0,0(GR1)              STORE ADDRESS IN SEARCH CCW.     32150021
         MVI   0(GR1),X'31'            RESET OP CODE.                   32200021
         ST    GR1,8(GR1)              RESET TIC ADDRESS.               32250021
         MVI   8(GR1),X'08'            RESET TIC OP CODE.               32300021
RESET1   LA    GR1,16(GR1)             RESET WRT BUFF PTR.              32350021
         SR    GR7,GR6                 GR7 HAS LENGTH OF RD CKD CCWS.   32400021
         L     GR5,TICADDR              LOAD TIC ADDRESS         S20201 32450021
         AR    GR5,GR7                  ADD RD CKD LENGTH TO TIC S20201 32500021
         ST    GR5,CCWB+8               TIC ADDR                 M5599  32550021
         MVI   CCWB+8,X08               TIC OP                   M5599  32600021
         LA    GR2,8(GR2)              RESET DATA BUFF PTR TO REC ONE.  32650021
RESET11  ST    GR2,0(GR1)              ST R1 DATA PTR IN CCW.           32700021
         SR    GR5,GR5                 CLEAR WORK REGISTER.             32750021
         IC    GR5,5(GR3)              KEY LENGTH.                      32800021
         AH    GR5,6(GR3)              PLUS DATA LENGTH.                32850021
         LA    GR5,8(GR5)              PLUS COUNT LENGTH.               32900021
         STH   GR5,6(GR1)              STORE NEW COUNT INTO CCW.        32950021
         AR    GR3,GR5                 ADD R1 LENGTH.                   33000021
         AR    GR2,GR5                 ADD R1 LENGTH TO DATA PTR.       33050021
         ST    GR3,SAVESLOT            STORE TO SEE IF DOUBLE WORD.     33100021
         BAL   GR15,ALIGNB             GO TO CHECK DOUBLE WORD ALIGNMT. 33150021
         L     GR3,SAVESLOT            POINTER BACK INTO REGISTER.      33200021
         BAL   GR15,ALIGNA             GO TO CHECK DOUBLE WORD ALIGNMT. 33250021
         L     GR2,SAVESLOT            POINTER BACK INTO REGISTER.      33300021
         MVI   0(GR1),X'1D'            RESET OP CODE.                   33350021
         LA    GR1,8(GR1)              RESET WRT BUFF POINTER.          33400021
         BCT   GR4,RESET11             LOOP THRU TO PROCESS R2.         33450021
RESETA   LA    GR6,24(GR6)             INCREMENT RD CKD PTR TO R3.      33500021
         LA    GR8,16                  DECREMENT FACTOR.                33550021
         SR    GR7,GR8                 SUBTRACT FROM LENGTH COUNTER.    33600021
         ST    GR7,AREA                STORE LENGTH OF CCW'S > R2.0811  33650021
*                                      IF ZERO,CLEAR WORK AREA.         33700021
         LTR   GR7,GR7                 MORE THAN TWO RECORDS.           33750021
         BCR   8,GR14                  NO-2 RECS-RETURN.          0811  33800021
         LR    GR8,GR1                 SET UP FOR EXECUTE.              33850021
         SPACE                                                          33900021
         BAL   GR15,RESETCCW           MOVE CCWS FOR WRITE.             33950021
         OI    4(GR7),X'60'            SET FLAGS IN LAST CCW.           34000021
RESETB   CLI   DEVSW,X'FF'             DUMPING TO DIRECT ACCESS.        34050021
         BE    RESETC                  YES--DO NOT CHANGE DATA PTR.     34100021
         ST    GR2,0(GR1)              STORE DATA BUFF PTR INTO CCW.    34150021
         LH    GR5,6(GR1)              INSERT COUNT FROM CCW.           34200021
         AR    GR2,GR5                 ADD COUNT TO DATA POINTER.       34250021
         BAL   GR15,ALIGNA             GO TO CHECK DOUBLE WORD BDRY.    34300021
         L     GR2,SAVESLOT            POINTER BACK INTO REGISTER.      34350021
RESETC   MVI   0(GR1),X'1D'            SET WRT OP CODE.                 34400021
         BXLE  GR1,GR6,RESETB          UPDATE CCW ADDRESS POINTER       34450021
         BR    GR14                    RETURN.                    0811  34500021
SKIPON   LA    GR5,CCWB                ADDR SEARCH,TIC,WRT DATA CCWS.   34550021
         MVC   0(24,GR1),0(GR5)        MOVE THREE CCWS TO WRT BUFF.     34600021
         CLI   DEVSW,X'FF'             DUMPING TO DIRECT ACCESS.        34650021
         BNE   SKIPONN                 NO--TAPE--DO NOT RESET PTRS.     34700021
         LA    GR0,TOSEEK+3            ADDRESS FOR SEARCH.              34750021
         ST    GR0,0(GR1)              STORE ADDRESS IN SEARCH CCW.     34800021
         MVI   0(GR1),X'31'            RESET OP CODE.                   34850021
         ST    GR1,8(GR1)              RESET TIC ADDRESS.               34900021
         MVI   8(GR1),X'08'            RESET TIC OP CODE.               34950021
         ST    GR3,16(GR1)             STORE DATA POINTER.              35000021
         MVI   16(GR1),X'05'           RESET WRT DATA OP CODE.          35050021
SKIPONN  LA    GR1,24(GR1)             BUMP POINTER TO R1,R2 CCWS.      35100021
         MVC   0(16,GR1),16(GR6)       MOVE IN R1,R2 CCWS.              35150021
         L     GR7,AREA                LENGTH OF CCW'S > R2.      0811  35200021
         LTR   GR7,GR7                 GREATER THAN R2 THIS TRK.        35250021
         LA    GR15,SKIPONE            RETURN ADDRESS.                  35300021
         BZ    SETCCWS                 NO--GO SET REGS FOR BXLE.        35350021
         LA    GR6,32(GR6)             YES-BUMP PTR TO WRT CKD R3.      35400021
         LA    GR8,16(GR1)             POINT TO NEXT AVAILABLE SLOT.    35450021
         BAL   GR15,RESETCCW           MOVE CCWS FOR RD BACK CHECK.     35500021
SKIPONE  EQU   *                                                   0161 35550021
         AH    GR7,SIXTEEN         INCRM FOR BXLE LOOP.            0161 35600021
SKIPONE1 EQU   *                                                   0161 35650021
         LH    GR5,6(GR1)          LOAD CNT FROM THIS CCW.         0161 35700021
         CR    GR5,GR6                 IS COUNT ONLY 8 FOR EOF REC.     35750021
         BNE   SKIPONF                 NO--GO SET RD CKD OP CODE.       35800021
         MVI   0(GR1),X'12'            YES-SET RD COUNT OP CODE.        35850021
         B     SKIPONF1                GO TO SET SKIP BIT ON.           35900021
SKIPONF  MVI   0(GR1),X'1E'            SET RD CKD OP CODE FOR NON-EOF.  35950021
SKIPONF1 MVI   4(GR1),X'70'            SET SKIP BIT ON FOR RD BACK CHK. 36000021
         BXLE  GR1,GR6,SKIPONE1    LOOP THRU UNTIL DONE.           0161 36050021
         MVC   0(8,GR1),CCWB+32        MOVE IN READ BACK CHK R0 CCW.    36100021
         CLI   DEVSW,X'FF'             DUMPING TO DIRECT ACCESS.        36150021
         BNE   SKIPONG                 NO--DO NOT RESET PTRS.           36200021
         L     GR0,DATBUFPT            DATA BUFFER ADDRESS.             36250021
         ST    GR0,0(GR1)              STORE INTO CCW.                  36300021
         MVI   0(GR1),X'16'            RESET OP CODE.                   36350021
SKIPONG  AR    GR1,GR6                 POINT TO END OF WRT/RD CCWS.     36400021
         BR    GR14                    RETURN.                          36450021
         SPACE                                                          36500021
RESETCCW LA    GR5,255                 SET NO. OF BYTES FOR EXEC.       36550021
CHKMVC   CR    GR7,GR5                 WILL THIS BE THE LAST MOVE.      36600021
         BNH   LASTMVC                 YES--BRANCH.                     36650021
         EX    GR5,MOVECCWS            MOVE 256 CHARACTERS.             36700021
         LA    GR8,256(GR8)            INCREMENT MOVE TO POINTER.       36750021
         LA    GR6,256(GR6)            INCREMENT MOVE FROM POINTER.     36800021
         SR    GR7,GR5                 DECREMENT TOTAL LENGTH.          36850021
         B     CHKMVC                  CONTINUE PROCESSING.             36900021
LASTMVC  EX    GR7,MOVECCWS            MOVE CCWS TO WRT/RD CKD BUFF.    36950021
         L     GR7,AREA                RESTORE TOTAL LENGTH.      0811  37000021
SETCCWS  LA    GR6,8                   INCREMENTING FACTOR.             37050021
         AR    GR7,GR1                 SET END ADDRESS                  37100021
         SR    GR7,GR6                    FOR BXLE LOOP.                37150021
         BR    GR15                    RETURN.                          37200021
         SPACE                                                          37250021
*                                                                       37300021
*  LINK TO IEHDAOUT HERE.                                               37350021
*                                                                       37400021
         SPACE                                                          37450021
LINKDOUT EQU   *                                                SA53223 37460021
         LOAD  EP=IEHDPRNT                                      SA53223 37470021
         LR    GR2,GR0                  SAVE ADDR FOR IEHDAOUT  SA53223 37480021
         LR    GR3,GR4                  PASS END OF DATA POINTER.       37500021
         LA    GR1,CCHH                PASS PTR. TO CURRENT TRACK ADDR  37550021
         LINK  EP=IEHDAOUT                                      OX01980 37600003
         DELETE EP=IEHDPRNT             REDUCE CDE USE CNT.     OX01980 37700003
         BR    GR8                     RETURN TO CALLER.                37750021
         EJECT                                                          37800021
*                                                                       37850021
* WAIT ON COMPLETION OF EXCP AGAINST 'FROM' DEVICE HERE.                37900021
*                                                                       37950021
         SPACE                                                          38000021
WAITDISK TM    OUTECB,COMPLETE         IS THE OPERATION COMPLETE        38050021
         BO    TESTD0                  YES-GO TEST THE STATUS.     3651 38100021
         WAIT  ECB=OUTECB              NO--AWAIT COMPLETION OF DISK.    38150021
TESTD0   EQU   *                                                   3651 38200021
         LA    GR2,TESTD3              RETURN ADDRESS IF RECOVER   O122 38250021
         TM    OUTSTAT+4,X'02'         UNIT CHECK.                 7343 38300021
         BZ    TESTD01             NO,BRANCH                     M0025  38350021
         TM    OUTSENSE,DC             DATA CHECK.                 3651 38400021
         BO    IOERR                   YES-I/O ERROR.              3651 38450021
         TM    OUTSENSE+1,X'04'        FILE PROTECT.               7042 38500021
         BO    TESTD01                 YES-THAT'S OKAY.            7042 38550021
         TM    OUTSENSE,X'02'          TRACK CONDITION.            7042 38600021
         BZ    IOERR                   NO-I/O ERROR.               7042 38650021
TESTD01  EQU   *                                                   7042 38700021
         TM    OUTSENSE+1,X'01'        TRACK OVERFLOW.             7042 38750021
         BZ    TESTD                   NO-CHECK FOR EOF.         A31314 38800021
         OI    SWITCH,TRKOVFL          NO-MUST BE TRACK OVERFLOW.  3651 38850021
         BR    GR14                    RETURN TO CALLER.           3651 38900021
         SPACE                                                          38950021
TESTD    EQU   *                                                  0811  39000021
         TM    OUTSTAT+4,X'01'         EOF INDICATION.                  39050021
         BZ    TESTD6                  NO-SEE IF ALL OKAY.         3651 39100021
         L     GR3,CCWBUFPT            ADDRESS RD CKD CCWS.             39150021
         LA    GR3,16(GR3)             POINT TO RD KD R2 CCW.           39200021
         L     GR4,OUTSTAT             CSW ADDRESS.                     39250021
         LA    GR6,8                   SET UP REGISTER FOR SUBTRACTION. 39300021
         SR    GR4,GR6                 POINT TO CCW CAUSING THE EOF.    39350021
         TM    4(GR4),CCH              COMMAND CHAINING.           3651 39400021
         BCR   8,GR14                  NO-RETURN TO CALLER.        3651 39450021
         CR    GR3,GR4                 WAS EOF ON R2.                   39500021
         BE    TESTD2                  YES--SET UP FORWARD TIC.         39550021
         MVI   0(GR4),X'12'            NO---CHANGE CCW TO RD CNT.       39600021
         B     TESTD3                  GO TO RESTART CHANNEL PROGRAM.   39650021
TESTD2   SR    GR3,GR6                 POINT TO FIRST TIC CCW.          39700021
         MVC   0(8,GR4),0(GR3)         MOVE IN TIC CCW.                 39750021
         LA    GR6,8(GR4)              COMPUTE FORWARD TIC ADDRESS.     39800021
         ST    GR6,0(GR4)              STORE ADDRESS IN TIC CCW.        39850021
         MVI   0(GR4),X'08'            RESET OP CODE.                   39900021
TESTD3   EXCP  OUTIOB                  RESTART CHANNEL PROGRAM.         39950021
         B     WAITDISK                GO TO AWAIT COMPLETION.          40000021
TESTD6   EQU   *                                                  0811  40050021
         CLI   OUTECB,GOOD             ALL OK.                    0811  40100021
         BCR   8,GR14                  YES-RETURN TO CALLER.       7042 40150021
TESTD02  EQU   *                                                   7042 40200021
         CLI   OUTECB,X'41'            EXPECTED I/O ERROR.         7042 40250021
         BNE   IOERR                   NO-NOT EXPECTED.            7042 40300021
         TM    OUTSTAT+5,X'40'         INCORRECT LENGTH.           7042 40350021
         BZ    IOERR                   NO-I/O ERROR.               7042 40400021
         BR    GR14                    RETURN TO CALLER.           7042 40450021
         EJECT                                                          40500021
*                                                                       40550021
* WAIT ON COMPLETION OF EXCP AGAINST 'TO' DEVICE HERE.                  40600021
*                                                                       40650021
         SPACE                                                          40700021
WAITTO   BAL   GR4,WAIT2               WAIT ON PRIMARY 'TO' DEVICE.     40750021
* CONTROL RETURNED HERE IF EOV HIT.                                     40800021
         OI    SWITCH,EOV              SET EOV SWITCH.                  40850021
* CONTROL RETURNED HERE IF WAIT WAS GOOD.                               40900021
         OC    COPYPTR(4),COPYPTR      ARE COPIES BEING MADE.           40950021
         BCR   8,GR14                  NO--RETURN.                      41000021
         L     GR8,COPYPTR             YES-ADDRESS OF FIRST COPY BLOCK. 41050021
         USING COPYBLK,GR8                                              41100021
WAIT1    LA    GR9,CIOBLOCK            I/O BLOCKS FOR COPY.             41150021
         BAL   GR4,WAIT2               AWAIT COMPLETION OF THIS COPY.   41200021
* CONTROL RETURNED HERE IF EOV HIT.                                     41250021
         MVI   CERRSW,X'FF'            SET EOV SWITCH.                  41300021
* CONTROL RETURNED HERE IF WAIT WAS GOOD.                               41350021
         SPACE                                                          41400021
         OC    CCOPYPTR(4),CCOPYPTR    ARE THERE MORE COPIES.           41450021
         BC    8,WAIT1A                NO--GO TO RETURN.                41500021
         L     GR8,CCOPYPTR            YES-ADDRESS NEXT COPY BLOCK.     41550021
         B     WAIT1                   GO WAIT ON NEXT COPY.            41600021
WAIT1A   LA    GR9,BLOCKS              PRIMARY I/O BLOCKS.              41650021
         BR    GR14                    RETURN.                          41700021
         SPACE                                                          41750021
WAIT2    TM    TOECB,COMPLETE          IS THE OPERATION COMPLETE.       41800021
         BO    WAIT3                   YES--GO TO TEST THE STATUS.      41850021
         WAIT  ECB=TOECB               NO--AWAIT COMPLETION             41900021
         SPACE 1                                                        41950021
WAIT3    CLI   TOECB,GOOD              ALL OK.                          42000021
         BNE   WAIT3A                  NO--GO TO SEE IF DA OUTPUT.      42050021
         LA    GR4,4(GR4)              YES--BUMP RETURN POINTER.        42100021
         BR    GR4                     RETURN.                          42150021
WAIT3A   CLI   DEVSW,X'FF'             DUMPING TO DIRECT ACCESS.        42200021
         BNE   WAIT4                   NO--TAPE--BRANCH.                42250021
*                                                                       42300021
* PROCESS HERE IF DIRECT ACCESS OUTPUT.                                 42350021
*                                                                       42400021
         TM    TOSTATUS+4,X'01'        EOF ENCOUNTERED.                 42450021
         BO    REPEAT                  YES--RESTART CCW CHAIN.          42500021
         TM    TOSENSE+1,X'08'         NO---TEST FOR NO RECORD FOUND.   42550021
         BZ    IOTERR                  NO---MUST BE I/O ERROR.          42600021
         L     GR3,TUCBPTR             ADDRESS OF UCB FOR 'TO' DEV.     42650021
         USING UCB,GR3                                                  42700021
         AIF   ('&LIB' EQ 'LIB2').NO2321                        Y02113  42750021
         CLI   UCBID,X'FF'             IS THIS A SUB UCB(2321).         42800021
         BE    WAIT3B                  NO--MAIN UCB--                   42850021
         LH    GR5,0(GR3)              BIN NUMBER.                      42900021
         SLA   GR5,4                   TIMES SIXTEEN.                   42950021
         LA    GR5,DATACELL-UCBOB(GR5) ADD LENGTH OF MAIN.              43000021
         LCR   GR5,GR5                 NEGATE.                          43050021
         AR    GR3,GR5                 ADDRESS OF MAIN UCB.             43100021
.NO2321  ANOP                           BRCH POINT IF VS ASSEM   Y02113 43150021
WAIT3B   CLC   TOSEEK+3(4),UCBSKA+3    WERE WE SWITCHED TO NEXT TRK.    43200021
         BE    IOTERR                  NO--LEGITIMATE ERROR.            43250021
         DROP  3                                                        43300021
         LA    GR3,CCWC                ADDRESS READ R0 CCW.             43350021
*                                                                       43400021
* THIS CODING IS USED ONLY WHEN INTERRUPTED WHILE DOING READ-BACK       43450021
* CHECKING AGAINST DA OUTPUT ON TRACK-OVERFLOW OR END-OF-FILE RECORDS.  43500021
*                                                                       43550021
REPEAT1  ST    GR3,TOCCWAD             RESET STARTING POINT IN IOB.     43600021
         EXCP  TOIOB                   FINISH THE CCW CHAIN.            43650021
         B     WAITTO                  GO TO AWAIT COMPLETION.          43700021
* EOF ON DISK ENCOUNTERED--PROCESS HERE.                                43750021
REPEAT   L     GR3,TOSTATUS            END OF INETERRUPTED CCW.         43800021
         LA    GR5,8                                                    43850021
         SR    GR3,GR5                 START OF INTERRUPTED CCW.        43900021
         TM    4(GR3),X'40'            IS THE CHAIN BIT ON.             43950021
         BC    8,REPEATA               NO--THIS CHAIN IS COMPLETE.      44000021
         LA    GR3,8(GR3)              YES--RESET THE START POINT.      44050021
         B     REPEAT1                 GO RESTART THE CCW CHAIN.        44100021
REPEATA  EQU   *                                                   6057 44150021
         CLI   DEVSW,X'FF'             DUMPING TO DA.              6057 44200021
         BCR   7,GR4                   NO-TAPE-RETURN.             6057 44250021
         LA    GR4,4(GR4)              YES-DA-BUMP RETURN POINTER. 6057 44300021
         BR    GR4                     RETURN.                          44350021
*                                                                       44400021
* PROCESS HERE IF TAPE OUTPUT.                                          44450021
*                                                                       44500021
WAIT4    TM    TOSTATUS+4,X'01'        EOV ENCOUNTERED.                 44550021
         BZ    IOTERR                  NO--MUST BE I/O ERROR.           44600021
         B     REPEAT                  GO SEE IF RESTART NEEDED.   6057 44650021
         SPACE 1                                                   O122 44700021
ALIGN    SR    GR5,GR5                 CLEAR WORK REGISTER.             44750021
         IC    GR5,5(GR3)              KEY LENGTH.                      44800021
         AH    GR5,6(GR3)              ADD DATA LENGTH.                 44850021
         LA    GR5,8(GR5)              ADD COUNT LENGTH.                44900021
         AR    GR2,GR5                 ADD RECORD LENGTH TO DATA PTR.   44950021
ALIGNA   ST    GR2,SAVESLOT            STORE TO SEE IF DOUBLE WORD.     45000021
ALIGNB   TM    SAVESLOT+3,X'07'        IS PTR ON DOUBLE WORD BOUNDARY.  45050021
         BCR   8,GR15                  YES--RETURN TO CALLER.           45100021
         NI    SAVESLOT+3,X'F8'        NO---FORCE TO DOUBLE WORD.       45150021
         L     GR5,SAVESLOT            POINTER BACK INTO REGISTER.      45200021
         LA    GR5,8(GR5)              ADD EIGHT AFTER FORCING DOUBLE.  45250021
         ST    GR5,SAVESLOT            STORE FOR FUTURE USE.            45300021
         BR    GR15                    RETURN.                          45350021
         EJECT                                                          51200021
*                                                                       51250021
*  RETURN TO IEHDDUMP HERE.                                             51300021
*                                                                       51350021
         SPACE                                                          51400021
OUT4     EQU   *                                                        51450021
         MVI   BRCHVAL,OUT04              SET BRCH TABLE VALUE  SA53223 51500021
         B     RETEXCP                  RETURN TO EXCP          SA53223 51550021
IOTERR   EQU   *                                                SA53223 51600021
         MVI   BRCHVAL,TAPERR             SET TAPE ERROR VALUE  SA53223 51650021
         B     RETEXCP                  RETURN TO PROC ERR      SA53223 51700021
IOERR    EQU   *                                                SA53223 51750021
         MVI   BRCHVAL,DISKERR          INDIC DISK ERR OCCURRED SA53223 51800021
         B     RETEXCP                  RETURN TO PROC ERR      SA53223 51850021
MSGWRT   EQU   *                                                SA53223 51900021
         MVI   BRCHVAL,MSG              INDIC MSG TO BE O/P     SA53223 51950001
         B     RETEXCP                  RETURN TO IEHDEXCP      SA53223 52000001
FINIS    EQU   *                                                SA53223 52010021
         MVI   BRCHVAL,FINISH           NOT USED                SA53223 52020001
         B     RETEXCP                  RETURN TO IEHDEXCP      SA53223 52030001
MULTPROC EQU   *                                                SA53223 52050021
         MVI   BRCHVAL,MULTI            INDIC MULTI-PROCESS     SA53223 52060021
         B     RETEXCP                  RESTORE REGISTERS       SA53223 52070001
PROC4    EQU   *                                                SA53223 52080021
         MVI   BRCHVAL,PROC04           PREPARE TO READ NXT TRK SA53223 52100021
RETEXCP  L     GR13,4(GR13)            RESTORE REGISTER THIRTEEN A51474 52350001
         RETURN (14,12),T,RC=(15)      RESTORE/RETURN WITH PROPER CODE. 52400021
         EJECT                                                          52450021
MOVECCWS MVC   0(1,GR8),0(GR6)                                          52500021
         SPACE 2                                                        52550021
         DS    0F                                                       52600021
FULWD    DC    H'0'                     COUNT FIELD ADDEND.     SA53223 52610021
HAFWD    DS    H                        COUNT FIELD DATA LENGTH SA53223 52650021
BUFFADDR DC    X'3E18'                 DATA BUFFER ADDR FOR S/A D/R.    52700021
SIXTEEN  DC    H'16'                                                    52750021
THIRTY2  DC    H'32'                                                    52800021
EIGHT    DC    H'8'                     LENGTH OF CCW           SA53223 52810001
OFFSET   DC    H'27'                    OFFSET FOR MSG VALUES   SA53223 52820001
*  THE FOLLOWING ARE 'BRCHVAL' BRANCH TABLE VALUES FOR IEHDEXCP SA53223 52850021
PROC04   EQU   X'00'                                            SA53223 52900021
DISKERR  EQU   X'04'                                            SA53223 52950021
TAPERR   EQU   X'08'                                            SA53223 53000021
OUT04    EQU   X'0C'                                            SA53223 53050021
MSG      EQU   X'10'                                            SA53223 53100021
FINISH   EQU   X'14'                                            SA53223 53110021
MULTI    EQU   X'18'                                            SA53223 53120021
*        END OF 'BRCHVAL' VALUES.                               SA53223 53150021
FOX0     EQU   X'0F'                    MASK FOR CHGING ZONE OF SA53223 53160021
*                                       CHAR BEFORE UNPKING.    SA53223 53180021
TAPMK    EQU   X'80'                                             A21395 53200021
GOOD     EQU   X'7F'                                                    53250021
DC       EQU   X'08'                   USED FOR DATA CHECKING TEST.3651 53300021
CCH      EQU   X'40'                   USED TO CHECK COMMAND CHAIN.3651 53350021
L2       EQU   2                        OFFSET CONSTANT         SA53223 53400021
L3       EQU   3                        OFFSET CONSTANT         SA53223 53450021
L8       EQU   8                        LENGTH CONSTANT         SA53223 53550021
MSG69    EQU   69                       ERROR MESSAGE VALUE     SA53223 53600021
D0       EQU   0                        OFFSET CONSTANT         SA53223 53610000
D12      EQU   12                       OFFSET CONSTANT         SA53223 53620000
D8       EQU   8                   DISP OF 8                     S20201 53650021
D4       EQU   4                        DISP OF 4               SA53223 53660021
X08      EQU   X'08'                   HEX CONSTANT.             S20201 53700021
RPSFEAT1 EQU   X'04'               RPS ON FROMDD                 S20201 53750021
TICCODE  EQU   X'08'               TIC CCW OP                    S20201 53800021
RPSFEAT  EQU   X'40'               RPS ON TODD                   S20201 53850021
D1       EQU   1                   DISP OF 1                     S20201 53900021
D3       EQU   3                        DISPL OF 3              Y02113  53950021
L4       EQU   4                        LENGTH OF 4             Y02113  54000021
TIMECHK  EQU   X'01'                    INDIC TIMESTAMP         Y02113  54050021
CLOCK    EQU   92                       F4DSCB TIMESTAMP DISPL  Y02113  54100021
*                                       INTO BUFFER             Y02113  54150021
SAVESLOT DS    1F                      FOR DOUBLE WORD ALIGNMENT.       54200021
CCHHADDR DS    1F                      SAVE AREA FOR CCHH OF IPL TRK.   54250021
AREA     DS    1F                      SAVE AREA FOR CCW LENGTH.  0811  54300021
CONVAD   DC    D'0'                     USED TO CONVERT CCHH    SA53223 54302001
         DC    X'0'                     USED WHEN UPACKING CCHH SA53223 54304001
LABEL1   DC    C'MAINTENANCE'           LABEL OF MAINT. AREA    SA53223 54310001
         DC    100F'0'                                                  54330001
LABEL2   DC    C'AREA'                  END OF MAINT. AREA      SA53223 54340001
         DS    0D                                                A37209 54350021
RDVOLBUF DS    CL92                     VOLID BUFFER             A37209 54400021
SRKEY    DC    X'0000000003'            RECORD THREE SEARCH      A37209 54450021
*                                       ARGUMENT                 A37209 54500021
         DS    0H                      HALF WORD ALIGHNMENT      A51474 54700021
ZERO     DC    6X'0'                   TWO BYTES OF ZEROS WILL   A51474 54750021
*                                      ALSO BE USED FROM THE     A51474 54800021
*                                      FOLLOWING CONSTANT.       A51474 54850021
F1       DC    F'1'                                                     54900021
         DS    0F                                                S20201 54950021
TICADDR  DC    X'000032E8'              TIC ADDR WITH NO RD CKD  S20201 55000021
         SPACE                                                          55050021
MSKFLGON DC    X'60000000'             SET CHAIN COMMAND AND SILI BITS  55100021
SCC2321  DC    X'00F60000'             INCREMENT TO NEXT SUBCELL.       55150021
STC2321  DC    X'0000FB00'             INCREMENT TO NEXT STRIP.         55200021
RPSBUF   DS    1F                                                S20201 55350021
TAPECCW5 CCW   X'1F',0,X'40',1         WTM.                             55400021
         CCW   3,0,X'20',24            NOOP-ALSO WRTS CNTRL REC AT EOV  55450021
         CCW   1,0,X'20',24            WRITE TRAILER RECORD.            55500021
         SPACE                                                          55550021
SEARIDEQ CCW   X'31',0,X'60',5         SEARCH ID EQUAL ON R0            55600021
         CCW   8,SEARIDEQ,X'60',5      TIC BACK.                        55650021
         CCW   6,0,X'60',8             READ R0 DATA.                    55700021
         CCW   X'9E',0,X'60',X'4000'   READ CKD R1               4074   55750021
*                                      WITH MAXIMUM COUNT               55800021
DUMMYCCW CCW   X'92',0,X'60',8         DUMMY READ COUNT CCW.            55850021
DMMYRCCW CCW   X'1E',0,X'60',0         DUMMY READ COUNT/KEY/DATA CCW    55900021
         SPACE 1                                                        55950021
HAR0CCW  CCW   7,X'0032AA',X'40',6     SEEK                             56000021
         CCW   X'1F',X'0031A6',X'40',1 SET FILE MASK                    56050021
HAR0CCW1 CCW   X'31',X'0032AC',X'60',5 SEARCH FOR R0.                   56100021
         CCW   8,X'0032D8',0,0         SEARCH UNTIL FOUND.              56150021
         CCW   5,X'003E18',X'60',8     WRITE R0 DATA.                   56200021
HAR0CCW2 CCW   X'31',X'0032AC',X'60',5 SEARCH FOR R0                    56250021
         CCW   8,X'0032F0',0,0         REPEAT UNTIL FOUND.              56300021
         CCW   6,X'003E18',X'70',8     READ BACK CHECK R0 DATA.         56350021
         CCW   X'11',X'000BF0',X'20',8 ERASE REST OF TRACK.             56400021
         EJECT                                                          56450021
R0R1CCWS CCW   7,X'0032AA',X'40',6     SEEK.                            56500021
         CCW   X'1F',X'0031A6',X'40',1 SET FILE MASK.                   56550021
CCWA     CCW   X'31',X'0032AC',X'60',5 SEARCH FOR R0                    56600021
         CCW   8,X'0032D8',0,0         REPEAT UNTIL FOUND.              56650021
         CCW   X'1D',X'003E20',X'60',X'FFFF' WRITE COUNT KEY DATA R1.   56700021
CCWB     CCW   X'31',X'0032AC',X'60',5 SEARCH FOR R0                    56750021
         CCW   8,X'0032F0',0,0         REPEAT UNTIL FOUND.              56800021
         CCW   5,X'003E18',X'60',8     WRITE DATA R0.                   56850021
         CCW   X'1E',X'003E20',X'70',X'FFFF' READ BACK CHECK R1.        56900021
CCWC     CCW   X'16',X'003E18',X'30',16      READ BACK CHECK R0 DATA.   56950021
         SPACE                                                          57000021
READVTOC CCW   X'31',0,X'60',5         SEARCH ON RECORD 1 OF VTOC.      57050021
         CCW   8,READVTOC,0,0          REPEAT UNTIL FOUND.              57100021
RDVDATA  CCW   6,0,X'20',96            READ FORMAT 4 DSCB.              57150021
*        CHANNEL PROGRAMS FOR SAVING OLD VOLID                          57200021
SRCHKEYR CCW   X'31',SRKEY,X'60',5      SEARCH ID EQUAL          A37209 57250021
         CCW   8,SRCHKEYR,0,0                                    A37209 57300021
         CCW   X'06',RDVOLBUF,X'20',92  READ IN VOLID            A37209 57350021
SRCHKEYW CCW   X'31',SRKEY,X'60',5      SEARCH ID EQUAL          A37209 57400021
         CCW   8,SRCHKEYW,0,0                                    A37209 57450021
         CCW   X'05',RDVOLBUF,X'20',92  WRITE OUT ORIGINAL VOLID A37209 57500021
TOTAL    DS    F'0'                                              A51474 57550021
EXCPSAVE DS    18F                      SAVE AREA                A37209 57600021
         SPACE                                                          57650021
* THIS IS USED TO WRITE HA, R0, R1 ONLY.                                57700021
R0CCWS   DSECT                                                          57750021
*   USED WHEN MODIFYING HA, R0 CCWS FOR EXECUTION.                      57800021
SEARCHR0 DS    2F                                                       57850021
TICBACK  DS    2F                                                       57900021
WRITER0  DS    2F                                                       57950021
SEARCH1  DS    2F                                                       58000021
TICAGAIN DS    2F                                                       58050021
READR0   DS    2F                                                       58100021
ERASEALL DS    2F                                                       58150021
READREC0 DS    2F                                                       58200021
         SPACE                                                          58250021
CCWS     DSECT                                                          58300021
SEIDEQR0 DS    CL8                                                      58350021
TICBACKA DS    CL8                                                      58400021
RDWRDATA DS    CL8                                                      58450021
RDWRTCKD DS    CL8                                                      58500021
RDWRTCNT DS    CL8                                                      58550021
         EJECT                                                          58600021
         IEHDWORK                                                       58650021
         EJECT                                                          58700021
IOBLOCKS DSECT                                                          58750021
* DUMP 'TO' ECB.                                                        58800021
TOECB    DS    1F                      WAIT//COMPLETE BITS PLUS CODE.   58850021
* DUMP 'TO' IOB.                                                        58900021
TOIOB    DS    0F                                                       58950021
TOFLGS   DS    CL2                     FLAGS ONE AND TWO.               59000021
TOSENSE  DS    CL2                     SENSE BYTES.                     59050021
TOECBAD  DS    1F                      ECB ADDRESS.                     59100021
TOSTATUS DS    2F                      CHANNEL STATUS.                  59150021
TOCCWAD  DS    1F                      CCW LIST ADDRESS.                59200021
TODCBAD  DS    1F                      DCB ADDRESS.                     59250021
TORESAD  DS    1F                      RESTART ADDRESS.                 59300021
TOBLKCNT DS    CL2                     BLOCK COUNT INCREMENT.           59350021
TOERROR  DS    CL2                     ERROR COUNT.                     59400021
TOSEEK   DS    2F                      MBBCCHHR.                        59450021
* DUMP 'TO' DCB.                                                        59500021
TODCB    DS    13F                     DCB.                             59550021
         DS    0D                      FOR DOUBLE WORD ALIGNMENT.       59600021
TAPECCW2 DS    1D                      USED TO PUT OUT CCW RECORD       59650021
*                                        AND DATA ON TAPE.              59700021
TAPECCW3 DS    2D                      WRITE HA,R0 CCWS ON TAPE.        59750021
TAPECCW4 DS    2D                      WRITE HA,R0,R1 CCWS ON TAPE.     59800021
         DS    0D                      FOR DOUBLE WORD ALIGNMENT.       59850021
* DUMP 'FROM' ECB.                                                      59900021
OUTECB   DS    1F                      WAIT//COMPLETE BITS PLUS CODE.   59950021
* DUMP 'FROM' IOB.                                                      60000021
OUTIOB   DS    0F                                                       60050021
OUTFLG   DS    CL2                     FLAGS ONE AND TWO.               60100021
OUTSENSE DS    CL2                     SENSE BYTES.                     60150021
OUTECBAD DS    1F                      ECB ADDRESS.                     60200021
OUTSTAT  DS    2F                      CHANNEL STATUS.                  60250021
OUTCCWAD DS    1F                      CCW LIST ADDRESS.                60300021
OUTDCBAD DS    1F                      DCB ADDRESS.                     60350021
OUTRESAD DS    1F                      RESTART ADDRESS.                 60400021
OUTBLKCT DS    CL2                     BLOCK COUNT INCREMENT.           60450021
OUTERROR DS    CL2                     ERROR COUNT.                     60500021
OUTSEEK  DS    2F                      7BBCCHHR.                        60550021
CCHH     EQU   OUTSEEK+3               CYLINDER/HEAD ADDRESS.           60600021
R        EQU   OUTSEEK+7               RECORD NUMBER.                   60650021
* DUMP 'FROM' DCB.                                                      60700021
OUTDCB   DS    18F                     DCB.                             60750021
         SPACE                                                          60800021
IOBLKEND DS    0H                      END OF IOBLOCKS DSECT.           60850021
DBSIZE   EQU   IOBLKEND-IOBLOCKS       SIZE OF IOBLOCKS DSECT.          60900021
         EJECT                                                          60950021
         SPACE 1                                                        61000021
         IEHDBLKS                                                       61050021
         EJECT                                                          61100021
         SPACE 2                                                        61150021
         SPACE                                                          61200021
TESTCNT  DSECT                                                  SA53223 61250021
         DS    CL5                      'CCHHR' OF COUNT FIELD  SA53223 61300021
TESTKEY  DS    CL1                      KEY LENGTH              SA53223 61350021
TESTDL   DS    H                        DATA LENGTH             SA53223 61400021
         SPACE                                                          61450021
RBUFFER  DSECT                                                          61500021
ZERO1    DS    CL8                     WILL CONTAIN 8 BYTES OF ZEROS.   61550021
CCWBUFF  EQU   ZERO1                                                    61600021
TICSW    DS    CL1                     'FF' INDICATES PREVIOUS CCW=TIC. 61650021
         DS    CL3                     NOT USED.                        61700021
ADDRESS  DS    CL4                     TEMPORARY ADDRESS HOLDER.        61750021
SEEKCCW  DS    CL8                     SEEK CCW FOR STAND-ALONE.        61800021
SETMASK  DS    CL8                     SET FILE MASK FOR STAND-ALONE.   61850021
SEARIDE  DS    CL8                     SEARCH EQUAL ID CCW.             61900021
         EJECT                                                          61950021
CVT      DSECT                                                          62000021
         CVT   SYS=MIN                                                  62050021
         EJECT                                                          62100021
UCB      DSECT                                                          62150021
         IEFUCBOB                                                       62200021
         EJECT                                                          62250021
JFCB     DSECT                                                          62300021
         IEFJFCBN                                                       62350021
         EJECT                                                          62400021
         DCBD  DSORG=PS                                                 62450021
         END                                                            62500021
