   TITLE 'IEHDPASS --- INSURES PASSWORD PROTECTION  IEHDASDR UTILITY'   00200121
         COPY  LCGASMSW                                          SM4351 00200221
IEHDPASS CSECT                                                          00200421
*        RELEASE 23 DELETIONS                                         * 00200720
*        RELEASE 22 DELETIONS                                         * 00201420
*        RELEASE 21 DELETIONS                                         * 00202120
*                                       OX03105 = YM3060                00202203
*1193                                                            A44112 00202421
*        RELEASE 20 DELETIONS                                         * 00202820
*1010630800                                                      M6183  00203020
*1010484000-486000                                               M4979  00203220
*1010287000,290000,349000,350000                                 A32516 00203720
*1010624000                                                      A33538 00206020
*1010396000                                                      S20201 00207020
*1010631000                                                      M5900  00207320
*        RELEASE 18 DELETIONS                                           00207620
*3166452900-453000,455900-457400,480000,613300                   MC0I   00208220
*STATUS CHANGE LEVEL 004                                                00209020
*                                                                     * 00212016
*FUNCTION/OPERATION- THIS ROUTINE PERFORMS THE FUNCTION OF            * 00216016
*   CHECKING FOR PASSWORD PROTECTED DATASETS ON VOLUMES WHICH         * 00220016
*   ARE BEING ANALYZED, FORMATTED, DUMPED FROM OR TO AND RESTORED TO. * 00224016
*   IF SUCH DATA SETS ARE FOUND, THIS ROUTINE REQUIRES THAT THE       * 00228016
*   APPROPRIATE PASSWORD(S) BE PROVIDED BEFORE ALLOWING THE           * 00232016
*   FUNCTION TO CONTINUE USING THE VOLUME.                            * 00236016
*     UNEXPIRED DATA SETS ARE ALSO CHECKED FOR ON THE TO DEVICE.      * 00240016
*   INSTRUCTION TO OVERRIDE SUCH DATASETS AND USE THE VOLUME          * 00244016
*   MUST APPEAR IN THE CONTROL CARD AND THE OPERATORS REPLY TO A      * 00248016
*   CONSOLE MESSAGE IN ORDER TO ALLOW THE FUNCTION TO CONTINUE.       * 00252016
*                                                                     * 00256016
*ENTRY POINTS- THE ONLY ENTRY POINT IS -IEHDPASS- AND CONTROL IS      * 00260016
*   RECEIVED FROM EITHER DUMP(IEHDDUMP), RESTORE(IEHDREST), OR        * 00264016
*   FORMAT/ANALYZE(IEHDANAL).                                         * 00268016
*                                                                     * 00272016
*INPUT- POINTERS TO A WORKAREA (REGISTER 12), TO A CONTROL BLOCK      * 00276016
*   (REGISTER 10), AND TO A BUFFER AREA (REGISTER 1).                 * 00280016
*     THE DIRECT ACCESS DEVICE BEING ANALYZED, FORMATTED, RESTORED    * 00284016
*   TO AND DUMPED FROM OR TO SERVE AS INPUT TO THIS MODULE. ALSO THE  * 00288016
*   TAPE BEING DUMPED TO, IF MAGNETIC TAPE IS USED, MAY BE INPUT TO   * 00292016
*   THIS ROUTINE.                                                     * 00296016
*                                                                     * 00300016
*EXITS- NORMAL- IF NO ERROR CONDITIONS OCCUR, -IEHDPASS- RETURNS TO   * 00304016
*   THE FUNCTION (IEHDANAL, IEHDDUMP, IEHDREST) WHICH LINKED TO IT    * 00308016
*   WITH A RETURN CODE OF ZERO.                                       * 00312016
*                                                                     * 00316016
*EXITS- ERROR- IF A NORMAL ERROR CONDITION OCCURS (ONE WHICH MAY BE   * 00320016
*   DIAGNOSED) AN ERROR MESSAGE IS WRITTEN AND A RETURN CODE          * 00324016
*   GREATER THAN ZERO IS PASSED BACK TO THE FUNCTION WHICH LINKED     * 00328016
*   TO -IEHDPASS-. IF AN ABNORMAL ERROR OCCURS A RETURN CODE GREATER  * 00332016
*   THAN ZERO IS SET BUT NO MESSAGE IS WRITTEN. RETURN IS ALWAYS TO   * 00336016
*   THE FORMAT/ANALYZE, DUMP OR RESTORE MODULE.                       * 00340016
*                                                                     * 00344016
*EXTERNAL ROUTINES- THIS ROUTINE IS ALWAYS ENTERED FROM EITHER        * 00348016
*   IEHDDUMP, IEHDREST OR IEHDANAL. MESSAGES WILL BE FORMULATED       * 00352016
*   BY IEHDMSGB AND PRINTED BY IEHDPRNT.                              * 00356016
*                                                                     * 00360016
*TABLES/WORKAREAS- UPON ENTRY REGISTERS 10 AND 12 POINT TO A          * 00364016
*   FUNCTION BLOCK AND A WORKAREA RESPECTIVELY. THEY ARE DESCRIBED    * 00368016
*   IN THE DSECTS CALLED -FUNCBLK- AND -WORK-. REGISTER 1 POINTS TO   * 00372016
*   A BUFFER AREA TO BUILD THE CHANNEL PROGRAM AND READ IN THE DSCBS. * 00376016
*                                                                     * 00380016
*   THE FOLLOWING ARE REGISTER ASSIGNMENTS.                             00400016
GR0      EQU   0                                                        00600016
GR1      EQU   1                                                        00800016
GR2      EQU   2                                                        01000016
GR3      EQU   3                                                        01200016
GR4      EQU   4                                                        01400016
GR5      EQU   5                                                        01600016
GR6      EQU   6                                                        01800016
GR7      EQU   7                                                        02000016
GR8      EQU   8                                                        02200016
GR9      EQU   9                                                        02400016
GR10     EQU   10                                                       02600016
GR11     EQU   11                                                       02800016
GR12     EQU   12                                                       03000016
GR13     EQU   13                                                       03200016
GR14     EQU   14                                                       03400016
GR15     EQU   15                                                       03600016
BASEREG  EQU   11                                                       03800016
VSAMID   EQU   X'08'                    FORMAT 1 VSAM FLAG      YM3060  03850003
D83      EQU   83                       OFFSET TO DSORG IN F1   YM3060  03900003
*                                       DSCB.                   YM3060  03950003
         USING FUNCBLK,10                                               04000016
         USING WORK,12                                                  04200016
         USING IEHDPASS,BASEREG                                         04400016
         USING CCWBUFF,9                                                04600016
         SAVE  (14,12),T,*             SAVE REGISTERS                   04800016
         LR    BASEREG,GR15            LOAD BASE REGISTER               05000016
         LA    GR2,PASSSAVE            SAVE AREA ADDRESS                05200016
         ST    GR2,8(GR13)             ADDRESS OF NEW AREA TO OLD       05400016
         ST    GR13,4(GR2)             ADDRESS OF OLD AREA TO NEW       05600016
         LR    GR13,GR2                LOAD SAVE AREA ADDRESS           05800016
         LA    GR1,0(GR1)              SELECT OUT ADDRESS ONLY IN REG   05900016
         LR    GR9,GR1                 PICK UP POINTER TO BUFFER AREA   06000016
