         TITLE 'BEAT      EDIT ATTENTION EXIT ROUTINE -- IKJEBEAT'      00300020
IKJEBEAT CSECT                                                          00600020
*A520000-522000                                                  A42949 00620020
*D522000,561000-564000                                           A42949 00640020
*A463200-464400,536000-540000,561000-701000,732600-733800        A42953 00660020
*A762640-762920,787000-811000,820000-827000,854000-859000        A42953 00680020
*A874200-875400,910400,921000-930000,966000                      A42953 00700020
*C867000                                                         A42953 00720020
*D537000-540000,570000-726000,786000-813000,822000-828000        A42953 00740020
*D852000-861000,921000-930000                                    A42953 00760020
*A557000,767000,780600-782100,935000-943000                      A42960 00780020
*D558000,765000-768000,936000-942000,960000-972000               A42960 00800020
*A522700-524100                                                 SA63662 00850021
         EXTRN IKJEBMA2                                                 00900020
*********************************************************************** 01200020
*                                                                     * 01500020
*STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20.6                    * 01800020
*                                                                     * 02100020
*FUNCTION --                                                          * 02400020
*                                                                     * 02700020
*       THIS ROUTINE GAINS CONTROL AFTER AN ATTN INTERRUPT WHILE THE  * 03000020
*   EDIT COMMAND PROCESSOR IS BEING EXECUTED.  UPON ENTRY, IKJEBEAT   * 03300020
*   STOPS ANY ATTACHED SUBTASKS PRIOR TO HANDLING THE ATTENTION.      * 03600020
*   THE ATTENTION SCHEDULING ROUTINE WILL HAVE ISSUED A TGET WITHOUT  * 03700020
*   TRANSFER OF DATA (THIS IS DETERMINED BY PARAMETERS ON THE STAX    * 03800020
*   MACRO ISSUED BY IKJEBEMA IN ESTABLISHING THE ATTENTION EXIT).     * 03900020
*   THE TGET RETURN CODE IS CHECKED. IF ZERO, THE INPUT IS A NULL     * 04200020
*   LINE.  OTHERWISE, A PUTGET IS ISSUED (WITH) THE 'ATTN'            * 04400020
*   OPTION, TO (1) PROCESS '?' WHEN ENTERED AT THE TERMINAL,          * 04600020
*   AND (2) RETURN A LINE OF INPUT FROM THE TERMINAL.                 * 04800020
*                                                                     * 05000020
*       WHEN THE INPUT LINE RETURNED BY PUTGET IS NULL, THE           * 05200020
*   BUFFER IT OCCUPIES IS FREEMAINED AND CONTROL IS RETURNED TO       * 05400020
*   THE CALLER.                                                       * 05600020
*                                                                     * 05800020
*       WHEN THE INPUT LINE RETURNED BY PUTGET CONTAINS ONE OR        * 06000020
*       MORE CHARACTERS FROM THE TERMINAL, THE FOLLOWING ACTIONS      * 06200020
*   ARE TAKEN --                                                      * 06400020
*                                                                     * 06600020
*       1.  FREEMAIN OF PREVIOUS BUFFER OBTAINED FOR THIS             * 06800020
*           ROUTINE (IF ANY)                                          * 07000020
*                                                                     * 07200020
*       2.  REPLACEMENT OF BUFFER ADDRESS IN THE ATTENTION ECB        * 07400020
*           WITH THE ADDRESS OF THE BUFFER RETURNED BY PUTGET.        * 07600020
*                                                                     * 07800020
*       3.  DELETION OF ALL ELEMENTS BUT THE TERMINAL FROM THE        * 08000020
*           INPUT STACK.  CLEARING OF INPUT QUEUES.                   * 08200020
*                                                                     * 08400020
*       4.  ITF ATTENTION PROCESSING (IF APPLICABLE).  THIS           * 08600020
*           CONSISTS OF INVOKING THE IKJNC311 MODULE VIA LINK.        * 08800020
*                                                                     * 09000020
*       5.  ISSUING POST MACRO FOR ATTENTION ECB.                     * 09200020
*                                                                     * 09400020
*       9.  INDICATING IN THE EDIT COMMUNICATION AREA THAT            * 09600020
*           THE TERMINAL IS THE CURRENT INPUT SOURCE.                 * 09800020
*                                                                     * 10000020
*       BEFORE RETURNING TO THE CALLER, THIS ROUTINE ISSUES THE       * 10200020
*   STATUS MACRO TO RE-START DISPACTCHABLE SUBTASKS.  IT DOES         * 10400020
*   SO REGARDLESS OF THE CONTENTS OF THE INPUT LINE ENTERED AT        * 10600020
*   THE TERMINAL.                                                     * 10800020
*                                                                     * 12600020
*ENTRY POINTS --                                                      * 12900020
*                                                                     * 13200020
*   IKJEBEAT -- FROM THE ATTENTION SCHEDULING ROUTINE, AFTER AN       * 13500020
*               ATTENTION INTERRUPT HAS OCCURRED, AND A LINE OF INPUT * 13800020
*               HAS BEEN ENTERED AT THE TERMINAL.                     * 14100020
*                                                                     * 14400020
*INPUT --                                                             * 14700020
*                                                                     * 15000020
*   1.  REGISTER ONE ADDRESSES THE ATTENTION EXIT PARAMETER LIST --   * 15300020
*                                                                     * 15600020
*       A.  ADDRESS OF THE TAIE, THE TERMINAL ATTENTION INTERRUPT     * 15900020
*           ELEMENT, CONTAINING THE INTERRUPT ADDRESS AND REGISTERS,  * 16200020
*           THE BUFFER LENGTH, AND THE TGET RETURN CODE               * 16500020
*                                                                     * 16800020
*       B.  ADDRESS OF THE INPUT BUFFER                               * 17100020
*                                                                     * 17400020
*       C.  ADDRESS OF USER AREA (IN THIS CASE THE EDIT COMMUNICATION * 17700020
*           AREA)                                                     * 18000020
*                                                                     * 18300020
*OUTPUT --                                                            * 18600020
*                                                                     * 18900020
*   THIS ROUTINE SETS NO RETURN CODES.  OUTPUT CONSISTS OF POSTING    * 19200020
*   THE ATTENTION ECB, INDICATING IN THE EDIT COMMUNICATION           * 19400020
*   AREA THAT THE CURRENT SOURCE OF INPUT IS THE TERMINAL, AND        * 19600020
*   UPDATING THE BUFFER ADDRESS IN THE ECB.                           * 19800020
*                                                                     * 20100020
*EXTERNAL REFERENCES --                                               * 20400020
*                                                                     * 20700020
*   IKJPTGT -- PUTS MODE MESSAGE TO TERMINAL, PROCESSES PREVIOUS      * 21000020
*              SECOND-LEVEL MESSAGES, AND OBTAINS INPUT FROM          * 21300020
*              THE TERMINAL.                                          * 21600020
*                                                                     * 21900020
*   IKJEBMA2 -- A SUBROUTINE OF THE EDIT MAIN CONTROLLER,             * 22200020
*               IKJEBEMA, INVOKED TO DELETE THE INPUT STACK AND       * 22500020
*               CLEAR THE INPUT QUEUE.                                * 22800020
*                                                                     * 23100020
*   MACROS USED --                                                    * 23400020
*                                                                     * 23700020
*      STATUS - USED TO STOP ATTACHED SUB-TASKS                       * 24000020
*      PUTGET - BUILDS PARAMETERS FOR AND INVOKES IKJPTGT             * 24100020
*      IKJEBECA - MAPPING MACRO FOR EDIT COMMUNICATION AREA           * 24200020
*      IKJTAIE - MAPPING MACRO FOR TERMINAL ATTENTION INTERRUPT       * 24300020
*                ELEMENT                                              * 24400020
*      IKJIOPL - MAPPING MACRO FOR TMP I/O SERVICE ROUTINE            * 24500020
*                PARAMETER LIST                                       * 24600020
*      IKJPGPB - MAPPING MACRO FOR PUTGET PARAMETER BLOCK             * 24700020
*                                                                     * 24900020
*EXITS,NORMAL -- RETURN TO THE CALLING ROUTINE WITH NO RETURN CODE SET* 25200020
*                                                                     * 25500020
*EXITS,ERROR -- NONE                                                  * 25800020
*                                                                     * 26100020
*TABLES/WORK AREAS --                                                 * 26400020
*                                                                     * 26700020
*   EDIT COMMUNICATION AREA -- CONTAINS THE ATTENTION WORKAREA AND    * 27000020
*                              VARIOUS CONTROL INFORMATION FOR        * 27300020
*                              THIS ROUTINE                           * 27600020
*                                                                     * 27900020
*   CAATNWKA -- A WORKAREA IN THE COMMUNICATION AREA CONTAINING SPACE * 28200020
*               FOR A SAVE AREA AND PARAMETER LISTS. IT IS DESCRIBED  * 28500020
*               BY THE DSECT ATWORKSV.                                * 28800020
*                                                                     * 29100020
*ATTRIBUTES -- REFRESHABLE, ENABLED, AND NON-PRIVILEGED               * 29400020
*                                                                     * 29700020
*NOTES -- REGISTER DEFINITIONS AS DESCRIBED BELOW. THIS ROUTINE IS    * 30000020
*         CHARACTER CODE INDEPENDENT.                                 * 30300020
*                                                                     * 30600020
*         THIS ROUTINE IS DESCRIBED IN PLM GY28-6773, TSO COMMAND     * 30670020
*         PROCESSOR PROGRAM LOGIC MANUAL, VOLUME 3, EDIT.             * 30740020
*                                                                     * 30810020
*********************************************************************** 30900020
         EJECT                                                          31200020
