IFH0     TITLE 'IFHSTATR - O/S VOLUME STATISTICS PRINT UTILITY'         00050019
         SPACE 3                                                        00100019
         SPACE 3                                                        00150019
*********************************************************************** 00200019
*                                                                     * 00250019
*TITLE: 'IFHSTATR' - O/S VOLUME STATISTICS PRINT UTILITY              * 00300019
*                                                                     * 00350019
*STATUS: CHANGE LEVEL 2                                               * 00400021
*                                                                     * 00450019
*FUNCTION: THIS PROGRAM READS,FORMATS AND PRINTS TYPE 15 RECORDS      * 00500019
*   FROM A SYS1.MAN DATA SET.                                         * 00550019
*                                                                     * 00600019
*ENTRY: IFHSTATR                                                      * 00650019
*                                                                     * 00700019
*INPUT: SYS1.MAN DATA SET                                             * 00750019
*                                                                     * 00800019
*OUTPUT: 121 CHARACTER RECORDS WITH USASI CARRIAGE CONTROL CHARACTERS * 00850019
*   IN THE FIRST BYTE ARE WRITTEN TO SYSUT2.                          * 00900019
*                                                                     * 00950019
*EXITS-NORMAL: RETURN TO SUPERVISOR                                   * 01000019
*                                                                     * 01050019
*EXITS-ERROR: NONE                                                    * 01100019
*                                                                     * 01150019
*ATTRIBUTES: NONE                                                     * 01200020
*                                                                     * 01250019
*********************************************************************** 01300019
         EJECT                                                          01350019
IFHSTATR CSECT                                                          01400019
*C 029000,090000                                                SA63311 01402021
*A099000                                                         A32893 01410020
*C024500                                                         A32893 01430020
*A041100                                                         A32896 01440020
*C137500,040000,040500,175000                                    A32896 01442020
*D148500                                                         A32896 01444020
*A 034100,035500-035800,098100,176700-176940                     A40940 01446021
*C 034500                                                        A40940 01448021
*D 035500                                                        A40940 01448421
*C 041100,137500                                                 A53648 01448821
*A 148500                                                        A53648 01449221
         SPACE                                                          01450019
*********************************************************************** 01500019
*                      REGISTER EQUATES AND USAGE                     * 01550019
*********************************************************************** 01600019
         SPACE                                                          01650019
R0       EQU   0                       NOT USED                         01700019
R1       EQU   1                       WORK                             01750019
R2       EQU   2                       WORK                             01800019
R3       EQU   3                       WORK                             01850019
R4       EQU   4                       WORK                             01900019
R5       EQU   5                       WORK                             01950019
R6       EQU   6                       WORK                             02000019
R7       EQU   7                       WORK                             02050019
R8       EQU   8                       WORK                             02100019
R9       EQU   9                       WORK                             02150019
R10      EQU   10                      LINE COUNT                       02200019
R11      EQU   11                      RETURN REG. FOR INTERNAL PROC.   02250019
R12      EQU   12                      BASE                             02300019
R13      EQU   13                      SAVE AREA POINTER                02350019
R14      EQU   14                      RETURN REGISTER                  02400019
R15      EQU   15                      USED FOR A RETURN CODE    A32893 02450020
         SPACE 3                                                        02500019
*********************************************************************** 02550019
*                      CONSTANT EQUATES AND USAGE                     * 02600019
*********************************************************************** 02650019
         SPACE 2                                                        02700019
