         COPY  LCGASMSW                                                 00092000
IEHDDUMP CSECT                                                          00100000
*        RELEASE 23 DELETIONS                                         * 00110020
*        RELEASE 22 DELETIONS                                         * 00130020
*        RELEASE 21 DELETIONS                                         * 00150020
*                                                       XA04592=SA69206 00150100
*584100-590400,593100-599400         SA65560 = OX2864 = OY2654          00150403
*600300,843000,843600                                                   00150803
*1244                                                            X02114 00151021
*462355,462359                                                   M0980  00152021
*1244462358                                                      A44482 00155021
*1244                                                            A42497 00160021
*        RELEASE 20 DELETIONS                                         * 00170020
*0910672300-674100                                               M4826  00172020
*0910844600                                                      M5900  00175020
*0910503100,504900,506700-507600                                 M5598  00180020
*0910462218-462274                                               A37209 00190020
*0910                                                            A33180 00220020
*0910902700                                                      A31384 00250020
*0910461700,464400                                               A34026 00270020
*0910158400,165600,354600,461735,461798,461994-462001,676800,    S20201 00280020
*0910593700-594000                                               A38120 00282020
*                                                                M0025  00285020
*0910678600,828900,829800,883800                                 S20201 00290020
*0910593400                                                      S20201 00290520
*0910233100-235800                                               M4998  00290720
*        RELEASE 19 DELETIONS                                           00291020
*2064593800                                                      A30268 00292020
*2064593230-593260                                               A29172 00293020
*2064                                                            M4513  00294020
*        RELEASE 18 DELETIONS                                           00295020
*3431594000-596700                                               1326   00296020
*3431584100-585000                                               2320   00297020
*3431287100-288000,592200,843300-844200                          2319   00298020
*STATUS CHANGE LEVEL 004                                                00328021
*                                                                     * 00360016
*FUNCTION/OPERATION- THIS ROUTINE IN CONJUNCTION WITH THE -IEHDEXCP-  * 00450016
*   AND -IEHDAOUT- ROUTINES HANDLES THE DUMP FUNCTION OF THE          * 00540016
*   IEHDASDR UTILITY PROGRAM. RESPONSIBILITY IS DIVIDED AS            * 00630016
*   FOLLOWS:                                                          * 00720016
*        IEHDDUMP- WILL PREPARE ALL INVOLVED DEVICES FOR PROCESSING   * 00810016
*                  AND OBTAIN CORE FOR THE BUFFER. UPON COMPLETION    * 00900016
*                  OF THE DUMP FUNCTION,WILL PERFORM HOUSEKEEPING     * 00990016
*                  FOR ALL INVOLVED DEVICES AND RELEASE THE BUFFER.   * 01080016
*                  CONTROL WILL THEN BE RETURNED TO THE MONITOR.      * 01170016
*        IEHDEXCP- WILL PERFORM ALL I/O OPERATIONS, PASSING CONTROL   * 01260016
*                  TO -IEHDAOUT- WHEN DUMPING TO A SYSTEM OUTPUT      * 01350016
*                  DEVICE. CONTROL WILL BE RETURNED TO -IEHDDUMP-     * 01440016
*                  UPON COMPLETION OF I/O PROCESSING.                 * 01530016
*        IEHDAOUT- WILL FORMAT AND DUMP ONE TRACK AT A TIME TO A      * 01620016
*                  SYSTEM OUTPUT DEVICE. CONTROL WILL BE RETURNED TO  * 01710016
*                  -IEHDEXCP-.                                        * 01800016
*                                                                     * 01890016
*   DUMP CONSISTS OF COPYING(DUMPING) DATA FROM ONE DIRECT ACCESS     * 01980016
*   DEVICE TO ONE OR MORE LIKE DIRECT ACCESS DEVICES, TO ONE OR MORE  * 02070016
*   TAPES, OR TO A SYSTEM OUTPUT DEVICE. ANY TAPES THUS CREATED CAN   * 02160016
*   THEN BE PROCESSED BY EITHER THE -IEHDASDR- UTILITY PROGRAM OR     * 02250016
*   THE STAND-ALONE DUMP/RESTORE PROGRAM(IBCDMPRS).                   * 02340016
*                                                                     * 02430016
*   THE -IEHDDUMP- ROUTINE LOCATES THE DEVICES BY USING THE DDNAMES   * 02520016
*   PASSED TO IT IN THE FUNCTION BLOCK. THIS ALLOWS THE ROUTINES TO   * 02610016
*   CONCURRENTLY PROCESS DUMP FUNCTIONS, AS EACH FUNCTION HAS         * 02700016
*   ASSOCIATED WITH ITS OWN I/O CONTROL BLOCKS. OPEN ON ALL DA        * 02790016
*   DEVICES IS DONE BY MEANS OF AN OPEN, TYPE=J ON THE FORMAT FOUR    * 02880016
*   DSCB.                                                             * 02970016
*                                                                     * 03060016
*   THE DATA ON THE DIRECT ACCESS DEVICE TO BE DUMPED(COPIED)         * 03150016
*   WILL BE READ IN ONE TRACK AT A TIME. ONLY THAT DATA               * 03240016
*   RESIDING ON TRACKS OWNED WILL BE COPIED. DATA OWNERSHIP           * 03330016
*   IS DETERMININED BY INTERROGATING THE FORMAT FIVE DSCB. WHEN       * 03420016
*   DUMPING DATA TO A SYSTEM OUTPUT DEVICE, THE ENTIRE RANGE OF       * 03510016
*   SPECIFIED TRACKS, OWNED AND UNOWNED, WILL BE DUMPED.              * 03600016
*                                                                     * 03690016
*ENTRY POINTS- THE ONLY ENTRY POINT IS -IEHDDUMP-, AND CONTROL        * 03780016
*   IS ALWAYS RECEIVED FROM THE MONITOR ROUTINE(IEHDASDS).            * 03870016
*                                                                     * 03960016
*INPUT- POINTERS TO A WORKAREA(REGISTER 12) AND TO A CONTROL          * 04050016
*   BLOCK(REGISTER 10).                                               * 04140016
*                                                                     * 04230016
*EXITS-NORMAL- A SUCCESSFUL DUMP OPERATION RESULTS IN A RETURN        * 04320016
*   TO THE MONITOR(IEHDASDS) WITH A RETURN CODE OF ZERO. A DUMP       * 04410016
*   COMPLETE MESSAGE IS ALSO PLACED IN THE MESSAGE DATA SET.          * 04500016
*                                                                     * 04590016
*EXITS-ERROR-  ANY ERROR ENCOUNTERED IS DESCRIBED BY AN APPROP-       * 04680016
*   IATE MESSAGE TO THE MESSAGE DATA SET. A RETURN CODE GREATER       * 04770016
*   THAN ZERO WILL ALSO BE PASSED TO THE MONITOR(IEHDASDS).           * 04860016
*                                                                     * 04950016
*                                                                     * 05040016
*EXTERNAL ROUTINES-  THIS ROUTINE IS ALWAYS ENTERED FROM THE          * 05130016
*   MONITOR ROUTINE(IEHDASDS). FOUR OTHER CSECTS ARE USED BY THIS     * 05220016
*   ROUTINE. ANY MESSAGES ISSUED WILL BE WRITTEN OUT BY THE MESSAGE   * 05310016
*   WRITER ROUTINE(IEHDPRNT) AFTER BEING SET UP BY THE MESSAGE        * 05400016
*   ROUTINE(IEHDMSGB). ALL CHECKING FOR DATA SET EXPIRATION DATES     * 05490016
*   AND PASSWORD PROTECTED DATA SETS IS DONE BY IEHDPASS.             * 05580016
*   THE OTHER CSECT USED BY THIS ROUTINE IS IEHDCONS WHICH            * 05670016
*   CONTAINS ALL OF THE DEVICE DEPENDENT CONSTANTS.                   * 05760016
*                                                                     * 05850016
*TABLES/WORK AREAS-  UPON ENTRY, REGISTERS 10 AND 12 POINT TO A       * 05940016
*   FUNCTION BLOCK AND WORK AREA RESPECTIVELY. THEY ARE DESCRIBED     * 06030016
*   IN THE DSECTS CALLED -FUNCBLK- AND -WORK-.                        * 06120016
*   THIS ROUTINE MUST ALSO SECURE ONE BUFFER FOR READING IN           * 06210016
*   DATA AND CREATION OF THE NECESSARY CCW LISTS AND/OR RECORDS.      * 06300016
*   THE BUFFER IS BROKEN DOWN INTO THE FOLLOWING AREAS-               * 06390016
*        CCWBUFPT-CREATION AND SET-UP OF THE RD CNT CCWS(M/T) OR      * 06480016
*        THE RD CKD CCWS.                                             * 06570016
*        WRTBUFPT-CREATION AND SET-UP OF THE WRT/RD CKD CCWS          * 06660016
*        (EXECUTED FOR DA OUTPUT OR WRITTEN AS A CCW RECORD FOR       * 06750016
*        TAPE OUTPUT).                                                * 06840016
*        CNTBUFPT-THE COUNTS FOR A PARTICULAR TRACK WILL BE           * 06930016
*        READ INTO THIS AREA.                                         * 07020016
*        DATBUFPT-THE DATA FOR A PARTICULAR TRACK WILL BE             * 07110016
*        READ INTO THIS AREA.                                         * 07200016
*        FORM5FPT-A TABLE OF THE UNOWNED EXTENTS FOR THE -FROM-       * 07290016
*        DA DEVICE.                                                   * 07380016
*                                                                     * 07470016
*   IF COPIES ARE BEING MADE, THERE WILL ALSO                         * 07560016
*   BE ONE OR MORE COPY BLOCKS CHAINED FROM THE FUNCTION BLOCK. SEE   * 07650016
*   THE -COPYBLK- DSECT FOR A DESCRIPTION.                            * 07740016
*                                                                     * 07830016
*ATTRIBUTES- SERIALLY REUSABLE, RELOCATABLE, NON-PRIVILEGED.          * 07920016
*                                                                     * 08010016
 TITLE 'IEHDDUMP-ENTRY POINT IEHDDUMP-IEHDASDR SYSTEM UTILITY PROGRAM'  08100016
*   THE FOLLOWING ARE REGISTER ASSIGNMENTS.                             08190016
GR0      EQU   0                                                        08280016
GR1      EQU   1                                                        08370016
GR2      EQU   2                                                        08460016
GR3      EQU   3                                                        08550016
GR4      EQU   4                                                        08640016
GR5      EQU   5                                                        08730016
GR6      EQU   6                                                        08820016
GR7      EQU   7                                                        08910016
GR8      EQU   8                                                        09000016
GR9      EQU   9                                                        09090016
GR10     EQU   10                                                       09180016
GR11     EQU   11                                                       09270016
GR12     EQU   12                                                       09360016
GR13     EQU   13                                                       09450016
GR14     EQU   14                                                       09540016
GR15     EQU   15                                                       09630016
RCVT     EQU   9                                                        09720016
UCBPTR   EQU   9                                                        09810016
BASEREG  EQU   11                                                       09900016
WORKBASE EQU   12                                                       09990016
         SPACE 2                                                        10080016
         USING FUNCBLK,10                                               10170016
         USING IEHDDUMP,BASEREG                                         10260016
         USING WORK,12                                                  10350016
         SPACE 1                                                        10440016
         SAVE  (14,12),T,*             SAVE THE REGISTERS.              10530016
         LR    BASEREG,GR15            LOAD THE BASE REGISTER.          10620016
         LA    GR7,DUMPSAVE            SAVE AREA ADDRESS                10710016
         ST    GR7,8(GR13)             ADDRESS OF NEW AREA TO OLD.      10800016
         ST    GR13,4(GR7)             ADDRESS OF OLD AREA TO NEW.      10890016
         LR    GR13,GR7                SAVE AREA FOR CALLED ROUTINES.   10980016
         L     GR3,PTRCFUNC            POINTER TO CURRENT FUNCTION.     11070016
         TM    0(GR3),PROCESS          PREVIOUSLY UNDER WAY.            11160016
         BZ    START2                  NO--START FROM THE BEGINNING.    11250016
         B     CALLEXCP                RETURN TO EXECUTING MODULE.      11340016
         EJECT                                                          11430016
*********************************************************************** 11520016
*                                                                     * 11610016
*   DETERMINE DIRECT DEVICE TYPE AND SET UP POINTER TO THE            * 11700016
*     PROPER DEVICE CONSTANTS FOR THIS DEVICE.                        * 11790016
*                                                                     * 11880016
*********************************************************************** 11970016
         SPACE 1                                                        12060016
         SPACE                                                          12150016
START2   L     GR8,FUCBPTR             UCB POINTER FOR 'FROM' DEVICE.   12240016
         CLI   IODEVCON,X'00'           HAVE WE ALREADY FIGURED  A42497 12260021
