   TITLE 'IGC0209H SVC 98 (PROTECT) THIRD LOAD - DSCB UPDATE ROUTINE'   00100020
IGC0209H CSECT                                                          00300020
*A 123500-123700,161500-161700,228500-229000,347500-347600,     SA53652 00310021
*A 379100-379200,374500                                         SA53652 00320021
*C 153000,162000                                                SA53652 00330021
*A 286900-287000                                                 A42339 00350021
*********************************************************************** 00400020
*                                                                     * 00500020
* STATUS -- CHANGE LEVEL 01                                      A42339 00600021
*                                                                     * 00700020
* FUNCTION -- THIRD LOAD OF THE PASSWORD DATA SET MAINTAINENCE ROUTINE* 00800020
*    1. UPDATE PASSWORD DATA SET DSCB IF NECESSARY                    * 00900020
*    2. UPDATE THE DSCB OF THE DATA SET BEING PROTECTED WHENEVER THE  * 01000020
*    CONTROL PASSWORD PROTECTION STATUS IS CHANGED                    * 01100020
*    3. CLEANUP AND RETURN                                            * 01200020
*                                                                     * 01300020
* ENTRY POINTS --                                                     * 01400020
*         IGC0209H - ENTRY POINT OF THIRD LOAD, ENTERED BY XCTL FROM  * 01500020
*    SECOND LOAD (IGC0109H)                                           * 01600020
*                                                                     * 01700020
* INPUT --                                                            * 01800020
*    REGISTER R5 POINTS TO WORK AREA                                  * 01900020
*    REGISTER R4 POINTS TO INPUT PARAMETER LIST                       * 02000020
*    REGISTER R11 CONTAINS RETURN CODE FROM PREVIOUS LOADS OF SVC 98  * 02100020
*                                                                     * 02200020
* OUTPUT --                                                           * 02300020
*    REGISTER R15 PASSES RETURN CODE                                  * 02400020
*    REGISTER R0 CONTAINS NUMBER OF INDEXES SEARCHED WHEN R15 = 32    * 02500020
*    REGISTER R1 CONTAINS LOCATE RETURN CODE WHEN R15 = 32            * 02600020
*    REGISTER R1 CONTAINS OBTAIN RETURN CODE WHEN R15 = 36            * 02700020
*    WHEN REGISTER R15 = 24 THE FOLLOWING MESSAGE IS SENT TO THE      * 02800020
*    CONSOLE OPERATOR - 'IEC021I NO SPACE IN PASSWORD DATA SET'       * 02900020
*                                                                     * 03000020
* EXTERNAL REFERENCES -- N/A                                          * 03100020
*                                                                     * 03200020
* EXITS, NORMAL -- RETURN TO CALLER                                   * 03300020
*                                                                     * 03400020
* EXITS, ERROR -- RETURN TO CALLER WITH NON-ZERO RETURN CODE          * 03500020
*    32  LOCATE FAILED                                                * 03600020
*    36  OBTAIN FAILED                                                * 03700020
*    40  UNABLE TO UPDATE DSCB                                        * 03800020
*    48  TAPE DATA SET CAN NOT BE PROTECTED                           * 03900020
*    52  DATA SET IN USE                                              * 03950020
*    RETURN CODES 4, 8, 12, 16, 20, 24, AND 44 MAY BE PASSED FROM     * 04000020
*    PREVIOUS LOADS OF SVC 98                                         * 04100020
*                                                                     * 04200020
* TABLES/WORK AREAS --                                                * 04300020
*    WORKD - A CONTIGUOUS AREA DEFINED BY IECDSECT FOR I/O CONTROL    * 04400020
*    BLOCKS FOLLOWED BY A LOCAL WORK AREA FOR COMMUNICATION AND       * 04500020
*    BUFFER SPACE                                                     * 04600020
*    PARMD - A DSECT TO MAP THE INPUT PARAMETER LIST                  * 04700020
*    WRKSPACE - A DSECT TO MAP THE LOCATE AND OBTAIN WORKAREAS        * 04800020
*                                                                     * 04900020
* ATTRIBUTES -- REENTRANT, READ ONLY, PRIVILIGED, ENABLED             * 05000020
*                                                                     * 05100020
* CHARACTER CODE DEPENDENCY -- CHARACTER CODE INDEPENDENT             * 05200020
*                                                                     * 05300020
* NOTES -- N/A                                                        * 05400020
*                                                                     * 05500020
*********************************************************************** 05600020
         EJECT                                                          05700020
