BEAA TITLE 'EDIT COMMAND ACCESS METHOD -VECTOR TABLE ---IKJEBEAA'       00030020
IKJEBEAA CSECT                                                          00060020
*A009700,013300-013420                                           A45116 00070021
*   THE FOLLOWING ARE REGISTER ASSIGNMENTS                              00090020
PARMREG0 EQU   0                       PARM POINTER                     00120020
PARMREG1 EQU   1                       PARM POINTER                     00150020
FROMREG  EQU   2                       FROM ADDRESS REGISTER            00180020
TOREG    EQU   3                       TO ADDRESS REGISTER              00210020
WORK2    EQU   2                       WORK REGISTER                    00240020
WORK3    EQU   3                       WORK REGISTER                    00270020
WORK4    EQU   4                       WORK REGISTER                    00300020
WORK5    EQU   5                       WORK REGISTER                    00330020
WORK6    EQU   6                       WORK REGISTER                    00360020
WORK7    EQU   7                       WORK REGISTER                    00390020
WORK8    EQU   8                       WORK REGISTER                    00420020
LINK9    EQU   9                       SUBROUTINE LINK REGISTER         00450020
WORK9    EQU   9                       WORK REGISTER                    00480020
COMMREG  EQU   10                      VECTOR TABLE ADDRESSING          00510020
BASEREG  EQU   11                      BASE REGISTER                    00540020
DATAREG  EQU   12                      UTILITY WORK AREA ADDRESSING     00570020
SAVEREG  EQU   13                      SAVE AREA ADDRESSING             00600020
RETREG   EQU   14                      RETURN REGISTER                  00630020
RETCDREG EQU   15                      RETURN CODE                      00660020
ENTRY    EQU   15                      ENTRY POINT ADDRESS              00690020
         SPACE 1                                                        00720020
*   DEFINITIONS                                                         00750020
ZERO     EQU   0                       CONSTANT OF ZERO                 00780020
ONE      EQU   1                       CONSTANT OF ONE                  00810020
L2       EQU   2                       LENGTH OF TWO                    00840020
L3       EQU   3                       LENGTH OF THREE                  00870020
L4       EQU   4                       LENGTH OF FOUR                   00900020
L8       EQU   8                       LENGTH OF EIGHT                  00930020
X0       EQU   0                       OFFSET OF ZERO                   00960020
X1       EQU   1                       OFFSET OF ONE             A45116 00970021
FOUR     EQU   4                       CONSTANT OF FOUR                 00990020
K50      EQU   50                      CONSTANT OF 50                   01020020
K78      EQU   78                      CONSTANT OF 78                   01050020
K255     EQU   255                     CONSTANT OF 255                  01080020
PTR      EQU   4                       LENGTH OF ADDRESSES              01110020
NRF      EQU   4                       RECORD DOES NOT EXIST CODE       01140020
EMPTY    EQU   8                       EMPTY DATA SET CODE              01170020
IOERR    EQU   12                      I/O ERROR CODE                   01200020
SAVEL    EQU   72                      SAVE AREA LENGTH                 01230020
WORD1    EQU   0                       OFFSET TO 1ST PARAMETER WORD     01260020
WORD2    EQU   4                       OFFSET TO 2ND PARAMETER WORD     01290020
WORD3    EQU   8                       OFFSET TO 3RD PARAMETER WORD     01320020
EQUAL    EQU   8                       MASK FOR BRANCH ON EQUAL  A45116 01330021
NOTZERO  EQU   7                       MASK FOR BR ON NOT ZERO   A45116 01340021
RECHIGH  EQU   2                       MASK, RECORD KEY HIGH     A45116 01342021
COMPLETE EQU   X'40'                   I/O COMPLETE FLAG                01350020
GOOD     EQU   X'7F'                   I/O SUCCESSFUL FLAG              01380020
LAST     EQU   X'80'                   LAST ENTRY INDICATOR             01410020
ALL      EQU   X'FF'                   REPRESENTS ALL BITS//BYTE SWITCH 01440020
         SPACE 1                                                        01470020
*   MESSAGE REFERENCES-  INSERTION FOR I/O ERROR MESSAGE IS RETURNED    01500020
*     VIA 'SYNADAF' AND STORED IN THE 'IOMSG' FIELD OF THE WORKAREA.    01530020
         EJECT                                                          01560020
*********************************************************************** 01570020
*                                                                     * 01600020
*STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                      * 01610020
*                                                                     * 01620020
*FUNCTION- THIS LOAD MODULE IS COMPRISED OF 14 CSECTS, THE FIRST      * 01630020
*   OF WHICH MUST BE THIS VECTOR TABLE. THE VECTOR TABLE CONTAINS     * 01640020
*   THE ADDRESSES OF THE THIRTEEN ROUTINES WHICH COMPRISE THE ACCESS  * 01650020
*   METHOD. IN ADDITION, THIS TABLE ALSO CONTAINS THE ADDRESS OF      * 01660020
*   THE SYNAD ROUTINE ADDRESS. THIS ALLOWS THE SYNAD ADDRESS IN THE   * 01670020
*   DCB TO BE EASILY RE-ESTABILSHED IF THIS LOAD MODULE IS EVER       * 01680020
*   DELETED AND THEN RELOADED.                                        * 01690020
*                                                                     * 01700020
*   EACH OF THE FOLLOWING ROUTINES (CSECTS) HAS ITS OWN PROLOGUE      * 01710020
*                                                                     * 01720020
*   THIS VECTOR TABLE IS USED BY ALL ROUTINES IN THIS MODULE THAT     * 01730020
*   CALL OTHER ROUTINES                                               * 01740020
*                                                                     * 01750020
*ENTRY POINTS-  THREE ENTRY POINTS VIA A CALL FROM IKJEBEUT           * 01760020
*       IKJEBEDR             -DELETES RECORDS                         * 01770020
*       IKJEBERR             -READS RECORDS                           * 01780020
*       IKJEBEWR             -WRITES RECORDS                          * 01790020
*                                                                     * 01800020
*INPUT -- FOR INPUT INTO THE LOAD MODULE IKJEBEAA, SEE THE            * 01810020
*   PROLOGUE DESCRIPTIONS UNDER THE IKJEBEDR, IKJEBERR, AND           * 01820020
*   IKJEBEWR ROUTINES.                                                * 01830020
*                                                                     * 01840020
*OUTPUT -- FOR OUTPUT OF THE LOAD MODULE, IKJEBEAA, SEE THE           * 01850020
*   PROLOGUE DESCRIPTIONS UNDER THE IKJEBEDR, IKJEBERR, AND           * 01860020
*   IKJEBEWR ROUTINES.                                                * 01870020
*                                                                     * 01880020
*EXTERNAL REFERENCES --  THIS FIRST CSECT, IKJEBEAA, CONTAINS         * 01890020
*   VCONS FOR ALL THE ROUTINES IN LOAD MODULE IKJEBEAA.               * 01900020
*                                                                     * 01910020
*EXITS,NORMAL -- SEE EACH INDIVIDUAL ROUTINE PROLOGUE                 * 01920020
*                                                                     * 01930020
*EXITS,ERROR -- SEE EACH INDIVIDUAL ROUTINE PROLOGUE                  * 01940020
*                                                                     * 01950020
*TABLES-                                                              * 01960020
*   'VECTABLE' IS A DSECT THAT DESCRIBES THIS VECTOR TABLE AND IS     * 01970020
*   USED IN THE FOLLOWING ADDITIONAL MODULES-                         * 01980020
*       IKJEBEUI             -UTILITY INITIALIZATION                  * 01990020
*       IKJEBEUT             -UTILITY ACCESSING                       * 02000020
*                                                                     * 02010020
*   RECORD FORMAT-                                                    * 02020020
*        ********************************************************     * 02030020
*        *        *    *    *                                   *     * 02040020
*        *  KEY   * LL * 00 *    DATA                           *     * 02050020
*        *        *    *    *                                   *     * 02060020
*        ********************************************************     * 02070020
*                                                                     * 02080020
*          WHERE-                                                     * 02090020
*            KEY-   IS A 4 BYTE BINARY FIELD DENOTING THE             * 02100020
*                   LOGICAL POSITION OF THE RECORD IN THE DATA SET.   * 02110020
*                                                                     * 02120020
*            LL-    IS A 2 BYTE LENGTH FIELD IN BINARY AND IS THE     * 02130020
*                   TOTAL LENGTH OF THE RECORD, EXCLUDING THE 'KEY'   * 02140020
*                   FIELD.                                            * 02150020
*                                                                     * 02160020
*            00-    IS A 2 BYTE FIELD CONTAINING BINARY ZERO.         * 02170020
*                                                                     * 02180020
*            DATA-  A 1 TO 251 BYTE FIELD THAT IS NOT ACCESSED BY     * 02190020
*                   THESE ROUTINES AND CAN BE IN ANY DATA FORMAT      * 02200020
*                   REPRESENTATION.                                   * 02210020
*                                                                     * 02220020
*   BLOCK FORMATS-                                                    * 02230020
*                                                                     * 02240020
*        DATA BLOCKS-  DESCRIBED IN DSECT 'BUFFER', STARTS AT         * 02250020
*                      LABEL 'DATA'.                                  * 02260020
*                                                                     * 02270020
*        DIRECTORY BLOCKS- DESCRIBED IN DSECT 'BUFFER', STARTS AT     * 02280020
*                      LABEL 'NLEV'                                   * 02290020
*                                                                     * 02300020
*ATTRIBUTES- REFRESHABLE,ENABLED,NON-PRIVILEGED                       * 02310020
*                                                                     * 02320020
*NOTES -- THE VCONS ARE ORDER-DEPENDENT BECAUSE THEY ARE MAPPED       * 02330020
*   BY THE DSECT 'VECTABLE'                                           * 02340020
*                                                                     * 02350020
*   THIS ROUTINE IS CHARACTER CODE INDEPENDENT                        * 02360020
*                                                                     * 02370020
*********************************************************************** 02380020
         EJECT                                                          03060020
         SPACE 2                                                        03090020
*   THIS CSECT MUST BE THE FIRST IN THE LOAD MODULE.                  * 03120020
*   THE ENTRIES BELOW ARE ORDER DEPENDENT AND CONTAIN                   03150020
*     THE ADDRESSES FOR THE FOLLOWING ROUTINES                          03180020
         SPACE 2                                                        03210020
         DC    V(IKJEBEAD)             ADD-A-BLOCK                      03240020
         DC    V(IKJEBEAS)             BUFFER ASSIGNMENT                03270020
         DC    V(IKJEBEDL)             REMOVE A RECORD                  03300020
         DC    V(IKJEBEDR)             DELETE A RECORD                  03330020
         DC    V(IKJEBEDS)             DIRECTORY SEARCH                 03360020
         DC    V(IKJEBEDU)             DIRECTORY UPDATE                 03390020
         DC    V(IKJEBELO)             FIND A RECORD                    03420020
         DC    V(IKJEBEMV)             MOVE DATA                        03450020
         DC    V(IKJEBERB)             READ A BLOCK                     03480020
         DC    V(IKJEBERR)             READ A RECORD                    03510020
         DC    V(IKJEBEWA)             WAIT ON I/O                      03540020
         DC    V(IKJEBEWB)             WRITE A BLOCK                    03570020
         DC    V(IKJEBEWR)             WRITE A RECORD                   03600020
         DC    V(IKJEBESY)             SYNAD ROUTINE                    03630020
 TITLE 'EDIT COMMAND ACCESS METHOD --ADD A BLOCK ROUTINE ---IKJEBEAD'   03660020
*********************************************************************** 03690020
*                                                                     * 03780020
*STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                      * 03810020
*                                                                     * 03840020
*FUNCTION-  -THIS ROUTINE IS USED WHENEVER A NEW BLOCK IS ADDED       * 03870020
*   TO THE UTILITY DATA SET. IF THERE ARE ANY EMPTY BLOCKS IN THE     * 03900020
*   DATA SET, THEY WILL BE RE-USED FIRST. ASSIGNING AN EMPTY BLOCK    * 03930020
*   CONSISTS OF REMOVING IT FROM THE EMPTY BLOCK QUEUE. THIS UNCHAIN- * 03960020
*   ING PROCESS CONSISTS OF PICKING UP THE TTR OF THE FIRST BLOCK ON  * 03990020
*   THE QUEUE FROM THE WORKAREA. THIS BLOCK IS READ IN AND IF ANOTHER * 04020020
*   BLOCK IS CHAINED TO THAT BLOCK, ITS TTR POINTER IS STORED IN THE  * 04050020
*   WORKAREA. WHEN THE LAST BLOCK IS USED, THE QUEUE POINTER (TTR)    * 04080020
*   IS SET TO ZERO.                                                   * 04110020
*        IF THERE ARE NO EMPTY BLOCKS, A BUFFER IS ASSIGNED BY THE    * 04140020
*   BUFFER ASSIGNMENT ROUTINE, IKJEBEAS. THIS EMPTY BUFFER IS         * 04170020
*   USED TO INITIATE A WRITE OPERATION IN ORDER TO FORMAT THE NEW     * 04200020
*   BLOCK IN THE DATA SET.                                            * 04230020
*        THE BUFFER ADDRESS FOR THE ASSIGNED BLOCK IS PASSED BACK     * 04260020
*   IN THE INPUT PARM LIST                                            * 04290020
*                                                                     * 04320020
*ENTRY POINT-  AT IKJEBEAD VIA A CALL FROM EITHER                     * 04350020
*       IKJEBEDU             -THE DIRECTORY UPDATE ROUTINE            * 04380020
*       IKJEBEWR             -THE WRITE A RECORD ROUTINE              * 04410020
*                                                                     * 04440020
*INPUT- REGISTER ONE POINTS TO A TWO WORD PARAMETER LIST              * 04470020
*   WORD1  -CONTAINS ADDRESS OF THE UTILITY WORKAREA                  * 04500020
*   WORD2  -NOT USED ON INPUT                                         * 04530020
*                                                                     * 04560020
*OUTPUT- REGISTERS AS DESCRIBED UNDER 'EXIT' BELOW                    * 04590020
*   WORD2 OF THE INPUT PARM LIST CONTAINS THE ADDRESS OF THE NEW      * 04620020
*     BUFFER AND BLOCK.                                               * 04650020
*   IF THERE WERE ANY EMPTY BLOCKS, IT REMOVES THE FIRST ONE ON THE   * 04680020
*     QUEUE.                                                          * 04710020
*                                                                     * 04740020
*EXTERNAL REFERENCES --                                               * 04770020
*       IKJEBERB            -READS IN EMPTY BLOCKS                    * 04800020
*       IKJEBEAS            -ASSIGNS A NEW BUFFER                     * 04830020
*       IKJEBEWB            -FORMATS NEW BLOCK                        * 04860020
*       IKJEBEWA            -WAITS ON I/O                             * 04890020
*                                                                     * 04920020
*EXITS,NORMAL --                                                      * 04950020
*   A RETURN CODE OF 0 IN REGISTER 15                                 * 04980020
*   BUFFER ADDRESS IN WORD2 OF PASSED PARAMETER LIST                  * 05010020
*                                                                     * 05040020
*EXITS,ERROR --                                                       * 05070020
*   A RETURN CODE OF 12 IN REGISTER 15  FOR I/O ERRORS                * 05100020
*                                                                     * 05130020
*TABLES/WORKAREA --                                                   * 05160020
*   DEPENDENT ON THE EMPTY BLOCK POINTER IN THE WORKAREA              * 05190020
*   DEPENDENT ON THE TABLE OF ROUTINE ADDRESSES FOR THE ABOVE         * 05220020
*     DESCRIBED EXTERNAL ROUTINES                                     * 05250020
*                                                                     * 05280020
*ATTRIBUTES- REFRESHABLE, ENABLED, NON-PRIVILEGED                     * 05310020
*                                                                     * 05340020
*NOTES -- REGISTER CONVENTIONS ARE AS FOLLOWS-                        * 05370020
*       BASEREG              -BASE REGISTER                           * 05400020
*       DATAREG              -WORK AREA ADDRESSING                    * 05430020
*       COMMREG              -VECTOR TABLE ADDRESSING                 * 05460020
*       WORK6                -BUFFER ADDRESSING                       * 05490020
*                                                                     * 05520020
*   THIS ROUTINE IS CHARACTER CODE INDEPENDENT                        * 05550020
*                                                                     * 05580020
*********************************************************************** 05610020
         SPACE 2                                                        05640020
IKJEBEAD CSECT                                                          05670020
*   PERFORM THE INITIALIZATION OPERATIONS HERE                          05700020
         SAVE  (14,12),T,*                                              05730020
         LA    SAVEREG,SAVEL(SAVEREG)  STEP TO NEXT SAVEAREA            05760020
         LR    BASEREG,ENTRY           ENTRY POINT ADDRESS              05790020
         USING IKJEBEAD,BASEREG                                         05820020
         L     DATAREG,WORD1(PARMREG1) WORKAREA ADDRESS                 05850020
         USING UTILWORK,DATAREG                                         05880020
         L     COMMREG,VTABLE          TABLE OF ROUTINE ADDRESSES       05910020
         USING VECTABLE,COMMREG                                         05940020
         SPACE 2                                                        05970020
*   IF THERE ARE ANY EMPTY BLOCKS, USE THE FIRST OR ONLY IN CHAIN       06000020
         LR    WORK2,PARMREG1          SAVE INPUT PARM LIST ADDRESS     06030020
         OC    DCBEBQX(L4),DCBEBQX     ARE THERE ANY EMPTY BLOCKS       06060020
         BNZ   AD1                     YES-                             06090020
         L     ENTRY,AS                ENTRY POINT ADDRESS              06120020
         CALL  (15)                    ASSIGN A BUFFER                  06150020
         LTR   RETCDREG,RETCDREG       ANY I/O ERRORS                   06180020
         BNZ   AD6                     YES                              06210020
         L     WORK6,L4(PARMREG1)      ASSIGNED BUFFER ADDRESS          06240020
         USING BUFFER,WORK6                                             06270020
         SPACE 2                                                        06300020
*   INITIATE THE WRITE OF THE NEW BLOCK HERE                            06330020
         OI    BUFSTATS,NEWBLK         INDICATE NEWLY ASSIGNED BLOCK    06360020
         L     ENTRY,WB                ENTRY POINT ADDRESS              06390020
         CALL  (15)                    FORMAT THE NEW BLOCK             06420020
         LTR   RETCDREG,RETCDREG       ANY I/O ERRORS                   06450020
         BNZ   AD6                     YES--RETURN                      06480020
         ST    WORK6,WORD2(PARMREG1)   BUFFER ADDRESS TO PARM LIST      06510020
         L     ENTRY,WA                ENTRY POINT ADDRESS              06540020
         CALL  (15)                    WAIT FOR THE I/O                 06570020
         LTR   RETCDREG,RETCDREG       ANY ERRORS                       06600020
         BNZ   AD6                     YES-RETURN                       06630020
         SPACE 2                                                        06660020
*   EXIT TO CALLING PROGRAM HERE                                        06690020
AD50     SR    RETCDREG,RETCDREG       SET RETURN CODE                  06720020
AD6      EQU   *                       ERROR RETURNS HERE               06750020
AD5      L     SAVEREG,WORD2(SAVEREG)  OLD SAVE AREA                    06780020
         RETURN (14,12),T,RC=(15)      RESTORE THE REGISTERS            06810020
         SPACE 2                                                        06840020
*   EMPTY BLOCK PROCESSING HANDLED HERE                                 06870020
AD1      MVC   PARM2(L4),DCBEBQX       TTR OF FIRST EMPTY BLOCK         06900020
         L     ENTRY,RB                ENTRY POINT ADDRESS              06930020
         CALL  (15)                    READ IN THE EMPTY BLOCK          06960020
         LTR   RETCDREG,RETCDREG       SUCCESSFUL                       06990020
         BNZ   AD6                     NO--TERMINATE                    07020020
AD4      L     WORK6,WORD2(PARMREG1)   BUFFER ADDRESS                   07050020
         MVC   DCBEBQX(TTR),EBTTR      TTR OF NEXT EMPTY BLOCK, IF ANY  07080020
         MVI   BUFSTATS,ZERO           CLEAR BUFFER STATUS FLAGS        07110020
         B     AD50                    EXIT SUCCESSFULLY                07140020
         SPACE                                                          07170020
         DROP  BASEREG,DATAREG,COMMREG,WORK6                            07200020
 TITLE 'EDIT COMMAND ACCESS METHOD  -BUFFER ASSIGNMENT  ---IKJEBEAS'    07230020
*********************************************************************** 07260020
*                                                                     * 07350020
*STATUS -- VERSION NO. 01, OS/36/ RELEASE NO. 20                      * 07380020
*                                                                     * 07410020
*FUNCTION --  THIS ROUTINE ASSIGNS A BUFFER FOR A GIVEN        * A45213 07440021
*   REQUEST. BUFFERS ARE ASSIGNED BY INSPECTING THE BUFFER     * A45213 07460021
*   CHAIN. THE FIRST BUFFER ON THE CHAIN IS RESERVED FOR THE   * A45213 07480021
*   DSDB AND IS NEVER ASSIGNED. STARTING WITH THE SECOND       * A45213 07500021
*   BUFFER IN THE CHAIN, EACH BUFFER IS INTERROGATED TO SEE IF * A45213 07520021
*   IT IS AVAILABLE,I.E.NEITHER THE WAIT,UPDATE,OR BLOCK IN    * A45213 07540021
*   BUFFER FLAGS ARE ON, NOR IS THE LAST REFERENCED LLDB (IF   * A45213 07560021
*   ANY) CONTAINED IN THE BUFFER. THE FIRST FOUND AVAILABLE    * A45213 07580021
*   BUFFER IS THEN ASSIGNED TO FULFILL THE REQUEST.            * A45213 07600021
*       IN THE EVENT THAT NO BUFFERS ARE AVAILABLE, AN ATTEMPT * A45213 07620021
*   WILL BE MADE TO FREE-UP BUFFERS, BY EITHER WAITING FOR     * A45213 07640021
*   BUFFERS THAT HAVE AN I/O OPERATION SCHEDULED WHICH HAS     * A45213 07660021
*   NOT YET BEEN WAITED UPON,OR WRITING BACK BUFFERS THAT HAVE * A45213 07680021
*   BEEN UPDATED BUT HAVE NOT BEEN WRITTEN BACK TO DIRECT-     * A45213 07700021
*   ACCESSS.                                                   * A45213 07720021
*       FOR PERFORMANCE REASONS,THE LAST REFERENCED LLDB,      * A45213 07740021
*   POINTED TO BY THE DCBLLDB FIELD,WILL BE RETAINED IN CORE   * A45213 07760021
*   AS LONG AS POSSIBLE. HOWEVER IF A BUFFER CANNOT BE ASSIGNED* A45213 07780021
*   DUE TO THIS RETENTION,THE BUFFER CONTAINING THIS LLDB IS   * A45213 07800021
*   ASSIGNED.                                                    A45213 07820021
*                                                                     * 07980020
*ENTRY POINT --  AT IKJEBEAS VIA A CALL FROM EITHER-                  * 08010020
*       IKJEBEAD             -ADD A BLOCK ROUTINE                     * 08040020
*       IKJEBERB             -READ A BLOCK ROUTINE                    * 08070020
*                                                                     * 08100020
*INPUT --  REGISTER 1 POINTS TO A TWO WORD PARM LIST-                 * 08130020
*       WORD1-   -ADDRESS OF WORKAREA//DCB                            * 08160020
*       WORD2-   -NOT USED ON INPUT                                   * 08190020
*                                                                     * 08220020
*OUTPUT --  THE SECOND WORD OF THE INPUT PARM LIST CONTAINS THE       * 08250020
*   ADDRESS OF THE ASSIGNED BUFFER.                                   * 08280020
*   THE REGISTERS ARE AS DESCRIBED UNDER 'EXIT' BELOW.                * 08310020
*                                                                     * 08340020
*EXTERNAL REFERENCES --                                               * 08370020
*       IKJEBEWA             -WAITS ON I/O REQUESTS                   * 08400020
*       IKJEBEWB             -WRITE OUT UPDATED BLOCKS                * 08430020
*                                                                     * 08460020
*EXITS,NORMAL --  REGISTER 15 CONTAINS A RETURN CODE OF 0.            * 08490020
*   WORD2 OF INPUT PARM LIST CONTAINS THE BUFFER ADDRESS              * 08520020
*                                                                     * 08550020
*EXITS,ERROR -- A RETURN CODE OF 12 IN REGISTER 15 FOR I/O ERRORS     * 08580020
*                                                                     * 08610020
*TABLES/WORK AREAS --                                                 * 08640020
*       DEPENDENT ON THE WORKAREA, 'UTILWORK'.                        * 08670020
*       DEPENDENT ON THE BUFFER DESCRIPTION.                          * 08700020
*       DEPENDENT ON THE VECTOR TABLE FOR EXTERNAL REFERENCES         * 08730020
*                                                                     * 08760020
*ATTRIBUTES -- REFERESHABLE, NON-PRIVILEGED,  ENABLED                 * 08790020
*                                                                     * 08820020
*NOTE -- THE REGISTER CONVENTIONS ARE AS FOLLOWS-                     * 08850020
*       BASEREG              -BASE REGISTER                           * 08880020
*       DATAREG              -WORK AREA ADDRESSING                    * 08910020
*       COMMREG              -VECTOR TABLE ADDRESS                    * 08940020
*       WORK6                -BUFFER ADDRESSING                       * 08970020
*                                                                     * 09000020
*   THIS ROUTINE IS CHARACTER CODE INDEPENDENT                        * 09030020
*                                                                     * 09060020
*********************************************************************** 09090020
         SPACE 2                                                        09120020
IKJEBEAS CSECT                                                          09150020
         SPACE                                                          09160021
*A074400-079500,095400-099700,108900-109940                      A45213 09170021
*D074400-078200,095400-102600,108900-109800                      A45213 09172021
         SPACE                                                          09174021
*   PERFORM THE INITIALIZATION OPERATIONS HERE                          09180020
         SAVE  (14,12),T,*             SAVE THE REGISTERS               09210020
         LA    SAVEREG,SAVEL(SAVEREG)  STEP TO NEXT SAVEAREA            09240020
         LR    BASEREG,ENTRY           ENTRY POINT ADDRESS              09270020
         USING IKJEBEAS,BASEREG                                         09300020
         L     DATAREG,WORD1(PARMREG1) WORKAREA ADDRESS                 09330020
         USING UTILWORK,DATAREG                                         09360020
         L     COMMREG,VTABLE          TABLE OF ROUTINE ADDRESSES       09390020
         USING VECTABLE,COMMREG                                         09420020
         LR    WORK2,PARMREG1          SAVE INPUT PARM ADDRESS          09450020
         SPACE 2                                                        09480020
*   LOOK FOR AN AVAILABLE BUFFER                                        09510020
* CHECK FOR UPDATED,WAITING,LLDB AND BLKINBUF HERE               A45213 09540021
*                                                                A45213 09550021
         USING BUFFER,WORK6                                      A45213 09560021
*                                                                A45213 09570021
         LA    WORK3,UPDATED+WAITB+WAITXR+WAITXW+BLKINBUF        A45213 09580021
