         TITLE 'TEST SVC      IGC0009G'                                 00100020
*********************************************************************** 00200020
*                                                                       00300020
* STATUS --                                                             00400020
*    VERSION NO. 02, OS/360 RELEASE NO. 21                       S21919 00500021
*                                                                       00600020
* FUNCTION --                                                           00700020
*    THIS SVC ROUTINE IS A TYPE 3 SVC USED BY THE TEST FACILITY         00900020
*    OF THE TIME SHARING OPTION (TSO) FOR MVT. IF CALLED BY THE         01000020
*    TASK BEING TESTED (TCBTCP BIT=1) IT ACTS AS BREAKPOINT             01100020
*    *   SVC. IF CALLED BY THE TEST TASK (TCBTCP BIT=0), THE SVC        01200020
*    *   ALTERS PROTECTED STORAGE IN ONE OF THE FOLLOWING WAYS.         01300020
*    *        1.ALTERS TCBTCP BIT IN A SPECIFIED TCB.                   01400020
*    *        2.ALTERS THE TCBTRN FIELD IN A SPECIFIED TCB.             01500020
*    *        3.ALTERS THE IC PORTION OF RBOPSW OF 1ST PRB/IRB ON       01600020
*    *          SPECIFIED TCB OR SPECIFIED PRB(IRB)                     01700020
*    *        4.ALTERS RBGRSAVE OF ACTIVE RB (SVRB FOR THIS SVC) ON     01800020
*    *          SPECIFIED TCB.                                          01900020
*    *        5.ALTERS FP REGSAVE AREA OF SPECIFIED TCB.                02000020
*    *        6.ALTERS WAIT CNT FOR SPECIFIED PRB(IRB)                  02050020
*                                                                       02100020
* ENTRY POINTS --                                                       02200020
*    IGC0009G                                                           02400020
*                                                                       02500020
* INPUT --                                                              02600020
*    BREAKPOINT FUNCTION-NO PARAMETERS,TCBTCP BIT=1.                    02800020
*    TEST SERVICE FUNCTION-TCBTCP BIT=0.                                03000020
*    *      NOTE -- THE LOW 3 BYTES OF R0 CONTAIN THE TCB ADDR          03150020
*    *      NOTE -- THE TCB ADDR MAY BE REPLACED BY A SPECIFIC          03160020
*    *      NOTE --  PRB(IRB) ADDRESS                                   03170020
*    *       1.SET TCBTCP=1                                             03180020
*    *          R0=X'40' (HI ORDER BYTE, FOLLOWED BY) TARGET TCB ADDR.  03200020
*    *          R1=N/A.                                                 03300020
*    *       2.SET TCBTCP=0                                             03400020
*    *          R0=X'20' & TARGET TCB ADDR.                             03500020
*    *          R1=N/A.                                                 03600020
*    *       3.ALTER TCBTRN FIELD                                       03700020
*    *          R0=X'10' & TARGET TCB ADDR.                             03800020
*    *          R1=NEW TCBTRN VALUE.                                    03900020
*    *       4.ALTER RBOPSW IC                                          04000020
*    *          R0=X'08' & TARGET TCB ADDR.                             04100020
*    *          R1=NEW IC VALUE.                                        04200020
*    *       5.ALTER RBGRSAVE                                           04300020
*    *          R0=X'04' & TARGET TCB ADDR.                             04400020
*    *          R1=REG.NUMBER AND NEW VALUE ADDR.(SINGLE REG CHANGE).   04500020
*    *          R1=X'FF' & 64 BYTE VALUE ADDR.(ALL REGS CHANGE).        04600020
*    *       6.ALTER TCB FP REG SAVE                                    04700020
*    *          R0=X'02' & TARGET TCB ADDR.                             04800020
*    *          R1(HIGH BYTE)=FPR NUMBER                                04850020
*    *          R1=NEW FP VALUE ADDR.                                   04900020
*    *       7.SET WAIT COUNT TO ZERO                                   04950020
*    *          R0=X'01' & TARGET TCB ADDR.                             04960020
*                                                                       05000020
* OUTPUT --                                                             05100020
*    NONE                                                               05300020
*                                                                       05400020
* EXTERNAL REFERENCES --                                                05500020
*         NONE                                                          05700020
*                                                                       05800020
* EXITS, NORMAL  --                                                     05900020
*         SVC3 BREAKPOINT FUNCTION R15 UNCHANGED                        06000020
*         SVC3 TEST SERVICE FUNCTION R15 = 0                            06100020
*                                                                       06150020
* EXITS, ERROR --                                                       06160020
*         SVC3 BREAKPOINT FUNCTION R15 UNCHANGED.                       06200020
*         SVC3 TEST SERVICE FUNCTION R15 = 4                            06300020
*                                                                       06400020
* TABLES/WORKAREAS --                                                   06450020
*    REG 9 AND THE TCBTRN WORD POINT TO TCOMTAB                         06460020
*    REG 7 USUALLY POINTS TO 'BREAKTAB' (BREAK ELEMENT QUEUE)           06470020
*                                                                       06480020
* ATTRIBUTES --                                                         06500020
*    TYPE 3 SVC.                                                        06700020
*    RE-ENTRANT                                                         06800020
*    REFRESHABLE.                                                       06900020
*                                                                       07000020
* CHARACTER CODE DEPENDENCY --                                          07050020
*                                                                       07060020
* NOTES --                                                              07070020
*    THIS SVC IS BROKEN INTO TWO PARTS.                                 07090020
*    THE BREAKPOINT FUNCTION STARTS AT LABEL 'IGC0009G'                 07092020
*    THE TEST SERVICE FUNCTION STARTS AT LABEL 'TSTSVC'                 07094020
*                                                                       07096020
*    ALTERATIONS OF SYSTEM BLOCKS ARE AS FOLLOWS                        07098020
*    SVRB - SVC97'S REGISTER SAVE AREA                                  07098420
*    PRB(IRB) PSW KEY OTHER THAN ZERO,PSW P BIT TO ONE - RBOPSW+4       07098820
*    TCBTRN FIELD OF TCB - THE TCBTCP BIT ON OR OFF AND THE LOW 3 BYTES 07099220
*    TCBATT BIT IN TCBTSFLG - TURNED OFF UPON ISSUING 'WAIT'            07099620
*    *                      - TURNED ON UPON FALLING THRU 'WAIT'        07099720
*    *                        THIS ALLOWS ATTENTIONS TO BE SERVICED     07099820
*    *                        FOR THE TEST SUBCOMMANDS                  07099920
*    TCBFRS FIELD(PREFIX OF TCB) - TO ALTER FLOATING POINT REGS         07133220
*    RBWCF IN PRB(IRB) - TO TESTING OF PP WHICH ENTERS A SOLID 'WAIT'   07143220
*    *                 - TURNED BACK ON AFTER A PSUEDO BREAKPOINT       07153220
*                                                                       07163220
*    REGISTER CONVENTION FOR SVC 97 ARE AS FOLLOWS                      07165220
*    REG 9 IS TCOMTAB POINTER                                           07165620
*    REG 10 IS THE BASE REGISTER                                        07166020
*    REG 11 IS USED ONLY FOR A LINK REGISTER                            07166420
*    REG 12 IS USED ONLY AS AN INTERNAL 'RETURN' REGISTER               07166520
*    REG 13 IS USED ONLY AS A HIGH ORDER BYTE MASK REGISTER             07166620
*    REG 7 IS USED MOSTLY AS A BASE FOR BREAK ELEMENT QUEUE             07177720
*    REG 5 IS THIS SVRB ADDRESS                                         07187720
*    REG 4 IS THIS TCB ADDRESS                                          07188120
*    REG 0 AND 1 CONTAIN THE INPUT PARAMETERS                           07188520
*                                                                       07188620
*********************************************************************** 07188920
         EJECT                                                          07200020
