TEST     TITLE 'IGC0006A - FIRST LOAD OF SVC 61, SAVE FOR TSO TEST'     00100020
* TITLE  IGC0006A - FIRST LOAD OF SVC 61, SAVE FOR TSO TEST           * 00200020
*                                                                     * 00300020
* STATUS   --                                                         * 00400020
*    CHANGE LEVEL 001                                            S21919 00450021
*                                                                     * 00500020
* FUNCTION/OPERATION --                                               * 00600020
*    THE FIRST LOAD MODULE OF SVC 61 SAVES INFORMATION ABOUT          * 00700020
*    LOAD MODULES FOR USE BY THE TSO TEST SYMBOL PROCESSOR,           * 00800020
*    MODULE IKJEGSYM AND INFORMS THE AT COMMAND OF THE NAME           * 00900020
*    OF THE MODULE BEING FETCHED SO DEFERRED BREAKPOINTS              * 00950020
*    CAN BE ESTABLISHED.                                              * 00960020
*    SVC 061 IS ISSUED BY FETCH WHEN BRINGING A LOAD MODULE           * 01000020
*    INTO CORE THAT HAS THE TEST ATTRIBUTE IN THE DIRECTORY ENTRY     * 01100020
*    FOR THE MEMBER OR WHEN A LOAD MODULE IS BROUGHT INTO CORE BY     * 01200020
*    TSO TEST.  THIS LOAD OPERATES IF THE MODULE IS RUNNING UNDER     * 01300020
*    A TSO TASK.  IF IT IS NOT A TSO TASK, IGC0006A WILL XCTL TO      * 01400020
*    THE SECOND LOAD OF SVC 61, MODULE IGC0106A.  IGC0106A WILL       * 01500020
*    PROCESS FOR TESTRAN.                                             * 01600020
*    IGC0006A BUILDS A INFO BLK REFLECTING THE LOAD MODULE            * 01700020
*    NAME, LOADED ADDRESS, ATTRIBUTES AND, IF AVAILABLE, A DDNAME     * 01800020
*    WHICH IKJEGSYM CAN OPEN A DCB TO READ THE ASSEMBLER'S SYMBOL     * 01900020
*    TABLES AND LINKAGE EDITORS CESD RECORDS.                         * 02000020
*    IF TEST IS RUNNING, THESE INFO BLOCKS ARE CHAINED FROM           * 02100020
*    A WORD IN TCOMTAB.  IF NOT, THEY ARE CHAINED FROM THE TCB        * 02200020
*    TRN FIELD.                                                       * 02300020
*    ALSO, IF TEST IS RUNNING, THE ECB POINTED TO FROM THE            * 02400020
*    ECBTST FIELD IN TCOMTAB IS POSTED WITH A X'44'.                  * 02500020
*    SVC 61 IS ALSO ISSUED BY THE OVERLAY SUPERVISOR IF               * 02600020
*    TEST IS RUNNING AND A NEW SEGMENT OF AN OVERLAY STRUCTURE        * 02700020
*    IS BROUGHT INTO CORE.  IN THIS CASE, SVC 61 WILL PASS THE        * 02800020
*    NAME OF THE LOAD MODULE TO THE AT COMMAND VIA POST-WAIT.         * 02900020
*                                                                     * 03000020
*    NOTE                                                             * 03100020
*    SVC 61, PRIOR TO TSO TEST, WAS A TYPE 3                          * 03200020
*    SVC THAT WAS OWNED AND USED BY TESTRAN.                          * 03300020
*    FOR TSO TEST, THE ORGINAL CODE IN THIS                           * 03400020
*    MODULE WAS MOVED, WITHOUT CHANGE, TO A                           * 03500020
*    NEW SECOND LOAD, MODULE IGC0106A.  IF                            * 03600020
*    TESTRAN IS REQUESTED, THIS LOAD WILL XCTL                        * 03700020
*    TO THE SECOND LOAD.                                              * 03800020
*                                                                     * 03900020
*                                                                     * 04000020
* ENTRY POINTS --                                                     * 04100020
*         IGC0006A   ONLY ENTRY TO SVC 61                             * 04200020
*                                                                     * 04300020
* INPUT --                                                            * 04400020
*    REGISTERS POINT TO SYSTEM INFORMATION                            * 04450020
*    -FROM CONTENTS SUPERVISOR                                        * 04460020
*    1 - NEGATIVE ADDRESS OF DCB USED TO FETCH THE MEMBER             * 04500020
*    3 - ADDRESS OF CVT                                               * 04600020
*    4 - ADDRESS OF TCB                                               * 04700020
*    5 - ADDRESS OF MY SVRB                                           * 04800020
*    76(5) -  ADDR OF BLDL ENTRY FOR MEMBER                           * 04900020
*    80(5) -  ADDR OF EXTENT LIST FOR MEMBER                          * 05000020
*    -FROM OVERLAY SUPERVISOR                                         * 05100020
*    1 - ZERO                                                         * 05200020
*    80(5) - ADDRESS OF SEGTAB                                        * 05300020
*                                                                     * 05400020
* OUTPUT --                                                           * 05500020
*    SVCINFO BLOCK   FOR TEST SYMBOL PROCESSOR, IKJEGSYM              * 05600020
*    IF TEST IS RUNNING, PASS LOADNAME TO AT COMMAND VIA GENERAL      * 05700020
*    WORK AREA                                                        * 05800020
*                                                                     * 05900020
* EXTERNAL REFERENCES --                                              * 06000020
*         XCTL         TO SECOND LOAD, IF TESTRAN REQUESTED           * 06100020
*         GETMAIN      OBTAIN CORE FOR A SYMINFO BLOCK OR AN ECB      * 06200020
*         POST         MAINLINE SO AT CMD CAN PROCESS                 * 06300020
*         WAIT         FOR AT CMD TO FINISH PROCESSING                * 06400020
*                      OR IF MULTI-TASKING, FOR MAINLINE TO FINISH    * 06410020
*                                                                     * 06500020
* EXITS, NORMAL --                                                    * 06600020
*         ISSUE SVC 3 WHEN DONE OR XCTL TO 2ND LOAD IF NOT A TSO TASK * 06700020
*                                                                     * 06800020
* EXITS, ERROR --                                                     * 06810020
*        N/A                                                          * 06820020
*                                                                     * 06830020
* TABLES/WORKAREAS --                                                 * 06900020
*    TCOMTAB   IF TEST IS RUNNING                                     * 07000020
*    TCB       TTRN FIELD, TIOT ADDRESS                               * 07100020
*    MY SVRB   WORK AREAS, POINTERS                                   * 07200020
*    BLDL      ENTRY FOR FETCH MEMBER                                 * 07300020
*    XL        FOR FETCHED MEMBER                                     * 07400020
*    DCB       USED TO FETCH MEMBER                                   * 07500020
*    TIOT      IF AVAILABLE, GET DDNAME ALLOCATING PDS                * 07600020
*                                                                     * 07700020
* ATTRIBUTES --                                                       * 07800020
*    REENTRANT AND REFRESHABLE                                        * 07900020
*                                                                     * 08000020
* CHARACTER CODE DEPENDENCY --                                        * 08050020
*    RE-ASSEMBLY IS REQUIRED FOR CHANGE OF CODE                       * 08060020
*                                                                     * 08070020
* NOTES --                                                            * 08100020
*    THE SVC INFO BLOCKS ARE FREED BY MAINLINE AT THE END             * 08200020
*    OF A TEST SESSION.                                               * 08300020
*                                                                     * 08400020
         EJECT                                                          08500020
         TCOMTAB                                                        08600020
         SPACE 2                                                        08700020
         TSTCWORK                                                       08800020
         EJECT                                                          08900020