*  REGISTER EQUATES                                                     05800020
R0       EQU   0                   GENERAL REGISTER 0                   05900020
R1       EQU   1                   GENERAL REGISTER 1                   06000020
R2       EQU   2                   GENERAL REGISTER 2 (UNUSED)          06100020
R3       EQU   3                   GENERAL REGISTER 3                   06200020
R4       EQU   4                   GENERAL REGISTER 4                   06300020
R5       EQU   5                   GENERAL REGISTER 5                   06400020
R6       EQU   6                   GENERAL REGISTER 6                   06500020
R7       EQU   7                   GENERAL REGISTER 7                   06600020
R8       EQU   8                   GENERAL REGISTER 8                   06700020
R9       EQU   9                   GENERAL REGISTER 9                   06800020
R10      EQU   10                  GENERAL REGISTER 10                  06900020
R11      EQU   11                  GENERAL REGISTER 11                  07000020
R12      EQU   12                  GENERAL REGISTER 12                  07100020
R13      EQU   13                  GENERAL REGISTER 13                  07200020
R14      EQU   14                  GENERAL REGISTER 14                  07300020
R15      EQU   15                  GENERAL REGISTER 15                  07400020
*  ABSOLUTE EQUATES (OFFSETS AND SHORT LENGTHS)                         07500020
ONE      EQU   1                   ONE                                  07600020
TWO      EQU   2                   TWO                                  07700020
F0       EQU   0                   ZERO                                 07800020
F1       EQU   1                   ONE                                  07900020
F2       EQU   2                   TWO                                  08000020
F3       EQU   3                   THREE                                08100020
F4       EQU   4                   FOUR                                 08200020
F5       EQU   5                   FIVE                                 08300020
F6       EQU   6                   SIX                                  08400020
F7       EQU   7                   SEVEN                                08500020
F8       EQU   8                   EIGHT                                08600020
F10      EQU   10                  TEN                                  08700020
F12      EQU   12                  TWELVE                               08800020
F16      EQU   16                  SIXTEEN                              08900020
F20      EQU   20                  TWENTY                               09000020
F43      EQU   43                  FORTY-THREE                          09100020
F77      EQU   77                  SEVENTY-SEVEN (USER DATA LENGTH)     09200020
F96      EQU   96                  NINETY-SIX                           09300020
L72      EQU   72                  LENGTH OF SAVEAREA                   09400020
*  RETURN CODE EQUATES                                                  09500020
RC4      EQU   4                   RETURN CODE = 4                      09600020
RC8      EQU   8                   RETURN CODE = 8                      09700020
RC12     EQU   12                  RETURN CODE = 12                     09800020
RC16     EQU   16                  RETURN CODE = 16                     09900020
RC20     EQU   20                  RETURN CODE = 20                     10000020
RC24     EQU   24                  RETURN CODE = 24                     10100020
RC28     EQU   28                  RETURN CODE = 28                     10200020
RC32     EQU   32                  RETURN CODE = 32                     10300020
RC36     EQU   36                  RETURN CODE = 36                     10400020
RC40     EQU   40                  RETURN CODE = 40                     10500020
RC44     EQU   44                  RETURN CODE = 44                     10600020
RC48     EQU   48                  RETURN CODE = 48                     10700020
RC52     EQU   52                  RETURN CODE = 52                     10730020
*  OTHER EQUATES                                                        10760020
MPUPDAT  EQU   X'01'               MASK TO TEST FOR MPDS UPDATE         10800020
DSNUPDAT EQU   X'02'               MASK TO TEST FOR PROTECTION UPDATE   10900020
DA2321   EQU   X'05'               2321 DATA CELL                       11000020
OPREAD   EQU   X'06'               READ DATA OP CODE                    11100020
OPWRITE  EQU   X'05'               WRITE DATA OP CODE                   11200020
OBTNCORE EQU   X'08'               OBTAIN CORE TO BE FREED              11300020
CHAIN    EQU   X'40'               CHAIN DATA FLAG                      11400020
GOODIO   EQU   X'20'               MASK TO TEST FOR SUCCESSFUL I/O      11500020
SRCHID   EQU   X'31'               SEARCH ID EQUAL OP CODE              11600020
FLAGOFF  EQU   X'14'               MASK TO TURN OFF ALL BUT BITS 3,5    11700020
NOPROT   EQU   X'EB'               MASK TO TURN OFF BITS 3,5            11800020
NOSEEK   EQU   X'18'               FILE MASK-NOSEEK                     11900020
IOERR    EQU   X'40'               MASK TO SET I/O ERROR INDICATOR      12000020
DSCBP3   EQU   X'10'               MASK TO SET PROTECTION BYTE BIT 3    12100020
DSCBP5   EQU   X'04'               MASK TO SET PROTECTION BYTE BIT 5    12200020
BLANK    EQU   C' '                BLANK                                12300020
SWON     EQU   X'FF'               MASK SWITCH ON               SA53652 12350021
SWOFF    EQU   X'00'               MASK SWITCH OFF              SA53652 12360021
F252     EQU   252                 OFF SET TO TTR               SA53652 12370021
RNLENGTH EQU   8                   LENGTH OF RNAME FOR ENQUEUE ON DSCB  12400020
HLEN     EQU   44                  DSNAME LENGTH FOR ENQUEUE            12500020
DSCBDLL  EQU   96                  DSCB DATA FIELD LENGTH               12600020
         EJECT                                                          12700020
         BALR  R12,R0              GET ADDRESS WHERE LOADED             12800020
         USING *,R12               ESTABLISH ADDRESSABILITY FOR PROGRAM 12900020
         USING PARMD,R4            ESTABLISH ADDRESSABILITY PARMLIST    13000020
         USING WORKD,R5            ESTABLISH ADDRESSABILITY FOR DSECT   13100020
         L     R13,OBTAIN4         ADDRESS OF OBTAIN WORKAREA           13200020
         USING WRKSPACE,R13        ESTABLISH ADDRESSABILITY WORKAREA    13300020
         LTR   R11,R11             IS RETURN CODE REGISTER = 0          13400020
         BNZ   CHECKRC             NO, GO CHECK RETURN CODE             13500020
         MVC   ENQLIST(ENQLEND-ENQL),ENQL INITIALIZE ENQ AND DEQ LISTS  13600020
         MVC   QNAME(F8),QNME      INITIALIZE QNAME                     13700020
         LA    R1,ENQLIST          POINT TO ENQUEUE PARAMETER LIST      13800020
         LA    R8,DEQLIST          POINT TO DEQUEUE PARAMETER LIST      13850020
         LA    R9,QNAME            ADDRESS OF QNAME                     13900020
         ST    R9,F4(R1)           SECOND WORD ENQUEUE LIST             14000020
         ST    R9,F4(R8)           SECOND WORD DEQUEUE LIST             14050020
         LA    R9,RNAME            ADDRESS OF RNAME                     14100020
         ST    R9,F8(R1)           THIRD WORD ENQUEUE LIST              14200020
         ST    R9,F8(R8)           THIRD WORD DEQUEUE LIST              14250020
         TM    DFLAG1,MPUPDAT      IS UPDATE OF PASSWORD DS REQUIRED    14300020
         BO    UPDATE              YES, GO UPDATE DSCB                  14400020
         B     DSFLAG              GO SEE IF DATA SET IS TO BE FLAGGED  14500020
