         TITLE 'IGC0308B --- ALTERNATE TRACK ASSIGNMENT FOR 2305'       00210021
         COPY  LCGASMSW                                          SM4351 00220021
IGC0308B CSECT                                                          00250021
* STATUS - CHANGE LEVEL 000                                           * 00400020
*                                                                     * 00600020
* FUNCTION                                                            * 00800020
*     THIS LOAD OF SVC 82 PERFORMS ALTERNATE TRACK ASSIGNMENT FOR     * 01000020
*     EITHER OF TWO CASES ON A 2305 DEVICE                            * 01200020
*                                                                     * 01400020
*                                                                     * 01600020
*       1)VOLUMES IN THE INITIALIZATION PROCESS.                      * 01800020
*       2)PRE-INITIALIZED VOLUMES(THEY HAVE A FORMAT 4 DSCB).         * 02000020
*                                                                     * 02200020
*     IF THE SPECIFIED DEFECTIVE TRACK IS A PRIMARY TRACK, THE        * 02400020
*     DYNAMIC ALTERNATE IS ASSIGNED TO THE ORIGINAL PRIMARY TRACK.    * 02600020
*                                                                     * 02800020
*     IF THE SPECIFIED DEFECTIVE TRACK IS THE UNASSIGNED DYNAMIC      * 03000020
*     ALTERNATE, NO TRACK ASSIGNMENTS ARE MADE AND A RETURN CODE        03200020
*     OF 16 IS PASSED TO CALLING ROUTINE.                             * 03400020
*                                                                     * 03600020
* ENTRY POINT - IGC0308B IS THE ONLY ENTRY POINT.                     * 03800020
*                                                                     * 04000020
* INPUT - REGISTER 1 POINTS TO 3-FULL WORDS AS FOLLOWS:               * 04200020
*         WORD1 - INPUT PARM LIST POINTER PASSED TO IGC0008B.         * 04400020
*         WORD2 - WORK AREA ADDRESS(DESCRIBED BY IOBLOCKS DESECT).    * 04600020
*         WIRD3 - POINTER TO SVRB EXTENDED SAVE AREA.                 * 04800020
*                                                                     * 05000020
* EXITS                                                               * 05200020
*     NORMAL - THE SECOND WORD OF THE INPUT PARM LIST CONTAINS THE    * 05400020
*              CCHH OF THE ASSIGNED ALTERNATE TRACK, IF ANY.  IF NO   * 05600020
*              ALTERNATE WAS ASSIGNED, THE SECOND WORD CONTAINS ZEROES* 05800020
*              WITH A RETURN CODE OF ZERO(IN EITHER CASE).            * 06000020
*              SIX BYTES OF THE ALTERNATE TRACK INFORMATION ARE       * 06200020
*              UPDATED(EITHER IN FORMAT 4 DSCB OR POINTED TO BY THE   * 06400020
*              PARM LIST).                                            * 06600020
*                                                                     * 06800020
*     ERROR - RETURN CODE OF 12 IF I/O ERROR WAS ENCOUNTERED.         * 07000020
*             RETURN COE OF 16 IF DYNMAIC ALTERNATE HAS BEEN          * 07200020
*             USED OR IS DEFECTED.                                    * 07400020
*                                                                     * 07600020
* SUPERVISOR MACROS - EXCP,WAIT,FREEMAIN.                             * 07800020
*                                                                     * 08000020
* WORKAREA/TABLES - USES THE WORK AREA DESCRIBED BY DSECT IOBLOCKS.   * 08200020
*                                                                     * 08400020
* OUTPUT - SEE EXITS DESCRPPTION.                                     * 08600020
*                                                                     * 08800020
* ATTRIBUTES - REENTRANT, RELOCATABLE, PRIVILEGED,ENABLED.            * 09000020
         EJECT                                                          09200020
*********************************************************************** 09400020
*                                                                     * 09600020
*     REGISTER ASSIGNMENTS.                                           * 09800020
*                                                                     * 10000020
*********************************************************************** 10200020
         SPACE 1                                                        10400020
