         TITLE 'IGG0860B - THIRD LOAD MODULE FOR SVC 86'         S20201 00100020
         COPY  LCGASMSW                                                 00150003
IGG0860B CSECT                                                          00200020
*                                           SA66582 = OY02760 = OX03068 00300003
*                                                                       00400020
*          RELEASE 22 DELETIONS/CHANGES                                 00500020
*          RELEASE 21 DELETIONS/CHANGES                                 00600020
*          RELEASE 20 DELETIONS/CHANGES                                 00700020
*0792001000-002000                                               S20201 00750020
* 181000-182000,186000,189000-194000                             M4693  00770020
*                                                                       00800020
*STATUS CHANGE LEVEL 002                                                00900020
*                                                                       01000020
*TITLE IGG0860B - THIRD LOAD MODULE OF SVC 86                         * 01100020
*                                                                     * 01200020
*FUNCTION/OPERATION                                                   * 01300020
*   IGG0860B ESTABLISHES ITS OWN ADDRESSABILITY, THAT OF THE 688-     * 01400020
*BYTE WORK AREA GOTTEN BY IGC0008F, AND THAT OF THE COUNT FIELD WORK  * 01500020
*AREA GOTTEN BY IGG0860A.  IT EXECUTES A CHANNEL PROGRAM TO READ HOME * 01600020
*ADDRESS, RECORD ZERO, AND COUNT FIELDS OF THE TRACK IN ERROR IN      * 01700020
*ORDER TO GET A COMPLETE DESCRIPTION OF THE TRACK.  SHOULD AN ERROR   * 01800020
*BE ENCOUNTERED IN READING A COUNT, NEW CHANNEL PROGRAMS MUST BE      * 01900020
*EXECUTED TO ASSIST IN CALCULATING KEY AND DATA LENGTHS FOR THE       * 02000020
*COUNT.                                                               * 02100020
*                                                                     * 02200020
*ENTRY POINTS                                                         * 02300020
*   IGG0860B GETS A DESCRIPTION OF THE TRACK CONTAINING THE RECORD    * 02400020
*IN ERROR.                                                            * 02500020
*                                                                     * 02600020
*INPUT                                                                * 02700020
*   CONSISTS OF THE WORK AREAS AS COMPLETED BY IGG0860A.              * 02800020
*                                                                     * 02900020
*OUTPUT                                                               * 03000020
*   CONSISTS OF THE WORK AREAS AND THE FOLLOWING RETURN CODES-        * 03100020
*                                                                     * 03200020
*        20 - INVALID I/O SENSE INDICATION                            * 03300020
*        36 - R0-HOME ADDRESS ERRORS ON BAD TRACK                     * 03400020
*        44 - UNRECOVERABLE HARD I/O ERROR IN A COUNT FIELD           * 03500020
*                                                                     * 03600020
*EXTERNAL ROUTINES                                                    * 03700020
*   NONE                                                              * 03800020
*                                                                     * 03900020
*EXITS                                                                * 04000020
*   ERROR - TRANSFERS CONTROL VIA XCTL TO IGG086AE WITH A RETURN      * 04100020
*           CODE IN REGISTER 4                                        * 04200020
*   NORMAL - TRANSFERS CONTROL VIA XCTL TO IGG0860C                   * 04300020
*                                                                     * 04400020
*TABLES/WORK AREAS                                                    * 04500020
*   THERE ARE TWO WORK AREAS AS FOLLOW-                               * 04600020
*                                                                     * 04700020
*        1.  A 688-BYTE WORK AREA INCLUDING THE FORMAT 4 DSCB,        * 04800020
*            MAXIMUM NUMBER OF COUNT FIELDS PER TRACK, A POINTER      * 04900020
*            TO THE USER'S PARAMETER LIST, THE ECB, IOB, DEB, AND     * 05000020
*            DCB CONSTRUCTED BY IGC0008F, A POINTER TO THE COUNT      * 05100020
*            FIELD WORK AREA, AN INDICATION OF THE ORIGINAL ERROR     * 05200020
*            TYPE, XCTL AREA, ADDRESS OF THE FIRST COUNT FIELD,       * 05300020
*            ADDRESS OF FIRST CCW IN NEW PORTION OF THE CHANNEL       * 05400020
*            PROGRAM, AND THE ADDRESS OF THE COUNT FIELD FOR THE      * 05500020
*            CCW IN ERROR.                                            * 05600020
*                                                                     * 05700020
*        2.  A CHANNEL PROGRAM TO READ HOME ADDRESS AND/OR RECORD     * 05800020
*            ZERO AND COUNTS.  IT ALSO INCLUDES THE AREA CONTAINING   * 05900020
*            THIS INFORMATION.                                        * 06000020
*                                                                     * 06100020
*ATTRIBUTES                                                           * 06200020
*   REENTRANT, REFRESHABLE                                            * 06300020
*                                                                     * 06400020
*                                                                       06500020
*                                                                       06600020
*********************************************************************** 06700020
*                                                                     * 06800020
*                               EQUATES                               * 06900020
*                                                                     * 07000020
*********************************************************************** 07100020
OFFSET   EQU   24                       USED TO EQUALIZE IOB-CCW OX3068 07150003
*                                       AND IOB-CSW CCW PTRS     OX3068 07160003
BIT1     EQU   X'40'                                                    07200020
BIT4     EQU   X'08'                                                    07300020
BIT6     EQU   X'02'                                                    07400020
BIT7     EQU   X'01'                                                    07500020
*********************************************************************** 07600020
*          COMPLETION CODES                                           * 07700020
*********************************************************************** 07800020
CC20     EQU   20                       NOT VALID ERROR CONDITION       07900020
CC36     EQU   36                       HA OR R0 ERRORS                 08000020
CC44     EQU   44                       NO ALTERNATE ASSIGNED           08100020
*********************************************************************** 08200020
*          DISPLACEMENT CONSTANTS                                     * 08300020
*********************************************************************** 08400020
D0       EQU   0                                                        08500020
D1       EQU   1                                                        08600020
D2       EQU   2                                                        08700020
D3       EQU   3                                                        08800020
D4       EQU   4                                                        08900020
D6       EQU   6                                                        09000020
D8       EQU   8                                                        09100020
D14      EQU   14                                                       09200020
D16      EQU   16                                                       09300020
D24      EQU   24                                                       09400020
*********************************************************************** 09500020
*          LENGTH CONSTANTS                                           * 09600020
*********************************************************************** 09700020
L1       EQU   1                                                        09800020
L2       EQU   2                                                        09900020
L3       EQU   3                                                        10000020
L4       EQU   4                                                        10100020
L5       EQU   5                                                        10200020
L7       EQU   7                                                        10300020
L8       EQU   8                                                        10400020
L20      EQU   20                                                       10500020
**********************************************************************  10510020
*        DEVICE EQUATES                                              *  10520020
**********************************************************************  10530020
D23051   EQU   X'06'                    2305-1 DEVICE TYPE       S20201 10540020
D23052   EQU   X'07'                    2305-2 DEVICE TYPE       S20201 10550020
D3330    EQU   X'09'                    3330   DEVICE TYPE       S20201 10560020
         AIF   ('&LIB' EQ 'LIB1').X225600                       XL03145 10562003
