         TITLE 'IGG086AE - SIXTH LOAD MODULE FOR SVC 86'         S20201 00100020
IGG086AE CSECT                                                          00200020
*                                                                       00300020
*                                                                       00400020
*          RELEASE 22 DELETIONS/CHANGES                                 00500020
*          RELEASE 21 DELETIONS/CHANGES                                 00600020
*3650179000-180000,187000-188000,190000-195000,333000-334000,    S21040 00630021
*3650382000,384000                                               S21040 00660021
*          RELEASE 20 DELETIONS/CHANGES                                 00700020
*0792001000-002000,320000,329000                                 S20201 00750020
*                                                                       00800020
*STATUS CHANGE LEVEL 003                                                00900021
*                                                                     * 01000020
*TITLE 'IGG086AE' - SIXTH LOAD MODULE OF SVC 86                       * 01100020
*                                                                     * 01200020
*FUNCTION/OPERATION                                                   * 01300020
*    IGG086AE HAS TWO MAJOR FUNCTIONS.  FIRST, IT UPDATES THE FORMAT  * 01400020
*4 DSCB TO REFLECT THE CURRENT NUMBER OF ALTERNATE TRACKS AVAILABLE   * 01500020
*AND THE ADDRESS OF THE NEXT AVAILABLE ALTERNATE.  IT THEN WRITES     * 01600020
*HOME ADDRESS AND RECORD ZERO ON THE BAD TRACK.  IF THE USER'S CHANNEL* 01700020
*PROGRAM IS RE-EXECUTABLE IT WILL ATTEMPT TO EXECUTE THE PROGRAM.     * 01800020
*SECOND, IT DEQUEUES THE VTOC, FREES GOTTEN CORE, AND EXITS.          * 01900020
*                                                                     * 02000020
*ENTRY POINT                                                          * 02100020
*    IGG086AE TESTS REGISTER FOUR FOR AN INDICATION OF WHETHER THE    * 02200020
*MODULE WERE ENTERED DUE TO AN ERROR CONDITION OR FOR NORMAL          * 02300020
*PROCESSING.                                                          * 02400020
*                                                                     * 02500020
*INPUT                                                                * 02600020
*    CONSISTS OF THE 688-BYTE WORK AREA POINTED TO BY REGISTER 11,    * 02700020
*A WORK AREA FOR COUNT FIELDS AND TRACK DESCRIPTION CHANNEL PROGRAM   * 02800020
*POINTED TO BY REGISTER 10, AND A CONDITION CODE IN REGISTER FOUR.    * 02900020
*                                                                     * 03000020
*OUTPUT                                                               * 03100020
*    RETURN CODE IN REGISTER FIFTEEN INDICATING THE STATUS OF         * 03200020
*COMPLETION OF THE JOB AND THE UPDATED FORMAT FOUR DSCB.  A RETURN    * 03300020
*PARAMETER LIST IS LOADED INTO REGISTER ZERO.  THE FIRST BYTE SHOWS   * 03400020
*THE NUMBER OF RECORD NUMBERS RETURN IN THE REMAINING THREE BYTES OF  * 03500020
*THE REGISTER.  THE RECORD NUMBERS OF A MAXIMUM OF THREE ERROR        * 03600020
*RECORDS ARE GIVEN TO IDENTIFY THOSE RECORDS WHICH COULD NOT BE READ  * 03700020
**OR WRITTEN WITHOUT ERROR.                                           * 03800020
*                                                                     * 03900020
*EXTERNAL ROUTINES                                                    * 04000020
*   NONE                                                              * 04100020
*                                                                     * 04200020
*EXITS                                                                * 04300020
*    ERROR - BRANCHES TO BEGIN, THAT PORTION OF THE PROGRAM WHICH     * 04400020
*            DEQUEUES THE VTOC, FREES GOTTEN CORE, AND EXITS          * 04500020
*    NORMAL - SVC 3 EXIT                                              * 04600020
*                                                                     * 04700020
*TABLES/WORK AREAS                                                    * 04800020
*    MAIN WORK AREA CONTAINING THE FORMAT 4 DSCB, MAXIMUM NUMBER OF   * 04900020
*COUNT FIELDS PER TRACK, A POINTER TO USER'S PARAMETER LIST, ECB,     * 05000020
*IOB, DEB, AND DCB.                                                   * 05100020
*                                                                     * 05200020
*ATTRIBUTES                                                           * 05300020
*    REENTRANT, REFRESHABLE                                           * 05400020
*                                                                     * 05500020
*                                                                       05600020
*                                                                       05700020
*********************************************************************** 05800020
*                                                                     * 05900020
*                               EQUATES                               * 06000020
*                                                                     * 06100020
*********************************************************************** 06200020
*********************************************************************** 06300020
*          COMPLETION CODES                                           * 06400020
*********************************************************************** 06500020
CC24     EQU   24                       ERROR READING FORMAT4 DSCB      06600020
CC36     EQU   36                       HA OR R0 ERRORS                 06700020
CC52     EQU   52                       ERROR RE-EXECUTING USER PROGRAM 06800020
*********************************************************************** 06900020
*********************************************************************** 07000020
*          DISPLACEMENT CONSTANTS                                     * 07100020
*********************************************************************** 07200020
D0       EQU   0                                                        07300020
D1       EQU   1                                                        07400020
D2       EQU   2                                                        07500020
D3       EQU   3                                                        07600020
D4       EQU   4                                                        07700020
D5       EQU   5                                                        07800020
D6       EQU   6                                                        07900020
D7       EQU   7                        *                        S21040 07950021
*********************************************************************** 08000020
*          LENGTH CONSTANTS                                           * 08100020
*********************************************************************** 08200020
L1       EQU   1                                                        08300020
L2       EQU   2                                                        08400020
L3       EQU   3                                                        08500020
L4       EQU   4                                                        08600020
L5       EQU   5                                                        08700020
L7       EQU   7                                                        08800020
L11      EQU   11                       *                        S21040 08810021
**********************************************************************  08820020
*        DEVICE EQUATES                                              *  08840020
**********************************************************************  08860020
D3330    EQU   X'09'                    3330 DEVICE TYPE         S20201 08880020
*********************************************************************** 08900020
*                                                                     * 09000020
*********************************************************************** 09100020
BADTRK   EQU   X'02'                                                    09200020
D2314    EQU   X'08'                    DEVICE TYPES                    09300020
D2321    EQU   X'05'                        *                           09400020
ENQSW    EQU   X'01'                    ENQUEUE SWITCH                  09500020
EOF      EQU   X'0D'                    END OF FILE                     09600020
FFSW     EQU   X'FF'                                                    09700020
FLAG1    EQU   X'42'                                                    09800020
IOEROR   EQU   X'20'                                                    09900020
NOREEX   EQU   X'80'                                                    10000020
R0DD8    EQU   X'08'                    RECORD ZERO DATA LENGTH  S21040 10050021
RR0      EQU   X'16'                    READ RECORD 0                   10100020
X0       EQU   0                                                        10200020
*                                                                       10300020
*                                                                       10400020
         EJECT                                                          10500020
