         TITLE 'IGG0860C - FOURTH LOAD MODULE FOR SVC 86'        S20201 00200020
IGG0860C CSECT                                                          00400020
*                                                                       00600020
*                                                                       00800020
*                                                                       01000020
*          RELEASE 22 DELETIONS/CHANGES                                 01200020
*          RELEASE 21 DELETIONS/CHANGES                                 01400020
*          RELEASE 20 DELETIONS/CHANGES                                 01600020
*0791002000-004000                                               S20201 01700020
*                                                                       01800020
*STATUS CHANGE LEVEL 002                                                02000020
*                                                                       02200020
*TITLE 'IGG0860C' - FOURTH LOAD MODULE OF SVC 86                      * 02400020
*FUNCTION/OPERATION                                                   * 02600020
*   IGG0860C - ESTABLISHES ITS OWN ADDRESSABILITY, THAT OF THE 688-   * 02800020
*BYTE WORK AREA, AND THAT OF THE WORK AREA FOR COUNT FIELDS.  BEING   * 03000020
*THE FOURTH LOAD MODULE OF SVC 86, THIS MODULE HAS THREE MAJOR        * 03200020
*FUNCTIONS -                                                          * 03400020
*                                                                     * 03600020
*        1.  CHECKS FOR A COUNT FIELD ERROR ON THE LAST RECORD        * 03800020
*            ON A TRACK                                               * 04000020
*        2.  COMPUTES SIZE OF LARGEST RECORD ON THE BAD TRACK         * 04200020
*            AND ISSUES A CONDITIONAL GETMAIN FOR THE LARGEST         * 04400020
*            RECORD                                                   * 04600020
*        3.  WRITES HA AND R0 ON THE CHOSEN ALTERNATE                 * 04800020
*                                                                     * 05000020
*ENTRY POINTS                                                         * 05200020
*   IGG0860C - CHECKS FOR ENTRANCE DUE TO NORMAL PROCESSING OR RETURN * 05400020
*FROM IGG0860D.                                                       * 05600020
*                                                                     * 05800020
*INPUT                                                                * 06000020
*   INCLUDED IN THE INPUT ARE A 688-BYTE MAIN WORK AREA AND A WORK    * 06200020
*AREA FOR CHANNEL PROGRAMS AND COUNT FIELDS FOR THE BAD TRACK         * 06400020
*                                                                     * 06600020
*OUTPUT                                                               * 06800020
*   THE OUTPUT CONSISTS OF THE 688-BYTE MAIN WORK AREA, A WORK AREA   * 07000020
*FOR CHANNEL PROGRAMS AND COUNT FIELDS FOR THE BAD TRACK AND A WORK   * 07200020
*AREA FOR THE LARGEST RECORD ON THE BAD TRACK.  IN AN ERROR SITUATION * 07400020
*ONE OF THE FOLLOWING RETURN CODES WILL BE SET                        * 07600020
*        12 - CORE NOT AVAILABLE                                      * 07800020
*        16 - I/O ERROR ON ALTERNATE AFTER N TRIES                    * 08000020
*        32 - ERROR IN COUNT FIELD OF LAST RECORD ON THE TRACK        * 08200020
*        36 - SEARCH HA ERROR ON ALTERNATE                            * 08400020
*                                                                     * 08600020
*EXTERNAL ROUTINES                                                    * 08800020
*   NONE                                                              * 09000020
*                                                                     * 09200020
*EXITS                                                                * 09400020
*   NORMAL - XCTL TO MODULE IGG0860D                                  * 09600020
*   ERROR - XCTL TO MODULE IGG086AE - RETURN CODE IN REGISTER FOUR    * 09800020
*                                                                     * 10000020
*TABLES/WORK AREAS                                                    * 10200020
*   A 688-BYTE WORK AREA CONTAINING THE FORMAT 4 DSCB, MAXIMUM        * 10400020
*NUMBER OF COUNT FIELDS PER TRACK, A POINTER TO USER'S PARAMETER LIST,* 10600020
*ECB, IOB, DEB, AND DCB.                                              * 10800020
*                                                                     * 11000020
*ATTRIBUTES                                                           * 11200020
*   REENTRANT, REFRESHABLE                                            * 11400020
*                                                                     * 11600020
*                                                                     * 11800020
*                                                                     * 12000020
*                                                                     * 12200020
*                                                                     * 12400020
*********************************************************************** 12600020
*                                                                     * 12800020
*                               EQUATES                               * 13000020
*                                                                     * 13200020
*********************************************************************** 13400020
BIT1     EQU   X'40'                                                    13600020
BIT2     EQU   X'20'                                                    13800020
BIT3     EQU   X'10'                                                    14000020
BIT4     EQU   X'08'                                                    14200020
*********************************************************************** 14400020
*          COMPLETION CODES                                           * 14600020
*********************************************************************** 14800020
CC12     EQU   12                       CORE NOT AVAILABLE              15000020
CC16     EQU   16                       ERROR IN ALTERNATE ASSIGNMENT   15200020
CC32     EQU   32                       LAST RECORD COUNT ERROR         15400020
CC36     EQU   36                       HA OR R0 ERRORS                 15600020
*********************************************************************** 15800020
*          DISPLACEMENT CONSTANTS                                     * 16000020
*********************************************************************** 16200020
D0       EQU   0                                                        16400020
D1       EQU   1                                                        16600020
D2       EQU   2                                                        16800020
D3       EQU   3                                                        17000020
D4       EQU   4                                                        17200020
D5       EQU   5                                                        17400020
D6       EQU   6                                                        17600020
D8       EQU   8                                                        17800020
D9       EQU   9                                                        18000020
*********************************************************************** 18200020
*          LENGTH CONSTANTS                                           * 18400020
*********************************************************************** 18600020
L1       EQU   1                                                        18800020
L2       EQU   2                                                        19000020
L3       EQU   3                                                        19200020
L4       EQU   4                                                        19400020
L7       EQU   7                                                        19600020
L8       EQU   8                                                        19800020
L16      EQU   16                                                       20000020
*********************************************************************** 20200020
*                                                                     * 20400020
*********************************************************************** 20600020
BADALT   EQU   X'03'                    TRACK STATUS FLAG BYTE          20800020
BITS8    EQU   8                                                        21000020
CCB      EQU   X'40'                    COMMAND CHAINING BIT            21200020
D2321    EQU   X'05'                        *                           21400020
FFSW     EQU   X'FF'                                                    21600020
GDTRK    EQU   X'01'                    TRACK STATUS FLAG               21800020
IOEROR   EQU   X'20'                                                    22000020
OVFLW    EQU   X'20'                    RECORD OVERFLOW                 22200020
RCNT     EQU   X'92'                    READ COUNT                      22400020
R0ERR    EQU   X'01'                    R0 ERROR SWITCH                 22600020
SHA      EQU   X'39'                    SEARCH HOME ADDRESS             22800020
X0       EQU   0                                                        23000020
ZEROS    EQU   X'00'                                                    23200020
*                                                                       23400020
*                                                                       23600020
         EJECT                                                          23800020
