         TITLE 'IGC0009H SVC 98 (PROTECT) FIRST LOAD - PASSWORD DATA SEX00100020
               T MAINTAINENCE/INITIALIZATION'                           00200020
IGC0009H CSECT                                                          00300020
*A 461500                                                        S99204 00302021
*C 458000                                                        A50990 00310021
*A 081500-081700,167500-167600,182500-182800                     A43379 00350021
*C424000                                                        SA69177 00360021
*A073500,169500,169600,470500                                   SA70270 00370021
*********************************************************************** 00400020
*                                                                     * 00500020
* STATUS -- CHANGE LEVEL 02                                     SA69177 00600021
*                                                                     * 00700020
* FUNCTION -- FIRST LOAD OF THE PASSWORD DATA SET MAINTAINENCE ROUTINE* 00800020
*    1. INITIALIZE A WORK AREA WITH A DCB, DEB, ECB, IOB, AND CCWS.   * 00900020
*    2. READ THE PASSWORD DATA SET DSCB FROM THE SYSTEM RESIDENCE     * 01000020
*    DEVICE.  THE DATA SET IS FLAGGED AS NEWLY ALLOCATED IF THE DSCB  * 01100020
*    DS1LSTAR FIELD IS ZEROED.  THE PASSWORD DATA SET WILL NOT BE     * 01200020
*    SEARCHED FOR EXISTING ENTRIES IF THIS FIELD IS ZERO.             * 01300020
*    3. VALIDATE PARAMETER LIST PASSED TO SVC 98.                     * 01400020
*                                                                     * 01500020
* ENTRY POINTS --                                                     * 01600020
*         IGC0009H - ENTRY POINT OF FIRST LOAD, ENTERED WHEN SVC 98   * 01700020
*    ISSUED                                                           * 01800020
*                                                                     * 01900020
* INPUT -- REGISTER 1 POINTS TO A PARAMETER LIST WHICH REQUESTS THE   * 02000020
*    DIFFERENT FUNCTIONS OF SVC 98.                                   * 02100020
*                                                                     * 02200020
* OUTPUT --                                                           * 02300020
*    REGISTER RW POINTS TO WORK AREA                                  * 02400020
*    REGISTER RPARM POINTS TO INPUT PARAMETER LIST                    * 02500020
*    REGISTER RA CONTAINS ENTRY CODE FOR IGC0109H (SECOND LOAD SVC 98)* 02600020
*    REGISTER RB PASSES RETURN CODE BETWEEN LOADS OF SVC 98           * 02700020
*                                                                     * 02800020
* EXTERNAL REFERENCES --                                              * 02900020
*         IEAOVL00 - BRANCH TO THE RESIDENT SUPERVISOR VALIDITY CHECK * 03000020
*    ROUTINE TO VALIDITY CHECK BUFFER ADDRESS PASSED IN THE PARAMETER * 03100020
*    LIST OF A LIST REQUEST                                           * 03200020
*         IECPCNVT - BRANCH TO THE RESIDENT DATA MANAGEMENT CONVERT   * 03300020
*    ROUTINE TO CONVERT A RELATIVE DIRECT ACCESS DEVICE ADDRESS (TTR) * 03400020
*    TO AN ACTUAL DIRECT ACCESS DEVICE ADDRESS (MBBCCHHR)             * 03500020
*                                                                     * 03600020
* EXITS, NORMAL -- XCTL TO IGC0109H TO PROCESS PASSWORD DATA SET      * 03700020
*                                                                     * 03800020
* EXITS, ERROR -- XCTL TO IGC0109H WITH NON-ZERO RETURN CODE          * 03900020
*    08  DATA SET NAME/PASSWORD NOT IN PASSWORD DATA SET              * 04000020
*    16  INCOMPLETE OR INCORRECT PARAMETER LIST                       * 04100020
*    28  VALIDITY CHECK OF BUFFER ADDRESS FAILED                      * 04200020
*    44  PASSWORD DATA SET NOT ON THE SYSTEM RESIDENCE VOLUME         * 04300020
*                                                                     * 04500020
* TABLES/WORK AREAS --                                                * 04600020
*    WORKD - A CONTIGUOUS AREA DEFINED BY IECDSECT FOR I/O CONTROL    * 04700020
*    BLOCKS FOLLOWED BY A LOCAL WORK AREA FOR COMMUNICATION AND       * 04800020
*    BUFFER SPACE                                                     * 04900020
*    PARMD - A DSECT TO MAP THE INPUT PARAMETER LIST                  * 05000020
*    WORKSPACE - A DSECT TO MAP THE LOCATE AND OBTAIN WORKAREAS       * 05100020
*                                                                     * 05200020
* ATTRIBUTES -- REENTRANT, READ ONLY, PRIVILIGED, ENABLED             * 05300020
*                                                                     * 05400020
* CHARACTER CODE DEPENDENCY -- CHARACTER CODE INDEPENDENT             * 05500020
*                                                                     * 05600020
* NOTES -- N/A                                                        * 05700020
*                                                                     * 05800020
*********************************************************************** 05900020
         EJECT                                                          06000020