IGC0009G CSECT                                                          07300020
*RELEASE 21 CHANGES                                              S21919 07350021
*A251200                                                         S21919 07360021
*C5000                                                           S21919 07370021
*                                                                       07400020
         BALR  R10,X0         SET PROGRAM BASE.                         07500020
         USING *,R10          *                                         07600020
         USING TCB,R4                                                   07700020
         SPACE                                                          07800020
         SPACE 1                                                        08000020
*              CHECK THE TEST FLAG TO SEE IF THIS TASK IS UNDER TEST.   08100020
         SPACE 1                                                        08200020
         TM    TCBTRN,TCBTCP  Q. IS THIS TASK UNDER TEST.               08300020
         L     R13,HIGHBYTE   MASK TO CLEAR HIGH ORDER BYTE.            08400020
         BZ    TSTSVC         NO,EXECUTE A TEST SERVICE.                08500020
*                             YES,SERVE AS BREAKPOINT SVC.              08600020
         SPACE 1                                                        08700020
*        THIS SECTION, DOWN TO THE LABEL 'TSTSVC', IS THE LOGIC       * 08800020
*        FOR THE SVC ACTING AS A BREAKPOINT SVC.                      * 08900020
         SPACE                                                          08930020
         SSM   ON             ENABLE FOR INTERRUPTS                     08960020
         SPACE                                                          09000020
*     TCBTRN FIELD OF TCB CONTAINS ADDRESS OF TCOMTAB.                  09100020
         SPACE                                                          09200020
         LA    R12,RETURN1    RETURN ADDRESS IN R12.                    09300020
         L     R9,TCBTRN      BASE FOR TCOMTAB.                         09400020
         USING TCOMTAB,R9              *                                09500020
         LR    R6,R9          MOVE ADDRESS.                             09600020
         BAL   R11,KEYCK      VALIDITY CHECK STORAGE KEYS.              09700020
         L     R6,ECBTST      R6=ADDR OF STORAGE BLOCK                  09800020
         BAL   R11,KEYCK      VALIDITY CHECK STORAGE KEYS.              09900020
         L     R3,RBLINK(,R5) R3=PRB ADDR,PP IN WHICH BREAK OCCURRED.   10000020
         L     R8,RBOPSW2W(R3) R8=RESUME ADDR OF PP.                    10100020
         NR    R8,R13         CLEAR HIGH BYTE.                          10200020
         BCTR  R8,X0          R8=RESUME ADDR-2                          10300020
         BCTR  R8,X0          *                                         10400020