* REGISTER ASSIGNMENTS                                                  24000020
PARMA    EQU   0                        PARAMETER REGISTER              24200020
PARMB    EQU   1                        PARAMETER REGISTER              24400020
WORKE    EQU   2                        WORK EVEN REGISTER              24600020
WORKO    EQU   3                        ODD WORK REGISTER               24800020
FOUR     EQU   4                        RETURN CODE REGISTER            25000020
FIVE     EQU   5                        WORK REGISTER                   25200020
SIX      EQU   6                        WORK REGISTER                   25400020
SEVEN    EQU   7                        WORK REGISTER                   25600020
EIGHT    EQU   8                        WORK REGISTER                   25800020
NINE     EQU   9                        RECORD BUFFER REGISTER          26000020
TEN      EQU   10                       TRACK DESCRIPTOR CHANNEL        26200020
*                                          PROGRAM AREA                 26400020
AREAREG  EQU   11                       MAIN WORK AREA REGISTER         26600020
BASEREG  EQU   12                       BASE REGISTER                   26800020
SAVEREG  EQU   13                       WORK REGISTER                   27000020
RETREG   EQU   14                       WORK REGISTER                   27200020
ADDREG   EQU   15                       WORK REGISTER                   27400020
         BALR  BASEREG,X0               ESTABLISH                       27600020
         USING OUTEXT,BASEREG              OWN ADDRESSABILITY           27800020
         USING WORKDSCT,AREAREG         ESTABLISH ADDRESSABILITY FOR    28000020
*                                          WORK AREA                    28200020
         USING CNTAREA,TEN              ESTABLISH ADDRESSABILITY FOR    28400020