*                                      GET TEST BITS             A45213 09590021
         BAL   RETREG,AS8              TEST BUFFER STATUS        A45213 09600021
*                                      IF A SUITABLE BUFFER WAS  A45213 09610021
*                                      FOUND,CONTROL IS RETURNED A45213 09620021
*                                      HERE, ELSE THE NEXT       A45213 09630021
*                                      INSTRUCTION IS SKIPPED.   A45213 09640021
         B     AS2                     *B TO ASSIGN BUFFER       A45213 09650021
         SPACE 2                                                 A45213 09660021
* CHECK FOR A BUFFER THAT CAN BE WAITED UPON HERE                A45213 09670021
         LA    WORK3,UPDATED+BLKINBUF  GET TEST BITS             A45213 09680021
         BAL   RETREG,AS8              TEST BUFFER STATUS        A45213 09690021
*                                      IF A SUITABLE BUFFER HAS  A45213 09700021
*                                      BEEN FOUND,CONTROL IS     A45213 09710021
*                                      RETURNED HERE,ELSE THE    A45213 09720021
*                                      NEXT INSTRUCTION IS       A45213 09730021
*                                      SKIPPED.                  A45213 09740021
         B     AS3                     *B TO WAIT ON BUFFER      A45213 09750021
         SPACE 2                                                 A45213 09760021
* CHECK FOR A BUFFER THAT CAN BE PURGED HERE                     A45213 09770021
         LA    WORK3,BLKINBUF          GET TEST BITS             A45213 09780021
         BAL   RETREG,AS8              TEST BUFFER STATUS        A45213 09790021
*                                      IF A PURGEABLE BUFFER HAS A45213 09800021
*                                      BEEN FOUND,CONTROL IS     A45213 09810021
*                                      RETURNED HERE,ELSE THE    A45213 09820021
*                                      NEXT INSTRUCTION IS       A45213 09830021
*                                      SKIPPED.                  A45213 09840021
         B     AS4                     *B TO PURGE PURGEABLE BUF A45213 09850021
         SPACE 2                                                        09860021
* NO BUFFER AVAILABLE, CAN ONLY HAPPEN IF BLKINBUF FLAG IS ONE   A45213 09870021
* IN ONE BUFFER (THIS FLAG IS SET TO ONE IN AT MOST ONE BUFFER   A45213 09880021
* AT ANY TIME), AND AN LLDB IS IN THE OTHER. USE THE LLDB BUFFER A45213 09890021
         SPACE                                                          09900021
         L     WORK6,DCBLLDB           YES-USE WITHOUT PURGE     A45213 09910021
         XC    DCBLLDB,DCBLLDB         ZERO PTR                  A45213 09920021
         TM    BUFSTATS,UPDATED        MUST LLDB BE WRITTEN OUT  A45213 09930021
         BZ    AS2                     NO, ASSIGN THIS BUFFER    A45213 09940021
         SPACE 2                                                 A45213 09950021
* PURGE BUFFER BY WRITING IT TO D-A HERE                         A45213 09960021
AS4      ST    WORK6,WORD2(WORK2)      STORE IN PARMLIST         A45213 09970021
         LR    PARMREG1,WORK2          ADDRESS LIST                     10290020
         L     ENTRY,WB                ENTRY POINT ADDRESS              10320020
         CALL  (15)                    WRITE OUT THIS BLOCK             10350020
         LTR   RETCDREG,RETCDREG       ANY ERRORS                       10380020
         BNZ   AS9                     YES-RETURN                       10410020
         SPACE 2                                                        10440020
*   WAIT FOR A BUFFER TO EMPTY BEFORE ASSIGNING IT                      10470020
AS3      ST    WORK6,WORD2(WORK2)      BUFFER ADDRESS TO LIST           10500020
         L     ENTRY,WA                ENTRY POINT ADDRESS              10530020
         CALL  (15)                    WAIT FOR THE I/O TO COMPLETE     10560020
         LTR   RETCDREG,RETCDREG       ANY I/O ERRORS                   10590020
         BNZ   AS9                     YES-RETURN                       10620020
         SPACE 2                                                        10650020
*   ASSIGN THE SELECTED BUFFER HERE                                     10680020
AS2      ST    WORK6,WORD2(PARMREG1)   BUFFER ADDRESS                   10710020
         SR    RETCDREG,RETCDREG       SET RETURN CODE = 0              10740020
AS9      EQU   *                       RETURN ON ERRORS HERE            10770020
AS11     L     SAVEREG,WORD2(SAVEREG)  OLD SAVE AREA                    10800020
         RETURN (14,12),T,RC=(15)      RESTORE THE REGISTERS            10830020
         SPACE 2                                                        10860020
* SEARCH THE BUFFER CHAIN FOR A SUITABLE BUFFER HERE             A45213 10890021
AS8      L     WORK6,DCBBUFAD          BUFFER CHAIN ADDRESS      A45213 10898021
AS81     L     WORK6,BUFCHAIN          DATA BUFFER ADDRESS       A45213 10906021
         LA    WORK6,X0(WORK6)         CLEAR HIGH BYTE           A45213 10914021
         XR    WORK4,WORK4             CLEAR FOR INSERT          A45213 10922021
         IC    WORK4,BUFSTATS          GET BUFFER STATUS         A45213 10930021
         NR    WORK4,WORK3             ARE ANY RELEVANT FLAGS ON A45213 10938021
         BC    NOTZERO,AS82            YES, BUFFER NOT SUITABLE  A45213 10946021
         C     WORK6,DCBLLDB           IS THIS CURRENT LLDB BUF  A45213 10954021
         BNE   X0(,RETREG)             NO-BUFFER IS SUITABLE     A45213 10962021
AS82     OC    BUFCHAIN+ONE(L3),BUFCHAIN+ONE  ANY MORE BUFFERS   A45213 10970021
         BNZ   AS81                    YES TRY NEXT BUFFER       A45213 10978021
         B     FOUR(,RETREG)           NO-SUITABLE BUFFER NOT    A45213 10986021
*                                      FOUND                     A45213 10994021
         SPACE 2                                                        11010020
         DROP  BASEREG,DATAREG,COMMREG,WORK6                            11040020
 TITLE 'EDIT COMMAND ACCESS METHOD --RECORD REMOVAL ---IKJEBEDL'        11070020
*********************************************************************** 11100020
*                                                                     * 11190020
*STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                      * 11220020
*                                                                     * 11250020
*FUNCTION --  THIS ROUTINE DELETES THE RECORD INDICATED BY THE        * 11280020
*   'BUFREF' FIELD IN THE SELECTED BUFFER.  DELETION OF A RECORD      * 11310020
*   INVOLVES REMOVING THE LOCATOR FOR THAT RECORD, ADJUSTING THE      * 11340020
*   POSITION OF OTHER LOCATORS IF NECESSARY, UPDATING THE RECORD      * 11370020
*   COUNT, AND MODIFYING THE SPACE CONTROL FIELDS FOR THAT BLOCK.     * 11400020
*        IF THE LAST RECORD OF A BLOCK IS DELETED, ONE OR MORE        * 11430020
*   INDEX ENTRIES IN THE DIRECTORY WILL BE UPDATED.                   * 11460020
*        ANYTIME A DELETION RESULTS IN AN EMPTY BLOCK, THAT BLOCK     * 11490020
*   WILL BE PLACED IN THE EMPTY BLOCK QUEUE.                          * 11520020
*                                                                     * 11550020
*ENTRY POINT --                                                       * 11580020
*       IKJEBEDL   -VIA A CALL FROM EITHER IKJEBEDR OR IKJEBEWR       * 11610020
*                                                                     * 11640020
*INPUT --  REGISTER ONE POINTS TO A TWO WORD PARAMETER LIST-          * 11670020
*       WORD1-     POINTS TO THE WORKAREA, UTILWORK.                  * 11700020
*       WORD2-     POINTS TO THE SELECTED BUFFER.                     * 11730020
*                                                                     * 11760020
*OUTPUT --  THE RECORD INDICATED BY THE BUFREF FIELD HAS BEEN         * 11790020
*   REMOVED FROM THE BUFFER AND THE DATA BLOCK CONTROL FIELDS         * 11820020
*   UPDATED.  THE DIRECTORY IS UPDATED IF THE LAST LOGICAL RECORD     * 11850020
*   IS DELETED.  THE EMPTY BLOCK QUEUE TAKES ON A NEW ENTRY IF        * 11880020
*   AN EMPTY DATA BLOCK OR DIRECTORY BLOCK RESULTS BECAUSE OF THE     * 11910020
*   RECORD DELETION.                                                  * 11940020
*                                                                     * 11970020
*EXTERNAL REFERENCES --                                               * 12000020
*       IKJEBEMV             -MOVES INDICES OR LOCATORS               * 12030020
*       IKJEBEDS             -SEARCHES THE DIRECTORY                  * 12060020
*       IKJEBERB             -READS A DIRECTORY BLOCK                 * 12090020
*       IKJEBEWB             -WRITE OUT BLOCKS                        * 12120020
*                                                                     * 12150020
*EXITS,NORMAL -- RETURNS TO THE CALLING ROUTINE//RETURN CODES-        * 12180020
*       RETURN CODE =0   NORMAL DELETION, OUTPUT AS ABOVE.            * 12210020
*       RETURN CODE =8   EMPTY DATA SET,  OUTPUT AS ABOVE.            * 12240020
*                                                                     * 12270020
*EXITS,ERROR --  RETURNS TO CALLING ROUTINE -                         * 12300020
*       RETURN CODE = 12 I/O ERROR ENCOUNTERED.                       * 12330020
*                                                                     * 12360020
*TABLES/WORKAREAS --                                                  * 12390020
*       DEPENDENT ON EMPTY BLOCK QUEUE POINTER IN WORKAREA.           * 12420020
*       DEPENDENT ON 'BUFFER' DSECT DESCRIPTION                       * 12450020
*                                                                     * 12480020
*ATTRIBUTES -- REFRESHABLE, ENABLED, NON-PRIVILEGED                   * 12510020
*                                                                     * 12540020
*NOTES --  REGISTER CONVENTIONS ARE AS FOLLOWS-                       * 12570020
*       BASEREG              -BASE REGISTER                           * 12600020
*       COMMREG              -VECTOR TABLE ADDRESSING                 * 12630020
*       DATAREG              -WORK AREA ADDRESSING                    * 12660020
*       WORK6                -BUFFER ADDRESSING                       * 12690020
*       WORK2,WORK3          -WORK REGISTERS                          * 12720020
*       WORK4,WORK5          -WORK REGISTERS                          * 12750020
*                                                                     * 12780020
*   THIS ROUTINE IS CHARACTER CODE INDEPENDENT                        * 12810020
*                                                                     * 12840020
*********************************************************************** 12870020
         SPACE 2                                                        12900020
IKJEBEDL CSECT                                                          12930020
*   PERFORM THE INITIALIZATION OPERATIONS HERE                          12960020
         SAVE  (14,12),T,*             SAVE THE REGISTERS               12990020
         LA    SAVEREG,SAVEL(SAVEREG)  STEP TO NEXT SAVEAREA            13020020
         LR    BASEREG,ENTRY           ENTRY POINT ADDRESS              13050020
         USING IKJEBEDL,BASEREG                                         13080020
         L     DATAREG,WORD1(PARMREG1) WORKAREA ADDRESS                 13110020
         USING UTILWORK,DATAREG                                         13140020
         L     COMMREG,VTABLE          TABLE OF ROUTINE ADDRESSES       13170020
         USING VECTABLE,COMMREG                                         13200020
         SPACE 2                                                        13230020
*   INDICATE BUFFER MODIFIED AND DECREMENT THE RECORD COUNT             13260020
         L     WORK6,WORD2(PARMREG1)   BUFFER ADDRESS                   13290020
         USING BUFFER,WORK6                                             13320020
         OI    BUFSTATS,UPDATED        INDICATE MODIFICATION TO BUFFER  13350020
         LH    WORK4,NUMREC            NUMBER OF RECORDS IN BLOCK       13380020
         BCTR  WORK4,ZERO              REDUCE RECORD COUNT BY ONE       13410020
         LTR   WORK4,WORK4             THIS AN EMPTY BLOCK NOW          13440020
         BNP   DL3                     YES-GO PUT IN EMPTY BLOCK QUEUE  13470020
         STH   WORK4,NUMREC            SAVE NEW RECORD COUNT            13500020
         SPACE 2                                                        13530020
*   OBTAIN CONTENTS OF LOCATOR AND LENGTH OF RECORD                     13560020
         SLA   WORK4,ONE               DOUBLE FOR INCREMENT TO LAST     13590020
         LA    PARMREG0,LOCATORS(WORK4) ADDRESS OF LAST LOCATOR         13620020
         L     WORK4,BUFREF            RECORD LOCATOR ADDRESS           13650020
         LH    WORK2,X0(WORK4)         CONTENTS OF LOCATOR              13680020
         LA    WORK5,DATA(WORK2)       RECORD ADDRESS                   13710020
         MVC   TEMP1(L2),KEYL(WORK5)   LENGTH OF RECORD                 13740020
         LH    WORK3,TEMP1             LENGTH OF RECORD                 13770020
         LA    WORK3,KEYL(WORK3)       ACCOUNT FOR KEY LENGTH           13800020
         SPACE 2                                                        13830020
*   IS THIS THE FIRST PHYSICAL RECORD                                   13860020
         CH    WORK2,DATASTRT          CHECK FOR FIRST PHYSICAL RECORD  13890020
         BE    DL4                     YES                              13920020
         AH    WORK3,RECVSP            OLD USABLE SPACE PLUS NEW        13950020
         STH   WORK3,RECVSP            SAVE FOR FUTURE USE              13980020
         B     DL1                     GO CHECK IF LAST LOGICAL         14010020
         SPACE 2                                                        14040020
*   IS THIS THE LAST LOGICAL RECORD                                     14070020
DL4      AH    WORK3,DATASTRT          OFFSET TO 1ST RECORD PLUS LENGTH 14100020
         STH   WORK3,DATASTRT            OF DELETED RECORD              14130020
DL1      SR    PARMREG0,WORK4          IS DELETED LOCATOR THE LAST      14160020
         BZ    DL9                     YES-MUST CHECK DIRECTORY         14190020
*                                      NO--REGISTER (PARMREG0) NOW      14220020
*                                      CONTAINS THE NO. OF BYTES TO     14250020
*                                      MOVE THE LOCATORS                14280020
         SPACE 2                                                        14310020
*   ADJUST LOCATORS TO FILL EMPTY POSITION                              14340020
         ST    WORK4,TEMP2             DELETED LOCATOR/MOVE-TO ADDRESS  14370020
         LA    WORK4,LOCL(WORK4)       ADDRESS OF NEXT LOCATOR          14400020
         ST    WORK4,TEMP1             MOVE FROM ADDRESS                14430020
         LA    PARMREG1,TEMP1          PARM LIST ADDRESS                14460020
         L     ENTRY,MV                ENTRY POINT ADDRESS              14490020
         CALL  (15)                    MOVE THE LOCATORS DOWN           14520020
         SPACE 2                                                        14550020
*   SET RETURN CODE AND EXIT HERE                                       14580020
DL2      SR    RETCDREG,RETCDREG       SET RETURN CODE = 0.             14610020
         L     WORK4,DCBRECNO          GET PREVIOUS RECORD COUNT        14617020
         BCTR  WORK4,ZERO              LOWER RECORD COUNT BY ONE        14624020
         ST    WORK4,DCBRECNO          STORE NEW COUNT                  14631020
DL15     EQU   *                       LEAVE RETURN CODE AS IS          14640020
DL7      L     SAVEREG,WORD2(SAVEREG)  OLD SAVE AREA                    14670020
         RETURN (14,12),T,RC=(15)      RESTORE THE REGISTERS            14700020
         SPACE 2                                                        14730020
*   PUT DATA BLOCKS IN THE EMPTY BLOCK QUEUE HERE                       14760020
DL3      MVC   EBTTR(L4),DCBEBQX       PREVIOUS EB TTR IF ANY, ELSE 0   14790020
         MVC   DCBEBQX(L4),BUFTTR      THIS NEW EB TTR FIRST IN CHAIN   14820020
         L     ENTRY,WB                ENTRY POINT ADDRESS              14850020
         CALL  (15)                    WRITE OUT THE EMPTY BLOCK        14880020
         LTR   RETCDREG,RETCDREG       ANY ERRORS                       14910020
         BNZ   DL15                    YES-RETURN                       14940020
         SPACE 2                                                        14970020
*   FIND DIRECTORY ENTRY FOR THIS BLOCK                                 15000020
         LA    WORK4,PRIMEKEY          KEY ADDRESS OF DELETED RECORD    15030020
         ST    WORK4,PARM2             STORE IN PARM LIST               15060020
         L     ENTRY,DS                ENTRY POINT ADDRESS              15090020
         CALL  (15)                    FIND THE DIRECTORY ENTRY         15120020
         LTR   RETCDREG,RETCDREG       ANY I/O ERRORS                   15150020
         BNZ   DL15                    YES-RETURN                       15180020
         SPACE 2                                                        15210020
*   UPDATE DIRECTORY BLOCK HERE                                         15240020
         L     WORK6,WORD2(PARMREG1)   INDEX BUFFER                     15270020
DL51     OI    BUFSTATS,UPDATED        INDICATE MODIFICATION            15300020
         LH    PARMREG1,NUMINDEX       NO. OF ENTRIES//THIS BLOCK       15330020
         BCTR  PARMREG1,ZERO           LESS ONE                         15360020
         STH   PARMREG1,NUMINDEX       SAVE NEW TOTAL OF ENTRIES        15390020
         LTR   PARMREG1,PARMREG1       IS BLOCK EMPTY NOW               15420020
         BP    DL8                     NO--PROCEED WITH UPDATE          15450020
         SPACE 2                                                        15480020
*   THIS IS AN EMPTY DIRECTORY BLOCK//CHECK IF LAST LEVEL               15510020
         CLC   NLEV(L2),DCBNLEV        IS THIS THE LAST LEVEL           15540020
         BNE   DL5                     NO--GO PUT BLOCK IN EMPTY QUEUE  15570020
DL6      XC    NLEV(L2),NLEV           RESET TO LEVEL 0 IN DSDB         15600020
         XC    DCBNLEV(L2),DCBNLEV     HIGHEST LEVEL = ZERO             15630020
         LA    RETCDREG,EMPTY          RETURN CODE//DATA SET EMPTY      15660020
         B     DL15                    RETURN TO CALLING ROUTINE        15690020
         SPACE 2                                                        15720020
*   PUT DIRECTORY BLOCKS IN THE EMPTY BLOCK QUEUE HERE                  15750020
DL5      MVC   EBTTR(FOUR),DCBEBQX     PREVIOUS EB TTR,IF ANY,ELSE 0    15780020
         MVC   DCBEBQX(FOUR),BUFTTR    THIS NEW EB TTR/ FIRST IN CHAIN  15810020
         LA    PARMREG1,PARM1          PARAMETER LIST ADDRESS           15840020
         L     ENTRY,WB                ENTRY POINT ADDRESS              15870020
         CALL  (15)                    WRITE OUT THE EMPTY BLOCK        15900020
         LTR   RETCDREG,RETCDREG       ANY ERRORS                       15930020
         BNZ   DL15                    YES-RETURN                       15960020
         SPACE 2                                                        15990020
*   FIND PREVIOUS ENTRY FOR THIS DIRECTORY BLOCK                        16020020
         MVC   INDEXSAV(KEYL),INDICES  KEY OF ONLY ENTRY IN BLOCK       16050020
         BAL   LINK9,DL300             GO FIND THE PREVIOUS LEVEL       16080020
         B     DL51                    UPDATE THIS PREVIOUS LEVEL       16110020
         SPACE 2                                                        16140020
*   UPDATE THE DIRECTORY BLOCK HERE                                     16170020
DL8      L     WORK3,BUFREF            ADDRESS OF ENTRY TO BE DELETED   16200020
         LR    PARMREG0,WORK3          ENTRY TO BE DELETED              16230020
         LH    WORK2,DLDIRSZ           SIZE OF EACH ENTRY               16260020
         SR    PARMREG0,WORK2          LESS THE LENGTH                  16290020
         ST    PARMREG0,BUFREF         SET TO PREVIOUS ENTRY            16320020
         AR    WORK2,WORK3             ADDRESS OF NEXT ENTRY            16350020
         MH    PARMREG1,DLDIRSZ        ENTRIES-1 TIMES LENGTH EQUALS    16380020
         LA    PARMREG1,INDICES(PARMREG1) ADDRESS OF LAST ENTRY         16410020
         SR    PARMREG1,WORK3          NO. OF BYTES TO MOVE             16440020
         BZ    DL10                    BRANCH IF LAST ENTRY             16470020
         LR    PARMREG0,PARMREG1       BYTE COUNT                       16500020
         SPACE 2                                                        16530020
*   MUST ADJUST THE INDEX ENTRIES                                       16560020
         ST    WORK3,TEMP2             ADDRESS DELETED ENTRY//MOVE TO   16590020
         ST    WORK2,TEMP1             NEXT ENTRY//MOVE-FROM            16620020
         LA    PARMREG1,TEMP1          PARM LIST ADDRESS                16650020
         L     ENTRY,MV                ENTRY POINT ADDRESS              16680020
         CALL  (15)                    MOVE THE INDICES DOWN            16710020
         SPACE 2                                                        16740020
*   CHECK STATUS OF DIRECTORY UPDATE                                    16770020
DL10     CLC   NLEV(L2),DCBNLEV        IS THIS THE DSDB BEING CHECKED   16800020
         BNE   DL11                    NO--GO MAKE MORE CHECKS          16830020
         B     DL2                     YES-RETURN                       16860020
         SPACE 2                                                        16890020
*   SAVE KEY NEW-LAST RECORD                                            16920020
DL9      BCTR  WORK4,ZERO              DECREMENT TO PREVIOUS LOCATOR    16950020
         BCTR  WORK4,ZERO              ADDRESS OF NEW LAST LOCATOR      16980020
         LH    WORK2,X0(WORK4)         CONTENTS OF THAT LOCATOR         17010020
         LA    WORK2,NUMREC(WORK2)     ADDRESS OF RECORD                17040020
         MVC   SECONKEY(KEYL),X0(WORK2) KEY OF NEW LAST RECORD          17070020
         SPACE 2                                                        17100020
*   FIND THE DIRECTORY BLOCK FOR PRIMEKEY                               17130020
DL91     ST    DATAREG,PARM1           WORK AREA ADDRESS                17160020
         LA    WORK2,PRIMEKEY          ADDRESS OF DESIRED KEY           17190020
         ST    WORK2,PARM2             STORE IN PARAMETER LIST          17220020
         LA    PARMREG1,PARM           PARM LIST ADDRESS                17250020
         L     ENTRY,DS                ENTRY POINT ADDRESS              17280020
         CALL  (15)                    FIND DIRECTORY ENTRY FOR KEY     17310020
*                                        THAT WAS LAST RECORD OF DB     17340020
         LTR   RETCDREG,RETCDREG       ANY I/O ERRORS                   17370020
         BNZ   DL15                    YES-RETURN                       17400020
         SPACE 2                                                        17430020
*   UPDATE FOUND ENTRY WITH NEW-LAST KEY                                17460020
         L     WORK6,WORD2(PARMREG1)   SELECTED BUFFER ADDRESS          17490020
DL12     L     WORK3,BUFREF            LOCATED INDEX ENTRY/KEY ADDRESS  17520020
         MVC   X0(KEYL,WORK3),SECONKEY SET NEW KEY VALUE IN ENTRY       17550020
         OI    BUFSTATS,UPDATED        INDICATE BUFFER MODIFIED         17580020
         SPACE 2                                                        17610020
*   IF THIS IS THE DSDB OR NOT THE LAST ENTRY, THEN RETURN              17640020
         CLC   NLEV(L2),DCBNLEV        IS THIS THE DSDB                 17670020
         BE    DL2                     YES--RETURN                      17700020
DL11     LH    WORK2,NUMINDEX          NUMBER OF ENTRIES IN BLOCK       17730020
         BCTR  WORK2,ZERO              LESS ONE                         17760020
         MH    WORK2,DLDIRSZ           DISPLACEMENT TO LAST ENTRY       17790020
         LA    WORK2,INDICES(WORK2)    ADDRESS OF LAST ENTRY            17820020
         CL    WORK2,BUFREF            WAS ALTERED ENTRY LAST           17850020
         BNE   DL2                     NO--ALL FINISHED//RETURN         17880020
         MVC   INDEXSAV(KEYL),X0(WORK2) KEY OF LAST ENTRY               17910020
         MVC   SECONKEY(KEYL),X0(WORK2) KEY OF LAST ENTRY               17940020
         BAL   LINK9,DL300             GO FIND THE PREVIOUS LEVEL       17970020
         B     DL12                    GO UPDATE THIS LEVEL             18000020
         SPACE 2                                                        18030020
*   FIND PREVIOUS LEVEL OF DIRECTORY BY LOOKING FOR TTR                 18060020
DL300    MVC   INDEXSAV+KEYL(TTR),BUFTTR TTR OF THIS BLOCK              18090020
         L     WORK6,DCBBUFAD          ADDRESS OF DIRECTORY START       18120020
DL306    LH    WORK3,NUMINDEX          NUMBER OF ENTRIES THIS BLOCK     18150020
         LA    WORK5,INDICES           FIRST ENTRY ADDRESS              18180020
DL320    CLC   INDEXSAV+KEYL(TTR),KEYL(WORK5) IS THE TTR THE SAME       18210020
         BE    DL321                   YES-CORRECT ENTRY FOUND          18240020
         LA    WORK5,KEYL+TTR(WORK5)   NEXT ENTRY ADDRESS               18270020
         BCT   WORK3,DL320             REPEAT UNTIL ALL ENTRIES CHECKED 18300020
         SPACE 2                                                        18330020
*   FIND PREVIOUS LEVEL BY LOOKING FOR KEY                              18360020
         LA    WORK5,INDICES           ADDRESS OF FIRST ENTRY           18390020
DL323    CLC   INDEXSAV(KEYL),X0(WORK5) THIS THE DESIRED ENTRY          18420020
         BNH   DL304                   YES-ENTRY FOUND                  18450020
         LA    WORK5,KEYL+TTR(WORK5)   NO--STEP TO NEXT ENTRY           18480020
         B     DL323                   REPEAT UNTIL ENTRY FOUND         18510020
         SPACE 2                                                        18540020
*   READ IN THE NEXT LEVEL IF NECESSARY                                 18570020
DL304    MVC   PARM2(TTR),KEYL(WORK5)  TTR OF NEXT LEVEL                18600020
         LA    PARMREG1,PARM1          PARAMETER LIST ADDRESS           18630020
         L     ENTRY,RB                ENTRY POINT ADDRESS              18660020
         CALL  (15)                    READ IN NEXT LEVEL               18690020
         LTR   RETCDREG,RETCDREG       ANY ERRORS                       18720020
         BNZ   DL15                    YES-RETURN                       18750020
         L     WORK6,WORD2(PARMREG1)   ADDRESS OF BUFFER/BLOCK          18780020
         B     DL306                   REPEAT UNTIL PROPER LEVEL FOUND  18810020