*********************************************************************** 31500020
*                                                                       31800020
* THE FOLLOWING EQU'S ALLOW SYMBOLIC ADDRESSING OF REGISTERS            32100020
*                                                                       32400020
*********************************************************************** 32700020
PARMREG0 EQU   0             REGISTER 0 IS A PARAMETER REGISTER         33000020
PARMREG1 EQU   1             REGISTER 1 IS A PARAMETER REGISTER         33300020
COMMREG  EQU   9             REGISTER 9 CONTAINS COMM AREA ADDR         33600020
BASEREG  EQU   11            REGISTER 11 IS THE BASE REGISTER           33900020
DATAREG  EQU   12            REGISTER 12 IS USED TO ADDRESS THE         34200020
*                            WORK AREA FOR THIS MODULE                  34500020
SAVEREG  EQU   13            REGISTER 13 CONTAINS THE SAVE AREA         34800020
*                            ADDRESS                                    35100020
RETCDREG EQU   15            RETURN CODES ARE PASSED IN REGISTER 15     35400020
REG2     EQU   2             WORK REGISTER                              35700020
REG3     EQU   3             WORK REGISTER                              36000020
REG4     EQU   4             WORK REGISTER                              36300020
REG5     EQU   5             WORK REGISTER                              36600020
REG6     EQU   6             WORK REGISTER                              36900020
REG7     EQU   7             WORK REGISTER                              37200020
REG8     EQU   8             WORK REGISTER                              37500020
         EJECT                                                          37800020
