109H     TITLE 'IGC0109H SVC 98 (PROTECT) SECOND LOAD - PASSWORD DATA SX00100000
               ET MAINTAINENCE/UPDATE ROUTINE'                          00200020
IGC0109H CSECT                                                          00300020
*A 335500                                                        A50964 00310021
*C 309000,336000                                                 A50964 00312021
*D 327500-327600                                                 A50964 00320021
*A 327500-327600                                                 A45004 00350021
*C 309000                                                        A45004 00360021
*A 128500-128600,202100-204992,530500-530984,571500,             A43379 00370021
*A 588500-588800,607500-607700                                   A43379 00380021
*C 364000                                                        A43379 00390021
*D 203000-204000,361000-363000,380000-399000,536000-537000       A43379 00392021
*  NOTE MOST OF A43379 CHANGES MADE TO GAIN SPACE                A43379 00396021
*                                                               SA69177 00398021
*********************************************************************** 00400020
*                                                                     * 00500020
* STATUS -- CHANGE LEVEL 03                                     SA69177 00600021
*                                                                     * 00700020
* FUNCTION -- SECOND LOAD OF THE PASSWORD DATA SET MAINTAINENCE       * 00800020
*    ROUTINE                                                          * 00900020
*    1. PROCESSES ALL VALID REQUESTS TO MODIFY OR TO PROVIDE          * 01000020
*    INFORMATION FROM THE PASSWORD DATA SET.  THE FOLLOWING ARE VALID * 01100020
*    REQUESTS -                                                       * 01200020
*    ADD - ADD A NEW (CONTROL) ENTRY OR ADD A (SECONDARY) ENTRY       * 01300020
*    REPLACE - REPLACE AN EXISTING ENTRY BY REPLACING (1) THE EIGHT   * 01400020
*    BYTE PASSWORD, (2) PROTECTION MODE, (3) USER DATA FIELD, OR ANY  * 01500020
*    COMBINATION OF THESE THREE.                                      * 01600020
*    DELETE - DELETE A SECONDARY ENTRY OR DELETE A CONTROL ENTRY AND  * 01700020
*    ANY EXISTING SECONDARY ENTRIES FOR A DATA SET NAME               * 01800020
*    LIST - PROVIDE THE REQUESTOR WITH THE 80 BYTE DATA FIELD OF A    * 01900020
*    PARTICULAR ENTRY IN THE PASSWORD DATA SET.                       * 02000020
*    TTR - PROVIDE THE REQUESTOR WITH THE RELATIVE LOCATION (TTR) OF  * 02100020
*    A PARTICULAR ENTRY IN THE PASSWORD DATA SET                      * 02200020
*    2. PROVIDE THE PROTECTION MODE FLAG BIT SETTING FOR THE DSCB OF  * 02300020
*    A DATA SET TO THE NEXT LOAD OF SVC 98.                           * 02400020
*                                                                     * 02500020
* ENTRY POINTS --                                                     * 02600020
*         IGC0109H - ENTRY POINT OF SECOND LOAD, ENTERED BY XCTL FROM * 02700020
*    FIRST LOAD (IGC0009H)                                            * 02800020
*                                                                     * 02900020
* INPUT --                                                            * 03000020
*    REGISTER RPARM POINTS TO INPUT PARAMETER LIST                    * 03100020
*    REGISTER RW POINTS TO WORK AREA                                  * 03200020
*    REGISTER RA CONTAINS ENTRY CODE FOR THIS LOAD                    * 03300020
*    REGISTER RB CONTAINS RETURN CODE FROM FIRST LOAD OF SVC 98       * 03400020
*                                                                     * 03500020
* OUTPUT --                                                           * 03600020
*    REGISTER RW POINTS TO WORK AREA                                  * 03700020
*    REGISTER RPARM POINTS TO INPUT PARAMETER LIST                    * 03800020
*    REGISTER RB PASSES RETURN CODE BETWEEN LOADS OF SVC 98           * 03900020
*                                                                     * 04000020
* EXTERNAL REFERENCES --                                              * 04100020
*         IECPCNVT - BRANCH TO THE RESIDENT DATA MANAGEMENT CONVERT   * 04200020
*    ROUTINE TO CONVERT A RELATIVE DIRECT ACCESS DEIVCE ADDRESS (TTR) * 04300020
*    TO AN ACTUAL DIRECT ACCESS DEVICE ADDRESS (MBBCCHHR)             * 04400020
*         IECPRLTV - BRANCH TO THE RESIDENT DATA MANAGEMENT CONVERT   * 04500020
*    ROUTINE TO CONVERT AN ACTUAL DIRECT ACCESS DEVICE ADDRESS        * 04600020
*    (MBBCCHHR) TO A RELATIVE DIRECT ACCESS DEVICE ADDRESS (TTR)      * 04700020
*                                                                     * 04800020
* EXITS, NORMAL -- XCTL TO IGC0209H TO PROCESS PASSWORD DATA SET      * 04900020
*                                                                     * 05000020
* EXITS, ERROR -- XCTL TO IGC0209H WITH NON-ZERO RETURN CODE          * 05100020
*    04  DATA SET NAME/PASSWORD ALREADY IN PASSWORD DATA SET          * 05200020
*    08  DATA SET NAME/PASSWORD NOT IN PASSWORD DATA SET              * 05300020
*    12  CONTROL PASSWORD IS REQUIRED OR IS INCORRECT                 * 05400020
*    16  INCOMPLETE OR INCORRECT PARAMETER LIST                       * 05500020
*    20  I/O ERROR IN PASSWORD DATA SET                               * 05600020
*    24  PASSWORD DATA SET IS FULL                                    * 05700020
*    RETURN CODES 8, 16, 28, AND 44 CAN OCCUR IN FIRST LOAD OF SVC 98 * 05800020
*                                                                     * 05900020
* TABLES/WORK AREAS --                                                * 06000020
*    WORKD - A CONTIGUOUS AREA DEFINED BY IECDSECT FOR I/O CONTROL    * 06100020
*    BLOCKS FOLLOWED BY A LOCAL WORK AREA FOR COMMUNICATION AND       * 06200020
*    BUFFER SPACE                                                     * 06300020
*    PARMD - A DSECT TO MAP THE INPUT PARAMETER LIST                  * 06400020
*    WRKSPACE - A DSECT TO MAP THE LOCATE AND OBTAIN WORKAREAS        * 06500020
*                                                                     * 06600020
* ATTRIBUTES -- REENTRANT, READ ONLY, PRIVILIGED, ENABLED             * 06700020
*                                                                     * 06800020
* CHARACTER CODE DEPENDENCY -- CHARACTER CODE INDEPENDENT             * 06900020
*                                                                     * 07000020
* NOTES -- N/A                                                        * 07100020
*                                                                     * 07200020
*                                                                     * 07300020
*    PASSWORD DATA SET - FORMAT OF EACH 132 BYTE ENTRY                * 07400020
*                                                                     * 07500020
*    *                     *                                       *  * 07600020
*    *    52 BYTE KEY      *       80 BYTE DATA AREA               *  * 07700020
*    ***************************************************************  * 07800020
*    *           *         *         *           *                 *  * 07900020
*    * 44 BYTES  * 8 BYTES * 2 BYTES * 1 BYTE    * 77 BYTES        *  * 08000020
*    *           *         *         *           *                 *  * 08100020
*    * FULLY     * PASSWORD* ACCESS  * PROTECTION* USER DATA FIELD *  * 08200020
*    * QUALIFIED *         * COUNTER * MODE      *                 *  * 08300020
*    * DSNAME    *         *         * INDICATOR *                 *  * 08400020
*    ***************************************************************  * 08500020
*                                                                     * 08600020
*    PROTECTION MODE INDICATOR - FORMAT OF 1 BYTE ENTRY               * 08700020
*    BIT 0   =0 INDICATES SECONDARY PASSWORD                          * 08800020
*    BIT 0   =1 INDICATES CONTROL PASSWORD                            * 08900020
*    BIT 1-6    RESERVED                                              * 09000020
*    BIT 7   =0 PROTECTED DATA SET IS READ ONLY                       * 09100020
*    BIT 7   =1 PROTECTED DATA SET CAN BE READ OR WRITTEN             * 09200020
*                                                                     * 09400020
*********************************************************************** 09500020
         EJECT                                                          09600020