*                                          COUNT FIELD WORK AREA        28600020
OUTEXT   LTR   FOUR,FOUR                CHECK FOR ENTRY FROM IGG0860D   28800020
         BNZ   SECONDEN                 YES, ENTRY FROM IGG0860D        29000020
         L     SIX,IOBFLAG3             LOAD ADDRESS OF LAST CCW        29200020
         S     SIX,FULL16               GET ADDRESS OF LAST VALID CCW   29400020
         CLI   D0(SIX),RCNT             WAS THERE AN ERROR ON LAST      29600020
*                                          COUNT RECORD                 29800020
         BNE   CHEKSPEC                 YES, THERE WAS A COUNT ERROR    30000020
         L     SIX,D0(X0,SIX)           PICK UP ADDRESS OF LAST COUNT   30200020
*                                          FIELD                        30400020
         A     SIX,FULL8                GET ADDRESS OF BYTE FOLLOWING   30600020
         MVI   D0(SIX),FFSW             SET FLAG TO INDICATE END OF     30800020
*                                          COUNTS                       31000020
         SPACE                                                          31200020
* THIS SECTION COMPUTES THE SIZE OF THE LARGEST RECORD ON THE TRACK     31400020
FINDSIZE SR    EIGHT,EIGHT              CLEAR WORK REGISTERS            31600020
         L     FIVE,SAVEADDR            PICK UP ADDRESS OF FIRST COUNT  31800020
*                                          FIELD                        32000020
FINDMAX  CLI   D0(FIVE),FFSW            DOES IT CONTAIN A COUNT         32200020
         BE    MORECORE                 NO, LAST COUNT                  32400020
         SR    SIX,SIX                                                  32600020
         IC    SIX,D5(X0,FIVE)          PICK UP KEY LENGTH              32800020
         AH    SIX,D6(X0,FIVE)             AND ADD DATA LENGTH          33000020
         LA    FIVE,D8(X0,FIVE)         ADDRESS OF NEXT COUNT FIELD     33200020
         CLR   SIX,EIGHT                IS THE NEW TOTAL THE GREATEST   33400020
         BNH   FINDMAX                  NO, GET NEXT TOTAL              33600020
         LR    EIGHT,SIX                PUT NEW HIGH IN COMPARE REG     33800020
         B     FINDMAX                  COMPLETE LOOP                   34000020
         SPACE                                                          34200020
MORECORE L     FIVE,SVRBEX              LOAD POINTER TO EXTENDED SVRB   34400020
         MVC   D0(L16,FIVE),GETL        MOVE L FORM OF GETMAIN TO       34600020
*                                          SVRB EXTENSION               34800020
         ST    FIVE,D4(X0,FIVE)         STORE ADDRESS OF WHERE ADDRESS  35000020
*                                          IS TO BE RETURNED            35200020
         LA    EIGHT,D8(X0,EIGHT)       ADD 8 FOR COUNT                 35400020
         ST    EIGHT,D0(X0,FIVE)        SOTRE NUMBER BYTES NEEDED       35600020
         LR    PARMB,FIVE                                               35800020
         GETMAIN  EC,LV=(8),MF=(E,(1))  GETMAIN FOR LARGEST RECORD      36000020
*                                          PLUS EIGHT                   36200020
         LTR   ADDREG,ADDREG            CHECK FOR GOTTEN CORE           36400020
         BZ    SAVE                     YES, CORE GOTTEN                36600020
         LA    FOUR,CC12                SET RETURN CODE FOR CORE NOT    36800020
*                                          AVAILABE                     37000020
         B     FREECORE                 EXIT TO ERROR LOAD              37200020
CHEKSPEC TM    SWITCH,OVFLW             DID USER'S DCB SPECIFY TRACK    37400020
*                                          OVERFLOW                     37600020
         BNO   GOBACK                   NO, CONTINUE PROCESSING         37800020
         L     PARMB,USERPARM           PICK UP ADDRESS OF USER'S       38000020
*                                          PARAMETER LIST               38200020
         TM    D4(PARMB),BIT2           WAS WRITE SPECIAL INDICATED     38400020
         BO    SETSW                    YES, SET SWITCH                 38600020
         TM    D4(PARMB),BIT3           WAS 'NOT WRITE SPECIAL'         38800020
*                                          SPECIFIED                    39000020
         BNO   CNTERR                   NO, CAN'T HANDLE ERROR          39200020
GOBACK   L     SIX,D0(X0,SIX)           PICK UP ADDRESS OF SPACE COUNT  39400020
         L     SIX,D0(X0,SIX)           PICK UP ADDRESS OF KEY LENGTH   39600020