*REGISTER ASSIGNMENTS                                                   10600020
PARMA    EQU   0                        PARAMETER REGISTER              10700020
PARMB    EQU   1                        PARAMETER REGISTER              10800020
WORKE    EQU   2                        WORK REGISTER                   10900020
WORKO    EQU   3                        WORK REGISTER                   11000020
FOUR     EQU   4                        WORK REGISTER - RETURN CODE     11100020
FIVE     EQU   5                        WORK REGISTER                   11200020
SIX      EQU   6                        WORK REGISTER                   11300020
SEVEN    EQU   7                        WORK REGISTER                   11400020
EIGHT    EQU   8                        WORK REGISTER                   11500020
NINE     EQU   9                        WORK REGISTER                   11600020
TEN      EQU   10                       ADDRESS OF COUNT WORK AREA      11700020
AREAREG  EQU   11                       ADDRESS OF WORK AREA            11800020
BASEREG  EQU   12                       ADDRESS OF MODULE               11900020
SAVEREG  EQU   13                       WORK REGISTER                   12000020
RETREG   EQU   14                       WORK REGISTER                   12100020
ADDREG   EQU   15                       COMPLETION CODE REGISTER        12200020
         SPACE                                                          12300020
         BALR  BASEREG,X0               ESTABLISH                       12400020
         USING FIRST,BASEREG               OWN ADDRESSABILITY           12500020
         USING WORKDSCT,AREAREG         ESTABLISH ADDRESSABILITY OF     12600020
*                                          WORK AREA                    12700020
         USING CNTAREA,TEN              ESTABLISH ADDRESSABILITY OF     12800020
*                                          COUNT FIELD WORK AREA        12900020
         SPACE                                                          13000020
*THIS SECTION BUILDS A CHANNEL PROGRAM TO WRITE AND READ BACK CHECK     13100020
*HOME ADDRESS AND RECORD ZERO ON THE BAD TRACK                          13200020
         SPACE                                                          13300020
FIRST    LTR   FOUR,FOUR                WAS THIS MODULE ENTERED         13400020
*                                          BECAUSE OF ERRORS            13500020
         LA    EIGHT,NORMAL                                             13600020
         ST    EIGHT,RETPT                                              13700020
         BZ    UPDATE                   NO.UPDATE VTOC                  13800020
         CH    FOUR,HALF48              DOES RETURN CODE INDICATE NO    13900020
         BE    BEGIN                       ERRORS FOUND ON TRACK        14000020
         CH    FOUR,HALF16              DOES CODE INDICATE ERROR IN     14100020
