         TITLE 'IGG0860D - FIFTH LOAD MODULE FOR SVC 86'         S20201 00100020
IGG0860D CSECT                                                          00200020
*                                                                       00300020
*                                                                       00400020
*                                                                       00500020
*          RELEASE 22 DELETIONS/CHANGES                                 00600020
*          RELEASE 21 DELETIONS/CHANGES                                 00700020
*          RELEASE 20 DELETIONS/CHANGES                                 00800020
*0792001000-002000,238000,359000-360000                          S20201 00850020
*                                                                       00900020
*STATUS CHANGE LEVEL 002                                                01000020
*                                                                       01100020
*TITLE 'IGG0860D' - FIFTH LOAD MODULE OF SVC 86                       * 01200020
*FUNCTION/OPERATION                                                   * 01300020
*   IGG0860D ESTABLISHES ITS OWN ADDRESSABILITY AND THAT OF ITS 688-  * 01400020
*BYTE WORK AREA.  BEING THE FIFTH LOAD MODULE OF SVC 86 THIS MODULE   * 01500020
*HAS FOUR MAJOR FUNCTIONS                                             * 01600020
*        1.  READS ALL RECORDS ON DEFECTIVE TRACK EXCEPT HOME         * 01700020
*            ADDRESS AND R0                                           * 01800020
*        2.  WRITES ALL RECORDS ON CHOSEN ALTERNATE TRACK             * 01900020
*        3.  FREES CORE FOR AREA FOR LARGEST RECORD, AREA FOR TRACK   * 02000020
*            DESCRIPTION CHANNEL PROGRAM AND COUNT FIELDS             * 02100020
*                                                                     * 02200020
*ENTRY POINT                                                          * 02300020
*   IGG0860D                                                          * 02400020
*                                                                     * 02500020
*INPUT                                                                * 02600020
*   INPUT CONSISTS OF A MAIN WORK AREA POINTED TO BY REGISTER 11,     * 02700020
*A WORK AREA FOR COUNT FIELDS AND TRACK DESCRIPTION CHANNEL PROGRAM   * 02800020
*POINTED TO BY REGISTER 10, AND A WORK AREA FOR THE LARGEST RECORD ON * 02900020
*THE DEFECTIVE TRACK POINTED TO BY REGISTER 9.                        * 03000020
*                                                                     * 03100020
*OUTPUT                                                               * 03200020
*   OUTPUT CONSISTS OF THE MAIN WORK AREA AND IN AN ERROR SITUATION   * 03300020
*ONE OF THE FOLLOWING RETURN CODES IN REGISTER FOUR                   * 03400020
*        16 - I/O ERROR IN ALTERNATE TRACK ASSIGNMENT                 * 03500020
*        20 - ERROR OTHER THAN DATA CHECK OR MISSING ADDRESS MARKER   * 03600020
*        40 - RECOVERABLE ERRORS ENCOUNTERED                          * 03700020
*        48 - NO ERRORS FOUND ON TRACK                                * 03800020
*                                                                     * 03900020
*EXTERNAL ROUTINES                                                    * 04000020
*   NONE                                                              * 04100020
*                                                                     * 04200020
*EXITS                                                                * 04300020
*   NORMAL - XCTL TO MODULE IGG086AE                                  * 04400020
*   ERROR - XCTL TO MODULE IGG086AE                                   * 04500020
*   ERROR ON ALTERNATE - XCTL TO MODULE IGG0860C                      * 04600020
*                                                                     * 04700020
* TABLES/WORK AREAS                                                   * 04800020
*   MAIN WORK AREA CONTAINING THE FORMAT 4 DSCB, MAXIMUM NUMBER OF    * 04900020
*COUNT FIELDS PER TRACK, A POINTER TO USER'S PARAMTER LIST, ECB, IOB, * 05000020
*DEB, AND DCB.                                                        * 05100020
*                                                                     * 05200020
*ATTRIBUTES                                                           * 05300020
*   REENTRANT, REFRESHABLE                                            * 05400020
*                                                                     * 05500020
*                                                                     * 05600020
*                                                                       05700020
*                                                                       05800020
*********************************************************************** 05900020
*                                                                     * 06000020
*                               EQUATES                               * 06100020
*                                                                     * 06200020
*********************************************************************** 06300020
BIT0     EQU   X'80'                                                    06400020
BIT1     EQU   X'40'                                                    06500020
BIT4     EQU   X'08'                                                    06600020
BIT6     EQU   X'02'                                                    06700020
BIT7     EQU   X'01'                                                    06800020
*********************************************************************** 06900020
*          COMPLETION CODES                                           * 07000020
*********************************************************************** 07100020
CC16     EQU   16                       ERROR IN ALTERNATE ASSIGNMENT   07200020
CC20     EQU   20                       NOT VALID ERROR CONDITION       07300020
CC40     EQU   40                       ALTERNATE ASSIGNED              07400020
CC48     EQU   48                       TRACK NOT FOUND DEFECTIVE       07500020
*********************************************************************** 07600020
*          DISPLACEMENT CONSTANTS                                     * 07700020
*********************************************************************** 07800020
D0       EQU   0                                                        07900020
D1       EQU   1                                                        08000020
D3       EQU   3                                                        08100020
D4       EQU   4                                                        08200020
D5       EQU   5                                                        08300020
D6       EQU   6                                                        08400020
D7       EQU   7                                                        08500020
D8       EQU   8                                                        08600020
*********************************************************************** 08700020
*          LENGTH CONSTANTS                                           * 08800020
*********************************************************************** 08900020
L1       EQU   1                                                        09000020
L2       EQU   2                                                        09100020
L3       EQU   3                                                        09200020
L4       EQU   4                                                        09300020
L5       EQU   5                                                        09400020
L8       EQU   8                                                        09500020
**********************************************************************  09520020
*        DEVICE EQUATES                                              *  09540020
**********************************************************************  09560020
D3330    EQU   X'09'                    3330 DEVICE TYPE         S20201 09580020
*********************************************************************** 09600020
*                                                                     * 09700020
*********************************************************************** 09800020
BITS8    EQU   8                                                        09900020
CCSKIP   EQU   X'50'                    COMMAND CHAIN & SKIP BITS       10000020
CNTLENG  EQU   X'08'                    COUNT LENGTH                    10100020
CSWOK    EQU   X'41'                                                    10200020
EOF      EQU   X'0D'                    END OF FILE                     10300020
ERRS3    EQU   X'03'                                                    10400020
FFSW     EQU   X'FF'                                                    10500020
IOEROR   EQU   X'20'                                                    10600020
OTHEROR  EQU   X'02'                                                    10700020
OUTEXTNT EQU   X'42'                    OUT OF EXTENT                   10800020
RCKD     EQU   X'1E'                    READ COUNT KEY DATA             10900020
RCNT     EQU   X'92'                    READ COUNT                      11000020
RKD      EQU   X'0E'                    READ KEY DATA                   11100020
SLISKP   EQU   X'30'                    SLI & SKIP BITS                 11200020
TIC      EQU   X'08'                                                    11300020
WSCKD    EQU   X'01'                    WRITE SPECIAL COUNT KEY DATA    11400020
X0       EQU   0                                                        11500020
ZEROS    EQU   X'00'                                                    11600020
*                                                                       11700020
*                                                                       11800020
         EJECT                                                          11900020