IGC0006A CSECT                                                          09000021
*RELEASE 21 CHANGES                                              S21919 09010021
*D257000                                                         S21919 09050021
*C4500,256000,258000                                             S21919 09060021
*A254500                                                         S21919 09070021
         SPACE 3                                                        09100020
*********************************************************************** 09200020
*                                                                     * 09300020
*        EQUATES                                                      * 09400020
*                                                                     * 09500020
*********************************************************************** 09600020
         SPACE 2                                                        09700020
*                                                                       09800020
*        REGISTER EQUATES                                               09900020
*                                                                       10000020
PARMREG0 EQU   0         REGISTER 0                                     10100020
PARMREG1 EQU   1         REGISTER 1                                     10200020
DCBPTR   EQU   2         ADDRESS OF DCB                                 10300020
ADDRCVT  EQU   3         ADDRESS OF CVT                                 10350020
TCBPTR   EQU   4         ADDRESS OF TCB                                 10400020
SVRBPTR  EQU   5         ADDRESS OF MY SVRB                             10500020
TSVCBASE EQU   6         BASE REGISTER FOR IGC0006A                     10600020
WORKA    EQU   7         REGISTER 7                                     10700020
WORKB    EQU   8         REGISTER 8                                     10800020
TCOMTABB EQU   9         WHEN TEST IS RUNNING, ADDRESS OF TCOMTAB       10900020
SVCINFOB EQU   10        ADDR OF ANSWER BLOCK, BASE FOR DESCRIPTIVE SEC 11000020
WKPARTB  EQU   11        ADDR OF EXTENDED AREA IN SVRB, USE AS WORKAREA 11100020
SEGTABAD EQU   12        IF ISSUER IS OVLY SUPRVSR, ADDRESS OF SEGTAB   11200020
SOMESAVE EQU   13        REGISTER 13                                    11300020
RETURN   EQU   14        REGISTER 14                                    11400020
REG15    EQU   15        REGISTER 15                                    11500020
*                                                                       11600020
*        NUMBER EQUATES                                                 11700020
*                                                                       11800020
N1       EQU   1             DECIMAL 1                                  11900020
N2       EQU   2             DECIMAL 2                                  12000020
*                                                                       12100020
*        LENGTH EQUATES                                                 12200020
*                                                                       12300020
L2       EQU   2             LENGTH OF 2                                12400020
L4       EQU   4             LENGTH OF 4                                12500020
L8       EQU   8             LENGTH OF 8                                12600020
*                                                                       12610020
*        CONDITION CODE EQUATES FOR BCR INSTRUCTIONS                    12620020
*                                                                       12630020
EQUAL    EQU   8             BRANCH IF EQUAL                            12640020
ONES     EQU   1             BRANCH IF ONES                             12650020
*                                                                       12700020
*        DISPLACMENT EQUATES                                            12800020
*                                                                       12900020
D0       EQU   0             ZERO DISPLACMENT                           13000020
D3       EQU   3             DISPLACMENT OF 3                           13100020
D4       EQU   4             DISPLACMENT OF 4                           13200020
D8       EQU   8             DISPLACMENT 0F 8                           13300020
D24      EQU   24            DISPLACMENT OF 24                          13350020
D32      EQU   32            DISPLACMENT OF 32                          13400020
D76      EQU   76            DISPLACMENT 0F 76                          13500020
D80      EQU   80            DISPLACMENT 0F 80                          13600020
D96      EQU   96            DISPLACMENT OF 96                          13700020
TIOTDD   EQU   4             OFFSET INTO TIOT ENTRY OF DDNAME           13800020
*                                                                       14600020
*        OTHER EQUATES                                                  14700020
*                                                                       14800020
EXIT     EQU   3             THREE                                      14900020
SP250    EQU   250           SUBPOOL 250, GET CORE IN SUBPOOL 0         14950020
ATATTRIB EQU   CWORKCMD+D8   LOC IN GEN WKAREA OF LMOD ATTRIB FOR AT    14960020
*                                                                       15000020
*        IMMEDIATE OPERANDS                                             15100020
*                                                                       15200020
X00      EQU   X'00'         HEX 00                                     15300020
X01      EQU   X'01'         HEX 01                                     15400020
X80      EQU   X'80'         HEX 80                                     15500020
X40      EQU   X'40'         HEX 40                                     15600020
TCBCHAIN EQU   X'80'         SW IN FLAGS, FIRST TIME - CHAIN FROM TCB   15700020
OVLYBLK  EQU   X'40'         SW IN FLAGS, OVLYED A DUPLICATE LOADNAME   15800020
OVLYBIT  EQU   X'20'         OVLY ATTRIBUTE BIT IN BLDL ATTRIBUTE FIELD 16000020
FF       EQU   X'FF'         MASK BYTE                                  16060020
         SPACE 3                                                        16100020