BLANK    EQU   C' '                    USED FOR ZERO SUPPRESSION        02750019
ZERO     EQU   C'0'                    USED FOR TESTING FOR ZEROS       02800019
TYPE15   EQU   X'15'                   RECORD TYPE                      02850019
CODE200  EQU   X'F0'               MASK FOR TESTING 200 BPI     SA63311 02900021
CODE556  EQU   X'40'                   MASK FOR TESTING FOR 556 BPI     02950019
CODE800  EQU   X'80'                   MASK FOR TESTING FOR 800 BPI     03000019
CODE1600 EQU   X'C0'                   MASK FOR TESTING FOR 1600 BPI    03050019
ONE      EQU   1                                                        03100019
TWO      EQU   2                                                        03150019
FOUR     EQU   4                                                        03200019
SIXTEEN  EQU   16                                                       03250019
TWENTY   EQU   20                                                       03300019
HUNDRED  EQU   100                                                      03350019
         EJECT                                                          03400019
         STM   R14,R12,12(R13)         SAVE REGISTERS            A40940 03410021
         BALR  R12,0                   ESTABLISH BASE            A40940 03450021
         USING *,R12                                                    03500019
         ST    R13,SAVE+4                                        A40940 03550021
         LA    R15,SAVE                                          A40940 03560021
         ST    R15,8(R13)                                        A40940 03570021
         LR    R13,R15                                           A40940 03580021
         SPACE                                                          03600020
         OPEN  (SYSUT1,(INPUT),SYSUT2,(OUTPUT))                         03650019
         TIME  DEC                     GET CURRENT DATE IN REG 1        03700019
         ST    R1,WORK                 STORE IN WORK AREA               03750019
         UNPK  WORK+8(5),WORK+1(3)     UNPACK CURRENT DATE              03800019
         MVC   CDATE(2),WORK+8         MOVE YEAR TO HEADING             03850019
         MVC   CDATE+3(3),WORK+10      MOVE DAY TO HEADING AFTER SLASH  03900019
NEWPAGE  L     R10,FIFTY               NUMBER OF DATA LINES PER PAGE    03950019
GETDATA  GET   SYSUT1                  READ A RECORD             A32896 04000020
         CLI   5(R1),TYPE15            TYPE '15' RECORD ?        A32896 04050020
         BNE   GETDATA                 NO, READ ANOTHER RECORD          04100019
         MVC   INAREA(RCRDEND-INAREA),0(R1) MOVE RCRD TO WRK     A53648 04110021
         CL    R10,FIFTY               IS THIS THE 1ST LINE ON PAGE ?   04150019
         BNE   CONVERT                 NO, DON'T PRINT HEADING          04200019
HEADING  MVI   DATAFLAG,TYPE15         INDICATE AT LEAST ONE RCD FOUND  04250019
         PUT   SYSUT2,LINE1            PRINT FIRST LINE OF HEADING      04300019
         PUT   SYSUT2,LINE2            PRINT SECOND LINE OF HEADING     04350019
         PUT   SYSUT2,LINE3            PRINT THIRD LINE OF HEADING      04400019
         PUT   SYSUT2,LINE4            PRINT FOURTH LINE OF HEADING     04450019
         EJECT                                                          04500019
*********************************************************************** 04550019
*     MOVE DATA FROM INPUT AREA TO PRINT AREA, MAKING NECESSARY       * 04600019
*     CONVERSIONS FOR PRINTING THE DATA.                              * 04650019
*********************************************************************** 04700019
         SPACE                                                          04750019