* REGISTER ASSIGNMENTS                                                  12000020
PARMA    EQU   0                        PARAMETER REGISTER              12100020
PARMB    EQU   1                        PARAMETER REGISTER              12200020
WORKE    EQU   2                        EVEN WORK REGISTER              12300020
WORKO    EQU   3                        ODD WORK REGISTER               12400020
FOUR     EQU   4                        RETURN CODE REGISTER            12500020
FIVE     EQU   5                        WORK REGISTER                   12600020
SIX      EQU   6                        *                               12700020
SEVEN    EQU   7                        *                               12800020
EIGHT    EQU   8                        *                               12900020
NINE     EQU   9                        *                               13000020
TEN      EQU   10                       *                               13100020
AREAREG  EQU   11                       MAIN WORK AREA REGISTER         13200020
BASEREG  EQU   12                       BASE REGISTER                   13300020
SAVEREG  EQU   13                       WORK REGISTER                   13400020
RETREG   EQU   14                       WORK REGISTER                   13500020
ADDREG   EQU   15                       COMPLETION CODE REGISTER        13600020
         BALR  BASEREG,X0               ESTABLISH                       13700020
         USING BEGIN,BASEREG               OWN ADDRESSABILITY           13800020
         USING WORKDSCT,AREAREG         ESTABLISH ADDRESSABILITY FOR    13900020
*                                          WORK AREA                    14000020
         USING CNTAREA,TEN              ESTABLISH ADDRESSABILITY FOR    14100020
*                                          COUNT FIELD WORK AREA        14200020
BEGIN    CLI   NUMBERR+D1,ZEROS         DID ANY RECOVERABLE COUNT FIELD 14300020
*                                          ERRORS OCCUR                 14400020
         BE    LD23                     NO,NO NEED TO RESET COUNTER     14500020
         XC    RECNUMB(L4),RECNUMB      CLEAR ERROR RECORD SAVE AREA    14600020
         XC    NUMBERR(L2),NUMBERR      RESET ERROR RECORD COUNTER TO   14700020
*                                          ZERO                         14800020
         OI    NUMBERR,BIT0             SET HIGH ORDER BIT TO INDICATE  14900020
*                                          RECOVERABLE COUNT ERRORS     15000020
LD23     LA    WORKO,CCW23              PICK UP ADDRESS OF FIRST READ   15100020
*                                         COUNT CCW                     15200020
         L     WORKE,SAVEADDR           PICK UP ADDRESS OF FIRST COUNT  15300020
*                                          FIELD                        15400020
         L     NINE,RECADDR             LOAD RECORD BUFFER ADDRESS      15500020