*                                       ADDRES                   A42497 12280021
         BNE   START4                   YES - DON'T RE-FIGURE    A42497 12300021
         USING UCB,8                                                    12330016
         CLI   UCBID,X'FF'             IS THIS A SUB UCB(2321).         12420016
         BNE   TO2321                  YES--GO TO PROCESS.              12510016
         TM    UCBTBYT3,UCB3DACC       IS THIS A DIRECT ACCESS DEVICE.  12600016
         BZ    BADPARM                 NO--MUST BE BAD PARAMETER.       12690016
START3   SR    GR3,GR3                 CLEAR WORK REGISTER.             12780016
         AIF   ('&LIB' EQ 'LIB1').NOWIN BRCH IF OS ASSEM        XL03130 12830003
         CLI   UCBTBYT4,WINCH           WINCHESTER DEVICE ?     XL03130 12840003
         BNE   NOWIN                    NO, BRCH                XL03130 12850003
         IC    GR3,IDEVMOD              PICKUP WINCH MODEL NO.  XL03130 12860003
         B     YESWIN                   BRCH AROUND OS CODE     XL03130 12862003
NOWIN    EQU   *                                                XL03130 12864003
.NOWIN   ANOP                                                   XL03130 12866003
         IC    GR3,UCBTBYT4            UCB DEVICE TYPE CODE.            12870016
YESWIN   EQU   *                                                XL03130 12920003
         LA    GR5,KDEVSIZE            SIZE OF EACH DEVICE ENTRY.       12960016
         BCTR  GR3,0                   DECREMENT FOR INDEX.             13050016
         MR    GR4,GR3                 ENTRY SIZE TIMES INDEX VALUE.    13140016
         L     GR4,IODEVCON            BEGIN ADDRESS OF DEVICE CONSTANT 13230016
         AR    GR4,GR5                 ADDRESS OF CONSTANTS THIS DEVICE 13320016
         ST    GR4,IODEVCON            SAVE IN FUNCTION BLOCK.          13410016
         MVC   IODEVCON(1),UCBTBYT4     UCB DEVICE TYPE CODE.           13500016
         TM    UCBTBYT2,RPS            RPS FEATURE ON FROMDD.    S20201 13520020
         BZ    START4                  NO-BRANCH.                S20201 13540020
         OI    SEQSW,FEATURE1          YES-SET RPS SWITCH.       S20201 13560020
         B     START4                  GO TO GET CORE FOR BUFFERS.      13590016
         SPACE                                                          13680016
TO2321   BAL   GR14,CONVUCB            CONVERT SUB UCB TO MAIN.         13770016
         B     START3                  GO TO GET DEVICE TYPE.           13860016
         SPACE                                                          13950016
CONVUCB  LH    GR5,0(GR8)              BIN NUMBER.                      14040016
         SLA   GR5,4                   TIMES SIXTEEN.                   14130016
         LA    GR5,DATACELL-UCBOB(GR5) ADD LENGTH OF MAIN.              14220016
         LCR   GR5,GR5                 NEGATE.                          14310016
         AR    GR8,GR5                 ADDRESS OF MAIN UCB.             14400016
         BR    GR14                    RETURN TO CALLER.                14490016
         DROP  8                                                        14580016
         SPACE                                                          14670016
         EJECT                                                          14760016
*********************************************************************** 14850016
*                                                                     * 14940016
*   THIS SECTION ATTEMPTS TO OBTAIN CORE FOR ONE BUFFER TO BE USED    * 15030016
*     FOR CCW PROCESSING AND DATA READ IN FROM THE DIRECT ACCESS      * 15120016
*     DEVICE. IF NO BUFFER IS OBTAINED, THE 'NOCORE' SWITCH IS SET    * 15210016
*     FOR THIS FUNCTION.                                              * 15300016
*                                                                     * 15390016
*********************************************************************** 15480016
         USING CONSTANT,GR9                                             15570016
START4   L     GR9,IODEVCON            ADDRESSING FOR DEVICE CONSTANTS. 15660016
         LH    GR2,BUFFSIZE            SIZE PER BUFFER/THIS DEVICE.     15750016
         LA    GR3,RPSBUFPT            SAVE ADDRESS OF BUFFER    S20201 15810020
*                                       HERE.                    S20201 15870020
         GETMAIN EC,LV=(2),A=(3)       GET CORE FOR BUFFER.             15930016
         LTR   GR15,GR15               WAS CORE AVAILABLE.              16020016
         BZ    BUFFOK                  YES--GO TO SET UP BUFFER PTRS.   16110016
         L     GR3,PTRCFUNC            NO--POINTER TO CURRENT FUNCTION. 16200016
         OI    0(GR3),WAITING+NOCORE   INDICATE NO CORE AVAILABLE.      16290016
         LA    GR15,4                  SET UP RETURN CODE.              16380016
         B     FINAL3                  RETURN TO MONITOR.               16470016
BUFFOK   EQU   *                                                 S20201 16500020
         L     GR3,RPSBUFPT            ADDRESS OF DUMP BUFFER.   S20201 16530020
         LA    GR3,D16(GR3)            INCREMENT TO POINT TO     S20201 16560020
         ST    GR3,CCWBUFPT              CCW BUFFER.             S20201 16590020
         AH    GR3,RCCWSIZE            ADD SIZE OF CCW BUFFER.          16650016
         ST    GR3,WRTBUFPT            SAVE POINTER TO WRTCCWS.         16740016
         AH    GR3,WRTSIZE             ADD SIZE OF WRT-RD CKD CCWS.     16830016
         ST    GR3,CNTBUFPT            SAVE POINTER TO COUNT BUFFER.    16920016
         AH    GR3,CNTSIZE             ADD SIZE OF COUNT BUFFER.        17010016
         ST    GR3,DATBUFPT            SAVE POINTER TO DATA BUFFER.     17100016
         AH    GR3,DATASIZE            ADD SIZE OF DATA BUFFER.         17190016
         ST    GR3,FORM5FPT            SAVE POINTER TO FORMAT 5 AREA.   17280016
CLEAR    L     GR1,DATBUFPT            BEGINNING OF DATA BUFFER.        17370016
         LH    GR3,DATASIZE            LENGTH OF DATA BUFFER.           17460016
         LA    GR2,255                 SET LENGTH FOR EXEC.             17550016
         MVI   0(GR1),C' '             PRIME FIRST BYTE FOR EXEC.       17640016
EXEC     CR    GR3,GR2                 THIS THE LAST MOVE.              17730016
         BNH   LASTEXEC                YES--DO ONE MORE MOVE.           17820016
         EX    GR2,MOVE                MOVE 256 BYTES.                  17910016
         LA    GR1,256(GR1)            INCREMENT DATA BUFF POINTER.     18000016
         SH    GR3,TWO56               UPDATE BYTE COUNT.               18090016
         B     EXEC                    RETURN TO CHECK POINT.           18180016
LASTEXEC EX    GR3,MOVE                CLEAR REMAINING PORTION.         18270016
         DROP  9                                                        18360016
         EJECT                                                          18450016
*********************************************************************** 18540016
*                                                                     * 18630016
*   THIS SECTION WILL SET UP THE 'FROM' DA IOBLOCKS (ECB,IOB,DCB)     * 18720016
*   IN THE FUNCTION BLOCK. THE DEB FIELDS WILL ALSO BE FILLED IN.     * 18810016
*   THE 'TO' DEVICE TYPE WILL BE DETERMINED AND THE CORRESPONDING     * 18900016
*     IOBLOCKS MOVED INTO THE FUNCTION BLOCK.                         * 18990016
*                                                                     * 19080016
*********************************************************************** 19170016
         SPACE 2                                                        19260016
         USING IOBLOCKS,9                                               19350016
SETUPBLK LA    GR9,BLOCKS              ADDRESSING FOR PRIMARY I/O BLKS. 19440016
         MVC   OUTECB(WBLKSIZE),WRTECB   SET UP 'FROM' DA I/O BLOCKS.   19530016
         LA    GR3,OUTECB              GET ADDRESS OF ECB.              19620016
         ST    GR3,OUTECBAD            SAVE ECB ADDRESS IN IOB.         19710016
         LA    GR3,OUTDCB              GET DCB ADDRESS.                 19800016
         ST    GR3,OUTDCBAD            SAVE DCB ADDRESS IN IOB.         19890016
         USING IHADCB,GR3                                               19980016
         MVC   DCBDDNAM(8),DDNAME1     MOVE DDNAME TO DCB.              20070016
         ST    GR10,DCBIOBAD           FUNCTION BLOCK ADDRESS TO DCB.   20160016
         MVC   OPENLD+1(3),OUTDCBAD+1  DA DCB NAME TO OPEN LIST.        20250016
         SPACE                                                          20340016
         BAL   GR14,OPENJ              GO TO OPEN 'FROM' DA DEVICE.     20430016
         L     GR3,FUCBPTR             UCB PTR. FOR 'FROM' DEVICE.      20520016
         USING UCB,3                                                    20610016
         CLI   UCBID,X'FF'             IS THIS A SUB UCB(2321).         20700016
         BE    SETUP                   NO--FORGET ABOUT BIN NUMBER.     20790016
         MVC   OUTSEEK+1(2),0(GR3)     BIN NUMBER.                      20880016
         DROP  3                                                        20970016
         SPACE                                                          21060016
         USING CONSTANT,9              ADDRESSING FOR DEVICE CONSTANT   21150016
SETUP    L     GR9,IODEVCON            ADDRESSING FOR DEVICE CONSTANTS. 21240016
         MVI   DUMPSW,X'F0'            SET SWITCH TO INDICATE FULL DUMP 21330016
         MVC   CCHHONE(4),CCHHBEG      LOWER LIMIT TO 1ST TRK DUMPED.   21420016
         TM    SEQSW,BEGIN             IS BEGINNING TRACK SPECIFIED.    21510016
         BZ    TESTEND                 NO--CHECK IF END ADDR SPECIFIED. 21600016
         MVI   DUMPSW,X'00'            SET SWITCH FOR PARTIAL DUMP.     21690016
         MVC   DUMPWORK(4),CCHHBEG     MOVE IN LOWER LIMIT.             21780016
         BAL   GR14,TRKVALID           GO CHECK FOR VALID LIMIT.        21870016
TESTEND  TM    SEQSW,END               IS ENDING TRACK SPECIFIED.       21960016
         BZ    FULLDUMP                NO--SET TO END OF PRIMARY TRKS.  22050016
         MVI   DUMPSW,X'00'            SET SWITCH FOR PARTIAL DUMP.     22140016
         MVC   DUMPWORK(4),CCHHEND     YES--MOVE IN UPPER LIMIT.        22230016
         BAL   GR14,TRKVALID           GO CHECK IF VALID LIMIT.         22320016
         CLC   CCHHBEG(4),CCHHEND      BEGIN ADDR HIGHER THAN END.      22410016
         BH    INVALTRK                YES--GO TO WRITE ERROR MSG.      22500016
         B     UPDATE                  GO TO UPDATE LAST TRK SPECIFIED. 22590016
FULLDUMP MVC   CCHHEND(4),LASTORIG     FULL DUMP-MOVE IN LAST PRIMARY.  22680016
UPDATE   BAL   GR14,UPCCHH             GO TO ADD ONE TO UPPER LIMIT     22770016
         DROP  9                                                        22860016
         USING UCB,8                                                    22950016
         USING IOBLOCKS,9                                               23040016
TESTTODD L     GR8,TUCBPTR             UCB PTR. FOR 'TO' DEVICE.        23130016
         LA    GR9,BLOCKS              PRIMARY I/O BLOCKS.              23220016
         CLC   SYSOUTDD(8),DDNAME2      IS IT SYSOUT             M4998  23280020
         BE    SETSW1                   YES - CHECK FOR COPIES   M4998  23340020
         CLI   UCBID,X'FF'              2321                     M4998  23400020
         BNE   SETUPDA                  YES - GO SET UP          M4998  23460020
         B     TESTTO                   CHECK IF TAPE            M4998  23520020
SETSW1   EQU   *                                                 M4998  23580020
         OC    COPYPTR(4),COPYPTR      YES--WERE COPIES REQUESTED.      23670016
         BZ    SETSW                   NO--GO SET SWITCHES.             23760016
         L     GR3,COPYPTR             YES--SET PTR TO DDNAME3.         23850016
         B     COPYERR1                GO PRINT MSG, TERMINATE.         23940016
SETSW    OI    DEVSW,X'F0'             SET SWITCHES TO INDICATE         24030016
         OI    SWITCH,DUMPALL            DUMPING TO SYSOUT.             24120016
         B     LINKPASS                GO CHK FOR PASSWORD DATASETS.    24210016