*********************************************************************** 38100020
*                                                                       38400020
*                             SPECIAL EQU'S                             38700020
*                                                                       39000020
*********************************************************************** 39300020
         SPACE 2                                                        39600020
* DISPLACEMENTS AND LENGTHS                                             39900020
D0       EQU   0             DISPLACEMENT OF 0                          40200020
D1       EQU   1             DISPLACEMENT OF 1                          40500020
D2       EQU   2             DISPLACEMENT OF 2                          40800020
D4       EQU   4             DISPLACEMENT OF 4                          41100020
D8       EQU   8             DISPLACEMENT OF 8                          41400020
D72      EQU   72            DISPLACEMENT OF 72                         41700020
D255     EQU   255           DISPLACEMENT OF 255                        42000020
D256     EQU   256           DISPLACEMENT OF 256                        42300020
L0       EQU   0             LENGTH OF ZERO BYTES                       42600020
L4       EQU   4             LENGTH OF FOUR BYTES                       42900020
L8       EQU   8             LENGTH OF EIGHT BYTES                      43200020
L12      EQU   12            LENGTH OF TWELVE BYTES                     43500020
L16      EQU   16            LENGTH OF SIXTEEN BYTES                    43800020
L20      EQU   20            LENGTH OF TWENTY BYTES                     44100020
         SPACE 2                                                        44400020
ATEDITCA EQU   8             DISPLACEMENT FOR ESTABLISHING              44700020
*                            ADDRESSABILITY TO COMMUNICATION AREA       45000020
         SPACE                                                          45300020