R0       EQU   0                                                        10600020
R1       EQU   1                                                        10800020
R2       EQU   2                                                        11000020
R3       EQU   3                                                        11200020
R4       EQU   4                                                        11400020
R5       EQU   5                                                        11600020
R6       EQU   7                                                        11800020
R7       EQU   8                                                        12000020
R8       EQU   8                                                        12200020
R9       EQU   9                                                        12400020
R10      EQU   10                                                       12600020
R11      EQU   11                                                       12800020
R14      EQU   14                                                       13000020
R15     EQU   15                                                        13200020
PARMPTR  EQU   1                                                        13400020
BASEREG  EQU   12                                                       13600020
         SPACE 1                                                        13800020
*********************************************************************** 14000020
*                                                                     * 14200020
*     EQUATE DEFINITIONS.                                             * 14400020
*                                                                     * 14600020
*********************************************************************** 14800020
         SPACE 1                                                        15000020
K0       EQU   0                       DISPLACEMENT CONSTANT.           15200020
K1       EQU   1                       DISPLACEMENT CONSTANT.           15400020
K2       EQU   2                       DISPLACEMENT CONSTANT.           15600020
K4       EQU   4                       DISPLACEMENT CONSTANT.           15800020
K5       EQU   5                       DISPLACEMENT                     16000020
K6       EQU   6                                                        16200020
K7       EQU   7                                                        16400020
K8       EQU   8                                                        16600020
K12      EQU   12                                                       16800020
K16      EQU   16                                                       17000020
K44      EQU   44                                                       17200020
ONE      EQU   1                                                        17400020
CODERO   EQU   X'16'                   READ R0  OP CODE                 17600020
FLAGS    EQU   X'42'                   FLAGS FOR IOBLOCK.               17800020
NULL     EQU   X'00'                   CODE FOR ANALYZE/FORMAT FUNCTION 18000020
OPCODE   EQU   X'06'                   READ DATA OP CODE.               18200020
SOPCODE  EQU   X'31'                   SEARCH ID EQU OP CODE.           18400020
ROPCODE  EQU   X'1A'                   READ HA OP CODE.                 18600020
WOPCODE  EQU   X'15'                   WRITE RECORD R0 OP CODE.         18800020
WRTCD    EQU   X'05'                   WRITE DATA OP CODE.              19000020
RDCD     EQU   X'19'                   WRITE HOME ADDRESS OP CODE.      19200020
RBEXSAVE EQU   96                      EXTENTED SAVE AREA OF SVRB.      19400020
LAST     EQU   X'80'                   LAST PARAMETER INDICATOR.        19600020
GOOD     EQU   X'7F'                   I/O GOOD COMPLETION BIT.         19800020
COMPLETE EQU   X'40'                   I/O COMPLETION BIT.              20000020
SKIP     EQU   X'10'                   SKIP DATA TRANSFER.              20200020
RETURN   EQU   3                       EXIT SVC CODE.                   20400020
CHAIN    EQU   X'40'                   COMMAND CHAIN CCWS.              20600020
SILI     EQU   X'20'                   SUPPRESS INCORRECT LENGTH.       20800020
ALT      EQU   X'01'                   ALTERNATE TRACK FLAG.            21000020
DEFECT   EQU   X'02'                   DEFECTIVE TRACK FLAG.            21200020
MOVEHA   EQU    X'40'                   MOVE HA DOWN THE TRACK.         21400020
UE       EQU   X'01'                   UNIT EXCEPTION.                  21600020
XFF      EQU   X'FF'                   HEX FF                           21800020
         EJECT                                                          22000020
         LR    BASEREG,R15             ESTABLISH ADDRESSING.            22200020
         USING IGC0308B,BASEREG                                         22400020
         SPACE                                                          22600020
         L     R11,K0(R1)              PARM LIST POINTER.               22800020
         L     R2,K4(R1)               WORKAREA ADDRESS.                23000020
         L     R5,K8(R1)               SVRB EXTENDED AREA.              23200020
         SPACE 2                                                        23400020
*********************************************************************** 23600020
*                                                                     * 23800020
*   INITIALIZE THE IOB.                                               * 24000020
*                                                                     * 24200020
*********************************************************************** 24400020
         SPACE 2                                                        24600020
         USING IOBLOCKS,R2                                              24800020
INITIOB  EQU   *                                                        25000020
         MVI   IOBFLAG1,FLAGS          SET PROPER FLAGS.                25200020
         LA    R3,ECB                  ECB ADDRESS.                     25400020
         ST    R3,IOBECBAD             STORE IN IOB.                    25600020
         MVI   IOBINCAM+ONE,ONE        BLOCK COUNT.                     25800020
         LA    R3,DCB-K44              DCB ADDRESS.                     26000020
         ST    R3,IOBDCBPT             STORE IN IOB.                    26200020