*                                                                       06100020
*        EQUATED SYMBOLS                                                06200020
*                                                                       06300020
NOSEEK   EQU   X'18'               FILE MASK-NO SEEKS                   06400020
CLRLL    EQU   X'2B'               TO CLEAR DSNAME BUFFER TO BLANKS     06500020
HLEN     EQU   X'2C'               MAXIMUM DSNAME LENGTH                06600020
NEWMASK  EQU   X'00'               IDENTIFY FIRST TIME INITIALIZATION   06700020
FLAGIOB  EQU   X'42'               IOB FLAG / COMMAND CHAIN-UNRELATED   06800020
DEBID    EQU   X'0F'               IDENTIFY AS A DEB                    06900020
CCWL     EQU   48                  CCW LIST LENGTH                      07000020
DATALL   EQU   X'50'               PASSWORD ENTRY DATA LENGTH           07100020
DSCBLL   EQU   96                  DSCB DATA FIELD LENGTH               07200020
KEYLL    EQU   X'34'               PASSWORD ENTRY KEY LENGTH            07300020
KEYL0    EQU   X'00'               PASSWORK ENTRY MIN LENGTH    SA70270 07350021
MPENQ    EQU   X'80'               MPDS ENQUEUE FLAG                    07400020
REPASS   EQU   X'40'               MASK INDICATES REPLACE OF PASSWORD   07500020
ENQF     EQU   X'20'               TO SET DFLAG1- INDICATE ENQUEUES     07600020
OBTNCORE EQU   X'08'               OBTAIN CORE TO BE FREED              07700020
ADD      EQU   X'01'               ENTRY CODE FOR ADD                   07800020
REPLACE  EQU   X'02'               ENTRY CODE FOR REPLACE               07900020
LIST     EQU   X'04'               ENTRY CODE FOR LIST                  08000020
TTR      EQU   X'05'               ENTRY CODE FOR TTR                   08100020
PCOD0    EQU   X'00'               PROTECTION CODE '00'          A43379 08150021
PCOD3    EQU   X'03'               PROTECTION CODE '03'          A43379 08160021
LO       EQU   4                   TEST FOR LOW COMPARE          A43379 08170021
USERSP   EQU   251                 SUBPOOL UNDER USERS PROTECT KEY      08200020
HI       EQU   2                   TEST FOR HIGH COMPARE                08300020
ZR       EQU   8                   TEST FOR EQUAL COMPARE               08400020
ZERO     EQU   0                   ZERO                                 08500020
N1       EQU   1                   ONE                                  08600020
N2       EQU   2                   TWO                                  08700020
N3       EQU   3                   THREE                                08800020
N4       EQU   4                   FOUR                                 08900020
N6       EQU   6                   SIX                                  09000020
N7       EQU   7                   SEVEN                                09100020
N8       EQU   8                   EIGHT                                09200020
N9       EQU   9                   NINE                                 09300020
N16      EQU   16                  SIXTEEN                              09400020
N17      EQU   17                  SEVENTEEN                            09450020
N24      EQU   24                  TWENTY-FOUR                          09500020
RNLENGTH EQU   44                  RNAME LENGTH FOR ENQUEUE ON DSCB     09600020
L132     EQU   132                 LENGTH OF KEY AND DATA FIELDS        09700020
BLANK    EQU   C' '                BLANK                                09800020
HFF      EQU   X'FF'               PASSWORD ENTRY DELETION CHARACTER    09900020
*                                                                       10000020
*        RETURN CODES FOR ALL CONDITIONS  (NORMAL OR ERROR)             10100020
*                                                                       10200020
C4       EQU   4                   RETURN CODE  4                       10300020
C8       EQU   8                   RETURN CODE  8                       10400020
C12      EQU   12                  RETURN CODE 12                       10500020
C16      EQU   16                  RETURN CODE 16                       10600020
C20      EQU   20                  RETURN CODE 20                       10700020
C24      EQU   24                  RETURN CODE 24                       10800020
C28      EQU   28                  RETURN CODE 28                       10900020
C32      EQU   32                  RETURN CODE 32                       11000020
C36      EQU   36                  RETURN CODE 36                       11100020
C40      EQU   40                  RETURN CODE 40                       11200020
C44      EQU   44                  RETURN CODE 44                       11300020
C48      EQU   48                  RETURN CODE 48                       11400020
*                                                                       11420020
*        REGISTER EQUATES                                               11440020
*                                                                       11460020
RP0      EQU   0                   PARAMETER REGISTER                   11500020
RP1      EQU   1                   PARAMETER REGISTER                   11600020
RP2      EQU   2                   PARAMETER REGISTER                   11700020
R2       EQU   2                   WORK REGISTER                        11800020
RCVT     EQU   3                   CVT ADDRESS                          11900020
RPARM    EQU   4                   ADDRESS OF CALLERS PARAMETER LIST    12000020
RW       EQU   5                   ADDRESS OF WORK AREA (WORKD)         12100020
RUCB     EQU   6                   UCB ADDRESS                          12200020
RWK6     EQU   6                   WORK REGISTER                        12300020
RWK7     EQU   7                   WORK REGISTER                        12400020
RWK8     EQU   8                   WORK REGISTER                        12500020
RWK9     EQU   9                   WORK REGISTER                        12600020
RA       EQU   10                  WORK REGISTER                        12700020
RB       EQU   11                  WORK REGISTER                        12800020
RBASE    EQU   12                  BASE REGISTER                        12900020
RD       EQU   13                  UNUSED REGISTER                      13100020
RE       EQU   14                  RETURN LINKAGE                       13200020
RF       EQU   15                  LINKAGE/RETURN CODE                  13300020
         EJECT                                                          13400020
         USING WORKD,RW            ESTABLISH ADDRESSABILITY FOR DSECT   13500020
         USING PARMD,RPARM         ESTABLISH ADDRESSABILITY PARMLIST    13600020
         USING CVTTCBP,RCVT        ESTABLISH ADDRESSABILITY FOR CVT     13700020
         USING SRT,RUCB            ESTABLISH ADDRESSABILITY FOR UCB     13800020
         BALR  RBASE,RP0           GET ADDRESS WHERE LOADED             13900020
         USING *,RBASE             ESTABLISH ADDRESSABILITY FOR PROGRAM 14000020
         SSM   ENABLE              ENABLE FOR INTERRUPTIONS             14100020
         LR    RA,RE               SAVE RETURN ADDRESS                  14200020
*        REGISTER 3 CONTAINS CVT ADDRESS AT ENTRY                       14260020
*        REGISTER 4 CONTAINS TCB ADDRESS AT ENTRY                       14320020
         LR    RB,RPARM            SAVE TCB POINTER FOR VALIDATION      14400020
         LR    RPARM,RP1           PARAMETER LIST POINTER               14500020
INITCOR  LA    RP0,WKSIZE          WORK AREA SIZE                       14600020
         GETMAIN R,LV=(0)          GET WORK AREA STORAGE                14700020
         LR    RW,RP1              BASE FOR WORK AREA WORKD             14800020
         ST    RB,TCBADDR          SAVE TCB ADDRESS FOR MFT ENQUEUE     14850020
         XC    COMMD(DCLEAR),COMMD CLEAR PORTION OF WORK AREA           14900020
         XC    DFOXKEY(L132),DFOXKEY CLEAR BUFFER                       15000020
         L     RUCB,CVTILK2        ADDRESS OF UCB LOOKUP TABLE          15100020
         ST    RUCB,DUCBADDR       SAVE FOR UCB SCAN IN IGC0209H        15200020
         ST    RA,DSAVR            SAVE RETURN ADDRESS IN WORK AREA     15300020
         MVC   JFCBELNM(WTOLL),FULMSG SET UP WTO MESSAGE IN WORK AREA   15400020