*********************************************************************** 16200020
*                                                                     * 16300020
*        THIS IS THE ENTRY INITILIZATION ROUTINE                      * 16400020
*                                                                     * 16500020
*********************************************************************** 16600020
         SPACE 2                                                        16700020
         BALR  TSVCBASE,D0                  ADDRESSABILITY              16800020
         BCTR  TSVCBASE,D0                  MAKE BASE EQUAL             16900020
         BCTR  TSVCBASE,D0                   TO ENTRY POINT             17000020
         USING IGC0006A,TSVCBASE                                        17100020
         LA    WKPARTB,RBEXSAVE-RBSECT(SVRBPTR)     BASE                17200020
         USING WORKPART,WKPARTB              WORK AREA IN SVRB          17300020
*                                                                       17400020
*        IF IT IS NOT A TSO TASK, XCTL TO THE SECOND LOAD, IGC0106A     17500020
*                                                                       17600020
         TM    TCBTSFLG-TCB(TCBPTR),TCBTSTSK    IS IT  A TSO TASK       17700020
         BO    FORTEST                      YES, GO SAVE FOR TEST       17800020
         MVC   XCTLLIST(LENLF),LFXCTL       LIST FORM OF XCTL TO WKAREA 17900020
         LA    REG15,EPNAME                 ADDR OF NAME OF SECOND LOAD 18000020
         ST    REG15,ADDREP                 INTO XCTL PARM LIST         18100020
         LA    REG15,XCTLLIST               ADDRESS OF XCTL PARM LIST   18200020
         L     WORKA,CVTPTR                 ADDRESS OF CVT              18300020
         L     WORKA,CVTSVDCB-CVT(WORKA)    ADDR- DCB FOR SVCLIB        18400020
         XCTL  ,DCB=(WORKA),MF=(E,(1)),SF=(E,(15))                      18500020
*                                                                       18600020
FORTEST  EQU   *                                                        18700020
         LPR   DCBPTR,PARMREG1              POSITIVE ADDRESS OF DCB     18800020
         LA    TCBPTR,D0(TCBPTR)            ADDR OF LOADNAME'S TCB      18900020
         USING TCOMTAB,TCOMTABB                                         19000020
         USING SVCINFO,SVCINFOB                                         19100020
         MVI   FLAGS,X00                    CLEAR SVC STATUS FLAGS      19200020
         XC    TCBADDR(L4),TCBADDR          CLEAR TCB ADDR FOR MAINLINE 19250020
         TM    TCBTRN-TCB(TCBPTR),TCBTCP    IS TEST RUNNING             19300020
         BZ    TESTOFF                      NO, GO SAVE FOR LATER USE   19400020
         L     TCOMTABB,TCBTRN-TCB(TCBPTR)  GET ADDR OF TCOMTAB         19500020
         L     WORKA,WORKAREA               ADDR OF AREA TO BE CHANGED  19600020
         BAL   RETURN,CHKSTKEY              GO CHECK STORAGE KEY        19700020
         LR    WORKA,TCOMTABB               ADDR OF AREA TO BE CHANGED  19800020
         BAL   RETURN,CHKSTKEY              GO CHECK STORAGE KEY        19900020
         L     WORKA,ECBTST                 ADDR OF AREA TO BE CHANGED  20000020
         BAL   RETURN,CHKSTKEY              GO CHECK STORAGE KEY        20100020
         LTR   DCBPTR,DCBPTR                IS ISSUER OVLY SUPERVISOR   20200020
         BZ    OVERLAY1                     YES, GO SEARCH SVCINFO BLKS 20300020
         L     SVCINFOB,TSTTRN              HEAD OF SVCINFO BLK CHAIN   20400020
         LTR   SVCINFOB,SVCINFOB            IS THEIR A CHAIN            20500020
         BZ    NOCNTRL                      NO, GO SET UP TO HAVE MAIN  20530020
*                                            LINE CREATE A TCB CNTRL    20560020
*                                            CHAIN BLK FOR THIS TCB     20590020
GETTCB   EQU   *                                                        20620020
         C     TCBPTR,D4(SVCINFOB)          IS CNTRL BLK FOR THIS TCB   20650020
         BNE   NEXTTCB                      NO, GO CHECK NEXT CNTRL BLK 20653020