PICKLENT SR    SIX,SIX                                                  15600020
         ST    WORKO,CCWPTR             SAVE POINTER TO LAST MODIFIED   15700020
         IC    SIX,D5(WORKE)            PICK UP KEY LENGTH              15800020
*                                          CCW                          15900020
         AH    SIX,D6(X0,WORKE)         ADD DATA LENGTH                 16000020
*                                         KEY AND DATA                  16100020
*                                          COMMAND                      16200020
         LTR   SIX,SIX                  CHECK FOR END OF FILE           16300020
         BZ    WRITEREC                 YES, END OF FILE- SKIP READ OF  16400020
RELOCATE LM    FOUR,FIVE,ASCCW51        PICK UP READ COUNT KEY AND DATA 16500020
         ALR   FOUR,NINE                PUT IN BUFFER ADDRESS           16600020
         ALR   FIVE,SIX                 PUT IN RECORD LENGTH            16700020
         CLI   D0(WORKO),TIC            IS CCW A TIC                    16800020
         BNE   STORE                    NO, STORE CCW                   16900020
         L     SEVEN,D0(WORKO)          PICK UP ADDRESS OF SPACE COUNT  17000020
         LA    SEVEN,D8(SEVEN)          GET POINTER TO FOLLOWING TIC    17100020
         MVC   D8(L8,SEVEN),D0(SEVEN)   REPLACE RETURN TIC WITH         17200020
*                                          TIC TO SPACE COUNT           17300020
         S     FIVE,FULL8               SUBTRACT 8 FROM TOTAL LENGTH    17400020
*                                         FOR COUNT FIELD               17500020
         LA    FOUR,D8(X0,FOUR)         ADJUST ADDRESS FOR READ KD      17600020
         STM   FOUR,FIVE,D0(SEVEN)      STORE NEW READ KEY DATA CCW     17700020
         MVI   D0(SEVEN),RKD            SET TO READ KEY DATA ONLY       17800020
         ST    SEVEN,CCWPTR             SAVE POINTER TO LAST MODIFIED   17900020
*                                          CCW                          18000020
         B     PICKUP                   GET ADDRESS OF FIRST CCW        18100020
STORE    STM   FOUR,FIVE,D0(WORKO)      STORE READ COUNT KEY DATA CCW   18200020
         EJECT                                                          18300020
PICKUP   LA    FIVE,CCW21               PICK UP ADDRESS OF FIRST CCW    18400020
*                                          FOR IOB START ADDRESS        18500020
         MVC   SEEK+D3(L4),HOMEAD+D1    MOVE IN SEEK ADDRESS FOR BAD    18600020
*                                          TRACK                        18700020
         BAL   SEVEN,SETUP              EXECUTE CHANNEL PROGRAM         18800020
         CLI   D0(WORKO),TIC            WAS READ COUNT REPLACED         18900020
*                                          BY A TIC                     19000020
         BNE   IOERR                    NO,TEST FOR I/O ERROR           19100020
         L     SEVEN,CCWPTR             POINTER TO READ KD CCW          19200020
         MVC   D0(L8,SEVEN),D8(SEVEN)   REPLACE WITH TIC CCW            19300020
IOERR    TM    ECB,IOEROR               CHECK FOR I/O ERROR             19400020
         BO    WRITEREC                 NO, I/O SUCCESSFUL              19500020
         CLI   ECB,CSWOK                ARE CSW CONTENTS USEFUL         19600020
         BE    ERR41                    YES,CSW CONTENTS ARE VALID      19700020
         CLI   ECB,OUTEXTNT             TEST FOR INDICATION THAT THE    19800020
* ERROR IS A RESULT OF READING AN OVERFLOW RECORD AND HAVING ONLY A     19900020
* SINGLE TRACK DEB EXTENT.  IF SO, THEN THE CSW CONTENTS CAN BE         20000020
* CONSIDERED RELIABLE                                                   20100020
         BNE   SETERCD                  ERROR CAN NOT BE HANDLED        20200020
ERR41    EQU   *                                                        20300020
         LA    SEVEN,BITS8                                              20400020
         L     FIVE,IOBFLAG3            PICK UP ADDRESS OF CCW IN       20500020
*                                          ERROR +8 FROM CSW            20600020
         SR    FIVE,SEVEN                                               20700020
         CLI   IOBCSWST,EOF             END OF FILE                     20800020
         BE    EOFSTOP                  YES, END OF FILE                20900020
         CLI   NUMBERR+D1,ERRS3         HAVE THERE BEEN THREE ERROR     21000020
*                                          RECORDS                      21100020
         BE    VALIDCHK                 CONTINUE PROCESSING BUT DO NOT  21200020
