         TITLE 'IGC0108B --- ASSIGNS ALTERNATE TRACKS'                  00100421
         COPY  LCGASMSW                                          SM4351 00100821
IGC0108B CSECT                                                          00102021
*0831299500                                                      S21041 00110021
*                                                                  1057 00130018
*3130215000-216000                                                 1057 00160018
*1062                                                            M5448  00180020
*0831290000                                                      M0492  00210021
*STATUS CHANGE LEVEL 004                                                00240021
*                                                                     * 00300016
*FUNCTION/OPERATION-  THIS LOAD OF SVC 82 PERFORMS ALTERNATE          * 00400016
*   TRACK ASSIGNMENT FOR EITHER OF TWO CASES.                         * 00500016
*                                                                     * 00600016
*     1) VOLUMES IN A STATE OF BEING INITIALIZED.                     * 00700016
*     2) PRE-INITIALIZED VOLUMES(THEY HAVE A FORMAT 4 DSCB).          * 00800016
*                                                                     * 00900016
*   IF THE SPECIFIED DEFECTIVE TRACK IS AN UNASSIGNED ALTERNATE, IT   * 01000016
*     IS FLAGGED TO PREVENT ITS EVER BEING ASSIGNED.                  * 01100016
*                                                                     * 01200016
*   IF THE SPECIFIED DEFECTIVE TRACK IS AN ASSIGNED ALTERNATE, THE    * 01300016
*     NEXT AVAILABLE ALTERNATE IS ASSIGNED TO THE ORIGINAL PRIMARY    * 01400016
*     TRACK.                                                          * 01500016
*                                                                     * 01600016
*   IF THE SPECIFIED DEFECTIVE TRACK IS A PRIMARY TRACK, THE NEXT     * 01700016
*     GOOD AVAILABLE ALTERNATE TRACK IS ASSIGNED TO IT.               * 01800016
*                                                                     * 01900016
*ENTRY POINT-  THE ONLY ENTRY POINT IS -IGC0108B-.                    * 02000016
*                                                                     * 02100016
*INPUT-  REGISTER 1 POINTS TO 3-FULL WORDS AS FOLLOWS.                * 02200016
*        WORD1-  INPUT PARM LIST POINTER PASSED TO IGC0008B.          * 02300016
*        WORD2-  WORKAREA ADDRESS- DESCRIBED BY -IOBLOCKS- DSECT.     * 02400016
*        WORD3-  POINTER TO SVRB EXTENDED SAVEAREA.                   * 02500016
*                                                                     * 02600016
*EXITS-NORMAL-  THE 2ND WORD OF THE INPUT PARM LIST CONTAINS THE      * 02700016
*   CCHH OF THE ASSIGNED ALTERNATE TRACK, IF ANY. THE 2ND WORD        * 02800016
*   CONTAINS ZEROS IF NO ALTERNATE NEED BE ASSIGNED.RC=0.             * 02900016
*   -THE 6-BYTES OF ALTERNATE TRACK INFORMATION IS UPDATED(EITHER IN  * 03000016
*   THE FORMAT 4 DSCB OR POINTED TO BY THE INPUT PARM LIST.           * 03100016
*                                                                     * 03200016
*EXITS-ERROR-  RETURN CODE=12//IO ERROR ENCOUNTERED.                  * 03300016
*              RETURN CODE=16//NO MORE ALTERNATES AVAILABLE.          * 03400016
*   RETURN TO CALLER VIA SVC 3.                                       * 03500016
*                                                                     * 03600016
*SUPERVISOR MACROS-  EXCP,WAIT,FREEMAIN.                              * 03700016
*                                                                     * 03800016
*TABLES/WORKAREA-  USES THE WORKAREA DESCRIBED BY DSECT -IOBLOCKS-.   * 03900016
*                                                                     * 04000016
*OUTPUT-  SEE EXIT DESCRIPTION.                                       * 04100016
*                                                                     * 04200016
*ATTRIBUTES-  REENTRANT,RELOCATABLE,PRIVILEGED,ENABLED.               * 04300016
*                                                                     * 04400016
*   THE FOLLOWING ARE REGISTER ASSIGNMENTS.                             04600016
R0       EQU   0                                                        04700016
R1       EQU   1                                                        04800016
R2       EQU   2                                                        04900016
R3       EQU   3                                                        05000016
R4       EQU   4                                                        05100016
R5       EQU   5                                                        05200016
R6       EQU   6                                                        05300016
R7       EQU   7                                                        05400016
R8       EQU   8                                                        05500016
R9       EQU   9                                                        05600016
R10      EQU   10                                                       05700016
R11      EQU   11                                                       05800016
R14      EQU   14                      LINK REGISTER.                   05900016
R15      EQU   15                                                       06000016
PARMPTR  EQU   1                       POINTS TO INPUT PARAMETERS.      06100016
BASEREG  EQU   12                      BASE REGISTER.                   06200016
         SPACE 3                                                        06300016
*   EQUATE DEFINITIONS.                                                 06400016
RBEXSAVE EQU   96                      EXTENDED SAVE AREA FOR SVRB.     06500016
LAST     EQU   X'80'                   LAST PARAMETER INDICATOR.        06600016
GOOD     EQU   X'7F'                   I/O GOOD COMPLETION BIT.         06700016
COMPLETE EQU   X'40'                   I/O COMPLETE BIT.                06800016
SKIP     EQU   X'10'                   SKIP DATA TRANSFER.              06900016
RETURN   EQU   3                       EXIT SVC CODE.                   07000016
CHAIN    EQU   X'40'                   COMMAND CHAIN CCWS.              07100016
SILI     EQU   X'20'                   SUPPRESS INCORRECT LENGTH.       07200016
ALT      EQU   X'01'                   ALTERNATE TRACK FLAG.            07300016
DEFECT   EQU   X'02'                   DEFECTIVE TRACK FLAG.            07400016
MOVEHA   EQU   X'40'                   MOVE HA DOWN THE TRACK.          07500016
UE       EQU   X'01'                   UNIT EXCEPTION.                  07600016
MAINUCB  EQU   X'FF'                   ID FOR PRIMARY UCB.              07700016
DA2321   EQU   X'05'                   UCB TYPE CODE FOR 2321.          07800016
DA2314   EQU   X'08'                   2314 UCB TYPE CODE.              07900016
         EJECT                                                          08000016
         LR    BASEREG,R15             ESTABLISH ADDRESSING.            08100016
         USING IGC0108B,BASEREG                                         08200016
         SPACE                                                          08300016
         L     R11,0(R1)               PARM LIST POINTER.               08400016
         L     R2,4(R1)                WORKAREA ADDRESS.                08500016
         L     R5,8(R1)                SVRB EXTENDED AREA.              08600016
         SPACE 2                                                        08700016
*********************************************************************** 08800016
*                                                                     * 08900016
*   INITIALIZE THE IOB.                                               * 09000016
*                                                                     * 09100016
*********************************************************************** 09200016
         SPACE 2                                                        09300016
         USING IOBLOCKS,R2                                              09400016
INITIOB  MVI   IOBFLAG1,X'42'          SET PROPER FLAGS.                09500016
         LA    R3,ECB                  ECB ADDRESS.                     09600016
         ST    R3,IOBECBAD             STORE IN IOB.                    09700016
         MVI   IOBINCAM+1,1            BLOCK COUNT.                     09800016
         LA    R3,DCB-44               DCB ADDRESS.                     09900016
         ST    R3,IOBDCBPT             STORE IN IOB.                    10000016
         L     R4,0(R11)               UCB ADDRESS.                     10100016
         USING UCB,R4                                                   10200016
         CLI   UCBID,MAINUCB           THIS A PRIMARY UCB.              10300016
         BE    TESTF                   GO TEST THE FUNCTION.            10400016
         OI    SW,D2321                SET 2321 SWITCH.                 10500016
         MVC   IOBSEEK+1(2),0(R4)      BIN NO. TO IOB.                  10600016
         DROP  4                                                        10700016
         SPACE 2                                                        10800016
TESTF    CLI   0(R11),X'00'            THIS AN ANALYZE/FORMAT REQUEST.  10900016
         BE    ASSG2                   YES--GO HANDLE.                  11000016
         EJECT                                                          11100016
*   BUILD CCWS FOR READING FORMAT 4 DSCB HERE.                          11200016
         USING IOBLOCKS,R2                                              11300016
FORM4    EQU   *                                                        11400016
         LA    R3,FORMAT4              FORMAT 4 READ-IN AREA.           11500016
         ST    R3,WRTRD                STORE IN READ-DATA CCW.          11600016
         MVI   WRTRD,X'06'             SET OP CODE.                     11700016
         MVI   WRTRD+7,96              SET COUNT.                       11800016
         LA    R3,SEARCH               SEARCH CCW ADDRESS.              11900016
         ST    R3,TIC                  STORE IN TIC.                    12000016
         MVI   TIC,8                   SET TIC OP CODE.                 12100016
         LA    R3,CCHHR                SEARCH ADDRESS.                  12200016
         ST    R3,SEARCH               STORE IN SEARCH CCW.             12300016
         MVI   SEARCH+4,X'40'          COMMAND CHAIN ON.                12400016
         MVI   SEARCH+7,5              SET COUNT.                       12500016
         MVI   SEARCH,X'31'            SET SEARCH OP CODE.              12600016
         SPACE 2                                                        12700016
         LA    R3,SEARCH               SEARCH CCW ADDRESS.              12800016
         ST    R3,IOBSTART             SET IN IOB.                      12900016
         SPACE                                                          13000016
*   STORE CCHHR OF VTOC IN IOB HERE.                                    13100016
         L     R3,0(R11)               UCB ADDRESS.                     13200016
         USING UCB,R3                                                   13300016
         CLI   UCBID,MAINUCB           THIS A 2321.                     13400016
         BNE   P2321                   YES-GO PROCESS.                  13500016
         L     R0,SRTEFSCT             TTR OF VTOC.                     13600016
         SPACE                                                          13700016
FINDCCHH LA    R3,RBEXSAVE(R5)         EXTENTED SVRB SAVE AREA.         13800016
         STM   1,12,0(R3)              SAVE THE REGISTERS.              13900016
         SPACE                                                          14000016
         USING CVT,R15                                                  14100016
         L     R15,CVTPTR              CVT ADDRESS.                     14200016
         L     R15,CVTPCNVT            CONVERT ROUTINE ADDRESS.         14300016
         DROP  15                                                       14400016
         LA    R1,DEB                  ADDDRESS OF DEB.                 14500016
         LA    R2,IOBSEEK              TARGET AREA FOR MBBCCHHR.        14600016
         BALR  R14,R15                 CONVERT TTR TO MBBCCHHR.         14700016
         LM    1,12,0(R3)              RESTORE THE REGISTERS.           14800016
         SPACE                                                          14900016
*   READ IN THE FORMAT 4 DSCB HERE.                                   * 15000016
         BAL   R9,WRTREAD              READ IN FORMAT4 DSCB DATA FIELD. 15100016
         BAL   R9,WAIT                 AWAIT COMPLETION.                15200016
         MVC   ALTINFO(6),ALTDATA      CCHH NEXT ALT. AND COUNT LEFT.   15300016
         SPACE                                                          15400016
ASSG1    CLC   ALTINFO+4(2),ZERO       ANY ALTERNATES LEFT.             15500016
         BNE   TESTALT                 YES-                             15600016
         SPACE                                                          15700016
EXIT16   BAL   R9,FREECORE             FREE THE WORK AREA.              15800016
         LA    R15,16                  SET RETURN CODE.                 15900016
         SVC   RETURN                  RETURN TO CALLER.                16000016
         SPACE                                                          16100016
         USING DATACELL,R3                                              16200016
P2321    L     R0,DCELVTOC             TTR OF VTOC---2321.              16300016
         B     FINDCCHH                CONVERT TO CCHH.                 16400016
         DROP  R3                                                       16500016
         SPACE 2                                                        16600016
ASSG2    EQU   *                       SET UP ALTERNATE INFORMATION.    16700016
         L     R4,8(R11)               POINTER TO ALT. INFORMATION.     16800016
         MVC   ALTINFO(6),0(R4)        SET UP ALTERNATE TRACK INFO.     16900016
         B     ASSG1                   GO PROCESS THIS TRACK.           17000016
         SPACE                                                          17100016
TESTALT  L     R3,4(R11)               SELECTED TRACK ADDRESS.          17200016
         SPACE                                                          17300016
         USING UCB,R4                                                   17400016
         L     R4,0(R11)               UCB ADDRESS                      17500016
         SPACE                                                          17600016
         CLI   UCBID,MAINUCB           THIS A PRIMARY UCB.              17700016
         BE    TEST1                   YES-GET DEVICE TYPE CODE.        17800016
         LA    R6,DA2321               NO--MUST BE 2321.                17900016
         B     TEST2                   GO INDEX TO DEVICE CONSTANTS.    18000016
         SPACE                                                          18100016
TEST1    SR    R6,R6                   CLEAR                            18200016
         IC    R6,UCBTBYT4             DEVICE TYPE CODE.                18300016
         CLI   UCBTBYT4,DA2314         THIS A 2314.                     18400016
         BNE   TEST2                   NO--                             18500016
         OI    SW,D2314                YES-REMEMBER THIS.               18600016
         DROP  R4                                                       18700016
         SPACE                                                          18800016
TEST2    LA    R4,FIRSTALT-8           TABLE-8.                         18900016
         SLA   R6,3                    UCB CODE TIME 8.                 19000016
         LA    R6,0(R6,R4)             ADDRESS OF CONSTANTS/THIS DEVICE 19100016
         SPACE                                                          19200016
         CL    R3,0(R6)                INPUT CCHH IN ALTERNATE AREA.    19300016
         BNH   NOTALT                  NO--MUST BE PRIMARY TRACK.       19400016
         SPACE 2                                                        19500016
YESALT   EQU   *                       INPUT TRACK IS IN ALTERNATE AREA 19600016
         ST    R3,R0COUNT              INPUT CCHH//TEMPORARY STORAGE.   19700016
         MVC   CCHHR(4),R0COUNT        SEEK ADDRESS IN IOB.             19800016
         LA    R4,RDHA                 READ HA CCW.                     19900016
         ST    R4,IOBSTART             STORE ADDRESS IN IOB.            20000016
         LA    R4,HA                   READ-IN HA AREA.                 20100016
         ST    R4,RDHA                 STORE IN CCW.                    20200016
         MVI   RDHA,X'1A'              RESET OP CODE.                   20300016
         MVI   RDHA+7,5                SET CORRECT COUNT.               20400016
         MVI   RDHA+4,CHAIN            CHAIN BIT ON.                    20500016
         LA    R4,R0COUNT              COUNT READ-IN AREA.              20600016
         ST    R4,READR0               STORE IN CCW.                    20700016
         MVI   READR0,X'16'            RESET OP CODE.                   20800016
         MVI   READR0+7,4              SET COUNT IN CCW.                20900016
         MVI   READR0+4,SILI           SUPPRESS INCORRECT LENGTH.       21000016
         BAL   R9,WRTREAD              READ IN HA/R0 RECORDS.           21100016
         BAL   R9,WAIT                 AWAIT COMPLETIOM.                21200016
         CLC   HA+1(4),R0COUNT         HA AND R0 SAME CCHH.             21300016
         L     R3,R0COUNT              PRIMARY TRACK ADDRESS.           21400016
         BE    A                       TRACK NOT ASSIGNED.         1057 21470018
         OI    SW,DEFALT               SET DEFECTIVE ALTERNATE SW  1057 21540018
A        EQU   *                                                   1057 21610018
         MVC   WRTHA(16),RDHA          REPOSITION THE CCWS.             21700016
         MVI   WRTHA,X'19'             SET WRITE HA OP CODE.            21800016
         MVI   WRTR0,X'15'             SET WRITE R0 OP CODE.            21900016
         MVI   WRTR0+4,CHAIN           SET CHAIN FLAG ON.               22000016
         MVI   WRTR0+7,16              SET COUNT IN CCW.                22100016
         MVI   R0COUNT+7,8             SET COUNT IN COUNT FIELD.        22200016
         MVI   RDHA+4,CHAIN+SKIP       SKIP DATA TRANSFER.              22300016
         MVI   READR0+4,SKIP+SILI      SKIP DATA TRANSFER.              22400016
         OI    HA,DEFECT+ALT           INDICATE DEFECTIVE ALT. IN FLAG. 22500016
         SPACE                                                          22600016
         LA    R4,WRTHA                CHANNEL PROGRAM START.           22700016
         ST    R4,IOBSTART             SET CCW ST ART IN IOB.           22800016
         SPACE                                                          22900016
         BAL   R9,WRTREAD              FLAG THIS TRACK DEFECTIVE.       23000016
         BAL   R9,WAIT                 AWAIT I/O COMPLETION.            23100016
         MVI   RDHA+4,CHAIN            COMMAND CHAIN FLAGS TO CCW  1057 23120018
         MVI   READR0+4,SILI           SUPPRESS LENGTH IND. TO CCW 1057 23140018
         TM    SW,DEFALT               DEFECTIVE ALTERNATE SW SET  1057 23160018
         BO    NOTALT                  YES-GO SEE IF GOOD ALTERNATE1057 23180018
         SPACE                                                          23200016
         XC    4(4,R11),4(R11)         CLEAR CCHH OF INPUT LIST//       23300016
*                                        NONE ASSIGNED.                 23400016
         B     EXIT0                   RETURN TO CALLER.                23500016
         EJECT                                                          23600016
*********************************************************************** 23700016
*                                                                     * 23800016
*   TEST IF THIS ALTERNATE TRACK IS A GOOD ONE.                         23900016
*                                                                     * 24000016
*********************************************************************** 24100016
         SPACE 2                                                        24200016
NOTALT   MVC   CCHHR(4),ALTINFO        CCHH OF NEXT ALT TO IOB.         24300016
         LA    R4,RDHA                 CCW ADDRESS.                     24400016
         ST    R4,IOBSTART             STORE IN IOB.                    24500016
         LA    R4,HA                   READ IN AREA.                    24600016
         ST    R4,RDHA                 STORE IN CCW.                    24700016
         MVI   RDHA,X'1A'              RESET OP CODE.                   24800016
         MVI   RDHA+7,5                SET COUNT IN CCW.                24900016
         SPACE                                                          25000016
         BAL   R9,WRTREAD              READ IN HOME-ADDRESS/ALTERNATE.  25100016
         BAL   R9,WAIT                 AWAIT COMPLETION.                25200016
         SPACE                                                          25300016
         TM    HA,DEFECT               THIS A GOOD ALTERNATE.           25400016
         BZ    WRTPRIM                 YES-GO USE IT.                   25500016
         SPACE 2                                                        25600016
*********************************************************************** 25700016
*                                                                     * 25800016
*   THE NEXT AVAILABLE TRACK WAS DEFECTIVE. MUST FIND ANOTHER ONE.    * 25900016
*                                                                     * 26000016
*********************************************************************** 26100016
         SPACE 2                                                        26200016
GETNEXT  EQU   *                       FIND NEXT ALTERNATE TRACK.       26300016
         BAL   R9,UPCCHH               GET ADDRESS OF NEXT ALTERNATE.   26400016
         LTR   R4,R4                   BETTER TEST FOR ZERO HERE.       26500016
         BZ    EXIT16                  NONE LEFT---BETTER LEAVE.        26600016
         B     NOTALT                  GO SEE IF NEXT ALTERNATE IS GOOD 26700016
         EJECT                                                          26800016
*********************************************************************** 26900016
*                                                                     * 27000016
*   WRITE HOME ADDRESS/RECORD ZERO ON THE PRIMARY TRACK HERE.         * 27100016
*                                                                     * 27200016
*********************************************************************** 27300016
WRTPRIM  ST    R3,R0COUNT              TEMPORARY STORAGE.               27400016
         MVC   CCHHR(4),R0COUNT        PRIMARY CCHH TO IOB.             27500016
         MVC   HA+1(4),R0COUNT         SET IN CCHH OF HA.               27600016
         MVI   HA,DEFECT               SET FLAG IN HA.                  27700016
         MVC   R0COUNT(4),ALTINFO      CCHH OF ALT TO PRIMARY R0.       27800016
         SPACE                                                          27900016
         LA    R4,HA                   WRITE-OUT AREA.                  28000016
         ST    R4,WRTHA                STORE IN CCW.                    28100016
         MVI   WRTHA,X'19'             SET OP CODE.                     28200016
         MVI   WRTHA+4,CHAIN           CHAIN BIT ON.                    28300016
         MVI   WRTHA+7,5               SET COUNT IN CCW.                28400016
         SPACE                                                          28500016
         LA    R4,R0COUNT              COUNT FIELD ADDRESS.             28600016
         ST    R4,WRTR0                STORE IN CCW.                    28700016
         MVI   WRTR0,X'15'             RESET OP CODE.                   28800016
         MVI   WRTR0+4,CHAIN           CHAIN BIT ON.                    28900016
         MVI   WRTR0+7,16               SET COUNT TO 16          M0492  28960021
         MVI   READR0+7,16                IN CCW'S               M0492  29020021
         SPACE                                                          29100016
         MVC   RDHA(16),WRTHA          MOVE WRITE CCWS OVER READS.      29200016
         MVI   RDHA,X'1A'              SET READ HA OP CODE.             29300016
         OI    RDHA+4,SKIP             SKIP DATA TRANSFER.              29400016
         MVI   READR0,X'16'            SET READ R0 OP CODE.             29500016
         MVI   READR0+4,SKIP+SILI      SKIP DATA TRANSFER.              29600016
         SPACE                                                          29700016
         LA    R4,WRTHA                CHANNEL PROGRAM START.           29800016
         ST    R4,IOBSTART             STORE IN IOB.                    29900016
         MVC   R0COUNT+K4(K4),ROLENGTH  SET R0 COUNT             S21041 29950021
         SPACE 2                                                        30000016
         BAL   R9,WRTREAD              WRITE HA/R0 ON PRIMARY.          30100016
         BAL   R9,WAIT                 AWAIT COMPLETION.                30200016
         SPACE                                                          30300016
         MVC   4(4,R11),ALTINFO        PUT CCHH OF ALT. IN PARM LIST.   30400016
         MVI   HA,ALT                  SET FLAG TO SHOW ALTERNATE.      30500016
         EJECT                                                          30600016
*********************************************************************** 30700016
*                                                                     * 30800016
*   WRITE HOME ADDRESS/RECORD ZERO ON THE ALTERNATE TRACK HERE.       * 30900016
*                                                                     * 31000016
*********************************************************************** 31100016
         SPACE 3                                                        31200016
WRTALT   MVC   CCHHR(4),ALTINFO        SEEK ADDRESS OF ALT. TO IOB.     31300016
         MVC   HA+1(4),ALTINFO         CCHH OF ALTERNATE.               31400016
         SPACE                                                          31500016
         ST    R3,R0COUNT              PRIMARY CCHH TO RECORD ZERO.     31600016
         MVI   R0COUNT+7,8             SET DATA LENGTH FOR EIGHT.       31700016
         MVI   WRTR0+7,16              SET CCW COUNT FOR 16.            31800016
         SPACE 3                                                        31900016
         BAL   R9,WRTREAD              WRITE HA/R0 ON ALTERNATE.        32000016
         BAL   R9,WAIT                 AWAIT COMPLETION.                32100016
TESTREQ  CLI   0(R11),X'00'            THIS A FORMAT-ANALYZE REQUEST.   32200016
         BNE   UPF4                    NO--NEED TO UPDATE FORMAT4 DSCB. 32300016
         SPACE 2                                                        32400016
         BAL   R9,UPCCHH               INCREMENT TO NEXT TRACK.         32500016
         L     R4,8(R11)               ADDRESS OF ALT. INFORMATION.     32600016
         MVC   0(6,R4),ALTINFO         UPDATE ALTERNATE TRACK INFO.     32700016
         SPACE 3                                                        32800016
EXIT0    BAL   R9,FREECORE             FREE THE WORKAREA.               32900016
         LA    R15,0                   SET RETURN CODE.                 33000016
         SVC   RETURN                  RETURN TO CALLER.                33100016
         EJECT                                                          33200016
*********************************************************************** 33300016
*                                                                     * 33400016
*   UPDATE THE FORMAT 4 DSCB HERE.                                    * 33500016
*                                                                     * 33600016
*********************************************************************** 33700016
         SPACE 3                                                        33800016
UPF4     EQU   *                       UPDAYE THE FORMAT 4 DSCB HERE.   33900016
         BAL   R9,UPCCHH               UPDATE TRACK ADDRESS.            34000016
         MVC   ALTDATA(6),ALTINFO      UPDATE ALTERNATE INFORMATION.    34100016
         LA    R3,SEARCH               CHANNEL PROGRAM ADDRESS.         34200016
         ST    R3,IOBSTART             STORE IN IOB.                    34300016
         MVI   WRTRD,X'05'             SET OP CODE FOR WRITE.           34400016
         MVC   CCHHR(4),VTOCCCHH       SEEK//SEARCH ADDRESS.            34500016
         BAL   R9,WRTREAD              WRITE OUT NEW FORMAT 4 DSCB DATA 34600016
         BAL   R9,WAIT                 AWAIT COMPLETION.                34700016
         MVI   WRTRD,X'06'             SET OP CODE FOR READ.            34800016
         OI    WRTRD+4,SKIP            SKIP DATA TRANSFER.              34900016
         BAL   R9,WRTREAD              READ BACK CHECK DATA.            35000016
         BAL   R9,WAIT                 AWAIT COMPLETION.                35100016
         B     EXIT0                   GO RETURN TO CALLER.             35200016
         SPACE                                                          35300016
*********************************************************************** 35400016
*                                                                     * 35500016
*   INCREMENT TO THE NEXT SEQUENTIAL TRACK HERE.                      * 35600016
*                                                                     * 35700016
*********************************************************************** 35800016
         SPACE 3                                                        35900016
UPCCHH   L     R4,ALTINFO              ALTERNATE TRACK USED.            36000016
         CLC   ALTINFO+3(1),3(R6)      THIS LAST TRACK OF CYLINDER.     36100016
         BC    4,CEXIT                 NO--                             36200016
         SPACE                                                          36300016
         A     R4,4(R6)                YES-ADD CYLINDER CONVERSION.     36400016
         CLI   ALTINFO+2,X'04'         2321 AND LAST CYLINDER.          36500016
         BC    7,CEXIT2                NO--                             36600016
         AL    R4,STC2321              YES-INCREMENT STRIP.             36800016
         CLI   ALTINFO+1,X'09'         LAST STRIP                       37000016
         BC    7,CEXIT2                NO--                             37100016
         AL    R4,SCC2321              YES--INCREMENT SUBCELL.          37200016
         B     CEXIT2                  GO STORE VALUE AND RETURN.       37300016
CEXIT    AL    R4,F1                   INCREMENT TO NEXT TRACK.         37500016
CEXIT2   ST    R4,ALTINFO              SAVE THIS INFORMATION.           37600016
         LH    R4,ALTINFO+4            CURRENT ALTERNATE COUNT.         37800016
         BCTR  R4,0                    DECREMENT BY ONE.                37900016
         STH   R4,ALTINFO+4            SAVE UPDATED COUNT.              38000016
         BR    R9                      RETURN.                          38100016
         EJECT                                                          38200016
*********************************************************************** 38300016
*                                                                     * 38400016
*   DEVICE CONSTANTS---ORDERED BY UCB TYPE CODES.                       38500016
*                                                                     * 38600016
*********************************************************************** 38700016
         SPACE 3                                                        38800016
         DS    0F                                                       38900016
FIRSTALT DC    X'00C70009'             2311 LAST PRIMARY.               39000016
CONVCYL  DC    X'0000FFF7'             2311 CYLINDER CONVERSION.        39100016
         SPACE 1                                                        39200016
         DS    4F                      2301/2303 NOT APPLICABLE.        39300016
         SPACE                                                          39400016
         DC    X'00F5002D'             2302 LAST PRIMARY.               39500016
         DC    X'0000FFD3'             2302 CYLINDER CONVERSION.        39600016
         SPACE 1                                                        39700016
         DC    X'13050413'             2321 LAST PRIMARY.               39800016
         DC    X'000000ED'             2321 CYLINDER CONVERSION.        39900016
         SPACE                                                          40000016
         DS    4F                      CODES 6 AND 7 NOT USED.          40100016
         SPACE                                                          40200016
         DC    X'00C70013'             2314 LAST PRIMARY.               40300016
         DC    X'0000FFED'             2314 CYLINDER CONVERSION.        40400016
         SPACE                                                          40420020
         DC    X'01930012'              CCHH AT LAST PRIMARY     M5448  40440020
         DC    X'0000FFEE'              CYL INCREMENT            M5448  40460020
         SPACE                                                          40500016
SCC2321  DC    X'00F60000'             INCREMENT TO NEXT SUBCELL.       40600016
STC2321  DC    X'0000FB00'             INCREMENT TO NEXT STRIP.         40700016
         EJECT                                                          40800016
WRTREAD  EXCP  IOB                     START THE I/O OPERATION.         40900016
         BR    R9                      RETURN.                          41000016
         SPACE   3                                                      41100016
WAIT     TM    ECB,COMPLETE            THIS OPERATION COMPLETE.         41200016
         BO    TEST                    YES-TEST ITS STATUS.             41300016
         WAIT  ECB=ECB                 NO--AWAIT COMPLETION.            41400016
TEST     CLI   ECB,GOOD                EVERYTHING A-OK.                 41500016
         BCR   8,R9                    YES-RETURN.                      41600016
         TM    IOBCSW+4,UE             THIS A UNIT EXCEPTION.           41700016
         BCR   1,R9                    YES-//THIS IS OKAY.              41800016
         TM    HA,MOVEHA               THIS THE 2ND ATTEMPT.            41900016
         BO    IOERR                   YES--CANNOT TRY AGAIN.           42000016
         TM    HA,DEFECT               THIS A DEFECTIVE TRACK.          42100016
         BC    8,IOERR                 NO--MUST BE IOERR.               42200016
         OI    HA,MOVEHA               SET FLAG TO MOVE DOWN TRACK.     42300016
         EXCP  IOB                     REPEAT THE REQUEST.              42400016
         B     WAIT                    AWAIT COMPLETION.                42500016
         SPACE 3                                                        42600016
FREECORE EQU   *                       RELEASE THE CORE HERE.           42700016
         LH    R3,SIZE                 SIZE OF AREA TO RELEASE.         42800016
         FREEMAIN R,LV=(3),A=(2),SP=253                                 42900016
         BR    R9                      RETURN.                          43000016
         SPACE                                                          43100016
IOERR    EQU   *                                                        43200016
         LA    R15,12                  SET RETURN CODE.                 43300016
         SVC   RETURN                  EXIT.*                           43400016
         SPACE 3                                                        43500016
F1       DC    F'1'                    TRACK INCREMENT CONSTANT.        43600016
ZERO     DC    1H'0'                   COMPARE CONSTANT.                43700016
ROLENGTH DC    1F'8'                    R0 KEY DATA L            S21041 43730021
K4       EQU   4                        DISPLACEMENT CON         S21041 43760021
         EJECT                                                          43800016
IOBLOCKS DSECT                                                          43900016
MYDEB    EQU   *                       DEB DEFINITION.                  44000016
DEBEOEA  DS    1F                      END-OF-EXTENT.                   44100016
DEBSIOA  DS    1F                      START I/O.                       44200016
DEBPCIA  DS    1F                      PCI.                             44300016
DEBCEA   DS    1F                      CHANNEL END.                     44400016
DEBXCEA  DS    1F                      ABNORMAL END.                    44500016
         DS    CL12                                                     44600016
DEBLNGTH DS    CL1                     DEB LENGTH(DOUBLE WORDS)         44700016
         DS    CL3                                                      44800016
DEB      EQU   *                       DEB PROPER                       44900016
DEBNMSUB DS    CL1                     OPEN SUBROUTINES.                45000016
DEBTCBAD DS    CL3                     TCB ADDRESS.                     45100016
DEBAMLNG DS    CL1                     LENGTH ACCESS METHOD.            45200016
DEBDEBAD DS    CL3                     NEXT DEB ADDRESS.                45300016
DEBOFLGS DS    CL1                     DATA SET FLAGS.                  45400016
DEBIRBAD DS    CL3                     IRB ADDRESS.                     45500016
DEBOPATB DS    CL1                     TYPE OF I/O.                     45600016
DEBSYSPG DS    CL3                     IOB PURGE ADDRESS.(SYSTEM)       45700016
DEBNMEXT DS    CL1                     NO. OF EXTENTS.                  45800016
DEBUSRPG DS    CL3                     IOB USER PURGE ADDRESS.          45900016
DEBPRIOR DS    CL1                     ZERO                             46000016
DEBECBAD DS    CL3                     PURGE ECB.                       46100016
DEBDEBID DS    CL1                     PROTECT KEY//ID.                 46200016
DEBDCBAD DS    CL3                     DCB ADDRESS.                     46300016
DEBEXSCL DS    CL1                     EXTENT SCALE.                    46400016
DEBAPPAD DS    CL3                     APPENDAGE VECTOR TABLE.          46500016
DEBDVMOD DS    CL1                     FILE MASK.                       46600016
DEBUCBAD DS    CL3                     UCB ADDRESS.                     46700016
DEBBINNO DS    CL2                     BIN NO. FOR 2321.                46800016
DEBSTRCC DS    CL2                     CYLINDER START.                  46900016
DEBSTRHH DS    CL2                     HEAD START.                      47000016
DEBENDCC DS    CL2                     CYLINDER END.                    47100016
DEBENDHH DS    CL2                     HEAD END.                        47200016
DEBNMTRK DS    CL2                     NUMBER OF TRACKS.                47300016
         DS    CL20                                                     47400016
DEBEND   DS    0C                      END OF DEB.                      47500016
         EJECT                                                          47600016
ECB      DS    1F                      ECB HERE.                        47700016
IOB      EQU   *                       IOB HERE.                        47800016
IOBFLAG1 DS    CL1                     FLAG1                            47900016
IOBFLAG2 DS    CL1                     FLAG2.                           48000016
IOBSENS0 DS    CL1                     SENSE BYTE ZERO.                 48100016
IOBSENS1 DS    CL1                     SENSE BYTE ONE.                  48200016
IOBECBAD DS    CL4                     ADDRESS OF ECB.                  48300016
IOBCSW   DS    CL8                     STATUS WORDS.                    48400016
IOBSTART DS    CL4                     CHANNEL PROGRAM ADDRESS.         48500016
IOBDCBPT DS    CL4                     ADDRESS OF DCB.                  48600016
IOBRESTR DS    CL4                     RESTART ADDRESS.                 48700016
IOBINCAM DS    CL2                     BLOCK COUNT.                     48800016
IOBERRCT DS    CL2                     ERROR COUNT.                     48900016
IOBSEEK  DS    CL8                     SEEK ADDRESS.                    49000016
CCHHR    EQU   IOBSEEK+3               SEARCH ADDRESS.                  49100016
DCB      DS    1F                      DEB ADDRESS.                     49200016
ALTINFO  DS    1D                      KEEP ALTERNATE TRACK INFO HERE.  49300016
WRTHA    DS    1D                      WRITE HOME ADDRESS.              49400016
WRTR0    DS    1D                      WRITE RECORD ZERO.               49500016
RDHA     DS    1D                      READ HOME ADDRESS.               49600016
READR0   DS    1D                      READ RECORD ZERO.                49700016
HA       DS    CL5                     HOME ADDRESS.                    49800016
SW       DS    CL1                     SWITCH.                          49900016
D2314    EQU   X'80'                   2314 DEVICE.                     50000016
D2321    EQU   X'40'                   2321 DEVICE.                     50100016
DEFALT   EQU   X'02'                                               1057 50150018
RETRY    EQU   X'01'                   GIVE IT ONE MORE TRY.            50200016
SIZE     DS    CL2                     SIZE OF GETMAIN AREA.            50300016
R0COUNT  DS    1D                      RECORD ZERO COUNT FIELD.         50400016
R0DATA   DS    1D                      RECORD ZERO DATA  FIELD.         50500016
IOEND1   DS    0C                      END OF BASIC I/O BLOCKS.         50600016
*   EXTENSION FOR GETALT//DYNAMIC TRACK REQUEST.                        50700016
SEARCH   DS    1D                      SEARCH CCW.                      50800016
TIC      DS    1D                      REPEAT UNTIL FOUND.              50900016
WRTRD    DS    1D                      WRITE OR READ DATA.              51000016
FORMAT4  DS    CL96                    FORMAT4 DSCB READ IN AREA.       51100016
ALTDATA  EQU   FORMAT4+8               ALTERNATE TRACK INFORMATION.     51200016
VTOCCCHH EQU   FORMAT4+63              CCHH START OF VTOC.              51300016
IOEND    DS    0C                                                       51400016
         EJECT                                                          51500016
UCB      DSECT                                                          51600016
         IEFUCBOB                                                       51700016
         EJECT                                                          51800016
CVT      DSECT                                                          51900016
         CVT   SYS=MIN                                                  52000016
         END                                                            52100016
