 TITLE 'IHGUADEL'                                                       00020000
*STATUS:                                                                00040000
*   CHANGE LEVEL 0                                                      00060000
*                                                                       00080000
*FUNCTION/OPERATION:                                                    00100000
*   THE DELETION PROGRAM (IHGUADEL) IS A SUPPORTING ROUTINE WHICH IS    00120000
*   DISTRIBUTED WITH THE UPDATE ANALYSIS PROGRAM.  CALLED BY AN         00140000
*   ANALYZER GENERATED EXEC CARD, THE DELETION PROGRAM USES THE         00160000
*   STOW MACRO INSTRUCTION TO DELETE MEMBER ENTRIES FROM SYSTEM         00180000
*   LIBRARY DIRECTORIES.                                                00200000
*                                                                       00220000
*ENTRY POINTS:                                                          00240000
*        DELSTART - THE FIRST INSTRUCTION OF THE PROGRAM IS ITS ONLY    00260000
*                   ENTRY POINT.                                        00280000
*                                                                       00300000
*INPUT:                                                                 00320000
*   THE PROGRAMS INPUT IS 80 CHARACTER CARD IMAGE RECORDS WHOSE         00340000
*   DDNAME IS SYSIN.                                                    00360000
*                                                                       00380000
*OUTPUT:                                                                00400000
*   COMPLETION MESSAGES ARE 120 CHARACTERS IN LENGTH AND ARE IN A       00420000
*   FORMAT SUITABLE FOR PRINTING.                                       00440000
*                                                                       00460000
*EXTERNAL ROUTINES:                                                     00480000
*   N/A                                                                 00500000
*EXITS-NORMAL:                                                          00520000
*   AFTER SUCCESSFUL OPERATION, THE PROGRAM EXITS WITH THE              00540000
*   FOLLOWING CALLING SEQUENCE:         L      13,DESAVEIT+4            00560000
*                                       RETURN (14,12)                  00580000
*                                                                       00600000
*EXITS-ERROR:                                                           00620000
*   N/A                                                                 00640000
*                                                                       00660000
*TABLES/WORK AREAS:                                                     00680000
*   N/A                                                                 00700000
*                                                                       00720000
*ATTRIBUTES:                                                            00740000
*   THE PROGRAM IS IN BLOCK FORMAT, NOT REENTERABLE, AND NOT SERIALLY   00760000
*   REUSABLE.                                                           00780000
*                                                                       00800000
*NOTES:                                                                 00820000
*    IHGUADEL IS THE UPDATE ANALYSIS DELETE PROGRAM.  IT IS TO BE       00840000
*     EXECUTED BY THE OUTPUT STREAM OF THE UPDATE ANALYSIS PROGRAM.     00860000
*     THIS PROG. DOES A STOW (DELETE) TO THE PART. DATA SET CALLED      00880000
*     OUT IN THE UADEL    DD STATEMENT.  THE SYSIN DD HAS CARDS WITH    00900000
*     THE MEMBER NAME IN COL 2 THAT IS TO BE DELETED.  COMPLETION MSG   00920000
*     GOES TO THE PRINTER AND AN ERROR MSG WOULD GO TO THE TYPEWRITER.  00940000
         SPACE 2                                                        00960000
IHGUADEL START                                                          00980000
D2       EQU   2                   GPR 2.                               01000000
D4       EQU   4                   GPR 4.                               01020000
D5       EQU   5                   GPR 5.                               01040000
         SPACE 2                                                        01060000
DELSTART SAVE  (14,12),,*               SAVE THE WORLD.                 01080000
         LR    D2,15                    LOAD BASE REG.                  01100000
         USING DELSTART,D2                                              01120000
         ST    13,DESAVEIT+4                                            01140000
         LA    13,DESAVEIT                                              01160000
         ST    13,DESAVEIT+8                                            01180000
         OPEN  (DEPRTDCB,(OUTPUT),DELIBDCB,(OUTPUT),DELINDCB,(INPUT))   01200000