*  NOW SET PROTECTION STATUS IN DSCB                                    14600020
SETFLAG  L     R8,VOLIST           LOAD ADDRESS OF USER'S VOLUME LIST   14700020
         LTR   R8,R8               DID USER SUPPLY VOLUME LIST          14800020
         BNZ   USERLIST            YES, GO USE USER'S VOLUME LIST       14900020
*  USER DID NOT SUPPLY VOLUME LIST.  USE LOCATE TO GET VOLUME LIST      15000020
         MVC   LOCNAME(ENDLLIST-LOCLIST),LOCLIST INITIALIZE CAMLST      15100020
         LA    R6,DKEY             POINTER TO DATA SET NAME-            15200020
INITLOC  ST    R6,LOCNAME2         -TO LOCATE CAMLST            SA53652 15300021
         LA    R6,LOCAREA          POINTER TO LOCATE WORKAREA-          15400020
         ST    R6,LOCNAME4         -TO LOCATE CAMLST                    15500020
         LOCATE LOCNAME            ISSUE LOCATE MACRO                   15600020
         LTR   R15,R15             TEST LOCATE RETURN CODE              15700020
         BNZ   LOCERROR            NON-ZERO IS ERROR                    15800020
         CLC   TAPECODE(F2),LOCAREA+F4 IS THIS A TAPE DATA SET          15900020
         BE    TAPE                YES, UNABLE TO FLAG TAPES            16000020
         LH    R10,LOCAREA         VOLUME COUNT                         16100020
         MVI   DMODE,SWOFF         INITIALIZE SWITCH OFF        SA53652 16150021
         CH    R10,TWENTY          TEST VOLUME COUNT            SA53652 16160021
         BH    DOTWENTY            GO PROCESS OVER 20 VOLS.     SA53652 16170021
VOLPOINT LA    R8,LOCAREA+F6       POINT TO FIRST VOLSER        SA53652 16200021
LOOKUP   L     R6,DUCBADDR         ADDRESS OF UCB LOOKUP TABLE          16300020
UCBSRCH  LH    R7,F0(R6)           LOAD UCB ADDRESS                     16400020
         LTR   R7,R7               CHECK UCB TABLE ENTRY                16500020
         BZ    NEXTUCB             IF ZERO, GET NEXT UCB TABLE ENTRY    16600020
         BM    VOLNTMTD            IF MINUS, VOLUME NOT MOUNTED         16800020
         USING SRT,R7              ESTABLISH ADDRESSABILITY UCB         16900020
         CLI   UCBTBYT3,UCB3DACC   IS THIS A DIRECT ACCESS DEVICE       17000020
         BE    CHK2321             YES, GO CHECK FOR 2321               17100020
         CLI   UCBTBYT3,UCB3TAPE   IS THIS A TAPE DATA SET              17200020
         BNE   NEXTUCB             NO, NOT TAPE, NOT DA, GO CHECK NEXT  17300020
CHKVOLID CLC   SRTEVOLI(F6),F0(R8) DO VOLSER'S MATCH                    17400020
         BE    MATCHID             YES GO UP USER COUNT                 17500020
NEXTUCB  LA    R6,F2(R6)           POINT TO NEXT ENTRY LOOKUP TABLE     17600020
         B     UCBSRCH             GO CHECK NEXT UCB                    17700020
CHK2321  CLI   UCBTBYT4,DA2321     IS THIS A 2321 DATA CELL             17800020
         BE    DATACEL             YES, GO PROCESS DATA CELL            17900020
         B     CHKVOLID            NO, DA DEVICE, GO CHECK VOLSER       18000020
MATCHID  CLI   UCBTBYT3,UCB3TAPE   IS THIS A TAPE                       18100020
         BE    TAPE                YES, UNABLE TO FLAG, GO SET RC       18200020
         ST    R7,DXDEBUCB         UCB ADDRESS TO DEB                   18300020
         SSM   DISABLE             SHUT OUT INTERRUPTS                  18400020
         SR    R9,R9               ZERO REGISTER                        18500020
         IC    R9,SRTEUSER         LOAD USER COUNT                      18600020
         LA    R9,F1(R9)           INCREMENT USER COUNT                 18700020
         STC   R9,SRTEUSER         SAVE USER COUNT, PREVENT DISMOUNT    18800020
         LA    R9,SRTEUSER         ADDRESS OF DATA MANAGEMENT USE COUNT 18900020
         ST    R9,USECOUNT         SAVE USE COUNT ADDRESS               19000020
         SSM   ENABLE              ALLOW INTERRUPTS                     19100020
*  NOW GET DSCB                                                         19200020
GETDSCB  LA    R9,DKEY             POINTER TO DATA SET NAME-            19300020
         ST    R9,OBTAIN2          -TO OBTAIN CAMLST                    19400020
         MVC   OBTVOL(F6),F0(R8)   VOLSER OF DATA SET                   19500020
         OBTAIN OBTPTR             GET DSCB                             19600020
         LTR   R15,R15             TEST OBTAIN RETURN CODE              19700020
         BNZ   OBTERROR            NON-ZERO IS OBTAIN ERROR             19800020
         B     FLAGDS              GO CHECK SECURITY FLAGS              19900020