ATPTTAIE EQU   0              DISPLACEMENT OF TAIE ADDR IN PARMLIST     45600020
         SPACE                                                          45900020
NOBRANCH EQU   0             SPECIFIES NO BRANCH IN BCTR                46200020
         SPACE                                                          46260020
NOBUFFER EQU   8              MASK FOR BCR INSTRUCTION.          A42953 46320020
         SPACE                                                          46380020
SUBPL1   EQU   1             SUBPOOL ONE                         A42953 46440020
         EJECT                                                          46500020
*********************************************************************** 46800020
*                                                                       47100020
*                             PROLOG                                    47400020
*                                                                       47700020
*********************************************************************** 48000020
         SPACE 2                                                        48300020
         SAVE  (14,12),,*     ENTRY LINKAGE                             48600020
         BALR  BASEREG,NOBRANCH    ESTABLISH ADDRESSABILITY FOR         48900020
         USING *,BASEREG           THIS MODULE                          49200020
         LR    REG2,PARMREG1 COPY PARAMETER LIST POINTER                49500020
         STATUS STOP          STOP ANY ACTIVE SUB-TASKS                 49800020
         L     COMMREG,ATEDITCA(,REG2) ESTABLISH COMMUNICATIONS         50100020
         USING IKJEBECA,COMMREG        AREA ADDRESSABILITY              50400020
         LA    PARMREG1,ATWORKSV     ADDRESS THIS RTN'S SAVE AREA       50700020
         ST    PARMREG1,D8(,SAVEREG) FORWARD CHAIN CALLER'S SAVE AREA   51000020
         ST    SAVEREG,D4(,PARMREG1) BACK CHAIN CURRENT SAVE AREA       51300020
         LR    SAVEREG,PARMREG1 INITIALIZE SAVE REGISTER                51600020
         XC    ATWORKA(ATLNWKA),ATWORKA ZERO WORK AREA                  51900020
         MVC   ATTMPLST(L8),CATMPLST  INITIALIZE TMP SERVICE     A42949 52000020
*                                       ROUTINE PARAMETER LIST,  A42949 52100020
*                                       WITHOUT ADDR OF ATTN ECB A42949 52200020
         LA    REG3,ATWORKA+8    MAKE ADDR OF ATTN  ECB         SA63662 52270021
         ST    REG3,ATWORKA+8    POINT TO ITSELF WITH ZEROS     SA63662 52340021
*                                IN THE HIGH ORDER BYTE         SA63662 52410021
         SPACE 2                                                        52500020
*********************************************************************** 52800020
*                                                                       53100020
* THE TGET RETURN CODE IN THE TAIE IS CHECKED. IF ZERO, A NULL LINE     53400020
* WAS ENTERED AT THE TERMINAL. OTHERWISE PUTGET IS ISSUED TO     A42953 53600020
* (1) PROCESS ANY QUESTION MARKS ENTERED AT THE TERMINAL, AND    A42953 53800020
* (2) TO OBTAIN AN INPUT LINE FROM THE TERMINAL.                 A42953 54000020
*                                                                       54300020
*********************************************************************** 54600020
         SPACE 2                                                        54900020
         L     REG3,ATPTTAIE(,REG2) ADDRESS TAIE                        55200020
         CLI   TAIETGET-TAIE(REG3),L0  WAS TGET RETURN CODE ZERO        55500020
         BE    ATNOLINE       YES, BRANCH TO NULL LINE EXIT      A42960 55700020
         EJECT                                                          55900020
**************************************************************** A42953 56100020
*                                                                A42953 56300020
* A PUTGET IS ISSUED TO OBTAIN THE LINE ENTERED AT THE TERMINAL. A42953 56500020
* BY SPECIFYING THE 'ATTN' KEYWORD, THE MODE MESSAGE IS PRINTED  A42953 56700020
* ONLY AFTER A '?' IS ENCOUNTERED, AND INPUT IS FROM THE         A42953 56900020
* TERMINAL.                                                      A42953 57100020
*                                                                A42953 57300020
**************************************************************** A42953 57500020
         SPACE                                                          57700020
         MVC   ATPARM(L16),ATPTGTPB MOVE PARM BLOCK TO DYNAMIC   A42953 57900020