DL321    ST    WORK5,BUFREF            FOUND ENTRY ADDRESS              18840020
         BR    LINK9                   RETURN TO CALLER                 18870020
         SPACE 2                                                        18900020
         DROP  BASEREG,COMMREG,DATAREG,WORK6                            18930020
         SPACE 2                                                        18960020
*   CONSTANTS FOR THE RECORD REMOVAL ROUTINE                            18990020
DLONE    DC    H'1'                    COMPARE CONSTANT OF ONE          19020020
DLDIRSZ  DC    H'7'                    LENGTH OF DIRECTORY ENTRY        19050020
         TITLE 'EDIT COMMAND ACCESS METHOD -RECORD DELETE ---IKJEBEDR'  19080020
*********************************************************************** 19110020
*                                                                     * 19170020
*STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                      * 19200020
*                                                                     * 19230020
*FUNCTION --  THIS ROUTINE IS USED TO DELETE THE CURRENT              * 19260020
*   REFERENCE RECORD.  IF A KEY IS SPECIFIED ON INPUT, IT REPLACES    * 19290020
*   THE REFERENCE (PRIMEKEY) BEFORE THE OPERATION TAKES PLACE. THE    * 19320020
*   RECORD LOCATING ROUTINE, IKJEBELO, IS USED TO FIND THE RECORD     * 19350020
*   AND IF IT EXISTS THE RECORD IS REMOVED FROM THE DATA SET BY THE   * 19380020
*   RECORD REMOVAL ROUTINE, IKJEBEDL.                                 * 19410020
*        IN THE EVENT THE RECORD DOES NOT EXIST OR AN ERROR IS        * 19440020
*   ENCOUNTERED, THE CURRENT REFERENCE FIELD (PRIMEKEY) IS RESET      * 19470020
*   TO ITS ORIGINAL VALUE.                                            * 19500020
*                                                                     * 19530020
*ENTRY POINT --  IKJEBEDR VIA A CALL FROM IKJEBEUT.                   * 19560020
*                                                                     * 19590020
*INPUT --  REGISTER 1 CONTAINS THE ADDRESS OF THE WORKAREA//DCB.      * 19620020
*          REGISTER 0 OPTIONALLY POINTS TO A KEY VALUE                * 19650020
*                                                                     * 19680020
*OUTPUT --  THE SPECIFIED RECORD HAS BEEN DELETED FROM THE DATA SET   * 19710020
*  OR A RETURN CODE IS PASSED BACK IF IT DOES NOT EXIST.              * 19740020
*   THE REGISTERS ARE DESCRIBED UNDER 'EXIT' BELOW.                   * 19770020
*                                                                     * 19800020
*EXTERNAL REFERENCES --                                               * 19830020
*       IKJEBELO             -FINDS THE SPECIFIED RECORD              * 19860020
*       IKJEBEDL             -DELETES THE SPECIFIED RECORD            * 19890020
*                                                                     * 19920020
*EXITS,NORMAL --   RETURNS TO THE CALLING ROUTINE.                    * 19950020
*       RETURN CODE = 0      -RECORD EXISTS, OUTPUT AS ABOVE.         * 19980020
*       RETURN CODE = 4      -RECORD DOES NOT EXIST.                  * 20010020
*                                                                     * 20040020
*EXITS,ERROR --    RETURNS TO THE CALLING ROUTINE.                    * 20070020
*       RETURN CODE = 12     -I/O ERROR                               * 20100020
*                                                                     * 20130020
*TABLES/WORKAREAS --                                                  * 20160020
*       DEPENDENT ON THE WORKAREA DESCRIPTION 'UTILWORK'.             * 20190020
*       DEPENDENT ON THE VECTOR TABLE, 'VECTABLE', FOR EXTERNAL       * 20220020
*         REFERENCES                                                  * 20250020
*                                                                     * 20280020
*ATTRIBUTES --  REFRESHABLE, NON-PRIVILEGED, ENABLED                  * 20310020
*                                                                     * 20340020
*NOTES  --  REGISTER CONVENTIONS ARE AS FOLLOWS                       * 20370020
*       BASEREG              -BASE REGISTER                           * 20400020
*       DATAREG              -WORK AREA ADDRESSING                    * 20430020
*       COMMREG              -VECTOR TABLE ADDRESSING                 * 20460020
*       WORK3,WORK6          -WORK REGISTERS                          * 20490020
*                                                                     * 20520020
*   THIS ROUTINE IS CHARACTER CODE INDEPENDENT                        * 20550020
*                                                                     * 20560020
*********************************************************************** 20580020
         EJECT                                                          20610020
IKJEBEDR CSECT                                                          20640020
*   PERFORM THE INITIALIZATION OPERATIONS HERE                          20670020
         SAVE  (14,12),T,*                                              20700020
         LR    BASEREG,ENTRY           ENTRY POINT ADDRESS              20730020
         USING IKJEBEDR,BASEREG                                         20760020
         LR    DATAREG,PARMREG1        WORK AREA ADDRESS                20790020
         USING UTILWORK,DATAREG                                         20820020
         L     COMMREG,VTABLE          TABLE OF ROUTINE ADDRESSES       20850020
         USING VECTABLE,COMMREG                                         20880020
         LA    WORK6,SAVEAREA          NEW SAVE AREA                    20910020
         ST    SAVEREG,WORD2(WORK6)    OLD ADDRESS TO NEW               20940020
         ST    WORK6,WORD3(SAVEREG)    NEW ADDRESS TO OLD               20970020
         LR    SAVEREG,WORK6           NEW SAVE AREA                    21000020
         SPACE 2                                                        21030020
*   HANDLE ANY INPUT KEY HERE                                           21060020
         MVC   SAVEKEY(KEYL),PRIMEKEY  SAVE OLD KEY                     21090020
         LR    WORK3,PARMREG0          KEY ADDRESS, IF ANY.             21120020
         LA    WORK3,ZERO(WORK3)       CLEAR HIGH ORDER BYTE            21150020
         LTR   WORK3,WORK3             IS THERE A KEY SPECIFIED         21180020
         BZ    DR1                     NO--GO FIND OLD REFERENCE        21210020
         MVC   PRIMEKEY(KEYL),X0(WORK3) MOVE IN NEW KEY                 21240020
         SPACE 2                                                        21270020
*   FIND THE SPECIFIED RECORD                                           21300020
DR1      LA    PARMREG1,PARM1          PARAMETER LIST ADDRESS           21330020
         LA    DATAREG,X0(DATAREG)     SET OPTION CODE=0                21360020
         ST    DATAREG,PARM1           PARM LIST FOR LOCATE             21390020
         L     ENTRY,LO                ENTRY POINT ADDRESS              21420020
         CALL  (15)                    FIND THE RECORD                  21450020
         LTR   RETCDREG,RETCDREG       DOES THE RECORD EXIST            21480020
         BZ    DR2                     YES-GO DELETE IT.                21510020
         SPACE 2                                                        21540020
*   ENTER HERE FOR ERRORS OR RECORD DOES NOT EXIST                      21570020
DR70     MVC   PRIMEKEY(KEYL),SAVEKEY  RESET REFERENCE KEY              21600020
DR7      TM    DCBSTATS,ERROR          ANY I/O ERRORS                   21630020
         BO    DR5                     YES-RETURN                       21660020
         LA    RETCDREG,NRF            RETURN CODE FOR NO RECORD        21690020
         SPACE 2                                                        21720020
*   FINAL HOUSEKEEPING AND RETURN HERE                                  21750020
DR5      EQU   *                       RETURN ON ERROR HERE             21780020
DR50     L     SAVEREG,WORD2(SAVEREG)  OLD SAVE AREA ADDRESS            21810020
         RETURN (14,12),T,RC=(15)      RESTORE THE REGISTERS            21840020
         SPACE 2                                                        21870020
*   IF THE RECORD EXISTS, USE THE RECORD REMOVAL ROUTINE                21900020
DR2      L     ENTRY,DL                ENTRY POINT ADDRESS              21930020
         CALL  (15)                    DELETE THE RECORD                21960020
         LTR   RETCDREG,RETCDREG       ANY ERRORS                       21990020
         BZ    DR50                    NO-RETURN TO CALLER              22020020
         CH    RETCDREG,DREMPTY        IS THE DATA SET NOW EMPTY        22050020
         BNE   DR70                    NO-GO CHECK ERROR CONDITIONS     22080020
         SR    RETCDREG,RETCDREG       SET RETURN CODE = 0              22110020
         B     DR50                    RETURN                           22140020
         SPACE                                                          22170020
         DROP  BASEREG,COMMREG,DATAREG                                  22200020
         SPACE                                                          22230020
*   CONSTANT AREA FOR RECORD DELETE ROUTINE                             22260020
DREMPTY  DC    H'8'                    RETURN CODE FOR EMPTY DATA SET   22290020
         TITLE 'EDIT COMMAND ACCESS METHOD -DIRECTORY SEARCH -IKJEBEDS' 22320020
*********************************************************************** 22350020
*                                                                     * 22440020
*STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                      * 22470020
*                                                                     * 22500020
*FUNCTION --  THIS ROUTINE ATTEMPTS TO LOCATE A DIRECTORY INDEX       * 22530020
*   ENTRY GIVEN AN INPUT KEY VALUE. AN ATTEMPT IS MADE TO FIND THE    * 22560020
*   PROPER ENTRY WITHIN ANY INDEX BLOCKS CURRENTLY IN CORE. IF THE    * 22590020
*   ENTRY CANNOT BE FOUND, SUBSEQUENT LOWER LEVEL DIRECTORY BLOCKS    * 22620020
*   ARE READ IN AS NECESSARY.                                         * 22650020
*        IF THE 'BEGIN' OR 'END' OPTIONS ARE SPECIFIED, THIS ROUTINE  * 22680020
*   WILL LOCATE THE FIRST OR LAST ENTRY RESPECTIVELY. ANYTIME THE     * 22710020
*   CORRECT ENTRY IS FOUND, THE 'BUFREF' FIELD FOR THAT BUFFER WILL   * 22740020
*   CONTAIN THE ADDRESS OF THE PROPER INDEX ENTRY AND A RETURN CODE   * 22770020
*   OF 0 IS PASSED BACK.                                              * 22800020
*        IF THE INPUT KEY DOES NOT FALL WITHIN THE DIRECTORY LIMITS,  * 22830020
*   A RETURN CODE OF 4 IS PASSED BACK.  A RETURN CODE OF 8 INDICATES  * 22860020
*   AN EMPTY DATA SET.  IN BOTH OF THESE CASES, THE 'BUFREF' FIELD    * 22890020
*   WILL POINT TO THE NEXT AVAILABLE INDEX ENTRY SLOT.                * 22920020
*                                                                     * 22950020
*ENTRY POINT --                                                       * 22980020
*       IKJEBEDS   VIA A CALL FROM IKJEBEDL(2), IKJEBEDU, IKJEBELO    * 23010020
*                                                                     * 23040020
*INPUT --  REGISTER 1 POINTS TO A TWO WORD PARAMETER LIST-            * 23070020
*       WORD1-   HIGH ORDER BYTE CONTAINS THE OPTION CODE             * 23100020
*                THREE LOW ORDER BYTES = ADDRESS OF WORKAREA          * 23130020
*       WORD2-   POINTS TO THE DESIRED KEY VALUE                      * 23160020
*                                                                     * 23190020
*OUTPUT --  WORD2 OF THE INPUT PARAMETER LIST WILL CONTAIN THE        * 23220020
*   ADDRESS OF THE LOCATED INDEX BUFFER.  THE BUFREF FIELD WILL       * 23250020
*   THEN POINT TO THE FOUND ENTRY OR THE NEXT AVAILABLE ENTRY         * 23280020
*   DEPENDING ON THE RETURN CODE. SEE 'EXIT' BELOW.                   * 23310020
*                                                                     * 23340020
*EXTERNAL REFERENCES --                                               * 23370020
*       IKJEBERB             -READ IN ADDITIONAL DIRECTORY BLOCKS     * 23400020
*                                                                     * 23430020
*EXITS,NORMAL --                                                      * 23460020
*       -ENTRY FOUND-   WORD2 OF THE INPUT LIST CONTAINS THE          * 23490020
*          SELECTED BUFFER ADDRESS.  RETURN CODE = 0.                 * 23520020
*       -DATA SET EMPTY-  WORD2 OF THE INPUT LIST CONTAINS THE        * 23550020
*          ADDRESS OF THE BUFFER WITH THE NEXT AVAILABLE SLOT.        * 23580020
*          RETURN CODE = 8.                                           * 23610020
*       -ENTRY NOT FOUND-  WORD2 OF THE INPUT LIST CONTAINS THE       * 23640020
*          ADDRESS OF THE BUFFER WITH THE NEXT AVAILABLE SLOT.        * 23670020
*          RETURN CODE = 4.                                           * 23700020
*                                                                     * 23730020
*EXITS,ERROR --  RETURNS TO THE CALLING ROUTINE WITH A RETURN CODE    * 23760020
*   OF 12 IF ANY I/O ERRORS ARE ENCOUNTERED.                          * 23790020
*                                                                     * 23820020
*TABLES/WORK AREAS --                                                 * 23850020
*       DEPENDENT ON THE VECTOR TABLE FOR CALL TO EXTERNAL ROUTINES   * 23880020
*       DEPENDENT ON THE BUFFER DESCRIPTION DSECT FOR DIRECTORY       * 23910020
*         BLOCK FORMAT                                                * 23940020
*                                                                     * 23970020
*ATTRIBUTES -- REFRESHABLE, ENABLED, NON-PRIVILEGED                   * 24000020
*                                                                     * 24030020
*NOTES --  REGISTER CONVENTIONS ARE AS FOLLOWS-                       * 24060020
*       BASEREG              -BASE REGISTER                           * 24090020
*       DATAREG              -WORK AREA ADDRESSING                    * 24120020
*       COMMREG              -VECTOR TABLE ADDRESSING                 * 24150020
*       WORK6                -DIRECTORY BLOCK BUFFER ADDRESSING       * 24180020
*       WORK2                -RETAIN INPUT PARM LIST POINTER          * 24210020
*       WORK3,WORK4,WORK5    -WORK REGISTERS                          * 24240020
*                                                                     * 24270020
*   THIS ROUTINE IS CHARACTER CODE INDEPENDENT                        * 24300020
*                                                                     * 24330020
*********************************************************************** 24360020
         SPACE 2                                                        24390020
IKJEBEDS CSECT                                                          24420020
         SPACE                                                          24430021
*A275800-275900                                                  A45213 24440021
         SPACE                                                          24442021
*   PERFORM THE INITIALIZATION OPERATIONS HERE                          24450020
         SAVE  (14,12),T,*             SAVE THE REGISTERS               24480020
         LA    SAVEREG,SAVEL(SAVEREG)  STEP TO NEXT SAVE AREA           24510020
         LR    BASEREG,ENTRY           ENTRY POINT ADDRESS              24540020
         USING IKJEBEDS,BASEREG                                         24570020
         L     DATAREG,WORD1(PARMREG1) WORK AREA ADDRESS                24600020
         USING UTILWORK,DATAREG                                         24630020
         L     COMMREG,VTABLE          TABLE OF ROUTINE ADDRESSES       24660020
         USING VECTABLE,COMMREG                                         24690020
         SPACE                                                          24720020
*   SAVE INPUT PARMS AND CHECK FOR EMPTY DATA SET                       24750020
         L     WORK2,WORD2(PARMREG1)   POINTER TO KEY VALUE             24780020
         MVC   TEMP3(KEYL),X0(WORK2)   INPUT KEY VALUE                  24810020
         L     WORK6,DCBBUFAD          ADDRESS OF DSDB                  24840020
         USING BUFFER,WORK6                                             24870020
         SR    WORK3,WORK3             CLEAR TO ZERO                    24900020
         CH    WORK3,NUMINDEX          IS THE DATA SET EMPTY            24930020
         BE    DS6                     YES-RETURN                       24960020
         SPACE 2                                                        24990020
*   DETERMINE THE OPTION HERE                                           25020020
         CLI   X0(PARMREG1),B          IS THIS THE BEGIN OPTION         25050020
         BE    DS40                    YES-GO PROCESS                   25080020
         BAL   LINK9,DS81              GO FIND THE LAST ENTRY           25110020
         CLI   X0(PARMREG1),E          IS THIS THE END OPTION           25140020
         BE    DS50                    YES-GO PROCESS                   25170020
         CLI   X0(PARMREG1),P          THIS THE PREVIOUS OPTION         25200020
         BE    DS23                    YES-GO PROCESS                   25230020
         CLI   X0(PARMREG1),N          THIS THE NEXT OPTION             25260020
         BE    DS34                    YES-GO PROCESS                   25290020
         CLC   TEMP3(KEYL),ZERO(WORK5) ARE WE WITHIN DIRECTORY LIMITS   25320020
         BH    DS71                    NO--INSURE LAST LEVEL            25350020
         SPACE 2                                                        25380020
*   PROCESS THE CURRENT OPTION HERE                                     25410020
DS14     LA    WORK5,INDICES           ADDRESS OF FIRST ENTRY           25440020
DS12     CLC   TEMP3(KEYL),X0(WORK5)   IS THIS THE DESIRED ENTRY        25470020
         BNH   DS13                    YES- FOR THIS LEVEL              25500020
         LA    WORK5,KEYL+TTR(WORK5)   ADDRESS OF NEXT ENTRY            25530020
         B     DS12                    REPEAT UNTIL FOUND               25560020
DS13     OC    NLEV(L2),NLEV           IS THIS THE LAST LEVEL           25590020
         BZ    DS1                     YES-HAVE FOUND THE ENTRY         25620020
         BAL   LINK9,DS15              NO--READ IN THE NEXT BLOCK       25650020
         B     DS14                    REPEAT TEST UNTIL FOUND          25680020
         SPACE 2                                                        25710020
*   PROCESS THE BEGIN OPTION HERE                                       25740020
DS40     LA    WORK5,INDICES           FIRST ENTRY ADDRESS              25770020
         OC    NLEV(L2),NLEV           THIS THE LOWEST LEVEL            25800020
         BZ    DS1                     YES-ENTRY AND LEVEL FOUND        25830020
         BAL   LINK9,DS15              GO READ IN NEXT LEVEL            25860020
         B     DS40                    REPEAT UNTIL ENTRY FOUND         25890020
         SPACE 2                                                        25920020
*   PROCESS THE END OPTION HERE                                         25950020
DS50     OC    NLEV(L2),NLEV           IS THIS LOWEST LEVEL             25980020
         BZ    DS1                     YES-ENTRY AND LEVEL FOUND        26010020
         BAL   LINK9,DS15              READ IN NEXT LEVEL               26040020
         BAL   LINK9,DS81              FIND LAST ENTRY                  26070020
         B     DS50                    GO CHECK LEVEL NUMBER            26100020
         SPACE 2                                                        26130020
*   PROCESS THE PREVIOUS OPTION HERE                                    26160020
DS23     OC    TEMP3(KEYL),TEMP3       IS THIS RECORD ZERO              26190020
         BZ    DS7                     YES-RECORD DOES NOT EXIST        26220020
DS20     CLC   TEMP3(KEYL),ZERO(WORK5) INPUT KEY VERSUS KEY LAST BLOCK  26250020
         BH    DS22                    ENTRY FOUND//GO CHECK LEVEL      26280020
         LA    WORK3,ONE               COMPARE CONSTANT OF ONE          26310020
         LA    WORK5,INDICES           ADDRESS OF FIRST ENTRY           26340020
DS21     MVC   TEMP1(KEYL),X0(WORK5)   INSURE KEY ALIGNMENT             26370020
         L     WORK4,TEMP3             INPUT KEY                        26400020
         S     WORK4,TEMP1             FIND THE DIFFERENCE              26430020
         CLR   WORK4,WORK3             IS THE DIFFERENCE ONE            26460020
         BE    DS22                    YES-USE THIS ENTRY               26490020
         CLC   TEMP3(KEYL),X0(WORK5)   INPUT KEY LESS THAN BLOCK VALUE  26520020
         BNH   DS22                    YES-GO CHECK IF LOWEST LEVEL     26550020
         LA    WORK5,KEYL+TTR(WORK5)   STEP TO NEXT ENTRY               26580020
         B     DS21                    REPEAT UNTIL FOUND               26610020
DS22     OC    NLEV(L2),NLEV           IS THIS THE LAST LEVEL           26640020
         BZ    DS1                     YES-GO PREPARE TO EXIT           26670020
         BAL   LINK9,DS15              NO--GO READ IN BLOCK/NEXT LEVEL  26700020
         BAL   LINK9,DS81              GO FIND THE LAST ENTRY           26730020
         B     DS20                    REPEAT UNTIL ENTRY FOUND         26760020
         SPACE 2                                                        26790020
*   PROCESS THE NEXT OPTION HERE                                        26820020
DS30     BAL   LINK9,DS81              FIND LAST ENTRY//THIS BLOCK      26850020
DS34     CLC   TEMP3(KEYL),X0(WORK5)   IS INPUT KEY BEYOND LIMITS       26880020
         BNL   DS7                     YES-RECORD DOES NOT EXIST        26910020
         LR    WORK4,WORK5             LAST ENTRY ADDRESS               26940020
DS31     SH    WORK4,DSDIRSIZ          STEP TO PREVIOUS ENTRY           26970020
         CLC   TEMP3(KEYL),X0(WORK4)   IS INPUT KEY GREATER/PREVIOUS    27000020
         BNL   DS32                    YES-GO CHECK IF LAST LEVEL       27030020
         LA    WORK3,INDICES           ADDRESS OF FIRST POSSIBLE ENTRY  27060020
         CR    WORK3,WORK4             HAVE ALL ENTRIES BEEN CHECKED    27090020
         BNL   DS33                    YES-MUST WANT FIRST ENTRY        27120020
         LR    WORK5,WORK4             REMEMBER LAST CHECKED ENTRY      27150020
         B     DS31                    REPEAT UNTIL FOUND               27180020
DS33     LA    WORK5,INDICES           ADDRESS OF FIRST ENTRY           27210020
DS32     OC    NLEV(L2),NLEV           ANY MORE DIRECTORY LEVELS        27240020
         BZ    DS1                     NO--EXIT WITH FOUND ENTRY        27270020
         BAL   LINK9,DS15              YES-GO READ IN NEXT BLOCK        27300020
         B     DS30                    REPEAT THE CHECKS//NEW BLOCK     27330020
         SPACE 2                                                        27360020
*   READ IN NEXT LEVEL DIRECTORY BLOCK HERE                             27390020
DS15     MVC   PARM2(TTR),KEYL(WORK5)  TTR OF NEXT BLOCK                27420020
         L     ENTRY,RB                ENTRY POINT ADDRESS              27450020
         CALL  (15)                    READ IN NEXT DIRECTORY BLOCK     27480020
         LTR   RETCDREG,RETCDREG       ANY ERRORS                       27510020
         BNZ   DS11                    YES-RETURN                       27540020
         L     WORK6,WORD2(PARMREG1)   ADDRESSING FOR NEXT BLOCK        27570020
         LA    WORK6,ZERO(,WORK6)      INSURE HIGH ORDER BYTE 0  A45213 27580021
         ST    WORK6,DCBLLDB           UPDATE POINTER            A45213 27590021
         BR    LINK9                   RETURN TO CALLER                 27600020
         SPACE 2                                                        27630020
*   FINDS ADDRESS OF LAST ENTRY IN DIRECTORY BLOCK                      27660020
DS81     LH    WORK3,NUMINDEX          NO. OF ENTRIES IN DSDB           27690020
         LA    WORK5,KEYL+TTR          SIZE OF EACH ENTRY               27720020
         BCTR  WORK3,ZERO              DECREMENT BY 1 TO FIND START     27750020
*                                        OF LAST ENTRY                  27780020
         MR    WORK4,WORK3             NO.OF ENTRIES TIMES SIZE         27810020
         SPACE 2                                                        27840020
*   ADDRESS OF LAST ENTRY IN DSDB                                       27870020
         LA    WORK5,INDICES(WORK5)    START OF INDICES PLUS NUMBER     27900020
*                                        OF BYTES IN INDICES BEFORE     27930020
*                                        LAST =LAST ENTRY ADDRESS       27960020
         BR    LINK9                   RETURN                           27990020
         SPACE 2                                                        28020020
*   HAVE FOUND THE DESIRED DIRECTORY ENTRY                              28050020
DS1      SR    RETCDREG,RETCDREG       RETURN CODE OF ZERO              28080020
DS2      ST    WORK5,BUFREF            ADDRESS OF DESIRED ENTRY         28110020
         ST    WORK6,FOUR(PARMREG1)    ADDRESS OF FOUND INDEX BUFFER    28140020
         SPACE 2                                                        28170020
*   RETURN TO THE CALLING ROUTINE HERE                                  28200020
DS11     EQU   *                       LEAVE RETURN CODE AS IS          28230020
DS9      L     SAVEREG,WORD2(SAVEREG)  OLD SAVE AREA                    28260020
         RETURN (14,12),T,RC=(15)      RESTORE THE REGISTERS            28290020
         SPACE 2                                                        28320020
*   NO RECORDS IN THE DATA SET                                          28350020
DS6      LA    RETCDREG,EMPTY          SET RETURN CODE                  28380020
         LA    WORK5,INDICES           SLOT ADDRESS FOR FIRST ENTRY     28410020
         B     DS2                     RETURN                           28440020
         SPACE 2                                                        28470020
*   RECORD DOES NOT EXIST                                               28500020
DS71     OC    NLEV(L2),NLEV           IS THIS THE LAST LEVEL           28530020
         BZ    DS7                     YES-GO RETURN                    28560020
         BAL   LINK9,DS15              NO--GO GET NEXT LEVEL            28590020
         BAL   LINK9,DS81              FIND LAST ENTRY/THIS LEVEL       28620020
         B     DS71                    REPEAT UNTIL LAST LEVEL FOUND    28650020
DS7      LA    RETCDREG,NRF            RETURN CODE FOR KEY NOT FOUND    28680020
         B     DS2                     RETURN                           28710020
         SPACE 2                                                        28740020
         DROP  BASEREG,COMMREG,DATAREG,WORK6                            28770020
         SPACE 2                                                        28800020
*   CONSTANT AREA FOR IKJEBEDS                                          28830020
DSDIRSIZ DC    H'7'                    LENGTH PER DIRECTORY ENTRY       28860020
 TITLE 'EDIT COMMAND ACCESS METHOD  -DIRECTORY UPDATE --- IKJEBEDU'     28890020