USERLIST SR    R10,R10             ZERO REGISTER                        20000020
         IC    R10,VOLNUM          VOLUME COUNT                         20100020
         LTR   R10,R10             TEST VOLUME COUNT                    20200020
         BZ    IOERROR             ZERO COUNT IS ERROR                  20300020
         LA    R8,F0(R8)           BLANK VOLNUM FROM HIGH ORDER BYTE    20400020
         LTR   R8,R8               CHECK POINTER TO VOLUME LIST         20500020
         BZ    IOERROR             ZERO POINTER IS ERROR                20600020
         B     LOOKUP              GO LOOKUP UCB                        20700020
*  2321 DATA-CELL UCB SEARCH (BIN SEARCH)                               20800020
*  INPUT- R7 POINTS TO UCB, R8 POINTS TO VOLSER                         20900020
DATACEL  LA    R9,F10              10 SUB-UCBS                          21000020
CHECKID  CLC   DCELVOLI(F6),F0(R8) ARE VOLUME SERIALS EQUAL             21100020
         BE    BINFOUND            YES, GO SAVE UCB INFORMATION         21200020
         LA    R7,F16(R7)          POINT TO NEXT SUBUCB                 21300020
         BCT   R9,CHECKID          IF MORE BINS, GO CHECK NEXT SUBUCB   21400020
         B     NEXTUCB             VOLUME NOT FOUND, GO CHECK NEXT UCB  21500020
BINFOUND LH    R9,F0(R6)           ADDRESS OF UCB-                      21600020
         ST    R9,DXDEBUCB         -TO DEB FIELD                        21700020
         MVC   DXDEBBIN(F2),DCELBBNR BIN NUMBER TO DEB FIELD            21800020
         MVC   DXDAADDR+F1(F2),DCELBBNR BIN NUMBER TO SEEK FIELD        21900020
         SSM   DISABLE             PREVENT INTERRUPTS                   22000020
         SR    R9,R9               ZERO REGISTER                        22100020
         IC    R9,DCELDMCT         LOAD USER COUNT                      22200020
         LA    R9,F1(R9)           INCREMENT USER COUNT                 22300020
         STC   R9,DCELDMCT         SAVE USER COUNT, PREVENT DISMOUNT    22400020
         LA    R9,DCELDMCT         ADDRESS OF DATA MANAGEMENT USE COUNT 22500020
         ST    R9,USECOUNT         SAVE USE COUNT ADDRESS               22600020
         SSM   ENABLE              ALLOW INTERRUPTS                     22700020
         B     GETDSCB             GO GET DSCB                          22800020
DOTWENTY LA    R10,F20             USE 20                       SA53652 22850021
         MVI   DMODE,SWON          TURN SWITCH ON               SA53652 22900021
         B     VOLPOINT            GO PROCESS 20 VOLS.          SA53652 22950021
RELOC    MVC   LOCNAME(ENDBLLOC-LOCBLK),LOCBLK  INIT CAMLST     SA53652 22960021
         MVC   DMBB(F3),LOCAREA + F252  SAVE TTR                SA53652 22970021
         LA    R6,DMBB             POINT TO TTR                 SA53652 22980021
         B     INITLOC             GO INIT LOCATE               SA53652 22990021
UPDATE   MVC   RNAME(F8),PDSDSN    MOVE PASSWORD DSNAME TO RNAME        23000020
         MVC   DSCLSTAR(F3),DSAVT  MOVE NEW PASSWORD TTR TO DSCB        23200020
*  NOW ENQUEUE ON PASSWORD DATA SET                                     23300020
         LA    R1,ENQLIST          POINT TO ENQUEUE LIST                23400020
         ENQ   MF=(E,(1))          ENQUEUE ON DSCB                      23500020
         STH   R15,DSAVT           SAVE ENQUEUE RETURN CODE             23550020
*  NOW GO UPDATE PASSWORD DATA SET DSCB FROM IN CORE IMAGE              23600020
         BAL   R3,WRITDSCB         GO WRITE BACK DSCB                   23700020
*  NOW DEQUEUE FROM PASSWORD DATA SET AND FROM DSCB                     23800020
         CLC   ZERO(F2),DSAVT      WAS ENQUEUE SUCCESSFUL               23830020
         BNE   SKIPDQ              NO, SKIP DEQUEUE                     23860020
         LA    R1,DEQLIST          POINT TO DEQUEUE LIST                23930020
         DEQ   MF=(E,(1))          DEQUEUE FROM DSCB                    24000020
SKIPDQ   LA    R1,DENQLST          POINT TO DSNAME ENQUEUE LIST         24100020
         LA    R9,DMPDS            POINT TO PASSWORD DATA SET NAME      24200020
         ST    R9,F8(R1)           RESET DEQUEUE LIST                   24300020
         DEQ   MF=(E,(1))          DEQUEUE FROM PASSWORD DATA SET       24400020
         TM    DFLAG1,IOERR        WAS I/O SUCCESSFUL                   24500020
         BO    IOERROR             GO FREE CORE                         24600020
DSFLAG   TM    DFLAG1,DSNUPDAT     IS UPDATE OF DSCB REQUIRED           24700020
         BO    SETFLAG             YES, GO FLAG DSCB                    24800020
         B     ZERORC              GO CLEANUP AND RETURN                24900020
FLAGDS   MVC   DXDSCB(F96),OBTWRK  MOVE DSCB TO DSCB MAP                25000020
         MVC   OLDFLAG(F1),DSCDSIND SAVE PROTECTION FLAG STATUS         25100020
         NI    OLDFLAG,FLAGOFF     TURN OFF ALL BUT PROTECTION BITS     25300020
*  THE FOLLOWING IS POSSIBLE BECAUSE DFLAG1 PROTECTION REQUEST BITS     25350020
*  CORRESPOND ONE TO ONE WITH DSCB PROTECTION BITS                      25400020
         MVC   NEWFLAG(F1),DFLAG1  SET PROTECTION REQUEST BITS          25450020
         NI    NEWFLAG,FLAGOFF     TURN OFF ALL BUT PROTECTION BITS     25500020