QPSEUDO  EQU   *              Q. IS IT A PSEUDO BREAKPOINT              10500020
         LA    R1,TSTGO+X6    NORMAL PSEUDO BREAK CHECK.                10600020
         CR    R1,R8          Q. IS IT A MATCH.                         10700020
         BE    PSEUDO         YES IT IS.                                10800020
         LA    R1,PPEXIT      BR R14 PSEUDO BREAKPOINT.                 10900020
         CR    R1,R8          Q. IS IT A MATCH.                         11000020
         BE    TSTPOST        YES IT IS.                                11100020
         TM    TSTFLGS3,TSTGOSW   Q.IS THIS A SPECIAL BREAKPT.          11200020
         BO    TSTPOST        YES.  POST 'TEST'.                        11300020
         L     R0,BREAKTAB    HEAD OF THE BREAK ELEMENT QUEUE.          11400020
BRKSRCH  EQU   *              BREAK ELEMENT SEARCH.                     11500020
         LTR   R7,R0          MOVE AND TEST FOR LAST.                   11600020
         USING BRKELEM,R7     BREAK ELEMENT ADDRESSABILITY.             11700020
         BCR   Z,R12          NO MORE. GO TO RETURN1.                   11800020
         LA    R6,BRKINST+X6  IF IC MATCHES THIS REPOINT IC & RTRN.     11900020
         CLR   R6,R8          Q. IS IT A MATCH.                         12000020
         BE    BRKRTURN       YES IT IS.  BRANCH.                       12100020
         C     R8,BRKADDR     IF IC MATCHES,A BREAKPT HAS BEEN HIT.     12200020
         L     R0,BRKLINK     GET THE NEXT, MAYBE.                      12300020
         BNE   BRKSRCH        NO MATCH. CHECK NEXT.                     12400020
COUNT    EQU   *              CHECK THE BREAK COUNT.                    12500020
         LH    R8,BRKCOUNT    Q. IS ACCUMULATOR ZERO.                   12600020
         LTR   R8,R8          *                                         12700020
         BNZ   DECREM         NO. DECREMENT AND ALLOW CONTINUATION.     12800020
         ST    R3,BRKRB       PRB(IRB) ADDRESS TO BREAK ELEMENT.        13700020
         MVC   BRKCOUNT(X2),BRKCOUNT+X2 YES,RESET ACCUMULATOR.          13800020
         B     TSTPOST        AND POST TEST,WAIT.                       13900020
DECREM   EQU   *                                                        14000020
         BCTR  R8,X0          MINUS ONE.                                14200020
         STH   R8,BRKCOUNT    CONTENTS BACK TO ACCUMULATOR.             14300020
         SPACE                                                          14400020
*        THIS SECTION CAUSES THE EXECUTION OF THE PROBLEM PROGRAM     * 14500020
*        TO RESUME BY POINTING THE RESUME PSW AT THE OVERLAID IN-     * 14600020
*        STRUCTION IN THE BREAK ELEMENT.IF THE INSTRUCTION IS BAL     * 14700020
*        OR BALR THE LINK REGISTER CONTENTS ARE SET IN THE SVRB       * 14800020
*        SAVE AREA.                                                   * 14900020
         SPACE                                                          15000020
         LA    R0,BRKINST     SAVED INSTRUCTION ADDRESS                 15100020
         TM    BRKFLGS,BALSW   Q.WAS ORIGINAL INSTR. BAL OR BALR.       15200020
         BZ    SETIC          SET IC IN RESUME PSW AND RETURN TO PP     15300020
BALBALR  EQU   *              SPECIAL CODE FOR BAL AND BALR             15400020
         SR    R0,R0          R0=ZERO                                   15500020
         TM    BRKINST,XC0     Q.DOES INSTRUCTION LENGTH EQUAL TWO.     15600020
         BZ    BALR           A.YES. HAS TO BE BALR.                    15700020
BAL      EQU   *              A.NO. HAS TO BE BAL.                      15800020
         L     R0,BRKINST     R0=THE BREAK INSTRUCTION                  15900020
         LR    R1,R0          R1=THE BREAK INSTRUCTION                  16000020
         N     R0,DISPMASK    R0=DISPLACEMENT                           16100020
         N     R1,BASEMASK    R1=BASE REGISTER                          16200020
         SRL   R1,N10         BASE REGISTER NUMBER X 4                  16300020
         BZ    BALR           REG 0 IS IGNORED AS A BASE REG.           16400020
         AL    R0,RBGRSAVE(R1,R5)  ADD BASE REGISTER ADDR. TO DISPL.    16500020
BALR     EQU   *              *                                         16600020
         L     R1,BRKINST     R1=ACTUAL BREAK INSTRUCTION               16700020
         N     R1,INDXMASK    R1=INDEX REGISTER OF BREAK INSTR.         16800020
         SRL   R1,N14         (INDEX REG X 4)                           16900020
         BZ    LINKREG        REG 0 IS IGNORED AS AN INDEX REG          17000020
         AL    R0,RBGRSAVE(R1,R5)  ADD INDEX REG TO TOTAL.              17100020
LINKREG  EQU   *              SETUP THE LINK REGISTER.                  17200020
         NR    R0,R13         CLEAR THE HIGH BYTE.                      17300020
         LA    R8,X2          BALR INSTRUCTION LENGTH.                  17400020
         TM    BRKINST,XC0    Q.IS THIS A BALR                          17500020
         BZ    LINKBALR       YES, THIS IS A BALR                       17600020
