BEAE     TITLE 'IKJEBEAE - STAE EXIT ROUTINE - EDIT CP TSO/360'         00400020
IKJEBEAE CSECT                                                          00800020
         ENTRY IKJEBEAE                                                 01200020
         EXTRN IKJEBMA2                                                 01400020
         EJECT                                                          01450020
*********************************************************************** 01600020
*                                                                     * 02000020
* STATUS -- VERSION NO. 01 - OS/360 RELEASE NO. 20                    * 03600020
*                                                                     * 04800020
* FUNCTION -- IKJEBEAE GAINS CONTROL WHENEVER THE EDIT TASK ABENDS.   * 05200020
*    ITS PRIMARY FUNCTION IS TO KEEP THE TASK FROM GOING THROUGH      * 05600020
*    ABEND PROCESSING.  IKJEBEAE CALLS IKJEBEMS TO PUT A MESSAGE TO   * 06000020
*    THE USER TO INFORM HIM OF THE ABEND SITUATION.  IKJEBEAE WILL    * 06400020
*    ALWAYS SPECIFY A RETRY ADDRESS AND RETURN CONTROL TO THE MAIN    * 06800020
*    CONTROLLER.                                                      * 07200020
*                                                                     * 07600020
* ENTRY POINTS --                                                     * 08000020
*         IKJEBEAE  - AFTER GAINING CONTROL FROM THE ABEND/STAE       * 08010020
*                     INTERFACE ROUTINE.                              * 08400020
*                                                                     * 08800020
* INPUT -- REGISTER 0 CONTAINS AN ENTRY CODE.  ENTRY CODES ARE --     * 09200020
*    0, 4, 8 A STAE WORK AREA PROVIDED, 12 NO WORK AREA PROVIDED.     * 09600020
*    REGISTER 1 CONTAINS THE ADDRESS OF THE STAE WORK AREA, WHEN      * 10000020
*    PROVIDED.                                                        * 10400020
*                                                                     * 10800020
* OUTPUT -- REGISTER 15 CONTAINS A RETURN CODE.  RETURN CODES ARE --  * 11200020
*    0 RETURN TO ABEND PROCESSING, OR 4 PASS CONTROL TO THE RETRY     * 11600020
*    ROUTINE WHOSE ADDRESS IS SPECIFIED IN REGISTER 0.                * 12000020
*                                                                     * 12400020
* EXTERNAL REFERENCES --                                              * 12800020
*                                                                     * 13200020
*         IKJEBEMS - EDIT MESSAGE SELECTION ROUTINE.                  * 13600020
*                                                                     * 14000020
*    MACROS USED --                                                   * 14050020
*         SAVE     - SAVE ENTRY REGISTERS.                            * 14100020
*         IKJEBEML - CALL IKJEBEMS                                    * 15600020
*         IKJEBEMG - PARAMETER LIST FOR PUTLINE INSERTIONS            * 16000020
*         IKJEBECA - EDIT COMMUNICATION AREA                          * 16400020
*         IKJEBEMI - SYMBOLIC REFERENCES TO EDIT MESSAGES             * 16800020
*                                                                     * 17200020
* EXITS,NORMAL -- TO ABEND/STAE INTERFACE ROUTINE WITH A RETURN CODE  * 17600020
*    IN REGISTER 15.                                                  * 18000020
*                                                                     * 18400020
* EXITS,ERROR -- NONE.                                                * 18800020
*                                                                     * 19200020
* TABLES/WORK AREAS --                                                * 19600020
*                                                                     * 20000020
*    THE EDIT COMMUNICATION AREA CONTAINS THE ADDRESS OF THE RETRY    * 20400020
*    ROUTINE.                                                         * 20800020
*                                                                     * 21200020
* ATTRIBUTES -- REFRESHABLE, ENABLED, NON-PRIVILEGED, RE-ENTRANT.     * 21600020
*                                                                     * 22000020
* CHARACTER CODE DEPENDENCY -- THIS ROUTINE IS CHARACTER CODE         * 22050020
*    DEPENDENT.                                                       * 22100020
*                                                                     * 22150020
* NOTES -- THIS ROUTINE ASSUMES THAT THE SAVE AREA USED INITIALLY     * 22400020
*    BY IKJEBEMA IS AT CASVAREA.  ALL OTHER SAVE AREAS IN             * 22450020
*    CASVAREA, OTHER THAN THE FIRST 72 BYTES, ARE ZEROED BY THIS      * 22500020
*    ROUTINE.                                                         * 22550020
*                                                                     * 22800020
*********************************************************************** 23200020
         EJECT                                                          23600020