*                                                                       09700020
*        EQUATED SYMBOLS                                                09800020
*                                                                       09900020
SRKEY    EQU   X'A9'               SEARCH-KEY-EQ M/T OP-CODE            10000020
SRID     EQU   X'31'               SEARCH ID OP-CODE                    10100020
WTKDAT   EQU   X'0D'               WRITE KEY-DATA OP-CODE               10200020
SUPDAT   EQU   X'10'               SUPPRESS DATA TRANSFER FLAG          10300020
CHAIN    EQU   X'40'               CHAIN DATA FLAG                      10400020
NKEYLL   EQU   X'2C'               DATA SET NAME KEY LENGTH             10500020
KEYLL    EQU   X'34'               PASSWORD ENTRY KEY LENGTH            10600020
SLI      EQU   X'20'               FLAG IN CCW - SUPPRESS       SA69177 10650021
*                                       INCORRECT LENGTH INDICATION     10660021
NOSLI    EQU   X'DF'               MASK TO TURN OFF SLI         SA69177 10670021
HLEN     EQU   X'2C'               MAXIMUM DSNAME LENGTH                10700020
HSTR     EQU   X'4D'               DATA FIELD - 77 BYTES                10800020
ENTLEN   EQU   X'84'               LENGTH OF PASSWORD ENTRY (132 BYTES) 10900020
COMMSK   EQU   X'20'               MASK- TEST FOR SUCCESSFUL I/O        11000020
EXTMSK   EQU   X'02'               MASK- TEST FOR END OF EXTENT         11100020
EOFCK1   EQU   X'41'               TO TEST ERROR EXCEPTION              11200020
EOFCK2   EQU   X'0D'               TO TEST FOR EXCEPTION ON WRITE EOD   11300020
NEWMASK  EQU   X'00'               IDENTIFY FIRST TIME INITIALIZATION   11400020
ADD      EQU   X'01'               ADD ENTRY CODE                       11500020
REPLACE  EQU   X'02'               REPLACE ENTRY CODE                   11600020
DELETE   EQU   X'03'               DELETE ENTRY CODE                    11700020
CTLPW    EQU   X'80'               MASK- CONTROL PROTECTION CODE        11800020
RDWRT    EQU   X'01'               PROTECTION MODE-READ/WRITE           11900020
PCOD0    EQU   X'00'               PROTECTION CODE MASK FOR DEFAULT     12000020
PCOD3    EQU   X'03'               DEFAULT PROTECTION CODE              12100020
MPENQ    EQU   X'80'               MPDS ENQUEUE FLAG                    12200020
REPASS   EQU   X'40'               MASK INDICATES REPLACE OF PASSWORD   12300020
ENQF     EQU   X'20'               TO SET DFLAG1 -INDICATE ENQUEUES     12400020
MPUPDAT  EQU   X'01'               TO SET FLAG UPDATE MPDS DSCB         12500020
DSNUPDAT EQU   X'02'               DSCB UPDATE INDICATOR                12600020
DSCBP3   EQU   X'10'               DSCB PROTECT BIT INDICATOR           12700020
DSCBP5   EQU   X'04'               DSCB PROTECT BIT INDICATOR           12800020
UNITCHCK EQU   X'02'               TEST FOR UNIT CHECK           A43379 12850021
CYLINDER EQU   X'20'               TEST FOR CYLINDER END         A43379 12860021
GC209    EQU   C'2'                TO MODIFY XCTL LIST TO IGC0209H      12900020
EQ       EQU   8                   TEST FOR EQUAL COMPARE CONDITION     13000020
ZERO     EQU   0                   ZERO                                 13100020
ONE      EQU   1                   ONE                                  13200020
FOUR     EQU   4                   FOUR                                 13300020
NZ       EQU   14                  FOURTEEN (NON-ZERO MASK)             13400020
N1       EQU   1                   ONE                                  13500020
N2       EQU   2                   TWO                                  13600020
N3       EQU   3                   THREE                                13700020
N4       EQU   4                   FOUR                                 13800020
N5       EQU   5                   FIVE                                 13900020
N7       EQU   7                   SEVEN                                14000020
N8       EQU   8                   EIGHT                                14100020
N16      EQU   16                  SIXTEEN                              14200020
RNLENGTH EQU   44                  RNAME LENGTH FOR ENQUEUE ON DSCB     14300020
BLANK    EQU   C' '                BLANK                                14400020
HFF      EQU   X'FF'               BYTE OF FF                           14500020
*                                                                       14600020
*        RETURN CODES FOR ALL CONDITIONS  (NORMAL OR ERROR)             14700020
*                                                                       14800020
C4       EQU   4                   RETURN CODE  4                       14900020
C8       EQU   8                   RETURN CODE  8                       15000020
C12      EQU   12                  RETURN CODE 12                       15100020
C16      EQU   16                  RETURN CODE 16                       15200020
C20      EQU   20                  RETURN CODE 20                       15300020
C24      EQU   24                  RETURN CODE 24                       15400020
C28      EQU   28                  RETURN CODE 28                       15500020
C32      EQU   32                  RETURN CODE 32                       15600020
C36      EQU   36                  RETURN CODE 36                       15700020
C40      EQU   40                  RETURN CODE 40                       15800020
C44      EQU   44                  RETURN CODE 44                       15900020
C48      EQU   48                  RETURN CODE 48                       16000020
*                                                                       16100020
*        REGISTER EQUATES                                               16200020
*                                                                       16250020
RP0      EQU   0                   PARAMETER REGISTER                   16300020
RP1      EQU   1                   PARAMETER REGISTER                   16400020
RP2      EQU   2                   PARAMETER REGISTER                   16500020
R2       EQU   2                   WORK REGISTER                        16600020
RC       EQU   3                   WORK REGISTER                        16700020
RPARM    EQU   4                   ADDRESS OF CALLERS PARAMETER LIST    16800020
RW       EQU   5                   ADDRESS OF WORK AREA (WORKD)         16900020
RWK6     EQU   6                   UNUSED REGISTER                      17000020
RWK7     EQU   7                   WORK REGISTER                        17100020
RWK8     EQU   8                   WORK REGISTER                        17200020
RWK9     EQU   9                   WORK REGISTER                        17300020
RA       EQU   10                  WORK REGISTER                        17400020
RB       EQU   11                  WORK REGISTER                        17500020
RBASE    EQU   12                  BASE REGISTER                        17600020
RD       EQU   13                  SAVE REGISTER                        17700020
RE       EQU   14                  RETURN LINKAGE                       17800020
RF       EQU   15                  LINKAGE/RETURN CODE                  17900020
         EJECT                                                          18000020
         USING WORKD,RW            ESTABLISH ADDRESSABILITY FOR DSECT   18100020
         USING PARMD,RPARM         ESTABLISH ADDRESSABILITY PARMLIST    18200020
         BALR  RBASE,RP0           GET ADDRESS WHERE LOADED             18300020
         USING *,RBASE             ESTABLIST ADDRESSABILITY FOR PROGRAM 18400020
*                                                                       18500020
*        TEST  ENTRY CONDITIONS AS SET UP BY INITIALIZATION (IGC0009H)  18600020
*        UPON ENTRY, THE BRANCH TABLE CODE AND ERROR CODE ARE IN        18700020
*        REGISTERS RA AND RB RESPECTIVELY. THE CONTENTS OF RA WILL      18800020
*        BE USED TO LINK TO THE REQUESTED PROCESSING ROUTINE AFTER      18900020
*        REGISTER RB HAS BEEN TESTED FOR  A NON-ZERO CODE.              19000020
*        IF AN ERROR CODE IS PASSED IN RB, THE ERROR EXIT IS TAKEN.     19100020
*                                                                       19200020
         LA    RD,ERETEND          ADDRESS OF ERROR EXIT                19300020
         LTR   RB,RB               HAS AN ERROR CODE BEEN PASSED        19400020
         BCR   N7,RD               GO TO ERROR EXIT                     19500020
         LA    RWK8,SRCH020        SAVE ADDRESS OF SUBROUTINE           19600020
         B     ENT010(RA)          GO TO PROCESS REQUEST                19700020
ENT010   B     COM050              ADD REQUESTED- FIRST ENTRY IN D/S    19800020
         B     ADD010              ADD REQUESTED                        19900020
         B     COM005              REPLACE REQUESTED                    20000020
         B     COM010              DELETE REQUESTED                     20100020
         B     LST010              LIST REQUESTED                       20200020