CHCKBYTE CLC   OLDFLAG,NEWFLAG     COMPARE SECURITY FLAGS               25800020
         BE    STATUSOK            FLAGS AGREE, NO UPDATE REQUIRED      25900020
         NI    DSCDSIND,NOPROT     TURN OFF PROTECTION BITS (3,5)       26000020
         OC    DSCDSIND,NEWFLAG    PUT NEW STATUS IN DSCB               26100020
         B     NQ                  GO WRITE BACK DSCB                   26200020
LOCERROR LR    R1,R15              LOCATE RETURN CODE TO REGISTER 1     26700020
         LA    R11,RC32            SET RETURN CODE = 32                 26800020
         B     FREECORE            GO FREE CORE                         26900020
TAPE     LA    R11,RC48            SET RETURN CODE = 48                 27000020
         B     FREECORE            GO FREE CORE                         27100020
INUSE    LA    R11,RC52            DATA SET IN USE RETURN CODE          27130020
         B     FREECORE            GO FREE CORE                         27160020
VOLNTMTD LA    R15,RC4             INDICATE VOLUME NOT MOUNTED          27200020
OBTERROR LR    R1,R15              OBTAIN RETURN CODE TO REGISTER 1     27300020
OBTAINRC LA    R11,RC36            SET RETURN CODE = 36                 27400020
         B     FREECORE            GO FREE CORE                         27500020
IOERROR  LA    R11,RC40            SET RETURN CODE = 40                 27600020
         B     FREECORE            GO FREE CORE                         27700020
NQ       SR    R9,R9               ZERO REGISTER                        27900020
         IC    R9,DSNLL            LENGTH OF DATA SET NAME              28100020
         LA    R1,ENQLIST          POINT TO ENQUEUE LIST                28120020
         STC   R9,F1(R1)           SET DSLENGTH AS RNAME LENGTH-        28140020
         STC   R9,DEQLIST+F1       FOR ENQ AND DEQ LISTS                28160020
         BCTR  R9,R0               DECREMENT FOR EXECUTE                28200020
         L     R6,DSN              ADDRESS OF DSN                       28300020
         EX    R9,MOVEDSN          MOVE DATA SET NAME TO RNAME          28400020
         ENQ   MF=(E,(1))          ENQUEUE                              28600020
         LTR   R15,R15             TEST ENQUEUE RETURN CODE             28630020
         BNZ   INUSE               DATA SET IN USE                      28680020
*  NOW REISSUE OBTAIN TO ENSURE AN ACCURATE DSCB                 A42339 28690021
         OBTAIN OBTPTR             GET DSCB                      A42339 28700021
         BAL   R3,WRITDSCB         GO UPDATE DSCB                       28730020
DQ       LA    R1,DEQLIST          POINT TO DEQUEUE LIST                28810020
         DEQ   MF=(E,(1))          DEQUEUE                              28900020
         B     STATUSOK            FLAGS UPDATED                        29000020
*                                                                       29100020
*  CHANNEL PROGRAM FOR DSCB UPDATE                                      29200020
*                                                                       29300020
*        SEARCH-ID-EQUAL           (DXCCW7)                             29400020
*        TIC                       (DXCCW8)                             29500020
*        WRITE-DATA                (DXCCW9)                             29600020
*        SEARCH-ID-EQUAL           (DXCCW10)                            29700020
*        TIC                       (DXCCW11)                            29800020
*        READ-DATA (VERIFICATION)  (DXCCW12)                            29900020
*                                                                       30000020
*  DSCB UPDATE  THE DSCB DATA FIELD IS WRITTEN BACK TO THE VTOC AT      30100020
*  THE LOCATION SPECIFIED BY OBTAIN'S CCHHR                             30200020
WRITDSCB LA    R9,DXDAADDR+F3      ADDRESS OF COUNT FIELD (CCHHR)-      30300020
         ST    R9,DXCCW7           -TO SEARCH CCW                       30400020
         ST    R9,DXCCW10          -TO SEARCH CCW                       30500020
         MVI   DXCCW7,SRCHID       SET SEARCH ID EQUAL OP CODE          30600020
         MVI   DXCCW10,SRCHID      SET SEARCH ID EQUAL OP CODE          30700020
         MVI   DXDEBUCB,NOSEEK     RESET FILE MASK TO INHIBIT SEEKS     30800020
         LA    R9,DXCCW7           ADDRESS OF STARTING CCW              30900020
         ST    R9,IOBSIOCC         POINT TO STARTING CCW                31000020
         LA    R9,DXDSCB           DSCB ADDRESS (WORK AREA)-            31100020
         ST    R9,DXCCW9           -TO WRITE CCW                        31200020
         MVI   DXCCW9,OPWRITE      SET WRITE OP CODE                    31300020
         MVI   DXCCW9+F7,DSCBDLL   DSCB DATA LENGTH TO CCW              31400020
         MVI   DXCCW12,OPREAD      SET READ OP CODE FOR VALIDITY CHECK  31500020
         MVI   DXCCW12+F7,DSCBDLL  DSCB DATA LENGTH TO CCW              31600020
         MVC   DXDAADDR+F3(F5),OBTCCH MOVE DSCB CCHHR TO COUNT FIELD    31700020
         MVC   DXDEBSCC(F4),OBTCCH SET EXTENTS-                         31800020
         MVC   DXDEBECC(F4),OBTCCH -IN DEB FOR SEARCH                   31900020
*  NOW ISSUE EXCP TO UPDATE DSCB                                        32000020
         EXCP  DXIOB               INITIATE I/O                         32100020
         WAIT  ECB=DXECB           WAIT FOR COMPLETION                  32200020