*                                          SAVE ERROR RECORD NUMBERS    21300020
         XR    EIGHT,EIGHT              CLEAR REGISTER                  21400020
         IC    EIGHT,NUMBERR+D1         PICK UP NUMBER OF ERROR RECORDS 21500020
         A     EIGHT,FULL1              INCREMENT BY ONE                21600020
         STC   EIGHT,NUMBERR+D1                                         21700020
         LA    SEVEN,RECNUMB            ADDRESS OF ERROR SAVE AREA      21800020
         ALR   EIGHT,SEVEN              GET DISPLACEMENT INTO RECNUMB   21900020
         MVC   D0(L1,EIGHT),D4(WORKE)   MOVE ERROR RECORD NUMBER TO     22000020
*                                          RECNUMB SAVE AREA            22100020
VALIDCHK TM    IOBCSWST,BIT6            DID UNIT CHECK OCCUR            22200020
         BNO   SETERCD                  NO, UNIT CHECK DID NOT OCCUR    22300020
         TM    IOBSENS0,BIT4            CHECK IOB SENSE BYTE FOR A      22400020
*                                          DATA CHECK                   22500020
         BO    DATACK                   YES, DATA CHECK                 22600020
         TM    IOBSENS1,BIT6            CHECK FOR MISSING ADDRESS       22700020
*                                          MARKER                       22800020
         BO    CHECKM                   YES, MISSING ADDRESS MARKER     22900020
         TM    IOBSENS1,BIT7            CHECK FOR OVERFLOW INCOMPLETE   23000020
         BO    WRITEREC                 YES, TAKE CARE OF SITUATION     23100020
*                                          IN ANOTHER SECTION (LASTREC) 23200020
SETERCD  LA    FOUR,CC20                SET COMPLETION CODE             23300020
ERNAME   MVC   XCTLID(L2),ATLAS06       MOVE ERROR LOAD NAME IN         23400020
         MVC   TTR(L3),TTR6             MOVE ERROR LOAD TTR IN          23500020
XCTL     XC    XCTLPTR+D4(L4),XCTLPTR+D4  CLEAR SECOND WORD OF POINTER  23600020
         XCTL  ,MF=(E,(1)),SF=(E,XCTLPTR)                               23700020
CHECKM   CLI   DEVTAB+D3,D3330          CHECK FOR 3330           S20201 23740020
         BE    SETERCD                  YES, INVALID IOB SENSE   S20201 23780020
         TM    IOBSENS1,BIT4            CHECK FOR NOT REGULAR    S20201 23820020
*                                       MISSING                  S20201 23860020
*                                          ADDRESS MARKER               23900020
         BO    SETERCD                  YES, NOT NORMAL MISSING         24000020
*                                          ADDRESS MARKER               24100020
         TM    IOBSENS0,BIT7            CHECK FOR BALLAST CELL NOT      24200020
*                                          FOUND                        24300020
         BO    SETERCD                  YES, NOT A NORMAL MISSING       24400020
*                                          ADDRESS MARKER               24500020
DATACK   CLI   D0(FIVE),RCKD            CHECK FOR CCW BEING A READ      24600020
*                                          COUNT KEY DATA               24700020
         BNE   USERREC                  NO,CCW IS READ KEY DATA         24800020
         MVI   D0(FIVE),RCNT            CHANGE READ COUNT KEYDATA TO    24900020
*                                       READ COUNT                      25000020
         MVI   D7(FIVE),CNTLENG         SET LENGTH TO 8                 25100020
         MVI   D6(FIVE),ZEROS                                           25200020
USERREC  L     FOUR,USERPARM            LOAD PARAMETER LIST ADDRESS     25300020
         TM    D4(FOUR),BIT1            WAS ONLY CCHH PASSED BY USER    25400020
         BO    WRITEREC                 YES,USER HAS NOT PASSED         25500020
*                                          FULL COUNT                   25600020
         L     FOUR,D4(FOUR)            LOAD ADDRESS OF COUNT FIELD     25700020
         CLC   D0(L5,WORKE),D0(FOUR)    IS THIS THE ERROR RECORD        25800020
*                                          PASSED BY CALLER             25900020
         BE    WRITEREC                 YES,CALLER'S RECORD             26000020
         OI    SWITCH,OTHEROR           SET SWITCH TO INDICATE ERROR    26100020