*                                                                       15500020
*        VALIDATE PARAMETER LIST PASSED BY REQUESTOR. FOR A LIST        15600020
*        REQUEST, THE BUFFER ADDRESS PASSED BY THE USER                 15700020
*        WILL BE VALIDATED TO BE WITHIN THE USERS PROTECTION KEY        15800020
*        AREA IN STORAGE. THE DATA SET NAME AND PASSWORD                15900020
*        ARE MOVED INTO AN I/O BUFFER.                                  16000020
*                                                                       16100020
         MVI   DKEY,BLANK          BLANK KEY                            16200020
         MVC   DKEY+N1(CLRLL),DKEY CLEAR DSNAME/PASSWORD AREA           16300020
         L     RWK6,DBUF           BUFFER AND ENTRY CODE                16400020
         LA    RA,PRMER010         ERROR ROUTINE ADDRESS                16500020
         CLI   ENCODE,TTR          IS ENTRY CODE TOO LARGE              16600020
         BCR   HI,RA               GO TO ERROR EXIT                     16700020
         CLI   ENCODE,ADD          IS ENTRY CODE TOO SMALL       A43379 16750021
         BCR   LO,RA               YES, GO TO ERROR EXIT         A43379 16760021
         CLI   DSNLL,KEYLL         IS DSNAME LENGTH TOO LARGE           16800020
         BCR   HI,RA               GO TO ERROR EXIT                     16900020
         CLI   DSNLL,KEYL0        IS DSNAME LESS OR EQ 0?       SA70270 16950021
         BNHR  RA                 YES, GO TO ERROR EXIT         SA70270 16960021
         L     RWK8,DSN            DSNAME ADDRESS                       17000020
         SRDA  RWK8,N24            SHIFT OUT ADDRESS TO NEXT REGISTER   17100020
         SRA   RWK9,N8             SET UP ADDRESS IF NOT ZERO           17200020
         BCR   ZR,RA               IF ZERO GO TO ERROR EXIT             17300020
         BCTR  RWK8,ZERO           DECREMENT LENGTH FOR EXECUTE         17400020
         EX    RWK8,MOVDSN         MOVE DSNAME TO BUFFER/SEARCH FIELD   17500020
         L     RWK9,CURRENT        CURRENT PASSWORD                     17600020
         CLI   ENCODE,ADD          IS THIS AN ADD REQUEST               17700020
         BE    CHK001              YES, CURRENT PASSWORD NOT REQUIRED   17800020
         LTR   RWK9,RWK9           IS CURRENT PW ADDR SPECIFIED         17900020
         BCR   ZR,RA               GO TO ERROR EXIT                     18000020
CHK001   CLI   ENCODE,REPLACE      REPLACE/ADD SPECIFIED                18100020
         BH    CHK010              GO PROCESS DELETE ENTRY              18200020
         CLI   PCODE,PCOD3         IS PROTECTION CODE TOO LARGE  A43379 18250021
         BCR   HI,RA               YES, GO TO ERROR EXIT         A43379 18260021
         CLI   PCODE,PCOD0         IS PROTECTION CODE TOO SMALL  A43379 18270021
         BCR   LO,RA               YES, GO TO ERROR EXIT         A43379 18280021
         L     RWK8,NEW            GET NEW PASSWORD ADDRESS             18300020
         LA    RWK8,ZERO(RWK8)     CLEAR HIGH ORDER BYTE                18400020
         LTR   RWK8,RWK8           IS NEW PASSWORD ADDRESS SPECIFIED    18500020
         BCR   ZR,RA               GO TO ERROR EXIT                     18600020
         CLI   ENCODE,ADD          IS ADD SPECIFIED                     18700020
         BE    CHK005              GO MOVE IN NEW PASSWORD              18800020
         CLC   ZERO(N8,RWK8),ZERO(RWK9) IS A NEW PASSWORD SPECIFIED     18900020
         BE    CHK010              IF NOT, MOVE IN CURRENT NEW PASSWORD 19000020
         OI    DFLAG2,REPASS       SET FLAG FOR SECOND LOAD             19100020
CHK005   LR    RWK9,RWK8           ADDRESS NEW PASSWORD TO REGISTER     19200020
CHK010   MVC   DKEY8(N8),ZERO(RWK9) MOVE PASSWORD TO BUFFER             19300020
         CLI   ENCODE,LIST         IS CODE A LIST REQUEST               19400020
         BNE   CHKEND              SKIP VALIDITY CHECK                  19500020
*                                                                       19600020
*        ROUTINE TO LINK TO THE VALIDITY CHECK ROUTINE IN               19700020
*        ORDER TO VALIDATE THE BUFFER ADDRESS TO BE USED BY             19800020
*        THE I/O ROUTINE FOR A DATA BUFFER.                             19900020
*                                                                       20000020
CHK030   LA    RWK7,ZERO(RWK6)     BUFFER ADDRESS TO BE VALIDATED       20100020
         LR    RWK9,RB             TCB POINTER                          20200020
         L     RWK8,CVT0VL00       LOAD ADDRESS OF VALIDATION ROUTINE   20300020
         BALR  RA,RWK8             GO TO VALIDATE ADDRESS               20400020
         BC    N7,PRMER020         IF CHECK FAILED GO TO ERROR EXIT     20500020
CHKEND   IC    RWK8,ENCODE         SET UP ENTRY CODE FOR BRANCH         20600020
         SLL   RWK8,N2             TABLE IN NEXT LOAD OF THE SVC        20700020
         STC   RWK8,DCODTAB        SAVE FOR ENTRY TO IGC0109H           20800020
*                                                                       20900020
*        INITIALIZE ENQUEUE PARAMETER LIST                              21000020
*                                                                       21100020
         MVC   DMPDSQN(N17),MPDSQN MOVE NAMES TO ENQUEUE BUFFERS        21200020
         MVC   DMPDS+N9(HLEN-N9),DMPDS+N8 CLEAR RNAME BUFFER            21300020
         MVC   DENQLST(N4),ENQMP   ENQ OPTIONS TO ENQ LIST              21500020
         LA    RWK8,DMPDSQN        QNAME POINTER                        21600020
         ST    RWK8,DENQLST+N4     QNAME ADDRESS TO ENQ LIST            21700020
         LA    RWK8,DKEY           ADDRESS OF KEY                       21800020
         ST    RWK8,DENQLST+N8     RNAME POINTS TO DSN OF REQUEST       21900020
         LA    RP1,DENQLST         POINT TO ENQUEUE LIST                22000020