CONVERT  MVC   VOLID(6),IVOLID         MOVE VOLUME-SERIAL TO OUT AREA   04800019
         SPACE                                                          04850019
         UNPK  WORK(8),IDATE(5)        UNPACK DATE                      04900019
         MVC   YEAR(2),WORK+1          MOVE DATE                        04950019
         MVC   DAY(3),WORK+3                     TO OUT AREA            05000019
         SPACE                                                          05050019
         MVC   CPUID(2),ICPUID         MOVE CPU ID TO OUT AREA          05100019
         SPACE                                                          05150019
         MVC   MODNO(2),IMODNO         MOVE CPU MODEL NO. TO OUT AREA   05200019
         SPACE                                                          05250019
         MVC   WORK(4),ITIME           MOVE TIME TO WORD BOUNDRY        05300019
         SR    R4,R4                   CLEAR EVEN REGISTER              05350019
         L     R5,WORK                 LOAD ODD REGISTER WITH TIME      05400019
         LA    R6,HUNDRED              DIVISOR FOR DIVIDE OPERATION     05450019
         DR    R4,R6                   ELEMINATE HUNDREDTHS OF SECONDS  05500019
         SR    R4,R4                   CLEAR EVEN REGISTER              05550019
         D     R4,SIXTY                SEC IN REG 4, MIN IN REG 5       05600019
         CVD   R4,WORK                 CONVERT SECONDS                  05650019
         MVC   WORK+10(2),WORK+6       SAVE PACKED SECONDS -XXXXSSS-    05700019
         SR    R4,R4                   CLEAR REGISTER                   05750019
         D     R4,SIXTY                MIN IN REG 4, HOURS IN REG 5     05800019
         CVD   R4,WORK                 CONVERT MINUTES                  05850019
         MVO   WORK+8(2),WORK+6(2)     MM+XSSS-                         05900019
         MVO   WORK+8(3),WORK+8(1)     000MMSS-                         05950019
         CVD   R5,WORK                 CONVERT HOURS                    06000019
         L     R5,WORK+4               PACKED DECIMAL HOURS IN REG 5    06050019
         SRL   R5,FOUR                 ELIMINATE SIGN FROM HOURS        06100019
         SLL   R5,TWENTY               SHIFT TO HOURS POSITION          06150019
         O     R5,WORK+8               0HHMMSS- IN REG 5                06200019
         ST    R5,WORK+20              STORE CONVERTED TIME             06250019
         UNPK  WORK(8),WORK+20(5)      UNPACK TIME                      06300019
         MVC   HOURS(2),WORK           MOVE                             06350019
         MVC   MINUTES(2),WORK+2            TIME TO                     06400019
         MVC   SECONDS(2),WORK+4                    OUT AREA            06450019
         SPACE                                                          06500019
         UNPK  WORK(4),IADDRESS(3)     MAKE CHANNEL/UNIT PRINTABLE      06550019
         TR    WORK(3),TRTABLE                                          06600019
         MVC   ADDRESS(3),WORK         MOVE CHAN & UNIT TO OUT AREA     06650019
         SPACE                                                          06700019
         LA    R1,ITREAD               LOAD ADDRESS OF COUNTER          06750019
         BAL   R11,ONEBYTE             BRANCH TO CONVERT 1 BYTE COUNTER 06800019
         MVC   TREAD(3),WORK           MOVE CONVERTED COUNTER TO OUTPUT 06850019
         EJECT                                                          06900020
         LA    R1,ITWRITE              LOAD ADDRESS OF COUNTER          06950019
         BAL   R11,ONEBYTE             BRANCH TO CONVERT 1 BYTE COUNTER 07000019
         MVC   TWRITE(3),WORK          MOVE CONVERTED COUNTER TO OUTPUT 07050019
         SPACE                                                          07100020
         LA    R1,ISIO                 LOAD ADDRESS OF COUNTER          07150019
         BAL   R11,TWOBYTE             BRANCH TO CONVERT 2 BYTE COUNTER 07200019
         MVC   SIO(5),WORK             MOVE CONVERTED COUNTER TO OUTPUT 07250019
         SPACE                                                          07300019
         LA    R1,IPREAD               LOAD ADDRESS OF COUNTER          07350019
         BAL   R11,ONEBYTE             BRANCH TO CONVERT 1 BYTE COUNTER 07400019
         MVC   PREAD(3),WORK           MOVE CONVERTED COUNTER TO OUTPUT 07450019
         SPACE                                                          07500019
         LA    R1,IPWRITE              LOAD ADDRESS OF COUNTER          07550019
         BAL   R11,ONEBYTE             BRANCH TO CONVERT 1 BYTE COUNTER 07600019
         MVC   PWRITE(3),WORK          MOVE CONVERTED COUNTER TO OUTPUT 07650019
         SPACE                                                          07700019
         LA    R1,INOISE               LOAD ADDRESS OF COUNTER          07750019
         BAL   R11,ONEBYTE             BRANCH TO CONVERT 1 BYTE COUNTER 07800019
         MVC   NOISE(3),WORK           MOVE CONVERTED COUNT           R 07850019
         SPACE                                                          07900019
         LA    R1,IERASE               LOAD ADDRESS OF COUNTER          07950019
         BAL   R11,TWOBYTE             BRANCH TO CONVERT 2 BYTE COUNTER 08000019
         MVC   ERASE(5),WORK           MOVE CONVERTED COUNTER TO OUTPUT 08050019
         SPACE                                                          08100019
         LA    R1,ICLEANER             LOAD ADDRESS OF COUNTER          08150019
         BAL   R11,TWOBYTE             BRANCH TO CONVERT 2 BYTE COUNTER 08200019
         MVC   CLEANER(5),WORK         MOVE CONVERTED COUNTER TO OUTPUT 08250019
         SPACE                                                          08300019