*  TTR FUNCTION MUST BE HERE                                     A43379 20210021
*  BRANCHED TO DIRECTLY VIA BRANCH TABLE ABOVE.                  A43379 20220021
*                                                                A43379 20250021
*        TTR REQUEST PROCESSING ROUTINE                          A43379 20300021
*        A REQUEST TO PROVIDE THE RELATIVE TRACK ADDRESS (TTR)   A43379 20350021
*        OF A SPECIFIC PASSWORD ENTRY IS SATISFIED BY RETURNING  A43379 20400021
*        A TTR LEFT ADJUSTED, IN A USER PROVIDED BUFFER.         A43379 20450021
*                                                                A43379 20460021
*        SEARCH FOR CORRECT ENTRY AND READ COUNT FIELD           A43379 20470021
TTR010   BALR  RC,RWK8             SEARCH FOR DSN ENTRY          A43379 20480021
*                                                                A43379 20490021
         B     TTR020              SUCCESS, CONVERT ADDRESS      A43379 20492021
         B     ERET020             ERROR, DS ENTRY NOT FOUND     A43379 20494021
TTR020   LA    RWK7,CVTPRLTV-CVT   CVT OFFSET TO CONVERT ROUTINE A43379 20496021
         BAL   RA,CONV010          CONVERT MBBCCHHR TO TTR       A43379 20498021
         L     RWK9,DBUF           ADDRESS OF REQUESTOR'S BUFFER A43379 20498421
         ST    RP0,ZERO(RWK9)      STORE TTR IN BUFFER           A43379 20498821
         B     RET010              PREPARE FOR EXIT              A43379 20499221
         EJECT                                                          20500020
*                                                                       20600020
*        ADD/REPLACE/DELETE REQUEST PROCESSING ROUTINE-                 20700020
*        THIS ROUTINE IS ENTERED ON AN ADD,REPLACE OR DELETE REQUEST    20800020
*        TO PERFORM THE MAINLINE PROCESSING.                            20900020
*        THIS ROUTINE LINKS TO SUBROUTINES FOR EXCP I/O FUNCTIONS,      21000020
*        TO BUILD THE PROPER PROTECTION MODE AND DATA FIELDS,           21100020
*        AND TO SET UP THE DEVICE ADDRESS (CCHHR) FOR AN ENTRY          21200020
*        TO BE ADDED TO THE END OF THE PASSWORD DATA SET.               21300020
*        DSN/PASSWORD FIELDS HAVE BEEN INITIALIZED IN THE FIRST LOAD.   21400020
*        RETURN FROM THE I/O SEARCH ROUTINE (EXCP) IS MADE AS FOLLOWS-  21500020
*                        BR    RC -KEY FOUND/ UPDATE SUCCESSFUL         21600020
*                        B   4(RC)-KEY NOT FOUND-ON SEARCH OF EXTENT    21700020
*        ON ANY OTHER ERROR CONDITION, THE ERROR EXIT IS ENTERED        21800020
*        DIRECTLY FROM THE SEARCH ROUTINE.                              21900020
*                                                                       22000020
*        ENTRY IS MADE HERE FOR ALL ADD REQUESTS EXCEPT                 22100020
*        A FIRST ADD INTO THE PASSWORD DATA SET.                        22200020
*                                                                       22300020
*                                                                       22400020
*        A SEARCH IS MADE FOR AN EXISTING ENTRY WITH THIS DSNAME.       22500020
*                                                                       22600020
ADD010   MVI   DXCCW4+N7,NKEYLL    SET SEARCH KEY LENGTH TO 44 BYTES    22700020
         OI    DXCCW4+N4,SLI       SUPPRESS WRONG LENGTH INDIC  SA69177 22750021
         BAL   RC,SRCH050          SEARCH FOR ENTRY WITH 44 BYTE DSN    22800020
         B     COM010              FOUND- CONTINUE SEARCH               22900020
         B     COM050              PROCESS AS A CONTROL ENTRY ADD       23000020
*        ENTRY IS MADE HERE FOR A REPLACE REQUEST                       23100020
*        IF THE PASSWORD ITSELF IS BEING REPLACED, A SEARCH IS MADE     23200020
*        TO VERIFY THAT THE NEW PASSWORD DOES NOT ALREADY EXIST         23300020
COM005   TM    DFLAG2,REPASS       IS THE PASSWORD BEING REPLACED       23400020
         BNO   COM010              NO, GO SEARCH FOR DSN/CURRENT PW     23500020
         BALR  RC,RWK8             YES, SEARCH FOR DSN/NEW PASSWORD     23600020
         B     ERET010             NEW PASSWORD FOUND, ERROR            23700020
         L     R2,CURRENT          NOT FOUND, SET UP CURRENT PW SEARCH  23800020
         EX    ZERO,MOVPW          MOVE PASSWORD TO SEARCH KEY AREA     23900020
*        ENTRY IS MADE HERE FOR A DELETE/REPLACE REQUEST                24000020
*                                                                       24100020
*        A SEARCH IS MADE FOR THE DATA SET NAME/PASSWORD. FOR           24200020
*        AN ADD THE (NEW) PASSWORD IS USED, FOR DELETE OR               24300020
*        REPLACE THE (CURRENT) PASSWORD IS USED.                        24400020
*                                                                       24500020
COM010   BALR  RC,RWK8             SEARCH FOR 52 BYTE DSN/PASSWORD KEY  24600020
         B     COM015              FOUND- CONTINUE SEARCH               24700020
         CLI   ENCODE,ADD          NOT FOUND- DETERMINE IF AN ADD..-    24800020
         BNE   ERET020             IF REPLACE/DELETE GO TO ERROR EXIT   24900020
         B     COM020              GO SEARCH FOR CONTROL PASSWORD ENTRY 25000020
COM015   CLI   ENCODE,ADD          ADD SPECIFIED                        25100020
         BE    ERET010             IF ADD-GO TO ERROR EXIT              25200020
*                                                                       25300020
*        REPLACE/DELETE IS SPECIFIED- DETERMINE IF ENTRY BEING          25400020
*        REPLACED OR DELETED IS A CONTROL ENTRY.                        25500020
*                                                                       25600020
         TM    DMODE,CTLPW         IS ENTRY A CONTROL ENTRY             25700020
         BO    COM050              IF YES-TEST FOR DELETE               25800020
*                                                                       25900020
*        THIS ROUTINE IS USED TO SEARCH FOR AND VERIFY THE CONTROL P/W  26000020
*                                                                       26100020
COM020   MVC   DREPSAV(DSAVLL),DCNT SAVE ENTIRE ENTRY FOR UPDATE        26200020
         L     R2,CONTROL          GET,ADDRESS OF CONTROL PASSWORD      26300020
         LTR   R2,R2               IS THE CONTROL PASSWORD PROVIDED     26400020
         LA    RB,C12              SET RETURN CODE IN CASE OF ERROR     26500020
         BCR   N8,RD               IF NOT GO TO ERROR EXIT              26600020
         EX    ZERO,MOVPW          MOVE CONTROL PASSWORD TO KEY FIELD   26700020
         BALR  RC,RWK8             SEARCH FOR 52 BYTE DSN/PASSWORD      26800020
*                                                                       26900020
         B     COM030              FOUND-VERIFY THAT IT IS A CONTROL    27000020
         BR    RD                  NOT FOUND-GO TO ERROR EXIT           27100020
COM030   TM    DMODE,CTLPW         IS THIS A CONTROL ENTRY              27200020
         BCR   NZ,RD               IF NOT GO TO ERROR EXIT              27300020
         XI    DMODE,CTLPW         CONTROL. SET INDICATOR OFF           27400020
         IC    RA,DMODE            SAVE MODE IN EVENT OF SECONDARY ADD  27500021
*                                                                       27600020
*        RESTORE THE FIELDS REQUIRED FOR AN ADD/REPLACE/DELETE          27700020
*                                                                       27800020
         MVC   DCNT(DSAVLL),DREPSAV RESTORE COMPLETE ENTRY TO BUFFER    27900020
         B     COM060              GO TO BUILD ENTRY FIELDS             28000020
ZEROOUT  EQU   *                                                SA66202 28050000
         XC    DKEYLEN(N3),DKEYLEN      UPDATE OK - EOD         SA66202 28060000
         B     EODRTN                                           SA66202 28070000
*                                                                       28100020
*        ENTRY IS MADE HERE FOR PROCESSING OF ADD/REPLACE/DELETE        28200020
*        REQUESTS FOR CONTROL PASSWORDS IN ORDER TO SET THE DSCB        28300020
*        UPDATE INDICATORS AND SET UP THE PROTECTION MODE MASK          28400020
*                                                                       28500020
COM050   OI    DPMODE,CTLPW        SET CONTROL PASSWORD INDICATION      28600020
         OI    DFLAG1,DSNUPDAT     INDICATE DSCB UPDATE REQUIREMENT     28700020