*                                                                       22100020
*        ENQ ON  MPDS FOR DSN                                           22200020
*                                                                       22300020
         ENQ   MF=(E,(1))          ENQUEUE                              22400020
         CLI   ENCODE,ADD          ADD REQUESTED                        22500020
         BNE   TABREC              IF NOT, SKIP SECOND ENQUEUE          22600020
         CLC   ZERO(N9,RWK8),MPDS  IS THE PASSWORD D/S BEING PROTECTED  22700020
         BE    INITEQE             BYPASS SECOND ENQ IF  IT IS          22800020
*                                                                       22900020
*        ENQ ON PASSWORD DATA SET IF AN ADD IS REQUESTED TO PREVENT     23000020
*        ACCESS BY MULTIPLE ADD REQUESTS.                               23100020
*                                                                       23200020
         LA    RWK8,DMPDS          ADDRESS OF PASSWORD DATA SET NAME    23300020
         ST    RWK8,DENQLST+N8     RNAME POINTS TO MPDS DSNAME          23400020
         LA    RP1,DENQLST         POINT TO ENQUEUE LIST                23500020
*                                                                       23600020
*        ENQUEUE ON PASSWORD DATA SET WITH MODIFIED PARAMETER LIST      23700020
*                                                                       23800020
         ENQ   MF=(E,(1))          ENQUEUE                              23900020
         B     TABREC              GO FIND TRACK CONSTANT               24000020
INITEQE  OI    DFLAG1,MPENQ        SPECIFY ONLY ONE ENQ DONE            24100020
*                                                                       24200020
*                                                                       24300020
*        ROUTINE TO FIND SYSRES DEVICE RECORD CAPACITY CONSTANT         24400020
*        CONSTANT IS BASED ON FIXED LENGTH KEYED RECORDS OF 132 BYTES.  24500020
*                                                                       24600020
TABREC   OI    DFLAG1,ENQF         INDICATE ENQUEUES DONE FOR DEQUEUE   24700020
         L     RUCB,CVTSYSAD       ADDRESS OF SYSRES DEVICE UCB         24800020
         MVC   OBTVOL(N6),SRTEVOLI SYSRES VOLUME SERIAL FOR OBTAIN      24900020
         LA    RWK7,TABR           DETERMINE TYPE AND SAVE              25000020
         LA    RWK9,TABREND        RECORDS PER TRACK CONSTANT           25100020
         LA    RWK8,N2             LENGTH OF EACH TABLE ENTRY           25200020
TABRC1   CLC   ZERO(N1,RWK7),UCBTBYT4 IS UCB TYPE CODE IN THE TABLE     25300020
         BE    TABRC2              TYPE FOUND IN TABLE                  25400020
         BXLE  RWK7,RWK8,TABRC1    CONTINUE SEARCH IF MORE ENTRIES      25500020
         B     PRMER030            RETURN-WITH ERROR                    25600020
TABRC2   MVC   DRECAP(N1),N1(RWK7) SAVE RECORD/TRACK CAPACITY           25700020
*                                                                       25800020
*        BEGIN INITIALIZATION FOR ACCESSING MPDS DSCB                   25900020
*                                                                       26000020
         LA    RP0,WRKSIZE         WORK AREA FOR OBTAIN/LOCATE          26100020
         LA    RP1,USERSP          GETMAIN UNDER USERS PROTECT KEY      26200020
         SLL   RP1,N24             SHIFT TO HIGH ORDER BYTE             26300020
         OR    RP0,RP1             REQUEST SUBPOOL 251                  26400020
*                                                                       26500020
*        GET WORK AREA FOR OBTAIN/LOCATE                                26600020
*        THE AREA WILL HAVE THE USERS PROTECTION KEY                    26700020
*                                                                       26800020
         GETMAIN R,LV=(0)          GET OBTAIN AREA CORE                 26900020
         OI    DFLAG1,OBTNCORE     INDICATE OBTAIN CORE TO BE FREED     27000020
         LR    R2,RP1              SAVE ADDRESS FOR OBTAIN OF DSCB      27100020
         MVC   OBTPTR(CAMEND-CAMFLAG),CAMFLAG INITIALIZE CAMLIST        27200020
         LA    RA,OBTDSN           ADDRESS OF FULLY QUALIFIED MPDS DSN  27300020
         ST    RA,OBTAIN2          DSNAME POINTER                       27400020
         LA    RA,OBTVOL           VOLUME SER POINTER                   27500020
         ST    RA,OBTAIN3          OBTAIN VOLUME                        27600020
         ST    R2,OBTAIN4          OBTAIN WORK AREA                     27700020
*                                                                       27800020
*        OBTAIN MPDS DSCB FROM SYSRES VTOC                              27900020
*                                                                       28000020
         OBTAIN OBTPTR             DO OBTAIN-DSCB TO DXDSCB AREA        28100020
         LTR   RF,RF               WAS OBTAIN SUCCESSFUL                28200020
         BNZ   PRMER030            GO TO ERROR EXIT- OBTAIN CODE IN RF  28300020
         MVC   DXDSCB(DSCBLL),ZERO(R2) MOVE DSCB TO I/O WORK AREA       28400020