*                                                                       20656020
*        A TCB CONTROL BLOCK AND THE ASSOCIATED SVCINFO BLOCK CHAIN     20659020
*        EXISTS FOR THE TCB THE SVC IS OPERATING UNDER.  CHECK IF THIS  20662020
*        IS A NEW TCB WHOSE ADDR IS THE SAME AS ONE THAT WAS DETACHED   20665020
*                                                                       20668020
         L     WORKA,RBLINK-RBSECT(SVRBPTR)      ADDR OF CALLERS PRB    20671020
         TM    RBSTAB2-RBSECT(WORKA),RBTCBNXT    IS HE ONLY RB ON TCB   20674020
         BZ    GOSEARCH                          NO, TCB NOT NEW, GO    20677020
         TM    RBCDFLGS-RBSECT(WORKA),X01        HAS LOAD BEEN ISSUED   20680020
         BO    GOSEARCH                          YES, TCB NOT NEW, GO   20683020
         L     WORKA,TCBLLS-TCB(TCBPTR)          ADDR OF LOAD LIST      20686020
         LTR   WORKA,WORKA                       IS THEIR A LOAD LIST   20689020
         BNZ   GOSEARCH                          YES, TCB NOT NEW, GO   20692020
*                                                                       20695020
*        THE TCB IS NEW OR THE ONLY RB HAS XCTLED.  START A NEW SVCINFO 20698020
*        BLOCK CHAIN USING THE OLD TCB CONTROL BLOCK                    20701020
*                                                                       20704020
         LA    WORKA,D8(SVCINFOB)           ADDR OF SVC CHAIN SLOT IN   20707020
*                                            TCB CONTROL BLOCK          20710020
         ST    WORKA,CHAINEND               SAVE FOR CHAINNING          20713020
         BAL   RETURN,CHKSTKEY              GO CHECK ITS STORAGE KEY    20716020
         B     SETUPGET                     GO GET A SVCINFO BLOCK      20719020
NEXTTCB  EQU   *                                                        20722020
         L     SVCINFOB,D0(SVCINFOB)        NO, ADDR OF NEXT CNTRL BLK  20740020
         LTR   SVCINFOB,SVCINFOB            IS THEIR ANY MORE           20770020
         BNZ   GETTCB                       YES, GO SEE IF FOR THIS TCB 20800020
NOCNTRL  EQU   *                                                        20830020
         ST    TCBPTR,TCBADDR               ADDR OF TCB FOR MAINLINE    20860020
         B     SETUPGET                     GO GET AN SVCINFO BLOCK     20890020
GOSEARCH EQU   *                                                        20920020
         L     SVCINFOB,D8(SVCINFOB)        ADDR OF CHAIN FOR CURR TCB  20950020
         BAL   RETURN,SEARCH1               GO SEARCH FOR END OF CHAIN  21100020
*                                            OR DUPLICATE ON CHAIN      21200020
         LR    WORKA,SVCINFOB               ADDR OF AREA TO BE CHANGED  21300020
         BAL   RETURN,CHKSTKEY              GO CHECK STORAGE KEY        21400020
         TM    FLAGS,OVLYBLK                WAS A DUPLICATE FOUND       21500020
         BO    TESTSET                      YES, GO CHECK MULTI-TASK SW 21600020
         LA    WORKA,NEXTBLK                END OF CHAIN, 0 NEXTBLK PTR 21700020
         ST    WORKA,CHAINEND               SAVE FOR CHAINNING          21800020
SETUPGET EQU   *                                                        21900020
         BAL   RETURN,GETSVCBK              GO GET A NEW SVCINFO BLOCK  22000020
         ST    SVCINFOB,SVCBLKPT            ADDR OF SVC BLK FOR MAINLNE 22050020
TESTSET  EQU   *                                                        22100020
         TS    TSTMTASK                     SHOULD WE SAVE FOR TEST     22200020
         BZ    PROCESS                      YES, GO SAVE FOR TEST       22300020
         L     PARMREG0,GETECB              GETMAIN, 8 BYTES IN SP 250  22400020
         GETMAIN   R,LV=(PARMREG0)          FOR AN ECB AND PTR TO NEXT  22500020
         L     WORKB,TSTSVCQ                PTR TO MULTI-TASK ECB CHAIN 22600020
         ST    PARMREG1,TSTSVCQ             GOTTEN ECB ADDR ON CHAIN    22700020
         SR    WORKA,WORKA                  CLEAR REGISTER TO ZERO      22800020
         STM   WORKA,WORKB,D0(PARMREG1)     GOTTEN CORE EQUALS          22900020
*                                            ECB(ZERO), PTR TO NEXT ECB 23000020
         LR    WORKA,PARMREG1               SAVE ADDR OF BLK-FREE LATER 23050020
         NI    TCBTSFLG-TCB(TCBPTR),FF-TCBATT   ENABLE FOR ATTEN        23060020
         SSM   ENABLE                       ENABLE FOR INTERRUPTS       23100020
         WAIT  N1,ECB=(PARMREG1)            WAIT FOR MAINLINE TO POST   23200020
         OI    TCBTSFLG-TCB(TCBPTR),TCBATT      DISABLE ATTENTION       23210020
         FREEMAIN  R,LV=L8,A=(WORKA),SP=SP250     FREE GOTTEN ECB BLK   23250020
PROCESS  EQU   *                                                        23300020
         SSM   ENABLE                       ENABLE FOR INTERRUPTS       23400020
         LTR   DCBPTR,DCBPTR                IS ISSUER OVLY SUPERVISOR   23500020
         BZ    DOPOST                       YES, GO PROCESS FOR OVLY    23600020
         BAL   RETURN,FILLBLK               GO FILL IN SVCINFO BLOCK    23700020
         L     WORKA,TCBADDR                CHAIN STATUS INDICATOR      23720020
         LTR   WORKA,WORKA                  DOES CHAIN EXIST FOR TCB    23740020
         BNZ   DOPOST                       NO, GO LET MAINLINE CHAIN   23760020
         BAL   RETURN,CHAINBLK              GO CHAIN BLOCK              23800020
         SPACE 3                                                        23900020