BPI1600  TM    IDENSITY,CODE1600       IS DENSITY = 1600 BPI ?          08350019
         BNO   BPI800                  NO, BRANCH                       08400019
         MVC   DENSITY(4),DEN1600      YES, MOVE DENSITY TO PRINT AREA  08450019
         B     CONVBLK                                                  08500019
BPI800   TM    IDENSITY,CODE800        IS DENSITY = 800 BPI ?           08550019
         BNO   BPI556                  NO, BRANCH                       08600019
         MVC   DENSITY(4),DEN800       YES, MOVE DENSITY TO PRINT AREA  08650019
         B     CONVBLK                                                  08700019
BPI556   TM    IDENSITY,CODE556        IS DENSITY = 556 BPI ?           08750019
         BNO   BPI200                  NO, BRANCH                       08800019
         MVC   DENSITY(4),DEN556       YES, MOVE DENSITY TO PRINT AREA  08850019
         B     CONVBLK                                                  08900019
BPI200   TM    IDENSITY,CODE200        IS DENSITY = 200 BPI ?           08950019
         BC    7,BPI0000                    NO,BRANCH           SA63311 09000021
         MVC   DENSITY(4),DEN200       YES, MOVE DENSITY TO PRINT AREA  09050019
         B     CONVBLK                                                  09100019
BPI0000  MVC   DENSITY(4),DEN0000      DENSITY IS WRONG OR NOT PRESENT  09150019
         SPACE                                                          09200019
CONVBLK  LA    R1,IBLOCK               LOAD ADDRESS OF COUNTER          09250019
         BAL   R11,TWOBYTE             BRANCH TO CONVERT 2 BYTE COUNTER 09300019
         MVC   BLOCK(5),WORK           MOVE CONVERTED COUNTER TO OUTPUT 09350019
         EJECT                                                          09450019
PUTDATA  PUT   SYSUT2,DATALINE         PRINT 1 LINE OF OUTPUT           09500019
         BCT   R10,GETDATA             BRANCH UNTIL PAGE IS FULL        09550019
         B     NEWPAGE                 START NEW PAGE                   09600019
FINISHED CLI   DATAFLAG,TYPE15         WERE THERE ANY TYPE 15 RECORDS ? 09650019
         BE    DONE                    YES, NORMAL EOJ                  09700019
         PUT   SYSUT2,ERRLINE          NO, PUT OUT ERROR MSG.           09750019
DONE     CLOSE (SYSUT1,,SYSUT2)                                         09800019
         L     R13,SAVE+4                                        A40940 09810021
         LM    R14,R12,12(R13)         RESTORE REGISTERS                09850019
         SR    R15,R15                 SET RETURN CODE OF ZERO   A32893 09900020
         BR    R14                     RETURN TO SUPERVISOR             09950019