TESTTO   TM    UCBTBYT3,UCB3TAPE       TAPE DEVICE.                     24300016
         BO    SETUPTAP                YES--INITIALIZE FOR TAPE.        24390016
         TM    UCBTBYT3,UCB3DACC       DIRECT ACCESS.                   24480016
         BZ    BADDEV                  NO--GO PRINT MSG, TERMINATE.     24570016
TESTDA   CLC   UCBTBYT4(1),IODEVCON    FROM AND TO SAME DEVICE TYPE.    24660016
         AIF   ('&LIB' EQ 'LIB1').DDUMP00 BR IF OS ASSEMBLY             24670000
         BE    SAMET                    BRCH IF LIKE DEVICES    XL03145 24710003
         CLI   IODEVCON,MERLN           IS FROMDD A MERLIN ?    XL03145 24720003
         BNE   BADDEV                   NO, GO TEST FOR WINCH.  XL03145 24730003
         CLI   UCBTBYT4,ICEBG           IS TODD AN ICEBERG      XL03145 24740003
.DDUMP00 ANOP                                                           24740100
         BNE   BADDEV                  GO TO PRINT MSG,TERMINATE.       24740403
         AIF   ('&LIB' EQ 'LIB1').DDUMP02 BR IF OS ASSEMBLY             24740800
         B     SETDOS                   BRCH IF ICEBERG         XL03145 24742003
SAMET    EQU   *                                                XL03145 24744003
         CLI   UCBTBYT4,WINCH           WINCHESTER DEVICE ?     XL03130 24744403
         BNE   TESTSYSR                 NO, TEST FOR SYSRES DEV XL03130 24744803
         CLC   IDEVMOD,ODEVMOD          COMPARE I/O DEV TYPES   XL03130 24746003
         BH    BADDEV                   GIVE ERROR MSG IF I/P   XL03130 24748003
         BE    TESTSYSR                 BRCH IF EQUAL MODELS    XL03130 24748103
*                                       DEVICE BIGGER THAN O/P XL03145  24748203
SETDOS   EQU   *                                                XL03130 24748303
         OI    FLGBYT1,DOSBIT           SET SWT FOR LATER TEST  XL03130 24748403
.DDUMP02 ANOP                                                           24798400
TESTSYSR TM    SRTESTAT,SRTESYSR       THIS IS SYSTEM RESIDENCE VOL.    24840016
         BO    INVALTO                 YES--THIS IS NOT ALLOWED.        24930016
         TM    UCBTBYT2,RPS            RPS FEATURE ON TODD.      S20201 24950020
         BZ    SETUPDA                 NO-BRANCH                 S20201 24970020
         OI    SEQSW+D1,FEATURE        YES-SET RPS SWITCH.       S20201 24990020
         DROP  8                                                        25020016
         SPACE 2                                                        25110016
*  IF DUMPING TO DIRECT ACCESS, SET UP I/O BLOCKS HERE.                 25200016
         SPACE                                                          25290016
SETUPDA  OI    DEVSW,X'FF'             SET DA SWITCH IN FUNCTION BLOCK. 25380016
         MVC   TOECB(WBLKSIZE),WRTECB  SET UP 'TO' DA BLOCK IN FUNC BLK 25470016
         LA    GR3,TOECB               GET 'TO' ECB ADDRESS             25560016
         ST    GR3,TOECBAD             SAVE IN IOB.                     25650016
         LA    GR3,TODCB               ADDRESS OF DCB.                  25740016
         ST    GR3,TODCBAD             SAVE IN IOB.                     25830016
         USING IHADCB,GR3                                               25920016
         MVC   DCBDDNAM(8),DDNAME2     MOVE DDNAME TO DCB.              26010016
         MVC   OPENLD+1(3),TODCBAD+1   DA DCB FOR OPEN LIST.            26100016
         ST    GR10,DCBIOBAD           STORE FUNCTION BLOCK PTR.        26190016
         SPACE 1                                                        26280016
         BAL   GR14,OPENJ              GO TO READ JFCB.                 26370016
         LA    GR9,BLOCKS              ADDRESSING FOR PRIMARY DEVICES.  26460016
         SPACE                                                          26550016
         BAL   GR14,FORMAT4            GO READ IN FORMAT 4.             26640016
         SPACE                                                          26730016
         MVC   ALTDATA(6),0(GR3)       SAVE ALTERNATE DATA.             26820016
         MVC   NOCYL,D10(GR3)           COPY TODD NO. OF CYL.   XL03130 26870003
         OC    COPYPTR(4),COPYPTR      ARE THERE COPIES.                26910016
         BZ    MORE2                   NO--GO CHK FOR PASSWORD DATASETS 27000016
         B     COPYPROC                YES-GO SET UP FOR COPIES.        27090016
         SPACE 2                                                        27180016
*  IF DUMPING TO TAPE, SET UP I/O BLOCKS HERE.                          27270016
         SPACE                                                          27360016
SETUPTAP MVC   TOECB(DTBLKSIZ),DTECB   'TO' TAPE I/O BLKS TO FUNCBLK.   27450016
         LA    GR3,TOECB               ADDRESS OF ECB.                  27540016
         ST    GR3,TOECBAD             SAVE IN IOB.                     27630016
         LA    GR3,TODCB               SAVE ADDRESS OF DCB              27720016
         ST    GR3,TODCBAD             IN IOB.                          27810016
         MVC   DCBDDNAM(8),DDNAME2     MOVE DDNAME TO DCB.              27900016
         DROP  3                                                        27990016
*  SET UP CONTROL RECORD FOR OUTPUT TO TAPE.                            28080016
         SR    GR3,GR3                 CLEAR WORK REGISTER.             28170016
         IC    GR3,IODEVCON            UCB DEVICE TYPE CODE.            28260016
         LA    GR3,CODES-1(GR3)        ADDRESS S/A D/R DEV TYPE CODE.   28350016
         MVC   CONTROL+21(1),0(GR3)    MOVE DEV TYPE CODE TO CTRL REC.  28440016
         MVC   CONTROL+12(8),RESTCODE  RESTORE TAPE CODE TO CTRL REC.   28530016
         AIF   ('&LIB' EQ 'LIB1').DDUMP04  BR IF OS ASSEMBLY            28540000
         MVC   DEVMOD,IDEVMOD           MOVE IN WINCH MODEL #   XL03130 28580003
.DDUMP04 ANOP                                                           28590000
         LA    GR3,CONTROL             PTR TO CONTROL RECORD.           28620016
         ST    GR3,TAPECCW5            POINTER INTO CCW.           2319 28680018
         MVI   TAPECCW5,X'01'          RESET OP CODE.              2319 28740018
         L     GR8,TUCBPTR             UCB POINTER.                1326 28800018
         BAL   GR2,OPENT               GO TO OPEN ON TAPE,WRT CTRL REC. 28890016
         MVC   REELCK(4),REELCTRL      INITIALIZE TRAILER INFO.         28980016
         OC    COPYPTR(4),COPYPTR      ARE THERE COPIES.                29070016
         BZ    MORE2                   NO--GO TO PROCESS FORMAT 5.      29160016
         EJECT                                                          29250016
*********************************************************************** 29340016
*                                                                     * 29430016
*   THIS SECTION WILL SET UP THE IOBLOCKS (ECB,IOB,DCB) AND THEN      * 29520016
*   OPEN THE DEVICES SPECIFIED IN THE COPY BLOCKS. IF THE 'TO'        * 29610016
*   DEVICES ARE INCONSISTENT, THE FUNCTION WILL BE TERMINATED.        * 29700016
*                                                                     * 29790016
*********************************************************************** 29880016
         SPACE                                                          29970016
         USING COPYBLK,7                                                30060016
         USING UCB,8                                                    30150016
         USING IOBLOCKS,9                                               30240016
COPYPROC L     GR7,COPYPTR             ADDRESSING FOR COPY BLOCK.       30330016
COPYP1   L     GR8,CUCBPTR             UCB PTR. FOR THIS COPY.          30420016
         LA    GR9,CIOBLOCK            ADDRESS OF COPY I/O BLOCK.       30510016
         CLI   UCBID,X'FF'             IS THIS A SUB UCB.(2321).        30600016
         BE    COPYP2                  NO--MAIN UCB--GO TO PROCESS.     30690016
         BAL   GR14,CONVUCB            GO TO CONVERT SUB UCB TO MAIN.   30780016
COPYP2   TM    UCBTBYT3,UCB3TAPE       THIS A TAPE DEVICE.              30870016
         BO    TAPECOPY                YES--INITIALIZE FOR TAPE.        30960016
         TM    UCBTBYT3,UCB3DACC       IS THIS DIRECT ACCESS DEVICE.    31050016
         BZ    BADDEV1                 ALL OTHER=ERROR.                 31140016
         CLI   DEVSW,X'FF'             WAS PRIMARY 'TO' DA.             31230016
         BNE   COPYERR                 GO TO PRINT MSG,TERMINATE.       31320016
         CLC   UCBTBYT4(1),IODEVCON    ARE FROM AND TO DEVICES ALIKE.   31410016
         AIF   ('&LIB' EQ 'LIB1').DDUMP06 BR IF OS ASSEMBLY             31460000
         BE    SAME                     BRCH IF LIKE DEVICES    XL03145 31542003
         CLI   IODEVCON,MERLN           IS FROMDD A MERLIN ?    XL03145 31552003
         BNE   COPYERR                  NO, GO TEST FOR WINCH.  XL03145 31562003
         CLI   UCBTBYT4,ICEBG           IS TODD AN ICEBERG      XL03145 31572003
         BNE   COPYERR                 GO TO PRINT MSG,TERMINATE.       31582003
         B     TSTSYSR                  BRCH IF ICEBERG         XL03145 31584003
SAME     EQU   *                                                XL03145 31586003
         CLI   UCBTBYT4,WINCH           WINCHESTER DEVICE ?     XL03130 31588003
         BNE   TSTSYSR                  NO, TEST FOR SYSRES DEV XL03130 31588403
         CLC   ODEVMOD,CDEVMOD          COMPARE O/P DEV TYPES   XL03130 31588803
.DDUMP06 ANOP                                                           31588900
         BNE   COPYERR                  GIVE ERROR MSG IF O/P   XL03130 31589203
*                                       DEVICE MODELS DIFFER.   XL03130 31589603
TSTSYSR  EQU   *                                                XL03145 31589703
         TM    SRTESTAT,SRTESYSR       THIS A SYSTEM RESIDENCE VOLUME.  31590016
         BO    CINVALTO                YES--THIS IS NOT ALLOWED.        31680016
         TM    SEQSW+D1,FEATURE       *RPS ON PRIMARY TODD.      S20201 31690020
         BZ    COPYP3                 *NO-BRANCH.                S20201 31700020
         TM    UCBTBYT2,RPS           *RPS ON THIS TODD          S20201 31710020
         BO    COPYP3                 *YES-SWITCH ALREADY SET.   S20201 31720020
         NI    SEQSW+D1,SWOFF         *NO-SET SWITCH OFF         S20201 31730020
COPYP3   EQU   *                                                 S20201 31740020
         SPACE                                                          31770016
*  SET UP DIRECT ACCESS I/O COPY BLOCKS HERE.                           31860016
         MVC   TOECB(WBLKSIZE),WRTECB   'TO' DA CTRL BLKS TO COPYBLK.   31950016
         LA    GR3,TOECB               GET 'TO' ECB ADDRESS.            32040016
         ST    GR3,TOECBAD             SAVE IN IOB.                     32130016
         LA    GR3,TODCB               ADDRESS OF DCB.                  32220016
         USING IHADCB,GR3                                               32310016
         ST    GR3,TODCBAD             SAVE IN IOB.                     32400016
         MVC   DCBDDNAM(8),DDNAME3     MOVE DDNAME TO DCB.              32490016
         ST    GR10,DCBIOBAD           STORE FUNCTION BLOCK PTR.        32580016
         MVC   OPENLD+1(3),TODCBAD+1   DA DCB TO OPEN LIST.             32670016
         SPACE                                                          32760016
         BAL   GR14,OPENJ              GO TO READ JFCB.                 32850016
         SPACE                                                          32940016
         LA    GR9,CIOBLOCK            I/O BLOCKS FOR COPY.             33030016
         SPACE                                                          33120016
         BAL   GR14,FORMAT4            GO READ IN THE FORMAT 4.         33210016
         SPACE                                                          33300016
         MVC   CALTDATA(6),0(GR3)      SAVE ALTERNATE DATA.             33390016
         B     MORECOPY                GO TO SEE IF MOVE COPY BLOCKS.   33480016
         EJECT                                                          33570016
         SPACE                                                          33660016