*                                          ENCOUNTERED IN OTHER THAN    26200020
*                                          RECORD PASSED                26300020
WRITEREC MVC   D0(L8,NINE),D0(WORKE)    MOVE IN COUNT FIELD TO BE       26400020
*                                          WRITTEN                      26500020
         LM    FOUR,FIVE,CPCCW1         PICK UP FIRST CCW               26600020
         ALR   FOUR,AREAREG             RE-ADJUST POINTER               26700020
         STM   FOUR,FIVE,CCW1           STORE IN FIRST AND FOURTH SLOTS 26800020
         STM   FOUR,FIVE,CCW44                                          26900020
         LM    FOUR,FIVE,CPCCW2         PICK UP SECOND CCW              27000020
         LA    PARMB,CCW1                                               27100020
         ALR   FOUR,PARMB               RE-ADJUST POINTER               27200020
         STM   FOUR,FIVE,CCW2                                           27300020
         LM    FOUR,FIVE,CPCCW3         PICK UP THIRD CCW               27400020
         ALR   FOUR,NINE                RE-ADJUST POINTER               27500020
         ALR   FIVE,SIX                 ADJUST LENGTH                   27600020
         STM   FOUR,FIVE,CCW3                                           27700020
         LM    FOUR,FIVE,CPCCW2         PICK UP FIFTH CCW               27800020
         LA    PARMB,CCW44                                              27900020
         ALR   FOUR,PARMB               RE-ADJUST POINTER               28000020
         STM   FOUR,FIVE,CCW45                                          28100020
         LM    FOUR,FIVE,CPCCW4         PICK UP SIXTH CCW               28200020
         ALR   FOUR,NINE                                                28300020
         ALR   FIVE,SIX                 RE-ADJUST LENGTH                28400020
         STM   FOUR,FIVE,CCW56                                          28500020
         IC    FOUR,D4(NINE)            PICK UP RECORD NUMBER           28600020
         BCTR  FOUR,X0                  REDUCE RECORD NUMBER BY ONE     28700020
         STC   FOUR,SEARCH+D4           STORE RECORD NUMBER TO BE USED  28800020
*                                          FOR SEARCH                   28900020
         MVC   SEARCH(L4),D0(NINE)      MOVE IN CCHH FOR SEARCH         29000020
NOTSET   LA    FIVE,CCW1                PICK UP ADDRESS OF FIRST CCW    29100020
*                                          FOR IOB START ADDRESS        29200020
         MVC   SEEK+D3(L4),DS4HCCHH     MOVE IN CCHH OF ALTERNATE       29300020
         BAL   SEVEN,SETUP              SET UP CONTROL BLOCKS           29400020
         TM    ECB,IOEROR               CHECK FOR IO ERROR              29500020
         BO    GREAT                    YES, NO I/O ERROR               29600020
         CLI   IOBCSWST,EOF             IS CONDITION END OF FILE        29700020
         BE    GREAT                    YES, END OF FILE (OK)           29800020
SETBACK  LA    FOUR,CC16                SET CODE IN FOUR AND XCTL TO    29900020
*                                          IGG0860C                     30000020
         MVC   XCTLID(L2),ATLAS04       MOVE PREVIOUS LOAD NAME IN      30100020
         MVC   TTR(L3),TTR4             MOVE PREVIOUS LOAD TTR IN       30200020
         B     XCTL                     EXIT TO APPROPRIATE MODULE      30300020
GREAT    CLI   D8(WORKE),FFSW           CHECK FOR LAST COUNT FIELD      30400020
         BE    LASTREC                  YES,LAST RECORD                 30500020
         L     SIX,CCWPTR               PICK UP POINTER TO LAST CCW     30600020
*                                          MODIFIED                     30700020
         OI    D4(SIX),CCSKIP           TURN ON COMMAND CHAIN AND SKIP  30800020
*                                          FLAGS IN RKD COMMAND         30900020
         LA    WORKE,D8(X0,WORKE)       BUMP COUNT FIELD POINTER        31000020
         LA    WORKO,D8(X0,WORKO)       BUMP CCW POINTER                31100020
         B     PICKLENT                 PICK UP NEXT RECORD             31200020
* THIS SECTION RE-READS THE LAST RECORD ON THE 'BAD' TRACK TO SEE IF A  31300020
* WRITE SPECIAL COUNT KEYDATA IS NEEDED, UNLESS IT IS AN EOF RECORD.    31400020
LASTREC  EQU   *                                                        31500020
         OC    D6(L2,WORKE),D6(WORKE)   DATA LENGTH = ZERO              31600020
         BZ    ENDUP                    YES, EXIT                       31700020
         L     FOUR,CCWPTR              GET POINTER TO LAST READ CCW    31800020
         CLI   D0(FOUR),RCNT            IS LAST CCW A RC                31900020
         BNE   NOTRC                    NO, GO ON                       32000020
         MVI   D0(FOUR),RCKD            REPLACE RC WITH RCKD CCW        32100020
         XR    EIGHT,EIGHT              CLEAR REGISTER                  32200020
         IC    EIGHT,D5(WORKE)          LOAD KEY LENGTH                 32300020
         AH    EIGHT,D6(WORKE)          ADD DATA LENGTH                 32400020
         ST    EIGHT,D4(FOUR)           STORE KEY DATA LENGTH IN CCW    32500020
NOTRC    EQU   *                                                        32600020
         CLI   D0(FOUR),TIC             IS LAST CCW A TIC               32700020
         BNE   NOTIC                    NO, WAS A READ CKD              32800020
         XR    EIGHT,EIGHT              CLEAR REGISTER                  32900020
         IC    EIGHT,D5(WORKE)          LOAD KEY LENGTH                 33000020
         AH    EIGHT,D6(WORKE)          ADD DATA LENGTH                 33100020
         ST    EIGHT,D4(FOUR)           STORE KEY DATA LENGTH IN CCW    33200020
         MVI   D0(FOUR),RKD             REPLACE TIC WITH READ KD        33300020
