         TITLE 'IGG0860A - SECOND LOAD MODULE FOR SVC 86'        S20201 00200020
IGG0860A CSECT                                                          00400020
*                                                                       00600020
*                                                                       00800020
*          RELEASE 22 DELETIONS/CHANGES                                 01000020
*          RELEASE 21 DELETIONS/CHANGES                                 01200020
*          RELEASE 20 DELETIONS/CHANGES                                 01400020
*0791002000-004000                                               S20201 01500020
*                                                                       01600020
*STATUS CHANGE LEVEL 002                                                01800020
*                                                                       02000020
*TITLE 'IGG0860A' - SECOND LOAD MODULE OF SVC 86                      * 02200020
*                                                                     * 02400020
*FUNCTION/OPERATION                                                     02600020
*   IGG0860A, THE SECOND LOAD MODULE OF SVC 86 ESTABLISHES ITS OWN    * 02800020
*ADDRESSABILITY, THAT OF THE 688-BYTE WORK AREA GOTTEN BY IGC0008F,   * 03000020
*AND THAT OF A WORK AREA WHICH IT GETS.  ITS FIRST FUNCTION IS TO     * 03200020
*EXECUTE A CHANNEL PROGRAM TO READ THE FORMAT 4 DSCB AND PICK UP THE  * 03400020
*NUMBER OF ALTERNATES AVAILABLE.  IN ADDITION THIS MODULE ALSO WILL   * 03600020
*COMPUTE THE AMOUNT OF CORE NEEDED TO BUILD A CHANNEL PROGRAM TO READ * 03800020
*HOME ADDRESS, R0, AND THE MAXIMUM NUMBER OF COUNT FIELDS PER TRACK   * 04000020
*+1.  IT GETS ADDITIONAL CORE TO CONTAIN HOME ADDRESS, R0, AND THE    * 04200020
*COUNT FIELDS.  SECOND, IT GENERATES THE CHANNEL PROGRAM.             * 04400020
*                                                                     * 04600020
*ENTRY POINT                                                          * 04800020
*   IGG0860A PICKS UP THE MAXIMUM NUMBER OF COUNT FIELDS PER TRACK    * 05000020
*FROM INFORMATION OBTAINED BY IGC0008F.                               * 05200020
*                                                                     * 05400020
*INPUT                                                                * 05600020
*   CONSISTS OF THE 688-BYTE WORK AREA SET UP BY IGC0008F.            * 05800020
*                                                                     * 06000020
*OUTPUT                                                               * 06200020
*     CONSISTS OF THE WORK AREA AND THE FOLLOWING RETURN CODES        * 06400020
*                                                                       06600020
*                                                                     * 06800020
*         8 - ALL ALTERNATES ASSIGNED                                 * 07000020
*        12 - CORE NOT AVAILABLE                                      * 07200020
*        24 - FORMAT 4 IN ERROR                                       * 07400020
*        28 - USER'S RECORD IS FORMAT4                                * 07600020
*                                                                     * 07800020
*EXTERNAL ROUTINES                                                    * 08000020
*    NONE                                                             * 08200020
*                                                                     * 08400020
*EXITS                                                                * 08600020
*   ERROR - TRANSFERS CONTROL VIA XCTL TO IGG086AE WITH A RETURN      * 08800020
*           CODE IN REGISTER 4.                                       * 09000020
*   NORMAL - TRANSFERS CONTROL VIA XCTL TO IGG0860B                   * 09200020
*                                                                     * 09400020
*TABLES/WORK AREAS                                                    * 09600020
*   THERE ARE TWO WORK AREAS AS FOLLOW                                * 09800020
*                                                                     * 10000020
*        1.  A 688-BYTE WORK AREA INCLUDING THE FORMAT 4 DSCB,        * 10200020
*            MAXIMUM NUMBER OF COUNT FIELDS PER TRACK + 1, A POINTER  * 10400020
*            TO THE USER'S PARAMETER LIST, THE ECB, IOB, DEB, AND     * 10600020
*            DCB CONSTRUCTED BY IGC0008F, A POINTER TO THE COUNT      * 10800020
*            FIELD WORK AREA, AND AN INDICATION OF THE ORIGINAL       * 11000020
*            ERROR TYPE.                                              * 11200020
*        2.  A CHANNEL PROGRAM TO READ HOME ADDRESS AND/OR RECORD     * 11400020
*            ZERO AND COUNTS.  IT ALSO INCLUDES THE SPACE INTO WHICH  * 11600020
*            THE INFORMATION WILL BE READ.                            * 11800020
*                                                                     * 12000020
*ATTRIBUTES                                                           * 12200020
*   REENTRANT, REFRESHABLE                                            * 12400020
*                                                                     * 12600020
*                                                                       12800020
*                                                                       13000020
*********************************************************************** 13200020
*                                                                     * 13400020
*                               EQUATES                               * 13600020
*                                                                     * 13800020
*********************************************************************** 14000020
BIT1     EQU   X'40'                                                    14200020
*********************************************************************** 14400020
*          COMPLETION CODES                                           * 14600020
*********************************************************************** 14800020
CC8      EQU   8                        NO ALTERNATES AVAILABLE         15000020
CC12     EQU   12                       CORE NOT AVAILABLE              15200020
CC24     EQU   24                       ERROR READING FORMAT4 DSCB      15400020
CC28     EQU   28                       FORMAT4 DSCB IN ERROR           15600020
*********************************************************************** 15800020
*          DISPLACEMENT CONSTANTS                                     * 16000020
*********************************************************************** 16200020
D0       EQU   0                                                        16400020
D1       EQU   1                                                        16600020
D2       EQU   2                                                        16800020
D3       EQU   3                                                        17000020
D4       EQU   4                                                        17200020
D7       EQU   7                                                        17400020
D8       EQU   8                                                        17600020
D48      EQU   48                                                       17800020
D255     EQU   255                                                      18000020
*********************************************************************** 18200020
*          LENGTH CONSTANTS                                           * 18400020
*********************************************************************** 18600020
L2       EQU   2                                                        18800020
L3       EQU   3                                                        19000020
L4       EQU   4                                                        19200020
L5       EQU   5                                                        19400020
L8       EQU   8                                                        19600020
L16      EQU   16                                                       19800020
*********************************************************************** 20000020
*                                                                     * 20200020
*********************************************************************** 20400020
BITS3    EQU   3                                                        20600020
BITS4    EQU   4                                                        20800020
CCOFF    EQU   X'00'                    COMMAND CHAIN OFF               21000020
DOG8     EQU   X'D8'                                                    21200020
ENQSW    EQU   X'01'                    ENQUEUE SWITCH                  21400020
FFSW     EQU   X'FF'                                                    21600020
IOEROR   EQU   X'20'                                                    21800020
ONEXT    EQU   X'01'                    ONE EXTENT                      22000020
R0ERR    EQU   X'01'                    R0 ERROR SWITCH                 22200020
TWO55    EQU   255                                                      22400020
X0       EQU   0                                                        22600020
ZEROS    EQU   X'00'                                                    22800020
*                                                                       23000020
*                                                                       23200020
         EJECT                                                          23400020