*********************************************************************** 24000020
*                                                                     * 24100020
*        IF TEST IS RUNNING, POST THE ECB                             * 24200020
*                                                                     * 24300020
*********************************************************************** 24400020
         SPACE 2                                                        24500020
DOPOST   EQU   *                                                        24600020
         L     WORKB,WORKAREA               BASE FOR TSTCWORK FROM      24700020
         USING TSTCWORK,WORKB                TCOMTAB                    24800020
         MVC   CWORKCMD(L8),LMODNAME        LOADNAME TO GENERAL WORK    24900020
*                                            AREA FOR AT COMMAND        25000020
         MVC   ATATTRIB(L2),LMATTRIB        ATTRIBUTES FOR AT CMD       25050020
         DROP  WORKB                                                    25100020
POSTWAIT EQU   *                                                        25200020
         LA    SVRBPTR,D0(SVRBPTR)          CLEAR HIGH ORDER BYTE       25260020
         ST    SVRBPTR,ECBPP                PTR TO MY SVRB FOR MAINLINE 25320020
         L     PARMREG1,ECBTST              ADDR OF ECB TO POST         25400020
         LA    PARMREG1,D0(,PARMREG1)       ZERO HIGH ORDER BYTE S21919 25450021
         L     PARMREG0,POSTCODE            COMPLETION CODE             25500020
         POST  (1),(0)                      POST TEST ECB        S21919 25600021
         WAIT  N1,ECB=ECBPP                 WAIT FOR MAINLINE    S21919 25800021
         SPACE 3                                                        25900020
*********************************************************************** 26000020
*                                                                     * 26100020
*        RETURN TO ISSUER OF SVC 061                                  * 26200020
*                                                                     * 26300020
*********************************************************************** 26400020
         SPACE 2                                                        26500020
TOISSUER EQU   *                                                        26600020
         LM    PARMREG0,REG15,D32(SVRBPTR)  RESTORE REGS FROM MY SVRB   26700020
         SVC   EXIT                         RETURN TO ISSUER OF SVC 61  26800020
         SPACE 3                                                        26900020
*********************************************************************** 27000020
*                                                                     * 27100020
*        SUB ROUTINES FOR MAINSTREAM                                  * 27200020
*                                                                     * 27300020
*********************************************************************** 27400020
         SPACE 2                                                        27500020
*                                                                       27600020
*        GET A SVCINFO BLOCK                                            27700020
*                                                                       27800020
GETSVCBK EQU   *                                                        27900020
         ST    RETURN,RETURNAD              SAVE RETURN ADDRESS         28000020
         L     PARMREG0,GETBLK              GETMAIN, 36 BYTES IN SP250  28100020
         GETMAIN   R,LV=(PARMREG0)          GET AN SVCINFO BLOCK        28200020
         LA    SVCINFOB,D0(PARMREG1)        ADDRESS OF GOTTEN CORE      28300020
         XC    NEXTBLK(L4),NEXTBLK          LAST NEXT BLK ADDR IS ZERO  28400020
         L     RETURN,RETURNAD              RESTORE RETURN ADDRESS      28500020
         BR    RETURN                       RETURN TO CALLER            28600020
*                                                                       28700020
*        SEARCH SVCINFO BLOCK CHAIN FOR THE END OF THE CHAIN OR A       28800020
*        DUPLICATE LOADNAME ON THE CHAIN.  IF THE LOADNAME DOES NOT     28900020
*        EXIST ON THE CHAIN OR THE DUPLICATE IS HUNG OFF OF A           29000020
*        DIFFERENT TCB, SET UP TO ADD ANOTHER SVCINFO BLOCK TO THE      29100020
*        CHAIN.  IF A DUPLICATE EXISTS ON THE SAME TCB, SET UP TO       29200020
*        OVERLAY THE OLD SVCINFO BLOCK.                                 29300020
*                                                                       29400020
SEARCH1  EQU   *                                                        29500020
         L     WORKA,D76(SVRBPTR)           ADDR OF LOADNAME-BLDL ENTRY 29600020
         SR    PARMREG1,PARMREG1            CLEAR REGISTER              29700020
LOOP1    EQU   *                                                        29800020
         CLC   LMODNAME(L8),D0(WORKA)       IS LOADNAME ON CHAIN        29900020
         BE    DUPLCATE                     YES, GO INDICATE OVLY BLK   30000020
         C     PARMREG1,NEXTBLK             IS IT END OF CHAIN          30200020
         BCR   EQUAL,RETURN                 YES, GO RETURN TO CALLER    30300020
         L     SVCINFOB,NEXTBLK             NO, POINT TO NEXT BLK       30400020
         B     LOOP1                        GO SEARCH NEXT BLOCK        30500020
DUPLCATE EQU   *                                                        30600020
         OI    FLAGS,OVLYBLK                YES, INDICATE OVLY-NO CHAIN 30900020
         BR    RETURN                       RETURN TO CALLER            31000020