*                                                                       28800020
*        BUILD PROTECTION MODE/DATA FIELDS                              28900020
*                                                                       29000020
COM060   LA    RWK9,DFOXKEY        GET ADDRESS OF 52 BYTE KEY OF FF'S   29100020
         CLI   ENCODE,DELETE       IS THIS A DELETE REQUEST             29200020
         BE    COM070              GO TO THE DELETE ROUTINE             29300020
         BAL   RC,BLDMD010         GO TO PROTECT MODE BUILD             29400020
         BAL   RC,BLDEN010         GO TO DATA FIELD BUILD               29500020
         CLI   DCODTAB,NEWMASK     IS THIS THE FIRST ENTRY IN DATA SET  29600020
         BE    ADDON010            IF YES- BYPASS SEARCH-ADD ENTRY      29700020
*                                  AT THE BEGINNING OF THE DATA SET     29800020
         CLI   ENCODE,REPLACE      IS THIS A REPLACE                    29900020
         BE    COM075              REPLACE- GO TO UPDATE ENTRY          30000020
         XC    DUSE,DUSE           CLEAR USE COUNT FIELD FOR ADDS       30100020
         ST    RWK9,DXCCW4         KEY ADDRESS TO FOURTH CCW            30200020
         MVI   DXCCW4,SRKEY        CCW TO SEARCH ON KEY OF FF'S         30300020
         OI    DXCCW6+N4,SUPDAT    TURN ON SKIP BIT                     30400020