* REGISTER ASSIGNMENTS                                                  23600020
PARMA    EQU   0                        PARAMETER REGISTER              23800020
PARMB    EQU   1                        PARAMETER REGISTER              24000020
WORKE    EQU   2                        EVEN WORK REGISTER              24200020
WORKO    EQU   3                        ODD WORK REGISTER               24400020
FOUR     EQU   4                        RETURN CODE REGISTER            24600020
FIVE     EQU   5                        WORK REGISTER                   24800020
SIX      EQU   6                        *                               25000020
SEVEN    EQU   7                        *                               25200020
EIGHT    EQU   8                        *                               25400020
NINE     EQU   9                        *                               25600020
TEN      EQU   10                       *                               25800020
AREAREG  EQU   11                       MAIN WORK AREA REGISTER         26000020
BASEREG  EQU   12                       BASE REGISTER                   26200020
SAVEREG  EQU   13                       WORK REGISTER                   26400020
RETREG   EQU   14                       WORK REGISTER                   26600020
ADDREG   EQU   15                       COMPLETION CODE REGISTER        26800020
         SPACE                                                          27000020
         BALR  BASEREG,X0               ESTABLISH OWN                   27200020
         USING BEGIN,BASEREG               ADDRESSABILITY               27400020
         USING WORKDSCT,AREAREG         ESTABLISH ADDRESSABILITY FOR    27600020