*                                          ASSIGNING ALTERNATE          14200020
         BNE   TEST3                    NO, MAKE ANOTHER TEST           14300020
         LA    EIGHT,BEGIN              ADDRESS OF EXIT ROUTINE         14400020
         ST    EIGHT,RETPT                                              14500020
         B     UPDATE                   BRANCH TO UPDATE THE VTOC       14600020
TEST3    CH    FOUR,HALF40              DOES CODE INDICATE ERR IN OTHER 14700020
*                                          THAN ORIGINAL ERROR RECORD   14800020
         BNE   BEGIN                    PREPARE FOR EXIT                14900020
         LA    EIGHT,NORMAL             ADDRESS OF CHANNEL PROGRAM      15000020
         ST    EIGHT,RETPT                                              15100020
         B     UPDATE                   BRANCH TO UPDATE VTOC           15200020
NORMAL   L     PARMB,USERPARM           PICK UP ADDRESS OF USER'S       15300020
*                                          PARAMETER LIST               15400020
         L     WORKO,D4(X0,PARMB)       GET ADDRESS OF USER'S CCHH      15500020
         LM    FIVE,EIGHT,CCWONE        LOAD FIRST TWO CCW'S            15600020
         LA    NINE,HOMEAD              PICK UP ADDRESS OF HOME ADDRESS 15700020
         ALR   FIVE,NINE                   TO BE WRITTEN                15800020
         LA    NINE,R0                  PICK UP ADDRESS OF RECORD ZERO  15900020
         ALR   SEVEN,NINE                  TO BE WRITTEN                16000020
         STM   FIVE,EIGHT,CCW1          STORE TWO CCW'S IN WORK AREA    16100020
         LM    FIVE,EIGHT,CCWTHREE      LOAD LAST TWO CCW'S             16200020
         LA    NINE,HOMEAD              PICK UP ADDRESS TO READ BACK    16300020
         ALR   FIVE,NINE                   CHECK HOME ADDRESS           16400020
         LA    NINE,R0                  PICK UP ADDRESS TO READ BACK    16500020
         ALR   SEVEN,NINE                  CHECK RECORD ZERO            16600020
         STM   FIVE,EIGHT,CCW3          STORE LAST 2 CCW'S IN WORK AREA 16700020
         MVC   SEEK+D3(L5),D0(WORKO)    SET SEEK ADDRESS TO BAD TRACK   16800020
         MVC   DEBSTRCC(L4),D0(WORKO)   SET DEB FOR SINGLE TRACK FXTENT 16900020
         MVC   DEBENDCC(L4),D0(WORKO)      USING BAD TRACK              17000020
         BAL   EIGHT,SETBLKS            BRANCH TO RESET CONTROL BLOCKS  17100020
         LA    EIGHT,CCW1               PUT ADDRESS OF CHANNEL PROGRAM  17200020
         ST    EIGHT,IOBSTART              INTO IOB                     17300020
         MVC   HOMEAD+D1(L4),D0(WORKO)  SET UP HOME ADDRESS             17400020
         MVI   HOMEAD,BADTRK            INDICATE DEFECTIVE TRACK        17500020
         XC    HOMEAD+D5(L3),HOMEAD+D5  CLEAR REMAINING BYTES           17600020
         MVC   R0(L4),ALTHA+D1          POINT DEFECTIVE PRIMARY TRACK   17700020
*                                          TO ALTERNATE                 17800020
         XC    R0+D5(L11),R0+D5         SET KDD AND DATA FIELD   S21040 17870021
*                                       TO 0                     S21040 17940021
         MVI   R0+D7,R0DD8              SET DATA LENGTH TO 8     S21040 18010021
         SPACE                                                          18100020
*THIS SECTION WRITES HOME ADDRESS AND R0 ON THE BAD TRACK AND READS     18200020
*BACK CHECK                                                             18300020
         SPACE                                                          18400020
CHPROG   EXCP  IOB                      FLAG BAD TRACK                  18500020
         WAIT  1,ECB=ECB                TEST FOR I/O COMPLETE           18600020
         TM    ECB,IOEROR               CHECK FOR SUCCESSFUL I/O S21040 18700021
         BNO   CHEKDEV                  NO, CHECK DEVICE TYPE    S21040 18800021
         SPACE                                                          18900020
         SPACE                                                          19600020
*THIS SECTION RE-EXECUTES THE USER'S CHANNEL PROGRAM IF POSSIBLE        19700020
         SPACE                                                          19800020