*  SET UP TAPE I/O COPY BLOCKS HERE.                                    33750016
TAPECOPY CLI   DEVSW,X'00'             DUMPING TO TAPE.                 33840016
         BNE   COPYERR                 NO--INVALID COPY REQUEST.        33930016
         MVC   TOECB(DTBLKSIZ),DTECB   'TO' TAPE CTRL BLKS TO COPYBLK.  34020016
         LA    GR3,TOECB               ADDRESS OF ECB.                  34110016
         ST    GR3,TOECBAD             SAVE IN IOB.                     34200016
         LA    GR3,TODCB               SAVE ADDRESS OF DCB              34290016
         ST    GR3,TODCBAD                IN IOB.                       34380016
         MVC   DCBDDNAM(8),DDNAME3     MOVE DDNAME TO DCB.              34470016
         DROP  GR3                                                      34560016
         L     GR8,CUCBPTR             COPY UCB POINTER.           1326 34600018
         BAL   GR2,OPENT               GO TO OPEN TAPE, WRT CTRL REC.   34650016
         MVC   CREELCK(4),REELCTRL     INITIALIZE TRAILER INFO.         34740016
MORECOPY L     GR7,CCOPYPTR            ADDRESS NEXT COPY BLOCK,IF ANY.  34830016
         LTR   GR7,GR7                 ANY MORE COPY BLOCK POINTERS.    34920016
         BP    COPYP1                  YES--GO PROCESS NEXT COPY.       35010016
MORE2    LA    GR9,BLOCKS              ADDRESSING FOR PRIMARY I/O BLKS. 35100016
         CLI   DEVSW,X'00'             DUMPING TO TAPE.                 35190016
         BNE   LINKPASS                NO--NO WAIT TODAY--.             35280016
         BAL   GR14,WAITTO             WAIT ON EXCP OF CONTROL RECORD.  35370016
LINKPASS EQU   *                        *                        S20201 35380020
         TM    SEQSW,FEATURE1          RPS FEATURE ON FROMDD.    S20201 35390020
         BO    LINKP                   YES-BRANCH.               S20201 35400020
         TM    SEQSW+D1,FEATURE        RPS FEATURE ON TODD.      S20201 35410020
         BZ    LINKP1                  NO-BRANCH.                S20201 35420020
LINKP    EQU   *                                                 S20201 35430020
         L     GR1,RPSBUFPT            PTR TO RPS BUFFER.        S20201 35440020
         MVC   D0(L16,GR1),SETCCW      MOVE SET SECTOR AND TIC   S20201 35450020
*                                        CCWS TO RPS BUFFER.            35460020
LINKP1   EQU   *                                                 S20201 35470020
         L     GR1,CCWBUFPT            PTR TO BUFFER FOR         S20201 35480020
*                                       PASSWORD.                S20201 35490020
         LINK  EP=IEHDPASS             CHK PASSWORD DS,EXPIRATION DTES  35550016
         LTR   GR15,GR15               RETURN OK.                       35640016
         BZ    CALLEXCP                YES--GO TO IEHDEXCP              35730099
         ST    GR15,DUMPWORK           TEMPORARY STORAGE FOR RET. CODE. 35820016
         BAL   GR14,CLOSEOUT           GO TO CLOSE ALL DUMP DCBS.       35910016
         BAL   GR14,FINALR1            GO TO FREE UP BUFFER.            36000016
         L     GR15,DUMPWORK           RESTORE RETURN CODE.             36090016
         B     FINAL3                  RETURN TO THE MONITOR.           36180016
         DROP  7,8                                                      36230000
         SPACE                                                          45540016
CALLEXCP CALL  IEHDEXCP                                                 45630016
         L     GR3,PTRCFUNC            POINTER TO CURRENT FUNCTION.     45720016
         TM    0(GR3),COMPLETE         IS THIS FUNCTION COMPLETE.       45810016
         BO    EOJ                     YES--GO TO CLOSE AND FREE BUFFS. 45900016
         LA    GR15,0                  SET RETURN CODE FOR MONITOR.     45990016
         B     FINAL3                  GO TO RETURN.                    46080016
EOJ      EQU   *                                                 A34026 46110020
         ST    GR15,COMPCODE           SAVE RETURN CODE.         A34026 46140020
FINISH   CLI   DEVSW,X'FF'             DUMPING TO DA.            M4513  46170719
         BNE   EOJ1                    NO--GO TO CLOSE DEBS      M4513  46171419
         LA    GR9,BLOCKS         ADDR OF PRIMARY I/O BLKS.      M4513  46172119
         L     GR8,TUCBPTR        UCB PTR FOR PRIMARY 'TO'       M4513  46172819
         L     GR3,FORM5FPT        GET F5 POINTER                S20201 46173220
         MVC   2(6,GR3),ALTDATA    AND PUT IN ALT TRK DATA       S20201 46173620
         LA    GR3,DDNAME2             DDNAME OF TO DEVICE.      M4513  46174219
         BAL   GR2,RDVOLID        GO TO UPDATE ALT TRK INFO      M4513  46174919
         OC    COPYPTR(4),COPYPTR    ARE COPIES BEING MADE       M4513  46175619
         BZ    EOJ1              NO-ONLY ONE OUTPUT VOL.         M4513  46176319
         L     GR3,COPYPTR             ADDR 1ST COPY.            M4513  46177019
         USING COPYBLK,GR3                                       M4513  46177719
CFINIS   LA    GR9,CIOBLOCK            ADDR OF COPY I/O BLK      M4513  46178419
         L     GR8,CUCBPTR             PTR TO UCB FOR COPY.      M4513  46179119
         L     GR2,FORM5FPT        GET F5 POINTER                S20201 46179520
         MVC   2(6,GR2),ALTDATA    AND PUT IN ALT TRK DATA       S20201 46179920
         BAL   GR2,RDVOLID             GO TO UPDATE ALT TRK      M4513  46180519
         OC    CCOPYPTR(4),CCOPYPTR    MORE 'DA' COPIES.         M4513  46181219
         BZ    EOJ1                NO-CLOSE AND FREE BUFFS.      M4513  46181919
         L     GR3,CCOPYPTR            ADDR NEXT COPYBLK.        M4513  46182619
         B     CFINIS                  GO PROCESS THIS COPY      M4513  46183319
*********************************************************************** 46184019
*                                                                     * 46184719
* THIS ROUTINE READS IN THE VOL LABEL OF THE DIRECT ACCESS            * 46185419
*     DEVICE. IF THE OLD SER NO. IS TO BE RETAINED AND IT IS          * 46186119
*     DIFFERENT THAN THE NEW SER NUMBER, THE VOL LABEL IS             * 46186819
*     REWRITTEN WITH THE OLD SER NUMBER. THIS ROUTINE ALSO            * 46187519
*     UPDATES THE ALT TRK INFROMATION FIELDS IN THE FORMAT4           * 46188219
*     DSCB.                                                           * 46188919
*                                                                     * 46189619
*        REG 8 MUST POINT TO THE UCB FOR THE DA DEVICE.               * 46190319
*        REG 9 MUST POINT TO THE DA CONTROL BLOCKS                    * 46191019
*          UPON ENTRY.                                                * 46191719
*        REGISTERS 4,7 ARE WORK REGISTERS.                            * 46192419
*        REGISTER 2 IS THE RETURN REGISTER.                           * 46193119
*                                                                     * 46193819
*********************************************************************** 46194519
         USING UCB,GR8                                           M4513  46195219
         USING IOBLOCKS,9                                        M4513  46195919
RDVOLID  XC    TOSEEK+3(5),TOSEEK+3    CLEAR SEARCH ARGUMENT.    M4513  46196619
         LA    GR7,TOSEEK+3            SEARCH ADDRESS.           M4513  46197319
         ST    GR7,READVTOC            PLACE IN SEARCH CCW.      M4513  46198019
         MVI   READVTOC,X'31'          RESET OP CODE.            M4513  46198719
         LA    GR7,READVTOC                                      S20201 46198920
         TM    SEQSW+D1,FEATURE        TODD HAVE RPS FEATURE.    S20201 46199120
         BZ    RDVOLIDA                NO-BRANCH.                S20201 46199320
         ST    GR7,TIC                 SET UP TIC/TO ADDRESS.    S20201 46199520
         LA    GR7,SETCCW              YES-POINT TO SET SECTOR   S20201 46199720
         MVI   K8(GR7),TICCODE         RESET TIC OP CODE.        S20201 46199920
*                                         CCW FOR IOB.                  46200120
RDVOLIDA EQU   *                        *                        S20201 46200320
         ST    GR7,TOCCWAD                                       S20201 46200520
         L     GR7,DATBUFPT            READ IN AREA.             M4513  46200819
         ST    GR7,RDVDATA             BUFF PTR TO READ CCW      M4513  46201519
         CLI   UCBTBYT4,X'01'          THIS A 2311.              M4513  46202219
         BNE   RDVOLID1            NO-DON'T CHECK IPL TEXT.      M4513  46202919
         MVI   TOSEEK+6,1              SET SEARCH FOR TRK 1      M4513  46203619
         LA    GR4,RDVDATA             CCW ADDRESS.              M4513  46204319
         ST    GR4,TOCCWAD             STORE IN IOB.             M4513  46205019
         MVI   RDVDATA,X'16'       SET OP CODE FOR READ R0.      M4513  46205719
         BAL   GR4,VOLEXCP           GO RAD IN CNT FLD R0.       M4513  46206419
         MVC   CCHHADDR(4),0(GR7)      SAVE CCHH OF IPL TRK      M4513  46207119
         MVI   TOSEEK+6,0              SET FOR TRACK 0.          M4513  46207819
         MVI   TOSEEK+7,2              SET FOR RECORD 2.         M4513  46208519
         LA    GR4,READVTOC            CCW ADDRESS.              M4513  46209219
         ST    GR4,TOCCWAD             STORE IN IOB.             M4513  46209919
         MVI   RDVDATA,6         SET OP CODE FOR READ DATA       M4513  46210619
         BAL   GR4,VOLEXCP             READ IN TRK 0/ RCD 2      M4513  46211319
         MVC   34(4,GR7),CCHHADDR      SEEK BOOTSTRAP ADDR       M4513  46212019
         MVI   RDVDATA,5         SET OP CODE FOR WRITE.          M4513  46212719
         BAL   GR4,VOLEXCP             GO REWRITE RECORD 2.      M4513  46213419
RDVOLID1 MVI   RDVDATA,6           SET OP CODE FOR READ.         M4513  46214119
         MVI   TOSEEK+7,3              SET SEARCH FOR RCD 3      M4513  46214819
         BAL   GR4,VOLEXCP             GO READ IN VOL LABEL      M4513  46215519
         CLC   UCBSKA+3(4),TOSEEK+3  DOES TRK 0 HAVE AN ALT      M4513  46216219
         BE    TRACKOK                 NO--CONTINUE              M4513  46216919
         LA    GR1,28                  TRK 0 DEFECTIVE MSG.      M4513  46217619
        BAL   GR4,SETUPMSG            GO TO SET UP TMSG.         M4513  46218319
         MVC   0(8,GR1),0(GR3)         DDNAME TO MSG.            M4513  46219019
         BAL   GR4,MSGWRT1             GO TO PRINT THIS MSG      M4513  46219719
TRACKOK  EQU   *                                                 M4513  46220419
         USING VLABEL,GR7                                        M4513  46221119
         CLI   IODEVCON,X'05'           IS THIS A 2321           A52430 46221500
         BE    IS2321                   NO, BRANCH AROUND        A52430 46221600
         TM    SEQSW,CPYVOLID           USE VOLID ON 'FROM' DISK A37209 46221820
         BNO   UPDATE4                  NO, KEEP ORIGINAL VOLID  A37209 46222520
         L     GR4,FUCBPTR              GET UCB PTR TO 'FROM'    A37209 46223220
*                                       DISK                     A37209 46223920
         MVC   SERIAL(6),28(GR4)        MOVE IN 'FROM' VOLID     A52430 46226700
GO2321   MVI   RDVDATA,5           SET CCW OP CODE TO WRITE      A52430 46228100
         BAL   GR4,VOLEXCP             REWRITE THE LABEL.        M4513  46228819
UPDATE4  L     GR1,CNTBUFPT            TEMPORARY STORAGE         M4513  46229519
         MVC   0(6,GR1),SERIAL             FOR SER NUMBER.       M4513  46230219
         MVC   TOSEEK+3(5),VTOCPTR     NEW VTOC ADDR IN IOB      M4513  46230919
         CLC   TOSEEK+3(4),CCHHBEG     VTOC ADDR GT FIRST        M4513  46231619
         BL    POSTUCB                  TRK THIS DUMP//NO.       M4513  46232319
         CLC   TOSEEK+3(4),CCHHEND     VTOC ADDR LT UPPER        M4513  46233019
         BNL   POSTUCB                  LIMIT//NO-POST UCB.      M4513  46233719
         MVI   RDVDATA,6               SET CCW CODE TO READ      M4513  46234419
         BAL   GR4,VOLEXCP        GO READ IN FORMAT 4 DSCB.      M4513  46235119