*                                       WORK AREA                       27800020
*                                                                       28000020
* ROUTINE TO ENQUEUE THE VTOC ON THIS VOLUME                            28200020
*                                                                       28400020
BEGIN    MVC   MJELNAME(L8),VTOCNAME    MOVE MAJOR QUE NAME TO WORKAREA 28600020
         MVI   ENQAREA,FFSW             SET LAST ENTRY CODE             28800020
         L     SIX,DEBDVMOD             RELOAD                          29000020
         SR    PARMB,PARMB              CLEAR CODE AND RETURN FIELDS    29200020
         STH   PARMB,ENQAREA+D2                                         29400020
*                                                                       29600020
         RESERVE (MJELNAME,MIELNAME,E,6,SYSTEMS),RET=HAVE,             *29800020
               MF=(E,ENQAREA),UCB=DEB+32                                30000020
         OI    SWITCH,ENQSW             ENQUEUE HAS BEEN EXECUTED       30200020
         EJECT                                                          30400020
*                                                                       30600020
*                                                                       30800020
* THIS SECTION READS IN THE DATA PORTION OF THE FORMAT 4 DSCB.          31000020
*                                                                       31200020
         EXCP  IOB                      READ FORMAT 4 DSCB              31400020
         WAIT  1,ECB=ECB                WAIT FOR I/O COMPLETE           31600020
         TM    ECB,IOEROR               CHECK FOR PERMANENT I/OERROR    31800020
         BO    CKALT                    NO, SUCCESSFUL COMPLETION       32000020
*                                                                       32200020
* THIS SECTION ANALYZES THE ERROR IN THE FORMAT4 DSCB READ CHANNEL      32400020
* PROGRAM                                                               32600020
         L     FOUR,USERPARM                                            32800020
         TM    D4(FOUR),BIT1            WAS FULL COUNT SPECIFIED        33000020
         BO    ERR24                    NO,SET RETURN CODE              33200020
         L     FOUR,D4(X0,FOUR)         GET POINTER TO COUNT FIELD      33400020
         CLC   VTOCADR(L5),D0(FOUR)     CHECK FOR USER'S RFCORD IN      33600020
*                                          ERROR BEING FORMAT 4         33800020
         BE    SETCODE                  YES, FORMAT 4 IS USER'S         34000020
*                                          RECORD                       34200020
ERR24    EQU   *                                                        34400020
         LA    FOUR,CC24                SET RETURN CODF - FORMAT 4 IN   34600020
         B     BADCASE                     ERROR                        34800020
SETCODE  LA    FOUR,CC28                SET RETURN CODE FOR RECORD IN   35000020
*                                          ERROR BEING FORMAT 4         35200020
         B     BADCASE                  GO TO ERROR LOAD                35400020
* THIS SECTION CHECKS FOR AVAILABLE ALTERNATES AND PICKS UP THE NUMBER  35600020
* OF AVAILABLE ALTERNATES AND THE ADDRESS OF THE NEXT AVAILABLE ONE     35800020
CKALT    MVI   DEBNMTRK,ZEROS           SET NUMBER OF TRACKS IN DEB     36000020
         MVI   DEBNMTRK+D1,ONEXT           EXTENT TO ONE                36200020
         MVI   DEBDVMOD,DOG8            SET DEB MASK TO ALLOW ALL       36400020
*                                          WRITES BUT INHIBIT ALL SEEKS 36600020
         OC    DS4NOATK(L2),DS4NOATK    CHECK FOR ANY ALTERNATES        36800020
         BNZ   PICKLESS                 YES ALTERNATE TRACKS AVAILABLE  37000020
         LA    FOUR,CC8                 SET COMPLETION CODE FOR NO      37200020
*                                          ALTERNATE TRACKS AVAILABLE   37400020
         B     BADCASE                  GO TO ERROR LOAD                37600020
PICKLESS CLC   DS4NOATK(L2),NUMALT      LESS ALTERNATES THAN 10         37800020
*                                          PER CENT                     38000020
         BNL   FIRST                    NO,MORE ALTERNATES THAN 10      38200020
*                                          PER CENT                     38400020
         MVC   NUMALT(L2),DS4NOATK      USE NUMBER AVAILABLE            38600020
* THIS SECTION CALCULATES CORE REQUIREMENTS FOR A CHANNEL PROGRAM TO    38800020
* READ COUNT FIELDS AND THEN ISSUES A CONDITIONAL GETMAIN               39000020
*                                                                       39200020
FIRST    L     FIVE,SVRBEX              LOAD POINTER TO EXTENDED SVRB   39400020
         LH    WORKO,MAXCOUNT           PICK UP MAXIMUM NUMBER OF       39600020