REEX     TM    SWITCH,NOREEX            IS USER'S CHANNEL PROGRAM       19900020
*                                          RE-EXECUTABLE                20000020
         BO    BEGIN                    NO,GO TO EXIT ROUTINE           20100020
         L     PARMB,USERPARM                                           20200020
         L     PARMB,D0(X0,PARMB)       PICK UP POINTER TO IOB          20300020
         LR    EIGHT,PARMB                                              20400020
         L     WORKE,D4(X0,PARMB)       PICK UP POINTER TO ECB          20500020
         EXCP  (1)                      RE-EXECUTE USER'S CHANNEL       20600020
*                                          PROGRAM                      20700020
         LR    PARMB,WORKE              SET ECB POINTER                 20800020
         WAIT  1,ECB=(1)                WAIT FOR I/O COMPLETE           20900020
         TM    D0(WORKE),IOEROR         CHECK FOR SUCCESSFUL COMPLETION 21000020
         BO    BEGIN                    YES,SUCCESSFUL COMPLETION       21100020
         CLI   CSW(EIGHT),EOF           WAS CONDITION END OF FILE       21200020
         BO    BEGIN                    YES,GO TO EXIT ROUTINE          21300020
         LA    FOUR,CC52                SET COMPLETION CODE FOR USER'S  21400020
*                                          CHANNEL PROGRAM RE-EXECUTED  21500020
*                                          WITH AN I/O ERROR            21600020
         B     BEGIN                    GO TO EXIT ROUTINE              21700020
         SPACE                                                          21800020
*THIS SECTION  SETS UP AND EXECUTES A CHANNEL PROGRAM TO WRITE AND      21900020
*READ BACK CHECK THE FORMAT 4 DSCB                                      22000020
         SPACE                                                          22100020
UPDATE   BAL   EIGHT,SETBLKS            RESET CONTROL BLOCKS            22200020
         CLI   DEVTAB+D3,D2321          CHECK FOR A 2321                22300020
         BNE   NOT2321                  NO, OTHER THAN 2321             22400020
         SR    EIGHT,EIGHT                                              22500020
         IC    EIGHT,DS4HCCHH+D3        PICK UP LOW ORDER H=TRACK       22600020
         LA    EIGHT,D1(X0,EIGHT)                                       22700020
         STC   EIGHT,SEEK+D6                                            22800020
         CLC   SEEK+D6(L1),DS4DEVSZ+D3  CHECK FOR NEED TO RESET TRACK   22900020
*                                          TO ZERO                      23000020
         BL    STORE1                   NO, TRACK ADDRESS VALID         23100020
         XC    DS4HCCHH+D3(L1),DS4HCCHH+D3  CLEAR TRACK TO ZERO         23200020
         IC    EIGHT,DS4HCCHH+D2        PICK UP CYLINDER ADDRESS        23300020
         LA    EIGHT,D1(X0,EIGHT)       INCREMENT BY ONE                23400020
         STC   EIGHT,SEEK+D5                                            23500020
         CLC   SEEK+D5(L1),CYLNO        CHECK FOR NEED TO RESET CYLIN-  23600020
*                                          CYLINDER TO ZERO             23700020
         BL    STORE2                   NO, CYLINDER ADDRESS VALID      23800020
         XC    DS4HCCHH+D2(L1),DS4HCCHH+D2  CLEAR CYLINDER NUMBER       23900020
         IC    EIGHT,DS4HCCHH+D1        PICK UP STRIP ADDRESS           24000020
         LA    EIGHT,D1(X0,EIGHT)       INCREMENT BY ONE                24100020
         STC   EIGHT,SEEK+D4                                            24200020
         CLC   SEEK+D4(L1),STRIPNO      CHECK FOR NEED TO RESET STRIP   24300020
*                                          ADDRESS TO ZERO              24400020
         BL    STORE3                   NO, STRIP ADDRESS VALID         24500020
         XC    DS4HCCHH+D1(L1),DS4HCCHH+D1  CLEAR STRIP TO ZERO         24600020
         IC    EIGHT,DS4HCCHH           PICK UP SUB-CELL ADDRESS        24700020
         LA    EIGHT,D1(X0,EIGHT)       INCREMENT BY ONE                24800020
         STC   EIGHT,SEEK+D3                                            24900020
         B     REDUCE                   REDUCE NUMBER OF AVAILABLE      25000020
*                                          ALTERNATES                   25100020
         SPACE                                                          25200020
NOT2321  LH    EIGHT,DS4HCCHH+D2        PICK UP HH OF NEXT ASSIGNABLE   25300020
*                                          ALTERNATE                    25400020
         LA    EIGHT,D1(X0,EIGHT)       INCREMENT BY ONE                25500020
         CH    EIGHT,DS4DEVSZ+D2        CHECK FOR NEED TO RESET TRACK   25600020