ONEBYTE  LA    R2,TWO                  NO. DECIMAL DIGITS - 1           10000019
         SR    R3,R3                   CLEAR WORK REGISTER              10050019
         IC    R3,0(0,R1)              LOAD COUNTER INTO REGISTER       10100019
         CVD   R3,WORK                 CONVERT TO DECIMAL               10150019
         UNPK  WORK(5),WORK+6(3)       UNPACK COUNTER + 1 BYTE          10200019
         B     SUPPRESS                                                 10250019
TWOBYTE  LA    R2,FOUR                 NO. DECIMAL DIGITS - 1           10300019
         MVC   WORK(2),0(R1)           MOVE COUNTER TO WORD BOUNDRY     10350019
         L     R3,WORK                 LOAD 2 BYTE COUNTER              10400019
         SRL   R3,SIXTEEN              SHIFT TO LOW ORDER POSITION      10450019
         CVD   R3,WORK+8               CONVERT TO DECIMAL               10500019
         UNPK  WORK(7),WORK+13(4)      UNPACK COUNTER + 1 BYTE          10550019
SUPPRESS LA    R5,WORK                 LOAD BASE REG FOR CLI & MVI      10600019
LOOP     CLI   0(R5),ZERO              IS THIS A LEADING ZERO ?         10650019
         BCR   7,R11                   RETURN TO CALLER ON 1ST NON-ZERO 10700019
         MVI   0(R5),BLANK             BLANK OUT LEADING ZEROS          10750019
         LA    R5,1(R5)                INCREMENT BASE REG TO NEXT DIGIT 10800019
         BCT   R2,LOOP                 BRANCH IF ALL DIGITS NOT CHECKED 10850019
         BR    R11                     RETURN TO CALLER                 10900019
         EJECT                                                          10950019
*********************************************************************** 11000019
*                            CONSTANTS                                * 11050019
*********************************************************************** 11100019
         SPACE                                                          11150019
FIFTY    DC    F'50'                   NUMBER OF DATA LINES PER PAGE    11200019
DEN0000  DC    C'0000'                 DENSITY NOT AVAILABLE            11250019
DEN200   DC    C' 200'                 200 BPI                          11300019
DEN556   DC    C' 556'                 556 BPI                          11350019
DEN800   DC    C' 800'                 800 BPI                          11400019
DEN1600  DC    C'1600'                 1600 BPI                         11450019
WORK     DS    4D                      WORK AREA FOR CONVERTING         11500019
TRTABLE  EQU   *-X'F0'                                                  11550019
         DC    C'0123456789ABCDEF'     TRANSLATE TABLE                  11600019
SIXTY    DC    F'60'                   DIVISOR FOR TIME CALCULATIONS    11650019
DATAFLAG DC    X'00'                   INDICATOR FOR TYPE 15 RECORDS    11700019
*********************************************************************** 11800019
*                  HEADINGS FOR OUTPUT PAGE                           * 11850019
*********************************************************************** 11900019
         SPACE 1                                                        11950019
LINE1    DS    0CL121                                                   12000019
         DC    CL1'1'                  CARRIAGE CONTROL FOR A NEW PAGE  12050019
         DC    CL40' '                                                  12100019
         DC    CL40'MAGNETIC TAPE ERROR STATISTICS BY VOLUME'           12150019
         DC    CL34' '                                                  12200019
CDATE    DC    CL6'  /   '             CURRENT DATE IN THE FORM YY/DDD  12250019
         SPACE 1                                                        12300019
LINE2    DS    0CL121                                                   12350019
         DC    CL1'0'                  CARRIAGE CONTROL TO SKIP 2 LINE  12400019
         DC    CL40'VOLUME          CPU  MOD    TIME    CHAN'           12450019
         DC    CL40'NEL  TEMP   TEMP   PERM  PERM   NOISE   '           12500019
         DC    CL40'ERASE  CLEANER   USAGE    TAPE    BLOCK '           12550019
         SPACE 1                                                        12600019