*                                          COUNT FIELDS PER TRACK+1     39800020
         SLL   WORKO,BITS4              MULTIPLY BY 16                  40000020
         LA    WORKO,D48(X0,WORKO)      ADD 48 BYTES FOR READING        40200020
*                                          HOME ADDRESS AND R0 AND A    40400020
*                                          FLAG FIELD                   40600020
         MVC   D0(L16,FIVE),GETL        MOVE L FORM OF GETMAIN TO SVRB  40800020
*                                          EXTENSION                    41000020
         ST    WORKO,D0(X0,FIVE)        STORE NUMBER BYTES REQUIRED     41200020
         ST    FIVE,D4(X0,FIVE)         STORE ADDRESS OF WHERE ADDRESS  41400020
*                                          IS TO BE RETURNED            41600020
         LR    PARMB,FIVE                                               41800020
         GETMAIN EC,MF=(E,(1))          GETMAIN FOR COUNT FIELD WORK    42000020
*                                          AREA                         42200020
         LTR   ADDREG,ADDREG            CHECK FOR GOTTEN CORE           42400020
         BZ    GOTCORE                  YES, CORE GOTTEN                42600020
         LA    FOUR,CC12                SET RETURN CODE TO 12 FOR       42800020
*                                          CORE NOT AVAILABLE           43000020
BADCASE  MVC   XCTLID(L2),ATLAS06       MOVE ERROR LOAD NAME IN         43200020
         MVC   TTR(L3),TTR6             MOVE ERROR LOAD TTR IN          43400020
         SPACE                                                          43600020
GETOUT   XC    XCTLPTR+D4(L4),XCTLPTR+D4   CLEAR SECOND WORD OF POINTER 43800020
         XCTL  ,MF=(E,(1)),SF=(E,XCTLPTR)                               44000020
         SPACE                                                          44200020
GOTCORE  L     TEN,D0(X0,FIVE)          LOAD ADDRESS OF WORK AREA       44400020
         USING CNTAREA,TEN              ESTABLISH ADDRESSABILITY TO     44600020
*                                          COUNT FIELD WORK AREA        44800020
         ST    WORKO,CNTCORE            SAVE NUMBER BYTES IN COUNT      45000020
*                                          FIELD WORK AREA              45200020
         ST    TEN,COREADDR             SAVE ADDRESS OF THIS AREA       45400020
         LR    FIVE,WORKO                                               45600020
         SPACE                                                          45800020
* THIS SECTION CLEARS THE COUNT FIELD WORK AREA TO ZEROES               46000020
         L     PARMB,USERPARM           PICK UP ADDRESS OF USER'S       46200020
*                                          PARAMETER LIST               46400020
         LR    SEVEN,TEN                                                46600020
CLRCORE  LA    SIX,TWO55                                                46800020
         CR    SIX,WORKO                ARE THERE MORE THAN 255 BYTES   47000020
         BH    LESS255                  NO, BRANCH TO ZERO REMAINING    47200020
*                                          BYTES                        47400020
         BCTR  SIX,X0                   DECREMENT LENGTH BY 1 FOR       47600020
*                                          EXECUTE INSTRUCTION          47800020
         EX    SIX,CLEARS               EXECUTE INSTRUCTION TO CLEAR    48000020
*                                          255 BYTES OF WORK AREA       48200020
         S     WORKO,FULL255            SUBTRACT 255 TO GET REMAINING   48400020
*                                          NUMBER BYTES                 48600020
         LA    SEVEN,D255(X0,SEVEN)     UPDATE POINTER TO AREA          48800020
         B     CLRCORE                  RETURN TO CLEAR CORE            49000020
CLEARS   XC    D0(X0,SEVEN),D0(SEVEN)                                   49200020
LESS255  LTR   WORKO,WORKO              DO ANY UNCLEARED BYTES REMAIN   49400020
         BZ    GETRK                    NO, GET ADDR OF TRACK IN ERROR  49600020
         BCTR  WORKO,X0                 DECREMENT LENGTH BY 1 FOR       49800020
*                                          EXECUTE INSTRUCTION          50000020
         EX    WORKO,CLEARS             CLEAR REMAINING BYTES           50200020
         SPACE                                                          50400020