*                                                                       28500020
*        INITIALIZE WORK AREA FOR I/O                                   28600020
*                                                                       28700020
         XC    DXECB(CLEARIO),DXECB CLEAR I/O WORK AREA                 28800020
         LA    RA,DXDEB            DEB ADDRESS                          28900020
         ST    RA,DXDCBDEB         DEB ADDRESS TO DCB                   29000020
         LA    RA,DXDCB            DCB ADDRESS                          29100020
         ST    RA,DXDEBDCB         DCB ADDRESS TO DEB                   29200020
         ST    RA,IOBWGHT          DCB ADDRESS TO IOB                   29300020
         L     RUCB,CVTSYSAD-CVT(RCVT) SYSRES DEVICE UCB ADDRESS        29400020
         ST    RUCB,DXDEBUCB       UCB ADDRESS TO DEB                   29500020
         L     RA,CVTXAPG          IOS APPENDAGE TABLE                  29600020
         ST    RA,DXDEBAPP         APPENDAGE TABLE TO DEB               29700020
         LA    RA,DXECB            ECB ADDRESS                          29800020
         ST    RA,IOBECBPT         ECB ADDRESS TO IOB                   29900020
         MVI   IOBFLAG1,FLAGIOB    SET IOB FLAGS                        30000020
         MVI   DXDEBUSR,N1         NO. OF EXTENTS=1                     30100020
         MVI   DXDEBID,DEBID       MASK TO IDENTIFY AS A DEB            30200020
         MVI   DXDEBMOD,NOSEEK     SET FILE MASK FOR NOSEEK X'18'       30300020
         OC    DXDEBSCC(N8),DSCLOWLM MOVE PASSWORD D/S EXTENTS TO DEB   30400020
         OC    DXDEBNTR(N2),NTRK   MAXIMUM TRACKS FOR DEB               30500020
         MVI   DCKDLL,KEYLL        KEY LENGTH FOR WRT C-K-D             30600020
         MVI   DCKDLL+N2,DATALL    DATA LENGTH FOR WRT C-K-D            30700020
         MVI   DFOXKEY,HFF         SET UP BYTE OF FFS                   30800020
         MVC   DFOXKEY+N1(KEYLL-N1),DFOXKEY SET UP 52 BYTES OF FFS      30900020
*                                                                       31000020
*        TEST FOR FIRST TIME INTO PASSWORD DATA SET                     31100020
*                                                                       31200020
         CLC   DSCLSTAR(N3),DXCCW1 IS TTR FIELD ZEROED                  31300020
         BNE   INITC0              NO- ASSUME PRIOR ACTIVITY IN MPDS    31400020
         MVI   DCODTAB,NEWMASK     FIRST TIME, SET CODE FOR NEW ADD     31500020
         MVC   DMPEND+N3(N4),DSCLOWLM  LIMIT SEARCH TO ONE TRACK        31600020
         CLI   ENCODE,ADD          YES-  IS FIRST REQUEST AN ADD        31700020
         BE    INITC1              GO SET UP CHANNEL PROGRAMS           31800020
         LA    RF,C8               DATA SET CONTAINS NO ENTRIES         31900020
         B     ERETURN             ERROR, RETURN                        32000020
*                                                                       32100020
*        CONVERT TTR TO MBBCCHHR                                        32200020
*        USE TTR (CONVERTED) AS UPPER EXTENT OF MPDS                    32300020
*                                                                       32400020
INITC0   LA    RP1,DXDEB           DEB ADDRESS                          32500020
         OC    DSAVT(N3),DSCLSTAR  TTR TO ZEROED FULL WORD              32600020
         L     RP0,DSAVT           TTRN WITH ZERO (N) FIELD             32700020
         LA    RP2,DMPEND          FOR MBBCCHHR                         32800020
         L     RF,CVTPCNVT-CVT(RCVT) GET ADDRESS OF CONVERT             32900020
         STM   RWK9,RD,DXJBF       SAVE REGISTERS IN WORKD              33000020
         BALR  RE,RF               GO TO CONVERT ROUTINE                33100020
         LM    RWK9,RD,DXJBF       RESTORE REGISTERS                    33200020
         MVC   DXDEBECC(N4),DMPEND+N3 CCHH PORTION TO DEB UPPER EXTENT  33300020
*                                                                       33400020
*        INITIALIZE CHANNEL PROGRAMS  ADDRESS FIELDS                    33500020
*        TWO CHANNEL PROGRAMS ARE USED, A SEARCH PROGRAM TO LOCATE      33600020
*        THE CORRECT PASSWORD ENTRY AND READ THE DATA FIELD             33700020
*        AND AN UPDATE CHANNEL PROGRAM TO WRITE AN UPDATED OR           33800020
*        A NEW ENTRY TO THE PASSWORD DATA SET.                          33900020
*                                                                       34000020
*        SEARCH CHANNEL PROGRAM                                         34100020
*                                                                       34200020
*              SEARCH ID EQ                 DXCCW1                      34300020
*              TIC                          DXCCW2                      34400020
*              READ COUNT                   DXCCW3                      34500020
*              SEARCH KEY EQ                DXCCW4                      34600020
*              TIC                          DXCCW5                      34700020
*              READ DATA                    DXCCW6                      34800020
*                                                                       34900020
*        WRITE UPDATE CHANNEL PROGRAM                                   35000020
*                                                                       35100020
*              SEARCH ID EQ                 DXCCW7                      35200020
*              TIC                          DXCCW8                      35300020
*              WRITE CNT-KEY-DATA/KEY-DATA  DXCCW9                      35400020
*              SEARCH ID EQ                 DXCCW10                     35500020
*              TIC                          DXCCW11                     35600020
*              READ DATA (VALIDATE)         DXCCW12                     35700020
*                                                                       35800020
INITC1   LA    RA,DXDAADDR+N3      IOB SEEK ADDRESS                     35900020
         ST    RA,DXCCW1           IOB SEEK ADDRESS TO S-ID (SEARCH)    36000020
         ST    RA,DXCCW7           IOB SEEK ADDRESS TO S-ID (UPDATE)    36100020
         LA    RA,DXCCW1           ADDRESS OF FIRST CCW                 36200020
         ST    RA,DXCCW2           SEARCH ID ADDRESS TO TIC             36300020
         LA    RA,DXCCW3           ADDRESS OF THIRD CCW                 36400020
         ST    RA,DXCCW5           READ COUNT ADDRESS TO TIC            36500020
         LA    RA,DATA             ADDRESS OF DATA BUFFER               36600020
         ST    RA,DXCCW6           DATA BUFFER ADDRESS TO READ CCW      36700020
         LA    RA,DCNT             ADDRESS OF COUNT BUFFER              36800020
         ST    RA,DXCCW3           CNT BUFFER ADDRESS FOR READ COUNT    36900020
         ST    RA,DXCCW9           CNT BUFFER ADDRESS TO WRT C-K-D      37000020
         ST    RA,DXCCW10          CNT BUFFER ADDRESS TO S-ID (UPDATE)  37100020
         LA    RA,DKEY             ADDRESS OF KEY                       37200020
         ST    RA,DXCCW4           KEY/DATA BUFFER ADDR TO S-K-EQ       37300020
         ST    RA,DXCCW12          KEY/DATA BUFFER ADDR TO READ VALIDAT 37400020
         LA    RA,DXCCW7           ADDRESS OF SEVENTH CCW               37500020
         ST    RA,DXCCW8           SEARCH ID ADDRESS TO TIC             37600020
         LA    RA,DXCCW10          ADDRESS OF TENTH CCW                 37700020
         ST    RA,DXCCW11          SEARCH KEY ADDRESS TO TIC            37800020
         OC    DXCCW(CCWL),CCWBASE BASIC SEARCH/READ (6 CCWS)           37900020
         OC    DXCCW7(N16),CCWSRCH SEARCH ID/TIC KNOWN CCHHR            38000020
         OC    DXCCW9(N8),CCWWRT   WRITE KEY/DATA                       38100020
         OC    DXCCW10(N16),CCWSRCH SEARCH ID/TIC VALIDATE              38200020
         OC    DXCCW12(N8),CCWVAL  READ VALIDATE                        38300020
         XR    RF,RF               CLEAR REGISTER FOR EXIT              38400020
         B     ERETURN             GO TO SECOND LOAD VIA XCTL           38500020
         EJECT                                                          38600020