*                                                                       30500020
*        SEARCH MPDS FOR AN EMPTY ENTRY (KEY ALL FF'S)                  30600020
*                                                                       30700020
         BALR  RC,RWK8             SEARCH FOR EMPTY ENTRY FIELD         30800020
         B     COM080              FOUND- GO ADD ENTRY           A50964 30900021
ADDON010 BAL   RC,ENBLK010         NOT FOUND- SET UP FOR ADD ON         31000020
*                                                                       31100020
*        SEARCH WILL POSITION FOR A WRITE COUNT-KEY-DATA                31200020
*                                                                       31300020
         BAL   RC,SRCH040          SEARCH/UPDATE ON END OF DATA SET     31400020
         B     ZEROOUT                  GO TO ZERO OUT RECORD   SA66202 31450000
EODRTN   EQU   *                                                SA66202 31500000
         BAL   RC,ENBLK020         FIND ADDRESS TO WRITE EOD RECORD     31600020
         MVI   DXCCW9+N7,N8        WRITE COUNT OF 8                     31700020
         BAL   RC,SRCH040          WRITE END OF DATA RECORD             31800020
         B     RET010              UPDATE SUCCESSFUL- GO TO EXIT        31900020
*        THIS ROUTINE IS ENTERED FOR DELETE REQUESTS TO SET UP FOR      32000020
*        WRITING OF A 52 BYTE KEY OF FFS (SIGNIFYING A DELETED ENTRY    32100020
*        TO THE SEARCH ROUTINE ADDING A NEW PASSWORD)                   32200020
COM070   ST    RWK9,DXCCW9         ADDRESS OF FFS KEY TO WRITE CCW      32300020
         MVI   DXCCW9+N7,KEYLL     SET TO WRITE 52 BYTE KEY OF FFS      32400020
         TM    DPMODE,CTLPW        IS A CONTROL ENTRY BEING DELETED     32500020
         BO    DELC010             IF YES, GO DELETE ALL ENTRIES        32600020
         B     COM090              GO TO WRITE UPDATED ENTRY OF (FF'S)  32700020
*                                                                       32800020
*        THIS ROUTINE WRITES AN UPDATED ENTRY (ADD,DELETE,REPLACE)      32900020
*        IN THE LOCATION OF THE EXISTING ENTRY. THE UPDATE IS           33000020
*        DONE VIA A WRITE KEY-DATA OPERATION.                           33100020
COM075   L     R2,NEW              GET ADDRESS OF NEW P/W FOR REPLACE   33200020
         EX    ZERO,MOVPW          MOVE NEW PASSWORD TO KEY FIELD       33300020
COM080   LA    RWK9,DKEY           KEY FIELD                            33400020
         ST    RWK9,DXCCW9         WRITE CCW SET FOR WRITE KEY-DATA     33500020
COM090   EX    ZERO,MOVCNT         SET IOB SEEK FIELD            A50964 33550021
         BAL   RC,SRCH030          SEARCH/WRITE UPDATE           A50964 33600021
         B     RET010              UPDATE SUCCESSFUL- GO TO EXIT        33700020
*                                                                       33800020
*        THIS ROUTINE IS ENTERED WHENEVER IT HAS BEEN DETERMINED THAT   33900020
*        A CONTROL PASSWORD IS BEING DELETED. ALL PASSWORD ENTRIES      34000020
*        WITH THE DATA SET NAME SPECIFIED IN THE PARAMETER LIST WILL    34100020
*        BE DELETED. UPON ENTRY TO THIS ROUTINE, THE SEARCH OF THE      34200020
*        PASSWORD DATA SET WILL BE MADE, STARTING AT THE ENTRY          34300020
*        FOLLOWING THE CONTROL ENTRY. ANY EXISTING SECONDARY PASSWORDS  34400020
*        WILL BE DELETED FIRST, LEAVING THE CONTROL ENTRY UNTIL LAST.   34500020
*                                                                       34600020
DELC010  BAL   RC,SRCH025          UPDATE CHANNEL COMMANDS -DELETE ALL  34700020
         MVC   DREPSAV+HLEN(N5),DCNT SAVE CCHHR OF CONTROL ENTRY        34800020
DELC020  EX    ZERO,MOVCNT         SET IOB SEEK TO LAST COUNT FIELD     34900020
         BAL   RC,SRCH055          SEARCH ON KEY/WRITE UPDATE           35000020
         B     DELC020             UPDATE SUCCESSFUL- RESUME SEARCH     35100020
         MVI   DXDAADDR+N7,ZERO    RESET SEARCH ID TO RECORD ZERO       35200020
*                                  SET TO SEARCH FROM                   35300020
*                                  FIRST ENTRY IN THE DATA SET.         35400020
         MVC   DXDAADDR+N3(N4),DSCLOWLM MOVE LOW EXTENT TO IOB FIELD    35500020
*        RESUME SEARCH FOR 44 BYTE DSNKEY,STARTING AT FIRST ENTRY       35600020
DELC030  BAL   RC,SRCH070          SEARCH ON KEY/WRITE UPDATE           35700020
         B     DELC040             UPDATE SUCCESSFUL-                   35800020
         B     ERET040             END OF EXTENT REACHED WITHOUT        35900020
*                                  FINDING CONTROL ENTRY-ERROR          36000020
DELC050  EX    ZERO,MOVCNT         LAST COUNT TO SEEK ADDRESS    A43379 36400021
         B     DELC030             CONTINUE SEARCH                      36500020
         EJECT                                                          36600020
*                                                                       36700020
*        LIST REQUEST PROCESSING ROUTINE                                36800020
*        A REQUEST TO PROVIDE THE SECURITY COUNTER,PROTECTION MODE      36900020
*        AND OPTIONAL DATA FIELD IS SATISFIED. THE 80 BYTES OF          37000020
*        INFORMATION ARE PLACED IN THE REQUESTOR'S BUFFER.              37100020
*                                                                       37200020
LST010   MVC   DXCCW6+N1(N3),DBUF+N1 BUFFER ADDRESS TO READ CCW         37300020
*        SEARCH FOR CORRECT ENTRY AND READ DATA INTO VALIDATED BUFFER   37400020
*                                                                       37500020
         BALR  RC,RWK8             SEARCH FOR DSN ENTRY                 37600020
*                                                                       37700020
         B     RET010              SUCCESSFUL RETURN                    37800020
         B     ERET020             ERROR, DATA SET ENTRY NOT FOUND      37900020
         EJECT                                                          40000020
*                                                                       40100020
*        ENBLK ROUTINE - PREPARE TO ADD A RECORD AFTER THE LAST BLOCK.  40200020
*        THIS ROUTINE SETS UP THE IOB SEEK FIELD WITH THE CCHHR ADDRESS 40300020
*        OF THE LAST BLOCK WRITTEN TO A TRACK. IF THERE IS NO ROOM TO   40400020
*        WRITE ANOTHER RECORD, THE RESIDENT CONVERT ROUTINE IS USED     40500020
*        TO FIND THE CCHHR OF THE NEXT TRACK.IN THIS EVENT, THE IOB     40600020
*        SEEK FIELD WILL CONTAIN A CCHHR WITH AN R FIELD OF RECORD 0.   40700020
*        THE COUNT FIELD RECORD NUMBER IS UPDATED BY 1 IN PREPARATION   40800020
*        FOR A WRITE CNT-KEY-DATA.                                      40900020
*                                                                       41000020
ENBLK010 MVC   DCNT(N8),DMPEND+N3  LAST BLOCK CCHHR +KL+DL TO COUNT     41100020
         LH    RWK9,DSAVT          GET TRACK (TT) PORTION OF LAST BLOCK 41200020
         XI    DFLAG1,MPUPDAT      INDICATE MPDS DSCB REQUIRES UPDATE   41300020
ENBLK020 CLC   DSCLSTAR+N2(N1),DRECAP WILL ANOTHER RECORD FIT ON TRACK. 41400020
         LA    R2,ENBLK040         ADDRESS OF COMMON ROUTINE            41500020
         BCR   FOUR,R2             YES. GO SET UP SEARCH ID             41600020
         BH    ENBLK030            NO. LAST ONE HAS BEEN WRITTEN. GET   41700020
*                                  ANOTHER TRACK                        41800020
         CLC   DMPEND+N3(N4),DSCUPPLM THERE IS SPACE FOR 1 MORE RECORD  41900020
*                                  IS THIS THE LAST TRACK IN EXTENT.    42000020
         BCR   FOUR,R2             NO. GO SET UP SEARCH ID FOR RECORD.  42100020
         CLI   DKEYLEN,ZERO        YES. IS END OF FILE BEING WRITTEN    42200020
*                                  IF NOT,SPACE REQUESTED FOR NEW ENTRY 42300020
         LA    RB,C24              SET RETURN CODE IN CASE OF ERROR     42400020
         BCR   N7,RD               PASSWORD DATA SET IS FULL            42500020
         BR    R2                  USE COUNT FIELD FROM PREVIOUS WRITE  42600020
ENBLK030 LA    RWK9,ONE(RWK9)      ADD ONE TRACK TO CURRENT TT FIELD    42700020
         LR    RP0,RWK9            REG 0=TTRN  PRIOR TO CONVERTING      42800020
         SLL   RP0,N16             TTRN REFLECTS-RECORD NO. ZERO        42900020
         LA    RWK7,CVTPCNVT-CVT   OFFSET OF CONVERT ROUTINE IN CVT     43000020
         BAL   RA,CONV010          CONVERT TTR TO MBBCCHHR              43100020
         MVC   DXDEBECC(N4),DCNT   MOVE CONVERTED TTR TO DEB TO         43200020
*                                  USE AS UPPER EXTENT FOR SEARCHES     43300020
ENBLK040 EX    ZERO,MOVCNT         MOVE COUNT TO IOB SEEK FIELD         43400020
         IC    RA,DRECNO           GET CURRENT RECORD NUMBER            43500020
         LA    RA,ONE(RA)          UPDATE RECORD NUMBER BY ONE          43600020
         STC   RA,DRECNO           PUT IN COUNT FIELD FOR WRITE C-K-D   43700020
         STC   RA,DSCLSTAR+N2      SAVE CURRENT RECORD COUNT            43750020
         CLI   DKEYLEN,ZERO        KEY LENGTH ZERO INDICATING EOF       43800020
         BCR   N8,RC               IF YES, DO NOT UPDATE TTR FOR DSCB   43900020
         STH   RWK9,DSAVT          SAVE TT PORTION OF TTR               44000020
         STC   RA,DSAVT+N2         SAVE R PORTION OF TTR                44100020
         BR    RC                  RETURN                               44200020
         EJECT                                                          44300020
*                                                                       44400020
*        PROTECTION MODE ANALYSIS- THIS ROUTINE USES THE PROTECTION     44500020
*        CODE SPECIFIED IN THE INPUT PARAMETER LIST TO CREATE THE       44600020
*        CORRECT PROTECTION MODE BYTE FOR THE PASSWORD BEING ADDED      44700020
*        OR REPLACED. IF THE PASSWORD IS A CONTROL PASSWORD, INDICATORS 44800020
*        ARE SET TO UPDATE THE DSCB WITH REQUESTED PROTECTION.          44900020
*                                                                       45000020
BLDMD010 CLI   PCODE,PCOD0         IS DEFAULT PROTECTION REQUESTED      45100020
         BNE   BLDMD020            IF NOT,CONVERT TO PROTECT MODE       45200020
         CLI   ENCODE,REPLACE      IS THIS A REPLACE WITH DEFAULT MODE  45300020
         BE    BLDMD035            USE EXISTING MODE IF REPLACE         45400020
         CLI   DPMODE,CTLPW        IS THIS A CONTROL PASSWORD ADD       45500020
         BNE   BLDMD050            USE CONTROL P/W MODE AS DEFAULT      45600021
         OI    DPMODE,PCOD3        IF CONTROL BEING ADDED, USE (03)     45700020
         B     BLDMD025            GO TO SET UPDATE FLAGS               45800020
BLDMD020 OC    DPMODE(N1),PCODE    USE CODE TO MASK REQUESTED OPTIONS   45900020
         TM    DPMODE,CTLPW        IS THIS A CONTROL PASSWORD ENTRY     46000020
         BNO   BLDMD030            IF NOT DSCB UPDATE IS NOT REQUIRED   46100020
BLDMD025 OI    DFLAG1,DSCBP3       SET  FOR DSCB UPDATE-PROTECTED       46200020
         TM    DPMODE,PCOD3        IS NOPWREAD/PWWRITE REQUESTED        46300020
         BNO   BLDMD030            IF NOT DO NOT RESET FLAGS            46400020
         OI    DFLAG1,DSCBP5       YES-SET DSCB FLAG-NOPWREAD           46500020
BLDMD030 NI    DPMODE,CTLPW+RDWRT  CONVERT MASK TO PROTECT MODE         46600020
         BR    RC                  RETURN                               46700020
BLDMD035 NI    DFLAG1,HFF-DSNUPDAT TURN OFF DSCB UPDATE INDICATOR       46800020
BLDMD040 IC    RA,DMODE            FOR REPLACE, GET EXISTING MODE       46900021
BLDMD050 STC   RA,DPMODE           SAVE MODE FOR INSERTION IN ENTRY     47000020
*                                  DURING DATA BUILD ROUTINE            47100020
         BR    RC                  RETURN                               47200020
         EJECT                                                          47300020
*                                                                       47400020
*        DATA AREA BUILD ROUTINE                                        47500020
*        THIS ROUTINE CREATES AN 80 BYTE DATA FIELD FOR A PASSWORD      47600020
*        ENTRY. THE FIELD MAY CONSIST OF BLANKS IF A NULL STRING WAS    47700020
*        SPECIFIED OR IF THE ROUTINE IS ENTERED TO BUILD A DELETED      47800020
*        ENTRY.                                                         47900020
*                                                                       48000020
BLDEN010 XR    RA,RA               CLEAR BYTE REGISTER FOR MOVE         48100020
         L     RB,STRING           STRING COUNT AND POINTER             48200020
         SLDA  RA,N8               SET UP STRING LENGTH IN REGISTER RA  48300020
*                                  BY SHIFT OF LENGTH/ADDRESS IN REG RB 48400020
         BNZ   BLDEN020            IF STRING EXISTS,MOVE IT             48500020
         CLI   ENCODE,REPLACE      IS REPLACE SPECIFIED WITHOUT STRING  48600020
         BE    BLDEN030            DEFAULT TO USE OF EXISTING FIELD     48700020
BLDEN020 EQU   *                   ADD OR DELETE IS SPECIFIED           48800020
         MVI   DAT77,BLANK         CLEAR WITH BLANKS                    48900020
         MVC   DAT77+N1(HSTR-N1),DAT77 CLEAR BUFFER FOR ALL ENTRIES     49000020
         SRA   RB,N8               ADJUST STRING POINTER TO ADDRESS     49100020
         BZ    BLDEN030            TEST FOR NULL STRING                 49200020
         LR    R2,RB               SAVE STRING POINTER                  49300020
         LTR   RA,RA               TEST LENGTH                          49400020
         LA    RB,C16              SET RETURN CODE IN CASE OF ERROR     49500020
         BCR   N8,RD               ZERO LENGTH IS AN ERROR              49600020
         BCTR  RA,ZERO             DECREMENT LENGTH FOR EXECUTE         49700020
         EX    RA,MOVSTR           MOVE STRING TO DATA BUFFER           49800020
BLDEN030 IC    RA,DPMODE           PLACE PROTECTION MODE                49900020
         STC   RA,DMODE            IN PROTECTION MODE FIELD             50000020
         BR    RC                  RETURN                               50100020
         EJECT                                                          50200020
*        THIS ROUTINE PROVIDES LINKAGE TO THE RESIDENT DATA             50300020
*        MANAGEMENT CONVERT ROUTINES.                                   50400020
*        CONVERT ROUTINES                                               50500020
*                                                                       50600020
*              MBBCCHHR TO TTR CONVERSION                               50700020
*        INPUT                                                          50800020
*        LOCATION (DMBB) MUST CONTAIN A VALUE-MBBCCHHR                  50900020
*        REGISTER RWK7 MUST CONTAIN OFFSET IN CVT OF CONVERT ROUTINE    51000020
*                                                                       51100020
*        OUTPUT                                                         51200020
*              REGISTER RP0 CONTAINS THE VALUE TTRN                     51300020
*                                                                       51400020
*              TTR TO MBBCCHHR CONVERSION                               51500020
*        INPUT                                                          51600020
*        REGISTER RP0 MUST CONTAIN A VALUE-TTRN                         51700020
*        REGISTER RWK7 MUST CONTAIN OFFSET IN CVT OF CONVERT ROUTINE    51800020
*                                                                       51900020
*        OUTPUT                                                         52000020
*              LOCATION (DMBB) CONTAINS THE CONVERTED VALUE             52100020
*                                                                       52200020
CONV010  L     RF,CVTPTR           CVT OFFSET                           52300020
         L     RF,ZERO(RWK7,RF)    SET UP BASE FOR CONVERT ROUTINE      52400020
         LA    RP1,DXDEB           DEB ADDRESS                          52500020
         LA    RP2,DMBB            FULL MBBCCHHR ADDRESS                52600020
         STM   RWK9,RD,RNAME       SAVE REGISTERS                       52700020
         BALR  RE,RF               GO TO CONVERT                        52800020
         LM    RWK9,RD,RNAME       RESTORE REGISTERS                    52900020
         BR    RA                  RETURN TO CALLER                     53000020
         EJECT                                                   A43379 53050021
*  CYLINDER BOUNDRY REACHED, SEARCH NOT COMPLETE                 A43379 53060021
*  UPDATE CYLINDER-HEAD ADDRESS AND CONTINUE SEARCH              A43379 53070021
CYLEND   MVC   DCNT(N5),DXDAADDR+N3 MOVE CYLINDER-HEAD ADDRESS   A43379 53080021
         LH    RWK7,DCNT           LOAD CYLINDER COUNT           A43379 53090021
         LA    RWK7,ZERO(RWK7)     UP CYLINDER COUNT             A43379 53092021
         SLL   RWK7,N16            ZERO HEAD ADDRESS             A43379 53094021
         ST    RWK7,DCNT           SAVE UPDATED ADDRESS          A43379 53096021
         EX    ZERO,MOVCNT         SET IOB SEEK FIELD            A43379 53098021
         B     SRCH070             REISSUE I/O                   A43379 53098421
         EJECT                                                          53100020
*                                                                       53200020
*        SEARCH ROUTINE- EXECUTE CHANNEL PROGRAMS TO SEARCH MPDS        53300020
*        THE  IOB,DEB AND CCW LISTS ARE MODIFED FOR EACH REQUEST        53400020
*        PRIOR TO THE EXCP BEING ISSUED.                                53500020
*                                                                       53800020
*        MODIFY CCW LIST TO PERFORM A WRITE KEY-DATA OPERATION          53900020
*                                                                       54000020
*        SEARCH CHANNEL PROGRAM                                         54100020
*                                                                       54200020
*              SEARCH ID EQ                 DXCCW1                      54300020
*              TIC                          DXCCW2                      54400020
*              READ COUNT                   DXCCW3                      54500020
*              SEARCH KEY EQ                DXCCW4                      54600020
*              TIC                          DXCCW5                      54700020
*              READ DATA                    DXCCW6                      54800020
*                                                                       54900020
*        WRITE UPDATE CHANNEL PROGRAM                                   55000020
*                                                                       55100020
*              SEARCH ID EQ                 DXCCW7                      55200020
*              TIC                          DXCCW8                      55300020
*              WRITE CNT-KEY-DATA/KEY-DATA  DXCCW9                      55400020
*              SEARCH ID EQ                 DXCCW10                     55500020
*              TIC                          DXCCW11                     55600020
*              READ DATA (VALIDATE)         DXCCW12                     55700020
*                                                                       55800020
SRCH025  MVI   DXCCW4+N7,NKEYLL    SET KEY LENGTH TO 44                 55900020
         OI    DXCCW4+N4,SLI       SUPPRESS INCORRECT LENGTH    SA69177 55950021
         OI    DXCCW6+N4,SUPDAT+CHAIN TURN ON SKIP AND CHAIN BITS       56000020
SRCH030  MVI   DXCCW9,WTKDAT       WRITE KEY-DATA OP-CODE TO CCW        56100020
         MVI   DXCCW9+N7,ENTLEN    SET CCW FOR WRITE KEY-DATA (132)     56200020
         LA    RWK7,DCNT           ADDRESS OF COUNT FIELD               56300020
         ST    RWK7,DXCCW7         POINT TO THE COUNT FIELD OF          56400020
         ST    RWK7,DXCCW10        RECORD NUMBER TO BE WRITTEN          56500020
         MVI   DXCCW7,SRID         REPLACE OP-CODE SEVENTH CCW          56600020
         MVI   DXCCW10,SRID        REPLACE OP-CODE TENTH CCW            56700020
         TM    DXCCW6+N4,CHAIN     IS CCWLIST SET FOR CONTROL PW DELETE 56800020
         BCR   ONE,RC              YES, RETURN                          56900020
SRCH040  LA    RWK7,DXCCW7         ADDRESS OF SEARCH-ID/UPDATE LIST     57000020
         B     SRCH060             GO TO I/O ROUTINE                    57100020
SRCH020  MVI   DXCCW4+N7,KEYLL     SET KEY LENGTH TO 52 BYTES    A43379 57150021
SRCH050  MVC   DXDAADDR+N3(N4),DSCLOWLM MOVE LOW EXTENT TO IOB FIELD    57200020
SRCH055  LA    RWK7,DXCCW          ADDRESS OF BASIC SEARCH CCWLIST      57300020
SRCH060  ST    RWK7,IOBSIOCC       UPDATE IOB POINTER TO CCW LIST       57400020
*                                                                       57500020
SRCH070  EXCP  DXIOB               ISSUE EXCP                           57600020
*                                                                       57700020
*                                                                       57800020
         WAIT  ECB=DXECB           ISSUE WAIT                           57900020
*                                                                       58000020
*  SLI BIT IS SET IN SEARCH ID EQUAL CCW WHEN LENGTH TO BE      SA69177 58050021
*  SEARCHED IS LESS THAN 52 BYTES.  INCORRECT LENGTH ERROR      SA69177 58060021
*  SHOULD OCCUR WHEN SEARCH IS FOR FULL DATA-SET-NAME-PLUS      SA69177 58080021
*  KEYWORD LENGTH, (52 BYTES), SO SLI BIT IS RESET HERE.        SA69177 58090021
*  I/O ERROR WILL OCCUR IF THE PASSWORD DATA SET DOES NOT HAVE          58096021
*  CORRECT KEYLENGTH.                                                   58098021
         NI    DXCCW4+N4,NOSLI     RESET SLI                    SA69177 58098421
*                                                                       58098821
         TM    DXECB,COMMSK        DID I/0 COMPLETE                     58100020
         BCR   ONE,RC              RETURN TO CALLER - SUCCESSFUL I/O    58170020
         TM    DXECB,EXTMSK        WAS END OF EXTENT REACHED            58240020
         BNO   EXCPCOND            NO, CHECK FOR EXCEPTIONAL CONDITION  58310020
         LA    RC,FOUR(RC)         YES, SET FOR RETURN, POSSIBLE ERROR  58380020
         BR    RC                  RETURN                               58450020
EXCPCOND CLI   DXECB,EOFCK1        IS THERE AN EXCEPTIONAL CONDITION    58520020
         BNE   ERET040             IF NOT, ASSUME PERMANENT ERROR       58590020
         CLI   IOBSTAT0,EOFCK2     ON EXCEPTION, IS IT FOR EOD          58700020
         BCR   EQ,RC               EXPECTED FOR EOD-RETURN              58800020
         TM    IOBSTAT0,UNITCHCK   UNIT CHECK                    A43379 58850021
         BNO   ERET040             NO, THEN I/O ERROR            A43379 58860021
         TM    IOBSENS1,CYLINDER   CYLINDER END                  A43379 58870021
         BO    CYLEND              YES, CONTINUE                 A43379 58880021
*                                                                       58900020
*        PERMANENT ERROR CONDITION EXISTS                               59000020
*                                                                       59100020
         EJECT                                                          59200020
*                                                                       59300020
*                                                                       59400020
*        ERROR EXIT- ENTERED WHEN AN ERROR CONDITION HAS BEEN DETECTED  59500020
*        IN IGC0009H OR IGC0109H.                                       59600020
*              ERROR CODE IS IN REGISTER RB ON ENTRY TO ERET010         59700020
*              ADDITIONAL ENTRY POINTS ARE PROVIDED FOR SPECIFIC        59800020
*              ERROR CONDITIONS TO PROVIDE THE ERROR CODE.              59900020
*                                                                       60000020
ERET040  LA    RB,C20              I/O ERROR IN PASSWORD DATA SET       60100020
         BR    RD                  GO TO EXIT                           60200020
ERET010  LA    RB,C4               REQUESTED PASSWORD ALREADY EXISTS    60300020
         BR    RD                  GO TO EXIT                           60400020
ERET020  LA    RB,C8               REQUESTED ENTRY NOT FOUND            60500020
ERETEND  NI    DFLAG1,HFF-(MPUPDAT+DSNUPDAT) NO DSCB UPDATE ON ERROR    60600020
         B     RET020              GO DEQUEUE VIA NORMAL EXIT           60700020
DELC040  CLC   DREPSAV+HLEN(N5),DCNT WAS THE LAST DELETE FOR     A43379 60750021
*                                  THE CONTROL ENTRY.            A43379 60760021
         BNE   DELC050             NO, GO SET IOB SEEK FIELD     A43379 60770021
*                                                                       60800020
*        EXIT ROUTINE                                                   60900020
*        ENTERED PRIOR TO XCTL TO IGC0209H OR ON RETURNING UNDER        61000020
*        NORMAL OR ERROR CONDITIONS TO PERFORM DEQUEUES.                61100020
*                                                                       61200020
RET010   XR    RB,RB               CLEAR RETURN CODE TO ZERO            61300020
*        DETERMINE HOW MANY DEQUEUES MUST BE DONE PRIOR TO EXIT.        61400020
RET020   LA    RP1,DENQLST         POINT TO DEQUEUE LIST                61500020
         TM    DFLAG1,ENQF         WERE ANY ENQUEUES DONE IN IGC0009H   61600020
         BNO   RET050              IF NOT INDICATED SKIP DEQUEUES       61700020
         CLI   ENCODE,ADD          ADD SPECIFIED                        61800020
         BNE   RET040              DO SINGLE DEQUEUE ON DSN             61900020
         TM    DFLAG1,MPUPDAT+MPENQ DETERMINE HOW MANY DEQUEUES NEEDED  62000020
         BO    RET050              ENQ WAS DONE TO PROTECT THE MPDS,    62100020
*                                  DO THE DEQUEUE IN THE FINAL LOAD     62200020
         BM    RET040              IF ERROR EXISTS, ENQ IS ON MPDS,     62300020
*                                  IF THIS IS NOT AN ERROR, MPDS DEQ    62400020
*                                  MUST BE DONE IN THE FINAL LOAD AFTER 62500020
*                                  THE DSCB IS UPDATED.                 62600020
*                                  CODE IS ZERO, BOTH DEQUEUES REQUIRED 62700020
*                                                                       62800020
*        DEQUEUE ON PASSWORD DATA SET                                   62900020
*                                                                       63000020
         DEQ   MF=(E,(1))          DEQUEUE                              63100020
         LA    RP1,DENQLST         POINT TO DEQUEUE LIST                63200020
RET040   LA    RWK9,DKEY           DATA SET NAME FROM KEY FIELD         63300020
         ST    RWK9,DENQLST+N8     DSNAME TO DEQUEUE LIST               63400020
*        DEQUEUE ON DATA SET ENTRY IN PASSWORD DATA SET                 63500020
         DEQ   MF=(E,(1))          DEQUEUE                              63600020
*                                                                       63700020
*        EXIT IS MADE TO THE THIRD LOAD (IGC0209H) TO PERFORM           63800020
*        UPDATING OF DSCBS OR TO CLEAN UP AND RETURN TO CALLER.         63900020
*        A NON-ZERO RETURN CODE IS IN REGISTER RB IF AN ERROR           64000020
*        CONDITION EXISTS. ON A NORMAL EXIT TO IGC0209H, FLAGS          64100020
*        ARE SET IN (DFLAG1) TO INDICATE DSCB UPDATING IF REQUIRED.     64200020
*                                                                       64300020
*        NORMAL EXIT IF DSCB UPDATING IS REQUIRED                       64400020
*        THE XCTL PARAMETER LIST ADDRESS IS IN REGISTER RD              64500020
*                                                                       64600020
RET050   LA    RD,DXJBF            XCTL PARAMETER LIST ADDRESS          64700020
         MVI   N4(RD),GC209        MODIFY LIST TO (IGC0209H)            64800020
         LA    RF,N8(RD)           ADDRESS OF LIST POINTER FOR XCTL     64900020
*                                                                       65000020
*        XCTL  TO NEXT LOAD OF SVC 98                                   65100020
*                                                                       65200020
         XCTL  EPLOC=(RD),DCB=0,SF=(E,(15)) XCTL                        65300020
         EJECT                                                          65400020
*        CONSTANTS                                                      65500020
MOVCNT   MVC   DXDAADDR+N3(N5),DCNT MOVE COUNT TO IOB SEEK FIELD        65600020
MOVPW    MVC   DKEY8(N8),ZERO(R2)  MOVE PASSWORD TO KEY FIELD           65700020
MOVSTR   MVC   DAT77(ZERO),ZERO(R2) MOVE DATA STRING TO BUFFER          65800020
         EJECT                                                          65900020
*        THIS WORK AREA IS USED BY ALL LOADS OF THE PROTECT SVC.        66000020
*        ANY CHANGES TO IT MUST BE MADE TO ALL LOADS.                   66100020
*                                                                       66200020
WORKD    DSECT                                                          66300020
*                                                                       66400020
         IECDSECT                                                       66500020
CLEARIO  EQU   *-DXECB             LENGTH FOR CLEARING I/O BLOCKS       66600020
*                                                                       66700020
COMMD    EQU   *                   CONTINUE DSECT                       66800020
*                                                                       66900020
*        WORK AREA FOR MPDS COMMUNICATION AND BUFFERING                 67000020
*        A CONTINUATION OF DSECT (WORKD)                                67100020
*                                                                       67200020
*                                                                       67300020
DSAVR    DS    F                   SAVE AREA FOR RETURN REGISTER        67400020
DSAVT    DS    F                   MPDS LAST BLOCK SAVE AREA            67500020
DUCBADDR DS    F                   ADDRESS OF UCB LOOKUP TABLE          67600020
DPMODE   DS    CL1                 PROTECTION MODE BYTE SAVE AREA       67700020
DRECAP   DS    CL1                 SYSRES DEVICE-RECORD/TRK CAPACITY    67800020
DCODTAB  DS    CL1                 ENTRY CODE SAVE AREA FOR NEXT LOAD   67900020
*                                                                       68000020
*        DFLAG - COMMUNICATES STATUS OF DSCB UPDATING REQUIREMENTS      68100020
*                                                                       68200020
DFLAG1   DS    BL1                 COMMUNICATION FLAG                   68300020
*        COMMUNICATION FLAG (DFLAG1) IN COMMD WORK AREA                 68400020
*              1 BYTE  (DFLAG1)                                         68500020
*                   BIT  0  =1 MPDS IS ENQ TO ADD OWN P/W PROTECTION    68600020
*                        1  =1 INDICATES I/O ERROR                      68700020
*                        2  =1 INDICATES ENQUEUED IN 1ST - 2ND LOADS    68800020
*                        3  =1 PROTECTED DATA SET-SET BIT 3 IN DSCB     68900020
*                        4  =1 OBTAIN WORKAREA TO BE FREED              69000020
*                        5  =1 NO PASSWORD TO READ-SET BIT 5 IN DSCB    69100020
*                        6  =1 UPDATE DSCB OF DATA SET WITH PROTECTION  69200020
*                              SPECIFIED IN BITS 3 AND 5                69300020
*                        7  =1 UPDATE MPDS DSCB FROM CORE IMAGE IN      69400020
*                              WORK AREA (WORKD) AND DEQ ON MPDS        69500020
*                                                                       69600020
DFLAG2   DS    BL1                 COMMUNICATION FLAG                   69700020
*              1 BYTE (DFLAG2)                                          69800020
*                   BIT 0     RESERVED                                  69900020
*                   BIT 1  =1 INDICATES NEW PASSWORD WITH REPLACE       70000020
*                   BIT 2     RESERVED                                  70100020
*                   BIT 3     RESERVED                                  70200020
*                   BIT 4     RESERVED                                  70300020
*                   BIT 5     RESERVED                                  70400020
*                   BIT 6     RESERVED                                  70500020
*                   BIT 7     RESERVED                                  70600020
*                                                                       70700020
         DS    0CL11               COUNT FIELD FOR I/O                  70800020
DMPEND   DS    CL8                 MBBCCHHR OF LAST RECORD WRITTEN      70900020
DCKDLL   DS    CL3                 KEY LENGTH/DATA LENGTH               71000020
*                                                                       71100020
*        EXCP BUFFER  AREA FOR COUNT KEY DATA READ/WRITE                71200020
*                                                                       71300020
         DS    0F                  ALIGN WORD                           71400020
         DS    CL1                 ALIGN FOR MBBCCHHR                   71500020
DMBB     DS    CL3                 MBB FIELD FOR CONVERT ROUTINE        71600020
         DS    0CL8                COUNT FIELD FOR I/O                  71700020
DCNT     DS    CL4                 CCHH PORTION OF COUNT                71800020
DRECNO   DS    CL1                 RECORD NUMBER                        71900020
DKEYLEN  DS    CL1                 KEY LENGTH FOR FOR WRITE             72000020
DDATALEN DS    CL2                 DATA LENGTH FOR WRITE                72100020
DKEY     DS    CL44                EXCP- 44 BYTE KEY (DSN)              72200020
DKEY8    DS    CL8                 EXCP- 8 BYTE EXTENSION (PASSWORD)    72300020
DATA     DS    0CL80               DATA FIELD                           72400020
DUSE     DS    CL2                 USE COUNT                            72500020
DMODE    DS    BL1                 PROTECTION MODE BYTE FIELD           72600020
DAT77    DS    CL77                USER DATA (77 BYTES OPTIONAL DATA)   72700020
DSAVLL   EQU   *-DCNT              COUNT-KEY-DATA FIELD LENGTH          72800020
DCLEAR   EQU   *-COMMD             WORK AREA TO BE CLEARED TO ZERO      72900020
DFOXKEY  DS    52C                 52 BYTE KEY OF FF                    73000020
         DS    80C                 80 BYTE DATA FIELD                   73100020
*                                                                       73200020
*        OBTAIN LIST                                                    73300020
*                                                                       73400020
OBTPTR   CAMLST SEARCH,OBTDSN,OBTVOL,OBTWRK                             73500020
         ORG   OBTPTR              LABEL OBTAIN FIELDS                  73600020
OBTAIN1  DS    F                   OBTAIN CAMLST FIRST FULL WORD        73700020
OBTAIN2  DS    F                   OBTAIN CAMLST SECOND FULL WORD       73800020
OBTAIN3  DS    F                   OBTAIN CAMLST THIRD FULL WORD        73900020
OBTAIN4  DS    F                   OBTAIN CAMLST FOURTH FULL WORD       74000020
         ORG                                                            74100020
*                                                                       74200020
*        ENQUEUE PARAMETER LIST                                         74300020
*                                                                       74400020
DENQLST  ENQ   (DMPDSQN,DMPDS,E,HLEN,SYSTEM),MF=L                       74500020
*        NAME LIST FOR ENQUEUE/DEQUEUE AND OBTAIN                       74600020
DMPDSQN  DS    0CL52               ONE FIELD FOR SETTING UP IN WORKD    74700020
         DS    CL8                 QNAME                                74800020
DMPDS    DS    CL44                RNAME                                74900020
OBTDSN   EQU   DMPDS               DSNAME OF MASTER PASSWORD DATA SET   75000020
OBTVOL   DS    CL6                 VOLUME SERIAL OF MPDS DSCB VOLUME    75100020
DREPSAV  DS    CL140               SAVEAREA FOR PASSWORD ENTRY          75200020
LOCNAME  CAMLST NAME,DKEY,,LOCAREA LOCATE CAMLST MACRO                  75300020
         ORG   LOCNAME             LABEL LOCATE CAMLST FIELDS           75400020
LOCNAME1 DS    F                   1ST WORD LOCATE CAMLST               75500020
LOCNAME2 DS    F                   2ND WORD LOCATE CAMLST               75600020
LOCNAME3 DS    F                   3RD WORD LOCATE CAMLST               75700020
LOCNAME4 DS    F                   4TH WORD LOCATE CAMLST               75800020
         ORG                                                            75900020
USECOUNT DS    F                   SAVE POINTER TO USER COUNT HERE      76000020
*  KEEP ENQ AND DEQ LISTS TOGETHER.                                     76050020
ENQLIST  ENQ   (QNAME,RNAME,E,RNLENGTH,SYSTEM),RET=USE,MF=L ENQUEUE     76100020
DEQLIST  DEQ   (QNAME,RNAME,RNLENGTH,SYSTEM),RET=HAVE,MF=L DEQUEUE      76150020
*  NOTE - MFT ENQUEUE WITH QNAME EQUAL TO SYSDSN REQUIRES TCB           76160020
*         ADDRESS IMMEDIATELY FOLLOWING QNAME.                          76170020
QNAME    DS    CL8                 QNAME BUFFER                         76200020
TCBADDR  DS    F                   TCB ADDRESS FOR MFT ENQUEUE          76250020
RNAME    DS    CL44                RNAME BUFFER                         76300020
OLDFLAG  DS    CL1                 OLD PROTECTION STATUS                76400020
NEWFLAG  DS    CL1                 NEW PROTECTION STATUS                76500020
WKSIZE   EQU   *-WORKD             SIZE OF PROGRAM WORKAREA             76600020
*                                                                       76700020
*        END OF MAPPING OF DSECT WORKAREA                               76800020
         EJECT                                                          76900020
PARMD    DSECT                                                          77000020
*                                                                       77100020
*              PARAMETER LIST FOR ALL REQUESTS                          77200020
*                                                                       77300020
*                                                                       77400020
*              COMMON  SEGMENT FOR ALL REQUESTS                         77500020
*                                                                       77600020
ENCODE   DS    0BL1                ENTRY CODE                           77700020
DBUF     DS    CL4                 ADDRESS OF BUFFER FOR CODE 04/05     77800020
DSNLL    DS    0CL1                DSN LENGTH                           77900020
DSN      DS    CL4                 ADDRESS OF DATA SET NAME             78000020
CURRENT  DS    CL4                 ADDRESS OF CURRENT PASSWORD          78100020
*                                                                       78200020
*              ADD / REPLACE / DELETE COMMON SEGMENT                    78300020
*                                                                       78400020
CONTROL  DS    CL4                 ADDRESS OF CONTROL PASSWORD          78500020
VOLNUM   DS    0CL1                NUMBER OF VOLUMES SPECIFIED          78600020
VOLIST   DS    CL4                 ADDRESS OF VOLUME LIST               78700020
*                                                                       78800020
*              ADD / REPLACE  COMMON SEGMENT                            78900020
*                                                                       79000020
PCODE    DS    0BL1                PROTECTION CODE                      79100020
NEW      DS    CL4                 ADDRESS OF NEW PASSWORD              79200020
STRINGL  DS    0CL1                STRING LENGTH                        79300020
STRING   DS    CL4                 ADDRESS OF DATA STRING               79400020
*                                                                       79500020
         EJECT                                                          79600020
*                                                                       79700020
WRKSPACE DSECT                                                          79800020
*                                                                       79900020
*  OBTAIN WORKAREA AND LOCATE WORKAREA                                  80000020
*                                                                       80100020
OBTWRK   DS    CL96                DSCB                                 80200020
OBTCCH   DS    CL5                 CCHHR                                80300020
         DS    CL249               OBTAIN WORK SPACE                    80400020
         DS    0D                  ALIGN LOCATE WORKAREA                80500020
LOCAREA  DS    CL265               LOCATE WORK SPACE (VOLUME LIST)      80600020
WRKSIZE  EQU   *-WRKSPACE          SIZE OF LOCATE AND OBTAIN WORKAREA   80700020
*                                                                       80800020
         EJECT                                                          80900020
SRT      DSECT                                                          81000020
         IEFUCBOB                                                       81100020
         EJECT                                                          81200020
CVT      DSECT                                                          81300020
         CVT                                                            81400020
         END                                                            81500020