NOTIC    EQU   *                                                        33400020
         TM    SWITCH,BIT1              IS WRITE SPECIAL REQUIRED       33500020
         BO    WRITSPEC                 YES, SET UP CHANNEL PROGRAM     33600020
         L     EIGHT,D4(FOUR)           LOAD LENGTH PROTION OF CCW      33700020
         LA    EIGHT,D1(EIGHT)          ADD ONE TO FORCE OVERFLOW       33800020
*                                          INCOMPLETE                   33900020
         ST    EIGHT,D4(FOUR)           STORE LENGTH                    34000020
         OI    D4(FOUR),SLISKP          TURN ON SKIP AND SLI BITS       34100020
         LA    FIVE,CCW21               PICK UP ADDRESS OF FIRST CCW    34200020
*                                          FOR IOB START ADDRESS        34300020
         MVC   SEEK+D3(L4),HOMEAD+D1    MOVE IN SEEK ADDRESS FOR BAD    34400020
*                                          TRACK                        34500020
         BAL   SEVEN,SETUP              EXECUTE CHANNEL PROGRAM         34600020
         TM    IOBSENS1,BIT7            CHECK FOR OVERFLOW INCOMPLETE   34700020
         BNO   ENDUP                    NO, BRANCH TO EXIT ROUTINE      34800020
* THIS SECTION IS ENTERED IF A WRITE SPECIAL IS REQUIRED                34900020
WRITSPEC MVI   CCW3,WSCKD               CHANGE WRITE COUNT KEY DATA CCW 35000020
*                                          TO A WRITE SPECIAL CCW       35100020
         LA    FIVE,CCW1                LOAD ADDRESS OF FIRST CCW FOR   35200020
*                                          IOB START ADDRESS            35300020
         MVC   SEEK+D3(L4),DS4HCCHH     MOVE IN SEEK ADDRESS OF         35400020
*                                          ALTERNATE                    35500020
         BAL   SEVEN,SETUP              EXECUTE CHANNEL PROGRAM         35600020
         TM    ECB,IOEROR               CHECK FOR I/O ERROR             35700020
         BO    ENDUP                    NO I/O ERROR                    35800020
         TM    IOBSENS1,BIT7            CHECK FOR OVERFLOW       S20201 35870020
*                                       INCOMPLETE               S20201 35940020
         BNO   SETBACK                  NOT OVERFLOW INCOMPLETE  S20201 36010020
ENDUP    L     PARMA,RECCORE            LOAD NUMBER OF BYTES TO BE      36100020
*                                          FREED                        36200020
         L     PARMB,RECADDR            LOAD POINTER TO CORE TO BE      36300020
*                                          FREED                        36400020
         FREEMAIN R,LV=(0),A=(1)        FREE BUFFER                     36500020
         XC    RECADDR(L8),RECADDR                                      36600020
         SR    FOUR,FOUR                SET REGISTER FOUR TO INDICATE   36700020
*                                         NORMAL ENTRY INTO LAST LOAD   36800020
         L     SIX,USERPARM             ADDRESS OF PARAMETER LIST       36900020
         TM    NUMBERR,BIT0             WERE THERE ANY RECOVERABLE      37000020
*                                          COUNT FIELD ERRORS           37100020
         BO    ISO                      YES,AN ALTERNATE MUST BE        37200020
*                                          ASSIGNED                     37300020
         CLI   NUMBERR+D1,ZEROS         WERE THERE ANY ERRORS IN KEY/   37400020
*                                          DATA FIELDS                  37500020
         BNE   ANYR                     YES,WAS A FULL COUNT SPECIFIED  37600020
         LA    FOUR,CC48                SET RETURN CODE FOR NO ERRORS   37700020
         B     NEXT                        FOUND ON TRACK               37800020
ISO      CLI   NUMBERR+D1,ZEROS         WERE THERE ANY ERRORS IN KEY/   37900020
*                                          DATA FIELDS                  38000020
         BE    NEXT                     NO,RETURN CODE IS SET FOR       38100020
*                                          SUCCESSFUL COMPLETION        38200020
ANYR     TM    D4(SIX),BIT1             WAS ONLY CCHH PASSED            38300020
         BO    OTHERR                   YES,RETURN CODE IS 40           38400020
         TM    SWITCH,OTHEROR           WAS THERE AN ERROR ON OTHER     38500020
*                                          THAN THE USER SPECIFIED      38600020
*                                          RECORD                       38700020
         BZ    NEXT                     NO,RETURN CODE IS ZERO          38800020
OTHERR   LA    FOUR,CC40                SET RETURN CODE FOR ERROR/      38900020
*                                          ERRORS ENCOUNTERED,AN        39000020
*                                          ALTERNATE IS ASSIGNED        39100020
NEXT     MVC   XCTLID(L2),ATLAS06       MOVE NEXT LOAD NAME IN          39200020
         MVC   TTR(L3),TTR6             MOVE NEXT LOAD TTR IN           39300020
         B     XCTL                     EXIT                            39400020