LINKBAL  EQU   *              *                                         17700020
         AR    R8,R8          BAL INSTRUCTION LENGTH.                   17800020
         XI    RBOPSW2W(R3),XC0  CHANGE ILC BITS TO B'10'               17900020
LINKBALR EQU   *              *                                         18000020
         MVC   RBOPSWIC(X3,R3),BRKADDR+X1  APPEND TO ILC/CC/PROGMASK    18100020
         AL    R8,RBOPSW2W(R3)   VALUE FOR THE LINK REGISTER.           18200020
         L     R6,BRKINST     ACTUAL BREAK INSTRUCTIONN                 18300020
         N     R6,LINKMASK    LINK REGISTER NUMBER                      18400020
         SRL   R6,N18         (LINK REG NUMBER X 4)                     18500020
         ST    R8,RBGRSAVE(R6,R5) STORE LINK REG CONTENTS IN SAVEAREA.  18600020
         TM    BRKINST,XC0     IS THIS A BALR Q.Q.Q.                    18700020
         BNZ   SETIC          NO.                                       18800020
         TM    BRKINST+X1,X0F IS IT A BALR Q.Q.Q.                       18900020
         BNZ   SETIC          NO.SET THE IC                             19000020
         LR    R0,R8          SETIC WITH LINK ADDRESS.                  19100020
SETIC    EQU   *              SET IC IN RESUME PSW                      19200020
         STH   R0,RBOPSWIC+X1(R3)   STORE ILC/CC/PGM MASK/IC IN PSW.    19300020
         SRL   R0,N16               DITTO                               19400020
         STC   R0,RBOPSWIC(R3)      DITTO                               19500020
         BR    R12            GO TO RETURN1                             19600020
BRKRTURN EQU   *                                                        19700020
         SH    R8,BACKUP2     R8=BREAK ELEMENT POINTER.                 19790020
         TM    BRKINST-BRKELEM(R8),XC0  TEST FOR BREAK INSTR LENGTH.    19880020
         LA    R6,X6          INSTRUCTION LENGTH OF SIX.                19970020
         BO    OUT            YES IT'S SIX.                             20060020
         LA    R6,X2          INSTRUCTION LENGTH OF TWO.                20150020
         BZ    OUT            YES IT'S TWO                              20240020
         AR    R6,R6          INSTRUCTION LENGTH OF FOUR.               20330020
*                             IT'S FOUR.                                20420020
OUT      EQU   *                                                        20510020
         L     R0,BRKADDR-BRKELEM(R8)  ADDR OF ORIG BRKPOINT.           20600020
         AR    R0,R6          PLUS CLOBBERED INSTR.LENGTH.              20700020
         NR    R0,R13         CLEAR HIGH BYTE.                          20800020
         B     SETIC          GO BACK TO PROBLEM PROGRAM.               20900020
*        RESTORE THE WAIT COUNT FIELD FOR A PSEUDO BREAKPOINT.          21000020
PSEUDO   EQU   *              IT'S A PSEUDO BREAK.                      21100020
         MVC   WTCOUNT(X1,R3),TSTGO+X4  DITTO.                          21200020
         TM    TSTFLGS3,TSTSTAI  IS THIS A STAI RETRY.                  21300020
         BZ    TSTPOST        NO.                                       21400020
         LM    R0,R1,RBGRSAVE(R5)  GET R0 AND R1 PASSED.                21500020
         LTR   R0,R0          WAS 104 BYTE WORKAREA PASSED Q.Q.Q.       21600020
         BNZ   PSEUDO1        NO. SKIP FREEMAIN.                        21700020
         L     R0,CORE104     SP NO.  LENGTH VALUE...                   21800020
         FREEMAIN  R,LV=(0),A=(1) FREE 104 BYTE W.A.                    21900020
PSEUDO1  EQU   *                                                        22000020
         L     R1,REGSAVE2    REGSAVE2 POINTER.                         22100020
         MVC   RBGRSAVE(N64,R5),X0(R1)    RESTORE THE ABENDED REGS.     22200020
TSTPOST  EQU   *                                                        22300020
         L     R1,RBOPSW2W(R3)  DECREMENT THE IC BY TWO.                22400020
         BCTR  R1,X0          *                                         22500020
         BCTR  R1,X0          *                                         22600020
         ST    R1,RBOPSW2W(R3)  CHANGE THE IC.                          22700020
         TS    TSTMTASK       SET MULTI TASK SWITCH.                    22900020
         BZ    GO             SWITCH ALREADY ON, BUILD ECB AND WAIT.    23000020
         L     R0,QGET        SP=78,LENGTH=8                            23100020
         GETMAIN R,LV=(0)     GET AN ECB.                               23200020
         SSM   OFF            DISABLE.                                  23300020
         LR    R2,R1          SAVE ADDRESS OF GOTTEN CORE               23400020
         L     R7,TSTSVCQ     GET THE TOP OF THE ECB QUEUE.             23500020
         ST    R1,TSTSVCQ     ADD GOTTEN CORE TO THE QUEUE.             23600020
         SR    R6,R6          ZERO FOR STORE MULTIPLE.                  23700020
         STM   R6,R7,X0(R1)   ECB=X'00000000' LINK=TSTSVCQ.             23800020
         SSM   ON             ENABLE.                                   23900020
         NI    TCBTSFLG,XFF-TCBATT  ALLOW ATTN INTERUPTS.               23950020
         WAIT  ECB=(1)        WAIT FOR POST BY IKJEGMNL                 24000020
         OI    TCBTSFLG,TCBATT  RESET ATTENTION BIT.                    24050020
         L     R0,QGET        FREE GOTTEN CORE.                         24100020
         FREEMAIN  R,LV=(0),A=(2)  FREE CORE.                           24200020