*                                         FOR CHANNEL PROG AND DSCBS    06200016
*********************************************************************** 06220016
*  THIS ROUTINE BUILDS THE CHANNEL PROGRAMS NEEDED TO READ IN THE     * 06240016
*     DSCBS ONE TRACK AT A TIME. THE CCWS ARE PLACED IN A VARIABLE    * 06260016
*     LENGTH BUFFER AREA WHICH IS POINTED TO BY REGISTER 1. WORK      * 06280016
*     AREAS ARE ALSO INITIALIZED.                                     * 06300016
*********************************************************************** 06320016
         USING CONSTANT,3                                               06340016
         L     GR3,IODEVCON            PICK UP POINTER TO CONSTANT AREA 06360016
         SR    GR0,GR0                 CLEAR REGISTER.                  06380016
         IC    GR0,DSCBTRK             PICK UP NUMBER DSCBS PER TRACK   06400016
         ST    GR0,DSCBNO              SAVE NUMBER DSCBS PER TRACK      06460016
         DROP  3                                                        06520016
         LR    GR15,GR0                COMPUTE ADDRESS OF               06600016
         SLL   GR15,3                     AREA TO READ DSCBS. SAVE      06800016
         LA    GR15,24(GR15)              POINTER                       07000016
         ALR   GR15,GR1                                                 07200016
         ST    GR15,DSCBPTR            SAVE POINTER TO DSCB READAREA    07400016
         LA    GR8,140                 SIZE OF ONE DSCB                 07600016
         LM    GR2,GR7,CCWLIST         PICK UP FIRST THREE CCWS         07800016
         ALR   GR4,GR1                 PUT CORRECT ADDRESS IN TIC CCW   08000016
         STM   GR2,GR5,0(GR1)          PLACE SEARCH AND TIC CCWS IN     08200016
*                                         BUFFER.                       08400016
         ALR   GR6,GR15                PUT ADDRESS OF READ IN AREA      08600016
*                                         IN READ CCW                   08800016
CCWLOOP  STM   GR6,GR7,16(GR1)         PLACE CORRECT NUMBER OF          09000016
         ALR   GR6,GR8                    READ INSTRUCTIONS IN          09200016
         LA    GR1,8(GR1)                 BUFFER WITH APPROPRIATE       09400016
         BCT   GR0,CCWLOOP                READ IN AREA ADDRESSES        09600016
         MVI   RDCNT,X'92'             INITIALIZE DUMMY CCWS.      0552 09700017
         LM    GR2,GR3,RDCNT           PICK UP LAST CCW                 09800016
         STM   GR2,GR3,16(GR1)         PLACE CCW TO POSITION TO         10000016
*                                         NEXT TRACK IN BUFFER          10200016
         ST    GR1,RDCNTAD        SAVE ADDR FOR RD CNT MODIFICATION.    10300016
         LA    GR4,CCW1                PUT CCW ADDRESS                  10400016
         ST    GR4,DCCWAD                 IN IOB                        10600016
         MVC   LASTDSCB(5),NINES       INITIALIZE FOR END OF READ DSCBS 10800016
         SR    GR5,GR5                  ZERO OUT REGISTER               11000016
         ST    GR5,SECSW               INITIALIZE SWITCHES TO ZERO      11600016
         ST    GR5,TABLEAD             INITIALIZE TABLE ADDRESS TO ZERO 11800016
*********************************************************************** 12000016
*   THIS ROUTINE DETERMINES WHICH FUNCTION IS IN OPERATION            * 12200016
*     AT PRESENT. DUMP REQUIRES CHECKING BOTH THE FROM AND TO DEVICES.* 12400016
*********************************************************************** 12600016
         CLI   FUNCSW,ANALYSIS         IS FUNCTION ANALYZE              12800016
         BE    TODEV                   YES-CHECK TO DEV ONLY            13000016
         CLI   FUNCSW,FORMAT           IS FUNCTION FORMAT               13200016
         BE    TODEV                   YES-CHECK TO DEV ONLY            13400016
         CLI   FUNCSW,RESTORE          IS FUNCTION RESTORE              13600016
         BE    TODEV1                  YES-CHECK TO DEV ONLY            13800016
         CLI   FUNCSW,DUMP             IS FUNCTION DUMP                 13860016
         BNE   SETCODE                 NO-ABNORMALLY TERMINATE JOB      13920016
*********************************************************************** 14000016
*   THIS ROUTINE SCANS THE TIOT TO DETERMINE THE AMOUNT OF CORE       * 14200016
*     NEEDED FOR THE DSNAME TABLE OF PASSWORD PROTECTED DATASETS ON   * 14300016
*     THE FROM DEVICE.                                                * 14400016
*********************************************************************** 14600016
         TM    SEQSW,FEATURE1      FROMDD HAVE RPS               S20201 14620020
         BZ    FROMDEV             NO                            S20201 14640020
         MVC   TIC+D1(L3),DCCWAD+D1  SET UP TIC ADDR             S20201 14660020
         LA    GR4,SETCCW          POINT TO RPS CCWS             S20201 14680020
         ST    GR4,DCCWAD          STORE IN IOB                  S20201 14700020
FROMDEV  EQU   *                        *                        S20201 14720020
         L     GR8,CVTPTR              PICK UP POINTER TO CVT           14800016
         USING CVT,GR8                                                  15000016
         L     GR6,CVTTCBP             PICK UP POINTER TO TCB           15200016
         L     GR6,4(GR6)                                               15300016
         L     GR7,12(GR6)             PICK UP POINTER TO TIOT          15400016
         USING TIOT,GR7                                                 15600016
         LA    GR6,DDENTRY             PICK UP ADDRESS OF FIRST DDENTRY 15800016
         ST    GR6,TIOTSAVE              IN TIOT AND SAVE               16000016
         USING DDENTRY,GR6                                              16200016
         DROP  7,8                                                      16400016
         SR    GR4,GR4                 INITIALIZE REGISTER TO ZERO      16600016
NEXTDD   CLC   TIOEDDNM(8),INCON       IS IT SYSIN                      16920016
         BE    BUMPPTR                 YES-BUMP POINTER TO NEXT ENTRY   17200016
         CLC   TIOEDDNM(8),PRINTCON    IS IT SYSPRINT                   17400016
         BE    BUMPPTR                 YES-BUMP POINTER TO NEXT ENTRY   17600016
         CLC   TIOEDDNM(8),BLANKS  IS IT BLANK                   A44112 17620021
         BE    BUMPPTR              YES MUST BE CONCATENATED DD  A44112 17640021
         SR    GR3,GR3                 PUT TIOT LENGTH IN               17680016
         IC    GR3,TIOELNGH               REGISTER                      17760016
         SH    GR3,TWENTY              CALCULATE INDEX TO LAST UCB PTR  17840016
         AR    GR6,GR3                 ADJUST DD ENTRY INDEX FOR UCB    17920016
CHECKUCB CLC   TIOEFSRT(3),FUCBPTR+1   UCB FOR FROM DEVICE?             18000016
         BNE   NEXTUCB                 NO- MORE UCBS                    18080016
ADDENTRY EX    GR5,SWITCH1             SWITCH TO REDIRECT FLOW 2ND TIME 18200016
         LA    GR4,52(GR4)             ADD TO CORE SIZE FOR GETMAIN     18400016