*                                                                       31100020
*        FILL  IN SVCINFO BLOCK                                         31200020
*                                                                       31300020
FILLBLK  EQU   *                                                        31400020
         MVI   LMFLAGS,X00                  CLEAR SVCINFO BLK SWITCHES  31500020
         L     WORKA,D76(SVRBPTR)           ADDR OF BLDL ENTRY          31700020
         USING BLDLENTY,WORKA               BASE FOR DESCRIPTIVE DSECT  31800020
         MVC   LMODNAME(L8),MNAME           LOAD MODULE NAME            31900020
         ST    TCBPTR,LMTCB                 ADDRESS OF LOADNAME'S TCB   32000020
         MVC   LMBEGTTR(L4),MBEGTTR         TTR OF BEGINNING OF MEMBER  32100020
         MVC   LMATTRIB(L2),MATTRIB         ATTRIBUTES OF MEMBER        32300020
         MVC   CONCATNO(N1),MCONCAT         CONCATENATION NO. OF PDS    32350020
         MVC   LMDDNAME(L8),BLANKS          BLANK DDNAME FIELD          32400020
         DROP  WORKA                                                    32440020
         C     DCBPTR,CVTLINK-CVT(ADDRCVT)  IS DCB USED, SYSTEM DCB     32480020
         BE    LINKLIB                      YES, GO CHECK FOR LINKLIB   32520020
         OI    LMFLAGS,X80                  INDICATE DDNAME AVAILABLE   32560020
         L     WORKA,TCBTIO-TCB(TCBPTR)     ADDRESS OF TIOT FROM TCB    32600020
         LA    WORKA,D0(WORKA)              CLEAR HIGH ORDER BYTE       32640020
         AH    WORKA,DCBTIOT-IHADCB(DCBPTR) ADDRESS OF DCB DDNAME ENTRY 32680020
         MVC   LMDDNAME(L8),TIOTDD(WORKA)   DDNAME FROM TIOT ENTRY      32720020
         CLC   LMDDNAME(L8),BLANKS          IS DATASET CONCATENATED     32760020
         BNE   GETLA                        NO, DDNAME OK, GET LOAD ADR 32800020
         L     WORKB,TCBTIO-TCB(TCBPTR)     ADDRESS OF TIOT FROM TCB    32840020
         LA    WORKB,D24(WORKB)             ADDRESS OF FIRST ENTRY      32880020
LOOPTIOT EQU   *                                                        32920020
         CR    WORKA,WORKB                  IS THIS ENTRY DCB DD ENTRY  32960020
         BE    GETLA                        YES, GOT DDNAME, GO GET LA  33000020
         CLC   BLANKS(L8),TIOTDD(WORKB)     IS TIOT ENTRY DDNAME BLANK  33040020
         BE    NEXTENTY                     YES, GO POINT TO NEXT ENTRY 33080020
         MVC   LMDDNAME(L8),TIOTDD(WORKB)   NO, GET DDNAME FROM TIOT    33120020
NEXTENTY EQU   *                                                        33160020
         SR    PARMREG1,PARMREG1            CLEAR REGISTER TO ZEROES    33200020
         IC    PARMREG1,D0(WORKB)           LENGTH OF THIS TIOT ENTRY   33240020
         AR    WORKB,PARMREG1               ADDRESS OF NEXT DD ENTRY    33280020
         B     LOOPTIOT                     GO CHECK FOR END OF LOOP    33320020
LINKLIB  EQU   *                                                        33360020
         XC    LMDDNAME(L8),LMDDNAME        CLEAR DDNAME TO ZEROES      33400020
         CLI   CONCATNO,X00                 IS DATASET LINKLIB          33440020
         BNE   GETLA                        NO, CAN DO NOTHING, GO ON   33480020
         OI    LMFLAGS,X40                  INDICATE DATASET IS LINKLIB 33520020
GETLA    EQU   *                                                        33600020
         L     WORKA,D80(SVRBPTR)           ADDR OF EXTENT LIST         33700020
         L     WORKB,D4(WORKA)              NUMBER OF SCATTERED BLOCKS  33800020
         SLL   WORKB,N2                     TIMES NO. BYTES IN A WORD   33900020
         LA    WORKA,D8(WORKB,WORKA)        PTR TO ADDR OF FIRST BLOCK  34000020
         MVC   LMLADDR(L4),D0(WORKA)        LOADED ADDR TO SVCINFO BLK  34100020
         BR    RETURN                       RETURN TO CALLER            34200020
*                                                                       34300020
*        IF NOT OVERLAYING A SVCINFO BLOCK, ADD NEW ONE TO CHAIN OR     34400020
*        START THE CHAIN                                                34500020
*                                                                       34600020
CHAINBLK EQU   *                                                        34700020
         TM    FLAGS,OVLYBLK                DID WE OVLY A BLOCK         34800020
         BCR   ONES,RETURN                  YES, RETURN TO CALLER       34900020
         TM    FLAGS,TCBCHAIN               START CHAIN FROM TCB        35000020
         BZ    CHAINIT                      NO, GO ADD TO EXISTNG CHAIN 35100020
         SR    PARMREG1,PARMREG1            CLEAR REGISTER              35200020
         IC    PARMREG1,TCBTRN-TCB(TCBPTR)  FLAG BYTE FROM TCBTRN FIELD 35300020
         OR    PARMREG1,SVCINFOB            FLAGS PLUS HEAD OF CHAIN    35400020
         ST    PARMREG1,TCBTRN-TCB(TCBPTR)  INTO TRN FIELD IN TCB       35500020
         BR    RETURN                       RETURN TO CALLER            35600020
CHAINIT  EQU   *                                                        35700020
         L     WORKB,CHAINEND               ADDR OF 0 NEXTBLK FOR CHAIN 35800020
         ST    SVCINFOB,D0(WORKB)           ADD NEW BLOCK TO CHAIN      35900020
         BR    RETURN                       RETURN TO CALLER            36000020
         SPACE 2                                                        36100020
*********************************************************************** 36200020
*                                                                     * 36300020
*        COMPARE STORAGE KEY IN TCB TO STORAGE KEY OF ADDRESS PASSED  * 36400020
*        IN WORKA                                                     * 36500020
*                                                                     * 36600020
*********************************************************************** 36700020
         SPACE 2                                                        36800020