*                                          NUMBER TO ZERO               25700020
         BL    NOUP                     NO, TRACK NUMBER IS VALID       25800020
         XC    DS4HCCHH+D2(L2),DS4HCCHH+D2  SET TRACK NUMBER TO ZERO    25900020
         LH    EIGHT,DS4HCCHH           PICK UP CC OF NEXT ASSIGNABLE   26000020
*                                          ALTERNATE                    26100020
         LA    EIGHT,D1(X0,EIGHT)       INCREMENT BY ONE                26200020
         STH   EIGHT,DS4HCCHH                                           26300020
         SPACE                                                          26400020
REDUCE   LH    EIGHT,DS4NOATK           REDUCE NUMBER OF AVAILABLE      26500020
         BCTR  EIGHT,X0                    ALTERNATES BY ONE            26600020
         STH   EIGHT,DS4NOATK                                           26700020
         B     LOADCCW                  RELOCATE F4 CHANNEL PROGRAM     26800020
NOUP     STH   EIGHT,DS4HCCHH+D2        STORE NEW TRACK NUMBER          26900020
         B     REDUCE                   REDUCE NUMBER OF AVAILABLE      27000020
*                                          ALTERNATES                   27100020
STORE1   MVC   DS4HCCHH+D3(L1),SEEK+D6  MOVE IN NEW TRACK ADDRESS       27200020
         B     REDUCE                   REDUCE NUMBER OF AVAILABLE      27300020
*                                          ALTERNATES                   27400020
STORE2   MVC   DS4HCCHH+D2(L1),SEEK+D5  MOVE IN NEW CYLINDER ADDRESS    27500020
         B     REDUCE                   REDUCE NUMBER OF AVAILABLE      27600020
*                                          ALTERNATES                   27700020
STORE3   MVC   DS4HCCHH+D1(L1),SEEK+D4  MOVE IN NEW STRIP ADDRESS       27800020
         B     REDUCE                   REDUCE NUMBER OF AVAILABLE      27900020
*                                          ALTERNATES                   28000020
LOADCCW  LM    FIVE,EIGHT,CCWFIVE                                       28100020
         LA    NINE,SEEK+D3             PICK UP ADDRESS OF CCHH FOR     28200020
*                                          SEARCH                       28300020
         ALR   FIVE,NINE                INSERT IN SEARCH CCW            28400020
         LA    NINE,CCW1                SET ADDRESS OF COMMAND FOR TIC  28500020
         ALR   SEVEN,NINE                                               28600020
         STM   FIVE,EIGHT,CCW1          RELOCATE FIRST TWO CCW'S        28700020
         LM    FIVE,SIX,CCWSEVEN        LOAD WRITE CCW                  28800020
         LA    NINE,IECSDSF4            GET POINTER TO WRITE            28900020
         ALR   FIVE,NINE                   FORMAT 4 DSCB                29000020
         LM    SEVEN,EIGHT,CCWFIVE      LOAD SID CCW                    29100020
         LA    NINE,SEEK+D3             PICK UP ADDRESS OF CCHH FOR     29200020
*                                          SEARCH                       29300020
         ALR   SEVEN,NINE                                               29400020
         STM   FIVE,EIGHT,CCW3          RELOCATE SECOND TWO CCW'S       29500020
         LM    FIVE,SIX,CCWSIX          LOAD TIC CCW                    29600020
         LA    NINE,CCW44               LOAD ADDRESS FOR TIC            29700020
         ALR   FIVE,NINE                                                29800020
         LM    SEVEN,EIGHT,CCWEIGHT     LOAD READ BACK CHECK CCW        29900020
         LA    NINE,IECSDSF4            GET POINTER TO READ BACK CHECK  30000020
         ALR   SEVEN,NINE                  FORMAT 4 DSCB                30100020
         STM   FIVE,EIGHT,CCW45         STORE LAST TWO CCW'S            30200020
         LA    NINE,CCW1                PUT ADDRESS OF CHANNEL PROGRAM  30300020
         ST    NINE,IOBSTART               INTO IOB                     30400020
         MVC   SEEK+D3(L5),VTOCADR      SET SEEK ADDRESS TO F4 DSCB     30500020
         MVC   DEBSTRCC(L4),VTOCADR     SET DEB FOR SINGLE TRACK EXTENT 30600020
         MVC   DEBENDCC(L4),VTOCADR        USING F4 DSCB                30700020
         EXCP  IOB                      REWRITE F4 DSCB                 30800020
         WAIT  1,ECB=ECB                WAIT FOR I/O COMPLETE           30900020
         TM    ECB,IOEROR               CHECK FOR PERMANENT I/O ERROR   31000020
         BZ    SETERR                   BRANCH TO SET ERROR CODE        31100020
         L     EIGHT,RETPT                                              31200020
         BR    EIGHT                    BRANCH TO NEXT ROUTINE          31300020
         SPACE                                                          31400020