*                                          IN COUNT TO BE SKIPPED       39800020
         A     SIX,FULL3                GET ADDRESS FO FLAG BYTE        40000020
         MVI   D0(SIX),FFSW             SET FLAG TO INDICATE END OF     40200020
*                                          COUNTS                       40400020
         B     FINDSIZE                 BRANCH TO GET MAXIMUM RECORD    40600020
*                                          SIZE                         40800020
SETSW    OI    SWITCH,BIT1              SET SWITCH TO INDICATE WRITE    41000020
*                                          SPECIAL IS REQUIRED          41200020
         B     GOBACK                   CONTINUE PROCESSING             41400020
CNTERR   LA    FOUR,CC32                SET COMPLETION CODE FOR ERROR   41600020
*                                          IN COUNT FIELD OF LAST       41800020
*                                          RECORD ON THE TRACK          42000020
         B     FREECORE                 EXIT TO ERROR LOAD              42200020
SAVE     L     NINE,D0(X0,FIVE)         LOAD ADDRESS OF GOTTEN CORE     42400020
         ST    NINE,RECADDR             SAVE THIS ADDRESS IN WORK AREA  42600020
         ST    EIGHT,RECCORE            SAVE NUMBER BYTES GOTTEN        42800020
* THIS SECTION OF CODE DOES A PRELIMINARY READ HA OF THE ALTERNATE      43000020
* TRACK AND TESTS THE FLAG BYTE FOR A DEFECTIVE ALTERNATE INDICATION    43200020
* IF THE ALTERNATE IS NOT FLAGGED DEFECTIVE THEN CCWS ARE BUILT TO      43400020
* WRITE HOME ADDRESS AND R0 ON THE ALTERNATE. . A DEFECTIVE INDICATION  43600020
* CAUSES THE FORMAT 4 TO BE UPDATED TO DETERMINE THE NEXT AVAILABLE     43800020
* ALTERNATE TRACK                                                       44000020
A        MVC   SEEK+D3(L4),DS4HCCHH     SET SEEK ADDRESS AND DEB EXTENT 44200020
         MVC   DEBSTRCC(L4),DS4HCCHH       TO REFLECT ADDRESS OF ALTER- 44400020
         MVC   DEBENDCC(L4),DS4HCCHH       NATE                         44600020
         XC    ECB(L4),ECB              CLEAR ECB                       44800020
         LA    FOUR,CCW1                                                45000020
         ST    FOUR,IOBSTART            STORE ADDRESS OF CHANNEL        45200020
*                                          PROGRAM INTO IOB START FIELD 45400020
         XC    IOBFLAG3(L8),IOBFLAG3    CLEAR CSW AND ERROR FLAGS       45600020
         LM    WORKE,SEVEN,CCWONE                                       45800020
         SR    EIGHT,EIGHT                                              46000020
         LA    EIGHT,SEEK+D3            PICK UP ADDRESS OF CCHH OF      46200020
*                                          ALTERNATE                    46400020
         ALR   WORKE,EIGHT                                              46600020
         LA    EIGHT,CHECKHA            PICK UP ADDRESS OF HOME ADDRESS 46800020
*                                         AREA                          47000020
         ALR   SIX,EIGHT                                                47200020
         LA    EIGHT,CCW1               PICK UP ADDRESS OF CCW TO TIC   47400020
*                                          TO                           47600020
         ALR   FOUR,EIGHT                                               47800020
         STM   WORKE,SEVEN,CCW1         STORE FIRST 3 CCW'S             48000020
         BAL   NINE,EXECUTE             DO READ HA                      48200020
         OI    CCW3+D4,CCB              TURN ON COMMAND CHAINING BIT OF 48400020
*                                          READ HA                      48600020
         LA    NINE,GOODALT             ALTERNATE IS NOT FLAGGED        48800020
*                                          DEFECTIVE, LOAD SUCCESSFUL   49000020
*                                          WRITE BRANCH ADDRESS         49200020
         LM    WORKE,WORKO,CCWTHREE     PICK UP NEXT CCW                49400020
         LA    EIGHT,ALTHA              PICK UP ADDRESS OF HOME ADDRESS 49600020
*                                         TO BE WRITTEN                 49800020
         ALR   WORKE,EIGHT                                              50000020
         STM   WORKE,WORKO,CCW44        STORE NEXT CCW                  50200020
         LM    WORKE,SEVEN,CCWFOUR      PICK UP LAST CCW'S              50400020
         LA    EIGHT,ALTR0              PICK UP ADDRESS OF R0 TO BE     50600020