GETRK    S     FIVE,FULL8               COMPUTE POINTER TO LAST COUNT   50600020
         ALR   FIVE,TEN                    FIELD                        50800020
         MVI   D0(FIVE),FFSW            SET FLAG FOR END OF COUNTS      51000020
         L     FIVE,D4(X0,PARMB)        PICK UP ADDRESS OF USER'S CCHH  51200020
         MVC   DEBSTRCC(L4),D0(FIVE)    INSERT CYLINDER AND TRACK       51400020
         MVC   DEBENDCC(L4),D0(FIVE)       ADDRESS FOR SINGLE TRACK     51600020
*                                          EXTENT                       51800020
         TM    D4(PARMB),BIT1           WAS ONLY CCHH SPECIFIED         52000020
         BZ    SEEKMV                   NO,MOVE IN FULL COUNT           52200020
         MVC   SEEK+D3(L4),D0(FIVE)     MOVE CCHH TO SEEK ADDRESS       52400020
         B     GENCOM                   GENERATE READ HA AND READ R0    52600020
SEEKMV   MVC   SEEK+D3(L5),D0(FIVE)     MOVE CCHHR TO SEEK ADDRESS      52800020
*                                          COUNT                        53000020
         CLI   SEEK+D7,ZEROS            IS ERROR RECORD R0              53200020
         BNE   GENCOM                   NO, GENERATE READ HA AND        53400020
*                                          READ R0                      53600020
         LTR   FIVE,FIVE                WAS THE UTILITY THE CALLER      53800020
         BP    GENCOM                   NO,GENERATE READ HA AND READ R0 54000020
         MVI   ERRTYPE,R0ERR            SET SWITCH TO INDICATE ERROR    54200020
*                                          RECORD IS R0 AND THE UTILITY 54400020
*                                          IS THE CALLER                54600020
         SPACE                                                          54800020
* THIS SECTION RELOCATES THE READ HOME ADDRESS AND READ RECORD ZERO     55000020
* COMMANDS IN THE WORK AREA                                             55200020
GENCOM   LM    SIX,NINE,CCWRHA          LOAD READ HOME ADDRESS AND      55400020
         ALR   SIX,TEN                     READ R0 CCW'S                55600020
         ALR   EIGHT,TEN                                                55800020
         STM   SIX,NINE,CCW21           STORE IN WORK AREA              56000020
         LA    SIX,CCW21                PUT CHANNEL PROGRAM POINTER     56200020
         ST    SIX,IOBSTART                INTO IOB                     56400020
         SPACE                                                          56600020
* THIS SECTION GENERATES READ COUNT COMMANDS FOR THE MAXIMUM NUMBER OF  56800020
* COUNT FIELDS ON A TRACK                                               57000020
GENCOUNT LH    NINE,MAXCOUNT            PICK UP MAXIMUM NUMBER COUNT    57200020
*                                          FIELDS                       57400020
         LR    FIVE,NINE                SET UP COUNTER                  57600020
         LA    SIX,CCW23                PICK UP ADDRESS OF FIRST READ   57800020
*                                          COUNT CCW                    58000020
         SLL   NINE,BITS3               MULTIPLY NUMBER FIELDS BY 8     58200020
         ALR   NINE,SIX                 GET ADDRESS OF FIRST SLOT FOR   58400020
*                                          COUNT                        58600020
         ST    NINE,SAVEADDR            SAVE COUNT FIELD ADDRESS        58800020
         LM    SEVEN,EIGHT,CCWRC        LOAD READ COUNT CCW             59000020
         ALR   SEVEN,NINE               INSERT DATA ADDRESS             59200020
GENPROG  STM   SEVEN,EIGHT,D0(SIX)      STORE CCW IN WORK AREA          59400020
         LA    SIX,D8(X0,SIX)           UPDATE ADDRESS FOR CCW          59600020
         A     SEVEN,FULL8              UPDATE DATA ADDRESS             59800020
         BCT   FIVE,GENPROG             IF COUNTER DOES NOT EQUAL ZERO  60000020
*                                          GENERATE ANOTHER READ COUNT  60200020
         S     SIX,FULL4                                                60400020
         MVI   D0(SIX),CCOFF            TURN OFF CHAIN COMMAND FLAG     60600020
         SPACE                                                          60800020
         MVC   XCTLID(L2),ATLAS03       MOVE NEXT LOAD NAME IN          61000020
         MVC   TTR(L3),TTR3             MOVE NEXT LOAD TTR IN           61200020
         B     GETOUT                   XCTL TO NEXT LOAD               61400020
         SPACE                                                          61600020