D3330C   EQU   X'0D'                   3330 C DEVICE            XL03145 10570003
D3340    EQU   X'0A'                   3340 DEVICE              XL03130 10572003
.X225600 ANOP                                                   XL03145 10580003
*********************************************************************** 10600020
*                                                                     * 10700020
*********************************************************************** 10800020
BADTRK   EQU   X'02'                                                    10900020
CSWOK    EQU   X'41'                                                    11000020
EOF      EQU   X'0D'                    END OF FILE                     11100020
ERRS2    EQU   X'02'                                                    11200020
ERRS3    EQU   X'03'                                                    11300020
IOEROR   EQU   X'20'                                                    11400020
OUTEXTNT EQU   X'42'                    OUT OF EXTENT                   11500020
RC1      EQU   X'01'                                                    11600020
RHA      EQU   X'1A'                    READ HOME ADDRESS               11700020
R0ERR    EQU   X'01'                    R0 ERROR SWITCH                 11800020
RR0      EQU   X'16'                    READ RECORD 0                   11900020
SPCT     EQU   X'0F'                    SPACE COUNT                     12000020
TIC      EQU   X'08'                                                    12100020
X0       EQU   0                                                        12200020
ZEROS    EQU   X'00'                                                    12300020
*                                                                       12400020
*                                                                       12500020
         EJECT                                                          12600020
* REGISTER ASSIGNMENTS                                                  12700020
PARMA    EQU   0                        PARAMETER REGISTER              12800020
PARMB    EQU   1                        PARAMETER REGISTER              12900020
WORKE    EQU   2                        EVEN WORK REGISTER              13000020
WORKO    EQU   3                        ODD WORK REGISTER               13100020
FOUR     EQU   4                        RETURN CODE REGISTER            13200020
FIVE     EQU   5                        WORK REGISTER                   13300020
SIX      EQU   6                        *                               13400020
SEVEN    EQU   7                        *                               13500020
EIGHT    EQU   8                        *                               13600020
NINE     EQU   9                        *                               13700020
TEN      EQU   10                       *                               13800020
AREAREG  EQU   11                       MAIN WORK AREA REGISTER         13900020
BASEREG  EQU   12                       BASE REGISTER                   14000020
SAVEREG  EQU   13                       WORK REGISTER                   14100020
RETREG   EQU   14                       WORK REGISTER                   14200020
ADDREG   EQU   15                       COMPLETION CODE REGISTER        14300020
         BALR  BASEREG,X0               ESTABLISH                       14400020
         USING EXPROG,BASEREG              OWN ADDRESSABILITY           14500020
         USING WORKDSCT,AREAREG         ESTABLISH ADDRESSABILITY FOR    14600020
*                                          WORK AREA                    14700020
         USING CNTAREA,TEN              ESTABLISH ADDRESSABILITY FOR    14800020