LINE3    DS    0CL121                                                   12650019
         DC    CL1' '                  CARRIAGE CONTROL TO SKIP 1 LINE  12700019
         DC    CL40'SERIAL   DATE    ID   NO   OF DAY   / UN'           12750019
         DC    CL40'IT   READ   WRITE  READ  WRITE  BLOCKS  '           12800019
         DC    CL40' GAPS  ACTIONS  (SIO''S)  DENSITY  LENGTH'          12850019
         SPACE 1                                                        12900019
LINE4    DS    0CL121                                                   12950019
         DC    CL1'+'                  CARRIAGE CONTROL TO OVERPRINT    13000019
         DC    CL40'______  ______  ___  ___  ________  ____'           13050019
         DC    CL40'___  ____   _____  ____  _____  ______  '           13100019
         DC    CL40'_____  _______  _______  _______  ______'           13150019
         SPACE                                                          13200019
ERRLINE  DS    0CL121                                                   13250019
         DC    CL1'-'                  CARRIAGE CONTROL TO SKIP 3 LINES 13300019
         DC    CL40' '                                                  13350019
         DC    CL40'            NO ESV RECORDS FOUND        '           13400019
         DC    CL40' '                                                  13450019
         EJECT                                                          13500019
*********************************************************************** 13550019
*            WORK AREA FOR STORING 1 LOGICAL INPUT RECORD             * 13600019
*********************************************************************** 13650019
         SPACE                                                          13700019
INAREA   DS    0C                      FORMAT OF TYPE '15' RCD   A53648 13750021
IRECLEN  DS    CL2                     LENGTH OF DATA RECORD            13800019
SKIP1    DS    CL3                     IGNORE 3 BYTE ZERO FIELD         13850019
IRECTYPE DS    CL1                     TYPE OF DATA RECORD              13900019
ITIME    DS    CL4                     TIME FROM GETTIME BINARY MACRO   13950019
IDATE    DS    CL4                     DATE IN THE FORM 00YYDDDX        14000019
ICPUID   DS    CL2                     CPU IDENTIFICATION               14050019
IMODNO   DS    CL2                     MODEL NUMBER OF CPU              14100019
SKIP2    DS    CL2                     IGNORE 2 BYTE FIELD              14150019
IVOLID   DS    CL6                     VOLUME-SERIAL NUMBER             14200019
IADDRESS DS    CL2                     CHANNEL & UNIT IN THE FORM 0CUU  14250019
SKIP3    DS    CL4                     IGNORE 4 BYTE UCB TYPE FIELD     14300019
ITREAD   DS    CL1                     TEMPORARY READ ERROR COUNTER     14350019
ITWRITE  DS    CL1                     TEMPORARY WRITE ERROR COUNTER    14400019
ISIO     DS    CL2                     START I/O COUNTER                14450019
IPREAD   DS    CL1                     PERMANENT READ ERROR COUNTER     14500019
IPWRITE  DS    CL1                     PERMANENT WRITE ERROR COUNTER    14550019
INOISE   DS    CL1                     NOISE BLOCK COUNTER              14600019
IERASE   DS    CL2                     ERASE GAP COUNTER                14650019
ICLEANER DS    CL2                     CLEANER ACTION COUNTER           14700020
IDENSITY DS    CL1                     DENSITY OF TAPE IN ERROR         14750019
IBLOCK   DS    CL2                     BLOCK-SIZE OF TAPE IN ERROR      14800019
RCRDEND  EQU   *                       END OF RECORD             A53648 14850021
         EJECT                                                          14900019
         SPACE 3                                                        14950019
*********************************************************************** 15000019
*            WORK AREA FOR CONSTRUCTION OF 1 LINE OF OUTPUT           * 15050019
*********************************************************************** 15100019
         SPACE                                                          15150019