*  WAS I/O SUCCESSFUL                                                   32300020
         TM    DXECB,GOODIO        WAS THERE AN ERROR                   32400020
         BCR   ONE,R3              NO, RETURN                           32500020
         OI    DFLAG1,IOERR        INDICATE I/O ERROR                   32600020
         BR    R3                  RETURN                               32700020
CHECKRC  LA    R9,RC24             REGISTER 9 = 24                      32800020
         CR    R11,R9              IS PASSWORD DATA SET FULL            32900020
         BNE   FREECORE            GO FREE CORE                         33000020
         LA    R1,JFCBELNM         POINT TO WRITE TO OPERATOR MESSAGE   33100020
         WTO   MF=(E,(1))          ISSUE WTO                            33200020
         B     FREECORE            GO CLEANUP AND RETURN                33300020
STATUSOK SSM   DISABLE             INHIBIT INTERRUPTS                   33400020
         L     R1,USECOUNT         GET ADDRESS OF USER COUNT            33500020
         IC    R9,F0(R1)           LOAD USER COUNT                      33600020
         BCTR  R9,R0               DECREMENT USER COUNT                 33700020
         STC   R9,F0(R1)           RESET USER COUNT                     33800020
         SSM   ENABLE              ALLOW INTERRUPTS                     33900020
         TM    DFLAG1,IOERR        WAS I/O SUCCESSFUL                   34000020
         BO    IOERROR             NO, GO FREE CORE                     34100020
         CLC   ZERO(F4),VOLIST     DID USER SUPPLY VOLUME LIST          34200020
         BE    LOCLISTS            IF NOT, USE LOCATE LIST              34300020
         LA    R8,F6(R8)           POINT TO NEXT VOLUME                 34400020
         B     MOREVOLS            GO CHECK IF MORE VPLUMES             34500020
LOCLISTS LA    R8,F12(R8)          POINT TO NEXT VOLUME                 34600020
MOREVOLS BCT   R10,LOOKUP          IF MORE VOLUMES, GO PROCESS NEXT VOL 34700020
         CLI   DMODE,SWON          MORE VOLS.                   SA53652 34750021
         BE    RELOC               YES,GO GET THEM              SA53652 34760021
ZERORC   SR    R11,R11             SET RETURN CODE = 0                  34800020
FREECORE EQU   *                   FREE CORE BEFORE RETURNING           34900020
         LR    R6,R1               SAVE REGISTER 1 DURING FREEMAIN      35000020
         LR    R4,R0               SAVE REGISTER 0 DURING FREEMAIN      35100020
         L     R9,DSAVR            LOAD RETURN ADDRESS                  35200020
         TM    DFLAG1,OBTNCORE     OBTAIN CORE TO BE FREED              35300020
         BZ    NOOBTAIN            NO, SKIP AROUND FREEMAIN             35400020
         LA    R0,WRKSIZE          SIZE OF OBTAIN AND LOCATE WORKAREA   35500020
         O     R0,SPN              SUBPOOL NUMBER IN HIGH ORDER BYTE    35600020
         L     R1,OBTAIN4          ADDRESS OF CORE TO BE FREED          35700020
         FREEMAIN R,LV=(0),A=(1)   FREE CORE                            35800020
NOOBTAIN LA    R0,WKSIZE           SIZE OF PROGRAM WORKAREA             35900020
         LR    R1,R5               ADDRESS OF CORE TO BE FREED          36000020
         FREEMAIN R,LV=(0),A=(1)   FREE CORE                            36100020
         LR    R1,R6               RESTORE REGISTER 1                   36200020
         LR    R0,R4               RESTORE REGISTER 0                   36300020
         LR    R15,R11             RESTORE REGISTER 15                  36400020
         LR    R14,R9              RETURN ADDRESS TO RETURN REGISTER    36500020
         BR    R14                 RETURN                               36600020
         EJECT                                                          36700020
*  CONSTANTS                                                            36800020
         DS    0H                  ALIGN CONSTANTS                      36900020
UCBEND   DC    X'FFFF'             END OF UCB LOOKUP TABLE INDICATOR    37000020
MOVEDSN  MVC   RNAME(F0),F0(R6)    MOVE DSNAME TO RNAME BUFFER          37100020
TAPECODE DC    X'8001'             COMMON PART OF ALL TAPE DEVICE CODES 37200020
DISABLE  DC    X'00'               PREVENT INTERRUPTS                   37300020
ENABLE   DC    X'FF'               ALLOW INTERRUPTS                     37400020
TWENTY   DC    H'20'               TWENTY                       SA53652 37450021
ZERO     DC    F'0'                ZERO WORD FOR COMPARES               37500020
SPN      DC    X'FB'               SUBPOOL NUMBER 251                   37600020
         DC    X'000000'           ZERO REST OF WORD                    37700020
LOCLIST  CAMLST NAME,0,,0          LOCATE CAMLST MACRO                  37800020
ENDLLIST EQU   *                   END OF LOCATE CAMLST MACRO           37900020
LOCBLK   CAMLST BLOCK,1,,3         LOCATE CAMLST(TTR)           SA53652 37910021
ENDBLLOC  EQU  *                   END OF CAMLST MACRO          SA53652 37920021
*  KEEP ENQ AND DEQ LISTS TOGETHER.                                     37950020
ENQL     ENQ   (0,0,E,RNLENGTH,SYSTEM),RET=USE,MF=L LIST FORM ENQUEUE   38010020
DEQL     DEQ   (0,0,RNLENGTH,SYSTEM),RET=HAVE,MF=L DEQUEUE              38070020
ENQLEND  EQU   *                   END OF ENQ AND DEQ EXPANSIONS        38130020
QNME     DC    CL8'SYSDSN  '       QNAME FOR ENQUEUE ON DSCB            38200020
PDSDSN   DC    CL8'PASSWORD'       PASSWORD DATA SET DSNAME             38260020
         EJECT                                                          38400020