*********************************************************************** 24000020
*                                                                     * 24400020
*   GENERAL REGISTER EQUATES FOR THIS ROUTINE.                        * 24800020
*                                                                     * 25200020
*********************************************************************** 25600020
PARMREG0 EQU   0              ENTRY CODE FROM ABEND/STAE                26000020
*                                  INTERFACE ROUTINE.                   26400020
PARMREG1 EQU   1              ADDRESS OF STAE WORKAREA OR               26800020
*                                  COMPLETION CODE.                     27200020
WORKREG2 EQU   2              ADDRESS OF STAE PARAMETER LIST FOR        27600020
*                                  ENTRY CODE 12 OR ADDRESS OF          28000020
*                                  FIRST SAVE AREA.                     28400020
WORKREG3 EQU   3              ADDRESS OF CURRENT SAVE AREA DURING       28800020
*                                  CLEAN-UP AND EXIT.                   29200020
WORKREG4 EQU   4              POINTER TO CURRENT CHARACTER IN           29300020
*                                  COMMAND NAME.                        29400020
INS2REG  EQU   5              ADDRESS OF INSERTION RECORD FOR           29600020
*                                  SECOND LEVEL MESSAGE.                30000020
LEV2REG  EQU   6              RELATIVE SECOND LEVEL MESSAGE             30100020
*                                  NUMBER.                              30200020
BRNCHREG EQU   7              ADDRESS OF RETURN ON EXIT FROM            30260020
*                                 SUBROUTINE.                           30320020
COMPCODE EQU   8              TASK COMPLETION CODE.                     30400020
COMMREG  EQU   9              ADDRESS OF COMMUNICATION AREA.            30800020
SAVEREG  EQU   13             ADDRESS OF SAVE AREA.                     31200020
BASEREG  EQU   11             BASE REGISTER FOR THIS ROUTINE.           31600020
RETREG   EQU   14             RETURN ADDRESS IN INVOKING ROUTINE.       32000020
RETCDREG EQU   15             RETURN CODE PASSED BACK TO CALLING        32400020
*                                  ROUTINE.                             32800020
         EJECT                                                          33200020
*********************************************************************** 33600020
*                                                                     * 34000020
*   PROLOG.                                                           * 34400020
*                                                                     * 34800020
*   NOTE -- INCLUDED AS A PART OF THIS PROLOG IS THE RE-INITIALIZATION* 35200020
*        OF ALL SAVE AREAS TO ZERO.  THE POINTER TO THE FIRST SAVE    * 35600020
*        AREA IS PRESERVED IN WORKREG2 WHILE THIS ROUTINE IS IN       * 36000020
*        CONTROL.  PRIOR TO EXIT, THE FIRST SAVE AREA POINTER WILL    * 36400020
*        BE RESTORED FOR USE BY THE STAE RETRY ROUTINE.               * 36800020
*                                                                     * 37200020
*********************************************************************** 37600020
         SAVE  (14,12),,*     SAVE ENTRY REGISTERS.                     38000020
         BALR  BASEREG,D0     ESTABLISH ADDRESSABILITY FOR THIS         38400020
         USING *,BASEREG           ROUTINE.                             38800020
         LA    RETCDREG,D12   CREATE CONSTANT FOR ENTRY CODE TEST       39200020
         CR    PARMREG0,RETCDREG   DETERMINE IF STAE PROVIDED A         39600020
         BNE   AE001010            WORK AREA.                           40000020
         LR    COMMREG,WORKREG2 PLACE ADDRESS OF COMMUNICATION          40400020