M0980    L     GR4,FORM5FPT             MOVE IN SAVED ALT.       M0980  46235521
         MVC   8(6,GR7),2(GR4)          TRACK INFORMATION        M0980  46235921
         AIF   ('&LIB' EQ 'LIB1').VSAM01 BRCH IF OS ASSEM Y02113        46236000
         MVC   D18(L2,GR7),NOCYL        MOVE TODD CYL NO.       XL03130 46236203
         TM    FLGBYT1,DOSBIT           SWT SET FOR DOS CONTAM  XL03130 46244303
         BNO   NODOS                    NO, BRCH                XL03130 46246303
         OI    D14(GR7),DOSCON          SET DOS CONTAM BIT      XL03130 46248303
NODOS    EQU   *                                                XL03130 46250303
         STCK  CLOCK(GR7)               STORE TIMESTAMP IN F4   Y02113  46257003
*                                       DSCB                            46263103
.VSAM01  ANOP                                                   Y02113  46269203
         MVI   RDVDATA,5         SET CCW OP CODE FOR WRITE       M4513  46275303
         BAL   GR4,VOLEXCP       GO REWRITE FORMAT 4 DSCB.       M4513  46281403
* POST UCB HERE.                                                        46287503
POSTUCB  ST    GR8,POSTLIST           UCB ADDR TO PARM LIST      M4513  46293603
         L     GR1,CNTBUFPT           TEMPORARY SER STORAGE      M4513  46299703
         ST    GR1,POSTLIST+4          NO. TO PARM LIST.         M4513  46305803
         LA    GR1,TOSEEK              VTOC POINTER.             M4513  46311903
         ST    GR1,POSTLIST+8          POINTER TO PARM LIST      M4513  46318003
         MVI   POSTLIST,X'08'          'POST' CODE FOR SVC.      M4513  46324103
         MVI   POSTLIST+8,X'80'        SET LIST ENTRY BIT.       M4513  46330203
         CNOP  0,4                                               M4513  46336303
         BAL   GR1,POST              PARM LIST ADDR FOR SVC      M4513  46342403
POSTLIST DC    F'0'                    UCB ADDRESS.              M4513  46348503
         DC    F'0'                    SERIAL NUMBER ADDR.       M4513  46354603
         DC    F'0'                    VTOC ADDRESS.             M4513  46360703
POST     SVC   POSTSER                 GO UPDATE UCBS.           M4513  46366803
POSTSER  EQU   82                      SVC NUMBER.               M4513  46372903
         BR    GR2                     RETURN TO CALLER.         M4513  46379003
IS2321   TM    SEQSW,CPYVOLID           USE VOLID ON 'FROM' DISK A52430 46385103
         BO    UPDATE4                  YES                      A52430 46391203
         LA    GR4,DCELVOLI-DATACELL(GR8)                        A52430 46397303
         MVC   SERIAL(6),0(GR4)                                  A52430 46403403
         B     GO2321                                            A52430 46409503
         DROP  7,8                                               A52430 46415603
EOJ1     EQU   *                                                 A52430 46421703
         BAL   GR14,CLOSEOUT           GO TO CLOSE ALL DUMP DCBS.       46427803
         BAL   GR14,FINALR1            GO TO FREE BUFFER, IF ANY.       46433903
         L     GR15,COMPCODE           RESTORE RETURM CODE.      A34026 46440020
         LTR   GR15,GR15               RETURN CODE ZERO.                46530016
         BZ    FINALR2                 YES--GO TO PUT OUT MESSAGE.      46620016
         B     UNUSABLE                NO---GO PUT OUT UNUSABLE MSG.    46710016
VOLEXCP  EXCP  TOIOB                   EXECUTE CHANNEL PROG      M4513  46720019
         WAIT  ECB=TOECB                                         A33180 46725020
         CLI   TOECB,GOOD              ALL OK.                   M4513  46730019
         BCR   8,GR4                   YES-RETURN.               M4513  46740019
         B     IOTERR                                            M4513  46750019
         DROP  9                                                        46800016
         EJECT                                                          46890016
         USING IOBLOCKS,9                                               46980016
WAITDISK LA    GR9,BLOCKS                                               47070016
         TM    OUTECB,COMPLETE         IS THE OPERATION COMPLETE        47160016
         BO    TESTD                   YES--GO TEST THE STATUS.         47250016
         WAIT  ECB=OUTECB              NO--AWAIT COMPLETION OF DISK.    47340016
         SPACE                                                          47430016
TESTD    CLI   OUTECB,GOOD             ALL OK.                          47520016
         BNE   IOERR                   NO--I/O ERROR                    47610016
         BR    GR14                    YES--RETURN                      47700016
         SPACE                                                          47790016
WAITTO   LA    GR9,BLOCKS              ADDRESSING FOR PRIMARY DEVICES.  47880016
         BAL   GR4,WAIT2               GO TO AWAIT COMPLETION.          47970016
         OC    COPYPTR(4),COPYPTR      ARE COPIES BEING MADE.           48060016
         BCR   8,GR14                  NO--RETURN.                      48150016
         L     GR8,COPYPTR             YES-ADDRESS OF FIRST COPY BLOCK. 48240016
         USING COPYBLK,GR8                                              48330016
WAIT1    LA    GR9,CIOBLOCK            I/O BLOCKS FOR COPY.             48420016
         BAL   GR4,WAIT2               AWAIT COMPLETION OF THIS COPY.   48510016
         OC    CCOPYPTR(4),CCOPYPTR    ARE THERE MORE COPIES.           48600016
         BC    8,WAIT1A                NO--RETURN.                      48690016
         L     GR8,CCOPYPTR            YES-ADDRESS NEXT COPY BLOCK.     48780016
         B     WAIT1                   GO WAIT ON NEXT COPY.            48870016
WAIT1A   LA    GR9,BLOCKS              ADDRESSING FOR PRIMARY I/O BLKS  48960016
         BR    GR14                    RETURN TO CALLER.                49050016
         SPACE                                                          49140016
WAIT2    TM    TOECB,COMPLETE          IS THE OPERATION COMPLETE.       49230016
         BO    TESTT                   YES--GO TEST THE STATUS.         49320016
         WAIT  ECB=TOECB               NO--AWAIT COMPLETION             49410016
         SPACE 1                                                        49500016
TESTT    CLI   TOECB,GOOD              ALL OK.                          49590016
         BNE   IOTERR                  NO--I/O ERROR.                   49680016
         BR    GR4                     RETURN.                          49770016
         SPACE                                                          49860016
         SPACE 1                                                        49950016
         USING CONSTANT,9                                               50040016
TRKVALID CLC   DUMPWORK(1),LASTORIG      COMPARE EACH BYTE              50130016
         BH    INVALTRK                  OF REQUESTED EXTENTS           50220016
         BE    CHEKREST                THAT'S O.K. TOO.            0969 50230017
         CLI   LASTALT,X'13'           THIS A 2321.                0969 50240017
         BNE   CHEKREST                NO-BRANCH.                  0969 50250017
         CLC   DUMPWORK+1(1),LASTALT+1  CKECK REQUEST.             0969 50260017
         BH    INVALTRK                INVALID REQUEST.            0969 50270017
         B     CHKREST                 CONTINUE CHECKING.          0969 50280017
CHEKREST EQU   *                                                   0969 50290017
         CLC   DUMPWORK(2),LASTORIG     COMPARE CC               M5598  50340020
         BH    INVALTRK                  A PARTIAL DUMP. IF ANY         50400016
CHKREST  EQU   *                                                   0969 50440017
         CLC   DUMPWORK+2(2),LASTORIG+2 COMPARE HH               M5598  50510020
         BH    INVALTRK                  HIGHER THAN THE CCHH OF        50580016
         BR    GR14                    RETURN TO CALLER IF LIMIT OKAY.  50850016
         EJECT                                                          50940016
*********************************************************************** 51030016
*                                                                     * 51120016
*   THE FOLLOWING ROUTINE UPDATES THE TRACK ADDRESS FOR SETTING       * 51210016
*   LIMITS FOR THE DUMP OPERATION.                                    * 51300016
*                                                                     * 51390016
*   REGISTER 9 POINTS TO THE CORRECT IOBLOCK.                         * 51480016
*   REGISTER 14 IS THE RETURN REGISTER.                               * 51570016
*                                                                     * 51660016
*********************************************************************** 51750016
         SPACE 2                                                        51840016
         USING IOBLOCKS,GR9                                             51930016
         USING CONSTANT,2                                               52020016
UPCCHH   L     GR2,IODEVCON            ADDRESSING FOR DEVICE CONSTANT.  52110016
         L     GR3,CCHHEND             CURRENT CCHH ADDRESS.            52200016
         CLC   CCHHEND+3(1),LASTORIG+3  THIS LAST TRACK OF CYLINDER.    52290016
         BC    4,UPCCHH1               NO--                             52380016
         A     GR3,CONVCYL             YES,STEP TO NEXT CYLINDER.       52470016
         SPACE 2                                                        52560016
CK2321   CLI   CCHHEND+2,X'04'         IS THIS 2321 AND LAST CYLINDER.  52650016
         BC    7,UPCCHH2               NO--RETURN.                      52740016
         AL    GR3,STC2321             INCREMENT STRIP.                 52830016
         CLI   CCHHEND+1,X'09'         THIS LAST STRIP.                 52920016
         BC    7,UPCCHH2               NO--RETURN.                      53010016
         AL    GR3,SCC2321             INCREMENT SUBCELL.               53100016
         B     UPCCHH2                 GO STORE VALUE AND RETURN.       53190016
         SPACE                                                          53280016
UPCCHH1  AL    GR3,F1                  INCREMENT TO NEXT TRACK.         53370016
UPCCHH2  ST    GR3,CCHHEND             SAVE NEW VALUE.                  53460016
         BR    14                      RETURN.                          53550016
         DROP  2                                                        53640016
         EJECT                                                          53730016
*********************************************************************** 53820016
*                                                                     * 53910016
*  THIS ROUTINE OPENS THE DATA CONTROL BLOCKS FOR ALL DIRECT ACCESS   * 54000016
*     DEVICES INVOLVED. THE OPEN IS ALWAYS PERFORMED ON THE FORMAT    * 54090016
*     FOUR DSCB OF THE VTOC.                                          * 54180016
*                                                                     * 54270016
*        REGISTER 14 IS THE RETURN REGISTER.                          * 54360016
*                                                                     * 54450016
*********************************************************************** 54540016
         SPACE                                                          54630016
         SPACE 3                                                        54720016
OPENJ    MVC   LIST+1(3),CCWBUFPT+1    BUFFER ADDRESS TO READ JFCB.     54810016
         RDJFCB MF=(E,OPENLD)                                           54900016
         L     GR8,CCWBUFPT            ADDRESS JFCB WAS READ INTO.      54990016
         USING JFCB,8                                                   55080016
         MVI   JFCBDSNM,X'04'          SET DSNAME FIELD FOR             55170016
         MVC   JFCBDSNM+1(43),JFCBDSNM   FORMAT 4 DSCB.                 55260016
         OI    JFCBTSDM,X'08'          PREVENT WRITING BACK JFCB.       55350016
         OPEN  MF=(E,OPENLD),TYPE=J                                     55440016
         DROP  8                                                        55530016
         L     GR8,OPENLD              DISK DCB ADDRESS                 55620016
         USING IHADCB,8                                                 55710016
         TM    DCBOFLGS,X'10'          WAS THERE A SUCCESSFUL OPEN.     55800016
         BZ    NOOPEN                  NO--GIVE AN ERROR MESSAGE        55890016
         NI    DCBMACRF+1,X'F3'        SET BITS OFF TO PREVENT CLOSE    55980016
*                                        FROM WRITING AN EOF RECORD     56070016
*                                        AND UPDATING THE DSCB.         56160016
         BR    GR14                    RETURN.                          56250016
         DROP  8                                                        56340016
         EJECT                                                          56430016
*********************************************************************** 56520016
*  THIS ROUTINE OPENS THE DATA CONTROL BLOCKS FOR ALL TAPE DEVICES.   * 56610016
*     UPON SUCCESSFUL OPEN, THE CONTROL RECORD WILL BE WRITTEN ON     * 56700016
*     THE TAPE.                                                       * 56790016
*                                                                     * 56880016
*        REGISTER 9 MUST POINT TO THE CORRECT IOBLOCKS.               * 56970016
*        REGISTER 8 MUST POINT TO THE UCB.                        1326* 57010018
*        REGISTERS 3,8 ARE WORK REGISTERS.                            * 57060016
*        REGISTER 2 IS THE RETURN REGISTER.                           * 57150016
*********************************************************************** 57240016
         USING IOBLOCKS,GR9                                             57330016
         USING UCB,8                                               1326 57370018