DATALINE DS    0CL121                  FORMAT OF 1 LINE OF OUTPUT       15200019
CONTROL  DC    CL1' '                  CARRIAGE CONTROL FOR SINGLE SP.  15250019
VOLID    DS    CL6                     VOLUME-SERIAL NUMBER             15300019
         DC    CL2' '                  SPACING                          15350019
YEAR     DS    CL2                     *                                15400019
SLASH    DC    CL1'/'                  DATE IN THE FORM YY/DDD          15450019
DAY      DS    CL3                     *                                15500019
         DC    CL3' '                  SPACING                          15550019
CPUID    DS    CL2                     CPU IDENTIFICATION               15600019
         DC    CL3' '                  SPACING                          15650019
MODNO    DS    CL2                     CPU MODEL NUMBER                 15700019
         DC    CL2' '                  SPACING                          15750019
HOURS    DS    CL2                     *                                15800019
COLON1   DC    CL1':'                  *                                15850019
MINUTES  DS    CL2                     TIME IN THE FORM HH:MM:SS        15900019
COLON2   DC    CL1':'                  *                                15950019
SECONDS  DS    CL2                     *                                16000019
         DC    CL4' '                  SPACING                          16050019
ADDRESS  DS    CL3                     CHANNEL & UNIT IN THE FORM CUU   16100019
         DC    CL5' '                  SPACING                          16150019
TREAD    DS    CL3                     TEMPORARY READ ERROR COUNTER     16200019
         DC    CL4' '                  SPACING                          16250019
TWRITE   DS    CL3                     TEMPORARY WRITE ERROR COUNTER    16300019
         DC    CL4' '                  SPACING                          16350019
PREAD    DS    CL3                     PERMANENT EAD ERROR COUNTER      16400019
         DC    CL3' '                  SPACING                          16450019
PWRITE   DS    CL3                     PERMANENT WRITE ERROR COUNTER    16500019
         DC    CL4' '                  SPACING                          16550019
NOISE    DS    CL3                     NOISE BLOCK COUNTER              16600019
         DC    CL4' '                  SPACING                          16650019
ERASE    DS    CL5                     ERASE GAP COUNTER                16700019
         DC    CL3' '                  SPACING                          16750019
CLEANER  DS    CL5                     CLEANER ACTION COUNTER           16800019
         DC    CL3' '                  SPACING                          16850019
SIO      DS    CL5                     START I/O COUNTER                16900019
         DC    CL6' '                  SPACING                          16950019
DENSITY  DS    CL4                     DENSITY OF TAPE HAVING ERROR     17000019
         DC    CL4' '                  SPACING                          17050019
BLOCK    DS    CL5                     BLOCK SIZE OF TAPE HAVING ERROR  17100019
         DC    CL1' '                  SPACING                          17150019
         EJECT                                                          17200019
*********************************************************************** 17250019
*                                    DCB'S                            * 17300019
*********************************************************************** 17350019
         SPACE                                                          17400019
SYSUT1   DCB   DDNAME=SYSUT1,DSORG=PS,EODAD=FINISHED,EROPT=SKP,        X17450019
               MACRF=(GL),RECFM=VBS,BFTEK=A                      A32896 17500020
         SPACE 3                                                        17550019
SYSUT2   DCB   DDNAME=SYSUT2,DSORG=PS,MACRF=(PM),RECFM=AFB,            X17600019
               LRECL=121,BLKSIZE=121                                    17650019
         SPACE 2                                                        17660021
*********************************************************************** 17670021
*                IFHSTATR'S GENERAL PURPOSE SAVE AREA                 * 17680021
*********************************************************************** 17690021
         SPACE 2                                                        17692021
SAVE     DS    18F                                               A40940 17694021
         SPACE 2                                                        17696021
         END                                                            17700019