SETERR   LA    FOUR,CC24                SET COMPLETION CODE TO 24 FOR   31500020
*                                          F4 DSCB CANNOT BE READ       31600020
         B     BEGIN                    WRAP UP                         31700020
         SPACE                                                          31800020
*THIS SECTION CHECKS DEVICE TYPE AND SETS FLAG TO MOVE HOME ADDRESS     31900020
*OVER 705 BYTES IF DEVICE IS 2314 OR 2321, AND 2370 BYTES FOR 3330      32000020
         SPACE                                                          32100020
CHEKDEV  CLI   DEVTAB+D3,D2314          CHECK FOR 2314                  32200020
         BE    SETBIT                   YES, SET FLAG                   32300020
         CLI   DEVTAB+D3,D3330          CHECK FOR 3330           S20201 32330020
         BE    SETBIT                   YES, SET FLAG            S20201 32360020
         CLI   DEVTAB+D3,D2321          CHECK FOR 2321                  32400020
         BNE   ERRCOND                  NO, NOT A 2321                  32500020
         SPACE                                                          32600020
SETBIT   MVI   HOMEAD,FLAG1             SET FLAG TO INDICATE DEFECTIVE  32700020
*                                          TRACK AND TO MOVE HOME       32800020
*                                          ADDRESS OVER 705 BYTES       32850020
*                                          FOR 2314 OR 2321 AND         32900020
*                                          2370 BYTES FOR 3330          32950020
         BAL   EIGHT,SETBLKS            RESET CONTROL BLOCKS            33000020
         EXCP  IOB                      RETRY HA AND R0 WRITE           33100020
         WAIT  1,ECB=ECB                WAIT FOR I/O COMPLETE           33200020
         TM    ECB,IOEROR               CHECK FOR SUCCESSFUL I/O S21040 33270021
         BO    REEX                     YES, TO TRY TO REEXECUTE S21040 33340021
*                                          USERS CHANNEL PROGRAM        33410021
         SPACE                                                          33500020
ERRCOND  LA    FOUR,CC36                SET RETURN CODE TO 36 - COULD   33600020
*                                          NOT FLAG BAD TRACK, HOME     33700020
*                                          ADDRESS OR R0 ERROR          33800020
         B     BEGIN                    WRAP UP                         33900020
         SPACE                                                          34000020
         SPACE                                                          34100020
SETBLKS  XC    ECB(L4),ECB              ZERO ECB                        34200020
         XC    IOBSENS0(L2),IOBSENS0    ZERO SENSE BYTES                34300020
         XC    IOBCSW(L7),IOBCSW        ZERO LOW ORDER BYTES OF IOB CSW 34400020
         BR    EIGHT                    RETURN                          34500020
BEGIN    MVC   RECNUMB(L1),NUMBERR+D1   MOVE IN NUMBER OF ERROR RECORDS 34600020
         TM    SWITCH,ENQSW             HAS ENQUEUE BEEN ISSUED         34700020
         BZ    NODEQ                    NO. DEQUEUE NOT REQUIRED        34800020
         SPACE                                                          34900020
* THIS SECTION DEQUES FROM THE VTOC                                     35000020
DEEQ     EQU   *                                                        35100020
         MVI   DEQAREA,FFSW             SET LAST ENTRY CODE             35200020
         SR    PARMB,PARMB              CLEAR OPTION                    35300020
         STH   PARMB,DEQAREA+D2                                         35400020
REGDEQ   DEQ   (MJELNAME,MIELNAME,6,SYSTEMS),MF=(E,DEQAREA)             35500020
NODEQ    OC    RECADDR(L4),RECADDR      DOES CORE FOR LARGEST RECORD    35600020
*                                          HAVE TO BE FREED             35700020
         BZ    NEXTCORE                 NO, CORE HAS BEEN FREED         35800020
         L     PARMA,RECCORE            LOAD NUMBER OF BYTES TO BE      35900020
*                                          FREED                        36000020
         L     PARMB,RECADDR            LOAD POINTER TO CORE TO BE      36100020
*                                          FREED                        36200020
         FREEMAIN R,LV=(0),A=(1)        BUFFER                          36300020
NEXTCORE OC    COREADDR(L4),COREADDR    DOES CORE FOR COUNT FIELDS HAVE 36400020
*                                          TO BE FREED                  36500020
         BZ    FREEMAIN                 NO, CORE HAS BEEN FREED         36600020
         L     PARMA,CNTCORE            LOAD NUMBER OF BYTES TO BE      36700020
*                                          FREED                        36800020
         L     PARMB,COREADDR           LOAD POINTER TO CORE TO BE      36900020