OPENT    MVC   OPENLT+1(3),TODCBAD+1   TAPE DCB ADDRESS TO OPEN LIST.   57420016
         LH    GR3,SRTEFSCT            TAPE DATA SET SEQUENCE COUNT1326 57450018
         DROP  8                                                   1326 57480018
         OPEN  MF=(E,OPENLT)           OPEN TAPE DCB.                   57510016
         L     GR8,OPENLT              TAPE DCB ADDRESS.                57600016
         USING IHADCB,8                                                 57690016
         TM    DCBOFLGS,X'10'          WAS THERE A SUCCESSFUL OPEN.     57780016
         BZ    NOOPEN                  NO--GIVE AN ERROR MESSAGE.       57870016
         DROP  8                                                        57960016
         MVC   LIST+1(3),CCWBUFPT+1    BUFFER ADDRESS TO RD JFCB.       58050016
         RDJFCB MF=(E,OPENLT)          READ JFCB.                       58140016
         L     GR8,CCWBUFPT            ADDRESS OF READ-IN JFCB.         58230016
         USING JFCB,8                                                   58320016
         TM    JFCBIND2,X'10'          SECURITY PROTECTED.              58950016
         BZ    WRTCNTRL                NO--GO TO PROCESS.        OX2864 59040003
         OI    SWITCH,PASSSW+STDLABEL  SET PASSWORD PROTECT SWITCH.     59130016
WRTCNTRL LA    GR3,TAPECCW5            CCW ADDRESS.                     60120016
WRTTM    EQU   *                                                   2319 60160018
         ST    GR3,TOCCWAD             STORE CCW ADDRESS IN IOB.        60210016
         EXCP  TOIOB                   PUT CONTROL RECORD ON TAPE.      60300016
         BR    GR2                     RETURN.                          60390016
         EJECT                                                          60480016
*********************************************************************** 60570016
*                                                                     * 60660016
*   THIS SECTION READS IN THE FORMAT 4 DSCB FROM THE VTOC.              60750016
*   THE ALTERNATE TRACK INFORMATION IS SAVED FOR THAT VOLUME.         * 60840016
*                                                                     * 60930016
*   REGISTER 3 WILL RETURN A POINTER TO THE 6 BYTES OF ALTERNATE DATA.* 61020016
*   REGISTER 9 MUST POINT TO THE I/O CONTROL BLOCKS FOR THIS DEVICE.  * 61110016
*   REGISTER 14 IS THE RETURN REGISTER.                               * 61200016
*                                                                     * 61290016
*********************************************************************** 61380016
         SPACE 1                                                        61470016
         USING IOBLOCKS,9                                               61560016
         USING IHADCB,GR8                                               61650016
FORMAT4  LA    GR8,TODCB               ADDRESS OF DCB.                  61740016
         L     GR1,DCBDEBAD            ADDRESS OF DEB.                  61830016
         MVC   TOSEEK+3(4),38(GR1)     CCHH OF VTOC TO IOB.             61920016
         CLI   IODEVCON,X'05'          IS THIS A 2321.                  62010016
         BNE   SETR                    NO--FORGET ABOUT BIN NUMBER.     62100016
         MVC   TOSEEK+1(2),36(GR1)     BIN NO. TO IOB FROM DEB.         62190016
SETR     MVI   TOSEEK+7,X'01'          SET R OF CCHHR FOR FORMAT4 DSCB. 62280016
         LA    GR3,TOSEEK+3            SEARCH ADDRESS.                  62370016
         ST    GR3,READVTOC            SEARCH ADDRESS TO SEARCH CCW.    62460016
         MVI   READVTOC,X'31'          RESET CCW OP CODE.               62550016
         LA    GR3,READVTOC            CCW ADDRESS//READ VTOC.          62640016
         TM    SEQSW+D1,FEATURE        TODD HAVE RPS FEATURE.    S20201 62650020
         BZ    SETRR                   NO-BRANCH                 S20201 62660020
         ST    GR3,TIC                 YES-RESET TIC ADDRESS.    S20201 62670020
         MVI   TIC,TICCODE             RESET TIC OP CODE.        S20201 62680020
         LA    GR3,SETCCW              POINT TO SET SECTOR CCW.  S20201 62690020
SETRR    EQU   *                        *                        S20201 62700020
         ST    GR3,TOCCWAD             SET UP IOB.                      62730016
         L     GR3,CCWBUFPT            ADDRESS OF BUFFER.               62820016
         ST    GR3,RDVDATA             STORE ADDRESS IN READ CCW.       62910016
         LA    GR3,RDVDATA             ADDRESS OF READ CCW.             63000016
         MVI   0(GR3),X'06'            RESET OP CODE.                   63090016
         EXCP  TOIOB                   READ IN THE FORMAT 4 DSCB.       63180016
         WAIT  ECB=TOECB               WAIT COMPLETION.                 63270016
         CLI   TOECB,GOOD              ANY ERRORS.                      63360016
         BNE   IOERR                   YESS--GO GIVE MESAAGE.           63450016
         MVC   TOSEEK+3(5),ZERO        ZERO 'CCHHR' OF SEARCH ARGUMENT. 63540016
         L     GR3,RDVDATA             ADDRESS OF FORMAT 4 DATA.        63630016
         LA    GR3,8(GR3)              ADDRESS OF ALTERNATE DATA.       63720016
         BR    GR14                    RETURN.                          63810016
         DROP  8,9                                                      63900016
         EJECT                                                          63990016
*********************************************************************** 64080016
*                                                                     * 64170016
*   THIS ROUTINE CLOSES THE DATA CONTROL BLOCKS FOR ALL DEVICES       * 64260016
*     (DIRECT ACCESS AND TAPE, IF ANY). IF THE DCBS HAVE NOT BEEN     * 64350016
*     OPENED WHEN THIS ROUTINE IS CALLED, NO ACTION IS PERFORMED.     * 64440016
*        REGISTERS 4,5,8,9 ARE WORK REGISTERS.                        * 64530016
*        REGISTER 2 IS THE RETURN REGISTER.                           * 64620016
*                                                                     * 64710016
*********************************************************************** 64800016
         SPACE                                                          64890016
         USING IOBLOCKS,9                                               64980016
         USING IHADCB,5                                                 65070016
CLOSEOUT LA    GR9,BLOCKS              ADDRESS OF BASIC I/O BLOCKS.     65160016
         L     GR5,OUTDCBAD            ADDRESS OF FROM DCB.             65250016
         TM    DCBOFLGS,X'10'          DEVICE EVER OPENED.              65340016
         BCR   8,GR14                  NO--RETURN TO CALLER.            65430016
         BAL   GR4,CLOSE1              GO TO CLOSE THIS DCB.            65520016
         CLI   DEVSW,X'F0'             DUMPING TO SYSOUT.               65610016
         BCR   8,GR14                  YES--RETURN TO CALLER.           65700016
         L     GR5,TODCBAD             TO DCB ADDRESS.                  65790016
         BAL   GR4,CLOSE               GO TO CLOSE THIS DCB.            65880016
         OC    COPYPTR(4),COPYPTR      COPIES REQUESTED.                65970016
         BCR   8,GR14                  NO--RETURN TO CALLER.            66060016
         L     GR8,COPYPTR             ADDR THIS COPY BLOCK.            66150016
         USING COPYBLK,GR8                                              66240016
CLOSEA   LA    GR9,CIOBLOCK            ADDR COPY I/O BLOCK.             66330016
         L     GR5,TODCBAD             ADDR. THIS COPY DCB.             66420016
         BAL   GR4,CLOSE               GO CLOSE THIS DCB.               66510016
         OC    CCOPYPTR(4),CCOPYPTR    MORE COPIES.                     66600016
         BCR   8,GR14                  NO--RETURN TO CALLER.            66690016
         L     GR8,CCOPYPTR            PTR. TO NEXT COPY BLOCK.         66780016
         B     CLOSEA                  CLOSE TILL ALL DCBS PROCESSED.   66870016
         SPACE                                                          66960016
CLOSE    TM    DCBOFLGS,X'10'          DEVICE EVER OPENED.              67050016
         BCR   8,GR4                   NO--RETURN.                      67140016
CLOSE1   EQU   *                                                 M4826  67170020
         CLI   DEVSW,X'00'         DUMPING TO TAPE               M4826  67200020
         BNE   CLOSEDA             NO                            M4826  67230020
         CLOSE ((5),REWIND)                                      M4826  67260020
         BR    GR4                 RETURN                        M4826  67290020
CLOSEDA  EQU   *                                                 M4826  67320020
         CLOSE ((5))                                             M4826  67350020
         BR    GR4                                               M4826  67380020
         DROP  GR5,GR8                                           M4826  67410020
         EJECT                                                          67500016
*   THIS SECTION FREES THE CORE THAT WAS USED FOR BUFFERS.              67590016
FINALR1  EQU   *                        *                        S20201 67650020
         CLC   RPSBUFPT(L4),ZERO       ANY BUFFERS ASSIGNED.     S20201 67710020
         BCR   8,GR14                  NO--RETURN.                      67770016
         L     GR1,RPSBUFPT            ADDRESS OF BUFFER.        S20201 67860020
         USING CONSTANT,2                                               67950016
FREEBUF  L     GR2,IODEVCON            ADDRESS OF DEVICE CONSTANTS.     68040016
         LH    GR0,BUFFSIZE            BUFFER SIZE.                     68130016
         FREEMAIN R,LV=(0),A=(1)                                        68220016
         BR    GR14                    RETURN TO CALLER.                68310016
         SPACE                                                          68400016
FINALR2  MVC   FORM5FPT(8),DDNAME2     DDNAME OF PRIMARY 'TO'.          68490016
         L     GR8,TUCBPTR             UCB PTR FOR PRIMARY 'TO'.        68580016
         BAL   GR7,FINALOUT            GO TO SET UP AND PRINT MSG.      68670016
         OC    COPYPTR(4),COPYPTR      ARE THERE COPIES.                68760016
         BZ    FINALR7                 NO--GO TO RETURN TO MONITOR.     68850016
         L     GR3,COPYPTR             YES--PTR TO FIRST OR ONLY COPY.  68940016
         USING COPYBLK,3                                                69030016
FINALR3  MVC   FORM5FPT(8),DDNAME3     DDNAME FOR THIS COPY.            69120016
         L     GR8,CUCBPTR             UCB PTR FOR THIS COPY.           69210016
         BAL   GR7,FINALOUT            GO TO SET UP AND PRINT THIS MSG  69300016
         OC    CCOPYPTR(4),CCOPYPTR    MORE COPIES.                     69390016
         BZ    FINALR7                 NO--GO TO RETURN TO THE MONITOR  69480016
         L     GR3,CCOPYPTR            PTR TO NEXT COPY.                69570016
         B     FINALR3                 GO TO PROCESS.                   69660016
         SPACE 2                                                        69750016
FINALOUT LA    GR1,6                   DUMP COMPLETION MESSAGE.         69840016
         BAL   GR2,SETUPMSG            GO TO SET UP THIS MESSAGE.       69930016
         MVC   MESS+9(7),DUMPTO        'DUMP TO' INTO MESSAGE.          70020016
         MVC   0(8,GR1),FORM5FPT       DDNAME TO MESSAGE.               70110016
         CLI   DEVSW,X'FF'             DUMPING TO DIRECT ACCESS.        70200016
         BNE   FINALR5                 NO--GO TO BLANK SERIAL REF.      70290016
         CLI   IODEVCON,X'05'          IS THIS 2321              A52430 70340000
         BE    FIXMSG                  YES, FIX MSG FOR 2321     A52430 70350000
         TM    SEQSW,CPYVOLID          DID WE RETAIN NEW SERIAL.        70380016
         BZ    FINALR4A                NO--DO NOT ALTER UCB PTR. A52430 70470000
         USING UCB,8                                                    70560016
         L     GR8,FUCBPTR             YES--FROM DEVICE UCB PTR.        70650016
FINALR4A MVC   40(6,GR1),SRTEVOLI      VOLID TO MESSAGE.         A52430 70700000
         B     FINALR6                 GO TO PRINT THIS MESSAGE. A52430 70710000
FIXMSG   TM    SEQSW,CPYVOLID          DO WE RETAIN OLD SERIAL   A52430 70740000
         BZ    TOBIN                   YES, GO GET TO SUB UCB    A52430 70790000
         L     GR8,FUCBPTR             NO, GET FROM SUB UCB      A52430 70830000