NEXTUCB  LTR   GR3,GR3                 MORE UCBS TO CHECK               18430016
         BE    BUMPPTR                 NO - GO GET NEXT DD ENTRY        18460016
         SH    GR3,FOUR                INDEX TO NEXT UCB                18490016
         SH    GR6,FOUR                POINT TO NEXT UCB PTR            18520016
         B     CHECKUCB                GO CHECK NEXT UCB                18550016
BUMPPTR  SR    GR3,GR3                 PUT TIOT LENGTH IN               18580016
         IC    GR3,TIOELNGH                REGISTER                     18610016
         AR    GR6,GR3                 BUMP PTR TO NEXT DD ENTRY        18640016
         L     GR0,0(GR6)              END OF TIOT REACHED              18700016
         LTR   GR0,GR0                                                  18800016
         BNE   NEXTDD                  NO-GET NEXT ENTRY                19000016
         EX    GR5,SWITCH2             SWITCH TO REDIRECT FLOW 2ND TIME 19200016
         LA    GR8,TABLEAD             YES-SET UP ADDRESS FOR GETMAIN   19800016
         ST    GR4,TABLESIZ            SAVE SIZE OF DSNAME TABLE        20000016
         GETMAIN EC,LV=(4),A=(8)       GET CORE FOR DSNAME TABLE        20200016
         LTR   GR15,GR15               CORE AVAILABLE?                  20400016
         BNE   MORECORE                NO-GO WRITE MESSAGE              20600016
*********************************************************************** 20800016
*   THIS ROUTINE CREATES A TABLE CONTAINING THE NAMES OF EVERY DATASET* 21000016
*    ON THE FROM DEVICE FOR WHICH A PASSWORD DD CARD WAS SUPPLIED.    * 21100016
*    THE CORRESPONDING DDNAME FOR EACH DSNAME IS ALSO PLACED IN THE   * 21200016
*    TABLE.                                                             21300016
*********************************************************************** 21600016
         L     GR6,TIOTSAVE            PICK UP POINTER TO TIOT DDENTRY  21800016
         LA    GR5,X'F0'               SET SWITCHES FOR 2ND TIME        22000016
*                                        SCAN OF TIOT                   22200016
         LA    GR7,DADCB               PICK UP POINTER TO DCB           22400016
         ST    GR7,DDCBAD                                               22500016
         USING IHADCB,7                                                 22600016
         MVC   OPENLD+1(3),DDCBAD+1    MOVE DCB ADDRESS TO LIST         22800016
         LA    GR2,READJFCB            PICK UP BUFFER ADDRESS TO        23000016
         ST    GR2,LIST                  READ JFCB                      23200016
         MVI   LIST,X'87'              PICK UP EXIT LIST CODE           23400016
         L     GR8,TABLEAD             PICK UP POINTER TO DSNAME TABLE  23600016
         LA    GR15,VTOCREAD           SET UP FOR BRANCH IF TABLE FULL  23800016
         BAL   GR14,NEXTDD             GO GET FIRST DDNAME FOR RDJFCB   24000016
         SR    GR6,GR3            RESET POINTER TO START DD ENTRY. 9956 24100017
         MVC   DCBDDNAM(8),TIOEDDNM    PUT DDNAME IN DCB                24200016
         MVC   0(8,GR8),DCBDDNAM       ENTER DDNAME IN TABLE            24400016
         LA    GR8,8(GR8)              BUMP POINTER TO DSNAME SLOT      24600016
         RDJFCB MF=(E,OPENLD)          READ JFCB                        24800016
         USING JFCB,2                                                   25000016
         MVC   0(44,GR8),JFCBDSNM      ENTER DSNAME IN TABLE            25200016
         MVI   JFCBTSDM,X'08'          STOP WRITE OF JFCB AT OPEN       25300016
         LA    GR8,44(GR8)             BUMP POINTER TO NEXT ENTRY SLOT  25400016
         BAL   GR15,BUMPPTR            GO GET NEXT DDNAME IF ANY        25600016
*********************************************************************** 26400016
*  THIS ROUTINE CHECKS ALL THE FORMAT 1 DATA SET LABELS ON THE FROM   * 26600016
*    DEVICE FOR PROTECTION AND LOOKS UP THE NAME OF PROTECTED DATASETS* 26800016
*     IN THE DSNAME TABLE CREATED. IF NO PASSWORD DD CARD WAS SUPPLIED* 27000016
*     FOR THE DATA SET AND IT DOES NOT APPEAR IN THE DSNAME TABLE     * 27200016
*     A MESSAGE IS WRITTEN AND A RETURN CODE OF 8 IS SET. OTHERWISE A * 27400016
*     MESSAGE IS WRITTEN TO THE OPERATOR REQUESTING THE PASSWORD      * 27600016
*     FOR EACH DATA SET, ONE AT A TIME. AN INCORRECT RESPONSE         * 27800016
*     RESULTS IN A RETURN CODE OF 8 WITH MESSAGE. A CORRECT RESPONSE  * 28000016
*     ALLOWS PROCESSING TO CONTINUE.                                  * 28200016
*********************************************************************** 28400016
VTOCREAD LR    GR5,GR8                                                  28420016
         USING UCB,GR8                                                  28440016
         L     GR8,FUCBPTR             PICK UP POINTER TO UCB           28460016
         CLI   UCBID,X'FF'             IS THIS A 2321                   28470016
         BNE   IS2321                  YES-GO HANDLE                    28480016
         MVC   JFCBVOLS(6),SRTEVOLI    PUT VOL/SER NO. IN JFCB          28500016
         DROP  8                                                        28520016
BACK     LA    GR8,44                  SET REGISTER TO LAST ENTRY       28540016
         SR    GR5,GR8                    FOR LOOP CONTROL              28560016
         LA    GR7,BLOCKS+180          PICK UP POINTER TO DCB FOR DUMP  28640016
         MVI   RDCNT,X'92'             INITIALIZE RDCNT TO MULTI-TRACK  28750016
         L     GR2,DCBDEBAD       PICK UP POINTER TO DEB.               28830016
         MVC   SEEKAD+1(6),36(GR2) EXTRACT LOW EXTENT FROM DEB.         28910016
REPEAT   EQU   *                                                 A32516 28980020
         ST    GR7,DDCBAD               PUT DCB ADDR IN IOB.     A32516 29050020
         L     GR6,DSCBNO         GET NO. OF DSCBS PER TRK.      A32516 29120020
         L     GR3,DSCBPTR             PICK UP POINTER TO DSCB READAREA 29200016
         CLI   RDCNT,X'12'             END OF VTOC REACHED              29260016
         BE    TAPECHK                                                  29320016
         CLC   SEEKAD+3(4),LASTDSCB    IS LAST F1 DSCB FINISHED         29400016
         BH    TAPECHK                 YES-GO CHECK TO DEVICE           29600016
         CLC   SEEKAD+3(4),42(GR2) IS THIS LAST TRACK OF VTOC.          29680016
         BNE   GOODCCW                 NO-GO READ                       29760016
         MVI   RDCNT,X'12'             YES CHANGE RDCNT TO SINGLE TRACK 29840016
         L     GR1,RDCNTAD                                              29860016
         MVI   16(GR1),X'12'      SET SINGLE READ COUNT.                29880016