SETUP    ST    FIVE,IOBSTART            STORE ADDRESS OF FIRST CCW      39500020
         MVC   DEBSTRCC(L4),SEEK+D3     SET UP DEB EXTENTS              39600020
         MVC   DEBENDCC(L4),SEEK+D3                                     39700020
         XC    ECB(L4),ECB              CLEAR ECB                       39800020
         XC    IOBFLAG3(L8),IOBFLAG3    CLEAR SENSE BYTES               39900020
         EXCP  IOB                      WRITE/READ RECORD               40000020
         WAIT  1,ECB=ECB                WAIT FOR I/O COMPLETE           40100020
         BR    SEVEN                    RETURN TO CALLER                40200020
EOFSTOP  EQU   *                                                        40300020
         CLI   D0(FIVE),RCKD            CHECK FOR CCW BEING READ CKD    40400020
         BNE   ISRKD                    NO,CCW IS A RKD                 40500020
         MVI   D0(FIVE),RCNT            CHANGE RCKD TO RC               40600020
         MVI   D7(FIVE),CNTLENG         SET LENGTH TO 8                 40700020
         NI    D6(FIVE),ZEROS                                           40800020
ISRKD    B     WRITEREC                 EVERYTHING OK                   40900020
CPCCW1   CCW   X'31',SEARCH-SVRBEX,X'40',5  SEARCH ID EQUAL             41000020
CPCCW2   CCW   X'08',0,X'40',0          TIC                             41100020
CPCCW3   CCW   X'1D',0,X'40',8          WRITE COUNT, KEY,DATA           41200020
CPCCW4   CCW   X'1E',0,X'10',8          READ COUNT,KEY,DATA             41300020
ASCCW51  CCW   X'1E',0,X'00',8          READ COUNT KEY DATA             41400020
SPACECT  CCW   X'0F',0,X'40',3          SPACE COUNT                     41500020
CCWNOP   CCW   X'03',CCW31-SVRBEX,X'60',1  NO-OP                        41600020
         EJECT                                                          41700020
         SPACE                                                          41800020
FULL8    DC    F'8'                     *                               41900020
FULL1    DC    F'1'                     *                               42000020
*XCTL BY TTR TABLE                                                      42100020
         SPACE                                                          42200020
         ORG   IGG0860D+1000            FIRST ORG                       42300020
         SPACE                                                          42400020
TTRTABLE EQU   *                                                        42500020
ATLAS04  DC    C'0C'                    ID OF PREVIOUS LOAD             42600020
TTR4     DC    X'00000000'              TTR OF PREVIOUS LOAD            42700020
ATLAS06  DC    C'AE'                    ID OF ERROR/NEXT LOAD           42800020
TTR6     DC    X'00000000'              TTR OF ERROR/NEXT LOAD          42900020
         DC    X'0000'                  LAST TABLE ENTRY CODE           43000020
         ORG   IGG0860D+1020            SECOND ORG                      43100020
         DC    C'086'                   ATLAS SVC CODE                  43200020
         DC    X'7D'                    RELATIVE TABLE START ADDRESS    43300020
*                                          IN DOUBLE WORDS              43400020
WORKDSCT DSECT                                                          43500020
SVRBEX   DS    1F                       SAVE AREA FOR SVRB EXTENSION    43600020
*                                          POINTER                      43700020
DEVTAB   DS    1F                       DEVICE TYPE INDICATOR FROM UCB  43800020
SWITCH   DS    CL1                      LOGIC SWITCH                    43900020
*                                       0 BIT INDICATES CHANNEL         44000020
*                                          PROGRAM NOT RE-EXECUTABLE    44100020
*                                       1 BIT INDICATES WRITE SPECIAL   44200020
*                                          REQUIRED                     44300020
*                                       2 BIT INDICATES TRACK OVERFLOW  44400020
*                                          DATA SET                     44500020
*                                       4 BIT INDICATES NO ALTERNATES   44600020
*                                          AVAILABLE                    44700020
*                                       6 BIT INDICATES AN ERROR ON     44800020
*                                          OTHER THAN THE ORIGINAL      44900020
*                                          ERROR RECORD                 45000020
*                                       7 BIT INDICATES VTOC HAS BEEN   45100020
*                                          ENQUEUED UPON                45200020
NUMBERR  DS    CL2                      NUMBER OF ERROR RECORDS         45300020
VTOCADR  DS    CL5                      VTOC ADDRESS CCHHR              45400020
SPLIT    DS    X'00'                    SPLIT CYLINDER SWITCH           45500020
RETPT    DS    1F                       POINTER TO NEXT ROUTINE         45600020
         DS    0F                                                       45700020
         IECSDSL1 (4)                                                   45800020