*                                          COUNT FIELD WORK AREA        14900020
* THIS SECTION EXECUTES THE CHANNEL PROGRAM                             15000020
EXPROG   BAL   EIGHT,SETBLKS            CLEAR ECB AND IOB               15100020
         EXCP  IOB                      READ COUNTS                     15200020
         WAIT  1,ECB=ECB                WAIT FOR I/O TO COMPLETE        15300020
         TM    HOMEAD,BADTRK            CHECK FOR FLAGGED        M4693  15320020
*                                       PRIMARY                  M4693  15340020
         BO    ISALT                    YES, PRIMARY TRACK IS    M4693  15360020
*                                       BAD                      M4693  15380020
MAKECHK  CLI   ECB,OUTEXTNT             IS TERMINATION DUE TO OUT OF    15400020
*                                          EXTENT                       15500020
         BE    OUTEXT                   YES                             15600020
         CLI   ECB,CSWOK                ARE CSW CONTENTS USEFUL         15700020
         BNE   SETCODE                  NO, SET ERROR CODE              15800020
         LA    SIX,IOB                  PICK UP ADDRESS OF IOB          15900020
         L     FIVE,IOBFLAG3            GET A(CCW) IN ERROR             16000020
         LA    FIVE,D0(X0,FIVE)         CLEAR HIGH ORDER BYTE           16100020
         S     FIVE,FULL8                                               16200020
         SPACE                                                          16300020
*A TEST IS MADE TO SEE IF THE ERROR OCCURED IN ATLAS' CHANNEL PROGRAM.  16400020
*IF IT DID NOT HOME ADDRESS OR R0 IS IN ERROR.                          16500020
         L     SEVEN,IOBSTART           GET START ADDRESS OF CHANNEL    16600020
*                                          PROGRAM                      16700020
         LA    SEVEN,D0(X0,SEVEN)       CLEAR HOGH ORDER BYTE           16800020
         CLR   FIVE,SEVEN               IS CCW ADDR GREATER THAN IOB    16900020
*                                          START ADDRESS                17000020
         BNL   CHECKHI                  YES, CHECK HIGH LIMIT           17100020
TESTADDR LA    SEVEN,CCW31              GET BEGINNING ADDR OF POSSIBLE  17200020
*                                          NEW CHANNEL PROGRAM          17300020
         CLR   FIVE,SEVEN                                               17400020
         BL    ERRCODE                  ERROR NOT IN ATLAS' CHANNEL     17500020
*                                          PROGRAM                      17600020
         LA    SEVEN,CHECKHA            CHECK HIGH LIMIT                17700020
         CLR   FIVE,SEVEN                                               17800020
         BNL   ERRCODE                  ERROR NOT IN ATLAS' CHANNEL     17900020
*                                          PROGRAM                      18000020
         B     TESTERR                  ERROR IN ATLAS CHANNEL   M4693  18100020
*                                       PROGRAM                  M4693  18200020
CHECKHI  L     SEVEN,SAVEADDR           LOAD ADDRESS OF FIRST COUNT     18300020
*                                          FIELD                        18400020
         CLR   FIVE,SEVEN               CHECK HIGH LIMIT                18500020
         BL    TESTERR                  CHECK IF ERROR IS IN NEW M4693  18560020
*                                       CHANNEL PROGRAM                 18620020
         B     TESTADDR                 WAS ERROR IN NEW CHANNEL PROG   18700020
         SPACE                                                          18800020
ISALT    EQU   *                        GET DESCRITPTION OF      M4693  19000020
*                                       ALTERNATE                M4693  19200020
         L     SEVEN,IOBSTART           START OF CCWS           OX03068 19250003
         L     FIVE,IOBFLAG3            CSW CCW PTR             OX03068 19300003
         LA    FIVE,0(FIVE)             ZERO HIGH BYTE          OX3068  19350003
         LA    SEVEN,OFFSET(SEVEN)      EQUALIZE PTRS           OX3068  19400003
         CLR   FIVE,SEVEN               COMPARE PTRS            OX3068  19450003
         BL    ERRCODE                  BRCH IF HA OR R0 ERR    OX3068  19460003
         MVC   SEEK+D3(L5),R0           MOVE ADDRESS OF ALTERNATE TO    19500020
*                                          SEEK ADDRESS                 19600020
         MVC   DEBSTRCC(L4),R0          SET UP DEB EXTENTS              19700020
         MVC   DEBENDCC(L4),R0                                          19800020
         B     EXPROG                   EXECUTE CHANNEL PROGRAM TO GET  19900020
*                                          DESCRIPTION OF ALTERNATE     20000020
         SPACE                                                          20100020
TESTERR  TM    IOBCSWST,BIT6            DID UNIT CHECK OCCUR            20200020
         BNO   SETCODE                  NO, SET ERROR CODE              20300020
         TM    SENSE0(SIX),BIT4         CHECK IOB SENSE BYTE0 FOR A     20400020