GOODCCW  EXCP  DISKIOB                 READ A DSCB                      29920016
         BAL   GR4,WAIT                AWAIT COMPLETION OF I/O          30000016
         CLI   44(GR3),X'F4'           IS DSCB A FORMAT 4               30200016
         BNE   CHECKF1                 NO-GO CHECK FORMAT 1             30400016
         MVC   LASTDSCB(5),45(GR3)     YES-SAVE ADDRESS OF LAST F1 DSCB 30600016
         LA    GR3,140(GR3)            BUMP POINTER TO NEXT DSCB        30800016
         BCTR  GR6,0                   SUBTRACT 1 FROM NO. DSCBS LEFT   31000016
CHECKF1  CLI   44(GR3),X'F1'           IS DSCB A FORMAT 1               31200016
         BNE   CONTROL1                                                 31400016
         TM    93(GR3),X'14'           D/S PASSWORD PROTECTED    A46957 31650000
         BC    9,CONTROL1              NO-CONTINUE               A46957 31700000
         LA    GR7,DADCB               PICK UP PPINTER TO DUMMY DCB TO  31750003
         ST    GR7,DDCBAD                  OPEN PASSWORD DATA SET       31800003
         TM    D83(GR3),VSAMID          VSAM DSCB ?             YM3060  31810003
         BNO   NOVSAM                   NO, CONTINUE            YM3060  31820003
         MVC   DCBDDNAM,DDNAME1         MOVE FROMDD DDNAME      YM3060  31830003
         B     VSAM1                    OPEN VSAM F1 DSCB       YM3060  31840003
NOVSAM   EQU       *                                            YM3060  31842003
         LA    GR4,52                  SET UP FOR LOOP CONTROL          31850003
         L     GR8,TABLEAD             YES-PICK UP POINTER TO TABLE     32000016
         LTR   GR8,GR8                 HAVE ENTRIES BEEN MADE IN TABLE  32060016
         BZ    NOCARD                   YES, CHECK ENTRIES      YM3060  32070003
CKTABLE  CLC   0(44,GR3),8(GR8)        IS DATA SET IN TABLE             32400016
         BE    GETPASS                 YES-GO REQUEST PASSWORD          32600016
         BXH   GR8,GR4,NOCARD          BUMP POINTER TO NEXT ENTRY       32800016
         B     CKTABLE                 CHECK NEXT TABLE ENTRY           33000016
GETPASS  MVC   DCBDDNAM(8),0(GR8)      PUT DDNAME IN DCB                33200016
VSAM1    EQU   *                                                YM3060  33250003
         L     GR2,LIST           SET UP JFCB POINTER.             0141 33300017
         MVC   JFCBDSNM,D0(GR3)        PUT DSNAME IN JFCB       YM3060  33400003
         OPEN  MF=(E,OPENLD),TYPE=J                                     33600016
         TM    DCBOFLGS,X'10'          WAS OPEN SUCCESSFUL              33800016
         BZ    BADPASS                 NO-GO TERMINATE JOB              34000016
         NI    DCBMACRF+1,X'F3'        SET BITS OFF TO STOP WRITE OF    34200016
*                                        EOF AND UPDATE OF DSCB         34400016
         CLOSE ((7))                                                    34600016
         TM    D83(GR3),VSAMID          VSAM DSCB ?             YM3060  34650003
         BO    VSAM2                    YES, DON,T SET TAPE     YM3060  34700003
*                                       SECURITY SWITCH.        YM3060  34750003
         MVI   SECSW,X'01'             SET SECURITY SWITCH              34800016
VSAM2    EQU   *                                                YM3060  34850003
         LA    GR7,BLOCKS+180       PUT DCB FROM DUMP IN IOB     A32516 34860020
         L     GR2,DCBDEBAD            OBTAIN POINTER TO DEB     A32516 34920020
CONTROL1 LA    GR3,140(GR3)            BUMP POINTER TO NEXT DSCB        35100016
         BCT   GR6,CHECKF1             SUBTRACT 1 FROM NO. DSCBS LEFT   35400016
         B     REPEAT                  READ AGAIN                       35800016
*********************************************************************** 36000016
*  THIS ROUTINE CHECKS TO SEE IF TO DEVICE IS TAPE AND IF SOURCE      * 36030016
*    DIRECT ACCESS DEVICE HAS PASSWORD PROTECTED DATASETS. IF SO      * 36060016
*    THE SWITCH WHICH INDICATES STANDARD LABEL, PASSWORD PROTECTED    * 36090016
*    TAPE WITH BLANK OR ZERO SEQUENCE NUMBER MUST BE ON FOR           * 36120016
*    PROCESSING TO CONTINUE. OTHERWISE JOB IS TERMINATED WITH MESSAGE.* 36150016
*********************************************************************** 36200016
TAPECHK  CLI   DEVSW,X'00'             IS TO DEVICE TAPE                36500016
         BNE   DADEV                   NO- GO CHECK DIRECT ACCESS       36800016
         CLI   SECSW,X'01'             YES-IS SECURITY SWITCH ON        37200016
         BNE   RELEASE                 NO-GO RETURN TO PROCESSING       37400016
         TM    SWITCH,PASSSW           YES-IT THIS STANDARD LABEL       37600016
*                                          PASSWORD PROTECTED TAPE      37800016
*                                          WITH SEQ NO = BLANK OR ZERO  37900016
         BO    RELEASE                 YES-GO RETURN TO PROCESSING      38000016
         LA    GR1,35                  TAPE NOT SL AND PROTECTED        38200016
         BAL   GR5,MSGBLD              GO BUILD MESSAGE                 38300016
         LA    GR5,SETCODE             SET UP FOR BRANCH AFTER PRINT    38400016
         B     MSGPRNT                 GO PRINT MESSAGE                 38500016
*********************************************************************** 38600016
*  THIS ROUTINE CHECKS ALL FORMAT 1 DATA SET LABELS ON A DA DEVICE    * 38610016
*    FOR EXPIRATION AND FOR PROTECTION. IF AT LEAST ONE UNEXPIRED     * 38620016
*    DATA SET IS ENCOUNTERED AND EITHER THE PURGE OPTION IS NOT       * 38630016
*    SPECIFIED BY THE USER OR THE PURGE OPTION IS SPECIFIED BUT THE   * 38640016
*    OPERATOR REQUESTS TERMINATION OF THE JOB IN RESPONSE TO A WTOR   * 38650016
*    MESSAGE, AN ERROR MESSAGE IS WRITTEN AND A RETURN CODE OF 8 IS   * 38660016
*    SET.                                                             * 38670016
*  OTHERWISE THE DATA SET IS CHECKED FOR PROTECTION. THE PASSWORD FOR * 38680016
*    A PROTECTED DATA SET MUST BE SUPPLIED IF THE DATA SET IS TO BE   * 38690016
*    SCRATCHED AND THE VOLUME USABLE.                                 * 38700016
*********************************************************************** 38800016
         USING COPYBLK,6                                                38900016
DADEV    CLI   DEVSW,X'FF'             IS TO DEVICE DIRECT ACCESS       39000016
         BNE   DUMPFUNC                NO-GO CHECK FOR DUMP FUNCTION    39100016