*********************************************************************** 28920020
*                                                                     * 29010020
*STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                      * 29040020
*                                                                     * 29070020
*FUNCTION --  THIS ROUTINE PERFORMS THE FUNCTION OF UPDATING THE      * 29100020
*   DIRECTORY BLOCK(S) WHENEVER A NEW RECORD IS ADDED TO THE DATA     * 29130020
*   SET SUCH THAT IS AFFECTS THE INDICES.  THIS MAY INVOLVE           * 29160020
*   CREATING A NEW ENTRY OR MODIFYING AN EXISTING ONE.                * 29190020
*        IF THE DATA SET WAS PREVIOUSLY EMPTY, ONLY ONE ENTRY         * 29220020
*   NEED BE ADDED TO THE PRIMARY (DSDB) INDEX BLOCK.  IF THERE        * 29250020
*   IS ONLY ONE LEVEL OF INDEXING BUT THE DSDB IS FULL, A NEW         * 29280020
*   LEVEL WILL BE CREATED BY SPLITING THE ORIGINAL INTO TWO LOWER     * 29310020
*   LEVEL INDEX BLOCKS. THE NEW INPUT ENTRY WILL BE ADDED TO THE      * 29340020
*   APPROPIATE LOWER LEVEL INDEX BLOCK AND ENTRIES FOR EACH OF THE    * 29370020
*   TWO NEW LOWER LEVEL INDEX BLOCKS WILL BE PLACED IN THE NEW        * 29400020
*   DSDB.                                                             * 29430020
*        THE DIRECTORY SEARCH ROUTINE, IKJEBEDS, IS ALWAYS USED       * 29460020
*   TO FIND THE PROPER INDEX BLOCK TO WHICH THE UPDATES ARE TO BE     * 29490020
*   MADE.  ANYTIME THE BLOCK IS FULL, IS IS SPLIT INTO TWO BLOCKS     * 29520020
*   AND AN ENTRY IS ADDED TO THE PREVIOUS LEVEL.  WHEN THE DSDB       * 29550020
*   IS FULL, ANOTHER LEVEL IS ADDED TO THE INDEX STRUCTURE AS         * 29580020
*   DESCRIBED ABOVE.                                                  * 29610020
*       WHENEVER A BLOCK SPLIT IS NECESSARY, THE BLOCK ASSIGNMENT     * 29640020
*   ROUTINE, IKJEBEAD, IS USED SO THAT ANOTHER BLOCK CAN BE ADDED     * 29670020
*   TO THE DATA SET                                                   * 29700020
*                                                                     * 29730020
*ENTRY POINT --  AT IKJEBEDU VIA A CALL FROM IKJEBEWR                 * 29760020
*                                                                     * 29790020
*INPUT --  REGISTER ONE POINTS TO A THREE WORD PARAMETER LIST         * 29820020
*       WORD1-  ADDRESS OF THE WORKAREA                               * 29850020
*       WORD2-  ADDRESS OF THE NEW KEY VALUE                          * 29880020
*       WORD3-  TTR OF NEW BLOCK ENTRY                                * 29910020
*                                                                     * 29940020
*OUTPUT -- THE NEW INPUT INDEX ENTRY (KEY+TTR) IS ADDED TO THE        * 29970020
*   APPROPIATE DIRECTORY BLOCK.  BEFORE AN ENTRY CAN BE ADDED,        * 30000020
*   BLOCKS WILL BE SPLIT INTO TWO BLOCKS, IF NECESSARY.               * 30030020
*                                                                     * 30060020
*EXTERNAL REFERENCES --                                               * 30090020
*       IKJEBEDS             -SEARCHES THE DIRECTORY                  * 30120020
*       IKJEBEAD             -ASSIGN TTR FOR NEW BLOCK                * 30150020
*       IKJEBEWB             -WRITE OUT NEW DIRECTORY BLOCKS          * 30180020
*       IKJEBERB             -READ DIRECTORY BLOCKS                   * 30210020
*                                                                     * 30240020
*EXITS,NORMAL -- RETURNS TO CALLING ROUTINE WITH A RETURN CODE        * 30270020
*   OF ZERO.  OUTPUT AS ABOVE.                                        * 30300020
*                                                                     * 30330020
*EXITS,ERROR -- RETURNS TO THE CALLING ROUTINE WITH A RETURN CODE     * 30360020
*   OF 12 IF ANY I/O ERRORS ARE ENCOUNTERED.                          * 30390020
*                                                                     * 30420020
*TABLES/WORKAREAS --                                                  * 30450020
*       DEPENDENT ON VECTOR TABLE FOR CALLS TO EXTERNAL ROUTINES      * 30480020
*       DEPENDENT ON BUFFER DESCRIPTION OF DIRECTORY BLOCKS           * 30510020
*                                                                     * 30540020
*ATTRIBUTES -- REFRESHABLE, ENABLED, NON-PRIVILEGED                   * 30570020
*                                                                     * 30600020
*NOTES --  THE REGISTER CONVENTIONS ARE AS FOLLOWS-                   * 30630020
*       BASEREG              -BASE REGISTER                           * 30660020
*       DATAREG              -WORK AREA ADDRESSING                    * 30690020
*       COMMREG              -VECTOR TABLE ADDRESSING                 * 30720020
*       WORK6                -OLD DIRECTORY BLOCK ADDRESSING          * 30750020
*       WORK7                -NEW DIRECTORY BLOCK ADDRESSING          * 30780020
*       WORK2,WORK3          -WORK REGISTERS                          * 30810020
*       WORK5,WORK8          -WORK REGISTERS                          * 30840020
*       LINK9                -INTERNAL SUBROUTINE LINKAGE             * 30870020
*                                                                     * 30900020
*   THIS ROUTINE IS CHARACTER CODE INDEPENDENT                        * 30930020
*                                                                     * 30960020
*********************************************************************** 30990020
         SPACE 2                                                        31020020
IKJEBEDU CSECT                                                          31050020
*   PERFORM THE INITIALIZATION OPERATIONS HERE                          31080020
         SAVE  (14,12),T,*             SAVE THE REGISTERS               31110020
         LA    SAVEREG,SAVEL(SAVEREG)  STEP TO NEXT SAVE AREA           31140020
         LR    BASEREG,ENTRY           ENTRY POINT ADDRESS              31170020
         USING IKJEBEDU,BASEREG                                         31200020
         L     DATAREG,WORD1(PARMREG1) WORKAREA ADDRESS                 31230020
         USING UTILWORK,DATAREG                                         31260020
         L     COMMREG,VTABLE          TABLE OF ROUTINE ADDRESSES       31290020
         USING VECTABLE,COMMREG                                         31320020
         SPACE 2                                                        31350020
*   SAVE THE INPUT PARAMETERS                                           31380020
         L     WORK2,WORD2(PARMREG1)   POINTER TO NEW KEY               31410020
         MVC   TEMP1(KEYL),X0(WORK2)   SAVE KEY FOR LATER USE           31440020
         MVC   TEMP2(TTR),WORD3(PARMREG1)  SAVE TTR FOR LATER USE       31470020
         SPACE 2                                                        31500020
*   FIND LAST DIRECTORY LEVEL FOR THIS KEY                              31530020
DU1      XC    INDEXSV4(L8),INDEXSV4   INITIALIZE TO ZERO               31560020
         LA    WORK8,TEMP1             ADDRESS OF NEW KEY               31590020
         ST    WORK8,PARM2                                              31620020
         L     ENTRY,DS                ENTRY POINT ADDRESS              31650020
         CALL  (15)                    FIND LOWEST LEVEL OF DIRECTORY   31680020
         TM    DCBSTATS,ERROR          ANY I/O ERRORS                   31710020
         BO    DU60                    YES-RETURN                       31740020
         L     WORK6,WORD2(PARMREG1)   FOUND INDEX BUFFER ADDRESS       31770020
         USING BUFFER,WORK6                                             31800020
         SPACE 2                                                        31830020
*   CHECK IF NEW ENTRY WILL FIT IN LOWEST LEVEL                         31860020
         BAL   RETREG,DU100            CHECK IF ENTRY FITS IN BLOCK     31890020
         LTR   RETCDREG,RETCDREG       IS UPDATE COMPLETE               31920020
         BNZ   DU6                     NO--BLOCK WAS FULL               31950020
         SPACE 2                                                        31980020
*   CHECK IF ANY MORE LEVELS AND IF THEY MUST BE UPDATED                32010020
DU90     CLC   NLEV(L2),DCBNLEV        IS THIS THE DSDB                 32040020
         BE    DU7                     YES-HIGHEST LEVEL, RETURN        32070020
         LR    WORK7,WORK5             SAVE ADDRESS OF UPDATED ENTRY    32100020
         LH    WORK3,NUMINDEX          NO. OF ENTRIES                   32130020
         BCTR  WORK3,ZERO              ENTRIES MINUS ONE                32160020
         LR    WORK5,WORK8             LENGTH OF EACH                   32190020
         MR    WORK4,WORK3             NUMBER OF ENTRIES-1 TIMES LENGTH 32220020
         LA    WORK5,INDICES(WORK5)    ADDRESS OF LAST ENTRY            32250020
         CLR   WORK7,WORK5             WAS UPDATED ENTRY THE LAST       32280020
         BNE   DU7                     NO--RETURN                       32310020
         SPACE 2                                                        32340020
*   UPDATE THE PREVIOUS LEVEL HERE                                      32370020
         BAL   LINK9,DU310             GO FIND PREVIOUS LEVEL           32400020
         L     WORK5,BUFREF            FOUND ENTRY ADDRESS              32430020
         MVC   ZERO(KEYL,WORK5),INDEXSAV CORRECT KEY TO ENTRY           32460020
         OI    BUFSTATS,UPDATED        INDICATE BUFFER MODIFIED         32490020
         B     DU90                    REPEAT UNTIL ALL LEVELS HANDLED  32520020
         SPACE 2                                                        32550020
*   RESTORE REGISTERS AND RETURN HERE                                   32580020
DU60     EQU   *                       RETURN ON ERRORS HERE            32610020
DU7      L     SAVEREG,WORD2(SAVEREG)  OLD SAVE AREA                    32640020
         RETURN (14,12),T,RC=(15)      RESTORE THE REGISTERS            32670020
         SPACE 2                                                        32700020
*   NEED ANOTHER DIRECTORY BLOCK -- MOVE FIRST HALF                     32730020
DU6      LH    WORK3,NUMINDEX          NO. OF ENTRIES                   32760020
         LR    WORK4,WORK3             SAVE TOTAL                       32790020
         SRA   WORK4,ONE               HALF OF TOTAL                    32820020
         SR    WORK3,WORK4             OTHER HALF OF TOTAL              32850020
         LA    WORK5,INDICES           FIRST ENTRY//OLD BLOCK           32880020
         OI    BUFSTATS,BLKINBUF       DO NOT USE THIS BUFFER           32910020
         BAL   LINK9,DU200             MOVE FIRST HALF OF ENTRIES       32940020
         CLC   NLEV(L2),DCBNLEV        IS THIS THE DSDB BEING SPLIT     32970020
         BNE   DU300                   NO--GO WORK ON OLD BLOCK         33000020
DU61     MVC   INDICES(KEYL+TTR),INDEXSV3  SET UP 1ST ENTRY IN OLD      33030020
         LR    WORK3,WORK4             NUMBER OF ENTRIES IN 2ND HALF    33060020
         BAL   LINK9,DU200             MOVE SECOND HALF OF ENTRIES      33090020
         MVC   INDICES+KEYL+TTR(KEYL+TTR),INDEXSV3     SET UP SECOND    33120020
*                                                      ENTRY IN OLD     33150020
         LA    WORK3,ONE+ONE           NUMBER OF ENTRIES =2             33180020
         STH   WORK3,NUMINDEX          STORE IN DSDB                    33210020
         SPACE 2                                                        33240020
*   UPDATE THE DIRECTORY LEVEL COUNT                                    33270020
         LH    WORK3,DCBNLEV           CURRENT LEVEL NUMBER             33300020
         LA    WORK3,ONE(WORK3)        ADD ONE TO TOTAL                 33330020
         STH   WORK3,DCBNLEV           SAVE TOTAL IN WORKAREA           33360020
         STH   WORK3,NLEV              LEVEL NO. TO DSDB                33390020
         B     DU1                     GO PROCESS INPUT ENTRY           33420020
         SPACE 2                                                        33450020
*   MUST RE-ORGANIZE THE OLD BLOCK HERE                                 33480020
DU300    LA    WORK3,INDICES           FIRST SLOT ADDRESS               33510020
         OI    BUFSTATS,UPDATED        INDICATE BUFFER MODIFIED         33540020
         STH   WORK4,NUMINDEX          NUMBER OF ENTRIES                33570020
DU301    MVC   X0(KEYL+TTR,WORK3),X0(WORK5) SLIDE ENTRY UP              33600020
         LA    WORK3,KEYL+TTR(WORK3)   INCREMENT MOVE-TO ADDRESS        33630020
         LA    WORK5,KEYL+TTR(WORK5)   INCREMENT MOVE FROM ADDRESS      33660020
         BCT   WORK4,DU301             REPEAT UNTIL ALL MOVED           33690020
         SH    WORK3,DUDIRSIZ          ADDRESS OF LAST ENTRY            33720020
         LR    WORK7,WORK3             ADDRESS OF LAST ENTRY            33750020
         OC    INDEXSV4(L8),INDEXSV4   ANY UPDATES FOR THIS BLOCK       33780020
         BZ    DU302                   NO--GO FIND PREVIOUS ENTRY       33810020
         MVC   INDEXSV2(L2),TEMP1      SAVE ORIGINAL INPUT PARMS        33840020
         MVC   TEMP1(L8),INDEXSV4      UPDATE FOR THIS BLOCK            33870020
         BAL   RETREG,DU100            PERFORM UPDATE TO THIS BLOCK     33900020
         MVC   TEMP1(L8),INDEXSV2      RESTORE INPUT PARMS              33930020
         XC    INDEXSV4(L8),INDEXSV4   INDICATE UPDATE COMPLETE         33960020
         LA    WORK7,KEYL+TTR(WORK7)   NEW LAST ENTRY ADDRESS           33990020
DU302    BAL   LINK9,DU310             FIND PREVIOUS LEVEL OF DIRECTORY 34020020
         B     DU305                   GO UPDATE THAT LEVEL             34050020
         SPACE 2                                                        34080020
*   FIND PREVIOUS LEVEL OF DIRECTORY BY LOOKING FOR TTR                 34110020
DU310    MVC   INDEXSAV(KEYL),X0(WORK7) KEY OF LAST ENTRY               34140020
         MVC   INDEXSAV+KEYL(TTR),BUFTTR  TTR OF THIS BLOCK             34170020
         L     WORK6,DCBBUFAD          ADDRESS OF DIRECTORY START       34200020
DU306    LH    WORK3,NUMINDEX          NUMBER OF ENTRIES THIS BLOCK     34230020
         LA    WORK5,INDICES           FIRST ENTRY ADDRESS              34260020
DU320    CLC   INDEXSAV+KEYL(TTR),KEYL(WORK5) IS THE TTR THE SAME       34290020
         BE    DU321                   YES-CORRECT ENTRY FOUND          34320020
         LA    WORK5,KEYL+TTR(WORK5)   NO--STEP TO NEXT ENTRY           34350020
         BCT   WORK3,DU320             REPEAT UNTIL ALL ENTRIES CHECKED 34380020
         SPACE 2                                                        34410020
*   FIND PREVIOUS LEVEL BY LOOKING FOR KEY                              34440020
         LH    WORK3,NUMINDEX          NUMBER OF ENTRIES                34470020
         LA    WORK5,KEYL+TTR          LENGTH OF EACH ENTRY             34500020
         BCTR  WORK3,ZERO              NUMBER OF ENTRIES-1              34530020
         MR    WORK4,WORK3             ENTRIES-1 TIMES LENGTH           34560020
         LA    WORK5,INDICES(WORK5)    ADDRESS OF LAST ENTRY            34590020
         CLC   INDEXSAV(KEYL),ZERO(WORK5) DO WE WANT LAST ENTRY         34620020
         BNL   DU304                   YES-USE THIS ENTRY               34650020
         LA    WORK5,INDICES           FIRST ENTRY ADDRESS              34680020
DU323    CLC   INDEXSAV(KEYL),X0(WORK5) IS THIS THE DESIRED ENTRY       34710020
         BNH   DU304                   YES-USE THIS ENTRY               34740020
         LA    WORK5,KEYL+TTR(WORK5)   NO--STEP TO NEXT ENTRY           34770020
         B     DU323                   REPEAT UNTIL ENTRY FOUND         34800020
DU321    ST    WORK5,BUFREF            FOUND ENTRY ADDRESS              34830020
         BR    LINK9                   RETURN                           34860020
         SPACE 2                                                        34890020
*   READ IN THE NEXT LEVEL OF DIRECTORY IF NECESSARY                    34920020
DU304    MVC   PARM2(TTR),KEYL(WORK5)  MUST READ IN NEXT LEVEL          34950020
         L     ENTRY,RB                ENTRY POINT ADDRESS              34980020
         CALL (15)                     READ IN NEXT LEVEL               35010020
         LTR   RETCDREG,RETCDREG       ANY ERRORS                       35040020
         BNZ   DU60                    YES--RETURN                      35070020
         L     WORK6,WORD2(PARMREG1)   ADDRESS OF BUFFER/BLOCK          35100020
         B     DU306                   REPEAT UNTIL PROPER LEVEL FOUND  35130020
         SPACE 2                                                        35160020
*   UPDATE PREVIOUS LEVEL OF DIRECTORY                                  35190020
DU305    MVC   INDEXSV2(L8),TEMP1      SAVE INPUT PARMS THIS ROUTINE    35220020
         MVC   TEMP1(L8),INDEXSV3      KEY/TTR OF NEW BLOCK             35250020
         BAL   RETREG,DU100            PLACE IN PREVIOUS LEVEL          35280020
         MVC   TEMP1(L8),INDEXSV2      RESTORE INPUT PARAMETERS         35310020
         LTR   RETCDREG,RETCDREG       WAS THERE SPACE IN PRIOR LEVEL   35340020
         BZ    DU1                     YES-GO START UPDATE AT BEGINNING 35370020
         MVC   INDEXSV4(L8),INDEXSV3   SAVE KEY/TTR OF NEW BLOCK        35400020
         B     DU6                     GO SPLIT THIS LEVEL              35430020
         SPACE 2                                                        35460020
*********************************************************************** 35490020
*   THIS ROUTINE CHECKS IF ANOTHER ENTRY WILL FIT IN THE SPECIFIED    * 35520020
*   BLOCK. IF ONLY THE KEY VALUE IS UNIQUE, ONLY THE KEY PORTION OF   * 35550020
*   THE ENTRY IS UPDATED.                                             * 35580020
*        RETURN CODES-  0    -BLOCK WAS UPDATE SUCCESSFULLY           * 35610020
*                       4    -NEED ANOTHER BLOCK//NO MORE SPACE       * 35640020
*   WORK6 CONTAINS THE ADDRESS OF A DIRECTORY BLOCK                   * 35670020
*   THE NEW KEY IS IN TEMP1                                           * 35700020
*   THE NEW TTR IS IN TEMP2                                           * 35730020
*********************************************************************** 35760020
         SPACE 2                                                        35790020
*   CHECK IF SPACE FOR ANOTHER ENTRY                                    35820020
DU100    LH    WORK3,NUMINDEX          NUMBER OF ENTRIES//THIS BLOCK    35850020
         LA    WORK5,KEYL+TTR          LENGTH OF EACH ENTRY             35880020
         LR    WORK8,WORK5             SAVE LENGTH                      35910020
         MR    WORK4,WORK3             LENGTH TIMES NO. OF ENTRIES      35940020
         LA    WORK5,INDICES(WORK5)    NEXT AVAILABLE SLOT ADDRESS      35970020
         LA    WORK4,INDLAST-NEWBUF(WORK6) LAST POSSIBLE ENTRY ADDR     36000020
         CLR   WORK5,WORK4             IS THERE SPACE IN THIS BLOCK     36030020
         BH    DU101                   NO--NEED ANOTHER BLOCK           36060020
         SPACE 2                                                        36090020
*   SPACE AVAILABLE --- IS NEXT AVAILABLE THE FIRST SLOT                36120020
         LA    WORK4,INDICES           ADDRESS OF 1ST SLOT              36150020
DU102    CLR   WORK5,WORK4             IS NEXT AVAILABLE= FIRST SLOT    36180020
         BE    DU103                   YES-USE THIS SLOT                36210020
         SPACE 2                                                        36240020
*   PROCESS ALL ENTRIES UNTIL THE PROPER SLOT IS FOUND                  36270020
         SR    WORK5,WORK8             PREVIOUS SLOT ADDRESS            36300020
         CLC   KEYL(TTR,WORK5),TEMP2   IS TTR THE SAME                  36330020
         BE    DU104                   YES-GO UPDATE KEY VALUE          36360020
         CLC   TEMP1(KEYL),X0(WORK5)   NEW KEY GREATER THAN PREVIOUS    36390020
         BH    DU105                   YES-GOES IN BLOCK HERE           36420020
         MVC   KEYL+TTR(KEYL+TTR,WORK5),X0(WORK5) MOVE ENTRY DOWN ONE   36450020
*                                                SLOT TOWARD END OF     36480020
*                                                DIRECTORY BLOCK        36510020
         B     DU102                   REPEAT UNTIL PROPER SLOT FOUND   36540020
         SPACE 2                                                        36570020
*   UPDATE ENTRY COUNT AND STORE TTR VALUE                              36600020
DU105    LA    WORK5,KEYL+TTR(WORK5)   RESET TO AVAILABLE SLOT          36630020
DU103    LH    WORK4,NUMINDEX          CURRENT ENTRY COUNT              36660020
         LA    WORK4,ONE(WORK4)        PLUS NEW ENTRY                   36690020
         STH   WORK4,NUMINDEX          SAVE NEW TOTAL                   36720020
         MVC   KEYL(TTR,WORK5),TEMP2   NEW TTR VALUE TO ENTRY           36750020
         SPACE 2                                                        36780020
*   PLACE KEY IN ENTRY AND RETURN                                       36810020
DU104    MVC   X0(KEYL,WORK5),TEMP1    NEW KEY VALUE TO ENTRY           36840020
         OI    BUFSTATS,UPDATED        INDICATE BUFFER MODIFIED         36870020
         SR    RETCDREG,RETCDREG       SET RETURN CODE                  36900020
         BR    RETREG                  RETURN                           36930020
         SPACE 2                                                        36960020
*   CHECK IF TTR MATCHES AND ONLY NEW KEY NEED BE STORED                36990020
*   WORK3 CONTAINS NUMBER OF ENTRIES                                    37020020
DU101    LA    WORK5,INDICES           ADDRESS OF FIRST SLOT            37050020
DU106    CLC   KEYL(TTR,WORK5),TEMP2   IS TTR SAME AS CURRENT ENTRY     37080020
         BE    DU104                   YES-UPDATE KEY VALUE             37110020
         LA    WORK5,TTR+KEYL(WORK5)   STEP TO NEXT ENTRY               37140020
         BCT   WORK3,DU106             REPEAT UNTIL ALL SEARCHED        37170020
         LA    RETCDREG,FOUR           CODE FOR NO SPACE IN BLOCK       37200020
         BR    RETREG                  RETURN TO CALLER                 37230020
         SPACE 2                                                        37260020
*********************************************************************** 37290020
*   THIS ROUTINE SPLITS A DIRECTORY BLOCK BY MOVING THE SPECIFIED     * 37320020
*   ENTRIES TO A NEW BLOCK                                            * 37350020
*    -WORK6 POINTS AT THE OLD BLOCK (DSDB) ON ENTRY                   * 37380020
*    -THIS ROUTINE GETS ANOTHER BUFFER/BLOCK ASSIGNED                 * 37410020
*    -WORK3 CONTAINS NO. OF ENTRIES TO MOVE INTO THAT BLOCK           * 37440020
*    -WORK5 CONTAINS THE STARTING MOVE-FROM ADDRESS                   * 37470020
*    -THIS NEW BLOCK GETS WRITTEN OUT                                 * 37500020
*    -THIS ROUTINE EXITS ON LINK9                                     * 37530020
*    -INDEXSV3 CONTAINS THE PROPER INDEX ENTRY(KEY AND TTR)           * 37560020
*       FOR THIS BLOCK                                                * 37590020
*********************************************************************** 37620020
         SPACE 2                                                        37650020
*   GET ANOTHER BUFFER BLOCK ASSIGNED                                   37680020
DU200    L     ENTRY,AD                ENTRY POINT ADDRESS              37710020
         CALL  (15)                    GET ANOTHER BLOCK//BUFFER        37740020
         LTR   RETCDREG,RETCDREG       ANY ERRORS                       37770020
         BNZ   DU60                    YES-RETURN                       37800020
         L     WORK7,WORD2(PARMREG1)   NEW BUFFER ADDRESS               37830020
         USING NEWBUF,WORK7                                             37860020
         NI    BUFSTATS,ALL-BLKINBUF   OLD BUFFER NOW AVAILABLE         37890020
         SPACE 2                                                        37920020
*   UPDATE THE BUFFER CONTROL FIELDS                                    37950020
         OI    NEWSTATS,UPDATED        INDICATE BUFFER MODIFIED         37980020
         STH   WORK3,NEWNUM            NO. OF ENTRIES IN THIS NEW BLOCK 38010020
         MVC   NEWNLEV(L2),NLEV        LEVEL NO. IS SAME AS OLD         38040020
         SPACE 2                                                        38070020
*   LOOP UNTIL ALL ARE MOVED                                            38100020
         LA    WORK8,NEWINDEX          MOVE-TO ADDRESS                  38130020
DU201    MVC   X0(TTR+KEYL,WORK8),X0(WORK5) MOVE ENTRY FROM OLD TO NEW  38160020
         LA    WORK5,TTR+KEYL(WORK5)      INCREMENT FROM-ADDRESS        38190020
         LA    WORK8,TTR+KEYL(WORK8)      INCREMENT TO  -ADDRESS        38220020
         BCT   WORK3,DU201                REPEAT UNTIL ALL MOVED        38250020
         SH    WORK8,DUDIRSIZ             ADDRESS OF LAST ENTRY         38280020
         SPACE 2                                                        38310020
*   SAVE THE LAST KEY AND TTR FOR THIS BLOCK BEFORE WRITING OUT         38340020
         MVC   INDEXSV3(KEYL),X0(WORK8) KEY INDEX FOR THIS BLOCK        38370020
         MVC   INDEXSV3+KEYL(TTR),NEWTTR   TTR INDEX THIS BLOCK         38400020
         SPACE 2                                                        38430020
*   CHECK IF PREVIOUS SPLIT TOOK PLACE                                  38460020
         OC    INDEXSV4(L8),INDEXSV4   UPDATE TO THIS BLOCK POSSIBLE    38490020
         BZ    DU202                   NO--GO WRITE OUT THE BLOCK       38520020
         CLC   INDEXSV4(KEYL),ZERO(WORK8) IS NEW GREATER THAN LAST OLD  38550020
         BH    DU202                   YES-GO WRITE OUT THIS BLOCK      38580020
         SPACE 2                                                        38610020
*   FIND PROPER PLACE TO INSERT NEW ENTRY                               38640020
         LA    WORK3,NEWINDEX          ADDRESS OF FIRST ENTRY SLOT      38670020
DU205    LA    WORK2,KEYL+TTR(WORK8)   ADDRESS OF NEXT SLOT             38700020
         CLR   WORK2,WORK3             IS THIS THE FIRST SLOT           38730020
         BE    DU206                   YES-USE THIS                     38760020
         CLC   INDEXSV4(KEYL),ZERO(WORK8) UPDATE GREATER THAN PREVIOUS  38790020
         BH    DU206                   YES-USE THIS SLOT                38820020
         MVC   X0(KEYL+TTR,WORK2),X0(WORK8)  NO--MOVE THIS ENTRY DOWN   38850020
         SH    WORK8,DUDIRSIZ          BACK UP TO PREVIOUS ENTRY        38880020
         B     DU205                   REPEAT UNTIL SLOT FOUND          38910020