*                                          FREED                        37000020
         FREEMAIN R,LV=(0),A=(1)        TRACK DESCRIPTOR CHANNEL PROG   37100020
FREEMAIN LR    PARMB,AREAREG            LOAD POINTER TO CORE TO BE      37200020
*                                          FREED                        37300020
         L     FIVE,RECNUMB             LOAD RETURN PARAMETER LIST      37400020
         FREEMAIN R,LV=688,A=(1)        MAIN WORK AREA                  37500020
*                                          NUMBERS                      37600020
         LR    PARMA,FIVE               RETURN PARAMETER LIST IN R0     37700020
         LR    ADDREG,FOUR              SET FINAL COMPLETION CODE       37800020
         SVC   EXIT                     RETURN TO CALLER                37900020
EXIT     EQU   3                        TERMINATION SVC                 38000020
CCWONE   CCW   X'19',0,X'40',5          WRITE HOME ADDRESS              38100020
CCWTWO   CCW   X'15',0,X'40',16         WRITE RECORD ZERO        S21040 38200021
CCWTHREE CCW   X'1A',0,X'50',5          READ HOME ADDRESS               38300020
CCWFOUR  CCW   X'16',0,X'10',16         READ RECORD ZERO         S21040 38400021
CCWFIVE  CCW   X'31',0,X'40',5          SID - FORMAT 4 DSCB             38500020
CCWSIX   CCW   X'08',0,X'40',0          TIC                             38600020
CCWSEVEN CCW   X'05',0,X'40',96         WRITE DATA OF F4 DSCB           38700020
CCWEIGHT CCW   X'06',0,X'10',96         READ DATA OF F4 DSCB            38800020
VTOCNAME DC    CL8'SYSVTOC'             VTOC NAME FOR ENQUEUE AND       38900020
*                                          DEQUEUE                      39000020
CYLNO    DC    X'05'                    NUMBER OF CYLINDERS PER TRACK   39100020
*                                          FOR A 2321                   39200020
STRIPNO  DC    X'0A'                    NUMBER OF STRIPS PER SUBCELL    39300020
*                                          FOR A 2321                   39400020
FULL8    DC    F'8'                     *                               39500020
HALF48   DC    H'48'                    *                               39600020
HALF16   DC    H'16'                    *                               39700020
HALF40   DC    H'40'                    *                               39800020
         ORG   IGG086AE+1021            FIRST AND ONLY ORG              39900020
END      DS    CL3'END'                 THE END                         40000020
WORKDSCT DSECT                                                          40100020
SVRBEX   DS    1F                       SAVE AREA FOR SVRB EXTENSION    40200020
*                                          POINTER                      40300020
DEVTAB   DS    1F                       DEVICE TYPE INDICATOR FROM UCB  40400020
SWITCH   DS    CL1                      LOGIC SWITCH                    40500020
*                                       0 BIT INDICATES CHANNEL         40600020
*                                          PROGRAM NOT RE-EXECUTABLE    40700020
*                                       1 BIT INDICATES WRITE SPECIAL   40800020
*                                          REQUIRED                     40900020
*                                       2 BIT INDICATES TRACK OVERFLOW  41000020
*                                          DATA SET                     41100020
*                                       3 BIT INDICATES ENQUEUE WAS     41200020
*                                          WITH STEP MUST COMPLETE      41300020
*                                       4 BIT INDICATES NO ALTERNATES   41400020
*                                          AVAILABLE                    41500020
*                                       6 BIT INDICATES AN ERROR ON     41600020
*                                          OTHER THAN THE ORIGINAL      41700020
*                                          ERROR RECORD                 41800020
*                                       7 BIT INDICATES VTOC HAS BEEN   41900020
*                                          ENQUEUED UPON                42000020
NUMBERR  DS    CL2                      NUMBER OF ERROR RECORDS         42100020
VTOCADR  DS    CL5                      VTOC ADDRESS CCHHR              42200020
SPLIT    DS    X'00'                    SPLIT CYLINDER SWITCH           42300020
RETPT    DS    1F                       POINTER TO NEXT ROUTINE         42400020
         DS    0F                                                       42500020
         IECSDSL1 (4)                                                   42600020