GO       EQU   *              POST/WAIT                                 24300020
         TM    TCBTRN,TCBTCP  HAS THE TEST BIT BEEN TURNED OFF.         24400020
         BCR   Z,R12          YES RETURN.                               24500020
         NR    R4,R13         CLEAR HIGH BYTE OF CALLERS TCB.           24600020
         ST    R4,PPTCB       PPTCB=THIS TCB.                           24700020
         NR    R5,R13         CLEAR HIGH BYTE.                          24800020
         LA    R6,ECBPP       R6=PP ECB ADDR.                           24900020
         ST    R5,X0(R6)      PUT SVRB ADDR INTO ECBPP.                 25000020
         L     R1,ECBTST      TEST ECB ADDRESS.                         25070020
         LA    R1,X0(,R1)     ZERO HIGH ORDER BYTE               S21919 25120021
         NI    TCBTSFLG,XFF-TCBATT  ALLOW ATTN INTERUPTS.               25210020
         POST  (1)            POST TEST ECB COMPLETE.                   25230020
         C     R5,X0(R6)      HAVE WE BEEN POSTED.                      25250020
         BNE   NOWAIT         DONT WAIT. EITHER POST OR FREED CORE.     25270020
         WAIT  ECB=(6)        WAIT ON PP ECB.                           25300020
NOWAIT   EQU   *                                                        25320020
         OI    TCBTSFLG,TCBATT  RESET ATTENTION BIT.                    25350020
         L     R1,RBOPSW2W(R3)  GET SECOND WORD OF PSW                  25400020
         NR    R1,R13         CLEAR HIGH BYTE.                          25500020
         SH    R1,BACKUP1     BACKUP TO BREAK ELEMENT.                  25600020
         L     R0,BREAKTAB    GET THE FIRST ELEMENT,IF ONE.             25700020
BRKSRCH1 EQU   *              CHECK IF IC POINTS TO BREAK INSTRUCTION.  25800020
*                             IF SO,CHECK AND SEE IF BRKINST IS         25900020
*                             A BAL OR BALR.                            26000020
*                             IF EITHER,TREAT IT SPECIAL.               26100020
*                             IF NOT, GO TO RETURN1.                    26200020
         LTR   R7,R0          MOVE AND TEST FOR LAST.                   26300020
         BCR   Z,R12          IT'S THE LAST. GO TO RETURN1              26400020
         CR    R1,R7          Q.DOES THE IC - 4 = A BREAK ELEMENT.      26500020
         L     R0,BRKLINK     GET THE NEXT ELEMENT ,IF ONE.             26600020
         BNE   BRKSRCH1       NO. LOOP.                                 26700020
FOUND1   EQU   *              GOT A MATCH.                              26900020
         TM    BRKFLGS,BALSW   IS THIS A BAL OR BALR Q.Q.               27000020
         BO    BALBALR        YES. IT IS ONE OF THESE.                  27100020
*                             GO TO SPECIAL PROCESSING OF BAL/BALR.     27200020
RETURN1  EQU   *              *                                         27300020
         LM    R0,R15,RBGRSAVE(R5)  RESTORE ALL REGS.                   27500020
         SVC   EXIT           RETURN.                                   27600020
KEYCK    EQU   *                                                        27700020
         N     R6,LOWFOUR     ZERO LOW BITS.                            27800020
         ISK   R7,R6          GET KEY.                                  27900020
         SLL   R7,N24         SHIFT KEY TO HIGH HEX.                    28000020
         X     R7,TCBPKF      KEYS EQUAL HIGH HEX RESULT IS 0.          28100020
         SRA   R7,N28         KEYS EQUAL, CONDITION CODE =0.            28200020
         BCR   NZ,R12         KEYS NOT EQUAL,GO TO RETURN1              28300020
         BR    R11            RETURN ON LINK REGISTER.                  28400020
         EJECT                                                          28500020
TSTSVC   EQU   *                                                        28600020
         SPACE                                                          28700020
*        THIS SECTION, DOWN TO THE AREA IN WHICH CONSTANTS AND        * 28800020
*        DUMMY SECTIONS ARE DEFINED, IS THE LOGIC FOR THE SVC         * 28900020
*        ACTING AS A SERVICE ROUTINE FOR THE TEST TASK.               * 29000020
         SPACE                                                          29100020
         LA    R12,RETURN     RETURN ADDRESS IN R12.                    29200020
         LR    R9,R0          REQUEST CODE AND TCB OR RB ADDR PASSED    29260020
         NR    R9,R13         CLEAR HIGH ORDER BYTE                     29320020
         L     R3,M(R4)       MOTHER TCB OF TMP/TEST TCB                29380020
         NR    R3,R13         CLEAR HIGH ORDER BYTE                     29440020
         LR    R8,R3          SAVE ADDRESS OF TMP/TEST TCB MOTHER       29500020