DU206    MVC   ZERO(KEYL+TTR,WORK2),INDEXSV4 NEW ENTRY TO BLOCK         38940020
         LH    WORK3,NEWNUM            CURRENT NO. OF ENTRIES           38970020
         LA    WORK3,ONE(WORK3)        PLUS THIS NEW ENTRY              39000020
         STH   WORK3,NEWNUM            SAVE THIS NEW TOTAL              39030020
         XC    INDEXSV4(L8),INDEXSV4   INDICATE ENTRY PROCESSED         39060020
DU202    L     ENTRY,WB                ENTRY POINT ADDRESS              39090020
         CALL  (15)                    INITIATE WRITE ON BLOCK          39120020
         LTR   RETCDREG,RETCDREG       ANY ERRORS                       39150020
         BNZ   DU60                    YES-RETURN -ERROR                39180020
         BR    LINK9                   RETURN TO CALLER                 39210020
         SPACE 2                                                        39240020
*   CONSTANTS FOR IKJEBEDU                                              39270020
DUDIRSIZ DC    H'7'                    LENGTH OF EACH INDEX ENTRY       39300020
 TITLE 'EDIT COMMAND ACCESS METHOD -RECORD LOCATING-  -IKJEBELO-'       39330020
*********************************************************************** 39360020
*                                                                     * 39450020
*STATUS -- VERSION NO. 01, OS/360 RELEASE NO, 20                      * 39480020
*                                                                     * 39510020
*FUNCTION --  THIS ROUTINE IS USED TO FIND A SPECIFIC RECORD.         * 39540020
*   DEPENDING ON THE OPTION SPECIFIED, THE RECORD MAY BE THE FIRST    * 39570020
*   IN THE DATA SET, THE LAST IN THE DATA SET, THE CURRENT            * 39600020
*   REFERENCE RECORD, THE FIRST PRIOR TO THE REFERENCE RECORD, OR     * 39630020
*   THE NEXT AFTER THE REFERENCE RECORD.  REFERENCE RECORD IS         * 39660020
*   DEFINED AS THE RECORD WITH A KEY VALUE EQUAL TO THAT STORED IN    * 39690020
*   'PRIMEKEY' OF THE WORKAREA.                                       * 39720020
*        IN ALL CASES ABOVE, FINDING THE BLOCK THAT CONTAINS THE      * 39750020
*   DESIRED RECORD INVOLVES USING THE DIRECTORY SEARCH ROUTINE,       * 39780020
*   IKJEBEDS.  IF THE CORRECT BLOCK EXISTS, IT IS READ IN WITH THE    * 39810020
*   READ BLOCK ROUTINE, IKJEBERB. WHEN THE CORRECT RECORD IS LOCATED  * 39840020
*   WITHIN THE DATA BLOCK, THE 'BUFREF' FIELD OF THAT BUFFER CONTAINS * 39870020
*   THE ADDRESS OF THE LOCATOR FOR THAT RECORD.                       * 39900020
*                                                                     * 39930020
*ENTRY POINTS -- AT IKJEBELO VIA A CALL FROM IKJEBEDR, IKJEBERR,      * 39960020
*   OR IKJEBEWR.                                                      * 39990020
*                                                                     * 40020020
*INPUT --  REGISTER 1 POINTS TO A 3 WORD PARAMETER LIST.              * 40050020
*   WORD1 --CONTAINS A POINTER TO WORKAREA//DCB.                      * 40080020
*        HIGH ORDER BYTE CONTAINS AN OPTION CODE AS FOLLOWS-          * 40110020
*          X'00'            -FIND CURRENT REFERENCE RECORD            * 40140020
*          X'01'            -FIND RECORD PRIOR TO REFERENCE           * 40170020
*          X'02'            -FIND RECORD AFTER REFERENCE              * 40200020
*          X'04'            -FIND FIRST RECORD IN DATA SET            * 40230020
*          X'05'            -FIND LAST RECORD IN DATA SET             * 40260020
*                                                                     * 40290020
*   WORD2 AND WORD3 -- NOT USED ON INPUT                              * 40320020
*                                                                     * 40350020
*OUTPUT --  REGISTERS AS DESCRIBED UNDER 'EXIT' BELOW.                * 40380020
*   WORD2 OF THE INPUT PARM LIST CONTAINS THE ADDRESS OF THE BUFFER   * 40410020
*   FOR THE FOUND RECORD.  THE 'BUFREF' FIELD OF THE BUFFER CONTAINS  * 40440020
*   THE ADDRESS OF THE 'LOCATOR' FOR THE FOUND RECORD.  THE 'PRIMEKEY'* 40470020
*   FIELD IN THE WORKAREA IS UPDATED WITH THE FOUND RECORD KEY.       * 40500020
*                                                                     * 40530020
*EXTERNAL REFERENCES --                                               * 40560020
*       IKJEBEDS            -FIND THE DESIRED DATA BLOCK              * 40590020
*       IKJEBERB            -READ IN THE REQUIRED DATA BLOCK          * 40620020
*                                                                     * 40650020
*EXITS,NORMAL -- RETURNS TO CALLING ROUTINE WITH A RETURN CODE--      * 40680020
*       RETURN CODE = 0     -OUTPUT AS ABOVE,  RECORD FOUND           * 40710020
*       RETURN CODE = 4     -NO OUTPUT,        RECORD NOT FOUND       * 40740020
*       RETURN CODE = 8     -NO OUTPUT,        EMPTY DATA SET         * 40770020
*                                                                     * 40800020
*                                                                     * 40830020
*EXITS,ERROR --  RETURNS TO THE CALLING ROUTINE.                      * 40860020
*       RETURN CODE = 12    -I/O ERROR ENCOUNTERED                    * 40890020
*                                                                     * 40920020
*TABLES/WORK AREAS --                                                 * 40950020
*       DEPENDENT ON THE 'BUFFER' DSECT DESCRIPTION.                  * 40980020
*       DEPENDENT ON THE 'UTILWORK' WORKAREA DESCRIPTION              * 41010020
*       DEPENDENT ON THE VECTOR TABLE FOR EXTERNAL REFERENCES         * 41040020
*                                                                     * 41070020
*ATTRIBUTES --  REFRESHABLE, NON-PRIVILEGED, ENABLED                  * 41100020
*                                                                     * 41130020
*NOTES --  THE REGISTER CONVENTIONS ARE AS FOLLOWS                    * 41160020
*       BASEREG                   -BASE REGISTER                      * 41190020
*       DATAREG                   -WORK AREA ADDRESSING               * 41220020
*       COMMREG                    -VECTOR TABLE ADDRESSING           * 41250020
*       WORK6                     -BUFFER ADDRESSING                  * 41280020
*       WORK2,WORK3,WORK4,WORK5   -WORK REGISTERS                     * 41310020
*                                                                     * 41340020
*   THIS ROUTINE IS CHARACTER CODE INDEPENDENT                        * 41370020
*                                                                     * 41400020
*********************************************************************** 41430020
         SPACE 2                                                        41460020
IKJEBELO CSECT                                                   A45116 41490021
         SPACE                                                          41492021
*A414900-451000                                                  A45116 41494021
*D414900-451000                                                  A45116 41496021
         SPACE                                                          41498021
*   PERFORM THE INITIALIZATION OPERATIONS HERE                   A45116 41500021
         SAVE  (14,12),T,*                                       A45116 41510021
         LA    SAVEREG,SAVEL(SAVEREG)  NEXT SAVE AREA            A45116 41520021
         LR    BASEREG,ENTRY           ENTRY POINT ADDRESS       A45116 41530021
         USING IKJEBELO,BASEREG                                  A45116 41540021
         L     DATAREG,WORD1(PARMREG1) WORK AREA ADDRESS         A45116 41550021
         USING UTILWORK,DATAREG                                  A45116 41560021
         L     COMMREG,VTABLE          TABLE OF ROUTINE ADDRS    A45116 41570021
         USING VECTABLE,COMMREG                                  A45116 41580021
         USING BUFFER,WORK6                                      A45116 41590021
         SPACE 2                                                        41600021
*   CHECK FOR INPUT OPTION CURRENT OR NEXT                       A45116 41610021
         CLI   X0(PARMREG1),K          WAS CURRENT SPECIFIED     A45116 41620021
         BE    LO2                     YES -                     A45116 41630021
         CLI   X0(PARMREG1),N          WAS NEXT SPECIFIED        A45116 41640021
         BE    LO3                     YES -                     A45116 41650021
         SPACE 2                                                        41660021
*   SEARCH DIRECTORY AND READ DATA BLOCK INTO CORE,              A45116 41670021
*   DETERMINE OPTION                                             A45116 41672021
         BAL   LINK9,LO1               GET DATA BLOCK            A45116 41680021
         LTR   RETCDREG,RETCDREG       ANY ERRORS                A45116 41690021
         BNZ   LO16                    YES, TERMINATE            A45116 41700021
         CLI   X0(PARMREG1),B          WAS BEGIN OPTION SPECIF   A45116 41710021
         BE    LO9                     YES -                     A45116 41720021
         CLI   X0(PARMREG1),P          PREVIOUS OPTION SPECIFIED A45116 41730021
         BE    LO6                     YES -                     A45116 41740021
*                                      NO, MUST BE LAST OPTION   A45116 41750021
         SPACE 2                                                        41760021
*   LOCATE LAST RECORD OF DATA BLOCK                             A45116 41770021
         LH    WORK2,NUMREC            NUMBER OF RECORDS         A45116 41780021
*                                        IN DATA BLOCK           A45116 41782021
         AR    WORK2,WORK2             TOTAL LENGTH OF LOCATORS  A45116 41790021
         LA    WORK3,LOCATORS-LOCL(WORK2)   ADDRESS OF LOCATOR   A45116 41800021
         LH    WORK2,X0(WORK3)         CONTENTS OF LOCATOR       A45116 41810021
LO8      LA    WORK2,DATA(WORK2)       ADDRESS OF RECORD         A45116 41820021
         SPACE 2                                                        41830021
*   SET UP OUTPUT AND RETURN TO CALLING ROUTINE HERE             A45116 41840021
LO12     EQU   *                                                 A45116 41850021
         ST    WORK3,BUFREF            ADDRESS OF RECORD LOCATOR A45116 41860021
LO13     MVC   PRIMEKEY(KEYL),X0(WORK2)  SAVE ACTUAL KEY VALUE   A45116 41870021
         SR    RETCDREG,RETCDREG       SET RETURN CODE           A45116 41880021
LO16     L     SAVEREG,WORD2(SAVEREG)  OLD SAVE AREA             A45116 41890021
         RETURN (14,12),T,RC=(15)      RESTORE REGISTERS         A45116 41900021
         SPACE 2                                                        41910021
*   MUST FIND FIRST RECORD OF DATA SET                           A45116 41920021
LO9      LH    WORK2,LOCATORS          CONTENTS OF FIRST LOCATOR A45116 41930021
         LA    WORK3,LOCATORS          ADDRESS OF FIRST LOCATOR  A45116 41940021
         B     LO8                     GO FIND ADDRESS OF RECORD A45116 41950021
         SPACE 2                                                        41960021
*   MUST FIND RECORD AFTER CURRENT REFERENCE                     A45116 41970021
LO3      BAL   WORK8,LO30              LOCATE NEXT RECORD        A45116 41980021
LO32     LTR   RETCDREG,RETCDREG       ANY ERRORS                A45116 41990021
         BNZ   LO16                    YES, TERMINATE            A45116 42000021
         B     LO12                    NO, RETURN LOCATOR ADDR   A45116 42010021
         SPACE 2                                                        42020021
*   MUST FIND CURRENT REFERENCE RECORD                           A45116 42030021
LO2      BAL   WORK8,LO20              LOCATE CURRENT RECORD     A45116 42040021
         B     LO32                    GO CHECK RETURN CODE      A45116 42050021
         SPACE 2                                                        42060021
*   MUST FIND RECORD PRIOR TO CURRENT REFERENCE                  A45116 42070021
LO6      LH    WORK5,NUMREC            NUMBER OF RECORDS IN      A45116 42080021
*                                        DATA BLOCK              A45116 42082021
         LR    WORK4,WORK5             TOTAL LENGTH OF           A45116 42090021
         AR    WORK4,WORK4               LOCATORS                A45116 42100021
LO62     LA    WORK3,LOCATORS-LOCL(WORK4)   ADDRESS OF LOCATOR   A45116 42110021
         LH    WORK2,LOCATORS-LOCL(WORK4)   CONTENTS OF LOCATOR  A45116 42120021
         LA    WORK2,DATA(WORK2)       RECORD ADDRESS            A45116 42130021
         CLC   X0(KEYL,WORK2),PRIMEKEY IS THIS THE PREVIOUS REC  A45116 42140021
         BL    LO12                    YES, RETURN LOCATOR ADDR  A45116 42150021
         BCTR  WORK4,ZERO              DECREMENT TO PICK UP      A45116 42160021
         BCTR  WORK4,ZERO                PREVIOUS LOCATOR        A45116 42170021
         BCT   WORK5,LO62              REPEAT UNTIL ALL RECORDS  A45116 42180021
*                                        HAVE BEEN TESTED        A45116 42182021
         SPACE 2                                                        42190021
*   RECORD PRIOR TO CURRENT REFERENCE NOT IN THIS DATA BLOCK,    A45116 42200021
*     MUST DO BINARY SEARCH BY KEY                               A45116 42210021
         MVC   HIGHKEY(KEYL),PRIMEKEY  INITIALIZE TOP BOUND FOR  A45116 42220021
*                                        SEARCH                  A45116 42222021
         SR    WORK4,WORK4             INITIALIZE LOWER BOUND    A45116 42230021
         ST    WORK4,LOWKEY              TO ZERO                 A45116 42240021
LO63     L     WORK4,LOWKEY            COMPUTE SEARCH KEY =      A45116 42250021
         A     WORK4,HIGHKEY             (LOWKEY + HIGHKEY)/2  , A45116 42260021
         SRL   WORK4,ONE                 IGNORING REMAINDER      A45116 42270021
         ST    WORK4,PRIMEKEY          SEARCH KEY                A45116 42280021
         BAL   WORK8,LO30              LOCATE NEXT RECORD AFTER  A45116 42290021
*                                        SEARCH KEY              A45116 42300021
         CLC   X0(KEYL,WORK2),HIGHKEY  IS RECORD FOUND A         A45116 42310021
*                                        CANDIDATE FOR           A45116 42312021
*                                        PREVIOUS RECORD         A45116 42320021
         BNL   LO64                    NO, CHECK FOR CONVERGENCE A45116 42330021
*                                      YES, CHECK IF THIS MUST   A45116 42340021
*                                        BE  PREVIOUS RECORD     A45116 42350021
         L     WORK4,HIGHKEY           HIGH BOUND                A45116 42360021
         BCTR  WORK4,ZERO                LESS ONE                A45116 42370021
         MVC   TEMP3(KEYL),X0(WORK2)   FOR ALIGNMENT             A45116 42380021
         L     WORK5,TEMP3             KEY OF RECORD FOUND       A45116 42390021
         CR    WORK4,WORK5             IS RECORD FOUND           A45116 42400021
*                                        NECESSARILY THE         A45116 42402021
*                                        PREVIOUS RECORD         A45116 42410021
         BE    LO12                    YES, RETURN               A45116 42420021
         ST    WORK5,LOWKEY            NO, RESET LOWER BOUND     A45116 42430021
*                                        AND REPEAT              A45116 42432021
         B     LO63                    REPEAT SEARCH             A45116 42440021
         SPACE 2                                                        42450021
*   NO RECORD FOUND BETWEEN SEARCH KEY AND HIGH BOUND. TEST FOR  A45116 42460021
*     CONVERGENCE BEFORE REPEATING SEARCH                        A45116 42470021
LO64     L     WORK4,PRIMEKEY          SEARCH KEY PLUS ONE (HIGH A45116 42480021
         AH    WORK4,LOCONST1            ORDER BYTE PRESERVED)   A45116 42490021
         C     WORK4,HIGHKEY           CONVERGED YET             A45116 42500021
         BE    LO65                    YES                       A45116 42510021
*                                      NO, RESET HIGH BOUND      A45116 42520021
*                                        AND REPEAT              A45116 42522021
         ST    WORK4,HIGHKEY           HIGH BOUND = SEARCH KEY+1 A45116 42530021
         B     LO63                    REPEAT SEARCH             A45116 42540021
         SPACE 2                                                        42550021
*   CONVERGENCE ATTAINED                                         A45116 42560021
LO65     BAL   WORK8,LO20              CHECK FOR RECORD WITH     A45116 42570021
*                                        KEY EQUAL TO LAST       A45116 42580021
*                                        SEARCH KEY              A45116 42582021
         LTR   RETCDREG,RETCDREG       WAS RECORD FOUND          A45116 42590021
         BZ    LO12                    YES, HAS TO BE PREVIOUS   A45116 42600021
*                                        RECORD                  A45116 42602021
         OC    LOWKEY(KEYL),LOWKEY     HAS A RECORD BEEN FOUND   A45116 42610021
*                                        DURING BINARY SEARCH    A45116 42620021
         BNZ   LO66                    YES, HAS TO BE PREVIOUS   A45116 42630021
*                                        RECORD                  A45116 42632021
*                                      NO, MUST CHECK KEY = 0    A45116 42640021
         OC    PRIMEKEY(KEYL),PRIMEKEY HAS KEY = 0 ALREADY BEEN  A45116 42650021
*                                        CHECKED                 A45116 42652021
         BZ    LO67                    YES, HENCE NO PREVIOUS    A45116 42660021
*                                        RECORD EXISTS           A45116 42670021
*                                      NO, MUST SEARCH KEY = 0   A45116 42680021
         SR    WORK4,WORK4             SET SEARCH KEY            A45116 42690021
         ST    WORK4,PRIMEKEY            TO ZERO                 A45116 42700021
         BAL   WORK8,LO20              SEARCH FOR RECORD KEY 0   A45116 42710021
         LTR   RETCDREG,RETCDREG       WAS RECORD FOUND          A45116 42720021
         BZ    LO12                    YES, THIS IS THE PREVIOUS A45116 42730021
*                                        RECORD                  A45116 42732021
         B     LO16                    NO, TERMINATE             A45116 42740021
         SPACE 2                                                        42750021
*   PREVIOUS RECORD FOUND TO BE THAT REFERENCED BY LOWKEY, SET   A45116 42760021
*     UP REGISTERS FOR RETURN                                    A45116 42770021
LO66     MVC   PRIMEKEY(KEYL),LOWKEY   KEY OF PREVIOUS RECORD    A45116 42780021
         BAL   WORK8,LO20              SET UP WORK2 AND WORK3    A45116 42790021
         B     LO12                    RETURN                    A45116 42800021
         SPACE 2                                                        42810021
LO67     LA    RETCDREG,NRF            RETURN CODE FOR RECORD    A45116 42820021
*                                        NOT FOUND               A45116 42822021
         B     LO16                    EXIT                      A45116 42830021
         SPACE 2                                                        42840021
*   THIS SUBROUTINE LOCATES RECORD WITH KEY EQUAL TO PRIMEKEY    A45116 42850021
LO20     MVI   X0(PARMREG1),K          INSURE THAT OPTION CODE   A45116 42860021
*                                         IS CORRECT             A45116 42862021
         BAL   LINK9,LO1               GET DATA BLOCK            A45116 42870021
         LTR   RETCDREG,RETCDREG       DATA BLOCK FOUND          A45116 42880021
         BCR   NOTZERO,WORK8           NO, RETURN                A45116 42890021
         LH    WORK5,NUMREC            NUMBER OF RECORDS IN      A45116 42900021
*                                        DATA BLOCK              A45116 42902021
         SR    WORK4,WORK4             OFFSET TO FIRST LOCATOR   A45116 42910021
LO21     LH    WORK2,LOCATORS(WORK4)   CONTENTS OF LOCATOR       A45116 42920021
         LA    WORK3,LOCATORS(WORK4)   ADDRESS OF LOCATOR        A45116 42930021
         LA    WORK2,DATA(WORK2)       ADDRESS OF RECORD         A45116 42940021
         CLC   PRIMEKEY(KEYL),X0(WORK2)  IS THIS THE REFERENCED  A45116 42950021
*                                        RECORD                  A45116 42952021
         BCR   EQUAL,WORK8             YES, RETURN               A45116 42960021
         BL    LO22                    NO MORE POSSIBILITES,     A45116 42970021
*                                        RECORD NOT IN DATA SET  A45116 42980021
         LA    WORK4,LOCL(WORK4)       INCREMENT TO NEXT LOCATOR A45116 42990021
         BCT   WORK5,LO21              REPEAT IF MORE RECORDS    A45116 43000021
LO22     LA    RETCDREG,NRF            RETURN CODE FOR NO RECORD A45116 43010021
         BR    WORK8                   RETURN                    A45116 43020021
         SPACE 2                                                        43030021
*   THIS SUBROUTINE LOCATES RECORD FOLLOWING REFERENCE           A45116 43040021
*     KEY (PRIMEKEY)                                             A45116 43042021
LO30     MVI   X0(PARMREG1),N          INSURE THAT OPTION CODE   A45116 43050021
*                                        IS CORRECT              A45116 43052021
         BAL   LINK9,LO1               GET DATA BLOCK            A45116 43060021
         LTR   RETCDREG,RETCDREG       ANY ERRORS                A45116 43070021
         BCR   NOTZERO,WORK8           YES, RETURN               A45116 43080021
         SR    WORK4,WORK4             OFFSET TO FIRST LOCATOR   A45116 43090021
LO31     LH    WORK2,LOCATORS(WORK4)   CONTENTS OF LOCATOR       A45116 43100021
         LA    WORK3,LOCATORS(WORK4)   ADDRESS OF LOCATOR        A45116 43110021
         LA    WORK2,DATA(WORK2)       ADDRESS OF RECORD         A45116 43120021
         CLC   X0(KEYL,WORK2),PRIMEKEY IS THIS THE NEXT RECORD   A45116 43130021
         BCR   RECHIGH,WORK8           YES, RETURN               A45116 43140021
         LA    WORK4,LOCL(WORK4)       INCREMENT TO NEXT LOCATOR A45116 43150021
         B     LO31                    REPEAT UNTIL FOUND        A45116 43160021
         SPACE 2                                                        43170021
*   THIS SUBROUTINE OBTAINS DATA BLOCK USING OPTION CODE         A45116 43180021
         SPACE                                                          43190021
*   BEGIN WITH DIRECTORY SEARCH                                  A45116 43200021
LO1      LA    WORK4,PRIMEKEY          SEARCH KEY ADDRESS INTO   A45116 43210021
         ST    WORK4,WORD2(PARMREG1)      PARM LIST              A45116 43220021
         L     ENTRY,DS                ENTRY POINT ADDRESS       A45116 43230021
         CALL  (15)                    FIND TTR OF BLOCK NEEDED  A45116 43240021
         CH    RETCDREG,LOEMPTY        EMPTY OR I/O ERROR        A45116 43250021
         BNL   LO16                    YES, TERMINATE            A45116 43260021
         LTR   RETCDREG,RETCDREG       WAS THE SEARCH SUCCESSFUL A45116 43270021
         BNZ   LO17                    NO-RECORD NOT FOUND       A45116 43280021
         BAL   WORK5,LO18              READ CORRECT DATA BLOCK   A45116 43290021
         BR    LINK9                   RETURN                    A45116 43300021
         SPACE                                                          43310021
*   READ IN DATA BLOCK                                           A45116 43320021
LO18     L     WORK6,WORD2(PARMREG1)   INDEX BUFFER FOUND  ADDR  A45116 43330021
         L     WORK4,BUFREF            FOUND ENTRY ADDRESS       A45116 43340021
         MVC   WORD2(TTR,PARMREG1),KEYL(WORK4)  MOVE TTR TO      A45116 43350021
*                                               PARM LIST        A45116 43352021
         L     ENTRY,RB                ENTRY POINT ADDRESS       A45116 43360021
         CALL  (15)                    READ IN DATA BLOCK        A45116 43370021
         LTR   RETCDREG,RETCDREG       ANY ERRORS                A45116 43380021
         BNZ   LO16                    YES, TERMINATE            A45116 43390021
         L     WORK6,WORD2(PARMREG1)   ADDRESS OF DATA BLOCK     A45116 43400021
         BR    WORK5                   RETURN                    A45116 43410021
LO17     BAL   WORK5,LO18              READ NEXT AVAILABLE BLOCK A45116 43420021
         LA    RETCDREG,NRF            RETURN CODE FOR RECORD    A45116 43430021
*                                        NOT FOUND               A45116 43432021
         BR    LINK9                   RETURN                    A45116 43440021
         SPACE 2                                                        44970020
         DROP  BASEREG,COMMREG,DATAREG,WORK6                     A45116 45000021
         SPACE 2                                                        45030020
*   CONSTANT AREA FOR RECORD LOCATE ROUTINE                      A45116 45060021
LOEMPTY  DC    H'8'                    DATA SET EMPTY CONSTANT   A45116 45090021
LOCONST1 DC    H'1'                    CONSTANT FOR INCREM KEY   A45116 45100021
         TITLE 'EDIT COMMAND ACCESS METHOD -MOVE ROUTINE ---IKJEBEMV'   45120020
*********************************************************************** 45150020
*                                                                     * 45240020
*STATUS -- VERSION NO. 01, OS/360 RELEASE NO 20                       * 45270020
*                                                                     * 45300020
*FUNCTION- THIS ROUTINE IS USED TO MOVE ANY NUMBER OF BYTES FROM      * 45330020
*   ONE LOCATION TO ANOTHER. MORE SPECIFICALLY IT IS USED FOR THE     * 45360020
*   FOLLOWING-                                                        * 45390020
*       -MOVES RECORDS INTO THE DATA SET BUFFERS                      * 45420020
*       -MOVES RECORDS FROM THE DATA SET BUFFERS                      * 45450020
*       -MOVES RECORD LOCATORS WITHIN THE DATA BLOCKS                 * 45480020
*       -MOVES INDEX ENTRIES WITHIN THE DIRECTORY BLOCKS              * 45510020
*                                                                     * 45540020
*ENTRY POINT- AT IKJEBEMV FROM THE FOLLOWING ROUTINES-                * 45570020
*       IKJEBEDL   (TWO  PLACES)      -RECORD DELETION                * 45600020
*       IKJEBERR                      -READING RECORDS                * 45630020
*       IKJEBEWR   (FOUR PLACES)      -WRITING RECORDS                * 45660020
*                                                                     * 45690020
*INPUT --                                                             * 45720020
*       REGISTER 0 CONTAINS THE LENGTH OF THE DATA TO MOVE            * 45750020
*        REGISTER 1 POINTS TO A TWO WORD PARAMETER LIST               * 45780020
*          WORD1- CONTAINS THE MOVE-FROM ADDRESS                      * 45810020
*          WORD2- CONTAINS THE MOVE-TO   ADDRESS                      * 45840020
*                                                                     * 45870020
*CUTPUT- THE NUMBER OF BYTES INDICATED IN REGISTER 0 ARE MOVED FROM   * 45900020
*   THE ADDRESS CONTAINED IN WORD1 OF THE INPUT LIST TO THE           * 45930020
*   ADDRESS SPECIFIED IN WORD2 OF THE INPUT LIST                      * 45960020
*                                                                     * 45990020
*EXTERNAL REFERENCES -- NONE                                          * 46020020
*                                                                     * 46050020
*EXITS,NORMAL-  NO RETURN CODE, OUTPUT AS ABOVE                       * 46080020
*                                                                     * 46110020
*EXITS,ERROR-  NONE                                                   * 46140020
*                                                                     * 46170020
*TABLES/WORK AREAS- NONE                                              * 46230020
*                                                                     * 46260020
*ATTRIBUTES- REFRESHABLE,ENABLED,NON-PRIVILEGED                       * 46290020
*                                                                     * 46320020
*NOTES --  REGISTER CONVENTIONS ARE AS FOLLOWS-                       * 46350020
*       BASEREG              -BASE REGISTER                           * 46380020
*       PARMREG0             -TOTAL BYTE COUNT                        * 46410020
*       FROMREG              -MOVE-FROM ADDRESS                       * 46440020
*       TOREG                -MOVE-TO  ADDRESS                        * 46470020
*       PARMREG1             -MOVE COUNT PER PASS                     * 46500020
*                                                                     * 46530020
*   THIS ROUTINE IS CHARACTER CODE INDEPENDENT                        * 46560020
*                                                                     * 46590020
*********************************************************************** 46620020
         EJECT                                                          46650020