TODEV1   LA    GR7,BLOCKS+44           PICK UP POINTER TO DCB/RESTORE   39400016
         B     TODEV2              GO TO PROCESS                 S20201 39600020
TODEV    LA    GR7,FBLOCKS             PICK UP POINTER TO DCB/FORMAT    39800016
*                                         AND ANALYSIS                  40000016
TODEV2   EQU   *                        *                        S20201 40010020
         LA    GR4,CCW1            RESET PTR IN                  S20201 40020020
         ST    GR4,DCCWAD          IOB                           S20201 40030020
         TM    SEQSW+D1,FEATURE    TODD HAVE RPS                 S20201 40040020
         BZ    GOAHEAD             NO                            S20201 40050020
         MVC   TIC+D1(L3),DCCWAD+D1  SET UP TIC ADDR             S20201 40060020
         LA    GR4,SETCCW          POINT TO RPS CCWS             S20201 40070020
         ST    GR4,DCCWAD          STORE IN IOB                  S20201 40080020
GOAHEAD  EQU   *                                                 S20201 40090020
VREAD    ST    GR7,DDCBAD              PUT DCB ADDRESS IN IOB           40100016
         MVC   LASTDSCB(5),NINES       INITIALIZE FOR END OF READ DSCB  40200016
         MVI   RDCNT,X'92'             INITIALIZE RDCNT TO MULTI-TRACK  40250016
         L     GR1,RDCNTAD                                              40260016
         MVI   16(GR1),X'92'      RESET RD CNT FOR MULTI-TRK.           40270016
         L     GR3,DCBDEBAD            PICK UP POINTER TO DEB           40300016
         MVC   SEEKAD+1(6),36(GR3)     EXTRACT LOW EXTENT FROM DEB      40400016
REPEAT2  L     GR2,DSCBNO              PICK UP NUMBER DSCBS PER TRACK   40600016
         L     GR5,DSCBPTR             PICK UP POINTER TO DSCB READAREA 40800016
         CLI   RDCNT,X'12'             END OF VTOC REACHED              40860016
         BE    CKMOREDD                YES-GO CHECK FOR COPIES          40920016
         CLC   SEEKAD+3(4),LASTDSCB    IS LAST F1 DSCB FINISHED         41000016
         BH    CKMOREDD                YES-GO CHECK FOR COPIES          41200016
         CLC   SEEKAD+3(4),42(GR3)     IS THIS LAST TRACK OF VTOC       41280016
         BNE   CCWOK                   NO-GO READ                       41360016
         MVI   RDCNT,X'12'             YES CHANGE RDCNT TO SINGLE TRACK 41440016
         L     GR1,RDCNTAD                                              41460016
         MVI   16(GR1),X'12'      SET SINGLE READ COUNT.                41480016
CCWOK    EXCP  DISKIOB                 READ A DSCB                      41520016
         BAL   GR4,WAIT                AWAIT COMPLETION OF I/O          41600016
         CLI   44(GR5),X'F4'           IS DSCB A FORMAT 4               41800016
         BNE   F1CHECK                 NO-GO CHECK FORMAT 1             42000016
         MVC   LASTDSCB(5),45(GR5)     YES-SAVE ADDRESS OF LAST F1 DSCB 42200016
         LA    GR5,140(GR5)            BUMP POINTER TO NEXT DSCB        42400016
         BCTR  GR2,0                   SUBTRACT 1 FROM NO. DSCBS LEFT   42600016
F1CHECK  CLI   44(GR5),X'F1'           IS DSCB A FORMAT 1               42800016
         BNE   CONTROL2                                                 43000016
         CLI   WTORSW,X'01'            IS WRITE TO OPERATOR SWITCH ON   43200016
         BE    SCRATCH                 YES-GO SCRATCH DATA SET          43400016
               TIME                                                     43600016
         LR    GR0,GR1                 PUT DATE IN REGISTER 0           43660016
         XC    DATE(8),DATE            CLEAR OUT DATE AREA              43720016
         STH   GR0,DATE+6              ISOLATE DAY                      43780016
         SRDL  GR0,4                   SAVE ZONE IN REGISTER 1          43840016
         SRL   GR0,12                  ISOLATE YEAR                     43900016
         SLDL  GR0,4                   PUT ZONE ON YEAR                 43960016
         CVB   GR4,DATE                CONVERT DAY                      44020016
         STH   GR0,DATE+6              PUT YEAR IN FIELD                44080016
         CVB   GR1,DATE                CONVERT YEAT                     44140016
         STH   GR4,DATE+6              SAVE DAY                         44200016
         STC   GR1,DATE+5              SAVE YEAR                        44260016
         CLC   56(3,GR5),DATE+5        DATA SET EXPIRED                 44360016
         BL    SCRATCH                 YES-GO SCRATCH DATA SET          44600016
         TM    SEQSW+1,PURGE           NO-PURGE REQUESTED?              44800016
         BZ    UNEXPIRE                NO-GO TERMINATE JOB              45000016
         MVI   WTORSW,X'01'            YES-SET WRITE TO 3PERATOR SWITCH 45200016
         CLI   COPYSW,X'01'            IS THIS COPIES                   45210016
         BNE   SKIP1                   NO-GO PICK UP UCB POINTER        45220016
         L     GR8,CUCBPTR             PICK UP POINTER TO COPY UCB      45230016
         B     CONTINUE                                                 45240016
SKIP1    L     GR8,TUCBPTR             PICK UP POINTER TO UCB           45250016
         USING UCB,GR8                                                  45260016
CONTINUE CLI   UCBID,X'FF'             IS THIS 2321                     45270016
         BNE   YES2321                 YES GO HANDLE                    45280016
PASSBY   MVC   TRYAGAIN+55(6),SRTEVOLI  PUT VOL-SER IN WTOR        MC0I 45300018
PASSBY1  MVC   TRYAGAIN+24(3),UCBNAME   PUT CH-UNIT ADDRESS IN WTORMC0I 45320018
         DROP  GR8                                                      45350016
         L     GR8,CVTPTR              PICK UP POINTER TO CVT           45380016
         USING CVT,GR8                                                  45410016
         L     GR8,CVTTCBP             PICK UP POINTER TO TCB           45440016
         L     GR8,4(GR8)                                               45470016
         DROP  8                                                        45500016
         L     GR8,12(GR8)             PICK UP POINTER TO TIOT          45530016
         USING TIOT,GR8                                                 45560016
         MVC   TRYAGAIN+63(8),TIOCNJOB  SAVE JOBNAME AND STEPNAME  MC0I 45600018
         MVC   TRYAGAIN+73(16),TIOCSTEP      IN WTOR MESSAGE       MC0I 45640018
TRYAGAIN WTOR  'IEH807D       HAS UNEXPIRED DATA SETS,       ,         X45680003
                        ,                 .',REPLY,1,DISKECB,      MC0IX45720018
               ROUTCDE=(4),DESC=(2)                                MC0I 45760018
WTREPLY  TM    DISKECB,COMPLETE        IS OPERATION COMPLETE            45800016
         BO    OKAY                    YES-GO CLEAR BITS                46000016
         WAIT  ECB=DISKECB             N/-WAIT FOR REPLY                46200016