DAU      L     R7,D(R8)       ADDRESS OF LAST ATTACHED DAUGHTER         29560020
         NR    R7,R13         CLEAR HIGH BYTE - IS THEIR A DAUGHTER     29620020
         BNZ   CHK            YES, GO SEE IF THIS PASSED TCB/RB ADDR    29680020
SIS      L     R7,S(R8)       ADDRESS OF LAST ATTACHED SISTER           29740020
         NR    R7,R13         CLEAR HIGH BYTE - IS THEIR A SISTER       29800020
         BNZ   CHK            YES, GO SEE IF THIS PASSED TCB/RB ADDR    29860020
MOTH     L     R8,M(R8)       ADDRESS OF MOTHER TCB                     29920020
         NR    R8,R13         CLEAR HIGH ORDER BYTE                     29980020
         CR    R8,R3          IS IT END OF CHAIN-BACK AT TMP/TEST MOTH  30040020
         BNE   SIS            NO, GO CHECK FOR SISTER TCB               30100020
         B     ERROR          YES, NOISE PASSED - NOT TCB OR RB, RETURN 30160020
CHK      SR    R2,R2          CLEAR FOR LATER USE                       30220020
         CR    R7,R9          IS ADDR PASSED ADDR OF THIS TCB           30280020
         BE    GOTTCB              YES, GO SET UP TO HANDLE REQUEST     30340020
         L     R2,TCBRBP-TCB(R7)   NO,  ADDR OF FIRST RB HUNG OFF TCB   30400020
RBLOOP   NR    R2,R13              CLEAR HIGH BYTE - IS THEIR AN RB     30460020
         BZ    RBEND          NO, GO SET UP TO CHECK NEXT TCB           30520020
         CR    R2,R9          IS ADDR PASSED ADDR OF THIS RB            30580020
         BE    GOTRB             YES, GO SET UP TO HANDLE REQUEST       30640020
         TM    RBSTAB+X1(R2),X80 IS IT END OF CHAIN-RBLINK POINT TO TCB 30700020
         L     R2,RBLINK(R2)  ADDRESS OF NEXT RB ON CHAIN               30760020
         BZ    RBLOOP         NO, ANOTHER RB EXISTS, GO CHECK IT        30820020
RBEND    LR    R8,R7          CHECKED TCB BECOMES MOTHER                30880020
         B     DAU            GO SEE IF IT HAS A DAUGHTER               30940020
GOTRB    N     R0,SAVECODE    ISOLATE REQUEST CODE                      31000020
         OR    R0,R7          COMBINE REQUEST CODE WITH TCB ADDRESS     31060020
GOTTCB   SSM   ON             ENABLE FOR INTERRUPTS                     31120020
         LR    R9,R0          REQUEST CODE AND TCB ADDRESS              31180020
         LR    R3,R0          R3=BXLE REG.                              31400020
         SPACE 1                                                        31500020
*               USING BXLE INSTRUCTION TO TEST GPR 3 AND BRANCH TO      31600020
*               PROPER LOGIC,PERFORM REQUESTED OPERATIONS.              31700020
         SPACE 1                                                        31800020
         BXLE  R3,R3,TCBTSTON SET TCB TEST BIT ON.         X'40'        31900020
         BXLE  R3,R3,TCBTSTOF SET TCB TEST BIT OFF.        X'20'        32000020
         BXLE  R3,R3,TCBTRNL  ALTER TESTRAN FIELD OF TCB.  X'10'        32100020
         BXLE  R3,R3,RBOPSWL  ALTER PP RESUME IC.          X'08'        32200020
         BXLE  R3,R3,GPREGCHG ALTER GP REGISTER(S).        X'04'        32300020
         BXLE  R3,R3,FPREGCHG ALTER FP REGISTER.           X'02'        32400020
         BXLE  R3,R3,WTCNTOFF ZERO WAIT COUNT FIELD        X'01'        32500020
ERROR    EQU   *              NO,ERROR RETURN.                          32600020
         LA    R15,X4         INDICATE ERROR.                           32700020
         SVC   EXIT           RETURN.                                   32800020
OBTAINRB EQU   *              FIND THE USERS PRB(IRB)                   35000020
         LTR   R6,R2          WAS RB PASSED IN R0                       35100020
         BNZ   PRB1           YES. SKIP AROUND SEARCH.                  35200020
         L     R8,TCBRBP-TCB(R9)  TOP RB ADDRESS.                       35300020
LOOP2    EQU   *                                                        35400020
         LR    R6,R8          MOVE ADDRESS.                             35500020
         TM    RBSTAB(R6),X80  Q.IS RB A PRB(IRB)                       35600020
         L     R8,RBLINK(R6)  GET NEXT RB.                              35700020
         BNZ   LOOP2          NO, CHECK NEXT RB.                        35800020
PRB1      EQU   *                                                       35900020
         TM    RBOPSW+X1(R6),X1  TEST P BIT.                            36000020
         BZ    ERROR          DONT CHANGE IC THATS PRIVILEDGED.         36100020
         TM    RBOPSW+X1(R6),XF0 CHECK FOR KEY ZERO.                    36200020
         BZ    ERROR          KEY ZERO...RETURN......                   36300020
         BR    R11            RETURN.                                   36400020