IKJEBEMV CSECT                                                          46680020
*   PERFORM THE INITIALIZATION OPERATIONS HERE                          46710020
         SAVE  (14,12),T,*                                              46740020
         LA    SAVEREG,SAVEL(SAVEREG)  NEXT SAVE AREA                   46770020
         LR    BASEREG,ENTRY                                            46800020
         USING IKJEBEMV,BASEREG                                         46830020
         SPACE                                                          46860020
*   SET UP THE STARTING POSITIONS AND LENGTH MINUS ONE                  46890020
         BCTR  PARMREG0,ZERO           DECREMENT ONE FROM LENGTH        46920020
         L     TOREG,WORD2(PARMREG1)   TO ADDRESS                       46950020
         L     FROMREG,WORD1(PARMREG1) FROM ADDRESS                     46980020
         SPACE                                                          47010020
*   MOVES 256 BYTES ON ALL PASSES EXCEPT THE LAST                       47040020
MV2      LA    PARMREG1,K255           MAXIMUM MOVE LENGTH              47070020
         CR    PARMREG0,PARMREG1       COMPARE BALANCE TO MAXIMUM       47100020
         BNL   MV3                     USE MAXIMUM MOVE LENGTH          47130020
         LR    PARMREG1,PARMREG0       USE BALANCE                      47160020
MV3      EX    PARMREG1,MOVEINST       MOVE REQUIRED AMOUNT             47190020
         LA    PARMREG1,ONE(PARMREG1)  AMOUNT MOVED                     47220020
         AR    FROMREG,PARMREG1        ADJUST FROM ADDRESS              47250020
         AR    TOREG,PARMREG1          ADJUST TO-ADDRESS                47280020
         SR    PARMREG0,PARMREG1       REDUCE THE BALANCE               47310020
         BNM   MV2                     ARE WE FINISHED -NO BRANCH       47340020
         SPACE                                                          47370020
*   EXIT HERE WHEN ALL MOVED                                            47400020
         L     SAVEREG,WORD2(SAVEREG)  YES-OLD SAVE AREA                47430020
         RETURN (14,12),T              RESTORE THE REGISTERS            47460020
         SPACE                                                          47490020
         DROP  BASEREG                                                  47520020
         SPACE 2                                                        47550020
*   CONSTANT AREA FOR IKJEBEMV                                          47580020
MOVEINST MVC   X0(ONE,TOREG),X0(FROMREG) EXECUTED TO MOVE DATA          47610020
 TITLE 'EDIT COMMAND ACCESS METHOD -READ A BLOCK ROUTINE --IKJEBERB'    47640020
*********************************************************************** 47670020
*                                                                     * 47760020
*STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                      * 47790020
*                                                                     * 47820020
*FUNCTION -- THIS ROUTINE READS IN A REQUESTED BLOCK GIVEN A TTR      * 47850020
*   THAT IS PASSED IN THE INPUT PARAMETER LIST.  IF THE REQUESTED     * 47880020
*   BLOCK IS ALREADY IN CORE, NO PHYSICAL I/O IS REQUIRED. THE        * 47910020
*   BUFFER CHAIN IS INSPECTED TO SEE IF THE REQUESTED BLOCK IS        * 47940020
*   PRESENT. IF THE BLOCK IS IN CORE, ITS ADDRESS IS PASSED BACK      * 47970020
*   IN THE PARAMETER LIST.                                            * 48000020
*        IF THE BLOCK IS NOT IN CORE, AN EMPTY BUFFER IS OBTAINED     * 48030020
*   BY CALLING THE BUFFER ASSIGNMENT ROUTINE, IKJEBEAS.  THE BLOCK    * 48060020
*   IS READ IN BY GOING TO THE RESIDENT CONVERT ROUTINE FOR THE       * 48090020
*   TTR TO MBBCCHHR CONVERSION.  A XDAP READ IS THEN PERFORMED TO     * 48120020
*   OBTAIN THE BLOCK.  THE WAIT ROUTINE, IKJEBEWA, INSURES THAT       * 48150020
*   THE I/O IS COMPLETE BEFORE RETURNING THE ADDRESS OF THE BUFFER    * 48180020
*   IN THE INPUT PARAMETER LIST.                                      * 48210020
*                                                                     * 48240020
*ENTRY POINTS --                                                      * 48270020
*       IKJEBERB VIA A CALL FROM EITHER IKJEBEAD, IKJEBEDL,           * 48300020
*        IKJEBEDS, IKJEBEDU, OR IKJEBELO.                             * 48330020
*                                                                     * 48360020
*INPUT -- REGISTER ONE POINTS TO A TWO WORD PARAMETER LIST.           * 48390020
*       WORD1-  CONTAINS A POINTER TO THE WORKAREA, UTILWORK          * 48420020
*       WORD2-  CONTAINS THE TTR OF THE DESIRED BLOCK                 * 48450020
*                                                                     * 48510020
*OUTPUT -- THE SECOND WORD OF THE INPUT PARM LIST CONTAINS THE        * 48540020
*   ADDRESS OF THE BUFFER THAT CONTAINS THE REQUESTED BLOCK.          * 48570020
*                                                                     * 48600020
*EXTERNAL REFERENCES --                                               * 48630020
*       IKJEBEAS             -ASSIGNS BUFFER READ-IN AREA             * 48660020
*       IKJEBEWA             -WAITS ON THE I/O OPERATION              * 48690020
*       IECPCNVT             -RESIDENT CONVERT ROUTINE                * 48720020
*       MACROS USED                                                   * 48750020
*         XDAP               -READ INTO CORE ANY BLOCK                * 48780020
*                                                                     * 48810020
*EXITS,NORMAL -- REGISTER 15 CONTAINS A RETURN CODE OF ZERO WITH      * 48840020
*   OUTPUT AS DESCRIBED ABOVE.                                        * 48870020
*                                                                     * 48900020
*EXITS,ERROR --  REGISTER 15 CONTAINS A RETURN CODE OF TWELVE ON      * 48930020
*   I/O ERRORS.                                                       * 48960020
*                                                                     * 48990020
*TABLES/WORK AREAS -- THIS ROUTINE IS DEPENDENT ON THE WORKAREA       * 49020020
*   FOR THE BUFFER ADDRESSES AND ON 'VECTABLE' FOR THE ADDRESSES      * 49050020
*   OF THE EXTERNAL ROUTINES.                                         * 49080020
*                                                                     * 49110020
*ATTRIBUTES -- REFRESHABLE, NON-PRIVILEGED, ENABLED                   * 49140020
*                                                                     * 49170020
*NOTES -- REGISTER CONVENTIONS ARE AS FOLLOWS-                        * 49200020
*       BASEREG              -BASE REGISTER                           * 49230020
*       DATAREG              -WORK AREA ADDRESSING                    * 49260020
*       COMMREG              -VECTOR TABLE ADDRESSING                 * 49290020
*       WORK6                -BUFFER ADDRESSING                       * 49320020
*                                                                     * 49350020
*   THIS ROUTINE IS CHARACTER CODE INDEPENDENT                        * 49380020
*                                                                     * 49410020
*********************************************************************** 49440020
         SPACE 2                                                        49470020
IKJEBERB CSECT                                                          49500020
*   PERFORM THE INITIALIZATION OPERATIONS HERE                          49530020
         SAVE  (14,12),T,*             SAVE THE REGISTERS               49560020
         LA    SAVEREG,SAVEL(SAVEREG)  STEP TO NEXT SAVEAREA            49590020
         LR    BASEREG,ENTRY           ENTRY POINT ADDRESS              49620020
         USING IKJEBERB,BASEREG                                         49650020
         L     DATAREG,WORD1(PARMREG1) WORK AREA ADDRESS                49680020
         USING UTILWORK,DATAREG                                         49710020
         L     COMMREG,VTABLE          TABLE OF ROUTINE ADDRESSES       49740020
         USING VECTABLE,COMMREG                                         49770020
         SPACE 2                                                        49800020
*   WAIT FOR ANY I/O TO COMPLETE HERE                                   49830020
         TM    DCBSTATS,IO             ANY I/O IN PROGRESS              49860020
         BZ    RB6                     NO--GO FIND THE BLOCK            49890020
         L     WORK7,FOUR(PARMREG1)    SAVE INPUT TTR                   49920020
         MVC   FOUR(PTR,PARMREG1),DCBBUFIO  LAST WAITING BUFFER         49950020
         L     ENTRY,WA                ENTRY POINT ADDRESS              49980020
         CALL  (15)                    WAIT FOR THE I/O TO COMPLETE     50010020
         LTR   RETCDREG,RETCDREG       ANY ERRORS                       50040020
         BNZ   RB13                    YES-RETURN                       50070020
         ST    WORK7,WORD2(PARMREG1)   RESTORE BUFFER ADDRESS           50100020
         SPACE 2                                                        50130020
*   CHECK IF THE DESIRED BLOCK IS IN CORE                               50160020
RB6      MVI   TTR+WORD2(PARMREG1),ZERO  INSURE TTR0                    50190020
         L     WORK5,WORD2(PARMREG1)   TTR OF DESIRED BLOCK             50220020
         L     WORK6,DCBBUFAD          ADDRESS OF FIRST BUFFER          50250020
         USING BUFFER,WORK6                                             50280020
RB2      C     WORK5,BUFTTR            IS THIS THE CORRECT BLOCK        50310020
         BE    RB1                     YES-RETURN                       50340020
         L     WORK6,BUFCHAIN          NO--ADDRESS OF NEXT BUFFER       50370020
         LTR   WORK6,WORK6             LAST IN CHAIN                    50400020
         BNZ   RB2                     NO--GO TEST NEXT BUFFER          50430020
*                                      YES-DESIRED BLOCK NOT IN CORE    50460020
         SPACE 2                                                        50490020
*   BLOCK IS NOT IN CORE AND MUST BE READ INTO EMPTY BUFFER             50520020
         L     ENTRY,AS                ENTRY POINT ADDRESS              50550020
         CALL  (15)                    GET AN EMPTY BUFFER              50580020
         LTR   RETCDREG,RETCDREG       ANY ERRORS                       50610020
         BNZ   RB13                    YES-RETURN                       50640020
         L     WORK6,WORD2(PARMREG1)   ASSIGNED BUFFER ADDRESS          50670020
         ST    WORK5,BUFTTR            TTR OF DESIRED BLOCK             50700020
         SPACE 2                                                        50730020
*   POSITION ACCESS METHOD FOR CORRECT BLOCK                            50760020
RB4      LR    PARMREG0,WORK5          TTR TO BE CONVERTED              50790020
         L     PARMREG1,DCBDEBAD       ADDRESS OF DEB                   50820020
         LA    WORK2,RBLKREF           ADDRESS TO RECEIVE MBBCCHHR      50850020
         LR    WORK3,DATAREG           SAVE ADDRESS FOR WORKAREA        50880020
         DROP  DATAREG                                                  50910020
         USING UTILWORK,WORK3                                           50940020
         STM   WORK9,SAVEREG,TEMPREGS  SAVE REGISTERS 9-13              50970020
         L     ENTRY,CVTPTR            ADDRESS OF CVT                   51000020
         USING CVT,ENTRY                                                51030020
         L     ENTRY,CVTPCNVT          ADDRESS OF CONVERT ROUTINE       51060020
         DROP  ENTRY                                                    51090020
         BALR  RETREG,ENTRY            CONVERT TTR TO MBBCCHHR          51120020
         LM    WORK9,SAVEREG,TEMPREGS  RESTORE REGISTERS 9-13           51150020
         DROP  WORK3                                                    51180020
         USING UTILWORK,DATAREG                                         51210020
         SPACE 2                                                        51240020
*   READ IN THE DESIRED BLOCK HERE                                      51270020
         XDAP  XDAPRLST,RI,UTILDCB,DATA,,MF=E   READ IN A BLOCK         51300020
         LA    PARMREG1,PARM1          PARAMETER LIST ADDRESS           51330020
         ST    WORK6,WORD2(PARMREG1)   BUFFER TO WAIT UPON              51360020
         MVI   BUFSTATS,WAITXR         INDICATE OPERATION UPON WHICH    51390020
*                                        TO WAIT                        51420020
         L     ENTRY,WA                ENTRY POINT ADDRESS              51450020
         CALL  (15)                    WAIT FOR THE I/O TO COMPLETE     51480020
         LTR   RETCDREG,RETCDREG       ANY ERRORS                       51510020
         BNZ   RB13                    YES-RETURN                       51540020
         SPACE 2                                                        51570020
*   STORE RETURN BUFFER ADDRESS AND EXIT HERE                           51600020
RB1      ST    WORK6,WORD2(PARMREG1)   DESIRED BUFFER ADDRESS           51630020
         SR    RETCDREG,RETCDREG       SET RETURN CODE = 0              51660020
RB13     L     SAVEREG,WORD2(SAVEREG)  OLD SAVE AREA ADDRESS            51690020
         RETURN (14,12),T,RC=(15)      RESTORE THE REGISTERS            51720020
         SPACE 2                                                        51750020
         DROP  BASEREG,COMMREG,DATAREG,WORK6                            51780020
 TITLE 'EDIT COMMAND ACCESS METHOD --READ A RECORD ROUTINE --IKJEBERR'  51810020
*********************************************************************** 51840020
*                                                                     * 51930020
*STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                      * 51960020
*                                                                     * 51990020
*FUNCTION --  THIS ROUTINE SERVES AS THE INTERFACE WHEN READING       * 52020020
*   RECORDS FROM THE UTILITY DATA SET. FIVE DIFFERENT READ OPTIONS    * 52050020
*   ARE POSSIBLE (AS SPECIFIED BELOW), IN ADDITION, AN INPUT KEY      * 52080020
*   MAY BE PROVIDED WHICH WILL REPLACE THE LAST REFERENCED KEY IN     * 52110020
*   THE ACCESS METHOD BEFORE THE OPERATION TAKES PLACE.  THE DESIRED  * 52140020
*   RECORD WILL EITHER BE MOVED TO THE ADDRESS SPECIFIED BY THE       * 52170020
*   CALLER OR A POINTER TO THE RECORD PASSED BACK IN A REGISTER.      * 52200020
*                                                                     * 52230020
*        FINDING THE DESIRED RECORD INVOLVES USING THE RECORD         * 52260020
*   LOCATING ROUTINE (IKJEBELO).  IF THE DESIRED RECORD DOES NOT      * 52290020
*   EXIST, A RETURN CODE OF 4 IS PASSED BACK.  A RETURN CODE OF 12    * 52320020
*   IS PASSED BACK IF AN I/O ERROR IS ENCOUNTERED.                    * 52350020
*                                                                     * 52380020
*ENTRY POINTS --                                                      * 52410020
*       IKJEBERR             VIA A CALL FROM IKJEBEUT                 * 52440020
*                                                                     * 52470020
*INPUT -- REGISTER ONE POINTS TO A 1-3 WORD PARAMETER LIST            * 52500020
*        WORD1-                                                       * 52530020
*         HIGH ORDER BYTE CONTAINS A CODE AS FOLLOWS-                 * 52560020
*           X'00'            READ CURRENT REFERENCE RECORD            * 52590020
*           X'01             READ RECORD PREVIOUS TO REFERENCE        * 52620020
*           X'02'            READ RECORD AFTER REFERENCE              * 52650020
*           X'04'            READ FIRST RECORD IN DATA SET            * 52680020
*           X'05'            READ LAST RECORD IN DATA SET             * 52710020
*         THREE LOW ORDER BYTES CONTAIN A POINTER TO THE WORKAREA/DCB * 52740020
*                                                                     * 52770020
*       WORD2-  OPTIONALLY CONTAINS A POINTER TO A FOUR BYTE BINARY   * 52800020
*         KEY THAT REPLACES THE LAST REFERENCED KEY IN THE ACCESS     * 52830020
*         METHOD BEFORE THE READ OPERATION TAKES PLACE.               * 52860020
*                                                                     * 52890020
*       WORD3-  OPTIONALLY CONTAINS AN ADDRESS WHICH INDICATES        * 52920020
*         WHERE THE LOCATED RECORD IS TO BE PLACED.                   * 52950020
*                                                                     * 52980020
*OUTPUT --  REGISTERS AS DESCRIBED BELOW                              * 53010020
*   THE DESIRED RECORD IS EITHER MOVED TO THE SPECIFIED LOCATION OR   * 53040020
*   A POINTER IS RETURNED TO THE RECORD IN REGISTER ONE.              * 53070020
*                                                                     * 53100020
*EXTERNAL REFERENCES --                                               * 53130020
*       IKJEBELO             -FINDS THE DESIRED RECORD                * 53160020
*       IKJEBEMV             -MOVES RECORD TO USER AREA, ON REQUEST   * 53190020
*                                                                     * 53220020
*EXITS,NORMAL --  A RETURN CODE OF ZERO IN REGISTER 15 AND THE        * 53250020
*   DESIRED RECORD HAS BEEN MADE AVAILABLE TO THE USER.               * 53280020
*        A RETURN CODE OF FOUR IS PASSED BACK IF THE REQUESTED        * 53310020
*   RECORD DOES NOT EXIST                                             * 53340020
*                                                                     * 53370020
*EXITS,ERROR --  A RETURN CODE OF 12 IS RETURNED IN REGISTER 15       * 53400020
*   IF AN I/O ERROR IS ENCOUNTERED                                    * 53430020
*                                                                     * 53460020
*TABLES/WORK AREAS --  THIS ROUTINE IS DEPENDENT ON THE WORKAREA,     * 53490020
*   UTILWORK, FOR THE REFERENCE KEY INFORMATION AND ON THE VECTOR     * 53520020
*   TABLE, 'VECTABLE', FOR THE EXTERNAL REFERENCES.                   * 53550020
*                                                                     * 53580020
*ATTRIBUTES -- REFRESHABLE,NON-PRIVILEGED,ENABLED                     * 53610020
*                                                                     * 53640020
*NOTES --  REGISTER USE IS AS FOLLOWS-                                * 53670020
*       BASEREG              -BASE REGISTER                           * 53700020
*       COMMREG              -VECTOR TABLE ADDRESSING                 * 53730020
*       DATAREG              -WORK AREA ADDRESSING                    * 53760020
*       WORK6                -BUFFER ADDRESSING                       * 53790020
*       WORK2,WORK4,WORK5    -WORK REGISTERS                          * 53820020
*                                                                     * 53850020
*   THIS ROUTINE IS CHARACTER CODE INDEPENDENT                        * 53880020
*                                                                     * 53910020
*                                                                     * 53940020
*********************************************************************** 53970020
         SPACE 2                                                        54000020
IKJEBERR CSECT                                                          54030020
*   PERFORM THE INITIALIZATION OPERATIONS HERE                          54060020
         SAVE  (14,12),T,*                                              54090020
         LR    BASEREG,ENTRY           ENTRY POINT ADDRESS              54120020
         USING IKJEBERR,BASEREG                                         54150020
         L     DATAREG,WORD1(PARMREG1) WORK AREA ADDRESS                54180020
         USING UTILWORK,DATAREG                                         54210020
         L     COMMREG,VTABLE          TABLE OF ROUTINE ADDRESSES       54240020
         USING VECTABLE,COMMREG                                         54270020
         LA    WORK5,SAVEAREA          NEW SAVE AREA                    54300020
         ST    SAVEREG,WORD2(WORK5)    OLD ADDRESS TO NEW               54330020
         ST    WORK5,WORD3(SAVEREG)    NEW ADDRESS TO OLD               54360020
         LR    SAVEREG,WORK5           NEW SAVE AREA                    54390020
         SPACE 2                                                        54420020
*   PROCESS INPUT PARAMETER LIST                                        54450020
         MVC   SAVEKEY(KEYL),PRIMEKEY  SAVE REFERENCE KEY               54480020
         LR    WORK4,PARMREG1          SAVE INPUT PARM LIST ADDRESS     54510020
         TM    X0(PARMREG1),LAST       MORE THAN ONE PARAMETER          54540020
         BO    RR3                     NO--                             54570020
         L     WORK6,WORD2(PARMREG1)   POSSIBLE POINTER TO KEY          54600020
         LA    WORK6,X0(WORK6)         CLEAR HIGH ORDER BYTE            54630020
         LTR   WORK6,WORK6             IS THERE A KEY POINTER           54660020
         BZ    RR3                     NO--                             54690020
RR1      MVC   PRIMEKEY(KEYL),X0(WORK6) RESET REFERENCE KEY             54720020
         SPACE 2                                                        54750020
*   FIND THE SPECIFIED RECORD                                           54780020
RR3      MVC   PARM1(PTR),WORD1(PARMREG1)  INPUT DCB POINTER AND OPTION 54810020
         LA    PARMREG1,PARM1                CODE TO PARAMETER LIST     54840020
         NI    PARM1,ALL-LAST          INSURE HIGH ORDER BIT OFF        54870020
         L     ENTRY,LO                ENTRY POINT ADDRESS              54900020
         CALL  (15)                    FIND THE RECORD                  54930020
         LTR   RETCDREG,RETCDREG       DOES THE RECORD EXIST            54960020
         BNZ   RR40                    NO--                             54990020
         SPACE 2                                                        55020020
*   THE RECORD WAS FOUND -- COMPUTE ADDRESS OF THE RECORD               55050020
RR2      L     WORK6,WORD2(PARMREG1)   BUFFER ADDRESS                   55080020
         USING BUFFER,WORK6                                             55110020
         L     WORK5,BUFREF            ADDRESS OF RECORD LOCATOR        55140020
         LH    WORK5,X0(WORK5)         CONTENTS OF LOCATOR              55170020
         LA    WORK5,DATA(WORK5)       RECORD ADDRESS                   55200020
         SPACE 2                                                        55230020
*   DETERMINE FORM OF OUTPUT HERE                                       55260020
         TM    X0(WORK4),LAST          MORE THAN ONE PARAMETER          55290020
         BO    RR5                     NO--PASS BACK ADDRESS OF RECORD  55320020
         TM    WORD2(WORK4),LAST       MORE THAN TWO PARAMETERS         55350020
         BO    RR5                     NO--PASS BACK ADDRESS OF RECORD  55380020
         L     WORK2,WORD3(WORK4)      AREA ADDRESS, IF ANY             55410020
         LA    WORK2,X0(WORK2)         CLEAR HIGH ORDER                 55440020
         LTR   WORK2,WORK2             IS THERE AN ADDRESS              55470020
         BNZ   RR4                     YES-MOVE RECORD TO THIS ADDRESS  55500020
         SPACE 2                                                        55530020
*   SET UP RETURN PARM LIST AND RETURN TO CALLER HERE                   55560020
RR5      LR    PARMREG1,WORK5          RECORD ADDRESS                   55590020
         SR    RETCDREG,RETCDREG       RETURN CODE                      55620020
RR6      L     SAVEREG,WORD2(SAVEREG)  OLD SAVE AREA                    55650020
         L     RETREG,L3*L4(SAVEREG)   RESTORE REGISTER 14              55680020
         L     PARMREG0,L8*L2+L4(SAVEREG) RESTORE REGISTER 0            55710020
         RETURN (2,12),T               RESTORE REGISTERS 2-12           55740020
         SPACE 2                                                        55770020
*   MOVE THE RECORD TO THE USER SPECIFIED AREA                        * 55800020
RR4      ST    WORK2,TEMP2             MOVE-TO ADDRESS                  55830020
         ST    WORK5,TEMP1             MOVE-FROM ADDRESS                55860020
         LA    PARMREG1,TEMP1          PARAMETER LIST ADDRESS           55890020
         MVC   TEMP3(L2),KEYL(WORK5)   LENGTH OF RECORD                 55920020
         LH    WORK2,TEMP3             LENGTH OF RECORD                 55950020
         LA    WORK2,KEYL(WORK2)       ACCOUNT FOR KEY LENGTH           55980020
         LR    PARMREG0,WORK2          LENGTH TO PARM REGISTER          56010020
         L     ENTRY,MV                ENTRY POINT ADDRESS              56040020
         CALL  (15)                    MOVE RECORD TO CALLERS AREA      56070020
         B     RR5                     RETURN                           56100020
         SPACE 2                                                        56130020
*   ON ERROR CONDITIONS ENTER HERE                                      56160020
RR40     MVC   PRIMEKEY(KEYL),SAVEKEY  RESTORE OLD KEY                  56190020
         TM    DCBSTATS,ERROR          ANY I/O ERRORS                   56220020
         BO    RR6                     YES- R.C. =12                    56250020
RR10     LA    RETCDREG,NRF            NO--RETURN CODE//NO RECORD       56280020
         B     RR6                     RETURN                           56310020
         SPACE 2                                                        56340020
         DROP  BASEREG,COMMREG,DATAREG,WORK6                            56370020
 TITLE 'EDIT COMMAND ACCESS METHOD --THE WAIT ROUTINE  ---IKJEBEWA'     56400020