TICADDR  DS    1F                       ADDRESS OF TIC CCW IN NEW       45900020
*                                          CHANNEL PROGRAM              46000020
SAVEADDR DS    1F                       ADDRESS OF FIRST COUNT FIELD    46100020
CNTCORE  DS    1F                       NUMBER OF BYTES IN COUNT FIELD  46200020
*                                          WORK AREA                    46300020
COREADDR DS    1F                       ADDRESS OF COUNT FIELD          46400020
*                                          WORK AREA                    46500020
RECADDR  DS    1F                       ADDRESS OF CORE GOTTEN FOR      46600020
*                                          LONGEST RECORD SIZE          46700020
RECCORE  DS    1F                       NUMBER OF BYTES IN THIS AREA    46800020
CNTADDR  DS    1F                       ADDRESS OF COUNT FIELD FOR      46900020
*                                          CCW IN ERROR                 47000020
ERRTYPE  DS    CL1                      TYPE OF ORIGINAL ERROR          47100020
RECNUMB  DS    1F                       R OF ERROR RECORDS              47200020
REGSAVE  DS    5F                       SAVE AREA FOR REGISTERS         47300020
ECB      DS    1F                       ECB                             47400020
IOB      DS    8F                       IOB                             47500020
IOBSENS0 EQU   IOB+2                                                    47600020
IOBSENS1 EQU   IOB+3                                                    47700020
IOBFLAG3 EQU   IOB+8                                                    47800020
IOBCSWST EQU   IOB+12                                                   47900020
IOBSTART EQU   IOB+16                                                   48000020
SEEK     DS    2F                       SEEK ADDRESS                    48100020
DEB      DS    12F                      DEB                             48200020
DEBSTRCC EQU   DEB+38                                                   48300020
DEBENDCC EQU   DEB+42                                                   48400020
DEBPTR   DS    F                        DCB SLOT                        48500020
MIELNAME DS    CL6                      VOLUME SERIAL SLOT              48600020
DCB      EQU   DEBPTR-44                                                48700020
R0AREA   DS    2D                       AREA FOR R0                     48800020
DEQAREA  DS    2D                       DEQ TABLE AREA                  48900020
MJELNAME DS    2F                       MAJOR QUEUE NAME AREA           49000020
ENQAREA  DS    2D                       ENQ TABLE AREA                  49100020
USERPARM DS    1F                       POINTER TO USER'S PARM LIST     49200020
NUMALT   DS    1H                       NUMBER OF ALTERNATES TO BE      49300020
*                                          TRIED                        49400020
MAXCOUNT DS    1H                       MAXIMUM NUMBER OF COUNT FIELDS  49500020
*                                          PER TRACK+1                  49600020
XCTLPTR  DS    2F                       PTR TO XCTL WORK AREA TABLE     49700020
XCTLAREA DS    0CL32                                                    49800020
XCTLNM   DS    CL6                      COMMON BYTES OF ATLAS NAME      49900020
XCTLID   DS    CL2                      ID OF ATLAS MODULE              50000020
         DS    CL6                      *                               50100020
TTR      DS    CL3                      TTR OF ATLAS MODULE             50200020
         DS    CL5                      *                               50300020
TTRATTB  DS    CL2                      ATTRIBUTES OF ATLAS - ALL LOADS 50400020
TTRCREQ  DS    CL3                      CORE REQUIREMENT OF ATLAS LOAD  50500020
TTRLNGTH DS    CL2                      LENGTH OF ATLAS LOAD            50600020
         DS    CL3                      *                               50700020
INCRMNT  DS    1F                       INCREMENT FOR READ COUNTS       50800020
PROGADDR DS    1F                       ADDRESS OF NEW CHANNEL PROGRAM  50900020
ALTHA    DS    2F                       ALTERNATE TRACK HOME ADDRESS    51000020
ALTR0    DS    4F                       ALTERNATE TRACK R0              51100020
CCW1     DS    1D                       CCW AREA                        51200020
CCW2     DS    1D                       *                               51300020
CCW3     DS    1D                       *                               51400020
CCW44    DS    1D                       *                               51500020
CCW45    DS    1D                       *                               51600020
CCW56    DS    1D                       *                               51700020
CCW57    DS    1D                       *                               51800020
CCW31    DS    1D                       *                               51900020
CCW32    DS    1D                       *                               52000020
CCW33    DS    1D                       *                               52100020
CCW34    DS    1D                       *                               52200020
CCW35    DS    1D                       *                               52300020
CCW36    DS    1D                       *                               52400020
CCW37    DS    1D                       *                               52500020
CCW38    DS    1D                       *                               52600020
CCW39    DS    1D                       *                               52700020
CHECKHA  DS    2F                       AREA FOR HOME ADDRESS OF        52800020
*                                       ALTERNATE                       52900020
SEARCH   DS    1D                       SEARCH RECORD ID                53000020
CCWPTR   DS    1F                       CCW POINTER                     53100020
*                                                                       53200020
CNTAREA  DSECT                                                          53300020
HOMEAD   DS    2F                       CCW AREA                        53400020
R0       DS    4F                       *                               53500020
CCW21    DS    2F                       *                               53600020
CCW22    DS    2F                       *                               53700020
CCW23    DS    2F                       *                               53800020
         END                                                            53900020