RBOPSWL  EQU   *              CHANGE THE REQUESTED I.C.                 36500020
         BAL   R11,OBTAINRB   PRB(IRB) WILL RETURN IN REGISTER 6        36600020
         ST    R1,RBOPSW+X4(R6)    CHANGE IC.                           36700020
         BR    R12            NORMAL RETURN. GO TO RETURN.              36800020
GPREGCHG EQU   *                                                        36900020
         LTR   R7,R1          GET REGISTER NUMBER & Q.ALLREGS TO CHANGE 37000020
         SLL   R7,X4          MULTIPLY REG NUMBER BY FOUR.              37100020
         SRL   R7,N28         DITTO                                     37200020
         SLL   R7,X2          DITTO                                     37300020
         L     R4,TCBRBP-TCB(R9)  GET TOP RB ADDRESS.                   37400020
         BM    ALL            YES.CHANGE ALL.                           37600020
         LA    R7,RBGRSAVE(R7,R4) R7=REG SAVE ADDR IN RB.               37700020
         MVC   X0(X4,R7),X0(R1)  STORE VALUE IN TCB.                    37800020
         BR    R12            GO TO RETURN.                             37900020
ALL      MVC   RBGRSAVE(N64,R4),X0(R1) MOVE IN NEW REGS.                38000020
         BR    R12            GO TO RETURN.                             38100020
*        THIS SECTION SETS THE TCBTSTCP BIT IN THE TCBFLTRN           * 38200020
*        FIELD OF THE TCB TO ONE.                                     * 38300020
         SPACE                                                          38400020
TCBTSTON EQU   *                                                        38500020
         OI    TCBTRN-TCB(R9),TCBTCP  TURN BIT ON.                      38600020
         BR    R12            GO TO RETURN.                             38700020
         SPACE                                                          38800020
*        THIS SECTION SETS THE TCBTSTCP BIT IN THE TCBFLTRN           * 38900020
*        FIELD OF THE TCB TO ZERO.                                    * 39000020
         SPACE                                                          39100020
TCBTSTOF EQU   *                                                        39200020
         NI    TCBTRN-TCB(R9),XFF-TCBTCP  TURN BIT OFF.                 39300020
         BR    R12            GO TO RETURN.                             39400020
         SPACE                                                          39500020
*        THIS SECTION SETS THE TCBTRN FIELD OF THE SPECIFIED TCB      * 39600020
*        TO THE VALUE PASSED IN REGISTER 1.                           * 39700020
         SPACE                                                          39800020
TCBTRNL  EQU   *                                                        39900020
         STH   R1,TCBTRN+X2-TCB(R9)  PLACE ADDRESS OF TCOMTAB TO TCB    40000020
         SRL   R1,N16         *                                         40100020
         STC   R1,TCBTRN+X1-TCB(R9)  *                                  40200020
         BR    R12            RETURN.                                   40250020
         SPACE                                                          40300020
*        THIS SECTION ALTERS A SPECIFIED FP REGISTER SAVE AREA        * 40400020
*        ASSOCIATED WITH THE SPECIFIED TCB WITH THE CONTENTS OF       * 40500020
*        AN EIGHT BYTE AREA POINTED TO BY R1.                         * 40600020
         SPACE                                                          40700020
FPREGCHG EQU   *                                                        40800020
         SH    R9,FPSAVE      R9=FPR SAVE AREA.                         40900020
         LR    R7,R1          R7=FP REGISTER NUMBER.                    41000020
         SLL   R7,X5          *                                         41100020
         SRL   R7,N29         *                                         41200020
         LA    R4,X1          TEST LOW BIT.                             41300020
         NR    R4,R7          LOW BIT=SINGLE PRECISION.                 41400020
         BNZ   SINGLE         SINGLE PRECISION.                         41500020
         SLL   R7,X2          TIMES 4.                                  41600020
         LA    R7,X0(R9,R7)    R7=SAVE ADDR FOR SPECIFIED FPR.          41700020
         MVC   X0(X8,R7),X0(R1)  MOVE NEW VALUE INTO SAVE AREA.         41800020
         BR    R12            GO TO RETURN.                             41900020
SINGLE   EQU   *              *                                         42000020
         BCTR  R7,X0          MAKE FPR EVEN.                            42100020
         SLL   R7,X2          TIMES 4.                                  42200020
         LA    R7,X0(R9,R7)   R7=SAVE ADDRESS FOR SPECIFIED FPR.        42300020
         MVC   X0(X4,R7),X0(R1)  MOVE NEW VALUE TO SAVE AREA.           42400020
         BR    R12            GO TO RETURN.                             42500020
         SPACE                                                          42600020
WTCNTOFF EQU   *              TURN OFF PROBLEM PROGRAM WAIT COUNT.      42700020
         BAL   R11,OBTAINRB   PRB(IRB) WILL RETURN IN REGISTER 6.       42800020
         MVI   WTCOUNT(R6),X0  ZERO THE WAIT COUNT.                     42900020
*                             RETURN.                                   43000020
         SPACE                                                          43100020
RETURN   EQU   *                                                        43200020
         SR    R15,R15        INDICATE NORMAL RETURN.                   43300020
         SVC   EXIT           RETURN.                                   43400020
         SPACE 1                                                        43500020