*        THIS WORK AREA IS USED BY ALL LOADS OF THE PROTECT SVC.        38500020
*        ANY CHANGES TO IT MUST BE MADE TO ALL LOADS.                   38600020
WORKD    DSECT                                                          38700020
*                                                                       38800020
         IECDSECT                                                       38900020
CLEARIO  EQU   *-DXECB             LENGTH FOR CLEARING I/O BLOCKS       39000020
*                                                                       39100020
COMMD    EQU   *                   CONTINUE DSECT                       39200020
*                                                                       39300020
*        WORK AREA FOR MPDS COMMUNICATION AND BUFFERING                 39400020
*        A CONTINUATION OF DSECT (WORKD)                                39500020
*                                                                       39600020
*                                                                       39700020
DSAVR    DS    F                   SAVE AREA FOR RETURN REGISTER        39800020
DSAVT    DS    F                   MPDS LAST BLOCK SAVE AREA            39900020
DUCBADDR DS    F                   ADDRESS OF UCB LOOKUP TABLE          40000020
DPMODE   DS    CL1                 PROTECTION MODE BYTE SAVE AREA       40100020
DRECAP   DS    CL1                 SYSRES DEVICE-RECORD/TRK CAPACITY    40200020
DCODTAB  DS    CL1                 ENTRY CODE SAVE AREA FOR NEXT LOAD   40300020
*                                                                       40400020
*        DFLAG - COMMUNICATES STATUS OF DSCB UPDATING REQUIREMENTS      40500020
*                                                                       40600020
DFLAG1   DS    BL1                 COMMUNICATION FLAG                   40700020
*        COMMUNICATION FLAG (DFLAG1) IN COMMD WORK AREA                 40800020
*              1 BYTE  (DFLAG1)                                         40900020
*                   BIT  0  =1 MPDS IS ENQ TO ADD OWN P/W PROTECTION    41000020
*                        1  =1 INDICATES I/O ERROR                      41100020
*                        2  =1 INDICATES ENQUEUED IN 1ST - 2ND LOADS    41200020
*                        3  =1 PROTECTED DATA SET-SET BIT 3 IN DSCB     41300020
*                        4  =1 OBTAIN WORK AREA TO BE FREED             41400020
*                        5  =1 NO PASSWORD TO READ-SET BIT 5 IN DSCB    41500020
*                        6  =1 UPDATE DSCB OF DATA SET WITH PROTECTION  41600020
*                              SPECIFIED IN BITS 3 AND 5                41700020
*                        7  =1 UPDATE MPDS DSCB FROM CORE IMAGE IN      41800020
*                              WORK AREA (WORKD) AND DEQ ON MPDS        41900020
*                                                                       42000020
DFLAG2   DS    BL1                 COMMUNICATION FLAG                   42100020
*              1 BYTE (DFLAG2)                                          42200020
*                   BIT 0     RESERVED                                  42300020
*                   BIT 1  =1 INDICATES NEW PASSWORD WITH REPLACE       42400020
*                   BIT 2     RESERVED                                  42500020
*                   BIT 3     RESERVED                                  42600020
*                   BIT 4     RESERVED                                  42700020
*                   BIT 5     RESERVED                                  42800020
*                   BIT 6     RESERVED                                  42900020
*                   BIT 7     RESERVED                                  43000020
*                                                                       43100020
         DS    0CL11               COUNT FIELD FOR I/O                  43200020
DMPEND   DS    CL8                 MBBCCHHR OF LAST RECORD WRITTEN      43300020
DCKDLL   DS    CL3                 KEY LENGTH/DATA LENGTH               43400020
*                                                                       43500020
*        EXCP BUFFER  AREA FOR COUNT KEY DATA READ/WRITE                43600020
*                                                                       43700020
         DS    0F                  ALIGN WORD                           43800020
         DS    CL1                 ALIGN FOR MBBCCHHR                   43900020
DMBB     DS    CL3                 MBB FIELD FOR CONVERT ROUTINE        44000020
         DS    0CL8                COUNT FIELD FOR I/O                  44100020
DCNT     DS    CL4                 CCHH PORTION OF COUNT                44200020
DRECNO   DS    CL1                 RECORD NUMBER                        44300020
DKEYLEN  DS    CL1                 KEY LENGTH FOR FOR WRITE             44400020
DDATALEN DS    CL2                 DATA LENGTH FOR WRITE                44500020
DKEY     DS    CL44                EXCP- 44 BYTE KEY (DSN)              44600020
DKEY8    DS    CL8                 EXCP- 8 BYTE EXTENSION (PASSWORD)    44700020
DATA     DS    0CL80               DATA FIELD                           44800020
DUSE     DS    CL2                 USE COUNT                            44900020
DMODE    DS    BL1                 PROTECTION MODE BYTE FIELD           45000020
DAT77    DS    CL77                USER DATA (77 BYTES OPTIONAL DATA)   45100020
DSAVLL   EQU   *-DCNT              COUNT-KEY-DATA FIELD LENGTH          45200020
DCLEAR   EQU   *-COMMD             WORK AREA TO BE CLEARED TO ZERO      45300020
DFOXKEY  DS    52C                 52 BYTE KEY OF FF                    45400020
         DS    80C                 80 BYTE DATA FIELD                   45500020
*                                                                       45600020
*        OBTAIN LIST                                                    45700020
*                                                                       45800020
OBTPTR   CAMLST SEARCH,OBTDSN,OBTVOL,OBTWRK                             45900020
         ORG   OBTPTR              LABEL OBTAIN FIELDS                  46000020