*                                          WRITTEN                      50800020
         ALR   WORKE,EIGHT                                              51000020
         ALR   SIX,EIGHT                                                51200020
         LA    EIGHT,ALTHA              PICK UP ADDRESS OF HA           51400020
         ALR   FOUR,EIGHT                                               51600020
         STM   WORKE,SEVEN,CCW45        STORE NEXT 3 CCW'S              51800020
         MVI   ALTHA,GDTRK              INDICATE HOME ADDRESS IS FOR    52000020
         MVC   ALTHA+D1(L4),DS4HCCHH       AN OPERATIVE ALTERNATE TRACK 52200020
         L     FOUR,USERPARM                                            52400020
         L     FOUR,D4(X0,FOUR)         PICK UP POINTER TO USER'S CCHH  52600020
         MVC   ALTR0(L16),R0            MOVE INTO NEW R0 THE ORIGINAL   52800020
*                                          PRIMARY TRACK ADDRESS FROM   53000020
*                                          R0 OF THE PRIMARY TRACK      53200020
         CLI   ERRTYPE,R0ERR            R0 PASSED BY UTILITY IN ERROR   53400020
         BNE   EXECUTE                  NO, R0 NOT PASSED BY UTILITY    53600020
*                                          AND IN ERROR                 53800020
         MVC   ALTR0(L8),D0(FOUR)       MOVE IN CALLER'S COUNT          54000020
*                                          PORTION OF R0                54200020
         MVI   ALTR0+D8,ZEROS           CLEAR DATA PORTION OF R0        54400020
         MVC   ALTR0+D9(L7),ALTR0+D8                                    54600020
EXECUTE  EXCP  IOB                      REWRITE HA & R0 ON ALTERNATE    54800020
         WAIT  1,ECB=ECB                WAIT FOR I/O COMPLETE           55000020
         TM    ECB,IOEROR               CHECK FOR AN I/O ERROR          55200020
         BO    SUCCESS                  NO, NO I/O ERROR                55400020
         LA    EIGHT,BITS8                                              55600020
         L     SEVEN,IOBFLAG3           PICK UP ADDRESS OF CCW IN ERROR 55800020
*                                          +8 FROM CSW IN IOB           56000020
         SR    SEVEN,EIGHT                                              56200020
         CLI   D0(SEVEN),SHA            CHECK FOR SEARCH HOME ADDRESS   56400020
*                                          ERROR                        56600020
         BE    LOWOIL                   YES, A SEARCH HOME ADDRESS      56800020
*                                          ERROR                        57000020
SECONDEN LH    EIGHT,NUMALT             PICK UP NUMBER OF ALTERNATES TO 57200020
*                                          BE TRIED                     57400020
         BCTR  EIGHT,X0                 REDUCE BY ONE                   57600020
         STH   EIGHT,NUMALT             STORE BACK NUMBER TO BE TRIED   57800020
         LTR   EIGHT,EIGHT              CHECK FOR MORE ALTERNATES       58000020
         BNZ   LOCATE                   YES, MORE ALTERNATES            58200020
         LA    FOUR,CC16                SET COMPLETION CODE TO 16       58400020
         OI    SWITCH,BIT4              SFT SWITCH TO INDICATE NO       58600020
*                                          ALTERNATES AVAILABLE         58800020
FREECORE MVC   XCTLID(L2),ATLAS06       MOVE ERROR LOAD NAME IN         59000020
         MVC   TTR(L3),TTR6             MOVE ERROR LOAD TTR IN          59200020
XCTL     XC    XCTLPTR+D4(L4),XCTLPTR+D4 CLEAR SECOND WORD OF POINTER   59400020
         XCTL  ,MF=(E,(1)),SF=(E,XCTLPTR)                               59600020
LOWOIL   LA    FOUR,CC36                SET COMPLETION CODE FOR 36-     59800020
*                                          SEARCH HOME ADDRESS ERROR    60000020
         B     FREECORE                 EXIT TO ERROR LOAD              60200020
LOCATE   CLI   DEVTAB+D3,D2321          CHECK FOR A 2321                60400020
         BNE   NOT2321                  NO, OTHER THAN 2321             60600020
         SR    EIGHT,EIGHT                                              60800020
         IC    EIGHT,DS4HCCHH+D3        PICK UP LOW ORDER H=TRACK       61000020
         LA    EIGHT,D1(X0,EIGHT)                                       61200020
         STC   EIGHT,SEEK+D6                                            61400020
         CLC   SEEK+D6(L1),DS4DEVSZ+D3  CHECK FOR NEED TO RESET TRACK   61600020