*                                          DATA CHECK                   20500020
         BO    TESTCCW                  YES, DATA CHECK                 20600020
         TM    SENSE1(SIX),BIT6         CHECK FOR MISSING ADDRESS       20700020
*                                          MARKER                       20800020
         BZ    SETCODE                  NOT MISSING, SET ERROR CODE     20900020
         CLI   DEVTAB+D3,D3330          CHECK FOR 3330           S20201 20930020
         BE    SETCODE                  YES, INVALID IOB SENSE   S20201 20960020
         AIF   ('&LIB' EQ 'LIB1').X225601                       XL03145 20962003
         CLI   DEVTAB+D3,D3330C        IS IT A 3330 C           XL03145 20970003
         BE    SETCODE                 YES, INVALID IOB SENSE   XL03145 20980003
         CLI   DEVTAB+D3,D3340         IS IT A 3340             XL03130 20982003
         BE    SETCODE                 YES,INVALID IOB SENSE    XL03130 20984003
.X225601 ANOP                                                   XL03145 20990003
         TM    SENSE1(SIX),BIT4         CHECK FOR NOT REGULAR MISSING   21000020
*                                          ADDRESS MARKER               21100020
         BO    SETCODE                  YES, NOT NORMAL, SET ERROR CODE 21200020
         TM    SENSE0(SIX),BIT7         CHECK FOR BALLAST CELL FOUND    21300020
         BZ    TESTCCW                  SITUATION UNDER CONTROL         21400020
SETCODE  LA    FOUR,CC20                SET COMPLETION CODE TO REFLECT  21500020
*                                          NOT VALID IOB SENSE          21600020
*                                          INDICATION                   21700020
BADCASE  MVC   XCTLID(L2),ATLAS06       MOVE ERROR LOAD NAME IN         21800020
         MVC   TTR(L3),TTR6             MOVE ERROR LOAD TTR IN          21900020
         SPACE                                                          22000020
GETOUT   XC    XCTLPTR+D4(L4),XCTLPTR+D4 CLEAR SECOND WORD OF POINTER   22100020
         XCTL  ,MF=(E,(1)),SF=(E,XCTLPTR)                               22200020
         SPACE                                                          22300020
TESTCCW  CLI   D0(FIVE),RHA             IS COMMAND A SINGLE TRACK READ  22400020
*                                         HA                            22500020
         BE    ERRCODE                  YES, HOME ADDRESS ERROR         22600020
         CLI   D0(FIVE),RR0             IS COMMAND A SINGLE TRACK       22700020
*                                         READ R0                       22800020
         LA    SEVEN,PICKUP             LOAD NEXT BRANCH ADDRESS        22900020
         BNE   CHKNUMB                  CHECK FOR THREE ERROR           23000020
*                                          RECORDS                      23100020
         BAL   SEVEN,SETCNT             UPDATE COUNT OF ERRORS          23200020
         MVI   RECNUMB+D1,ZEROS         SAVE ERROR RECORD NUMBER        23300020
         CLI   ERRTYPE,R0ERR            DID UTILITY PASS R0             23400020
         BNE   ERRCODE                  NO,ERROR IN R0                  23500020
*                                       THE SVC HAS INSUFFICIENT        23600020
*                                          DATA TO HANDLE R0 ERROR      23700020
         LM    SIX,SEVEN,CCWRHA         LOAD READ HOME ADDRESS CCW      23800020
         ALR   SIX,TEN                                                  23900020
         STM   SIX,SEVEN,CCW22          STORE IN SECOND CCW SLOT        24000020
         LA    SIX,CCW22                PUT POINTER TO CHANNEL PROGRAM  24100020
         ST    SIX,IOBSTART                INTO IOB                     24200020
         B     EXPROG                   BRANCH TO GENERATE READ COUNTS  24300020
CHKNUMB  CLI   NUMBERR+D1,ERRS3         HAVE THERE BEEN THREE           24400020
*                                          ERROR RECORDS                24500020
         BNE   SETCNT                   NO, UPDATE COUNT OF ERRORS      24600020
         B     INVALID                  SET RETURN CODE TO 44 FOR MORE  24700020
*                                          THAN THREE ERROR RECORDS     24800020
*                                          ENCOUNTERED                  24900020
SETCNT   IC    NINE,NUMBERR+D1          PICK UP NUMBER ERROR RECORDS    25000020
*                                          ENCOUNTERED                  25100020
         A     NINE,FULL1               INCREMENT BY ONE                25200020
         STC   NINE,NUMBERR+D1                                          25300020
         BR    SEVEN                    CONTINUE PROCESSING             25400020
         SPACE                                                          25500020
PICKUP   L     SEVEN,D0(X0,FIVE)        PICK UP ADDRESS OF COUNT FIELD  25600020
*                                          FOR CCW IN ERROR             25700020
         ST    SEVEN,CNTADDR            SAVE ADDRESS OF LAST COUNT      25800020
*                                          FIELD                        25900020
         L     PARMB,USERPARM           PICK UP POINTER TO USER'S       26000020