OBTAIN1  DS    F                   OBTAIN CAMLST FIRST FULL WORD        46100020
OBTAIN2  DS    F                   OBTAIN CAMLST SECOND FULL WORD       46200020
OBTAIN3  DS    F                   OBTAIN CAMLST THIRD FULL WORD        46300020
OBTAIN4  DS    F                   OBTAIN CAMLST FOURTH FULL WORD       46400020
         ORG                                                            46500020
*                                                                       46600020
*        ENQUEUE PARAMETER LIST                                         46700020
*                                                                       46800020
DENQLST  ENQ   (DMPDSQN,DMPDS,E,HLEN,SYSTEM),MF=L                       46900020
*        NAME LIST FOR ENQUEUE/DEQUEUE AND OBTAIN                       47000020
DMPDSQN  DS    0CL52               ONE FIELD FOR SETTING UP IN WORKD    47100020
         DS    CL8                 QNAME                                47200020
DMPDS    DS    CL44                RNAME                                47300020
OBTDSN   EQU   DMPDS               DSNAME OF MASTER PASSWORD DATA SET   47400020
OBTVOL   DS    CL6                 VOLUME SERIAL OF MPDS DSCB VOLUME    47500020
DREPSAV  DS    CL140               SAVEAREA FOR PASSWORD ENTRY          47600020
LOCNAME  CAMLST NAME,DKEY,,LOCAREA LOCATE CAMLST MACRO                  47700020
         ORG   LOCNAME             LABEL LOCATE CAMLST FIELDS           47800020
LOCNAME1 DS    F                   1ST WORD LOCATE CAMLST               47900020
LOCNAME2 DS    F                   2ND WORD LOCATE CAMLST               48000020
LOCNAME3 DS    F                   3RD WORD LOCATE CAMLST               48100020
LOCNAME4 DS    F                   4TH WORD LOCATE CAMLST               48200020
         ORG                                                            48300020
USECOUNT DS    F                   SAVE POINTER TO USER COUNT HERE      48400020
*  KEEP ENQ AND DEQ LISTS TOGETHER.                                     48450020
ENQLIST  ENQ   (QNAME,RNAME,E,RNLENGTH,SYSTEM),RET=USE,MF=L ENQUEUE     48500020
DEQLIST  DEQ   (QNAME,RNAME,RNLENGTH,SYSTEM),RET=HAVE,MF=L DEQUEUE      48550020
*  NOTE - MFT ENQUEUE WITH QNAME EQUAL TO SYSDSN REQUIRES TCB           48560020
*         ADDRESS IMMEDIATELY FOLLOWING QNAME.                          48570020
QNAME    DS    CL8                 QNAME BUFFER                         48600020
TCBADDR  DS    F                   TCB ADDRESS FOR MFT ENQUEUE          48650020
RNAME    DS    CL44                RNAME BUFFER                         48700020
OLDFLAG  DS    CL1                 OLD PROTECTION STATUS                48800020
NEWFLAG  DS    CL1                 NEW PROTECTION STATUS                48900020
WKSIZE   EQU   *-WORKD             SIZE OF PROGRAM WORKAREA             49000020
*                                                                       49100020
*        END OF MAPPING OF DSECT WORKAREA                               49200020
         EJECT                                                          49300020
PARMD    DSECT                                                          49400020
*                                                                       49500020
*              PARAMETER LIST FOR ALL REQUESTS                          49600020
*                                                                       49700020
*                                                                       49800020
*              COMMON  SEGMENT FOR ALL REQUESTS                         49900020
*                                                                       50000020
ENCODE   DS    0BL1                ENTRY CODE                           50100020
DBUF     DS    CL4                 ADDRESS OF BUFFER FOR CODE 04/05     50200020
DSNLL    DS    0CL1                DSN LENGTH                           50300020
DSN      DS    CL4                 ADDRESS OF DATA SET NAME             50400020
CURRENT  DS    CL4                 ADDRESS OF CURRENT PASSWORD          50500020
*                                                                       50600020
*              ADD / REPLACE / DELETE COMMON SEGMENT                    50700020
*                                                                       50800020
CONTROL  DS    CL4                 ADDRESS OF CONTROL PASSWORD          50900020
VOLNUM   DS    0CL1                NUMBER OF VOLUMES SPECIFIED          51000020
VOLIST   DS    CL4                 ADDRESS OF VOLUME LIST               51100020
*                                                                       51200020
*              ADD / REPLACE  COMMON SEGMENT                            51300020
*                                                                       51400020
PCODE    DS    0BL1                PROTECTION CODE                      51500020
NEW      DS    CL4                 ADDRESS OF NEW PASSWORD              51600020
STRINGL  DS    0CL1                STRING LENGTH                        51700020
STRING   DS    CL4                 ADDRESS OF DATA STRING               51800020
*                                                                       51900020
         EJECT                                                          52000020
*                                                                       52100020
WRKSPACE DSECT                                                          52200020
*                                                                       52300020
*  OBTAIN WORKAREA AND LOCATE WORKAREA                                  52400020
*                                                                       52500020
OBTWRK   DS    CL96                DSCB                                 52600020
OBTCCH   DS    CL5                 CCHHR                                52700020
         DS    CL249               OBTAIN WORK SPACE                    52800020
         DS    0D                  ALIGN LOCATE WORKAREA                52900020
LOCAREA  DS    CL265               LOCATE WORK SPACE (VOLUME LIST)      53000020
WRKSIZE  EQU   *-WRKSPACE          SIZE OF LOCATE AND OBTAIN WORKAREA   53100020
*                                                                       53200020
         EJECT                                                          53300020
*                                                                       53400020
TCB      DSECT                                                          53500020
         IKJTCB                                                         53600020
         EJECT                                                          53700020
SRT      DSECT                                                          53800020
         IEFUCBOB                                                       53900020
         EJECT                                                          54000020
CVT      DSECT                                                          54100020
         CVT                                                            54200020
*                                                                       54300020
         END                                                            54400020