OKAY     MVI   DISKECB,0               CLEAR POSTED BITS IN ECB         46400016
         CLI   REPLY,X'E4'             DOES REPLY INDICATE USE          46600016
         BE    SCRATCH                 YES-GO SCRATCH DATA SET          46800016
         CLI   REPLY,X'E3'             NO-DOES REPLY INDICATE TERMINATE 47000016
         BNE   NEWREPLY                NO-OPERATOR ERROR                47200016
UNEXPIRE LA    GR1,37                  UNEXPIRED DATASET ON TODD        47400016
         B     ERRORT                                                   47600016
NEWREPLY MVC   FILLIN+55(8),TIOCNJOB   PUT JOBNAME AND STEPNAME IN      47700016
         MVC   FILLIN+65(16),TIOCSTEP       WTO MESSAGE                 47800016
FILLIN   WTO   'IEH808I REPLY IN ERROR. REPLY WITH "U" OR "T",         C47900016
               ,                 .',ROUTCDE=(4),DESC=(5)           MC0I 48000018
         B     TRYAGAIN                                                 48200016
         EJECT                                                          48200103
SCRATCH  TM    93(GR5),X'10'            IS IT PASSWORD PROTECTED M4979  48300020
         BZ    CONTROL2                 NO - DONT CHECK          M4979  48400020
         CLI   COPYSW,X'01'            COPIES BEING USED                48620016
         BNE   SKIP2                   NO-GO GET UCB POINTER            48640016
         L     GR8,CUCBPTR             PICK UP POINTER TO UCB           48660016
         B     ONWARD                                                   48680016
SKIP2    L     GR8,TUCBPTR             PICK UP POINTER TO UCB           48700016
         USING UCB,GR8                                                  48720016
ONWARD   CLI   UCBID,X'FF'             IS THIS 2321                     48810016
         BNE   Y2321                   YES GO HANDLE                    48900016
PASSOVER MVC   VOLIST+6(6),SRTEVOLI    PUT VOL-SER IN LIST              48990016
PASS     MVC   VOLIST+2(4),UCBTYP      PUT DEVICE TYPE IN LIST          49080016
         SR    GR0,GR0                 ZERO OUT REGISTER                49200016
         ST    GR5,PARMLIST+4          PROVIDE CURRENT DSCB FOR SCRATCH 49300016
         CLI   FUNCSW,RESTORE          IS FUNCTION DUMP/RESTORE US03168 49302003
         BH    PR040                    NO-CONTINUE             US03168 49304003
         CLI   DUMPSW,X'00'             YES-IS IT PARTIAL       US03168 49306003
         BNE   PR040                    NO-CONTINUE             US03168 49308003
         SPACE 1                                                        49309003
PR010    EQU   *                                                US03168 49310003
         LA    GR1,DADCB                LOAD DCBADDRS           US03168 49310203
         DROP  GR2,GR7                                          US03168 49310403
         USING IHADCB,GR1                                       US03168 49310603
         ST    GR1,OPENLD               PUT DCB ADDRS IN PARM   US03168 49311003
         MVI   OPENLD,X'80'             SET END PARM FLAG       US03168 49311203
         MVC   DCBDDNAM,DDNAME2         MOVE PRIME TO DDNAME    US03168 49311403
         CLI   COPYSW,X'01'             IS COPY SWITCH ON       US03168 49311603
         BNE   PR020                    NO-BRANCH OVER          US03168 49311803
         MVC   DCBDDNAM,DDNAME3         MOVE COPY TO DDNAME     US03168 49314003
PR020    EQU   *                                                US03168 49314203
         LA    GR0,READJFCB             ADDRS OF JFCB           US03168 49316003
         ST    GR0,LIST                 STORE IN PARM LIST      US03168 49318003
         MVI   LIST,X'87'               SET END INDICATOR       US03168 49320003
         RDJFCB MF=(E,OPENLD)           READ IN JFCB            US03168 49322003
         LA    GR1,READJFCB             ADDRS OF JFCB           US03168 49324003
         USING JFCB,GR1                                         US03168 49326003
         MVI   JFCBTSDM,X'08'           PREVENT JFCB WRITE-BACK US03168 49326103
         SPACE 1                                                        49336003
         MVC   JFCBDSNM,D0(GR5)         MOVE DSNAME TO JFCB     US03168 49340003
         OPEN  MF=(E,OPENLD),TYPE=J     OPEN DATASET            US03168 49342003
         LA    GR1,DADCB                LOAD DCB ADDRS          US03168 49344003
         USING IHADCB,GR1                                       US03168 49346003
         TM    DCBOFLGS,X'10'           WAS OPEN SUCCESSFUL     US03168 49348003
         BO    PR030                    YES-CONTINUE            US03168 49350003
         LA    GR1,36                   NO-SET ERROR CODE       US03168 49352003
         B     ERRORT                   GO PRINT MSG            US03168 49354003
         SPACE 1                                                        49356003
PR030    EQU   *                                                US03168 49358003
         CLOSE MF=(E,OPENLD)            CLOSE DATASET           US03168 49360003
         B     CONTROL2                 CONTINUE PROCESSING     US03168 49362003
         EJECT                                                          49364003
PR040    EQU   *                                                US03168 49366003
         DROP  GR1                                              US03168 49368003
         USING IHADCB,GR7                                       US03168 49370003
         SCRATCH PARMLIST              SCRATCH DATA SET                 49400016
         LTR   GR15,GR15               RETURN SUCCESSFUL                49600016
         BE    CONTROL2                                                 49800016
         TM    VOLIST+13,X'04'         I/O ERROR DURING SCRATCH         49820016
         BZ    PASSERR                 NO-PASSWORD ERROR                49840016
         LA    GR1,13                  YES-GO BUILD MESSAGE             49860016
         BAL   GR5,MSGBLD                                               49880016
         MVC   0(3,GR1),MSGCON         PROVIDE SVC NO TO PRINT          49900016
         CLI   COPYSW,X'01'            COPIES BEING USED                49920016
         BNE   SKIP3                   NO-GO MOVE DDNAME TO PRINT       49940016
         MVC   3(8,GR1),DDNAME3        PROVIDE COPIES TODD TO PRINT     49960016
         B     GO                                                       49980016
SKIP3    MVC   3(8,GR1),DDNAME2        PROVIDE TODD NAME TO PRINT       50000016
GO       LA    GR5,SETCODE             SET UP BRANCH AFTER PRINT        50020016
         B     MSGPRNT                 GO PRINT MESSAGE                 50040016
PASSERR  TM    VOLIST+13,X'02'         PASSWORD ERROR                   50080016
         BZ    SETCODE                 NO-OTHER ERROR/ABNORMALLY END    50120016
         LA    GR1,36                  YES-INCORRECT PASSWORD/TODD      50160016
         B     ERRORT                                                   50200016
CONTROL2 LA    GR5,140(GR5)            BUMP POINTER TO NEXT DSCB        50400016
         BCT   GR2,F1CHECK             SUBTRACT 1 FROM NO.DSCBS LEFT    50600016
         B     REPEAT2                 READ AGAIN                       51000016
         EJECT                                                          51000203