CHKSTKEY EQU   *                                                        36900020
         N     WORKA,ADDRMASK               ADDR OF AREA SET FOR ISK    37000020
         ISK   WORKB,WORKA                  GET STORAGE KEY OF AREA     37100020
         N     WORKB,KEYMASK                CLEAR NOISE BITS            37200020
         STC   WORKB,AREAKEY                KEY INTO WORK AREA          37300020
         CLC   AREAKEY(N1),TCBPKF-TCB(TCBPTR) IS AREA KEY = REGION KEY  37400020
         BCR   EQUAL,RETURN                 YES, GO BACK AND PROCESS    37500020
         B     TOISSUER                     NO, GO RETURN TO ISSUER     37600020
         SPACE 2                                                        37700020
*********************************************************************** 37800020
*                                                                     * 37900020
*        THIS ROUTINE WILL PASS THE LOADNAME OF A LOAD MODULE LINK    * 38000020
*        EDITTED IN OVERLAY TO THE AT COMMAND WHEN THE OVERLAY        * 38100020
*        SUPERVISOR BRINGS A NEW SEGMENT INTO CORE                    * 38200020
*                                                                     * 38300020
*********************************************************************** 38400020
         SPACE 2                                                        38500020
OVERLAY1 EQU   *                                                        38600020
         L     SEGTABAD,D80(SVRBPTR)        ADDRESS OF SEGMENT TABLE    38700020
         LA    SEGTABAD,D0(SEGTABAD)        ADDRESS OF SEGMENT TABLE    38800020
         L     SVCINFOB,TSTTRN              HEAD OF SVCINFO BLOCK CHAIN 38900020
OVERLAYA EQU   *                                                        38950020
         LTR   SVCINFOB,SVCINFOB            IS THEIR A CHAIN            39000020
         BZ    TOISSUER                     NO, GO SET UP RETURN        39100020
         C     TCBPTR,D4(SVCINFOB)          THIS CHAIN FOR CURRENT TCB  39110020
         BE    OVERLAYB                     YES, GO SEARCH CHAIN        39120020
         L     SVCINFOB,D0(SVCINFOB)        ADDR OF NEXT TCB CNTRL BLK  39130020
         B     OVERLAYA                     GO CHECK FOR A CHAIN        39140020
OVERLAYB EQU   *                                                        39150020
         L     SVCINFOB,D8(SVCINFOB)        PTR TO FIRST BLK ON CHAIN   39160020
OVERLAY2 EQU   *                                                        39200020
         C     SEGTABAD,LMLADDR             IS SEGTAB FOR THIS SVC BLK  39300020
         BE    OVERLAY4                     YES, GO CHECK FOR OVLY      39400020
OVERLAY3 EQU   *                                                        39500020
         C     DCBPTR,NEXTBLK               IS THIS THE LAST BLOCK      39600020
         BE    TOISSUER                     YES, GO SET UP RETURN       39700020
         L     SVCINFOB,NEXTBLK             POINT TO NEXT SVCINFO BLK   39800020
         B     OVERLAY2                     GO CHECK NEXT SVCINFO BLK   39900020
OVERLAY4 EQU   *                                                        40000020
         TM    LMATTRIB,OVLYBIT             IS LOAD MODULE IN OVERLAY   40100020
         BZ    OVERLAY3                     NO, GO BACK-CONTINUE SEARCH 40200020
         B     TESTSET                      YES, GO PASS LOADNAME TO    40300020
*                                            AT COMMAND                 40400020
         SPACE 2                                                        41200020
*********************************************************************** 41400020
*                                                                     * 41500020
*        THIS ROUTINE WILL SAVE THE SVC INFO IF TEST IS NOT RUNNING   * 41600020
*                                                                     * 41700020
*********************************************************************** 41800020
         SPACE 2                                                        41900020
TESTOFF  EQU   *                                                        42000020
         L     SVCINFOB,TCBTRN-TCB(TCBPTR)  TRN FIELD OF TCB CAN BE     42100020
*                                            HEAD OF SVCINFO BLK CHAIN  42200020
*                                            ZERO                       42300020
         LA    SVCINFOB,D0(SVCINFOB)        CLEAR TRN FLAGS FIELD       42400020
         LTR   SVCINFOB,SVCINFOB            IS IT FIRST TIME            42500020
         BNZ   NOTFIRST                     NO, GO SET UP TO SEARCH     42600020
         OI    FLAGS,TCBCHAIN               INDICATE CHAIN FROM TCB     42700020
SETGET   EQU   *                                                        42800020
         BAL   RETURN,GETSVCBK              GO GET AN SVCINFO BLOCK     42900020
SETFILL  EQU   *                                                        43000020
         BAL   RETURN,FILLBLK               GO FILL IN GOTTEN SVC BLK   43100020
         BAL   RETURN,CHAINBLK              GO START CHAIN FROM TCBTRN  43200020
         B     TOISSUER                     GO SET UP RETURN TO ISSUER  43300020
NOTFIRST EQU   *                                                        43400020
         BAL   RETURN,SEARCH1               GO SEARCH FOR DUP OR END    43500020
         LR    WORKA,SVCINFOB               ADDRESS OF AREA TO CHANGE   43600020
         BAL   RETURN,CHKSTKEY              GO CHECK STORAGE KEY        43700020
         TM    FLAGS,OVLYBLK                ARE WE GOING TO OVLY A BLK  43800020
         BO    SETFILL                      YES, GO SET UP TO OVLY BLK  43900020
         LA    WORKA,NEXTBLK                LAST 0 NEXTBLK ADDRESS      44000020
         ST    WORKA,CHAINEND               SAVE FOR CHAINNING          44100020
         B     SETGET                       GO SET UP TO GET A SVC BLK  44200020
         SPACE 2                                                        44300020