*                                  AREA IN COMMREG.                     40800020
         LR    COMPCODE,PARMREG1 TASK COMPLETION CODE.                  41200020
         B     AE001020       BRANCH TO SAVE REGISTERS.                 41600020
AE001010 EQU   *                                                        42000020
         L     COMMREG,D0(,PARMREG1) PLACE ADDRESS OF COMMUNICA-        42400020
*                                  TION AREA IN COMMREG.                42800020
         L     COMPCODE,D4(,PARMREG1) TASK COMPLETION CODE.             43200020
AE001020 EQU   *                                                        43600020
         USING IKJEBECA,COMMREG ESTABLISH ADDRESSABILITY TO THE         44000020
*                                  COMMUNICATION AREA.                  44400020
         XC    CASVAREA+(D72+(D256*D0))(D256),CASVAREA+(D72+(D256*D0))  44700020
         XC    CASVAREA+(D72+(D256*D1))(D256),CASVAREA+(D72+(D256*D1))  45000020
         XC    CASVAREA+(D72+(D256*D2))((CANXTSVA-(CASVAREA+D72))-(D256X45300020
               *D2)),CASVAREA+(D72+(D256*D2))                           45600020
*   THE ABOVE ZEROES THE CHAINED SAVE AREAS (EXCEPT THE FIRST SAVE AREA 45900020
*   BELONGING TO IKJEBEMA) IN THE COMMUNICATION AREA.                   46200020
         LA    RETCDREG,CASVAREA+D72 ADDRESS OF SAVE AREA FOR           46500020
*                                  IKJEBEAE.                            46800020
         ST    SAVEREG,D4(,RETCDREG) CROSS CHAIN PREVIOUS AND           47200020
         ST    RETCDREG,D8(,SAVEREG) CURRENT SAVE AREAS.                47600020
         LR    SAVEREG,RETCDREG LOAD POINTER TO SAVE AREA.              48000020
         LA    RETCDREG,D72(,RETCDREG) COMPUTE ADDRESS OF NEXT          48400020
         ST    RETCDREG,CANXTSVA   SAVE AREA AND SAVE.                  48800020
         EJECT                                                          49200020
*********************************************************************** 49205020
*                                                                     * 49210020
*   CLEAN-UP PROCESSING.                                              * 49215020
*                                                                     * 49220020
*   1. STOP AUTOMATIC LINE NUMBER PROMPTING - ISSUE THE SPAUTOPT      * 49225020
*      MACRO INSTRUCTION TO INSURE THAT LINE NUMBER PROMPTING IS      * 49230020
*      STOPPED.                                                       * 49235020
*                                                                     * 49240020
*   2. DELETE THE INPUT STACK - INSURE THAT INPUT FOR PROMPT          * 49245020
*      MESSAGE IN THE RETRY ROUTINE IS FROM THE TERMINAL.             * 49250020
*                                                                     * 49255020
*   3. PLACE THE COMPLETION CODE IN THE ECT AND INDICATE THAT AN      * 49260020
*      ABEND IS IN PROGRESS.                                          * 49265020
*                                                                     * 49270020
*   4. FREE ANY GOTTEN CORE - DETERMINE IF A IKJPARS PDL EXISTS, IF   * 49275020
*      A SUBCOMMAND BUFFER EXISTS, OR IF A GETMAINED BUFFER EXISTS.   * 49280020
*      ISSUE A FREEMAIN MACRO INSTRUCTION FOR ANY OF THE ABOVE THAT   * 49285020
*      EXISTS.                                                        * 49290020
*                                                                     * 49295020
*   5. TERMINATE THE VERIFY OPTION AND SET THE ABEND IN PROGRESS      * 49300020
*      FLAG IN THE COMMUNICATION AREA.                                * 49305020
*                                                                     * 49310020
*********************************************************************** 49315020
*                             STOP AUTOMATIC LINE NUMBER PROMPT.        49320020
         SPAUTOPT                                                       49325020
         B     AE001030(RETCDREG) RETURN CODE BRANCH TABLE.             49330020