TOBIN    MVC   40(6,GR1),4(GR8)        SET VOLID TO MESSAGE      A52430 70970000
         B     FINALR6                 GO PRINT THIS MESSAGE     A52430 70980000
FINALR5  MVC   22(18,GR1),21(GR1)      BLANKOUT VOLID REF IF TAPE OUT.  71190016
FINALR6  BAL   GR9,MSGWRT1             GO TO PRINT THIS MESSAGE.        71280016
         BR    GR7                     RETURN TO CALLER                 71370016
         EJECT                                                          71460016
FINALR7  LA    GR15,0                  SET UP RETURN CODE.              71550016
         CLI   RCODE,X'FF'             WAS FORMAT 5 BAD.                71640016
         BNE   FINAL3                  NO--BRANCH.                      71730016
         LA    GR15,4                  YES--RESET RETURN CODE.          71820016
FINAL3   L     GR13,DUMPSAVE+4         RESTORE REGISTER 13.             71910016
         RETURN (14,12),T,RC=(15)      RESTORE/RETURN WITH PROPER CODE. 72000016
         SPACE 2                                                        72090016
         EJECT                                                          72180016
*********************************************************************** 72270016
*                                                                     * 72360016
*   THIS SECTION SETS UP THE PROPER MESSAGES AND LINKS TO THE         * 72450016
*   MESSAGE WRITER TO OUTPUT ANY MESSAGES.                            * 72540016
*                                                                     * 72630016
*********************************************************************** 72720016
         SPACE 1                                                        72810016
BADPARM  LA    GR1,19                  FROMDD IS NOT DIRECT ACCESS.     72900016
         LA    GR3,DDNAME1             DDNAME FOR MESSAGE.              72990016
         BAL   GR2,SETUPMSG            GO TO SET UP THIS MESSAGE.       73080016
         B     MSGOUT                  GO TO PRINT THIS MESSAGE.        73170016
         SPACE                                                          73260016
         USING IHADCB,8                                                 73350016
NOOPEN   LA    GR1,5                   DEVICE CANNOT BE OPENED.         73440016
         LA    GR3,DCBDDNAM            DDNAME FOR MESSAGE.              73530016
         BAL   GR2,SETUPMSG            GO TO SET UP THIS MESSAGE.       73620016
         B     MSGOUT                  GO TO PRINT THIS MESSAGE.        73710016
         SPACE                                                          73800016
         SPACE                                                          73890016
BADDEV   LA    GR3,DDNAME2             DDNAME FOR MESSAGE.              73980016
         B     BADDEV2                 GO TO SET UP FOR THIS MESS AGE.  74070016
BADDEV1  LR    GR3,GR7                 POINT TO DDNAME FOR MESSAGE.     74160016
BADDEV2  LA    GR1,20                  INVALID DUMP TO DEV SPECIFIED.   74250016
         BAL   GR2,SETUPMSG            GO TO SET UP THIS MESSAGE.       74340016
         B     MSGOUT                  GO TO PRINT THIS MESSAGE.        74430016
         SPACE                                                          74520016
COPYERR  LR    GR3,GR7                 POINT TO DDNAME FOR MESSAGE.     74610016
COPYERR1 LA    GR1,21                  INCONSISTENT COPY DEVICES.       74700016
         BAL   GR2,SETUPMSG            GO TO SET UP THIS MESSAGE.       74790016
         B     MSGOUT                  GO TO PRINT THIS MESSAGE.        74880016
         SPACE                                                          74970016
          SPACE                                                         75060016
INVALTO  LA    GR3,DDNAME2             SET UP DDNAME FOR MESSAGE.       75150016
         B     INVALMSG                GO TO SET UP FOR MESSAGE.        75240016
CINVALTO LR    GR3,GR7                 POINT TO DDNAME FOR MESSAGE.     75330016
INVALMSG LA    GR1,14                  INVALID DUMP DEVICE.             75420016
         BAL   GR2,SETUPMSG            GO TO SET UP THIS MESSAGE.       75510016
         MVC   MESS+8(7),DUMPTO        FILL IN 'DUMP TO' IN MESSAGE.    75600016
         B     MSGOUT                  GO TO PRINT THIS MESSAGE.        75690016
         SPACE                                                          75780016
INVALTRK LA    GR3,DDNAME1             SET UP DDNAME FOR MESSAGE.       75870016
         LA    GR1,22                  INVALID TRK ADDRESS SPECIFIED.   75960016
         BAL   GR2,SETUPMSG            GO TO SET UP THIS MESSAGE.       76050016
         B     MSGOUT                  GO TO PRINT THIS MESSAGE.        76140016
         EJECT                                                          76230016
*********************************************************************** 76320016
*  THIS ROUTINE WILL RECEIVE CONTROL UPON DETECTION OF AN I/O ERROR.  * 76410016
*                                                                     * 76500016
*  SYNADAF(SVC 68) AND ITS ASSOCIATED MACROS WILL BE USED TO          * 76590016
*  DETERMINE THE ERROR CONDITION.                                     * 76680016
*                                                                     * 76770016
*********************************************************************** 76860016
IOERR    LA    GR3,OUTIOB              FROM IOB ADDRESS.                76950016
         B     IOMSG                   GO TO EXECUTE SYNADAF.           77040016
IOTERR   LA    GR3,TOIOB               TO IOB ADDRESS.                  77130016
IOMSG    LA    GR1,13                  I/O ERROR MESSAGE.               77220016
         BAL   GR2,SETUPMSG            SET UP THIS MESSAGE.             77310016
         LR    GR1,GR3                 RESTORE POINTER TO IOB.          77400016
         SYNADAF ACSMETH=EXCP,PARM1=(1)                                 77490016
         MVC   MESS+22(78),49(GR1)     SYNADAF MSG TO BUFFER.    SM4350 77580021
         SYNADRLS                                                       77670016
         BAL   GR14,CLOSEOUT           GO TO CLOSE ALL DCBS.            77760016
         BAL   GR14,FINALR1            GO TO FREE CORE.                 77850016
         BAL   GR9,MSGWRT1             PRINT I/O ERROR MSG.             77940016
         CLI   DEVSW,X'FF'             DUMPING TO DA.                   78030016
         BE    UNUSE1                  GO SET HIGH RETURN CODE.         78120016
UNUSABLE CLI   DEVSW,X'F0'             DUMPING TO SYSOUT.               78210016
         BE    UNUSE1                  YES--GO SET HIGH RETURN CODE.    78300016
         LA    GR3,DDNAME2             DDNAME FOR MESSAGE.              78390016
         BAL   GR4,MSGWRTA             GO TO SET UP AND PRINT MESSAGE.  78480016
         OC    COPYPTR(4),COPYPTR      ANY COPIES.                      78570016
         BZ    UNUSE1                  NO-BRANCH.                       78660016
         USING COPYBLK,GR3                                              78750016
         L     GR3,COPYPTR             PTR TO 1ST OR ONLY COPY BLK.     78840016
UNUSE    BAL   GR4,MSGWRTA             GO TO SET UP AND PRINT MSG.      78930016
         OC    CCOPYPTR(4),CCOPYPTR    MORE COPIES.                     79020016
         BZ    UNUSE1                  NO-BRANCH.                       79110016
         L     GR3,CCOPYPTR            YES-PTR TO NEXT COPY BLK.        79200016
         B     UNUSE                   CONTINUE PROCESSING.             79290016
UNUSE1   LA    GR15,8                  SET RETURN CODE.                 79380016
         B     FINAL3                  RETURN TO MONITOR.               79470016
         EJECT                                                          79560016
MSGWRTA  LA    GR1,30                  UNUSABLE MESSAGE.                79650016
         BAL   GR2,SETUPMSG            GO TO SET UP THIS MSG.           79740016
         MVC   0(8,GR1),0(GR3)         DDNAME TO MESSAGE.               79830016
         BAL   GR9,MSGWRT1             GO TO PRINT MSG.                 79920016
         BR    GR4                     RETURN TO CALLER.                80010016
         DROP  GR3                                                      80100016
         SPACE                                                          80190016
SETUPMSG LINK  EP=IEHDMSGB             GO TO MOVE IN DESIRED MESSAGE.   80280016
         BR    GR2                     RETURN.                          80370016
         SPACE                                                          80460016
MSGOUT   MVC   0(8,GR1),0(GR3)         DDNAME TO MESSAGE.               80550016
         SPACE                                                          80640016
MSGWRT   BAL   GR14,CLOSEOUT           GO TO CLOSE ALL DUMP DCBS.       80730016
         BAL   GR14,FINALR1            GO FREE BUFFER SPACE, IF ANY.    80820016
         BAL   GR9,MSGWRT1             GO TO PRINT OUT MESSAGE.         80910016
         LA    GR15,8                  SET UP ERROR RETURN CODE.        81000016
         B     FINAL3                  RETURN TO MONITOR.               81090016
MSGWRT1  LINK  EP=IEHDPRNT             PRINT THE MESSAGE.               81180016
         BR    GR9                     RETURN.                          81270016
         SPACE                                                          81360016
MOVE     MVC   1(1,GR1),0(GR1)         EXECUTED TO CLEAR DATA BUFFER.   81450016
         SPACE                                                          81540016
         EJECT                                                          81630016
         DS    0H                                                       81720016
SIXTEEN  DC    H'32'                                                    81810016
TWO56    DC    H'256'                                                   81900016
RESTCODE DC    X'F47006016663B24D'     RESTORE TAPE CODE.               81990016
R1       EQU   X'01'                    RECORD NO. OF F4 DSCB   SA58744 82040001
R2       EQU   X'02'                    RECORD NO. OF F5 DSCB   SA58744 82050001
D58      EQU   58                       OFFSET INTO F4 DSCB     SA58744 82060001
CONTAM   EQU   X'80'                    DOS CONTAMINATION BIT   SA58744 82070001
GOOD     EQU   X'7F'                                                    82080016
HALF2    DC    H'2'                                              S20201 82082020
D0       EQU   0                       DISPLACEMENT OF ZERO.     S20201 82084020
D1       EQU   1                                                 S20201 82088020
NOCYL    DC    H'0'                     NUMBER OF TODD CYL.     XL03130 82091903
WINCH    EQU   X'0A'                    WINCHESTER DEVICE TYPE  XL03130 82095903
ICEBG    EQU   X'0D'                    ICEBERG DEVICE TYPE     XL03145 82099803
MERLN    EQU   X'09'                    MERLIN DEVICE TYPE      XL03145 82103703
L1       EQU   1                                                XL03145 82107603
L2       EQU   2                                                XL03145 82111503
D14      EQU   14                       DOS CONTAM BIT OFFSET   XL03145 82115403
D10      EQU   10                       OFFSET TO F4 CYL CNT    XL03145 82119303
D18      EQU   18                       OFFSET TO F4 CYL CNT    XL03145 82121303
DOSCON   EQU   X'80'                    F4 DSCB DOS CONTAM FLAG XL03130 82123203
D16      EQU   16                      DISPLACEMENT OF SIXTEEN.  S20201 82127103
K8       EQU   8                                                 S20201 82131003
L4       EQU   4                       LENGTH OF FOUR.           S20201 82134903
L16      EQU   16                      LENGTH OF EIGHT.          S20201 82138803
D38      EQU   38                       DISP OF 38              Y02113  82142703
CLOCK    EQU   32                       DISPL INTO BUFFER FOR   Y02113  82146603
*                                       TIMESTAMP               Y02113  82150503
RPS      EQU   X'10'                   TEST FOR UCB RPS FEATURE. S20201 82154403
SWOFF    EQU   X'BF'                  *TO SET RPS SWITCH OFF.    S20201 82158303
TICCODE  EQU   X'08'                                             S20201 82162203
COMPCODE DS    1F                      FOR COMPLETION CODE.      A34026 82166103
ZERO     DC    2F'0'                                                    82170016
F1       DC    F'1'                                                     82260016
CCHHADDR DS    1F            SAVE AREA FOR CCHH OF IPL TRK.      M4513  82300019
*    TABLE OF STAND/ALONE DUMP/RESTORE DEVICE TYPE CODES.               82350016
CODES    DC    X'01'                   2311.                            82440016
         DC    X'05'                   2301.                            82530016
         DC    X'04'                   2303.                            82620016
         DC    X'03'                   2302.                            82710016
         DC    X'00'                   2321.                            82800016
         DC    X'06'               2305-1                        S20201 82890020
         DC   X'07'                2305-2                        S20201 82980020
         DC    X'02'                   2314.                            83070016
         DC    X'09'               3330                          S20201 83110020
         DC    X'0A'               WINCHESTER                   XL03130 83120003
         DC    X'0B'               UNUSED                               83130003
         DC    X'0C'               UNUSED                               83140003
         DC    X'0D'               ICEBERG                      XL03145 83150003
         DS    0F                                                       83160016