*********************************************************************** 56430020
*                                                                     * 56520020
*STATUS -- LEVEL NO. 01, OS/360 RELEASE NO. 20                        * 56550020
*                                                                     * 56580020
*FUNCTION -- THIS ROUTINE IS UTILIZED TO INSURE THAT A PREVIOUS I/O   * 56610020
*   REQUEST IS COMPLETE.  A WAIT MACRO IS ISSUED FOR A PRIOR XDAP     * 56640020
*   OPERATION AND A CHECK MACRO FOR A BSAM OPERATION.  IN THE EVENT   * 56670020
*   THAT AN I/O ERROR HAS OCCURRED, THE SYNAD ROUTINE WILL BE         * 56700020
*   GIVEN CONTROL DIRECTLY AFTER THE WAIT OR INDICRECTLY AS A RESULT  * 56730020
*   GIVEN CONTROL DIRECTLY AFTER THE WAIT OR INDIRECTLY AS A RESULT   * 56740020
*   OF A CHECK MACRO.  THE SYNAD ROUTINE OBTAINS THE ERROR INFORM-    * 56760020
*   ATION VIA THE SYNADAF MACRO.                                      * 56790020
*        IF THE I/O HAS JUST COMPLETED ON A NEWLY FORMATTED BLOCK,    * 56820020
*   ITS TTR IS OBTAINED WITH THE NOTE MACRO AND RETAINED IN THE       * 56850020
*   BUFFER.                                                           * 56880020
*                                                                     * 56910020
*ENTRY POINTS --                                                      * 56940020
*       IKJEBEWA             -VIA A CALL FROM IKJEBEAD, IKJEBEAS,     * 56970020
*                               IKJEBERB, IKJEBEWB.                   * 57000020
*INPUT --  REGISTER 1 POINTS TO A TWO WORD PARAMETER LIST             * 57030020
*       WORD1-  CONTAINS ADDRESS OF THE WORKAREA, UTILWORK            * 57060020
*       WORD2-  CONTAINS ADDRESS OF BUFFER TO 'WAIT' UPON             * 57090020
*                                                                     * 57120020
*OUTPUT --  THE I/O OPERATION ON THE SPECIFIED IS ALLOWED TO          * 57150020
*   COMPLETE. ANY I/O ERROR RESULTS IN THE SYNADAF INFORMATION        * 57180020
*   BEING STORED IN THE 'IOMSG' FIELD OF THE WORKAREA.                * 57210020
*                                                                     * 57240020
*EXTERNAL REFERENCES --                                               * 57270020
*       MACROS USED                                                   * 57300020
*         WAIT               -'WAIT' ON XDAP OPERATION                * 57330020
*         CHECK              -'WAIT' AND 'CHECK' BSAM OPERATION       * 57360020
*         NOTE               -FIND TTR OF LAST NEW BLOCK              * 57390020
*         SYNADAF            -OBTAIN I/O ERROR INFORMATION            * 57420020
*         SYNADRLS           -RELEASE ERROR MESSAGE BUFFER            * 57450020
*                                                                     * 57480020
*EXITS,NORMAL -- REGISTER 15 CONTAINS A RETURN CODE OF ZERO AND THE   * 57510020
*   I/O ON THE SPECIFIED BUFFER IS INSURED OF BEING COMPLETED.        * 57540020
*                                                                     * 57570020
*EXITS,ERROR --  REGISTER 15 CONTAINS A RETURN CODE OF 12.  THE       * 57600020
*   SPECIFIC ERROR INFORMATION IS STORED IN THE WORKAREA.             * 57630020
*                                                                     * 57660020
*TABLES/WORK AREAS -- THIS ROUTINE IS DEPENDENT UPON THE DCB AND      * 57690020
*   BUFFER STATUS SWITCHES, THE BSAM DECBS, THE XDAP ECB, AND         * 57720020
*   THE ERROR MESSAGE FIELD IN THE WORKAREA.                          * 57750020
*                                                                     * 57780020
*ATTRIBUTES -- REFRESHABLE,NON-PRIVILEGED,ENABLED                     * 57810020
*                                                                     * 57840020
*NOTES --  THE REGISTER CONVENTIONS ARE AS FOLLOWS-                   * 57870020
*       BASEREG              -BASE REGISTER                           * 57900020
*       DATAREG              -WORK AREA ADDRESSING                    * 57930020
*       WORK6                -BUFFER ADDRESSING                       * 57960020
*                                                                     * 57990020
*   THIS ROUTINE IS CHARACTER CODE INDEPENDENT                        * 58020020
*                                                                     * 58050020
*********************************************************************** 58080020
         SPACE 2                                                        58110020
IKJEBEWA CSECT                                                          58140020
         ENTRY IKJEBESY                                                 58170020
*   PERFORM THE INITIALIZATION OPERATIONS HERE                          58200020
         SAVE  (14,12),T,*             SAVE THE REGISTERS               58230020
         LA    SAVEREG,SAVEL(SAVEREG)  STEP TO NEXT SAVEAREA            58260020
         LR    BASEREG,ENTRY           ENTRY POINT ADDRESS              58290020
         USING IKJEBEWA,BASEREG                                         58320020
         L     DATAREG,WORD1(PARMREG1) WORK AREA ADDRESS                58350020
         USING UTILWORK,DATAREG                                         58380020
         SPACE 2                                                        58410020
*   CHECK FOR TYPE OF OPERATION (BSAM OR XDAP)                          58440020
         L     WORK6,WORD2(PARMREG1)   BUFFER ADDRESS                   58470020
         USING BUFFER,WORK6                                             58500020
         TM    BUFSTATS,WAITB          WAS THIS A BSAM OPERATION        58530020
         BO    WA5                     YES-GO ISSUE CHECK MACRO         58560020
         SPACE 2                                                        58590020
*   INSURE THAT THE XDAP OPERATION IS COMPLETE                          58620020
         LA    PARMREG1,XRECB          ECB FOR XDAP READ                58650020
         TM    BUFSTATS,WAITXR         WAS THIS A XDAP READ             58680020
         BO    WA3                     YES-GO CHECK IF A-OK             58710020
         LA    PARMREG1,XWECB          ECB FOR XDAP WRITE               58740020
WA3      TM    X0(PARMREG1),COMPLETE   IS THE I/O COMPLETE              58770020
         BO    WA6                     YES--GO CHECK STATUS             58800020
         WAIT  ECB=(1)                 WAIT FOR COMPLETION              58830020
         SPACE 2                                                        58860020
*   TEST FOR ERRORS AND PROCESS SAME IN SYNAD ROUTINE                   58890020
WA6      CLI   X0(PARMREG1),GOOD       ANY ERRORS                       58920020
         BE    WA11                    NO--RETURN                       58950020
         L     ENTRY,DCBSYNAD          ADDRESS OF SYNAD ROUTINE         58980020
         BALR  RETREG,ENTRY            PROCESS ERROR INFORMATION        59010020
WA21     LA    RETCDREG,IOERR          SET RETURN CODE =12              59040020
         B     WA2                     RETURN TO CALLER                 59070020
         SPACE 2                                                        59100020
*   INSURE A COMPLETED BSAM OPERATION HERE                              59130020
WA5      LA    PARMREG1,WRDECB         ADDRESS OF BSAM WRITE DECB       59160020
WA52     CHECK (1)                     WAIT FOR COMPLETION OF I/O       59190020
         TM    DCBSTATS,ERROR          WERE THERE ANY ERRORS            59220020
         BO    WA21                    YES--RETURN                      59250020
         SPACE 2                                                        59280020
*   LOG TTR OF ALL NEW BLOCKS                                           59310020
         LA    PARMREG1,UTILDCB        ADDRESS OF DCB                   59340020
         NOTE  (1)                     FIND TTR OF LAST BLOCK           59370020
         ST    PARMREG1,BUFTTR         SAVE IN BUFFER FIELD             59400020
         SPACE 2                                                        59430020
*   TURN OFF ALL FLAGS AND EXIT HERE                                    59460020
WA11     NI    BUFSTATS,ALL-WAITB-WAITXR-WAITXW  TURN OFF WAIT FLAGS    59490020
         NI    DCBSTATS,ALL-IO         TURN OFF IO FLAG                 59520020
WA1      SR    RETCDREG,RETCDREG       SET RETURN CODE                  59550020
WA2      L     SAVEREG,WORD2(SAVEREG)  OLD SAVE AREA                    59580020
         RETURN (14,12),T,RC=(15)      RESTORE THE REGISTERS            59610020
         EJECT                                                          59640020
*   ERROR PROCESSING HERE                                               59670020
*   REGISTER 0 CONTAINS THE ADDRESS OF DECB FOR BSAM OPERATIONS         59700020
*   REGISTER 1 INDICATES BSAM READ OR WRITE AND DCB ADDRESS             59730020
*   REGISTERS 2-13 SAME AS AT 'CHECK' TIME OR WAIT ON XDAP              59760020
*   REGISTER 14 IS THE RETURN ADDRESS                                   59790020
*   REGISTER 15 IS THE ENTRY POINT ADDRESS                              59820020
IKJEBESY EQU   *                       ENTER SYNAD ROUTINE HERE         59850020
*   DETERMINE THE OPERATION IN ERROR                                    59880020
         TM    BUFSTATS,WAITB          IS THIS A BSAM OPERATION         59910020
         BO    SY1                     YES-                             59940020
         SPACE 2                                                        59970020
*   PROCESS XDAP ERRORS HERE                                            60000020
         LA    PARMREG1,XRIOB          XDAP READ IOB ADDRESS            60030020
         TM    BUFSTATS,WAITXR         WAS THIS A XDAP READ             60060020
         BO    SY2                     YES-GO ISSUE SYNADAF             60090020
         LA    PARMREG1,XWIOB          XDAP WRITE IOB ADDRESS           60120020
SY2      SYNADAF ACSMETH=EXCP          OBTAIN ERROR INFORMATION         60150020
SY11     MVC   IOMSG(K78),K50(PARMREG1) I/O ERROR INFO TO WORKAREA      60180020
         SYNADRLS                      RELEASE THE SYNADAF BUFFER       60210020
         OI    DCBSTATS,ERROR          INDICATE PERMANENT ERROR         60240020
         BR    RETREG                  RETURN                           60270020
         SPACE 2                                                        60300020
*   PROCESS BSAM ERRORS HERE                                            60330020
SY1      SYNADAF ACSMETH=BSAM          OBTAIN ERROR INFORMATION         60360020
         B     SY11                    RETURN                           60390020
         SPACE 2                                                        60420020
         DROP  BASEREG,DATAREG,WORK6                                    60450020
 TITLE 'EDIT COMMAND ACCESS METHOD --WRITE A BLOCK ROUTINE ---IKJEBEWB' 60480020
*********************************************************************** 60510020
*                                                                     * 60600020
*STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                      * 60630020
*                                                                     * 60660020
*FUNCTION --  THIS ROUTINE INITIATES A WRITE OPERATION OF THE BLOCK   * 60690020
*   IN A SPECIFIED BUFFER.  BEFORE THE WRITE IS STARTED, ANY PREVIOUS * 60720020
*   I/O IS BROUGHT TO COMPLETION BY CALLING THE WAIT ROUTINE, IKJEBEWA* 60750020
*   NEW BLOCKS ARE WRITTEN OUT WITH A BSAM WRITE AND A XDAP WRITE     * 60780020
*   IS USED ON ALL PREVIOUSLY FORMATTED BLOCKS.                       * 60810020
*        IF AN XDAP WRITE IS USED ON AN OLD BLOCK, ITS TTR IS         * 60840020
*   COMVERTED TO AN ACTUAL DEVICE TRACK ADDRESS BY THE SYSTEM         * 60870020
*   RESIDENT CONVERT ROUTINE, IECPCNVT.                               * 60900020
*        ANYTIME A BLOCK IS WRITTEN OUT, BIT SWITCHES ARE SET IN      * 60930020
*   THE BUFFER INDICATING THE TYPE OF OPERATION AND THE BUFFER        * 60960020
*   ADDRESS IS SAVED IN THE WORKAREA.                                 * 60990020
*                                                                     * 61020020
*ENTRY POINT --                                                       * 61050020
*       IKJEBEWB   -VIA A CALL FROM IKJEBEAD, IKJEBEAS, IKJEBEDL,     * 61080020
*                     IKJEBEDU, AND IKJEBEWR.                         * 61110020
*                                                                     * 61140020
*INPUT --  REGISTER ONE POINTS TO A TWO-WORD PARAMETER LIST           * 61170020
*       WORD1-   CONTAINS THE ADDRESS OF THE WORKAREA                 * 61200020
*       WORD2-   CONTAINS THE ADDRESS OF THE BUFFER THAT CONTAINS     * 61230020
*                THE BLOCK TO BE WRITTEN.                             * 61260020
*                                                                     * 61290020
*OUTPUT -- A WRITE OPERATION TO A DIRECT ACCESS DEVICE IS INITIATED   * 61320020
*   FOR THE BLOCK CONTAINED IN THE SPECIFIED BUFFER.                  * 61350020
*                                                                     * 61380020
*EXTERNAL REFERENCES --                                               * 61410020
*       IKJEBEWA             -WAITS ON ANY I/O IN PROGRESS            * 61440020
*       IECPCNVT             -CONVERTS TTR TO MBBCCHHR                * 61470020
*       MACROS USED                                                   * 61500020
*         WRITE              -INITIATE WRITE OF NEW BLOCK             * 61560020
*         XDAP               -INITIATE WRITE OF OLD BLOCK             * 61590020
*EXITS,NORMAL --  RETURNS TO CALLING ROUTINE WITH REGISTER 15         * 61650020
*   CONTAINING A RETURN CODE OF 0.                                    * 61680020
*                                                                     * 61710020
*EXITS,ERROR --   RETURNS TO CALLING ROUTINE WITH REGISTER 15         * 61740020
*   CONTAINING A RETURN CODE OF 12.                                   * 61770020
*                                                                     * 61800020
*TABLES/WORK AREAS -- THIS ROUTINE IS DEPENDENT ON THE VECTOR TABLE   * 61830020
*   FOR CALLS TO EXTERNAL ROUTINES.  THIS ROUTINE IS DEPENDENT ON THE * 61860020
*   CVT FOR THE ADDRESS OF THE RESIDENT CONVERT ROUTINE, IECPCNVT.    * 61890020
*                                                                     * 61920020
*ATTRIBUTES -- REFRESHABLE, ENABLED, NON-PRIVILEGED                   * 61950020
*                                                                     * 61980020
*NOTES --  REGISTER CONVENTIONS ARE AS FOLLOWS-                       * 62010020
*       BASEREG              -BASE REGISTER                           * 62040020
*       COMMREG              -VECTOR TABLE ADDRESSING                 * 62070020
*       DATAREG              -WORKAREA ADDRESSING                     * 62100020
*       WORK6                -BUFFER ADDRESSING                       * 62130020
*       WORK2,WORK3          -WORK REGISTERS                          * 62160020
*                                                                     * 62190020
*   THIS ROUTINE IS CHARACTER CODE INDEPENDENT                        * 62220020
*                                                                     * 62250020
*********************************************************************** 62280020
         SPACE 2                                                        62310020
IKJEBEWB CSECT                                                          62340020
*   PERFORM THE INITIALIZATION OPERATIONS HERE                          62370020
         SAVE  (14,12),T,*             SAVE THE REGISTERS               62400020
         LA    SAVEREG,SAVEL(SAVEREG)  STEP TO NEXT SAVE AREA.          62430020
         LR    BASEREG,ENTRY           ENTRY POINT ADDRESS              62460020
         USING IKJEBEWB,BASEREG                                         62490020
         L     DATAREG,WORD1(PARMREG1) WORK AREA ADDRESS                62520020
         USING UTILWORK,DATAREG                                         62550020
         L     COMMREG,VTABLE          TABLE OF ROUTINE ADDRESSES       62580020
         USING VECTABLE,COMMREG                                         62610020
         SPACE 2                                                        62640020
*   WAIT ON PREVIOUS I/O BEFORE STARTING NEW I/O                        62670020
         L     WORK6,WORD2(PARMREG1)   BUFFER ADDRESS                   62700020
         USING BUFFER,WORK6                                             62730020
         TM    DCBSTATS,IO             ANY I/O IN PROGRESS              62760020
         BZ    WB3                     NO--DETERMINE TYPE OF OPERATION  62790020
WB1      MVC   PARM2(PTR),DCBBUFIO     BUFFER ADDRESS TO WAIT ON        62820020
         L     ENTRY,WA                ENTRY POINT ADDRESS              62850020
         CALL  (15)                    WAIT ON THAT BUFFER              62880020
         LTR   RETCDREG,RETCDREG       ANY ERRORS                       62910020
         BNZ   WB10                    YES-RETURN                       62940020
         ST    WORK6,PARM2             RESTORE INPUT BUFFER ADDRESS     62970020
         SPACE 2                                                        63000020
*   DETERMINE THE TYPE OF I/O OPERATION HERE                            63030020
WB3      TM    BUFSTATS,NEWBLK         IS THIS A NEW BLOCK              63060020
         BZ    WB2                     NO--USE XDAP WRITE               63090020
*                                      YES-USE BSAM WRITE               63120020
         SPACE 2                                                        63150020
*   WRITE OUT THE NEW BLOCK                                             63180020
         WRITE WRDECB,SF,UTILDCB,DATA,'S',,,MF=E                        63210020
         MVI   BUFSTATS,WAITB          INDICATE TO WAIT LATER ON        63240020
*                                        THE BSAM WRITE OPERATION       63270020
         SPACE 2                                                        63300020
*   PERFORM FINAL HOUSEKEEPING AND EXIT HERE                            63330020
WB11     SR    RETCDREG,RETCDREG       SET RETURN CODE = 0              63360020
         OI    DCBSTATS,IO             INDICATE I/O IN PROGRESS         63390020
         ST    WORK6,DCBBUFIO          ADDRESS OF BUFFER BEING WRITTEN  63420020
WB10     EQU   *                       RETURN HERE ON ERRORS            63450020
WB5      L     SAVEREG,WORD2(SAVEREG)  OLD SAVE AREA                    63480020
         RETURN (14,12),T,RC=(15)      RESTORE THE REGISTERS            63510020
         SPACE 2                                                        63540020
*   CONVERT TTR OF BLOCK TO ACTUAL TRACK ADDRESS                        63570020
WB2      L     PARMREG0,BUFTTR         TTR TO BE CONVERTED              63600020
         L     PARMREG1,DCBDEBAD       ADDRESS OF DEB                   63630020
         LA    WORK2,WBLKREF           ADDRESS TO RECEIVE MBBCCHHR      63660020
         LR    WORK3,DATAREG           SAVE ADDRESS FOR WORKAREA        63690020
         DROP  DATAREG                                                  63720020
         USING UTILWORK,WORK3                                           63750020
         STM   WORK9,SAVEREG,TEMPREGS  SAVE REGISTERS 9-13              63780020
         L     ENTRY,CVTPTR            ADDRESS OF CVT                   63810020
         USING CVT,ENTRY                                                63840020
         L     ENTRY,CVTPCNVT          ADDRESS OF CONVERT ROUTINE       63870020
         DROP  ENTRY                                                    63900020
         BALR  RETREG,ENTRY            CONVERT TTR TO MBBCCHHR          63930020
         LM    WORK9,SAVEREG,TEMPREGS  RESTORE REGISTERS 9-13           63960020
         DROP  WORK3                                                    63990020
         USING UTILWORK,DATAREG                                         64020020
         SPACE 2                                                        64050020
*   WRITE OUT THE BLOCK WITH AN XDAP-WRITE HERE                         64080020
         XDAP  XDAPWLST,WI,UTILDCB,DATA,,MF=E                           64110020
         MVI   BUFSTATS,WAITXW         SET WAIT FLAG FOR XDAP-WRITE     64140020
         B     WB11                    RETURN                           64170020
         SPACE 2                                                        64200020
         DROP  BASEREG,COMMREG,DATAREG,WORK6                            64230020
 TITLE 'EDIT COMMAND ACCESS METHOD --WRITE A RECORD --- IKJEBEWR'       64260020
*********************************************************************** 64290020
*                                                                     * 64380020
*STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                      * 64410020
*                                                                     * 64440020
*FUNCTION --  THIS ROUTINE IS CALLED TO PLACE NEW RECORDS IN THE      * 64470020
*   DATA SET.  A CHECK IS ALWAYS MADE TO SEE IF A RECORD EXISTS       * 64500020
*   WITH THE SAME KEY VALUE AS THE NEW INPUT RECORD.  IF A RECORD     * 64530020
*   EXISTS WITH THE SAME KEY VALUE, THE LENGTH OF THE OLD RECORD      * 64560020
*   IS CHECKED TO SEE IF THE NEW RECORD WILL FIT IN ITS PLACE. IF     * 64590020
*   THE OLD RECORD IS THE SAME SIZE OR LARGER, THE NEW RECORD         * 64620020
*   IS MOVED TO THE SAME POSITION AND NO DIRECTORY UPDATING IS        * 64650020
*   NECESSARY.                                                        * 64680020
*        IN THE EVENT THAT THE NEW RECORD IS LARGER, THE OLD RECORD   * 64710020
*   IS DELETED BY USING THE RECORD REMOVAL ROUTINE, IKJEBEDL.  THAT   * 64740020
*   BLOCK IS THEN CHECKED TO SEE IF THERE IS SPACE FOR THE NEW RECORD.* 64770020
*   ANYTIME A RECORD LOGICALLY BELONGS IN A BLOCK AND THERE IS        * 64800020
*   INSUFFICIENT SPACE, IT IS SPLIT INTO TWO DATA BLOCKS.             * 64830020
*        IF THE KEY OF THE INPUT RECORD IS UNIQUE, THE NEW INPUT      * 64860020
*   RECORD MUST BE INSERTED IN THE DATA BLOCK WHERE IT LOGICALLY      * 64890020
*   BELONGS.  AGAIN, AS IN THE ABOVE CASE, THE DATA BLOCK MAY BE      * 64920020
*   REQUIRED TO BE SPLIT INTO TWO DATA BLOCKS.                        * 64950020
*        WHENEVER A NEW RECORD BECOMES THE LAST LOGICAL RECORD OF     * 64980020
*   A DATA BLOCK OR DATA BLOCKS ARE SPLIT, THE DIRECTORY IS UPDATED   * 65010020
*   BY CALLING THE DIRECTORY UPDATE ROUTINE, IKJEBEDU.                * 65040020
*        ANYTIME A BUFFER IS MODIFIED, ITS 'UPDATE' FLAG WILL BE      * 65070020
*   TURNED ON SO THAT THEY GET WRITTEN OUT, IF NECESSARY              * 65100020
*                                                                     * 65130020
*ENTRY POINT --                                                       * 65160020
*       IKJEBEWR             -VIA A CALL FROM IKJEBEUT                * 65190020
*                                                                     * 65220020
*INPUT --  REGISTER 1 POINTS TO A THREE WORD PARAMETER LIST           * 65250020
*       WORD1-   ADDRESS OF THE WORKAREA                              * 65280020
*       WORD2-   ADDRESS OF NEW RECORD TO BE PLACED IN DATA SET       * 65310020
*       WORD3-   NOT USED                                             * 65340020
*                                                                     * 65370020
*OUTPUT --  THE SPECIFIED RECORD HAS BEEN PLACED IN THE DATA SET      * 65400020
*   THE REGISTERS ARE DESCRIBED UNDER 'EXIT' BELOW.                   * 65430020
*                                                                     * 65460020
*EXTERNAL REFERENCES --                                               * 65490020
*       IKJEBELO             -CHECK IF RECORD EXISTS                  * 65520020
*       IKJEBEDL             -DELETE THE OLD RECORD                   * 65550020
*       IKJEBEDU             -UPDATE THE DIRECTORY                    * 65580020
*       IKJEBEAD             -DETERMINE TTR FOR NEW BLOCK             * 65610020
*       IKJEBEMV             -MOVES DATA OR CONTROL INFORMATION       * 65670020
*       IKJEBEWB             -WRITE OUT DATA BLOCKS                   * 65700020
*                                                                     * 65730020
*EXITS,NORMAL --  OUTPUT AS DESCRIBED ABOVE.  REGISTER 15 CONTAINS    * 65760020
*   A RETURN CODE OF 0.                                               * 65790020
*                                                                     * 65820020
*EXITS,ERROR --  RETURNS TO THE CALLING ROUTINE WITH A RETURN CODE    * 65850020
*   OF 12.                                                            * 65880020
*                                                                     * 65910020
*TABLES/WORK AREAS --                                                 * 65940020
*       DEPENDENT ON THE VECTOR TABLE FOR EXTERNAL REFERENCES.        * 65970020
*                                                                     * 66000020
*ATTRIBUTES -- REFRESHABLE, NON-PRIVILEGED, ENABLED                   * 66030020
*                                                                     * 66060020
*NOTES --  REGISTER CONVENTIONS AREAS FOLLOWS-                        * 66090020
*       BASEREG              -BASE REGISTER                           * 66120020
*       COMMREG              -VECTOR TABLE ADDRESSING                 * 66150020
*       DATAREG              -WORK AREA ADDRESSING                    * 66180020
*       WORK6                -BUFFER ADDRESSING, OLD BLOCKS           * 66210020
*       WORK7                -BUFFER ADDRESSING, NEW BLOCKS           * 66240020
*       WORK2                -INPUT RECORD ADDRESS                    * 66270020
*       WORK3,WORK4,WORK5    -WORK REGISTERS                          * 66300020
*       LINK9                -INTERNAL SUBROUTINE LINKAGE             * 66330020
*                                                                     * 66360020
*   THIS SUBROUTINE IS CHARACTER CODE INDEPENDENT                     * 66390020
*                                                                     * 66420020
*********************************************************************** 66450020
         SPACE 2                                                        66480020
IKJEBEWR CSECT                                                          66510020
         SPACE                                                          66520021
*A676900                                                         A45115 66530021
*C680470                                                         A45115 66532021
*D680400,680610                                                  A45115 66534021
         SPACE                                                          66536021
*   PERFORM THE INITIALIZATION OPERATIONS HERE                          66540020
         SAVE  (14,12),T,*             SAVE THE REGISTERS               66570020
         LR    BASEREG,ENTRY           ENTRY POINT ADDRESS              66600020
         USING IKJEBEWR,BASEREG                                         66630020
         L     DATAREG,WORD1(PARMREG1) WORKAREA ADDRESS                 66660020
         USING UTILWORK,DATAREG                                         66690020
         L     COMMREG,VTABLE          TABLE OF ROUTINE ADDRESSES       66720020
         USING VECTABLE,COMMREG                                         66750020
         LA    WORK5,SAVEAREA          NEW SAVE AREA                    66780020
         ST    SAVEREG,WORD2(WORK5)    OLD ADDRESS TO NEW               66810020
         ST    WORK5,WORD3(SAVEREG)    NEW ADDRESS TO OLD               66840020
         LR    SAVEREG,WORK5           NEW SAVE AREA                    66870020
         SPACE 2                                                        66900020
*   CHECK IF THE RECORD EXISTS                                          66930020
         L     WORK2,WORD2(PARMREG1)   ADDRESS OF RECORD                66960020
WR1      LA    PARMREG1,PARM1          PARM LIST ADDRESS                66990020
         LA    DATAREG,X0(DATAREG)     SET OPTION CODE =0               67020020
         ST    DATAREG,PARM1           CODE AND WORKAREA ADDRESS        67050020
         MVC   PRIMEKEY(KEYL),X0(WORK2) KEY VALUE OF RECORD TO WRITE    67080020
         L     ENTRY,LO                ENTRY POINT ADDRESS              67110020
         CALL  (15)                    CHECK IF RECORD EXISTS           67140020
         TM    DCBSTATS,ERROR          WAS THERE AN I/O ERROR           67170020
         BO    WR25                    YES-RETURN                       67200020
         LTR   RETCDREG,RETCDREG       DOES THE RECORD EXIST            67230020
         BNZ   WR7                     NO--                             67260020