FUNCTEST EQU   *                                                        26400020
         CLI   K0(R11),NULL             THIS AN ANALYZE/FORMAT REQUEST. 26600020
         BE    ASSGN                   YES--GO HANDLE.                  26800020
         SPACE 1                                                        27000020
*   BUILD CCWS FOR READING FORMAT 4 DSCB HERE.                          27200020
         USING IOBLOCKS,R2                                              27400020
FORM4    EQU   *                                                        27600020
         LA    R3,FORMAT4              FORMAT 4 READ-IN AREA.           27800020
         ST    R3,WRTRD                STORE IN READ-DATA CCW.          28000020
         MVI   WRTRD,OPCODE             SET OP CODE.                    28200020
         MVI   WRTRD+K7,RBEXSAVE       SET COUNT.                       28400020
         LA    R3,SEARCH               SEARCH CCW ADDRESS.              28600020
         ST    R3,TIC                  STORE IN TIC.                    28800020
         MVI   TIC,K8                  SET TIC OP CODE.                 29000020
         LA    R3,CCHHR                SEARCH ADDRESS.                  29200020
         ST    R3,SEARCH               STORE IN SEARCH CCW.             29400020
         MVI   SEARCH+K4,COMPLETE      COMMAND CHAIN ON.                29600020
         MVI   SEARCH+K7,K5            SET COUNT.                       29800020
         MVI   SEARCH,SOPCODE          SET SEARCH OP CODE.              30000020
         LA    R3,SEARCH               SEARCH CCW ADDRESS.              30200020
         ST    R3,IOBSTART             SET IN IOB.                      30400020
         SPACE                                                          30600020
*   STORE CCHHR OF VTOC IN IOB HERE.                                    30800020
         L     R3,K0(R11)               UCB ADDRESS.                    31000020
         USING UCB,R3                                                   31200020
         L     R0,SRTEFSCT             TTR OF VTOC.                     31400020
         SPACE                                                          31600020
FINDCCHH EQU   *                                                        31800020
         LA    R3,RBEXSAVE(R5)         EXTENTED SVRB SAVE AREA.         32000020
         STM   R1,BASEREG,K0(R3)       SAVE THE REGISTERS.              32200020
         USING CVT,R15                                                  32400020
         L     R15,CVTPTR              CVT ADDRESS.                     32600020
         L     R15,CVTPCNVT            CONVERT ROUTINE ADDRESS.         32800020
         DROP  R15                                                      33000020
         LA    R1,DEB                  ADDDRESS OF DEB.                 33200020
         LA    R2,IOBSEEK              TARGET AREA FOR MBBCCHHR.        33400020
         BALR  R14,R15                 CONVERT TTR TO MBBCCHHR.         33600020
         LM    R1,BASEREG,K0(R3)       RESTORE THE REGISTERS.           33800020
         SPACE                                                          34000020
*   READ IN THE FORMAT 4 DSCB HERE.                                   * 34200020
         SPACE                                                          34400020
         BAL   R9,WRTREAD              READ IN FORMAT4 DSCB DATA FIELD. 34600020
         BAL   R9,WAIT                 AWAIT COMPLETION.                34800020
         MVC   ALTINFO(K6),ALTDATA     CCHH NEXT ALT. AND COUNT LEFT.   35000020
         SPACE                                                          35200020
ASSG1    EQU   *                                                        35400020
         CLC   ALTINFO+K4(K2),ZERO     ANY ALTERNATES LEFT.             35600020
         BNE   WRTPRIM                 YES-                             35800020
EXIT16   EQU   *                                                        36000020
         BAL   R9,FREECORE             FREE THE WORK AREA.              36200020
         LA    R15,K16                 SET RETURN CODE.                 36400020
         SVC   RETURN                  RETURN TO CALLER.                36600020
         SPACE                                                          36800020
         EJECT                                                          37000020