*                                          PARAMETER LIST               26100020
         LR    WORKE,PARMB              SAVE POINTER TO LIST            26200020
         L     PARMB,D4(X0,PARMB)       PICK UP POINTER TO USER'S       26300020
*                                          COUNT                        26400020
         MVC   D0(L4,SEVEN),D0(PARMB)   MOVE USER'S COUNT TO COUNT      26500020
*                                          FIELD AREA                   26600020
         LR    SIX,FIVE                                                 26700020
         S     SIX,FULL8                PICK UP ADDRESS OF PREVIOUS CCW 26800020
         CLI   D0(SIX),RR0              WAS PREVIOUS COMMAND READ R0    26900020
         BE    SETONE                   YES INSERT RECORD NUMBER        27000020
         CLI   D0(SIX),RHA              WAS PREVIOUS COMMAND A RD HA    27100020
         BNE   GETNUMB                  NO,GET RECORD NUMBER            27200020
SETONE   MVI   D4(SEVEN),RC1            INSERT RECORD NUMBER = 1        27300020
         CLI   NUMBERR+D1,ERRS2         WAS RO IN ERROR                 27400020
         BNE   FIRSTERR                 NO,R1 IS THE FIRST ERROR        27500020
         MVI   RECNUMB+D2,RC1           STORE RECORD NUMBER             27600020
         B     ISITEOF                  TEST FOR ZERO DATA LENGTH       27700020
FIRSTERR MVI   RECNUMB+D1,RC1           SAVE RECORD NUMBER              27800020
         B     ISITEOF                  TEST FOR END OF FILE            27900020
GETNUMB  SR    SIX,SIX                  CLEAR REGISTER                  28000020
         LR    NINE,SEVEN               GET ADDRESS OF RECORD NUMBER    28100020
         S     NINE,FULL4                  FIELD IN PREVIOUS COUNT      28200020
         IC    SIX,D0(X0,NINE)          PICK UP NUMBER                  28300020
         LA    SIX,D1(X0,SIX)           INCREMENT BY ONE TO GET NUMBER  28400020
         STC   SIX,D4(X0,SEVEN)            OF RECORD IN ERROR           28500020
         XR    FOUR,FOUR                CLEAR REGISTER                  28600020
         IC    FOUR,NUMBERR+D1          PICK UP NUMBER OF ERRORS        28700020
         LA    NINE,RECNUMB             DETERMINE DISPLACEMENT INTO     28800020
         ALR   FOUR,NINE                   ERROR RECORD SAVE AREA       28900020
         STC   SIX,D0(FOUR)             SAVE NUMBER OF ERROR RECORD     29000020
ISITEOF  SR    SIX,SIX                  CLEAR REGISTER                  29100020
         CH    SIX,D6(X0,SEVEN)         IS DATA LENGTH EQUAL TO ZERO    29200020
         LA    FOUR,SETREAD             REGULAR PROCESS                 29300020
         BNE   SETUP                    NO, REGULAR COUNT ERROR         29400020
         TM    D4(WORKE),BIT1           WAS A FULL COUNT FIELD GIVEN    29500020
         BO    INVALID                  NO, MAY BE EOF ERROR            29600020
         XR    FOUR,FOUR                CLEAR REGISTER                  29700020
         IC    FOUR,NUMBERR+D1          PICK UP NUMBER OF ERROR RECORDS 29800020
         LA    NINE,RECNUMB                                             29900020
         ALR   FOUR,NINE                GET POINTER TO LAST ERROR       30000020
*                                          RECORD NUMBER                30100020
         CLC   D4(L1,PARMB),D0(FOUR)    IS THIS USER'S ERROR RECORD     30200020
         BNE   INVALID                  NO, CAN'T HANDLE EOF            30300020
         LA    FOUR,SETEOF              ADDRESS FOR ROUTINE TO SET EOF  30400020
SETUP    BAL   EIGHT,SETBLKS            BRANCH TO CLEAR CONTROL BLOCKS  30500020
         LM    SIX,SEVEN,CCWTIC         REPLACE READ COUNT COMMAND WITH 30600020
         ALR   SIX,AREAREG                 A TIC TO NEW CHANNEL PROGRAM 30700020
         L     EIGHT,INCRMNT            GET POINTER TO NEW CHANNEL      30800020
         ALR   SIX,EIGHT                   PROGRAM                      30900020
         ST    SIX,PROGADDR             SAVE ADDRESS OF NEW CHANNEL     31000020
*                                          PROGRAM                      31100020
         MVC   D4(L20,SIX),CCWSPACE+D4  MOVE NEW CHANNEL PROGRAM        31200020
*                                          TO WORK AREA                 31300020
         L     WORKO,TICADDR            GET ADDR OF PREVIOUS            31400020