AE001030 EQU   *                                                        49335020
         B     AE001040       00 - SUCCESSFUL COMPLETION.               49340020
         B     AE002050       04 - INVALID PARAMETERS.                  49345020
*                             08 - AUTOMATIC LINE NUMBER PROMPT         49350020
*                                  NOT IN EFFECT.                       49355020
AE001040 EQU   *                                                        49360020
         XC    AEWKAREA(AEWKEND-AEWKAREA),AEWKAREA ZERO WORK AREA       49364020
         L     RETCDREG,AEPTBMA2 ADDRESS OF FREEMAIN/INPUT STACK        49368020
*                                  CLEAN-UP ROUTINE.                    49372020
         CALL  (15),ID=1,MF=(E,AESTPB) BRANCH TO CLEAR QUEUES AND      X49376020
                                   DELETE THE INPUT STACK.              49380020
         LTR   RETCDREG,RETCDREG TEST FOR SUCCESSFUL RETURN.            49388020
         BNZ   AE002050       FOR RETURN CODE = 4, BRANCH TO EXIT       49396020
AE001060 EQU   *                                                        49405020
         L     WORKREG2,CAPTECT ADDRESS OF ECT.                         49412020
         USING ECT,WORKREG2   ADDRESSABILITY TO ECT DSECT.              49420020
         ST    COMPCODE,ECTRTCD-L'ECTRCDF PLACE COMPLETION CODE         49425020
         MVI   ECTRCDF,AEABEND     IN ECT AND INDICATE CP ABEND.        49430020
         TM    ECTSWS,ECTATRM DETERMINE IF EDIT CP IS BEING             49431020
*                                  DETACHED (WITH STAE) BY TMP.         49432020
         BO    AE002050       IF SO, BRANCH TO RETURN, SPECIFYING       49433020
*                                  NO RETRY ROUTINE.                    49434020
         TM    CAPRSPDL,CAFREEDL CHECK IF A PDL EXISTS.                 49435020
         BO    AE001070       IF NO PDL, BRANCH TO CHECK IF A           49440020
*                                  SYNTAX CHECKER/RUN BUFFER            49445020
*                                  EXISTS.                              49450020
         LA    WORKREG3,CAPTPRSD ADDRESS OF PDL TO BE FREED.            49455020
         IKJRLSA (WORKREG3)   FREE IKJPARS PDL.                         49470020
AE001070 EQU   *                                                        49480020
         OC    CAPTCORE+D1(D3),CAPTCORE+D1 DOES A SYNTAX CHECKER OR     49485020
*                                          RUN BUFFER EXIST             49490020
         BZ    AE001080       IF NOT, BRANCH TO CHECK IF A              49495020
*                                  SUBCOMMAND BUFFER EXISTS.            49500020
         L     WORKREG3,CACORELN LENGTH OF GETMAIN AREA.                49505020
         FREEMAIN E,LV=(WORKREG3),A=CAPTCORE,SP=SUBPOOL1,              X49510020
               MF=(E,AEFREMNL) FREE BUFFER.                             49515020
AE001080 EQU   *                                                        49525020
         L     RETCDREG,AEPTBMA2 ADDRESS OF FREEMAIN/INPUT STACK        49535020
*                                  CLEAN-UP ROUTINE.                    49545020
         CALL  (15),ID=0,MF=(E,AEFREMNL) BRANCH TO FREE CURRENT        X49555020
                                   INPUT BUFFER.                        49565020
AE001090 EQU   *                                                        49585020
         NI    CACFLAG1,D255-CAVRFYSW TERMINATE VERIFY OPTION.          49590020
         OI    CACFLAG4,CAABEND INDICATE THAT EDIT IS ABENDING.         49595020