*********************************************************************** 37200020
*                                                                     * 37400020
*   WRITE HOME ADDRESS/RECORD ZERO ON THE PRIMARY TRACK HERE.         * 37600020
*                                                                     * 37800020
*********************************************************************** 38000020
WRTPRIM  EQU   *                                                        38200020
         L     R3,K4(R11)              PUT CCHH OF BAD PRIMARY IN R3    38400020
         ST    R3,R0COUNT              TEMPORARY STORAGE                38600020
         MVC   CCHHR(K4),R0COUNT       PRIMARY CCHH TO IOB.             38800020
         MVC   HA+K1(K4),R0COUNT       SET IN CCHH OF HA.               39000020
         MVI   HA,DEFECT               SET FLAG IN HA.                  39200020
         LA    R4,HA                   WRITE-OUT AREA.                  39400020
         ST    R4,WRTHA                STORE IN CCW.                    39600020
         MVI   WRTHA,RDCD              SET OP CODE.                     39800020
         NI    WRTHA+K4,XFF-CHAIN      SET CHAIN BIT OFF                40000020
         MVI   WRTHA+K7,K5             SET COUNT IN CCW.                40200020
         LA    R4,R0COUNT              COUNT FIELD ADDRESS.             40400020
         ST    R4,WRTR0                STORE IN CCW.                    40600020
         MVI   WRTR0,WOPCODE           RESET OP CODE.                   40800020
         NI    WRTR0+K4,XFF-CHAIN      SET CHAIN BIT OFF                41000020
         LA    R4,WRTHA                CHANNEL PROGRAM START.           41200020
         ST    R4,IOBSTART             STORE IN IOB.                    41400020
         BAL   R9,WRTREAD              WRITE HA/R0 ON PRIMARY.          41600020
         BAL   R9,WAIT                 AWAIT COMPLETION.                41800020
         MVC   K4(K4,R11),ALTINFO      PUT CCHH OF ALT. IN PARM LIST.   42000020
         EJECT                                                          42200020
*********************************************************************** 42400020
*                                                                     * 42600020
*   WRITE HOME ADDRESS/RECORD ZERO ON THE ALTERNATE TRACK HERE.       * 42800020
*                                                                     * 43000020
*********************************************************************** 43200020
         SPACE 1                                                        43400020
WRTALT   EQU   *                                                        43600020
         LA    R4,WRTR0                ADDR OF START OF CHAN PROG.      43800020
         ST    R4,IOBSTART             STORE IN IOB                     44000020
         ST    R3,R0COUNT              PRIMARY CCHH TO RECORD ZERO.     44200020
         MVI   R0COUNT+K7,K8           SET DATA LENGTH FOR EIGHT.       44400020
         MVI   WRTR0+K7,K16            SET CCW COUNT FOR 16.            44600020
         BAL   R9,WRTREAD              WRITE R0 ON ALTERNATE.           44800020
         BAL   R9,WAIT                 AWAIT COMPLETION.                45000020
         SPACE                                                          45200020
         XC    ALTINFO+K4(K2),ALTINFO+K4 CLEAR NO. OF ALT. TO ZERO.     45400020
         CLI   K0(R11),NULL            THIS A FORMAT-ANALYZE REQUEST.   45600020
         BNE   UPFORMAT                NO--NEED TO UPDATE FORMAT4 DSCB. 45800020
         L     R4,K8(R11)              ADDRESS OF ALT. INFORMATION.     46000020
         MVC   K0(K6,R4),ALTINFO       UPDATE ALTERNATE TRACK INFO.     46200020
         SPACE 3                                                        46400020
EXIT0    BAL   R9,FREECORE             FREE THE WORKAREA.               46600020
         LA    R15,0                   SET RETURN CODE.                 46800020
         SVC   RETURN                  RETURN TO CALLER.                47000020
ASSGN    EQU   *                       SET UP ALTERNATE INFORMATION.    47200020
         L     R4,K8(R11)              POINTER TO ALT. INFORMATION.     47400020
         MVC   ALTINFO(K6),K0(R4)      SET UP ALTERNATE TRACK INFO.     47600020
         B     ASSG1                   GO PROCESS THIS TRACK.           47800020
         EJECT                                                          48000020
*********************************************************************** 48200020
*                                                                     * 48400020
*   UPDATE THE FORMAT 4 DSCB HERE.                                    * 48600020
*                                                                     * 48800020
*********************************************************************** 49000020
         SPACE 3                                                        49200020