*********************************************************************** 51200016
*  THIS ROUTINE CHECKS TO SEE IF THERE ARE COPY VOLUMES. IF SO, THE   * 51250016
*   DCB IS PICKED UP, THE WRITE TO OPERATOR SWITCH IS INITIALIZED     * 51300016
*   AND THE NEXT VOLUME IS PROCESSED.                                 * 51350016
*********************************************************************** 51400016
CKMOREDD CLI   COPYSW,X'01'            HAVE ANY COPIES BEEN DONE        51500016
         BE    MORECOPY                YES-PICK UP CORRECT POINTER      51600016
         L     GR6,COPYPTR             ARE COPIES INVOLVED              51700016
         LTR   GR6,GR6                                                  51800016
         BE    RELEASE                 NO-GO RETURN CONTROL             52000016
         MVI   COPYSW,X'01'            INDICATE FIRST COPY DONE         52800016
         USING COPYBLK,6                                                53000016
RESUME   TM    FUNCSW,X'40'            IS FUNCTION FORMAT OR ANALYZE    53080016
         BO    FORMANAL               YES-FO PICK UP PROPER DCB POINTER 53160016
         LA    GR7,CIOBLOCK+44         PICK UP COPY DCB POINTER FOR     53240016
         B     SKIP                       DUMP OR RESTORE               53320016
FORMANAL LA    GR7,CIOBLOCK            PICK UP COPY DCB POINTER - F/A   53400016
SKIP     MVI   WTORSW,X'00'            RESET WTOR SWITCH                53480016
         B     VREAD                   GO READ DSCB'S                   53600016
MORECOPY L     GR6,CCOPYPTR            PICK UP POINTER TO COPYBLOCK     54200016
         LTR   GR6,GR6                 MORE COPIES                      54260016
         BE    RELEASE                 NO-GO RETURN CONTROL             54320016
         B     RESUME                                                   54400016
*********************************************************************** 54600016
*  THIS ROUTINE IS USED TO PRINT ERROR MESSAGES FOR THE TO DEVICE     * 54660016
*    TO FREE CORE GOTTEN AND TO RETURN CONTROL.                       * 54720016
*********************************************************************** 54800016
ERRORT   BAL   GR5,MSGBLD              GO BUILD MESSAGE                 55200016
         CLI   COPYSW,X'01'            COPIES BEING USED                55300016
         BNE   SKIP4                   NO-GO MOVE DDNAME TO PRINT       55400016
         MVC   0(8,GR1),DDNAME3        YES-PROVIDE COPIES TODD TO PRINT 55500016
         B     FORWARD                                                  55600016
SKIP4    MVC   0(8,GR1),DDNAME2        PROVIDE TODD NAME TO PRINT       55700016
FORWARD  BAL   GR5,MSGPRNT             GO PRINT MESSAGE                 55800016
SETCODE  LA    GR15,8                  SET UP RETURN CODE/ERROR         56200016
ENDUP    CLI   FUNCSW,DUMP             MUST CORE BE FREED/DUMP ONLY     56300016
         BNE   GOBACK                  NO-GO RETURN                     56400016
         LR    GR3,GR15                SAVE RETURN CODE                 56450016
         L     GR4,TABLESIZ            PICK UP SIZE OF CORE             56500016
         LA    GR8,TABLEAD             PICK UP ADDRESS OF CORE          56600016
         FREEMAIN E,LV=(4),A=(8)       FREE CORE GOTTEN                 56800016
         LR    GR15,GR3                PUT RETURN CODE BACK IN REG 15   56900016
GOBACK   L     GR13,PASSSAVE+4         RESTORE REGISTER 13              57000016
         RETURN (14,12),T,RC=(15)      RETURN WITH PROPER CODE          57200016
*********************************************************************** 57400016
*  THIS SECTION PRINTS ERROR MESSAGES FOR THE FROM DEVICE, AND SETS   * 57450016
*    UP RETURN CODES. THE SYNADAF MACRO IS USED FOR THE I/O ERROR     * 57500016
*    MESSAGE.                                                         * 57550016
*********************************************************************** 57600016
NOCARD   LA    GR1,40                  NO DD CARD FOR SECURITY DS       57660016
         B     ERRORF                                                   57720016
BADPASS  LA    GR1,36                  INCORRECT PASSWORD/FROMDD        57800016
ERRORF   BAL   GR5,MSGBLD              GO BUILD MESSAGE                 58000016
         MVC   0(8,GR1),DDNAME1        PROVIDE FROMDD NAME TO PRINT     58200016
         LA    GR5,SETCODE             SET UP FOR BRANCH AFTER PRINT    58300016
         B     MSGPRNT                 GO PRINT MESSAGE                 58400016
DUMPFUNC CLI   FUNCSW,DUMP             IS FUNCTION DUMP                 58500016
         BNE   SETCODE                 NO-ABNORMALLY TERMINATE JOB      58600016
RELEASE  LA    GR15,0                  SET UP RETURN CODE/SUCCESSFUL    58800016
         B     ENDUP                                                    59000016
MORECORE L     GR7,PTRCFUNC            INDICATE CORE NOT AVAILABLE/WAIT 59200016
         OI    0(GR7),NOCORE+WAITING                                    59400016
         LA    GR15,4                  SET RETURN CODE AND RETURN       59600016
         B     ENDUP                                                    59800016
IOERR    LA    GR1,13                  I/O ERROR                        60000016
         BAL   GR5,MSGBLD              GO BUILD MESSAGE                 60200016
         SYNADAF ACSMETH=EXCP,PARM1=DISKIOB                             60400016
         MVC   MESS+22(78),49(GR1)     I/O INFORMATION TO PRINT  SM4350 60600021
         SYNADRLS                                                       60800016
         LA    GR5,SETCODE             SET UP FOR BRANCH AFTER PRINT    60870016
         B     MSGPRNT                 GO PRINT MESSAGE                 60940016
MSGBLD   LINK  EP=IEHDMSGB             BUILD MESSAGE                    61010016
         BR    GR5                                                      61080016
MSGPRNT  LINK  EP=IEHDPRNT             PRINT MESSAGE                    61150016
         BR    GR5                                                      61220016
         DROP  6                                                        61290016
*********************************************************************** 61296016
*   THIS SECTION CALCULATES THE ADDRESS OF THE MAIN UCB GIVEN THE SUB * 61302016
*      UCB POINTER FOR A 2321.                                        * 61308016
*********************************************************************** 61314016
         USING DATACELL,GR8                                             61318016
         USING JFCB,GR2                                         US03168 61318103
IS2321   MVC   JFCBVOLS(6),DCELVOLI    PUT VOL-SER FOR 2321 IN JFCB     61322016
         B     BACK                                                     61326016
YES2321  MVC   TRYAGAIN+56(6),DCELVOLI  PICK UP 2321 VOL-SER       MC0I 61328018
         MVI   TRYAGAIN+26,C'/'                                    MC0I 61330018
         MVC   TRYAGAIN+27(1),DCELBBNR+1    BIN NO. W/CUU FOR 2321 MC0I 61332018
         LA    GR3,PASSBY1             SET BRANCH AFTER CALCULATION     61334016
         B     CKMAIN                                                   61338016
Y2321    MVC   VOLIST+6(6),DCELVOLI    PICK UP 2321 VOL/SER             61342016
         LA    GR3,PASS                SET BRANCH AFTER CALCULATION     61346016