*                                  AREA.                         A42953 58100020
         LA    PARMREG1,ATPARM OBTAIN ADDRESS OF PARAMETER BLOCK A42953 58300020
         ST    PARMREG1,ATTMPLST+IOPLIOPB-IOPL CHAIN BLOCK       A42953 58500020
*                                  TO PARAMETER LIST.            A42953 58700020
         LA    REG2,CAMODEMG  OBTAIN MODE MESSAGE OUTPUT         A42953 58900020
*                               DESCRIPTOR ADDRESS               A42953 59100020
         PUTGET OUTPUT=((REG2),SINGLE,ATTN),MF=(E,ATTMPLST)      A42953 59300020
         LTR   RETCDREG,RETCDREG CHECK IF LINE WAS SUCCESSFULLY  A42953 59500020
*                                  OBTAINED FROM TERMINAL.       A42953 59700020
         BNZ   ATNOLINE       IF ERROR OCCURRED, ACTION IS SAME  A42953 59900020
*                               AS FOR NULL LINE.                A42953 60100020
         EJECT                                                          60300020
**************************************************************** A42953 60500020
*                                                                A42953 60700020
* A LINE HAS BEEN OBTAINED FROM THE TERMINAL.  IF THIS LINE IS   A42953 60900020
* NULL, IT MUST BE FREEMAINED BEFORE TAKING NULL LINE EXIT.      A42953 61100020
* OTHERWISE, THE INPUT BUFFER IS ASSUMED TO CONTAIN A SUBCOMMAND A42953 61300020
*                                                                A42953 61500020
**************************************************************** A42953 61700020
         SPACE                                                          61900020
         L     REG8,ATPARM+PGPBIBUF-PGPB OBTAIN BUFFER ADDRESS.  A42953 62100020
         LA    REG3,D4        OBTAIN LENGTH OF NULL-LINE BUFFER. A42953 62300020
         SH    REG3,D0(,REG8) SUBTRACT ACTUAL BUFFER LENGTH.     A42953 62500020
         BM    ATSCMD         IF RESULT NEGATIVE, LINE IS TO     A42953 62700020
*                                  BE TREATED AS A SUBCOMMAND.   A42953 62900020
*                                                                A42953 63100020
* OTHERWISE, THE LINE IS NULL.  FREEMAIN BUFFER JUST OBTAINED.   A42953 63300020
*                                                                A42953 63500020
         ST    REG8,ATBUFFER  SPECIFY ADDRESS TO BE FREEMAINED.  A42953 63700020
         BAL   REG6,ATFREEBF  FREE NULL LINE BUFFER              A42953 63900020
         B     ATNOLINE       BRANCH TO TAKE NULL LINE EXIT.     A42953 64100020
         EJECT                                                   A42953 64300020
**************************************************************** A42953 64500020
*                                                                A42953 64700020
* LINE ENTERED IS TO BE TREATED AS A SUBCOMMAND --               A42953 64900020
*                                                                A42953 65100020
*   1. FREEMAIN ANY BUFFER OBTAINED THROUGH PREVIOUS ATTENTION   A42953 65300020
*      PROCESSING, AND STORE ADDRESS OF NEW BUFFER.              A42953 65500020
*                                                                A42953 65700020
*   2. CALL IKJEBMA2 TO DELETE INPUT STACK AND CLEAR INPUT       A42953 65900020
*      QUEUES                                                    A42953 66100020
*                                                                A42953 66300020
*   3. PREFORM ITF ATTENTION PROCESSING AS NECESSARY.            A42953 66500020
*                                                                A42953 66700020
*   4. ISSUE POST FOR ATTENTION ECB.                             A42953 66900020
*                                                                A42953 67100020
*   5. INDICATE THAT TERMINAL IS CURRENT SOURCE OF INPUT.        A42953 67300020
*                                                                A42953 67500020
*   6. FINAL PROCESSING CONSISTS OF ISSUING STATUS MACRO TO      A42953 67700020
*      RESTART DIPATCHABLE SUBTASKS.  THIS PROCESS IS PERFORMED  A42953 67900020
*      UNCONDITIONALLY -- IT APPLIES TO SUBCOMMAND AND NULL      A42953 68100020
*      LINE INPUT.                                               A42953 68300020
*                                                                A42953 68500020
**************************************************************** A42953 68700020
         SPACE                                                          68900020