*********************************************************************** 49600020
*                                                                     * 50000020
*   BUILD PARAMETER LIST FOR IKJEBEMS.  MOVE PARAMETER LIST TO WORK   * 50400020
*   AREA.  CONVERT COMPLETION CODE TO DECIMAL AND CONVERT TO          * 50800020
*   PRINTABLE EBCDIC.  COMPLETE THE INSERTION RECORD FOR THE          * 51200020
*   SECOND LEVEL MESSAGE.  WHEN THE PARAMETER LIST IS COMPLETE, CALL  * 51600020
*   IKJEBEMS.                                                         * 52000020
*                                                                     * 52400020
*********************************************************************** 52800020
         MVC   AECMDNAM(L'AECMDNAM-D1),CAMODETX+D1 SET UP COMMAND       53100020
*                                  NAME INSERTION.                      53400020
         LH    WORKREG3,CAMODELN OBTAIN LENGTH OF MODE MESSAGE,         53700020
         BCTR  WORKREG3,D0         REDUCE BY 1 FOR LEADING BLANK        54000020
         STH   WORKREG3,AECMDLEN   AND SAVE IN CONTROL FIELD.           54330020
         LA    WORKREG3,M422IN1 OBTAIN OFFSET TO INSERTION AND          54420020
         STH   WORKREG3,AECMDOFF   SAVE IN CONTROL FIELD.               54510020
         LA    COMPCODE,D0(,COMPCODE) ZERO HIGH ORDER BYTE OF THE       54600020
*                                  COMPLETION CODE.                     54690020
         LR    WORKREG3,COMPCODE SAVE COMPLETION CODE FOR TEST.         54780020
         N     WORKREG3,AESYSTCD DETERMINE IF A USER COMPLETION         54870020
*                                  CODE.                                54960020
         BC    AEUSER,AE002030 BRANCH TO SELECT DIAGNOSTIC.             55050020
         SRL   COMPCODE,D12(D0) SHIFT SYSTEM COMPLETION CODE INTO       55140020
*                                  POSITION FOR CONVERSION.             55230020
         LA    LEV2REG,M4221  SECOND LEVEL MESSAGE NUMBER.              55320020
         LA    INS2REG,M4221IN1 OFFSET TO INSERTION RECORD.             55410020
         SLL   COMPCODE,D4(D0) SHIFT COMPLETION CODE LEFT 4 BITS        55420020
         ST    COMPCODE,AEBINDEC   SO THAT ZONE FIELD MAY BE            55430020
         OI    AEBINDEC+D3,AEZONES ADDED FOR CONVERSION.                55440020
         UNPK  AECDETXT(D3),AEBINDEC+D2(D2) CONVERT COMPLETION          55450020
         TR    AECDETXT(D3),AETRNSTB-AECHRZRO CODE TO HEXADECIMAL       55460020
         B     AE002040       BRANCH TO CONVERT COMPLETION CODE         55500020
*                                  TO PRINTABLE EBCDIC.                 55590020
AE002030 EQU   *                                                        55680020
         LA    LEV2REG,M4222  SECOND LEVEL MESSAGE NUMBER.              55770020
         LA    INS2REG,M4222IN1 OFFSET TO INSERTION RECORD.             55860020
         BCTR  WORKREG3,D0    SET UP MASK OF ALL F'S AND USE AS         55870020
         ST    WORKREG3,AECDETXT   ZONE BITS FOR RETURN CODE.           55880020
         CVD   COMPCODE,AEBINDEC CONVERT USER RETURN CODE TO            55890020
         UNPK  AEBINDEC(D5),AEBINDEC+D5(D3) EBCDIC AND USE FOUR         55900020
         MVN   AECDETXT(D4),AEBINDEC+D1 SIGNIFICANT DIGITS.             55910020
AE002040 EQU   *                                                        55950020
         LA    WORKREG3,D6(,LEV2REG) COMPUTE LENGTH OF INSERTION        56040020
         STH   WORKREG3,AECDELEN   AND SAVE.                            56130020
         STH   INS2REG,AECDEOFF PLACE OFFSET FOR INSERTION IN           56670020
*                                  CONTROL FIELD OF RECORD.             56760020
         IKJEBEML M422,(LEV2REG),AECMDINS,AECDEINS,MF=(E,AEMSPLST)      56850020
         SPACE                                                          56900020
         LTR   RETCDREG,RETCDREG CHECK FOR SUCCESSFUL COMPLETION        56940020
*                                  CODE FROM PUTLINE.                   57030020
         BNZ   AE002050       UNSUCCESSFUL, SKIP RETRY.                 57120020
         SPACE                                                          57170020
         TM   CACFLAG4,CAINPROC  WAS EDIT BEING EXECUTED FROM           57180020
*                                  AN IN CORE PROCEDURE                 57190020
         BO    AE002050       YES, SKIP RETRY                           57200020
         SPACE 2                                                        58000020
*********************************************************************** 58400020
*                                                                     * 58800020
*   UPON RETURN FROM IKJEBEMS, SET ABEND IN PROGRESS FLAG IN THE      * 59200020
*   COMMUNICATION AREA, LOAD ADDRESS OF RETRY ROUTINE INTO            * 59600020
*   REGISTER ZERO, AND RETURN TO ABEND PROCESSING WITH A RETURN       * 60000020
*   CODE OF 4.                                                        * 60400020
*                                                                     * 60800020
*********************************************************************** 61200020
         SPACE                                                          61250020
         LA    RETCDREG,D4(,D0) SET RETURN CODE = 4, RETRY              61800020
*                                  ROUTINE SPECIFIED.                   62100020
         L     PARMREG0,CAPTRTRY ADDRESS OF STAE RETRY ROUTINE.         62400020
AE002070 EQU   *                                                        62600020
         LR    WORKREG3,SAVEREG SAVE ADDRESS OF CURRENT SAVE AREA       62800020
         L     SAVEREG,D4(,SAVEREG) ADDRESS OF PREVIOUS SAVE AREA       63200020
         XC    D0(D72,WORKREG3),D0(WORKREG3) ZERO SAVE AREA.            63600020
         L     RETREG,R14(,SAVEREG) RELOAD EXIT ADDRESS.                64800020
         LM    PARMREG1,BASEREG,R1(SAVEREG) RELOAD REGS 1 THRU 12       66000020
         BR    RETREG         RETURN TO ABEND/STAE INTERFACE.           66400020
         SPACE 4                                                        66400420
*********************************************************************** 66402020
*                                                                     * 66404020
*   RETURN HERE WHEN RETRY NOT INDICATED                              * 66410020
*                                                                     * 66420020
*********************************************************************** 66430020
         SPACE 2                                                        66440020
AE002050 EQU   *                                                        66450020
         SR    RETCDREG,RETCDREG SET RETURN CODE TO INDICATE THAT       66500020
*                                  ABEND PROCESSING IS TO               66550020
*                                  CONTINUE.                            66600020
         B     AE002070       BRANCH TO EXIT.                           66650020
         EJECT                                                          66800020
*********************************************************************** 66850020
*                                                                     * 66900020
*   EQUATES, CONSTANTS, AND TABLES USED BY THIS ROUTINE.              * 68000020
*                                                                     * 68400020
*********************************************************************** 68800020
D0       EQU   0              DECIMAL VALUE ZERO.                       69600020
D1       EQU   1              DECIMAL VALUE 1.                          70000020
D2       EQU   2              DECIMAL VALUE 2.                          70400020
D3       EQU   3              DECIMAL VALUE 3.                          70800020
D4       EQU   4              DECIMAL VALUE 4.                          71200020
D5       EQU   5              DECIMAL VALUE 5.                          71600020
D6       EQU   6              DECIMAL VALUE 6.                          72000020
D7       EQU   7              DECIMAL VALUE 7.                          72200020
D8       EQU   8              DECIMAL VALUE 8.                          72400020
D12      EQU   12             DECIMAL VALUE 12.                         72800020
D72      EQU   72             DECIMAL VALUE 72.                         73200020
D255     EQU   255            DECIMAL VALUE 255.                        73400020
D256     EQU   256            DECIMAL VALUE 256.                        73600020
R1       EQU   6*4            OFFSET IN SAVE AREA TO REG(1).            74000020
R14      EQU   3*4            OFFSET IN SAVE AREA TO REG(14).           74400020
AEABEND  EQU   X'80'          INDICATE CP ABEND IN PROGRESS IN          74600020
*                                  ECT.                                 74800020
AEBLANK  EQU   C' '           CHARACTER BLANK.                          75000020
AECHRZRO EQU   C'0'           CHARACTER ZERO.                           75200020
AEUSER   EQU   B'1000'        CONDITION CODE USED TO DETERMINE IF       75400020
*                                  A USER ABEND OCCURRED.               75600020
AEZONES  EQU   X'0F'          PACKED DECIMAL ZONE FIELD.                75800020
SUBPOOL1 EQU   1              SUBPOOL VALUE USED FOR FREEMAIN.          76000020
         DS    0F             ALIGN ON FULL WORD BOUNDARY.              76200020
AESYSTCD DC    XL4'00FFF000'  MASK USED TO DETERMINE IF A USER          76400020
*                                  ABEND OCCURRED.                      76600020
AETRNSTB DC    C'0123456789ABCDEF' TRANSLATE TABLE FOR OBTAINING        77200020
*                                  PRINTABLE HEXADECIMAL.               77600020
AEPTBMA2 DC    A(IKJEBMA2)    ADDRESS OF FREEMAIN/INPUT STACK           77630020
*                                  CLEAN-UP ROUTINE.                    77660020
         EJECT                                                          77900020
         IKJEBECA                                                       78000020
*********************************************************************** 78400020
*                                                                     * 78800020
*   FORMAT OF WORK AREA USED BY IKJEBEAE.                             * 79200020
*                                                                     * 79600020
*********************************************************************** 80000020
         ORG   CATEMPBF       FORMAT IKJEBEAE WORK AREA.                80400020
AEWKAREA DS    0D             ABNORMAL END WORK AREA.                   80800020
AEBINDEC DS    D              BINARY TO DECIMAL CONVERSION AREA.        81200020
AESTPB   DS    2F             STACK PARAMETER BLOCK.                    81300020
AEFREMNL DS    3F             PARAMETER LIST FOR FREEMAIN.              81400020
AECMDINS DS    0F             COMMAND NAME INSERTION RECORD.            81500020
AECMDPTR DS    A              POINTER TO NEXT INSERTION RECORD.         81600020
AECMDLEN DS    H              LENGTH OF THIS INSERTION.                 81700020
AECMDOFF DS    H              OFFSET TO INSERTION.                      81800020
AECMDNAM DS    CL8            INSERTION TEXT.                           81900020
AECDEINS DS    0F             COMPLETION CODE INSERTION RECORD.         82000020
AECDEPTR DS    A              POINTER TO NEXT INSERTION RECORD.         82100020
AECDELEN DS    H              LENGTH OF THIS INSERTION.                 82200020
AECDEOFF DS    H              OFFSET TO INSERTION.                      82300020
AECDETXT DS    CL8            INSERTION TEXT.                           82400020
AEPARMS  DS    0F             REMOTE PARAMETER LIST FOR IKJEBEMS.       83600020
AEMSPLST DS    8F             PARAMETER LIST FOR IKJEBEMS.              84000020
AEWKEND  EQU   *                                                        84200020
         IKJEBEMI (422)       EQUATES FOR MESSAGE IKJ52422I.            84400020
         EJECT                                                          84440020
         IKJSTPB                                                        84480020
STPBLEN  EQU   *-STPB         LENGTH OF STACK PARAMETER BLOCK.          84520020
         EJECT                                                          84560020
         IKJECT                                                         84600020
         EJECT                                                          84640020
         IKJCPPL                                                        84680020
         EJECT                                                          84720020
         END                                                            84800020