CKMAIN   LH    GR15,DCELBBNR           CALCULATE MAIN UCB               61350016
         SLL   GR15,4                                                   61356016
         LA    GR15,SRTEUSER-UCBOB(GR15)                                61362016
         SR    GR8,GR15                                                 61368016
NOCONVRT BR    GR3                                                      61374016
         DROP  8                                                        61380016
*********************************************************************** 61400016
*    WAIT ROUTINE FOR I/O OPERATIONS                                  * 61500016
*********************************************************************** 61600016
WAIT     TM    DISKECB,COMPLETE        IS OPERATION COMPLETE            61800016
         BO    TEST                    YES-GO TEST STATUS               62000016
         WAIT  ECB=DISKECB             NO-WAIT COMPLETION OF DISK       62200016
TEST     EQU   *                                                 A33538 62280020
         CLC   DSENSE(2),ZERO          ANY ERROR CONDITION.      A33538 62360020
         BNE   IOERR                   YES-I/O ERROR.            A33538 62440020
         CLI   DISKECB,GOOD            ALL OK.                   A33538 62520020
         BNE   IOERR                   NO-I/O ERROR                     62600016
         MVI   DISKECB,0               CLEAR POSTED BITS IN ECB         62800016
         BR    GR4                     RETURN                           63000016
         SPACE                                                          63050020
SETCCW   DS    0D                                                M6183  63080020
         CCW   X'23',F1,X'40',1         SET SECTOR ZERO          M5900  63110020
TIC      CCW   8,0,X'40',0                                       S20201 63150020
CCWLIST  CCW   X'31',SEEKAD+3,X'40',5                                   63200016
         CCW   X'08',CCW1-CCWBUFF,0,0                                   63400016
RDCCW    CCW   X'0E',0,X'60',140                                        63600016
RDCNT    CCW   X'92',SEEKAD+3,X'20',5                                   63800016
*   DA EVENT CONTROL BLOCK (ECB).                                       64000016
         DS    0D                      NECESSARY ALIGNMENT              64200016
DISKECB  DC    F'0'                    WAIT/COMPLETE BITS               64400016
*   DA INPUT/OUTPUT BLOCK (IOB).                                        64600016
DISKIOB  DS    0F                                                       64800016
DFLAGS   DC    XL2'4200'               FLAG1 AND FLAG2                  65000016
DSENSE   DC    H'0'                    SENSE BYTES                      65200016
DECBAD   DC    A(DISKECB)              ECB ADDRESS                      65400016
DSTATUS  DC    2F'0'                   CHANNEL STATUS                   65600016
DCCWAD   DC    1F'0'                   CCW ADDRESS                      65800016
DDCBAD   DC    F'0'                    DCBADDRESS                       66000016
DRESAD   DC    F'0'                    RESTART ADDRESS                  66200016
DBLKCT   DC    H'1'                    BLOCK COUNT INCREMENT            66400016
DERROR   DC    H'0'                    ERROR COUNT                      66600016
SEEKAD   DC    1F'0'                   MBBCCHHR                         66800016
         DC    X'00000001'                                              67000016
LASTDSCB DS    CL5                                                      67200016
NINES    DC    CL5'99999'                                               67400016
ZERO     DC    H'0'                    CHECK SENSE BYTES.        A33538 67500020
LIST     DS    0F                      FOR READ IN JFCB                 67600016
         DC    X'87'                                                    67800016
         DC    AL3(0)                                                   68000016
OPENLD   RDJFCB (,(INPUT)),MF=L        PARAMETER LIST FOR OPEN          68200016
TABLESIZ DS    1F                      SIZE OF DSNAME TABLE             68400016
TABLEAD  DS    1F                      POINTER TO DSNAME TABLE          68600016
DATE     DS    1D                      CURRENT DATE                     68800016
SECSW    DS    CL1                     SECURITY SWITCH                  69000016
WTORSW   DS    CL1                     WRITE TO OPERATOR INDICATOR      69200016
COPYSW   DS    CL1                     COPYSWITCH                       69400016
REPLY    DS    CL1                     OPERATOR REPLY                   69600016
REPLYAD  DC    A(REPLY)                ADDRESS OF OPERATOR REPLY AREA   69800016
GOOD     EQU   X'7F'                   NO I/O ERROR                     69900016
TICCODE  EQU   X'08'               TIC CCW OP CODE               S20201 69920020
D0       EQU   0                        DISP OF ZERO            SA61117 69922003
D1       EQU   1                   DISP OF 1                     S20201 69940020
L3       EQU   3                   LENGTH OF 3                   S20201 69960020
PARMLIST CAMLST SCRATCH,0,,VOLIST,,OVRD                                 70000016
VOLIST   DC    H'1'                    VOLUME LIST FOR SCRATCH DATA SET 70200016
         DS    1H                                                       70400016
         DS    2F                                                       70600016
         DC    H'0'                                                     70800016
DSCBNO   DS    1F                      SAVE AREA FOR NUMBER DSCBS       70900016
DSCBPTR  DS    1F                      POINTER TO READAREA FOR DSCBS    71000016
RDCNTAD  DS    F                                                        71050016
INCON    DC    C'SYSIN   '                                              71100016
PRINTCON DC    C'SYSPRINT'                                              71200016
DPASS    DC    CL8'DPASS   '            PAREST DDNAME           SA61117 71202003
F1       DC    F'1'                                              S20201 71250020
BLANKS   DC    CL8' '                                            A44112 71270021
TWENTY   DC    H'20'                                                    71300016
FOUR     DC    H'4'                                                     71400016
MSGCON   DC    C'29,'                  SVC NO. FOR I/O ERROR MESSAGE    71500016
TIOTSAVE DS    1F                      SAVE AREA FOR FIRST DD ENTRY     71600016
PASSSAVE DS    18F                                                      71800016
SWITCH1  NOPR  14                                                       72000016
SWITCH2  NOPR  15                                                       72200016
READJFCB DS    44F                     AREA TO READ IN JFCB             72400016
DADCB    DCB   DSORG=PS,MACRF=(E),DEVD=DA,EXLST=LIST                    72600016
         IEHDWORK                                                       72800016
         IEHDBLKS                                                       73000016
CCWBUFF  DSECT                                                          73200016
CCW1     DS    1D                                                       73400016
CCW2     DS    1D                                                       73600016
CCW3     DS    1D                                                       73800016
CVT      DSECT                                                          74000016
         CVT   SYS=MIN                                                  74200016
UCB      DSECT                                                          74400016
         IEFUCBOB                                                       74600016
JFCB     DSECT                                                          74800016
         IEFJFCBN                                                       75000016
         DCBD  DSORG=PS                                                 75200016
TIOT     DSECT                                                          75400016
TIOCNJOB DS    2F                                                       75600016
TIOCSTEP DS    4F                                                       75800016
DDENTRY  DS    0F                      DD ENTRY FOR EACH DD CARD        76000016
TIOELNGH DS    CL1                     LENGTH OF DD ENTRY               76200016
TIOESTTA DS    CL1                                                      76400016
TIOERLOC DS    CL2                                                      76600016
TIOEDDNM DS    2F                                                       77000016
TIOEJFCB DS    CL3                                                      77400016
TIOESTTC DS    CL1                                                      77600016
TIOESTTB DS    CL1                                                      77800016
TIOEFSRT DS    CL3                                                      78000016
         END                                                            88000016