*                                          LAST TIC                     31500020
         LR    NINE,FIVE                                                31600020
         LA    FIVE,D8(X0,FIVE)         PUT ADDRESS OF CCW FOLLOWING    31700020
         ST    FIVE,D16(X0,SIX)            ERROR CCW IN RETURN TIC      31800020
         LA    FIVE,D16(X0,SIX)         GET ADDRESS OF LAST TIC         31900020
         MVI   D0(FIVE),TIC             INSERT COMMAND CODE IN TIC CCW  32000020
         ST    FIVE,TICADDR             SAVE ADDRESS OF LAST TIC CCW    32100020
         LA    EIGHT,D24(X0,EIGHT)      UPDATE THE INCREMENT            32200020
         ST    EIGHT,INCRMNT                                            32300020
         STM   SIX,SEVEN,D0(NINE)       REPLACE READ COUNT CCW WITH     32400020
*                                          TIC TO NEW CHANNEL PROGRAM   32500020
         S     NINE,FULL8               GET POINTER TO CCW              32600020
*                                          PREVIOUS TO ERROR CCW        32700020
         CLI   D0(NINE),TIC             IS CCW PREVIOUS TO ERROR        32800020
*                                          CCW A TIC COMMAND            32900020
         BNE   NOTIC                    NO,NOT A DOUBLE TIC             33000020
         S     WORKO,FULL8                                              33100020
         MVC   D0(L4,WORKO),D8(NINE)    TIC TO SPACE COUNT CCW          33200020
NOTIC    L     SEVEN,CNTADDR            PICK UP ADDRESS OF ERROR COUNT  33300020
*                                           FIELD                       33400020
         A     SEVEN,FULL5              GET ADDRESS OF KEY AND DATA     33500020
*                                          LENGTH FIELDS                33600020
         ST    SEVEN,D0(X0,SIX)         COMPLETE SPACE COUNT COMMAND    33700020
         MVI   D0(SIX),SPCT             INSERT COMMAND CODE             33800020
         BR    FOUR                     BRANCH TO NEXT ROUTINE          33900020
SETREAD  SR    WORKE,WORKE              CLEAR WORK REGISTER             34000020
         IC    WORKE,D0(X0,SEVEN)       PICK UP KEY LENGTH              34100020
         LA    SEVEN,D1(X0,SEVEN)       GET ADDRESS OF DATA LENGTH      34200020
         LH    WORKO,D0(X0,SEVEN)       PICK UP DATA LENGTH             34300020
         AR    WORKE,WORKO              GET KEY + DATA LENGTH           34400020
         STH   WORKE,D14(X0,SIX)        INSERT BYTE COUNT INTO READ     34500020
*                                           KEY DATA CCW                34600020
         EXCP  IOB                      READ COUNT WITH READ KD         34700020
         WAIT  1,ECB=ECB                WAIT FOR I/O TO COMPLETE        34800020
         B     TESTECB                  CHECK CONDITION OF ECB          34900020
SETEOF   S     SEVEN,FULL5              GET ADDRESS OF ERROR COUNT      35000020
         MVC   D0(L8,SEVEN),D0(PARMB)   MOVE IN USER'S COUNT            35100020
         B     REPLCCW                  CHANGE READ KEY/DATA TO TIC     35200020
SETBLKS  XC    ECB(L4),ECB              ZERO ECB                        35300020
         XC    IOBSENS0(L2),IOBSENS0    ZERO SENSE BYTES                35400020
         XC    IOBCSW(L7),IOBCSW        ZERO LOW ORDER BYTES OF IOB CSW 35500020
         BR    EIGHT                    RETURN                          35600020
         SPACE                                                          35700020
TESTECB  TM    ECB,IOEROR               TEST FOR PERMANENT I/O ERROR    35800020
         BZ    CHKLAST                  YES, PERMANENT I/O ERROR        35900020
         SPACE                                                          36000020
REPLCCW  MVC   D8(L8,SIX),D0(FIVE)      REPLACE READ KEY/DATA           36100020
*                                          WITH TIC                     36200020
         B     EXPROG                   GO TO ORIGINAL EXCP             36300020
         SPACE                                                          36400020
CHKLAST  EQU   *                                                        36500020
         CLC   IOBCSW(L3),TICADDR+D1    COMPARE ADDRESS OF LAST CCW     36600020
*                                          WITH ADDRESS OF LAST TIC CCW 36700020
         BNE   INVALID                  IF NOT EQUAL, SET ERROR CODE    36800020
CHKREC   L     PARMB,USERPARM                                           36900020
         TM    D4(PARMB),BIT1           WAS A FULL COUNT FIELD GIVEN    37000020
         BO    INVALID                  UNRECOVERABLE ERROR IN KDD OF   37100020
*                                          COUNT FIELD                  37200020
         L     FOUR,D4(X0,PARMB)        PICK UP ADDRESS OF CCHH         37300020
*                                           PARAMETER                   37400020
         XR    SEVEN,SEVEN              CLEAR REGISTER                  37500020
         LA    EIGHT,RECNUMB            GET POINTER TO R OF LAST        37600020
         IC    SEVEN,NUMBERR+D1            ERROR RECORD                 37700020
         ALR   SEVEN,EIGHT                                              37800020
         CLC   D4(L1,FOUR),D0(SEVEN)    WAS THE LAST ERROR RECORD THE   37900020