UPFORMAT EQU   *                       UPDAYE THE FORMAT 4 DSCB HERE.   49400020
         MVC   ALTDATA(K6),ALTINFO     UPDATE ALTERNATE INFORMATION.    49600020
         LA    R3,SEARCH               CHANNEL PROGRAM ADDRESS.         49800020
         ST    R3,IOBSTART             STORE IN IOB.                    50000020
         MVI   WRTRD,WRTCD             SET OP CODE FOR WRITE.           50200020
         MVC   CCHHR(K4),VTOCCCHH      SEEK//SEARCH ADDRESS.            50400020
         BAL   R9,WRTREAD              WRITE OUT NEW FORMAT 4 DSCB DATA 50600020
         BAL   R9,WAIT                 AWAIT COMPLETION.                50800020
         MVI   WRTRD,OPCODE            SET OP CODE FOR READ.            51000020
         OI    WRTRD+K4,SKIP           SKIP DATA TRANSFER.              51200020
         BAL   R9,WRTREAD              READ BACK CHECK DATA.            51400020
         BAL   R9,WAIT                 AWAIT COMPLETION.                51600020
         B     EXIT0                   GO RETURN TO CALLER.             51800020
         SPACE                                                          52000020
*********************************************************************** 52200020
*                                                                     * 52400020
*     EXECUTE CHANNEL PROGRAM                                         * 52600020
*                                                                     * 52800020
*********************************************************************** 53000020
         SPACE                                                          53200020
WRTREAD  EXCP  IOB                     START THE I/O OPERATION.         53400020
         BR    R9                      RETURN.                          53600020
WAIT     TM    ECB,COMPLETE            THIS OPERATION COMPLETE.         53800020
         BO    TEST                    YES-TEST ITS STATUS.             54000020
         WAIT  ECB=ECB                 NO--AWAIT COMPLETION.            54200020
TEST     CLI   ECB,GOOD                EVERYTHING A-OK.                 54400020
         BCR   K8,R9                   YES-RETURN.                      54600020
IOERR    EQU   *                                                        54800020
         LA    R15,K12                 SET RETURN CODE.                 55000020
         SVC   RETURN                  EXIT.*                           55200020
         SPACE 3                                                        55400020
FREECORE EQU   *                       RELEASE THE CORE HERE.           55600020
         LH    R3,SIZE                 SIZE OF AREA TO RELEASE.         55800020
         FREEMAIN R,LV=(3),A=(2),SP=253                                 56000020
         BR    R9                      RETURN.                          56200020
         SPACE                                                          56400020
         SPACE 3                                                        56600020
F1       DC    F'1'                    TRACK INCREMENT CONSTANT.        56800020
ZERO     DC    1H'0'                   COMPARE CONSTANT.                57000020
         EJECT                                                          57200020
IOBLOCKS DSECT                                                          57400020
MYDEB    EQU   *                       DEB DEFINITION.                  57600020
DEBEOEA  DS    1F                      END-OF-EXTENT.                   57800020
DEBSIOA  DS    1F                      START I/O.                       58000020
DEBPCIA  DS    1F                      PCI.                             58200020
DEBCEA   DS    1F                      CHANNEL END.                     58400020
DEBXCEA  DS    1F                      ABNORMAL END.                    58600020
         DS    CL12                                                     58800020
DEBLNGTH DS    CL1                     DEB LENGTH(DOUBLE WORDS)         59000020
         DS    CL3                                                      59200020
DEB      EQU   *                       DEB PROPER                       59400020
DEBNMSUB DS    CL1                     OPEN SUBROUTINES.                59600020
DEBTCBAD DS    CL3                     TCB ADDRESS.                     59800020
DEBAMLNG DS    CL1                     LENGTH ACCESS METHOD.            60000020
DEBDEBAD DS    CL3                     NEXT DEB ADDRESS.                60200020
DEBOFLGS DS    CL1                     DATA SET FLAGS.                  60400020
DEBIRBAD DS    CL3                     IRB ADDRESS.                     60600020
DEBOPATB DS    CL1                     TYPE OF I/O.                     60800020
DEBSYSPG DS    CL3                     IOB PURGE ADDRESS.(SYSTEM)       61000020
DEBNMEXT DS    CL1                     NO. OF EXTENTS.                  61200020
DEBUSRPG DS    CL3                     IOB USER PURGE ADDRESS.          61400020
DEBPRIOR DS    CL1                     ZERO                             61600020
DEBECBAD DS    CL3                     PURGE ECB.                       61800020
DEBDEBID DS    CL1                     PROTECT KEY//ID.                 62000020
DEBDCBAD DS    CL3                     DCB ADDRESS.                     62200020
DEBEXSCL DS    CL1                     EXTENT SCALE.                    62400020
DEBAPPAD DS    CL3                     APPENDAGE VECTOR TABLE.          62600020
DEBDVMOD DS    CL1                     FILE MASK.                       62800020
DEBUCBAD DS    CL3                     UCB ADDRESS.                     63000020
DEBBINNO DS    CL2                     BIN NO. FOR 2321.                63200020
DEBSTRCC DS    CL2                     CYLINDER START.                  63400020
DEBSTRHH DS    CL2                     HEAD START.                      63600020
DEBENDCC DS    CL2                     CYLINDER END.                    63800020
DEBENDHH DS    CL2                     HEAD END.                        64000020
DEBNMTRK DS    CL2                     NUMBER OF TRACKS.                64200020
         DS    CL20                                                     64400020