*                                          TO ZERO                      61800020
         BL    STORE1                   NO, TRACK ADDRESS VALID         62000020
         XC    DS4HCCHH+D3(L1),DS4HCCHH+D3  CLEAR TRACK TO ZERO         62200020
         IC    EIGHT,DS4HCCHH+D2        PICK UP CYLINDER ADDRESS        62400020
         LA    EIGHT,D1(X0,EIGHT)       INCREMENT BY ONE                62600020
         STC   EIGHT,SEEK+D5                                            62800020
         CLC   SEEK+D5(L1),CYLNO        CHECK FOR NEED TO RESET CYLIN-  63000020
*                                          DER TO ZERO                  63200020
         BL    STORE2                   NO, CYLINDER ADDRESS VALID      63400020
         XC    DS4HCCHH+D2(L1),DS4HCCHH+D2  CLEAR CYLINDER NUMBER       63600020
         IC    EIGHT,DS4HCCHH+D1        PICK UP STRIP ADDRESS           63800020
         LA    EIGHT,D1(X0,EIGHT)       INCREMENT BY ONE                64000020
         STC   EIGHT,SEEK+D4                                            64200020
         CLC   SEEK+D4(L1),STRIPNO      CHECK FOR NEED TO RESET STRIP   64400020
*                                          ADDRESS TO ZERO              64600020
         BL    STORE3                   NO, STRIP ADDRESS VALID         64800020
         XC    DS4HCCHH+D1(L1),DS4HCCHH+D1  CLEAR STRIP TO ZERO         65000020
         IC    EIGHT,DS4HCCHH           PICK UP SUB-CELL ADDRESS        65200020
         LA    EIGHT,D1(X0,EIGHT)       INCREMENT BY ONE                65400020
         STC   EIGHT,SEEK+D3                                            65600020
         B     REDUCE                   REDUCE NUMBER OF ALTERNATES     65800020
NOT2321  LH    EIGHT,DS4HCCHH+D2        PICK UP HH OF NEXT ASSIGNABLE   66000020
*                                          ALTERNATE                    66200020
         LA    EIGHT,D1(X0,EIGHT)       ADD ONE                         66400020
         CH    EIGHT,DS4DEVSZ+D2        COMPARE FOR NEED TO RESET       66600020
*                                       TRACK NUMBER TO ZERO            66800020
         BL    NOUP                     NO, TRACK NUMBER IS VALID       67000020
         XC    DS4HCCHH+D2(L2),DS4HCCHH+D2 SET TRACK NUMBER FO ZERO     67200020
         LH    EIGHT,DS4HCCHH                                           67400020
         LA    EIGHT,D1(X0,EIGHT)       INCREMENT CYLINDER NUMBER BY    67600020
         STH   EIGHT,DS4HCCHH              ONE                          67800020
REDUCE   LH    EIGHT,DS4NOATK           REDUCE NUMBER OF AVAILABLE      68000020
         BCTR  EIGHT,X0                    ALTERNATES BY ONE            68200020
         STH   EIGHT,DS4NOATK                                           68400020
         B     A                        TRY ANOTHER ALTERNATE           68600020
NOUP     STH   EIGHT,DS4HCCHH+D2        STORE NEW TRACK NUMBER          68800020
         B     REDUCE                   REDUCE NUMBER OF ALTERNATES     69000020
STORE1   MVC   DS4HCCHH+D3(L1),SEEK+D6  MOVE IN NEW TRACK ADDRESS       69200020
         B     REDUCE                   REDUCE NUMBER OF ALTERNATES     69400020
STORE2   MVC   DS4HCCHH+D2(L1),SEEK+D5  MOVE IN NEW CYLINDER ADDRESS    69600020
         B     REDUCE                   REDUCE NUMBER OF ALTERNATES     69800020
STORE3   MVC   DS4HCCHH+D1(L1),SEEK+D4  MOVE IN NEW STRIP ADDRESS       70000020
         B     REDUCE                   REDUCE NUMBER OF ALTERNATES     70200020
SUCCESS  CLI   CHECKHA,BADALT           IS ALTERNATE DEFECTIVE          70400020
         BE    SECONDEN                 YES, ALTERNATE IS DEFECTIVE     70600020
         BR    NINE                     BRANCH TO WRITE HA OR BRANCH    70800020