ATSCMD   EQU   *                                                 A42953 69100020
         L     REG3,CAATNBUF  OBTAIN ATTENTION BUFFER            A42953 69300020
         ST    REG3,ATBUFFER  SPECIFY BUFFER ADDRESS TO BE       A42953 69500020
*                             FREEMAINED.                        A42953 69700020
         ST    REG8,CAATNBUF  SAVE NEW INPUT BUFFER ADDRESS      A42953 69900020
         BAL   REG6,ATFREEBF  BRANCH TO FREE BUFFER.             A42953 70100020
         NI    CACFLAG2,D255-CAMODMSG  INSURE THAT CONTROLLER DOES      72700020
*                                      NOT REISSUE MODE MESSAGE         72800020
         L     RETCDREG,ATPTBMA2         INVOKE IKJEBEMA SUBROUTINE     72900020
         CALL  (15),ID=2,MF=(E,ATWKAREA) TO FLUSH INPUT STACK           73200020
         EJECT                                                          73230020
**************************************************************** A42953 73260020
*                                                                A42953 73290020
* PERFORM ITF PROCESSING IF NECESSARY, POST ATTN ECB.            A42953 73320020
*                                                                A42953 73350020
**************************************************************** A42953 73380020
         SPACE                                                          73410020
         OC    CAPTCHK(L4),CAPTCHK IS ITF IN SYSTEM                     73500020
         BZ    ATPOST              NO,POST ECB                          73800020
         TM    CACFLAG1,CAINITSC   IS ITF INIT IN PROCESS               73850020
         BO    ATPOST              YES, SKIP ITF ATTN PROCESSING        73900020
         CLI   CADSCODE,CABASIC    WAS THE DATA SET A BASIC DATA SET    74100020
         BE    ATITF               YES,GO PROCESS ITF                   74400020
         CLI   CADSCODE,CAIPLI     WAS THE DATA SET AN IPLI DATA SET    74700020
         BNE   ATPOST              NO,POST ECB                          75000020
ATITF    EQU   *                                                        75300020
         LINK  EP=IKJNC311         INVOKE ITF ROUTINE                   75600020
         SPACE                                                          75700020
ATPOST   EQU   *                                                        75900020
         POST  CAATTN              POST ATTENTION ECB                   76200020
         SPACE                                                          76210020
         NI    CACFLAG4,D255-CAINPROC INDICATE TERMINAL INPUT LINE      76250020
         EJECT                                                          76257020
**************************************************************** A42953 76264020
*                                                                A42953 76271020
*                           EXIT PROCESSING                      A42953 76278020
*                                                                A42953 76285020
**************************************************************** A42953 76292020
         SPACE                                                          76300020
ATEXIT   EQU   *                                                 A42960 76700020
         STATUS START         START ANY STOPPED SUB-TASKS               77100020
         L     SAVEREG,D4(,SAVEREG) RESTORE CALLER'S SAVE               77400020
*                                   REGISTER                            77700020
         RETURN (14,12)       RETURN TO CALLER                          78000020
         SPACE 3                                                        78030020
* NULL LINE EXIT. RESTART AUTOMATIC LINE PROMPTING IN CASE       A42960 78060020
* ATTENTION OCCURRED WHILE IN INPUT MODE                         A42960 78090020
         SPACE                                                          78120020
ATNOLINE EQU   *                                                 A42960 78150020
         RTAUTOPT  ,          RESTART AUTOMATIC LINE PROMPT      A42960 78180020
         B     ATEXIT         RETURN                             A42960 78210020
         EJECT                                                          78300020
**************************************************************** A42953 78700020
*                                                                A42953 79100020
* THE FOLLOWING SUBROUTINE IS INVOKED TO FREEMAIN EXCESS         A42953 79500020
* BUFFERS.  ZEROS IN THE LOW-ORDER THREE BYTES OF THE STORAGE    A42953 79900020
* WORD'ATBUFFER' INDICATE THAT NO BUFFER EXISTS TO BE FREED.     A42953 80300020
*                                                                A42953 80700020
**************************************************************** A42953 81100020
         SPACE 2                                                        81600020