CVT      EQU   16             FIXED LOCATION OF CVT ADDRESS.            43600020
CVTHEAD  EQU   160            DISP OF HEAD OF TCB QUEUE IN CVT.         43700020
RBSTAB   EQU   10             DISP OF STATUS BITS IN RB.                43800020
RBGRSAVE EQU   32             REG SAVE AREA DISPLACEMENT IN SVRB.       43900020
RBOPSW   EQU   16             RESUME PSW DISPLACEMENT IN RB.            44000020
RBOPSW2W EQU   RBOPSW+4       SECOND WORD OF RBOPSW                     44100020
RBOPSWIC EQU   RBOPSW+5       IC OF RBOPSW                              44200020
RBLINK   EQU   28             LINK FIELD DISPLACEMENT IN RB.            44300020
WTCOUNT  EQU   RBLINK         WAIT COUNT DISPLACEMENT IN RB.            44400020
RBCDE    EQU   12             *                                         44500020
CDNAME   EQU   8              *                                         44600020
CDEATR1  EQU   0              *                                         44700020
MINORBIT EQU   X'04'          *                                         44800020
CDEXLMJ  EQU   20             *                                         44900020
LLSNE    EQU   0              *                                         45000020
XLADR    EQU   12             *                                         45100020
EXIT     EQU   3              *                                         45200020
NZ       EQU   7              NOT ZERO CC.                              45300020
Z        EQU   8              ZERO CC.                                  45400020
X0       EQU   0              HEXIDECIMAL 0                             45500020
X1       EQU   1              HEXIDECIMAL 1                             45600020
X2       EQU   2              HEXIDECIMAL 2                             45700020
X3       EQU   3              HEXIDECIMAL 3                             45800020
X4       EQU   4              HEXIDECIMAL 4                             45900020
X5       EQU   5              HEXIDECIMAL 5                             46000020
X6       EQU   6              HEXIDECIMAL 6                             46100020
X7       EQU   7              HEXIDECIMAL 7                             46200020
X8       EQU   8              HEXIDECIMAL 8                             46300020
X9       EQU   9              HEXIDECIMAL 9                             46400020
N10      EQU   10             DECIMAL 10                                46500020
N14      EQU   14             FOURTEEN                                  46600020
N16      EQU   16             SIXTEEN                                   46700020
N18      EQU   18             EIGHTEEN                                  46800020
N24      EQU   24             TWENTY FOUR                               46900020
N28      EQU   28             TWENTY EIGHT                              47000020
N29      EQU   29             TWENTY NINE                               47100020
N64      EQU   64             SIXTY FOUR                                47200020
X0F      EQU   X'0F'          HEXIDECIMAL 0F                            47300020
X3F      EQU   X'3F'          HEXIDECIMAL 3F                            47400020
X80      EQU   X'80'          HEXIDECIMAL 80                            47500020
XC0      EQU   X'C0'          HEXIDECIMAL C0                            47600020
XF0      EQU   X'F0'          HEXIDECIMAL F0                            47700020
XFF      EQU   X'FF'          HEXIDECIMAL FF                            47800020
         SPACE 1                                                        47900020
FPSAVE   DC    Y(32)          BACK DISPLACEMENT OF FPR SAVE AREA.       47950020
         DS    0F                                                       48000020
CORE104  DC    AL1(250),AL3(104)  STAI WORK AREA AND SUBPOOL NUMBER     48100020
QGET     DC    AL1(250),AL3(8)   TSTSVCQ ELEMENT. SP=250 LV=8.          48200020
LOWFOUR  DC    X'FFFFFFF0'    ROUND.                                    48300020
DISPMASK DC    X'00000FFF'    DISPLACEMENT MASK.                        48400020
BASEMASK DC    X'0000F000'    BASE REGISTER MASK.                       48500020
INDXMASK DC    X'000F0000'    INDEX REGISTER MASK                       48600020
LINKMASK DC    X'00F00000'    LINK REGISTER MASK                        48700020
HIGHBYTE DC    X'00FFFFFF'    ADDRESS MASK.                             48800020
SAVECODE DC    X'FF000000'    MASK TO ZERO LOW 24 BITS.                 48900020
ON       EQU   SAVECODE       ENABLE SYSTEM MASK.                       49100020
OFF      EQU   SAVECODE+1     DISABLE SYSTEM MASK.                      49200020
         BRKELEM                                                        49300020
IGC0009G CSECT                                                          49400020
BACKUP1  DC    Y(BRKINST-BRKELEM)   VALUE TO BACKUP THE IC.             49500020
BACKUP2  DC    Y(BRKINST-BRKELEM+6)  VALUE TO BACKUP THE IC             49600020
         SPACE 2                                                        49700020
         IKJTCB                                                         49800020
S        EQU   TCBNTC-TCB     LAST ATTACHED SISTER TCB                  49820020
M        EQU   TCBOTC-TCB     MOTHER TCB                                49840020
D        EQU   TCBLTC-TCB     LAST ATTACHED DAUGHTER TCB                49860020
         TCOMTAB                                                        49900020
         SPACE                                                          50000020
         SPACE                                                          50100020
         REGEQU                                                         50200020
         END                                                            50300020