*********************************************************************** 44400020
*                                                                     * 44500020
*        CONSTANTS                                                    * 44600020
*                                                                     * 44700020
*********************************************************************** 44800020
         SPACE 2                                                        44900020
POSTCODE DS    0F                                                       45000020
         DC    X'04000000'                  COMPLETION CODE FOR ECB     45100020
ADDRMASK DC    X'00FFF800'                  AND FIELD FOR AREA ADDRESS  45200020
KEYMASK  DC    X'000000F0'                  AND FIELD FOR AREA KEY      45300020
GETECB   DC    AL1(250)                     GETMAIN WORD,               45400020
         DC    AL3(8)                        GET 8 BYTES IN SP 250      45500020
GETBLK   DC    AL1(250)                     GETMAIN PARMS FOR SVC BLK   45600020
         DC    AL3(36)                       GET 36 BYTES IN SP 250     45700020
LFXCTL   XCTL  EP=IGC0106A,SF=L                                         45800020
ELFXCTL  EQU   *                                                        45900020
BLANKS   DC    8C' '                        BLANKS FOR CLEARING WKAREAS 46000020
ENABLE   DC    X'FF'                        ENABLED SYSTEM MASK         46100020
         SPACE 3                                                        46200020
*********************************************************************** 46300020
*                                                                     * 46400020
*        DSECTS                                                       * 46500020
*                                                                     * 46600020
*********************************************************************** 46700020
         SPACE 2                                                        46800020
WORKPART DSECT     ,    THIS DSECT DESCRIBES THE EXTENDED SAVE AREA     46900020
*                       IN MY SVRB AS USED AS A WORK AREA               47000020
*                                                                       47100020
TCBADDR  DS    F                            TCB ADDRESS FOR MAINLINE    47130020
SVCBLKPT DS    F                            SVC BLK ADDR FOR MAINLINE   47160020
CHAINEND DS    F                            ADDR OF 0 NEXTBLK IN CHAIN  47200020
RETURNAD DS    F                            RETURN ADDRESS              47300020
AREA1    DS    H                            WORK AREA                   47400020
AREAKEY  DS    X                            STORAGE KEY OF AREA         47500020
FLAGS    DS    X                            FLAGS FOR SVC PROCESSING    47600020
*                                                BIT 0 FIRST TIME, TCB  47700020
*                                                    1 OVLYED A BLOCK   47800020
EWKPART1 EQU   *                                                        47900020
         ORG   WORKPART      GO BACK TO BEGINNING OF WORK AREA          48000020
XCTLLIST DS    0F                      LIST FORM OF XCTL                48100020
ADDREP   DS    A                            ADDR OF 2ND LOAD E.P. NAME  48200020
ADDRDCB  DS    A                            ADDRESS OF A SVCLIB DCB     48300020
EPNAME   DS    8C                           NAME OF 2ND LOAD, XCTL TO   48400020
EWKPART2 EQU   *                                                        48500020
         SPACE 2                                                        48600020
SVCINFO  DSECT     ,    THIS DSECT DESCRIBES THE INFORMATION SAVED      48700020
*                       FOR THE TSO TEST SYMBOL PROCESSOR, IKJEGSYM     48800020
*                                                                       48900020
LMODNAME DS    D                            MEMBER NAME                 49000020
LMLADDR  DS    F                            LOADED ADDRESS              49100020
LMBEGTTR DS    F                            TTR OF BEG OF MEMBER        49200020
LMATTRIB DS    H                            ATTRIBUTES OF MEMBER        49300020
LMFLAGS  DS    X                            FLAGS FOR SVCINFO BLOCK     49400020
*                                                BIT 0 DDNAME PRESENT   49500020
*                                                BIT 1 LIB IS LINKLIB   49550020
CONCATNO DS    X                            CONCATENATION NO. OF PDS    49600020
LMDDNAME DS    2F                           DDNAME ALLOC PDS OR BLANKS  49900020
LMTCB    DS    F                            LOADNAME TCB ADDRESS        50000020
NEXTBLK  DS    A                            POINT TO NEXT BLOCK OR ZERO 50100020
         SPACE 2                                                        50200020
BLDLENTY DSECT     ,    THIS DSECT DESCRIBES THE STANDARD PART OF THE   50300020
*                       DIRECTORY ENTRY AS SUPPLIED BY BLDL             50400020
*                                                                       50500020
MNAME    DS    D                            MEMBER NAME                 50600020
MBEGTTR  DS    3X                           TTR OF BEG OF MEMBER        50700020
MCONCAT  DS    X                            CONCATENATION NO. OF PDS    50800020
MLIBRARY DS    X                            TYPE LIBRARY INDICATOR      50900020
*                                                X'01' FOUND IN LINKLIB 51000020
MFILLER  DS    9X                           OTHER INFO NOT PERTINET     51100020
MATTRIB  DS    2X                           MEMBER ATTRIBUTES           51200020
         SPACE 2                                                        51300020
LENLF    EQU   ELFXCTL-LFXCTL               LEN OF XCTL PARM LIST       51400020
LWKPART1 EQU   EWKPART1-WORKPART            LEN OF WORK AREA1 IN SVRB   51500020
LWKPART2 EQU   EWKPART2-WORKPART            LEN OF WORK AREA2 IN SVRB   51600020
         EJECT                                                          51650020
CVT      DSECT                                                          51660020
         CVT                                                            51670020
         EJECT                                                          51680020
         IKJTCB                                                         51690020
         EJECT                                                          51692020
         IKJRB                                                          51692420
         EJECT                                                          51692820
IHADCB   DCBD  DEVD=DA,DSORG=PO                                         51694020
         END                                                            51700020