GETL     GETMAIN  EC,MF=L               L FORM FOR COUNTS AND TRACK     61800020
VTOCNAME DC    CL8'SYSVTOC'             MAJOR QUE ELEMENT NAME          62000020
*                                          DESCRIPTOR CHANNEL PROGRAM   62200020
CCWRHA   CCW   X'1A',HOMEAD-CNTAREA,X'40',5  READ HOME ADDRESS          62400020
CCWRR0   CCW   X'16',R0-CNTAREA,X'40',16  READ RECORD ZERO              62600020
CCWRC    CCW   X'92',0,X'40',8          READ COUNT                      62800020
FULL255  DC    F'255'                   *                               63000020
FULL8    DC    F'8'                     *                               63200020
FULL4    DC    F'4'                     *                               63400020
         SPACE                                                          63600020
*XCTL BY TTR TABLE                                                      63800020
         SPACE                                                          64000020
         ORG   IGG0860A+1000            FIRST ORG                       64200020
         SPACE                                                          64400020
TTRTABLE EQU   *                                                        64600020
         SPACE                                                          64800020
ATLAS03  DC    C'0B'                    ID OF NEXT ATLAS LOAD           65000020
TTR3     DC    X'00000000'              TTR OF NEXT ATLAS LOAD          65200020
ATLAS06  DC    C'AE'                    ID OF ERROR LOAD                65400020
TTR6     DC    X'00000000'              TTR OF ERROR LOAD               65600020
         DC    X'0000'                  LAST TABLE ENTRY CODE           65800020
         ORG   IGG0860A+1020            SECOND ORG                      66000020
         DC    C'086'                   ATLAS SVC CODE                  66200020
         DC    X'7D'                    RELATIVE TABLE START ADDRESS    66400020
*                                          IN DOUBLE WORDS              66600020
         SPACE                                                          66800020
         EJECT                                                          67000020
WORKDSCT DSECT                                                          67200020
SVRBEX   DS    1F                       SAVE AREA FOR SVRB EXTENSION    67400020
*                                          POINTER                      67600020
DEVTAB   DS    1F                       DEVICE TYPE INDICATOR FROM UCB  67800020
SWITCH   DS    CL1                      LOGIC SWITCH                    68000020
*                                       0 BIT INDICATES CHANNEL         68200020
*                                          PROGRAM NOT RE-EXECUTABLE    68400020
*                                       1 BIT INDICATES WRITE SPECIAL   68600020
*                                          REQUIRED                     68800020
*                                       2 BIT INDICATES TRACK OVERFLOW  69000020
*                                          DATA SET                     69200020
*                                       4 BIT INDICATES NO ALTERNATES   69400020
*                                          AVAILABLE                    69600020
*                                       6 BIT INDICATES AN ERROR ON     69800020
*                                          OTHER THAN THE ORIGINAL      70000020
*                                          ERROR RECORD                 70200020
*                                       7 BIT INDICATES VTOC HAS BEEN   70400020
*                                          ENQUEUED UPON                70600020
NUMBERR  DS    CL2                      NUMBER OF ERROR RECORDS         70800020
VTOCADR  DS    CL5                      VTOC ADDRESS CCHHR              71000020
SPLIT    DS    X'00'                    SPLIT CYLINDER SWITCH           71200020
RETPT    DS    1F                       POINTER TO NEXT ROUTINE         71400020
         DS    0F                                                       71600020
         IECSDSL1 (4)                                                   71800020