*                                          TO NEXT LOAD                 71000020
GOODALT  EQU   *                                                        71200020
         MVC   XCTLID(L2),ATLAS05       MOVE NEXT LOAD NAME IN          71400020
         MVC   TTR(L3),TTR5             MOVE NEXT LOAD TTR IN           71600020
         B     XCTL                     EXIT TO NEXT LOAD MOUDLE        71800020
CCWONE   CCW   X'39',0,X'40',4          SEARCH HOME ADDRESS             72000020
CCWTWO   CCW   X'08',0,X'40',0          TIC TO SEARCH HA                72200020
CCWTOA   CCW   X'1A',0,X'00',5          READ HOME ADDRESS               72400020
CCWTHREE CCW   X'19',0,X'40',5          WRITE HOME ADDRESS              72600020
CCWFOUR  CCW   X'15',0,X'40',16         WRITE R0                        72800020
CCWFIVE  CCW   X'1A',0,X'40',5          READ HOME ADDRESS               73000020
CCWSIX   CCW   X'16',0,X'10',16         READ R0                         73200020
GETL     GETMAIN EC,MF=L                L FORM FOR BUFFER               73400020
CYLNO    DC    X'05'                    NUMBER OF CYLINDERS PER TRACK   73600020
*                                          FOR A 2321                   73800020
STRIPNO  DC    X'0A'                    NUMBER OF STRIPS PER SUBCELL    74000020
*                                          FOR A 2321                   74200020
FULL16   DC    F'16'                    *                               74400020
FULL8    DC    F'8'                     *                               74600020
FULL3    DC    F'3'                     *                               74800020
         SPACE                                                          75000020
*XCTL BY TTR TABLE                                                      75200020
         SPACE                                                          75400020
         ORG   IGG0860C+1000            FIRST ORG                       75600020
         SPACE                                                          75800020
TTRTABLE EQU   *                                                        76000020
ATLAS05  DC    C'0D'                    ID OF NEXT LOAD                 76200020
TTR5     DC    X'00000000'              TTR OF NEXT LOAD                76400020
ATLAS06  DC    C'AE'                    ID OF ERROR LOAD                76600020
TTR6     DC    X'00000000'              TTR OF ERROR LOAD               76800020
         DC    X'0000'                  LAST TABLE ENTRY CODE           77000020
         ORG   IGG0860C+1020            SECOND ORG                      77200020
         DC    C'086'                   ATLAS SVC CODE                  77400020
         DC    X'7D'                    RELATIVE TABLE START ADDRESS    77600020
*                                          IN DOUBLE WORDS              77800020
WORKDSCT DSECT                                                          78000020
SVRBEX   DS    1F                       SAVE AREA FOR SVRB EXTENSION    78200020
*                                          POINTER                      78400020
DEVTAB   DS    1F                       DEVICE TYPE INDICATOR FROM UCB  78600020
SWITCH   DS    CL1                      LOGIC SWITCH                    78800020
*                                       0 BIT INDICATES CHANNEL         79000020
*                                          PROGRAM NOT RE-EXECUTABLE    79200020
*                                       1 BIT INDICATES WRITE SPECIAL   79400020
*                                          REQUIRED                     79600020
*                                       2 BIT INDICATES TRACK OVERFLOW  79800020
*                                          DATA SET                     80000020
*                                       4 BIT INDICATES NO ALTERNATES   80200020
*                                          AVAILABLE                    80400020
*                                       6 BIT INDICATES AN ERROR ON     80600020
*                                          OTHER THAN THE ORIGINAL      80800020
*                                          ERROR RECORD                 81000020
*                                       7 BIT INDICATES VTOC HAS BEEN   81200020
*                                          ENQUEUED UPON                81400020
NUMBERR  DS    CL2                      NUMBER OF ERROR RECORDS         81600020
VTOCADR  DS    CL5                      VTOC ADDRESS CCHHR              81800020
SPLIT    DS    X'00'                    SPLIT CYLINDER SWITCH           82000020
RETPT    DS    1F                       POINTER TO NEXT ROUTINE         82200020
         DS    0F                                                       82400020
         IECSDSL1 (4)                                                   82600020