*                                                                       38700020
*        EXIT ROUTINE- AN EXIT IS MADE TO THE NEXT LOAD OF THE          38800020
*        SVC VIA AN XCTL. A NON-ZERO RETURN CODE IS IN REGISTER RB      38900020
*        IF AN ERROR HAS OCCURRED IN THIS LOAD.                         39000020
PRMER010 LA    RF,C16              PARAMETER LIST ERROR                 39100020
         B     ERETURN             ERROR, RETURN                        39200020
PRMER020 LA    RF,C28              VALIDITY CHECK FAILURE               39300020
         B     ERETURN             ERROR,RETURN                         39400020
PRMER030 LA    RF,C44              PASSWORD DATA SET NOT FOUND          39500020
ERETURN  XR    RA,RA               CLEAR REGISTER                       39600020
         IC    RA,DCODTAB          SET UP FOR ENTRY INTO IGC0109H       39700020
         LR    RB,RF               SAVE THE RETURN CODE                 39800020
*                                                                       39900020
*        SET UP FOR XCTL TO IGC0109H                                    40000020
*        THE WORK AREA (DXJBF) IS USED AS AN XCTL LIST                  40100020
*                                                                       40200020
         LA    R2,DXJBF            XCTL PARAMETER LIST ADDRESS          40300020
         MVC   ZERO(N8,R2),NXLOAD  MOVE IN NAME OF NEXT LOAD            40400020
         LA    RF,N8(R2)           ADDRESS OF LIST POINTER FOR XCTL     40500020
*                                                                       40600020
*        XCTL TO NEXT LOAD OF SVC 98                                    40700020
*                                                                       40800020
         XCTL  EPLOC=(R2),DCB=0,SF=(E,(15)) XCTL                        40900020
*                                                                       41000020
         EJECT                                                          41100020
*                                                                       41200020
*        CONSTANTS                                                      41300020
*                                                                       41400020
         DS    0D                  ALIGN DOUBLE WORD                    41500020
*                                                                       41600020
*        CCW LIST FOR ALL EXCP I/O OPERATIONS                           41700020
*                                                                       41800020
CCWBASE  DS    0CL48               BASIC SEARCH CCWS                    41900020
*                                                                       42000020
CCWSRCH  DC    X'3100000060000005' SEARCH ID EQUAL                      42100020
         DC    X'0800000000000000' TIC                                  42200020
         DC    X'9200000060000008' READ COUNT M/T                       42300020
         DC    X'A900000040000034' SEARCH KEY EQ (DSN+PW)       SA69177 42400021
         DC    X'0800000000000000' TIC                                  42500020
*                                                                       42600020
*        READ  FOR 80 BYTE DATA FIELD                                   42700020
CCWRD    DC    X'8600000020000050' READ DATA (CHAIN FROM S-K-EQ)        42800020
*                                                                       42900020
*        WRITE - UPDATE IN PLACE OR ADD ON , WRITE EOF                  43000020
CCWWRT   DC    X'1D0000006000008C' WRITE COUNT-KEY-DATA                 43100020
*                                                                       43200020
*        VALIDATE WRITES                                                43300020
CCWVAL   DC    X'0E00000030000050' READ DATA (VALIDATE)                 43400020
*                                                                       43500020
MOVDSN   MVC   DKEY(ZERO),ZERO(RWK9) MOVE FOR DSNAME                    43600020
*                                                                       43700020
*        CAMLST PARAMETER LIST                                          43800020
*                                                                       43900020
CAMFLAG  CAMLST SEARCH,0,0,0                                            44000020
CAMEND   EQU   *                   END OF CAMLIST                       44100020
*                                                                       44200020
*        ENQUEUE/DEQUEUE CONSTANTS                                      44300020
*                                                                       44400020
ENQMP    DC    X'FF2C4000'         ENQUEUE/DEQUEUE CONSTANT             44500020
*        KEEP NEXT TWO FIELDS TOGETHER, MOVED BY ONE INSTRUCTION        44530020
*        NOTE - EXTRA BLANK REQUIRED, USED TO CLEAR BUFFER              44560020
MPDSQN   DC    CL8'SYSPSWRD'       QNAME FOR ALL ENQUEUES               44600020
MPDS     DC    CL9'PASSWORD '      NAME OF PASSWORD DATA SET            44700020
         EJECT                                                          44800020
*                                                                       44900020
*        THIS TABLE CONTAINS A 2 BYTE FIELD FOR EACH SYSTEM RESIDENCE   45000020
*        DEVICE SUPPORTED. THE FIRST BYTE IS THE UCB ID FOR DEVICE      45100020
*        THE SECOND BYTE IS THE NUMBER OF 132 BYTE KEYED RECORDS THAT   45200020
*        WILL FIT ON EACH TRACK (MINUS 1 RECORD).                       45300020
*                                                                       45400020
TABR     EQU   *                   LOOK UP TABLE FOR DEVICE CONSTANT    45500020
         DC    X'010F'             2311    ID/RECORD CAPACITY           45600020
         DC    X'023F'             2301    ID/RECORD CAPACITY           45700020
         DC    X'0310'             2303    ID/RECORD CAPACITY           45800021
         DC    X'0819'             2314    ID/RECORD CAPACITY           45900020
         DC    X'0612'             2305-1  ID/RECORD CAPACITY           46000020
         DC    X'0722'             2305-2  ID/RECORD CAPACITY           46100020
         DC    X'0B27'             3330-B  ID/RECORD CAPACITY    S99204 46150021