TICADDR  DS    1F                       ADDRESS OF TIC CCW IN NEW       42700020
*                                          CHANNEL PROGRAM              42800020
SAVEADDR DS    1F                       ADDRESS OF FIRST COUNT FIELD    42900020
CNTCORE  DS    1F                       NUMBER OF BYTES IN COUNT FIELD  43000020
*                                          WORK AREA                    43100020
COREADDR DS    1F                       ADDRESS OF COUNT FIELD          43200020
*                                          WORK AREA                    43300020
RECADDR  DS    1F                       ADDRESS OF CORE GOTTEN FOR      43400020
*                                          LONGEST RECORD SIZE          43500020
RECCORE  DS    1F                       NUMBER OF BYTES IN THIS AREA    43600020
CNTADDR  DS    1F                       ADDRESS OF COUNT FIELD FOR      43700020
*                                          CCW IN ERROR                 43800020
ERRTYPE  DS    CL1                      TYPE OF ORIGINAL ERROR          43900020
RECNUMB  DS    1F                       R OF ERROR RECORDS              44000020
REGSAVE  DS    5F                       SAVE AREA FOR REGISTERS         44100020
ECB      DS    1F                       ECB                             44200020
IOB      DS    8F                       IOB                             44300020
CSW      EQU   12                                                       44400020
IOBSENS0 EQU   IOB+2                                                    44500020
IOBFLAG3 EQU   IOB+8                                                    44600020
IOBCSW   EQU   IOB+9                                                    44700020
IOBCSWST EQU   IOB+12                                                   44800020
IOBSTART EQU   IOB+16                                                   44900020
SEEK     DS    2F                       SEEK ADDRESS                    45000020
DEB      DS    12F                      DEB                             45100020
DEBSTRCC EQU   DEB+38                                                   45200020
DEBENDCC EQU   DEB+42                                                   45300020
DEBPTR   DS    F                        DCB SLOT                        45400020
MIELNAME DS    CL6                      VOLUME SERIAL SLOT              45500020
DCB      EQU   DEBPTR-44                                                45600020
R0AREA   DS    2D                       AREA FOR R0                     45700020
DEQAREA  DS    2D                       DEQ TABLE AREA                  45800020
MJELNAME DS    2F                       MAJOR QUEUE NAME AREA           45900020
ENQAREA  DS    2D                       ENQ TABLE AREA                  46000020
USERPARM DS    1F                       POINTER TO USER'S PARM LIST     46100020
NUMALT   DS    1H                       NUMBER OF ALTERNATES TO BE      46200020
*                                          TRIED                        46300020
MAXCOUNT DS    1H                       MAXIMUM NUMBER OF COUNT FIELDS  46400020
*                                          PER TRACK+1                  46500020
XCTLPTR  DS    2F                       PTR TO XCTL WORK AREA TABLE     46600020
XCTLAREA DS    0CL32                                                    46700020
XCTLNM   DS    CL6                      COMMON BYTES OF ATLAS NAME      46800020
XCTLID   DS    CL2                      ID OF ATLAS MODULE              46900020
         DS    CL6                      *                               47000020
TTR      DS    CL3                      TTR OF ATLAS MODULE             47100020
         DS    CL5                      *                               47200020
TTRATTB  DS    CL2                      ATTRIBUTES OF ATLAS - ALL LOADS 47300020
TTRCREQ  DS    CL3                      CORE REQUIREMENT OF ATLAS LOAD  47400020
TTRLNGTH DS    CL2                      LENGTH OF ATLAS LOAD            47500020
         DS    CL3                      *                               47600020
INCRMNT  DS    1F                       INCREMENT FOR READ COUNTS       47700020
PROGADDR DS    1F                       ADDRESS OF NEW CHANNEL PROGRAM  47800020
ALTHA    DS    2F                       ALTERNATE TRACK HOME ADDRESS    47900020
ALTR0    DS    4F                       ALTERNATE TRACK R0              48000020
CCW1     DS    1D                       CCW AREA                        48100020
CCW2     DS    1D                       *                               48200020
CCW3     DS    1D                       *                               48300020
CCW44    DS    1D                       *                               48400020
CCW45    DS    1D                       *                               48500020
CCW56    DS    1D                       *                               48600020
CCW57    DS    1D                       *                               48700020
CCW31    DS    1D                       *                               48800020
CCW32    DS    1D                       *                               48900020
CCW33    DS    1D                       *                               49000020
CCW34    DS    1D                       *                               49100020
CCW35    DS    1D                       *                               49200020
CCW36    DS    1D                       *                               49300020
CCW37    DS    1D                       *                               49400020
CCW38    DS    1D                       *                               49500020
CCW39    DS    1D                       *                               49600020
CHECKHA  DS    2F                       AREA FOR HOME ADDRESS OF        49700020
*                                       ALTERNATE                       49800020
*                                                                       49900020
CVT      DSECT                                                          50000020
UCB      DSECT                                                          50100020
CNTAREA  DSECT                                                          50200020
HOMEAD   DS    2F                       CCW AREA                        50300020
R0       DS    4F                       *                               50400020
CCW21    DS    2F                       *                               50500020
CCW22    DS    2F                       *                               50600020
CCW23    DS    2F                       *                               50700020
         END                                                            50800020