DEBEND   DS    0C                      END OF DEB.                      64600020
         EJECT                                                          64800020
ECB      DS    1F                      ECB HERE.                        65000020
IOB      EQU   *                       IOB HERE.                        65200020
IOBFLAG1 DS    CL1                     FLAG1                            65400020
IOBFLAG2 DS    CL1                     FLAG2.                           65600020
IOBSENS0 DS    CL1                     SENSE BYTE ZERO.                 65800020
IOBSENS1 DS    CL1                     SENSE BYTE ONE.                  66000020
IOBECBAD DS    CL4                     ADDRESS OF ECB.                  66200020
IOBCSW   DS    CL8                     STATUS WORDS.                    66400020
IOBSTART DS    CL4                     CHANNEL PROGRAM ADDRESS.         66600020
IOBDCBPT DS    CL4                     ADDRESS OF DCB.                  66800020
IOBRESTR DS    CL4                     RESTART ADDRESS.                 67000020
IOBINCAM DS    CL2                     BLOCK COUNT.                     67200020
IOBERRCT DS    CL2                     ERROR COUNT.                     67400020
IOBSEEK  DS    CL8                     SEEK ADDRESS.                    67600020
CCHHR    EQU   IOBSEEK+3               SEARCH ADDRESS.                  67800020
DCB      DS    1F                      DEB ADDRESS.                     68000020
ALTINFO  DS    1D                      KEEP ALTERNATE TRACK INFO HERE.  68200020
WRTHA    DS    1D                      WRITE HOME ADDRESS.              68400020
WRTR0    DS    1D                      WRITE RECORD ZERO.               68600020
RDHA     DS    1D                      READ HOME ADDRESS.               68800020
READR0   DS    1D                      READ RECORD ZERO.                69000020
HA       DS    CL5                     HOME ADDRESS.                    69200020
SW       DS    CL1                     SWITCH.                          69400020
D2314    EQU   X'80'                   2314 DEVICE.                     69600020
D2321    EQU   X'40'                   2321 DEVICE.                     69800020
DEFALT   EQU   X'02'                                               1057 70000020
RETRY    EQU   X'01'                   GIVE IT ONE MORE TRY.            70200020
SIZE     DS    CL2                     SIZE OF GETMAIN AREA.            70400020
R0COUNT  DS    1D                      RECORD ZERO COUNT FIELD.         70600020
R0DATA   DS    1D                      RECORD ZERO DATA  FIELD.         70800020
IOEND1   DS    0C                      END OF BASIC I/O BLOCKS.         71000020
*   EXTENSION FOR GETALT//DYNAMIC TRACK REQUEST.                        71200020
SEARCH   DS    1D                      SEARCH CCW.                      71400020
TIC      DS    1D                      REPEAT UNTIL FOUND.              71600020
WRTRD    DS    1D                      WRITE OR READ DATA.              71800020
FORMAT4  DS    CL96                    FORMAT4 DSCB READ IN AREA.       72000020
ALTDATA  EQU   FORMAT4+8               ALTERNATE TRACK INFORMATION.     72200020
VTOCCCHH EQU   FORMAT4+63              CCHH START OF VTOC.              72400020
IOEND    DS    0C                                                       72600020
         EJECT                                                          72800020
UCB      DSECT                                                          73000020
         IEFUCBOB                                                       73200020
         EJECT                                                          73400020
CVT      DSECT                                                          73600020
         CVT   SYS=MIN                                                  73800020
         END                                                            74000020