SCC2321  DC    X'00F60000'             INCREMENT TO NEXT SUBCELL.       83250016
STC2321  DC    X'0000FB00'             INCREMENT TO NEXT STRIP.         83340016
REELCTRL EQU   F1                                                       83430016
DUMPTO   DC    C'DUMP TO'              FOR COMPLETION MESSAGE.          83520016
DUMPSAVE DS    18F                                                      83610016
LIST     DS    0F                      FOR READ IN JFCB.                83700016
         DC    X'87'                                                    83790016
         DC    AL3(0)                                                   83880016
         SPACE 3                                                        83970016
OPENLT  OPEN  (,(OUTPUT)),MF=L         PARAMETER LIST FOR OPEN TAPE.    84060016
OPENLD   RDJFCB (,(OUTPUT)),MF=L       PARAMETER LIST FOR OPEN DA.      84150016
         EJECT                                                          84240016
TAPECCW5 CCW   1,0,X'20',24            WRITE CONTROL RECORD.       2319 84420018
         SPACE                                                          84440020
SETCCW   EQU   *                                                 M5900  84450020
         CCW   X'23',F1,X'40',1         SET SECTOR ZERO          M5900  84460020
TIC      CCW   8,0,X'40',0             TIC INTO CHANNEL PROGRAM. S20201 84480020
         SPACE                                                          84510016
READVTOC CCW   X'31',0,X'60',5         SEARCH ON RECORD 1 OF VTOC.      84600016
         CCW   8,READVTOC,0,0          REPEAT UNTIL FOUND.              84690016
RDVDATA  CCW   6,0,X'20',140           READ VTOC DSCB.                  84780016
         SPACE 1                                                        84870016
HAR0CCW  CCW   7,X'0032AA',X'40',6     SEEK                             84960016
         CCW   X'1F',X'0031A6',X'40',1 SET FILE MASK                    85050016
HAR0CCW1 CCW   X'31',X'0032AC',X'60',5 SEARCH FOR R0.                   85140016
         CCW   8,X'0032D8',0,0         SEARCH UNTIL FOUND.              85230016
         CCW   5,X'003E18',X'60',8     WRITE R0 DATA.                   85320016
HAR0CCW2 CCW   X'31',X'0032AC',X'60',5 SEARCH FOR R0                    85410016
         CCW   8,X'0032F0',0,0         REPEAT UNTIL FOUND.              85500016
         CCW   6,X'003E18',X'70',8     READ BACK CHECK R0 DATA.         85590016
         CCW   X'11',X'000BF0',X'20',8 ERASE REST OF TRACK.             85680016
         SPACE                                                          85770016
R0R1CCWS CCW   7,X'0032AA',X'40',6     SEEK.                            85860016
         CCW   X'1F',X'0031A6',X'40',1 SET FILE MASK.                   85950016
CCWA     CCW   X'31',X'0032AC',X'60',5 SEARCH FOR R0                    86040016
         CCW   8,X'0032D8',0,0         REPEAT UNTIL FOUND.              86130016
         CCW   X'1D',X'003E20',X'60',X'FFFF'   WRITE CNT,KEY DATA R1.   86220016
CCWB     CCW   X'31',X'0032AC',X'60',5 SEARCH FOR R0                    86310016
         CCW   8,X'0032F0',0,0         REPEAT UNTIL FOUND.              86400016
         CCW   5,X'003E18',X'60',8     WRITE DATA R0.                   86490016
         CCW   X'1E',X'003E20',X'70',X'FFFF'   READ BACK CHK R1.        86580016
         CCW   X'16',X'003E18',X'30',16    READ BACK CHK R0.            86670016
         SPACE                                                          86760016
         EJECT                                                          86850016
*   DUMP DA WRITE-OUT ECB.                                              86940016
         DS    0D                      ALIGNMENT.                       87030016
WRTECB   DC    F'0'                    WAIT//COMPLETE BITS.             87120016
*   DUMP DA WRITE-OUT IOB.                                              87210016
WRTIOB   DS    0F                                                       87300016
WRTFLAGS DC    XL2'4200'               FLAG ONE AND TWO.                87390016
WRTSENSE DS    H'0'                    SENSE BYTES.                     87480016
WRTECBAD DC    A(WRTECB)               ECB ADDRESS.                     87570016
WRTSTAT  DC    2F'0'                   CHANNEL STATUS.                  87660016
WRTCCWAD DS    A(0)                    CCW ADDRESS.                     87750016
WRTDCBAD DC    A(WRTDCB)               DCB ADDRESS.                     87840016
WRTRESAD DC    F'0'                    RESTART ADDRESS.                 87930016
WRTBLKCT DC    H'1'                    BLOCK COUNT INCREMENT.           88020016
WRTERROR DC    H'0'                    ERROR COUNT.                     88110016
WRTSEEK  DC    2F'0'                   MBBCCHHR.                        88200016
*   DUMP DA WRITE-OUT DCB.                                              88290016
         AIF   ('&LIB' EQ 'LIB1').OSDCB                                 88342000
WRTDCB   DCB   DSORG=PS,MACRF=(E),DEVD=DA,EOEA=P8,XENDA=P9,            C88344000
               EXLST=LIST,                                             C88394000
               SIOA=P7,PGFX=YES                                   M5431 88460000
         AGO   .C1                                                      88462000
.OSDCB   ANOP                                                           88464000
WRTDCB   DCB   DSORG=PS,MACRF=(E),DEVD=DA,EOEA=P8,XENDA=P9,            C88466000
               EXLST=LIST                                               88468000
.C1      ANOP                                                           88468400
WRTLSTBL DS    0H                      END OF CONTROL BLOCKS.           88470016
WBLKSIZE EQU   WRTLSTBL-WRTECB         SIZE OF I/O BLOCKS-CUMP.         88560016
         EJECT                                                          88650016
*   DUMP TAPE WRITE-TO ECB                                              88740016
         DS    0D                      ALIGNMENT.                       88830016
DTECB    DS    1F                      WAIT//COMPLETE BITS PLUS CODE.   88920016
         SPACE                                                          89010016
*   DUMP TAPE WRITE-TO IOB.                                             89100016
DTIOB    DS    0F                                                       89190016
DTFLAGS  DC    XL2'4200'               FLAGS ONE AND TWO.               89280016
DTSENSE  DC    H'0'                    SENSE BYTES.                     89370016
DTECBAD  DC    A(DTECB)                ECB ADDRESS.                     89460016
DTSTATUS DC    2F'0'                   CHANNEL STATUS.                  89550016
DTCCWS   DC    A(0)                    ADDRESS OF CCWS.                 89640016
DTDCBAD  DC    A(DTDCB)                DCB ADDRESS.                     89730016
DTRESAD  DC    F'0'                    RESTART ADDRESS.                 89820016
DTBLKCT  DC    H'0'                    BLOCK COUNT INCREMENT.           89910016
DTERROR  DC    H'0'                    ERROR COUNT.                     90000016
DTPADD   DC    2F'0'                   NOT USED FOR TAPE IOB.           90090016
DTDCB    DCB   DSORG=PS,MACRF=(E),DEVD=TA,EXLST=LIST             A31384 90130020
         SPACE                                                          90180016
CCW2     CCW   1,0,X'20',0             USED TO PUT OUT CCW RECORD.      90360016
*                                         AND DATA FOR TAPE.            90450016
CCW3     CCW   1,HAR0CCW-16,X'60',88   WRITE HA,R0 CCWS ON TAPE.        90540016
         CCW   1,0,X'20',24            WRITE R0 DATA ON TAPE.           90630016
CCW4     CCW   1,R0R1CCWS-16,X'60',96  WRITE HA,R0,R1 CCWS ON TAPE.     90720016
         CCW   1,0,X'20',0             WRITE R0,R1 DATA ON TAPE.        90810016
         SPACE                                                          90900016
DTLSTBLK DS    0H                      END OF CONTROL BLOCK.            90990016
DTBLKSIZ EQU   DTLSTBLK-DTECB          SIZE OF TAPE I/O BLOCK FOR DUMP. 91080016
         EJECT                                                          91170016
         IEHDWORK                                                       91260016
         EJECT                                                          91350016
IOBLOCKS DSECT                                                          91440016
* DUMP 'TO' ECB.                                                        91530016
TOECB    DS    1F                      WAIT//COMPLETE BITS PLUS CODE.   91620016
* DUMP 'TO' IOB.                                                        91710016
TOIOB    DS    0F                                                       91800016
TOFLGS   DS    CL2                     FLAGS ONE AND TWO.               91890016
TOSENSE  DS    CL2                     SENSE BYTES.                     91980016
TOECBAD  DS    1F                      ECB ADDRESS.                     92070016
TOSTATUS DS    2F                      CHANNEL STATUS.                  92160016
TOCCWAD  DS    1F                      CCW LIST ADDRESS.                92250016
TODCBAD  DS    1F                      DCB ADDRESS.                     92340016
TORESAD  DS    1F                      RESTART ADDRESS.                 92430016
TOBLKCNT DS    CL2                     BLOCK COUNT INCREMENT.           92520016
TOERROR  DS    CL2                     ERROR COUNT.                     92610016
TOSEEK   DS    2F                      MBBCCHHR.                        92700016
* DUMP 'TO' DCB.                                                        92790016
TODCB    DS    13F                     DCB.                             92880016
         DS    0D                      FOR DOUBLE WORD ALIGNMENT.       92970016
TAPECCW2 DS    1D                      USED TO PUT OUT CCW RECORD       93060016
*                                        AND DATA ON TAPE.              93150016
TAPECCW3 DS    2D                      WRITE HA,R0 CCWS ON TAPE.        93240016
TAPECCW4 DS    2D                      WRITE HA,R0,R1 CCWS ON TAPE.     93330016
         DS    0D                      FOR DOUBLE WORD ALIGNMENT.       93420016
* DUMP 'FROM' ECB.                                                      93510016
OUTECB   DS    1F                      WAIT//COMPLETE BITS PLUS CODE.   93600016
* DUMP 'FROM' IOB.                                                      93690016
OUTIOB   DS    0F                                                       93780016
OUTFLG   DS    CL2                     FLAGS ONE AND TWO.               93870016
OUTSENSE DS    CL2                     SENSE BYTES.                     93960016
OUTECBAD DS    1F                      ECB ADDRESS.                     94050016
OUTSTAT  DS    2F                      CHANNEL STATUS.                  94140016
OUTCCWAD DS    1F                      CCW LIST ADDRESS.                94230016
OUTDCBAD DS    1F                      DCB ADDRESS.                     94320016
OUTRESAD DS    1F                      RESTART ADDRESS.                 94410016
OUTBLKCT DS    CL2                     BLOCK COUNT INCREMENT.           94500016
OUTERROR DS    CL2                     ERROR COUNT.                     94590016
OUTSEEK  DS    2F                      7BBCCHHR.                        94680016
CCHH     EQU   OUTSEEK+3               CYLINDER/HEAD ADDRESS.           94770016
R        EQU   OUTSEEK+7               RECORD NUMBER.                   94860016
* DUMP 'FROM' DCB.                                                      94950016
OUTDCB   DS    18F                     DCB.                             95040016
         SPACE                                                          95130016
IOBLKEND DS    0H                      END OF IOBLOCKS DSECT.           95220016
DBSIZE   EQU   IOBLKEND-IOBLOCKS       SIZE OF IOBLOCKS DSECT.          95310016
         SPACE 1                                                        95400016
         IEHDBLKS                                                       95490016
VLABEL   DSECT                                                 , M4513  95499019
VOLUME   DS    CL3                     LABEL IDENTIFIES.         M4513  95508019
VOLNO    DS    CL1                     LABEL NUMBER.             M4513  95517019
SERIAL   DS    CL6                     LABEL SERIAL NUMBER.      M4513  95526019
SECURITY DS    CL1                     VOLUME SECURITY.          M4513  95535019
VTOCPTR  DS    CL10                    POINTER TO VTOC.          M4513  95544019
         DS    CL20                    RESERVED.                 M4513  95553019
OWNER    DS    CL10                    OWNER IDENTIFICATION      M4513  95562019
         DS    CL29                    BLANK.                    M4513  95571019
         SPACE                                                          95580016
         EJECT                                                          95670016
CVT      DSECT                                                          95760016
         CVT   SYS=MIN                                                  95850016
         EJECT                                                          95940016
UCB      DSECT                                                          96030016
         IEFUCBOB                                                       96120016
         EJECT                                                          96210016
JFCB     DSECT                                                          96300016
         IEFJFCBN                                                       96390016
         EJECT                                                          96480016
         DCBD  DSORG=PS                                                 96570016
         END                                                            96660016