TICADDR  DS    1F                       ADDRESS OF TIC CCW IN NEW       82800020
*                                          CHANNEL PROGRAM              83000020
SAVEADDR DS    1F                       ADDRESS OF FIRST COUNT FIELD    83200020
CNTCORE  DS    1F                       NUMBER OF BYTES IN COUNT FIELD  83400020
*                                          WORK AREA                    83600020
COREADDR DS    1F                       ADDRESS OF COUNT FIELD          83800020
*                                          WORK AREA                    84000020
RECADDR  DS    1F                       ADDRESS OF CORE GOTTEN FOR      84200020
*                                          LONGEST RECORD SIZE          84400020
RECCORE  DS    1F                       NUMBER OF BYTES IN THIS AREA    84600020
CNTADDR  DS    1F                       ADDRESS OF COUNT FIELD FOR      84800020
*                                          CCW IN ERROR                 85000020
ERRTYPE  DS    CL1                      TYPE OF ORIGINAL ERROR          85200020
RECNUMB  DS    1F                       R OF ERROR RECORDS              85400020
REGSAVE  DS    5F                       SAVE AREA FOR REGISTERS         85600020
ECB      DS    1F                       ECB                             85800020
IOB      DS    8F                       IOB                             86000020
IOBFLAG3 EQU   IOB+8                                                    86200020
IOBSTART EQU   IOB+16                                                   86400020
SEEK     DS    2F                       SEEK ADDRESS                    86600020
DEB      DS    12F                      DEB                             86800020
DEBSTRCC EQU   DEB+38                                                   87000020
DEBENDCC EQU   DEB+42                                                   87200020
DEBPTR   DS    F                        DCB SLOT                        87400020
MIELNAME DS    CL6                      VOLUME SERIAL SLOT              87600020
DCB      EQU   DEBPTR-44                                                87800020
R0AREA   DS    2D                       AREA FOR R0                     88000020
DEQAREA  DS    2D                       DEQ TABLE AREA                  88200020
MJELNAME DS    2F                       MAJOR QUEUE NAME AREA           88400020
ENQAREA  DS    2D                       ENQ TABLE AREA                  88600020
USERPARM DS    1F                       POINTER TO USER'S PARM LIST     88800020
NUMALT   DS    1H                       NUMBER OF ALTERNATES TO BE      89000020
*                                          TRIED                        89200020
MAXCOUNT DS    1H                       MAXIMUM NUMBER OF COUNT FIELDS  89400020
*                                          PER TRACK+1                  89600020
XCTLPTR  DS    2F                       PTR TO XCTL WORK AREA TABLE     89800020
XCTLAREA DS    0CL32                                                    90000020
XCTLNM   DS    CL6                      COMMON BYTES OF ATLAS NAME      90200020
XCTLID   DS    CL2                      ID OF ATLAS MODULE              90400020
         DS    CL6                      *                               90600020
TTR      DS    CL3                      TTR OF ATLAS MODULE             90800020
         DS    CL5                      *                               91000020
TTRATTB  DS    CL2                      ATTRIBUTES OF ATLAS - ALL LOADS 91200020
TTRCREQ  DS    CL3                      CORE REQUIREMENT OF ATLAS LOAD  91400020
TTRLNGTH DS    CL2                      LENGTH OF ATLAS LOAD            91600020
         DS    CL3                      *                               91800020
INCRMNT  DS    1F                       INCREMENT FOR READ COUNTS       92000020
PROGADDR DS    1F                       ADDRESS OF NEW CHANNEL PROGRAM  92200020
ALTHA    DS    2F                       ALTERNATE TRACK HOME ADDRESS    92400020
ALTR0    DS    4F                       ALTERNATE TRACK R0              92600020
CCW1     DS    1D                       CCW AREA                        92800020
CCW2     DS    1D                       *                               93000020
CCW3     DS    1D                       *                               93200020
CCW44    DS    1D                       *                               93400020
CCW45    DS    1D                       *                               93600020
CCW56    DS    1D                       *                               93800020
CCW57    DS    1D                       *                               94000020
CCW31    DS    1D                       *                               94200020
CCW32    DS    1D                       *                               94400020
CCW33    DS    1D                       *                               94600020
CCW34    DS    1D                       *                               94800020
CCW35    DS    1D                       *                               95000020
CCW36    DS    1D                       *                               95200020
CCW37    DS    1D                       *                               95400020
CCW38    DS    1D                       *                               95600020
CCW39    DS    1D                       *                               95800020
CHECKHA  DS    2F                       AREA FOR HOME ADDRESS OF        96000020
*                                       ALTERNATE                       96200020
*                                                                       96400020
CNTAREA  DSECT                                                          96600020
HOMEAD   DS    2F                       CCW AREA                        96800020
R0       DS    4F                       *                               97000020
CCW21    DS    2F                       *                               97200020
CCW22    DS    2F                       *                               97400020
CCW23    DS    2F                       *                               97600020
         END                                                            97800020