TICADDR  DS    1F                       ADDRESS OF TIC CCW IN NEW       72000020
*                                          CHANNEL PROGRAM              72200020
SAVEADDR DS    1F                       ADDRESS OF FIRST COUNT FIELD    72400020
CNTCORE  DS    1F                       NUMBER OF BYTES IN COUNT FIELD  72600020
*                                          WORK AREA                    72800020
COREADDR DS    1F                       ADDRESS OF COUNT FIELD          73000020
*                                          WORK AREA                    73200020
RECADDR  DS    1F                       ADDRESS OF CORE GOTTEN FOR      73400020
*                                          LONGEST RECORD SIZE          73600020
RECCORE  DS    1F                       NUMBER OF BYTES IN THIS AREA    73800020
CNTADDR  DS    1F                       ADDRESS OF COUNT FIELD FOR      74000020
*                                          CCW IN ERROR                 74200020
ERRTYPE  DS    CL1                      TYPE OF ORIGINAL ERROR          74400020
RECNUMB  DS    1F                       R OF ERROR RECORDS              74600020
REGSAVE  DS    5F                       SAVE AREA FOR REGISTERS         74800020
ECB      DS    1F                       ECB                             75000020
IOB      DS    8F                       IOB                             75200020
IOBSTART EQU   IOB+16                   ADDRESS OF CHANNEL PROGRAM      75400020
SEEK     DS    2F                       SEEK ADDRESS                    75600020
DEB      DS    12F                      DEB                             75800020
DEBSTRCC EQU   DEB+38                                                   76000020
DEBENDCC EQU   DEB+42                                                   76200020
DEBNMTRK EQU   DEB+46                                                   76400020
DEBDVMOD EQU   DEB+32                                                   76600020
DEBPTR   DS    F                        DCB SLOT                        76800020
MIELNAME DS    CL6                      VOLUME SERIAL SLOT              77000020
DCB      EQU   DEBPTR-44                                                77200020
R0AREA   DS    2D                       AREA FOR R0                     77400020
DEQAREA  DS    2D                       DEQ TABLE AREA                  77600020
MJELNAME DS    2F                       MAJOR QUEUE NAME AREA           77800020
ENQAREA  DS    2D                       ENQ TABLE AREA                  78000020
USERPARM DS    1F                       POINTER TO USER'S PARM LIST     78200020
NUMALT   DS    1H                       NUMBER OF ALTERNATES TO BE      78400020
*                                          TRIED                        78600020
MAXCOUNT DS    1H                       MAXIMUM NUMBER OF COUNT FIELDS  78800020
*                                          PER TRACK+1                  79000020
XCTLPTR  DS    2F                       PTR TO XCTL WORK AREA TABLE     79200020
XCTLAREA DS    0CL32                                                    79400020
XCTLNM   DS    CL6                      COMMON BYTES OF ATLAS NAME      79600020
XCTLID   DS    CL2                      ID OF ATLAS MODULE              79800020
         DS    CL6                      *                               80000020
TTR      DS    CL3                      TTR OF ATLAS MODULE             80200020
         DS    CL5                      *                               80400020
TTRATTB  DS    CL2                      ATTRIBUTES OF ATLAS - ALL LOADS 80600020
TTRCREQ  DS    CL3                      CORE REQUIREMENT OF ATLAS LOAD  80800020
TTRLNGTH DS    CL2                      LENGTH OF ATLAS LOAD            81000020
         DS    CL3                      *                               81200020
INCRMNT  DS    1F                       INCREMENT FOR READ COUNTS       81400020
PROGADDR DS    1F                       ADDRESS OF NEW CHANNEL PROGRAM  81600020
ALTHA    DS    2F                       ALTERNATE TRACK HOME ADDRESS    81800020
ALTR0    DS    4F                       ALTERNATE TRACK R0              82000020
CCW1     DS    1D                       CCW AREA                        82200020
CCW2     DS    1D                       *                               82400020
CCW3     DS    1D                       *                               82600020
CCW44    DS    1D                       *                               82800020
CCW45    DS    1D                       *                               83000020
CCW56    DS    1D                       *                               83200020
CCW57    DS    1D                       *                               83400020
CCW31    DS    1D                       *                               83600020
CCW32    DS    1D                       *                               83800020
CCW33    DS    1D                       *                               84000020
CCW34    DS    1D                       *                               84200020
CCW35    DS    1D                       *                               84400020
CCW36    DS    1D                       *                               84600020
CCW37    DS    1D                       *                               84800020
CCW38    DS    1D                       *                               85000020
CCW39    DS    1D                       *                               85200020
CHECKHA  DS    2F                       AREA FOR HOME ADDRESS OF        85400020
*                                       ALTERNATE                       85600020
*                                                                       85800020
CVT      DSECT                                                          86000020
UCB      DSECT                                                          86200020
CNTAREA  DSECT                                                          86400020
HOMEAD   DS    2F                       CCW AREA                        86600020
R0       DS    4F                       *                               86800020
CCW21    DS    2F                       *                               87000020
CCW22    DS    2F                       *                               87200020
CCW23    DS    2F                       *                               87400020
         END                                                            87600020