TABREND  DC    X'0927'             3330    ID/RECORD CAPACITY           46200020
*                                                                       46300020
*        END OF TABLE LOOKUP TABLE                                      46400020
*                                                                       46500020
FULMSG   WTO   'IEC021I NO SPACE IN PASSWORD DATA SET',MF=L,ROUTCDE=(9)X46560020
               ,DESC=4             WTO                                  46620020
WTOLL    EQU   *-FULMSG            LENGTH OF WTO MESSAGE                46700020
NXLOAD   DC    C'IGC0109H'         SECOND LOAD - SVC 98                 46800020
NTRK     DC    X'7FFF'             MAXIMUM TRACKS FOR DEB               46900020
ENABLE   DC    X'FF'               SYSTEM MASK TO ENABLE I/O            47000020
PATCH    DC    20F'0'             PATCH AREA                    SA70270 47050021
         SPACE 3                                                        47100020
         EJECT                                                          47200020
*        THIS WORK AREA IS USED BY ALL LOADS OF THE PROTECT SVC.        47300020
*        ANY CHANGES TO IT MUST BE MADE TO ALL LOADS.                   47400020
WORKD    DSECT                                                          47500020
*                                                                       47600020
         IECDSECT                                                       47700020
CLEARIO  EQU   *-DXECB             LENGTH FOR CLEARING I/O BLOCKS       47800020
*                                                                       47900020
COMMD    EQU   *                   CONTINUE DSECT                       48000020
*                                                                       48100020
*        WORK AREA FOR MPDS COMMUNICATION AND BUFFERING                 48200020
*        A CONTINUATION OF DSECT (WORKD)                                48300020
*                                                                       48400020
*                                                                       48500020
DSAVR    DS    F                   SAVE AREA FOR RETURN REGISTER        48600020
DSAVT    DS    F                   MPDS LAST BLOCK SAVE AREA            48700020
DUCBADDR DS    F                   ADDRESS OF UCB LOOKUP TABLE          48800020
DPMODE   DS    CL1                 PROTECTION MODE BYTE SAVE AREA       48900020
DRECAP   DS    CL1                 SYSRES DEVICE-RECORD/TRK CAPACITY    49000020
DCODTAB  DS    CL1                 ENTRY CODE SAVE AREA FOR NEXT LOAD   49100020
*                                                                       49200020
*        DFLAG - COMMUNICATES STATUS OF DSCB UPDATING REQUIREMENTS      49300020
*                                                                       49400020
DFLAG1   DS    BL1                 COMMUNICATION FLAG                   49500020
*        COMMUNICATION FLAG (DFLAG1) IN COMMD WORK AREA                 49600020
*              1 BYTE  (DFLAG1)                                         49700020
*                   BIT  0  =1 MPDS IS ENQ TO ADD OWN P/W PROTECTION    49800020
*                        1  =1 INDICATES I/O ERROR                      49900020
*                        2  =1 INDICATES ENQUEUED IN 1ST - 2ND LOADS    50000020
*                        3  =1 PROTECTED DATA SET-SET BIT 3 IN DSCB     50100020
*                        4  =1 OBTAIN CORE TO BE FREED                  50200020
*                        5  =1 NO PASSWORD TO READ-SET BIT 5 IN DSCB    50300020
*                        6  =1 UPDATE DSCB OF DATA SET WITH PROTECTION  50400020
*                              SPECIFIED IN BITS 3 AND 5                50500020
*                        7  =1 UPDATE MPDS DSCB FROM CORE IMAGE IN      50600020
*                              WORK AREA (WORKD) AND DEQ ON MPDS        50700020
*                                                                       50800020
DFLAG2   DS    BL1                 COMMUNICATION FLAG                   50900020
*              1 BYTE (DFLAG2)                                          51000020
*                   BIT 0     RESERVED                                  51100020
*                   BIT 1  =1 INDICATES NEW PASSWORD WITH REPLACE       51200020
*                   BIT 2     RESERVED                                  51300020
*                   BIT 3     RESERVED                                  51400020
*                   BIT 4     RESERVED                                  51500020
*                   BIT 5     RESERVED                                  51600020
*                   BIT 6     RESERVED                                  51700020
*                   BIT 7     RESERVED                                  51800020
*                                                                       51900020
         DS    0CL11               COUNT FIELD FOR I/O                  52000020
DMPEND   DS    CL8                 MBBCCHHR OF LAST RECORD WRITTEN      52100020
DCKDLL   DS    CL3                 KEY LENGTH/DATA LENGTH               52200020
*                                                                       52300020
*        EXCP BUFFER  AREA FOR COUNT KEY DATA READ/WRITE                52400020
*                                                                       52500020
         DS    0F                  ALIGN WORD                           52600020
         DS    CL1                 ALIGN FOR MBBCCHHR                   52700020
DMBB     DS    CL3                 MBB FIELD FOR CONVERT ROUTINE        52800020
         DS    0CL8                COUNT FIELD FOR I/O                  52900020
DCNT     DS    CL4                 CCHH PORTION OF COUNT                53000020
DRECNO   DS    CL1                 RECORD NUMBER                        53100020
DKEYLEN  DS    CL1                 KEY LENGTH FOR FOR WRITE             53200020
DDATALEN DS    CL2                 DATA LENGTH FOR WRITE                53300020
DKEY     DS    CL44                EXCP- 44 BYTE KEY (DSN)              53400020
DKEY8    DS    CL8                 EXCP- 8 BYTE EXTENSION (PASSWORD)    53500020
DATA     DS    0CL80               DATA FIELD                           53600020
DUSE     DS    CL2                 USE COUNT                            53700020
DMODE    DS    BL1                 PROTECTION MODE BYTE FIELD           53800020
DAT77    DS    CL77                USER DATA (77 BYTES OPTIONAL DATA)   53900020
DSAVLL   EQU   *-DCNT              COUNT-KEY-DATA FIELD LENGTH          54000020
DCLEAR   EQU   *-COMMD             WORK AREA TO BE CLEARED TO ZERO      54100020
DFOXKEY  DS    52C                 52 BYTE KEY OF FF                    54200020
         DS    80C                 80 BYTE DATA FIELD                   54300020