ATFREEBF EQU   *                                                        81900020
         OC    ATBFRPT(L'ATBFRPT),ATBFRPT CHECK IF BUFFER EXISTS A42953 82000020
*                                  TO BE FREED.                  A42953 82100020
         BCR   NOBUFFER,REG6  IF NOT, RETURN TO CALLER.          A42953 82200020
         L     PARMREG1,ATBUFFER OBTAIN BUFFER ADDRESS.          A42953 82300020
         L     PARMREG0,ATFREEWD SUBPOOL NUMBER                  A42953 82400020
         AH    PARMREG0,D0(,PARMREG1) OBTAIN LENGTH OF BUFFER.   A42953 82500020
         FREEMAIN R,LV=(0),A=(1) RELEASE STORAGE.                A42953 82600020
         BR    REG6           RETURN TO CALLER.                  A42953 82700020
         SPACE 2                                                        83100020
*********************************************************************** 83400020
*                                                                       83700020
*                             LOCAL STORAGE                             84000020
*                                                                       84300020
*********************************************************************** 84600020
         SPACE 2                                                        84900020
* PARAMETER BLOCK FOR PUTGET SERVICE ROUTINE                     A42953 85400020
ATPTGTPB PUTGET TERMPUT=(EDIT,BREAKIN),TERMGET=(EDIT,WAIT),MF=L  A42953 85900020
         SPACE 2                                                        86400020
* ENTRY POINT FOR STACK DELETE AND TCLEARQ SUBROUTINE            A42953 86700020
* IN IKJEBEMA                                                           87000020
ATPTBMA2 DC    A(IKJEBMA2)   ENTRY ADDRESS                              87300020
         SPACE                                                          87360020
ATFREEWD DS    0A             FULLWORD FOR R-FORM OF FREEMAIN    A42953 87420020
         DC    AL1(SUBPL1)    SUBPOOL ONE                        A42953 87480020
         DC    AL3(L0)        FOR FREEMAIN LENGTH                A42953 87540020
         EJECT                                                          87600020
ATCOMMA  IKJEBECA             DEFINE EDIT COMMUNICATIONS AREA           87900020
         EJECT                                                          88200020
         ORG   CAATNWKA       DEFINE WORKAREA IN COMMUNICATION AREA     88500020
         SPACE 2                                                        88800020
ATWORKSV DS    0F             DEFINE IKJEBEAT WORK/SAVE AREA            89100020
ATSAVEA  DS    18F            SAVE AREA FOR THIS MODULE                 89400020
* THIS AREA IS CLEARED TO ZERO UPON ENTRY TO IKJEBEAT                   89700020
ATWORKA  DS    0F             WORK AREA FOR THIS MODULE                 90000020
ATTMPLST DS    3F             TMP STANDARD PARAMETER LIST               90300020
ATSRPLST DS    F              TMP SERVICE ROUTINE PARAMETER LIST        90600020
ATPARM   DS    5F             PARAMETER LIST FOR SERVICE ROUTINE        90900020
         SPACE                                                          90970020
ATLNWKA  EQU   *-ATWORKA      LENGTH OF WORK AREA ONLY           A42953 91040020
         SPACE                                                          91110020
         ORG   ATPARM         REUSE CORE                                91200020
ATWKAREA DS    5F             WORK AREA FOR IKJEBMA2                    91500020
         ORG   ATPARM         REUSE CORE                                91800020
ATBUFFER DS    0A             ADDRESS OF BUFFER TO BE FREED.     A42953 92100020
ATBFRECB DS    X              HIGH ORDER CONTAINS ECB INFO.      A42953 92400020
ATBFRPT  DS    AL3            3-BYTE BUFFER ADDRESS.             A42953 92700020
         ORG   ,              RESUME WORK AREA MAP.              A42953 93000020
         EJECT                                                          93300020
**************************************************************** A42960 93500020
*                                                                A42960 93700020
*                TERMINAL ATTENTION INTERRUPT ELEMENT            A42960 93900020
*                                                                A42960 94100020
**************************************************************** A42960 94300020
         SPACE                                                          94500020
         IKJTAIE                                                        94800020
         EJECT                                                          95100020
         IKJIOPL                                                        95400020
         EJECT                                                          95700020
         IKJPGPB                                                 A42953 96600020
         SPACE                                                          97500020
         END                                                            97800020