*                                          ORIGINAL RECORD IN ERR       38000020
         BNE   INVALID                  NO, SET ERROR CODE              38100020
         L     SEVEN,CNTADDR            LOAD ADDR OF COUNT FIELD        38200020
         MVC   D0(L8,SEVEN),D0(FOUR)    MOVE IN USER'S COUNT            38300020
         B     REPLCCW                  BRANCH TO REPLACE READ KEY/DATA 38400020
*                                          CCW WITH TIC                 38500020
         SPACE                                                          38600020
ERRCODE  LA    FOUR,CC36                SET COMPLETION CODE TO 36 FOR   38700020
*                                          HOME ADDRESS OR R0 ERROR     38800020
         B     BADCASE                  GO TO ERROR LOAD                38900020
INVALID  LA    FOUR,CC44                SET COMPLETION CODE FOR ERROR   39000020
*                                          IN EOF RECORD OR KDD OF      39100020
*                                          COUNT FIELD                  39200020
         B     BADCASE                  EXIT TO ERROR LOAD              39300020
OUTEXT   MVC   XCTLID(L2),ATLAS04       MOVE NEXT LOAD NAME IN          39400020
         MVC   TTR(L3),TTR4             MOVE NEXT LOAD TTR IN           39500020
         SR    FOUR,FOUR                SET COMPLETION CODE TO ZERO     39600020
         B     GETOUT                   EXIT TO NEXT LOAD               39700020
SENSE0   EQU   2                                                        39800020
SENSE1   EQU   3                                                        39900020
STATUS0  EQU   12                       FIRST CSW STATUS BYTE           40000020
CCWSPACE CCW   X'0F',0,X'40',3          SPACE COUNT                     40100020
CCWRKD   CCW   X'0E',CCW31-SVRBEX,X'10',0  READ KEY/DATA                40200020
CCWTIC   CCW   X'08',CCW31-SVRBEX,X'40',0  TIC                          40300020
CCWRHA   CCW   X'1A',HOMEAD-CNTAREA,X'40',5  READ HOME ADDRESS          40400020
CCWRR0   CCW   X'16',R0-CNTAREA,X'40',16  READ RECORD ZERO              40500020
CCWRC    CCW   X'92',0,X'40',8          READ COUNT                      40600020
FULL8    DC    F'8'                     *                               40700020
FULL1    DC    F'1'                     *                               40800020
FULL4    DC    F'4'                     *                               40900020
FULL5    DC    F'5'                     *                               41000020
         SPACE                                                          41100020
*XCTL BY TTR TABLE                                                      41200020
         SPACE                                                          41300020
         ORG   IGG0860B+1000            FIRST ORG                       41400020
         SPACE                                                          41500020
TTRTABLE EQU   *                                                        41600020
ATLAS04  DC    C'0C'                    ID OF NEXT ATLAS LOAD           41700020
TTR4     DC    X'00000000'              TTR OF NEXT ATLAS LOAD          41800020
ATLAS06  DC    C'AE'                    ID OF ERROR LOAD                41900020
TTR6     DC    X'00000000'              TTR OF ERROR LOAD               42000020
         DC    X'0000'                  LAST TABLE ENTRY CODE           42100020
         ORG   IGG0860B+1020            SECOND ORG                      42200020
         DC    C'086'                   ATLAS SVC CODE                  42300020
         DC    X'7D'                    RELATIVE TABLE START ADDRESS    42400020
*                                          IN DOUBLE WORDS              42500020
WORKDSCT DSECT                                                          42600020
SVRBEX   DS    1F                       SAVE AREA FOR SVRB EXTENSION    42700020
*                                       POINTER                         42800020
DEVTAB   DS    1F                       DEVICE TYPE INDICATOR FROM UCB  42900020
SWITCH   DS    CL1                      LOGIC SWITCH                    43000020
*                                       0 BIT INDICATES CHANNEL         43100020
*                                          PROGRAM NOT RE-EXECUTABLE    43200020
*                                       1 BIT INDICATES WRITE SPECIAL   43300020
*                                          REQUIRED                     43400020
*                                       2 BIT INDICATES TRACK OVERFLOW  43500020
*                                          DATA SET                     43600020
*                                       7 BIT INDICATES VTOC HAS BEEN   43700020
*                                       ENQUEUED UPON                   43800020
NUMBERR  DS    CL2                      NUMBER OF ERROR RECORDS         43900020
VTOCADR  DS    CL5                      VTOC ADDRESS CCHHR              44000020
SPLIT    DS    X'00'                    SPLIT CYLINDER SWITCH           44100020
RETPT    DS    1F                       POINTER TO NEXT ROUTINE         44200020
         DS    0F                                                       44300020
         IECSDSL1 (4)                                                   44400020