*                                      YES-THERE WAS A PREVIOUS RECORD  67290020
*                                        WITH THE SAME KEY VALUE        67320020
*  YES-THE RECORD DOES EXIST//COMPARE NEW LENGTH TO OLD                 67350020
         L     WORK6,WORD2(PARMREG1)   BUFFER ADDRESS WITH RECORD       67380020
         USING BUFFER,WORK6                                             67410020
         L     WORK5,BUFREF            RECORD LOCATOR ADDRESS           67440020
         LH    WORK5,X0(WORK5)         LOCATOR CONTENTS                 67470020
         LA    WORK5,DATA(WORK5)       RECORD ADDRESS                   67500020
         CLC   KEYL(L2,WORK2),KEYL(WORK5) IS NEW RECORD SHORTER OR =    67530020
         BH    WR2                     NO--MUST DELETE OLD RECORD       67560020
*                                      YES-CAN PLACE NEW RECORD IN      67590020
         SPACE 2                                                        67620020
*   PLACE NEW RECORD IN THE DATA BLOCK HERE                             67650020
         ST    WORK2,TEMP1             NEW RECORD ADDRESS               67680020
         ST    WORK5,TEMP2             OLD RECORD ADDRESS               67710020
         MVC   TEMP3(L2),KEYL(WORK2)   LENGTH OF NEW RECORD-MINUS KEY   67740020
         LH    PARMREG1,TEMP3          LENGTH OF RECORD                 67770020
         LA    PARMREG1,KEYL(PARMREG1) ACCOUNT FOR KEY LENGTH           67800020
         LR    PARMREG0,PARMREG1       TOTAL LENGTH OF RECORD           67830020
         LA    PARMREG1,TEMP1          PARM LIST ADDRESS                67860020
         L     ENTRY,MV                ENTRY POINT ADDRESS              67890020
         CALL  (15)                    PUT NEW RECORD IN DB             67920020
         OI    BUFSTATS,UPDATED        INDICATE BUFFER MODIFIED         67950020
         B     WR32                    EXIT, RECORD COUNT SAME   A45115 67960021
         SPACE 2                                                        67980020
*   FINAL PROCESSING AND EXIT HERE                                      68010020
WR3      L     WORK4,DCBRECNO          GET PREVIOUS RECORD COUNT A45115 68047021
         LA    WORK4,ONE(WORK4)        UP RECORD COUNT BY ONE           68054020
         ST    WORK4,DCBRECNO          STORE NEW COUNT                  68061020
WR32     SR    RETCDREG,RETCDREG       SET RETURN CODE = 0       A45115 68063021
WR25     EQU   *                       RETURN HERE ON I/O ERRORS        68070020
         L     SAVEREG,WORD2(SAVEREG)  OLD SAVE AREA                    68100020
         RETURN (14,12),T,RC=(15)      RESTORE THE REGISTERS            68130020
         SPACE 2                                                        68160020
*   DELETE THE OLD RECORD HERE                                          68190020
WR2      ST    WORK6,PARM2             BUFFER ADDRESS                   68220020
         L     ENTRY,DL                ENTRY POINT ADDRESS              68250020
         CALL  (15)                    DELETE THE OLD RECORD            68280020
         TM    DCBSTATS,ERROR          ANY I/O ERRORS                   68310020
         BO    WR25                    YES-RETURN                       68340020
         B     WR1                     GO FIND THE CORRECT BUFFER NOW   68370020
         SPACE 2                                                        68400020
*   CHECK IF ANY RECORDS IN THE DATA SET                                68430020
WR7      XC    SECONKEY(KEYL+KEYL),SECONKEY  CLEAR TO ZERO              68460020
         XC    THIRDKEY(L'THIRDKEY),THIRDKEY CLEAR TO ZERO              68490020
         CH    RETCDREG,WREMPTY        IS THE DATA SET EMPTY            68520020
         BNE   WR12                    NO--GO CHECK SPACE               68550020
         OI    DCBSTATS,DSEMPTY        YES-REMEMBER EMPTY STATUS        68580020
         SPACE 2                                                        68610020
*   ASSIGN A NEW BLOCK AND BUFFER                                       68640020
WR22     L     ENTRY,AD                ENTRY POINT ADDRESS              68670020
         CALL  (15)                    GET BUFFER FOR NEW BLOCK         68700020
         LTR   RETCDREG,RETCDREG       ANY I/O ERRORS                   68730020
         BNZ   WR25                    YES-RETURN                       68760020
         L     WORK7,WORD2(PARMREG1)   NEW BUFFER ADDRESS               68790020
         USING NEWBUF,WORK7                                             68820020
         XC    NUMBER(CTRLEND-DATA),NUMBER CLEAR CONTROL FIELDS         68850020
         LA    WORK5,BLKSIZE           OFFSET TO END OF BUFFER BLOCK    68880020
         STH   WORK5,DATBEGIN          INITIALIZE RECORD OFFSET FIELD   68910020
         OI    NEWSTATS,UPDATED        SET BUFFER FLAG                  68940020
         TM    DCBSTATS,DSEMPTY        THIS AN EMPTY DATA SET           68970020
         BO    WR110                   YES-GO PUT RECORD IN NEW BLOCK   69000020
         SPACE 2                                                        69030020
*   CHECK IF THIS DATA BLOCK MUST BE SPLIT                              69060020
         TM    DCBSTATS,SPLIT          MUST OLD BLOCK BE SPLIT          69090020
         BO    WR8                     YES--GO SPLIT BLOCK              69120020
         MVC   THIRDKEY(KEYL),X0(WORK2) KEY FOR NEW BLOCK               69150020
         MVC   THIRDKEY+KEYL(TTR),NEWTTR TTR FOR THIS BLOCK             69180020
         B     WR110                   GO PUT RECORD IN NEW BLOCK       69210020
         SPACE 2                                                        69240020
*   SPLIT THE DATA BLOCK HERE                                           69270020
WR8      NI    BUFSTATS,ALL-BLKINBUF   INDICATE BUFFER OBTAINED         69300020
         LH    WORK3,NUMREC            TOTAL NUMBER OF RECORDS          69330020
         LR    WORK4,WORK3             SAVE THE TOTAL                   69360020
         SRA   WORK4,ONE               DIVIDE BY TWO                    69390020
         SR    WORK3,WORK4             NUMREC-NUMREC/2                  69420020
         STH   WORK4,NUMBER            NO. OF RECORDS IN NEW DB         69450020
         STH   WORK3,NUMREC            NO. OF RECORDS TO REMAIN IN OLD  69480020
         LA    WORK5,NEWLOCAT          1ST LOCATOR//NEW BLOCK           69510020
         ST    WORK5,NEWBUREF          SAVE IN BUFREF SLOT              69540020
         LA    WORK5,LOCATORS          1ST LOCATOR//OLD BLOCK           69570020
         ST    WORK5,BUFREF            SAVE IN BUFREF SLOT              69600020
         LR    WORK9,WORK4             LOOP CONTROL                     69630020
         SPACE 2                                                        69660020
*   MOVE FIRST HALF OF LOGICAL RECORDS TO NEW DATA BLOCK                69690020
WR81     L     WORK5,BUFREF            CURRENT LOCATOR ADDRESS          69720020
         LH    WORK4,X0(WORK5)         CONTENTS OF LOCATOR              69750020
         LA    WORK8,DATA(WORK4)       RECORD ADDRESS                   69780020
         LA    WORK5,LOCL(WORK5)       NEXT LOCATOR ADDRESS             69810020
         ST    WORK5,BUFREF            SAVE FOR NEXT PASS               69840020
         MVC   TEMP1(L2),KEYL(WORK8)   LENGTH OF RECORD                 69870020
         LH    WORK4,TEMP1             LENGTH OF RECORD                 69900020
         ST    WORK8,TEMP1             MOVE-FROM ADDRESS                69930020
         LA    WORK4,KEYL(WORK4)       ACCOUNT FOR KEY FIELD LENGTH     69960020
         LH    PARMREG1,DATBEGIN       LAST FILLED SLOT//NEW BLOCK      69990020
         SR    PARMREG1,WORK4          LESS LENGTH OF THIS RECORD       70020020
         STH   PARMREG1,DATBEGIN       OFFSET TO 1ST PHYSICAL RECORD    70050020
         L     WORK5,NEWBUREF          CURRENT LOCATOR ADDRESS          70080020
         STH   PARMREG1,X0(WORK5)      INSERT LOCATOR IN BLOCK          70110020
         LA    WORK5,LOCL(WORK5)       ADDRESS FOR NEXT LOCATOR         70140020
         ST    WORK5,NEWBUREF          SAVE FOR NEXT RECORD             70170020
         LA    PARMREG1,NEWDATA(PARMREG1)  MOVE-TO ADDRESS              70200020
         ST    PARMREG1,TEMP2          STORE IN PARM LIST               70230020
         LA    PARMREG1,TEMP1          PARM LIST ADDRESS                70260020
         LR    PARMREG0,WORK4          SET LENGTH PARAMETER             70290020
         L     ENTRY,MV                ENTRY POINT ADDRESS              70320020
         CALL  (15)                    MOVE RECORD FROM OLD DB TO NEW   70350020
         BCT   WORK9,WR81              REPEAT UNTIL ALL RECORDS MOVED   70380020
         B     WR83                    GO REORGANIZE THE BLOCK          70410020
          SPACE 2                                                       70440020
*   RE-ORGANIZE THE OLD DATA BLOCK HERE                                 70470020
WR82     OI    DCBSTATS,REORG          REORGANIZE ONLY, NO SPLIT        70500020
         LA    WORK9,LOCATORS          INITIALIZE BUFREF TO ADDRESS     70510020
         ST    WORK9,BUFREF              OF FIRST LOCATOR               70520020
WR83     ST    WORK2,TEMP3             SAVE ADDRESS OF NEW RECORD       70530020
         DROP  WORK7                                                    70560020
         L     WORK8,DCBWRKAD          ADDRESS OF AVAILABLE BUFFER      70590020
         USING NEWBUF,WORK8                                             70620020
         XC    NUMBER(CTRLEND-DATA),NUMBER CLEAR CONTROL FIELDS         70650020
         MVC   NEWBUF(DATA-BUFFER),BUFFER CONTROL FIELDS TO NEW BUFFER  70680020
         LA    WORK5,BLKSIZE           INITIALIZE FOR OFFSET TO 1ST     70710020
         STH   WORK5,DATBEGIN            RECORD IN BLOCK                70740020
         LH    WORK9,NUMREC            NUMBER OF RECORDS                70770020
         STH   WORK9,NUMBER            PLACE IN NEW BUFFER              70800020
         LA    WORK3,NEWLOCAT          NEW LOCATOR ADDRESS              70830020
         L     WORK2,BUFREF            ADDRESS OF 1ST LOCATOR REMAINING 70860020
         SPACE 2                                                        70890020
*   LOOP UNTIL ALL LOCATORS AND RECORDS MOVED                           70920020
WR9      LH    WORK5,X0(WORK2)         CONTENTS OF LOCATOR              70950020
         LA    WORK5,DATA(WORK5)       RECORD ADDRESS IN OLD BLOCK      70980020
         LH    WORK4,DATBEGIN          OFFSET TO 1ST PHYSICAL RECORD    71010020
         MVC   TEMP1(L2),KEYL(WORK5)   LENGTH OF RECORD                 71040020
         LH    PARMREG1,TEMP1          LENGTH OF RECORD                 71070020
         LA    PARMREG1,KEYL(PARMREG1) ACCOUNT FOR KEY LENGTH           71100020
         SR    WORK4,PARMREG1          NEW OFFSET                       71130020
         STH   WORK4,DATBEGIN          UPDATE BUFFER FIELD              71160020
         STH   WORK4,X0(WORK3)         LOCATOR TO NEW BUFFER            71190020
         LA    WORK4,NEWDATA(WORK4)    MOVE-TO ADDRESS                  71220020
         ST    WORK4,TEMP2             PLACE IN PARM LIST               71250020
         ST    WORK5,TEMP1             MOVE FROM ADDRESS/PARM LIST      71280020
         LR    PARMREG0,PARMREG1       LENGTH OF RECORD                 71310020
         LA    PARMREG1,TEMP1          PARAMETER LIST ADDRESS           71340020
         L     ENTRY,MV                ENTRY POINT ADDRESS              71370020
         CALL  (15)                    PLACE RECORD IN BLOCK            71400020
         LA    WORK3,LOCL(WORK3)       ADDRESS FOR NEXT LOCATOR         71430020
         LA    WORK2,LOCL(WORK2)       ADDRESS NEXT OLD LOCATOR         71460020
         BCT   WORK9,WR9               LOOP UNTIL ALL MOVED             71490020
         SPACE 2                                                        71520020
*   PLACE THIS NEW BUFFER IN THE CHAIN                                  71550020
         L     PARMREG1,NBKCHAIN       PREVIOUS BUFFER IN CHAIN         71580020
         ST    WORK8,BUFCHAIN-BUFFER(PARMREG1) NEW ADDRESS TO PREVIOUS  71610020
         L     PARMREG1,NEWCHAIN       PREVIOUS FORWARD CHAIN           71640020
         LTR   PARMREG1,PARMREG1       MORE BUFFERS IN CHAIN            71670020
         BZ    WR91                    NO--CHAIN IS OK                  71700020
         ST    WORK8,TEMP1             ADDRESS OF NEW BUFFER TO         71730020
         MVC   NBKCHAIN+ONE-NEWBUF(L3,PARMREG1),TEMP1+ONE  NEXT BUFFER  71760020
         SPACE                                                          71790020
WR91     ST    WORK6,DCBWRKAD          OLD BUFFER BECOMES SPARE         71820020
         OI    NEWSTATS,UPDATED        INDICATE BUFFER CHANGED/UPDATED  71850020
         LR    WORK6,WORK8             CORRECT ADDRESS FOR THIS         71880020
         DROP  WORK8                     REORGANIZED OLD BLOCK          71910020
         USING NEWBUF,WORK7                                             71940020
         L     WORK2,TEMP3             RESTORE NEW RECORD ADDRESS       71970020
         TM    DCBSTATS,REORG          WAS BLOCK RE-ORDERED ONLY        72000020
         BO    WR11                    YES-GO PLACE RECORD IN BLOCK     72030020
         SPACE 2                                                        72060020
*   FIND  LAST LOCATOR IN NEW BLOCK                                     72090020
         LH    WORK5,NUMBER            NUMBER OF RECORDS//THIS DB       72120020
         SLL   WORK5,ONE               TIMES TWO                        72150020
         LH    WORK5,NEWLOCAT-LOCL(WORK5) CONTENTS OF LOCATOR           72180020
         LA    WORK5,NEWDATA(WORK5)    RECORD ADDRESS                   72210020
         MVC   THIRDKEY(KEYL),X0(WORK5)  LAST KEY, NEW BLOCK            72240020
         MVC   THIRDKEY+KEYL(TTR),NEWTTR TTR FOR THIS BLOCK             72270020
         CLC   X0(KEYL,WORK2),X0(WORK5)  DOES KEY OF NEW RECORD FIT IN  72300020
*                                        NEW BLOCK                      72330020
         BH    WR6                     NO--MOVE RECORD INTO OLD BLOCK   72360020
         SPACE 2                                                        72390020
*   WRITE OUT THE OLD BLOCK HERE                                        72420020
         ST    WORK6,PARM2             BUFFER ADDRESS                   72450020
         ST    DATAREG,PARM1           WORKAREA ADDRESS                 72480020
         LA    PARMREG1,PARM           PARM LIST ADDRESS                72510020
         L     ENTRY,WB                ENTRY POINT ADDRESS              72540020
         CALL  (15)                    WRITE OUT THE OLD BLOCK          72570020
         LTR   RETCDREG,RETCDREG       ANY ERRORS                       72600020
         BNZ   WR25                    YES--RETURN                      72630020
WR10     XC    SECONKEY(KEYL),SECONKEY INDICATE PROCESSING OF OLD DB    72660020
*                                        IS COMPLETE                    72690020
WR110    LR    WORK6,WORK7             SET UP ADDRESSING OF THIS NEW DB 72720020
         B     WR15                    GO PLACE THE RECORD IN BUFFER    72750020
         SPACE 2                                                        72780020
*   THE OLD DATA BLOCK HAS BEEN RE-ORDERED                              72810020
WR11     NI    DCBSTATS,ALL-REORG      INDICATE BLOCK WAS REORDERED     72840020
         XC    RECVSP(L2),RECVSP       EMPTY SPACE IN NOW ZERO          72870020
         B     WR121                   GO RECHECK SPACE                 72900020
         SPACE 2                                                        72930020
*   CHECK IF SPACE IS AVAILABLE IN DATA BLOCK                           72960020
WR12     L     WORK6,WORD2(PARMREG1)   ADDRESS OF DESIRED DATA BLOCK    72990020
WR121    LH    WORK3,NUMREC            NUMBER OF RECORDS                73020020
         LA    WORK3,CTRLEND-DATA+LOCL+KEYL(WORK3,WORK3)   PLUS THE     73050020
*                                      BLOCK AND RECORD OVERHEAD        73080020
         LH    WORK4,DATASTRT          DISPLACEMENT FIRST PHYSICAL TO   73110020
*                                        RECORD                         73140020
         SR    WORK4,WORK3             WORK4= AVAILABLE SPACE           73170020
         CH    WORK4,KEYL(WORK2)       IS SPACE AVAILABLE FOR THE       73200020
*                                        NEW RECORD                     73230020
         BNL   WR6                     YES- GO PLACE RECORD IN BLOCK    73260020
         SPACE 2                                                        73290020
*   DETERMINE IF NEW BLOCK REQUIRED OR OLD MUST BE SPLIT OR RE-ORDERED  73320020
WR13     LH    WORK3,NUMREC            NUMBER OF RECORDS                73350020
         SLL   WORK3,ONE               TIMES 2                          73380020
         LH    WORK3,LOCATORS-LOCL(WORK3)  CONTENTS LAST LOCATOR        73410020
         LA    WORK3,DATA(WORK3)       ADDRESS OF LAST RECORD           73440020
         CLC   X0(KEYL,WORK2),X0(WORK3) COMPARE NEW KEY TO LAST OLD     73470020
         BH    WR22                    NO SPLIT NECESSARY               73500020
         LH    WORK3,KEYL(WORK2)       LENGTH OF NEW RECORD             73530020
         LA    WORK3,KEYL(WORK3)       ACCOUNT FOR KEY LENGTH           73560020
         AH    WORK4,RECVSP            AVAILABLE SPACE PLUS             73590020
*                                        RECOVERABLE SPACE              73620020
         CR    WORK3,WORK4             ENOUGH SPACE TO REORDER BLOCK    73650020
         BNH   WR82                    YES-GO RE-ORDER THIS BLOCK       73680020
         LH    WORK3,LOCATORS          CONTENTS OF 1ST LOCATOR          73710020
         LA    WORK3,DATA(WORK3)       FIRST LOGICAL RECORD ADDRESS     73740020
         CLC   X0(KEYL,WORK2),X0(WORK3) IS NEW KEY LESS THAN 1ST        73770020
*                                       LOGICAL RECORD IN THIS DB.      73800020
         BL    WR22                    YES-GO ASSIGN A NEW BLOCK        73830020
WR14     OI    DCBSTATS,SPLIT          INDICATE BLOCK MUST SPLIT        73860020
         OI    BUFSTATS,BLKINBUF       KEEP THIS BUFFER IN CORE         73890020
         B     WR22                    GO GET ANOTHER BLOCK             73920020
         SPACE                                                          73950020
*   SAVE THE KEY OF THE LAST RECORD IN THE DATA BLOCK                   73980020
WR6      LH    WORK3,NUMREC            NUMBER OF RECORDS                74010020
         SLL   WORK3,ONE               TIMES TWO                        74040020
         LH    WORK3,LOCATORS-LOCL(WORK3)  CONTENTS OF LAST LOCATOR     74070020
         LA    WORK3,DATA(WORK3)       ADDRESS OF LAST RECORD           74100020
         MVC   SECONKEY(KEYL),X0(WORK3) SAVE LAST KEY IN THIS BLOCK     74130020
         MVC   SECONKEY+KEYL(TTR),BUFTTR TTR OF THIS BLOCK              74160020
         SPACE 2                                                        74190020
*   MOVES THE NEW RECORD INTO THE PROPER DATA BLOCK                     74220020
WR15     LH    WORK5,DATASTRT          OFFSET TO 1ST PHYSICAL RECORD    74250020
         MVC   TEMP1(L2),KEYL(WORK2)   LENGTH OF RECORD                 74280020
         LH    PARMREG1,TEMP1          LENGTH OF RECORD                 74310020
         LA    PARMREG1,KEYL(PARMREG1) ACCOUNT FOR KEY FIELD            74340020
         SR    WORK5,PARMREG1          NEW OFFSET TO 1ST RECORD         74370020
         STH   WORK5,DATASTRT          SAVE IN BLOCK                    74400020
         LA    WORK5,DATA(WORK5)       ACTUAL RECORD ADDRESS            74430020
         ST    WORK5,TEMP2             MOVE-TO ADDRESS                  74460020
         ST    WORK2,TEMP1             MOVE-FROM ADDRESS                74490020
         LR    PARMREG0,PARMREG1       TOTAL LENGTH OF RECORD           74520020
         LA    PARMREG1,TEMP1          PARM LIST ADDRESS                74550020
         L     ENTRY,MV                ENTRY POINT ADDRESS              74580020
         CALL  (15)                    PLACE NEW RECORD IN BLOCK        74610020
         SPACE 2                                                        74640020
*  UPDATE THE BUFFER CONTROL FIELDS                                     74670020
         OI    BUFSTATS,UPDATED        INSURE UPDATE SWITCH IS ON       74700020
         LH    WORK4,NUMREC            PREVIOUS RECORD COUNT            74730020
         LA    WORK4,ONE(WORK4)        PLUS THIS NEW RECORD             74760020
         STH   WORK4,NUMREC            SAVE NEW RECORD COUNT            74790020
         LR    WORK5,WORK4             TOTAL RECORDS                    74820020
         SLA   WORK5,ONE               TOTAL RECORDS TIMES TWO          74850020
         SPACE 2                                                        74880020
*   PLACE NEW RECORD LOCATOR IN BLOCK                                   74910020
WR30     LA    WORK4,LOCATORS-LOCL-LOCL(WORK5) ADDRESS OF LAST OLD      74940020
         BCTR  WORK5,ZERO              RESET INDEX FOR PREVIOUS         74970020
         BCTR  WORK5,ZERO                LOCATOR ON NEXT PASS           75000020
         LTR   WORK5,WORK5             IS THIS THE LAST LOCATOR         75030020
         BZ    WR31                    YES-LAST LOCATOR FOUND           75060020
         MVC   LOCL(LOCL,WORK4),X0(WORK4) MOVE LOCATOR UP               75090020
         LH    WORK3,X0(WORK4)         LOCATOR CONTENTS                 75120020
         LA    WORK3,DATA(WORK3)       RECORD ADDRESS                   75150020
         CLC   PRIMEKEY(KEYL),X0(WORK3) COMPARE NEW KEY VERSUS EACH OLD 75180020
         BL    WR30                    REPEAT LOOP UNTIL FOUND          75210020
WR31     MVC   LOCL(LOCL,WORK4),DATASTRT  SET NEW RECORD LOCATOR        75240020
         SPACE 2                                                        75270020
*   WAS THE DATA SET PREVIOUSLY EMPTY                                   75300020
         TM    DCBSTATS,DSEMPTY        WAS THIS AN EMPTY DATA SET       75330020
         BO    WR16                    YES--GO SET UP DSDB              75360020
         OC    THIRDKEY(KEYL+TTR),THIRDKEY  WAS THERE A BLOCK SPLIT OR  75390020
*                                             NEW BLOCK ADDED           75420020
         BNZ   WR17                    YES-UPDATE DSDB FOR NEW BLOCK    75450020
WR21     OC    SECONKEY(KEYL+TTR),SECONKEY  ZERO IF OLD BLOCK DID NOT   75480020
*                                             GET NEW RECORD            75510020
         BZ    WR20                    DIRECTORY IS OKAY--RETURN        75540020
         SPACE                                                          75570020
WR18     CLC   PRIMEKEY(KEYL),SECONKEY WAS THIS LAST RECORD OF OLD DB   75600020
         BNH   WR20                    DIRECTORY UPDATE OKAY--RETURN    75630020
         MVC   SECONKEY(KEYL),PRIMEKEY NEW HIGH KEY                     75660020
         SPACE 2                                                        75690020
*   UPDATE DIRECTORY FOR OLD BLOCK                                      75720020
WR19     LA    WORK3,SECONKEY          KEY VALUE OF LAST RECORD         75750020
         ST    WORK3,PARM2             STORE IN PARM LIST               75780020
         MVC   PARM3(TTR),SECONKEY+KEYL TTR OF BUFFER                   75810020
         BAL   LINK9,WR100             GO UPDATE THE DIRECTORY          75840020
WR20     NI    DCBSTATS,ALL-DSEMPTY-SPLIT  TURN OFF CONTROL SWITCHES    75870020
         XC    SECONKEY(KEYL+KEYL),SECONKEY CLEAR CONTROL FIELDS        75900020
         B     WR3                     GO EXIT THIS ROUTINE             75930020
         SPACE 2                                                        75960020
*   SET UP THE DSDB FOR PREVIOUSLY EMPTY DATA SET                       75990020
WR16     LA    WORK3,PRIMEKEY          KEY VALUE FOR DB OF EMPTY DS     76020020
         ST    WORK3,PARM2             STORE IN PARM LIST               76050020
         MVC   PARM3(L4),BUFTTR        TTR OF BUFFER                    76080020
         BAL   LINK9,WR100             UPDATE THE DIRECTORY             76110020
         B     WR20                    RETURN                           76140020
         SPACE 2                                                        76170020
*   UPDATE DIRECTORY FOR NEW BLOCK                                      76200020
WR17     LA    WORK3,THIRDKEY          KEY OF NEW BLOCK                 76230020
         ST    WORK3,PARM2             STORE IN PARM LIST               76260020
         MVC   PARM3(TTR),THIRDKEY+KEYL TTR OF BUFFER                   76290020
         BAL   LINK9,WR100             UPDATE THE DIRECTORY             76320020
         B     WR21                    CHECK IF OLD BLOCK WAS UPDATED   76350020
         SPACE 2                                                        76380020
*   LINKAGE FOR THE DIRECTORY UPDATE ROUTINE HERE                       76410020
WR100    ST    DATAREG,PARM1           WORK AREA ADDRESS                76440020
         LA    PARMREG1,PARM1          PARM LIST ADDRESS                76470020
         L     ENTRY,DU                ENTRY POINT ADDRESS              76500020
         CALL  (15)                    UPDATE THE DIRECTORY             76530020
         LTR   RETCDREG,RETCDREG       ANY ERRORS                       76560020
         BNZ   WR25                    YES-RETURN                       76590020
         BR    LINK9                   RETURN TO CALLER                 76620020
         SPACE 2                                                        76650020
*   CONSTANT AREA FOR IKJEBEWR                                          76680020
WREMPTY  DC    H'8'                    COMPARE CONSTANT //EMPTY DS      76710020
         EJECT                                                          76740020
*********************************************************************** 76770020
         IKJEBEUW                                                       76800020
         EJECT                                                          76830020
CVT      DSECT                                                          76860020
         CVT   SYS=MVT                                                  76890020
*********************************************************************** 76920020
         END                                                            76950020