DEL020   READ  DELDECB,SF,DELINDCB,DELINAR                              01220000
         CHECK DELDECB                                                  01240000
         MVI   DELOUTAR+4,C' '          CLEAR OUT THE                   01260000
         MVC   DELOUTAR+5(115),DELOUTAR+4   PRINT AREA.                 01280000
         MVC   DESTOWAR,DELINAR+1       MOVE NAME FROM CARD TO STOW AR. 01300000
         STOW  DELIBDCB,DESTOWAR,D      DELETE THE MEMBER.              01320000
         STC   15,DECOMCOD              STORE COMPLETE CODE.            01340000
         TM    DECOMCOD,X'1C'           WAS STOW SUCCESSFUL.            01360000
         BZ    DEL090                    YES.                           01380000
         TM    DECOMCOD,X'08'            NO. WAS THE NAME IN DIRECTORY. 01400000
         BO    DEL080                    NO.                            01420000
         MVC   DEL050+16(8),DELINAR+1    YES. THEN TELL THE OPERATOR    01440000
DEL050   WTO   'IHG032I          PERM I/O ERROR.'   OF THE I/O ERROR.   01460000
         LA    D4,DELMSGC               LOAD THE MSG ADDR               01480000
         IC    D5,DLENMSGC               AND LENGTH.                    01500000
         B     DEL100                                                   01520000
DEL080   LA    D4,DELMSGB               LOAD MSG  ADDR                  01540000
         IC    D5,DLENMSGB               AND LENGTH.                    01560000
         B     DEL100                                                   01580000
DEL090   LA    D4,DELMSGA               LOAD MSG ADDR                   01600000
         IC    D5,DLENMSGA               AND LENGTH.                    01620000
DEL100   EX    D5,DEMOVMSG              MOVE MSG TO PRINT AREA.         01640000
         MVC   DELOUTAR+8(8),DELINAR+1  MOVE MBR NAME TO PRINT AREA.    01660000
         WRITE DECBPRT,SF,DEPRTDCB,DELOUTCC  WRITE IT.                  01680000
         CHECK DECBPRT                                                  01700000
         B     DEL020                  RETURN TO GET ANOTHER CARD.      01720000
         SPACE 2                                                        01740000
DELEODAD CLOSE (DEPRTDCB,,DELIBDCB,,DELINDCB)    END OF DATA.           01760000
         L     13,DESAVEIT+4                                            01780000
         RETURN (14,12)                 RETURN TO CONTROL PROG.         01800000
         EJECT                                                          01820000
*                                                                       01840000
*    CONSTANTS, WORK AREAS AND MESSAGES.                                01860000
****************************************                                01880000
         SPACE                                                          01900000
DEMOVMSG MVC   DELOUTAR+4(0),0(D4)      MOVE MSG. CONSTANT              01920000
DESTOWAR DS    CL8                      STOW  MBR NAME AREA.            01940000
DELINAR  DS    CL80                     CARD INPUT AREA.                01960000
DECOMCOD DS    CL1                                                      01980000
DELOUTCC DC    C'0'                     CARRIAGE CONTROL.               02000000
DELOUTAR DC    C'IHG0'                  WRITE OUT AREA.                 02020000
         DS    CL128                                                    02040000
         SPACE 2                                                        02060000
DLENMSGA DC    HL1'29'                  LENGTH OF MSGA MINUS 1.         02080000
DLENMSGB DC    HL1'33'                  LENGTH OF MSGB MINUS 1.         02100000
DLENMSGC DC    HL1'28'                  LENGTH OF MSGC MINUS 1.         02120000
         SPACE 2                                                        02140000
DELMSGA  DC    CL30'31I          HAS BEEN DELETED.'                     02160000
DELMSGB  DC    CL34'32I          WAS NOT ON DIRECTORY.'                 02180000
DELMSGC  DC    CL29'33I          ,PERM I/O ERROR.'                      02200000
         SPACE 2                                                        02220000
DESAVEIT DS    18F                      SAVE AREA.                      02240000
         EJECT                                                          02260000
*   LIBRARY DCB                                                         02280000
*                                                                       02300000
DELIBDCB DCB   DSORG=PO,MACRF=(W),DDNAME=UADEL                          02320000
         EJECT                                                          02340000
*   CONTROL CARD INPUT DCB                                              02360000
*                                                                       02380000
DELINDCB DCB   DSORG=PS,MACRF=R,DDNAME=SYSIN,RECFM=F,                  C02400000
               BLKSIZE=80,EODAD=DELEODAD                                02420000
         EJECT                                                          02440000
*   PRINT OUT DCB                                                       02460000
*                                                                       02480000
DEPRTDCB DCB   DSORG=PS,MACRF=W,DDNAME=SYSPRINT,                       C02500000
               RECFM=FA,BLKSIZE=120                                     02520000
         END   DELSTART                                                 02540000