TICADDR  DS    1F                       ADDRESS OF TIC CCW IN NEW       44500020
*                                          CHANNEL PROGRAM              44600020
SAVEADDR DS    1F                       ADDRESS OF FIRST COUNT FIELD    44700020
CNTCORE  DS    1F                       NUMBER BYTES IN COUNT FIELD     44800020
*                                          WORK AREA                    44900020
COREADDR DS    1F                       ADDRESS OF COUNT FIELD          45000020
*                                          WORK AREA                    45100020
RECADDR  DS    1F                       ADDRESS OF CORE GOTTEN FOR      45200020
*                                          LONGEST RECORD SIZE          45300020
RECCORE  DS    1F                       NUMBER OF BYTES IN THIS AREA    45400020
DDNAME   DS    1D                      DDNAME SAVE AREA         XL03130 45450003
DEVINFO  DS    5F                      DEVICE INFO              XL03130 45460003
CNTADDR  DS    1F                       ADDRESS OF COUNT FIELD FOR      45500020
*                                          CCW IN ERROR                 45600020
ERRTYPE  DS    CL1                      TYPE OF ORIGINAL ERROR          45700020
RECNUMB  DS    1F                       R OF ERROR RECORDS              45800020
REGSAVE  DS    5F                       SAVE AREA FOR REGISTERS         45900020
ECB      DS    1F                       ECB                             46000020
IOB      DS    8F                       IOB                             46100020
IOBSENS0 EQU   IOB+2                                                    46200020
IOBFLAG3 EQU   IOB+8                                                    46300020
IOBCSW   EQU   IOB+9                                                    46400020
IOBCSWST EQU   IOB+12                                                   46500020
IOBSTART EQU   IOB+16                                                   46600020
SEEK     DS    2F                       SEEK ADDRESS                    46700020
DEB      DS    12F                      DEB                             46800020
DEBSTRCC EQU   DEB+38                                                   46900020
DEBENDCC EQU   DEB+42                                                   47000020
DEBPTR   DS    F                        DCB SLOT                        47100020
MIELNAME DS    CL6                      VOLUME SERIAL SLOT              47200020
DCB      EQU   DEBPTR-44                                                47300020
R0AREA   DS    2D                       AREA FOR R0                     47400020
DEQAREA  DS    2D                       DEQ TABLE AREA                  47500020
MJELNAME DS    2F                       MAJOR QUEUE NAME AREA           47600020
ENQAREA  DS    2D                       ENQ TABLE AREA                  47700020
USERPARM DS    1F                       POINTER TO USER'S PARM LIST     47800020
NUMALT   DS    1H                       NUMBER OF ALTERNATES TO BE      47900020
*                                         TRIED                         48000020
MAXCOUNT DS    1H                       MAXIMUM NUMBER OF COUNT FIELDS  48100020
*                                          PER TRACK+1                  48200020
XCTLPTR  DS    2F                       PTR TO XCTL WORK AREA TABLE     48300020
XCTLAREA DS    0CL32                                                    48400020
XCTLNM   DS    CL6                      COMMON BYTES OF ATLAS NAME      48500020
XCTLID   DS    CL2                      ID OF ATLAS MODULE              48600020
         DS    CL6                      *                               48700020
TTR      DS    CL3                      TTR OF ATLAS MODULE             48800020
         DS    CL5                      *                               48900020
TTRATTB  DS    CL2                      ATTRIBUTES OF ATLAS - ALL LOADS 49000020
TTRCREQ  DS    CL3                      CORE REQUIREMENT OF ATLAS LOAD  49100020
TTRLNGTH DS    CL2                      LENGTH OF ATLAS LOAD            49200020
         DS    CL3                      *                               49300020
INCRMNT  DS    1F                       CCW POINTER                     49400020
PROGADDR DS    1F                       ADDRESS OF NEW CHANNEL PROGRAM  49500020
ALTHA    DS    2F                       ALTERNATE TRACK HOME ADDRESS    49600020
ALTR0    DS    4F                       ALTERNATE TRACK R0              49700020
CCW1     DS    1D                       CCW AREA                        49800020
CCW2     DS    1D                       *                               49900020
CCW3     DS    1D                       *                               50000020
CCW44    DS    1D                       *                               50100020
CCW45    DS    1D                       *                               50200020
CCW56    DS    1D                       *                               50300020
CCW57    DS    1D                       *                               50400020
CCW31    DS    1D                       *                               50500020
CCW32    DS    1D                       *                               50600020
CCW33    DS    1D                       *                               50700020
CCW34    DS    1D                       *                               50800020
CCW35    DS    1D                       *                               50900020
CCW36    DS    1D                       *                               51000020
CCW37    DS    1D                       *                               51100020
CCW38    DS    1D                       *                               51200020
CCW39    DS    1D                       *                               51300020
CHECKHA  DS    2F                       AREA FOR HOME ADDRESS OF        51400020
*                                       ALTERNATE                       51500020
FLAG     DS    1F                       TO BE REMOVED                   51600020
*                                                                       51700020
CVT      DSECT                                                          51800020
UCB      DSECT                                                          51900020
CNTAREA  DSECT                                                          52000020
HOMEAD   DS    2F                       CCW AREA                        52100020
R0       DS    4F                       *                               52200020
CCW21    DS    2F                       *                               52300020
CCW22    DS    2F                       *                               52400020
CCW23    DS    2F                       *                               52500020
         END                                                            52600020