*                                                                       54400020
*        OBTAIN LIST                                                    54500020
*                                                                       54600020
OBTPTR   CAMLST SEARCH,OBTDSN,OBTVOL,OBTWRK                             54700020
         ORG   OBTPTR              LABEL OBTAIN FIELDS                  54800020
OBTAIN1  DS    F                   OBTAIN CAMLST FIRST FULL WORD        54900020
OBTAIN2  DS    F                   OBTAIN CAMLST SECOND FULL WORD       55000020
OBTAIN3  DS    F                   OBTAIN CAMLST THIRD FULL WORD        55100020
OBTAIN4  DS    F                   OBTAIN CAMLST FOURTH FULL WORD       55200020
         ORG                                                            55300020
*                                                                       55400020
*        ENQUEUE PARAMETER LIST                                         55500020
*                                                                       55600020
DENQLST  ENQ   (DMPDSQN,DMPDS,E,HLEN,SYSTEM),MF=L                       55700020
*        NAME LIST FOR ENQUEUE/DEQUEUE AND OBTAIN                       55800020
DMPDSQN  DS    0CL52               ONE FIELD FOR SETTING UP IN WORKD    55900020
         DS    CL8                 QNAME                                56000020
DMPDS    DS    CL44                RNAME                                56100020
OBTDSN   EQU   DMPDS               DSNAME OF MASTER PASSWORD DATA SET   56200020
OBTVOL   DS    CL6                 VOLUME SERIAL OF MPDS DSCB VOLUME    56300020
DREPSAV  DS    CL140               SAVEAREA FOR PASSWORD ENTRY          56400020
LOCNAME  CAMLST NAME,DKEY,,LOCAREA LOCATE CAMLST MACRO                  56500020
         ORG   LOCNAME             LABEL LOCATE CAMLST FIELDS           56600020
LOCNAME1 DS    F                   1ST WORD LOCATE CAMLST               56700020
LOCNAME2 DS    F                   2ND WORD LOCATE CAMLST               56800020
LOCNAME3 DS    F                   3RD WORD LOCATE CAMLST               56900020
LOCNAME4 DS    F                   4TH WORD LOCATE CAMLST               57000020
         ORG                                                            57100020
USECOUNT DS    F                   SAVE POINTER TO USER COUNT HERE      57200020
*  KEEP ENQ AND DEQ LISTS TOGETHER.                                     57250020
ENQLIST  ENQ   (QNAME,RNAME,E,RNLENGTH,SYSTEM),RET=USE,MF=L ENQUEUE     57300020
DEQLIST  DEQ   (QNAME,RNAME,RNLENGTH,SYSTEM),RET=HAVE,MF=L DEQUEUE      57350020
*  NOTE - MFT ENQUEUE WITH QNAME EQUAL TO SYSDSN REQUIRES TCB           57360020
*         ADDRESS IMMEDIATELY FOLLOWING THE QNAME.                      57370020
QNAME    DS    CL8                 QNAME BUFFER                         57400020
TCBADDR  DS    F                   TCB ADDRESS FOR MFT ENQUEUE          57450020
RNAME    DS    CL44                RNAME BUFFER                         57500020
OLDFLAG  DS    CL1                 OLD PROTECTION STATUS                57600020
NEWFLAG  DS    CL1                 NEW PROTECTION STATUS                57700020
WKSIZE   EQU   *-WORKD             SIZE OF PROGRAM WORKAREA             57800020
*                                                                       57900020
*        END OF MAPPING OF DSECT WORKAREA                               58000020
         EJECT                                                          58100020
PARMD    DSECT                                                          58200020
*                                                                       58300020
*              PARAMETER LIST FOR ALL REQUESTS                          58400020
*                                                                       58500020
*                                                                       58600020
*              COMMON  SEGMENT FOR ALL REQUESTS                         58700020
*                                                                       58800020
ENCODE   DS    0BL1                ENTRY CODE                           58900020
DBUF     DS    CL4                 ADDRESS OF BUFFER FOR CODE 04/05     59000020
DSNLL    DS    0CL1                DSN LENGTH                           59100020
DSN      DS    CL4                 ADDRESS OF DATA SET NAME             59200020
CURRENT  DS    CL4                 ADDRESS OF CURRENT PASSWORD          59300020
*                                                                       59400020
*              ADD / REPLACE / DELETE COMMON SEGMENT                    59500020
*                                                                       59600020
CONTROL  DS    CL4                 ADDRESS OF CONTROL PASSWORD          59700020
VOLNUM   DS    0CL1                NUMBER OF VOLUMES SPECIFIED          59800020
VOLIST   DS    CL4                 ADDRESS OF VOLUME LIST               59900020
*                                                                       60000020
*              ADD / REPLACE  COMMON SEGMENT                            60100020
*                                                                       60200020
PCODE    DS    0BL1                PROTECTION CODE                      60300020
NEW      DS    CL4                 ADDRESS OF NEW PASSWORD              60400020
STRINGL  DS    0CL1                STRING LENGTH                        60500020
STRING   DS    CL4                 ADDRESS OF DATA STRING               60600020
*                                                                       60700020
         EJECT                                                          60800020
*                                                                       60900020
WRKSPACE DSECT                                                          61000020
*                                                                       61100020
*  OBTAIN WORKAREA AND LOCATE WORKAREA                                  61200020
*                                                                       61300020
OBTWRK   DS    CL96                DSCB                                 61400020
OBTCCH   DS    CL5                 CCHHR                                61500020
         DS    CL249               OBTAIN WORK SPACE                    61600020
         DS    0D                  ALIGN LOCATE WORKAREA                61700020
LOCAREA  DS    CL265               LOCATE WORK SPACE (VOLUME LIST)      61800020
WRKSIZE  EQU   *-WRKSPACE          SIZE OF LOCATE AND OBTAIN WORKAREA   61900020
*                                                                       62000020
         EJECT                                                          62100020
SRT      DSECT                                                          62200020
         IEFUCBOB                                                       62300020
         EJECT                                                          62400020
CVT      DSECT                                                          62500020
         CVT                                                            62600020
         END                                                            62700020
